src/Pure/PIDE/document.ML
author wenzelm
Mon Aug 15 21:54:32 2011 +0200 (2011-08-15)
changeset 44202 44c4ae5c5ce2
parent 44201 6429ab1b6883
child 44222 9d5ef6cd4ee1
permissions -rw-r--r--
touch descendants of edited nodes;
more precise handling of Graph exceptions;
     1 (*  Title:      Pure/PIDE/document.ML
     2     Author:     Makarius
     3 
     4 Document as collection of named nodes, each consisting of an editable
     5 list of commands, associated with asynchronous execution process.
     6 *)
     7 
     8 signature DOCUMENT =
     9 sig
    10   type id = int
    11   type version_id = id
    12   type command_id = id
    13   type exec_id = id
    14   val no_id: id
    15   val new_id: unit -> id
    16   val parse_id: string -> id
    17   val print_id: id -> string
    18   type node_header = (string * string list * (string * bool) list) Exn.result
    19   datatype node_edit =
    20     Clear |
    21     Edits of (command_id option * command_id option) list |
    22     Header of node_header
    23   type edit = string * node_edit
    24   type state
    25   val init_state: state
    26   val join_commands: state -> unit
    27   val cancel_execution: state -> unit -> unit
    28   val define_command: command_id -> string -> state -> state
    29   val edit: version_id -> version_id -> edit list -> state -> (command_id * exec_id) list * state
    30   val execute: version_id -> state -> state
    31   val state: unit -> state
    32   val change_state: (state -> state) -> unit
    33 end;
    34 
    35 structure Document: DOCUMENT =
    36 struct
    37 
    38 (* unique identifiers *)
    39 
    40 type id = int;
    41 type version_id = id;
    42 type command_id = id;
    43 type exec_id = id;
    44 
    45 val no_id = 0;
    46 val new_id = Synchronized.counter ();
    47 
    48 val parse_id = Markup.parse_int;
    49 val print_id = Markup.print_int;
    50 
    51 fun err_dup kind id = error ("Duplicate " ^ kind ^ ": " ^ print_id id);
    52 fun err_undef kind id = error ("Undefined " ^ kind ^ ": " ^ print_id id);
    53 
    54 
    55 
    56 (** document structure **)
    57 
    58 type node_header = (string * string list * (string * bool) list) Exn.result;
    59 structure Entries = Linear_Set(type key = command_id val ord = int_ord);
    60 
    61 abstype node = Node of
    62  {header: node_header,
    63   entries: exec_id option Entries.T,  (*command entries with excecutions*)
    64   result: Toplevel.state lazy}
    65 and version = Version of node Graph.T  (*development graph wrt. static imports*)
    66 with
    67 
    68 fun make_node (header, entries, result) =
    69   Node {header = header, entries = entries, result = result};
    70 
    71 fun map_node f (Node {header, entries, result}) =
    72   make_node (f (header, entries, result));
    73 
    74 fun get_header (Node {header, ...}) = header;
    75 fun set_header header = map_node (fn (_, entries, result) => (header, entries, result));
    76 
    77 fun map_entries f (Node {header, entries, result}) = make_node (header, f entries, result);
    78 fun fold_entries start f (Node {entries, ...}) = Entries.fold start f entries;
    79 fun first_entry start P (Node {entries, ...}) = Entries.get_first start P entries;
    80 
    81 fun get_theory pos (Node {result, ...}) = Toplevel.end_theory pos (Lazy.get_finished result);
    82 fun set_result result = map_node (fn (header, entries, _) => (header, entries, result));
    83 
    84 val empty_exec = Lazy.value Toplevel.toplevel;
    85 val empty_node = make_node (Exn.Exn (ERROR "Bad theory header"), Entries.empty, empty_exec);
    86 val clear_node = map_node (fn (header, _, _) => (header, Entries.empty, empty_exec));
    87 
    88 fun get_node nodes name = Graph.get_node nodes name handle Graph.UNDEF _ => empty_node;
    89 fun remove_node name nodes = Graph.del_node name nodes handle Graph.UNDEF _ => nodes;
    90 fun default_node name = Graph.default_node (name, empty_node);
    91 fun update_node name f = default_node name #> Graph.map_node name f;
    92 
    93 
    94 (* node edits and associated executions *)
    95 
    96 datatype node_edit =
    97   Clear |
    98   Edits of (command_id option * command_id option) list |
    99   Header of node_header;
   100 
   101 type edit = string * node_edit;
   102 
   103 fun the_entry (Node {entries, ...}) id =
   104   (case Entries.lookup entries id of
   105     NONE => err_undef "command entry" id
   106   | SOME entry => entry);
   107 
   108 fun update_entry (id, exec_id) =
   109   map_entries (Entries.update (id, SOME exec_id));
   110 
   111 fun reset_after id entries =
   112   (case Entries.get_after entries id of
   113     NONE => entries
   114   | SOME next => Entries.update (next, NONE) entries);
   115 
   116 val edit_node = map_entries o fold
   117   (fn (id, SOME id2) => Entries.insert_after id (id2, NONE)
   118     | (id, NONE) => Entries.delete_after id #> reset_after id);
   119 
   120 
   121 (* version operations *)
   122 
   123 val empty_version = Version Graph.empty;
   124 
   125 fun nodes_of (Version nodes) = nodes;
   126 val node_of = get_node o nodes_of;
   127 
   128 fun cycle_msg names = "Cyclic dependency of " ^ space_implode " via " (map quote names);
   129 
   130 fun touch_descendants name nodes =
   131   fold (fn desc => desc <> name ? update_node desc (map_entries (reset_after NONE)))
   132     (Graph.all_succs nodes [name]) nodes;
   133 
   134 fun edit_nodes (name, node_edit) (Version nodes) =
   135   Version
   136     (touch_descendants name
   137       (case node_edit of
   138         Clear => update_node name clear_node nodes
   139       | Edits edits =>
   140           nodes
   141           |> update_node name (edit_node edits)
   142       | Header header =>
   143           let
   144             val node = get_node nodes name;
   145             val nodes' = Graph.new_node (name, node) (remove_node name nodes);
   146             val parents =
   147               (case header of Exn.Res (_, parents, _) => parents | _ => [])
   148               |> filter (can (Graph.get_node nodes'));
   149             val (header', nodes'') =
   150               (header, Graph.add_deps_acyclic (name, parents) nodes')
   151                 handle Graph.CYCLES cs => (Exn.Exn (ERROR (cat_lines (map cycle_msg cs))), nodes')
   152                   | Graph.UNDEF d => (Exn.Exn (ERROR ("Undefined theory entry: " ^ quote d)), nodes')
   153           in
   154             nodes''
   155             |> Graph.map_node name (set_header header')
   156           end));
   157 
   158 fun def_node name (Version nodes) = Version (default_node name nodes);
   159 fun put_node (name, node) (Version nodes) = Version (update_node name (K node) nodes);
   160 
   161 end;
   162 
   163 
   164 
   165 (** global state -- document structure and execution process **)
   166 
   167 abstype state = State of
   168  {versions: version Inttab.table,  (*version_id -> document content*)
   169   commands: Toplevel.transition future Inttab.table,  (*command_id -> transition (future parsing)*)
   170   execs: Toplevel.state lazy Inttab.table,  (*exec_id -> execution process*)
   171   execution: unit future list}  (*global execution process*)
   172 with
   173 
   174 fun make_state (versions, commands, execs, execution) =
   175   State {versions = versions, commands = commands, execs = execs, execution = execution};
   176 
   177 fun map_state f (State {versions, commands, execs, execution}) =
   178   make_state (f (versions, commands, execs, execution));
   179 
   180 val init_state =
   181   make_state (Inttab.make [(no_id, empty_version)],
   182     Inttab.make [(no_id, Future.value Toplevel.empty)],
   183     Inttab.make [(no_id, empty_exec)],
   184     []);
   185 
   186 
   187 (* document versions *)
   188 
   189 fun define_version (id: version_id) version =
   190   map_state (fn (versions, commands, execs, execution) =>
   191     let val versions' = Inttab.update_new (id, version) versions
   192       handle Inttab.DUP dup => err_dup "document version" dup
   193     in (versions', commands, execs, execution) end);
   194 
   195 fun the_version (State {versions, ...}) (id: version_id) =
   196   (case Inttab.lookup versions id of
   197     NONE => err_undef "document version" id
   198   | SOME version => version);
   199 
   200 
   201 (* commands *)
   202 
   203 fun define_command (id: command_id) text =
   204   map_state (fn (versions, commands, execs, execution) =>
   205     let
   206       val id_string = print_id id;
   207       val tr = Future.fork_pri 2 (fn () =>
   208         Position.setmp_thread_data (Position.id_only id_string)
   209           (fn () => Outer_Syntax.prepare_command (Position.id id_string) text) ());
   210       val commands' =
   211         Inttab.update_new (id, tr) commands
   212           handle Inttab.DUP dup => err_dup "command" dup;
   213     in (versions, commands', execs, execution) end);
   214 
   215 fun the_command (State {commands, ...}) (id: command_id) =
   216   (case Inttab.lookup commands id of
   217     NONE => err_undef "command" id
   218   | SOME tr => tr);
   219 
   220 fun join_commands (State {commands, ...}) =
   221   Inttab.fold (fn (_, tr) => fn () => ignore (Future.join_result tr)) commands ();
   222 
   223 
   224 (* command executions *)
   225 
   226 fun define_exec (exec_id, exec) =
   227   map_state (fn (versions, commands, execs, execution) =>
   228     let val execs' = Inttab.update_new (exec_id, exec) execs
   229       handle Inttab.DUP dup => err_dup "command execution" dup
   230     in (versions, commands, execs', execution) end);
   231 
   232 fun the_exec (State {execs, ...}) exec_id =
   233   (case Inttab.lookup execs exec_id of
   234     NONE => err_undef "command execution" exec_id
   235   | SOME exec => exec);
   236 
   237 
   238 (* document execution *)
   239 
   240 fun cancel_execution (State {execution, ...}) =
   241   (List.app Future.cancel execution;
   242     fn () => ignore (Future.join_results execution));
   243 
   244 end;
   245 
   246 
   247 
   248 (* toplevel transactions *)
   249 
   250 local
   251 
   252 fun timing tr t = Toplevel.status tr (Markup.timing t);
   253 
   254 fun proof_status tr st =
   255   (case try Toplevel.proof_of st of
   256     SOME prf => Toplevel.status tr (Proof.status_markup prf)
   257   | NONE => ());
   258 
   259 fun async_state tr st =
   260   ignore
   261     (singleton
   262       (Future.forks {name = "Document.async_state",
   263         group = SOME (Task_Queue.new_group NONE), deps = [], pri = 0, interrupts = true})
   264       (fn () =>
   265         Toplevel.setmp_thread_position tr
   266           (fn () => Toplevel.print_state false st) ()));
   267 
   268 fun run int tr st =
   269   (case Toplevel.transition int tr st of
   270     SOME (st', NONE) => ([], SOME st')
   271   | SOME (_, SOME exn_info) =>
   272       (case ML_Compiler.exn_messages (Runtime.EXCURSION_FAIL exn_info) of
   273         [] => Exn.interrupt ()
   274       | errs => (errs, NONE))
   275   | NONE => ([ML_Compiler.exn_message Runtime.TERMINATE], NONE));
   276 
   277 in
   278 
   279 fun run_command tr st =
   280   let
   281     val is_init = Toplevel.is_init tr;
   282     val is_proof = Keyword.is_proof (Toplevel.name_of tr);
   283     val do_print = not is_init andalso (Toplevel.print_of tr orelse is_proof);
   284 
   285     val start = Timing.start ();
   286     val (errs, result) =
   287       if Toplevel.is_toplevel st andalso not is_init then ([], SOME st)
   288       else run (is_init orelse is_proof) (Toplevel.set_print false tr) st;
   289     val _ = timing tr (Timing.result start);
   290     val _ = List.app (Toplevel.error_msg tr) errs;
   291   in
   292     (case result of
   293       NONE => (Toplevel.status tr Markup.failed; st)
   294     | SOME st' =>
   295        (Toplevel.status tr Markup.finished;
   296         proof_status tr st';
   297         if do_print then async_state tr st' else ();
   298         st'))
   299   end;
   300 
   301 end;
   302 
   303 
   304 
   305 
   306 (** editing **)
   307 
   308 (* edit *)
   309 
   310 local
   311 
   312 fun is_changed node' ((_, id), exec) =
   313   (case try (the_entry node') id of
   314     NONE => true
   315   | SOME exec' => exec' <> exec);
   316 
   317 fun new_exec (command_id, command) (assigns, execs, exec) =
   318   let
   319     val exec_id' = new_id ();
   320     val exec' =
   321       Lazy.lazy (fn () =>
   322         let
   323           val tr = Toplevel.put_id (print_id exec_id') (Future.get_finished command);
   324           val st = Lazy.get_finished exec;
   325         in run_command tr st end);
   326   in ((command_id, exec_id') :: assigns, (exec_id', exec') :: execs, exec') end;
   327 
   328 in
   329 
   330 fun edit (old_id: version_id) (new_id: version_id) edits state =
   331   let
   332     val old_version = the_version state old_id;
   333     val _ = Time.now ();  (* FIXME odd workaround for polyml-5.4.0/x86_64 *)
   334     val new_version =
   335       old_version
   336       |> fold (def_node o #1) edits
   337       |> fold edit_nodes edits;
   338 
   339     val updates =
   340       nodes_of new_version |> Graph.schedule
   341         (fn deps => fn (name, node) =>
   342           (case first_entry NONE (is_changed (node_of old_version name)) node of
   343             NONE => Future.value (([], [], []), node)
   344           | SOME ((prev, id), _) =>
   345               let
   346                 fun init () =
   347                   let
   348                     val (thy_name, imports, uses) = Exn.release (get_header node);
   349                     (* FIXME provide files via Scala layer *)
   350                     val dir = Path.dir (Path.explode name);
   351                     val files = map (apfst Path.explode) uses;
   352 
   353                     val parents =
   354                       imports |> map (fn import =>
   355                         (case AList.lookup (op =) deps import of
   356                           SOME parent_future =>
   357                             get_theory (Position.file_only (import ^ ".thy"))
   358                               (#2 (Future.join parent_future))
   359                         | NONE => Thy_Info.get_theory (Thy_Info.base_name import)));
   360                   in Thy_Load.begin_theory dir thy_name imports files parents end
   361                 fun get_command id =
   362                   (id, the_command state id |> Future.map (Toplevel.modify_init init));
   363               in
   364                 singleton
   365                   (Future.forks {name = "Document.edit", group = NONE,
   366                     deps = map (Future.task_of o #2) deps, pri = 2, interrupts = false})
   367                   (fn () =>
   368                     let
   369                       val prev_exec =
   370                         (case prev of
   371                           NONE => no_id
   372                         | SOME prev_id => the_default no_id (the_entry node prev_id));
   373                       val (assigns, execs, result) =
   374                         fold_entries (SOME id) (new_exec o get_command o #2 o #1)
   375                           node ([], [], the_exec state prev_exec);
   376                       val node' = node
   377                         |> fold update_entry assigns
   378                         |> set_result result;
   379                     in ((assigns, execs, [(name, node')]), node') end)
   380               end))
   381       |> Future.join_results |> Exn.release_all |> map #1;
   382 
   383     val state' = state
   384       |> fold (fold define_exec o #2) updates
   385       |> define_version new_id (fold (fold put_node o #3) updates new_version);
   386 
   387   in (maps #1 (rev updates), state') end;
   388 
   389 end;
   390 
   391 
   392 (* execute *)
   393 
   394 fun execute version_id state =
   395   state |> map_state (fn (versions, commands, execs, _) =>
   396     let
   397       val version = the_version state version_id;
   398 
   399       fun force_exec NONE = ()
   400         | force_exec (SOME exec_id) = ignore (Lazy.force (the_exec state exec_id));
   401 
   402       val execution' =
   403         nodes_of version |> Graph.schedule
   404           (fn deps => fn (name, node) =>
   405             singleton
   406               (Future.forks
   407                 {name = "theory:" ^ name, group = NONE,
   408                   deps = map (Future.task_of o #2) deps,
   409                   pri = 1, interrupts = true})
   410               (fold_entries NONE (fn (_, exec) => fn () => force_exec exec) node));
   411 
   412     in (versions, commands, execs, execution') end);
   413 
   414 
   415 
   416 (** global state **)
   417 
   418 val global_state = Synchronized.var "Document" init_state;
   419 
   420 fun state () = Synchronized.value global_state;
   421 val change_state = Synchronized.change global_state;
   422 
   423 end;
   424