src/HOL/Set.ML
author nipkow
Wed Feb 12 18:53:59 1997 +0100 (1997-02-12)
changeset 2608 450c9b682a92
parent 2499 0bc87b063447
child 2721 f08042e18c7d
permissions -rw-r--r--
New class "order" and accompanying changes.
In particular reflexivity of <= is now one rewrite rule.
     1 (*  Title:      HOL/set
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1991  University of Cambridge
     5 
     6 Set theory for higher-order logic.  A set is simply a predicate.
     7 *)
     8 
     9 open Set;
    10 
    11 section "Relating predicates and sets";
    12 
    13 AddIffs [mem_Collect_eq];
    14 
    15 goal Set.thy "!!a. P(a) ==> a : {x.P(x)}";
    16 by (Asm_simp_tac 1);
    17 qed "CollectI";
    18 
    19 val prems = goal Set.thy "!!a. a : {x.P(x)} ==> P(a)";
    20 by (Asm_full_simp_tac 1);
    21 qed "CollectD";
    22 
    23 val [prem] = goal Set.thy "[| !!x. (x:A) = (x:B) |] ==> A = B";
    24 by (rtac (prem RS ext RS arg_cong RS box_equals) 1);
    25 by (rtac Collect_mem_eq 1);
    26 by (rtac Collect_mem_eq 1);
    27 qed "set_ext";
    28 
    29 val [prem] = goal Set.thy "[| !!x. P(x)=Q(x) |] ==> {x. P(x)} = {x. Q(x)}";
    30 by (rtac (prem RS ext RS arg_cong) 1);
    31 qed "Collect_cong";
    32 
    33 val CollectE = make_elim CollectD;
    34 
    35 AddSIs [CollectI];
    36 AddSEs [CollectE];
    37 
    38 
    39 section "Bounded quantifiers";
    40 
    41 val prems = goalw Set.thy [Ball_def]
    42     "[| !!x. x:A ==> P(x) |] ==> ! x:A. P(x)";
    43 by (REPEAT (ares_tac (prems @ [allI,impI]) 1));
    44 qed "ballI";
    45 
    46 val [major,minor] = goalw Set.thy [Ball_def]
    47     "[| ! x:A. P(x);  x:A |] ==> P(x)";
    48 by (rtac (minor RS (major RS spec RS mp)) 1);
    49 qed "bspec";
    50 
    51 val major::prems = goalw Set.thy [Ball_def]
    52     "[| ! x:A. P(x);  P(x) ==> Q;  x~:A ==> Q |] ==> Q";
    53 by (rtac (major RS spec RS impCE) 1);
    54 by (REPEAT (eresolve_tac prems 1));
    55 qed "ballE";
    56 
    57 (*Takes assumptions ! x:A.P(x) and a:A; creates assumption P(a)*)
    58 fun ball_tac i = etac ballE i THEN contr_tac (i+1);
    59 
    60 AddSIs [ballI];
    61 AddEs  [ballE];
    62 
    63 val prems = goalw Set.thy [Bex_def]
    64     "[| P(x);  x:A |] ==> ? x:A. P(x)";
    65 by (REPEAT (ares_tac (prems @ [exI,conjI]) 1));
    66 qed "bexI";
    67 
    68 qed_goal "bexCI" Set.thy 
    69    "[| ! x:A. ~P(x) ==> P(a);  a:A |] ==> ? x:A.P(x)"
    70  (fn prems=>
    71   [ (rtac classical 1),
    72     (REPEAT (ares_tac (prems@[bexI,ballI,notI,notE]) 1))  ]);
    73 
    74 val major::prems = goalw Set.thy [Bex_def]
    75     "[| ? x:A. P(x);  !!x. [| x:A; P(x) |] ==> Q  |] ==> Q";
    76 by (rtac (major RS exE) 1);
    77 by (REPEAT (eresolve_tac (prems @ [asm_rl,conjE]) 1));
    78 qed "bexE";
    79 
    80 AddIs  [bexI];
    81 AddSEs [bexE];
    82 
    83 (*Trival rewrite rule;   (! x:A.P)=P holds only if A is nonempty!*)
    84 goalw Set.thy [Ball_def] "(! x:A. True) = True";
    85 by (Simp_tac 1);
    86 qed "ball_True";
    87 
    88 (*Dual form for existentials*)
    89 goalw Set.thy [Bex_def] "(? x:A. False) = False";
    90 by (Simp_tac 1);
    91 qed "bex_False";
    92 
    93 Addsimps [ball_True, bex_False];
    94 
    95 (** Congruence rules **)
    96 
    97 val prems = goal Set.thy
    98     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
    99 \    (! x:A. P(x)) = (! x:B. Q(x))";
   100 by (resolve_tac (prems RL [ssubst]) 1);
   101 by (REPEAT (ares_tac [ballI,iffI] 1
   102      ORELSE eresolve_tac ([make_elim bspec, mp] @ (prems RL [iffE])) 1));
   103 qed "ball_cong";
   104 
   105 val prems = goal Set.thy
   106     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   107 \    (? x:A. P(x)) = (? x:B. Q(x))";
   108 by (resolve_tac (prems RL [ssubst]) 1);
   109 by (REPEAT (etac bexE 1
   110      ORELSE ares_tac ([bexI,iffI] @ (prems RL [iffD1,iffD2])) 1));
   111 qed "bex_cong";
   112 
   113 section "Subsets";
   114 
   115 val prems = goalw Set.thy [subset_def] "(!!x.x:A ==> x:B) ==> A <= B";
   116 by (REPEAT (ares_tac (prems @ [ballI]) 1));
   117 qed "subsetI";
   118 
   119 (*Rule in Modus Ponens style*)
   120 val major::prems = goalw Set.thy [subset_def] "[| A <= B;  c:A |] ==> c:B";
   121 by (rtac (major RS bspec) 1);
   122 by (resolve_tac prems 1);
   123 qed "subsetD";
   124 
   125 (*The same, with reversed premises for use with etac -- cf rev_mp*)
   126 qed_goal "rev_subsetD" Set.thy "[| c:A;  A <= B |] ==> c:B"
   127  (fn prems=>  [ (REPEAT (resolve_tac (prems@[subsetD]) 1)) ]);
   128 
   129 (*Converts A<=B to x:A ==> x:B*)
   130 fun impOfSubs th = th RSN (2, rev_subsetD);
   131 
   132 qed_goal "contra_subsetD" Set.thy "!!c. [| A <= B; c ~: B |] ==> c ~: A"
   133  (fn prems=>  [ (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ]);
   134 
   135 qed_goal "rev_contra_subsetD" Set.thy "!!c. [| c ~: B;  A <= B |] ==> c ~: A"
   136  (fn prems=>  [ (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ]);
   137 
   138 (*Classical elimination rule*)
   139 val major::prems = goalw Set.thy [subset_def] 
   140     "[| A <= B;  c~:A ==> P;  c:B ==> P |] ==> P";
   141 by (rtac (major RS ballE) 1);
   142 by (REPEAT (eresolve_tac prems 1));
   143 qed "subsetCE";
   144 
   145 (*Takes assumptions A<=B; c:A and creates the assumption c:B *)
   146 fun set_mp_tac i = etac subsetCE i  THEN  mp_tac i;
   147 
   148 AddSIs [subsetI];
   149 AddEs  [subsetD, subsetCE];
   150 
   151 qed_goal "subset_refl" Set.thy "A <= (A::'a set)"
   152  (fn _=> [Fast_tac 1]);
   153 
   154 val prems = goal Set.thy "!!B. [| A<=B;  B<=C |] ==> A<=(C::'a set)";
   155 by (Fast_tac 1);
   156 qed "subset_trans";
   157 
   158 
   159 section "Equality";
   160 
   161 (*Anti-symmetry of the subset relation*)
   162 val prems = goal Set.thy "[| A <= B;  B <= A |] ==> A = (B::'a set)";
   163 by (rtac (iffI RS set_ext) 1);
   164 by (REPEAT (ares_tac (prems RL [subsetD]) 1));
   165 qed "subset_antisym";
   166 val equalityI = subset_antisym;
   167 
   168 AddSIs [equalityI];
   169 
   170 (* Equality rules from ZF set theory -- are they appropriate here? *)
   171 val prems = goal Set.thy "A = B ==> A<=(B::'a set)";
   172 by (resolve_tac (prems RL [subst]) 1);
   173 by (rtac subset_refl 1);
   174 qed "equalityD1";
   175 
   176 val prems = goal Set.thy "A = B ==> B<=(A::'a set)";
   177 by (resolve_tac (prems RL [subst]) 1);
   178 by (rtac subset_refl 1);
   179 qed "equalityD2";
   180 
   181 val prems = goal Set.thy
   182     "[| A = B;  [| A<=B; B<=(A::'a set) |] ==> P |]  ==>  P";
   183 by (resolve_tac prems 1);
   184 by (REPEAT (resolve_tac (prems RL [equalityD1,equalityD2]) 1));
   185 qed "equalityE";
   186 
   187 val major::prems = goal Set.thy
   188     "[| A = B;  [| c:A; c:B |] ==> P;  [| c~:A; c~:B |] ==> P |]  ==>  P";
   189 by (rtac (major RS equalityE) 1);
   190 by (REPEAT (contr_tac 1 ORELSE eresolve_tac ([asm_rl,subsetCE]@prems) 1));
   191 qed "equalityCE";
   192 
   193 (*Lemma for creating induction formulae -- for "pattern matching" on p
   194   To make the induction hypotheses usable, apply "spec" or "bspec" to
   195   put universal quantifiers over the free variables in p. *)
   196 val prems = goal Set.thy 
   197     "[| p:A;  !!z. z:A ==> p=z --> R |] ==> R";
   198 by (rtac mp 1);
   199 by (REPEAT (resolve_tac (refl::prems) 1));
   200 qed "setup_induction";
   201 
   202 
   203 section "Set complement -- Compl";
   204 
   205 qed_goalw "Compl_iff" Set.thy [Compl_def] "(c : Compl(A)) = (c~:A)"
   206  (fn _ => [ (Fast_tac 1) ]);
   207 
   208 Addsimps [Compl_iff];
   209 
   210 val prems = goalw Set.thy [Compl_def]
   211     "[| c:A ==> False |] ==> c : Compl(A)";
   212 by (REPEAT (ares_tac (prems @ [CollectI,notI]) 1));
   213 qed "ComplI";
   214 
   215 (*This form, with negated conclusion, works well with the Classical prover.
   216   Negated assumptions behave like formulae on the right side of the notional
   217   turnstile...*)
   218 val major::prems = goalw Set.thy [Compl_def]
   219     "c : Compl(A) ==> c~:A";
   220 by (rtac (major RS CollectD) 1);
   221 qed "ComplD";
   222 
   223 val ComplE = make_elim ComplD;
   224 
   225 AddSIs [ComplI];
   226 AddSEs [ComplE];
   227 
   228 
   229 section "Binary union -- Un";
   230 
   231 qed_goalw "Un_iff" Set.thy [Un_def] "(c : A Un B) = (c:A | c:B)"
   232  (fn _ => [ Fast_tac 1 ]);
   233 
   234 Addsimps [Un_iff];
   235 
   236 goal Set.thy "!!c. c:A ==> c : A Un B";
   237 by (Asm_simp_tac 1);
   238 qed "UnI1";
   239 
   240 goal Set.thy "!!c. c:B ==> c : A Un B";
   241 by (Asm_simp_tac 1);
   242 qed "UnI2";
   243 
   244 (*Classical introduction rule: no commitment to A vs B*)
   245 qed_goal "UnCI" Set.thy "(c~:B ==> c:A) ==> c : A Un B"
   246  (fn prems=>
   247   [ (Simp_tac 1),
   248     (REPEAT (ares_tac (prems@[disjCI]) 1)) ]);
   249 
   250 val major::prems = goalw Set.thy [Un_def]
   251     "[| c : A Un B;  c:A ==> P;  c:B ==> P |] ==> P";
   252 by (rtac (major RS CollectD RS disjE) 1);
   253 by (REPEAT (eresolve_tac prems 1));
   254 qed "UnE";
   255 
   256 AddSIs [UnCI];
   257 AddSEs [UnE];
   258 
   259 
   260 section "Binary intersection -- Int";
   261 
   262 qed_goalw "Int_iff" Set.thy [Int_def] "(c : A Int B) = (c:A & c:B)"
   263  (fn _ => [ (Fast_tac 1) ]);
   264 
   265 Addsimps [Int_iff];
   266 
   267 goal Set.thy "!!c. [| c:A;  c:B |] ==> c : A Int B";
   268 by (Asm_simp_tac 1);
   269 qed "IntI";
   270 
   271 goal Set.thy "!!c. c : A Int B ==> c:A";
   272 by (Asm_full_simp_tac 1);
   273 qed "IntD1";
   274 
   275 goal Set.thy "!!c. c : A Int B ==> c:B";
   276 by (Asm_full_simp_tac 1);
   277 qed "IntD2";
   278 
   279 val [major,minor] = goal Set.thy
   280     "[| c : A Int B;  [| c:A; c:B |] ==> P |] ==> P";
   281 by (rtac minor 1);
   282 by (rtac (major RS IntD1) 1);
   283 by (rtac (major RS IntD2) 1);
   284 qed "IntE";
   285 
   286 AddSIs [IntI];
   287 AddSEs [IntE];
   288 
   289 section "Set difference";
   290 
   291 qed_goalw "Diff_iff" Set.thy [set_diff_def] "(c : A-B) = (c:A & c~:B)"
   292  (fn _ => [ (Fast_tac 1) ]);
   293 
   294 Addsimps [Diff_iff];
   295 
   296 qed_goal "DiffI" Set.thy "!!c. [| c : A;  c ~: B |] ==> c : A - B"
   297  (fn _=> [ Asm_simp_tac 1 ]);
   298 
   299 qed_goal "DiffD1" Set.thy "!!c. c : A - B ==> c : A"
   300  (fn _=> [ (Asm_full_simp_tac 1) ]);
   301 
   302 qed_goal "DiffD2" Set.thy "!!c. [| c : A - B;  c : B |] ==> P"
   303  (fn _=> [ (Asm_full_simp_tac 1) ]);
   304 
   305 qed_goal "DiffE" Set.thy "[| c : A - B;  [| c:A; c~:B |] ==> P |] ==> P"
   306  (fn prems=>
   307   [ (resolve_tac prems 1),
   308     (REPEAT (ares_tac (prems RL [DiffD1, DiffD2 RS notI]) 1)) ]);
   309 
   310 AddSIs [DiffI];
   311 AddSEs [DiffE];
   312 
   313 section "The empty set -- {}";
   314 
   315 qed_goalw "empty_iff" Set.thy [empty_def] "(c : {}) = False"
   316  (fn _ => [ (Fast_tac 1) ]);
   317 
   318 Addsimps [empty_iff];
   319 
   320 qed_goal "emptyE" Set.thy "!!a. a:{} ==> P"
   321  (fn _ => [Full_simp_tac 1]);
   322 
   323 AddSEs [emptyE];
   324 
   325 qed_goal "empty_subsetI" Set.thy "{} <= A"
   326  (fn _ => [ (Fast_tac 1) ]);
   327 
   328 qed_goal "equals0I" Set.thy "[| !!y. y:A ==> False |] ==> A={}"
   329  (fn [prem]=>
   330   [ (fast_tac (!claset addIs [prem RS FalseE]) 1) ]);
   331 
   332 qed_goal "equals0D" Set.thy "!!a. [| A={};  a:A |] ==> P"
   333  (fn _ => [ (Fast_tac 1) ]);
   334 
   335 goal Set.thy "Ball {} P = True";
   336 by (simp_tac (HOL_ss addsimps [mem_Collect_eq, Ball_def, empty_def]) 1);
   337 qed "ball_empty";
   338 
   339 goal Set.thy "Bex {} P = False";
   340 by (simp_tac (HOL_ss addsimps [mem_Collect_eq, Bex_def, empty_def]) 1);
   341 qed "bex_empty";
   342 Addsimps [ball_empty, bex_empty];
   343 
   344 goalw Set.thy [Ball_def] "(!x:A.False) = (A = {})";
   345 by(Fast_tac 1);
   346 qed "ball_False";
   347 Addsimps [ball_False];
   348 
   349 (* The dual is probably not helpful:
   350 goal Set.thy "(? x:A.True) = (A ~= {})";
   351 by(Fast_tac 1);
   352 qed "bex_True";
   353 Addsimps [bex_True];
   354 *)
   355 
   356 
   357 section "Augmenting a set -- insert";
   358 
   359 qed_goalw "insert_iff" Set.thy [insert_def] "a : insert b A = (a=b | a:A)"
   360  (fn _ => [Fast_tac 1]);
   361 
   362 Addsimps [insert_iff];
   363 
   364 qed_goal "insertI1" Set.thy "a : insert a B"
   365  (fn _ => [Simp_tac 1]);
   366 
   367 qed_goal "insertI2" Set.thy "!!a. a : B ==> a : insert b B"
   368  (fn _=> [Asm_simp_tac 1]);
   369 
   370 qed_goalw "insertE" Set.thy [insert_def]
   371     "[| a : insert b A;  a=b ==> P;  a:A ==> P |] ==> P"
   372  (fn major::prems=>
   373   [ (rtac (major RS UnE) 1),
   374     (REPEAT (eresolve_tac (prems @ [CollectE]) 1)) ]);
   375 
   376 (*Classical introduction rule*)
   377 qed_goal "insertCI" Set.thy "(a~:B ==> a=b) ==> a: insert b B"
   378  (fn prems=>
   379   [ (Simp_tac 1),
   380     (REPEAT (ares_tac (prems@[disjCI]) 1)) ]);
   381 
   382 AddSIs [insertCI]; 
   383 AddSEs [insertE];
   384 
   385 section "Singletons, using insert";
   386 
   387 qed_goal "singletonI" Set.thy "a : {a}"
   388  (fn _=> [ (rtac insertI1 1) ]);
   389 
   390 goal Set.thy "!!a. b : {a} ==> b=a";
   391 by (Fast_tac 1);
   392 qed "singletonD";
   393 
   394 bind_thm ("singletonE", make_elim singletonD);
   395 
   396 qed_goal "singleton_iff" thy "(b : {a}) = (b=a)" 
   397 (fn _ => [Fast_tac 1]);
   398 
   399 goal Set.thy "!!a b. {a}={b} ==> a=b";
   400 by (fast_tac (!claset addEs [equalityE]) 1);
   401 qed "singleton_inject";
   402 
   403 AddSDs [singleton_inject];
   404 
   405 
   406 section "The universal set -- UNIV";
   407 
   408 qed_goal "UNIV_I" Set.thy "x : UNIV"
   409   (fn _ => [rtac ComplI 1, etac emptyE 1]);
   410 
   411 qed_goal "subset_UNIV" Set.thy "A <= UNIV"
   412   (fn _ => [rtac subsetI 1, rtac UNIV_I 1]);
   413 
   414 
   415 section "Unions of families -- UNION x:A. B(x) is Union(B``A)";
   416 
   417 goalw Set.thy [UNION_def] "(b: (UN x:A. B(x))) = (EX x:A. b: B(x))";
   418 by (Fast_tac 1);
   419 qed "UN_iff";
   420 
   421 Addsimps [UN_iff];
   422 
   423 (*The order of the premises presupposes that A is rigid; b may be flexible*)
   424 goal Set.thy "!!b. [| a:A;  b: B(a) |] ==> b: (UN x:A. B(x))";
   425 by (Auto_tac());
   426 qed "UN_I";
   427 
   428 val major::prems = goalw Set.thy [UNION_def]
   429     "[| b : (UN x:A. B(x));  !!x.[| x:A;  b: B(x) |] ==> R |] ==> R";
   430 by (rtac (major RS CollectD RS bexE) 1);
   431 by (REPEAT (ares_tac prems 1));
   432 qed "UN_E";
   433 
   434 AddIs  [UN_I];
   435 AddSEs [UN_E];
   436 
   437 val prems = goal Set.thy
   438     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   439 \    (UN x:A. C(x)) = (UN x:B. D(x))";
   440 by (REPEAT (etac UN_E 1
   441      ORELSE ares_tac ([UN_I,equalityI,subsetI] @ 
   442                       (prems RL [equalityD1,equalityD2] RL [subsetD])) 1));
   443 qed "UN_cong";
   444 
   445 
   446 section "Intersections of families -- INTER x:A. B(x) is Inter(B``A)";
   447 
   448 goalw Set.thy [INTER_def] "(b: (INT x:A. B(x))) = (ALL x:A. b: B(x))";
   449 by (Auto_tac());
   450 qed "INT_iff";
   451 
   452 Addsimps [INT_iff];
   453 
   454 val prems = goalw Set.thy [INTER_def]
   455     "(!!x. x:A ==> b: B(x)) ==> b : (INT x:A. B(x))";
   456 by (REPEAT (ares_tac ([CollectI,ballI] @ prems) 1));
   457 qed "INT_I";
   458 
   459 goal Set.thy "!!b. [| b : (INT x:A. B(x));  a:A |] ==> b: B(a)";
   460 by (Auto_tac());
   461 qed "INT_D";
   462 
   463 (*"Classical" elimination -- by the Excluded Middle on a:A *)
   464 val major::prems = goalw Set.thy [INTER_def]
   465     "[| b : (INT x:A. B(x));  b: B(a) ==> R;  a~:A ==> R |] ==> R";
   466 by (rtac (major RS CollectD RS ballE) 1);
   467 by (REPEAT (eresolve_tac prems 1));
   468 qed "INT_E";
   469 
   470 AddSIs [INT_I];
   471 AddEs  [INT_D, INT_E];
   472 
   473 val prems = goal Set.thy
   474     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   475 \    (INT x:A. C(x)) = (INT x:B. D(x))";
   476 by (REPEAT_FIRST (resolve_tac [INT_I,equalityI,subsetI]));
   477 by (REPEAT (dtac INT_D 1
   478      ORELSE ares_tac (prems RL [equalityD1,equalityD2] RL [subsetD]) 1));
   479 qed "INT_cong";
   480 
   481 
   482 section "Unions over a type; UNION1(B) = Union(range(B))";
   483 
   484 goalw Set.thy [UNION1_def] "(b: (UN x. B(x))) = (EX x. b: B(x))";
   485 by (Simp_tac 1);
   486 by (Fast_tac 1);
   487 qed "UN1_iff";
   488 
   489 Addsimps [UN1_iff];
   490 
   491 (*The order of the premises presupposes that A is rigid; b may be flexible*)
   492 goal Set.thy "!!b. b: B(x) ==> b: (UN x. B(x))";
   493 by (Auto_tac());
   494 qed "UN1_I";
   495 
   496 val major::prems = goalw Set.thy [UNION1_def]
   497     "[| b : (UN x. B(x));  !!x. b: B(x) ==> R |] ==> R";
   498 by (rtac (major RS UN_E) 1);
   499 by (REPEAT (ares_tac prems 1));
   500 qed "UN1_E";
   501 
   502 AddIs  [UN1_I];
   503 AddSEs [UN1_E];
   504 
   505 
   506 section "Intersections over a type; INTER1(B) = Inter(range(B))";
   507 
   508 goalw Set.thy [INTER1_def] "(b: (INT x. B(x))) = (ALL x. b: B(x))";
   509 by (Simp_tac 1);
   510 by (Fast_tac 1);
   511 qed "INT1_iff";
   512 
   513 Addsimps [INT1_iff];
   514 
   515 val prems = goalw Set.thy [INTER1_def]
   516     "(!!x. b: B(x)) ==> b : (INT x. B(x))";
   517 by (REPEAT (ares_tac (INT_I::prems) 1));
   518 qed "INT1_I";
   519 
   520 goal Set.thy "!!b. b : (INT x. B(x)) ==> b: B(a)";
   521 by (Asm_full_simp_tac 1);
   522 qed "INT1_D";
   523 
   524 AddSIs [INT1_I]; 
   525 AddDs  [INT1_D];
   526 
   527 
   528 section "Union";
   529 
   530 goalw Set.thy [Union_def] "(A : Union(C)) = (EX X:C. A:X)";
   531 by (Fast_tac 1);
   532 qed "Union_iff";
   533 
   534 Addsimps [Union_iff];
   535 
   536 (*The order of the premises presupposes that C is rigid; A may be flexible*)
   537 goal Set.thy "!!X. [| X:C;  A:X |] ==> A : Union(C)";
   538 by (Auto_tac());
   539 qed "UnionI";
   540 
   541 val major::prems = goalw Set.thy [Union_def]
   542     "[| A : Union(C);  !!X.[| A:X;  X:C |] ==> R |] ==> R";
   543 by (rtac (major RS UN_E) 1);
   544 by (REPEAT (ares_tac prems 1));
   545 qed "UnionE";
   546 
   547 AddIs  [UnionI];
   548 AddSEs [UnionE];
   549 
   550 
   551 section "Inter";
   552 
   553 goalw Set.thy [Inter_def] "(A : Inter(C)) = (ALL X:C. A:X)";
   554 by (Fast_tac 1);
   555 qed "Inter_iff";
   556 
   557 Addsimps [Inter_iff];
   558 
   559 val prems = goalw Set.thy [Inter_def]
   560     "[| !!X. X:C ==> A:X |] ==> A : Inter(C)";
   561 by (REPEAT (ares_tac ([INT_I] @ prems) 1));
   562 qed "InterI";
   563 
   564 (*A "destruct" rule -- every X in C contains A as an element, but
   565   A:X can hold when X:C does not!  This rule is analogous to "spec". *)
   566 goal Set.thy "!!X. [| A : Inter(C);  X:C |] ==> A:X";
   567 by (Auto_tac());
   568 qed "InterD";
   569 
   570 (*"Classical" elimination rule -- does not require proving X:C *)
   571 val major::prems = goalw Set.thy [Inter_def]
   572     "[| A : Inter(C);  A:X ==> R;  X~:C ==> R |] ==> R";
   573 by (rtac (major RS INT_E) 1);
   574 by (REPEAT (eresolve_tac prems 1));
   575 qed "InterE";
   576 
   577 AddSIs [InterI];
   578 AddEs  [InterD, InterE];
   579 
   580 
   581 section "The Powerset operator -- Pow";
   582 
   583 qed_goalw "Pow_iff" Set.thy [Pow_def] "(A : Pow(B)) = (A <= B)"
   584  (fn _ => [ (Asm_simp_tac 1) ]);
   585 
   586 AddIffs [Pow_iff]; 
   587 
   588 qed_goalw "PowI" Set.thy [Pow_def] "!!A B. A <= B ==> A : Pow(B)"
   589  (fn _ => [ (etac CollectI 1) ]);
   590 
   591 qed_goalw "PowD" Set.thy [Pow_def] "!!A B. A : Pow(B)  ==>  A<=B"
   592  (fn _=> [ (etac CollectD 1) ]);
   593 
   594 val Pow_bottom = empty_subsetI RS PowI;        (* {}: Pow(B) *)
   595 val Pow_top = subset_refl RS PowI;             (* A : Pow(A) *)
   596 
   597 
   598 
   599 (*** Set reasoning tools ***)
   600 
   601 
   602 (*Each of these has ALREADY been added to !simpset above.*)
   603 val mem_simps = [insert_iff, empty_iff, Un_iff, Int_iff, Compl_iff, Diff_iff, 
   604                  mem_Collect_eq, 
   605 		 UN_iff, UN1_iff, Union_iff, 
   606 		 INT_iff, INT1_iff, Inter_iff];
   607 
   608 (*Not for Addsimps -- it can cause goals to blow up!*)
   609 goal Set.thy "(a : (if Q then x else y)) = ((Q --> a:x) & (~Q --> a : y))";
   610 by (simp_tac (!simpset setloop split_tac [expand_if]) 1);
   611 qed "mem_if";
   612 
   613 val mksimps_pairs = ("Ball",[bspec]) :: mksimps_pairs;
   614 
   615 simpset := !simpset addcongs [ball_cong,bex_cong]
   616                     setmksimps (mksimps mksimps_pairs);