src/HOL/Series.thy
author paulson
Thu Jan 07 17:40:55 2016 +0000 (2016-01-07)
changeset 62087 44841d07ef1d
parent 62049 b0f941e207cf
child 62217 527488dc8b90
permissions -rw-r--r--
revisions to limits and derivatives, plus new lemmas
     1 (*  Title       : Series.thy
     2     Author      : Jacques D. Fleuriot
     3     Copyright   : 1998  University of Cambridge
     4 
     5 Converted to Isar and polished by lcp
     6 Converted to setsum and polished yet more by TNN
     7 Additional contributions by Jeremy Avigad
     8 *)
     9 
    10 section \<open>Infinite Series\<close>
    11 
    12 theory Series
    13 imports Limits Inequalities
    14 begin
    15 
    16 subsection \<open>Definition of infinite summability\<close>
    17 
    18 definition
    19   sums :: "(nat \<Rightarrow> 'a::{topological_space, comm_monoid_add}) \<Rightarrow> 'a \<Rightarrow> bool"
    20   (infixr "sums" 80)
    21 where
    22   "f sums s \<longleftrightarrow> (\<lambda>n. \<Sum>i<n. f i) \<longlonglongrightarrow> s"
    23 
    24 definition summable :: "(nat \<Rightarrow> 'a::{topological_space, comm_monoid_add}) \<Rightarrow> bool" where
    25    "summable f \<longleftrightarrow> (\<exists>s. f sums s)"
    26 
    27 definition
    28   suminf :: "(nat \<Rightarrow> 'a::{topological_space, comm_monoid_add}) \<Rightarrow> 'a"
    29   (binder "\<Sum>" 10)
    30 where
    31   "suminf f = (THE s. f sums s)"
    32 
    33 lemma sums_def': "f sums s \<longleftrightarrow> (\<lambda>n. \<Sum>i = 0..n. f i) \<longlonglongrightarrow> s"
    34   apply (simp add: sums_def)
    35   apply (subst LIMSEQ_Suc_iff [symmetric])
    36   apply (simp only: lessThan_Suc_atMost atLeast0AtMost)
    37   done
    38 
    39 subsection \<open>Infinite summability on topological monoids\<close>
    40 
    41 lemma sums_subst[trans]: "f = g \<Longrightarrow> g sums z \<Longrightarrow> f sums z"
    42   by simp
    43 
    44 lemma sums_cong: "(\<And>n. f n = g n) \<Longrightarrow> f sums c \<longleftrightarrow> g sums c"
    45   by (drule ext) simp
    46 
    47 lemma sums_summable: "f sums l \<Longrightarrow> summable f"
    48   by (simp add: sums_def summable_def, blast)
    49 
    50 lemma summable_iff_convergent: "summable f \<longleftrightarrow> convergent (\<lambda>n. \<Sum>i<n. f i)"
    51   by (simp add: summable_def sums_def convergent_def)
    52 
    53 lemma summable_iff_convergent':
    54   "summable f \<longleftrightarrow> convergent (\<lambda>n. setsum f {..n})"
    55   by (simp_all only: summable_iff_convergent convergent_def
    56         lessThan_Suc_atMost [symmetric] LIMSEQ_Suc_iff[of "\<lambda>n. setsum f {..<n}"])
    57 
    58 lemma suminf_eq_lim: "suminf f = lim (\<lambda>n. \<Sum>i<n. f i)"
    59   by (simp add: suminf_def sums_def lim_def)
    60 
    61 lemma sums_zero[simp, intro]: "(\<lambda>n. 0) sums 0"
    62   unfolding sums_def by simp
    63 
    64 lemma summable_zero[simp, intro]: "summable (\<lambda>n. 0)"
    65   by (rule sums_zero [THEN sums_summable])
    66 
    67 lemma sums_group: "f sums s \<Longrightarrow> 0 < k \<Longrightarrow> (\<lambda>n. setsum f {n * k ..< n * k + k}) sums s"
    68   apply (simp only: sums_def setsum_nat_group tendsto_def eventually_sequentially)
    69   apply safe
    70   apply (erule_tac x=S in allE)
    71   apply safe
    72   apply (rule_tac x="N" in exI, safe)
    73   apply (drule_tac x="n*k" in spec)
    74   apply (erule mp)
    75   apply (erule order_trans)
    76   apply simp
    77   done
    78 
    79 lemma suminf_cong: "(\<And>n. f n = g n) \<Longrightarrow> suminf f = suminf g"
    80   by (rule arg_cong[of f g], rule ext) simp
    81 
    82 lemma summable_cong:
    83   assumes "eventually (\<lambda>x. f x = (g x :: 'a :: real_normed_vector)) sequentially"
    84   shows   "summable f = summable g"
    85 proof -
    86   from assms obtain N where N: "\<forall>n\<ge>N. f n = g n" by (auto simp: eventually_at_top_linorder)
    87   def C \<equiv> "(\<Sum>k<N. f k - g k)"
    88   from eventually_ge_at_top[of N]
    89     have "eventually (\<lambda>n. setsum f {..<n} = C + setsum g {..<n}) sequentially"
    90   proof eventually_elim
    91     fix n assume n: "n \<ge> N"
    92     from n have "{..<n} = {..<N} \<union> {N..<n}" by auto
    93     also have "setsum f ... = setsum f {..<N} + setsum f {N..<n}"
    94       by (intro setsum.union_disjoint) auto
    95     also from N have "setsum f {N..<n} = setsum g {N..<n}" by (intro setsum.cong) simp_all
    96     also have "setsum f {..<N} + setsum g {N..<n} = C + (setsum g {..<N} + setsum g {N..<n})"
    97       unfolding C_def by (simp add: algebra_simps setsum_subtractf)
    98     also have "setsum g {..<N} + setsum g {N..<n} = setsum g ({..<N} \<union> {N..<n})"
    99       by (intro setsum.union_disjoint [symmetric]) auto
   100     also from n have "{..<N} \<union> {N..<n} = {..<n}" by auto
   101     finally show "setsum f {..<n} = C + setsum g {..<n}" .
   102   qed
   103   from convergent_cong[OF this] show ?thesis
   104     by (simp add: summable_iff_convergent convergent_add_const_iff)
   105 qed
   106 
   107 lemma sums_finite:
   108   assumes [simp]: "finite N" and f: "\<And>n. n \<notin> N \<Longrightarrow> f n = 0"
   109   shows "f sums (\<Sum>n\<in>N. f n)"
   110 proof -
   111   { fix n
   112     have "setsum f {..<n + Suc (Max N)} = setsum f N"
   113     proof cases
   114       assume "N = {}"
   115       with f have "f = (\<lambda>x. 0)" by auto
   116       then show ?thesis by simp
   117     next
   118       assume [simp]: "N \<noteq> {}"
   119       show ?thesis
   120       proof (safe intro!: setsum.mono_neutral_right f)
   121         fix i assume "i \<in> N"
   122         then have "i \<le> Max N" by simp
   123         then show "i < n + Suc (Max N)" by simp
   124       qed
   125     qed }
   126   note eq = this
   127   show ?thesis unfolding sums_def
   128     by (rule LIMSEQ_offset[of _ "Suc (Max N)"])
   129        (simp add: eq atLeast0LessThan del: add_Suc_right)
   130 qed
   131 
   132 lemma summable_finite: "finite N \<Longrightarrow> (\<And>n. n \<notin> N \<Longrightarrow> f n = 0) \<Longrightarrow> summable f"
   133   by (rule sums_summable) (rule sums_finite)
   134 
   135 lemma sums_If_finite_set: "finite A \<Longrightarrow> (\<lambda>r. if r \<in> A then f r else 0) sums (\<Sum>r\<in>A. f r)"
   136   using sums_finite[of A "(\<lambda>r. if r \<in> A then f r else 0)"] by simp
   137 
   138 lemma summable_If_finite_set[simp, intro]: "finite A \<Longrightarrow> summable (\<lambda>r. if r \<in> A then f r else 0)"
   139   by (rule sums_summable) (rule sums_If_finite_set)
   140 
   141 lemma sums_If_finite: "finite {r. P r} \<Longrightarrow> (\<lambda>r. if P r then f r else 0) sums (\<Sum>r | P r. f r)"
   142   using sums_If_finite_set[of "{r. P r}"] by simp
   143 
   144 lemma summable_If_finite[simp, intro]: "finite {r. P r} \<Longrightarrow> summable (\<lambda>r. if P r then f r else 0)"
   145   by (rule sums_summable) (rule sums_If_finite)
   146 
   147 lemma sums_single: "(\<lambda>r. if r = i then f r else 0) sums f i"
   148   using sums_If_finite[of "\<lambda>r. r = i"] by simp
   149 
   150 lemma summable_single[simp, intro]: "summable (\<lambda>r. if r = i then f r else 0)"
   151   by (rule sums_summable) (rule sums_single)
   152 
   153 context
   154   fixes f :: "nat \<Rightarrow> 'a::{t2_space, comm_monoid_add}"
   155 begin
   156 
   157 lemma summable_sums[intro]: "summable f \<Longrightarrow> f sums (suminf f)"
   158   by (simp add: summable_def sums_def suminf_def)
   159      (metis convergent_LIMSEQ_iff convergent_def lim_def)
   160 
   161 lemma summable_LIMSEQ: "summable f \<Longrightarrow> (\<lambda>n. \<Sum>i<n. f i) \<longlonglongrightarrow> suminf f"
   162   by (rule summable_sums [unfolded sums_def])
   163 
   164 lemma sums_unique: "f sums s \<Longrightarrow> s = suminf f"
   165   by (metis limI suminf_eq_lim sums_def)
   166 
   167 lemma sums_iff: "f sums x \<longleftrightarrow> summable f \<and> (suminf f = x)"
   168   by (metis summable_sums sums_summable sums_unique)
   169 
   170 lemma summable_sums_iff:
   171   "summable (f :: nat \<Rightarrow> 'a :: {comm_monoid_add,t2_space}) \<longleftrightarrow> f sums suminf f"
   172   by (auto simp: sums_iff summable_sums)
   173 
   174 lemma sums_unique2:
   175   fixes a b :: "'a::{comm_monoid_add,t2_space}"
   176   shows "f sums a \<Longrightarrow> f sums b \<Longrightarrow> a = b"
   177 by (simp add: sums_iff)
   178 
   179 lemma suminf_finite:
   180   assumes N: "finite N" and f: "\<And>n. n \<notin> N \<Longrightarrow> f n = 0"
   181   shows "suminf f = (\<Sum>n\<in>N. f n)"
   182   using sums_finite[OF assms, THEN sums_unique] by simp
   183 
   184 end
   185 
   186 lemma suminf_zero[simp]: "suminf (\<lambda>n. 0::'a::{t2_space, comm_monoid_add}) = 0"
   187   by (rule sums_zero [THEN sums_unique, symmetric])
   188 
   189 
   190 subsection \<open>Infinite summability on ordered, topological monoids\<close>
   191 
   192 lemma sums_le:
   193   fixes f g :: "nat \<Rightarrow> 'a::{ordered_comm_monoid_add, linorder_topology}"
   194   shows "\<forall>n. f n \<le> g n \<Longrightarrow> f sums s \<Longrightarrow> g sums t \<Longrightarrow> s \<le> t"
   195   by (rule LIMSEQ_le) (auto intro: setsum_mono simp: sums_def)
   196 
   197 context
   198   fixes f :: "nat \<Rightarrow> 'a::{ordered_comm_monoid_add, linorder_topology}"
   199 begin
   200 
   201 lemma suminf_le: "\<lbrakk>\<forall>n. f n \<le> g n; summable f; summable g\<rbrakk> \<Longrightarrow> suminf f \<le> suminf g"
   202   by (auto dest: sums_summable intro: sums_le)
   203 
   204 lemma setsum_le_suminf: "summable f \<Longrightarrow> \<forall>m\<ge>n. 0 \<le> f m \<Longrightarrow> setsum f {..<n} \<le> suminf f"
   205   by (rule sums_le[OF _ sums_If_finite_set summable_sums]) auto
   206 
   207 lemma suminf_nonneg: "summable f \<Longrightarrow> \<forall>n. 0 \<le> f n \<Longrightarrow> 0 \<le> suminf f"
   208   using setsum_le_suminf[of 0] by simp
   209 
   210 lemma setsum_less_suminf2: "summable f \<Longrightarrow> \<forall>m\<ge>n. 0 \<le> f m \<Longrightarrow> n \<le> i \<Longrightarrow> 0 < f i \<Longrightarrow> setsum f {..<n} < suminf f"
   211   using
   212     setsum_le_suminf[of "Suc i"]
   213     add_strict_increasing[of "f i" "setsum f {..<n}" "setsum f {..<i}"]
   214     setsum_mono2[of "{..<i}" "{..<n}" f]
   215   by (auto simp: less_imp_le ac_simps)
   216 
   217 lemma setsum_less_suminf: "summable f \<Longrightarrow> \<forall>m\<ge>n. 0 < f m \<Longrightarrow> setsum f {..<n} < suminf f"
   218   using setsum_less_suminf2[of n n] by (simp add: less_imp_le)
   219 
   220 lemma suminf_pos2: "summable f \<Longrightarrow> \<forall>n. 0 \<le> f n \<Longrightarrow> 0 < f i \<Longrightarrow> 0 < suminf f"
   221   using setsum_less_suminf2[of 0 i] by simp
   222 
   223 lemma suminf_pos: "summable f \<Longrightarrow> \<forall>n. 0 < f n \<Longrightarrow> 0 < suminf f"
   224   using suminf_pos2[of 0] by (simp add: less_imp_le)
   225 
   226 lemma suminf_le_const: "summable f \<Longrightarrow> (\<And>n. setsum f {..<n} \<le> x) \<Longrightarrow> suminf f \<le> x"
   227   by (metis LIMSEQ_le_const2 summable_LIMSEQ)
   228 
   229 lemma suminf_eq_zero_iff: "summable f \<Longrightarrow> \<forall>n. 0 \<le> f n \<Longrightarrow> suminf f = 0 \<longleftrightarrow> (\<forall>n. f n = 0)"
   230 proof
   231   assume "summable f" "suminf f = 0" and pos: "\<forall>n. 0 \<le> f n"
   232   then have f: "(\<lambda>n. \<Sum>i<n. f i) \<longlonglongrightarrow> 0"
   233     using summable_LIMSEQ[of f] by simp
   234   then have "\<And>i. (\<Sum>n\<in>{i}. f n) \<le> 0"
   235   proof (rule LIMSEQ_le_const)
   236     fix i show "\<exists>N. \<forall>n\<ge>N. (\<Sum>n\<in>{i}. f n) \<le> setsum f {..<n}"
   237       using pos by (intro exI[of _ "Suc i"] allI impI setsum_mono2) auto
   238   qed
   239   with pos show "\<forall>n. f n = 0"
   240     by (auto intro!: antisym)
   241 qed (metis suminf_zero fun_eq_iff)
   242 
   243 lemma suminf_pos_iff: "summable f \<Longrightarrow> \<forall>n. 0 \<le> f n \<Longrightarrow> 0 < suminf f \<longleftrightarrow> (\<exists>i. 0 < f i)"
   244   using setsum_le_suminf[of 0] suminf_eq_zero_iff by (simp add: less_le)
   245 
   246 end
   247 
   248 lemma summableI_nonneg_bounded:
   249   fixes f:: "nat \<Rightarrow> 'a::{ordered_comm_monoid_add, linorder_topology, conditionally_complete_linorder}"
   250   assumes pos[simp]: "\<And>n. 0 \<le> f n" and le: "\<And>n. (\<Sum>i<n. f i) \<le> x"
   251   shows "summable f"
   252   unfolding summable_def sums_def[abs_def]
   253 proof (intro exI order_tendstoI)
   254   have [simp, intro]: "bdd_above (range (\<lambda>n. \<Sum>i<n. f i))"
   255     using le by (auto simp: bdd_above_def)
   256   { fix a assume "a < (SUP n. \<Sum>i<n. f i)"
   257     then obtain n where "a < (\<Sum>i<n. f i)"
   258       by (auto simp add: less_cSUP_iff)
   259     then have "\<And>m. n \<le> m \<Longrightarrow> a < (\<Sum>i<m. f i)"
   260       by (rule less_le_trans) (auto intro!: setsum_mono2)
   261     then show "eventually (\<lambda>n. a < (\<Sum>i<n. f i)) sequentially"
   262       by (auto simp: eventually_sequentially) }
   263   { fix a assume "(SUP n. \<Sum>i<n. f i) < a"
   264     moreover have "\<And>n. (\<Sum>i<n. f i) \<le> (SUP n. \<Sum>i<n. f i)"
   265       by (auto intro: cSUP_upper)
   266     ultimately show "eventually (\<lambda>n. (\<Sum>i<n. f i) < a) sequentially"
   267       by (auto intro: le_less_trans simp: eventually_sequentially) }
   268 qed
   269 
   270 
   271 subsection \<open>Infinite summability on real normed vector spaces\<close>
   272 
   273 lemma sums_Suc_iff:
   274   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   275   shows "(\<lambda>n. f (Suc n)) sums s \<longleftrightarrow> f sums (s + f 0)"
   276 proof -
   277   have "f sums (s + f 0) \<longleftrightarrow> (\<lambda>i. \<Sum>j<Suc i. f j) \<longlonglongrightarrow> s + f 0"
   278     by (subst LIMSEQ_Suc_iff) (simp add: sums_def)
   279   also have "\<dots> \<longleftrightarrow> (\<lambda>i. (\<Sum>j<i. f (Suc j)) + f 0) \<longlonglongrightarrow> s + f 0"
   280     by (simp add: ac_simps setsum.reindex image_iff lessThan_Suc_eq_insert_0)
   281   also have "\<dots> \<longleftrightarrow> (\<lambda>n. f (Suc n)) sums s"
   282   proof
   283     assume "(\<lambda>i. (\<Sum>j<i. f (Suc j)) + f 0) \<longlonglongrightarrow> s + f 0"
   284     with tendsto_add[OF this tendsto_const, of "- f 0"]
   285     show "(\<lambda>i. f (Suc i)) sums s"
   286       by (simp add: sums_def)
   287   qed (auto intro: tendsto_add simp: sums_def)
   288   finally show ?thesis ..
   289 qed
   290 
   291 lemma summable_Suc_iff: "summable (\<lambda>n. f (Suc n) :: 'a :: real_normed_vector) = summable f"
   292 proof
   293   assume "summable f"
   294   hence "f sums suminf f" by (rule summable_sums)
   295   hence "(\<lambda>n. f (Suc n)) sums (suminf f - f 0)" by (simp add: sums_Suc_iff)
   296   thus "summable (\<lambda>n. f (Suc n))" unfolding summable_def by blast
   297 qed (auto simp: sums_Suc_iff summable_def)
   298 
   299 context
   300   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   301 begin
   302 
   303 lemma sums_add: "f sums a \<Longrightarrow> g sums b \<Longrightarrow> (\<lambda>n. f n + g n) sums (a + b)"
   304   unfolding sums_def by (simp add: setsum.distrib tendsto_add)
   305 
   306 lemma summable_add: "summable f \<Longrightarrow> summable g \<Longrightarrow> summable (\<lambda>n. f n + g n)"
   307   unfolding summable_def by (auto intro: sums_add)
   308 
   309 lemma suminf_add: "summable f \<Longrightarrow> summable g \<Longrightarrow> suminf f + suminf g = (\<Sum>n. f n + g n)"
   310   by (intro sums_unique sums_add summable_sums)
   311 
   312 lemma sums_diff: "f sums a \<Longrightarrow> g sums b \<Longrightarrow> (\<lambda>n. f n - g n) sums (a - b)"
   313   unfolding sums_def by (simp add: setsum_subtractf tendsto_diff)
   314 
   315 lemma summable_diff: "summable f \<Longrightarrow> summable g \<Longrightarrow> summable (\<lambda>n. f n - g n)"
   316   unfolding summable_def by (auto intro: sums_diff)
   317 
   318 lemma suminf_diff: "summable f \<Longrightarrow> summable g \<Longrightarrow> suminf f - suminf g = (\<Sum>n. f n - g n)"
   319   by (intro sums_unique sums_diff summable_sums)
   320 
   321 lemma sums_minus: "f sums a \<Longrightarrow> (\<lambda>n. - f n) sums (- a)"
   322   unfolding sums_def by (simp add: setsum_negf tendsto_minus)
   323 
   324 lemma summable_minus: "summable f \<Longrightarrow> summable (\<lambda>n. - f n)"
   325   unfolding summable_def by (auto intro: sums_minus)
   326 
   327 lemma suminf_minus: "summable f \<Longrightarrow> (\<Sum>n. - f n) = - (\<Sum>n. f n)"
   328   by (intro sums_unique [symmetric] sums_minus summable_sums)
   329 
   330 lemma sums_Suc: "(\<lambda> n. f (Suc n)) sums l \<Longrightarrow> f sums (l + f 0)"
   331   by (simp add: sums_Suc_iff)
   332 
   333 lemma sums_iff_shift: "(\<lambda>i. f (i + n)) sums s \<longleftrightarrow> f sums (s + (\<Sum>i<n. f i))"
   334 proof (induct n arbitrary: s)
   335   case (Suc n)
   336   moreover have "(\<lambda>i. f (Suc i + n)) sums s \<longleftrightarrow> (\<lambda>i. f (i + n)) sums (s + f n)"
   337     by (subst sums_Suc_iff) simp
   338   ultimately show ?case
   339     by (simp add: ac_simps)
   340 qed simp
   341 
   342 lemma summable_iff_shift: "summable (\<lambda>n. f (n + k)) \<longleftrightarrow> summable f"
   343   by (metis diff_add_cancel summable_def sums_iff_shift[abs_def])
   344 
   345 lemma sums_split_initial_segment: "f sums s \<Longrightarrow> (\<lambda>i. f (i + n)) sums (s - (\<Sum>i<n. f i))"
   346   by (simp add: sums_iff_shift)
   347 
   348 lemma summable_ignore_initial_segment: "summable f \<Longrightarrow> summable (\<lambda>n. f(n + k))"
   349   by (simp add: summable_iff_shift)
   350 
   351 lemma suminf_minus_initial_segment: "summable f \<Longrightarrow> (\<Sum>n. f (n + k)) = (\<Sum>n. f n) - (\<Sum>i<k. f i)"
   352   by (rule sums_unique[symmetric]) (auto simp: sums_iff_shift)
   353 
   354 lemma suminf_split_initial_segment: "summable f \<Longrightarrow> suminf f = (\<Sum>n. f(n + k)) + (\<Sum>i<k. f i)"
   355   by (auto simp add: suminf_minus_initial_segment)
   356 
   357 lemma suminf_split_head: "summable f \<Longrightarrow> (\<Sum>n. f (Suc n)) = suminf f - f 0"
   358   using suminf_split_initial_segment[of 1] by simp
   359 
   360 lemma suminf_exist_split:
   361   fixes r :: real assumes "0 < r" and "summable f"
   362   shows "\<exists>N. \<forall>n\<ge>N. norm (\<Sum>i. f (i + n)) < r"
   363 proof -
   364   from LIMSEQ_D[OF summable_LIMSEQ[OF \<open>summable f\<close>] \<open>0 < r\<close>]
   365   obtain N :: nat where "\<forall> n \<ge> N. norm (setsum f {..<n} - suminf f) < r" by auto
   366   thus ?thesis
   367     by (auto simp: norm_minus_commute suminf_minus_initial_segment[OF \<open>summable f\<close>])
   368 qed
   369 
   370 lemma summable_LIMSEQ_zero: "summable f \<Longrightarrow> f \<longlonglongrightarrow> 0"
   371   apply (drule summable_iff_convergent [THEN iffD1])
   372   apply (drule convergent_Cauchy)
   373   apply (simp only: Cauchy_iff LIMSEQ_iff, safe)
   374   apply (drule_tac x="r" in spec, safe)
   375   apply (rule_tac x="M" in exI, safe)
   376   apply (drule_tac x="Suc n" in spec, simp)
   377   apply (drule_tac x="n" in spec, simp)
   378   done
   379 
   380 lemma summable_imp_convergent:
   381   "summable (f :: nat \<Rightarrow> 'a) \<Longrightarrow> convergent f"
   382   by (force dest!: summable_LIMSEQ_zero simp: convergent_def)
   383 
   384 lemma summable_imp_Bseq:
   385   "summable f \<Longrightarrow> Bseq (f :: nat \<Rightarrow> 'a :: real_normed_vector)"
   386   by (simp add: convergent_imp_Bseq summable_imp_convergent)
   387 
   388 end
   389 
   390 lemma summable_minus_iff:
   391   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   392   shows "summable (\<lambda>n. - f n) \<longleftrightarrow> summable f"
   393   by (auto dest: summable_minus) \<comment>\<open>used two ways, hence must be outside the context above\<close>
   394 
   395 
   396 context
   397   fixes f :: "'i \<Rightarrow> nat \<Rightarrow> 'a::real_normed_vector" and I :: "'i set"
   398 begin
   399 
   400 lemma sums_setsum: "(\<And>i. i \<in> I \<Longrightarrow> (f i) sums (x i)) \<Longrightarrow> (\<lambda>n. \<Sum>i\<in>I. f i n) sums (\<Sum>i\<in>I. x i)"
   401   by (induct I rule: infinite_finite_induct) (auto intro!: sums_add)
   402 
   403 lemma suminf_setsum: "(\<And>i. i \<in> I \<Longrightarrow> summable (f i)) \<Longrightarrow> (\<Sum>n. \<Sum>i\<in>I. f i n) = (\<Sum>i\<in>I. \<Sum>n. f i n)"
   404   using sums_unique[OF sums_setsum, OF summable_sums] by simp
   405 
   406 lemma summable_setsum: "(\<And>i. i \<in> I \<Longrightarrow> summable (f i)) \<Longrightarrow> summable (\<lambda>n. \<Sum>i\<in>I. f i n)"
   407   using sums_summable[OF sums_setsum[OF summable_sums]] .
   408 
   409 end
   410 
   411 lemma (in bounded_linear) sums: "(\<lambda>n. X n) sums a \<Longrightarrow> (\<lambda>n. f (X n)) sums (f a)"
   412   unfolding sums_def by (drule tendsto, simp only: setsum)
   413 
   414 lemma (in bounded_linear) summable: "summable (\<lambda>n. X n) \<Longrightarrow> summable (\<lambda>n. f (X n))"
   415   unfolding summable_def by (auto intro: sums)
   416 
   417 lemma (in bounded_linear) suminf: "summable (\<lambda>n. X n) \<Longrightarrow> f (\<Sum>n. X n) = (\<Sum>n. f (X n))"
   418   by (intro sums_unique sums summable_sums)
   419 
   420 lemmas sums_of_real = bounded_linear.sums [OF bounded_linear_of_real]
   421 lemmas summable_of_real = bounded_linear.summable [OF bounded_linear_of_real]
   422 lemmas suminf_of_real = bounded_linear.suminf [OF bounded_linear_of_real]
   423 
   424 lemmas sums_scaleR_left = bounded_linear.sums[OF bounded_linear_scaleR_left]
   425 lemmas summable_scaleR_left = bounded_linear.summable[OF bounded_linear_scaleR_left]
   426 lemmas suminf_scaleR_left = bounded_linear.suminf[OF bounded_linear_scaleR_left]
   427 
   428 lemmas sums_scaleR_right = bounded_linear.sums[OF bounded_linear_scaleR_right]
   429 lemmas summable_scaleR_right = bounded_linear.summable[OF bounded_linear_scaleR_right]
   430 lemmas suminf_scaleR_right = bounded_linear.suminf[OF bounded_linear_scaleR_right]
   431 
   432 lemma summable_const_iff: "summable (\<lambda>_. c) \<longleftrightarrow> (c :: 'a :: real_normed_vector) = 0"
   433 proof -
   434   {
   435     assume "c \<noteq> 0"
   436     hence "filterlim (\<lambda>n. of_nat n * norm c) at_top sequentially"
   437       by (subst mult.commute)
   438          (auto intro!: filterlim_tendsto_pos_mult_at_top filterlim_real_sequentially)
   439     hence "\<not>convergent (\<lambda>n. norm (\<Sum>k<n. c))"
   440       by (intro filterlim_at_infinity_imp_not_convergent filterlim_at_top_imp_at_infinity)
   441          (simp_all add: setsum_constant_scaleR)
   442     hence "\<not>summable (\<lambda>_. c)" unfolding summable_iff_convergent using convergent_norm by blast
   443   }
   444   thus ?thesis by auto
   445 qed
   446 
   447 
   448 subsection \<open>Infinite summability on real normed algebras\<close>
   449 
   450 context
   451   fixes f :: "nat \<Rightarrow> 'a::real_normed_algebra"
   452 begin
   453 
   454 lemma sums_mult: "f sums a \<Longrightarrow> (\<lambda>n. c * f n) sums (c * a)"
   455   by (rule bounded_linear.sums [OF bounded_linear_mult_right])
   456 
   457 lemma summable_mult: "summable f \<Longrightarrow> summable (\<lambda>n. c * f n)"
   458   by (rule bounded_linear.summable [OF bounded_linear_mult_right])
   459 
   460 lemma suminf_mult: "summable f \<Longrightarrow> suminf (\<lambda>n. c * f n) = c * suminf f"
   461   by (rule bounded_linear.suminf [OF bounded_linear_mult_right, symmetric])
   462 
   463 lemma sums_mult2: "f sums a \<Longrightarrow> (\<lambda>n. f n * c) sums (a * c)"
   464   by (rule bounded_linear.sums [OF bounded_linear_mult_left])
   465 
   466 lemma summable_mult2: "summable f \<Longrightarrow> summable (\<lambda>n. f n * c)"
   467   by (rule bounded_linear.summable [OF bounded_linear_mult_left])
   468 
   469 lemma suminf_mult2: "summable f \<Longrightarrow> suminf f * c = (\<Sum>n. f n * c)"
   470   by (rule bounded_linear.suminf [OF bounded_linear_mult_left])
   471 
   472 end
   473 
   474 lemma sums_mult_iff:
   475   assumes "c \<noteq> 0"
   476   shows   "(\<lambda>n. c * f n :: 'a :: {real_normed_algebra,field}) sums (c * d) \<longleftrightarrow> f sums d"
   477   using sums_mult[of f d c] sums_mult[of "\<lambda>n. c * f n" "c * d" "inverse c"]
   478   by (force simp: field_simps assms)
   479 
   480 lemma sums_mult2_iff:
   481   assumes "c \<noteq> (0 :: 'a :: {real_normed_algebra, field})"
   482   shows   "(\<lambda>n. f n * c) sums (d * c) \<longleftrightarrow> f sums d"
   483   using sums_mult_iff[OF assms, of f d] by (simp add: mult.commute)
   484 
   485 lemma sums_of_real_iff:
   486   "(\<lambda>n. of_real (f n) :: 'a :: real_normed_div_algebra) sums of_real c \<longleftrightarrow> f sums c"
   487   by (simp add: sums_def of_real_setsum[symmetric] tendsto_of_real_iff del: of_real_setsum)
   488 
   489 
   490 subsection \<open>Infinite summability on real normed fields\<close>
   491 
   492 context
   493   fixes c :: "'a::real_normed_field"
   494 begin
   495 
   496 lemma sums_divide: "f sums a \<Longrightarrow> (\<lambda>n. f n / c) sums (a / c)"
   497   by (rule bounded_linear.sums [OF bounded_linear_divide])
   498 
   499 lemma summable_divide: "summable f \<Longrightarrow> summable (\<lambda>n. f n / c)"
   500   by (rule bounded_linear.summable [OF bounded_linear_divide])
   501 
   502 lemma suminf_divide: "summable f \<Longrightarrow> suminf (\<lambda>n. f n / c) = suminf f / c"
   503   by (rule bounded_linear.suminf [OF bounded_linear_divide, symmetric])
   504 
   505 text\<open>Sum of a geometric progression.\<close>
   506 
   507 lemma geometric_sums: "norm c < 1 \<Longrightarrow> (\<lambda>n. c^n) sums (1 / (1 - c))"
   508 proof -
   509   assume less_1: "norm c < 1"
   510   hence neq_1: "c \<noteq> 1" by auto
   511   hence neq_0: "c - 1 \<noteq> 0" by simp
   512   from less_1 have lim_0: "(\<lambda>n. c^n) \<longlonglongrightarrow> 0"
   513     by (rule LIMSEQ_power_zero)
   514   hence "(\<lambda>n. c ^ n / (c - 1) - 1 / (c - 1)) \<longlonglongrightarrow> 0 / (c - 1) - 1 / (c - 1)"
   515     using neq_0 by (intro tendsto_intros)
   516   hence "(\<lambda>n. (c ^ n - 1) / (c - 1)) \<longlonglongrightarrow> 1 / (1 - c)"
   517     by (simp add: nonzero_minus_divide_right [OF neq_0] diff_divide_distrib)
   518   thus "(\<lambda>n. c ^ n) sums (1 / (1 - c))"
   519     by (simp add: sums_def geometric_sum neq_1)
   520 qed
   521 
   522 lemma summable_geometric: "norm c < 1 \<Longrightarrow> summable (\<lambda>n. c^n)"
   523   by (rule geometric_sums [THEN sums_summable])
   524 
   525 lemma suminf_geometric: "norm c < 1 \<Longrightarrow> suminf (\<lambda>n. c^n) = 1 / (1 - c)"
   526   by (rule sums_unique[symmetric]) (rule geometric_sums)
   527 
   528 lemma summable_geometric_iff: "summable (\<lambda>n. c ^ n) \<longleftrightarrow> norm c < 1"
   529 proof
   530   assume "summable (\<lambda>n. c ^ n :: 'a :: real_normed_field)"
   531   hence "(\<lambda>n. norm c ^ n) \<longlonglongrightarrow> 0"
   532     by (simp add: norm_power [symmetric] tendsto_norm_zero_iff summable_LIMSEQ_zero)
   533   from order_tendstoD(2)[OF this zero_less_one] obtain n where "norm c ^ n < 1"
   534     by (auto simp: eventually_at_top_linorder)
   535   thus "norm c < 1" using one_le_power[of "norm c" n] by (cases "norm c \<ge> 1") (linarith, simp)
   536 qed (rule summable_geometric)
   537 
   538 end
   539 
   540 lemma power_half_series: "(\<lambda>n. (1/2::real)^Suc n) sums 1"
   541 proof -
   542   have 2: "(\<lambda>n. (1/2::real)^n) sums 2" using geometric_sums [of "1/2::real"]
   543     by auto
   544   have "(\<lambda>n. (1/2::real)^Suc n) = (\<lambda>n. (1 / 2) ^ n / 2)"
   545     by (simp add: mult.commute)
   546   thus ?thesis using sums_divide [OF 2, of 2]
   547     by simp
   548 qed
   549 
   550 
   551 subsection \<open>Telescoping\<close>
   552 
   553 lemma telescope_sums:
   554   assumes "f \<longlonglongrightarrow> (c :: 'a :: real_normed_vector)"
   555   shows   "(\<lambda>n. f (Suc n) - f n) sums (c - f 0)"
   556   unfolding sums_def
   557 proof (subst LIMSEQ_Suc_iff [symmetric])
   558   have "(\<lambda>n. \<Sum>k<Suc n. f (Suc k) - f k) = (\<lambda>n. f (Suc n) - f 0)"
   559     by (simp add: lessThan_Suc_atMost atLeast0AtMost [symmetric] setsum_Suc_diff)
   560   also have "\<dots> \<longlonglongrightarrow> c - f 0" by (intro tendsto_diff LIMSEQ_Suc[OF assms] tendsto_const)
   561   finally show "(\<lambda>n. \<Sum>n<Suc n. f (Suc n) - f n) \<longlonglongrightarrow> c - f 0" .
   562 qed
   563 
   564 lemma telescope_sums':
   565   assumes "f \<longlonglongrightarrow> (c :: 'a :: real_normed_vector)"
   566   shows   "(\<lambda>n. f n - f (Suc n)) sums (f 0 - c)"
   567   using sums_minus[OF telescope_sums[OF assms]] by (simp add: algebra_simps)
   568 
   569 lemma telescope_summable:
   570   assumes "f \<longlonglongrightarrow> (c :: 'a :: real_normed_vector)"
   571   shows   "summable (\<lambda>n. f (Suc n) - f n)"
   572   using telescope_sums[OF assms] by (simp add: sums_iff)
   573 
   574 lemma telescope_summable':
   575   assumes "f \<longlonglongrightarrow> (c :: 'a :: real_normed_vector)"
   576   shows   "summable (\<lambda>n. f n - f (Suc n))"
   577   using summable_minus[OF telescope_summable[OF assms]] by (simp add: algebra_simps)
   578 
   579 
   580 subsection \<open>Infinite summability on Banach spaces\<close>
   581 
   582 text\<open>Cauchy-type criterion for convergence of series (c.f. Harrison)\<close>
   583 
   584 lemma summable_Cauchy:
   585   fixes f :: "nat \<Rightarrow> 'a::banach"
   586   shows "summable f \<longleftrightarrow> (\<forall>e>0. \<exists>N. \<forall>m\<ge>N. \<forall>n. norm (setsum f {m..<n}) < e)"
   587   apply (simp only: summable_iff_convergent Cauchy_convergent_iff [symmetric] Cauchy_iff, safe)
   588   apply (drule spec, drule (1) mp)
   589   apply (erule exE, rule_tac x="M" in exI, clarify)
   590   apply (rule_tac x="m" and y="n" in linorder_le_cases)
   591   apply (frule (1) order_trans)
   592   apply (drule_tac x="n" in spec, drule (1) mp)
   593   apply (drule_tac x="m" in spec, drule (1) mp)
   594   apply (simp_all add: setsum_diff [symmetric])
   595   apply (drule spec, drule (1) mp)
   596   apply (erule exE, rule_tac x="N" in exI, clarify)
   597   apply (rule_tac x="m" and y="n" in linorder_le_cases)
   598   apply (subst norm_minus_commute)
   599   apply (simp_all add: setsum_diff [symmetric])
   600   done
   601 
   602 context
   603   fixes f :: "nat \<Rightarrow> 'a::banach"
   604 begin
   605 
   606 text\<open>Absolute convergence imples normal convergence\<close>
   607 
   608 lemma summable_norm_cancel: "summable (\<lambda>n. norm (f n)) \<Longrightarrow> summable f"
   609   apply (simp only: summable_Cauchy, safe)
   610   apply (drule_tac x="e" in spec, safe)
   611   apply (rule_tac x="N" in exI, safe)
   612   apply (drule_tac x="m" in spec, safe)
   613   apply (rule order_le_less_trans [OF norm_setsum])
   614   apply (rule order_le_less_trans [OF abs_ge_self])
   615   apply simp
   616   done
   617 
   618 lemma summable_norm: "summable (\<lambda>n. norm (f n)) \<Longrightarrow> norm (suminf f) \<le> (\<Sum>n. norm (f n))"
   619   by (auto intro: LIMSEQ_le tendsto_norm summable_norm_cancel summable_LIMSEQ norm_setsum)
   620 
   621 text \<open>Comparison tests\<close>
   622 
   623 lemma summable_comparison_test: "\<exists>N. \<forall>n\<ge>N. norm (f n) \<le> g n \<Longrightarrow> summable g \<Longrightarrow> summable f"
   624   apply (simp add: summable_Cauchy, safe)
   625   apply (drule_tac x="e" in spec, safe)
   626   apply (rule_tac x = "N + Na" in exI, safe)
   627   apply (rotate_tac 2)
   628   apply (drule_tac x = m in spec)
   629   apply (auto, rotate_tac 2, drule_tac x = n in spec)
   630   apply (rule_tac y = "\<Sum>k=m..<n. norm (f k)" in order_le_less_trans)
   631   apply (rule norm_setsum)
   632   apply (rule_tac y = "setsum g {m..<n}" in order_le_less_trans)
   633   apply (auto intro: setsum_mono simp add: abs_less_iff)
   634   done
   635 
   636 lemma summable_comparison_test_ev:
   637   shows "eventually (\<lambda>n. norm (f n) \<le> g n) sequentially \<Longrightarrow> summable g \<Longrightarrow> summable f"
   638   by (rule summable_comparison_test) (auto simp: eventually_at_top_linorder)
   639 
   640 (*A better argument order*)
   641 lemma summable_comparison_test': "summable g \<Longrightarrow> (\<And>n. n \<ge> N \<Longrightarrow> norm(f n) \<le> g n) \<Longrightarrow> summable f"
   642   by (rule summable_comparison_test) auto
   643 
   644 subsection \<open>The Ratio Test\<close>
   645 
   646 lemma summable_ratio_test:
   647   assumes "c < 1" "\<And>n. n \<ge> N \<Longrightarrow> norm (f (Suc n)) \<le> c * norm (f n)"
   648   shows "summable f"
   649 proof cases
   650   assume "0 < c"
   651   show "summable f"
   652   proof (rule summable_comparison_test)
   653     show "\<exists>N'. \<forall>n\<ge>N'. norm (f n) \<le> (norm (f N) / (c ^ N)) * c ^ n"
   654     proof (intro exI allI impI)
   655       fix n assume "N \<le> n" then show "norm (f n) \<le> (norm (f N) / (c ^ N)) * c ^ n"
   656       proof (induct rule: inc_induct)
   657         case (step m)
   658         moreover have "norm (f (Suc m)) / c ^ Suc m * c ^ n \<le> norm (f m) / c ^ m * c ^ n"
   659           using \<open>0 < c\<close> \<open>c < 1\<close> assms(2)[OF \<open>N \<le> m\<close>] by (simp add: field_simps)
   660         ultimately show ?case by simp
   661       qed (insert \<open>0 < c\<close>, simp)
   662     qed
   663     show "summable (\<lambda>n. norm (f N) / c ^ N * c ^ n)"
   664       using \<open>0 < c\<close> \<open>c < 1\<close> by (intro summable_mult summable_geometric) simp
   665   qed
   666 next
   667   assume c: "\<not> 0 < c"
   668   { fix n assume "n \<ge> N"
   669     then have "norm (f (Suc n)) \<le> c * norm (f n)"
   670       by fact
   671     also have "\<dots> \<le> 0"
   672       using c by (simp add: not_less mult_nonpos_nonneg)
   673     finally have "f (Suc n) = 0"
   674       by auto }
   675   then show "summable f"
   676     by (intro sums_summable[OF sums_finite, of "{.. Suc N}"]) (auto simp: not_le Suc_less_eq2)
   677 qed
   678 
   679 end
   680 
   681 text\<open>Relations among convergence and absolute convergence for power series.\<close>
   682 
   683 lemma Abel_lemma:
   684   fixes a :: "nat \<Rightarrow> 'a::real_normed_vector"
   685   assumes r: "0 \<le> r" and r0: "r < r0" and M: "\<And>n. norm (a n) * r0^n \<le> M"
   686     shows "summable (\<lambda>n. norm (a n) * r^n)"
   687 proof (rule summable_comparison_test')
   688   show "summable (\<lambda>n. M * (r / r0) ^ n)"
   689     using assms
   690     by (auto simp add: summable_mult summable_geometric)
   691 next
   692   fix n
   693   show "norm (norm (a n) * r ^ n) \<le> M * (r / r0) ^ n"
   694     using r r0 M [of n]
   695     apply (auto simp add: abs_mult field_simps)
   696     apply (cases "r=0", simp)
   697     apply (cases n, auto)
   698     done
   699 qed
   700 
   701 
   702 text\<open>Summability of geometric series for real algebras\<close>
   703 
   704 lemma complete_algebra_summable_geometric:
   705   fixes x :: "'a::{real_normed_algebra_1,banach}"
   706   shows "norm x < 1 \<Longrightarrow> summable (\<lambda>n. x ^ n)"
   707 proof (rule summable_comparison_test)
   708   show "\<exists>N. \<forall>n\<ge>N. norm (x ^ n) \<le> norm x ^ n"
   709     by (simp add: norm_power_ineq)
   710   show "norm x < 1 \<Longrightarrow> summable (\<lambda>n. norm x ^ n)"
   711     by (simp add: summable_geometric)
   712 qed
   713 
   714 subsection \<open>Cauchy Product Formula\<close>
   715 
   716 text \<open>
   717   Proof based on Analysis WebNotes: Chapter 07, Class 41
   718   @{url "http://www.math.unl.edu/~webnotes/classes/class41/prp77.htm"}
   719 \<close>
   720 
   721 lemma Cauchy_product_sums:
   722   fixes a b :: "nat \<Rightarrow> 'a::{real_normed_algebra,banach}"
   723   assumes a: "summable (\<lambda>k. norm (a k))"
   724   assumes b: "summable (\<lambda>k. norm (b k))"
   725   shows "(\<lambda>k. \<Sum>i\<le>k. a i * b (k - i)) sums ((\<Sum>k. a k) * (\<Sum>k. b k))"
   726 proof -
   727   let ?S1 = "\<lambda>n::nat. {..<n} \<times> {..<n}"
   728   let ?S2 = "\<lambda>n::nat. {(i,j). i + j < n}"
   729   have S1_mono: "\<And>m n. m \<le> n \<Longrightarrow> ?S1 m \<subseteq> ?S1 n" by auto
   730   have S2_le_S1: "\<And>n. ?S2 n \<subseteq> ?S1 n" by auto
   731   have S1_le_S2: "\<And>n. ?S1 (n div 2) \<subseteq> ?S2 n" by auto
   732   have finite_S1: "\<And>n. finite (?S1 n)" by simp
   733   with S2_le_S1 have finite_S2: "\<And>n. finite (?S2 n)" by (rule finite_subset)
   734 
   735   let ?g = "\<lambda>(i,j). a i * b j"
   736   let ?f = "\<lambda>(i,j). norm (a i) * norm (b j)"
   737   have f_nonneg: "\<And>x. 0 \<le> ?f x" by (auto)
   738   hence norm_setsum_f: "\<And>A. norm (setsum ?f A) = setsum ?f A"
   739     unfolding real_norm_def
   740     by (simp only: abs_of_nonneg setsum_nonneg [rule_format])
   741 
   742   have "(\<lambda>n. (\<Sum>k<n. a k) * (\<Sum>k<n. b k)) \<longlonglongrightarrow> (\<Sum>k. a k) * (\<Sum>k. b k)"
   743     by (intro tendsto_mult summable_LIMSEQ summable_norm_cancel [OF a] summable_norm_cancel [OF b])
   744   hence 1: "(\<lambda>n. setsum ?g (?S1 n)) \<longlonglongrightarrow> (\<Sum>k. a k) * (\<Sum>k. b k)"
   745     by (simp only: setsum_product setsum.Sigma [rule_format] finite_lessThan)
   746 
   747   have "(\<lambda>n. (\<Sum>k<n. norm (a k)) * (\<Sum>k<n. norm (b k))) \<longlonglongrightarrow> (\<Sum>k. norm (a k)) * (\<Sum>k. norm (b k))"
   748     using a b by (intro tendsto_mult summable_LIMSEQ)
   749   hence "(\<lambda>n. setsum ?f (?S1 n)) \<longlonglongrightarrow> (\<Sum>k. norm (a k)) * (\<Sum>k. norm (b k))"
   750     by (simp only: setsum_product setsum.Sigma [rule_format] finite_lessThan)
   751   hence "convergent (\<lambda>n. setsum ?f (?S1 n))"
   752     by (rule convergentI)
   753   hence Cauchy: "Cauchy (\<lambda>n. setsum ?f (?S1 n))"
   754     by (rule convergent_Cauchy)
   755   have "Zfun (\<lambda>n. setsum ?f (?S1 n - ?S2 n)) sequentially"
   756   proof (rule ZfunI, simp only: eventually_sequentially norm_setsum_f)
   757     fix r :: real
   758     assume r: "0 < r"
   759     from CauchyD [OF Cauchy r] obtain N
   760     where "\<forall>m\<ge>N. \<forall>n\<ge>N. norm (setsum ?f (?S1 m) - setsum ?f (?S1 n)) < r" ..
   761     hence "\<And>m n. \<lbrakk>N \<le> n; n \<le> m\<rbrakk> \<Longrightarrow> norm (setsum ?f (?S1 m - ?S1 n)) < r"
   762       by (simp only: setsum_diff finite_S1 S1_mono)
   763     hence N: "\<And>m n. \<lbrakk>N \<le> n; n \<le> m\<rbrakk> \<Longrightarrow> setsum ?f (?S1 m - ?S1 n) < r"
   764       by (simp only: norm_setsum_f)
   765     show "\<exists>N. \<forall>n\<ge>N. setsum ?f (?S1 n - ?S2 n) < r"
   766     proof (intro exI allI impI)
   767       fix n assume "2 * N \<le> n"
   768       hence n: "N \<le> n div 2" by simp
   769       have "setsum ?f (?S1 n - ?S2 n) \<le> setsum ?f (?S1 n - ?S1 (n div 2))"
   770         by (intro setsum_mono2 finite_Diff finite_S1 f_nonneg
   771                   Diff_mono subset_refl S1_le_S2)
   772       also have "\<dots> < r"
   773         using n div_le_dividend by (rule N)
   774       finally show "setsum ?f (?S1 n - ?S2 n) < r" .
   775     qed
   776   qed
   777   hence "Zfun (\<lambda>n. setsum ?g (?S1 n - ?S2 n)) sequentially"
   778     apply (rule Zfun_le [rule_format])
   779     apply (simp only: norm_setsum_f)
   780     apply (rule order_trans [OF norm_setsum setsum_mono])
   781     apply (auto simp add: norm_mult_ineq)
   782     done
   783   hence 2: "(\<lambda>n. setsum ?g (?S1 n) - setsum ?g (?S2 n)) \<longlonglongrightarrow> 0"
   784     unfolding tendsto_Zfun_iff diff_0_right
   785     by (simp only: setsum_diff finite_S1 S2_le_S1)
   786 
   787   with 1 have "(\<lambda>n. setsum ?g (?S2 n)) \<longlonglongrightarrow> (\<Sum>k. a k) * (\<Sum>k. b k)"
   788     by (rule Lim_transform2)
   789   thus ?thesis by (simp only: sums_def setsum_triangle_reindex)
   790 qed
   791 
   792 lemma Cauchy_product:
   793   fixes a b :: "nat \<Rightarrow> 'a::{real_normed_algebra,banach}"
   794   assumes a: "summable (\<lambda>k. norm (a k))"
   795   assumes b: "summable (\<lambda>k. norm (b k))"
   796   shows "(\<Sum>k. a k) * (\<Sum>k. b k) = (\<Sum>k. \<Sum>i\<le>k. a i * b (k - i))"
   797   using a b
   798   by (rule Cauchy_product_sums [THEN sums_unique])
   799 
   800 lemma summable_Cauchy_product:
   801   assumes "summable (\<lambda>k. norm (a k :: 'a :: {real_normed_algebra,banach}))"
   802           "summable (\<lambda>k. norm (b k))"
   803   shows   "summable (\<lambda>k. \<Sum>i\<le>k. a i * b (k - i))"
   804   using Cauchy_product_sums[OF assms] by (simp add: sums_iff)
   805 
   806 subsection \<open>Series on @{typ real}s\<close>
   807 
   808 lemma summable_norm_comparison_test: "\<exists>N. \<forall>n\<ge>N. norm (f n) \<le> g n \<Longrightarrow> summable g \<Longrightarrow> summable (\<lambda>n. norm (f n))"
   809   by (rule summable_comparison_test) auto
   810 
   811 lemma summable_rabs_comparison_test: "\<lbrakk>\<exists>N. \<forall>n\<ge>N. \<bar>f n\<bar> \<le> g n; summable g\<rbrakk> \<Longrightarrow> summable (\<lambda>n. \<bar>f n :: real\<bar>)"
   812   by (rule summable_comparison_test) auto
   813 
   814 lemma summable_rabs_cancel: "summable (\<lambda>n. \<bar>f n :: real\<bar>) \<Longrightarrow> summable f"
   815   by (rule summable_norm_cancel) simp
   816 
   817 lemma summable_rabs: "summable (\<lambda>n. \<bar>f n :: real\<bar>) \<Longrightarrow> \<bar>suminf f\<bar> \<le> (\<Sum>n. \<bar>f n\<bar>)"
   818   by (fold real_norm_def) (rule summable_norm)
   819 
   820 lemma summable_zero_power [simp]: "summable (\<lambda>n. 0 ^ n :: 'a :: {comm_ring_1,topological_space})"
   821 proof -
   822   have "(\<lambda>n. 0 ^ n :: 'a) = (\<lambda>n. if n = 0 then 0^0 else 0)" by (intro ext) (simp add: zero_power)
   823   moreover have "summable \<dots>" by simp
   824   ultimately show ?thesis by simp
   825 qed
   826 
   827 lemma summable_zero_power' [simp]: "summable (\<lambda>n. f n * 0 ^ n :: 'a :: {ring_1,topological_space})"
   828 proof -
   829   have "(\<lambda>n. f n * 0 ^ n :: 'a) = (\<lambda>n. if n = 0 then f 0 * 0^0 else 0)"
   830     by (intro ext) (simp add: zero_power)
   831   moreover have "summable \<dots>" by simp
   832   ultimately show ?thesis by simp
   833 qed
   834 
   835 lemma summable_power_series:
   836   fixes z :: real
   837   assumes le_1: "\<And>i. f i \<le> 1" and nonneg: "\<And>i. 0 \<le> f i" and z: "0 \<le> z" "z < 1"
   838   shows "summable (\<lambda>i. f i * z^i)"
   839 proof (rule summable_comparison_test[OF _ summable_geometric])
   840   show "norm z < 1" using z by (auto simp: less_imp_le)
   841   show "\<And>n. \<exists>N. \<forall>na\<ge>N. norm (f na * z ^ na) \<le> z ^ na"
   842     using z by (auto intro!: exI[of _ 0] mult_left_le_one_le simp: abs_mult nonneg power_abs less_imp_le le_1)
   843 qed
   844 
   845 lemma summable_0_powser:
   846   "summable (\<lambda>n. f n * 0 ^ n :: 'a :: real_normed_div_algebra)"
   847 proof -
   848   have A: "(\<lambda>n. f n * 0 ^ n) = (\<lambda>n. if n = 0 then f n else 0)"
   849     by (intro ext) auto
   850   thus ?thesis by (subst A) simp_all
   851 qed
   852 
   853 lemma summable_powser_split_head:
   854   "summable (\<lambda>n. f (Suc n) * z ^ n :: 'a :: real_normed_div_algebra) = summable (\<lambda>n. f n * z ^ n)"
   855 proof -
   856   have "summable (\<lambda>n. f (Suc n) * z ^ n) \<longleftrightarrow> summable (\<lambda>n. f (Suc n) * z ^ Suc n)"
   857   proof
   858     assume "summable (\<lambda>n. f (Suc n) * z ^ n)"
   859     from summable_mult2[OF this, of z] show "summable (\<lambda>n. f (Suc n) * z ^ Suc n)"
   860       by (simp add: power_commutes algebra_simps)
   861   next
   862     assume "summable (\<lambda>n. f (Suc n) * z ^ Suc n)"
   863     from summable_mult2[OF this, of "inverse z"] show "summable (\<lambda>n. f (Suc n) * z ^ n)"
   864       by (cases "z \<noteq> 0", subst (asm) power_Suc2) (simp_all add: algebra_simps)
   865   qed
   866   also have "\<dots> \<longleftrightarrow> summable (\<lambda>n. f n * z ^ n)" by (rule summable_Suc_iff)
   867   finally show ?thesis .
   868 qed
   869 
   870 lemma powser_split_head:
   871   assumes "summable (\<lambda>n. f n * z ^ n :: 'a :: {real_normed_div_algebra,banach})"
   872   shows   "suminf (\<lambda>n. f n * z ^ n) = f 0 + suminf (\<lambda>n. f (Suc n) * z ^ n) * z"
   873           "suminf (\<lambda>n. f (Suc n) * z ^ n) * z = suminf (\<lambda>n. f n * z ^ n) - f 0"
   874           "summable (\<lambda>n. f (Suc n) * z ^ n)"
   875 proof -
   876   from assms show "summable (\<lambda>n. f (Suc n) * z ^ n)" by (subst summable_powser_split_head)
   877 
   878   from suminf_mult2[OF this, of z]
   879     have "(\<Sum>n. f (Suc n) * z ^ n) * z = (\<Sum>n. f (Suc n) * z ^ Suc n)"
   880     by (simp add: power_commutes algebra_simps)
   881   also from assms have "\<dots> = suminf (\<lambda>n. f n * z ^ n) - f 0"
   882     by (subst suminf_split_head) simp_all
   883   finally show "suminf (\<lambda>n. f n * z ^ n) = f 0 + suminf (\<lambda>n. f (Suc n) * z ^ n) * z" by simp
   884   thus "suminf (\<lambda>n. f (Suc n) * z ^ n) * z = suminf (\<lambda>n. f n * z ^ n) - f 0" by simp
   885 qed
   886 
   887 lemma summable_partial_sum_bound:
   888   fixes f :: "nat \<Rightarrow> 'a :: banach"
   889   assumes summable: "summable f" and e: "e > (0::real)"
   890   obtains N where "\<And>m n. m \<ge> N \<Longrightarrow> norm (\<Sum>k=m..n. f k) < e"
   891 proof -
   892   from summable have "Cauchy (\<lambda>n. \<Sum>k<n. f k)"
   893     by (simp add: Cauchy_convergent_iff summable_iff_convergent)
   894   from CauchyD[OF this e] obtain N
   895     where N: "\<And>m n. m \<ge> N \<Longrightarrow> n \<ge> N \<Longrightarrow> norm ((\<Sum>k<m. f k) - (\<Sum>k<n. f k)) < e" by blast
   896   {
   897     fix m n :: nat assume m: "m \<ge> N"
   898     have "norm (\<Sum>k=m..n. f k) < e"
   899     proof (cases "n \<ge> m")
   900       assume n: "n \<ge> m"
   901       with m have "norm ((\<Sum>k<Suc n. f k) - (\<Sum>k<m. f k)) < e" by (intro N) simp_all
   902       also from n have "(\<Sum>k<Suc n. f k) - (\<Sum>k<m. f k) = (\<Sum>k=m..n. f k)"
   903         by (subst setsum_diff [symmetric]) (simp_all add: setsum_last_plus)
   904       finally show ?thesis .
   905     qed (insert e, simp_all)
   906   }
   907   thus ?thesis by (rule that)
   908 qed
   909 
   910 lemma powser_sums_if:
   911   "(\<lambda>n. (if n = m then (1 :: 'a :: {ring_1,topological_space}) else 0) * z^n) sums z^m"
   912 proof -
   913   have "(\<lambda>n. (if n = m then 1 else 0) * z^n) = (\<lambda>n. if n = m then z^n else 0)"
   914     by (intro ext) auto
   915   thus ?thesis by (simp add: sums_single)
   916 qed
   917 
   918 lemma
   919    fixes f :: "nat \<Rightarrow> real"
   920    assumes "summable f"
   921    and "inj g"
   922    and pos: "!!x. 0 \<le> f x"
   923    shows summable_reindex: "summable (f o g)"
   924    and suminf_reindex_mono: "suminf (f o g) \<le> suminf f"
   925    and suminf_reindex: "(\<And>x. x \<notin> range g \<Longrightarrow> f x = 0) \<Longrightarrow> suminf (f \<circ> g) = suminf f"
   926 proof -
   927   from \<open>inj g\<close> have [simp]: "\<And>A. inj_on g A" by(rule subset_inj_on) simp
   928 
   929   have smaller: "\<forall>n. (\<Sum>i<n. (f \<circ> g) i) \<le> suminf f"
   930   proof
   931     fix n
   932     have "\<forall> n' \<in> (g ` {..<n}). n' < Suc (Max (g ` {..<n}))"
   933       by(metis Max_ge finite_imageI finite_lessThan not_le not_less_eq)
   934     then obtain m where n: "\<And>n'. n' < n \<Longrightarrow> g n' < m" by blast
   935 
   936     have "(\<Sum>i<n. f (g i)) = setsum f (g ` {..<n})"
   937       by (simp add: setsum.reindex)
   938     also have "\<dots> \<le> (\<Sum>i<m. f i)"
   939       by (rule setsum_mono3) (auto simp add: pos n[rule_format])
   940     also have "\<dots> \<le> suminf f"
   941       using \<open>summable f\<close>
   942       by (rule setsum_le_suminf) (simp add: pos)
   943     finally show "(\<Sum>i<n. (f \<circ>  g) i) \<le> suminf f" by simp
   944   qed
   945 
   946   have "incseq (\<lambda>n. \<Sum>i<n. (f \<circ> g) i)"
   947     by (rule incseq_SucI) (auto simp add: pos)
   948   then obtain  L where L: "(\<lambda> n. \<Sum>i<n. (f \<circ> g) i) \<longlonglongrightarrow> L"
   949     using smaller by(rule incseq_convergent)
   950   hence "(f \<circ> g) sums L" by (simp add: sums_def)
   951   thus "summable (f o g)" by (auto simp add: sums_iff)
   952 
   953   hence "(\<lambda>n. \<Sum>i<n. (f \<circ> g) i) \<longlonglongrightarrow> suminf (f \<circ> g)"
   954     by(rule summable_LIMSEQ)
   955   thus le: "suminf (f \<circ> g) \<le> suminf f"
   956     by(rule LIMSEQ_le_const2)(blast intro: smaller[rule_format])
   957 
   958   assume f: "\<And>x. x \<notin> range g \<Longrightarrow> f x = 0"
   959 
   960   from \<open>summable f\<close> have "suminf f \<le> suminf (f \<circ> g)"
   961   proof(rule suminf_le_const)
   962     fix n
   963     have "\<forall> n' \<in> (g -` {..<n}). n' < Suc (Max (g -` {..<n}))"
   964       by(auto intro: Max_ge simp add: finite_vimageI less_Suc_eq_le)
   965     then obtain m where n: "\<And>n'. g n' < n \<Longrightarrow> n' < m" by blast
   966 
   967     have "(\<Sum>i<n. f i) = (\<Sum>i\<in>{..<n} \<inter> range g. f i)"
   968       using f by(auto intro: setsum.mono_neutral_cong_right)
   969     also have "\<dots> = (\<Sum>i\<in>g -` {..<n}. (f \<circ> g) i)"
   970       by(rule setsum.reindex_cong[where l=g])(auto)
   971     also have "\<dots> \<le> (\<Sum>i<m. (f \<circ> g) i)"
   972       by(rule setsum_mono3)(auto simp add: pos n)
   973     also have "\<dots> \<le> suminf (f \<circ> g)"
   974       using \<open>summable (f o g)\<close>
   975       by(rule setsum_le_suminf)(simp add: pos)
   976     finally show "setsum f {..<n} \<le> suminf (f \<circ> g)" .
   977   qed
   978   with le show "suminf (f \<circ> g) = suminf f" by(rule antisym)
   979 qed
   980 
   981 lemma sums_mono_reindex:
   982   assumes subseq: "subseq g" and zero: "\<And>n. n \<notin> range g \<Longrightarrow> f n = 0"
   983   shows   "(\<lambda>n. f (g n)) sums c \<longleftrightarrow> f sums c"
   984 unfolding sums_def
   985 proof
   986   assume lim: "(\<lambda>n. \<Sum>k<n. f k) \<longlonglongrightarrow> c"
   987   have "(\<lambda>n. \<Sum>k<n. f (g k)) = (\<lambda>n. \<Sum>k<g n. f k)"
   988   proof
   989     fix n :: nat
   990     from subseq have "(\<Sum>k<n. f (g k)) = (\<Sum>k\<in>g`{..<n}. f k)"
   991       by (subst setsum.reindex) (auto intro: subseq_imp_inj_on)
   992     also from subseq have "\<dots> = (\<Sum>k<g n. f k)"
   993       by (intro setsum.mono_neutral_left ballI zero)
   994          (auto dest: subseq_strict_mono simp: strict_mono_less strict_mono_less_eq)
   995     finally show "(\<Sum>k<n. f (g k)) = (\<Sum>k<g n. f k)" .
   996   qed
   997   also from LIMSEQ_subseq_LIMSEQ[OF lim subseq] have "\<dots> \<longlonglongrightarrow> c" unfolding o_def .
   998   finally show "(\<lambda>n. \<Sum>k<n. f (g k)) \<longlonglongrightarrow> c" .
   999 next
  1000   assume lim: "(\<lambda>n. \<Sum>k<n. f (g k)) \<longlonglongrightarrow> c"
  1001   def g_inv \<equiv> "\<lambda>n. LEAST m. g m \<ge> n"
  1002   from filterlim_subseq[OF subseq] have g_inv_ex: "\<exists>m. g m \<ge> n" for n
  1003     by (auto simp: filterlim_at_top eventually_at_top_linorder)
  1004   hence g_inv: "g (g_inv n) \<ge> n" for n unfolding g_inv_def by (rule LeastI_ex)
  1005   have g_inv_least: "m \<ge> g_inv n" if "g m \<ge> n" for m n using that
  1006     unfolding g_inv_def by (rule Least_le)
  1007   have g_inv_least': "g m < n" if "m < g_inv n" for m n using that g_inv_least[of n m] by linarith
  1008   have "(\<lambda>n. \<Sum>k<n. f k) = (\<lambda>n. \<Sum>k<g_inv n. f (g k))"
  1009   proof
  1010     fix n :: nat
  1011     {
  1012       fix k assume k: "k \<in> {..<n} - g`{..<g_inv n}"
  1013       have "k \<notin> range g"
  1014       proof (rule notI, elim imageE)
  1015         fix l assume l: "k = g l"
  1016         have "g l < g (g_inv n)" by (rule less_le_trans[OF _ g_inv]) (insert k l, simp_all)
  1017         with subseq have "l < g_inv n" by (simp add: subseq_strict_mono strict_mono_less)
  1018         with k l show False by simp
  1019       qed
  1020       hence "f k = 0" by (rule zero)
  1021     }
  1022     with g_inv_least' g_inv have "(\<Sum>k<n. f k) = (\<Sum>k\<in>g`{..<g_inv n}. f k)"
  1023       by (intro setsum.mono_neutral_right) auto
  1024     also from subseq have "\<dots> = (\<Sum>k<g_inv n. f (g k))" using subseq_imp_inj_on
  1025       by (subst setsum.reindex) simp_all
  1026     finally show "(\<Sum>k<n. f k) = (\<Sum>k<g_inv n. f (g k))" .
  1027   qed
  1028   also {
  1029     fix K n :: nat assume "g K \<le> n"
  1030     also have "n \<le> g (g_inv n)" by (rule g_inv)
  1031     finally have "K \<le> g_inv n" using subseq by (simp add: strict_mono_less_eq subseq_strict_mono)
  1032   }
  1033   hence "filterlim g_inv at_top sequentially"
  1034     by (auto simp: filterlim_at_top eventually_at_top_linorder)
  1035   from lim and this have "(\<lambda>n. \<Sum>k<g_inv n. f (g k)) \<longlonglongrightarrow> c" by (rule filterlim_compose)
  1036   finally show "(\<lambda>n. \<Sum>k<n. f k) \<longlonglongrightarrow> c" .
  1037 qed
  1038 
  1039 lemma summable_mono_reindex:
  1040   assumes subseq: "subseq g" and zero: "\<And>n. n \<notin> range g \<Longrightarrow> f n = 0"
  1041   shows   "summable (\<lambda>n. f (g n)) \<longleftrightarrow> summable f"
  1042   using sums_mono_reindex[of g f, OF assms] by (simp add: summable_def)
  1043 
  1044 lemma suminf_mono_reindex:
  1045   assumes "subseq g" "\<And>n. n \<notin> range g \<Longrightarrow> f n = (0 :: 'a :: {t2_space,comm_monoid_add})"
  1046   shows   "suminf (\<lambda>n. f (g n)) = suminf f"
  1047 proof (cases "summable f")
  1048   case False
  1049   hence "\<not>(\<exists>c. f sums c)" unfolding summable_def by blast
  1050   hence "suminf f = The (\<lambda>_. False)" by (simp add: suminf_def)
  1051   moreover from False have "\<not>summable (\<lambda>n. f (g n))"
  1052     using summable_mono_reindex[of g f, OF assms] by simp
  1053   hence "\<not>(\<exists>c. (\<lambda>n. f (g n)) sums c)" unfolding summable_def by blast
  1054   hence "suminf (\<lambda>n. f (g n)) = The (\<lambda>_. False)" by (simp add: suminf_def)
  1055   ultimately show ?thesis by simp
  1056 qed (insert sums_mono_reindex[of g f, OF assms] summable_mono_reindex[of g f, OF assms],
  1057      simp_all add: sums_iff)
  1058 
  1059 end