src/HOL/Tools/datatype_rep_proofs.ML
author haftmann
Thu Dec 01 08:28:02 2005 +0100 (2005-12-01)
changeset 18314 4595eb4627fa
parent 17985 d5d576b72371
child 18330 444f16d232a2
permissions -rw-r--r--
oriented pairs theory * 'a to 'a * theory
     1 (*  Title:      HOL/Tools/datatype_rep_proofs.ML
     2     ID:         $Id$
     3     Author:     Stefan Berghofer, TU Muenchen
     4 
     5 Definitional introduction of datatypes
     6 Proof of characteristic theorems:
     7 
     8  - injectivity of constructors
     9  - distinctness of constructors
    10  - induction theorem
    11 
    12 *)
    13 
    14 signature DATATYPE_REP_PROOFS =
    15 sig
    16   val representation_proofs : bool -> DatatypeAux.datatype_info Symtab.table ->
    17     string list -> DatatypeAux.descr list -> (string * sort) list ->
    18       (string * mixfix) list -> (string * mixfix) list list -> theory attribute
    19         -> theory -> (thm list list * thm list list * thm list list *
    20           DatatypeAux.simproc_dist list * thm) * theory
    21 end;
    22 
    23 structure DatatypeRepProofs : DATATYPE_REP_PROOFS =
    24 struct
    25 
    26 open DatatypeAux;
    27 
    28 val (_ $ (_ $ (_ $ (distinct_f $ _) $ _))) = hd (prems_of distinct_lemma);
    29 
    30 
    31 (** theory context references **)
    32 
    33 val f_myinv_f = thm "f_myinv_f";
    34 val myinv_f_f = thm "myinv_f_f";
    35 
    36 
    37 fun exh_thm_of (dt_info : datatype_info Symtab.table) tname =
    38   #exhaustion (the (Symtab.lookup dt_info tname));
    39 
    40 (******************************************************************************)
    41 
    42 fun representation_proofs flat_names (dt_info : datatype_info Symtab.table)
    43       new_type_names descr sorts types_syntax constr_syntax case_names_induct thy =
    44   let
    45     val Datatype_thy =
    46       if Context.theory_name thy = "Datatype" then thy
    47       else theory "Datatype";
    48     val node_name = "Datatype_Universe.node";
    49     val In0_name = "Datatype_Universe.In0";
    50     val In1_name = "Datatype_Universe.In1";
    51     val Scons_name = "Datatype_Universe.Scons";
    52     val Leaf_name = "Datatype_Universe.Leaf";
    53     val Numb_name = "Datatype_Universe.Numb";
    54     val Lim_name = "Datatype_Universe.Lim";
    55     val Suml_name = "Datatype.Suml";
    56     val Sumr_name = "Datatype.Sumr";
    57 
    58     val [In0_inject, In1_inject, Scons_inject, Leaf_inject,
    59          In0_eq, In1_eq, In0_not_In1, In1_not_In0,
    60          Lim_inject, Suml_inject, Sumr_inject] = map (get_thm Datatype_thy o Name)
    61         ["In0_inject", "In1_inject", "Scons_inject", "Leaf_inject",
    62          "In0_eq", "In1_eq", "In0_not_In1", "In1_not_In0",
    63          "Lim_inject", "Suml_inject", "Sumr_inject"];
    64 
    65     val descr' = List.concat descr;
    66 
    67     val big_name = space_implode "_" new_type_names;
    68     val thy1 = add_path flat_names big_name thy;
    69     val big_rec_name = big_name ^ "_rep_set";
    70     val rep_set_names = map (Sign.full_name (Theory.sign_of thy1))
    71       (if length descr' = 1 then [big_rec_name] else
    72         (map ((curry (op ^) (big_rec_name ^ "_")) o string_of_int)
    73           (1 upto (length descr'))));
    74 
    75     val tyvars = map (fn (_, (_, Ts, _)) => map dest_DtTFree Ts) (hd descr);
    76     val leafTs' = get_nonrec_types descr' sorts;
    77     val branchTs = get_branching_types descr' sorts;
    78     val branchT = if null branchTs then HOLogic.unitT
    79       else fold_bal (fn (T, U) => Type ("+", [T, U])) branchTs;
    80     val arities = get_arities descr' \ 0;
    81     val unneeded_vars = hd tyvars \\ foldr add_typ_tfree_names [] (leafTs' @ branchTs);
    82     val leafTs = leafTs' @ (map (fn n => TFree (n, (the o AList.lookup (op =) sorts) n)) unneeded_vars);
    83     val recTs = get_rec_types descr' sorts;
    84     val newTs = Library.take (length (hd descr), recTs);
    85     val oldTs = Library.drop (length (hd descr), recTs);
    86     val sumT = if null leafTs then HOLogic.unitT
    87       else fold_bal (fn (T, U) => Type ("+", [T, U])) leafTs;
    88     val Univ_elT = HOLogic.mk_setT (Type (node_name, [sumT, branchT]));
    89     val UnivT = HOLogic.mk_setT Univ_elT;
    90 
    91     val In0 = Const (In0_name, Univ_elT --> Univ_elT);
    92     val In1 = Const (In1_name, Univ_elT --> Univ_elT);
    93     val Leaf = Const (Leaf_name, sumT --> Univ_elT);
    94     val Lim = Const (Lim_name, (branchT --> Univ_elT) --> Univ_elT);
    95 
    96     (* make injections needed for embedding types in leaves *)
    97 
    98     fun mk_inj T' x =
    99       let
   100         fun mk_inj' T n i =
   101           if n = 1 then x else
   102           let val n2 = n div 2;
   103               val Type (_, [T1, T2]) = T
   104           in
   105             if i <= n2 then
   106               Const ("Sum_Type.Inl", T1 --> T) $ (mk_inj' T1 n2 i)
   107             else
   108               Const ("Sum_Type.Inr", T2 --> T) $ (mk_inj' T2 (n - n2) (i - n2))
   109           end
   110       in mk_inj' sumT (length leafTs) (1 + find_index_eq T' leafTs)
   111       end;
   112 
   113     (* make injections for constructors *)
   114 
   115     fun mk_univ_inj ts = access_bal (fn t => In0 $ t, fn t => In1 $ t, if ts = [] then
   116         Const ("arbitrary", Univ_elT)
   117       else
   118         foldr1 (HOLogic.mk_binop Scons_name) ts);
   119 
   120     (* function spaces *)
   121 
   122     fun mk_fun_inj T' x =
   123       let
   124         fun mk_inj T n i =
   125           if n = 1 then x else
   126           let
   127             val n2 = n div 2;
   128             val Type (_, [T1, T2]) = T;
   129             fun mkT U = (U --> Univ_elT) --> T --> Univ_elT
   130           in
   131             if i <= n2 then Const (Suml_name, mkT T1) $ mk_inj T1 n2 i
   132             else Const (Sumr_name, mkT T2) $ mk_inj T2 (n - n2) (i - n2)
   133           end
   134       in mk_inj branchT (length branchTs) (1 + find_index_eq T' branchTs)
   135       end;
   136 
   137     val mk_lim = foldr (fn (T, t) => Lim $ mk_fun_inj T (Abs ("x", T, t)));
   138 
   139     (************** generate introduction rules for representing set **********)
   140 
   141     val _ = message "Constructing representing sets ...";
   142 
   143     (* make introduction rule for a single constructor *)
   144 
   145     fun make_intr s n (i, (_, cargs)) =
   146       let
   147         fun mk_prem (dt, (j, prems, ts)) = (case strip_dtyp dt of
   148             (dts, DtRec k) =>
   149               let
   150                 val Ts = map (typ_of_dtyp descr' sorts) dts;
   151                 val free_t =
   152                   app_bnds (mk_Free "x" (Ts ---> Univ_elT) j) (length Ts)
   153               in (j + 1, list_all (map (pair "x") Ts,
   154                   HOLogic.mk_Trueprop (HOLogic.mk_mem (free_t,
   155                     Const (List.nth (rep_set_names, k), UnivT)))) :: prems,
   156                 mk_lim free_t Ts :: ts)
   157               end
   158           | _ =>
   159               let val T = typ_of_dtyp descr' sorts dt
   160               in (j + 1, prems, (Leaf $ mk_inj T (mk_Free "x" T j))::ts)
   161               end);
   162 
   163         val (_, prems, ts) = foldr mk_prem (1, [], []) cargs;
   164         val concl = HOLogic.mk_Trueprop (HOLogic.mk_mem
   165           (mk_univ_inj ts n i, Const (s, UnivT)))
   166       in Logic.list_implies (prems, concl)
   167       end;
   168 
   169     val consts = map (fn s => Const (s, UnivT)) rep_set_names;
   170 
   171     val intr_ts = List.concat (map (fn ((_, (_, _, constrs)), rep_set_name) =>
   172       map (make_intr rep_set_name (length constrs))
   173         ((1 upto (length constrs)) ~~ constrs)) (descr' ~~ rep_set_names));
   174 
   175     val (thy2, {raw_induct = rep_induct, intrs = rep_intrs, ...}) =
   176       setmp InductivePackage.quiet_mode (!quiet_mode)
   177         (InductivePackage.add_inductive_i false true big_rec_name false true false
   178            consts (map (fn x => (("", x), [])) intr_ts) []) thy1;
   179 
   180     (********************************* typedef ********************************)
   181 
   182     val thy3 = add_path flat_names big_name (Library.foldl (fn (thy, ((((name, mx), tvs), c), name')) =>
   183       setmp TypedefPackage.quiet_mode true
   184         (TypedefPackage.add_typedef_i false (SOME name') (name, tvs, mx) c NONE
   185           (rtac exI 1 THEN
   186             QUIET_BREADTH_FIRST (has_fewer_prems 1)
   187             (resolve_tac rep_intrs 1))) thy |> #1)
   188               (parent_path flat_names thy2, types_syntax ~~ tyvars ~~
   189                 (Library.take (length newTs, consts)) ~~ new_type_names));
   190 
   191     (*********************** definition of constructors ***********************)
   192 
   193     val big_rep_name = (space_implode "_" new_type_names) ^ "_Rep_";
   194     val rep_names = map (curry op ^ "Rep_") new_type_names;
   195     val rep_names' = map (fn i => big_rep_name ^ (string_of_int i))
   196       (1 upto (length (List.concat (tl descr))));
   197     val all_rep_names = map (Sign.intern_const (Theory.sign_of thy3)) rep_names @
   198       map (Sign.full_name (Theory.sign_of thy3)) rep_names';
   199 
   200     (* isomorphism declarations *)
   201 
   202     val iso_decls = map (fn (T, s) => (s, T --> Univ_elT, NoSyn))
   203       (oldTs ~~ rep_names');
   204 
   205     (* constructor definitions *)
   206 
   207     fun make_constr_def tname T n ((thy, defs, eqns, i), ((cname, cargs), (cname', mx))) =
   208       let
   209         fun constr_arg (dt, (j, l_args, r_args)) =
   210           let val T = typ_of_dtyp descr' sorts dt;
   211               val free_t = mk_Free "x" T j
   212           in (case (strip_dtyp dt, strip_type T) of
   213               ((_, DtRec m), (Us, U)) => (j + 1, free_t :: l_args, mk_lim
   214                 (Const (List.nth (all_rep_names, m), U --> Univ_elT) $
   215                    app_bnds free_t (length Us)) Us :: r_args)
   216             | _ => (j + 1, free_t::l_args, (Leaf $ mk_inj T free_t)::r_args))
   217           end;
   218 
   219         val (_, l_args, r_args) = foldr constr_arg (1, [], []) cargs;
   220         val constrT = (map (typ_of_dtyp descr' sorts) cargs) ---> T;
   221         val abs_name = Sign.intern_const (Theory.sign_of thy) ("Abs_" ^ tname);
   222         val rep_name = Sign.intern_const (Theory.sign_of thy) ("Rep_" ^ tname);
   223         val lhs = list_comb (Const (cname, constrT), l_args);
   224         val rhs = mk_univ_inj r_args n i;
   225         val def = equals T $ lhs $ (Const (abs_name, Univ_elT --> T) $ rhs);
   226         val def_name = (Sign.base_name cname) ^ "_def";
   227         val eqn = HOLogic.mk_Trueprop (HOLogic.mk_eq
   228           (Const (rep_name, T --> Univ_elT) $ lhs, rhs));
   229         val (thy', [def_thm]) = thy |>
   230           Theory.add_consts_i [(cname', constrT, mx)] |>
   231           (PureThy.add_defs_i false o map Thm.no_attributes) [(def_name, def)];
   232 
   233       in (thy', defs @ [def_thm], eqns @ [eqn], i + 1) end;
   234 
   235     (* constructor definitions for datatype *)
   236 
   237     fun dt_constr_defs ((thy, defs, eqns, rep_congs, dist_lemmas),
   238         ((((_, (_, _, constrs)), tname), T), constr_syntax)) =
   239       let
   240         val _ $ (_ $ (cong_f $ _) $ _) = concl_of arg_cong;
   241         val sg = Theory.sign_of thy;
   242         val rep_const = cterm_of sg
   243           (Const (Sign.intern_const sg ("Rep_" ^ tname), T --> Univ_elT));
   244         val cong' = standard (cterm_instantiate [(cterm_of sg cong_f, rep_const)] arg_cong);
   245         val dist = standard (cterm_instantiate [(cterm_of sg distinct_f, rep_const)] distinct_lemma);
   246         val (thy', defs', eqns', _) = Library.foldl ((make_constr_def tname T) (length constrs))
   247           ((add_path flat_names tname thy, defs, [], 1), constrs ~~ constr_syntax)
   248       in
   249         (parent_path flat_names thy', defs', eqns @ [eqns'],
   250           rep_congs @ [cong'], dist_lemmas @ [dist])
   251       end;
   252 
   253     val (thy4, constr_defs, constr_rep_eqns, rep_congs, dist_lemmas) = Library.foldl dt_constr_defs
   254       ((thy3 |> Theory.add_consts_i iso_decls |> parent_path flat_names, [], [], [], []),
   255         hd descr ~~ new_type_names ~~ newTs ~~ constr_syntax);
   256 
   257     (*********** isomorphisms for new types (introduced by typedef) ***********)
   258 
   259     val _ = message "Proving isomorphism properties ...";
   260 
   261     (* get axioms from theory *)
   262 
   263     val newT_iso_axms = map (fn s =>
   264       (get_thm thy4 (Name ("Abs_" ^ s ^ "_inverse")),
   265        get_thm thy4 (Name ("Rep_" ^ s ^ "_inverse")),
   266        get_thm thy4 (Name ("Rep_" ^ s)))) new_type_names;
   267 
   268     (*------------------------------------------------*)
   269     (* prove additional theorems:                     *)
   270     (*  inj_on dt_Abs_i rep_set_i  and  inj dt_Rep_i  *)
   271     (*------------------------------------------------*)
   272 
   273     fun prove_newT_iso_inj_thm (((s, (thm1, thm2, _)), T), rep_set_name) =
   274       let
   275         val sg = Theory.sign_of thy4;
   276         val RepT = T --> Univ_elT;
   277         val Rep_name = Sign.intern_const sg ("Rep_" ^ s);
   278         val AbsT = Univ_elT --> T;
   279         val Abs_name = Sign.intern_const sg ("Abs_" ^ s);
   280 
   281         val inj_Abs_thm = 
   282 	    standard (Goal.prove sg [] []
   283 	      (HOLogic.mk_Trueprop 
   284 		(Const ("Fun.inj_on", [AbsT, UnivT] ---> HOLogic.boolT) $
   285 		 Const (Abs_name, AbsT) $ Const (rep_set_name, UnivT)))
   286               (fn _ => EVERY [rtac inj_on_inverseI 1, etac thm1 1]));
   287 
   288         val setT = HOLogic.mk_setT T
   289 
   290         val inj_Rep_thm =
   291 	    standard (Goal.prove sg [] []
   292 	      (HOLogic.mk_Trueprop
   293 		(Const ("Fun.inj_on", [RepT, setT] ---> HOLogic.boolT) $
   294 		 Const (Rep_name, RepT) $ Const ("UNIV", setT)))
   295               (fn _ => EVERY [rtac inj_inverseI 1, rtac thm2 1]));
   296 
   297       in (inj_Abs_thm, inj_Rep_thm) end;
   298 
   299     val newT_iso_inj_thms = map prove_newT_iso_inj_thm
   300       (new_type_names ~~ newT_iso_axms ~~ newTs ~~
   301         Library.take (length newTs, rep_set_names));
   302 
   303     (********* isomorphisms between existing types and "unfolded" types *******)
   304 
   305     (*---------------------------------------------------------------------*)
   306     (* isomorphisms are defined using primrec-combinators:                 *)
   307     (* generate appropriate functions for instantiating primrec-combinator *)
   308     (*                                                                     *)
   309     (*   e.g.  dt_Rep_i = list_rec ... (%h t y. In1 (Scons (Leaf h) y))    *)
   310     (*                                                                     *)
   311     (* also generate characteristic equations for isomorphisms             *)
   312     (*                                                                     *)
   313     (*   e.g.  dt_Rep_i (cons h t) = In1 (Scons (dt_Rep_j h) (dt_Rep_i t)) *)
   314     (*---------------------------------------------------------------------*)
   315 
   316     fun make_iso_def k ks n ((fs, eqns, i), (cname, cargs)) =
   317       let
   318         val argTs = map (typ_of_dtyp descr' sorts) cargs;
   319         val T = List.nth (recTs, k);
   320         val rep_name = List.nth (all_rep_names, k);
   321         val rep_const = Const (rep_name, T --> Univ_elT);
   322         val constr = Const (cname, argTs ---> T);
   323 
   324         fun process_arg ks' ((i2, i2', ts, Ts), dt) =
   325           let
   326             val T' = typ_of_dtyp descr' sorts dt;
   327             val (Us, U) = strip_type T'
   328           in (case strip_dtyp dt of
   329               (_, DtRec j) => if j mem ks' then
   330                   (i2 + 1, i2' + 1, ts @ [mk_lim (app_bnds
   331                      (mk_Free "y" (Us ---> Univ_elT) i2') (length Us)) Us],
   332                    Ts @ [Us ---> Univ_elT])
   333                 else
   334                   (i2 + 1, i2', ts @ [mk_lim
   335                      (Const (List.nth (all_rep_names, j), U --> Univ_elT) $
   336                         app_bnds (mk_Free "x" T' i2) (length Us)) Us], Ts)
   337             | _ => (i2 + 1, i2', ts @ [Leaf $ mk_inj T' (mk_Free "x" T' i2)], Ts))
   338           end;
   339 
   340         val (i2, i2', ts, Ts) = Library.foldl (process_arg ks) ((1, 1, [], []), cargs);
   341         val xs = map (uncurry (mk_Free "x")) (argTs ~~ (1 upto (i2 - 1)));
   342         val ys = map (uncurry (mk_Free "y")) (Ts ~~ (1 upto (i2' - 1)));
   343         val f = list_abs_free (map dest_Free (xs @ ys), mk_univ_inj ts n i);
   344 
   345         val (_, _, ts', _) = Library.foldl (process_arg []) ((1, 1, [], []), cargs);
   346         val eqn = HOLogic.mk_Trueprop (HOLogic.mk_eq
   347           (rep_const $ list_comb (constr, xs), mk_univ_inj ts' n i))
   348 
   349       in (fs @ [f], eqns @ [eqn], i + 1) end;
   350 
   351     (* define isomorphisms for all mutually recursive datatypes in list ds *)
   352 
   353     fun make_iso_defs (ds, (thy, char_thms)) =
   354       let
   355         val ks = map fst ds;
   356         val (_, (tname, _, _)) = hd ds;
   357         val {rec_rewrites, rec_names, ...} = the (Symtab.lookup dt_info tname);
   358 
   359         fun process_dt ((fs, eqns, isos), (k, (tname, _, constrs))) =
   360           let
   361             val (fs', eqns', _) = Library.foldl (make_iso_def k ks (length constrs))
   362               ((fs, eqns, 1), constrs);
   363             val iso = (List.nth (recTs, k), List.nth (all_rep_names, k))
   364           in (fs', eqns', isos @ [iso]) end;
   365         
   366         val (fs, eqns, isos) = Library.foldl process_dt (([], [], []), ds);
   367         val fTs = map fastype_of fs;
   368         val defs = map (fn (rec_name, (T, iso_name)) => ((Sign.base_name iso_name) ^ "_def",
   369           equals (T --> Univ_elT) $ Const (iso_name, T --> Univ_elT) $
   370             list_comb (Const (rec_name, fTs @ [T] ---> Univ_elT), fs))) (rec_names ~~ isos);
   371         val (thy', def_thms) = (PureThy.add_defs_i false o map Thm.no_attributes) defs thy;
   372 
   373         (* prove characteristic equations *)
   374 
   375         val rewrites = def_thms @ (map mk_meta_eq rec_rewrites);
   376         val char_thms' = map (fn eqn => standard (Goal.prove thy' [] [] eqn
   377           (fn _ => EVERY [rewrite_goals_tac rewrites, rtac refl 1]))) eqns;
   378 
   379       in (thy', char_thms' @ char_thms) end;
   380 
   381     val (thy5, iso_char_thms) = foldr make_iso_defs
   382       (add_path flat_names big_name thy4, []) (tl descr);
   383 
   384     (* prove isomorphism properties *)
   385 
   386     fun mk_funs_inv thm =
   387       let
   388         val {sign, prop, ...} = rep_thm thm;
   389         val _ $ (_ $ (Const (_, Type (_, [U, _])) $ _ $ S)) $
   390           (_ $ (_ $ (r $ (a $ _)) $ _)) = Type.freeze prop;
   391         val used = add_term_tfree_names (a, []);
   392 
   393         fun mk_thm i =
   394           let
   395             val Ts = map (TFree o rpair HOLogic.typeS)
   396               (variantlist (replicate i "'t", used));
   397             val f = Free ("f", Ts ---> U)
   398           in standard (Goal.prove sign [] [] (Logic.mk_implies
   399             (HOLogic.mk_Trueprop (HOLogic.list_all
   400                (map (pair "x") Ts, HOLogic.mk_mem (app_bnds f i, S))),
   401              HOLogic.mk_Trueprop (HOLogic.mk_eq (list_abs (map (pair "x") Ts,
   402                r $ (a $ app_bnds f i)), f))))
   403             (fn _ => EVERY [REPEAT (rtac ext 1), REPEAT (etac allE 1), rtac thm 1, atac 1]))
   404           end
   405       in map (fn r => r RS subst) (thm :: map mk_thm arities) end;
   406 
   407     (* prove  inj dt_Rep_i  and  dt_Rep_i x : dt_rep_set_i *)
   408 
   409     fun prove_iso_thms (ds, (inj_thms, elem_thms)) =
   410       let
   411         val (_, (tname, _, _)) = hd ds;
   412         val {induction, ...} = the (Symtab.lookup dt_info tname);
   413 
   414         fun mk_ind_concl (i, _) =
   415           let
   416             val T = List.nth (recTs, i);
   417             val Rep_t = Const (List.nth (all_rep_names, i), T --> Univ_elT);
   418             val rep_set_name = List.nth (rep_set_names, i)
   419           in (HOLogic.all_const T $ Abs ("y", T, HOLogic.imp $
   420                 HOLogic.mk_eq (Rep_t $ mk_Free "x" T i, Rep_t $ Bound 0) $
   421                   HOLogic.mk_eq (mk_Free "x" T i, Bound 0)),
   422               HOLogic.mk_mem (Rep_t $ mk_Free "x" T i, Const (rep_set_name, UnivT)))
   423           end;
   424 
   425         val (ind_concl1, ind_concl2) = ListPair.unzip (map mk_ind_concl ds);
   426 
   427         val rewrites = map mk_meta_eq iso_char_thms;
   428         val inj_thms' = map (fn r => r RS injD)
   429           (map snd newT_iso_inj_thms @ inj_thms);
   430 
   431         val inj_thm = standard (Goal.prove thy5 [] []
   432           (HOLogic.mk_Trueprop (mk_conj ind_concl1)) (fn _ => EVERY
   433             [(indtac induction THEN_ALL_NEW ObjectLogic.atomize_tac) 1,
   434              REPEAT (EVERY
   435                [rtac allI 1, rtac impI 1,
   436                 exh_tac (exh_thm_of dt_info) 1,
   437                 REPEAT (EVERY
   438                   [hyp_subst_tac 1,
   439                    rewrite_goals_tac rewrites,
   440                    REPEAT (dresolve_tac [In0_inject, In1_inject] 1),
   441                    (eresolve_tac [In0_not_In1 RS notE, In1_not_In0 RS notE] 1)
   442                    ORELSE (EVERY
   443                      [REPEAT (eresolve_tac (Scons_inject ::
   444                         map make_elim [Leaf_inject, Inl_inject, Inr_inject]) 1),
   445                       REPEAT (cong_tac 1), rtac refl 1,
   446                       REPEAT (atac 1 ORELSE (EVERY
   447                         [REPEAT (rtac ext 1),
   448                          REPEAT (eresolve_tac (mp :: allE ::
   449                            map make_elim (Suml_inject :: Sumr_inject ::
   450                              Lim_inject :: fun_cong :: inj_thms')) 1),
   451                          atac 1]))])])])]));
   452 
   453         val inj_thms'' = map (fn r => r RS datatype_injI)
   454                              (split_conj_thm inj_thm);
   455 
   456         val elem_thm = 
   457 	    standard (Goal.prove thy5 [] [] (HOLogic.mk_Trueprop (mk_conj ind_concl2))
   458 	      (fn _ =>
   459 	       EVERY [(indtac induction THEN_ALL_NEW ObjectLogic.atomize_tac) 1,
   460 		rewrite_goals_tac rewrites,
   461 		REPEAT ((resolve_tac rep_intrs THEN_ALL_NEW
   462                   ((REPEAT o etac allE) THEN' ares_tac elem_thms)) 1)]));
   463 
   464       in (inj_thms'' @ inj_thms, elem_thms @ (split_conj_thm elem_thm))
   465       end;
   466 
   467     val (iso_inj_thms_unfolded, iso_elem_thms) = foldr prove_iso_thms
   468       ([], map #3 newT_iso_axms) (tl descr);
   469     val iso_inj_thms = map snd newT_iso_inj_thms @ iso_inj_thms_unfolded;
   470 
   471     (* prove  x : dt_rep_set_i --> x : range dt_Rep_i *)
   472 
   473     fun mk_iso_t (((set_name, iso_name), i), T) =
   474       let val isoT = T --> Univ_elT
   475       in HOLogic.imp $ 
   476         HOLogic.mk_mem (mk_Free "x" Univ_elT i, Const (set_name, UnivT)) $
   477           (if i < length newTs then Const ("True", HOLogic.boolT)
   478            else HOLogic.mk_mem (mk_Free "x" Univ_elT i,
   479              Const ("image", [isoT, HOLogic.mk_setT T] ---> UnivT) $
   480                Const (iso_name, isoT) $ Const ("UNIV", HOLogic.mk_setT T)))
   481       end;
   482 
   483     val iso_t = HOLogic.mk_Trueprop (mk_conj (map mk_iso_t
   484       (rep_set_names ~~ all_rep_names ~~ (0 upto (length descr' - 1)) ~~ recTs)));
   485 
   486     (* all the theorems are proved by one single simultaneous induction *)
   487 
   488     val range_eqs = map (fn r => mk_meta_eq (r RS range_ex1_eq))
   489       iso_inj_thms_unfolded;
   490 
   491     val iso_thms = if length descr = 1 then [] else
   492       Library.drop (length newTs, split_conj_thm
   493         (standard (Goal.prove thy5 [] [] iso_t (fn _ => EVERY
   494            [(indtac rep_induct THEN_ALL_NEW ObjectLogic.atomize_tac) 1,
   495             REPEAT (rtac TrueI 1),
   496             rewrite_goals_tac (mk_meta_eq choice_eq ::
   497               symmetric (mk_meta_eq expand_fun_eq) :: range_eqs),
   498             rewrite_goals_tac (map symmetric range_eqs),
   499             REPEAT (EVERY
   500               [REPEAT (eresolve_tac ([rangeE, ex1_implies_ex RS exE] @
   501                  List.concat (map (mk_funs_inv o #1) newT_iso_axms)) 1),
   502                TRY (hyp_subst_tac 1),
   503                rtac (sym RS range_eqI) 1,
   504                resolve_tac iso_char_thms 1])]))));
   505 
   506     val Abs_inverse_thms' =
   507       map #1 newT_iso_axms @
   508       map2 (fn (r_inj, r) => f_myinv_f OF [r_inj, r RS mp])
   509         (iso_inj_thms_unfolded, iso_thms);
   510 
   511     val Abs_inverse_thms = List.concat (map mk_funs_inv Abs_inverse_thms');
   512 
   513     (******************* freeness theorems for constructors *******************)
   514 
   515     val _ = message "Proving freeness of constructors ...";
   516 
   517     (* prove theorem  Rep_i (Constr_j ...) = Inj_j ...  *)
   518     
   519     fun prove_constr_rep_thm eqn =
   520       let
   521         val inj_thms = map (fn (r, _) => r RS inj_onD) newT_iso_inj_thms;
   522         val rewrites = o_def :: constr_defs @ (map (mk_meta_eq o #2) newT_iso_axms)
   523       in standard (Goal.prove thy5 [] [] eqn (fn _ => EVERY
   524         [resolve_tac inj_thms 1,
   525          rewrite_goals_tac rewrites,
   526          rtac refl 1,
   527          resolve_tac rep_intrs 2,
   528          REPEAT (resolve_tac iso_elem_thms 1)]))
   529       end;
   530 
   531     (*--------------------------------------------------------------*)
   532     (* constr_rep_thms and rep_congs are used to prove distinctness *)
   533     (* of constructors.                                             *)
   534     (*--------------------------------------------------------------*)
   535 
   536     val constr_rep_thms = map (map prove_constr_rep_thm) constr_rep_eqns;
   537 
   538     val dist_rewrites = map (fn (rep_thms, dist_lemma) =>
   539       dist_lemma::(rep_thms @ [In0_eq, In1_eq, In0_not_In1, In1_not_In0]))
   540         (constr_rep_thms ~~ dist_lemmas);
   541 
   542     fun prove_distinct_thms (_, []) = []
   543       | prove_distinct_thms (dist_rewrites', t::_::ts) =
   544           let
   545             val dist_thm = standard (Goal.prove thy5 [] [] t (fn _ =>
   546               EVERY [simp_tac (HOL_ss addsimps dist_rewrites') 1]))
   547           in dist_thm::(standard (dist_thm RS not_sym))::
   548             (prove_distinct_thms (dist_rewrites', ts))
   549           end;
   550 
   551     val distinct_thms = map prove_distinct_thms (dist_rewrites ~~
   552       DatatypeProp.make_distincts new_type_names descr sorts thy5);
   553 
   554     val simproc_dists = map (fn ((((_, (_, _, constrs)), rep_thms), congr), dists) =>
   555       if length constrs < !DatatypeProp.dtK then FewConstrs dists
   556       else ManyConstrs (congr, HOL_basic_ss addsimps rep_thms)) (hd descr ~~
   557         constr_rep_thms ~~ rep_congs ~~ distinct_thms);
   558 
   559     (* prove injectivity of constructors *)
   560 
   561     fun prove_constr_inj_thm rep_thms t =
   562       let val inj_thms = Scons_inject :: (map make_elim
   563         ((map (fn r => r RS injD) iso_inj_thms) @
   564           [In0_inject, In1_inject, Leaf_inject, Inl_inject, Inr_inject,
   565            Lim_inject, Suml_inject, Sumr_inject]))
   566       in standard (Goal.prove thy5 [] [] t (fn _ => EVERY
   567         [rtac iffI 1,
   568          REPEAT (etac conjE 2), hyp_subst_tac 2, rtac refl 2,
   569          dresolve_tac rep_congs 1, dtac box_equals 1,
   570          REPEAT (resolve_tac rep_thms 1),
   571          REPEAT (eresolve_tac inj_thms 1),
   572          REPEAT (ares_tac [conjI] 1 ORELSE (EVERY [REPEAT (rtac ext 1),
   573            REPEAT (eresolve_tac (make_elim fun_cong :: inj_thms) 1),
   574            atac 1]))]))
   575       end;
   576 
   577     val constr_inject = map (fn (ts, thms) => map (prove_constr_inj_thm thms) ts)
   578       ((DatatypeProp.make_injs descr sorts) ~~ constr_rep_thms);
   579 
   580     val ((constr_inject', distinct_thms'), thy6) =
   581       thy5
   582       |> parent_path flat_names
   583       |> store_thmss "inject" new_type_names constr_inject
   584       ||>> store_thmss "distinct" new_type_names distinct_thms;
   585 
   586     (*************************** induction theorem ****************************)
   587 
   588     val _ = message "Proving induction rule for datatypes ...";
   589 
   590     val Rep_inverse_thms = (map (fn (_, iso, _) => iso RS subst) newT_iso_axms) @
   591       (map (fn r => r RS myinv_f_f RS subst) iso_inj_thms_unfolded);
   592     val Rep_inverse_thms' = map (fn r => r RS myinv_f_f) iso_inj_thms_unfolded;
   593 
   594     fun mk_indrule_lemma ((prems, concls), ((i, _), T)) =
   595       let
   596         val Rep_t = Const (List.nth (all_rep_names, i), T --> Univ_elT) $
   597           mk_Free "x" T i;
   598 
   599         val Abs_t = if i < length newTs then
   600             Const (Sign.intern_const (Theory.sign_of thy6)
   601               ("Abs_" ^ (List.nth (new_type_names, i))), Univ_elT --> T)
   602           else Const ("Inductive.myinv", [T --> Univ_elT, Univ_elT] ---> T) $
   603             Const (List.nth (all_rep_names, i), T --> Univ_elT)
   604 
   605       in (prems @ [HOLogic.imp $ HOLogic.mk_mem (Rep_t,
   606             Const (List.nth (rep_set_names, i), UnivT)) $
   607               (mk_Free "P" (T --> HOLogic.boolT) (i + 1) $ (Abs_t $ Rep_t))],
   608           concls @ [mk_Free "P" (T --> HOLogic.boolT) (i + 1) $ mk_Free "x" T i])
   609       end;
   610 
   611     val (indrule_lemma_prems, indrule_lemma_concls) =
   612       Library.foldl mk_indrule_lemma (([], []), (descr' ~~ recTs));
   613 
   614     val cert = cterm_of (Theory.sign_of thy6);
   615 
   616     val indrule_lemma = standard (Goal.prove thy6 [] []
   617       (Logic.mk_implies
   618         (HOLogic.mk_Trueprop (mk_conj indrule_lemma_prems),
   619          HOLogic.mk_Trueprop (mk_conj indrule_lemma_concls))) (fn _ => EVERY
   620            [REPEAT (etac conjE 1),
   621             REPEAT (EVERY
   622               [TRY (rtac conjI 1), resolve_tac Rep_inverse_thms 1,
   623                etac mp 1, resolve_tac iso_elem_thms 1])]));
   624 
   625     val Ps = map head_of (HOLogic.dest_conj (HOLogic.dest_Trueprop (concl_of indrule_lemma)));
   626     val frees = if length Ps = 1 then [Free ("P", snd (dest_Var (hd Ps)))] else
   627       map (Free o apfst fst o dest_Var) Ps;
   628     val indrule_lemma' = cterm_instantiate (map cert Ps ~~ map cert frees) indrule_lemma;
   629 
   630     val dt_induct_prop = DatatypeProp.make_ind descr sorts;
   631     val dt_induct = standard (Goal.prove thy6 []
   632       (Logic.strip_imp_prems dt_induct_prop) (Logic.strip_imp_concl dt_induct_prop)
   633       (fn prems => EVERY
   634         [rtac indrule_lemma' 1,
   635          (indtac rep_induct THEN_ALL_NEW ObjectLogic.atomize_tac) 1,
   636          EVERY (map (fn (prem, r) => (EVERY
   637            [REPEAT (eresolve_tac Abs_inverse_thms 1),
   638             simp_tac (HOL_basic_ss addsimps ((symmetric r)::Rep_inverse_thms')) 1,
   639             DEPTH_SOLVE_1 (ares_tac [prem] 1 ORELSE etac allE 1)]))
   640                 (prems ~~ (constr_defs @ (map mk_meta_eq iso_char_thms))))]));
   641 
   642     val (thy7, [dt_induct']) = thy6 |>
   643       Theory.add_path big_name |>
   644       PureThy.add_thms [(("induct", dt_induct), [case_names_induct])] |>>
   645       Theory.parent_path;
   646 
   647   in
   648     ((constr_inject', distinct_thms', dist_rewrites, simproc_dists, dt_induct'), thy7)
   649   end;
   650 
   651 end;