src/HOL/Orderings.thy
author ballarin
Tue Sep 18 18:53:12 2007 +0200 (2007-09-18)
changeset 24641 448edc627ee4
parent 24422 c0b5ff9e9e4d
child 24704 9a95634ab135
permissions -rw-r--r--
Transitivity reasoner set up for locales order and linorder.
     1 (*  Title:      HOL/Orderings.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     4 *)
     5 
     6 header {* Syntactic and abstract orders *}
     7 
     8 theory Orderings
     9 imports Set Fun
    10 uses
    11   "~~/src/Provers/order.ML"
    12 begin
    13 
    14 subsection {* Partial orders *}
    15 
    16 class order = ord +
    17   assumes less_le: "x \<sqsubset> y \<longleftrightarrow> x \<sqsubseteq> y \<and> x \<noteq> y"
    18   and order_refl [iff]: "x \<sqsubseteq> x"
    19   and order_trans: "x \<sqsubseteq> y \<Longrightarrow> y \<sqsubseteq> z \<Longrightarrow> x \<sqsubseteq> z"
    20   assumes antisym: "x \<sqsubseteq> y \<Longrightarrow> y \<sqsubseteq> x \<Longrightarrow> x = y"
    21 
    22 begin
    23 
    24 text {* Reflexivity. *}
    25 
    26 lemma eq_refl: "x = y \<Longrightarrow> x \<^loc>\<le> y"
    27     -- {* This form is useful with the classical reasoner. *}
    28 by (erule ssubst) (rule order_refl)
    29 
    30 lemma less_irrefl [iff]: "\<not> x \<^loc>< x"
    31 by (simp add: less_le)
    32 
    33 lemma le_less: "x \<^loc>\<le> y \<longleftrightarrow> x \<^loc>< y \<or> x = y"
    34     -- {* NOT suitable for iff, since it can cause PROOF FAILED. *}
    35 by (simp add: less_le) blast
    36 
    37 lemma le_imp_less_or_eq: "x \<^loc>\<le> y \<Longrightarrow> x \<^loc>< y \<or> x = y"
    38 unfolding less_le by blast
    39 
    40 lemma less_imp_le: "x \<^loc>< y \<Longrightarrow> x \<^loc>\<le> y"
    41 unfolding less_le by blast
    42 
    43 lemma less_imp_neq: "x \<^loc>< y \<Longrightarrow> x \<noteq> y"
    44 by (erule contrapos_pn, erule subst, rule less_irrefl)
    45 
    46 
    47 text {* Useful for simplification, but too risky to include by default. *}
    48 
    49 lemma less_imp_not_eq: "x \<^loc>< y \<Longrightarrow> (x = y) \<longleftrightarrow> False"
    50 by auto
    51 
    52 lemma less_imp_not_eq2: "x \<^loc>< y \<Longrightarrow> (y = x) \<longleftrightarrow> False"
    53 by auto
    54 
    55 
    56 text {* Transitivity rules for calculational reasoning *}
    57 
    58 lemma neq_le_trans: "a \<noteq> b \<Longrightarrow> a \<^loc>\<le> b \<Longrightarrow> a \<^loc>< b"
    59 by (simp add: less_le)
    60 
    61 lemma le_neq_trans: "a \<^loc>\<le> b \<Longrightarrow> a \<noteq> b \<Longrightarrow> a \<^loc>< b"
    62 by (simp add: less_le)
    63 
    64 
    65 text {* Asymmetry. *}
    66 
    67 lemma less_not_sym: "x \<^loc>< y \<Longrightarrow> \<not> (y \<^loc>< x)"
    68 by (simp add: less_le antisym)
    69 
    70 lemma less_asym: "x \<^loc>< y \<Longrightarrow> (\<not> P \<Longrightarrow> y \<^loc>< x) \<Longrightarrow> P"
    71 by (drule less_not_sym, erule contrapos_np) simp
    72 
    73 lemma eq_iff: "x = y \<longleftrightarrow> x \<^loc>\<le> y \<and> y \<^loc>\<le> x"
    74 by (blast intro: antisym)
    75 
    76 lemma antisym_conv: "y \<^loc>\<le> x \<Longrightarrow> x \<^loc>\<le> y \<longleftrightarrow> x = y"
    77 by (blast intro: antisym)
    78 
    79 lemma less_imp_neq: "x \<^loc>< y \<Longrightarrow> x \<noteq> y"
    80 by (erule contrapos_pn, erule subst, rule less_irrefl)
    81 
    82 
    83 text {* Transitivity. *}
    84 
    85 lemma less_trans: "x \<^loc>< y \<Longrightarrow> y \<^loc>< z \<Longrightarrow> x \<^loc>< z"
    86 by (simp add: less_le) (blast intro: order_trans antisym)
    87 
    88 lemma le_less_trans: "x \<^loc>\<le> y \<Longrightarrow> y \<^loc>< z \<Longrightarrow> x \<^loc>< z"
    89 by (simp add: less_le) (blast intro: order_trans antisym)
    90 
    91 lemma less_le_trans: "x \<^loc>< y \<Longrightarrow> y \<^loc>\<le> z \<Longrightarrow> x \<^loc>< z"
    92 by (simp add: less_le) (blast intro: order_trans antisym)
    93 
    94 
    95 text {* Useful for simplification, but too risky to include by default. *}
    96 
    97 lemma less_imp_not_less: "x \<^loc>< y \<Longrightarrow> (\<not> y \<^loc>< x) \<longleftrightarrow> True"
    98 by (blast elim: less_asym)
    99 
   100 lemma less_imp_triv: "x \<^loc>< y \<Longrightarrow> (y \<^loc>< x \<longrightarrow> P) \<longleftrightarrow> True"
   101 by (blast elim: less_asym)
   102 
   103 
   104 text {* Transitivity rules for calculational reasoning *}
   105 
   106 lemma less_asym': "a \<^loc>< b \<Longrightarrow> b \<^loc>< a \<Longrightarrow> P"
   107 by (rule less_asym)
   108 
   109 
   110 text {* Reverse order *}
   111 
   112 lemma order_reverse:
   113   "order (\<lambda>x y. y \<^loc>\<le> x) (\<lambda>x y. y \<^loc>< x)"
   114 by unfold_locales
   115    (simp add: less_le, auto intro: antisym order_trans)
   116 
   117 end
   118 
   119 
   120 subsection {* Linear (total) orders *}
   121 
   122 class linorder = order +
   123   assumes linear: "x \<sqsubseteq> y \<or> y \<sqsubseteq> x"
   124 begin
   125 
   126 lemma less_linear: "x \<^loc>< y \<or> x = y \<or> y \<^loc>< x"
   127 unfolding less_le using less_le linear by blast
   128 
   129 lemma le_less_linear: "x \<^loc>\<le> y \<or> y \<^loc>< x"
   130 by (simp add: le_less less_linear)
   131 
   132 lemma le_cases [case_names le ge]:
   133   "(x \<^loc>\<le> y \<Longrightarrow> P) \<Longrightarrow> (y \<^loc>\<le> x \<Longrightarrow> P) \<Longrightarrow> P"
   134 using linear by blast
   135 
   136 lemma linorder_cases [case_names less equal greater]:
   137   "(x \<^loc>< y \<Longrightarrow> P) \<Longrightarrow> (x = y \<Longrightarrow> P) \<Longrightarrow> (y \<^loc>< x \<Longrightarrow> P) \<Longrightarrow> P"
   138 using less_linear by blast
   139 
   140 lemma not_less: "\<not> x \<^loc>< y \<longleftrightarrow> y \<^loc>\<le> x"
   141 apply (simp add: less_le)
   142 using linear apply (blast intro: antisym)
   143 done
   144 
   145 lemma not_less_iff_gr_or_eq:
   146  "\<not>(x \<^loc>< y) \<longleftrightarrow> (x \<^loc>> y | x = y)"
   147 apply(simp add:not_less le_less)
   148 apply blast
   149 done
   150 
   151 lemma not_le: "\<not> x \<^loc>\<le> y \<longleftrightarrow> y \<^loc>< x"
   152 apply (simp add: less_le)
   153 using linear apply (blast intro: antisym)
   154 done
   155 
   156 lemma neq_iff: "x \<noteq> y \<longleftrightarrow> x \<^loc>< y \<or> y \<^loc>< x"
   157 by (cut_tac x = x and y = y in less_linear, auto)
   158 
   159 lemma neqE: "x \<noteq> y \<Longrightarrow> (x \<^loc>< y \<Longrightarrow> R) \<Longrightarrow> (y \<^loc>< x \<Longrightarrow> R) \<Longrightarrow> R"
   160 by (simp add: neq_iff) blast
   161 
   162 lemma antisym_conv1: "\<not> x \<^loc>< y \<Longrightarrow> x \<^loc>\<le> y \<longleftrightarrow> x = y"
   163 by (blast intro: antisym dest: not_less [THEN iffD1])
   164 
   165 lemma antisym_conv2: "x \<^loc>\<le> y \<Longrightarrow> \<not> x \<^loc>< y \<longleftrightarrow> x = y"
   166 by (blast intro: antisym dest: not_less [THEN iffD1])
   167 
   168 lemma antisym_conv3: "\<not> y \<^loc>< x \<Longrightarrow> \<not> x \<^loc>< y \<longleftrightarrow> x = y"
   169 by (blast intro: antisym dest: not_less [THEN iffD1])
   170 
   171 text{*Replacing the old Nat.leI*}
   172 lemma leI: "\<not> x \<^loc>< y \<Longrightarrow> y \<^loc>\<le> x"
   173 unfolding not_less .
   174 
   175 lemma leD: "y \<^loc>\<le> x \<Longrightarrow> \<not> x \<^loc>< y"
   176 unfolding not_less .
   177 
   178 (*FIXME inappropriate name (or delete altogether)*)
   179 lemma not_leE: "\<not> y \<^loc>\<le> x \<Longrightarrow> x \<^loc>< y"
   180 unfolding not_le .
   181 
   182 
   183 text {* Reverse order *}
   184 
   185 lemma linorder_reverse:
   186   "linorder (\<lambda>x y. y \<^loc>\<le> x) (\<lambda>x y. y \<^loc>< x)"
   187 by unfold_locales
   188   (simp add: less_le, auto intro: antisym order_trans simp add: linear)
   189 
   190 
   191 text {* min/max *}
   192 
   193 text {* for historic reasons, definitions are done in context ord *}
   194 
   195 definition (in ord)
   196   min :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   197   [code unfold, code inline del]: "min a b = (if a \<^loc>\<le> b then a else b)"
   198 
   199 definition (in ord)
   200   max :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   201   [code unfold, code inline del]: "max a b = (if a \<^loc>\<le> b then b else a)"
   202 
   203 lemma min_le_iff_disj:
   204   "min x y \<^loc>\<le> z \<longleftrightarrow> x \<^loc>\<le> z \<or> y \<^loc>\<le> z"
   205 unfolding min_def using linear by (auto intro: order_trans)
   206 
   207 lemma le_max_iff_disj:
   208   "z \<^loc>\<le> max x y \<longleftrightarrow> z \<^loc>\<le> x \<or> z \<^loc>\<le> y"
   209 unfolding max_def using linear by (auto intro: order_trans)
   210 
   211 lemma min_less_iff_disj:
   212   "min x y \<^loc>< z \<longleftrightarrow> x \<^loc>< z \<or> y \<^loc>< z"
   213 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   214 
   215 lemma less_max_iff_disj:
   216   "z \<^loc>< max x y \<longleftrightarrow> z \<^loc>< x \<or> z \<^loc>< y"
   217 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   218 
   219 lemma min_less_iff_conj [simp]:
   220   "z \<^loc>< min x y \<longleftrightarrow> z \<^loc>< x \<and> z \<^loc>< y"
   221 unfolding min_def le_less using less_linear by (auto intro: less_trans)
   222 
   223 lemma max_less_iff_conj [simp]:
   224   "max x y \<^loc>< z \<longleftrightarrow> x \<^loc>< z \<and> y \<^loc>< z"
   225 unfolding max_def le_less using less_linear by (auto intro: less_trans)
   226 
   227 lemma split_min [noatp]:
   228   "P (min i j) \<longleftrightarrow> (i \<^loc>\<le> j \<longrightarrow> P i) \<and> (\<not> i \<^loc>\<le> j \<longrightarrow> P j)"
   229 by (simp add: min_def)
   230 
   231 lemma split_max [noatp]:
   232   "P (max i j) \<longleftrightarrow> (i \<^loc>\<le> j \<longrightarrow> P j) \<and> (\<not> i \<^loc>\<le> j \<longrightarrow> P i)"
   233 by (simp add: max_def)
   234 
   235 end
   236 
   237 
   238 subsection {* Reasoning tools setup *}
   239 
   240 ML {*
   241 
   242 signature ORDERS =
   243 sig
   244   val print_structures: Proof.context -> unit
   245   val setup: theory -> theory
   246   val order_tac: Proof.context -> int -> tactic
   247 end;
   248 
   249 structure Orders: ORDERS =
   250 struct
   251 
   252 (** Theory and context data **)
   253 
   254 fun struct_eq ((s1: string, ts1), (s2, ts2)) =
   255   (s1 = s2) andalso eq_list (op aconv) (ts1, ts2);
   256 
   257 structure Data = GenericDataFun
   258 (
   259   type T = ((string * term list) * Order_Tac.less_arith) list;
   260     (* Order structures:
   261        identifier of the structure, list of operations and record of theorems
   262        needed to set up the transitivity reasoner,
   263        identifier and operations identify the structure uniquely. *)
   264   val empty = [];
   265   val extend = I;
   266   fun merge _ = AList.join struct_eq (K fst);
   267 );
   268 
   269 fun print_structures ctxt =
   270   let
   271     val structs = Data.get (Context.Proof ctxt);
   272     fun pretty_term t = Pretty.block
   273       [Pretty.quote (ProofContext.pretty_term ctxt t), Pretty.brk 1,
   274         Pretty.str "::", Pretty.brk 1,
   275         Pretty.quote (ProofContext.pretty_typ ctxt (type_of t))];
   276     fun pretty_struct ((s, ts), _) = Pretty.block
   277       [Pretty.str s, Pretty.str ":", Pretty.brk 1,
   278        Pretty.enclose "(" ")" (Pretty.breaks (map pretty_term ts))];
   279   in
   280     Pretty.writeln (Pretty.big_list "Order structures:" (map pretty_struct structs))
   281   end;
   282 
   283 
   284 (** Method **)
   285 
   286 fun struct_tac ((s, [eq, le, less]), thms) =
   287   let
   288     fun decomp thy (Trueprop $ t) =
   289       let
   290         fun excluded t =
   291           (* exclude numeric types: linear arithmetic subsumes transitivity *)
   292           let val T = type_of t
   293           in
   294 	    T = HOLogic.natT orelse T = HOLogic.intT orelse T = HOLogic.realT
   295           end;
   296 	fun dec (Const (@{const_name Not}, _) $ t) = (case dec t
   297 	      of NONE => NONE
   298 	       | SOME (t1, rel, t2) => SOME (t1, "~" ^ rel, t2))
   299           | dec (bin_op $ t1 $ t2) =
   300               if excluded t1 then NONE
   301               else if Pattern.matches thy (eq, bin_op) then SOME (t1, "=", t2)
   302               else if Pattern.matches thy (le, bin_op) then SOME (t1, "<=", t2)
   303               else if Pattern.matches thy (less, bin_op) then SOME (t1, "<", t2)
   304               else NONE
   305 	  | dec _ = NONE;
   306       in dec t end;
   307   in
   308     case s of
   309       "order" => Order_Tac.partial_tac decomp thms
   310     | "linorder" => Order_Tac.linear_tac decomp thms
   311     | _ => error ("Unknown kind of order `" ^ s ^ "' encountered in transitivity reasoner.")
   312   end
   313 
   314 fun order_tac ctxt =
   315   FIRST' (map (fn s => CHANGED o struct_tac s) (Data.get (Context.Proof ctxt)));
   316 
   317 
   318 (** Attribute **)
   319 
   320 fun add_struct_thm s tag =
   321   Thm.declaration_attribute
   322     (fn thm => Data.map (AList.map_default struct_eq (s, Order_Tac.empty TrueI) (Order_Tac.update tag thm)));
   323 fun del_struct s =
   324   Thm.declaration_attribute
   325     (fn _ => Data.map (AList.delete struct_eq s));
   326 
   327 val attribute = Attrib.syntax
   328      (Scan.lift ((Args.add -- Args.name >> (fn (_, s) => SOME s) ||
   329           Args.del >> K NONE) --| Args.colon (* FIXME ||
   330         Scan.succeed true *) ) -- Scan.lift Args.name --
   331       Scan.repeat Args.term
   332       >> (fn ((SOME tag, n), ts) => add_struct_thm (n, ts) tag
   333            | ((NONE, n), ts) => del_struct (n, ts)));
   334 
   335 
   336 (** Diagnostic command **)
   337 
   338 val print = Toplevel.unknown_context o
   339   Toplevel.keep (Toplevel.node_case
   340     (Context.cases (print_structures o ProofContext.init) print_structures)
   341     (print_structures o Proof.context_of));
   342 
   343 val printP =
   344   OuterSyntax.improper_command "print_orders"
   345     "print order structures available to transitivity reasoner" OuterKeyword.diag
   346     (Scan.succeed (Toplevel.no_timing o print));
   347 
   348 
   349 (** Setup **)
   350 
   351 val setup = let val _ = OuterSyntax.add_parsers [printP] in
   352     Method.add_methods [("order", Method.ctxt_args (Method.SIMPLE_METHOD' o order_tac),
   353       "normalisation of algebraic structure")] #>
   354     Attrib.add_attributes [("order", attribute, "theorems controlling transitivity reasoner")]
   355   end;
   356 
   357 end;
   358 
   359 *}
   360 
   361 setup Orders.setup
   362 
   363 
   364 text {* Declarations to set up transitivity reasoner of partial and linear orders. *}
   365 
   366 (* The type constraint on @{term op =} below is necessary since the operation
   367    is not a parameter of the locale. *)
   368 lemmas (in order)
   369   [order add less_reflE: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   370   less_irrefl [THEN notE]
   371 lemmas (in order)
   372   [order add le_refl: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   373   order_refl
   374 lemmas (in order)
   375   [order add less_imp_le: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   376   less_imp_le
   377 lemmas (in order)
   378   [order add eqI: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   379   antisym
   380 lemmas (in order)
   381   [order add eqD1: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   382   eq_refl
   383 lemmas (in order)
   384   [order add eqD2: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   385   sym [THEN eq_refl]
   386 lemmas (in order)
   387   [order add less_trans: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   388   less_trans
   389 lemmas (in order)
   390   [order add less_le_trans: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   391   less_le_trans
   392 lemmas (in order)
   393   [order add le_less_trans: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   394   le_less_trans
   395 lemmas (in order)
   396   [order add le_trans: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   397   order_trans
   398 lemmas (in order)
   399   [order add le_neq_trans: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   400   le_neq_trans
   401 lemmas (in order)
   402   [order add neq_le_trans: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   403   neq_le_trans
   404 lemmas (in order)
   405   [order add less_imp_neq: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   406   less_imp_neq
   407 lemmas (in order)
   408   [order add eq_neq_eq_imp_neq: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   409    eq_neq_eq_imp_neq
   410 lemmas (in order)
   411   [order add not_sym: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   412   not_sym
   413 
   414 lemmas (in linorder) [order del: order "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] = _
   415 
   416 lemmas (in linorder)
   417   [order add less_reflE: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   418   less_irrefl [THEN notE]
   419 lemmas (in linorder)
   420   [order add le_refl: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   421   order_refl
   422 lemmas (in linorder)
   423   [order add less_imp_le: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   424   less_imp_le
   425 lemmas (in linorder)
   426   [order add not_lessI: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   427   not_less [THEN iffD2]
   428 lemmas (in linorder)
   429   [order add not_leI: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   430   not_le [THEN iffD2]
   431 lemmas (in linorder)
   432   [order add not_lessD: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   433   not_less [THEN iffD1]
   434 lemmas (in linorder)
   435   [order add not_leD: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   436   not_le [THEN iffD1]
   437 lemmas (in linorder)
   438   [order add eqI: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   439   antisym
   440 lemmas (in linorder)
   441   [order add eqD1: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   442   eq_refl
   443 lemmas (in linorder)
   444   [order add eqD2: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   445   sym [THEN eq_refl]
   446 lemmas (in linorder)
   447   [order add less_trans: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   448   less_trans
   449 lemmas (in linorder)
   450   [order add less_le_trans: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   451   less_le_trans
   452 lemmas (in linorder)
   453   [order add le_less_trans: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   454   le_less_trans
   455 lemmas (in linorder)
   456   [order add le_trans: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   457   order_trans
   458 lemmas (in linorder)
   459   [order add le_neq_trans: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   460   le_neq_trans
   461 lemmas (in linorder)
   462   [order add neq_le_trans: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   463   neq_le_trans
   464 lemmas (in linorder)
   465   [order add less_imp_neq: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   466   less_imp_neq
   467 lemmas (in linorder)
   468   [order add eq_neq_eq_imp_neq: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   469   eq_neq_eq_imp_neq
   470 lemmas (in linorder)
   471   [order add not_sym: linorder "op = :: 'a => 'a => bool" "op \<^loc><=" "op \<^loc><"] =
   472   not_sym
   473 
   474 
   475 setup {*
   476 let
   477 
   478 fun prp t thm = (#prop (rep_thm thm) = t);
   479 
   480 fun prove_antisym_le sg ss ((le as Const(_,T)) $ r $ s) =
   481   let val prems = prems_of_ss ss;
   482       val less = Const (@{const_name less}, T);
   483       val t = HOLogic.mk_Trueprop(le $ s $ r);
   484   in case find_first (prp t) prems of
   485        NONE =>
   486          let val t = HOLogic.mk_Trueprop(HOLogic.Not $ (less $ r $ s))
   487          in case find_first (prp t) prems of
   488               NONE => NONE
   489             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv1}))
   490          end
   491      | SOME thm => SOME(mk_meta_eq(thm RS @{thm order_class.antisym_conv}))
   492   end
   493   handle THM _ => NONE;
   494 
   495 fun prove_antisym_less sg ss (NotC $ ((less as Const(_,T)) $ r $ s)) =
   496   let val prems = prems_of_ss ss;
   497       val le = Const (@{const_name less_eq}, T);
   498       val t = HOLogic.mk_Trueprop(le $ r $ s);
   499   in case find_first (prp t) prems of
   500        NONE =>
   501          let val t = HOLogic.mk_Trueprop(NotC $ (less $ s $ r))
   502          in case find_first (prp t) prems of
   503               NONE => NONE
   504             | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv3}))
   505          end
   506      | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv2}))
   507   end
   508   handle THM _ => NONE;
   509 
   510 fun add_simprocs procs thy =
   511   (Simplifier.change_simpset_of thy (fn ss => ss
   512     addsimprocs (map (fn (name, raw_ts, proc) =>
   513       Simplifier.simproc thy name raw_ts proc)) procs); thy);
   514 fun add_solver name tac thy =
   515   (Simplifier.change_simpset_of thy (fn ss => ss addSolver
   516     (mk_solver' name (fn ss => tac (MetaSimplifier.the_context ss)))); thy);
   517 
   518 in
   519   add_simprocs [
   520        ("antisym le", ["(x::'a::order) <= y"], prove_antisym_le),
   521        ("antisym less", ["~ (x::'a::linorder) < y"], prove_antisym_less)
   522      ]
   523   #> add_solver "Transitivity" Orders.order_tac
   524   (* Adding the transitivity reasoners also as safe solvers showed a slight
   525      speed up, but the reasoning strength appears to be not higher (at least
   526      no breaking of additional proofs in the entire HOL distribution, as
   527      of 5 March 2004, was observed). *)
   528 end
   529 *}
   530 
   531 
   532 subsection {* Dense orders *}
   533 
   534 class dense_linear_order = linorder + 
   535   assumes gt_ex: "\<exists>y. x \<sqsubset> y" 
   536   and lt_ex: "\<exists>y. y \<sqsubset> x"
   537   and dense: "x \<sqsubset> y \<Longrightarrow> (\<exists>z. x \<sqsubset> z \<and> z \<sqsubset> y)"
   538   (*see further theory Dense_Linear_Order*)
   539 
   540 
   541 lemma interval_empty_iff:
   542   fixes x y z :: "'a\<Colon>dense_linear_order"
   543   shows "{y. x < y \<and> y < z} = {} \<longleftrightarrow> \<not> x < z"
   544   by (auto dest: dense)
   545 
   546 subsection {* Name duplicates *}
   547 
   548 lemmas order_less_le = less_le
   549 lemmas order_eq_refl = order_class.eq_refl
   550 lemmas order_less_irrefl = order_class.less_irrefl
   551 lemmas order_le_less = order_class.le_less
   552 lemmas order_le_imp_less_or_eq = order_class.le_imp_less_or_eq
   553 lemmas order_less_imp_le = order_class.less_imp_le
   554 lemmas order_less_imp_not_eq = order_class.less_imp_not_eq
   555 lemmas order_less_imp_not_eq2 = order_class.less_imp_not_eq2
   556 lemmas order_neq_le_trans = order_class.neq_le_trans
   557 lemmas order_le_neq_trans = order_class.le_neq_trans
   558 
   559 lemmas order_antisym = antisym
   560 lemmas order_less_not_sym = order_class.less_not_sym
   561 lemmas order_less_asym = order_class.less_asym
   562 lemmas order_eq_iff = order_class.eq_iff
   563 lemmas order_antisym_conv = order_class.antisym_conv
   564 lemmas order_less_trans = order_class.less_trans
   565 lemmas order_le_less_trans = order_class.le_less_trans
   566 lemmas order_less_le_trans = order_class.less_le_trans
   567 lemmas order_less_imp_not_less = order_class.less_imp_not_less
   568 lemmas order_less_imp_triv = order_class.less_imp_triv
   569 lemmas order_less_asym' = order_class.less_asym'
   570 
   571 lemmas linorder_linear = linear
   572 lemmas linorder_less_linear = linorder_class.less_linear
   573 lemmas linorder_le_less_linear = linorder_class.le_less_linear
   574 lemmas linorder_le_cases = linorder_class.le_cases
   575 lemmas linorder_not_less = linorder_class.not_less
   576 lemmas linorder_not_le = linorder_class.not_le
   577 lemmas linorder_neq_iff = linorder_class.neq_iff
   578 lemmas linorder_neqE = linorder_class.neqE
   579 lemmas linorder_antisym_conv1 = linorder_class.antisym_conv1
   580 lemmas linorder_antisym_conv2 = linorder_class.antisym_conv2
   581 lemmas linorder_antisym_conv3 = linorder_class.antisym_conv3
   582 
   583 lemmas min_le_iff_disj = linorder_class.min_le_iff_disj
   584 lemmas le_max_iff_disj = linorder_class.le_max_iff_disj
   585 lemmas min_less_iff_disj = linorder_class.min_less_iff_disj
   586 lemmas less_max_iff_disj = linorder_class.less_max_iff_disj
   587 lemmas min_less_iff_conj [simp] = linorder_class.min_less_iff_conj
   588 lemmas max_less_iff_conj [simp] = linorder_class.max_less_iff_conj
   589 lemmas split_min = linorder_class.split_min
   590 lemmas split_max = linorder_class.split_max
   591 
   592 
   593 subsection {* Bounded quantifiers *}
   594 
   595 syntax
   596   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   597   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3EX _<_./ _)"  [0, 0, 10] 10)
   598   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   599   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _<=_./ _)" [0, 0, 10] 10)
   600 
   601   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3ALL _>_./ _)"  [0, 0, 10] 10)
   602   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3EX _>_./ _)"  [0, 0, 10] 10)
   603   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _>=_./ _)" [0, 0, 10] 10)
   604   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _>=_./ _)" [0, 0, 10] 10)
   605 
   606 syntax (xsymbols)
   607   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   608   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   609   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   610   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   611 
   612   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   613   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   614   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   615   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   616 
   617 syntax (HOL)
   618   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3! _<_./ _)"  [0, 0, 10] 10)
   619   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3? _<_./ _)"  [0, 0, 10] 10)
   620   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3! _<=_./ _)" [0, 0, 10] 10)
   621   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3? _<=_./ _)" [0, 0, 10] 10)
   622 
   623 syntax (HTML output)
   624   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   625   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   626   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   627   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   628 
   629   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   630   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   631   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   632   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   633 
   634 translations
   635   "ALL x<y. P"   =>  "ALL x. x < y \<longrightarrow> P"
   636   "EX x<y. P"    =>  "EX x. x < y \<and> P"
   637   "ALL x<=y. P"  =>  "ALL x. x <= y \<longrightarrow> P"
   638   "EX x<=y. P"   =>  "EX x. x <= y \<and> P"
   639   "ALL x>y. P"   =>  "ALL x. x > y \<longrightarrow> P"
   640   "EX x>y. P"    =>  "EX x. x > y \<and> P"
   641   "ALL x>=y. P"  =>  "ALL x. x >= y \<longrightarrow> P"
   642   "EX x>=y. P"   =>  "EX x. x >= y \<and> P"
   643 
   644 print_translation {*
   645 let
   646   val All_binder = Syntax.binder_name @{const_syntax All};
   647   val Ex_binder = Syntax.binder_name @{const_syntax Ex};
   648   val impl = @{const_syntax "op -->"};
   649   val conj = @{const_syntax "op &"};
   650   val less = @{const_syntax less};
   651   val less_eq = @{const_syntax less_eq};
   652 
   653   val trans =
   654    [((All_binder, impl, less), ("_All_less", "_All_greater")),
   655     ((All_binder, impl, less_eq), ("_All_less_eq", "_All_greater_eq")),
   656     ((Ex_binder, conj, less), ("_Ex_less", "_Ex_greater")),
   657     ((Ex_binder, conj, less_eq), ("_Ex_less_eq", "_Ex_greater_eq"))];
   658 
   659   fun matches_bound v t = 
   660      case t of (Const ("_bound", _) $ Free (v', _)) => (v = v')
   661               | _ => false
   662   fun contains_var v = Term.exists_subterm (fn Free (x, _) => x = v | _ => false)
   663   fun mk v c n P = Syntax.const c $ Syntax.mark_bound v $ n $ P
   664 
   665   fun tr' q = (q,
   666     fn [Const ("_bound", _) $ Free (v, _), Const (c, _) $ (Const (d, _) $ t $ u) $ P] =>
   667       (case AList.lookup (op =) trans (q, c, d) of
   668         NONE => raise Match
   669       | SOME (l, g) =>
   670           if matches_bound v t andalso not (contains_var v u) then mk v l u P
   671           else if matches_bound v u andalso not (contains_var v t) then mk v g t P
   672           else raise Match)
   673      | _ => raise Match);
   674 in [tr' All_binder, tr' Ex_binder] end
   675 *}
   676 
   677 
   678 subsection {* Transitivity reasoning *}
   679 
   680 lemma ord_le_eq_trans: "a <= b ==> b = c ==> a <= c"
   681 by (rule subst)
   682 
   683 lemma ord_eq_le_trans: "a = b ==> b <= c ==> a <= c"
   684 by (rule ssubst)
   685 
   686 lemma ord_less_eq_trans: "a < b ==> b = c ==> a < c"
   687 by (rule subst)
   688 
   689 lemma ord_eq_less_trans: "a = b ==> b < c ==> a < c"
   690 by (rule ssubst)
   691 
   692 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
   693   (!!x y. x < y ==> f x < f y) ==> f a < c"
   694 proof -
   695   assume r: "!!x y. x < y ==> f x < f y"
   696   assume "a < b" hence "f a < f b" by (rule r)
   697   also assume "f b < c"
   698   finally (order_less_trans) show ?thesis .
   699 qed
   700 
   701 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
   702   (!!x y. x < y ==> f x < f y) ==> a < f c"
   703 proof -
   704   assume r: "!!x y. x < y ==> f x < f y"
   705   assume "a < f b"
   706   also assume "b < c" hence "f b < f c" by (rule r)
   707   finally (order_less_trans) show ?thesis .
   708 qed
   709 
   710 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
   711   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
   712 proof -
   713   assume r: "!!x y. x <= y ==> f x <= f y"
   714   assume "a <= b" hence "f a <= f b" by (rule r)
   715   also assume "f b < c"
   716   finally (order_le_less_trans) show ?thesis .
   717 qed
   718 
   719 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
   720   (!!x y. x < y ==> f x < f y) ==> a < f c"
   721 proof -
   722   assume r: "!!x y. x < y ==> f x < f y"
   723   assume "a <= f b"
   724   also assume "b < c" hence "f b < f c" by (rule r)
   725   finally (order_le_less_trans) show ?thesis .
   726 qed
   727 
   728 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
   729   (!!x y. x < y ==> f x < f y) ==> f a < c"
   730 proof -
   731   assume r: "!!x y. x < y ==> f x < f y"
   732   assume "a < b" hence "f a < f b" by (rule r)
   733   also assume "f b <= c"
   734   finally (order_less_le_trans) show ?thesis .
   735 qed
   736 
   737 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
   738   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
   739 proof -
   740   assume r: "!!x y. x <= y ==> f x <= f y"
   741   assume "a < f b"
   742   also assume "b <= c" hence "f b <= f c" by (rule r)
   743   finally (order_less_le_trans) show ?thesis .
   744 qed
   745 
   746 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
   747   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   748 proof -
   749   assume r: "!!x y. x <= y ==> f x <= f y"
   750   assume "a <= f b"
   751   also assume "b <= c" hence "f b <= f c" by (rule r)
   752   finally (order_trans) show ?thesis .
   753 qed
   754 
   755 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
   756   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   757 proof -
   758   assume r: "!!x y. x <= y ==> f x <= f y"
   759   assume "a <= b" hence "f a <= f b" by (rule r)
   760   also assume "f b <= c"
   761   finally (order_trans) show ?thesis .
   762 qed
   763 
   764 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
   765   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   766 proof -
   767   assume r: "!!x y. x <= y ==> f x <= f y"
   768   assume "a <= b" hence "f a <= f b" by (rule r)
   769   also assume "f b = c"
   770   finally (ord_le_eq_trans) show ?thesis .
   771 qed
   772 
   773 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
   774   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   775 proof -
   776   assume r: "!!x y. x <= y ==> f x <= f y"
   777   assume "a = f b"
   778   also assume "b <= c" hence "f b <= f c" by (rule r)
   779   finally (ord_eq_le_trans) show ?thesis .
   780 qed
   781 
   782 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
   783   (!!x y. x < y ==> f x < f y) ==> f a < c"
   784 proof -
   785   assume r: "!!x y. x < y ==> f x < f y"
   786   assume "a < b" hence "f a < f b" by (rule r)
   787   also assume "f b = c"
   788   finally (ord_less_eq_trans) show ?thesis .
   789 qed
   790 
   791 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
   792   (!!x y. x < y ==> f x < f y) ==> a < f c"
   793 proof -
   794   assume r: "!!x y. x < y ==> f x < f y"
   795   assume "a = f b"
   796   also assume "b < c" hence "f b < f c" by (rule r)
   797   finally (ord_eq_less_trans) show ?thesis .
   798 qed
   799 
   800 text {*
   801   Note that this list of rules is in reverse order of priorities.
   802 *}
   803 
   804 lemmas order_trans_rules [trans] =
   805   order_less_subst2
   806   order_less_subst1
   807   order_le_less_subst2
   808   order_le_less_subst1
   809   order_less_le_subst2
   810   order_less_le_subst1
   811   order_subst2
   812   order_subst1
   813   ord_le_eq_subst
   814   ord_eq_le_subst
   815   ord_less_eq_subst
   816   ord_eq_less_subst
   817   forw_subst
   818   back_subst
   819   rev_mp
   820   mp
   821   order_neq_le_trans
   822   order_le_neq_trans
   823   order_less_trans
   824   order_less_asym'
   825   order_le_less_trans
   826   order_less_le_trans
   827   order_trans
   828   order_antisym
   829   ord_le_eq_trans
   830   ord_eq_le_trans
   831   ord_less_eq_trans
   832   ord_eq_less_trans
   833   trans
   834 
   835 
   836 (* FIXME cleanup *)
   837 
   838 text {* These support proving chains of decreasing inequalities
   839     a >= b >= c ... in Isar proofs. *}
   840 
   841 lemma xt1:
   842   "a = b ==> b > c ==> a > c"
   843   "a > b ==> b = c ==> a > c"
   844   "a = b ==> b >= c ==> a >= c"
   845   "a >= b ==> b = c ==> a >= c"
   846   "(x::'a::order) >= y ==> y >= x ==> x = y"
   847   "(x::'a::order) >= y ==> y >= z ==> x >= z"
   848   "(x::'a::order) > y ==> y >= z ==> x > z"
   849   "(x::'a::order) >= y ==> y > z ==> x > z"
   850   "(a::'a::order) > b ==> b > a ==> P"
   851   "(x::'a::order) > y ==> y > z ==> x > z"
   852   "(a::'a::order) >= b ==> a ~= b ==> a > b"
   853   "(a::'a::order) ~= b ==> a >= b ==> a > b"
   854   "a = f b ==> b > c ==> (!!x y. x > y ==> f x > f y) ==> a > f c" 
   855   "a > b ==> f b = c ==> (!!x y. x > y ==> f x > f y) ==> f a > c"
   856   "a = f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   857   "a >= b ==> f b = c ==> (!! x y. x >= y ==> f x >= f y) ==> f a >= c"
   858 by auto
   859 
   860 lemma xt2:
   861   "(a::'a::order) >= f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   862 by (subgoal_tac "f b >= f c", force, force)
   863 
   864 lemma xt3: "(a::'a::order) >= b ==> (f b::'b::order) >= c ==> 
   865     (!!x y. x >= y ==> f x >= f y) ==> f a >= c"
   866 by (subgoal_tac "f a >= f b", force, force)
   867 
   868 lemma xt4: "(a::'a::order) > f b ==> (b::'b::order) >= c ==>
   869   (!!x y. x >= y ==> f x >= f y) ==> a > f c"
   870 by (subgoal_tac "f b >= f c", force, force)
   871 
   872 lemma xt5: "(a::'a::order) > b ==> (f b::'b::order) >= c==>
   873     (!!x y. x > y ==> f x > f y) ==> f a > c"
   874 by (subgoal_tac "f a > f b", force, force)
   875 
   876 lemma xt6: "(a::'a::order) >= f b ==> b > c ==>
   877     (!!x y. x > y ==> f x > f y) ==> a > f c"
   878 by (subgoal_tac "f b > f c", force, force)
   879 
   880 lemma xt7: "(a::'a::order) >= b ==> (f b::'b::order) > c ==>
   881     (!!x y. x >= y ==> f x >= f y) ==> f a > c"
   882 by (subgoal_tac "f a >= f b", force, force)
   883 
   884 lemma xt8: "(a::'a::order) > f b ==> (b::'b::order) > c ==>
   885     (!!x y. x > y ==> f x > f y) ==> a > f c"
   886 by (subgoal_tac "f b > f c", force, force)
   887 
   888 lemma xt9: "(a::'a::order) > b ==> (f b::'b::order) > c ==>
   889     (!!x y. x > y ==> f x > f y) ==> f a > c"
   890 by (subgoal_tac "f a > f b", force, force)
   891 
   892 lemmas xtrans = xt1 xt2 xt3 xt4 xt5 xt6 xt7 xt8 xt9
   893 
   894 (* 
   895   Since "a >= b" abbreviates "b <= a", the abbreviation "..." stands
   896   for the wrong thing in an Isar proof.
   897 
   898   The extra transitivity rules can be used as follows: 
   899 
   900 lemma "(a::'a::order) > z"
   901 proof -
   902   have "a >= b" (is "_ >= ?rhs")
   903     sorry
   904   also have "?rhs >= c" (is "_ >= ?rhs")
   905     sorry
   906   also (xtrans) have "?rhs = d" (is "_ = ?rhs")
   907     sorry
   908   also (xtrans) have "?rhs >= e" (is "_ >= ?rhs")
   909     sorry
   910   also (xtrans) have "?rhs > f" (is "_ > ?rhs")
   911     sorry
   912   also (xtrans) have "?rhs > z"
   913     sorry
   914   finally (xtrans) show ?thesis .
   915 qed
   916 
   917   Alternatively, one can use "declare xtrans [trans]" and then
   918   leave out the "(xtrans)" above.
   919 *)
   920 
   921 subsection {* Order on bool *}
   922 
   923 instance bool :: order 
   924   le_bool_def: "P \<le> Q \<equiv> P \<longrightarrow> Q"
   925   less_bool_def: "P < Q \<equiv> P \<le> Q \<and> P \<noteq> Q"
   926   by intro_classes (auto simp add: le_bool_def less_bool_def)
   927 lemmas [code func del] = le_bool_def less_bool_def
   928 
   929 lemma le_boolI: "(P \<Longrightarrow> Q) \<Longrightarrow> P \<le> Q"
   930 by (simp add: le_bool_def)
   931 
   932 lemma le_boolI': "P \<longrightarrow> Q \<Longrightarrow> P \<le> Q"
   933 by (simp add: le_bool_def)
   934 
   935 lemma le_boolE: "P \<le> Q \<Longrightarrow> P \<Longrightarrow> (Q \<Longrightarrow> R) \<Longrightarrow> R"
   936 by (simp add: le_bool_def)
   937 
   938 lemma le_boolD: "P \<le> Q \<Longrightarrow> P \<longrightarrow> Q"
   939 by (simp add: le_bool_def)
   940 
   941 lemma [code func]:
   942   "False \<le> b \<longleftrightarrow> True"
   943   "True \<le> b \<longleftrightarrow> b"
   944   "False < b \<longleftrightarrow> b"
   945   "True < b \<longleftrightarrow> False"
   946   unfolding le_bool_def less_bool_def by simp_all
   947 
   948 
   949 subsection {* Order on sets *}
   950 
   951 instance set :: (type) order
   952   by (intro_classes,
   953       (assumption | rule subset_refl subset_trans subset_antisym psubset_eq)+)
   954 
   955 lemmas basic_trans_rules [trans] =
   956   order_trans_rules set_rev_mp set_mp
   957 
   958 
   959 subsection {* Order on functions *}
   960 
   961 instance "fun" :: (type, ord) ord
   962   le_fun_def: "f \<le> g \<equiv> \<forall>x. f x \<le> g x"
   963   less_fun_def: "f < g \<equiv> f \<le> g \<and> f \<noteq> g" ..
   964 
   965 lemmas [code func del] = le_fun_def less_fun_def
   966 
   967 instance "fun" :: (type, order) order
   968   by default
   969     (auto simp add: le_fun_def less_fun_def expand_fun_eq
   970        intro: order_trans order_antisym)
   971 
   972 lemma le_funI: "(\<And>x. f x \<le> g x) \<Longrightarrow> f \<le> g"
   973   unfolding le_fun_def by simp
   974 
   975 lemma le_funE: "f \<le> g \<Longrightarrow> (f x \<le> g x \<Longrightarrow> P) \<Longrightarrow> P"
   976   unfolding le_fun_def by simp
   977 
   978 lemma le_funD: "f \<le> g \<Longrightarrow> f x \<le> g x"
   979   unfolding le_fun_def by simp
   980 
   981 text {*
   982   Handy introduction and elimination rules for @{text "\<le>"}
   983   on unary and binary predicates
   984 *}
   985 
   986 lemma predicate1I [Pure.intro!, intro!]:
   987   assumes PQ: "\<And>x. P x \<Longrightarrow> Q x"
   988   shows "P \<le> Q"
   989   apply (rule le_funI)
   990   apply (rule le_boolI)
   991   apply (rule PQ)
   992   apply assumption
   993   done
   994 
   995 lemma predicate1D [Pure.dest, dest]: "P \<le> Q \<Longrightarrow> P x \<Longrightarrow> Q x"
   996   apply (erule le_funE)
   997   apply (erule le_boolE)
   998   apply assumption+
   999   done
  1000 
  1001 lemma predicate2I [Pure.intro!, intro!]:
  1002   assumes PQ: "\<And>x y. P x y \<Longrightarrow> Q x y"
  1003   shows "P \<le> Q"
  1004   apply (rule le_funI)+
  1005   apply (rule le_boolI)
  1006   apply (rule PQ)
  1007   apply assumption
  1008   done
  1009 
  1010 lemma predicate2D [Pure.dest, dest]: "P \<le> Q \<Longrightarrow> P x y \<Longrightarrow> Q x y"
  1011   apply (erule le_funE)+
  1012   apply (erule le_boolE)
  1013   apply assumption+
  1014   done
  1015 
  1016 lemma rev_predicate1D: "P x ==> P <= Q ==> Q x"
  1017   by (rule predicate1D)
  1018 
  1019 lemma rev_predicate2D: "P x y ==> P <= Q ==> Q x y"
  1020   by (rule predicate2D)
  1021 
  1022 
  1023 subsection {* Monotonicity, least value operator and min/max *}
  1024 
  1025 locale mono =
  1026   fixes f
  1027   assumes mono: "A \<le> B \<Longrightarrow> f A \<le> f B"
  1028 
  1029 lemmas monoI [intro?] = mono.intro
  1030   and monoD [dest?] = mono.mono
  1031 
  1032 lemma LeastI2_order:
  1033   "[| P (x::'a::order);
  1034       !!y. P y ==> x <= y;
  1035       !!x. [| P x; ALL y. P y --> x \<le> y |] ==> Q x |]
  1036    ==> Q (Least P)"
  1037 apply (unfold Least_def)
  1038 apply (rule theI2)
  1039   apply (blast intro: order_antisym)+
  1040 done
  1041 
  1042 lemma Least_mono:
  1043   "mono (f::'a::order => 'b::order) ==> EX x:S. ALL y:S. x <= y
  1044     ==> (LEAST y. y : f ` S) = f (LEAST x. x : S)"
  1045     -- {* Courtesy of Stephan Merz *}
  1046   apply clarify
  1047   apply (erule_tac P = "%x. x : S" in LeastI2_order, fast)
  1048   apply (rule LeastI2_order)
  1049   apply (auto elim: monoD intro!: order_antisym)
  1050   done
  1051 
  1052 lemma Least_equality:
  1053   "[| P (k::'a::order); !!x. P x ==> k <= x |] ==> (LEAST x. P x) = k"
  1054 apply (simp add: Least_def)
  1055 apply (rule the_equality)
  1056 apply (auto intro!: order_antisym)
  1057 done
  1058 
  1059 lemma min_leastL: "(!!x. least <= x) ==> min least x = least"
  1060 by (simp add: min_def)
  1061 
  1062 lemma max_leastL: "(!!x. least <= x) ==> max least x = x"
  1063 by (simp add: max_def)
  1064 
  1065 lemma min_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> min x least = least"
  1066 apply (simp add: min_def)
  1067 apply (blast intro: order_antisym)
  1068 done
  1069 
  1070 lemma max_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> max x least = x"
  1071 apply (simp add: max_def)
  1072 apply (blast intro: order_antisym)
  1073 done
  1074 
  1075 lemma min_of_mono:
  1076   "(!!x y. (f x <= f y) = (x <= y)) ==> min (f m) (f n) = f (min m n)"
  1077 by (simp add: min_def)
  1078 
  1079 lemma max_of_mono:
  1080   "(!!x y. (f x <= f y) = (x <= y)) ==> max (f m) (f n) = f (max m n)"
  1081 by (simp add: max_def)
  1082 
  1083 
  1084 subsection {* legacy ML bindings *}
  1085 
  1086 ML {*
  1087 val monoI = @{thm monoI};
  1088 *}
  1089 
  1090 end