src/HOL/Tools/inductive.ML
author bulwahn
Wed Jul 07 08:25:21 2010 +0200 (2010-07-07)
changeset 37734 489ac1ecb9f1
parent 37264 8b931fb51cc6
child 37901 ea7d4423cb5b
permissions -rw-r--r--
added the new command inductive_cases to derive simplification equations for inductive predicates; added binding simps for general simplification equation
     1 (*  Title:      HOL/Tools/inductive.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Stefan Berghofer and Markus Wenzel, TU Muenchen
     4 
     5 (Co)Inductive Definition module for HOL.
     6 
     7 Features:
     8   * least or greatest fixedpoints
     9   * mutually recursive definitions
    10   * definitions involving arbitrary monotone operators
    11   * automatically proves introduction and elimination rules
    12 
    13   Introduction rules have the form
    14   [| M Pj ti, ..., Q x, ... |] ==> Pk t
    15   where M is some monotone operator (usually the identity)
    16   Q x is any side condition on the free variables
    17   ti, t are any terms
    18   Pj, Pk are two of the predicates being defined in mutual recursion
    19 *)
    20 
    21 signature BASIC_INDUCTIVE =
    22 sig
    23   type inductive_result =
    24     {preds: term list, elims: thm list, raw_induct: thm,
    25      induct: thm, inducts: thm list, intrs: thm list, eqs: thm list}
    26   val morph_result: morphism -> inductive_result -> inductive_result
    27   type inductive_info = {names: string list, coind: bool} * inductive_result
    28   val the_inductive: Proof.context -> string -> inductive_info
    29   val print_inductives: Proof.context -> unit
    30   val mono_add: attribute
    31   val mono_del: attribute
    32   val get_monos: Proof.context -> thm list
    33   val mk_cases: Proof.context -> term -> thm
    34   val inductive_forall_name: string
    35   val inductive_forall_def: thm
    36   val rulify: thm -> thm
    37   val inductive_cases: (Attrib.binding * string list) list -> local_theory ->
    38     thm list list * local_theory
    39   val inductive_cases_i: (Attrib.binding * term list) list -> local_theory ->
    40     thm list list * local_theory
    41   type inductive_flags =
    42     {quiet_mode: bool, verbose: bool, alt_name: binding, coind: bool,
    43       no_elim: bool, no_ind: bool, skip_mono: bool, fork_mono: bool}
    44   val add_inductive_i:
    45     inductive_flags -> ((binding * typ) * mixfix) list ->
    46     (string * typ) list -> (Attrib.binding * term) list -> thm list -> local_theory ->
    47     inductive_result * local_theory
    48   val add_inductive: bool -> bool ->
    49     (binding * string option * mixfix) list ->
    50     (binding * string option * mixfix) list ->
    51     (Attrib.binding * string) list ->
    52     (Facts.ref * Attrib.src list) list ->
    53     bool -> local_theory -> inductive_result * local_theory
    54   val add_inductive_global: inductive_flags ->
    55     ((binding * typ) * mixfix) list -> (string * typ) list -> (Attrib.binding * term) list ->
    56     thm list -> theory -> inductive_result * theory
    57   val arities_of: thm -> (string * int) list
    58   val params_of: thm -> term list
    59   val partition_rules: thm -> thm list -> (string * thm list) list
    60   val partition_rules': thm -> (thm * 'a) list -> (string * (thm * 'a) list) list
    61   val unpartition_rules: thm list -> (string * 'a list) list -> 'a list
    62   val infer_intro_vars: thm -> int -> thm list -> term list list
    63   val setup: theory -> theory
    64 end;
    65 
    66 signature INDUCTIVE =
    67 sig
    68   include BASIC_INDUCTIVE
    69   type add_ind_def =
    70     inductive_flags ->
    71     term list -> (Attrib.binding * term) list -> thm list ->
    72     term list -> (binding * mixfix) list ->
    73     local_theory -> inductive_result * local_theory
    74   val declare_rules: binding -> bool -> bool -> string list -> term list ->
    75     thm list -> binding list -> Attrib.src list list -> (thm * string list * int) list ->
    76     thm list -> thm -> local_theory -> thm list * thm list * thm list * thm * thm list * local_theory
    77   val add_ind_def: add_ind_def
    78   val gen_add_inductive_i: add_ind_def -> inductive_flags ->
    79     ((binding * typ) * mixfix) list -> (string * typ) list -> (Attrib.binding * term) list ->
    80     thm list -> local_theory -> inductive_result * local_theory
    81   val gen_add_inductive: add_ind_def -> bool -> bool ->
    82     (binding * string option * mixfix) list ->
    83     (binding * string option * mixfix) list ->
    84     (Attrib.binding * string) list -> (Facts.ref * Attrib.src list) list ->
    85     bool -> local_theory -> inductive_result * local_theory
    86   val gen_ind_decl: add_ind_def -> bool -> (bool -> local_theory -> local_theory) parser
    87 end;
    88 
    89 structure Inductive: INDUCTIVE =
    90 struct
    91 
    92 
    93 (** theory context references **)
    94 
    95 val inductive_forall_name = "HOL.induct_forall";
    96 val inductive_forall_def = @{thm induct_forall_def};
    97 val inductive_conj_name = "HOL.induct_conj";
    98 val inductive_conj_def = @{thm induct_conj_def};
    99 val inductive_conj = @{thms induct_conj};
   100 val inductive_atomize = @{thms induct_atomize};
   101 val inductive_rulify = @{thms induct_rulify};
   102 val inductive_rulify_fallback = @{thms induct_rulify_fallback};
   103 
   104 val notTrueE = TrueI RSN (2, notE);
   105 val notFalseI = Seq.hd (atac 1 notI);
   106 
   107 val simp_thms' = map mk_meta_eq
   108   @{lemma "(~True) = False" "(~False) = True"
   109       "(True --> P) = P" "(False --> P) = True"
   110       "(P & True) = P" "(True & P) = P"
   111     by (fact simp_thms)+};
   112 
   113 val simp_thms'' = map mk_meta_eq [@{thm inf_fun_eq}, @{thm inf_bool_eq}] @ simp_thms';
   114 
   115 val simp_thms''' = map mk_meta_eq
   116   [@{thm le_fun_def}, @{thm le_bool_def}, @{thm sup_fun_eq}, @{thm sup_bool_eq}];
   117 
   118 
   119 (** context data **)
   120 
   121 type inductive_result =
   122   {preds: term list, elims: thm list, raw_induct: thm,
   123    induct: thm, inducts: thm list, intrs: thm list, eqs: thm list};
   124 
   125 fun morph_result phi {preds, elims, raw_induct: thm, induct, inducts, intrs, eqs} =
   126   let
   127     val term = Morphism.term phi;
   128     val thm = Morphism.thm phi;
   129     val fact = Morphism.fact phi;
   130   in
   131    {preds = map term preds, elims = fact elims, raw_induct = thm raw_induct,
   132     induct = thm induct, inducts = fact inducts, intrs = fact intrs, eqs = fact eqs}
   133   end;
   134 
   135 type inductive_info =
   136   {names: string list, coind: bool} * inductive_result;
   137 
   138 structure InductiveData = Generic_Data
   139 (
   140   type T = inductive_info Symtab.table * thm list;
   141   val empty = (Symtab.empty, []);
   142   val extend = I;
   143   fun merge ((tab1, monos1), (tab2, monos2)) : T =
   144     (Symtab.merge (K true) (tab1, tab2), Thm.merge_thms (monos1, monos2));
   145 );
   146 
   147 val get_inductives = InductiveData.get o Context.Proof;
   148 
   149 fun print_inductives ctxt =
   150   let
   151     val (tab, monos) = get_inductives ctxt;
   152     val space = Consts.space_of (ProofContext.consts_of ctxt);
   153   in
   154     [Pretty.strs ("(co)inductives:" :: map #1 (Name_Space.extern_table (space, tab))),
   155      Pretty.big_list "monotonicity rules:" (map (Display.pretty_thm ctxt) monos)]
   156     |> Pretty.chunks |> Pretty.writeln
   157   end;
   158 
   159 
   160 (* get and put data *)
   161 
   162 fun the_inductive ctxt name =
   163   (case Symtab.lookup (#1 (get_inductives ctxt)) name of
   164     NONE => error ("Unknown (co)inductive predicate " ^ quote name)
   165   | SOME info => info);
   166 
   167 fun put_inductives names info = InductiveData.map
   168   (apfst (fold (fn name => Symtab.update (name, info)) names));
   169 
   170 
   171 
   172 (** monotonicity rules **)
   173 
   174 val get_monos = #2 o get_inductives;
   175 val map_monos = InductiveData.map o apsnd;
   176 
   177 fun mk_mono thm =
   178   let
   179     fun eq2mono thm' = thm' RS (thm' RS eq_to_mono);
   180     fun dest_less_concl thm = dest_less_concl (thm RS @{thm le_funD})
   181       handle THM _ => thm RS @{thm le_boolD}
   182   in
   183     case concl_of thm of
   184       Const ("==", _) $ _ $ _ => eq2mono (thm RS meta_eq_to_obj_eq)
   185     | _ $ (Const (@{const_name "op ="}, _) $ _ $ _) => eq2mono thm
   186     | _ $ (Const (@{const_name Orderings.less_eq}, _) $ _ $ _) =>
   187       dest_less_concl (Seq.hd (REPEAT (FIRSTGOAL
   188         (resolve_tac [@{thm le_funI}, @{thm le_boolI'}])) thm))
   189     | _ => thm
   190   end handle THM _ =>
   191     error ("Bad monotonicity theorem:\n" ^ Display.string_of_thm_without_context thm);
   192 
   193 val mono_add = Thm.declaration_attribute (map_monos o Thm.add_thm o mk_mono);
   194 val mono_del = Thm.declaration_attribute (map_monos o Thm.del_thm o mk_mono);
   195 
   196 
   197 
   198 (** misc utilities **)
   199 
   200 fun message quiet_mode s = if quiet_mode then () else writeln s;
   201 fun clean_message quiet_mode s = if ! quick_and_dirty then () else message quiet_mode s;
   202 
   203 fun coind_prefix true = "co"
   204   | coind_prefix false = "";
   205 
   206 fun log (b:int) m n = if m >= n then 0 else 1 + log b (b * m) n;
   207 
   208 fun make_bool_args f g [] i = []
   209   | make_bool_args f g (x :: xs) i =
   210       (if i mod 2 = 0 then f x else g x) :: make_bool_args f g xs (i div 2);
   211 
   212 fun make_bool_args' xs =
   213   make_bool_args (K HOLogic.false_const) (K HOLogic.true_const) xs;
   214 
   215 fun arg_types_of k c = drop k (binder_types (fastype_of c));
   216 
   217 fun find_arg T x [] = sys_error "find_arg"
   218   | find_arg T x ((p as (_, (SOME _, _))) :: ps) =
   219       apsnd (cons p) (find_arg T x ps)
   220   | find_arg T x ((p as (U, (NONE, y))) :: ps) =
   221       if (T: typ) = U then (y, (U, (SOME x, y)) :: ps)
   222       else apsnd (cons p) (find_arg T x ps);
   223 
   224 fun make_args Ts xs =
   225   map (fn (T, (NONE, ())) => Const (@{const_name undefined}, T) | (_, (SOME t, ())) => t)
   226     (fold (fn (t, T) => snd o find_arg T t) xs (map (rpair (NONE, ())) Ts));
   227 
   228 fun make_args' Ts xs Us =
   229   fst (fold_map (fn T => find_arg T ()) Us (Ts ~~ map (pair NONE) xs));
   230 
   231 fun dest_predicate cs params t =
   232   let
   233     val k = length params;
   234     val (c, ts) = strip_comb t;
   235     val (xs, ys) = chop k ts;
   236     val i = find_index (fn c' => c' = c) cs;
   237   in
   238     if xs = params andalso i >= 0 then
   239       SOME (c, i, ys, chop (length ys) (arg_types_of k c))
   240     else NONE
   241   end;
   242 
   243 fun mk_names a 0 = []
   244   | mk_names a 1 = [a]
   245   | mk_names a n = map (fn i => a ^ string_of_int i) (1 upto n);
   246 
   247 fun select_disj 1 1 = []
   248   | select_disj _ 1 = [rtac disjI1]
   249   | select_disj n i = (rtac disjI2)::(select_disj (n - 1) (i - 1));
   250 
   251 
   252 (** process rules **)
   253 
   254 local
   255 
   256 fun err_in_rule ctxt name t msg =
   257   error (cat_lines ["Ill-formed introduction rule " ^ quote name,
   258     Syntax.string_of_term ctxt t, msg]);
   259 
   260 fun err_in_prem ctxt name t p msg =
   261   error (cat_lines ["Ill-formed premise", Syntax.string_of_term ctxt p,
   262     "in introduction rule " ^ quote name, Syntax.string_of_term ctxt t, msg]);
   263 
   264 val bad_concl = "Conclusion of introduction rule must be an inductive predicate";
   265 
   266 val bad_ind_occ = "Inductive predicate occurs in argument of inductive predicate";
   267 
   268 val bad_app = "Inductive predicate must be applied to parameter(s) ";
   269 
   270 fun atomize_term thy = MetaSimplifier.rewrite_term thy inductive_atomize [];
   271 
   272 in
   273 
   274 fun check_rule ctxt cs params ((binding, att), rule) =
   275   let
   276     val err_name = Binding.str_of binding;
   277     val params' = Term.variant_frees rule (Logic.strip_params rule);
   278     val frees = rev (map Free params');
   279     val concl = subst_bounds (frees, Logic.strip_assums_concl rule);
   280     val prems = map (curry subst_bounds frees) (Logic.strip_assums_hyp rule);
   281     val rule' = Logic.list_implies (prems, concl);
   282     val aprems = map (atomize_term (ProofContext.theory_of ctxt)) prems;
   283     val arule = list_all_free (params', Logic.list_implies (aprems, concl));
   284 
   285     fun check_ind err t = case dest_predicate cs params t of
   286         NONE => err (bad_app ^
   287           commas (map (Syntax.string_of_term ctxt) params))
   288       | SOME (_, _, ys, _) =>
   289           if exists (fn c => exists (fn t => Logic.occs (c, t)) ys) cs
   290           then err bad_ind_occ else ();
   291 
   292     fun check_prem' prem t =
   293       if member (op =) cs (head_of t) then
   294         check_ind (err_in_prem ctxt err_name rule prem) t
   295       else (case t of
   296           Abs (_, _, t) => check_prem' prem t
   297         | t $ u => (check_prem' prem t; check_prem' prem u)
   298         | _ => ());
   299 
   300     fun check_prem (prem, aprem) =
   301       if can HOLogic.dest_Trueprop aprem then check_prem' prem prem
   302       else err_in_prem ctxt err_name rule prem "Non-atomic premise";
   303   in
   304     (case concl of
   305        Const (@{const_name Trueprop}, _) $ t =>
   306          if member (op =) cs (head_of t) then
   307            (check_ind (err_in_rule ctxt err_name rule') t;
   308             List.app check_prem (prems ~~ aprems))
   309          else err_in_rule ctxt err_name rule' bad_concl
   310      | _ => err_in_rule ctxt err_name rule' bad_concl);
   311     ((binding, att), arule)
   312   end;
   313 
   314 val rulify =
   315   hol_simplify inductive_conj
   316   #> hol_simplify inductive_rulify
   317   #> hol_simplify inductive_rulify_fallback
   318   #> Simplifier.norm_hhf;
   319 
   320 end;
   321 
   322 
   323 
   324 (** proofs for (co)inductive predicates **)
   325 
   326 (* prove monotonicity *)
   327 
   328 fun prove_mono quiet_mode skip_mono fork_mono predT fp_fun monos ctxt =
   329  (message (quiet_mode orelse skip_mono andalso !quick_and_dirty orelse fork_mono)
   330     "  Proving monotonicity ...";
   331   (if skip_mono then Skip_Proof.prove else if fork_mono then Goal.prove_future else Goal.prove) ctxt
   332     [] []
   333     (HOLogic.mk_Trueprop
   334       (Const (@{const_name Orderings.mono}, (predT --> predT) --> HOLogic.boolT) $ fp_fun))
   335     (fn _ => EVERY [rtac @{thm monoI} 1,
   336       REPEAT (resolve_tac [@{thm le_funI}, @{thm le_boolI'}] 1),
   337       REPEAT (FIRST
   338         [atac 1,
   339          resolve_tac (map mk_mono monos @ get_monos ctxt) 1,
   340          etac @{thm le_funE} 1, dtac @{thm le_boolD} 1])]));
   341 
   342 
   343 (* prove introduction rules *)
   344 
   345 fun prove_intrs quiet_mode coind mono fp_def k intr_ts rec_preds_defs ctxt ctxt' =
   346   let
   347     val _ = clean_message quiet_mode "  Proving the introduction rules ...";
   348 
   349     val unfold = funpow k (fn th => th RS fun_cong)
   350       (mono RS (fp_def RS
   351         (if coind then @{thm def_gfp_unfold} else @{thm def_lfp_unfold})));
   352 
   353     val rules = [refl, TrueI, notFalseI, exI, conjI];
   354 
   355     val intrs = map_index (fn (i, intr) =>
   356       Skip_Proof.prove ctxt [] [] intr (fn _ => EVERY
   357        [rewrite_goals_tac rec_preds_defs,
   358         rtac (unfold RS iffD2) 1,
   359         EVERY1 (select_disj (length intr_ts) (i + 1)),
   360         (*Not ares_tac, since refl must be tried before any equality assumptions;
   361           backtracking may occur if the premises have extra variables!*)
   362         DEPTH_SOLVE_1 (resolve_tac rules 1 APPEND assume_tac 1)])
   363        |> singleton (ProofContext.export ctxt ctxt')) intr_ts
   364 
   365   in (intrs, unfold) end;
   366 
   367 
   368 (* prove elimination rules *)
   369 
   370 fun prove_elims quiet_mode cs params intr_ts intr_names unfold rec_preds_defs ctxt ctxt''' =
   371   let
   372     val _ = clean_message quiet_mode "  Proving the elimination rules ...";
   373 
   374     val ([pname], ctxt') = Variable.variant_fixes ["P"] ctxt;
   375     val P = HOLogic.mk_Trueprop (Free (pname, HOLogic.boolT));
   376 
   377     fun dest_intr r =
   378       (the (dest_predicate cs params (HOLogic.dest_Trueprop (Logic.strip_assums_concl r))),
   379        Logic.strip_assums_hyp r, Logic.strip_params r);
   380 
   381     val intrs = map dest_intr intr_ts ~~ intr_names;
   382 
   383     val rules1 = [disjE, exE, FalseE];
   384     val rules2 = [conjE, FalseE, notTrueE];
   385 
   386     fun prove_elim c =
   387       let
   388         val Ts = arg_types_of (length params) c;
   389         val (anames, ctxt'') = Variable.variant_fixes (mk_names "a" (length Ts)) ctxt';
   390         val frees = map Free (anames ~~ Ts);
   391 
   392         fun mk_elim_prem ((_, _, us, _), ts, params') =
   393           list_all (params',
   394             Logic.list_implies (map (HOLogic.mk_Trueprop o HOLogic.mk_eq)
   395               (frees ~~ us) @ ts, P));
   396         val c_intrs = filter (equal c o #1 o #1 o #1) intrs;
   397         val prems = HOLogic.mk_Trueprop (list_comb (c, params @ frees)) ::
   398            map mk_elim_prem (map #1 c_intrs)
   399       in
   400         (Skip_Proof.prove ctxt'' [] prems P
   401           (fn {prems, ...} => EVERY
   402             [cut_facts_tac [hd prems] 1,
   403              rewrite_goals_tac rec_preds_defs,
   404              dtac (unfold RS iffD1) 1,
   405              REPEAT (FIRSTGOAL (eresolve_tac rules1)),
   406              REPEAT (FIRSTGOAL (eresolve_tac rules2)),
   407              EVERY (map (fn prem =>
   408                DEPTH_SOLVE_1 (ares_tac [rewrite_rule rec_preds_defs prem, conjI] 1)) (tl prems))])
   409           |> singleton (ProofContext.export ctxt'' ctxt'''),
   410          map #2 c_intrs, length Ts)
   411       end
   412 
   413    in map prove_elim cs end;
   414 
   415 (* prove simplification equations *)
   416 
   417 fun prove_eqs quiet_mode cs params intr_ts intrs elims ctxt ctxt'' =
   418   let
   419     val _ = clean_message quiet_mode "  Proving the simplification rules ...";
   420     
   421     fun dest_intr r =
   422       (the (dest_predicate cs params (HOLogic.dest_Trueprop (Logic.strip_assums_concl r))),
   423        Logic.strip_assums_hyp r, Logic.strip_params r);
   424     val intr_ts' = map dest_intr intr_ts;
   425     fun prove_eq c elim =
   426       let
   427         val Ts = arg_types_of (length params) c;
   428         val (anames, ctxt') = Variable.variant_fixes (mk_names "a" (length Ts)) ctxt;
   429         val frees = map Free (anames ~~ Ts);
   430         val c_intrs = filter (equal c o #1 o #1 o #1) (intr_ts' ~~ intrs);
   431         fun mk_intr_conj (((_, _, us, _), ts, params'), _) =
   432           let
   433             fun list_ex ([], t) = t
   434               | list_ex ((a,T)::vars, t) =
   435                  (HOLogic.exists_const T) $ (Abs(a, T, list_ex(vars,t)));
   436             val conjs = map2 (curry HOLogic.mk_eq) frees us @ (map HOLogic.dest_Trueprop ts)
   437           in
   438             list_ex (params', if null conjs then @{term True} else foldr1 HOLogic.mk_conj conjs)
   439           end;
   440         val lhs = list_comb (c, params @ frees)
   441         val rhs =
   442           if null c_intrs then @{term False} else foldr1 HOLogic.mk_disj (map mk_intr_conj c_intrs)
   443         val eq = HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs, rhs))
   444         fun prove_intr1 (i, _) = Subgoal.FOCUS_PREMS (fn {params, prems, ...} =>
   445             let
   446               val (prems', last_prem) = split_last prems
   447             in
   448               EVERY1 (select_disj (length c_intrs) (i + 1))
   449               THEN EVERY (replicate (length params) (rtac @{thm exI} 1))
   450               THEN EVERY (map (fn prem => (rtac @{thm conjI} 1 THEN rtac prem 1)) prems')
   451               THEN rtac last_prem 1
   452             end) ctxt' 1
   453         fun prove_intr2 (((_, _, us, _), ts, params'), intr) =
   454           EVERY (replicate (length params') (etac @{thm exE} 1))
   455           THEN EVERY (replicate (length ts + length us - 1) (etac @{thm conjE} 1))
   456           THEN Subgoal.FOCUS_PREMS (fn {params, prems, ...} =>
   457             let
   458               val (eqs, prems') = chop (length us) prems
   459               val rew_thms = map (fn th => th RS @{thm eq_reflection}) eqs
   460             in
   461               rewrite_goal_tac rew_thms 1
   462               THEN rtac intr 1
   463               THEN (EVERY (map (fn p => rtac p 1) prems'))              
   464             end) ctxt' 1 
   465       in
   466         Skip_Proof.prove ctxt' [] [] eq (fn {...} =>
   467           rtac @{thm iffI} 1 THEN etac (#1 elim) 1
   468           THEN EVERY (map_index prove_intr1 c_intrs)
   469           THEN (if null c_intrs then etac @{thm FalseE} 1 else
   470             let val (c_intrs', last_c_intr) = split_last c_intrs in
   471               EVERY (map (fn ci => etac @{thm disjE} 1 THEN prove_intr2 ci) c_intrs')
   472               THEN prove_intr2 last_c_intr
   473             end))
   474         |> rulify
   475         |> singleton (ProofContext.export ctxt' ctxt'')
   476       end;  
   477   in
   478     map2 prove_eq cs elims
   479   end;
   480   
   481 (* derivation of simplified elimination rules *)
   482 
   483 local
   484 
   485 (*delete needless equality assumptions*)
   486 val refl_thin = Goal.prove_global @{theory HOL} [] [] @{prop "!!P. a = a ==> P ==> P"}
   487   (fn _ => assume_tac 1);
   488 val elim_rls = [asm_rl, FalseE, refl_thin, conjE, exE];
   489 val elim_tac = REPEAT o Tactic.eresolve_tac elim_rls;
   490 
   491 fun simp_case_tac ss i =
   492   EVERY' [elim_tac, asm_full_simp_tac ss, elim_tac, REPEAT o bound_hyp_subst_tac] i;
   493 
   494 in
   495 
   496 fun mk_cases ctxt prop =
   497   let
   498     val thy = ProofContext.theory_of ctxt;
   499     val ss = simpset_of ctxt;
   500 
   501     fun err msg =
   502       error (Pretty.string_of (Pretty.block
   503         [Pretty.str msg, Pretty.fbrk, Syntax.pretty_term ctxt prop]));
   504 
   505     val elims = Induct.find_casesP ctxt prop;
   506 
   507     val cprop = Thm.cterm_of thy prop;
   508     val tac = ALLGOALS (simp_case_tac ss) THEN prune_params_tac;
   509     fun mk_elim rl =
   510       Thm.implies_intr cprop (Tactic.rule_by_tactic ctxt tac (Thm.assume cprop RS rl))
   511       |> singleton (Variable.export (Variable.auto_fixes prop ctxt) ctxt);
   512   in
   513     (case get_first (try mk_elim) elims of
   514       SOME r => r
   515     | NONE => err "Proposition not an inductive predicate:")
   516   end;
   517 
   518 end;
   519 
   520 (* inductive_cases *)
   521 
   522 fun gen_inductive_cases prep_att prep_prop args lthy =
   523   let
   524     val thy = ProofContext.theory_of lthy;
   525     val facts = args |> map (fn ((a, atts), props) =>
   526       ((a, map (prep_att thy) atts),
   527         map (Thm.no_attributes o single o mk_cases lthy o prep_prop lthy) props));
   528   in lthy |> Local_Theory.notes facts |>> map snd end;
   529 
   530 val inductive_cases = gen_inductive_cases Attrib.intern_src Syntax.read_prop;
   531 val inductive_cases_i = gen_inductive_cases (K I) Syntax.check_prop;
   532 
   533 
   534 val ind_cases_setup =
   535   Method.setup @{binding ind_cases}
   536     (Scan.lift (Scan.repeat1 Args.name_source --
   537       Scan.optional (Args.$$$ "for" |-- Scan.repeat1 Args.name) []) >>
   538       (fn (raw_props, fixes) => fn ctxt =>
   539         let
   540           val (_, ctxt') = Variable.add_fixes fixes ctxt;
   541           val props = Syntax.read_props ctxt' raw_props;
   542           val ctxt'' = fold Variable.declare_term props ctxt';
   543           val rules = ProofContext.export ctxt'' ctxt (map (mk_cases ctxt'') props)
   544         in Method.erule 0 rules end))
   545     "dynamic case analysis on predicates";
   546 
   547 (* derivation of simplified equation *)
   548 
   549 fun mk_simp_eq ctxt prop =
   550   let
   551     val (c, args) = strip_comb (HOLogic.dest_Trueprop prop)
   552     val ctxt' = Variable.auto_fixes prop ctxt
   553     val cname = fst (dest_Const c)
   554     val info = the_inductive ctxt cname
   555     val eq = nth (#eqs (snd info)) (find_index (fn c => c = cname) (#names (fst info)))
   556     val (_, args') = strip_comb (fst (HOLogic.dest_eq (HOLogic.dest_Trueprop (Thm.prop_of eq))))
   557     val certify = cterm_of (ProofContext.theory_of ctxt)
   558   in
   559     cterm_instantiate (map (pairself certify) (args' ~~ args)) eq
   560     |> Conv.fconv_rule (Conv.arg_conv (Conv.arg_conv
   561       (Simplifier.full_rewrite (simpset_of ctxt))))
   562     |> singleton (Variable.export ctxt' ctxt)
   563   end
   564 
   565 (* inductive simps *)
   566 
   567 fun gen_inductive_simps prep_att prep_prop args lthy =
   568   let
   569     val thy = ProofContext.theory_of lthy;
   570     val facts = args |> map (fn ((a, atts), props) =>
   571       ((a, map (prep_att thy) atts),
   572         map (Thm.no_attributes o single o mk_simp_eq lthy o prep_prop lthy) props));
   573   in lthy |> Local_Theory.notes facts |>> map snd end;
   574 
   575 val inductive_simps = gen_inductive_simps Attrib.intern_src Syntax.read_prop;
   576 val inductive_simps_i = gen_inductive_simps (K I) Syntax.check_prop;
   577     
   578 (* prove induction rule *)
   579 
   580 fun prove_indrule quiet_mode cs argTs bs xs rec_const params intr_ts mono
   581     fp_def rec_preds_defs ctxt ctxt''' =
   582   let
   583     val _ = clean_message quiet_mode "  Proving the induction rule ...";
   584     val thy = ProofContext.theory_of ctxt;
   585 
   586     (* predicates for induction rule *)
   587 
   588     val (pnames, ctxt') = Variable.variant_fixes (mk_names "P" (length cs)) ctxt;
   589     val preds = map2 (curry Free) pnames
   590       (map (fn c => arg_types_of (length params) c ---> HOLogic.boolT) cs);
   591 
   592     (* transform an introduction rule into a premise for induction rule *)
   593 
   594     fun mk_ind_prem r =
   595       let
   596         fun subst s =
   597           (case dest_predicate cs params s of
   598             SOME (_, i, ys, (_, Ts)) =>
   599               let
   600                 val k = length Ts;
   601                 val bs = map Bound (k - 1 downto 0);
   602                 val P = list_comb (List.nth (preds, i),
   603                   map (incr_boundvars k) ys @ bs);
   604                 val Q = list_abs (mk_names "x" k ~~ Ts,
   605                   HOLogic.mk_binop inductive_conj_name
   606                     (list_comb (incr_boundvars k s, bs), P))
   607               in (Q, case Ts of [] => SOME (s, P) | _ => NONE) end
   608           | NONE =>
   609               (case s of
   610                 (t $ u) => (fst (subst t) $ fst (subst u), NONE)
   611               | (Abs (a, T, t)) => (Abs (a, T, fst (subst t)), NONE)
   612               | _ => (s, NONE)));
   613 
   614         fun mk_prem s prems =
   615           (case subst s of
   616             (_, SOME (t, u)) => t :: u :: prems
   617           | (t, _) => t :: prems);
   618 
   619         val SOME (_, i, ys, _) = dest_predicate cs params
   620           (HOLogic.dest_Trueprop (Logic.strip_assums_concl r))
   621 
   622       in list_all_free (Logic.strip_params r,
   623         Logic.list_implies (map HOLogic.mk_Trueprop (fold_rev mk_prem
   624           (map HOLogic.dest_Trueprop (Logic.strip_assums_hyp r)) []),
   625             HOLogic.mk_Trueprop (list_comb (List.nth (preds, i), ys))))
   626       end;
   627 
   628     val ind_prems = map mk_ind_prem intr_ts;
   629 
   630 
   631     (* make conclusions for induction rules *)
   632 
   633     val Tss = map (binder_types o fastype_of) preds;
   634     val (xnames, ctxt'') =
   635       Variable.variant_fixes (mk_names "x" (length (flat Tss))) ctxt';
   636     val mutual_ind_concl = HOLogic.mk_Trueprop (foldr1 HOLogic.mk_conj
   637         (map (fn (((xnames, Ts), c), P) =>
   638            let val frees = map Free (xnames ~~ Ts)
   639            in HOLogic.mk_imp
   640              (list_comb (c, params @ frees), list_comb (P, frees))
   641            end) (unflat Tss xnames ~~ Tss ~~ cs ~~ preds)));
   642 
   643 
   644     (* make predicate for instantiation of abstract induction rule *)
   645 
   646     val ind_pred = fold_rev lambda (bs @ xs) (foldr1 HOLogic.mk_conj
   647       (map_index (fn (i, P) => fold_rev (curry HOLogic.mk_imp)
   648          (make_bool_args HOLogic.mk_not I bs i)
   649          (list_comb (P, make_args' argTs xs (binder_types (fastype_of P))))) preds));
   650 
   651     val ind_concl = HOLogic.mk_Trueprop
   652       (HOLogic.mk_binrel @{const_name Orderings.less_eq} (rec_const, ind_pred));
   653 
   654     val raw_fp_induct = (mono RS (fp_def RS @{thm def_lfp_induct}));
   655 
   656     val induct = Skip_Proof.prove ctxt'' [] ind_prems ind_concl
   657       (fn {prems, ...} => EVERY
   658         [rewrite_goals_tac [inductive_conj_def],
   659          DETERM (rtac raw_fp_induct 1),
   660          REPEAT (resolve_tac [@{thm le_funI}, @{thm le_boolI}] 1),
   661          rewrite_goals_tac simp_thms'',
   662          (*This disjE separates out the introduction rules*)
   663          REPEAT (FIRSTGOAL (eresolve_tac [disjE, exE, FalseE])),
   664          (*Now break down the individual cases.  No disjE here in case
   665            some premise involves disjunction.*)
   666          REPEAT (FIRSTGOAL (etac conjE ORELSE' bound_hyp_subst_tac)),
   667          REPEAT (FIRSTGOAL
   668            (resolve_tac [conjI, impI] ORELSE' (etac notE THEN' atac))),
   669          EVERY (map (fn prem => DEPTH_SOLVE_1 (ares_tac [rewrite_rule
   670              (inductive_conj_def :: rec_preds_defs @ simp_thms'') prem,
   671            conjI, refl] 1)) prems)]);
   672 
   673     val lemma = Skip_Proof.prove ctxt'' [] []
   674       (Logic.mk_implies (ind_concl, mutual_ind_concl)) (fn _ => EVERY
   675         [rewrite_goals_tac rec_preds_defs,
   676          REPEAT (EVERY
   677            [REPEAT (resolve_tac [conjI, impI] 1),
   678             REPEAT (eresolve_tac [@{thm le_funE}, @{thm le_boolE}] 1),
   679             atac 1,
   680             rewrite_goals_tac simp_thms',
   681             atac 1])])
   682 
   683   in singleton (ProofContext.export ctxt'' ctxt''') (induct RS lemma) end;
   684 
   685 
   686 
   687 (** specification of (co)inductive predicates **)
   688 
   689 fun mk_ind_def quiet_mode skip_mono fork_mono alt_name coind
   690     cs intr_ts monos params cnames_syn lthy =
   691   let
   692     val fp_name = if coind then @{const_name Inductive.gfp} else @{const_name Inductive.lfp};
   693 
   694     val argTs = fold (combine (op =) o arg_types_of (length params)) cs [];
   695     val k = log 2 1 (length cs);
   696     val predT = replicate k HOLogic.boolT ---> argTs ---> HOLogic.boolT;
   697     val p :: xs = map Free (Variable.variant_frees lthy intr_ts
   698       (("p", predT) :: (mk_names "x" (length argTs) ~~ argTs)));
   699     val bs = map Free (Variable.variant_frees lthy (p :: xs @ intr_ts)
   700       (map (rpair HOLogic.boolT) (mk_names "b" k)));
   701 
   702     fun subst t =
   703       (case dest_predicate cs params t of
   704         SOME (_, i, ts, (Ts, Us)) =>
   705           let
   706             val l = length Us;
   707             val zs = map Bound (l - 1 downto 0);
   708           in
   709             list_abs (map (pair "z") Us, list_comb (p,
   710               make_bool_args' bs i @ make_args argTs
   711                 ((map (incr_boundvars l) ts ~~ Ts) @ (zs ~~ Us))))
   712           end
   713       | NONE =>
   714           (case t of
   715             t1 $ t2 => subst t1 $ subst t2
   716           | Abs (x, T, u) => Abs (x, T, subst u)
   717           | _ => t));
   718 
   719     (* transform an introduction rule into a conjunction  *)
   720     (*   [| p_i t; ... |] ==> p_j u                       *)
   721     (* is transformed into                                *)
   722     (*   b_j & x_j = u & p b_j t & ...                    *)
   723 
   724     fun transform_rule r =
   725       let
   726         val SOME (_, i, ts, (Ts, _)) = dest_predicate cs params
   727           (HOLogic.dest_Trueprop (Logic.strip_assums_concl r));
   728         val ps = make_bool_args HOLogic.mk_not I bs i @
   729           map HOLogic.mk_eq (make_args' argTs xs Ts ~~ ts) @
   730           map (subst o HOLogic.dest_Trueprop)
   731             (Logic.strip_assums_hyp r)
   732       in
   733         fold_rev (fn (x, T) => fn P => HOLogic.exists_const T $ Abs (x, T, P))
   734           (Logic.strip_params r)
   735           (if null ps then HOLogic.true_const else foldr1 HOLogic.mk_conj ps)
   736       end
   737 
   738     (* make a disjunction of all introduction rules *)
   739 
   740     val fp_fun = fold_rev lambda (p :: bs @ xs)
   741       (if null intr_ts then HOLogic.false_const
   742        else foldr1 HOLogic.mk_disj (map transform_rule intr_ts));
   743 
   744     (* add definiton of recursive predicates to theory *)
   745 
   746     val rec_name =
   747       if Binding.is_empty alt_name then
   748         Binding.name (space_implode "_" (map (Binding.name_of o fst) cnames_syn))
   749       else alt_name;
   750 
   751     val ((rec_const, (_, fp_def)), lthy') = lthy
   752       |> Local_Theory.conceal
   753       |> Local_Theory.define
   754         ((rec_name, case cnames_syn of [(_, syn)] => syn | _ => NoSyn),
   755          ((Binding.empty, [Attrib.internal (K Nitpick_Defs.add)]),
   756          fold_rev lambda params
   757            (Const (fp_name, (predT --> predT) --> predT) $ fp_fun)))
   758       ||> Local_Theory.restore_naming lthy;
   759     val fp_def' = Simplifier.rewrite (HOL_basic_ss addsimps [fp_def])
   760       (cterm_of (ProofContext.theory_of lthy') (list_comb (rec_const, params)));
   761     val specs =
   762       if length cs < 2 then []
   763       else
   764         map_index (fn (i, (name_mx, c)) =>
   765           let
   766             val Ts = arg_types_of (length params) c;
   767             val xs = map Free (Variable.variant_frees lthy intr_ts
   768               (mk_names "x" (length Ts) ~~ Ts))
   769           in
   770             (name_mx, (Attrib.empty_binding, fold_rev lambda (params @ xs)
   771               (list_comb (rec_const, params @ make_bool_args' bs i @
   772                 make_args argTs (xs ~~ Ts)))))
   773           end) (cnames_syn ~~ cs);
   774     val (consts_defs, lthy'') = lthy'
   775       |> Local_Theory.conceal
   776       |> fold_map Local_Theory.define specs
   777       ||> Local_Theory.restore_naming lthy';
   778     val preds = (case cs of [_] => [rec_const] | _ => map #1 consts_defs);
   779 
   780     val (_, lthy''') = Variable.add_fixes (map (fst o dest_Free) params) lthy'';
   781     val mono = prove_mono quiet_mode skip_mono fork_mono predT fp_fun monos lthy''';
   782     val (_, lthy'''') =
   783       Local_Theory.note (apfst Binding.conceal Attrib.empty_binding,
   784         ProofContext.export lthy''' lthy'' [mono]) lthy'';
   785 
   786   in (lthy'''', lthy''', rec_name, mono, fp_def', map (#2 o #2) consts_defs,
   787     list_comb (rec_const, params), preds, argTs, bs, xs)
   788   end;
   789 
   790 fun declare_rules rec_binding coind no_ind cnames
   791     preds intrs intr_bindings intr_atts elims eqs raw_induct lthy =
   792   let
   793     val rec_name = Binding.name_of rec_binding;
   794     fun rec_qualified qualified = Binding.qualify qualified rec_name;
   795     val intr_names = map Binding.name_of intr_bindings;
   796     val ind_case_names = Rule_Cases.case_names intr_names;
   797     val induct =
   798       if coind then
   799         (raw_induct, [Rule_Cases.case_names [rec_name],
   800           Rule_Cases.case_conclusion (rec_name, intr_names),
   801           Rule_Cases.consumes 1, Induct.coinduct_pred (hd cnames)])
   802       else if no_ind orelse length cnames > 1 then
   803         (raw_induct, [ind_case_names, Rule_Cases.consumes 0])
   804       else (raw_induct RSN (2, rev_mp), [ind_case_names, Rule_Cases.consumes 1]);
   805 
   806     val (intrs', lthy1) =
   807       lthy |>
   808       Spec_Rules.add
   809         (if coind then Spec_Rules.Co_Inductive else Spec_Rules.Inductive) (preds, intrs) |>
   810       Local_Theory.notes
   811         (map (rec_qualified false) intr_bindings ~~ intr_atts ~~
   812           map (fn th => [([th],
   813            [Attrib.internal (K (Context_Rules.intro_query NONE))])]) intrs) |>>
   814       map (hd o snd);
   815     val (((_, elims'), (_, [induct'])), lthy2) =
   816       lthy1 |>
   817       Local_Theory.note ((rec_qualified true (Binding.name "intros"), []), intrs') ||>>
   818       fold_map (fn (name, (elim, cases, k)) =>
   819         Local_Theory.note
   820           ((Binding.qualify true (Long_Name.base_name name) (Binding.name "cases"),
   821             [Attrib.internal (K (Rule_Cases.case_names cases)),
   822              Attrib.internal (K (Rule_Cases.consumes 1)),
   823              Attrib.internal (K (Rule_Cases.constraints k)),
   824              Attrib.internal (K (Induct.cases_pred name)),
   825              Attrib.internal (K (Context_Rules.elim_query NONE))]), [elim]) #>
   826         apfst (hd o snd)) (if null elims then [] else cnames ~~ elims) ||>>
   827       Local_Theory.note
   828         ((rec_qualified true (Binding.name (coind_prefix coind ^ "induct")),
   829           map (Attrib.internal o K) (#2 induct)), [rulify (#1 induct)]);
   830 
   831     val (eqs', lthy3) = lthy2 |> 
   832       fold_map (fn (name, eq) => Local_Theory.note
   833           ((Binding.qualify true (Long_Name.base_name name) (Binding.name "simps"), []), [eq])
   834           #> apfst (hd o snd))
   835         (if null eqs then [] else (cnames ~~ eqs))
   836     val (inducts, lthy4) =
   837       if no_ind orelse coind then ([], lthy3)
   838       else
   839         let val inducts = cnames ~~ Project_Rule.projects lthy3 (1 upto length cnames) induct' in
   840           lthy3 |>
   841           Local_Theory.notes [((rec_qualified true (Binding.name "inducts"), []),
   842             inducts |> map (fn (name, th) => ([th],
   843               [Attrib.internal (K ind_case_names),
   844                Attrib.internal (K (Rule_Cases.consumes 1)),
   845                Attrib.internal (K (Induct.induct_pred name))])))] |>> snd o hd
   846         end;
   847   in (intrs', elims', eqs', induct', inducts, lthy4) end;
   848 
   849 type inductive_flags =
   850   {quiet_mode: bool, verbose: bool, alt_name: binding, coind: bool,
   851     no_elim: bool, no_ind: bool, skip_mono: bool, fork_mono: bool};
   852 
   853 type add_ind_def =
   854   inductive_flags ->
   855   term list -> (Attrib.binding * term) list -> thm list ->
   856   term list -> (binding * mixfix) list ->
   857   local_theory -> inductive_result * local_theory;
   858 
   859 fun add_ind_def {quiet_mode, verbose, alt_name, coind, no_elim, no_ind, skip_mono, fork_mono}
   860     cs intros monos params cnames_syn lthy =
   861   let
   862     val _ = null cnames_syn andalso error "No inductive predicates given";
   863     val names = map (Binding.name_of o fst) cnames_syn;
   864     val _ = message (quiet_mode andalso not verbose)
   865       ("Proofs for " ^ coind_prefix coind ^ "inductive predicate(s) " ^ commas_quote names);
   866 
   867     val cnames = map (Local_Theory.full_name lthy o #1) cnames_syn;  (* FIXME *)
   868     val ((intr_names, intr_atts), intr_ts) =
   869       apfst split_list (split_list (map (check_rule lthy cs params) intros));
   870 
   871     val (lthy1, lthy2, rec_name, mono, fp_def, rec_preds_defs, rec_const, preds,
   872       argTs, bs, xs) = mk_ind_def quiet_mode skip_mono fork_mono alt_name coind cs intr_ts
   873         monos params cnames_syn lthy;
   874 
   875     val (intrs, unfold) = prove_intrs quiet_mode coind mono fp_def (length bs + length xs)
   876       intr_ts rec_preds_defs lthy2 lthy1;
   877     val elims =
   878       if no_elim then []
   879       else
   880         prove_elims quiet_mode cs params intr_ts (map Binding.name_of intr_names)
   881           unfold rec_preds_defs lthy2 lthy1;
   882     val raw_induct = zero_var_indexes
   883       (if no_ind then Drule.asm_rl
   884        else if coind then
   885          singleton (ProofContext.export lthy2 lthy1)
   886            (rotate_prems ~1 (Object_Logic.rulify
   887              (fold_rule rec_preds_defs
   888                (rewrite_rule simp_thms'''
   889                 (mono RS (fp_def RS @{thm def_coinduct}))))))
   890        else
   891          prove_indrule quiet_mode cs argTs bs xs rec_const params intr_ts mono fp_def
   892            rec_preds_defs lthy2 lthy1);
   893     val eqs =
   894       if no_elim then [] else prove_eqs quiet_mode cs params intr_ts intrs elims lthy2 lthy1
   895 
   896     val elims' = map (fn (th, ns, i) => (rulify th, ns, i)) elims
   897     val intrs' = map rulify intrs
   898 
   899     val (intrs'', elims'', eqs', induct, inducts, lthy3) = declare_rules rec_name coind no_ind
   900       cnames preds intrs' intr_names intr_atts elims' eqs raw_induct lthy1;
   901 
   902     val result =
   903       {preds = preds,
   904        intrs = intrs'',
   905        elims = elims'',
   906        raw_induct = rulify raw_induct,
   907        induct = induct,
   908        inducts = inducts,
   909        eqs = eqs'};
   910 
   911     val lthy4 = lthy3
   912       |> Local_Theory.declaration false (fn phi =>
   913         let val result' = morph_result phi result;
   914         in put_inductives cnames (*global names!?*) ({names = cnames, coind = coind}, result') end);
   915   in (result, lthy4) end;
   916 
   917 
   918 (* external interfaces *)
   919 
   920 fun gen_add_inductive_i mk_def
   921     (flags as {quiet_mode, verbose, alt_name, coind, no_elim, no_ind, skip_mono, fork_mono})
   922     cnames_syn pnames spec monos lthy =
   923   let
   924     val thy = ProofContext.theory_of lthy;
   925     val _ = Theory.requires thy "Inductive" (coind_prefix coind ^ "inductive definitions");
   926 
   927 
   928     (* abbrevs *)
   929 
   930     val (_, ctxt1) = Variable.add_fixes (map (Binding.name_of o fst o fst) cnames_syn) lthy;
   931 
   932     fun get_abbrev ((name, atts), t) =
   933       if can (Logic.strip_assums_concl #> Logic.dest_equals) t then
   934         let
   935           val _ = Binding.is_empty name andalso null atts orelse
   936             error "Abbreviations may not have names or attributes";
   937           val ((x, T), rhs) = Local_Defs.abs_def (snd (Local_Defs.cert_def ctxt1 t));
   938           val var =
   939             (case find_first (fn ((c, _), _) => Binding.name_of c = x) cnames_syn of
   940               NONE => error ("Undeclared head of abbreviation " ^ quote x)
   941             | SOME ((b, T'), mx) =>
   942                 if T <> T' then error ("Bad type specification for abbreviation " ^ quote x)
   943                 else (b, mx));
   944         in SOME (var, rhs) end
   945       else NONE;
   946 
   947     val abbrevs = map_filter get_abbrev spec;
   948     val bs = map (Binding.name_of o fst o fst) abbrevs;
   949 
   950 
   951     (* predicates *)
   952 
   953     val pre_intros = filter_out (is_some o get_abbrev) spec;
   954     val cnames_syn' = filter_out (member (op =) bs o Binding.name_of o fst o fst) cnames_syn;
   955     val cs = map (Free o apfst Binding.name_of o fst) cnames_syn';
   956     val ps = map Free pnames;
   957 
   958     val (_, ctxt2) = lthy |> Variable.add_fixes (map (Binding.name_of o fst o fst) cnames_syn');
   959     val _ = map (fn abbr => Local_Defs.fixed_abbrev abbr ctxt2) abbrevs;
   960     val ctxt3 = ctxt2 |> fold (snd oo Local_Defs.fixed_abbrev) abbrevs;
   961     val expand = Assumption.export_term ctxt3 lthy #> ProofContext.cert_term lthy;
   962 
   963     fun close_rule r = list_all_free (rev (fold_aterms
   964       (fn t as Free (v as (s, _)) =>
   965           if Variable.is_fixed ctxt1 s orelse
   966             member (op =) ps t then I else insert (op =) v
   967         | _ => I) r []), r);
   968 
   969     val intros = map (apsnd (Syntax.check_term lthy #> close_rule #> expand)) pre_intros;
   970     val preds = map (fn ((c, _), mx) => (c, mx)) cnames_syn';
   971   in
   972     lthy
   973     |> mk_def flags cs intros monos ps preds
   974     ||> fold (snd oo Local_Theory.abbrev Syntax.mode_default) abbrevs
   975   end;
   976 
   977 fun gen_add_inductive mk_def verbose coind cnames_syn pnames_syn intro_srcs raw_monos int lthy =
   978   let
   979     val ((vars, intrs), _) = lthy
   980       |> ProofContext.set_mode ProofContext.mode_abbrev
   981       |> Specification.read_spec (cnames_syn @ pnames_syn) intro_srcs;
   982     val (cs, ps) = chop (length cnames_syn) vars;
   983     val monos = Attrib.eval_thms lthy raw_monos;
   984     val flags = {quiet_mode = false, verbose = verbose, alt_name = Binding.empty,
   985       coind = coind, no_elim = false, no_ind = false, skip_mono = false, fork_mono = not int};
   986   in
   987     lthy
   988     |> gen_add_inductive_i mk_def flags cs (map (apfst Binding.name_of o fst) ps) intrs monos
   989   end;
   990 
   991 val add_inductive_i = gen_add_inductive_i add_ind_def;
   992 val add_inductive = gen_add_inductive add_ind_def;
   993 
   994 fun add_inductive_global flags cnames_syn pnames pre_intros monos thy =
   995   let
   996     val name = Sign.full_name thy (fst (fst (hd cnames_syn)));
   997     val ctxt' = thy
   998       |> Theory_Target.init NONE
   999       |> add_inductive_i flags cnames_syn pnames pre_intros monos |> snd
  1000       |> Local_Theory.exit;
  1001     val info = #2 (the_inductive ctxt' name);
  1002   in (info, ProofContext.theory_of ctxt') end;
  1003 
  1004 
  1005 (* read off arities of inductive predicates from raw induction rule *)
  1006 fun arities_of induct =
  1007   map (fn (_ $ t $ u) =>
  1008       (fst (dest_Const (head_of t)), length (snd (strip_comb u))))
  1009     (HOLogic.dest_conj (HOLogic.dest_Trueprop (concl_of induct)));
  1010 
  1011 (* read off parameters of inductive predicate from raw induction rule *)
  1012 fun params_of induct =
  1013   let
  1014     val (_ $ t $ u :: _) =
  1015       HOLogic.dest_conj (HOLogic.dest_Trueprop (concl_of induct));
  1016     val (_, ts) = strip_comb t;
  1017     val (_, us) = strip_comb u
  1018   in
  1019     List.take (ts, length ts - length us)
  1020   end;
  1021 
  1022 val pname_of_intr =
  1023   concl_of #> HOLogic.dest_Trueprop #> head_of #> dest_Const #> fst;
  1024 
  1025 (* partition introduction rules according to predicate name *)
  1026 fun gen_partition_rules f induct intros =
  1027   fold_rev (fn r => AList.map_entry op = (pname_of_intr (f r)) (cons r)) intros
  1028     (map (rpair [] o fst) (arities_of induct));
  1029 
  1030 val partition_rules = gen_partition_rules I;
  1031 fun partition_rules' induct = gen_partition_rules fst induct;
  1032 
  1033 fun unpartition_rules intros xs =
  1034   fold_map (fn r => AList.map_entry_yield op = (pname_of_intr r)
  1035     (fn x :: xs => (x, xs)) #>> the) intros xs |> fst;
  1036 
  1037 (* infer order of variables in intro rules from order of quantifiers in elim rule *)
  1038 fun infer_intro_vars elim arity intros =
  1039   let
  1040     val thy = theory_of_thm elim;
  1041     val _ :: cases = prems_of elim;
  1042     val used = map (fst o fst) (Term.add_vars (prop_of elim) []);
  1043     fun mtch (t, u) =
  1044       let
  1045         val params = Logic.strip_params t;
  1046         val vars = map (Var o apfst (rpair 0))
  1047           (Name.variant_list used (map fst params) ~~ map snd params);
  1048         val ts = map (curry subst_bounds (rev vars))
  1049           (List.drop (Logic.strip_assums_hyp t, arity));
  1050         val us = Logic.strip_imp_prems u;
  1051         val tab = fold (Pattern.first_order_match thy) (ts ~~ us)
  1052           (Vartab.empty, Vartab.empty);
  1053       in
  1054         map (Envir.subst_term tab) vars
  1055       end
  1056   in
  1057     map (mtch o apsnd prop_of) (cases ~~ intros)
  1058   end;
  1059 
  1060 
  1061 
  1062 (** package setup **)
  1063 
  1064 (* setup theory *)
  1065 
  1066 val setup =
  1067   ind_cases_setup #>
  1068   Attrib.setup @{binding mono} (Attrib.add_del mono_add mono_del)
  1069     "declaration of monotonicity rule";
  1070 
  1071 
  1072 (* outer syntax *)
  1073 
  1074 val _ = Keyword.keyword "monos";
  1075 
  1076 fun gen_ind_decl mk_def coind =
  1077   Parse.fixes -- Parse.for_fixes --
  1078   Scan.optional Parse_Spec.where_alt_specs [] --
  1079   Scan.optional (Parse.$$$ "monos" |-- Parse.!!! Parse_Spec.xthms1) []
  1080   >> (fn (((preds, params), specs), monos) =>
  1081       (snd oo gen_add_inductive mk_def true coind preds params specs monos));
  1082 
  1083 val ind_decl = gen_ind_decl add_ind_def;
  1084 
  1085 val _ =
  1086   Outer_Syntax.local_theory' "inductive" "define inductive predicates" Keyword.thy_decl
  1087     (ind_decl false);
  1088 
  1089 val _ =
  1090   Outer_Syntax.local_theory' "coinductive" "define coinductive predicates" Keyword.thy_decl
  1091     (ind_decl true);
  1092 
  1093 val _ =
  1094   Outer_Syntax.local_theory "inductive_cases"
  1095     "create simplified instances of elimination rules (improper)" Keyword.thy_script
  1096     (Parse.and_list1 Parse_Spec.specs >> (snd oo inductive_cases));
  1097 
  1098 val _ =
  1099   Outer_Syntax.local_theory "inductive_simps"
  1100     "create simplification rules for inductive predicates" Keyword.thy_script
  1101     (Parse.and_list1 Parse_Spec.specs >> (snd oo inductive_simps));
  1102 
  1103 end;