src/HOL/Real/RealDef.thy
author haftmann
Fri Jul 20 14:28:01 2007 +0200 (2007-07-20)
changeset 23879 4776af8be741
parent 23482 2f4be6844f7c
child 24075 366d4d234814
permissions -rw-r--r--
split class abs from class minus
     1 (*  Title       : Real/RealDef.thy
     2     ID          : $Id$
     3     Author      : Jacques D. Fleuriot
     4     Copyright   : 1998  University of Cambridge
     5     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     6     Additional contributions by Jeremy Avigad
     7 *)
     8 
     9 header{*Defining the Reals from the Positive Reals*}
    10 
    11 theory RealDef
    12 imports PReal
    13 uses ("real_arith.ML")
    14 begin
    15 
    16 definition
    17   realrel   ::  "((preal * preal) * (preal * preal)) set" where
    18   "realrel = {p. \<exists>x1 y1 x2 y2. p = ((x1,y1),(x2,y2)) & x1+y2 = x2+y1}"
    19 
    20 typedef (Real)  real = "UNIV//realrel"
    21   by (auto simp add: quotient_def)
    22 
    23 definition
    24   (** these don't use the overloaded "real" function: users don't see them **)
    25   real_of_preal :: "preal => real" where
    26   "real_of_preal m = Abs_Real(realrel``{(m + 1, 1)})"
    27 
    28 consts
    29    (*overloaded constant for injecting other types into "real"*)
    30    real :: "'a => real"
    31 
    32 instance real :: zero
    33   real_zero_def: "0 == Abs_Real(realrel``{(1, 1)})" ..
    34 
    35 instance real :: one
    36   real_one_def: "1 == Abs_Real(realrel``{(1 + 1, 1)})" ..
    37 
    38 instance real :: plus
    39   real_add_def: "z + w ==
    40        contents (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
    41 		 { Abs_Real(realrel``{(x+u, y+v)}) })" ..
    42 
    43 instance real :: minus
    44   real_minus_def: "- r ==  contents (\<Union>(x,y) \<in> Rep_Real(r). { Abs_Real(realrel``{(y,x)}) })"
    45   real_diff_def: "r - (s::real) == r + - s" ..
    46 
    47 instance real :: times
    48   real_mult_def:
    49     "z * w ==
    50        contents (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
    51 		 { Abs_Real(realrel``{(x*u + y*v, x*v + y*u)}) })" ..
    52 
    53 instance real :: inverse
    54   real_inverse_def: "inverse (R::real) == (THE S. (R = 0 & S = 0) | S * R = 1)"
    55   real_divide_def: "R / (S::real) == R * inverse S" ..
    56 
    57 instance real :: ord
    58   real_le_def: "z \<le> (w::real) == 
    59     \<exists>x y u v. x+v \<le> u+y & (x,y) \<in> Rep_Real z & (u,v) \<in> Rep_Real w"
    60   real_less_def: "(x < (y::real)) == (x \<le> y & x \<noteq> y)" ..
    61 
    62 instance real :: abs
    63   real_abs_def:  "abs (r::real) == (if r < 0 then - r else r)" ..
    64 
    65 
    66 subsection {* Equivalence relation over positive reals *}
    67 
    68 lemma preal_trans_lemma:
    69   assumes "x + y1 = x1 + y"
    70       and "x + y2 = x2 + y"
    71   shows "x1 + y2 = x2 + (y1::preal)"
    72 proof -
    73   have "(x1 + y2) + x = (x + y2) + x1" by (simp add: add_ac)
    74   also have "... = (x2 + y) + x1"  by (simp add: prems)
    75   also have "... = x2 + (x1 + y)"  by (simp add: add_ac)
    76   also have "... = x2 + (x + y1)"  by (simp add: prems)
    77   also have "... = (x2 + y1) + x"  by (simp add: add_ac)
    78   finally have "(x1 + y2) + x = (x2 + y1) + x" .
    79   thus ?thesis by (rule add_right_imp_eq)
    80 qed
    81 
    82 
    83 lemma realrel_iff [simp]: "(((x1,y1),(x2,y2)) \<in> realrel) = (x1 + y2 = x2 + y1)"
    84 by (simp add: realrel_def)
    85 
    86 lemma equiv_realrel: "equiv UNIV realrel"
    87 apply (auto simp add: equiv_def refl_def sym_def trans_def realrel_def)
    88 apply (blast dest: preal_trans_lemma) 
    89 done
    90 
    91 text{*Reduces equality of equivalence classes to the @{term realrel} relation:
    92   @{term "(realrel `` {x} = realrel `` {y}) = ((x,y) \<in> realrel)"} *}
    93 lemmas equiv_realrel_iff = 
    94        eq_equiv_class_iff [OF equiv_realrel UNIV_I UNIV_I]
    95 
    96 declare equiv_realrel_iff [simp]
    97 
    98 
    99 lemma realrel_in_real [simp]: "realrel``{(x,y)}: Real"
   100 by (simp add: Real_def realrel_def quotient_def, blast)
   101 
   102 declare Abs_Real_inject [simp]
   103 declare Abs_Real_inverse [simp]
   104 
   105 
   106 text{*Case analysis on the representation of a real number as an equivalence
   107       class of pairs of positive reals.*}
   108 lemma eq_Abs_Real [case_names Abs_Real, cases type: real]: 
   109      "(!!x y. z = Abs_Real(realrel``{(x,y)}) ==> P) ==> P"
   110 apply (rule Rep_Real [of z, unfolded Real_def, THEN quotientE])
   111 apply (drule arg_cong [where f=Abs_Real])
   112 apply (auto simp add: Rep_Real_inverse)
   113 done
   114 
   115 
   116 subsection {* Addition and Subtraction *}
   117 
   118 lemma real_add_congruent2_lemma:
   119      "[|a + ba = aa + b; ab + bc = ac + bb|]
   120       ==> a + ab + (ba + bc) = aa + ac + (b + (bb::preal))"
   121 apply (simp add: add_assoc)
   122 apply (rule add_left_commute [of ab, THEN ssubst])
   123 apply (simp add: add_assoc [symmetric])
   124 apply (simp add: add_ac)
   125 done
   126 
   127 lemma real_add:
   128      "Abs_Real (realrel``{(x,y)}) + Abs_Real (realrel``{(u,v)}) =
   129       Abs_Real (realrel``{(x+u, y+v)})"
   130 proof -
   131   have "(\<lambda>z w. (\<lambda>(x,y). (\<lambda>(u,v). {Abs_Real (realrel `` {(x+u, y+v)})}) w) z)
   132         respects2 realrel"
   133     by (simp add: congruent2_def, blast intro: real_add_congruent2_lemma) 
   134   thus ?thesis
   135     by (simp add: real_add_def UN_UN_split_split_eq
   136                   UN_equiv_class2 [OF equiv_realrel equiv_realrel])
   137 qed
   138 
   139 lemma real_minus: "- Abs_Real(realrel``{(x,y)}) = Abs_Real(realrel `` {(y,x)})"
   140 proof -
   141   have "(\<lambda>(x,y). {Abs_Real (realrel``{(y,x)})}) respects realrel"
   142     by (simp add: congruent_def add_commute) 
   143   thus ?thesis
   144     by (simp add: real_minus_def UN_equiv_class [OF equiv_realrel])
   145 qed
   146 
   147 instance real :: ab_group_add
   148 proof
   149   fix x y z :: real
   150   show "(x + y) + z = x + (y + z)"
   151     by (cases x, cases y, cases z, simp add: real_add add_assoc)
   152   show "x + y = y + x"
   153     by (cases x, cases y, simp add: real_add add_commute)
   154   show "0 + x = x"
   155     by (cases x, simp add: real_add real_zero_def add_ac)
   156   show "- x + x = 0"
   157     by (cases x, simp add: real_minus real_add real_zero_def add_commute)
   158   show "x - y = x + - y"
   159     by (simp add: real_diff_def)
   160 qed
   161 
   162 
   163 subsection {* Multiplication *}
   164 
   165 lemma real_mult_congruent2_lemma:
   166      "!!(x1::preal). [| x1 + y2 = x2 + y1 |] ==>
   167           x * x1 + y * y1 + (x * y2 + y * x2) =
   168           x * x2 + y * y2 + (x * y1 + y * x1)"
   169 apply (simp add: add_left_commute add_assoc [symmetric])
   170 apply (simp add: add_assoc right_distrib [symmetric])
   171 apply (simp add: add_commute)
   172 done
   173 
   174 lemma real_mult_congruent2:
   175     "(%p1 p2.
   176         (%(x1,y1). (%(x2,y2). 
   177           { Abs_Real (realrel``{(x1*x2 + y1*y2, x1*y2+y1*x2)}) }) p2) p1)
   178      respects2 realrel"
   179 apply (rule congruent2_commuteI [OF equiv_realrel], clarify)
   180 apply (simp add: mult_commute add_commute)
   181 apply (auto simp add: real_mult_congruent2_lemma)
   182 done
   183 
   184 lemma real_mult:
   185       "Abs_Real((realrel``{(x1,y1)})) * Abs_Real((realrel``{(x2,y2)})) =
   186        Abs_Real(realrel `` {(x1*x2+y1*y2,x1*y2+y1*x2)})"
   187 by (simp add: real_mult_def UN_UN_split_split_eq
   188          UN_equiv_class2 [OF equiv_realrel equiv_realrel real_mult_congruent2])
   189 
   190 lemma real_mult_commute: "(z::real) * w = w * z"
   191 by (cases z, cases w, simp add: real_mult add_ac mult_ac)
   192 
   193 lemma real_mult_assoc: "((z1::real) * z2) * z3 = z1 * (z2 * z3)"
   194 apply (cases z1, cases z2, cases z3)
   195 apply (simp add: real_mult right_distrib add_ac mult_ac)
   196 done
   197 
   198 lemma real_mult_1: "(1::real) * z = z"
   199 apply (cases z)
   200 apply (simp add: real_mult real_one_def right_distrib
   201                   mult_1_right mult_ac add_ac)
   202 done
   203 
   204 lemma real_add_mult_distrib: "((z1::real) + z2) * w = (z1 * w) + (z2 * w)"
   205 apply (cases z1, cases z2, cases w)
   206 apply (simp add: real_add real_mult right_distrib add_ac mult_ac)
   207 done
   208 
   209 text{*one and zero are distinct*}
   210 lemma real_zero_not_eq_one: "0 \<noteq> (1::real)"
   211 proof -
   212   have "(1::preal) < 1 + 1"
   213     by (simp add: preal_self_less_add_left)
   214   thus ?thesis
   215     by (simp add: real_zero_def real_one_def)
   216 qed
   217 
   218 instance real :: comm_ring_1
   219 proof
   220   fix x y z :: real
   221   show "(x * y) * z = x * (y * z)" by (rule real_mult_assoc)
   222   show "x * y = y * x" by (rule real_mult_commute)
   223   show "1 * x = x" by (rule real_mult_1)
   224   show "(x + y) * z = x * z + y * z" by (rule real_add_mult_distrib)
   225   show "0 \<noteq> (1::real)" by (rule real_zero_not_eq_one)
   226 qed
   227 
   228 subsection {* Inverse and Division *}
   229 
   230 lemma real_zero_iff: "Abs_Real (realrel `` {(x, x)}) = 0"
   231 by (simp add: real_zero_def add_commute)
   232 
   233 text{*Instead of using an existential quantifier and constructing the inverse
   234 within the proof, we could define the inverse explicitly.*}
   235 
   236 lemma real_mult_inverse_left_ex: "x \<noteq> 0 ==> \<exists>y. y*x = (1::real)"
   237 apply (simp add: real_zero_def real_one_def, cases x)
   238 apply (cut_tac x = xa and y = y in linorder_less_linear)
   239 apply (auto dest!: less_add_left_Ex simp add: real_zero_iff)
   240 apply (rule_tac
   241         x = "Abs_Real (realrel``{(1, inverse (D) + 1)})"
   242        in exI)
   243 apply (rule_tac [2]
   244         x = "Abs_Real (realrel``{(inverse (D) + 1, 1)})" 
   245        in exI)
   246 apply (auto simp add: real_mult preal_mult_inverse_right ring_simps)
   247 done
   248 
   249 lemma real_mult_inverse_left: "x \<noteq> 0 ==> inverse(x)*x = (1::real)"
   250 apply (simp add: real_inverse_def)
   251 apply (drule real_mult_inverse_left_ex, safe)
   252 apply (rule theI, assumption, rename_tac z)
   253 apply (subgoal_tac "(z * x) * y = z * (x * y)")
   254 apply (simp add: mult_commute)
   255 apply (rule mult_assoc)
   256 done
   257 
   258 
   259 subsection{*The Real Numbers form a Field*}
   260 
   261 instance real :: field
   262 proof
   263   fix x y z :: real
   264   show "x \<noteq> 0 ==> inverse x * x = 1" by (rule real_mult_inverse_left)
   265   show "x / y = x * inverse y" by (simp add: real_divide_def)
   266 qed
   267 
   268 
   269 text{*Inverse of zero!  Useful to simplify certain equations*}
   270 
   271 lemma INVERSE_ZERO: "inverse 0 = (0::real)"
   272 by (simp add: real_inverse_def)
   273 
   274 instance real :: division_by_zero
   275 proof
   276   show "inverse 0 = (0::real)" by (rule INVERSE_ZERO)
   277 qed
   278 
   279 
   280 subsection{*The @{text "\<le>"} Ordering*}
   281 
   282 lemma real_le_refl: "w \<le> (w::real)"
   283 by (cases w, force simp add: real_le_def)
   284 
   285 text{*The arithmetic decision procedure is not set up for type preal.
   286   This lemma is currently unused, but it could simplify the proofs of the
   287   following two lemmas.*}
   288 lemma preal_eq_le_imp_le:
   289   assumes eq: "a+b = c+d" and le: "c \<le> a"
   290   shows "b \<le> (d::preal)"
   291 proof -
   292   have "c+d \<le> a+d" by (simp add: prems)
   293   hence "a+b \<le> a+d" by (simp add: prems)
   294   thus "b \<le> d" by simp
   295 qed
   296 
   297 lemma real_le_lemma:
   298   assumes l: "u1 + v2 \<le> u2 + v1"
   299       and "x1 + v1 = u1 + y1"
   300       and "x2 + v2 = u2 + y2"
   301   shows "x1 + y2 \<le> x2 + (y1::preal)"
   302 proof -
   303   have "(x1+v1) + (u2+y2) = (u1+y1) + (x2+v2)" by (simp add: prems)
   304   hence "(x1+y2) + (u2+v1) = (x2+y1) + (u1+v2)" by (simp add: add_ac)
   305   also have "... \<le> (x2+y1) + (u2+v1)" by (simp add: prems)
   306   finally show ?thesis by simp
   307 qed
   308 
   309 lemma real_le: 
   310      "(Abs_Real(realrel``{(x1,y1)}) \<le> Abs_Real(realrel``{(x2,y2)})) =  
   311       (x1 + y2 \<le> x2 + y1)"
   312 apply (simp add: real_le_def)
   313 apply (auto intro: real_le_lemma)
   314 done
   315 
   316 lemma real_le_anti_sym: "[| z \<le> w; w \<le> z |] ==> z = (w::real)"
   317 by (cases z, cases w, simp add: real_le)
   318 
   319 lemma real_trans_lemma:
   320   assumes "x + v \<le> u + y"
   321       and "u + v' \<le> u' + v"
   322       and "x2 + v2 = u2 + y2"
   323   shows "x + v' \<le> u' + (y::preal)"
   324 proof -
   325   have "(x+v') + (u+v) = (x+v) + (u+v')" by (simp add: add_ac)
   326   also have "... \<le> (u+y) + (u+v')" by (simp add: prems)
   327   also have "... \<le> (u+y) + (u'+v)" by (simp add: prems)
   328   also have "... = (u'+y) + (u+v)"  by (simp add: add_ac)
   329   finally show ?thesis by simp
   330 qed
   331 
   332 lemma real_le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::real)"
   333 apply (cases i, cases j, cases k)
   334 apply (simp add: real_le)
   335 apply (blast intro: real_trans_lemma)
   336 done
   337 
   338 (* Axiom 'order_less_le' of class 'order': *)
   339 lemma real_less_le: "((w::real) < z) = (w \<le> z & w \<noteq> z)"
   340 by (simp add: real_less_def)
   341 
   342 instance real :: order
   343 proof qed
   344  (assumption |
   345   rule real_le_refl real_le_trans real_le_anti_sym real_less_le)+
   346 
   347 (* Axiom 'linorder_linear' of class 'linorder': *)
   348 lemma real_le_linear: "(z::real) \<le> w | w \<le> z"
   349 apply (cases z, cases w)
   350 apply (auto simp add: real_le real_zero_def add_ac)
   351 done
   352 
   353 
   354 instance real :: linorder
   355   by (intro_classes, rule real_le_linear)
   356 
   357 
   358 lemma real_le_eq_diff: "(x \<le> y) = (x-y \<le> (0::real))"
   359 apply (cases x, cases y) 
   360 apply (auto simp add: real_le real_zero_def real_diff_def real_add real_minus
   361                       add_ac)
   362 apply (simp_all add: add_assoc [symmetric])
   363 done
   364 
   365 lemma real_add_left_mono: 
   366   assumes le: "x \<le> y" shows "z + x \<le> z + (y::real)"
   367 proof -
   368   have "z + x - (z + y) = (z + -z) + (x - y)"
   369     by (simp add: diff_minus add_ac) 
   370   with le show ?thesis 
   371     by (simp add: real_le_eq_diff[of x] real_le_eq_diff[of "z+x"] diff_minus)
   372 qed
   373 
   374 lemma real_sum_gt_zero_less: "(0 < S + (-W::real)) ==> (W < S)"
   375 by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of S] diff_minus)
   376 
   377 lemma real_less_sum_gt_zero: "(W < S) ==> (0 < S + (-W::real))"
   378 by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of S] diff_minus)
   379 
   380 lemma real_mult_order: "[| 0 < x; 0 < y |] ==> (0::real) < x * y"
   381 apply (cases x, cases y)
   382 apply (simp add: linorder_not_le [where 'a = real, symmetric] 
   383                  linorder_not_le [where 'a = preal] 
   384                   real_zero_def real_le real_mult)
   385   --{*Reduce to the (simpler) @{text "\<le>"} relation *}
   386 apply (auto dest!: less_add_left_Ex
   387      simp add: add_ac mult_ac
   388           right_distrib preal_self_less_add_left)
   389 done
   390 
   391 lemma real_mult_less_mono2: "[| (0::real) < z; x < y |] ==> z * x < z * y"
   392 apply (rule real_sum_gt_zero_less)
   393 apply (drule real_less_sum_gt_zero [of x y])
   394 apply (drule real_mult_order, assumption)
   395 apply (simp add: right_distrib)
   396 done
   397 
   398 instance real :: distrib_lattice
   399   "inf x y \<equiv> min x y"
   400   "sup x y \<equiv> max x y"
   401   by default (auto simp add: inf_real_def sup_real_def min_max.sup_inf_distrib1)
   402 
   403 
   404 subsection{*The Reals Form an Ordered Field*}
   405 
   406 instance real :: ordered_field
   407 proof
   408   fix x y z :: real
   409   show "x \<le> y ==> z + x \<le> z + y" by (rule real_add_left_mono)
   410   show "x < y ==> 0 < z ==> z * x < z * y" by (rule real_mult_less_mono2)
   411   show "\<bar>x\<bar> = (if x < 0 then -x else x)" by (simp only: real_abs_def)
   412 qed
   413 
   414 text{*The function @{term real_of_preal} requires many proofs, but it seems
   415 to be essential for proving completeness of the reals from that of the
   416 positive reals.*}
   417 
   418 lemma real_of_preal_add:
   419      "real_of_preal ((x::preal) + y) = real_of_preal x + real_of_preal y"
   420 by (simp add: real_of_preal_def real_add left_distrib add_ac)
   421 
   422 lemma real_of_preal_mult:
   423      "real_of_preal ((x::preal) * y) = real_of_preal x* real_of_preal y"
   424 by (simp add: real_of_preal_def real_mult right_distrib add_ac mult_ac)
   425 
   426 
   427 text{*Gleason prop 9-4.4 p 127*}
   428 lemma real_of_preal_trichotomy:
   429       "\<exists>m. (x::real) = real_of_preal m | x = 0 | x = -(real_of_preal m)"
   430 apply (simp add: real_of_preal_def real_zero_def, cases x)
   431 apply (auto simp add: real_minus add_ac)
   432 apply (cut_tac x = x and y = y in linorder_less_linear)
   433 apply (auto dest!: less_add_left_Ex simp add: add_assoc [symmetric])
   434 done
   435 
   436 lemma real_of_preal_leD:
   437       "real_of_preal m1 \<le> real_of_preal m2 ==> m1 \<le> m2"
   438 by (simp add: real_of_preal_def real_le)
   439 
   440 lemma real_of_preal_lessI: "m1 < m2 ==> real_of_preal m1 < real_of_preal m2"
   441 by (auto simp add: real_of_preal_leD linorder_not_le [symmetric])
   442 
   443 lemma real_of_preal_lessD:
   444       "real_of_preal m1 < real_of_preal m2 ==> m1 < m2"
   445 by (simp add: real_of_preal_def real_le linorder_not_le [symmetric])
   446 
   447 lemma real_of_preal_less_iff [simp]:
   448      "(real_of_preal m1 < real_of_preal m2) = (m1 < m2)"
   449 by (blast intro: real_of_preal_lessI real_of_preal_lessD)
   450 
   451 lemma real_of_preal_le_iff:
   452      "(real_of_preal m1 \<le> real_of_preal m2) = (m1 \<le> m2)"
   453 by (simp add: linorder_not_less [symmetric])
   454 
   455 lemma real_of_preal_zero_less: "0 < real_of_preal m"
   456 apply (insert preal_self_less_add_left [of 1 m])
   457 apply (auto simp add: real_zero_def real_of_preal_def
   458                       real_less_def real_le_def add_ac)
   459 apply (rule_tac x="m + 1" in exI, rule_tac x="1" in exI)
   460 apply (simp add: add_ac)
   461 done
   462 
   463 lemma real_of_preal_minus_less_zero: "- real_of_preal m < 0"
   464 by (simp add: real_of_preal_zero_less)
   465 
   466 lemma real_of_preal_not_minus_gt_zero: "~ 0 < - real_of_preal m"
   467 proof -
   468   from real_of_preal_minus_less_zero
   469   show ?thesis by (blast dest: order_less_trans)
   470 qed
   471 
   472 
   473 subsection{*Theorems About the Ordering*}
   474 
   475 lemma real_gt_zero_preal_Ex: "(0 < x) = (\<exists>y. x = real_of_preal y)"
   476 apply (auto simp add: real_of_preal_zero_less)
   477 apply (cut_tac x = x in real_of_preal_trichotomy)
   478 apply (blast elim!: real_of_preal_not_minus_gt_zero [THEN notE])
   479 done
   480 
   481 lemma real_gt_preal_preal_Ex:
   482      "real_of_preal z < x ==> \<exists>y. x = real_of_preal y"
   483 by (blast dest!: real_of_preal_zero_less [THEN order_less_trans]
   484              intro: real_gt_zero_preal_Ex [THEN iffD1])
   485 
   486 lemma real_ge_preal_preal_Ex:
   487      "real_of_preal z \<le> x ==> \<exists>y. x = real_of_preal y"
   488 by (blast dest: order_le_imp_less_or_eq real_gt_preal_preal_Ex)
   489 
   490 lemma real_less_all_preal: "y \<le> 0 ==> \<forall>x. y < real_of_preal x"
   491 by (auto elim: order_le_imp_less_or_eq [THEN disjE] 
   492             intro: real_of_preal_zero_less [THEN [2] order_less_trans] 
   493             simp add: real_of_preal_zero_less)
   494 
   495 lemma real_less_all_real2: "~ 0 < y ==> \<forall>x. y < real_of_preal x"
   496 by (blast intro!: real_less_all_preal linorder_not_less [THEN iffD1])
   497 
   498 
   499 subsection{*More Lemmas*}
   500 
   501 lemma real_mult_left_cancel: "(c::real) \<noteq> 0 ==> (c*a=c*b) = (a=b)"
   502 by auto
   503 
   504 lemma real_mult_right_cancel: "(c::real) \<noteq> 0 ==> (a*c=b*c) = (a=b)"
   505 by auto
   506 
   507 lemma real_mult_less_iff1 [simp]: "(0::real) < z ==> (x*z < y*z) = (x < y)"
   508   by (force elim: order_less_asym
   509             simp add: Ring_and_Field.mult_less_cancel_right)
   510 
   511 lemma real_mult_le_cancel_iff1 [simp]: "(0::real) < z ==> (x*z \<le> y*z) = (x\<le>y)"
   512 apply (simp add: mult_le_cancel_right)
   513 apply (blast intro: elim: order_less_asym)
   514 done
   515 
   516 lemma real_mult_le_cancel_iff2 [simp]: "(0::real) < z ==> (z*x \<le> z*y) = (x\<le>y)"
   517 by(simp add:mult_commute)
   518 
   519 lemma real_inverse_gt_one: "[| (0::real) < x; x < 1 |] ==> 1 < inverse x"
   520 by (simp add: one_less_inverse_iff) (* TODO: generalize/move *)
   521 
   522 
   523 subsection{*Embedding the Integers into the Reals*}
   524 
   525 defs (overloaded)
   526   real_of_nat_def: "real z == of_nat z"
   527   real_of_int_def: "real z == of_int z"
   528 
   529 lemma real_eq_of_nat: "real = of_nat"
   530   apply (rule ext)
   531   apply (unfold real_of_nat_def)
   532   apply (rule refl)
   533   done
   534 
   535 lemma real_eq_of_int: "real = of_int"
   536   apply (rule ext)
   537   apply (unfold real_of_int_def)
   538   apply (rule refl)
   539   done
   540 
   541 lemma real_of_int_zero [simp]: "real (0::int) = 0"  
   542 by (simp add: real_of_int_def) 
   543 
   544 lemma real_of_one [simp]: "real (1::int) = (1::real)"
   545 by (simp add: real_of_int_def) 
   546 
   547 lemma real_of_int_add [simp]: "real(x + y) = real (x::int) + real y"
   548 by (simp add: real_of_int_def) 
   549 
   550 lemma real_of_int_minus [simp]: "real(-x) = -real (x::int)"
   551 by (simp add: real_of_int_def) 
   552 
   553 lemma real_of_int_diff [simp]: "real(x - y) = real (x::int) - real y"
   554 by (simp add: real_of_int_def) 
   555 
   556 lemma real_of_int_mult [simp]: "real(x * y) = real (x::int) * real y"
   557 by (simp add: real_of_int_def) 
   558 
   559 lemma real_of_int_setsum [simp]: "real ((SUM x:A. f x)::int) = (SUM x:A. real(f x))"
   560   apply (subst real_eq_of_int)+
   561   apply (rule of_int_setsum)
   562 done
   563 
   564 lemma real_of_int_setprod [simp]: "real ((PROD x:A. f x)::int) = 
   565     (PROD x:A. real(f x))"
   566   apply (subst real_eq_of_int)+
   567   apply (rule of_int_setprod)
   568 done
   569 
   570 lemma real_of_int_zero_cancel [simp]: "(real x = 0) = (x = (0::int))"
   571 by (simp add: real_of_int_def) 
   572 
   573 lemma real_of_int_inject [iff]: "(real (x::int) = real y) = (x = y)"
   574 by (simp add: real_of_int_def) 
   575 
   576 lemma real_of_int_less_iff [iff]: "(real (x::int) < real y) = (x < y)"
   577 by (simp add: real_of_int_def) 
   578 
   579 lemma real_of_int_le_iff [simp]: "(real (x::int) \<le> real y) = (x \<le> y)"
   580 by (simp add: real_of_int_def) 
   581 
   582 lemma real_of_int_gt_zero_cancel_iff [simp]: "(0 < real (n::int)) = (0 < n)"
   583 by (simp add: real_of_int_def) 
   584 
   585 lemma real_of_int_ge_zero_cancel_iff [simp]: "(0 <= real (n::int)) = (0 <= n)"
   586 by (simp add: real_of_int_def) 
   587 
   588 lemma real_of_int_lt_zero_cancel_iff [simp]: "(real (n::int) < 0) = (n < 0)"
   589 by (simp add: real_of_int_def)
   590 
   591 lemma real_of_int_le_zero_cancel_iff [simp]: "(real (n::int) <= 0) = (n <= 0)"
   592 by (simp add: real_of_int_def)
   593 
   594 lemma real_of_int_abs [simp]: "real (abs x) = abs(real (x::int))"
   595 by (auto simp add: abs_if)
   596 
   597 lemma int_less_real_le: "((n::int) < m) = (real n + 1 <= real m)"
   598   apply (subgoal_tac "real n + 1 = real (n + 1)")
   599   apply (simp del: real_of_int_add)
   600   apply auto
   601 done
   602 
   603 lemma int_le_real_less: "((n::int) <= m) = (real n < real m + 1)"
   604   apply (subgoal_tac "real m + 1 = real (m + 1)")
   605   apply (simp del: real_of_int_add)
   606   apply simp
   607 done
   608 
   609 lemma real_of_int_div_aux: "d ~= 0 ==> (real (x::int)) / (real d) = 
   610     real (x div d) + (real (x mod d)) / (real d)"
   611 proof -
   612   assume "d ~= 0"
   613   have "x = (x div d) * d + x mod d"
   614     by auto
   615   then have "real x = real (x div d) * real d + real(x mod d)"
   616     by (simp only: real_of_int_mult [THEN sym] real_of_int_add [THEN sym])
   617   then have "real x / real d = ... / real d"
   618     by simp
   619   then show ?thesis
   620     by (auto simp add: add_divide_distrib ring_simps prems)
   621 qed
   622 
   623 lemma real_of_int_div: "(d::int) ~= 0 ==> d dvd n ==>
   624     real(n div d) = real n / real d"
   625   apply (frule real_of_int_div_aux [of d n])
   626   apply simp
   627   apply (simp add: zdvd_iff_zmod_eq_0)
   628 done
   629 
   630 lemma real_of_int_div2:
   631   "0 <= real (n::int) / real (x) - real (n div x)"
   632   apply (case_tac "x = 0")
   633   apply simp
   634   apply (case_tac "0 < x")
   635   apply (simp add: compare_rls)
   636   apply (subst real_of_int_div_aux)
   637   apply simp
   638   apply simp
   639   apply (subst zero_le_divide_iff)
   640   apply auto
   641   apply (simp add: compare_rls)
   642   apply (subst real_of_int_div_aux)
   643   apply simp
   644   apply simp
   645   apply (subst zero_le_divide_iff)
   646   apply auto
   647 done
   648 
   649 lemma real_of_int_div3:
   650   "real (n::int) / real (x) - real (n div x) <= 1"
   651   apply(case_tac "x = 0")
   652   apply simp
   653   apply (simp add: compare_rls)
   654   apply (subst real_of_int_div_aux)
   655   apply assumption
   656   apply simp
   657   apply (subst divide_le_eq)
   658   apply clarsimp
   659   apply (rule conjI)
   660   apply (rule impI)
   661   apply (rule order_less_imp_le)
   662   apply simp
   663   apply (rule impI)
   664   apply (rule order_less_imp_le)
   665   apply simp
   666 done
   667 
   668 lemma real_of_int_div4: "real (n div x) <= real (n::int) / real x" 
   669   by (insert real_of_int_div2 [of n x], simp)
   670 
   671 subsection{*Embedding the Naturals into the Reals*}
   672 
   673 lemma real_of_nat_zero [simp]: "real (0::nat) = 0"
   674 by (simp add: real_of_nat_def)
   675 
   676 lemma real_of_nat_one [simp]: "real (Suc 0) = (1::real)"
   677 by (simp add: real_of_nat_def)
   678 
   679 lemma real_of_nat_add [simp]: "real (m + n) = real (m::nat) + real n"
   680 by (simp add: real_of_nat_def)
   681 
   682 (*Not for addsimps: often the LHS is used to represent a positive natural*)
   683 lemma real_of_nat_Suc: "real (Suc n) = real n + (1::real)"
   684 by (simp add: real_of_nat_def)
   685 
   686 lemma real_of_nat_less_iff [iff]: 
   687      "(real (n::nat) < real m) = (n < m)"
   688 by (simp add: real_of_nat_def)
   689 
   690 lemma real_of_nat_le_iff [iff]: "(real (n::nat) \<le> real m) = (n \<le> m)"
   691 by (simp add: real_of_nat_def)
   692 
   693 lemma real_of_nat_ge_zero [iff]: "0 \<le> real (n::nat)"
   694 by (simp add: real_of_nat_def zero_le_imp_of_nat)
   695 
   696 lemma real_of_nat_Suc_gt_zero: "0 < real (Suc n)"
   697 by (simp add: real_of_nat_def del: of_nat_Suc)
   698 
   699 lemma real_of_nat_mult [simp]: "real (m * n) = real (m::nat) * real n"
   700 by (simp add: real_of_nat_def of_nat_mult)
   701 
   702 lemma real_of_nat_setsum [simp]: "real ((SUM x:A. f x)::nat) = 
   703     (SUM x:A. real(f x))"
   704   apply (subst real_eq_of_nat)+
   705   apply (rule of_nat_setsum)
   706 done
   707 
   708 lemma real_of_nat_setprod [simp]: "real ((PROD x:A. f x)::nat) = 
   709     (PROD x:A. real(f x))"
   710   apply (subst real_eq_of_nat)+
   711   apply (rule of_nat_setprod)
   712 done
   713 
   714 lemma real_of_card: "real (card A) = setsum (%x.1) A"
   715   apply (subst card_eq_setsum)
   716   apply (subst real_of_nat_setsum)
   717   apply simp
   718 done
   719 
   720 lemma real_of_nat_inject [iff]: "(real (n::nat) = real m) = (n = m)"
   721 by (simp add: real_of_nat_def)
   722 
   723 lemma real_of_nat_zero_iff [iff]: "(real (n::nat) = 0) = (n = 0)"
   724 by (simp add: real_of_nat_def)
   725 
   726 lemma real_of_nat_diff: "n \<le> m ==> real (m - n) = real (m::nat) - real n"
   727 by (simp add: add: real_of_nat_def of_nat_diff)
   728 
   729 lemma real_of_nat_gt_zero_cancel_iff [simp]: "(0 < real (n::nat)) = (0 < n)"
   730 by (simp add: add: real_of_nat_def) 
   731 
   732 lemma real_of_nat_le_zero_cancel_iff [simp]: "(real (n::nat) \<le> 0) = (n = 0)"
   733 by (simp add: add: real_of_nat_def)
   734 
   735 lemma not_real_of_nat_less_zero [simp]: "~ real (n::nat) < 0"
   736 by (simp add: add: real_of_nat_def)
   737 
   738 lemma real_of_nat_ge_zero_cancel_iff [simp]: "(0 \<le> real (n::nat)) = (0 \<le> n)"
   739 by (simp add: add: real_of_nat_def)
   740 
   741 lemma nat_less_real_le: "((n::nat) < m) = (real n + 1 <= real m)"
   742   apply (subgoal_tac "real n + 1 = real (Suc n)")
   743   apply simp
   744   apply (auto simp add: real_of_nat_Suc)
   745 done
   746 
   747 lemma nat_le_real_less: "((n::nat) <= m) = (real n < real m + 1)"
   748   apply (subgoal_tac "real m + 1 = real (Suc m)")
   749   apply (simp add: less_Suc_eq_le)
   750   apply (simp add: real_of_nat_Suc)
   751 done
   752 
   753 lemma real_of_nat_div_aux: "0 < d ==> (real (x::nat)) / (real d) = 
   754     real (x div d) + (real (x mod d)) / (real d)"
   755 proof -
   756   assume "0 < d"
   757   have "x = (x div d) * d + x mod d"
   758     by auto
   759   then have "real x = real (x div d) * real d + real(x mod d)"
   760     by (simp only: real_of_nat_mult [THEN sym] real_of_nat_add [THEN sym])
   761   then have "real x / real d = \<dots> / real d"
   762     by simp
   763   then show ?thesis
   764     by (auto simp add: add_divide_distrib ring_simps prems)
   765 qed
   766 
   767 lemma real_of_nat_div: "0 < (d::nat) ==> d dvd n ==>
   768     real(n div d) = real n / real d"
   769   apply (frule real_of_nat_div_aux [of d n])
   770   apply simp
   771   apply (subst dvd_eq_mod_eq_0 [THEN sym])
   772   apply assumption
   773 done
   774 
   775 lemma real_of_nat_div2:
   776   "0 <= real (n::nat) / real (x) - real (n div x)"
   777   apply(case_tac "x = 0")
   778   apply simp
   779   apply (simp add: compare_rls)
   780   apply (subst real_of_nat_div_aux)
   781   apply assumption
   782   apply simp
   783   apply (subst zero_le_divide_iff)
   784   apply simp
   785 done
   786 
   787 lemma real_of_nat_div3:
   788   "real (n::nat) / real (x) - real (n div x) <= 1"
   789   apply(case_tac "x = 0")
   790   apply simp
   791   apply (simp add: compare_rls)
   792   apply (subst real_of_nat_div_aux)
   793   apply assumption
   794   apply simp
   795 done
   796 
   797 lemma real_of_nat_div4: "real (n div x) <= real (n::nat) / real x" 
   798   by (insert real_of_nat_div2 [of n x], simp)
   799 
   800 lemma real_of_int_real_of_nat: "real (int n) = real n"
   801 by (simp add: real_of_nat_def real_of_int_def int_eq_of_nat)
   802 
   803 lemma real_of_int_of_nat_eq [simp]: "real (of_nat n :: int) = real n"
   804 by (simp add: real_of_int_def real_of_nat_def)
   805 
   806 lemma real_nat_eq_real [simp]: "0 <= x ==> real(nat x) = real x"
   807   apply (subgoal_tac "real(int(nat x)) = real(nat x)")
   808   apply force
   809   apply (simp only: real_of_int_real_of_nat)
   810 done
   811 
   812 subsection{*Numerals and Arithmetic*}
   813 
   814 instance real :: number ..
   815 
   816 defs (overloaded)
   817   real_number_of_def: "(number_of w :: real) == of_int w"
   818     --{*the type constraint is essential!*}
   819 
   820 instance real :: number_ring
   821 by (intro_classes, simp add: real_number_of_def) 
   822 
   823 text{*Collapse applications of @{term real} to @{term number_of}*}
   824 lemma real_number_of [simp]: "real (number_of v :: int) = number_of v"
   825 by (simp add:  real_of_int_def of_int_number_of_eq)
   826 
   827 lemma real_of_nat_number_of [simp]:
   828      "real (number_of v :: nat) =  
   829         (if neg (number_of v :: int) then 0  
   830          else (number_of v :: real))"
   831 by (simp add: real_of_int_real_of_nat [symmetric] int_nat_number_of)
   832  
   833 
   834 use "real_arith.ML"
   835 
   836 setup real_arith_setup
   837 
   838 
   839 subsection{* Simprules combining x+y and 0: ARE THEY NEEDED?*}
   840 
   841 text{*Needed in this non-standard form by Hyperreal/Transcendental*}
   842 lemma real_0_le_divide_iff:
   843      "((0::real) \<le> x/y) = ((x \<le> 0 | 0 \<le> y) & (0 \<le> x | y \<le> 0))"
   844 by (simp add: real_divide_def zero_le_mult_iff, auto)
   845 
   846 lemma real_add_minus_iff [simp]: "(x + - a = (0::real)) = (x=a)" 
   847 by arith
   848 
   849 lemma real_add_eq_0_iff: "(x+y = (0::real)) = (y = -x)"
   850 by auto
   851 
   852 lemma real_add_less_0_iff: "(x+y < (0::real)) = (y < -x)"
   853 by auto
   854 
   855 lemma real_0_less_add_iff: "((0::real) < x+y) = (-x < y)"
   856 by auto
   857 
   858 lemma real_add_le_0_iff: "(x+y \<le> (0::real)) = (y \<le> -x)"
   859 by auto
   860 
   861 lemma real_0_le_add_iff: "((0::real) \<le> x+y) = (-x \<le> y)"
   862 by auto
   863 
   864 
   865 (*
   866 FIXME: we should have this, as for type int, but many proofs would break.
   867 It replaces x+-y by x-y.
   868 declare real_diff_def [symmetric, simp]
   869 *)
   870 
   871 
   872 subsubsection{*Density of the Reals*}
   873 
   874 lemma real_lbound_gt_zero:
   875      "[| (0::real) < d1; 0 < d2 |] ==> \<exists>e. 0 < e & e < d1 & e < d2"
   876 apply (rule_tac x = " (min d1 d2) /2" in exI)
   877 apply (simp add: min_def)
   878 done
   879 
   880 
   881 text{*Similar results are proved in @{text Ring_and_Field}*}
   882 lemma real_less_half_sum: "x < y ==> x < (x+y) / (2::real)"
   883   by auto
   884 
   885 lemma real_gt_half_sum: "x < y ==> (x+y)/(2::real) < y"
   886   by auto
   887 
   888 
   889 subsection{*Absolute Value Function for the Reals*}
   890 
   891 lemma abs_minus_add_cancel: "abs(x + (-y)) = abs (y + (-(x::real)))"
   892 by (simp add: abs_if)
   893 
   894 (* FIXME: redundant, but used by Integration/RealRandVar.thy in AFP *)
   895 lemma abs_le_interval_iff: "(abs x \<le> r) = (-r\<le>x & x\<le>(r::real))"
   896 by (force simp add: OrderedGroup.abs_le_iff)
   897 
   898 lemma abs_add_one_gt_zero [simp]: "(0::real) < 1 + abs(x)"
   899 by (simp add: abs_if)
   900 
   901 lemma abs_real_of_nat_cancel [simp]: "abs (real x) = real (x::nat)"
   902 by (rule abs_of_nonneg [OF real_of_nat_ge_zero])
   903 
   904 lemma abs_add_one_not_less_self [simp]: "~ abs(x) + (1::real) < x"
   905 by simp
   906  
   907 lemma abs_sum_triangle_ineq: "abs ((x::real) + y + (-l + -m)) \<le> abs(x + -l) + abs(y + -m)"
   908 by simp
   909 
   910 subsection{*Code generation using Isabelle's rats*}
   911 
   912 types_code
   913   real ("Rat.rat")
   914 attach (term_of) {*
   915 fun term_of_real x =
   916  let 
   917   val rT = HOLogic.realT
   918   val (p, q) = Rat.quotient_of_rat x
   919  in if q = 1 then HOLogic.mk_number rT p
   920     else Const("HOL.divide",[rT,rT] ---> rT) $
   921            (HOLogic.mk_number rT p) $ (HOLogic.mk_number rT q)
   922 end;
   923 *}
   924 attach (test) {*
   925 fun gen_real i =
   926 let val p = random_range 0 i; val q = random_range 0 i;
   927     val r = if q=0 then Rat.rat_of_int i else Rat.rat_of_quotient(p,q)
   928 in if one_of [true,false] then r else Rat.neg r end;
   929 *}
   930 
   931 consts_code
   932   "0 :: real" ("Rat.zero")
   933   "1 :: real" ("Rat.one")
   934   "uminus :: real \<Rightarrow> real" ("Rat.neg")
   935   "op + :: real \<Rightarrow> real \<Rightarrow> real" ("Rat.add")
   936   "op * :: real \<Rightarrow> real \<Rightarrow> real" ("Rat.mult")
   937   "inverse :: real \<Rightarrow> real" ("Rat.inv")
   938   "op \<le> :: real \<Rightarrow> real \<Rightarrow> bool" ("Rat.le")
   939   "op < :: real \<Rightarrow> real \<Rightarrow> bool" ("Rat.lt")
   940   "op = :: real \<Rightarrow> real \<Rightarrow> bool" ("curry Rat.eq")
   941   "real :: int \<Rightarrow> real" ("Rat.rat'_of'_int")
   942   "real :: nat \<Rightarrow> real" ("(Rat.rat'_of'_int o {*int*})")
   943 
   944 lemma [code, code unfold]:
   945   "number_of k = real (number_of k :: int)"
   946   by simp
   947 
   948 end