src/HOL/Tools/res_atp.ML
author paulson
Thu Sep 21 17:33:11 2006 +0200 (2006-09-21)
changeset 20661 46832fee1215
parent 20643 267f30cbe2cb
child 20757 fe84fe0dfd30
permissions -rw-r--r--
Yet another version of fake_thm_name. "Full" hashing ensures that there are no collisions
unless theorems differ by sorts alone, which should not matter. Also minor fixes to
standard hashing.
     1 (*  Author: Jia Meng, Cambridge University Computer Laboratory, NICTA
     2     ID: $Id$
     3     Copyright 2004 University of Cambridge
     4 
     5 ATPs with TPTP format input.
     6 *)
     7 
     8 (*FIXME: Do we need this signature?*)
     9 signature RES_ATP =
    10 sig
    11   val prover: string ref
    12   val custom_spass: string list ref
    13   val destdir: string ref
    14   val helper_path: string -> string -> string
    15   val problem_name: string ref
    16   val time_limit: int ref
    17    
    18   datatype mode = Auto | Fol | Hol
    19   val linkup_logic_mode : mode ref
    20   val write_subgoal_file: bool -> mode -> Proof.context -> thm list -> thm list -> int -> string
    21   val vampire_time: int ref
    22   val eprover_time: int ref
    23   val spass_time: int ref
    24   val run_vampire: int -> unit
    25   val run_eprover: int -> unit
    26   val run_spass: int -> unit
    27   val vampireLimit: unit -> int
    28   val eproverLimit: unit -> int
    29   val spassLimit: unit -> int
    30   val atp_method: (Proof.context -> thm list -> int -> tactic) ->
    31     Method.src -> Proof.context -> Proof.method
    32   val cond_rm_tmp: string -> unit
    33   val keep_atp_input: bool ref
    34   val fol_keep_types: bool ref
    35   val hol_full_types: unit -> unit
    36   val hol_partial_types: unit -> unit
    37   val hol_const_types_only: unit -> unit
    38   val hol_no_types: unit -> unit
    39   val hol_typ_level: unit -> ResHolClause.type_level
    40   val include_all: bool ref
    41   val run_relevance_filter: bool ref
    42   val run_blacklist_filter: bool ref
    43   val blacklist: string list ref
    44   val add_all : unit -> unit
    45   val add_claset : unit -> unit
    46   val add_simpset : unit -> unit
    47   val add_clasimp : unit -> unit
    48   val add_atpset : unit -> unit
    49   val rm_all : unit -> unit
    50   val rm_claset : unit -> unit
    51   val rm_simpset : unit -> unit
    52   val rm_atpset : unit -> unit
    53   val rm_clasimp : unit -> unit
    54 end;
    55 
    56 structure ResAtp =
    57 struct
    58 
    59 (********************************************************************)
    60 (* some settings for both background automatic ATP calling procedure*)
    61 (* and also explicit ATP invocation methods                         *)
    62 (********************************************************************)
    63 
    64 (*** background linkup ***)
    65 val call_atp = ref false; 
    66 val hook_count = ref 0;
    67 val time_limit = ref 80;
    68 val prover = ref "E";   (* use E as the default prover *)
    69 val custom_spass =   (*specialized options for SPASS*)
    70       ref ["-Auto=0","-FullRed=0","-IORe","-IOFc","-RTaut","-RFSub","-RBSub"];
    71 val destdir = ref "";   (*Empty means write files to /tmp*)
    72 val problem_name = ref "prob";
    73 
    74 (*Return the path to a "helper" like SPASS or tptp2X, first checking that
    75   it exists.  FIXME: modify to use Path primitives and move to some central place.*)  
    76 fun helper_path evar base =
    77   case getenv evar of
    78       "" => error  ("Isabelle environment variable " ^ evar ^ " not defined")
    79     | home => 
    80         let val path = home ^ "/" ^ base
    81         in  if File.exists (File.unpack_platform_path path) then path 
    82 	    else error ("Could not find the file " ^ path)
    83 	end;  
    84 
    85 fun probfile_nosuffix _ = 
    86   if !destdir = "" then File.platform_path (File.tmp_path (Path.basic (!problem_name)))
    87   else if File.exists (File.unpack_platform_path (!destdir))
    88   then !destdir ^ "/" ^ !problem_name
    89   else error ("No such directory: " ^ !destdir);
    90 
    91 fun prob_pathname n = probfile_nosuffix n ^ "_" ^ Int.toString n;
    92 
    93 
    94 (*** ATP methods ***)
    95 val vampire_time = ref 60;
    96 val eprover_time = ref 60;
    97 val spass_time = ref 60;
    98 
    99 fun run_vampire time =  
   100     if (time >0) then vampire_time:= time
   101     else vampire_time:=60;
   102 
   103 fun run_eprover time = 
   104     if (time > 0) then eprover_time:= time
   105     else eprover_time:=60;
   106 
   107 fun run_spass time = 
   108     if (time > 0) then spass_time:=time
   109     else spass_time:=60;
   110 
   111 
   112 fun vampireLimit () = !vampire_time;
   113 fun eproverLimit () = !eprover_time;
   114 fun spassLimit () = !spass_time;
   115 
   116 val keep_atp_input = ref false;
   117 val fol_keep_types = ResClause.keep_types;
   118 val hol_full_types = ResHolClause.full_types;
   119 val hol_partial_types = ResHolClause.partial_types;
   120 val hol_const_types_only = ResHolClause.const_types_only;
   121 val hol_no_types = ResHolClause.no_types;
   122 fun hol_typ_level () = ResHolClause.find_typ_level ();
   123 fun is_typed_hol () = 
   124     let val tp_level = hol_typ_level()
   125     in
   126 	not (tp_level = ResHolClause.T_NONE)
   127     end;
   128 
   129 fun atp_input_file () =
   130     let val file = !problem_name 
   131     in
   132 	if !destdir = "" then File.platform_path (File.tmp_path (Path.basic file))
   133 	else if File.exists (File.unpack_platform_path (!destdir))
   134 	then !destdir ^ "/" ^ file
   135 	else error ("No such directory: " ^ !destdir)
   136     end;
   137 
   138 val include_all = ref false;
   139 val include_simpset = ref false;
   140 val include_claset = ref false; 
   141 val include_atpset = ref true;
   142 
   143 (*Tests show that follow_defs gives VERY poor results with "include_all"*)
   144 fun add_all() = (include_all:=true; ReduceAxiomsN.follow_defs := false);
   145 fun rm_all() = include_all:=false;
   146 
   147 fun add_simpset() = include_simpset:=true;
   148 fun rm_simpset() = include_simpset:=false;
   149 
   150 fun add_claset() = include_claset:=true;
   151 fun rm_claset() = include_claset:=false;
   152 
   153 fun add_clasimp() = (include_simpset:=true;include_claset:=true);
   154 fun rm_clasimp() = (include_simpset:=false;include_claset:=false);
   155 
   156 fun add_atpset() = include_atpset:=true;
   157 fun rm_atpset() = include_atpset:=false;
   158 
   159 
   160 (**** relevance filter ****)
   161 val run_relevance_filter = ReduceAxiomsN.run_relevance_filter;
   162 val run_blacklist_filter = ref true;
   163 
   164 (******************************************************************)
   165 (* detect whether a given problem (clauses) is FOL/HOL/HOLC/HOLCS *)
   166 (******************************************************************)
   167 
   168 datatype logic = FOL | HOL | HOLC | HOLCS;
   169 
   170 fun string_of_logic FOL = "FOL"
   171   | string_of_logic HOL = "HOL"
   172   | string_of_logic HOLC = "HOLC"
   173   | string_of_logic HOLCS = "HOLCS";
   174 
   175 fun is_fol_logic FOL = true
   176   | is_fol_logic  _ = false
   177 
   178 (*HOLCS will not occur here*)
   179 fun upgrade_lg HOLC _ = HOLC
   180   | upgrade_lg HOL HOLC = HOLC
   181   | upgrade_lg HOL _ = HOL
   182   | upgrade_lg FOL lg = lg; 
   183 
   184 (* check types *)
   185 fun has_bool_hfn (Type("bool",_)) = true
   186   | has_bool_hfn (Type("fun",_)) = true
   187   | has_bool_hfn (Type(_, Ts)) = exists has_bool_hfn Ts
   188   | has_bool_hfn _ = false;
   189 
   190 fun is_hol_fn tp =
   191     let val (targs,tr) = strip_type tp
   192     in
   193 	exists (has_bool_hfn) (tr::targs)
   194     end;
   195 
   196 fun is_hol_pred tp =
   197     let val (targs,tr) = strip_type tp
   198     in
   199 	exists (has_bool_hfn) targs
   200     end;
   201 
   202 exception FN_LG of term;
   203 
   204 fun fn_lg (t as Const(f,tp)) (lg,seen) = 
   205     if is_hol_fn tp then (upgrade_lg HOL lg, t ins seen) else (lg, t ins seen) 
   206   | fn_lg (t as Free(f,tp)) (lg,seen) = 
   207     if is_hol_fn tp then (upgrade_lg HOL lg, t ins seen) else (lg, t ins seen) 
   208   | fn_lg (t as Var(f,tp)) (lg,seen) =
   209     if is_hol_fn tp then (upgrade_lg HOL lg,t ins seen) else (lg,t ins seen)
   210   | fn_lg (t as Abs(_,_,_)) (lg,seen) = (upgrade_lg HOLC lg,t ins seen)
   211   | fn_lg f _ = raise FN_LG(f); 
   212 
   213 
   214 fun term_lg [] (lg,seen) = (lg,seen)
   215   | term_lg (tm::tms) (FOL,seen) =
   216       let val (f,args) = strip_comb tm
   217 	  val (lg',seen') = if f mem seen then (FOL,seen) 
   218 			    else fn_lg f (FOL,seen)
   219       in
   220 	if is_fol_logic lg' then ()
   221         else Output.debug ("Found a HOL term: " ^ Display.raw_string_of_term f);
   222         term_lg (args@tms) (lg',seen')
   223       end
   224   | term_lg _ (lg,seen) = (lg,seen)
   225 
   226 exception PRED_LG of term;
   227 
   228 fun pred_lg (t as Const(P,tp)) (lg,seen)= 
   229       if is_hol_pred tp then (upgrade_lg HOL lg, t ins seen) else (lg,t ins seen) 
   230   | pred_lg (t as Free(P,tp)) (lg,seen) =
   231       if is_hol_pred tp then (upgrade_lg HOL lg, t ins seen) else (lg,t ins seen)
   232   | pred_lg (t as Var(_,_)) (lg,seen) = (upgrade_lg HOL lg, t ins seen)
   233   | pred_lg P _ = raise PRED_LG(P);
   234 
   235 
   236 fun lit_lg (Const("Not",_) $ P) (lg,seen) = lit_lg P (lg,seen)
   237   | lit_lg P (lg,seen) =
   238       let val (pred,args) = strip_comb P
   239 	  val (lg',seen') = if pred mem seen then (lg,seen) 
   240 			    else pred_lg pred (lg,seen)
   241       in
   242 	if is_fol_logic lg' then ()
   243 	else Output.debug ("Found a HOL predicate: " ^ Display.raw_string_of_term pred);
   244 	term_lg args (lg',seen')
   245       end;
   246 
   247 fun lits_lg [] (lg,seen) = (lg,seen)
   248   | lits_lg (lit::lits) (FOL,seen) =
   249       let val (lg,seen') = lit_lg lit (FOL,seen)
   250       in
   251 	if is_fol_logic lg then ()
   252 	else Output.debug ("Found a HOL literal: " ^ Display.raw_string_of_term lit);
   253 	lits_lg lits (lg,seen')
   254       end
   255   | lits_lg lits (lg,seen) = (lg,seen);
   256 
   257 fun dest_disj_aux (Const ("op |", _) $ t $ t') disjs = 
   258     dest_disj_aux t (dest_disj_aux t' disjs)
   259   | dest_disj_aux t disjs = t::disjs;
   260 
   261 fun dest_disj t = dest_disj_aux t [];
   262 
   263 fun logic_of_clause tm (lg,seen) =
   264     let val tm' = HOLogic.dest_Trueprop tm
   265 	val disjs = dest_disj tm'
   266     in
   267 	lits_lg disjs (lg,seen)
   268     end;
   269 
   270 fun logic_of_clauses [] (lg,seen) = (lg,seen)
   271   | logic_of_clauses (cls::clss) (FOL,seen) =
   272     let val (lg,seen') = logic_of_clause cls (FOL,seen)
   273 	val _ =
   274           if is_fol_logic lg then ()
   275           else Output.debug ("Found a HOL clause: " ^ Display.raw_string_of_term cls)
   276     in
   277 	logic_of_clauses clss (lg,seen')
   278     end
   279   | logic_of_clauses (cls::clss) (lg,seen) = (lg,seen);
   280 
   281 fun problem_logic_goals_aux [] (lg,seen) = lg
   282   | problem_logic_goals_aux (subgoal::subgoals) (lg,seen) = 
   283     problem_logic_goals_aux subgoals (logic_of_clauses subgoal (lg,seen));
   284     
   285 fun problem_logic_goals subgoals = problem_logic_goals_aux subgoals (FOL,[]);
   286 
   287 (***************************************************************)
   288 (* Retrieving and filtering lemmas                             *)
   289 (***************************************************************)
   290 
   291 (*** white list and black list of lemmas ***)
   292 
   293 (*The rule subsetI is frequently omitted by the relevance filter.*)
   294 val whitelist = ref [subsetI]; 
   295 
   296 (*Names of theorems and theorem lists to be banned. The final numeric suffix of
   297   theorem lists is first removed.
   298 
   299   These theorems typically produce clauses that are prolific (match too many equality or
   300   membership literals) and relate to seldom-used facts. Some duplicate other rules.
   301   FIXME: this blacklist needs to be maintained using theory data and added to using
   302   an attribute.*)
   303 val blacklist = ref
   304   ["Datatype.prod.size",
   305    "Datatype.unit.induct", (*"unit" thms cause unsound proofs; unit.nchotomy is caught automatically*)
   306    "Datatype.unit.inducts",
   307    "Datatype.unit.split_asm", 
   308    "Datatype.unit.split",
   309    "Datatype.unit.splits",
   310    "Divides.dvd_0_left_iff",
   311    "Finite_Set.card_0_eq",
   312    "Finite_Set.card_infinite",
   313    "Finite_Set.Max_ge",
   314    "Finite_Set.Max_in",
   315    "Finite_Set.Max_le_iff",
   316    "Finite_Set.Max_less_iff",
   317    "Finite_Set.max.f_below_strict_below.below_f_conv", (*duplicates in Orderings.*)
   318    "Finite_Set.max.f_below_strict_below.strict_below_f_conv", (*duplicates in Orderings.*)
   319    "Finite_Set.Min_ge_iff",
   320    "Finite_Set.Min_gr_iff",
   321    "Finite_Set.Min_in",
   322    "Finite_Set.Min_le",
   323    "Finite_Set.min_max.below_inf_sup_Inf_Sup.inf_Sup_absorb", 
   324    "Finite_Set.min_max.below_inf_sup_Inf_Sup.sup_Inf_absorb", 
   325    "Finite_Set.min.f_below_strict_below.below_f_conv",        (*duplicates in Orderings.*)
   326    "Finite_Set.min.f_below_strict_below.strict_below_f_conv", (*duplicates in Orderings.*)
   327    "Fun.vimage_image_eq",   (*involves an existential quantifier*)
   328    "HOL.split_if_asm",     (*splitting theorem*)
   329    "HOL.split_if",         (*splitting theorem*)
   330    "IntDef.abs_split",
   331    "IntDef.Integ.Abs_Integ_inject",
   332    "IntDef.Integ.Abs_Integ_inverse",
   333    "IntDiv.zdvd_0_left",
   334    "List.append_eq_append_conv",
   335    "List.hd_Cons_tl",   (*Says everything is [] or Cons. Probably prolific.*)
   336    "List.in_listsD",
   337    "List.in_listsI",
   338    "List.lists.Cons",
   339    "List.listsE",
   340    "Nat.less_one", (*not directional? obscure*)
   341    "Nat.not_gr0",
   342    "Nat.one_eq_mult_iff", (*duplicate by symmetry*)
   343    "NatArith.of_nat_0_eq_iff",
   344    "NatArith.of_nat_eq_0_iff",
   345    "NatArith.of_nat_le_0_iff",
   346    "NatSimprocs.divide_le_0_iff_number_of",  (*too many clauses*)
   347    "NatSimprocs.divide_less_0_iff_number_of",
   348    "NatSimprocs.equation_minus_iff_1",  (*not directional*)
   349    "NatSimprocs.equation_minus_iff_number_of", (*not directional*)
   350    "NatSimprocs.le_minus_iff_1", (*not directional*)
   351    "NatSimprocs.le_minus_iff_number_of",  (*not directional*)
   352    "NatSimprocs.less_minus_iff_1", (*not directional*)
   353    "NatSimprocs.less_minus_iff_number_of", (*not directional*)
   354    "NatSimprocs.minus_equation_iff_number_of", (*not directional*)
   355    "NatSimprocs.minus_le_iff_1", (*not directional*)
   356    "NatSimprocs.minus_le_iff_number_of", (*not directional*)
   357    "NatSimprocs.minus_less_iff_1", (*not directional*)
   358    "NatSimprocs.mult_le_cancel_left_number_of", (*excessive case analysis*)
   359    "NatSimprocs.mult_le_cancel_right_number_of", (*excessive case analysis*)
   360    "NatSimprocs.mult_less_cancel_left_number_of", (*excessive case analysis*)
   361    "NatSimprocs.mult_less_cancel_right_number_of", (*excessive case analysis*)
   362    "NatSimprocs.zero_le_divide_iff_number_of", (*excessive case analysis*)
   363    "NatSimprocs.zero_less_divide_iff_number_of",
   364    "OrderedGroup.abs_0_eq", (*duplicate by symmetry*)
   365    "OrderedGroup.diff_eq_0_iff_eq", (*prolific?*)
   366    "OrderedGroup.join_0_eq_0",
   367    "OrderedGroup.meet_0_eq_0",
   368    "OrderedGroup.pprt_eq_0",   (*obscure*)
   369    "OrderedGroup.pprt_eq_id",   (*obscure*)
   370    "OrderedGroup.pprt_mono",   (*obscure*)
   371    "Orderings.split_max",      (*splitting theorem*)
   372    "Orderings.split_min",      (*splitting theorem*)
   373    "Parity.even_nat_power",   (*obscure, somewhat prolilfic*)
   374    "Parity.power_eq_0_iff_number_of",
   375    "Parity.power_le_zero_eq_number_of",   (*obscure and prolific*)
   376    "Parity.power_less_zero_eq_number_of",
   377    "Parity.zero_le_power_eq_number_of",   (*obscure and prolific*)
   378    "Parity.zero_less_power_eq_number_of",   (*obscure and prolific*)
   379    "Power.zero_less_power_abs_iff",
   380    "Product_Type.split_eta_SetCompr",   (*involves an existential quantifier*)
   381    "Product_Type.split_paired_Ball_Sigma",     (*splitting theorem*)
   382    "Product_Type.split_paired_Bex_Sigma",      (*splitting theorem*)
   383    "Product_Type.split_split_asm",             (*splitting theorem*)
   384    "Product_Type.split_split",                 (*splitting theorem*)
   385    "Product_Type.unit_abs_eta_conv",
   386    "Product_Type.unit_induct",
   387    "Relation.diagI",
   388    "Relation.Domain_def",   (*involves an existential quantifier*)
   389    "Relation.Image_def",   (*involves an existential quantifier*)
   390    "Relation.ImageI",
   391    "Ring_and_Field.divide_cancel_left", (*fields are seldom used & often prolific*)
   392    "Ring_and_Field.divide_cancel_right",
   393    "Ring_and_Field.divide_divide_eq_left",
   394    "Ring_and_Field.divide_divide_eq_right",
   395    "Ring_and_Field.divide_eq_0_iff",
   396    "Ring_and_Field.divide_eq_1_iff",
   397    "Ring_and_Field.divide_eq_eq_1",
   398    "Ring_and_Field.divide_le_0_1_iff",
   399    "Ring_and_Field.divide_le_eq_1_neg",  (*obscure and prolific*)
   400    "Ring_and_Field.divide_le_eq_1_pos",  (*obscure and prolific*)
   401    "Ring_and_Field.divide_less_0_1_iff",
   402    "Ring_and_Field.divide_less_eq_1_neg",  (*obscure and prolific*)
   403    "Ring_and_Field.divide_less_eq_1_pos",  (*obscure and prolific*)
   404    "Ring_and_Field.eq_divide_eq_1", (*duplicate by symmetry*)
   405    "Ring_and_Field.field_mult_cancel_left",
   406    "Ring_and_Field.field_mult_cancel_right",
   407    "Ring_and_Field.inverse_le_iff_le_neg",
   408    "Ring_and_Field.inverse_le_iff_le",
   409    "Ring_and_Field.inverse_less_iff_less_neg",
   410    "Ring_and_Field.inverse_less_iff_less",
   411    "Ring_and_Field.le_divide_eq_1_neg", (*obscure and prolific*)
   412    "Ring_and_Field.le_divide_eq_1_pos", (*obscure and prolific*)
   413    "Ring_and_Field.less_divide_eq_1_neg", (*obscure and prolific*)
   414    "Ring_and_Field.less_divide_eq_1_pos", (*obscure and prolific*)
   415    "Ring_and_Field.one_eq_divide_iff",  (*duplicate by symmetry*)
   416    "Set.ball_simps", "Set.bex_simps",   (*quantifier rewriting: useless*)
   417    "Set.Collect_bex_eq",   (*involves an existential quantifier*)
   418    "Set.Collect_ex_eq",   (*involves an existential quantifier*)
   419    "Set.Diff_eq_empty_iff", (*redundant with paramodulation*)
   420    "Set.Diff_insert0",
   421    "Set.disjoint_insert",
   422    "Set.empty_Union_conv",   (*redundant with paramodulation*)
   423    "Set.full_SetCompr_eq",   (*involves an existential quantifier*)
   424    "Set.image_Collect",      (*involves an existential quantifier*)
   425    "Set.image_def",          (*involves an existential quantifier*)
   426    "Set.insert_disjoint",
   427    "Set.Int_UNIV",  (*redundant with paramodulation*)
   428    "Set.Inter_iff", (*We already have InterI, InterE*)
   429    "Set.Inter_UNIV_conv",
   430    "Set.psubsetE",    (*too prolific and obscure*)
   431    "Set.psubsetI",
   432    "Set.singleton_insert_inj_eq'",
   433    "Set.singleton_insert_inj_eq",
   434    "Set.singletonD",  (*these two duplicate some "insert" lemmas*)
   435    "Set.singletonI",
   436    "Set.Un_empty", (*redundant with paramodulation*)
   437    "Set.UNION_def",   (*involves an existential quantifier*)
   438    "Set.Union_empty_conv", (*redundant with paramodulation*)
   439    "Set.Union_iff",              (*We already have UnionI, UnionE*)
   440    "SetInterval.atLeastAtMost_iff", (*obscure and prolific*)
   441    "SetInterval.atLeastLessThan_iff", (*obscure and prolific*)
   442    "SetInterval.greaterThanAtMost_iff", (*obscure and prolific*)
   443    "SetInterval.greaterThanLessThan_iff", (*obscure and prolific*)
   444    "SetInterval.ivl_subset"];  (*excessive case analysis*)
   445 
   446 
   447 (*These might be prolific but are probably OK, and min and max are basic.
   448    "Orderings.max_less_iff_conj", 
   449    "Orderings.min_less_iff_conj",
   450    "Orderings.min_max.below_inf.below_inf_conv",
   451    "Orderings.min_max.below_sup.above_sup_conv",
   452 Very prolific and somewhat obscure:
   453    "Set.InterD",
   454    "Set.UnionI",
   455 *)
   456 
   457 (*** retrieve lemmas from clasimpset and atpset, may filter them ***)
   458 
   459 (*Hashing to detect duplicate and variant clauses, e.g. from the [iff] attribute*)
   460 
   461 exception HASH_CLAUSE and HASH_STRING;
   462 
   463 (*Catches (for deletion) theorems automatically generated from other theorems*)
   464 fun insert_suffixed_names ht x = 
   465      (Polyhash.insert ht (x^"_iff1", ()); 
   466       Polyhash.insert ht (x^"_iff2", ()); 
   467       Polyhash.insert ht (x^"_dest", ())); 
   468 
   469 (*Are all characters in this string digits?*)
   470 fun all_numeric s = null (String.tokens Char.isDigit s);
   471 
   472 (*Delete a suffix of the form _\d+*)
   473 fun delete_numeric_suffix s =
   474   case rev (String.fields (fn c => c = #"_") s) of
   475       last::rest => 
   476           if all_numeric last 
   477           then [s, space_implode "_" (rev rest)]
   478           else [s]
   479     | [] => [s];
   480 
   481 fun banned_thmlist s =
   482   (Sign.base_name s) mem_string ["induct","inducts","split","splits","split_asm"];
   483 
   484 fun make_banned_test xs = 
   485   let val ht = Polyhash.mkTable (Polyhash.hash_string, op =)
   486                                 (6000, HASH_STRING)
   487       fun banned_aux s = isSome (Polyhash.peek ht s) orelse banned_thmlist s
   488       fun banned s = exists banned_aux (delete_numeric_suffix s)
   489   in  app (fn x => Polyhash.insert ht (x,())) (!blacklist);
   490       app (insert_suffixed_names ht) (!blacklist @ xs); 
   491       banned
   492   end;
   493 
   494 (** a hash function from Term.term to int, and also a hash table **)
   495 val xor_words = List.foldl Word.xorb 0w0;
   496 
   497 fun hashw_term ((Const(c,_)), w) = Polyhash.hashw_string (c,w)
   498   | hashw_term ((Free(a,_)), w) = Polyhash.hashw_string (a,w)
   499   | hashw_term ((Var(_,_)), w) = w
   500   | hashw_term ((Bound i), w) = Polyhash.hashw_int(i,w)
   501   | hashw_term ((Abs(_,_,t)), w) = hashw_term (t, w)
   502   | hashw_term ((P$Q), w) = hashw_term (Q, (hashw_term (P, w)));
   503 
   504 fun hashw_pred (P,w) = 
   505     let val (p,args) = strip_comb P
   506     in
   507 	List.foldl hashw_term w (p::args)
   508     end;
   509 
   510 fun hash_literal (Const("Not",_)$P) = Word.notb(hashw_pred(P,0w0))
   511   | hash_literal P = hashw_pred(P,0w0);
   512 
   513 
   514 fun get_literals (Const("Trueprop",_)$P) lits = get_literals P lits
   515   | get_literals (Const("op |",_)$P$Q) lits = get_literals Q (get_literals P lits)
   516   | get_literals lit lits = (lit::lits);
   517 
   518 
   519 fun hash_term t = Word.toIntX (xor_words (map hash_literal (get_literals t [])));
   520 
   521 (*Versions ONLY for "faking" a theorem name. Here we take variable names into account
   522   so that similar theorems don't collide.  FIXME: this entire business of "faking" 
   523   theorem names must end!*)
   524 fun hashw_typ (TVar ((a,i), _), w) = Polyhash.hashw_string (a, Polyhash.hashw_int(i,w))
   525   | hashw_typ (TFree (a,_), w) = Polyhash.hashw_string (a,w)
   526   | hashw_typ (Type (a, Ts), w) = Polyhash.hashw_string (a, List.foldl hashw_typ w Ts);
   527 
   528 fun full_hashw_term ((Const(c,T)), w) = Polyhash.hashw_string (c, hashw_typ(T,w))
   529   | full_hashw_term ((Free(a,_)), w) = Polyhash.hashw_string (a,w)
   530   | full_hashw_term ((Var((a,i),_)), w) = Polyhash.hashw_string (a, Polyhash.hashw_int(i,w))
   531   | full_hashw_term ((Bound i), w) = Polyhash.hashw_int(i,w)
   532   | full_hashw_term ((Abs(_,T,t)), w) = full_hashw_term (t, hashw_typ(T,w))
   533   | full_hashw_term ((P$Q), w) = full_hashw_term (Q, (full_hashw_term (P, w)));
   534 
   535 fun full_hashw_thm (th,w) = 
   536   let val {prop,hyps,...} = rep_thm th
   537   in List.foldl full_hashw_term w (prop::hyps) end
   538 
   539 fun full_hash_thm th = full_hashw_thm (th,0w0);
   540 
   541 fun equal_thm (thm1,thm2) = Term.aconv(prop_of thm1, prop_of thm2);
   542 
   543 (*Create a hash table for clauses, of the given size*)
   544 fun mk_clause_table n =
   545       Polyhash.mkTable (hash_term o prop_of, equal_thm)
   546                        (n, HASH_CLAUSE);
   547 
   548 (*Use a hash table to eliminate duplicates from xs. Argument is a list of
   549   (name, theorem) pairs, but the theorems are hashed into the table. *)
   550 fun make_unique xs = 
   551   let val ht = mk_clause_table 2200
   552   in
   553       (app (ignore o Polyhash.peekInsert ht) (map swap xs);  
   554        map swap (Polyhash.listItems ht))
   555   end;
   556 
   557 (*FIXME: SLOW!!!*)
   558 fun mem_thm th [] = false
   559   | mem_thm th ((th',_)::thms_names) = equal_thm (th,th') orelse mem_thm th thms_names;
   560 
   561 (*FIXME: SLOW!!! These two functions are called only by get_relevant_clauses.
   562   It would be faster to compare names, rather than theorems, and to use
   563   a symbol table or hash table.*)
   564 fun insert_thms [] thms_names = thms_names
   565   | insert_thms ((thm,name)::thms_names) thms_names' =
   566       if mem_thm thm thms_names' then insert_thms thms_names thms_names' 
   567       else insert_thms thms_names ((thm,name)::thms_names');
   568 
   569 (* filter axiom clauses, but keep supplied clauses and clauses in whitelist *)
   570 fun get_relevant_clauses thy cls_thms white_cls goals =
   571   insert_thms white_cls (ReduceAxiomsN.relevance_filter thy cls_thms goals);
   572 
   573 (*This name is cryptic but short. Unlike gensym, we get the same name each time.*)
   574 fun fake_thm_name th = 
   575     Context.theory_name (theory_of_thm th) ^ "." ^ Word.toString (full_hash_thm th);
   576 
   577 fun put_name_pair ("",th) = (fake_thm_name th, th)
   578   | put_name_pair (a,th)  = (a,th);
   579 
   580 fun display_thms [] = ()
   581   | display_thms ((name,thm)::nthms) = 
   582       let val nthm = name ^ ": " ^ (string_of_thm thm)
   583       in Output.debug nthm; display_thms nthms  end;
   584  
   585 fun all_facts_of ctxt =
   586   FactIndex.find (ProofContext.fact_index_of ctxt) ([], [])
   587   |> maps #2 |> map (`Thm.name_of_thm);
   588 
   589 (* get lemmas from claset, simpset, atpset and extra supplied rules *)
   590 fun get_clasimp_atp_lemmas ctxt user_thms = 
   591   let val included_thms =
   592 	if !include_all 
   593 	then (tap (fn ths => Output.debug
   594 	             ("Including all " ^ Int.toString (length ths) ^ " theorems")) 
   595 	          (all_facts_of ctxt @ PureThy.all_thms_of (ProofContext.theory_of ctxt)))
   596 	else 
   597 	let val claset_thms =
   598 		if !include_claset then ResAxioms.claset_rules_of_ctxt ctxt
   599 		else []
   600 	    val simpset_thms = 
   601 		if !include_simpset then ResAxioms.simpset_rules_of_ctxt ctxt
   602 		else []
   603 	    val atpset_thms =
   604 		if !include_atpset then ResAxioms.atpset_rules_of_ctxt ctxt
   605 		else []
   606 	    val _ = if !Output.show_debug_msgs 
   607 		    then (Output.debug "ATP theorems: "; display_thms atpset_thms) 
   608 		    else ()		 
   609 	in  claset_thms @ simpset_thms @ atpset_thms  end
   610       val user_rules = map (put_name_pair o ResAxioms.pairname)
   611 			   (if null user_thms then !whitelist else user_thms)
   612   in
   613       (map put_name_pair included_thms, user_rules)
   614   end;
   615 
   616 (*Remove lemmas that are banned from the backlist. Also remove duplicates. *)
   617 fun blacklist_filter thms = 
   618   if !run_blacklist_filter then 
   619       let val banned = make_banned_test (map #1 thms)
   620 	  fun ok (a,_) = not (banned a)
   621       in  filter ok thms  end
   622   else thms;
   623 
   624 
   625 (***************************************************************)
   626 (* ATP invocation methods setup                                *)
   627 (***************************************************************)
   628 
   629 fun cnf_hyps_thms ctxt = 
   630     let val ths = Assumption.prems_of ctxt
   631     in fold (fold (insert Thm.eq_thm) o ResAxioms.skolem_thm) ths [] end;
   632 
   633 (*Translation mode can be auto-detected, or forced to be first-order or higher-order*)
   634 datatype mode = Auto | Fol | Hol;
   635 
   636 val linkup_logic_mode = ref Auto;
   637 
   638 (*Ensures that no higher-order theorems "leak out"*)
   639 fun restrict_to_logic logic cls =
   640   if is_fol_logic logic then filter (Meson.is_fol_term o prop_of o fst) cls 
   641 	                else cls;
   642 
   643 fun tptp_writer logic goals filename (axioms,classrels,arities) user_lemmas =
   644     if is_fol_logic logic 
   645     then ResClause.tptp_write_file goals filename (axioms, classrels, arities)
   646     else ResHolClause.tptp_write_file goals filename (axioms, classrels, arities) user_lemmas;
   647 
   648 fun dfg_writer logic goals filename (axioms,classrels,arities) user_lemmas =
   649     if is_fol_logic logic 
   650     then ResClause.dfg_write_file goals filename (axioms, classrels, arities)
   651     else ResHolClause.dfg_write_file goals filename (axioms, classrels, arities) user_lemmas;
   652 
   653 (*Called by the oracle-based methods declared in res_atp_methods.ML*)
   654 fun write_subgoal_file dfg mode ctxt conjectures user_thms n =
   655     let val conj_cls = make_clauses conjectures 
   656                          |> ResAxioms.assume_abstract_list |> Meson.finish_cnf
   657 	val hyp_cls = cnf_hyps_thms ctxt
   658 	val goal_cls = conj_cls@hyp_cls
   659 	val logic = case mode of 
   660                             Auto => problem_logic_goals [map prop_of goal_cls]
   661 			  | Fol => FOL
   662 			  | Hol => HOL
   663 	val (included_thms,user_rules) = get_clasimp_atp_lemmas ctxt user_thms
   664 	val user_lemmas_names = map #1 user_rules
   665 	val cla_simp_atp_clauses = included_thms |> blacklist_filter
   666 	                             |> make_unique |> ResAxioms.cnf_rules_pairs
   667                                      |> restrict_to_logic logic 
   668 	val user_cls = ResAxioms.cnf_rules_pairs user_rules
   669 	val thy = ProofContext.theory_of ctxt
   670 	val axclauses = get_relevant_clauses thy cla_simp_atp_clauses
   671 	                            user_cls (map prop_of goal_cls)
   672 	val keep_types = if is_fol_logic logic then !fol_keep_types else is_typed_hol ()
   673 	val classrel_clauses = if keep_types then ResClause.classrel_clauses_thy thy else []
   674 	val arity_clauses = if keep_types then ResClause.arity_clause_thy thy else []
   675         val writer = if dfg then dfg_writer else tptp_writer 
   676 	val file = atp_input_file()
   677     in
   678 	(writer logic goal_cls file (axclauses,classrel_clauses,arity_clauses) user_lemmas_names;
   679 	 Output.debug ("Writing to " ^ file);
   680 	 file)
   681     end;
   682 
   683 
   684 (**** remove tmp files ****)
   685 fun cond_rm_tmp file = 
   686     if !keep_atp_input then Output.debug "ATP input kept..." 
   687     else if !destdir <> "" then Output.debug ("ATP input kept in directory " ^ (!destdir))
   688     else (Output.debug "deleting ATP inputs..."; OS.FileSys.remove file);
   689 
   690 
   691 (****** setup ATPs as Isabelle methods ******)
   692 fun atp_meth' tac ths ctxt = 
   693     Method.SIMPLE_METHOD' HEADGOAL
   694     (tac ctxt ths);
   695 
   696 fun atp_meth tac ths ctxt = 
   697     let val thy = ProofContext.theory_of ctxt
   698 	val _ = ResClause.init thy
   699 	val _ = ResHolClause.init thy
   700     in
   701 	atp_meth' tac ths ctxt
   702     end;
   703 
   704 fun atp_method tac = Method.thms_ctxt_args (atp_meth tac);
   705 
   706 (***************************************************************)
   707 (* automatic ATP invocation                                    *)
   708 (***************************************************************)
   709 
   710 (* call prover with settings and problem file for the current subgoal *)
   711 fun watcher_call_provers sign sg_terms (childin, childout, pid) =
   712   let
   713     fun make_atp_list [] n = []
   714       | make_atp_list (sg_term::xs) n =
   715           let
   716             val probfile = prob_pathname n
   717             val time = Int.toString (!time_limit)
   718           in
   719             Output.debug ("problem file in watcher_call_provers is " ^ probfile);
   720             (*options are separated by Watcher.setting_sep, currently #"%"*)
   721             if !prover = "spass"
   722             then
   723               let val spass = helper_path "SPASS_HOME" "SPASS"
   724                   val sopts =
   725    "-Auto%-SOS=1%-PGiven=0%-PProblem=0%-Splits=0%-FullRed=0%-DocProof%-TimeLimit=" ^ time
   726               in 
   727                   ("spass", spass, sopts, probfile) :: make_atp_list xs (n+1)
   728               end
   729             else if !prover = "vampire"
   730 	    then 
   731               let val vampire = helper_path "VAMPIRE_HOME" "vampire"
   732                   val casc = if !time_limit > 70 then "--mode casc%" else ""
   733                   val vopts = casc ^ "-m 100000%-t " ^ time
   734               in
   735                   ("vampire", vampire, vopts, probfile) :: make_atp_list xs (n+1)
   736               end
   737       	     else if !prover = "E"
   738       	     then
   739 	       let val Eprover = helper_path "E_HOME" "eproof"
   740 	       in
   741 		  ("E", Eprover, 
   742 		     "--tptp-in%-l5%-xAuto%-tAuto%--silent%--cpu-limit=" ^ time, probfile) ::
   743 		   make_atp_list xs (n+1)
   744 	       end
   745 	     else error ("Invalid prover name: " ^ !prover)
   746           end
   747 
   748     val atp_list = make_atp_list sg_terms 1
   749   in
   750     Watcher.callResProvers(childout,atp_list);
   751     Output.debug "Sent commands to watcher!"
   752   end
   753   
   754 fun trace_array fname =
   755   let val path = File.tmp_path (Path.basic fname)
   756   in  Array.app (File.append path o (fn s => s ^ "\n"))  end;
   757 
   758 (*Converting a subgoal into negated conjecture clauses*)
   759 fun neg_clauses th n =
   760   let val tacs = [rtac ccontr, ObjectLogic.atomize_tac, skolemize_tac]
   761       val st = Seq.hd (EVERY' tacs n th)
   762       val negs = Option.valOf (metahyps_thms n st)
   763   in make_clauses negs |> ResAxioms.assume_abstract_list |> Meson.finish_cnf end;
   764 		                       
   765 (*We write out problem files for each subgoal. Argument probfile generates filenames,
   766   and allows the suppression of the suffix "_1" in problem-generation mode.
   767   FIXME: does not cope with &&, and it isn't easy because one could have multiple
   768   subgoals, each involving &&.*)
   769 fun write_problem_files probfile (ctxt,th)  =
   770   let val goals = Thm.prems_of th
   771       val _ = Output.debug ("number of subgoals = " ^ Int.toString (length goals))
   772       val thy = ProofContext.theory_of ctxt
   773       fun get_neg_subgoals [] _ = []
   774         | get_neg_subgoals (gl::gls) n = neg_clauses th n :: get_neg_subgoals gls (n+1)
   775       val goal_cls = get_neg_subgoals goals 1
   776       val logic = case !linkup_logic_mode of
   777 		Auto => problem_logic_goals (map ((map prop_of)) goal_cls)
   778 	      | Fol => FOL
   779 	      | Hol => HOL
   780       val (included_thms,white_thms) = get_clasimp_atp_lemmas ctxt []
   781       val included_cls = included_thms |> blacklist_filter
   782                                        |> make_unique |> ResAxioms.cnf_rules_pairs 
   783                                        |> restrict_to_logic logic 
   784       val white_cls = ResAxioms.cnf_rules_pairs white_thms
   785       (*clauses relevant to goal gl*)
   786       val axcls_list = map (fn gl => get_relevant_clauses thy included_cls white_cls [gl])
   787                            goals
   788       val _ = Output.debug ("clauses = " ^ Int.toString(length included_cls))
   789       val keep_types = if is_fol_logic logic then !ResClause.keep_types 
   790                        else is_typed_hol ()
   791       val classrel_clauses = if keep_types then ResClause.classrel_clauses_thy thy
   792                              else []
   793       val _ = Output.debug ("classrel clauses = " ^ 
   794                             Int.toString (length classrel_clauses))
   795       val arity_clauses = if keep_types then ResClause.arity_clause_thy thy 
   796                           else []
   797       val _ = Output.debug ("arity clauses = " ^ Int.toString (length arity_clauses))
   798       val writer = if !prover = "spass" then dfg_writer else tptp_writer 
   799       fun write_all [] [] _ = []
   800 	| write_all (ccls::ccls_list) (axcls::axcls_list) k =
   801 	   (writer logic ccls (probfile k) (axcls,classrel_clauses,arity_clauses) [],
   802 	    probfile k) 
   803 	   :: write_all ccls_list axcls_list (k+1)
   804       val (clnames::_, filenames) = ListPair.unzip (write_all goal_cls axcls_list 1)
   805       val thm_names = Array.fromList clnames
   806       val _ = if !Output.show_debug_msgs 
   807               then trace_array "thm_names" thm_names else ()
   808   in
   809       (filenames, thm_names)
   810   end;
   811 
   812 val last_watcher_pid = ref (NONE : (TextIO.instream * TextIO.outstream * 
   813                                     Posix.Process.pid * string list) option);
   814 
   815 fun kill_last_watcher () =
   816     (case !last_watcher_pid of 
   817          NONE => ()
   818        | SOME (_, _, pid, files) => 
   819 	  (Output.debug ("Killing old watcher, pid = " ^ string_of_pid pid);
   820 	   Watcher.killWatcher pid;  
   821 	   ignore (map (try OS.FileSys.remove) files)))
   822      handle OS.SysErr _ => Output.debug "Attempt to kill watcher failed";
   823 
   824 (*writes out the current clasimpset to a tptp file;
   825   turns off xsymbol at start of function, restoring it at end    *)
   826 val isar_atp = setmp print_mode [] 
   827  (fn (ctxt, th) =>
   828   if Thm.no_prems th then ()
   829   else
   830     let
   831       val _ = kill_last_watcher()
   832       val (files,thm_names) = write_problem_files prob_pathname (ctxt,th)
   833       val (childin, childout, pid) = Watcher.createWatcher (th, thm_names)
   834     in
   835       last_watcher_pid := SOME (childin, childout, pid, files);
   836       Output.debug ("problem files: " ^ space_implode ", " files); 
   837       Output.debug ("pid: " ^ string_of_pid pid);
   838       watcher_call_provers (sign_of_thm th) (Thm.prems_of th) (childin, childout, pid)
   839     end);
   840 
   841 val isar_atp_writeonly = setmp print_mode [] 
   842       (fn (ctxt,th) =>
   843        if Thm.no_prems th then ()
   844        else 
   845          let val probfile = if Thm.nprems_of th = 1 then probfile_nosuffix 
   846           	            else prob_pathname
   847          in ignore (write_problem_files probfile (ctxt,th)) end);
   848 
   849 
   850 (** the Isar toplevel hook **)
   851 
   852 fun invoke_atp_ml (ctxt, goal) =
   853   let val thy = ProofContext.theory_of ctxt;
   854   in
   855     Output.debug ("subgoals in isar_atp:\n" ^ 
   856 		  Pretty.string_of (ProofContext.pretty_term ctxt
   857 		    (Logic.mk_conjunction_list (Thm.prems_of goal))));
   858     Output.debug ("current theory: " ^ Context.theory_name thy);
   859     inc hook_count;
   860     Output.debug ("in hook for time: " ^ Int.toString (!hook_count));
   861     ResClause.init thy;
   862     ResHolClause.init thy;
   863     if !destdir = "" andalso !time_limit > 0 then isar_atp (ctxt, goal)
   864     else isar_atp_writeonly (ctxt, goal)
   865   end;
   866 
   867 val invoke_atp = Toplevel.no_timing o Toplevel.unknown_proof o Toplevel.keep
   868  (fn state =>
   869   let val (ctxt, (_, goal)) = Proof.get_goal (Toplevel.proof_of state)
   870   in  invoke_atp_ml (ctxt, goal)  end);
   871 
   872 val call_atpP =
   873   OuterSyntax.command 
   874     "ProofGeneral.call_atp" 
   875     "call automatic theorem provers" 
   876     OuterKeyword.diag
   877     (Scan.succeed invoke_atp);
   878 
   879 val _ = OuterSyntax.add_parsers [call_atpP];
   880 
   881 end;