src/HOL/Limits.thy
author hoelzl
Mon Mar 14 14:37:35 2011 +0100 (2011-03-14)
changeset 41970 47d6e13d1710
parent 39302 d7728f65b353
child 44079 bcc60791b7b9
permissions -rw-r--r--
generalize infinite sums
     1 (*  Title       : Limits.thy
     2     Author      : Brian Huffman
     3 *)
     4 
     5 header {* Filters and Limits *}
     6 
     7 theory Limits
     8 imports RealVector
     9 begin
    10 
    11 subsection {* Nets *}
    12 
    13 text {*
    14   A net is now defined simply as a filter on a set.
    15   The definition also allows non-proper filters.
    16 *}
    17 
    18 locale is_filter =
    19   fixes net :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
    20   assumes True: "net (\<lambda>x. True)"
    21   assumes conj: "net (\<lambda>x. P x) \<Longrightarrow> net (\<lambda>x. Q x) \<Longrightarrow> net (\<lambda>x. P x \<and> Q x)"
    22   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> net (\<lambda>x. P x) \<Longrightarrow> net (\<lambda>x. Q x)"
    23 
    24 typedef (open) 'a net =
    25   "{net :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter net}"
    26 proof
    27   show "(\<lambda>x. True) \<in> ?net" by (auto intro: is_filter.intro)
    28 qed
    29 
    30 lemma is_filter_Rep_net: "is_filter (Rep_net net)"
    31 using Rep_net [of net] by simp
    32 
    33 lemma Abs_net_inverse':
    34   assumes "is_filter net" shows "Rep_net (Abs_net net) = net"
    35 using assms by (simp add: Abs_net_inverse)
    36 
    37 
    38 subsection {* Eventually *}
    39 
    40 definition eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a net \<Rightarrow> bool" where
    41   "eventually P net \<longleftrightarrow> Rep_net net P"
    42 
    43 lemma eventually_Abs_net:
    44   assumes "is_filter net" shows "eventually P (Abs_net net) = net P"
    45 unfolding eventually_def using assms by (simp add: Abs_net_inverse)
    46 
    47 lemma expand_net_eq:
    48   shows "net = net' \<longleftrightarrow> (\<forall>P. eventually P net = eventually P net')"
    49 unfolding Rep_net_inject [symmetric] fun_eq_iff eventually_def ..
    50 
    51 lemma eventually_True [simp]: "eventually (\<lambda>x. True) net"
    52 unfolding eventually_def
    53 by (rule is_filter.True [OF is_filter_Rep_net])
    54 
    55 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P net"
    56 proof -
    57   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
    58   thus "eventually P net" by simp
    59 qed
    60 
    61 lemma eventually_mono:
    62   "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually P net \<Longrightarrow> eventually Q net"
    63 unfolding eventually_def
    64 by (rule is_filter.mono [OF is_filter_Rep_net])
    65 
    66 lemma eventually_conj:
    67   assumes P: "eventually (\<lambda>x. P x) net"
    68   assumes Q: "eventually (\<lambda>x. Q x) net"
    69   shows "eventually (\<lambda>x. P x \<and> Q x) net"
    70 using assms unfolding eventually_def
    71 by (rule is_filter.conj [OF is_filter_Rep_net])
    72 
    73 lemma eventually_mp:
    74   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) net"
    75   assumes "eventually (\<lambda>x. P x) net"
    76   shows "eventually (\<lambda>x. Q x) net"
    77 proof (rule eventually_mono)
    78   show "\<forall>x. (P x \<longrightarrow> Q x) \<and> P x \<longrightarrow> Q x" by simp
    79   show "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) net"
    80     using assms by (rule eventually_conj)
    81 qed
    82 
    83 lemma eventually_rev_mp:
    84   assumes "eventually (\<lambda>x. P x) net"
    85   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) net"
    86   shows "eventually (\<lambda>x. Q x) net"
    87 using assms(2) assms(1) by (rule eventually_mp)
    88 
    89 lemma eventually_conj_iff:
    90   "eventually (\<lambda>x. P x \<and> Q x) net \<longleftrightarrow> eventually P net \<and> eventually Q net"
    91 by (auto intro: eventually_conj elim: eventually_rev_mp)
    92 
    93 lemma eventually_elim1:
    94   assumes "eventually (\<lambda>i. P i) net"
    95   assumes "\<And>i. P i \<Longrightarrow> Q i"
    96   shows "eventually (\<lambda>i. Q i) net"
    97 using assms by (auto elim!: eventually_rev_mp)
    98 
    99 lemma eventually_elim2:
   100   assumes "eventually (\<lambda>i. P i) net"
   101   assumes "eventually (\<lambda>i. Q i) net"
   102   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
   103   shows "eventually (\<lambda>i. R i) net"
   104 using assms by (auto elim!: eventually_rev_mp)
   105 
   106 subsection {* Finer-than relation *}
   107 
   108 text {* @{term "net \<le> net'"} means that @{term net} is finer than
   109 @{term net'}. *}
   110 
   111 instantiation net :: (type) complete_lattice
   112 begin
   113 
   114 definition
   115   le_net_def: "net \<le> net' \<longleftrightarrow> (\<forall>P. eventually P net' \<longrightarrow> eventually P net)"
   116 
   117 definition
   118   less_net_def: "(net :: 'a net) < net' \<longleftrightarrow> net \<le> net' \<and> \<not> net' \<le> net"
   119 
   120 definition
   121   top_net_def: "top = Abs_net (\<lambda>P. \<forall>x. P x)"
   122 
   123 definition
   124   bot_net_def: "bot = Abs_net (\<lambda>P. True)"
   125 
   126 definition
   127   sup_net_def: "sup net net' = Abs_net (\<lambda>P. eventually P net \<and> eventually P net')"
   128 
   129 definition
   130   inf_net_def: "inf a b = Abs_net
   131       (\<lambda>P. \<exists>Q R. eventually Q a \<and> eventually R b \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   132 
   133 definition
   134   Sup_net_def: "Sup A = Abs_net (\<lambda>P. \<forall>net\<in>A. eventually P net)"
   135 
   136 definition
   137   Inf_net_def: "Inf A = Sup {x::'a net. \<forall>y\<in>A. x \<le> y}"
   138 
   139 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
   140 unfolding top_net_def
   141 by (rule eventually_Abs_net, rule is_filter.intro, auto)
   142 
   143 lemma eventually_bot [simp]: "eventually P bot"
   144 unfolding bot_net_def
   145 by (subst eventually_Abs_net, rule is_filter.intro, auto)
   146 
   147 lemma eventually_sup:
   148   "eventually P (sup net net') \<longleftrightarrow> eventually P net \<and> eventually P net'"
   149 unfolding sup_net_def
   150 by (rule eventually_Abs_net, rule is_filter.intro)
   151    (auto elim!: eventually_rev_mp)
   152 
   153 lemma eventually_inf:
   154   "eventually P (inf a b) \<longleftrightarrow>
   155    (\<exists>Q R. eventually Q a \<and> eventually R b \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   156 unfolding inf_net_def
   157 apply (rule eventually_Abs_net, rule is_filter.intro)
   158 apply (fast intro: eventually_True)
   159 apply clarify
   160 apply (intro exI conjI)
   161 apply (erule (1) eventually_conj)
   162 apply (erule (1) eventually_conj)
   163 apply simp
   164 apply auto
   165 done
   166 
   167 lemma eventually_Sup:
   168   "eventually P (Sup A) \<longleftrightarrow> (\<forall>net\<in>A. eventually P net)"
   169 unfolding Sup_net_def
   170 apply (rule eventually_Abs_net, rule is_filter.intro)
   171 apply (auto intro: eventually_conj elim!: eventually_rev_mp)
   172 done
   173 
   174 instance proof
   175   fix x y :: "'a net" show "x < y \<longleftrightarrow> x \<le> y \<and> \<not> y \<le> x"
   176     by (rule less_net_def)
   177 next
   178   fix x :: "'a net" show "x \<le> x"
   179     unfolding le_net_def by simp
   180 next
   181   fix x y z :: "'a net" assume "x \<le> y" and "y \<le> z" thus "x \<le> z"
   182     unfolding le_net_def by simp
   183 next
   184   fix x y :: "'a net" assume "x \<le> y" and "y \<le> x" thus "x = y"
   185     unfolding le_net_def expand_net_eq by fast
   186 next
   187   fix x :: "'a net" show "x \<le> top"
   188     unfolding le_net_def eventually_top by (simp add: always_eventually)
   189 next
   190   fix x :: "'a net" show "bot \<le> x"
   191     unfolding le_net_def by simp
   192 next
   193   fix x y :: "'a net" show "x \<le> sup x y" and "y \<le> sup x y"
   194     unfolding le_net_def eventually_sup by simp_all
   195 next
   196   fix x y z :: "'a net" assume "x \<le> z" and "y \<le> z" thus "sup x y \<le> z"
   197     unfolding le_net_def eventually_sup by simp
   198 next
   199   fix x y :: "'a net" show "inf x y \<le> x" and "inf x y \<le> y"
   200     unfolding le_net_def eventually_inf by (auto intro: eventually_True)
   201 next
   202   fix x y z :: "'a net" assume "x \<le> y" and "x \<le> z" thus "x \<le> inf y z"
   203     unfolding le_net_def eventually_inf
   204     by (auto elim!: eventually_mono intro: eventually_conj)
   205 next
   206   fix x :: "'a net" and A assume "x \<in> A" thus "x \<le> Sup A"
   207     unfolding le_net_def eventually_Sup by simp
   208 next
   209   fix A and y :: "'a net" assume "\<And>x. x \<in> A \<Longrightarrow> x \<le> y" thus "Sup A \<le> y"
   210     unfolding le_net_def eventually_Sup by simp
   211 next
   212   fix z :: "'a net" and A assume "z \<in> A" thus "Inf A \<le> z"
   213     unfolding le_net_def Inf_net_def eventually_Sup Ball_def by simp
   214 next
   215   fix A and x :: "'a net" assume "\<And>y. y \<in> A \<Longrightarrow> x \<le> y" thus "x \<le> Inf A"
   216     unfolding le_net_def Inf_net_def eventually_Sup Ball_def by simp
   217 qed
   218 
   219 end
   220 
   221 lemma net_leD:
   222   "net \<le> net' \<Longrightarrow> eventually P net' \<Longrightarrow> eventually P net"
   223 unfolding le_net_def by simp
   224 
   225 lemma net_leI:
   226   "(\<And>P. eventually P net' \<Longrightarrow> eventually P net) \<Longrightarrow> net \<le> net'"
   227 unfolding le_net_def by simp
   228 
   229 lemma eventually_False:
   230   "eventually (\<lambda>x. False) net \<longleftrightarrow> net = bot"
   231 unfolding expand_net_eq by (auto elim: eventually_rev_mp)
   232 
   233 subsection {* Map function for nets *}
   234 
   235 definition netmap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a net \<Rightarrow> 'b net" where
   236   "netmap f net = Abs_net (\<lambda>P. eventually (\<lambda>x. P (f x)) net)"
   237 
   238 lemma eventually_netmap:
   239   "eventually P (netmap f net) = eventually (\<lambda>x. P (f x)) net"
   240 unfolding netmap_def
   241 apply (rule eventually_Abs_net)
   242 apply (rule is_filter.intro)
   243 apply (auto elim!: eventually_rev_mp)
   244 done
   245 
   246 lemma netmap_ident: "netmap (\<lambda>x. x) net = net"
   247 by (simp add: expand_net_eq eventually_netmap)
   248 
   249 lemma netmap_netmap: "netmap f (netmap g net) = netmap (\<lambda>x. f (g x)) net"
   250 by (simp add: expand_net_eq eventually_netmap)
   251 
   252 lemma netmap_mono: "net \<le> net' \<Longrightarrow> netmap f net \<le> netmap f net'"
   253 unfolding le_net_def eventually_netmap by simp
   254 
   255 lemma netmap_bot [simp]: "netmap f bot = bot"
   256 by (simp add: expand_net_eq eventually_netmap)
   257 
   258 
   259 subsection {* Sequentially *}
   260 
   261 definition sequentially :: "nat net" where
   262   "sequentially = Abs_net (\<lambda>P. \<exists>k. \<forall>n\<ge>k. P n)"
   263 
   264 lemma eventually_sequentially:
   265   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   266 unfolding sequentially_def
   267 proof (rule eventually_Abs_net, rule is_filter.intro)
   268   fix P Q :: "nat \<Rightarrow> bool"
   269   assume "\<exists>i. \<forall>n\<ge>i. P n" and "\<exists>j. \<forall>n\<ge>j. Q n"
   270   then obtain i j where "\<forall>n\<ge>i. P n" and "\<forall>n\<ge>j. Q n" by auto
   271   then have "\<forall>n\<ge>max i j. P n \<and> Q n" by simp
   272   then show "\<exists>k. \<forall>n\<ge>k. P n \<and> Q n" ..
   273 qed auto
   274 
   275 lemma sequentially_bot [simp]: "sequentially \<noteq> bot"
   276 unfolding expand_net_eq eventually_sequentially by auto
   277 
   278 lemma eventually_False_sequentially [simp]:
   279   "\<not> eventually (\<lambda>n. False) sequentially"
   280 by (simp add: eventually_False)
   281 
   282 lemma le_sequentially:
   283   "net \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) net)"
   284 unfolding le_net_def eventually_sequentially
   285 by (safe, fast, drule_tac x=N in spec, auto elim: eventually_rev_mp)
   286 
   287 
   288 definition
   289   trivial_limit :: "'a net \<Rightarrow> bool" where
   290   "trivial_limit net \<longleftrightarrow> eventually (\<lambda>x. False) net"
   291 
   292 lemma trivial_limit_sequentially[intro]: "\<not> trivial_limit sequentially"
   293   by (auto simp add: trivial_limit_def eventually_sequentially)
   294 
   295 subsection {* Standard Nets *}
   296 
   297 definition within :: "'a net \<Rightarrow> 'a set \<Rightarrow> 'a net" (infixr "within" 70) where
   298   "net within S = Abs_net (\<lambda>P. eventually (\<lambda>x. x \<in> S \<longrightarrow> P x) net)"
   299 
   300 definition nhds :: "'a::topological_space \<Rightarrow> 'a net" where
   301   "nhds a = Abs_net (\<lambda>P. \<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   302 
   303 definition at :: "'a::topological_space \<Rightarrow> 'a net" where
   304   "at a = nhds a within - {a}"
   305 
   306 lemma eventually_within:
   307   "eventually P (net within S) = eventually (\<lambda>x. x \<in> S \<longrightarrow> P x) net"
   308 unfolding within_def
   309 by (rule eventually_Abs_net, rule is_filter.intro)
   310    (auto elim!: eventually_rev_mp)
   311 
   312 lemma within_UNIV: "net within UNIV = net"
   313   unfolding expand_net_eq eventually_within by simp
   314 
   315 lemma eventually_nhds:
   316   "eventually P (nhds a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   317 unfolding nhds_def
   318 proof (rule eventually_Abs_net, rule is_filter.intro)
   319   have "open UNIV \<and> a \<in> UNIV \<and> (\<forall>x\<in>UNIV. True)" by simp
   320   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. True)" by - rule
   321 next
   322   fix P Q
   323   assume "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
   324      and "\<exists>T. open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)"
   325   then obtain S T where
   326     "open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
   327     "open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)" by auto
   328   hence "open (S \<inter> T) \<and> a \<in> S \<inter> T \<and> (\<forall>x\<in>(S \<inter> T). P x \<and> Q x)"
   329     by (simp add: open_Int)
   330   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x \<and> Q x)" by - rule
   331 qed auto
   332 
   333 lemma eventually_nhds_metric:
   334   "eventually P (nhds a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. dist x a < d \<longrightarrow> P x)"
   335 unfolding eventually_nhds open_dist
   336 apply safe
   337 apply fast
   338 apply (rule_tac x="{x. dist x a < d}" in exI, simp)
   339 apply clarsimp
   340 apply (rule_tac x="d - dist x a" in exI, clarsimp)
   341 apply (simp only: less_diff_eq)
   342 apply (erule le_less_trans [OF dist_triangle])
   343 done
   344 
   345 lemma eventually_at_topological:
   346   "eventually P (at a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> P x))"
   347 unfolding at_def eventually_within eventually_nhds by simp
   348 
   349 lemma eventually_at:
   350   fixes a :: "'a::metric_space"
   351   shows "eventually P (at a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> P x)"
   352 unfolding at_def eventually_within eventually_nhds_metric by auto
   353 
   354 
   355 subsection {* Boundedness *}
   356 
   357 definition Bfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a net \<Rightarrow> bool" where
   358   "Bfun f net = (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) net)"
   359 
   360 lemma BfunI:
   361   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) net" shows "Bfun f net"
   362 unfolding Bfun_def
   363 proof (intro exI conjI allI)
   364   show "0 < max K 1" by simp
   365 next
   366   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) net"
   367     using K by (rule eventually_elim1, simp)
   368 qed
   369 
   370 lemma BfunE:
   371   assumes "Bfun f net"
   372   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) net"
   373 using assms unfolding Bfun_def by fast
   374 
   375 
   376 subsection {* Convergence to Zero *}
   377 
   378 definition Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a net \<Rightarrow> bool" where
   379   "Zfun f net = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) net)"
   380 
   381 lemma ZfunI:
   382   "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) net) \<Longrightarrow> Zfun f net"
   383 unfolding Zfun_def by simp
   384 
   385 lemma ZfunD:
   386   "\<lbrakk>Zfun f net; 0 < r\<rbrakk> \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) net"
   387 unfolding Zfun_def by simp
   388 
   389 lemma Zfun_ssubst:
   390   "eventually (\<lambda>x. f x = g x) net \<Longrightarrow> Zfun g net \<Longrightarrow> Zfun f net"
   391 unfolding Zfun_def by (auto elim!: eventually_rev_mp)
   392 
   393 lemma Zfun_zero: "Zfun (\<lambda>x. 0) net"
   394 unfolding Zfun_def by simp
   395 
   396 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) net = Zfun (\<lambda>x. f x) net"
   397 unfolding Zfun_def by simp
   398 
   399 lemma Zfun_imp_Zfun:
   400   assumes f: "Zfun f net"
   401   assumes g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) net"
   402   shows "Zfun (\<lambda>x. g x) net"
   403 proof (cases)
   404   assume K: "0 < K"
   405   show ?thesis
   406   proof (rule ZfunI)
   407     fix r::real assume "0 < r"
   408     hence "0 < r / K"
   409       using K by (rule divide_pos_pos)
   410     then have "eventually (\<lambda>x. norm (f x) < r / K) net"
   411       using ZfunD [OF f] by fast
   412     with g show "eventually (\<lambda>x. norm (g x) < r) net"
   413     proof (rule eventually_elim2)
   414       fix x
   415       assume *: "norm (g x) \<le> norm (f x) * K"
   416       assume "norm (f x) < r / K"
   417       hence "norm (f x) * K < r"
   418         by (simp add: pos_less_divide_eq K)
   419       thus "norm (g x) < r"
   420         by (simp add: order_le_less_trans [OF *])
   421     qed
   422   qed
   423 next
   424   assume "\<not> 0 < K"
   425   hence K: "K \<le> 0" by (simp only: not_less)
   426   show ?thesis
   427   proof (rule ZfunI)
   428     fix r :: real
   429     assume "0 < r"
   430     from g show "eventually (\<lambda>x. norm (g x) < r) net"
   431     proof (rule eventually_elim1)
   432       fix x
   433       assume "norm (g x) \<le> norm (f x) * K"
   434       also have "\<dots> \<le> norm (f x) * 0"
   435         using K norm_ge_zero by (rule mult_left_mono)
   436       finally show "norm (g x) < r"
   437         using `0 < r` by simp
   438     qed
   439   qed
   440 qed
   441 
   442 lemma Zfun_le: "\<lbrakk>Zfun g net; \<forall>x. norm (f x) \<le> norm (g x)\<rbrakk> \<Longrightarrow> Zfun f net"
   443 by (erule_tac K="1" in Zfun_imp_Zfun, simp)
   444 
   445 lemma Zfun_add:
   446   assumes f: "Zfun f net" and g: "Zfun g net"
   447   shows "Zfun (\<lambda>x. f x + g x) net"
   448 proof (rule ZfunI)
   449   fix r::real assume "0 < r"
   450   hence r: "0 < r / 2" by simp
   451   have "eventually (\<lambda>x. norm (f x) < r/2) net"
   452     using f r by (rule ZfunD)
   453   moreover
   454   have "eventually (\<lambda>x. norm (g x) < r/2) net"
   455     using g r by (rule ZfunD)
   456   ultimately
   457   show "eventually (\<lambda>x. norm (f x + g x) < r) net"
   458   proof (rule eventually_elim2)
   459     fix x
   460     assume *: "norm (f x) < r/2" "norm (g x) < r/2"
   461     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
   462       by (rule norm_triangle_ineq)
   463     also have "\<dots> < r/2 + r/2"
   464       using * by (rule add_strict_mono)
   465     finally show "norm (f x + g x) < r"
   466       by simp
   467   qed
   468 qed
   469 
   470 lemma Zfun_minus: "Zfun f net \<Longrightarrow> Zfun (\<lambda>x. - f x) net"
   471 unfolding Zfun_def by simp
   472 
   473 lemma Zfun_diff: "\<lbrakk>Zfun f net; Zfun g net\<rbrakk> \<Longrightarrow> Zfun (\<lambda>x. f x - g x) net"
   474 by (simp only: diff_minus Zfun_add Zfun_minus)
   475 
   476 lemma (in bounded_linear) Zfun:
   477   assumes g: "Zfun g net"
   478   shows "Zfun (\<lambda>x. f (g x)) net"
   479 proof -
   480   obtain K where "\<And>x. norm (f x) \<le> norm x * K"
   481     using bounded by fast
   482   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) net"
   483     by simp
   484   with g show ?thesis
   485     by (rule Zfun_imp_Zfun)
   486 qed
   487 
   488 lemma (in bounded_bilinear) Zfun:
   489   assumes f: "Zfun f net"
   490   assumes g: "Zfun g net"
   491   shows "Zfun (\<lambda>x. f x ** g x) net"
   492 proof (rule ZfunI)
   493   fix r::real assume r: "0 < r"
   494   obtain K where K: "0 < K"
   495     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   496     using pos_bounded by fast
   497   from K have K': "0 < inverse K"
   498     by (rule positive_imp_inverse_positive)
   499   have "eventually (\<lambda>x. norm (f x) < r) net"
   500     using f r by (rule ZfunD)
   501   moreover
   502   have "eventually (\<lambda>x. norm (g x) < inverse K) net"
   503     using g K' by (rule ZfunD)
   504   ultimately
   505   show "eventually (\<lambda>x. norm (f x ** g x) < r) net"
   506   proof (rule eventually_elim2)
   507     fix x
   508     assume *: "norm (f x) < r" "norm (g x) < inverse K"
   509     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   510       by (rule norm_le)
   511     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
   512       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero * K)
   513     also from K have "r * inverse K * K = r"
   514       by simp
   515     finally show "norm (f x ** g x) < r" .
   516   qed
   517 qed
   518 
   519 lemma (in bounded_bilinear) Zfun_left:
   520   "Zfun f net \<Longrightarrow> Zfun (\<lambda>x. f x ** a) net"
   521 by (rule bounded_linear_left [THEN bounded_linear.Zfun])
   522 
   523 lemma (in bounded_bilinear) Zfun_right:
   524   "Zfun f net \<Longrightarrow> Zfun (\<lambda>x. a ** f x) net"
   525 by (rule bounded_linear_right [THEN bounded_linear.Zfun])
   526 
   527 lemmas Zfun_mult = mult.Zfun
   528 lemmas Zfun_mult_right = mult.Zfun_right
   529 lemmas Zfun_mult_left = mult.Zfun_left
   530 
   531 
   532 subsection {* Limits *}
   533 
   534 definition tendsto :: "('a \<Rightarrow> 'b::topological_space) \<Rightarrow> 'b \<Rightarrow> 'a net \<Rightarrow> bool"
   535     (infixr "--->" 55) where
   536   "(f ---> l) net \<longleftrightarrow> (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) net)"
   537 
   538 ML {*
   539 structure Tendsto_Intros = Named_Thms
   540 (
   541   val name = "tendsto_intros"
   542   val description = "introduction rules for tendsto"
   543 )
   544 *}
   545 
   546 setup Tendsto_Intros.setup
   547 
   548 lemma tendsto_mono: "net \<le> net' \<Longrightarrow> (f ---> l) net' \<Longrightarrow> (f ---> l) net"
   549 unfolding tendsto_def le_net_def by fast
   550 
   551 lemma topological_tendstoI:
   552   "(\<And>S. open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) net)
   553     \<Longrightarrow> (f ---> l) net"
   554   unfolding tendsto_def by auto
   555 
   556 lemma topological_tendstoD:
   557   "(f ---> l) net \<Longrightarrow> open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) net"
   558   unfolding tendsto_def by auto
   559 
   560 lemma tendstoI:
   561   assumes "\<And>e. 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) net"
   562   shows "(f ---> l) net"
   563 apply (rule topological_tendstoI)
   564 apply (simp add: open_dist)
   565 apply (drule (1) bspec, clarify)
   566 apply (drule assms)
   567 apply (erule eventually_elim1, simp)
   568 done
   569 
   570 lemma tendstoD:
   571   "(f ---> l) net \<Longrightarrow> 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) net"
   572 apply (drule_tac S="{x. dist x l < e}" in topological_tendstoD)
   573 apply (clarsimp simp add: open_dist)
   574 apply (rule_tac x="e - dist x l" in exI, clarsimp)
   575 apply (simp only: less_diff_eq)
   576 apply (erule le_less_trans [OF dist_triangle])
   577 apply simp
   578 apply simp
   579 done
   580 
   581 lemma tendsto_iff:
   582   "(f ---> l) net \<longleftrightarrow> (\<forall>e>0. eventually (\<lambda>x. dist (f x) l < e) net)"
   583 using tendstoI tendstoD by fast
   584 
   585 lemma tendsto_Zfun_iff: "(f ---> a) net = Zfun (\<lambda>x. f x - a) net"
   586 by (simp only: tendsto_iff Zfun_def dist_norm)
   587 
   588 lemma tendsto_ident_at [tendsto_intros]: "((\<lambda>x. x) ---> a) (at a)"
   589 unfolding tendsto_def eventually_at_topological by auto
   590 
   591 lemma tendsto_ident_at_within [tendsto_intros]:
   592   "((\<lambda>x. x) ---> a) (at a within S)"
   593 unfolding tendsto_def eventually_within eventually_at_topological by auto
   594 
   595 lemma tendsto_const [tendsto_intros]: "((\<lambda>x. k) ---> k) net"
   596 by (simp add: tendsto_def)
   597 
   598 lemma tendsto_const_iff:
   599   fixes k l :: "'a::metric_space"
   600   assumes "net \<noteq> bot" shows "((\<lambda>n. k) ---> l) net \<longleftrightarrow> k = l"
   601 apply (safe intro!: tendsto_const)
   602 apply (rule ccontr)
   603 apply (drule_tac e="dist k l" in tendstoD)
   604 apply (simp add: zero_less_dist_iff)
   605 apply (simp add: eventually_False assms)
   606 done
   607 
   608 lemma tendsto_dist [tendsto_intros]:
   609   assumes f: "(f ---> l) net" and g: "(g ---> m) net"
   610   shows "((\<lambda>x. dist (f x) (g x)) ---> dist l m) net"
   611 proof (rule tendstoI)
   612   fix e :: real assume "0 < e"
   613   hence e2: "0 < e/2" by simp
   614   from tendstoD [OF f e2] tendstoD [OF g e2]
   615   show "eventually (\<lambda>x. dist (dist (f x) (g x)) (dist l m) < e) net"
   616   proof (rule eventually_elim2)
   617     fix x assume "dist (f x) l < e/2" "dist (g x) m < e/2"
   618     then show "dist (dist (f x) (g x)) (dist l m) < e"
   619       unfolding dist_real_def
   620       using dist_triangle2 [of "f x" "g x" "l"]
   621       using dist_triangle2 [of "g x" "l" "m"]
   622       using dist_triangle3 [of "l" "m" "f x"]
   623       using dist_triangle [of "f x" "m" "g x"]
   624       by arith
   625   qed
   626 qed
   627 
   628 lemma norm_conv_dist: "norm x = dist x 0"
   629 unfolding dist_norm by simp
   630 
   631 lemma tendsto_norm [tendsto_intros]:
   632   "(f ---> a) net \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> norm a) net"
   633 unfolding norm_conv_dist by (intro tendsto_intros)
   634 
   635 lemma tendsto_norm_zero:
   636   "(f ---> 0) net \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> 0) net"
   637 by (drule tendsto_norm, simp)
   638 
   639 lemma tendsto_norm_zero_cancel:
   640   "((\<lambda>x. norm (f x)) ---> 0) net \<Longrightarrow> (f ---> 0) net"
   641 unfolding tendsto_iff dist_norm by simp
   642 
   643 lemma tendsto_norm_zero_iff:
   644   "((\<lambda>x. norm (f x)) ---> 0) net \<longleftrightarrow> (f ---> 0) net"
   645 unfolding tendsto_iff dist_norm by simp
   646 
   647 lemma add_diff_add:
   648   fixes a b c d :: "'a::ab_group_add"
   649   shows "(a + c) - (b + d) = (a - b) + (c - d)"
   650 by simp
   651 
   652 lemma minus_diff_minus:
   653   fixes a b :: "'a::ab_group_add"
   654   shows "(- a) - (- b) = - (a - b)"
   655 by simp
   656 
   657 lemma tendsto_add [tendsto_intros]:
   658   fixes a b :: "'a::real_normed_vector"
   659   shows "\<lbrakk>(f ---> a) net; (g ---> b) net\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> a + b) net"
   660 by (simp only: tendsto_Zfun_iff add_diff_add Zfun_add)
   661 
   662 lemma tendsto_minus [tendsto_intros]:
   663   fixes a :: "'a::real_normed_vector"
   664   shows "(f ---> a) net \<Longrightarrow> ((\<lambda>x. - f x) ---> - a) net"
   665 by (simp only: tendsto_Zfun_iff minus_diff_minus Zfun_minus)
   666 
   667 lemma tendsto_minus_cancel:
   668   fixes a :: "'a::real_normed_vector"
   669   shows "((\<lambda>x. - f x) ---> - a) net \<Longrightarrow> (f ---> a) net"
   670 by (drule tendsto_minus, simp)
   671 
   672 lemma tendsto_diff [tendsto_intros]:
   673   fixes a b :: "'a::real_normed_vector"
   674   shows "\<lbrakk>(f ---> a) net; (g ---> b) net\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x - g x) ---> a - b) net"
   675 by (simp add: diff_minus tendsto_add tendsto_minus)
   676 
   677 lemma tendsto_setsum [tendsto_intros]:
   678   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::real_normed_vector"
   679   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> a i) net"
   680   shows "((\<lambda>x. \<Sum>i\<in>S. f i x) ---> (\<Sum>i\<in>S. a i)) net"
   681 proof (cases "finite S")
   682   assume "finite S" thus ?thesis using assms
   683   proof (induct set: finite)
   684     case empty show ?case
   685       by (simp add: tendsto_const)
   686   next
   687     case (insert i F) thus ?case
   688       by (simp add: tendsto_add)
   689   qed
   690 next
   691   assume "\<not> finite S" thus ?thesis
   692     by (simp add: tendsto_const)
   693 qed
   694 
   695 lemma (in bounded_linear) tendsto [tendsto_intros]:
   696   "(g ---> a) net \<Longrightarrow> ((\<lambda>x. f (g x)) ---> f a) net"
   697 by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
   698 
   699 lemma (in bounded_bilinear) tendsto [tendsto_intros]:
   700   "\<lbrakk>(f ---> a) net; (g ---> b) net\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x ** g x) ---> a ** b) net"
   701 by (simp only: tendsto_Zfun_iff prod_diff_prod
   702                Zfun_add Zfun Zfun_left Zfun_right)
   703 
   704 
   705 subsection {* Continuity of Inverse *}
   706 
   707 lemma (in bounded_bilinear) Zfun_prod_Bfun:
   708   assumes f: "Zfun f net"
   709   assumes g: "Bfun g net"
   710   shows "Zfun (\<lambda>x. f x ** g x) net"
   711 proof -
   712   obtain K where K: "0 \<le> K"
   713     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   714     using nonneg_bounded by fast
   715   obtain B where B: "0 < B"
   716     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) net"
   717     using g by (rule BfunE)
   718   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) net"
   719   using norm_g proof (rule eventually_elim1)
   720     fix x
   721     assume *: "norm (g x) \<le> B"
   722     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   723       by (rule norm_le)
   724     also have "\<dots> \<le> norm (f x) * B * K"
   725       by (intro mult_mono' order_refl norm_g norm_ge_zero
   726                 mult_nonneg_nonneg K *)
   727     also have "\<dots> = norm (f x) * (B * K)"
   728       by (rule mult_assoc)
   729     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
   730   qed
   731   with f show ?thesis
   732     by (rule Zfun_imp_Zfun)
   733 qed
   734 
   735 lemma (in bounded_bilinear) flip:
   736   "bounded_bilinear (\<lambda>x y. y ** x)"
   737 apply default
   738 apply (rule add_right)
   739 apply (rule add_left)
   740 apply (rule scaleR_right)
   741 apply (rule scaleR_left)
   742 apply (subst mult_commute)
   743 using bounded by fast
   744 
   745 lemma (in bounded_bilinear) Bfun_prod_Zfun:
   746   assumes f: "Bfun f net"
   747   assumes g: "Zfun g net"
   748   shows "Zfun (\<lambda>x. f x ** g x) net"
   749 using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
   750 
   751 lemma inverse_diff_inverse:
   752   "\<lbrakk>(a::'a::division_ring) \<noteq> 0; b \<noteq> 0\<rbrakk>
   753    \<Longrightarrow> inverse a - inverse b = - (inverse a * (a - b) * inverse b)"
   754 by (simp add: algebra_simps)
   755 
   756 lemma Bfun_inverse_lemma:
   757   fixes x :: "'a::real_normed_div_algebra"
   758   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   759 apply (subst nonzero_norm_inverse, clarsimp)
   760 apply (erule (1) le_imp_inverse_le)
   761 done
   762 
   763 lemma Bfun_inverse:
   764   fixes a :: "'a::real_normed_div_algebra"
   765   assumes f: "(f ---> a) net"
   766   assumes a: "a \<noteq> 0"
   767   shows "Bfun (\<lambda>x. inverse (f x)) net"
   768 proof -
   769   from a have "0 < norm a" by simp
   770   hence "\<exists>r>0. r < norm a" by (rule dense)
   771   then obtain r where r1: "0 < r" and r2: "r < norm a" by fast
   772   have "eventually (\<lambda>x. dist (f x) a < r) net"
   773     using tendstoD [OF f r1] by fast
   774   hence "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) net"
   775   proof (rule eventually_elim1)
   776     fix x
   777     assume "dist (f x) a < r"
   778     hence 1: "norm (f x - a) < r"
   779       by (simp add: dist_norm)
   780     hence 2: "f x \<noteq> 0" using r2 by auto
   781     hence "norm (inverse (f x)) = inverse (norm (f x))"
   782       by (rule nonzero_norm_inverse)
   783     also have "\<dots> \<le> inverse (norm a - r)"
   784     proof (rule le_imp_inverse_le)
   785       show "0 < norm a - r" using r2 by simp
   786     next
   787       have "norm a - norm (f x) \<le> norm (a - f x)"
   788         by (rule norm_triangle_ineq2)
   789       also have "\<dots> = norm (f x - a)"
   790         by (rule norm_minus_commute)
   791       also have "\<dots> < r" using 1 .
   792       finally show "norm a - r \<le> norm (f x)" by simp
   793     qed
   794     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
   795   qed
   796   thus ?thesis by (rule BfunI)
   797 qed
   798 
   799 lemma tendsto_inverse_lemma:
   800   fixes a :: "'a::real_normed_div_algebra"
   801   shows "\<lbrakk>(f ---> a) net; a \<noteq> 0; eventually (\<lambda>x. f x \<noteq> 0) net\<rbrakk>
   802          \<Longrightarrow> ((\<lambda>x. inverse (f x)) ---> inverse a) net"
   803 apply (subst tendsto_Zfun_iff)
   804 apply (rule Zfun_ssubst)
   805 apply (erule eventually_elim1)
   806 apply (erule (1) inverse_diff_inverse)
   807 apply (rule Zfun_minus)
   808 apply (rule Zfun_mult_left)
   809 apply (rule mult.Bfun_prod_Zfun)
   810 apply (erule (1) Bfun_inverse)
   811 apply (simp add: tendsto_Zfun_iff)
   812 done
   813 
   814 lemma tendsto_inverse [tendsto_intros]:
   815   fixes a :: "'a::real_normed_div_algebra"
   816   assumes f: "(f ---> a) net"
   817   assumes a: "a \<noteq> 0"
   818   shows "((\<lambda>x. inverse (f x)) ---> inverse a) net"
   819 proof -
   820   from a have "0 < norm a" by simp
   821   with f have "eventually (\<lambda>x. dist (f x) a < norm a) net"
   822     by (rule tendstoD)
   823   then have "eventually (\<lambda>x. f x \<noteq> 0) net"
   824     unfolding dist_norm by (auto elim!: eventually_elim1)
   825   with f a show ?thesis
   826     by (rule tendsto_inverse_lemma)
   827 qed
   828 
   829 lemma tendsto_divide [tendsto_intros]:
   830   fixes a b :: "'a::real_normed_field"
   831   shows "\<lbrakk>(f ---> a) net; (g ---> b) net; b \<noteq> 0\<rbrakk>
   832     \<Longrightarrow> ((\<lambda>x. f x / g x) ---> a / b) net"
   833 by (simp add: mult.tendsto tendsto_inverse divide_inverse)
   834 
   835 lemma tendsto_unique:
   836   fixes f :: "'a \<Rightarrow> 'b::t2_space"
   837   assumes "\<not> trivial_limit net"  "(f ---> l) net"  "(f ---> l') net"
   838   shows "l = l'"
   839 proof (rule ccontr)
   840   assume "l \<noteq> l'"
   841   obtain U V where "open U" "open V" "l \<in> U" "l' \<in> V" "U \<inter> V = {}"
   842     using hausdorff [OF `l \<noteq> l'`] by fast
   843   have "eventually (\<lambda>x. f x \<in> U) net"
   844     using `(f ---> l) net` `open U` `l \<in> U` by (rule topological_tendstoD)
   845   moreover
   846   have "eventually (\<lambda>x. f x \<in> V) net"
   847     using `(f ---> l') net` `open V` `l' \<in> V` by (rule topological_tendstoD)
   848   ultimately
   849   have "eventually (\<lambda>x. False) net"
   850   proof (rule eventually_elim2)
   851     fix x
   852     assume "f x \<in> U" "f x \<in> V"
   853     hence "f x \<in> U \<inter> V" by simp
   854     with `U \<inter> V = {}` show "False" by simp
   855   qed
   856   with `\<not> trivial_limit net` show "False"
   857     by (simp add: trivial_limit_def)
   858 qed
   859 
   860 end