src/HOL/Divides.thy
author haftmann
Wed Feb 24 14:19:53 2010 +0100 (2010-02-24)
changeset 35367 45a193f0ed0c
parent 35216 7641e8d831d2
child 35644 d20cf282342e
permissions -rw-r--r--
lemma div_mult_swap, dvd_div_eq_mult, dvd_div_div_eq_mult
     1 (*  Title:      HOL/Divides.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1999  University of Cambridge
     4 *)
     5 
     6 header {* The division operators div and mod *}
     7 
     8 theory Divides
     9 imports Nat_Numeral Nat_Transfer
    10 uses "~~/src/Provers/Arith/cancel_div_mod.ML"
    11 begin
    12 
    13 subsection {* Syntactic division operations *}
    14 
    15 class div = dvd +
    16   fixes div :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "div" 70)
    17     and mod :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "mod" 70)
    18 
    19 
    20 subsection {* Abstract division in commutative semirings. *}
    21 
    22 class semiring_div = comm_semiring_1_cancel + no_zero_divisors + div +
    23   assumes mod_div_equality: "a div b * b + a mod b = a"
    24     and div_by_0 [simp]: "a div 0 = 0"
    25     and div_0 [simp]: "0 div a = 0"
    26     and div_mult_self1 [simp]: "b \<noteq> 0 \<Longrightarrow> (a + c * b) div b = c + a div b"
    27     and div_mult_mult1 [simp]: "c \<noteq> 0 \<Longrightarrow> (c * a) div (c * b) = a div b"
    28 begin
    29 
    30 text {* @{const div} and @{const mod} *}
    31 
    32 lemma mod_div_equality2: "b * (a div b) + a mod b = a"
    33   unfolding mult_commute [of b]
    34   by (rule mod_div_equality)
    35 
    36 lemma mod_div_equality': "a mod b + a div b * b = a"
    37   using mod_div_equality [of a b]
    38   by (simp only: add_ac)
    39 
    40 lemma div_mod_equality: "((a div b) * b + a mod b) + c = a + c"
    41   by (simp add: mod_div_equality)
    42 
    43 lemma div_mod_equality2: "(b * (a div b) + a mod b) + c = a + c"
    44   by (simp add: mod_div_equality2)
    45 
    46 lemma mod_by_0 [simp]: "a mod 0 = a"
    47   using mod_div_equality [of a zero] by simp
    48 
    49 lemma mod_0 [simp]: "0 mod a = 0"
    50   using mod_div_equality [of zero a] div_0 by simp
    51 
    52 lemma div_mult_self2 [simp]:
    53   assumes "b \<noteq> 0"
    54   shows "(a + b * c) div b = c + a div b"
    55   using assms div_mult_self1 [of b a c] by (simp add: mult_commute)
    56 
    57 lemma mod_mult_self1 [simp]: "(a + c * b) mod b = a mod b"
    58 proof (cases "b = 0")
    59   case True then show ?thesis by simp
    60 next
    61   case False
    62   have "a + c * b = (a + c * b) div b * b + (a + c * b) mod b"
    63     by (simp add: mod_div_equality)
    64   also from False div_mult_self1 [of b a c] have
    65     "\<dots> = (c + a div b) * b + (a + c * b) mod b"
    66       by (simp add: algebra_simps)
    67   finally have "a = a div b * b + (a + c * b) mod b"
    68     by (simp add: add_commute [of a] add_assoc left_distrib)
    69   then have "a div b * b + (a + c * b) mod b = a div b * b + a mod b"
    70     by (simp add: mod_div_equality)
    71   then show ?thesis by simp
    72 qed
    73 
    74 lemma mod_mult_self2 [simp]: "(a + b * c) mod b = a mod b"
    75   by (simp add: mult_commute [of b])
    76 
    77 lemma div_mult_self1_is_id [simp]: "b \<noteq> 0 \<Longrightarrow> b * a div b = a"
    78   using div_mult_self2 [of b 0 a] by simp
    79 
    80 lemma div_mult_self2_is_id [simp]: "b \<noteq> 0 \<Longrightarrow> a * b div b = a"
    81   using div_mult_self1 [of b 0 a] by simp
    82 
    83 lemma mod_mult_self1_is_0 [simp]: "b * a mod b = 0"
    84   using mod_mult_self2 [of 0 b a] by simp
    85 
    86 lemma mod_mult_self2_is_0 [simp]: "a * b mod b = 0"
    87   using mod_mult_self1 [of 0 a b] by simp
    88 
    89 lemma div_by_1 [simp]: "a div 1 = a"
    90   using div_mult_self2_is_id [of 1 a] zero_neq_one by simp
    91 
    92 lemma mod_by_1 [simp]: "a mod 1 = 0"
    93 proof -
    94   from mod_div_equality [of a one] div_by_1 have "a + a mod 1 = a" by simp
    95   then have "a + a mod 1 = a + 0" by simp
    96   then show ?thesis by (rule add_left_imp_eq)
    97 qed
    98 
    99 lemma mod_self [simp]: "a mod a = 0"
   100   using mod_mult_self2_is_0 [of 1] by simp
   101 
   102 lemma div_self [simp]: "a \<noteq> 0 \<Longrightarrow> a div a = 1"
   103   using div_mult_self2_is_id [of _ 1] by simp
   104 
   105 lemma div_add_self1 [simp]:
   106   assumes "b \<noteq> 0"
   107   shows "(b + a) div b = a div b + 1"
   108   using assms div_mult_self1 [of b a 1] by (simp add: add_commute)
   109 
   110 lemma div_add_self2 [simp]:
   111   assumes "b \<noteq> 0"
   112   shows "(a + b) div b = a div b + 1"
   113   using assms div_add_self1 [of b a] by (simp add: add_commute)
   114 
   115 lemma mod_add_self1 [simp]:
   116   "(b + a) mod b = a mod b"
   117   using mod_mult_self1 [of a 1 b] by (simp add: add_commute)
   118 
   119 lemma mod_add_self2 [simp]:
   120   "(a + b) mod b = a mod b"
   121   using mod_mult_self1 [of a 1 b] by simp
   122 
   123 lemma mod_div_decomp:
   124   fixes a b
   125   obtains q r where "q = a div b" and "r = a mod b"
   126     and "a = q * b + r"
   127 proof -
   128   from mod_div_equality have "a = a div b * b + a mod b" by simp
   129   moreover have "a div b = a div b" ..
   130   moreover have "a mod b = a mod b" ..
   131   note that ultimately show thesis by blast
   132 qed
   133 
   134 lemma dvd_eq_mod_eq_0 [code, code_unfold, code_inline del]: "a dvd b \<longleftrightarrow> b mod a = 0"
   135 proof
   136   assume "b mod a = 0"
   137   with mod_div_equality [of b a] have "b div a * a = b" by simp
   138   then have "b = a * (b div a)" unfolding mult_commute ..
   139   then have "\<exists>c. b = a * c" ..
   140   then show "a dvd b" unfolding dvd_def .
   141 next
   142   assume "a dvd b"
   143   then have "\<exists>c. b = a * c" unfolding dvd_def .
   144   then obtain c where "b = a * c" ..
   145   then have "b mod a = a * c mod a" by simp
   146   then have "b mod a = c * a mod a" by (simp add: mult_commute)
   147   then show "b mod a = 0" by simp
   148 qed
   149 
   150 lemma mod_div_trivial [simp]: "a mod b div b = 0"
   151 proof (cases "b = 0")
   152   assume "b = 0"
   153   thus ?thesis by simp
   154 next
   155   assume "b \<noteq> 0"
   156   hence "a div b + a mod b div b = (a mod b + a div b * b) div b"
   157     by (rule div_mult_self1 [symmetric])
   158   also have "\<dots> = a div b"
   159     by (simp only: mod_div_equality')
   160   also have "\<dots> = a div b + 0"
   161     by simp
   162   finally show ?thesis
   163     by (rule add_left_imp_eq)
   164 qed
   165 
   166 lemma mod_mod_trivial [simp]: "a mod b mod b = a mod b"
   167 proof -
   168   have "a mod b mod b = (a mod b + a div b * b) mod b"
   169     by (simp only: mod_mult_self1)
   170   also have "\<dots> = a mod b"
   171     by (simp only: mod_div_equality')
   172   finally show ?thesis .
   173 qed
   174 
   175 lemma dvd_imp_mod_0: "a dvd b \<Longrightarrow> b mod a = 0"
   176 by (rule dvd_eq_mod_eq_0[THEN iffD1])
   177 
   178 lemma dvd_div_mult_self: "a dvd b \<Longrightarrow> (b div a) * a = b"
   179 by (subst (2) mod_div_equality [of b a, symmetric]) (simp add:dvd_imp_mod_0)
   180 
   181 lemma dvd_mult_div_cancel: "a dvd b \<Longrightarrow> a * (b div a) = b"
   182 by (drule dvd_div_mult_self) (simp add: mult_commute)
   183 
   184 lemma dvd_div_mult: "a dvd b \<Longrightarrow> (b div a) * c = b * c div a"
   185 apply (cases "a = 0")
   186  apply simp
   187 apply (auto simp: dvd_def mult_assoc)
   188 done
   189 
   190 lemma div_dvd_div[simp]:
   191   "a dvd b \<Longrightarrow> a dvd c \<Longrightarrow> (b div a dvd c div a) = (b dvd c)"
   192 apply (cases "a = 0")
   193  apply simp
   194 apply (unfold dvd_def)
   195 apply auto
   196  apply(blast intro:mult_assoc[symmetric])
   197 apply(fastsimp simp add: mult_assoc)
   198 done
   199 
   200 lemma dvd_mod_imp_dvd: "[| k dvd m mod n;  k dvd n |] ==> k dvd m"
   201   apply (subgoal_tac "k dvd (m div n) *n + m mod n")
   202    apply (simp add: mod_div_equality)
   203   apply (simp only: dvd_add dvd_mult)
   204   done
   205 
   206 text {* Addition respects modular equivalence. *}
   207 
   208 lemma mod_add_left_eq: "(a + b) mod c = (a mod c + b) mod c"
   209 proof -
   210   have "(a + b) mod c = (a div c * c + a mod c + b) mod c"
   211     by (simp only: mod_div_equality)
   212   also have "\<dots> = (a mod c + b + a div c * c) mod c"
   213     by (simp only: add_ac)
   214   also have "\<dots> = (a mod c + b) mod c"
   215     by (rule mod_mult_self1)
   216   finally show ?thesis .
   217 qed
   218 
   219 lemma mod_add_right_eq: "(a + b) mod c = (a + b mod c) mod c"
   220 proof -
   221   have "(a + b) mod c = (a + (b div c * c + b mod c)) mod c"
   222     by (simp only: mod_div_equality)
   223   also have "\<dots> = (a + b mod c + b div c * c) mod c"
   224     by (simp only: add_ac)
   225   also have "\<dots> = (a + b mod c) mod c"
   226     by (rule mod_mult_self1)
   227   finally show ?thesis .
   228 qed
   229 
   230 lemma mod_add_eq: "(a + b) mod c = (a mod c + b mod c) mod c"
   231 by (rule trans [OF mod_add_left_eq mod_add_right_eq])
   232 
   233 lemma mod_add_cong:
   234   assumes "a mod c = a' mod c"
   235   assumes "b mod c = b' mod c"
   236   shows "(a + b) mod c = (a' + b') mod c"
   237 proof -
   238   have "(a mod c + b mod c) mod c = (a' mod c + b' mod c) mod c"
   239     unfolding assms ..
   240   thus ?thesis
   241     by (simp only: mod_add_eq [symmetric])
   242 qed
   243 
   244 lemma div_add [simp]: "z dvd x \<Longrightarrow> z dvd y
   245   \<Longrightarrow> (x + y) div z = x div z + y div z"
   246 by (cases "z = 0", simp, unfold dvd_def, auto simp add: algebra_simps)
   247 
   248 text {* Multiplication respects modular equivalence. *}
   249 
   250 lemma mod_mult_left_eq: "(a * b) mod c = ((a mod c) * b) mod c"
   251 proof -
   252   have "(a * b) mod c = ((a div c * c + a mod c) * b) mod c"
   253     by (simp only: mod_div_equality)
   254   also have "\<dots> = (a mod c * b + a div c * b * c) mod c"
   255     by (simp only: algebra_simps)
   256   also have "\<dots> = (a mod c * b) mod c"
   257     by (rule mod_mult_self1)
   258   finally show ?thesis .
   259 qed
   260 
   261 lemma mod_mult_right_eq: "(a * b) mod c = (a * (b mod c)) mod c"
   262 proof -
   263   have "(a * b) mod c = (a * (b div c * c + b mod c)) mod c"
   264     by (simp only: mod_div_equality)
   265   also have "\<dots> = (a * (b mod c) + a * (b div c) * c) mod c"
   266     by (simp only: algebra_simps)
   267   also have "\<dots> = (a * (b mod c)) mod c"
   268     by (rule mod_mult_self1)
   269   finally show ?thesis .
   270 qed
   271 
   272 lemma mod_mult_eq: "(a * b) mod c = ((a mod c) * (b mod c)) mod c"
   273 by (rule trans [OF mod_mult_left_eq mod_mult_right_eq])
   274 
   275 lemma mod_mult_cong:
   276   assumes "a mod c = a' mod c"
   277   assumes "b mod c = b' mod c"
   278   shows "(a * b) mod c = (a' * b') mod c"
   279 proof -
   280   have "(a mod c * (b mod c)) mod c = (a' mod c * (b' mod c)) mod c"
   281     unfolding assms ..
   282   thus ?thesis
   283     by (simp only: mod_mult_eq [symmetric])
   284 qed
   285 
   286 lemma mod_mod_cancel:
   287   assumes "c dvd b"
   288   shows "a mod b mod c = a mod c"
   289 proof -
   290   from `c dvd b` obtain k where "b = c * k"
   291     by (rule dvdE)
   292   have "a mod b mod c = a mod (c * k) mod c"
   293     by (simp only: `b = c * k`)
   294   also have "\<dots> = (a mod (c * k) + a div (c * k) * k * c) mod c"
   295     by (simp only: mod_mult_self1)
   296   also have "\<dots> = (a div (c * k) * (c * k) + a mod (c * k)) mod c"
   297     by (simp only: add_ac mult_ac)
   298   also have "\<dots> = a mod c"
   299     by (simp only: mod_div_equality)
   300   finally show ?thesis .
   301 qed
   302 
   303 lemma div_mult_div_if_dvd:
   304   "y dvd x \<Longrightarrow> z dvd w \<Longrightarrow> (x div y) * (w div z) = (x * w) div (y * z)"
   305   apply (cases "y = 0", simp)
   306   apply (cases "z = 0", simp)
   307   apply (auto elim!: dvdE simp add: algebra_simps)
   308   apply (subst mult_assoc [symmetric])
   309   apply (simp add: no_zero_divisors)
   310   done
   311 
   312 lemma div_mult_swap:
   313   assumes "c dvd b"
   314   shows "a * (b div c) = (a * b) div c"
   315 proof -
   316   from assms have "b div c * (a div 1) = b * a div (c * 1)"
   317     by (simp only: div_mult_div_if_dvd one_dvd)
   318   then show ?thesis by (simp add: mult_commute)
   319 qed
   320    
   321 lemma div_mult_mult2 [simp]:
   322   "c \<noteq> 0 \<Longrightarrow> (a * c) div (b * c) = a div b"
   323   by (drule div_mult_mult1) (simp add: mult_commute)
   324 
   325 lemma div_mult_mult1_if [simp]:
   326   "(c * a) div (c * b) = (if c = 0 then 0 else a div b)"
   327   by simp_all
   328 
   329 lemma mod_mult_mult1:
   330   "(c * a) mod (c * b) = c * (a mod b)"
   331 proof (cases "c = 0")
   332   case True then show ?thesis by simp
   333 next
   334   case False
   335   from mod_div_equality
   336   have "((c * a) div (c * b)) * (c * b) + (c * a) mod (c * b) = c * a" .
   337   with False have "c * ((a div b) * b + a mod b) + (c * a) mod (c * b)
   338     = c * a + c * (a mod b)" by (simp add: algebra_simps)
   339   with mod_div_equality show ?thesis by simp 
   340 qed
   341   
   342 lemma mod_mult_mult2:
   343   "(a * c) mod (b * c) = (a mod b) * c"
   344   using mod_mult_mult1 [of c a b] by (simp add: mult_commute)
   345 
   346 lemma dvd_mod: "k dvd m \<Longrightarrow> k dvd n \<Longrightarrow> k dvd (m mod n)"
   347   unfolding dvd_def by (auto simp add: mod_mult_mult1)
   348 
   349 lemma dvd_mod_iff: "k dvd n \<Longrightarrow> k dvd (m mod n) \<longleftrightarrow> k dvd m"
   350 by (blast intro: dvd_mod_imp_dvd dvd_mod)
   351 
   352 lemma div_power:
   353   "y dvd x \<Longrightarrow> (x div y) ^ n = x ^ n div y ^ n"
   354 apply (induct n)
   355  apply simp
   356 apply(simp add: div_mult_div_if_dvd dvd_power_same)
   357 done
   358 
   359 lemma dvd_div_eq_mult:
   360   assumes "a \<noteq> 0" and "a dvd b"  
   361   shows "b div a = c \<longleftrightarrow> b = c * a"
   362 proof
   363   assume "b = c * a"
   364   then show "b div a = c" by (simp add: assms)
   365 next
   366   assume "b div a = c"
   367   then have "b div a * a = c * a" by simp
   368   moreover from `a dvd b` have "b div a * a = b" by (simp add: dvd_div_mult_self)
   369   ultimately show "b = c * a" by simp
   370 qed
   371    
   372 lemma dvd_div_div_eq_mult:
   373   assumes "a \<noteq> 0" "c \<noteq> 0" and "a dvd b" "c dvd d"
   374   shows "b div a = d div c \<longleftrightarrow> b * c = a * d"
   375   using assms by (auto simp add: mult_commute [of _ a] dvd_div_mult_self dvd_div_eq_mult div_mult_swap intro: sym)
   376 
   377 end
   378 
   379 class ring_div = semiring_div + idom
   380 begin
   381 
   382 text {* Negation respects modular equivalence. *}
   383 
   384 lemma mod_minus_eq: "(- a) mod b = (- (a mod b)) mod b"
   385 proof -
   386   have "(- a) mod b = (- (a div b * b + a mod b)) mod b"
   387     by (simp only: mod_div_equality)
   388   also have "\<dots> = (- (a mod b) + - (a div b) * b) mod b"
   389     by (simp only: minus_add_distrib minus_mult_left add_ac)
   390   also have "\<dots> = (- (a mod b)) mod b"
   391     by (rule mod_mult_self1)
   392   finally show ?thesis .
   393 qed
   394 
   395 lemma mod_minus_cong:
   396   assumes "a mod b = a' mod b"
   397   shows "(- a) mod b = (- a') mod b"
   398 proof -
   399   have "(- (a mod b)) mod b = (- (a' mod b)) mod b"
   400     unfolding assms ..
   401   thus ?thesis
   402     by (simp only: mod_minus_eq [symmetric])
   403 qed
   404 
   405 text {* Subtraction respects modular equivalence. *}
   406 
   407 lemma mod_diff_left_eq: "(a - b) mod c = (a mod c - b) mod c"
   408   unfolding diff_minus
   409   by (intro mod_add_cong mod_minus_cong) simp_all
   410 
   411 lemma mod_diff_right_eq: "(a - b) mod c = (a - b mod c) mod c"
   412   unfolding diff_minus
   413   by (intro mod_add_cong mod_minus_cong) simp_all
   414 
   415 lemma mod_diff_eq: "(a - b) mod c = (a mod c - b mod c) mod c"
   416   unfolding diff_minus
   417   by (intro mod_add_cong mod_minus_cong) simp_all
   418 
   419 lemma mod_diff_cong:
   420   assumes "a mod c = a' mod c"
   421   assumes "b mod c = b' mod c"
   422   shows "(a - b) mod c = (a' - b') mod c"
   423   unfolding diff_minus using assms
   424   by (intro mod_add_cong mod_minus_cong)
   425 
   426 lemma dvd_neg_div: "y dvd x \<Longrightarrow> -x div y = - (x div y)"
   427 apply (case_tac "y = 0") apply simp
   428 apply (auto simp add: dvd_def)
   429 apply (subgoal_tac "-(y * k) = y * - k")
   430  apply (erule ssubst)
   431  apply (erule div_mult_self1_is_id)
   432 apply simp
   433 done
   434 
   435 lemma dvd_div_neg: "y dvd x \<Longrightarrow> x div -y = - (x div y)"
   436 apply (case_tac "y = 0") apply simp
   437 apply (auto simp add: dvd_def)
   438 apply (subgoal_tac "y * k = -y * -k")
   439  apply (erule ssubst)
   440  apply (rule div_mult_self1_is_id)
   441  apply simp
   442 apply simp
   443 done
   444 
   445 end
   446 
   447 
   448 subsection {* Division on @{typ nat} *}
   449 
   450 text {*
   451   We define @{const div} and @{const mod} on @{typ nat} by means
   452   of a characteristic relation with two input arguments
   453   @{term "m\<Colon>nat"}, @{term "n\<Colon>nat"} and two output arguments
   454   @{term "q\<Colon>nat"}(uotient) and @{term "r\<Colon>nat"}(emainder).
   455 *}
   456 
   457 definition divmod_nat_rel :: "nat \<Rightarrow> nat \<Rightarrow> nat \<times> nat \<Rightarrow> bool" where
   458   "divmod_nat_rel m n qr \<longleftrightarrow>
   459     m = fst qr * n + snd qr \<and>
   460       (if n = 0 then fst qr = 0 else if n > 0 then 0 \<le> snd qr \<and> snd qr < n else n < snd qr \<and> snd qr \<le> 0)"
   461 
   462 text {* @{const divmod_nat_rel} is total: *}
   463 
   464 lemma divmod_nat_rel_ex:
   465   obtains q r where "divmod_nat_rel m n (q, r)"
   466 proof (cases "n = 0")
   467   case True  with that show thesis
   468     by (auto simp add: divmod_nat_rel_def)
   469 next
   470   case False
   471   have "\<exists>q r. m = q * n + r \<and> r < n"
   472   proof (induct m)
   473     case 0 with `n \<noteq> 0`
   474     have "(0\<Colon>nat) = 0 * n + 0 \<and> 0 < n" by simp
   475     then show ?case by blast
   476   next
   477     case (Suc m) then obtain q' r'
   478       where m: "m = q' * n + r'" and n: "r' < n" by auto
   479     then show ?case proof (cases "Suc r' < n")
   480       case True
   481       from m n have "Suc m = q' * n + Suc r'" by simp
   482       with True show ?thesis by blast
   483     next
   484       case False then have "n \<le> Suc r'" by auto
   485       moreover from n have "Suc r' \<le> n" by auto
   486       ultimately have "n = Suc r'" by auto
   487       with m have "Suc m = Suc q' * n + 0" by simp
   488       with `n \<noteq> 0` show ?thesis by blast
   489     qed
   490   qed
   491   with that show thesis
   492     using `n \<noteq> 0` by (auto simp add: divmod_nat_rel_def)
   493 qed
   494 
   495 text {* @{const divmod_nat_rel} is injective: *}
   496 
   497 lemma divmod_nat_rel_unique:
   498   assumes "divmod_nat_rel m n qr"
   499     and "divmod_nat_rel m n qr'"
   500   shows "qr = qr'"
   501 proof (cases "n = 0")
   502   case True with assms show ?thesis
   503     by (cases qr, cases qr')
   504       (simp add: divmod_nat_rel_def)
   505 next
   506   case False
   507   have aux: "\<And>q r q' r'. q' * n + r' = q * n + r \<Longrightarrow> r < n \<Longrightarrow> q' \<le> (q\<Colon>nat)"
   508   apply (rule leI)
   509   apply (subst less_iff_Suc_add)
   510   apply (auto simp add: add_mult_distrib)
   511   done
   512   from `n \<noteq> 0` assms have "fst qr = fst qr'"
   513     by (auto simp add: divmod_nat_rel_def intro: order_antisym dest: aux sym)
   514   moreover from this assms have "snd qr = snd qr'"
   515     by (simp add: divmod_nat_rel_def)
   516   ultimately show ?thesis by (cases qr, cases qr') simp
   517 qed
   518 
   519 text {*
   520   We instantiate divisibility on the natural numbers by
   521   means of @{const divmod_nat_rel}:
   522 *}
   523 
   524 instantiation nat :: semiring_div
   525 begin
   526 
   527 definition divmod_nat :: "nat \<Rightarrow> nat \<Rightarrow> nat \<times> nat" where
   528   [code del]: "divmod_nat m n = (THE qr. divmod_nat_rel m n qr)"
   529 
   530 lemma divmod_nat_rel_divmod_nat:
   531   "divmod_nat_rel m n (divmod_nat m n)"
   532 proof -
   533   from divmod_nat_rel_ex
   534     obtain qr where rel: "divmod_nat_rel m n qr" .
   535   then show ?thesis
   536   by (auto simp add: divmod_nat_def intro: theI elim: divmod_nat_rel_unique)
   537 qed
   538 
   539 lemma divmod_nat_eq:
   540   assumes "divmod_nat_rel m n qr" 
   541   shows "divmod_nat m n = qr"
   542   using assms by (auto intro: divmod_nat_rel_unique divmod_nat_rel_divmod_nat)
   543 
   544 definition div_nat where
   545   "m div n = fst (divmod_nat m n)"
   546 
   547 definition mod_nat where
   548   "m mod n = snd (divmod_nat m n)"
   549 
   550 lemma divmod_nat_div_mod:
   551   "divmod_nat m n = (m div n, m mod n)"
   552   unfolding div_nat_def mod_nat_def by simp
   553 
   554 lemma div_eq:
   555   assumes "divmod_nat_rel m n (q, r)" 
   556   shows "m div n = q"
   557   using assms by (auto dest: divmod_nat_eq simp add: divmod_nat_div_mod)
   558 
   559 lemma mod_eq:
   560   assumes "divmod_nat_rel m n (q, r)" 
   561   shows "m mod n = r"
   562   using assms by (auto dest: divmod_nat_eq simp add: divmod_nat_div_mod)
   563 
   564 lemma divmod_nat_rel: "divmod_nat_rel m n (m div n, m mod n)"
   565   by (simp add: div_nat_def mod_nat_def divmod_nat_rel_divmod_nat)
   566 
   567 lemma divmod_nat_zero:
   568   "divmod_nat m 0 = (0, m)"
   569 proof -
   570   from divmod_nat_rel [of m 0] show ?thesis
   571     unfolding divmod_nat_div_mod divmod_nat_rel_def by simp
   572 qed
   573 
   574 lemma divmod_nat_base:
   575   assumes "m < n"
   576   shows "divmod_nat m n = (0, m)"
   577 proof -
   578   from divmod_nat_rel [of m n] show ?thesis
   579     unfolding divmod_nat_div_mod divmod_nat_rel_def
   580     using assms by (cases "m div n = 0")
   581       (auto simp add: gr0_conv_Suc [of "m div n"])
   582 qed
   583 
   584 lemma divmod_nat_step:
   585   assumes "0 < n" and "n \<le> m"
   586   shows "divmod_nat m n = (Suc ((m - n) div n), (m - n) mod n)"
   587 proof -
   588   from divmod_nat_rel have divmod_nat_m_n: "divmod_nat_rel m n (m div n, m mod n)" .
   589   with assms have m_div_n: "m div n \<ge> 1"
   590     by (cases "m div n") (auto simp add: divmod_nat_rel_def)
   591   from assms divmod_nat_m_n have "divmod_nat_rel (m - n) n (m div n - Suc 0, m mod n)"
   592     by (cases "m div n") (auto simp add: divmod_nat_rel_def)
   593   with divmod_nat_eq have "divmod_nat (m - n) n = (m div n - Suc 0, m mod n)" by simp
   594   moreover from divmod_nat_div_mod have "divmod_nat (m - n) n = ((m - n) div n, (m - n) mod n)" .
   595   ultimately have "m div n = Suc ((m - n) div n)"
   596     and "m mod n = (m - n) mod n" using m_div_n by simp_all
   597   then show ?thesis using divmod_nat_div_mod by simp
   598 qed
   599 
   600 text {* The ''recursion'' equations for @{const div} and @{const mod} *}
   601 
   602 lemma div_less [simp]:
   603   fixes m n :: nat
   604   assumes "m < n"
   605   shows "m div n = 0"
   606   using assms divmod_nat_base divmod_nat_div_mod by simp
   607 
   608 lemma le_div_geq:
   609   fixes m n :: nat
   610   assumes "0 < n" and "n \<le> m"
   611   shows "m div n = Suc ((m - n) div n)"
   612   using assms divmod_nat_step divmod_nat_div_mod by simp
   613 
   614 lemma mod_less [simp]:
   615   fixes m n :: nat
   616   assumes "m < n"
   617   shows "m mod n = m"
   618   using assms divmod_nat_base divmod_nat_div_mod by simp
   619 
   620 lemma le_mod_geq:
   621   fixes m n :: nat
   622   assumes "n \<le> m"
   623   shows "m mod n = (m - n) mod n"
   624   using assms divmod_nat_step divmod_nat_div_mod by (cases "n = 0") simp_all
   625 
   626 instance proof -
   627   have [simp]: "\<And>n::nat. n div 0 = 0"
   628     by (simp add: div_nat_def divmod_nat_zero)
   629   have [simp]: "\<And>n::nat. 0 div n = 0"
   630   proof -
   631     fix n :: nat
   632     show "0 div n = 0"
   633       by (cases "n = 0") simp_all
   634   qed
   635   show "OFCLASS(nat, semiring_div_class)" proof
   636     fix m n :: nat
   637     show "m div n * n + m mod n = m"
   638       using divmod_nat_rel [of m n] by (simp add: divmod_nat_rel_def)
   639   next
   640     fix m n q :: nat
   641     assume "n \<noteq> 0"
   642     then show "(q + m * n) div n = m + q div n"
   643       by (induct m) (simp_all add: le_div_geq)
   644   next
   645     fix m n q :: nat
   646     assume "m \<noteq> 0"
   647     then show "(m * n) div (m * q) = n div q"
   648     proof (cases "n \<noteq> 0 \<and> q \<noteq> 0")
   649       case False then show ?thesis by auto
   650     next
   651       case True with `m \<noteq> 0`
   652         have "m > 0" and "n > 0" and "q > 0" by auto
   653       then have "\<And>a b. divmod_nat_rel n q (a, b) \<Longrightarrow> divmod_nat_rel (m * n) (m * q) (a, m * b)"
   654         by (auto simp add: divmod_nat_rel_def) (simp_all add: algebra_simps)
   655       moreover from divmod_nat_rel have "divmod_nat_rel n q (n div q, n mod q)" .
   656       ultimately have "divmod_nat_rel (m * n) (m * q) (n div q, m * (n mod q))" .
   657       then show ?thesis by (simp add: div_eq)
   658     qed
   659   qed simp_all
   660 qed
   661 
   662 end
   663 
   664 lemma divmod_nat_if [code]: "divmod_nat m n = (if n = 0 \<or> m < n then (0, m) else
   665   let (q, r) = divmod_nat (m - n) n in (Suc q, r))"
   666 by (simp add: divmod_nat_zero divmod_nat_base divmod_nat_step)
   667     (simp add: divmod_nat_div_mod)
   668 
   669 text {* Simproc for cancelling @{const div} and @{const mod} *}
   670 
   671 ML {*
   672 local
   673 
   674 structure CancelDivMod = CancelDivModFun(struct
   675 
   676   val div_name = @{const_name div};
   677   val mod_name = @{const_name mod};
   678   val mk_binop = HOLogic.mk_binop;
   679   val mk_sum = Nat_Arith.mk_sum;
   680   val dest_sum = Nat_Arith.dest_sum;
   681 
   682   val div_mod_eqs = map mk_meta_eq [@{thm div_mod_equality}, @{thm div_mod_equality2}];
   683 
   684   val trans = trans;
   685 
   686   val prove_eq_sums = Arith_Data.prove_conv2 all_tac (Arith_Data.simp_all_tac
   687     (@{thm add_0_left} :: @{thm add_0_right} :: @{thms add_ac}))
   688 
   689 end)
   690 
   691 in
   692 
   693 val cancel_div_mod_nat_proc = Simplifier.simproc @{theory}
   694   "cancel_div_mod" ["(m::nat) + n"] (K CancelDivMod.proc);
   695 
   696 val _ = Addsimprocs [cancel_div_mod_nat_proc];
   697 
   698 end
   699 *}
   700 
   701 
   702 subsubsection {* Quotient *}
   703 
   704 lemma div_geq: "0 < n \<Longrightarrow>  \<not> m < n \<Longrightarrow> m div n = Suc ((m - n) div n)"
   705 by (simp add: le_div_geq linorder_not_less)
   706 
   707 lemma div_if: "0 < n \<Longrightarrow> m div n = (if m < n then 0 else Suc ((m - n) div n))"
   708 by (simp add: div_geq)
   709 
   710 lemma div_mult_self_is_m [simp]: "0<n ==> (m*n) div n = (m::nat)"
   711 by simp
   712 
   713 lemma div_mult_self1_is_m [simp]: "0<n ==> (n*m) div n = (m::nat)"
   714 by simp
   715 
   716 
   717 subsubsection {* Remainder *}
   718 
   719 lemma mod_less_divisor [simp]:
   720   fixes m n :: nat
   721   assumes "n > 0"
   722   shows "m mod n < (n::nat)"
   723   using assms divmod_nat_rel [of m n] unfolding divmod_nat_rel_def by auto
   724 
   725 lemma mod_less_eq_dividend [simp]:
   726   fixes m n :: nat
   727   shows "m mod n \<le> m"
   728 proof (rule add_leD2)
   729   from mod_div_equality have "m div n * n + m mod n = m" .
   730   then show "m div n * n + m mod n \<le> m" by auto
   731 qed
   732 
   733 lemma mod_geq: "\<not> m < (n\<Colon>nat) \<Longrightarrow> m mod n = (m - n) mod n"
   734 by (simp add: le_mod_geq linorder_not_less)
   735 
   736 lemma mod_if: "m mod (n\<Colon>nat) = (if m < n then m else (m - n) mod n)"
   737 by (simp add: le_mod_geq)
   738 
   739 lemma mod_1 [simp]: "m mod Suc 0 = 0"
   740 by (induct m) (simp_all add: mod_geq)
   741 
   742 lemma mod_mult_distrib: "(m mod n) * (k\<Colon>nat) = (m * k) mod (n * k)"
   743   apply (cases "n = 0", simp)
   744   apply (cases "k = 0", simp)
   745   apply (induct m rule: nat_less_induct)
   746   apply (subst mod_if, simp)
   747   apply (simp add: mod_geq diff_mult_distrib)
   748   done
   749 
   750 lemma mod_mult_distrib2: "(k::nat) * (m mod n) = (k*m) mod (k*n)"
   751 by (simp add: mult_commute [of k] mod_mult_distrib)
   752 
   753 (* a simple rearrangement of mod_div_equality: *)
   754 lemma mult_div_cancel: "(n::nat) * (m div n) = m - (m mod n)"
   755 by (cut_tac a = m and b = n in mod_div_equality2, arith)
   756 
   757 lemma mod_le_divisor[simp]: "0 < n \<Longrightarrow> m mod n \<le> (n::nat)"
   758   apply (drule mod_less_divisor [where m = m])
   759   apply simp
   760   done
   761 
   762 subsubsection {* Quotient and Remainder *}
   763 
   764 lemma divmod_nat_rel_mult1_eq:
   765   "divmod_nat_rel b c (q, r) \<Longrightarrow> c > 0
   766    \<Longrightarrow> divmod_nat_rel (a * b) c (a * q + a * r div c, a * r mod c)"
   767 by (auto simp add: split_ifs divmod_nat_rel_def algebra_simps)
   768 
   769 lemma div_mult1_eq:
   770   "(a * b) div c = a * (b div c) + a * (b mod c) div (c::nat)"
   771 apply (cases "c = 0", simp)
   772 apply (blast intro: divmod_nat_rel [THEN divmod_nat_rel_mult1_eq, THEN div_eq])
   773 done
   774 
   775 lemma divmod_nat_rel_add1_eq:
   776   "divmod_nat_rel a c (aq, ar) \<Longrightarrow> divmod_nat_rel b c (bq, br) \<Longrightarrow>  c > 0
   777    \<Longrightarrow> divmod_nat_rel (a + b) c (aq + bq + (ar + br) div c, (ar + br) mod c)"
   778 by (auto simp add: split_ifs divmod_nat_rel_def algebra_simps)
   779 
   780 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
   781 lemma div_add1_eq:
   782   "(a+b) div (c::nat) = a div c + b div c + ((a mod c + b mod c) div c)"
   783 apply (cases "c = 0", simp)
   784 apply (blast intro: divmod_nat_rel_add1_eq [THEN div_eq] divmod_nat_rel)
   785 done
   786 
   787 lemma mod_lemma: "[| (0::nat) < c; r < b |] ==> b * (q mod c) + r < b * c"
   788   apply (cut_tac m = q and n = c in mod_less_divisor)
   789   apply (drule_tac [2] m = "q mod c" in less_imp_Suc_add, auto)
   790   apply (erule_tac P = "%x. ?lhs < ?rhs x" in ssubst)
   791   apply (simp add: add_mult_distrib2)
   792   done
   793 
   794 lemma divmod_nat_rel_mult2_eq:
   795   "divmod_nat_rel a b (q, r) \<Longrightarrow> 0 < b \<Longrightarrow> 0 < c
   796    \<Longrightarrow> divmod_nat_rel a (b * c) (q div c, b *(q mod c) + r)"
   797 by (auto simp add: mult_ac divmod_nat_rel_def add_mult_distrib2 [symmetric] mod_lemma)
   798 
   799 lemma div_mult2_eq: "a div (b*c) = (a div b) div (c::nat)"
   800   apply (cases "b = 0", simp)
   801   apply (cases "c = 0", simp)
   802   apply (force simp add: divmod_nat_rel [THEN divmod_nat_rel_mult2_eq, THEN div_eq])
   803   done
   804 
   805 lemma mod_mult2_eq: "a mod (b*c) = b*(a div b mod c) + a mod (b::nat)"
   806   apply (cases "b = 0", simp)
   807   apply (cases "c = 0", simp)
   808   apply (auto simp add: mult_commute divmod_nat_rel [THEN divmod_nat_rel_mult2_eq, THEN mod_eq])
   809   done
   810 
   811 
   812 subsubsection{*Further Facts about Quotient and Remainder*}
   813 
   814 lemma div_1 [simp]: "m div Suc 0 = m"
   815 by (induct m) (simp_all add: div_geq)
   816 
   817 
   818 (* Monotonicity of div in first argument *)
   819 lemma div_le_mono [rule_format (no_asm)]:
   820     "\<forall>m::nat. m \<le> n --> (m div k) \<le> (n div k)"
   821 apply (case_tac "k=0", simp)
   822 apply (induct "n" rule: nat_less_induct, clarify)
   823 apply (case_tac "n<k")
   824 (* 1  case n<k *)
   825 apply simp
   826 (* 2  case n >= k *)
   827 apply (case_tac "m<k")
   828 (* 2.1  case m<k *)
   829 apply simp
   830 (* 2.2  case m>=k *)
   831 apply (simp add: div_geq diff_le_mono)
   832 done
   833 
   834 (* Antimonotonicity of div in second argument *)
   835 lemma div_le_mono2: "!!m::nat. [| 0<m; m\<le>n |] ==> (k div n) \<le> (k div m)"
   836 apply (subgoal_tac "0<n")
   837  prefer 2 apply simp
   838 apply (induct_tac k rule: nat_less_induct)
   839 apply (rename_tac "k")
   840 apply (case_tac "k<n", simp)
   841 apply (subgoal_tac "~ (k<m) ")
   842  prefer 2 apply simp
   843 apply (simp add: div_geq)
   844 apply (subgoal_tac "(k-n) div n \<le> (k-m) div n")
   845  prefer 2
   846  apply (blast intro: div_le_mono diff_le_mono2)
   847 apply (rule le_trans, simp)
   848 apply (simp)
   849 done
   850 
   851 lemma div_le_dividend [simp]: "m div n \<le> (m::nat)"
   852 apply (case_tac "n=0", simp)
   853 apply (subgoal_tac "m div n \<le> m div 1", simp)
   854 apply (rule div_le_mono2)
   855 apply (simp_all (no_asm_simp))
   856 done
   857 
   858 (* Similar for "less than" *)
   859 lemma div_less_dividend [rule_format]:
   860      "!!n::nat. 1<n ==> 0 < m --> m div n < m"
   861 apply (induct_tac m rule: nat_less_induct)
   862 apply (rename_tac "m")
   863 apply (case_tac "m<n", simp)
   864 apply (subgoal_tac "0<n")
   865  prefer 2 apply simp
   866 apply (simp add: div_geq)
   867 apply (case_tac "n<m")
   868  apply (subgoal_tac "(m-n) div n < (m-n) ")
   869   apply (rule impI less_trans_Suc)+
   870 apply assumption
   871   apply (simp_all)
   872 done
   873 
   874 declare div_less_dividend [simp]
   875 
   876 text{*A fact for the mutilated chess board*}
   877 lemma mod_Suc: "Suc(m) mod n = (if Suc(m mod n) = n then 0 else Suc(m mod n))"
   878 apply (case_tac "n=0", simp)
   879 apply (induct "m" rule: nat_less_induct)
   880 apply (case_tac "Suc (na) <n")
   881 (* case Suc(na) < n *)
   882 apply (frule lessI [THEN less_trans], simp add: less_not_refl3)
   883 (* case n \<le> Suc(na) *)
   884 apply (simp add: linorder_not_less le_Suc_eq mod_geq)
   885 apply (auto simp add: Suc_diff_le le_mod_geq)
   886 done
   887 
   888 lemma mod_eq_0_iff: "(m mod d = 0) = (\<exists>q::nat. m = d*q)"
   889 by (auto simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
   890 
   891 lemmas mod_eq_0D [dest!] = mod_eq_0_iff [THEN iffD1]
   892 
   893 (*Loses information, namely we also have r<d provided d is nonzero*)
   894 lemma mod_eqD: "(m mod d = r) ==> \<exists>q::nat. m = r + q*d"
   895   apply (cut_tac a = m in mod_div_equality)
   896   apply (simp only: add_ac)
   897   apply (blast intro: sym)
   898   done
   899 
   900 lemma split_div:
   901  "P(n div k :: nat) =
   902  ((k = 0 \<longrightarrow> P 0) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P i)))"
   903  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   904 proof
   905   assume P: ?P
   906   show ?Q
   907   proof (cases)
   908     assume "k = 0"
   909     with P show ?Q by simp
   910   next
   911     assume not0: "k \<noteq> 0"
   912     thus ?Q
   913     proof (simp, intro allI impI)
   914       fix i j
   915       assume n: "n = k*i + j" and j: "j < k"
   916       show "P i"
   917       proof (cases)
   918         assume "i = 0"
   919         with n j P show "P i" by simp
   920       next
   921         assume "i \<noteq> 0"
   922         with not0 n j P show "P i" by(simp add:add_ac)
   923       qed
   924     qed
   925   qed
   926 next
   927   assume Q: ?Q
   928   show ?P
   929   proof (cases)
   930     assume "k = 0"
   931     with Q show ?P by simp
   932   next
   933     assume not0: "k \<noteq> 0"
   934     with Q have R: ?R by simp
   935     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   936     show ?P by simp
   937   qed
   938 qed
   939 
   940 lemma split_div_lemma:
   941   assumes "0 < n"
   942   shows "n * q \<le> m \<and> m < n * Suc q \<longleftrightarrow> q = ((m\<Colon>nat) div n)" (is "?lhs \<longleftrightarrow> ?rhs")
   943 proof
   944   assume ?rhs
   945   with mult_div_cancel have nq: "n * q = m - (m mod n)" by simp
   946   then have A: "n * q \<le> m" by simp
   947   have "n - (m mod n) > 0" using mod_less_divisor assms by auto
   948   then have "m < m + (n - (m mod n))" by simp
   949   then have "m < n + (m - (m mod n))" by simp
   950   with nq have "m < n + n * q" by simp
   951   then have B: "m < n * Suc q" by simp
   952   from A B show ?lhs ..
   953 next
   954   assume P: ?lhs
   955   then have "divmod_nat_rel m n (q, m - n * q)"
   956     unfolding divmod_nat_rel_def by (auto simp add: mult_ac)
   957   with divmod_nat_rel_unique divmod_nat_rel [of m n]
   958   have "(q, m - n * q) = (m div n, m mod n)" by auto
   959   then show ?rhs by simp
   960 qed
   961 
   962 theorem split_div':
   963   "P ((m::nat) div n) = ((n = 0 \<and> P 0) \<or>
   964    (\<exists>q. (n * q \<le> m \<and> m < n * (Suc q)) \<and> P q))"
   965   apply (case_tac "0 < n")
   966   apply (simp only: add: split_div_lemma)
   967   apply simp_all
   968   done
   969 
   970 lemma split_mod:
   971  "P(n mod k :: nat) =
   972  ((k = 0 \<longrightarrow> P n) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P j)))"
   973  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   974 proof
   975   assume P: ?P
   976   show ?Q
   977   proof (cases)
   978     assume "k = 0"
   979     with P show ?Q by simp
   980   next
   981     assume not0: "k \<noteq> 0"
   982     thus ?Q
   983     proof (simp, intro allI impI)
   984       fix i j
   985       assume "n = k*i + j" "j < k"
   986       thus "P j" using not0 P by(simp add:add_ac mult_ac)
   987     qed
   988   qed
   989 next
   990   assume Q: ?Q
   991   show ?P
   992   proof (cases)
   993     assume "k = 0"
   994     with Q show ?P by simp
   995   next
   996     assume not0: "k \<noteq> 0"
   997     with Q have R: ?R by simp
   998     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   999     show ?P by simp
  1000   qed
  1001 qed
  1002 
  1003 theorem mod_div_equality': "(m::nat) mod n = m - (m div n) * n"
  1004   apply (rule_tac P="%x. m mod n = x - (m div n) * n" in
  1005     subst [OF mod_div_equality [of _ n]])
  1006   apply arith
  1007   done
  1008 
  1009 lemma div_mod_equality':
  1010   fixes m n :: nat
  1011   shows "m div n * n = m - m mod n"
  1012 proof -
  1013   have "m mod n \<le> m mod n" ..
  1014   from div_mod_equality have 
  1015     "m div n * n + m mod n - m mod n = m - m mod n" by simp
  1016   with diff_add_assoc [OF `m mod n \<le> m mod n`, of "m div n * n"] have
  1017     "m div n * n + (m mod n - m mod n) = m - m mod n"
  1018     by simp
  1019   then show ?thesis by simp
  1020 qed
  1021 
  1022 
  1023 subsubsection {*An ``induction'' law for modulus arithmetic.*}
  1024 
  1025 lemma mod_induct_0:
  1026   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
  1027   and base: "P i" and i: "i<p"
  1028   shows "P 0"
  1029 proof (rule ccontr)
  1030   assume contra: "\<not>(P 0)"
  1031   from i have p: "0<p" by simp
  1032   have "\<forall>k. 0<k \<longrightarrow> \<not> P (p-k)" (is "\<forall>k. ?A k")
  1033   proof
  1034     fix k
  1035     show "?A k"
  1036     proof (induct k)
  1037       show "?A 0" by simp  -- "by contradiction"
  1038     next
  1039       fix n
  1040       assume ih: "?A n"
  1041       show "?A (Suc n)"
  1042       proof (clarsimp)
  1043         assume y: "P (p - Suc n)"
  1044         have n: "Suc n < p"
  1045         proof (rule ccontr)
  1046           assume "\<not>(Suc n < p)"
  1047           hence "p - Suc n = 0"
  1048             by simp
  1049           with y contra show "False"
  1050             by simp
  1051         qed
  1052         hence n2: "Suc (p - Suc n) = p-n" by arith
  1053         from p have "p - Suc n < p" by arith
  1054         with y step have z: "P ((Suc (p - Suc n)) mod p)"
  1055           by blast
  1056         show "False"
  1057         proof (cases "n=0")
  1058           case True
  1059           with z n2 contra show ?thesis by simp
  1060         next
  1061           case False
  1062           with p have "p-n < p" by arith
  1063           with z n2 False ih show ?thesis by simp
  1064         qed
  1065       qed
  1066     qed
  1067   qed
  1068   moreover
  1069   from i obtain k where "0<k \<and> i+k=p"
  1070     by (blast dest: less_imp_add_positive)
  1071   hence "0<k \<and> i=p-k" by auto
  1072   moreover
  1073   note base
  1074   ultimately
  1075   show "False" by blast
  1076 qed
  1077 
  1078 lemma mod_induct:
  1079   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
  1080   and base: "P i" and i: "i<p" and j: "j<p"
  1081   shows "P j"
  1082 proof -
  1083   have "\<forall>j<p. P j"
  1084   proof
  1085     fix j
  1086     show "j<p \<longrightarrow> P j" (is "?A j")
  1087     proof (induct j)
  1088       from step base i show "?A 0"
  1089         by (auto elim: mod_induct_0)
  1090     next
  1091       fix k
  1092       assume ih: "?A k"
  1093       show "?A (Suc k)"
  1094       proof
  1095         assume suc: "Suc k < p"
  1096         hence k: "k<p" by simp
  1097         with ih have "P k" ..
  1098         with step k have "P (Suc k mod p)"
  1099           by blast
  1100         moreover
  1101         from suc have "Suc k mod p = Suc k"
  1102           by simp
  1103         ultimately
  1104         show "P (Suc k)" by simp
  1105       qed
  1106     qed
  1107   qed
  1108   with j show ?thesis by blast
  1109 qed
  1110 
  1111 lemma div2_Suc_Suc [simp]: "Suc (Suc m) div 2 = Suc (m div 2)"
  1112 by (auto simp add: numeral_2_eq_2 le_div_geq)
  1113 
  1114 lemma add_self_div_2 [simp]: "(m + m) div 2 = (m::nat)"
  1115 by (simp add: nat_mult_2 [symmetric])
  1116 
  1117 lemma mod2_Suc_Suc [simp]: "Suc(Suc(m)) mod 2 = m mod 2"
  1118 apply (subgoal_tac "m mod 2 < 2")
  1119 apply (erule less_2_cases [THEN disjE])
  1120 apply (simp_all (no_asm_simp) add: Let_def mod_Suc)
  1121 done
  1122 
  1123 lemma mod2_gr_0 [simp]: "0 < (m\<Colon>nat) mod 2 \<longleftrightarrow> m mod 2 = 1"
  1124 proof -
  1125   { fix n :: nat have  "(n::nat) < 2 \<Longrightarrow> n = 0 \<or> n = 1" by (induct n) simp_all }
  1126   moreover have "m mod 2 < 2" by simp
  1127   ultimately have "m mod 2 = 0 \<or> m mod 2 = 1" .
  1128   then show ?thesis by auto
  1129 qed
  1130 
  1131 text{*These lemmas collapse some needless occurrences of Suc:
  1132     at least three Sucs, since two and fewer are rewritten back to Suc again!
  1133     We already have some rules to simplify operands smaller than 3.*}
  1134 
  1135 lemma div_Suc_eq_div_add3 [simp]: "m div (Suc (Suc (Suc n))) = m div (3+n)"
  1136 by (simp add: Suc3_eq_add_3)
  1137 
  1138 lemma mod_Suc_eq_mod_add3 [simp]: "m mod (Suc (Suc (Suc n))) = m mod (3+n)"
  1139 by (simp add: Suc3_eq_add_3)
  1140 
  1141 lemma Suc_div_eq_add3_div: "(Suc (Suc (Suc m))) div n = (3+m) div n"
  1142 by (simp add: Suc3_eq_add_3)
  1143 
  1144 lemma Suc_mod_eq_add3_mod: "(Suc (Suc (Suc m))) mod n = (3+m) mod n"
  1145 by (simp add: Suc3_eq_add_3)
  1146 
  1147 lemmas Suc_div_eq_add3_div_number_of =
  1148     Suc_div_eq_add3_div [of _ "number_of v", standard]
  1149 declare Suc_div_eq_add3_div_number_of [simp]
  1150 
  1151 lemmas Suc_mod_eq_add3_mod_number_of =
  1152     Suc_mod_eq_add3_mod [of _ "number_of v", standard]
  1153 declare Suc_mod_eq_add3_mod_number_of [simp]
  1154 
  1155 
  1156 lemma Suc_times_mod_eq: "1<k ==> Suc (k * m) mod k = 1" 
  1157 apply (induct "m")
  1158 apply (simp_all add: mod_Suc)
  1159 done
  1160 
  1161 declare Suc_times_mod_eq [of "number_of w", standard, simp]
  1162 
  1163 lemma [simp]: "n div k \<le> (Suc n) div k"
  1164 by (simp add: div_le_mono) 
  1165 
  1166 lemma Suc_n_div_2_gt_zero [simp]: "(0::nat) < n ==> 0 < (n + 1) div 2"
  1167 by (cases n) simp_all
  1168 
  1169 lemma div_2_gt_zero [simp]: "(1::nat) < n ==> 0 < n div 2" 
  1170 using Suc_n_div_2_gt_zero [of "n - 1"] by simp
  1171 
  1172   (* Potential use of algebra : Equality modulo n*)
  1173 lemma mod_mult_self3 [simp]: "(k*n + m) mod n = m mod (n::nat)"
  1174 by (simp add: mult_ac add_ac)
  1175 
  1176 lemma mod_mult_self4 [simp]: "Suc (k*n + m) mod n = Suc m mod n"
  1177 proof -
  1178   have "Suc (k * n + m) mod n = (k * n + Suc m) mod n" by simp
  1179   also have "... = Suc m mod n" by (rule mod_mult_self3) 
  1180   finally show ?thesis .
  1181 qed
  1182 
  1183 lemma mod_Suc_eq_Suc_mod: "Suc m mod n = Suc (m mod n) mod n"
  1184 apply (subst mod_Suc [of m]) 
  1185 apply (subst mod_Suc [of "m mod n"], simp) 
  1186 done
  1187 
  1188 
  1189 subsection {* Division on @{typ int} *}
  1190 
  1191 definition divmod_int_rel :: "int \<Rightarrow> int \<Rightarrow> int \<times> int \<Rightarrow> bool" where
  1192     --{*definition of quotient and remainder*}
  1193     [code]: "divmod_int_rel a b = (\<lambda>(q, r). a = b * q + r \<and>
  1194                (if 0 < b then 0 \<le> r \<and> r < b else b < r \<and> r \<le> 0))"
  1195 
  1196 definition adjust :: "int \<Rightarrow> int \<times> int \<Rightarrow> int \<times> int" where
  1197     --{*for the division algorithm*}
  1198     [code]: "adjust b = (\<lambda>(q, r). if 0 \<le> r - b then (2 * q + 1, r - b)
  1199                          else (2 * q, r))"
  1200 
  1201 text{*algorithm for the case @{text "a\<ge>0, b>0"}*}
  1202 function posDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1203   "posDivAlg a b = (if a < b \<or>  b \<le> 0 then (0, a)
  1204      else adjust b (posDivAlg a (2 * b)))"
  1205 by auto
  1206 termination by (relation "measure (\<lambda>(a, b). nat (a - b + 1))")
  1207   (auto simp add: mult_2)
  1208 
  1209 text{*algorithm for the case @{text "a<0, b>0"}*}
  1210 function negDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1211   "negDivAlg a b = (if 0 \<le>a + b \<or> b \<le> 0  then (-1, a + b)
  1212      else adjust b (negDivAlg a (2 * b)))"
  1213 by auto
  1214 termination by (relation "measure (\<lambda>(a, b). nat (- a - b))")
  1215   (auto simp add: mult_2)
  1216 
  1217 text{*algorithm for the general case @{term "b\<noteq>0"}*}
  1218 definition negateSnd :: "int \<times> int \<Rightarrow> int \<times> int" where
  1219   [code_unfold]: "negateSnd = apsnd uminus"
  1220 
  1221 definition divmod_int :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1222     --{*The full division algorithm considers all possible signs for a, b
  1223        including the special case @{text "a=0, b<0"} because 
  1224        @{term negDivAlg} requires @{term "a<0"}.*}
  1225   "divmod_int a b = (if 0 \<le> a then if 0 \<le> b then posDivAlg a b
  1226                   else if a = 0 then (0, 0)
  1227                        else negateSnd (negDivAlg (-a) (-b))
  1228                else 
  1229                   if 0 < b then negDivAlg a b
  1230                   else negateSnd (posDivAlg (-a) (-b)))"
  1231 
  1232 instantiation int :: Divides.div
  1233 begin
  1234 
  1235 definition
  1236   "a div b = fst (divmod_int a b)"
  1237 
  1238 definition
  1239  "a mod b = snd (divmod_int a b)"
  1240 
  1241 instance ..
  1242 
  1243 end
  1244 
  1245 lemma divmod_int_mod_div:
  1246   "divmod_int p q = (p div q, p mod q)"
  1247   by (auto simp add: div_int_def mod_int_def)
  1248 
  1249 text{*
  1250 Here is the division algorithm in ML:
  1251 
  1252 \begin{verbatim}
  1253     fun posDivAlg (a,b) =
  1254       if a<b then (0,a)
  1255       else let val (q,r) = posDivAlg(a, 2*b)
  1256                in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
  1257            end
  1258 
  1259     fun negDivAlg (a,b) =
  1260       if 0\<le>a+b then (~1,a+b)
  1261       else let val (q,r) = negDivAlg(a, 2*b)
  1262                in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
  1263            end;
  1264 
  1265     fun negateSnd (q,r:int) = (q,~r);
  1266 
  1267     fun divmod (a,b) = if 0\<le>a then 
  1268                           if b>0 then posDivAlg (a,b) 
  1269                            else if a=0 then (0,0)
  1270                                 else negateSnd (negDivAlg (~a,~b))
  1271                        else 
  1272                           if 0<b then negDivAlg (a,b)
  1273                           else        negateSnd (posDivAlg (~a,~b));
  1274 \end{verbatim}
  1275 *}
  1276 
  1277 
  1278 
  1279 subsubsection{*Uniqueness and Monotonicity of Quotients and Remainders*}
  1280 
  1281 lemma unique_quotient_lemma:
  1282      "[| b*q' + r'  \<le> b*q + r;  0 \<le> r';  r' < b;  r < b |]  
  1283       ==> q' \<le> (q::int)"
  1284 apply (subgoal_tac "r' + b * (q'-q) \<le> r")
  1285  prefer 2 apply (simp add: right_diff_distrib)
  1286 apply (subgoal_tac "0 < b * (1 + q - q') ")
  1287 apply (erule_tac [2] order_le_less_trans)
  1288  prefer 2 apply (simp add: right_diff_distrib right_distrib)
  1289 apply (subgoal_tac "b * q' < b * (1 + q) ")
  1290  prefer 2 apply (simp add: right_diff_distrib right_distrib)
  1291 apply (simp add: mult_less_cancel_left)
  1292 done
  1293 
  1294 lemma unique_quotient_lemma_neg:
  1295      "[| b*q' + r' \<le> b*q + r;  r \<le> 0;  b < r;  b < r' |]  
  1296       ==> q \<le> (q'::int)"
  1297 by (rule_tac b = "-b" and r = "-r'" and r' = "-r" in unique_quotient_lemma, 
  1298     auto)
  1299 
  1300 lemma unique_quotient:
  1301      "[| divmod_int_rel a b (q, r); divmod_int_rel a b (q', r');  b \<noteq> 0 |]  
  1302       ==> q = q'"
  1303 apply (simp add: divmod_int_rel_def linorder_neq_iff split: split_if_asm)
  1304 apply (blast intro: order_antisym
  1305              dest: order_eq_refl [THEN unique_quotient_lemma] 
  1306              order_eq_refl [THEN unique_quotient_lemma_neg] sym)+
  1307 done
  1308 
  1309 
  1310 lemma unique_remainder:
  1311      "[| divmod_int_rel a b (q, r); divmod_int_rel a b (q', r');  b \<noteq> 0 |]  
  1312       ==> r = r'"
  1313 apply (subgoal_tac "q = q'")
  1314  apply (simp add: divmod_int_rel_def)
  1315 apply (blast intro: unique_quotient)
  1316 done
  1317 
  1318 
  1319 subsubsection{*Correctness of @{term posDivAlg}, the Algorithm for Non-Negative Dividends*}
  1320 
  1321 text{*And positive divisors*}
  1322 
  1323 lemma adjust_eq [simp]:
  1324      "adjust b (q,r) = 
  1325       (let diff = r-b in  
  1326         if 0 \<le> diff then (2*q + 1, diff)   
  1327                      else (2*q, r))"
  1328 by (simp add: Let_def adjust_def)
  1329 
  1330 declare posDivAlg.simps [simp del]
  1331 
  1332 text{*use with a simproc to avoid repeatedly proving the premise*}
  1333 lemma posDivAlg_eqn:
  1334      "0 < b ==>  
  1335       posDivAlg a b = (if a<b then (0,a) else adjust b (posDivAlg a (2*b)))"
  1336 by (rule posDivAlg.simps [THEN trans], simp)
  1337 
  1338 text{*Correctness of @{term posDivAlg}: it computes quotients correctly*}
  1339 theorem posDivAlg_correct:
  1340   assumes "0 \<le> a" and "0 < b"
  1341   shows "divmod_int_rel a b (posDivAlg a b)"
  1342 using prems apply (induct a b rule: posDivAlg.induct)
  1343 apply auto
  1344 apply (simp add: divmod_int_rel_def)
  1345 apply (subst posDivAlg_eqn, simp add: right_distrib)
  1346 apply (case_tac "a < b")
  1347 apply simp_all
  1348 apply (erule splitE)
  1349 apply (auto simp add: right_distrib Let_def mult_ac mult_2_right)
  1350 done
  1351 
  1352 
  1353 subsubsection{*Correctness of @{term negDivAlg}, the Algorithm for Negative Dividends*}
  1354 
  1355 text{*And positive divisors*}
  1356 
  1357 declare negDivAlg.simps [simp del]
  1358 
  1359 text{*use with a simproc to avoid repeatedly proving the premise*}
  1360 lemma negDivAlg_eqn:
  1361      "0 < b ==>  
  1362       negDivAlg a b =       
  1363        (if 0\<le>a+b then (-1,a+b) else adjust b (negDivAlg a (2*b)))"
  1364 by (rule negDivAlg.simps [THEN trans], simp)
  1365 
  1366 (*Correctness of negDivAlg: it computes quotients correctly
  1367   It doesn't work if a=0 because the 0/b equals 0, not -1*)
  1368 lemma negDivAlg_correct:
  1369   assumes "a < 0" and "b > 0"
  1370   shows "divmod_int_rel a b (negDivAlg a b)"
  1371 using prems apply (induct a b rule: negDivAlg.induct)
  1372 apply (auto simp add: linorder_not_le)
  1373 apply (simp add: divmod_int_rel_def)
  1374 apply (subst negDivAlg_eqn, assumption)
  1375 apply (case_tac "a + b < (0\<Colon>int)")
  1376 apply simp_all
  1377 apply (erule splitE)
  1378 apply (auto simp add: right_distrib Let_def mult_ac mult_2_right)
  1379 done
  1380 
  1381 
  1382 subsubsection{*Existence Shown by Proving the Division Algorithm to be Correct*}
  1383 
  1384 (*the case a=0*)
  1385 lemma divmod_int_rel_0: "b \<noteq> 0 ==> divmod_int_rel 0 b (0, 0)"
  1386 by (auto simp add: divmod_int_rel_def linorder_neq_iff)
  1387 
  1388 lemma posDivAlg_0 [simp]: "posDivAlg 0 b = (0, 0)"
  1389 by (subst posDivAlg.simps, auto)
  1390 
  1391 lemma negDivAlg_minus1 [simp]: "negDivAlg -1 b = (-1, b - 1)"
  1392 by (subst negDivAlg.simps, auto)
  1393 
  1394 lemma negateSnd_eq [simp]: "negateSnd(q,r) = (q,-r)"
  1395 by (simp add: negateSnd_def)
  1396 
  1397 lemma divmod_int_rel_neg: "divmod_int_rel (-a) (-b) qr ==> divmod_int_rel a b (negateSnd qr)"
  1398 by (auto simp add: split_ifs divmod_int_rel_def)
  1399 
  1400 lemma divmod_int_correct: "b \<noteq> 0 ==> divmod_int_rel a b (divmod_int a b)"
  1401 by (force simp add: linorder_neq_iff divmod_int_rel_0 divmod_int_def divmod_int_rel_neg
  1402                     posDivAlg_correct negDivAlg_correct)
  1403 
  1404 text{*Arbitrary definitions for division by zero.  Useful to simplify 
  1405     certain equations.*}
  1406 
  1407 lemma DIVISION_BY_ZERO [simp]: "a div (0::int) = 0 & a mod (0::int) = a"
  1408 by (simp add: div_int_def mod_int_def divmod_int_def posDivAlg.simps)  
  1409 
  1410 
  1411 text{*Basic laws about division and remainder*}
  1412 
  1413 lemma zmod_zdiv_equality: "(a::int) = b * (a div b) + (a mod b)"
  1414 apply (case_tac "b = 0", simp)
  1415 apply (cut_tac a = a and b = b in divmod_int_correct)
  1416 apply (auto simp add: divmod_int_rel_def div_int_def mod_int_def)
  1417 done
  1418 
  1419 lemma zdiv_zmod_equality: "(b * (a div b) + (a mod b)) + k = (a::int)+k"
  1420 by(simp add: zmod_zdiv_equality[symmetric])
  1421 
  1422 lemma zdiv_zmod_equality2: "((a div b) * b + (a mod b)) + k = (a::int)+k"
  1423 by(simp add: mult_commute zmod_zdiv_equality[symmetric])
  1424 
  1425 text {* Tool setup *}
  1426 
  1427 ML {*
  1428 local
  1429 
  1430 structure CancelDivMod = CancelDivModFun(struct
  1431 
  1432   val div_name = @{const_name div};
  1433   val mod_name = @{const_name mod};
  1434   val mk_binop = HOLogic.mk_binop;
  1435   val mk_sum = Arith_Data.mk_sum HOLogic.intT;
  1436   val dest_sum = Arith_Data.dest_sum;
  1437 
  1438   val div_mod_eqs = map mk_meta_eq [@{thm zdiv_zmod_equality}, @{thm zdiv_zmod_equality2}];
  1439 
  1440   val trans = trans;
  1441 
  1442   val prove_eq_sums = Arith_Data.prove_conv2 all_tac (Arith_Data.simp_all_tac 
  1443     (@{thm diff_minus} :: @{thms add_0s} @ @{thms add_ac}))
  1444 
  1445 end)
  1446 
  1447 in
  1448 
  1449 val cancel_div_mod_int_proc = Simplifier.simproc @{theory}
  1450   "cancel_zdiv_zmod" ["(k::int) + l"] (K CancelDivMod.proc);
  1451 
  1452 val _ = Addsimprocs [cancel_div_mod_int_proc];
  1453 
  1454 end
  1455 *}
  1456 
  1457 lemma pos_mod_conj : "(0::int) < b ==> 0 \<le> a mod b & a mod b < b"
  1458 apply (cut_tac a = a and b = b in divmod_int_correct)
  1459 apply (auto simp add: divmod_int_rel_def mod_int_def)
  1460 done
  1461 
  1462 lemmas pos_mod_sign  [simp] = pos_mod_conj [THEN conjunct1, standard]
  1463    and pos_mod_bound [simp] = pos_mod_conj [THEN conjunct2, standard]
  1464 
  1465 lemma neg_mod_conj : "b < (0::int) ==> a mod b \<le> 0 & b < a mod b"
  1466 apply (cut_tac a = a and b = b in divmod_int_correct)
  1467 apply (auto simp add: divmod_int_rel_def div_int_def mod_int_def)
  1468 done
  1469 
  1470 lemmas neg_mod_sign  [simp] = neg_mod_conj [THEN conjunct1, standard]
  1471    and neg_mod_bound [simp] = neg_mod_conj [THEN conjunct2, standard]
  1472 
  1473 
  1474 
  1475 subsubsection{*General Properties of div and mod*}
  1476 
  1477 lemma divmod_int_rel_div_mod: "b \<noteq> 0 ==> divmod_int_rel a b (a div b, a mod b)"
  1478 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1479 apply (force simp add: divmod_int_rel_def linorder_neq_iff)
  1480 done
  1481 
  1482 lemma divmod_int_rel_div: "[| divmod_int_rel a b (q, r);  b \<noteq> 0 |] ==> a div b = q"
  1483 by (simp add: divmod_int_rel_div_mod [THEN unique_quotient])
  1484 
  1485 lemma divmod_int_rel_mod: "[| divmod_int_rel a b (q, r);  b \<noteq> 0 |] ==> a mod b = r"
  1486 by (simp add: divmod_int_rel_div_mod [THEN unique_remainder])
  1487 
  1488 lemma div_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a div b = 0"
  1489 apply (rule divmod_int_rel_div)
  1490 apply (auto simp add: divmod_int_rel_def)
  1491 done
  1492 
  1493 lemma div_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a div b = 0"
  1494 apply (rule divmod_int_rel_div)
  1495 apply (auto simp add: divmod_int_rel_def)
  1496 done
  1497 
  1498 lemma div_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a div b = -1"
  1499 apply (rule divmod_int_rel_div)
  1500 apply (auto simp add: divmod_int_rel_def)
  1501 done
  1502 
  1503 (*There is no div_neg_pos_trivial because  0 div b = 0 would supersede it*)
  1504 
  1505 lemma mod_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a mod b = a"
  1506 apply (rule_tac q = 0 in divmod_int_rel_mod)
  1507 apply (auto simp add: divmod_int_rel_def)
  1508 done
  1509 
  1510 lemma mod_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a mod b = a"
  1511 apply (rule_tac q = 0 in divmod_int_rel_mod)
  1512 apply (auto simp add: divmod_int_rel_def)
  1513 done
  1514 
  1515 lemma mod_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a mod b = a+b"
  1516 apply (rule_tac q = "-1" in divmod_int_rel_mod)
  1517 apply (auto simp add: divmod_int_rel_def)
  1518 done
  1519 
  1520 text{*There is no @{text mod_neg_pos_trivial}.*}
  1521 
  1522 
  1523 (*Simpler laws such as -a div b = -(a div b) FAIL, but see just below*)
  1524 lemma zdiv_zminus_zminus [simp]: "(-a) div (-b) = a div (b::int)"
  1525 apply (case_tac "b = 0", simp)
  1526 apply (simp add: divmod_int_rel_div_mod [THEN divmod_int_rel_neg, simplified, 
  1527                                  THEN divmod_int_rel_div, THEN sym])
  1528 
  1529 done
  1530 
  1531 (*Simpler laws such as -a mod b = -(a mod b) FAIL, but see just below*)
  1532 lemma zmod_zminus_zminus [simp]: "(-a) mod (-b) = - (a mod (b::int))"
  1533 apply (case_tac "b = 0", simp)
  1534 apply (subst divmod_int_rel_div_mod [THEN divmod_int_rel_neg, simplified, THEN divmod_int_rel_mod],
  1535        auto)
  1536 done
  1537 
  1538 
  1539 subsubsection{*Laws for div and mod with Unary Minus*}
  1540 
  1541 lemma zminus1_lemma:
  1542      "divmod_int_rel a b (q, r)
  1543       ==> divmod_int_rel (-a) b (if r=0 then -q else -q - 1,  
  1544                           if r=0 then 0 else b-r)"
  1545 by (force simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_diff_distrib)
  1546 
  1547 
  1548 lemma zdiv_zminus1_eq_if:
  1549      "b \<noteq> (0::int)  
  1550       ==> (-a) div b =  
  1551           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
  1552 by (blast intro: divmod_int_rel_div_mod [THEN zminus1_lemma, THEN divmod_int_rel_div])
  1553 
  1554 lemma zmod_zminus1_eq_if:
  1555      "(-a::int) mod b = (if a mod b = 0 then 0 else  b - (a mod b))"
  1556 apply (case_tac "b = 0", simp)
  1557 apply (blast intro: divmod_int_rel_div_mod [THEN zminus1_lemma, THEN divmod_int_rel_mod])
  1558 done
  1559 
  1560 lemma zmod_zminus1_not_zero:
  1561   fixes k l :: int
  1562   shows "- k mod l \<noteq> 0 \<Longrightarrow> k mod l \<noteq> 0"
  1563   unfolding zmod_zminus1_eq_if by auto
  1564 
  1565 lemma zdiv_zminus2: "a div (-b) = (-a::int) div b"
  1566 by (cut_tac a = "-a" in zdiv_zminus_zminus, auto)
  1567 
  1568 lemma zmod_zminus2: "a mod (-b) = - ((-a::int) mod b)"
  1569 by (cut_tac a = "-a" and b = b in zmod_zminus_zminus, auto)
  1570 
  1571 lemma zdiv_zminus2_eq_if:
  1572      "b \<noteq> (0::int)  
  1573       ==> a div (-b) =  
  1574           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
  1575 by (simp add: zdiv_zminus1_eq_if zdiv_zminus2)
  1576 
  1577 lemma zmod_zminus2_eq_if:
  1578      "a mod (-b::int) = (if a mod b = 0 then 0 else  (a mod b) - b)"
  1579 by (simp add: zmod_zminus1_eq_if zmod_zminus2)
  1580 
  1581 lemma zmod_zminus2_not_zero:
  1582   fixes k l :: int
  1583   shows "k mod - l \<noteq> 0 \<Longrightarrow> k mod l \<noteq> 0"
  1584   unfolding zmod_zminus2_eq_if by auto 
  1585 
  1586 
  1587 subsubsection{*Division of a Number by Itself*}
  1588 
  1589 lemma self_quotient_aux1: "[| (0::int) < a; a = r + a*q; r < a |] ==> 1 \<le> q"
  1590 apply (subgoal_tac "0 < a*q")
  1591  apply (simp add: zero_less_mult_iff, arith)
  1592 done
  1593 
  1594 lemma self_quotient_aux2: "[| (0::int) < a; a = r + a*q; 0 \<le> r |] ==> q \<le> 1"
  1595 apply (subgoal_tac "0 \<le> a* (1-q) ")
  1596  apply (simp add: zero_le_mult_iff)
  1597 apply (simp add: right_diff_distrib)
  1598 done
  1599 
  1600 lemma self_quotient: "[| divmod_int_rel a a (q, r);  a \<noteq> (0::int) |] ==> q = 1"
  1601 apply (simp add: split_ifs divmod_int_rel_def linorder_neq_iff)
  1602 apply (rule order_antisym, safe, simp_all)
  1603 apply (rule_tac [3] a = "-a" and r = "-r" in self_quotient_aux1)
  1604 apply (rule_tac a = "-a" and r = "-r" in self_quotient_aux2)
  1605 apply (force intro: self_quotient_aux1 self_quotient_aux2 simp add: add_commute)+
  1606 done
  1607 
  1608 lemma self_remainder: "[| divmod_int_rel a a (q, r);  a \<noteq> (0::int) |] ==> r = 0"
  1609 apply (frule self_quotient, assumption)
  1610 apply (simp add: divmod_int_rel_def)
  1611 done
  1612 
  1613 lemma zdiv_self [simp]: "a \<noteq> 0 ==> a div a = (1::int)"
  1614 by (simp add: divmod_int_rel_div_mod [THEN self_quotient])
  1615 
  1616 (*Here we have 0 mod 0 = 0, also assumed by Knuth (who puts m mod 0 = 0) *)
  1617 lemma zmod_self [simp]: "a mod a = (0::int)"
  1618 apply (case_tac "a = 0", simp)
  1619 apply (simp add: divmod_int_rel_div_mod [THEN self_remainder])
  1620 done
  1621 
  1622 
  1623 subsubsection{*Computation of Division and Remainder*}
  1624 
  1625 lemma zdiv_zero [simp]: "(0::int) div b = 0"
  1626 by (simp add: div_int_def divmod_int_def)
  1627 
  1628 lemma div_eq_minus1: "(0::int) < b ==> -1 div b = -1"
  1629 by (simp add: div_int_def divmod_int_def)
  1630 
  1631 lemma zmod_zero [simp]: "(0::int) mod b = 0"
  1632 by (simp add: mod_int_def divmod_int_def)
  1633 
  1634 lemma zmod_minus1: "(0::int) < b ==> -1 mod b = b - 1"
  1635 by (simp add: mod_int_def divmod_int_def)
  1636 
  1637 text{*a positive, b positive *}
  1638 
  1639 lemma div_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a div b = fst (posDivAlg a b)"
  1640 by (simp add: div_int_def divmod_int_def)
  1641 
  1642 lemma mod_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a mod b = snd (posDivAlg a b)"
  1643 by (simp add: mod_int_def divmod_int_def)
  1644 
  1645 text{*a negative, b positive *}
  1646 
  1647 lemma div_neg_pos: "[| a < 0;  0 < b |] ==> a div b = fst (negDivAlg a b)"
  1648 by (simp add: div_int_def divmod_int_def)
  1649 
  1650 lemma mod_neg_pos: "[| a < 0;  0 < b |] ==> a mod b = snd (negDivAlg a b)"
  1651 by (simp add: mod_int_def divmod_int_def)
  1652 
  1653 text{*a positive, b negative *}
  1654 
  1655 lemma div_pos_neg:
  1656      "[| 0 < a;  b < 0 |] ==> a div b = fst (negateSnd (negDivAlg (-a) (-b)))"
  1657 by (simp add: div_int_def divmod_int_def)
  1658 
  1659 lemma mod_pos_neg:
  1660      "[| 0 < a;  b < 0 |] ==> a mod b = snd (negateSnd (negDivAlg (-a) (-b)))"
  1661 by (simp add: mod_int_def divmod_int_def)
  1662 
  1663 text{*a negative, b negative *}
  1664 
  1665 lemma div_neg_neg:
  1666      "[| a < 0;  b \<le> 0 |] ==> a div b = fst (negateSnd (posDivAlg (-a) (-b)))"
  1667 by (simp add: div_int_def divmod_int_def)
  1668 
  1669 lemma mod_neg_neg:
  1670      "[| a < 0;  b \<le> 0 |] ==> a mod b = snd (negateSnd (posDivAlg (-a) (-b)))"
  1671 by (simp add: mod_int_def divmod_int_def)
  1672 
  1673 text {*Simplify expresions in which div and mod combine numerical constants*}
  1674 
  1675 lemma divmod_int_relI:
  1676   "\<lbrakk>a == b * q + r; if 0 < b then 0 \<le> r \<and> r < b else b < r \<and> r \<le> 0\<rbrakk>
  1677     \<Longrightarrow> divmod_int_rel a b (q, r)"
  1678   unfolding divmod_int_rel_def by simp
  1679 
  1680 lemmas divmod_int_rel_div_eq = divmod_int_relI [THEN divmod_int_rel_div, THEN eq_reflection]
  1681 lemmas divmod_int_rel_mod_eq = divmod_int_relI [THEN divmod_int_rel_mod, THEN eq_reflection]
  1682 lemmas arithmetic_simps =
  1683   arith_simps
  1684   add_special
  1685   add_0_left
  1686   add_0_right
  1687   mult_zero_left
  1688   mult_zero_right
  1689   mult_1_left
  1690   mult_1_right
  1691 
  1692 (* simprocs adapted from HOL/ex/Binary.thy *)
  1693 ML {*
  1694 local
  1695   val mk_number = HOLogic.mk_number HOLogic.intT;
  1696   fun mk_cert u k l = @{term "plus :: int \<Rightarrow> int \<Rightarrow> int"} $
  1697     (@{term "times :: int \<Rightarrow> int \<Rightarrow> int"} $ u $ mk_number k) $
  1698       mk_number l;
  1699   fun prove ctxt prop = Goal.prove ctxt [] [] prop
  1700     (K (ALLGOALS (full_simp_tac (HOL_basic_ss addsimps @{thms arithmetic_simps}))));
  1701   fun binary_proc proc ss ct =
  1702     (case Thm.term_of ct of
  1703       _ $ t $ u =>
  1704       (case try (pairself (`(snd o HOLogic.dest_number))) (t, u) of
  1705         SOME args => proc (Simplifier.the_context ss) args
  1706       | NONE => NONE)
  1707     | _ => NONE);
  1708 in
  1709   fun divmod_proc rule = binary_proc (fn ctxt => fn ((m, t), (n, u)) =>
  1710     if n = 0 then NONE
  1711     else let val (k, l) = Integer.div_mod m n;
  1712     in SOME (rule OF [prove ctxt (Logic.mk_equals (t, mk_cert u k l))]) end);
  1713 end
  1714 *}
  1715 
  1716 simproc_setup binary_int_div ("number_of m div number_of n :: int") =
  1717   {* K (divmod_proc (@{thm divmod_int_rel_div_eq})) *}
  1718 
  1719 simproc_setup binary_int_mod ("number_of m mod number_of n :: int") =
  1720   {* K (divmod_proc (@{thm divmod_int_rel_mod_eq})) *}
  1721 
  1722 lemmas posDivAlg_eqn_number_of [simp] =
  1723     posDivAlg_eqn [of "number_of v" "number_of w", standard]
  1724 
  1725 lemmas negDivAlg_eqn_number_of [simp] =
  1726     negDivAlg_eqn [of "number_of v" "number_of w", standard]
  1727 
  1728 
  1729 text{*Special-case simplification *}
  1730 
  1731 lemma zmod_minus1_right [simp]: "a mod (-1::int) = 0"
  1732 apply (cut_tac a = a and b = "-1" in neg_mod_sign)
  1733 apply (cut_tac [2] a = a and b = "-1" in neg_mod_bound)
  1734 apply (auto simp del: neg_mod_sign neg_mod_bound)
  1735 done
  1736 
  1737 lemma zdiv_minus1_right [simp]: "a div (-1::int) = -a"
  1738 by (cut_tac a = a and b = "-1" in zmod_zdiv_equality, auto)
  1739 
  1740 (** The last remaining special cases for constant arithmetic:
  1741     1 div z and 1 mod z **)
  1742 
  1743 lemmas div_pos_pos_1_number_of [simp] =
  1744     div_pos_pos [OF int_0_less_1, of "number_of w", standard]
  1745 
  1746 lemmas div_pos_neg_1_number_of [simp] =
  1747     div_pos_neg [OF int_0_less_1, of "number_of w", standard]
  1748 
  1749 lemmas mod_pos_pos_1_number_of [simp] =
  1750     mod_pos_pos [OF int_0_less_1, of "number_of w", standard]
  1751 
  1752 lemmas mod_pos_neg_1_number_of [simp] =
  1753     mod_pos_neg [OF int_0_less_1, of "number_of w", standard]
  1754 
  1755 
  1756 lemmas posDivAlg_eqn_1_number_of [simp] =
  1757     posDivAlg_eqn [of concl: 1 "number_of w", standard]
  1758 
  1759 lemmas negDivAlg_eqn_1_number_of [simp] =
  1760     negDivAlg_eqn [of concl: 1 "number_of w", standard]
  1761 
  1762 
  1763 
  1764 subsubsection{*Monotonicity in the First Argument (Dividend)*}
  1765 
  1766 lemma zdiv_mono1: "[| a \<le> a';  0 < (b::int) |] ==> a div b \<le> a' div b"
  1767 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1768 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
  1769 apply (rule unique_quotient_lemma)
  1770 apply (erule subst)
  1771 apply (erule subst, simp_all)
  1772 done
  1773 
  1774 lemma zdiv_mono1_neg: "[| a \<le> a';  (b::int) < 0 |] ==> a' div b \<le> a div b"
  1775 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1776 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
  1777 apply (rule unique_quotient_lemma_neg)
  1778 apply (erule subst)
  1779 apply (erule subst, simp_all)
  1780 done
  1781 
  1782 
  1783 subsubsection{*Monotonicity in the Second Argument (Divisor)*}
  1784 
  1785 lemma q_pos_lemma:
  1786      "[| 0 \<le> b'*q' + r'; r' < b';  0 < b' |] ==> 0 \<le> (q'::int)"
  1787 apply (subgoal_tac "0 < b'* (q' + 1) ")
  1788  apply (simp add: zero_less_mult_iff)
  1789 apply (simp add: right_distrib)
  1790 done
  1791 
  1792 lemma zdiv_mono2_lemma:
  1793      "[| b*q + r = b'*q' + r';  0 \<le> b'*q' + r';   
  1794          r' < b';  0 \<le> r;  0 < b';  b' \<le> b |]   
  1795       ==> q \<le> (q'::int)"
  1796 apply (frule q_pos_lemma, assumption+) 
  1797 apply (subgoal_tac "b*q < b* (q' + 1) ")
  1798  apply (simp add: mult_less_cancel_left)
  1799 apply (subgoal_tac "b*q = r' - r + b'*q'")
  1800  prefer 2 apply simp
  1801 apply (simp (no_asm_simp) add: right_distrib)
  1802 apply (subst add_commute, rule zadd_zless_mono, arith)
  1803 apply (rule mult_right_mono, auto)
  1804 done
  1805 
  1806 lemma zdiv_mono2:
  1807      "[| (0::int) \<le> a;  0 < b';  b' \<le> b |] ==> a div b \<le> a div b'"
  1808 apply (subgoal_tac "b \<noteq> 0")
  1809  prefer 2 apply arith
  1810 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1811 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
  1812 apply (rule zdiv_mono2_lemma)
  1813 apply (erule subst)
  1814 apply (erule subst, simp_all)
  1815 done
  1816 
  1817 lemma q_neg_lemma:
  1818      "[| b'*q' + r' < 0;  0 \<le> r';  0 < b' |] ==> q' \<le> (0::int)"
  1819 apply (subgoal_tac "b'*q' < 0")
  1820  apply (simp add: mult_less_0_iff, arith)
  1821 done
  1822 
  1823 lemma zdiv_mono2_neg_lemma:
  1824      "[| b*q + r = b'*q' + r';  b'*q' + r' < 0;   
  1825          r < b;  0 \<le> r';  0 < b';  b' \<le> b |]   
  1826       ==> q' \<le> (q::int)"
  1827 apply (frule q_neg_lemma, assumption+) 
  1828 apply (subgoal_tac "b*q' < b* (q + 1) ")
  1829  apply (simp add: mult_less_cancel_left)
  1830 apply (simp add: right_distrib)
  1831 apply (subgoal_tac "b*q' \<le> b'*q'")
  1832  prefer 2 apply (simp add: mult_right_mono_neg, arith)
  1833 done
  1834 
  1835 lemma zdiv_mono2_neg:
  1836      "[| a < (0::int);  0 < b';  b' \<le> b |] ==> a div b' \<le> a div b"
  1837 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1838 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
  1839 apply (rule zdiv_mono2_neg_lemma)
  1840 apply (erule subst)
  1841 apply (erule subst, simp_all)
  1842 done
  1843 
  1844 
  1845 subsubsection{*More Algebraic Laws for div and mod*}
  1846 
  1847 text{*proving (a*b) div c = a * (b div c) + a * (b mod c) *}
  1848 
  1849 lemma zmult1_lemma:
  1850      "[| divmod_int_rel b c (q, r);  c \<noteq> 0 |]  
  1851       ==> divmod_int_rel (a * b) c (a*q + a*r div c, a*r mod c)"
  1852 by (auto simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_distrib mult_ac)
  1853 
  1854 lemma zdiv_zmult1_eq: "(a*b) div c = a*(b div c) + a*(b mod c) div (c::int)"
  1855 apply (case_tac "c = 0", simp)
  1856 apply (blast intro: divmod_int_rel_div_mod [THEN zmult1_lemma, THEN divmod_int_rel_div])
  1857 done
  1858 
  1859 lemma zmod_zmult1_eq: "(a*b) mod c = a*(b mod c) mod (c::int)"
  1860 apply (case_tac "c = 0", simp)
  1861 apply (blast intro: divmod_int_rel_div_mod [THEN zmult1_lemma, THEN divmod_int_rel_mod])
  1862 done
  1863 
  1864 lemma zmod_zdiv_trivial: "(a mod b) div b = (0::int)"
  1865 apply (case_tac "b = 0", simp)
  1866 apply (auto simp add: linorder_neq_iff div_pos_pos_trivial div_neg_neg_trivial)
  1867 done
  1868 
  1869 text{*proving (a+b) div c = a div c + b div c + ((a mod c + b mod c) div c) *}
  1870 
  1871 lemma zadd1_lemma:
  1872      "[| divmod_int_rel a c (aq, ar);  divmod_int_rel b c (bq, br);  c \<noteq> 0 |]  
  1873       ==> divmod_int_rel (a+b) c (aq + bq + (ar+br) div c, (ar+br) mod c)"
  1874 by (force simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_distrib)
  1875 
  1876 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
  1877 lemma zdiv_zadd1_eq:
  1878      "(a+b) div (c::int) = a div c + b div c + ((a mod c + b mod c) div c)"
  1879 apply (case_tac "c = 0", simp)
  1880 apply (blast intro: zadd1_lemma [OF divmod_int_rel_div_mod divmod_int_rel_div_mod] divmod_int_rel_div)
  1881 done
  1882 
  1883 instance int :: ring_div
  1884 proof
  1885   fix a b c :: int
  1886   assume not0: "b \<noteq> 0"
  1887   show "(a + c * b) div b = c + a div b"
  1888     unfolding zdiv_zadd1_eq [of a "c * b"] using not0 
  1889       by (simp add: zmod_zmult1_eq zmod_zdiv_trivial zdiv_zmult1_eq)
  1890 next
  1891   fix a b c :: int
  1892   assume "a \<noteq> 0"
  1893   then show "(a * b) div (a * c) = b div c"
  1894   proof (cases "b \<noteq> 0 \<and> c \<noteq> 0")
  1895     case False then show ?thesis by auto
  1896   next
  1897     case True then have "b \<noteq> 0" and "c \<noteq> 0" by auto
  1898     with `a \<noteq> 0`
  1899     have "\<And>q r. divmod_int_rel b c (q, r) \<Longrightarrow> divmod_int_rel (a * b) (a * c) (q, a * r)"
  1900       apply (auto simp add: divmod_int_rel_def) 
  1901       apply (auto simp add: algebra_simps)
  1902       apply (auto simp add: zero_less_mult_iff zero_le_mult_iff mult_le_0_iff mult_commute [of a] mult_less_cancel_right)
  1903       done
  1904     moreover with `c \<noteq> 0` divmod_int_rel_div_mod have "divmod_int_rel b c (b div c, b mod c)" by auto
  1905     ultimately have "divmod_int_rel (a * b) (a * c) (b div c, a * (b mod c))" .
  1906     moreover from  `a \<noteq> 0` `c \<noteq> 0` have "a * c \<noteq> 0" by simp
  1907     ultimately show ?thesis by (rule divmod_int_rel_div)
  1908   qed
  1909 qed auto
  1910 
  1911 lemma posDivAlg_div_mod:
  1912   assumes "k \<ge> 0"
  1913   and "l \<ge> 0"
  1914   shows "posDivAlg k l = (k div l, k mod l)"
  1915 proof (cases "l = 0")
  1916   case True then show ?thesis by (simp add: posDivAlg.simps)
  1917 next
  1918   case False with assms posDivAlg_correct
  1919     have "divmod_int_rel k l (fst (posDivAlg k l), snd (posDivAlg k l))"
  1920     by simp
  1921   from divmod_int_rel_div [OF this `l \<noteq> 0`] divmod_int_rel_mod [OF this `l \<noteq> 0`]
  1922   show ?thesis by simp
  1923 qed
  1924 
  1925 lemma negDivAlg_div_mod:
  1926   assumes "k < 0"
  1927   and "l > 0"
  1928   shows "negDivAlg k l = (k div l, k mod l)"
  1929 proof -
  1930   from assms have "l \<noteq> 0" by simp
  1931   from assms negDivAlg_correct
  1932     have "divmod_int_rel k l (fst (negDivAlg k l), snd (negDivAlg k l))"
  1933     by simp
  1934   from divmod_int_rel_div [OF this `l \<noteq> 0`] divmod_int_rel_mod [OF this `l \<noteq> 0`]
  1935   show ?thesis by simp
  1936 qed
  1937 
  1938 lemma zmod_eq_0_iff: "(m mod d = 0) = (EX q::int. m = d*q)"
  1939 by (simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
  1940 
  1941 (* REVISIT: should this be generalized to all semiring_div types? *)
  1942 lemmas zmod_eq_0D [dest!] = zmod_eq_0_iff [THEN iffD1]
  1943 
  1944 
  1945 subsubsection{*Proving  @{term "a div (b*c) = (a div b) div c"} *}
  1946 
  1947 (*The condition c>0 seems necessary.  Consider that 7 div ~6 = ~2 but
  1948   7 div 2 div ~3 = 3 div ~3 = ~1.  The subcase (a div b) mod c = 0 seems
  1949   to cause particular problems.*)
  1950 
  1951 text{*first, four lemmas to bound the remainder for the cases b<0 and b>0 *}
  1952 
  1953 lemma zmult2_lemma_aux1: "[| (0::int) < c;  b < r;  r \<le> 0 |] ==> b*c < b*(q mod c) + r"
  1954 apply (subgoal_tac "b * (c - q mod c) < r * 1")
  1955  apply (simp add: algebra_simps)
  1956 apply (rule order_le_less_trans)
  1957  apply (erule_tac [2] mult_strict_right_mono)
  1958  apply (rule mult_left_mono_neg)
  1959   using add1_zle_eq[of "q mod c"]apply(simp add: algebra_simps)
  1960  apply (simp)
  1961 apply (simp)
  1962 done
  1963 
  1964 lemma zmult2_lemma_aux2:
  1965      "[| (0::int) < c;   b < r;  r \<le> 0 |] ==> b * (q mod c) + r \<le> 0"
  1966 apply (subgoal_tac "b * (q mod c) \<le> 0")
  1967  apply arith
  1968 apply (simp add: mult_le_0_iff)
  1969 done
  1970 
  1971 lemma zmult2_lemma_aux3: "[| (0::int) < c;  0 \<le> r;  r < b |] ==> 0 \<le> b * (q mod c) + r"
  1972 apply (subgoal_tac "0 \<le> b * (q mod c) ")
  1973 apply arith
  1974 apply (simp add: zero_le_mult_iff)
  1975 done
  1976 
  1977 lemma zmult2_lemma_aux4: "[| (0::int) < c; 0 \<le> r; r < b |] ==> b * (q mod c) + r < b * c"
  1978 apply (subgoal_tac "r * 1 < b * (c - q mod c) ")
  1979  apply (simp add: right_diff_distrib)
  1980 apply (rule order_less_le_trans)
  1981  apply (erule mult_strict_right_mono)
  1982  apply (rule_tac [2] mult_left_mono)
  1983   apply simp
  1984  using add1_zle_eq[of "q mod c"] apply (simp add: algebra_simps)
  1985 apply simp
  1986 done
  1987 
  1988 lemma zmult2_lemma: "[| divmod_int_rel a b (q, r);  b \<noteq> 0;  0 < c |]  
  1989       ==> divmod_int_rel a (b * c) (q div c, b*(q mod c) + r)"
  1990 by (auto simp add: mult_ac divmod_int_rel_def linorder_neq_iff
  1991                    zero_less_mult_iff right_distrib [symmetric] 
  1992                    zmult2_lemma_aux1 zmult2_lemma_aux2 zmult2_lemma_aux3 zmult2_lemma_aux4)
  1993 
  1994 lemma zdiv_zmult2_eq: "(0::int) < c ==> a div (b*c) = (a div b) div c"
  1995 apply (case_tac "b = 0", simp)
  1996 apply (force simp add: divmod_int_rel_div_mod [THEN zmult2_lemma, THEN divmod_int_rel_div])
  1997 done
  1998 
  1999 lemma zmod_zmult2_eq:
  2000      "(0::int) < c ==> a mod (b*c) = b*(a div b mod c) + a mod b"
  2001 apply (case_tac "b = 0", simp)
  2002 apply (force simp add: divmod_int_rel_div_mod [THEN zmult2_lemma, THEN divmod_int_rel_mod])
  2003 done
  2004 
  2005 
  2006 subsubsection {*Splitting Rules for div and mod*}
  2007 
  2008 text{*The proofs of the two lemmas below are essentially identical*}
  2009 
  2010 lemma split_pos_lemma:
  2011  "0<k ==> 
  2012     P(n div k :: int)(n mod k) = (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i j)"
  2013 apply (rule iffI, clarify)
  2014  apply (erule_tac P="P ?x ?y" in rev_mp)  
  2015  apply (subst mod_add_eq) 
  2016  apply (subst zdiv_zadd1_eq) 
  2017  apply (simp add: div_pos_pos_trivial mod_pos_pos_trivial)  
  2018 txt{*converse direction*}
  2019 apply (drule_tac x = "n div k" in spec) 
  2020 apply (drule_tac x = "n mod k" in spec, simp)
  2021 done
  2022 
  2023 lemma split_neg_lemma:
  2024  "k<0 ==>
  2025     P(n div k :: int)(n mod k) = (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i j)"
  2026 apply (rule iffI, clarify)
  2027  apply (erule_tac P="P ?x ?y" in rev_mp)  
  2028  apply (subst mod_add_eq) 
  2029  apply (subst zdiv_zadd1_eq) 
  2030  apply (simp add: div_neg_neg_trivial mod_neg_neg_trivial)  
  2031 txt{*converse direction*}
  2032 apply (drule_tac x = "n div k" in spec) 
  2033 apply (drule_tac x = "n mod k" in spec, simp)
  2034 done
  2035 
  2036 lemma split_zdiv:
  2037  "P(n div k :: int) =
  2038   ((k = 0 --> P 0) & 
  2039    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i)) & 
  2040    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i)))"
  2041 apply (case_tac "k=0", simp)
  2042 apply (simp only: linorder_neq_iff)
  2043 apply (erule disjE) 
  2044  apply (simp_all add: split_pos_lemma [of concl: "%x y. P x"] 
  2045                       split_neg_lemma [of concl: "%x y. P x"])
  2046 done
  2047 
  2048 lemma split_zmod:
  2049  "P(n mod k :: int) =
  2050   ((k = 0 --> P n) & 
  2051    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P j)) & 
  2052    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P j)))"
  2053 apply (case_tac "k=0", simp)
  2054 apply (simp only: linorder_neq_iff)
  2055 apply (erule disjE) 
  2056  apply (simp_all add: split_pos_lemma [of concl: "%x y. P y"] 
  2057                       split_neg_lemma [of concl: "%x y. P y"])
  2058 done
  2059 
  2060 text {* Enable (lin)arith to deal with @{const div} and @{const mod}
  2061   when these are applied to some constant that is of the form
  2062   @{term "number_of k"}: *}
  2063 declare split_zdiv [of _ _ "number_of k", standard, arith_split]
  2064 declare split_zmod [of _ _ "number_of k", standard, arith_split]
  2065 
  2066 
  2067 subsubsection{*Speeding up the Division Algorithm with Shifting*}
  2068 
  2069 text{*computing div by shifting *}
  2070 
  2071 lemma pos_zdiv_mult_2: "(0::int) \<le> a ==> (1 + 2*b) div (2*a) = b div a"
  2072 proof cases
  2073   assume "a=0"
  2074     thus ?thesis by simp
  2075 next
  2076   assume "a\<noteq>0" and le_a: "0\<le>a"   
  2077   hence a_pos: "1 \<le> a" by arith
  2078   hence one_less_a2: "1 < 2 * a" by arith
  2079   hence le_2a: "2 * (1 + b mod a) \<le> 2 * a"
  2080     unfolding mult_le_cancel_left
  2081     by (simp add: add1_zle_eq add_commute [of 1])
  2082   with a_pos have "0 \<le> b mod a" by simp
  2083   hence le_addm: "0 \<le> 1 mod (2*a) + 2*(b mod a)"
  2084     by (simp add: mod_pos_pos_trivial one_less_a2)
  2085   with  le_2a
  2086   have "(1 mod (2*a) + 2*(b mod a)) div (2*a) = 0"
  2087     by (simp add: div_pos_pos_trivial le_addm mod_pos_pos_trivial one_less_a2
  2088                   right_distrib) 
  2089   thus ?thesis
  2090     by (subst zdiv_zadd1_eq,
  2091         simp add: mod_mult_mult1 one_less_a2
  2092                   div_pos_pos_trivial)
  2093 qed
  2094 
  2095 lemma neg_zdiv_mult_2: "a \<le> (0::int) ==> (1 + 2*b) div (2*a) = (b+1) div a"
  2096 apply (subgoal_tac " (1 + 2* (-b - 1)) div (2 * (-a)) = (-b - 1) div (-a) ")
  2097 apply (rule_tac [2] pos_zdiv_mult_2)
  2098 apply (auto simp add: right_diff_distrib)
  2099 apply (subgoal_tac " (-1 - (2 * b)) = - (1 + (2 * b))")
  2100 apply (simp only: zdiv_zminus_zminus diff_minus minus_add_distrib [symmetric])
  2101 apply (simp_all add: algebra_simps)
  2102 apply (simp only: ab_diff_minus minus_add_distrib [symmetric] number_of_Min zdiv_zminus_zminus)
  2103 done
  2104 
  2105 lemma zdiv_number_of_Bit0 [simp]:
  2106      "number_of (Int.Bit0 v) div number_of (Int.Bit0 w) =  
  2107           number_of v div (number_of w :: int)"
  2108 by (simp only: number_of_eq numeral_simps) (simp add: mult_2 [symmetric])
  2109 
  2110 lemma zdiv_number_of_Bit1 [simp]:
  2111      "number_of (Int.Bit1 v) div number_of (Int.Bit0 w) =  
  2112           (if (0::int) \<le> number_of w                    
  2113            then number_of v div (number_of w)     
  2114            else (number_of v + (1::int)) div (number_of w))"
  2115 apply (simp only: number_of_eq numeral_simps UNIV_I split: split_if) 
  2116 apply (simp add: pos_zdiv_mult_2 neg_zdiv_mult_2 add_ac mult_2 [symmetric])
  2117 done
  2118 
  2119 
  2120 subsubsection{*Computing mod by Shifting (proofs resemble those for div)*}
  2121 
  2122 lemma pos_zmod_mult_2:
  2123   fixes a b :: int
  2124   assumes "0 \<le> a"
  2125   shows "(1 + 2 * b) mod (2 * a) = 1 + 2 * (b mod a)"
  2126 proof (cases "0 < a")
  2127   case False with assms show ?thesis by simp
  2128 next
  2129   case True
  2130   then have "b mod a < a" by (rule pos_mod_bound)
  2131   then have "1 + b mod a \<le> a" by simp
  2132   then have A: "2 * (1 + b mod a) \<le> 2 * a" by simp
  2133   from `0 < a` have "0 \<le> b mod a" by (rule pos_mod_sign)
  2134   then have B: "0 \<le> 1 + 2 * (b mod a)" by simp
  2135   have "((1\<Colon>int) mod ((2\<Colon>int) * a) + (2\<Colon>int) * b mod ((2\<Colon>int) * a)) mod ((2\<Colon>int) * a) = (1\<Colon>int) + (2\<Colon>int) * (b mod a)"
  2136     using `0 < a` and A
  2137     by (auto simp add: mod_mult_mult1 mod_pos_pos_trivial ring_distribs intro!: mod_pos_pos_trivial B)
  2138   then show ?thesis by (subst mod_add_eq)
  2139 qed
  2140 
  2141 lemma neg_zmod_mult_2:
  2142   fixes a b :: int
  2143   assumes "a \<le> 0"
  2144   shows "(1 + 2 * b) mod (2 * a) = 2 * ((b + 1) mod a) - 1"
  2145 proof -
  2146   from assms have "0 \<le> - a" by auto
  2147   then have "(1 + 2 * (- b - 1)) mod (2 * (- a)) = 1 + 2 * ((- b - 1) mod (- a))"
  2148     by (rule pos_zmod_mult_2)
  2149   then show ?thesis by (simp add: zmod_zminus2 algebra_simps)
  2150      (simp add: diff_minus add_ac)
  2151 qed
  2152 
  2153 lemma zmod_number_of_Bit0 [simp]:
  2154      "number_of (Int.Bit0 v) mod number_of (Int.Bit0 w) =  
  2155       (2::int) * (number_of v mod number_of w)"
  2156 apply (simp only: number_of_eq numeral_simps) 
  2157 apply (simp add: mod_mult_mult1 pos_zmod_mult_2 
  2158                  neg_zmod_mult_2 add_ac mult_2 [symmetric])
  2159 done
  2160 
  2161 lemma zmod_number_of_Bit1 [simp]:
  2162      "number_of (Int.Bit1 v) mod number_of (Int.Bit0 w) =  
  2163       (if (0::int) \<le> number_of w  
  2164                 then 2 * (number_of v mod number_of w) + 1     
  2165                 else 2 * ((number_of v + (1::int)) mod number_of w) - 1)"
  2166 apply (simp only: number_of_eq numeral_simps) 
  2167 apply (simp add: mod_mult_mult1 pos_zmod_mult_2 
  2168                  neg_zmod_mult_2 add_ac mult_2 [symmetric])
  2169 done
  2170 
  2171 
  2172 subsubsection{*Quotients of Signs*}
  2173 
  2174 lemma div_neg_pos_less0: "[| a < (0::int);  0 < b |] ==> a div b < 0"
  2175 apply (subgoal_tac "a div b \<le> -1", force)
  2176 apply (rule order_trans)
  2177 apply (rule_tac a' = "-1" in zdiv_mono1)
  2178 apply (auto simp add: div_eq_minus1)
  2179 done
  2180 
  2181 lemma div_nonneg_neg_le0: "[| (0::int) \<le> a; b < 0 |] ==> a div b \<le> 0"
  2182 by (drule zdiv_mono1_neg, auto)
  2183 
  2184 lemma div_nonpos_pos_le0: "[| (a::int) \<le> 0; b > 0 |] ==> a div b \<le> 0"
  2185 by (drule zdiv_mono1, auto)
  2186 
  2187 text{* Now for some equivalences of the form @{text"a div b >=< 0 \<longleftrightarrow> \<dots>"}
  2188 conditional upon the sign of @{text a} or @{text b}. There are many more.
  2189 They should all be simp rules unless that causes too much search. *}
  2190 
  2191 lemma pos_imp_zdiv_nonneg_iff: "(0::int) < b ==> (0 \<le> a div b) = (0 \<le> a)"
  2192 apply auto
  2193 apply (drule_tac [2] zdiv_mono1)
  2194 apply (auto simp add: linorder_neq_iff)
  2195 apply (simp (no_asm_use) add: linorder_not_less [symmetric])
  2196 apply (blast intro: div_neg_pos_less0)
  2197 done
  2198 
  2199 lemma neg_imp_zdiv_nonneg_iff:
  2200   "b < (0::int) ==> (0 \<le> a div b) = (a \<le> (0::int))"
  2201 apply (subst zdiv_zminus_zminus [symmetric])
  2202 apply (subst pos_imp_zdiv_nonneg_iff, auto)
  2203 done
  2204 
  2205 (*But not (a div b \<le> 0 iff a\<le>0); consider a=1, b=2 when a div b = 0.*)
  2206 lemma pos_imp_zdiv_neg_iff: "(0::int) < b ==> (a div b < 0) = (a < 0)"
  2207 by (simp add: linorder_not_le [symmetric] pos_imp_zdiv_nonneg_iff)
  2208 
  2209 (*Again the law fails for \<le>: consider a = -1, b = -2 when a div b = 0*)
  2210 lemma neg_imp_zdiv_neg_iff: "b < (0::int) ==> (a div b < 0) = (0 < a)"
  2211 by (simp add: linorder_not_le [symmetric] neg_imp_zdiv_nonneg_iff)
  2212 
  2213 lemma nonneg1_imp_zdiv_pos_iff:
  2214   "(0::int) <= a \<Longrightarrow> (a div b > 0) = (a >= b & b>0)"
  2215 apply rule
  2216  apply rule
  2217   using div_pos_pos_trivial[of a b]apply arith
  2218  apply(cases "b=0")apply simp
  2219  using div_nonneg_neg_le0[of a b]apply arith
  2220 using int_one_le_iff_zero_less[of "a div b"] zdiv_mono1[of b a b]apply simp
  2221 done
  2222 
  2223 
  2224 subsubsection {* The Divides Relation *}
  2225 
  2226 lemmas zdvd_iff_zmod_eq_0_number_of [simp] =
  2227   dvd_eq_mod_eq_0 [of "number_of x::int" "number_of y::int", standard]
  2228 
  2229 lemma zdvd_zmod: "f dvd m ==> f dvd (n::int) ==> f dvd m mod n"
  2230   by (rule dvd_mod) (* TODO: remove *)
  2231 
  2232 lemma zdvd_zmod_imp_zdvd: "k dvd m mod n ==> k dvd n ==> k dvd (m::int)"
  2233   by (rule dvd_mod_imp_dvd) (* TODO: remove *)
  2234 
  2235 lemma zmult_div_cancel: "(n::int) * (m div n) = m - (m mod n)"
  2236   using zmod_zdiv_equality[where a="m" and b="n"]
  2237   by (simp add: algebra_simps)
  2238 
  2239 lemma zpower_zmod: "((x::int) mod m)^y mod m = x^y mod m"
  2240 apply (induct "y", auto)
  2241 apply (rule zmod_zmult1_eq [THEN trans])
  2242 apply (simp (no_asm_simp))
  2243 apply (rule mod_mult_eq [symmetric])
  2244 done
  2245 
  2246 lemma zdiv_int: "int (a div b) = (int a) div (int b)"
  2247 apply (subst split_div, auto)
  2248 apply (subst split_zdiv, auto)
  2249 apply (rule_tac a="int (b * i) + int j" and b="int b" and r="int j" and r'=ja in unique_quotient)
  2250 apply (auto simp add: divmod_int_rel_def of_nat_mult)
  2251 done
  2252 
  2253 lemma zmod_int: "int (a mod b) = (int a) mod (int b)"
  2254 apply (subst split_mod, auto)
  2255 apply (subst split_zmod, auto)
  2256 apply (rule_tac a="int (b * i) + int j" and b="int b" and q="int i" and q'=ia 
  2257        in unique_remainder)
  2258 apply (auto simp add: divmod_int_rel_def of_nat_mult)
  2259 done
  2260 
  2261 lemma abs_div: "(y::int) dvd x \<Longrightarrow> abs (x div y) = abs x div abs y"
  2262 by (unfold dvd_def, cases "y=0", auto simp add: abs_mult)
  2263 
  2264 lemma zdvd_mult_div_cancel:"(n::int) dvd m \<Longrightarrow> n * (m div n) = m"
  2265 apply (subgoal_tac "m mod n = 0")
  2266  apply (simp add: zmult_div_cancel)
  2267 apply (simp only: dvd_eq_mod_eq_0)
  2268 done
  2269 
  2270 text{*Suggested by Matthias Daum*}
  2271 lemma int_power_div_base:
  2272      "\<lbrakk>0 < m; 0 < k\<rbrakk> \<Longrightarrow> k ^ m div k = (k::int) ^ (m - Suc 0)"
  2273 apply (subgoal_tac "k ^ m = k ^ ((m - Suc 0) + Suc 0)")
  2274  apply (erule ssubst)
  2275  apply (simp only: power_add)
  2276  apply simp_all
  2277 done
  2278 
  2279 text {* by Brian Huffman *}
  2280 lemma zminus_zmod: "- ((x::int) mod m) mod m = - x mod m"
  2281 by (rule mod_minus_eq [symmetric])
  2282 
  2283 lemma zdiff_zmod_left: "(x mod m - y) mod m = (x - y) mod (m::int)"
  2284 by (rule mod_diff_left_eq [symmetric])
  2285 
  2286 lemma zdiff_zmod_right: "(x - y mod m) mod m = (x - y) mod (m::int)"
  2287 by (rule mod_diff_right_eq [symmetric])
  2288 
  2289 lemmas zmod_simps =
  2290   mod_add_left_eq  [symmetric]
  2291   mod_add_right_eq [symmetric]
  2292   zmod_zmult1_eq   [symmetric]
  2293   mod_mult_left_eq [symmetric]
  2294   zpower_zmod
  2295   zminus_zmod zdiff_zmod_left zdiff_zmod_right
  2296 
  2297 text {* Distributive laws for function @{text nat}. *}
  2298 
  2299 lemma nat_div_distrib: "0 \<le> x \<Longrightarrow> nat (x div y) = nat x div nat y"
  2300 apply (rule linorder_cases [of y 0])
  2301 apply (simp add: div_nonneg_neg_le0)
  2302 apply simp
  2303 apply (simp add: nat_eq_iff pos_imp_zdiv_nonneg_iff zdiv_int)
  2304 done
  2305 
  2306 (*Fails if y<0: the LHS collapses to (nat z) but the RHS doesn't*)
  2307 lemma nat_mod_distrib:
  2308   "\<lbrakk>0 \<le> x; 0 \<le> y\<rbrakk> \<Longrightarrow> nat (x mod y) = nat x mod nat y"
  2309 apply (case_tac "y = 0", simp)
  2310 apply (simp add: nat_eq_iff zmod_int)
  2311 done
  2312 
  2313 text  {* transfer setup *}
  2314 
  2315 lemma transfer_nat_int_functions:
  2316     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> (nat x) div (nat y) = nat (x div y)"
  2317     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> (nat x) mod (nat y) = nat (x mod y)"
  2318   by (auto simp add: nat_div_distrib nat_mod_distrib)
  2319 
  2320 lemma transfer_nat_int_function_closures:
  2321     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> x div y >= 0"
  2322     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> x mod y >= 0"
  2323   apply (cases "y = 0")
  2324   apply (auto simp add: pos_imp_zdiv_nonneg_iff)
  2325   apply (cases "y = 0")
  2326   apply auto
  2327 done
  2328 
  2329 declare TransferMorphism_nat_int [transfer add return:
  2330   transfer_nat_int_functions
  2331   transfer_nat_int_function_closures
  2332 ]
  2333 
  2334 lemma transfer_int_nat_functions:
  2335     "(int x) div (int y) = int (x div y)"
  2336     "(int x) mod (int y) = int (x mod y)"
  2337   by (auto simp add: zdiv_int zmod_int)
  2338 
  2339 lemma transfer_int_nat_function_closures:
  2340     "is_nat x \<Longrightarrow> is_nat y \<Longrightarrow> is_nat (x div y)"
  2341     "is_nat x \<Longrightarrow> is_nat y \<Longrightarrow> is_nat (x mod y)"
  2342   by (simp_all only: is_nat_def transfer_nat_int_function_closures)
  2343 
  2344 declare TransferMorphism_int_nat [transfer add return:
  2345   transfer_int_nat_functions
  2346   transfer_int_nat_function_closures
  2347 ]
  2348 
  2349 text{*Suggested by Matthias Daum*}
  2350 lemma int_div_less_self: "\<lbrakk>0 < x; 1 < k\<rbrakk> \<Longrightarrow> x div k < (x::int)"
  2351 apply (subgoal_tac "nat x div nat k < nat x")
  2352  apply (simp add: nat_div_distrib [symmetric])
  2353 apply (rule Divides.div_less_dividend, simp_all)
  2354 done
  2355 
  2356 text {* code generator setup *}
  2357 
  2358 context ring_1
  2359 begin
  2360 
  2361 lemma of_int_num [code]:
  2362   "of_int k = (if k = 0 then 0 else if k < 0 then
  2363      - of_int (- k) else let
  2364        (l, m) = divmod_int k 2;
  2365        l' = of_int l
  2366      in if m = 0 then l' + l' else l' + l' + 1)"
  2367 proof -
  2368   have aux1: "k mod (2\<Colon>int) \<noteq> (0\<Colon>int) \<Longrightarrow> 
  2369     of_int k = of_int (k div 2 * 2 + 1)"
  2370   proof -
  2371     have "k mod 2 < 2" by (auto intro: pos_mod_bound)
  2372     moreover have "0 \<le> k mod 2" by (auto intro: pos_mod_sign)
  2373     moreover assume "k mod 2 \<noteq> 0"
  2374     ultimately have "k mod 2 = 1" by arith
  2375     moreover have "of_int k = of_int (k div 2 * 2 + k mod 2)" by simp
  2376     ultimately show ?thesis by auto
  2377   qed
  2378   have aux2: "\<And>x. of_int 2 * x = x + x"
  2379   proof -
  2380     fix x
  2381     have int2: "(2::int) = 1 + 1" by arith
  2382     show "of_int 2 * x = x + x"
  2383     unfolding int2 of_int_add left_distrib by simp
  2384   qed
  2385   have aux3: "\<And>x. x * of_int 2 = x + x"
  2386   proof -
  2387     fix x
  2388     have int2: "(2::int) = 1 + 1" by arith
  2389     show "x * of_int 2 = x + x" 
  2390     unfolding int2 of_int_add right_distrib by simp
  2391   qed
  2392   from aux1 show ?thesis by (auto simp add: divmod_int_mod_div Let_def aux2 aux3)
  2393 qed
  2394 
  2395 end
  2396 
  2397 lemma zmod_eq_dvd_iff: "(x::int) mod n = y mod n \<longleftrightarrow> n dvd x - y"
  2398 proof
  2399   assume H: "x mod n = y mod n"
  2400   hence "x mod n - y mod n = 0" by simp
  2401   hence "(x mod n - y mod n) mod n = 0" by simp 
  2402   hence "(x - y) mod n = 0" by (simp add: mod_diff_eq[symmetric])
  2403   thus "n dvd x - y" by (simp add: dvd_eq_mod_eq_0)
  2404 next
  2405   assume H: "n dvd x - y"
  2406   then obtain k where k: "x-y = n*k" unfolding dvd_def by blast
  2407   hence "x = n*k + y" by simp
  2408   hence "x mod n = (n*k + y) mod n" by simp
  2409   thus "x mod n = y mod n" by (simp add: mod_add_left_eq)
  2410 qed
  2411 
  2412 lemma nat_mod_eq_lemma: assumes xyn: "(x::nat) mod n = y  mod n" and xy:"y \<le> x"
  2413   shows "\<exists>q. x = y + n * q"
  2414 proof-
  2415   from xy have th: "int x - int y = int (x - y)" by simp 
  2416   from xyn have "int x mod int n = int y mod int n" 
  2417     by (simp add: zmod_int[symmetric])
  2418   hence "int n dvd int x - int y" by (simp only: zmod_eq_dvd_iff[symmetric]) 
  2419   hence "n dvd x - y" by (simp add: th zdvd_int)
  2420   then show ?thesis using xy unfolding dvd_def apply clarsimp apply (rule_tac x="k" in exI) by arith
  2421 qed
  2422 
  2423 lemma nat_mod_eq_iff: "(x::nat) mod n = y mod n \<longleftrightarrow> (\<exists>q1 q2. x + n * q1 = y + n * q2)" 
  2424   (is "?lhs = ?rhs")
  2425 proof
  2426   assume H: "x mod n = y mod n"
  2427   {assume xy: "x \<le> y"
  2428     from H have th: "y mod n = x mod n" by simp
  2429     from nat_mod_eq_lemma[OF th xy] have ?rhs 
  2430       apply clarify  apply (rule_tac x="q" in exI) by (rule exI[where x="0"], simp)}
  2431   moreover
  2432   {assume xy: "y \<le> x"
  2433     from nat_mod_eq_lemma[OF H xy] have ?rhs 
  2434       apply clarify  apply (rule_tac x="0" in exI) by (rule_tac x="q" in exI, simp)}
  2435   ultimately  show ?rhs using linear[of x y] by blast  
  2436 next
  2437   assume ?rhs then obtain q1 q2 where q12: "x + n * q1 = y + n * q2" by blast
  2438   hence "(x + n * q1) mod n = (y + n * q2) mod n" by simp
  2439   thus  ?lhs by simp
  2440 qed
  2441 
  2442 lemma div_nat_number_of [simp]:
  2443      "(number_of v :: nat)  div  number_of v' =  
  2444           (if neg (number_of v :: int) then 0  
  2445            else nat (number_of v div number_of v'))"
  2446   unfolding nat_number_of_def number_of_is_id neg_def
  2447   by (simp add: nat_div_distrib)
  2448 
  2449 lemma one_div_nat_number_of [simp]:
  2450      "Suc 0 div number_of v' = nat (1 div number_of v')" 
  2451 by (simp del: nat_numeral_1_eq_1 add: numeral_1_eq_Suc_0 [symmetric]) 
  2452 
  2453 lemma mod_nat_number_of [simp]:
  2454      "(number_of v :: nat)  mod  number_of v' =  
  2455         (if neg (number_of v :: int) then 0  
  2456          else if neg (number_of v' :: int) then number_of v  
  2457          else nat (number_of v mod number_of v'))"
  2458   unfolding nat_number_of_def number_of_is_id neg_def
  2459   by (simp add: nat_mod_distrib)
  2460 
  2461 lemma one_mod_nat_number_of [simp]:
  2462      "Suc 0 mod number_of v' =  
  2463         (if neg (number_of v' :: int) then Suc 0
  2464          else nat (1 mod number_of v'))"
  2465 by (simp del: nat_numeral_1_eq_1 add: numeral_1_eq_Suc_0 [symmetric]) 
  2466 
  2467 lemmas dvd_eq_mod_eq_0_number_of =
  2468   dvd_eq_mod_eq_0 [of "number_of x" "number_of y", standard]
  2469 
  2470 declare dvd_eq_mod_eq_0_number_of [simp]
  2471 
  2472 
  2473 subsubsection {* Nitpick *}
  2474 
  2475 lemma zmod_zdiv_equality':
  2476 "(m\<Colon>int) mod n = m - (m div n) * n"
  2477 by (rule_tac P="%x. m mod n = x - (m div n) * n"
  2478     in subst [OF mod_div_equality [of _ n]])
  2479    arith
  2480 
  2481 lemmas [nitpick_def] = dvd_eq_mod_eq_0 [THEN eq_reflection]
  2482                        mod_div_equality' [THEN eq_reflection]
  2483                        zmod_zdiv_equality' [THEN eq_reflection]
  2484 
  2485 subsubsection {* Code generation *}
  2486 
  2487 definition pdivmod :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  2488   "pdivmod k l = (\<bar>k\<bar> div \<bar>l\<bar>, \<bar>k\<bar> mod \<bar>l\<bar>)"
  2489 
  2490 lemma pdivmod_posDivAlg [code]:
  2491   "pdivmod k l = (if l = 0 then (0, \<bar>k\<bar>) else posDivAlg \<bar>k\<bar> \<bar>l\<bar>)"
  2492 by (subst posDivAlg_div_mod) (simp_all add: pdivmod_def)
  2493 
  2494 lemma divmod_int_pdivmod: "divmod_int k l = (if k = 0 then (0, 0) else if l = 0 then (0, k) else
  2495   apsnd ((op *) (sgn l)) (if 0 < l \<and> 0 \<le> k \<or> l < 0 \<and> k < 0
  2496     then pdivmod k l
  2497     else (let (r, s) = pdivmod k l in
  2498       if s = 0 then (- r, 0) else (- r - 1, \<bar>l\<bar> - s))))"
  2499 proof -
  2500   have aux: "\<And>q::int. - k = l * q \<longleftrightarrow> k = l * - q" by auto
  2501   show ?thesis
  2502     by (simp add: divmod_int_mod_div pdivmod_def)
  2503       (auto simp add: aux not_less not_le zdiv_zminus1_eq_if
  2504       zmod_zminus1_eq_if zdiv_zminus2_eq_if zmod_zminus2_eq_if)
  2505 qed
  2506 
  2507 lemma divmod_int_code [code]: "divmod_int k l = (if k = 0 then (0, 0) else if l = 0 then (0, k) else
  2508   apsnd ((op *) (sgn l)) (if sgn k = sgn l
  2509     then pdivmod k l
  2510     else (let (r, s) = pdivmod k l in
  2511       if s = 0 then (- r, 0) else (- r - 1, \<bar>l\<bar> - s))))"
  2512 proof -
  2513   have "k \<noteq> 0 \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> 0 < l \<and> 0 \<le> k \<or> l < 0 \<and> k < 0 \<longleftrightarrow> sgn k = sgn l"
  2514     by (auto simp add: not_less sgn_if)
  2515   then show ?thesis by (simp add: divmod_int_pdivmod)
  2516 qed
  2517 
  2518 code_modulename SML
  2519   Divides Arith
  2520 
  2521 code_modulename OCaml
  2522   Divides Arith
  2523 
  2524 code_modulename Haskell
  2525   Divides Arith
  2526 
  2527 end