src/Pure/library.ML
author wenzelm
Thu Aug 23 13:03:29 2012 +0200 (2012-08-23)
changeset 48902 44a6967240b7
parent 48271 b28defd0b5a5
child 50637 81d6fe75ea5b
permissions -rw-r--r--
prefer classic take_prefix/take_suffix over chop_while (cf. 0659e84bdc5f);
     1 (*  Title:      Pure/library.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Basic library: functions, pairs, booleans, lists, integers,
     6 strings, lists as sets, orders, current directory, misc.
     7 
     8 See also General/basics.ML for the most fundamental concepts.
     9 *)
    10 
    11 infix 2 ?
    12 infix 3 o oo ooo oooo
    13 infix 4 ~~ upto downto
    14 infix orf andf
    15 
    16 signature BASIC_LIBRARY =
    17 sig
    18   (*functions*)
    19   val undefined: 'a -> 'b
    20   val I: 'a -> 'a
    21   val K: 'a -> 'b -> 'a
    22   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    23   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    24   val ? : bool * ('a -> 'a) -> 'a -> 'a
    25   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    26   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    27   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    28   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    29   val funpow_yield: int -> ('a -> 'b * 'a) -> 'a -> 'b list * 'a
    30 
    31   (*user errors*)
    32   exception ERROR of string
    33   val error: string -> 'a
    34   val cat_error: string -> string -> 'a
    35   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    36 
    37   (*pairs*)
    38   val pair: 'a -> 'b -> 'a * 'b
    39   val rpair: 'a -> 'b -> 'b * 'a
    40   val fst: 'a * 'b -> 'a
    41   val snd: 'a * 'b -> 'b
    42   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    43   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    44   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    45   val swap: 'a * 'b -> 'b * 'a
    46   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    47   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    48   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    49 
    50   (*booleans*)
    51   val equal: ''a -> ''a -> bool
    52   val not_equal: ''a -> ''a -> bool
    53   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    54   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    55   val exists: ('a -> bool) -> 'a list -> bool
    56   val forall: ('a -> bool) -> 'a list -> bool
    57   val setmp_CRITICAL: 'a Unsynchronized.ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    58   val setmp_thread_data: 'a Universal.tag -> 'a -> 'a -> ('b -> 'c) -> 'b -> 'c
    59 
    60   (*lists*)
    61   val single: 'a -> 'a list
    62   val the_single: 'a list -> 'a
    63   val singleton: ('a list -> 'b list) -> 'a -> 'b
    64   val yield_singleton: ('a list -> 'c -> 'b list * 'c) -> 'a -> 'c -> 'b * 'c
    65   val perhaps_apply: ('a -> 'a option) list -> 'a -> 'a option
    66   val perhaps_loop: ('a -> 'a option) -> 'a -> 'a option
    67   val foldl1: ('a * 'a -> 'a) -> 'a list -> 'a
    68   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    69   val eq_list: ('a * 'a -> bool) -> 'a list * 'a list -> bool
    70   val maps: ('a -> 'b list) -> 'a list -> 'b list
    71   val filter: ('a -> bool) -> 'a list -> 'a list
    72   val filter_out: ('a -> bool) -> 'a list -> 'a list
    73   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
    74   val take: int -> 'a list -> 'a list
    75   val drop: int -> 'a list -> 'a list
    76   val chop: int -> 'a list -> 'a list * 'a list
    77   val chop_groups: int -> 'a list -> 'a list list
    78   val nth: 'a list -> int -> 'a
    79   val nth_list: 'a list list -> int -> 'a list
    80   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    81   val nth_drop: int -> 'a list -> 'a list
    82   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    83   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    84   val map_range: (int -> 'a) -> int -> 'a list
    85   val split_last: 'a list -> 'a list * 'a
    86   val find_first: ('a -> bool) -> 'a list -> 'a option
    87   val find_index: ('a -> bool) -> 'a list -> int
    88   val get_first: ('a -> 'b option) -> 'a list -> 'b option
    89   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
    90   val flat: 'a list list -> 'a list
    91   val unflat: 'a list list -> 'b list -> 'b list list
    92   val grouped: int -> (('a list -> 'b list) -> 'c list list -> 'd list list) ->
    93     ('a -> 'b) -> 'c list -> 'd list
    94   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    95   val burrow_options: ('a list -> 'b list) -> 'a option list -> 'b option list
    96   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    97   val separate: 'a -> 'a list -> 'a list
    98   val surround: 'a -> 'a list -> 'a list
    99   val replicate: int -> 'a -> 'a list
   100   val map_product: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   101   val fold_product: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   102   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   103   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   104   val fold_rev2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   105   val forall2: ('a -> 'b -> bool) -> 'a list -> 'b list -> bool
   106   val map_split: ('a -> 'b * 'c) -> 'a list -> 'b list * 'c list
   107   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   108   val ~~ : 'a list * 'b list -> ('a * 'b) list
   109   val split_list: ('a * 'b) list -> 'a list * 'b list
   110   val burrow_fst: ('a list -> 'b list) -> ('a * 'c) list -> ('b * 'c) list
   111   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   112   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   113   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   114   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   115   val prefixes1: 'a list -> 'a list list
   116   val prefixes: 'a list -> 'a list list
   117   val suffixes1: 'a list -> 'a list list
   118   val suffixes: 'a list -> 'a list list
   119 
   120   (*integers*)
   121   val upto: int * int -> int list
   122   val downto: int * int -> int list
   123   val radixpand: int * int -> int list
   124   val radixstring: int * string * int -> string
   125   val string_of_int: int -> string
   126   val signed_string_of_int: int -> string
   127   val string_of_indexname: string * int -> string
   128   val read_radix_int: int -> string list -> int * string list
   129   val read_int: string list -> int * string list
   130   val oct_char: string -> string
   131 
   132   (*strings*)
   133   val nth_string: string -> int -> string
   134   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   135   val exists_string: (string -> bool) -> string -> bool
   136   val forall_string: (string -> bool) -> string -> bool
   137   val first_field: string -> string -> (string * string) option
   138   val enclose: string -> string -> string -> string
   139   val unenclose: string -> string
   140   val quote: string -> string
   141   val space_implode: string -> string list -> string
   142   val commas: string list -> string
   143   val commas_quote: string list -> string
   144   val cat_lines: string list -> string
   145   val space_explode: string -> string -> string list
   146   val split_lines: string -> string list
   147   val prefix_lines: string -> string -> string
   148   val prefix: string -> string -> string
   149   val suffix: string -> string -> string
   150   val unprefix: string -> string -> string
   151   val unsuffix: string -> string -> string
   152   val trim_line: string -> string
   153   val replicate_string: int -> string -> string
   154   val translate_string: (string -> string) -> string -> string
   155   val match_string: string -> string -> bool
   156 
   157   (*reals*)
   158   val string_of_real: real -> string
   159   val signed_string_of_real: real -> string
   160   val smart_string_of_real: real -> string
   161 
   162   (*lists as sets -- see also Pure/General/ord_list.ML*)
   163   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   164   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   165   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   166   val update: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   167   val union: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   168   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   169   val inter: ('a * 'b -> bool) -> 'b list -> 'a list -> 'a list
   170   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   171   val subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   172   val eq_set: ('a * 'a -> bool) -> 'a list * 'a list -> bool
   173   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   174   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   175   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   176   val map_transpose: ('a list -> 'b) -> 'a list list -> 'b list
   177 
   178   (*lists as multisets*)
   179   val remove1: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   180   val combine: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   181   val submultiset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   182 
   183   (*orders*)
   184   val is_equal: order -> bool
   185   val rev_order: order -> order
   186   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   187   val bool_ord: bool * bool -> order
   188   val int_ord: int * int -> order
   189   val string_ord: string * string -> order
   190   val fast_string_ord: string * string -> order
   191   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   192   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   193   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   194   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   195   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   196   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   197   val sort_strings: string list -> string list
   198   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   199   val tag_list: int -> 'a list -> (int * 'a) list
   200   val untag_list: (int * 'a) list -> 'a list
   201   val order_list: (int * 'a) list -> 'a list
   202 
   203   (*random numbers*)
   204   exception RANDOM
   205   val random: unit -> real
   206   val random_range: int -> int -> int
   207   val one_of: 'a list -> 'a
   208   val frequency: (int * 'a) list -> 'a
   209 
   210   (*misc*)
   211   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   212   val divide_and_conquer': ('a -> 'b -> ('a list * ('c list * 'b -> 'c * 'b)) * 'b) ->
   213     'a -> 'b -> 'c * 'b
   214   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   215   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   216   type serial = int
   217   val serial: unit -> serial
   218   val serial_string: unit -> string
   219   eqtype stamp
   220   val stamp: unit -> stamp
   221   structure Object: sig type T = exn end
   222   val cd: string -> unit
   223   val pwd: unit -> string
   224   val getenv: string -> string
   225   val getenv_strict: string -> string
   226 end;
   227 
   228 signature LIBRARY =
   229 sig
   230   include BASIC_LIBRARY
   231   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   232   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   233 end;
   234 
   235 structure Library: LIBRARY =
   236 struct
   237 
   238 (* functions *)
   239 
   240 fun undefined _ = raise Match;
   241 
   242 fun I x = x;
   243 fun K x = fn _ => x;
   244 fun curry f x y = f (x, y);
   245 fun uncurry f (x, y) = f x y;
   246 
   247 (*conditional application*)
   248 fun b ? f = fn x => if b then f x else x;
   249 
   250 (*composition with multiple args*)
   251 fun (f oo g) x y = f (g x y);
   252 fun (f ooo g) x y z = f (g x y z);
   253 fun (f oooo g) x y z w = f (g x y z w);
   254 
   255 (*function exponentiation: f (... (f x) ...) with n applications of f*)
   256 fun funpow (0 : int) _ = I
   257   | funpow n f = f #> funpow (n - 1) f;
   258 
   259 fun funpow_yield (0 : int) _ x = ([], x)
   260   | funpow_yield n f x = x |> f ||>> funpow_yield (n - 1) f |>> op ::;
   261 
   262 
   263 (* user errors *)
   264 
   265 exception ERROR of string;
   266 fun error msg = raise ERROR msg;
   267 
   268 fun cat_error "" msg = error msg
   269   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   270 
   271 fun assert_all pred list msg =
   272   let
   273     fun ass [] = ()
   274       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   275   in ass list end;
   276 
   277 
   278 (* pairs *)
   279 
   280 fun pair x y = (x, y);
   281 fun rpair x y = (y, x);
   282 
   283 fun fst (x, y) = x;
   284 fun snd (x, y) = y;
   285 
   286 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   287 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   288 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   289 
   290 fun swap (x, y) = (y, x);
   291 
   292 fun apfst f (x, y) = (f x, y);
   293 fun apsnd f (x, y) = (x, f y);
   294 fun pairself f (x, y) = (f x, f y);
   295 
   296 
   297 (* booleans *)
   298 
   299 (*polymorphic equality*)
   300 fun equal x y = x = y;
   301 fun not_equal x y = x <> y;
   302 
   303 (*combining predicates*)
   304 fun p orf q = fn x => p x orelse q x;
   305 fun p andf q = fn x => p x andalso q x;
   306 
   307 val exists = List.exists;
   308 val forall = List.all;
   309 
   310 
   311 (* flags *)
   312 
   313 fun setmp_CRITICAL flag value f x =
   314   NAMED_CRITICAL "setmp" (fn () => Unsynchronized.setmp flag value f x);
   315 
   316 fun setmp_thread_data tag orig_data data f x =
   317   uninterruptible (fn restore_attributes => fn () =>
   318     let
   319       val _ = Thread.setLocal (tag, data);
   320       val result = Exn.capture (restore_attributes f) x;
   321       val _ = Thread.setLocal (tag, orig_data);
   322     in Exn.release result end) ();
   323 
   324 
   325 
   326 (** lists **)
   327 
   328 fun single x = [x];
   329 
   330 fun the_single [x] = x
   331   | the_single _ = raise List.Empty;
   332 
   333 fun singleton f x = the_single (f [x]);
   334 
   335 fun yield_singleton f x = f [x] #>> the_single;
   336 
   337 fun perhaps_apply funs arg =
   338   let
   339     fun app [] res = res
   340       | app (f :: fs) (changed, x) =
   341           (case f x of
   342             NONE => app fs (changed, x)
   343           | SOME x' => app fs (true, x'));
   344   in (case app funs (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   345 
   346 fun perhaps_loop f arg =
   347   let
   348     fun loop (changed, x) =
   349       (case f x of
   350         NONE => (changed, x)
   351       | SOME x' => loop (true, x'));
   352   in (case loop (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   353 
   354 
   355 (* fold -- old versions *)
   356 
   357 (*the following versions of fold are designed to fit nicely with infixes*)
   358 
   359 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   360     for operators that associate to the left (TAIL RECURSIVE)*)
   361 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   362   let fun itl (e, [])  = e
   363         | itl (e, a::l) = itl (f(e, a), l)
   364   in  itl end;
   365 
   366 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   367     for operators that associate to the right (not tail recursive)*)
   368 fun foldr f (l, e) =
   369   let fun itr [] = e
   370         | itr (a::l) = f(a, itr l)
   371   in  itr l  end;
   372 
   373 (*  (op @) [x1, ..., xn]  ===>  ((x1 @ x2) @ x3) ... @ xn
   374     for operators that associate to the left (TAIL RECURSIVE)*)
   375 fun foldl1 f [] = raise List.Empty
   376   | foldl1 f (x :: xs) = foldl f (x, xs);
   377 
   378 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   379     for n > 0, operators that associate to the right (not tail recursive)*)
   380 fun foldr1 f [] = raise List.Empty
   381   | foldr1 f l =
   382       let fun itr [x] = x
   383             | itr (x::l) = f(x, itr l)
   384       in  itr l  end;
   385 
   386 
   387 (* basic list functions *)
   388 
   389 fun eq_list eq (list1, list2) =
   390   pointer_eq (list1, list2) orelse
   391     let
   392       fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   393         | eq_lst _ = true;
   394     in length list1 = length list2 andalso eq_lst (list1, list2) end;
   395 
   396 fun maps f [] = []
   397   | maps f (x :: xs) = f x @ maps f xs;
   398 
   399 val filter = List.filter;
   400 fun filter_out f = filter (not o f);
   401 val map_filter = List.mapPartial;
   402 
   403 fun take (0: int) xs = []
   404   | take _ [] = []
   405   | take n (x :: xs) = x :: take (n - 1) xs;
   406 
   407 fun drop (0: int) xs = xs
   408   | drop _ [] = []
   409   | drop n (x :: xs) = drop (n - 1) xs;
   410 
   411 fun chop (0: int) xs = ([], xs)
   412   | chop _ [] = ([], [])
   413   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   414 
   415 fun chop_groups n list =
   416   (case chop (Int.max (n, 1)) list of
   417     ([], _) => []
   418   | (g, rest) => g :: chop_groups n rest);
   419 
   420 
   421 (*return nth element of a list, where 0 designates the first element;
   422   raise Subscript if list too short*)
   423 fun nth xs i = List.nth (xs, i);
   424 
   425 fun nth_list xss i = nth xss i handle General.Subscript => [];
   426 
   427 fun nth_map 0 f (x :: xs) = f x :: xs
   428   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   429   | nth_map (_: int) _ [] = raise Subscript;
   430 
   431 fun nth_drop n xs =
   432   List.take (xs, n) @ List.drop (xs, n + 1);
   433 
   434 fun map_index f =
   435   let
   436     fun mapp (_: int) [] = []
   437       | mapp i (x :: xs) = f (i, x) :: mapp (i + 1) xs
   438   in mapp 0 end;
   439 
   440 fun fold_index f =
   441   let
   442     fun fold_aux (_: int) [] y = y
   443       | fold_aux i (x :: xs) y = fold_aux (i + 1) xs (f (i, x) y);
   444   in fold_aux 0 end;
   445 
   446 fun map_range f i =
   447   let
   448     fun mapp (k: int) =
   449       if k < i then f k :: mapp (k + 1) else [];
   450   in mapp 0 end;
   451 
   452 (*rear decomposition*)
   453 fun split_last [] = raise List.Empty
   454   | split_last [x] = ([], x)
   455   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   456 
   457 (*find first element satisfying predicate*)
   458 val find_first = List.find;
   459 
   460 (*find position of first element satisfying a predicate*)
   461 fun find_index pred =
   462   let fun find (_: int) [] = ~1
   463         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   464   in find 0 end;
   465 
   466 (*get first element by lookup function*)
   467 fun get_first _ [] = NONE
   468   | get_first f (x :: xs) =
   469       (case f x of
   470         NONE => get_first f xs
   471       | some => some);
   472 
   473 fun get_index f =
   474   let
   475     fun get (_: int) [] = NONE
   476       | get i (x :: xs) =
   477           (case f x of
   478             NONE => get (i + 1) xs
   479           | SOME y => SOME (i, y))
   480   in get 0 end;
   481 
   482 val flat = List.concat;
   483 
   484 fun unflat (xs :: xss) ys =
   485       let val (ps, qs) = chop (length xs) ys
   486       in ps :: unflat xss qs end
   487   | unflat [] [] = []
   488   | unflat _ _ = raise ListPair.UnequalLengths;
   489 
   490 fun grouped n comb f = chop_groups n #> comb (map f) #> flat;
   491 
   492 fun burrow f xss = unflat xss (f (flat xss));
   493 
   494 fun burrow_options f os = map (try hd) (burrow f (map the_list os));
   495 
   496 fun fold_burrow f xss s =
   497   apfst (unflat xss) (f (flat xss) s);
   498 
   499 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   500 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   501   | separate _ xs = xs;
   502 
   503 fun surround s (x :: xs) = s :: x :: surround s xs
   504   | surround s [] = [s];
   505 
   506 (*make the list [x, x, ..., x] of length n*)
   507 fun replicate (n: int) x =
   508   let fun rep (0, xs) = xs
   509         | rep (n, xs) = rep (n - 1, x :: xs)
   510   in
   511     if n < 0 then raise Subscript
   512     else rep (n, [])
   513   end;
   514 
   515 
   516 (* direct product *)
   517 
   518 fun map_product f _ [] = []
   519   | map_product f [] _ = []
   520   | map_product f (x :: xs) ys = map (f x) ys @ map_product f xs ys;
   521 
   522 fun fold_product f _ [] z = z
   523   | fold_product f [] _ z = z
   524   | fold_product f (x :: xs) ys z = z |> fold (f x) ys |> fold_product f xs ys;
   525 
   526 
   527 (* lists of pairs *)
   528 
   529 fun map2 _ [] [] = []
   530   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   531   | map2 _ _ _ = raise ListPair.UnequalLengths;
   532 
   533 fun fold2 f [] [] z = z
   534   | fold2 f (x :: xs) (y :: ys) z = fold2 f xs ys (f x y z)
   535   | fold2 f _ _ _ = raise ListPair.UnequalLengths;
   536 
   537 fun fold_rev2 f [] [] z = z
   538   | fold_rev2 f (x :: xs) (y :: ys) z = f x y (fold_rev2 f xs ys z)
   539   | fold_rev2 f _ _ _ = raise ListPair.UnequalLengths;
   540 
   541 fun forall2 P [] [] = true
   542   | forall2 P (x :: xs) (y :: ys) = P x y andalso forall2 P xs ys
   543   | forall2 P _ _ = raise ListPair.UnequalLengths;
   544 
   545 fun map_split f [] = ([], [])
   546   | map_split f (x :: xs) =
   547       let
   548         val (y, w) = f x;
   549         val (ys, ws) = map_split f xs;
   550       in (y :: ys, w :: ws) end;
   551 
   552 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   553   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   554   | zip_options _ [] = []
   555   | zip_options [] _ = raise ListPair.UnequalLengths;
   556 
   557 (*combine two lists forming a list of pairs:
   558   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   559 fun [] ~~ [] = []
   560   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   561   | _ ~~ _ = raise ListPair.UnequalLengths;
   562 
   563 (*inverse of ~~; the old 'split':
   564   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   565 val split_list = ListPair.unzip;
   566 
   567 fun burrow_fst f xs = split_list xs |>> f |> op ~~;
   568 
   569 
   570 (* prefixes, suffixes *)
   571 
   572 fun is_prefix _ [] _ = true
   573   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   574   | is_prefix eq _ _ = false;
   575 
   576 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   577    where xi is the first element that does not satisfy the predicate*)
   578 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   579   let fun take (rxs, []) = (rev rxs, [])
   580         | take (rxs, x :: xs) =
   581             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   582   in  take([], xs)  end;
   583 
   584 fun chop_prefix eq ([], ys) = ([], ([], ys))
   585   | chop_prefix eq (xs, []) = ([], (xs, []))
   586   | chop_prefix eq (xs as x :: xs', ys as y :: ys') =
   587       if eq (x, y) then
   588         let val (ps', xys'') = chop_prefix eq (xs', ys')
   589         in (x :: ps', xys'') end
   590       else ([], (xs, ys));
   591 
   592 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   593    where xi is the last element that does not satisfy the predicate*)
   594 fun take_suffix _ [] = ([], [])
   595   | take_suffix pred (x :: xs) =
   596       (case take_suffix pred xs of
   597         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   598       | (prfx, sffx) => (x :: prfx, sffx));
   599 
   600 fun prefixes1 [] = []
   601   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   602 
   603 fun prefixes xs = [] :: prefixes1 xs;
   604 
   605 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   606 fun suffixes xs = [] :: suffixes1 xs;
   607 
   608 
   609 
   610 (** integers **)
   611 
   612 (* lists of integers *)
   613 
   614 (*make the list [from, from + 1, ..., to]*)
   615 fun ((i: int) upto j) =
   616   if i > j then [] else i :: (i + 1 upto j);
   617 
   618 (*make the list [from, from - 1, ..., to]*)
   619 fun ((i: int) downto j) =
   620   if i < j then [] else i :: (i - 1 downto j);
   621 
   622 
   623 (* convert integers to strings *)
   624 
   625 (*expand the number in the given base;
   626   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   627 fun radixpand (base, num) : int list =
   628   let
   629     fun radix (n, tail) =
   630       if n < base then n :: tail
   631       else radix (n div base, (n mod base) :: tail)
   632   in radix (num, []) end;
   633 
   634 (*expands a number into a string of characters starting from "zerochar";
   635   example: radixstring (2, "0", 8) gives "1000"*)
   636 fun radixstring (base, zerochar, num) =
   637   let val offset = ord zerochar;
   638       fun chrof n = chr (offset + n)
   639   in implode (map chrof (radixpand (base, num))) end;
   640 
   641 
   642 local
   643   val zero = ord "0";
   644   val small = 10000: int;
   645   val small_table = Vector.tabulate (small, Int.toString);
   646 in
   647 
   648 fun string_of_int i =
   649   if i < 0 then Int.toString i
   650   else if i < 10 then chr (zero + i)
   651   else if i < small then Vector.sub (small_table, i)
   652   else Int.toString i;
   653 
   654 end;
   655 
   656 fun signed_string_of_int i =
   657   if i < 0 then "-" ^ string_of_int (~ i) else string_of_int i;
   658 
   659 fun string_of_indexname (a, 0) = a
   660   | string_of_indexname (a, i) = a ^ "_" ^ string_of_int i;
   661 
   662 
   663 (* read integers *)
   664 
   665 fun read_radix_int radix cs =
   666   let
   667     val zero = ord "0";
   668     val limit = zero + radix;
   669     fun scan (num, []) = (num, [])
   670       | scan (num, c :: cs) =
   671         if zero <= ord c andalso ord c < limit then
   672           scan (radix * num + (ord c - zero), cs)
   673         else (num, c :: cs);
   674   in scan (0, cs) end;
   675 
   676 val read_int = read_radix_int 10;
   677 
   678 fun oct_char s = chr (#1 (read_radix_int 8 (raw_explode s)));
   679 
   680 
   681 
   682 (** strings **)
   683 
   684 (* functions tuned for strings, avoiding explode *)
   685 
   686 fun nth_string str i =
   687   (case try String.substring (str, i, 1) of
   688     SOME s => s
   689   | NONE => raise Subscript);
   690 
   691 fun fold_string f str x0 =
   692   let
   693     val n = size str;
   694     fun iter (x, i) =
   695       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   696   in iter (x0, 0) end;
   697 
   698 fun exists_string pred str =
   699   let
   700     val n = size str;
   701     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   702   in ex 0 end;
   703 
   704 fun forall_string pred = not o exists_string (not o pred);
   705 
   706 fun first_field sep str =
   707   let
   708     val n = size sep;
   709     val len = size str;
   710     fun find i =
   711       if i + n > len then NONE
   712       else if String.substring (str, i, n) = sep then SOME i
   713       else find (i + 1);
   714   in
   715     (case find 0 of
   716       NONE => NONE
   717     | SOME i => SOME (String.substring (str, 0, i), String.extract (str, i + n, NONE)))
   718   end;
   719 
   720 (*enclose in brackets*)
   721 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   722 fun unenclose str = String.substring (str, 1, size str - 2);
   723 
   724 (*simple quoting (does not escape special chars)*)
   725 val quote = enclose "\"" "\"";
   726 
   727 fun space_implode a bs = implode (separate a bs);
   728 
   729 val commas = space_implode ", ";
   730 val commas_quote = commas o map quote;
   731 
   732 val cat_lines = space_implode "\n";
   733 
   734 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   735 fun space_explode _ "" = []
   736   | space_explode sep s = String.fields (fn c => str c = sep) s;
   737 
   738 val split_lines = space_explode "\n";
   739 
   740 fun prefix_lines "" txt = txt
   741   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   742 
   743 fun prefix prfx s = prfx ^ s;
   744 fun suffix sffx s = s ^ sffx;
   745 
   746 fun unprefix prfx s =
   747   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   748   else raise Fail "unprefix";
   749 
   750 fun unsuffix sffx s =
   751   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   752   else raise Fail "unsuffix";
   753 
   754 val trim_line = perhaps (try (unsuffix "\n"));
   755 
   756 fun replicate_string (0: int) _ = ""
   757   | replicate_string 1 a = a
   758   | replicate_string k a =
   759       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   760       else replicate_string (k div 2) (a ^ a) ^ a;
   761 
   762 fun translate_string f = String.translate (f o String.str);
   763 
   764 (*crude matching of str against simple glob pat*)
   765 fun match_string pat str =
   766   let
   767     fun match [] _ = true
   768       | match (p :: ps) s =
   769           size p <= size s andalso
   770             (case try (unprefix p) s of
   771               SOME s' => match ps s'
   772             | NONE => match (p :: ps) (String.substring (s, 1, size s - 1)));
   773   in match (space_explode "*" pat) str end;
   774 
   775 
   776 (** reals **)
   777 
   778 val string_of_real = Real.fmt (StringCvt.GEN NONE);
   779 
   780 fun signed_string_of_real x =
   781   if x < 0.0 then "-" ^ string_of_real (~ x) else string_of_real x;
   782 
   783 fun smart_string_of_real x =
   784   let
   785     val s = signed_string_of_real x;
   786   in
   787     (case space_explode "." s of
   788       [a, b] => if forall_string (fn c => c = "0") b then a else s
   789     | _ => s)
   790   end;
   791 
   792 
   793 
   794 (** lists as sets -- see also Pure/General/ord_list.ML **)
   795 
   796 (* canonical operations *)
   797 
   798 fun member eq list x =
   799   let
   800     fun memb [] = false
   801       | memb (y :: ys) = eq (x, y) orelse memb ys;
   802   in memb list end;
   803 
   804 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   805 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   806 fun update eq x xs = cons x (remove eq x xs);
   807 
   808 fun inter eq xs = filter (member eq xs);
   809 
   810 fun union eq = fold (insert eq);
   811 fun subtract eq = fold (remove eq);
   812 
   813 fun merge eq (xs, ys) =
   814   if pointer_eq (xs, ys) then xs
   815   else if null xs then ys
   816   else fold_rev (insert eq) ys xs;
   817 
   818 
   819 (* subset and set equality *)
   820 
   821 fun subset eq (xs, ys) = forall (member eq ys) xs;
   822 
   823 fun eq_set eq (xs, ys) =
   824   eq_list eq (xs, ys) orelse
   825     (subset eq (xs, ys) andalso subset (eq o swap) (ys, xs));
   826 
   827 
   828 (*makes a list of the distinct members of the input; preserves order, takes
   829   first of equal elements*)
   830 fun distinct eq lst =
   831   let
   832     fun dist (rev_seen, []) = rev rev_seen
   833       | dist (rev_seen, x :: xs) =
   834           if member eq rev_seen x then dist (rev_seen, xs)
   835           else dist (x :: rev_seen, xs);
   836   in dist ([], lst) end;
   837 
   838 (*returns a list containing all repeated elements exactly once; preserves
   839   order, takes first of equal elements*)
   840 fun duplicates eq lst =
   841   let
   842     fun dups (rev_dups, []) = rev rev_dups
   843       | dups (rev_dups, x :: xs) =
   844           if member eq rev_dups x orelse not (member eq xs x) then
   845             dups (rev_dups, xs)
   846           else dups (x :: rev_dups, xs);
   847   in dups ([], lst) end;
   848 
   849 fun has_duplicates eq =
   850   let
   851     fun dups [] = false
   852       | dups (x :: xs) = member eq xs x orelse dups xs;
   853   in dups end;
   854 
   855 
   856 (* matrices *)
   857 
   858 fun map_transpose f xss =
   859   let
   860     val n =
   861       (case distinct (op =) (map length xss) of
   862         [] => 0
   863       | [n] => n
   864       | _ => raise ListPair.UnequalLengths);
   865   in map_range (fn m => f (map (fn xs => nth xs m) xss)) n end;
   866 
   867 
   868 
   869 (** lists as multisets **)
   870 
   871 fun remove1 eq x [] = []
   872   | remove1 eq x (y :: ys) = if eq (x, y) then ys else y :: remove1 eq x ys;
   873 
   874 fun combine eq xs ys = fold (remove1 eq) ys xs @ ys;
   875 
   876 fun submultiset _ ([], _)  = true
   877   | submultiset eq (x :: xs, ys) = member eq ys x andalso submultiset eq (xs, remove1 eq x ys);
   878 
   879 
   880 
   881 (** orders **)
   882 
   883 fun is_equal EQUAL = true
   884   | is_equal _ = false;
   885 
   886 fun rev_order LESS = GREATER
   887   | rev_order EQUAL = EQUAL
   888   | rev_order GREATER = LESS;
   889 
   890 (*assume rel is a linear strict order*)
   891 fun make_ord rel (x, y) =
   892   if rel (x, y) then LESS
   893   else if rel (y, x) then GREATER
   894   else EQUAL;
   895 
   896 fun bool_ord (false, true) = LESS
   897   | bool_ord (true, false) = GREATER
   898   | bool_ord _ = EQUAL;
   899 
   900 val int_ord = Int.compare;
   901 val string_ord = String.compare;
   902 
   903 fun fast_string_ord (s1, s2) =
   904   if pointer_eq (s1, s2) then EQUAL
   905   else (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
   906 
   907 fun option_ord ord (SOME x, SOME y) = ord (x, y)
   908   | option_ord _ (NONE, NONE) = EQUAL
   909   | option_ord _ (NONE, SOME _) = LESS
   910   | option_ord _ (SOME _, NONE) = GREATER;
   911 
   912 (*lexicographic product*)
   913 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
   914   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
   915 
   916 (*dictionary order -- in general NOT well-founded!*)
   917 fun dict_ord elem_ord (x :: xs, y :: ys) =
   918       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
   919   | dict_ord _ ([], []) = EQUAL
   920   | dict_ord _ ([], _ :: _) = LESS
   921   | dict_ord _ (_ :: _, []) = GREATER;
   922 
   923 (*lexicographic product of lists*)
   924 fun list_ord elem_ord (xs, ys) =
   925   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
   926 
   927 
   928 (* sorting *)
   929 
   930 (*stable mergesort -- preserves order of equal elements*)
   931 fun mergesort unique ord =
   932   let
   933     fun merge (xs as x :: xs') (ys as y :: ys') =
   934           (case ord (x, y) of
   935             LESS => x :: merge xs' ys
   936           | EQUAL =>
   937               if unique then merge xs ys'
   938               else x :: merge xs' ys
   939           | GREATER => y :: merge xs ys')
   940       | merge [] ys = ys
   941       | merge xs [] = xs;
   942 
   943     fun merge_all [xs] = xs
   944       | merge_all xss = merge_all (merge_pairs xss)
   945     and merge_pairs (xs :: ys :: xss) = merge xs ys :: merge_pairs xss
   946       | merge_pairs xss = xss;
   947 
   948     fun runs (x :: y :: xs) =
   949           (case ord (x, y) of
   950              LESS => ascending y [x] xs
   951            | EQUAL =>
   952                if unique then runs (x :: xs)
   953                else ascending y [x] xs
   954            | GREATER => descending y [x] xs)
   955       | runs xs = [xs]
   956 
   957     and ascending x xs (zs as y :: ys) =
   958           (case ord (x, y) of
   959              LESS => ascending y (x :: xs) ys
   960            | EQUAL =>
   961                if unique then ascending x xs ys
   962                else ascending y (x :: xs) ys
   963            | GREATER => rev (x :: xs) :: runs zs)
   964       | ascending x xs [] = [rev (x :: xs)]
   965 
   966     and descending x xs (zs as y :: ys) =
   967           (case ord (x, y) of
   968              GREATER => descending y (x :: xs) ys
   969            | EQUAL =>
   970                if unique then descending x xs ys
   971                else (x :: xs) :: runs zs
   972            | LESS => (x :: xs) :: runs zs)
   973       | descending x xs [] = [x :: xs];
   974 
   975   in merge_all o runs end;
   976 
   977 fun sort ord = mergesort false ord;
   978 fun sort_distinct ord = mergesort true ord;
   979 
   980 val sort_strings = sort string_ord;
   981 fun sort_wrt key xs = sort (string_ord o pairself key) xs;
   982 
   983 
   984 (* items tagged by integer index *)
   985 
   986 (*insert tags*)
   987 fun tag_list k [] = []
   988   | tag_list k (x :: xs) = (k:int, x) :: tag_list (k + 1) xs;
   989 
   990 (*remove tags and suppress duplicates -- list is assumed sorted!*)
   991 fun untag_list [] = []
   992   | untag_list [(k: int, x)] = [x]
   993   | untag_list ((k, x) :: (rest as (k', x') :: _)) =
   994       if k = k' then untag_list rest
   995       else x :: untag_list rest;
   996 
   997 (*return list elements in original order*)
   998 fun order_list list = untag_list (sort (int_ord o pairself fst) list);
   999 
  1000 
  1001 
  1002 (** random numbers **)
  1003 
  1004 exception RANDOM;
  1005 
  1006 fun rmod x y = x - y * Real.realFloor (x / y);
  1007 
  1008 local
  1009   val a = 16807.0;
  1010   val m = 2147483647.0;
  1011   val random_seed = Unsynchronized.ref 1.0;
  1012 in
  1013 
  1014 fun random () = CRITICAL (fn () =>
  1015   let val r = rmod (a * ! random_seed) m
  1016   in (random_seed := r; r) end);
  1017 
  1018 end;
  1019 
  1020 fun random_range l h =
  1021   if h < l orelse l < 0 then raise RANDOM
  1022   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1023 
  1024 fun one_of xs = nth xs (random_range 0 (length xs - 1));
  1025 
  1026 fun frequency xs =
  1027   let
  1028     val sum = foldl op + (0, map fst xs);
  1029     fun pick n ((k: int, x) :: xs) =
  1030       if n <= k then x else pick (n - k) xs
  1031   in pick (random_range 1 sum) xs end;
  1032 
  1033 
  1034 
  1035 (** misc **)
  1036 
  1037 fun divide_and_conquer decomp x =
  1038   let val (ys, recomb) = decomp x
  1039   in recomb (map (divide_and_conquer decomp) ys) end;
  1040 
  1041 fun divide_and_conquer' decomp x s =
  1042   let val ((ys, recomb), s') = decomp x s
  1043   in recomb (fold_map (divide_and_conquer' decomp) ys s') end;
  1044 
  1045 
  1046 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1047    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1048 fun partition_list p i j =
  1049   let
  1050     fun part (k: int) xs =
  1051       if k > j then
  1052         (case xs of
  1053           [] => []
  1054         | _ => raise Fail "partition_list")
  1055       else
  1056         let val (ns, rest) = List.partition (p k) xs
  1057         in ns :: part (k + 1) rest end;
  1058   in part (i: int) end;
  1059 
  1060 fun partition_eq (eq: 'a * 'a -> bool) =
  1061   let
  1062     fun part [] = []
  1063       | part (x :: ys) =
  1064           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1065           in (x :: xs) :: part xs' end;
  1066   in part end;
  1067 
  1068 
  1069 (* serial numbers and abstract stamps *)
  1070 
  1071 type serial = int;
  1072 val serial = Multithreading.serial;
  1073 val serial_string = string_of_int o serial;
  1074 
  1075 datatype stamp = Stamp of serial;
  1076 fun stamp () = Stamp (serial ());
  1077 
  1078 
  1079 (* generic objects *)
  1080 
  1081 (*note that the builtin exception datatype may be extended by new
  1082   constructors at any time*)
  1083 structure Object = struct type T = exn end;
  1084 
  1085 
  1086 (* current directory *)
  1087 
  1088 val cd = OS.FileSys.chDir;
  1089 val pwd = OS.FileSys.getDir;
  1090 
  1091 
  1092 (* getenv *)
  1093 
  1094 fun getenv x =
  1095   (case OS.Process.getEnv x of
  1096     NONE => ""
  1097   | SOME y => y);
  1098 
  1099 fun getenv_strict x =
  1100   (case getenv x of
  1101     "" => error ("Undefined Isabelle environment variable: " ^ quote x)
  1102   | y => y);
  1103 
  1104 end;
  1105 
  1106 structure Basic_Library: BASIC_LIBRARY = Library;
  1107 open Basic_Library;
  1108