src/HOL/Set.ML
author paulson
Tue Jun 20 11:42:24 2000 +0200 (2000-06-20)
changeset 9088 453996655ac2
parent 9075 e8521ed7f35b
child 9108 9fff97d29837
permissions -rw-r--r--
replaced the useless [p]subset_insertD by [p]subset_insert_iff
     1 (*  Title:      HOL/set
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1991  University of Cambridge
     5 
     6 Set theory for higher-order logic.  A set is simply a predicate.
     7 *)
     8 
     9 section "Relating predicates and sets";
    10 
    11 Addsimps [Collect_mem_eq];
    12 AddIffs  [mem_Collect_eq];
    13 
    14 Goal "P(a) ==> a : {x. P(x)}";
    15 by (Asm_simp_tac 1);
    16 qed "CollectI";
    17 
    18 Goal "a : {x. P(x)} ==> P(a)";
    19 by (Asm_full_simp_tac 1);
    20 qed "CollectD";
    21 
    22 bind_thm ("CollectE", make_elim CollectD);
    23 
    24 val [prem] = Goal "[| !!x. (x:A) = (x:B) |] ==> A = B";
    25 by (rtac (prem RS ext RS arg_cong RS box_equals) 1);
    26 by (rtac Collect_mem_eq 1);
    27 by (rtac Collect_mem_eq 1);
    28 qed "set_ext";
    29 
    30 val [prem] = Goal "[| !!x. P(x)=Q(x) |] ==> {x. P(x)} = {x. Q(x)}";
    31 by (rtac (prem RS ext RS arg_cong) 1);
    32 qed "Collect_cong";
    33 
    34 val CollectE = make_elim CollectD;
    35 
    36 AddSIs [CollectI];
    37 AddSEs [CollectE];
    38 
    39 
    40 section "Bounded quantifiers";
    41 
    42 val prems = Goalw [Ball_def]
    43     "[| !!x. x:A ==> P(x) |] ==> ALL x:A. P(x)";
    44 by (REPEAT (ares_tac (prems @ [allI,impI]) 1));
    45 qed "ballI";
    46 
    47 bind_thms ("strip", [impI, allI, ballI]);
    48 
    49 Goalw [Ball_def] "[| ALL x:A. P(x);  x:A |] ==> P(x)";
    50 by (Blast_tac 1);
    51 qed "bspec";
    52 
    53 val major::prems = Goalw [Ball_def]
    54     "[| ALL x:A. P(x);  P(x) ==> Q;  x~:A ==> Q |] ==> Q";
    55 by (rtac (major RS spec RS impCE) 1);
    56 by (REPEAT (eresolve_tac prems 1));
    57 qed "ballE";
    58 
    59 (*Takes assumptions ALL x:A.P(x) and a:A; creates assumption P(a)*)
    60 fun ball_tac i = etac ballE i THEN contr_tac (i+1);
    61 
    62 AddSIs [ballI];
    63 AddEs  [ballE];
    64 AddXDs [bspec];
    65 (* gives better instantiation for bound: *)
    66 claset_ref() := claset() addWrapper ("bspec", fn tac2 =>
    67 			 (dtac bspec THEN' atac) APPEND' tac2);
    68 
    69 (*Normally the best argument order: P(x) constrains the choice of x:A*)
    70 Goalw [Bex_def] "[| P(x);  x:A |] ==> EX x:A. P(x)";
    71 by (Blast_tac 1);
    72 qed "bexI";
    73 
    74 (*The best argument order when there is only one x:A*)
    75 Goalw [Bex_def] "[| x:A;  P(x) |] ==> EX x:A. P(x)";
    76 by (Blast_tac 1);
    77 qed "rev_bexI";
    78 
    79 val prems = Goal 
    80    "[| ALL x:A. ~P(x) ==> P(a);  a:A |] ==> EX x:A. P(x)";
    81 by (rtac classical 1);
    82 by (REPEAT (ares_tac (prems@[bexI,ballI,notI,notE]) 1))  ;
    83 qed "bexCI";
    84 
    85 val major::prems = Goalw [Bex_def]
    86     "[| EX x:A. P(x);  !!x. [| x:A; P(x) |] ==> Q  |] ==> Q";
    87 by (rtac (major RS exE) 1);
    88 by (REPEAT (eresolve_tac (prems @ [asm_rl,conjE]) 1));
    89 qed "bexE";
    90 
    91 AddIs  [bexI];
    92 AddSEs [bexE];
    93 
    94 (*Trival rewrite rule*)
    95 Goal "(ALL x:A. P) = ((EX x. x:A) --> P)";
    96 by (simp_tac (simpset() addsimps [Ball_def]) 1);
    97 qed "ball_triv";
    98 
    99 (*Dual form for existentials*)
   100 Goal "(EX x:A. P) = ((EX x. x:A) & P)";
   101 by (simp_tac (simpset() addsimps [Bex_def]) 1);
   102 qed "bex_triv";
   103 
   104 Addsimps [ball_triv, bex_triv];
   105 
   106 (** Congruence rules **)
   107 
   108 val prems = Goalw [Ball_def]
   109     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   110 \    (ALL x:A. P(x)) = (ALL x:B. Q(x))";
   111 by (asm_simp_tac (simpset() addsimps prems) 1);
   112 qed "ball_cong";
   113 
   114 val prems = Goalw [Bex_def]
   115     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   116 \    (EX x:A. P(x)) = (EX x:B. Q(x))";
   117 by (asm_simp_tac (simpset() addcongs [conj_cong] addsimps prems) 1);
   118 qed "bex_cong";
   119 
   120 Addcongs [ball_cong,bex_cong];
   121 
   122 section "Subsets";
   123 
   124 val prems = Goalw [subset_def] "(!!x. x:A ==> x:B) ==> A <= B";
   125 by (REPEAT (ares_tac (prems @ [ballI]) 1));
   126 qed "subsetI";
   127 
   128 (*Map the type ('a set => anything) to just 'a.
   129   For overloading constants whose first argument has type "'a set" *)
   130 fun overload_1st_set s = Blast.overloaded (s, HOLogic.dest_setT o domain_type);
   131 
   132 (*While (:) is not, its type must be kept
   133   for overloading of = to work.*)
   134 Blast.overloaded ("op :", domain_type);
   135 
   136 overload_1st_set "Ball";		(*need UNION, INTER also?*)
   137 overload_1st_set "Bex";
   138 
   139 (*Image: retain the type of the set being expressed*)
   140 Blast.overloaded ("image", domain_type);
   141 
   142 (*Rule in Modus Ponens style*)
   143 Goalw [subset_def] "[| A <= B;  c:A |] ==> c:B";
   144 by (Blast_tac 1);
   145 qed "subsetD";
   146 AddXIs [subsetD];
   147 
   148 (*The same, with reversed premises for use with etac -- cf rev_mp*)
   149 Goal "[| c:A;  A <= B |] ==> c:B";
   150 by (REPEAT (ares_tac [subsetD] 1)) ;
   151 qed "rev_subsetD";
   152 AddXIs [rev_subsetD];
   153 
   154 (*Converts A<=B to x:A ==> x:B*)
   155 fun impOfSubs th = th RSN (2, rev_subsetD);
   156 
   157 Goal "[| A <= B; c ~: B |] ==> c ~: A";
   158 by (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ;
   159 qed "contra_subsetD";
   160 
   161 Goal "[| c ~: B;  A <= B |] ==> c ~: A";
   162 by (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ;
   163 qed "rev_contra_subsetD";
   164 
   165 (*Classical elimination rule*)
   166 val major::prems = Goalw [subset_def] 
   167     "[| A <= B;  c~:A ==> P;  c:B ==> P |] ==> P";
   168 by (rtac (major RS ballE) 1);
   169 by (REPEAT (eresolve_tac prems 1));
   170 qed "subsetCE";
   171 
   172 (*Takes assumptions A<=B; c:A and creates the assumption c:B *)
   173 fun set_mp_tac i = etac subsetCE i  THEN  mp_tac i;
   174 
   175 AddSIs [subsetI];
   176 AddEs  [subsetD, subsetCE];
   177 
   178 Goal "A <= (A::'a set)";
   179 by (Fast_tac 1);
   180 qed "subset_refl";		(*Blast_tac would try order_refl and fail*)
   181 
   182 Goal "[| A<=B;  B<=C |] ==> A<=(C::'a set)";
   183 by (Blast_tac 1);
   184 qed "subset_trans";
   185 
   186 
   187 section "Equality";
   188 
   189 (*Anti-symmetry of the subset relation*)
   190 Goal "[| A <= B;  B <= A |] ==> A = (B::'a set)";
   191 by (rtac set_ext 1);
   192 by (blast_tac (claset() addIs [subsetD]) 1);
   193 qed "subset_antisym";
   194 val equalityI = subset_antisym;
   195 
   196 AddSIs [equalityI];
   197 
   198 (* Equality rules from ZF set theory -- are they appropriate here? *)
   199 Goal "A = B ==> A<=(B::'a set)";
   200 by (etac ssubst 1);
   201 by (rtac subset_refl 1);
   202 qed "equalityD1";
   203 
   204 Goal "A = B ==> B<=(A::'a set)";
   205 by (etac ssubst 1);
   206 by (rtac subset_refl 1);
   207 qed "equalityD2";
   208 
   209 val prems = Goal
   210     "[| A = B;  [| A<=B; B<=(A::'a set) |] ==> P |]  ==>  P";
   211 by (resolve_tac prems 1);
   212 by (REPEAT (resolve_tac (prems RL [equalityD1,equalityD2]) 1));
   213 qed "equalityE";
   214 
   215 AddEs [equalityE];
   216 
   217 val major::prems = Goal
   218     "[| A = B;  [| c:A; c:B |] ==> P;  [| c~:A; c~:B |] ==> P |]  ==>  P";
   219 by (rtac (major RS equalityE) 1);
   220 by (REPEAT (contr_tac 1 ORELSE eresolve_tac ([asm_rl,subsetCE]@prems) 1));
   221 qed "equalityCE";
   222 
   223 (*Lemma for creating induction formulae -- for "pattern matching" on p
   224   To make the induction hypotheses usable, apply "spec" or "bspec" to
   225   put universal quantifiers over the free variables in p. *)
   226 val prems = Goal 
   227     "[| p:A;  !!z. z:A ==> p=z --> R |] ==> R";
   228 by (rtac mp 1);
   229 by (REPEAT (resolve_tac (refl::prems) 1));
   230 qed "setup_induction";
   231 
   232 Goal "A = B ==> (x : A) = (x : B)";
   233 by (Asm_simp_tac 1);
   234 qed "eqset_imp_iff";
   235 
   236 
   237 section "The universal set -- UNIV";
   238 
   239 Goalw [UNIV_def] "x : UNIV";
   240 by (rtac CollectI 1);
   241 by (rtac TrueI 1);
   242 qed "UNIV_I";
   243 
   244 Addsimps [UNIV_I];
   245 AddIs    [UNIV_I];  (*unsafe makes it less likely to cause problems*)
   246 
   247 Goal "A <= UNIV";
   248 by (rtac subsetI 1);
   249 by (rtac UNIV_I 1);
   250 qed "subset_UNIV";
   251 
   252 (** Eta-contracting these two rules (to remove P) causes them to be ignored
   253     because of their interaction with congruence rules. **)
   254 
   255 Goalw [Ball_def] "Ball UNIV P = All P";
   256 by (Simp_tac 1);
   257 qed "ball_UNIV";
   258 
   259 Goalw [Bex_def] "Bex UNIV P = Ex P";
   260 by (Simp_tac 1);
   261 qed "bex_UNIV";
   262 Addsimps [ball_UNIV, bex_UNIV];
   263 
   264 
   265 section "The empty set -- {}";
   266 
   267 Goalw [empty_def] "(c : {}) = False";
   268 by (Blast_tac 1) ;
   269 qed "empty_iff";
   270 
   271 Addsimps [empty_iff];
   272 
   273 Goal "a:{} ==> P";
   274 by (Full_simp_tac 1);
   275 qed "emptyE";
   276 
   277 AddSEs [emptyE];
   278 
   279 Goal "{} <= A";
   280 by (Blast_tac 1) ;
   281 qed "empty_subsetI";
   282 
   283 (*One effect is to delete the ASSUMPTION {} <= A*)
   284 AddIffs [empty_subsetI];
   285 
   286 val [prem]= Goal "[| !!y. y:A ==> False |] ==> A={}";
   287 by (blast_tac (claset() addIs [prem RS FalseE]) 1) ;
   288 qed "equals0I";
   289 
   290 (*Use for reasoning about disjointness: A Int B = {} *)
   291 Goal "A={} ==> a ~: A";
   292 by (Blast_tac 1) ;
   293 qed "equals0D";
   294 
   295 Goalw [Ball_def] "Ball {} P = True";
   296 by (Simp_tac 1);
   297 qed "ball_empty";
   298 
   299 Goalw [Bex_def] "Bex {} P = False";
   300 by (Simp_tac 1);
   301 qed "bex_empty";
   302 Addsimps [ball_empty, bex_empty];
   303 
   304 Goal "UNIV ~= {}";
   305 by (blast_tac (claset() addEs [equalityE]) 1);
   306 qed "UNIV_not_empty";
   307 AddIffs [UNIV_not_empty];
   308 
   309 
   310 
   311 section "The Powerset operator -- Pow";
   312 
   313 Goalw [Pow_def] "(A : Pow(B)) = (A <= B)";
   314 by (Asm_simp_tac 1);
   315 qed "Pow_iff";
   316 
   317 AddIffs [Pow_iff]; 
   318 
   319 Goalw [Pow_def] "A <= B ==> A : Pow(B)";
   320 by (etac CollectI 1);
   321 qed "PowI";
   322 
   323 Goalw [Pow_def] "A : Pow(B)  ==>  A<=B";
   324 by (etac CollectD 1);
   325 qed "PowD";
   326 
   327 
   328 val Pow_bottom = empty_subsetI RS PowI;        (* {}: Pow(B) *)
   329 val Pow_top = subset_refl RS PowI;             (* A : Pow(A) *)
   330 
   331 
   332 section "Set complement";
   333 
   334 Goalw [Compl_def] "(c : -A) = (c~:A)";
   335 by (Blast_tac 1);
   336 qed "Compl_iff";
   337 
   338 Addsimps [Compl_iff];
   339 
   340 val prems = Goalw [Compl_def] "[| c:A ==> False |] ==> c : -A";
   341 by (REPEAT (ares_tac (prems @ [CollectI,notI]) 1));
   342 qed "ComplI";
   343 
   344 (*This form, with negated conclusion, works well with the Classical prover.
   345   Negated assumptions behave like formulae on the right side of the notional
   346   turnstile...*)
   347 Goalw [Compl_def] "c : -A ==> c~:A";
   348 by (etac CollectD 1);
   349 qed "ComplD";
   350 
   351 val ComplE = make_elim ComplD;
   352 
   353 AddSIs [ComplI];
   354 AddSEs [ComplE];
   355 
   356 
   357 section "Binary union -- Un";
   358 
   359 Goalw [Un_def] "(c : A Un B) = (c:A | c:B)";
   360 by (Blast_tac 1);
   361 qed "Un_iff";
   362 Addsimps [Un_iff];
   363 
   364 Goal "c:A ==> c : A Un B";
   365 by (Asm_simp_tac 1);
   366 qed "UnI1";
   367 
   368 Goal "c:B ==> c : A Un B";
   369 by (Asm_simp_tac 1);
   370 qed "UnI2";
   371 
   372 (*Classical introduction rule: no commitment to A vs B*)
   373 
   374 val prems = Goal "(c~:B ==> c:A) ==> c : A Un B";
   375 by (Simp_tac 1);
   376 by (REPEAT (ares_tac (prems@[disjCI]) 1)) ;
   377 qed "UnCI";
   378 
   379 val major::prems = Goalw [Un_def]
   380     "[| c : A Un B;  c:A ==> P;  c:B ==> P |] ==> P";
   381 by (rtac (major RS CollectD RS disjE) 1);
   382 by (REPEAT (eresolve_tac prems 1));
   383 qed "UnE";
   384 
   385 AddSIs [UnCI];
   386 AddSEs [UnE];
   387 
   388 
   389 section "Binary intersection -- Int";
   390 
   391 Goalw [Int_def] "(c : A Int B) = (c:A & c:B)";
   392 by (Blast_tac 1);
   393 qed "Int_iff";
   394 Addsimps [Int_iff];
   395 
   396 Goal "[| c:A;  c:B |] ==> c : A Int B";
   397 by (Asm_simp_tac 1);
   398 qed "IntI";
   399 
   400 Goal "c : A Int B ==> c:A";
   401 by (Asm_full_simp_tac 1);
   402 qed "IntD1";
   403 
   404 Goal "c : A Int B ==> c:B";
   405 by (Asm_full_simp_tac 1);
   406 qed "IntD2";
   407 
   408 val [major,minor] = Goal
   409     "[| c : A Int B;  [| c:A; c:B |] ==> P |] ==> P";
   410 by (rtac minor 1);
   411 by (rtac (major RS IntD1) 1);
   412 by (rtac (major RS IntD2) 1);
   413 qed "IntE";
   414 
   415 AddSIs [IntI];
   416 AddSEs [IntE];
   417 
   418 section "Set difference";
   419 
   420 Goalw [set_diff_def] "(c : A-B) = (c:A & c~:B)";
   421 by (Blast_tac 1);
   422 qed "Diff_iff";
   423 Addsimps [Diff_iff];
   424 
   425 Goal "[| c : A;  c ~: B |] ==> c : A - B";
   426 by (Asm_simp_tac 1) ;
   427 qed "DiffI";
   428 
   429 Goal "c : A - B ==> c : A";
   430 by (Asm_full_simp_tac 1) ;
   431 qed "DiffD1";
   432 
   433 Goal "[| c : A - B;  c : B |] ==> P";
   434 by (Asm_full_simp_tac 1) ;
   435 qed "DiffD2";
   436 
   437 val prems = Goal "[| c : A - B;  [| c:A; c~:B |] ==> P |] ==> P";
   438 by (resolve_tac prems 1);
   439 by (REPEAT (ares_tac (prems RL [DiffD1, DiffD2 RS notI]) 1)) ;
   440 qed "DiffE";
   441 
   442 AddSIs [DiffI];
   443 AddSEs [DiffE];
   444 
   445 
   446 section "Augmenting a set -- insert";
   447 
   448 Goalw [insert_def] "a : insert b A = (a=b | a:A)";
   449 by (Blast_tac 1);
   450 qed "insert_iff";
   451 Addsimps [insert_iff];
   452 
   453 Goal "a : insert a B";
   454 by (Simp_tac 1);
   455 qed "insertI1";
   456 
   457 Goal "!!a. a : B ==> a : insert b B";
   458 by (Asm_simp_tac 1);
   459 qed "insertI2";
   460 
   461 val major::prems = Goalw [insert_def]
   462     "[| a : insert b A;  a=b ==> P;  a:A ==> P |] ==> P";
   463 by (rtac (major RS UnE) 1);
   464 by (REPEAT (eresolve_tac (prems @ [CollectE]) 1));
   465 qed "insertE";
   466 
   467 (*Classical introduction rule*)
   468 val prems = Goal "(a~:B ==> a=b) ==> a: insert b B";
   469 by (Simp_tac 1);
   470 by (REPEAT (ares_tac (prems@[disjCI]) 1)) ;
   471 qed "insertCI";
   472 
   473 AddSIs [insertCI]; 
   474 AddSEs [insertE];
   475 
   476 Goal "(A <= insert x B) = (if x:A then A-{x} <= B else A<=B)";
   477 by Auto_tac; 
   478 qed "subset_insert_iff";
   479 
   480 section "Singletons, using insert";
   481 
   482 Goal "a : {a}";
   483 by (rtac insertI1 1) ;
   484 qed "singletonI";
   485 
   486 Goal "b : {a} ==> b=a";
   487 by (Blast_tac 1);
   488 qed "singletonD";
   489 
   490 bind_thm ("singletonE", make_elim singletonD);
   491 
   492 Goal "(b : {a}) = (b=a)";
   493 by (Blast_tac 1);
   494 qed "singleton_iff";
   495 
   496 Goal "{a}={b} ==> a=b";
   497 by (blast_tac (claset() addEs [equalityE]) 1);
   498 qed "singleton_inject";
   499 
   500 (*Redundant? But unlike insertCI, it proves the subgoal immediately!*)
   501 AddSIs [singletonI];   
   502 AddSDs [singleton_inject];
   503 AddSEs [singletonE];
   504 
   505 Goal "{b} = insert a A = (a = b & A <= {b})";
   506 by (blast_tac (claset() addSEs [equalityE]) 1);
   507 qed "singleton_insert_inj_eq";
   508 
   509 Goal "(insert a A = {b}) = (a = b & A <= {b})";
   510 by (blast_tac (claset() addSEs [equalityE]) 1);
   511 qed "singleton_insert_inj_eq'";
   512 
   513 AddIffs [singleton_insert_inj_eq, singleton_insert_inj_eq'];
   514 
   515 Goal "A <= {x} ==> A={} | A = {x}";
   516 by (Fast_tac 1);
   517 qed "subset_singletonD";
   518 
   519 Goal "{x. x=a} = {a}";
   520 by (Blast_tac 1);
   521 qed "singleton_conv";
   522 Addsimps [singleton_conv];
   523 
   524 Goal "{x. a=x} = {a}";
   525 by (Blast_tac 1);
   526 qed "singleton_conv2";
   527 Addsimps [singleton_conv2];
   528 
   529 
   530 section "Unions of families -- UNION x:A. B(x) is Union(B``A)";
   531 
   532 Goalw [UNION_def] "(b: (UN x:A. B(x))) = (EX x:A. b: B(x))";
   533 by (Blast_tac 1);
   534 qed "UN_iff";
   535 
   536 Addsimps [UN_iff];
   537 
   538 (*The order of the premises presupposes that A is rigid; b may be flexible*)
   539 Goal "[| a:A;  b: B(a) |] ==> b: (UN x:A. B(x))";
   540 by Auto_tac;
   541 qed "UN_I";
   542 
   543 val major::prems = Goalw [UNION_def]
   544     "[| b : (UN x:A. B(x));  !!x.[| x:A;  b: B(x) |] ==> R |] ==> R";
   545 by (rtac (major RS CollectD RS bexE) 1);
   546 by (REPEAT (ares_tac prems 1));
   547 qed "UN_E";
   548 
   549 AddIs  [UN_I];
   550 AddSEs [UN_E];
   551 
   552 val prems = Goalw [UNION_def]
   553     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   554 \    (UN x:A. C(x)) = (UN x:B. D(x))";
   555 by (asm_simp_tac (simpset() addsimps prems) 1);
   556 qed "UN_cong";
   557 
   558 
   559 section "Intersections of families -- INTER x:A. B(x) is Inter(B``A)";
   560 
   561 Goalw [INTER_def] "(b: (INT x:A. B(x))) = (ALL x:A. b: B(x))";
   562 by Auto_tac;
   563 qed "INT_iff";
   564 
   565 Addsimps [INT_iff];
   566 
   567 val prems = Goalw [INTER_def]
   568     "(!!x. x:A ==> b: B(x)) ==> b : (INT x:A. B(x))";
   569 by (REPEAT (ares_tac ([CollectI,ballI] @ prems) 1));
   570 qed "INT_I";
   571 
   572 Goal "[| b : (INT x:A. B(x));  a:A |] ==> b: B(a)";
   573 by Auto_tac;
   574 qed "INT_D";
   575 
   576 (*"Classical" elimination -- by the Excluded Middle on a:A *)
   577 val major::prems = Goalw [INTER_def]
   578     "[| b : (INT x:A. B(x));  b: B(a) ==> R;  a~:A ==> R |] ==> R";
   579 by (rtac (major RS CollectD RS ballE) 1);
   580 by (REPEAT (eresolve_tac prems 1));
   581 qed "INT_E";
   582 
   583 AddSIs [INT_I];
   584 AddEs  [INT_D, INT_E];
   585 
   586 val prems = Goalw [INTER_def]
   587     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   588 \    (INT x:A. C(x)) = (INT x:B. D(x))";
   589 by (asm_simp_tac (simpset() addsimps prems) 1);
   590 qed "INT_cong";
   591 
   592 
   593 section "Union";
   594 
   595 Goalw [Union_def] "(A : Union(C)) = (EX X:C. A:X)";
   596 by (Blast_tac 1);
   597 qed "Union_iff";
   598 
   599 Addsimps [Union_iff];
   600 
   601 (*The order of the premises presupposes that C is rigid; A may be flexible*)
   602 Goal "[| X:C;  A:X |] ==> A : Union(C)";
   603 by Auto_tac;
   604 qed "UnionI";
   605 
   606 val major::prems = Goalw [Union_def]
   607     "[| A : Union(C);  !!X.[| A:X;  X:C |] ==> R |] ==> R";
   608 by (rtac (major RS UN_E) 1);
   609 by (REPEAT (ares_tac prems 1));
   610 qed "UnionE";
   611 
   612 AddIs  [UnionI];
   613 AddSEs [UnionE];
   614 
   615 
   616 section "Inter";
   617 
   618 Goalw [Inter_def] "(A : Inter(C)) = (ALL X:C. A:X)";
   619 by (Blast_tac 1);
   620 qed "Inter_iff";
   621 
   622 Addsimps [Inter_iff];
   623 
   624 val prems = Goalw [Inter_def]
   625     "[| !!X. X:C ==> A:X |] ==> A : Inter(C)";
   626 by (REPEAT (ares_tac ([INT_I] @ prems) 1));
   627 qed "InterI";
   628 
   629 (*A "destruct" rule -- every X in C contains A as an element, but
   630   A:X can hold when X:C does not!  This rule is analogous to "spec". *)
   631 Goal "[| A : Inter(C);  X:C |] ==> A:X";
   632 by Auto_tac;
   633 qed "InterD";
   634 
   635 (*"Classical" elimination rule -- does not require proving X:C *)
   636 val major::prems = Goalw [Inter_def]
   637     "[| A : Inter(C);  X~:C ==> R;  A:X ==> R |] ==> R";
   638 by (rtac (major RS INT_E) 1);
   639 by (REPEAT (eresolve_tac prems 1));
   640 qed "InterE";
   641 
   642 AddSIs [InterI];
   643 AddEs  [InterD, InterE];
   644 
   645 
   646 (*** Image of a set under a function ***)
   647 
   648 (*Frequently b does not have the syntactic form of f(x).*)
   649 Goalw [image_def] "[| b=f(x);  x:A |] ==> b : f``A";
   650 by (Blast_tac 1);
   651 qed "image_eqI";
   652 Addsimps [image_eqI];
   653 
   654 bind_thm ("imageI", refl RS image_eqI);
   655 
   656 (*This version's more effective when we already have the required x*)
   657 Goalw [image_def] "[| x:A;  b=f(x) |] ==> b : f``A";
   658 by (Blast_tac 1);
   659 qed "rev_image_eqI";
   660 
   661 (*The eta-expansion gives variable-name preservation.*)
   662 val major::prems = Goalw [image_def]
   663     "[| b : (%x. f(x))``A;  !!x.[| b=f(x);  x:A |] ==> P |] ==> P"; 
   664 by (rtac (major RS CollectD RS bexE) 1);
   665 by (REPEAT (ares_tac prems 1));
   666 qed "imageE";
   667 
   668 AddIs  [image_eqI];
   669 AddSEs [imageE]; 
   670 
   671 Goal "f``(A Un B) = f``A Un f``B";
   672 by (Blast_tac 1);
   673 qed "image_Un";
   674 
   675 Goal "(z : f``A) = (EX x:A. z = f x)";
   676 by (Blast_tac 1);
   677 qed "image_iff";
   678 
   679 (*This rewrite rule would confuse users if made default.*)
   680 Goal "(f``A <= B) = (ALL x:A. f(x): B)";
   681 by (Blast_tac 1);
   682 qed "image_subset_iff";
   683 
   684 (*Replaces the three steps subsetI, imageE, hyp_subst_tac, but breaks too
   685   many existing proofs.*)
   686 val prems = Goal "(!!x. x:A ==> f(x) : B) ==> f``A <= B";
   687 by (blast_tac (claset() addIs prems) 1);
   688 qed "image_subsetI";
   689 
   690 
   691 (*** Range of a function -- just a translation for image! ***)
   692 
   693 Goal "b=f(x) ==> b : range(f)";
   694 by (EVERY1 [etac image_eqI, rtac UNIV_I]);
   695 bind_thm ("range_eqI", UNIV_I RSN (2,image_eqI));
   696 
   697 bind_thm ("rangeI", UNIV_I RS imageI);
   698 
   699 val [major,minor] = Goal 
   700     "[| b : range(%x. f(x));  !!x. b=f(x) ==> P |] ==> P"; 
   701 by (rtac (major RS imageE) 1);
   702 by (etac minor 1);
   703 qed "rangeE";
   704 
   705 
   706 (*** Set reasoning tools ***)
   707 
   708 
   709 (** Rewrite rules for boolean case-splitting: faster than 
   710 	addsplits[split_if]
   711 **)
   712 
   713 bind_thm ("split_if_eq1", read_instantiate [("P", "%x. x = ?b")] split_if);
   714 bind_thm ("split_if_eq2", read_instantiate [("P", "%x. ?a = x")] split_if);
   715 
   716 (*Split ifs on either side of the membership relation.
   717 	Not for Addsimps -- can cause goals to blow up!*)
   718 bind_thm ("split_if_mem1", 
   719     read_instantiate_sg (Theory.sign_of Set.thy) [("P", "%x. x : ?b")] split_if);
   720 bind_thm ("split_if_mem2", 
   721     read_instantiate_sg (Theory.sign_of Set.thy) [("P", "%x. ?a : x")] split_if);
   722 
   723 val split_ifs = [if_bool_eq_conj, split_if_eq1, split_if_eq2,
   724 		  split_if_mem1, split_if_mem2];
   725 
   726 
   727 (*Each of these has ALREADY been added to simpset() above.*)
   728 val mem_simps = [insert_iff, empty_iff, Un_iff, Int_iff, Compl_iff, Diff_iff, 
   729                  mem_Collect_eq, UN_iff, Union_iff, INT_iff, Inter_iff];
   730 
   731 (*Would like to add these, but the existing code only searches for the 
   732   outer-level constant, which in this case is just "op :"; we instead need
   733   to use term-nets to associate patterns with rules.  Also, if a rule fails to
   734   apply, then the formula should be kept.
   735   [("uminus", Compl_iff RS iffD1), ("op -", [Diff_iff RS iffD1]), 
   736    ("op Int", [IntD1,IntD2]),
   737    ("Collect", [CollectD]), ("Inter", [InterD]), ("INTER", [INT_D])]
   738  *)
   739 val mksimps_pairs =
   740   [("Ball",[bspec])] @ mksimps_pairs;
   741 
   742 simpset_ref() := simpset() setmksimps (mksimps mksimps_pairs);
   743 
   744 Addsimps[subset_UNIV, subset_refl];
   745 
   746 
   747 (*** The 'proper subset' relation (<) ***)
   748 
   749 Goalw [psubset_def] "!!A::'a set. [| A <= B; A ~= B |] ==> A<B";
   750 by (Blast_tac 1);
   751 qed "psubsetI";
   752 AddSIs [psubsetI];
   753 
   754 Goalw [psubset_def]
   755   "(A < insert x B) = (if x:B then A<B else if x:A then A-{x} < B else A<=B)";
   756 by (asm_simp_tac (simpset() addsimps [subset_insert_iff]) 1);
   757 by (Blast_tac 1); 
   758 qed "psubset_insert_iff";
   759 
   760 bind_thm ("psubset_eq", psubset_def RS meta_eq_to_obj_eq);
   761 
   762 bind_thm ("psubset_imp_subset", psubset_eq RS iffD1 RS conjunct1);
   763 
   764 Goal"[| (A::'a set) < B; B <= C |] ==> A < C";
   765 by (auto_tac (claset(), simpset() addsimps [psubset_eq]));
   766 qed "psubset_subset_trans";
   767 
   768 Goal"[| (A::'a set) <= B; B < C|] ==> A < C";
   769 by (auto_tac (claset(), simpset() addsimps [psubset_eq]));
   770 qed "subset_psubset_trans";
   771 
   772 Goalw [psubset_def] "A < B ==> EX b. b : (B - A)";
   773 by (Blast_tac 1);
   774 qed "psubset_imp_ex_mem";
   775 
   776 
   777 (* attributes *)
   778 
   779 local
   780 
   781 fun gen_rulify_prems x =
   782   Attrib.no_args (Drule.rule_attribute (fn _ => (standard o
   783     rule_by_tactic (REPEAT (ALLGOALS (resolve_tac [allI, ballI, impI])))))) x;
   784 
   785 in
   786 
   787 val rulify_prems_attrib_setup =
   788  [Attrib.add_attributes
   789   [("rulify_prems", (gen_rulify_prems, gen_rulify_prems), "put theorem into standard rule form")]];
   790 
   791 end;