src/Pure/Thy/thy_output.ML
author wenzelm
Wed May 14 20:30:53 2008 +0200 (2008-05-14)
changeset 26893 44d9960d3587
parent 26762 78ed28528ca6
child 26996 090a619e7d87
permissions -rw-r--r--
added defined_command, defined_option;
     1 (*  Title:      Pure/Thy/thy_output.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Theory document output.
     6 *)
     7 
     8 signature THY_OUTPUT =
     9 sig
    10   val display: bool ref
    11   val quotes: bool ref
    12   val indent: int ref
    13   val source: bool ref
    14   val add_commands: (string * (Args.src -> Toplevel.node option -> string)) list -> unit
    15   val add_options: (string * (string -> (unit -> string) -> unit -> string)) list -> unit
    16   val defined_command: string -> bool
    17   val defined_option: string -> bool
    18   val print_antiquotations: unit -> unit
    19   val boolean: string -> bool
    20   val integer: string -> int
    21   val args: (Context.generic * Args.T list -> 'a * (Context.generic * Args.T list)) ->
    22     (Args.src -> Proof.context -> 'a -> string) -> Args.src -> Toplevel.node option -> string
    23   datatype markup = Markup | MarkupEnv | Verbatim
    24   val modes: string list ref
    25   val eval_antiquote: Scan.lexicon -> Toplevel.node option -> string * Position.T -> string
    26   val process_thy: Scan.lexicon -> (string -> string list) -> (markup -> string -> bool) ->
    27     Toplevel.transition list -> (OuterLex.token, 'a) Source.source -> Buffer.T
    28   val output_list: (Proof.context -> 'a -> Pretty.T) -> Args.src ->
    29     Proof.context -> 'a list -> string
    30   val output: (Proof.context -> 'a -> Pretty.T) -> Args.src -> Proof.context -> 'a -> string
    31 end;
    32 
    33 structure ThyOutput: THY_OUTPUT =
    34 struct
    35 
    36 structure T = OuterLex;
    37 structure P = OuterParse;
    38 
    39 
    40 (** global options **)
    41 
    42 val locale = ref "";
    43 val display = ref false;
    44 val quotes = ref false;
    45 val indent = ref 0;
    46 val source = ref false;
    47 val break = ref false;
    48 
    49 
    50 
    51 (** maintain global commands **)
    52 
    53 local
    54 
    55 val global_commands =
    56   ref (Symtab.empty: (Args.src -> Toplevel.node option -> string) Symtab.table);
    57 
    58 val global_options =
    59   ref (Symtab.empty: (string -> (unit -> string) -> unit -> string) Symtab.table);
    60 
    61 fun add_item kind (name, x) tab =
    62  (if not (Symtab.defined tab name) then ()
    63   else warning ("Redefined text antiquotation " ^ kind ^ ": " ^ quote name);
    64   Symtab.update (name, x) tab);
    65 
    66 in
    67 
    68 fun add_commands xs = CRITICAL (fn () => change global_commands (fold (add_item "command") xs));
    69 fun add_options xs = CRITICAL (fn () => change global_options (fold (add_item "option") xs));
    70 
    71 fun defined_command name = Symtab.defined (! global_commands) name;
    72 fun defined_option name = Symtab.defined (! global_options) name;
    73 
    74 fun command src =
    75   let val ((name, _), pos) = Args.dest_src src in
    76     (case Symtab.lookup (! global_commands) name of
    77       NONE => error ("Unknown text antiquotation command: " ^ quote name ^ Position.str_of pos)
    78     | SOME f => f src)
    79   end;
    80 
    81 fun option (name, s) f () =
    82   (case Symtab.lookup (! global_options) name of
    83     NONE => error ("Unknown text antiquotation option: " ^ quote name)
    84   | SOME opt => opt s f ());
    85 
    86 fun options [] f = f
    87   | options (opt :: opts) f = option opt (options opts f);
    88 
    89 
    90 fun print_antiquotations () =
    91  [Pretty.big_list "text antiquotation commands:"
    92     (map Pretty.str (sort_strings (Symtab.keys (! global_commands)))),
    93   Pretty.big_list "text antiquotation options:"
    94     (map Pretty.str (sort_strings (Symtab.keys (! global_options))))]
    95  |> Pretty.chunks |> Pretty.writeln;
    96 
    97 end;
    98 
    99 
   100 
   101 (** syntax of antiquotations **)
   102 
   103 (* option values *)
   104 
   105 fun boolean "" = true
   106   | boolean "true" = true
   107   | boolean "false" = false
   108   | boolean s = error ("Bad boolean value: " ^ quote s);
   109 
   110 fun integer s =
   111   let
   112     fun int ss =
   113       (case Library.read_int ss of (i, []) => i
   114       | _ => error ("Bad integer value: " ^ quote s));
   115   in (case Symbol.explode s of "-" :: ss => ~ (int ss) | ss => int ss) end;
   116 
   117 
   118 (* args syntax *)
   119 
   120 fun syntax scan = Args.context_syntax "text antiquotation" scan;
   121 
   122 fun args scan f src node : string =
   123   let
   124     val loc = if ! locale = "" then NONE else SOME (! locale);
   125     val (x, ctxt) = syntax scan src (Toplevel.presentation_context node loc);
   126   in f src ctxt x end;
   127 
   128 
   129 (* outer syntax *)
   130 
   131 local
   132 
   133 val property = P.xname -- Scan.optional (P.$$$ "=" |-- P.!!! P.xname) "";
   134 val properties = Scan.optional (P.$$$ "[" |-- P.!!! (P.enum "," property --| P.$$$ "]")) [];
   135 
   136 in
   137 
   138 val antiq = P.!!! (P.position P.xname -- properties -- P.arguments --| Scan.ahead P.eof)
   139   >> (fn (((x, pos), y), z) => (y, Args.src ((x, z), pos)));
   140 
   141 end;
   142 
   143 
   144 (* eval_antiquote *)
   145 
   146 val modes = ref ([]: string list);
   147 
   148 fun eval_antiquote lex node (str, pos) =
   149   let
   150     fun expand (Antiquote.Text s) = s
   151       | expand (Antiquote.Antiq x) =
   152           let val (opts, src) = Antiquote.scan_arguments lex antiq x in
   153             options opts (fn () => command src node) ();  (*preview errors!*)
   154             PrintMode.with_modes (! modes @ Latex.modes)
   155               (Output.no_warnings (options opts (fn () => command src node))) ()
   156           end;
   157     val ants = Antiquote.scan_antiquotes (str, pos);
   158   in
   159     if is_none node andalso exists Antiquote.is_antiq ants then
   160       error ("Cannot expand text antiquotations at top-level" ^ Position.str_of pos)
   161     else implode (map expand ants)
   162   end;
   163 
   164 
   165 
   166 (** present theory source **)
   167 
   168 (*NB: arranging white space around command spans is a black art.*)
   169 
   170 (* presentation tokens *)
   171 
   172 datatype token =
   173     NoToken
   174   | BasicToken of T.token
   175   | MarkupToken of string * (string * Position.T)
   176   | MarkupEnvToken of string * (string * Position.T)
   177   | VerbatimToken of string * Position.T;
   178 
   179 fun output_token lex state =
   180   let
   181     val eval = eval_antiquote lex (try Toplevel.node_of state)
   182   in
   183     fn NoToken => ""
   184      | BasicToken tok => Latex.output_basic tok
   185      | MarkupToken (cmd, txt) => Latex.output_markup cmd (eval txt)
   186      | MarkupEnvToken (cmd, txt) => Latex.output_markup_env cmd (eval txt)
   187      | VerbatimToken txt => Latex.output_verbatim (eval txt)
   188   end;
   189 
   190 fun basic_token pred (BasicToken tok) = pred tok
   191   | basic_token _ _ = false;
   192 
   193 val improper_token = basic_token (not o T.is_proper);
   194 val comment_token = basic_token T.is_comment;
   195 val blank_token = basic_token T.is_blank;
   196 val newline_token = basic_token T.is_newline;
   197 
   198 
   199 (* command spans *)
   200 
   201 type command = string * Position.T * string list;   (*name, position, tags*)
   202 type source = (token * (string * int)) list;        (*token, markup flag, meta-comment depth*)
   203 
   204 datatype span = Span of command * (source * source * source * source) * bool;
   205 
   206 fun make_span cmd src =
   207   let
   208     fun take_newline (tok :: toks) =
   209           if newline_token (fst tok) then ([tok], toks, true)
   210           else ([], tok :: toks, false)
   211       | take_newline [] = ([], [], false);
   212     val (((src_prefix, src_main), src_suffix1), (src_suffix2, src_appendix, newline)) =
   213       src
   214       |> take_prefix (improper_token o fst)
   215       ||>> take_suffix (improper_token o fst)
   216       ||>> take_prefix (comment_token o fst)
   217       ||> take_newline;
   218   in Span (cmd, (src_prefix, src_main, src_suffix1 @ src_suffix2, src_appendix), newline) end;
   219 
   220 
   221 (* present spans *)
   222 
   223 local
   224 
   225 fun err_bad_nesting pos =
   226   error ("Bad nesting of commands in presentation" ^ pos);
   227 
   228 fun edge which f (x: string option, y) =
   229   if x = y then I
   230   else (case which (x, y) of NONE => I | SOME txt => Buffer.add (f txt));
   231 
   232 val begin_tag = edge #2 Latex.begin_tag;
   233 val end_tag = edge #1 Latex.end_tag;
   234 fun open_delim delim e = edge #2 Latex.begin_delim e #> delim #> edge #2 Latex.end_delim e;
   235 fun close_delim delim e = edge #1 Latex.begin_delim e #> delim #> edge #1 Latex.end_delim e;
   236 
   237 in
   238 
   239 fun present_span lex default_tags span state state'
   240     (tag_stack, active_tag, newline, buffer, present_cont) =
   241   let
   242     val present = fold (fn (tok, (flag, 0)) =>
   243         Buffer.add (output_token lex state' tok)
   244         #> Buffer.add flag
   245       | _ => I);
   246 
   247     val Span ((cmd_name, cmd_pos, cmd_tags), srcs, span_newline) = span;
   248 
   249     val (tag, tags) = tag_stack;
   250     val tag' = try hd (fold OuterKeyword.update_tags cmd_tags (the_list tag));
   251 
   252     val active_tag' =
   253       if is_some tag' then tag'
   254       else if cmd_name = "end" andalso not (Toplevel.is_toplevel state') then NONE
   255       else try hd (default_tags cmd_name);
   256     val edge = (active_tag, active_tag');
   257 
   258     val newline' =
   259       if is_none active_tag' then span_newline else newline;
   260 
   261     val nesting = Toplevel.level state' - Toplevel.level state;
   262     val tag_stack' =
   263       if nesting = 0 andalso not (Toplevel.is_proof state) then tag_stack
   264       else if nesting >= 0 then (tag', replicate nesting tag @ tags)
   265       else
   266         (case Library.drop (~ nesting - 1, tags) of
   267           tgs :: tgss => (tgs, tgss)
   268         | [] => err_bad_nesting (Position.str_of cmd_pos));
   269 
   270     val buffer' =
   271       buffer
   272       |> end_tag edge
   273       |> close_delim (fst present_cont) edge
   274       |> snd present_cont
   275       |> open_delim (present (#1 srcs)) edge
   276       |> begin_tag edge
   277       |> present (#2 srcs);
   278     val present_cont' =
   279       if newline then (present (#3 srcs), present (#4 srcs))
   280       else (I, present (#3 srcs) #> present (#4 srcs));
   281   in (tag_stack', active_tag', newline', buffer', present_cont') end;
   282 
   283 fun present_trailer ((_, tags), active_tag, _, buffer, present_cont) =
   284   if not (null tags) then err_bad_nesting " at end of theory"
   285   else
   286     buffer
   287     |> end_tag (active_tag, NONE)
   288     |> close_delim (fst present_cont) (active_tag, NONE)
   289     |> snd present_cont;
   290 
   291 end;
   292 
   293 
   294 (* process_thy *)
   295 
   296 datatype markup = Markup | MarkupEnv | Verbatim;
   297 
   298 local
   299 
   300 val space_proper =
   301   Scan.one T.is_blank -- Scan.many T.is_comment -- Scan.one T.is_proper;
   302 
   303 val is_improper = not o (T.is_proper orf T.is_begin_ignore orf T.is_end_ignore);
   304 val improper = Scan.many is_improper;
   305 val improper_end = Scan.repeat (Scan.unless space_proper (Scan.one is_improper));
   306 val blank_end = Scan.repeat (Scan.unless space_proper (Scan.one T.is_blank));
   307 
   308 val opt_newline = Scan.option (Scan.one T.is_newline);
   309 
   310 val ignore =
   311   Scan.depend (fn d => opt_newline |-- Scan.one T.is_begin_ignore
   312     >> pair (d + 1)) ||
   313   Scan.depend (fn d => Scan.one T.is_end_ignore --|
   314     (if d = 0 then Scan.fail_with (K "Bad nesting of meta-comments") else opt_newline)
   315     >> pair (d - 1));
   316 
   317 val tag = (improper -- P.$$$ "%" -- improper) |-- P.!!! (P.tag_name --| blank_end);
   318 
   319 val locale =
   320   Scan.option ((P.$$$ "(" -- improper -- P.$$$ "in") |--
   321     P.!!! (improper |-- P.xname --| (improper -- P.$$$ ")")));
   322 
   323 in
   324 
   325 fun process_thy lex default_tags is_markup trs src =
   326   let
   327     (* tokens *)
   328 
   329     val ignored = Scan.state --| ignore
   330       >> (fn d => (NONE, (NoToken, ("", d))));
   331 
   332     fun markup mark mk flag = Scan.peek (fn d =>
   333       improper |-- P.position (Scan.one (T.is_kind T.Command andf is_markup mark o T.val_of)) --
   334       Scan.repeat tag --
   335       P.!!!! ((improper -- locale -- improper) |-- P.position P.text --| improper_end)
   336       >> (fn (((tok, pos), tags), txt) =>
   337         let val name = T.val_of tok
   338         in (SOME (name, pos, tags), (mk (name, txt), (flag, d))) end));
   339 
   340     val command = Scan.peek (fn d =>
   341       P.position (Scan.one (T.is_kind T.Command)) --
   342       Scan.repeat tag
   343       >> (fn ((tok, pos), tags) =>
   344         let val name = T.val_of tok
   345         in (SOME (name, pos, tags), (BasicToken tok, (Latex.markup_false, d))) end));
   346 
   347     val cmt = Scan.peek (fn d =>
   348       P.$$$ "--" |-- P.!!!! (improper |-- P.position P.text)
   349       >> (fn txt => (NONE, (MarkupToken ("cmt", txt), ("", d)))));
   350 
   351     val other = Scan.peek (fn d =>
   352        P.not_eof >> (fn tok => (NONE, (BasicToken tok, ("", d)))));
   353 
   354     val token =
   355       ignored ||
   356       markup Markup MarkupToken Latex.markup_true ||
   357       markup MarkupEnv MarkupEnvToken Latex.markup_true ||
   358       markup Verbatim (VerbatimToken o #2) "" ||
   359       command || cmt || other;
   360 
   361 
   362     (* spans *)
   363 
   364     val stopper =
   365       ((NONE, (BasicToken (#1 T.stopper), ("", 0))),
   366         fn (_, (BasicToken x, _)) => #2 T.stopper x | _ => false);
   367 
   368     val cmd = Scan.one (is_some o fst);
   369     val non_cmd = Scan.one (is_none o fst andf not o #2 stopper) >> #2;
   370 
   371     val comments = Scan.many (comment_token o fst o snd);
   372     val blank = Scan.one (blank_token o fst o snd);
   373     val newline = Scan.one (newline_token o fst o snd);
   374     val before_cmd =
   375       Scan.option (newline -- comments) --
   376       Scan.option (newline -- comments) --
   377       Scan.option (blank -- comments) -- cmd;
   378 
   379     val span =
   380       Scan.repeat non_cmd -- cmd --
   381         Scan.repeat (Scan.unless before_cmd non_cmd) --
   382         Scan.option (newline >> (single o snd))
   383       >> (fn (((toks1, (cmd, tok2)), toks3), tok4) =>
   384           make_span (the cmd) (toks1 @ (tok2 :: (toks3 @ the_default [] tok4))));
   385 
   386     val spans =
   387       src
   388       |> Source.filter (not o T.is_semicolon)
   389       |> Source.source' 0 T.stopper (Scan.error (Scan.bulk token)) NONE
   390       |> Source.source stopper (Scan.error (Scan.bulk span)) NONE
   391       |> Source.exhaust;
   392   in
   393     if length trs = length spans then
   394       ((NONE, []), NONE, true, Buffer.empty, (I, I))
   395       |> Toplevel.present_excursion (trs ~~ map (present_span lex default_tags) spans)
   396       |> present_trailer
   397     else error "Messed-up outer syntax for presentation"
   398   end;
   399 
   400 end;
   401 
   402 
   403 
   404 (** setup default output **)
   405 
   406 (* options *)
   407 
   408 val _ = add_options
   409  [("show_types", Library.setmp Syntax.show_types o boolean),
   410   ("show_sorts", Library.setmp Syntax.show_sorts o boolean),
   411   ("show_structs", Library.setmp show_structs o boolean),
   412   ("show_question_marks", Library.setmp show_question_marks o boolean),
   413   ("long_names", Library.setmp NameSpace.long_names o boolean),
   414   ("short_names", Library.setmp NameSpace.short_names o boolean),
   415   ("unique_names", Library.setmp NameSpace.unique_names o boolean),
   416   ("eta_contract", Library.setmp Syntax.eta_contract o boolean),
   417   ("locale", Library.setmp locale),
   418   ("display", Library.setmp display o boolean),
   419   ("break", Library.setmp break o boolean),
   420   ("quotes", Library.setmp quotes o boolean),
   421   ("mode", fn s => fn f => PrintMode.with_modes [s] f),
   422   ("margin", Pretty.setmp_margin o integer),
   423   ("indent", Library.setmp indent o integer),
   424   ("source", Library.setmp source o boolean),
   425   ("goals_limit", Library.setmp goals_limit o integer)];
   426 
   427 
   428 (* basic pretty printing *)
   429 
   430 val str_of_source = space_implode " " o map Args.string_of o #2 o #1 o Args.dest_src;
   431 
   432 fun tweak_line s =
   433   if ! display then s else Symbol.strip_blanks s;
   434 
   435 val pretty_text = Pretty.chunks o map Pretty.str o map tweak_line o Library.split_lines;
   436 
   437 fun pretty_term ctxt t = Syntax.pretty_term (Variable.auto_fixes t ctxt) t;
   438 
   439 fun pretty_term_abbrev ctxt t = ProofContext.pretty_term_abbrev (Variable.auto_fixes t ctxt) t;
   440 
   441 fun pretty_term_typ ctxt t =
   442   Syntax.pretty_term ctxt (TypeInfer.constrain (Term.fastype_of t) t);
   443 
   444 fun pretty_term_typeof ctxt = Syntax.pretty_typ ctxt o Term.fastype_of;
   445 
   446 fun pretty_const ctxt c =
   447   let
   448     val t = Const (c, Consts.type_scheme (ProofContext.consts_of ctxt) c)
   449       handle TYPE (msg, _, _) => error msg;
   450     val ([t'], _) = Variable.import_terms true [t] ctxt;
   451   in pretty_term ctxt t' end;
   452 
   453 fun pretty_abbrev ctxt s =
   454   let
   455     val t = Syntax.parse_term ctxt s |> singleton (ProofContext.standard_infer_types ctxt);
   456     fun err () = error ("Abbreviated constant expected: " ^ Syntax.string_of_term ctxt t);
   457     val (head, args) = Term.strip_comb t;
   458     val (c, T) = Term.dest_Const head handle TERM _ => err ();
   459     val (U, u) = Consts.the_abbreviation (ProofContext.consts_of ctxt) c
   460       handle TYPE _ => err ();
   461     val t' = Term.betapplys (Envir.expand_atom T (U, u), args);
   462   in pretty_term_abbrev ctxt (Logic.mk_equals (t, t')) end;
   463 
   464 fun pretty_fact ctxt (prop, method_text) =
   465   let
   466     val _ = ctxt
   467       |> Proof.theorem_i NONE (K I) [[(prop, [])]]
   468       |> Proof.global_terminal_proof (method_text, NONE);
   469   in pretty_term ctxt prop end;
   470 
   471 fun pretty_thm ctxt = pretty_term ctxt o Thm.full_prop_of;
   472 
   473 fun pretty_term_style ctxt (name, t) =
   474   pretty_term ctxt (TermStyle.the_style (ProofContext.theory_of ctxt) name ctxt t);
   475 
   476 fun pretty_thm_style ctxt (name, th) =
   477   pretty_term_style ctxt (name, Thm.full_prop_of th);
   478 
   479 fun pretty_prf full ctxt thms =
   480   Pretty.chunks (map (ProofContext.pretty_proof_of ctxt full) thms);
   481 
   482 fun pretty_theory ctxt name =
   483   (Theory.requires (ProofContext.theory_of ctxt) name "presentation"; Pretty.str name);
   484 
   485 
   486 (* Isar output *)
   487 
   488 fun output_list pretty src ctxt xs =
   489   map (pretty ctxt) xs        (*always pretty in order to exhibit errors!*)
   490   |> (if ! source then K [pretty_text (str_of_source src)] else I)
   491   |> (if ! quotes then map Pretty.quote else I)
   492   |> (if ! display then
   493     map (Output.output o Pretty.string_of o Pretty.indent (! indent))
   494     #> space_implode "\\isasep\\isanewline%\n"
   495     #> enclose "\\begin{isabelle}%\n" "%\n\\end{isabelle}"
   496   else
   497     map (Output.output o (if ! break then Pretty.string_of else Pretty.str_of))
   498     #> space_implode "\\isasep\\isanewline%\n"
   499     #> enclose "\\isa{" "}");
   500 
   501 fun output pretty src ctxt = output_list pretty src ctxt o single;
   502 
   503 fun proof_state node =
   504   (case Option.map Toplevel.proof_node node of
   505     SOME (SOME prf) => ProofHistory.current prf
   506   | _ => error "No proof state");
   507 
   508 fun output_goals main_goal src node = args (Scan.succeed ()) (output (fn _ => fn _ =>
   509   Pretty.chunks (Proof.pretty_goals main_goal (proof_state node)))) src node;
   510 
   511 fun ml_val txt = "fn _ => (" ^ txt ^ ");";
   512 fun ml_type txt = "val _ = NONE : (" ^ txt ^ ") option;";
   513 fun ml_struct txt = "functor DUMMY_FUNCTOR() = struct structure DUMMY = " ^ txt ^ " end;"
   514 
   515 fun output_ml ml src ctxt (txt, pos) =
   516  (ML_Context.eval_in (SOME (Context.Proof ctxt)) false pos (ml txt);
   517   (if ! source then str_of_source src else txt)
   518   |> (if ! quotes then quote else I)
   519   |> (if ! display then enclose "\\begin{verbatim}\n" "\n\\end{verbatim}"
   520   else
   521     split_lines
   522     #> map (space_implode "\\verb,|," o map (enclose "\\verb|" "|") o space_explode "|")
   523     #> space_implode "\\isasep\\isanewline%\n"));
   524 
   525 
   526 (* commands *)
   527 
   528 val _ = add_commands
   529  [("thm", args Attrib.thms (output_list pretty_thm)),
   530   ("thm_style", args (Scan.lift Args.liberal_name -- Attrib.thm) (output pretty_thm_style)),
   531   ("prop", args Args.prop (output pretty_term)),
   532   ("lemma", args (Args.prop -- Scan.lift Method.simple_text) (output pretty_fact)),
   533   ("term", args Args.term (output pretty_term)),
   534   ("term_style", args (Scan.lift Args.liberal_name -- Args.term) (output pretty_term_style)),
   535   ("term_type", args Args.term (output pretty_term_typ)),
   536   ("typeof", args Args.term (output pretty_term_typeof)),
   537   ("const", args Args.const_proper (output pretty_const)),
   538   ("abbrev", args (Scan.lift Args.name) (output pretty_abbrev)),
   539   ("typ", args Args.typ_abbrev (output Syntax.pretty_typ)),
   540   ("text", args (Scan.lift Args.name) (output (K pretty_text))),
   541   ("goals", output_goals true),
   542   ("subgoals", output_goals false),
   543   ("prf", args Attrib.thms (output (pretty_prf false))),
   544   ("full_prf", args Attrib.thms (output (pretty_prf true))),
   545   ("theory", args (Scan.lift Args.name) (output pretty_theory)),
   546   ("ML", args (Scan.lift (Args.position Args.name)) (output_ml ml_val)),
   547   ("ML_type", args (Scan.lift (Args.position Args.name)) (output_ml ml_type)),
   548   ("ML_struct", args (Scan.lift (Args.position Args.name)) (output_ml ml_struct))];
   549 
   550 end;