src/HOL/Wellfounded.thy
author bulwahn
Wed Jan 25 16:07:48 2012 +0100 (2012-01-25)
changeset 46333 46c2c96f5d92
parent 46177 adac34829e10
child 46349 b159ca4e268b
permissions -rw-r--r--
adding very basic code generation to Wellfounded theory
     1 (*  Title:      HOL/Wellfounded.thy
     2     Author:     Tobias Nipkow
     3     Author:     Lawrence C Paulson
     4     Author:     Konrad Slind
     5     Author:     Alexander Krauss
     6 *)
     7 
     8 header {*Well-founded Recursion*}
     9 
    10 theory Wellfounded
    11 imports Transitive_Closure
    12 uses ("Tools/Function/size.ML")
    13 begin
    14 
    15 subsection {* Basic Definitions *}
    16 
    17 definition wf :: "('a * 'a) set => bool" where
    18   "wf r \<longleftrightarrow> (!P. (!x. (!y. (y,x):r --> P(y)) --> P(x)) --> (!x. P(x)))"
    19 
    20 definition wfP :: "('a => 'a => bool) => bool" where
    21   "wfP r \<longleftrightarrow> wf {(x, y). r x y}"
    22 
    23 lemma wfP_wf_eq [pred_set_conv]: "wfP (\<lambda>x y. (x, y) \<in> r) = wf r"
    24   by (simp add: wfP_def)
    25 
    26 lemma wfUNIVI: 
    27    "(!!P x. (ALL x. (ALL y. (y,x) : r --> P(y)) --> P(x)) ==> P(x)) ==> wf(r)"
    28   unfolding wf_def by blast
    29 
    30 lemmas wfPUNIVI = wfUNIVI [to_pred]
    31 
    32 text{*Restriction to domain @{term A} and range @{term B}.  If @{term r} is
    33     well-founded over their intersection, then @{term "wf r"}*}
    34 lemma wfI: 
    35  "[| r \<subseteq> A <*> B; 
    36      !!x P. [|\<forall>x. (\<forall>y. (y,x) : r --> P y) --> P x;  x : A; x : B |] ==> P x |]
    37   ==>  wf r"
    38   unfolding wf_def by blast
    39 
    40 lemma wf_induct: 
    41     "[| wf(r);           
    42         !!x.[| ALL y. (y,x): r --> P(y) |] ==> P(x)  
    43      |]  ==>  P(a)"
    44   unfolding wf_def by blast
    45 
    46 lemmas wfP_induct = wf_induct [to_pred]
    47 
    48 lemmas wf_induct_rule = wf_induct [rule_format, consumes 1, case_names less, induct set: wf]
    49 
    50 lemmas wfP_induct_rule = wf_induct_rule [to_pred, induct set: wfP]
    51 
    52 lemma wf_not_sym: "wf r ==> (a, x) : r ==> (x, a) ~: r"
    53   by (induct a arbitrary: x set: wf) blast
    54 
    55 lemma wf_asym:
    56   assumes "wf r" "(a, x) \<in> r"
    57   obtains "(x, a) \<notin> r"
    58   by (drule wf_not_sym[OF assms])
    59 
    60 lemma wf_not_refl [simp]: "wf r ==> (a, a) ~: r"
    61   by (blast elim: wf_asym)
    62 
    63 lemma wf_irrefl: assumes "wf r" obtains "(a, a) \<notin> r"
    64 by (drule wf_not_refl[OF assms])
    65 
    66 lemma wf_wellorderI:
    67   assumes wf: "wf {(x::'a::ord, y). x < y}"
    68   assumes lin: "OFCLASS('a::ord, linorder_class)"
    69   shows "OFCLASS('a::ord, wellorder_class)"
    70 using lin by (rule wellorder_class.intro)
    71   (blast intro: class.wellorder_axioms.intro wf_induct_rule [OF wf])
    72 
    73 lemma (in wellorder) wf:
    74   "wf {(x, y). x < y}"
    75 unfolding wf_def by (blast intro: less_induct)
    76 
    77 
    78 subsection {* Basic Results *}
    79 
    80 text {* Point-free characterization of well-foundedness *}
    81 
    82 lemma wfE_pf:
    83   assumes wf: "wf R"
    84   assumes a: "A \<subseteq> R `` A"
    85   shows "A = {}"
    86 proof -
    87   { fix x
    88     from wf have "x \<notin> A"
    89     proof induct
    90       fix x assume "\<And>y. (y, x) \<in> R \<Longrightarrow> y \<notin> A"
    91       then have "x \<notin> R `` A" by blast
    92       with a show "x \<notin> A" by blast
    93     qed
    94   } thus ?thesis by auto
    95 qed
    96 
    97 lemma wfI_pf:
    98   assumes a: "\<And>A. A \<subseteq> R `` A \<Longrightarrow> A = {}"
    99   shows "wf R"
   100 proof (rule wfUNIVI)
   101   fix P :: "'a \<Rightarrow> bool" and x
   102   let ?A = "{x. \<not> P x}"
   103   assume "\<forall>x. (\<forall>y. (y, x) \<in> R \<longrightarrow> P y) \<longrightarrow> P x"
   104   then have "?A \<subseteq> R `` ?A" by blast
   105   with a show "P x" by blast
   106 qed
   107 
   108 text{*Minimal-element characterization of well-foundedness*}
   109 
   110 lemma wfE_min:
   111   assumes wf: "wf R" and Q: "x \<in> Q"
   112   obtains z where "z \<in> Q" "\<And>y. (y, z) \<in> R \<Longrightarrow> y \<notin> Q"
   113   using Q wfE_pf[OF wf, of Q] by blast
   114 
   115 lemma wfI_min:
   116   assumes a: "\<And>x Q. x \<in> Q \<Longrightarrow> \<exists>z\<in>Q. \<forall>y. (y, z) \<in> R \<longrightarrow> y \<notin> Q"
   117   shows "wf R"
   118 proof (rule wfI_pf)
   119   fix A assume b: "A \<subseteq> R `` A"
   120   { fix x assume "x \<in> A"
   121     from a[OF this] b have "False" by blast
   122   }
   123   thus "A = {}" by blast
   124 qed
   125 
   126 lemma wf_eq_minimal: "wf r = (\<forall>Q x. x\<in>Q --> (\<exists>z\<in>Q. \<forall>y. (y,z)\<in>r --> y\<notin>Q))"
   127 apply auto
   128 apply (erule wfE_min, assumption, blast)
   129 apply (rule wfI_min, auto)
   130 done
   131 
   132 lemmas wfP_eq_minimal = wf_eq_minimal [to_pred]
   133 
   134 text{* Well-foundedness of transitive closure *}
   135 
   136 lemma wf_trancl:
   137   assumes "wf r"
   138   shows "wf (r^+)"
   139 proof -
   140   {
   141     fix P and x
   142     assume induct_step: "!!x. (!!y. (y, x) : r^+ ==> P y) ==> P x"
   143     have "P x"
   144     proof (rule induct_step)
   145       fix y assume "(y, x) : r^+"
   146       with `wf r` show "P y"
   147       proof (induct x arbitrary: y)
   148         case (less x)
   149         note hyp = `\<And>x' y'. (x', x) : r ==> (y', x') : r^+ ==> P y'`
   150         from `(y, x) : r^+` show "P y"
   151         proof cases
   152           case base
   153           show "P y"
   154           proof (rule induct_step)
   155             fix y' assume "(y', y) : r^+"
   156             with `(y, x) : r` show "P y'" by (rule hyp [of y y'])
   157           qed
   158         next
   159           case step
   160           then obtain x' where "(x', x) : r" and "(y, x') : r^+" by simp
   161           then show "P y" by (rule hyp [of x' y])
   162         qed
   163       qed
   164     qed
   165   } then show ?thesis unfolding wf_def by blast
   166 qed
   167 
   168 lemmas wfP_trancl = wf_trancl [to_pred]
   169 
   170 lemma wf_converse_trancl: "wf (r^-1) ==> wf ((r^+)^-1)"
   171   apply (subst trancl_converse [symmetric])
   172   apply (erule wf_trancl)
   173   done
   174 
   175 text {* Well-foundedness of subsets *}
   176 
   177 lemma wf_subset: "[| wf(r);  p<=r |] ==> wf(p)"
   178   apply (simp (no_asm_use) add: wf_eq_minimal)
   179   apply fast
   180   done
   181 
   182 lemmas wfP_subset = wf_subset [to_pred]
   183 
   184 text {* Well-foundedness of the empty relation *}
   185 
   186 lemma wf_empty [iff]: "wf {}"
   187   by (simp add: wf_def)
   188 
   189 lemma wfP_empty [iff]:
   190   "wfP (\<lambda>x y. False)"
   191 proof -
   192   have "wfP bot" by (fact wf_empty [to_pred bot_empty_eq2])
   193   then show ?thesis by (simp add: bot_fun_def)
   194 qed
   195 
   196 lemma wf_Int1: "wf r ==> wf (r Int r')"
   197   apply (erule wf_subset)
   198   apply (rule Int_lower1)
   199   done
   200 
   201 lemma wf_Int2: "wf r ==> wf (r' Int r)"
   202   apply (erule wf_subset)
   203   apply (rule Int_lower2)
   204   done  
   205 
   206 text {* Exponentiation *}
   207 
   208 lemma wf_exp:
   209   assumes "wf (R ^^ n)"
   210   shows "wf R"
   211 proof (rule wfI_pf)
   212   fix A assume "A \<subseteq> R `` A"
   213   then have "A \<subseteq> (R ^^ n) `` A" by (induct n) force+
   214   with `wf (R ^^ n)`
   215   show "A = {}" by (rule wfE_pf)
   216 qed
   217 
   218 text {* Well-foundedness of insert *}
   219 
   220 lemma wf_insert [iff]: "wf(insert (y,x) r) = (wf(r) & (x,y) ~: r^*)"
   221 apply (rule iffI)
   222  apply (blast elim: wf_trancl [THEN wf_irrefl]
   223               intro: rtrancl_into_trancl1 wf_subset 
   224                      rtrancl_mono [THEN [2] rev_subsetD])
   225 apply (simp add: wf_eq_minimal, safe)
   226 apply (rule allE, assumption, erule impE, blast) 
   227 apply (erule bexE)
   228 apply (rename_tac "a", case_tac "a = x")
   229  prefer 2
   230 apply blast 
   231 apply (case_tac "y:Q")
   232  prefer 2 apply blast
   233 apply (rule_tac x = "{z. z:Q & (z,y) : r^*}" in allE)
   234  apply assumption
   235 apply (erule_tac V = "ALL Q. (EX x. x : Q) --> ?P Q" in thin_rl) 
   236   --{*essential for speed*}
   237 txt{*Blast with new substOccur fails*}
   238 apply (fast intro: converse_rtrancl_into_rtrancl)
   239 done
   240 
   241 text{*Well-foundedness of image*}
   242 
   243 lemma wf_map_pair_image: "[| wf r; inj f |] ==> wf(map_pair f f ` r)"
   244 apply (simp only: wf_eq_minimal, clarify)
   245 apply (case_tac "EX p. f p : Q")
   246 apply (erule_tac x = "{p. f p : Q}" in allE)
   247 apply (fast dest: inj_onD, blast)
   248 done
   249 
   250 
   251 subsection {* Well-Foundedness Results for Unions *}
   252 
   253 lemma wf_union_compatible:
   254   assumes "wf R" "wf S"
   255   assumes "R O S \<subseteq> R"
   256   shows "wf (R \<union> S)"
   257 proof (rule wfI_min)
   258   fix x :: 'a and Q 
   259   let ?Q' = "{x \<in> Q. \<forall>y. (y, x) \<in> R \<longrightarrow> y \<notin> Q}"
   260   assume "x \<in> Q"
   261   obtain a where "a \<in> ?Q'"
   262     by (rule wfE_min [OF `wf R` `x \<in> Q`]) blast
   263   with `wf S`
   264   obtain z where "z \<in> ?Q'" and zmin: "\<And>y. (y, z) \<in> S \<Longrightarrow> y \<notin> ?Q'" by (erule wfE_min)
   265   { 
   266     fix y assume "(y, z) \<in> S"
   267     then have "y \<notin> ?Q'" by (rule zmin)
   268 
   269     have "y \<notin> Q"
   270     proof 
   271       assume "y \<in> Q"
   272       with `y \<notin> ?Q'` 
   273       obtain w where "(w, y) \<in> R" and "w \<in> Q" by auto
   274       from `(w, y) \<in> R` `(y, z) \<in> S` have "(w, z) \<in> R O S" by (rule rel_compI)
   275       with `R O S \<subseteq> R` have "(w, z) \<in> R" ..
   276       with `z \<in> ?Q'` have "w \<notin> Q" by blast 
   277       with `w \<in> Q` show False by contradiction
   278     qed
   279   }
   280   with `z \<in> ?Q'` show "\<exists>z\<in>Q. \<forall>y. (y, z) \<in> R \<union> S \<longrightarrow> y \<notin> Q" by blast
   281 qed
   282 
   283 
   284 text {* Well-foundedness of indexed union with disjoint domains and ranges *}
   285 
   286 lemma wf_UN: "[| ALL i:I. wf(r i);  
   287          ALL i:I. ALL j:I. r i ~= r j --> Domain(r i) Int Range(r j) = {}  
   288       |] ==> wf(UN i:I. r i)"
   289 apply (simp only: wf_eq_minimal, clarify)
   290 apply (rename_tac A a, case_tac "EX i:I. EX a:A. EX b:A. (b,a) : r i")
   291  prefer 2
   292  apply force 
   293 apply clarify
   294 apply (drule bspec, assumption)  
   295 apply (erule_tac x="{a. a:A & (EX b:A. (b,a) : r i) }" in allE)
   296 apply (blast elim!: allE)  
   297 done
   298 
   299 lemma wfP_SUP:
   300   "\<forall>i. wfP (r i) \<Longrightarrow> \<forall>i j. r i \<noteq> r j \<longrightarrow> inf (DomainP (r i)) (RangeP (r j)) = bot \<Longrightarrow> wfP (SUPR UNIV r)"
   301   apply (rule wf_UN [where I=UNIV and r="\<lambda>i. {(x, y). r i x y}", to_pred])
   302   apply (simp_all add: inf_set_def)
   303   apply auto
   304   done
   305 
   306 lemma wf_Union: 
   307  "[| ALL r:R. wf r;  
   308      ALL r:R. ALL s:R. r ~= s --> Domain r Int Range s = {}  
   309   |] ==> wf(Union R)"
   310   using wf_UN[of R "\<lambda>i. i"] by (simp add: SUP_def)
   311 
   312 (*Intuition: we find an (R u S)-min element of a nonempty subset A
   313              by case distinction.
   314   1. There is a step a -R-> b with a,b : A.
   315      Pick an R-min element z of the (nonempty) set {a:A | EX b:A. a -R-> b}.
   316      By definition, there is z':A s.t. z -R-> z'. Because z is R-min in the
   317      subset, z' must be R-min in A. Because z' has an R-predecessor, it cannot
   318      have an S-successor and is thus S-min in A as well.
   319   2. There is no such step.
   320      Pick an S-min element of A. In this case it must be an R-min
   321      element of A as well.
   322 
   323 *)
   324 lemma wf_Un:
   325      "[| wf r; wf s; Domain r Int Range s = {} |] ==> wf(r Un s)"
   326   using wf_union_compatible[of s r] 
   327   by (auto simp: Un_ac)
   328 
   329 lemma wf_union_merge: 
   330   "wf (R \<union> S) = wf (R O R \<union> S O R \<union> S)" (is "wf ?A = wf ?B")
   331 proof
   332   assume "wf ?A"
   333   with wf_trancl have wfT: "wf (?A^+)" .
   334   moreover have "?B \<subseteq> ?A^+"
   335     by (subst trancl_unfold, subst trancl_unfold) blast
   336   ultimately show "wf ?B" by (rule wf_subset)
   337 next
   338   assume "wf ?B"
   339 
   340   show "wf ?A"
   341   proof (rule wfI_min)
   342     fix Q :: "'a set" and x 
   343     assume "x \<in> Q"
   344 
   345     with `wf ?B`
   346     obtain z where "z \<in> Q" and "\<And>y. (y, z) \<in> ?B \<Longrightarrow> y \<notin> Q" 
   347       by (erule wfE_min)
   348     then have A1: "\<And>y. (y, z) \<in> R O R \<Longrightarrow> y \<notin> Q"
   349       and A2: "\<And>y. (y, z) \<in> S O R \<Longrightarrow> y \<notin> Q"
   350       and A3: "\<And>y. (y, z) \<in> S \<Longrightarrow> y \<notin> Q"
   351       by auto
   352     
   353     show "\<exists>z\<in>Q. \<forall>y. (y, z) \<in> ?A \<longrightarrow> y \<notin> Q"
   354     proof (cases "\<forall>y. (y, z) \<in> R \<longrightarrow> y \<notin> Q")
   355       case True
   356       with `z \<in> Q` A3 show ?thesis by blast
   357     next
   358       case False 
   359       then obtain z' where "z'\<in>Q" "(z', z) \<in> R" by blast
   360 
   361       have "\<forall>y. (y, z') \<in> ?A \<longrightarrow> y \<notin> Q"
   362       proof (intro allI impI)
   363         fix y assume "(y, z') \<in> ?A"
   364         then show "y \<notin> Q"
   365         proof
   366           assume "(y, z') \<in> R" 
   367           then have "(y, z) \<in> R O R" using `(z', z) \<in> R` ..
   368           with A1 show "y \<notin> Q" .
   369         next
   370           assume "(y, z') \<in> S" 
   371           then have "(y, z) \<in> S O R" using  `(z', z) \<in> R` ..
   372           with A2 show "y \<notin> Q" .
   373         qed
   374       qed
   375       with `z' \<in> Q` show ?thesis ..
   376     qed
   377   qed
   378 qed
   379 
   380 lemma wf_comp_self: "wf R = wf (R O R)"  -- {* special case *}
   381   by (rule wf_union_merge [where S = "{}", simplified])
   382 
   383 
   384 subsection {* Acyclic relations *}
   385 
   386 lemma wf_acyclic: "wf r ==> acyclic r"
   387 apply (simp add: acyclic_def)
   388 apply (blast elim: wf_trancl [THEN wf_irrefl])
   389 done
   390 
   391 lemmas wfP_acyclicP = wf_acyclic [to_pred]
   392 
   393 text{* Wellfoundedness of finite acyclic relations*}
   394 
   395 lemma finite_acyclic_wf [rule_format]: "finite r ==> acyclic r --> wf r"
   396 apply (erule finite_induct, blast)
   397 apply (simp (no_asm_simp) only: split_tupled_all)
   398 apply simp
   399 done
   400 
   401 lemma finite_acyclic_wf_converse: "[|finite r; acyclic r|] ==> wf (r^-1)"
   402 apply (erule finite_converse [THEN iffD2, THEN finite_acyclic_wf])
   403 apply (erule acyclic_converse [THEN iffD2])
   404 done
   405 
   406 lemma wf_iff_acyclic_if_finite: "finite r ==> wf r = acyclic r"
   407 by (blast intro: finite_acyclic_wf wf_acyclic)
   408 
   409 
   410 subsection {* @{typ nat} is well-founded *}
   411 
   412 lemma less_nat_rel: "op < = (\<lambda>m n. n = Suc m)^++"
   413 proof (rule ext, rule ext, rule iffI)
   414   fix n m :: nat
   415   assume "m < n"
   416   then show "(\<lambda>m n. n = Suc m)^++ m n"
   417   proof (induct n)
   418     case 0 then show ?case by auto
   419   next
   420     case (Suc n) then show ?case
   421       by (auto simp add: less_Suc_eq_le le_less intro: tranclp.trancl_into_trancl)
   422   qed
   423 next
   424   fix n m :: nat
   425   assume "(\<lambda>m n. n = Suc m)^++ m n"
   426   then show "m < n"
   427     by (induct n)
   428       (simp_all add: less_Suc_eq_le reflexive le_less)
   429 qed
   430 
   431 definition
   432   pred_nat :: "(nat * nat) set" where
   433   "pred_nat = {(m, n). n = Suc m}"
   434 
   435 definition
   436   less_than :: "(nat * nat) set" where
   437   "less_than = pred_nat^+"
   438 
   439 lemma less_eq: "(m, n) \<in> pred_nat^+ \<longleftrightarrow> m < n"
   440   unfolding less_nat_rel pred_nat_def trancl_def by simp
   441 
   442 lemma pred_nat_trancl_eq_le:
   443   "(m, n) \<in> pred_nat^* \<longleftrightarrow> m \<le> n"
   444   unfolding less_eq rtrancl_eq_or_trancl by auto
   445 
   446 lemma wf_pred_nat: "wf pred_nat"
   447   apply (unfold wf_def pred_nat_def, clarify)
   448   apply (induct_tac x, blast+)
   449   done
   450 
   451 lemma wf_less_than [iff]: "wf less_than"
   452   by (simp add: less_than_def wf_pred_nat [THEN wf_trancl])
   453 
   454 lemma trans_less_than [iff]: "trans less_than"
   455   by (simp add: less_than_def)
   456 
   457 lemma less_than_iff [iff]: "((x,y): less_than) = (x<y)"
   458   by (simp add: less_than_def less_eq)
   459 
   460 lemma wf_less: "wf {(x, y::nat). x < y}"
   461   using wf_less_than by (simp add: less_than_def less_eq [symmetric])
   462 
   463 
   464 subsection {* Accessible Part *}
   465 
   466 text {*
   467  Inductive definition of the accessible part @{term "acc r"} of a
   468  relation; see also \cite{paulin-tlca}.
   469 *}
   470 
   471 inductive_set
   472   acc :: "('a * 'a) set => 'a set"
   473   for r :: "('a * 'a) set"
   474   where
   475     accI: "(!!y. (y, x) : r ==> y : acc r) ==> x : acc r"
   476 
   477 abbreviation
   478   termip :: "('a => 'a => bool) => 'a => bool" where
   479   "termip r \<equiv> accp (r\<inverse>\<inverse>)"
   480 
   481 abbreviation
   482   termi :: "('a * 'a) set => 'a set" where
   483   "termi r \<equiv> acc (r\<inverse>)"
   484 
   485 lemmas accpI = accp.accI
   486 
   487 text {* Induction rules *}
   488 
   489 theorem accp_induct:
   490   assumes major: "accp r a"
   491   assumes hyp: "!!x. accp r x ==> \<forall>y. r y x --> P y ==> P x"
   492   shows "P a"
   493   apply (rule major [THEN accp.induct])
   494   apply (rule hyp)
   495    apply (rule accp.accI)
   496    apply fast
   497   apply fast
   498   done
   499 
   500 theorems accp_induct_rule = accp_induct [rule_format, induct set: accp]
   501 
   502 theorem accp_downward: "accp r b ==> r a b ==> accp r a"
   503   apply (erule accp.cases)
   504   apply fast
   505   done
   506 
   507 lemma not_accp_down:
   508   assumes na: "\<not> accp R x"
   509   obtains z where "R z x" and "\<not> accp R z"
   510 proof -
   511   assume a: "\<And>z. \<lbrakk>R z x; \<not> accp R z\<rbrakk> \<Longrightarrow> thesis"
   512 
   513   show thesis
   514   proof (cases "\<forall>z. R z x \<longrightarrow> accp R z")
   515     case True
   516     hence "\<And>z. R z x \<Longrightarrow> accp R z" by auto
   517     hence "accp R x"
   518       by (rule accp.accI)
   519     with na show thesis ..
   520   next
   521     case False then obtain z where "R z x" and "\<not> accp R z"
   522       by auto
   523     with a show thesis .
   524   qed
   525 qed
   526 
   527 lemma accp_downwards_aux: "r\<^sup>*\<^sup>* b a ==> accp r a --> accp r b"
   528   apply (erule rtranclp_induct)
   529    apply blast
   530   apply (blast dest: accp_downward)
   531   done
   532 
   533 theorem accp_downwards: "accp r a ==> r\<^sup>*\<^sup>* b a ==> accp r b"
   534   apply (blast dest: accp_downwards_aux)
   535   done
   536 
   537 theorem accp_wfPI: "\<forall>x. accp r x ==> wfP r"
   538   apply (rule wfPUNIVI)
   539   apply (rule_tac P=P in accp_induct)
   540    apply blast
   541   apply blast
   542   done
   543 
   544 theorem accp_wfPD: "wfP r ==> accp r x"
   545   apply (erule wfP_induct_rule)
   546   apply (rule accp.accI)
   547   apply blast
   548   done
   549 
   550 theorem wfP_accp_iff: "wfP r = (\<forall>x. accp r x)"
   551   apply (blast intro: accp_wfPI dest: accp_wfPD)
   552   done
   553 
   554 
   555 text {* Smaller relations have bigger accessible parts: *}
   556 
   557 lemma accp_subset:
   558   assumes sub: "R1 \<le> R2"
   559   shows "accp R2 \<le> accp R1"
   560 proof (rule predicate1I)
   561   fix x assume "accp R2 x"
   562   then show "accp R1 x"
   563   proof (induct x)
   564     fix x
   565     assume ih: "\<And>y. R2 y x \<Longrightarrow> accp R1 y"
   566     with sub show "accp R1 x"
   567       by (blast intro: accp.accI)
   568   qed
   569 qed
   570 
   571 
   572 text {* This is a generalized induction theorem that works on
   573   subsets of the accessible part. *}
   574 
   575 lemma accp_subset_induct:
   576   assumes subset: "D \<le> accp R"
   577     and dcl: "\<And>x z. \<lbrakk>D x; R z x\<rbrakk> \<Longrightarrow> D z"
   578     and "D x"
   579     and istep: "\<And>x. \<lbrakk>D x; (\<And>z. R z x \<Longrightarrow> P z)\<rbrakk> \<Longrightarrow> P x"
   580   shows "P x"
   581 proof -
   582   from subset and `D x`
   583   have "accp R x" ..
   584   then show "P x" using `D x`
   585   proof (induct x)
   586     fix x
   587     assume "D x"
   588       and "\<And>y. R y x \<Longrightarrow> D y \<Longrightarrow> P y"
   589     with dcl and istep show "P x" by blast
   590   qed
   591 qed
   592 
   593 
   594 text {* Set versions of the above theorems *}
   595 
   596 lemmas acc_induct = accp_induct [to_set]
   597 
   598 lemmas acc_induct_rule = acc_induct [rule_format, induct set: acc]
   599 
   600 lemmas acc_downward = accp_downward [to_set]
   601 
   602 lemmas not_acc_down = not_accp_down [to_set]
   603 
   604 lemmas acc_downwards_aux = accp_downwards_aux [to_set]
   605 
   606 lemmas acc_downwards = accp_downwards [to_set]
   607 
   608 lemmas acc_wfI = accp_wfPI [to_set]
   609 
   610 lemmas acc_wfD = accp_wfPD [to_set]
   611 
   612 lemmas wf_acc_iff = wfP_accp_iff [to_set]
   613 
   614 lemmas acc_subset = accp_subset [to_set]
   615 
   616 lemmas acc_subset_induct = accp_subset_induct [to_set]
   617 
   618 text {* Very basic code generation setup *}
   619 
   620 declare accp.simps[code]
   621 
   622 lemma [code_unfold]:
   623   "(x : acc r) = accp (%x xa. (x, xa) : r) x"
   624 by (simp add: accp_acc_eq)
   625 
   626 subsection {* Tools for building wellfounded relations *}
   627 
   628 text {* Inverse Image *}
   629 
   630 lemma wf_inv_image [simp,intro!]: "wf(r) ==> wf(inv_image r (f::'a=>'b))"
   631 apply (simp (no_asm_use) add: inv_image_def wf_eq_minimal)
   632 apply clarify
   633 apply (subgoal_tac "EX (w::'b) . w : {w. EX (x::'a) . x: Q & (f x = w) }")
   634 prefer 2 apply (blast del: allE)
   635 apply (erule allE)
   636 apply (erule (1) notE impE)
   637 apply blast
   638 done
   639 
   640 text {* Measure functions into @{typ nat} *}
   641 
   642 definition measure :: "('a => nat) => ('a * 'a)set"
   643 where "measure = inv_image less_than"
   644 
   645 lemma in_measure[simp]: "((x,y) : measure f) = (f x < f y)"
   646   by (simp add:measure_def)
   647 
   648 lemma wf_measure [iff]: "wf (measure f)"
   649 apply (unfold measure_def)
   650 apply (rule wf_less_than [THEN wf_inv_image])
   651 done
   652 
   653 lemma wf_if_measure: fixes f :: "'a \<Rightarrow> nat"
   654 shows "(!!x. P x \<Longrightarrow> f(g x) < f x) \<Longrightarrow> wf {(y,x). P x \<and> y = g x}"
   655 apply(insert wf_measure[of f])
   656 apply(simp only: measure_def inv_image_def less_than_def less_eq)
   657 apply(erule wf_subset)
   658 apply auto
   659 done
   660 
   661 
   662 text{* Lexicographic combinations *}
   663 
   664 definition lex_prod :: "('a \<times>'a) set \<Rightarrow> ('b \<times> 'b) set \<Rightarrow> (('a \<times> 'b) \<times> ('a \<times> 'b)) set" (infixr "<*lex*>" 80) where
   665   "ra <*lex*> rb = {((a, b), (a', b')). (a, a') \<in> ra \<or> a = a' \<and> (b, b') \<in> rb}"
   666 
   667 lemma wf_lex_prod [intro!]: "[| wf(ra); wf(rb) |] ==> wf(ra <*lex*> rb)"
   668 apply (unfold wf_def lex_prod_def) 
   669 apply (rule allI, rule impI)
   670 apply (simp (no_asm_use) only: split_paired_All)
   671 apply (drule spec, erule mp) 
   672 apply (rule allI, rule impI)
   673 apply (drule spec, erule mp, blast) 
   674 done
   675 
   676 lemma in_lex_prod[simp]: 
   677   "(((a,b),(a',b')): r <*lex*> s) = ((a,a'): r \<or> (a = a' \<and> (b, b') : s))"
   678   by (auto simp:lex_prod_def)
   679 
   680 text{* @{term "op <*lex*>"} preserves transitivity *}
   681 
   682 lemma trans_lex_prod [intro!]: 
   683     "[| trans R1; trans R2 |] ==> trans (R1 <*lex*> R2)"
   684 by (unfold trans_def lex_prod_def, blast) 
   685 
   686 text {* lexicographic combinations with measure functions *}
   687 
   688 definition 
   689   mlex_prod :: "('a \<Rightarrow> nat) \<Rightarrow> ('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set" (infixr "<*mlex*>" 80)
   690 where
   691   "f <*mlex*> R = inv_image (less_than <*lex*> R) (%x. (f x, x))"
   692 
   693 lemma wf_mlex: "wf R \<Longrightarrow> wf (f <*mlex*> R)"
   694 unfolding mlex_prod_def
   695 by auto
   696 
   697 lemma mlex_less: "f x < f y \<Longrightarrow> (x, y) \<in> f <*mlex*> R"
   698 unfolding mlex_prod_def by simp
   699 
   700 lemma mlex_leq: "f x \<le> f y \<Longrightarrow> (x, y) \<in> R \<Longrightarrow> (x, y) \<in> f <*mlex*> R"
   701 unfolding mlex_prod_def by auto
   702 
   703 text {* proper subset relation on finite sets *}
   704 
   705 definition finite_psubset  :: "('a set * 'a set) set"
   706 where "finite_psubset = {(A,B). A < B & finite B}"
   707 
   708 lemma wf_finite_psubset[simp]: "wf(finite_psubset)"
   709 apply (unfold finite_psubset_def)
   710 apply (rule wf_measure [THEN wf_subset])
   711 apply (simp add: measure_def inv_image_def less_than_def less_eq)
   712 apply (fast elim!: psubset_card_mono)
   713 done
   714 
   715 lemma trans_finite_psubset: "trans finite_psubset"
   716 by (simp add: finite_psubset_def less_le trans_def, blast)
   717 
   718 lemma in_finite_psubset[simp]: "(A, B) \<in> finite_psubset = (A < B & finite B)"
   719 unfolding finite_psubset_def by auto
   720 
   721 text {* max- and min-extension of order to finite sets *}
   722 
   723 inductive_set max_ext :: "('a \<times> 'a) set \<Rightarrow> ('a set \<times> 'a set) set" 
   724 for R :: "('a \<times> 'a) set"
   725 where
   726   max_extI[intro]: "finite X \<Longrightarrow> finite Y \<Longrightarrow> Y \<noteq> {} \<Longrightarrow> (\<And>x. x \<in> X \<Longrightarrow> \<exists>y\<in>Y. (x, y) \<in> R) \<Longrightarrow> (X, Y) \<in> max_ext R"
   727 
   728 lemma max_ext_wf:
   729   assumes wf: "wf r"
   730   shows "wf (max_ext r)"
   731 proof (rule acc_wfI, intro allI)
   732   fix M show "M \<in> acc (max_ext r)" (is "_ \<in> ?W")
   733   proof cases
   734     assume "finite M"
   735     thus ?thesis
   736     proof (induct M)
   737       show "{} \<in> ?W"
   738         by (rule accI) (auto elim: max_ext.cases)
   739     next
   740       fix M a assume "M \<in> ?W" "finite M"
   741       with wf show "insert a M \<in> ?W"
   742       proof (induct arbitrary: M)
   743         fix M a
   744         assume "M \<in> ?W"  and  [intro]: "finite M"
   745         assume hyp: "\<And>b M. (b, a) \<in> r \<Longrightarrow> M \<in> ?W \<Longrightarrow> finite M \<Longrightarrow> insert b M \<in> ?W"
   746         {
   747           fix N M :: "'a set"
   748           assume "finite N" "finite M"
   749           then
   750           have "\<lbrakk>M \<in> ?W ; (\<And>y. y \<in> N \<Longrightarrow> (y, a) \<in> r)\<rbrakk> \<Longrightarrow>  N \<union> M \<in> ?W"
   751             by (induct N arbitrary: M) (auto simp: hyp)
   752         }
   753         note add_less = this
   754         
   755         show "insert a M \<in> ?W"
   756         proof (rule accI)
   757           fix N assume Nless: "(N, insert a M) \<in> max_ext r"
   758           hence asm1: "\<And>x. x \<in> N \<Longrightarrow> (x, a) \<in> r \<or> (\<exists>y \<in> M. (x, y) \<in> r)"
   759             by (auto elim!: max_ext.cases)
   760 
   761           let ?N1 = "{ n \<in> N. (n, a) \<in> r }"
   762           let ?N2 = "{ n \<in> N. (n, a) \<notin> r }"
   763           have N: "?N1 \<union> ?N2 = N" by (rule set_eqI) auto
   764           from Nless have "finite N" by (auto elim: max_ext.cases)
   765           then have finites: "finite ?N1" "finite ?N2" by auto
   766           
   767           have "?N2 \<in> ?W"
   768           proof cases
   769             assume [simp]: "M = {}"
   770             have Mw: "{} \<in> ?W" by (rule accI) (auto elim: max_ext.cases)
   771 
   772             from asm1 have "?N2 = {}" by auto
   773             with Mw show "?N2 \<in> ?W" by (simp only:)
   774           next
   775             assume "M \<noteq> {}"
   776             have N2: "(?N2, M) \<in> max_ext r" 
   777               by (rule max_extI[OF _ _ `M \<noteq> {}`]) (insert asm1, auto intro: finites)
   778             
   779             with `M \<in> ?W` show "?N2 \<in> ?W" by (rule acc_downward)
   780           qed
   781           with finites have "?N1 \<union> ?N2 \<in> ?W" 
   782             by (rule add_less) simp
   783           then show "N \<in> ?W" by (simp only: N)
   784         qed
   785       qed
   786     qed
   787   next
   788     assume [simp]: "\<not> finite M"
   789     show ?thesis
   790       by (rule accI) (auto elim: max_ext.cases)
   791   qed
   792 qed
   793 
   794 lemma max_ext_additive: 
   795  "(A, B) \<in> max_ext R \<Longrightarrow> (C, D) \<in> max_ext R \<Longrightarrow>
   796   (A \<union> C, B \<union> D) \<in> max_ext R"
   797 by (force elim!: max_ext.cases)
   798 
   799 
   800 definition min_ext :: "('a \<times> 'a) set \<Rightarrow> ('a set \<times> 'a set) set"  where
   801   "min_ext r = {(X, Y) | X Y. X \<noteq> {} \<and> (\<forall>y \<in> Y. (\<exists>x \<in> X. (x, y) \<in> r))}"
   802 
   803 lemma min_ext_wf:
   804   assumes "wf r"
   805   shows "wf (min_ext r)"
   806 proof (rule wfI_min)
   807   fix Q :: "'a set set"
   808   fix x
   809   assume nonempty: "x \<in> Q"
   810   show "\<exists>m \<in> Q. (\<forall> n. (n, m) \<in> min_ext r \<longrightarrow> n \<notin> Q)"
   811   proof cases
   812     assume "Q = {{}}" thus ?thesis by (simp add: min_ext_def)
   813   next
   814     assume "Q \<noteq> {{}}"
   815     with nonempty
   816     obtain e x where "x \<in> Q" "e \<in> x" by force
   817     then have eU: "e \<in> \<Union>Q" by auto
   818     with `wf r` 
   819     obtain z where z: "z \<in> \<Union>Q" "\<And>y. (y, z) \<in> r \<Longrightarrow> y \<notin> \<Union>Q" 
   820       by (erule wfE_min)
   821     from z obtain m where "m \<in> Q" "z \<in> m" by auto
   822     from `m \<in> Q`
   823     show ?thesis
   824     proof (rule, intro bexI allI impI)
   825       fix n
   826       assume smaller: "(n, m) \<in> min_ext r"
   827       with `z \<in> m` obtain y where y: "y \<in> n" "(y, z) \<in> r" by (auto simp: min_ext_def)
   828       then show "n \<notin> Q" using z(2) by auto
   829     qed      
   830   qed
   831 qed
   832 
   833 text{* Bounded increase must terminate: *}
   834 
   835 lemma wf_bounded_measure:
   836 fixes ub :: "'a \<Rightarrow> nat" and f :: "'a \<Rightarrow> nat"
   837 assumes "!!a b. (b,a) : r \<Longrightarrow> ub b \<le> ub a & ub a \<ge> f b & f b > f a"
   838 shows "wf r"
   839 apply(rule wf_subset[OF wf_measure[of "%a. ub a - f a"]])
   840 apply (auto dest: assms)
   841 done
   842 
   843 lemma wf_bounded_set:
   844 fixes ub :: "'a \<Rightarrow> 'b set" and f :: "'a \<Rightarrow> 'b set"
   845 assumes "!!a b. (b,a) : r \<Longrightarrow>
   846   finite(ub a) & ub b \<subseteq> ub a & ub a \<supseteq> f b & f b \<supset> f a"
   847 shows "wf r"
   848 apply(rule wf_bounded_measure[of r "%a. card(ub a)" "%a. card(f a)"])
   849 apply(drule assms)
   850 apply (blast intro: card_mono finite_subset psubset_card_mono dest: psubset_eq[THEN iffD2])
   851 done
   852 
   853 
   854 subsection {* size of a datatype value *}
   855 
   856 use "Tools/Function/size.ML"
   857 
   858 setup Size.setup
   859 
   860 lemma size_bool [code]:
   861   "size (b\<Colon>bool) = 0" by (cases b) auto
   862 
   863 lemma nat_size [simp, code]: "size (n\<Colon>nat) = n"
   864   by (induct n) simp_all
   865 
   866 declare "prod.size" [no_atp]
   867 
   868 lemma [code]:
   869   "size (P :: 'a Predicate.pred) = 0" by (cases P) simp
   870 
   871 lemma [code]:
   872   "pred_size f P = 0" by (cases P) simp
   873 
   874 end