src/HOL/Real.thy
author hoelzl
Wed May 07 12:25:35 2014 +0200 (2014-05-07)
changeset 56889 48a745e1bde7
parent 56571 f4635657d66f
child 57275 0ddb5b755cdc
permissions -rw-r--r--
avoid the Complex constructor, use the more natural Re/Im view; moved csqrt to Complex.
     1 (*  Title:      HOL/Real.thy
     2     Author:     Jacques D. Fleuriot, University of Edinburgh, 1998
     3     Author:     Larry Paulson, University of Cambridge
     4     Author:     Jeremy Avigad, Carnegie Mellon University
     5     Author:     Florian Zuleger, Johannes Hoelzl, and Simon Funke, TU Muenchen
     6     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     7     Construction of Cauchy Reals by Brian Huffman, 2010
     8 *)
     9 
    10 header {* Development of the Reals using Cauchy Sequences *}
    11 
    12 theory Real
    13 imports Rat Conditionally_Complete_Lattices
    14 begin
    15 
    16 text {*
    17   This theory contains a formalization of the real numbers as
    18   equivalence classes of Cauchy sequences of rationals.  See
    19   @{file "~~/src/HOL/ex/Dedekind_Real.thy"} for an alternative
    20   construction using Dedekind cuts.
    21 *}
    22 
    23 subsection {* Preliminary lemmas *}
    24 
    25 lemma add_diff_add:
    26   fixes a b c d :: "'a::ab_group_add"
    27   shows "(a + c) - (b + d) = (a - b) + (c - d)"
    28   by simp
    29 
    30 lemma minus_diff_minus:
    31   fixes a b :: "'a::ab_group_add"
    32   shows "- a - - b = - (a - b)"
    33   by simp
    34 
    35 lemma mult_diff_mult:
    36   fixes x y a b :: "'a::ring"
    37   shows "(x * y - a * b) = x * (y - b) + (x - a) * b"
    38   by (simp add: algebra_simps)
    39 
    40 lemma inverse_diff_inverse:
    41   fixes a b :: "'a::division_ring"
    42   assumes "a \<noteq> 0" and "b \<noteq> 0"
    43   shows "inverse a - inverse b = - (inverse a * (a - b) * inverse b)"
    44   using assms by (simp add: algebra_simps)
    45 
    46 lemma obtain_pos_sum:
    47   fixes r :: rat assumes r: "0 < r"
    48   obtains s t where "0 < s" and "0 < t" and "r = s + t"
    49 proof
    50     from r show "0 < r/2" by simp
    51     from r show "0 < r/2" by simp
    52     show "r = r/2 + r/2" by simp
    53 qed
    54 
    55 subsection {* Sequences that converge to zero *}
    56 
    57 definition
    58   vanishes :: "(nat \<Rightarrow> rat) \<Rightarrow> bool"
    59 where
    60   "vanishes X = (\<forall>r>0. \<exists>k. \<forall>n\<ge>k. \<bar>X n\<bar> < r)"
    61 
    62 lemma vanishesI: "(\<And>r. 0 < r \<Longrightarrow> \<exists>k. \<forall>n\<ge>k. \<bar>X n\<bar> < r) \<Longrightarrow> vanishes X"
    63   unfolding vanishes_def by simp
    64 
    65 lemma vanishesD: "\<lbrakk>vanishes X; 0 < r\<rbrakk> \<Longrightarrow> \<exists>k. \<forall>n\<ge>k. \<bar>X n\<bar> < r"
    66   unfolding vanishes_def by simp
    67 
    68 lemma vanishes_const [simp]: "vanishes (\<lambda>n. c) \<longleftrightarrow> c = 0"
    69   unfolding vanishes_def
    70   apply (cases "c = 0", auto)
    71   apply (rule exI [where x="\<bar>c\<bar>"], auto)
    72   done
    73 
    74 lemma vanishes_minus: "vanishes X \<Longrightarrow> vanishes (\<lambda>n. - X n)"
    75   unfolding vanishes_def by simp
    76 
    77 lemma vanishes_add:
    78   assumes X: "vanishes X" and Y: "vanishes Y"
    79   shows "vanishes (\<lambda>n. X n + Y n)"
    80 proof (rule vanishesI)
    81   fix r :: rat assume "0 < r"
    82   then obtain s t where s: "0 < s" and t: "0 < t" and r: "r = s + t"
    83     by (rule obtain_pos_sum)
    84   obtain i where i: "\<forall>n\<ge>i. \<bar>X n\<bar> < s"
    85     using vanishesD [OF X s] ..
    86   obtain j where j: "\<forall>n\<ge>j. \<bar>Y n\<bar> < t"
    87     using vanishesD [OF Y t] ..
    88   have "\<forall>n\<ge>max i j. \<bar>X n + Y n\<bar> < r"
    89   proof (clarsimp)
    90     fix n assume n: "i \<le> n" "j \<le> n"
    91     have "\<bar>X n + Y n\<bar> \<le> \<bar>X n\<bar> + \<bar>Y n\<bar>" by (rule abs_triangle_ineq)
    92     also have "\<dots> < s + t" by (simp add: add_strict_mono i j n)
    93     finally show "\<bar>X n + Y n\<bar> < r" unfolding r .
    94   qed
    95   thus "\<exists>k. \<forall>n\<ge>k. \<bar>X n + Y n\<bar> < r" ..
    96 qed
    97 
    98 lemma vanishes_diff:
    99   assumes X: "vanishes X" and Y: "vanishes Y"
   100   shows "vanishes (\<lambda>n. X n - Y n)"
   101   unfolding diff_conv_add_uminus by (intro vanishes_add vanishes_minus X Y)
   102 
   103 lemma vanishes_mult_bounded:
   104   assumes X: "\<exists>a>0. \<forall>n. \<bar>X n\<bar> < a"
   105   assumes Y: "vanishes (\<lambda>n. Y n)"
   106   shows "vanishes (\<lambda>n. X n * Y n)"
   107 proof (rule vanishesI)
   108   fix r :: rat assume r: "0 < r"
   109   obtain a where a: "0 < a" "\<forall>n. \<bar>X n\<bar> < a"
   110     using X by fast
   111   obtain b where b: "0 < b" "r = a * b"
   112   proof
   113     show "0 < r / a" using r a by simp
   114     show "r = a * (r / a)" using a by simp
   115   qed
   116   obtain k where k: "\<forall>n\<ge>k. \<bar>Y n\<bar> < b"
   117     using vanishesD [OF Y b(1)] ..
   118   have "\<forall>n\<ge>k. \<bar>X n * Y n\<bar> < r"
   119     by (simp add: b(2) abs_mult mult_strict_mono' a k)
   120   thus "\<exists>k. \<forall>n\<ge>k. \<bar>X n * Y n\<bar> < r" ..
   121 qed
   122 
   123 subsection {* Cauchy sequences *}
   124 
   125 definition
   126   cauchy :: "(nat \<Rightarrow> rat) \<Rightarrow> bool"
   127 where
   128   "cauchy X \<longleftrightarrow> (\<forall>r>0. \<exists>k. \<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>X m - X n\<bar> < r)"
   129 
   130 lemma cauchyI:
   131   "(\<And>r. 0 < r \<Longrightarrow> \<exists>k. \<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>X m - X n\<bar> < r) \<Longrightarrow> cauchy X"
   132   unfolding cauchy_def by simp
   133 
   134 lemma cauchyD:
   135   "\<lbrakk>cauchy X; 0 < r\<rbrakk> \<Longrightarrow> \<exists>k. \<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>X m - X n\<bar> < r"
   136   unfolding cauchy_def by simp
   137 
   138 lemma cauchy_const [simp]: "cauchy (\<lambda>n. x)"
   139   unfolding cauchy_def by simp
   140 
   141 lemma cauchy_add [simp]:
   142   assumes X: "cauchy X" and Y: "cauchy Y"
   143   shows "cauchy (\<lambda>n. X n + Y n)"
   144 proof (rule cauchyI)
   145   fix r :: rat assume "0 < r"
   146   then obtain s t where s: "0 < s" and t: "0 < t" and r: "r = s + t"
   147     by (rule obtain_pos_sum)
   148   obtain i where i: "\<forall>m\<ge>i. \<forall>n\<ge>i. \<bar>X m - X n\<bar> < s"
   149     using cauchyD [OF X s] ..
   150   obtain j where j: "\<forall>m\<ge>j. \<forall>n\<ge>j. \<bar>Y m - Y n\<bar> < t"
   151     using cauchyD [OF Y t] ..
   152   have "\<forall>m\<ge>max i j. \<forall>n\<ge>max i j. \<bar>(X m + Y m) - (X n + Y n)\<bar> < r"
   153   proof (clarsimp)
   154     fix m n assume *: "i \<le> m" "j \<le> m" "i \<le> n" "j \<le> n"
   155     have "\<bar>(X m + Y m) - (X n + Y n)\<bar> \<le> \<bar>X m - X n\<bar> + \<bar>Y m - Y n\<bar>"
   156       unfolding add_diff_add by (rule abs_triangle_ineq)
   157     also have "\<dots> < s + t"
   158       by (rule add_strict_mono, simp_all add: i j *)
   159     finally show "\<bar>(X m + Y m) - (X n + Y n)\<bar> < r" unfolding r .
   160   qed
   161   thus "\<exists>k. \<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>(X m + Y m) - (X n + Y n)\<bar> < r" ..
   162 qed
   163 
   164 lemma cauchy_minus [simp]:
   165   assumes X: "cauchy X"
   166   shows "cauchy (\<lambda>n. - X n)"
   167 using assms unfolding cauchy_def
   168 unfolding minus_diff_minus abs_minus_cancel .
   169 
   170 lemma cauchy_diff [simp]:
   171   assumes X: "cauchy X" and Y: "cauchy Y"
   172   shows "cauchy (\<lambda>n. X n - Y n)"
   173   using assms unfolding diff_conv_add_uminus by (simp del: add_uminus_conv_diff)
   174 
   175 lemma cauchy_imp_bounded:
   176   assumes "cauchy X" shows "\<exists>b>0. \<forall>n. \<bar>X n\<bar> < b"
   177 proof -
   178   obtain k where k: "\<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>X m - X n\<bar> < 1"
   179     using cauchyD [OF assms zero_less_one] ..
   180   show "\<exists>b>0. \<forall>n. \<bar>X n\<bar> < b"
   181   proof (intro exI conjI allI)
   182     have "0 \<le> \<bar>X 0\<bar>" by simp
   183     also have "\<bar>X 0\<bar> \<le> Max (abs ` X ` {..k})" by simp
   184     finally have "0 \<le> Max (abs ` X ` {..k})" .
   185     thus "0 < Max (abs ` X ` {..k}) + 1" by simp
   186   next
   187     fix n :: nat
   188     show "\<bar>X n\<bar> < Max (abs ` X ` {..k}) + 1"
   189     proof (rule linorder_le_cases)
   190       assume "n \<le> k"
   191       hence "\<bar>X n\<bar> \<le> Max (abs ` X ` {..k})" by simp
   192       thus "\<bar>X n\<bar> < Max (abs ` X ` {..k}) + 1" by simp
   193     next
   194       assume "k \<le> n"
   195       have "\<bar>X n\<bar> = \<bar>X k + (X n - X k)\<bar>" by simp
   196       also have "\<bar>X k + (X n - X k)\<bar> \<le> \<bar>X k\<bar> + \<bar>X n - X k\<bar>"
   197         by (rule abs_triangle_ineq)
   198       also have "\<dots> < Max (abs ` X ` {..k}) + 1"
   199         by (rule add_le_less_mono, simp, simp add: k `k \<le> n`)
   200       finally show "\<bar>X n\<bar> < Max (abs ` X ` {..k}) + 1" .
   201     qed
   202   qed
   203 qed
   204 
   205 lemma cauchy_mult [simp]:
   206   assumes X: "cauchy X" and Y: "cauchy Y"
   207   shows "cauchy (\<lambda>n. X n * Y n)"
   208 proof (rule cauchyI)
   209   fix r :: rat assume "0 < r"
   210   then obtain u v where u: "0 < u" and v: "0 < v" and "r = u + v"
   211     by (rule obtain_pos_sum)
   212   obtain a where a: "0 < a" "\<forall>n. \<bar>X n\<bar> < a"
   213     using cauchy_imp_bounded [OF X] by fast
   214   obtain b where b: "0 < b" "\<forall>n. \<bar>Y n\<bar> < b"
   215     using cauchy_imp_bounded [OF Y] by fast
   216   obtain s t where s: "0 < s" and t: "0 < t" and r: "r = a * t + s * b"
   217   proof
   218     show "0 < v/b" using v b(1) by simp
   219     show "0 < u/a" using u a(1) by simp
   220     show "r = a * (u/a) + (v/b) * b"
   221       using a(1) b(1) `r = u + v` by simp
   222   qed
   223   obtain i where i: "\<forall>m\<ge>i. \<forall>n\<ge>i. \<bar>X m - X n\<bar> < s"
   224     using cauchyD [OF X s] ..
   225   obtain j where j: "\<forall>m\<ge>j. \<forall>n\<ge>j. \<bar>Y m - Y n\<bar> < t"
   226     using cauchyD [OF Y t] ..
   227   have "\<forall>m\<ge>max i j. \<forall>n\<ge>max i j. \<bar>X m * Y m - X n * Y n\<bar> < r"
   228   proof (clarsimp)
   229     fix m n assume *: "i \<le> m" "j \<le> m" "i \<le> n" "j \<le> n"
   230     have "\<bar>X m * Y m - X n * Y n\<bar> = \<bar>X m * (Y m - Y n) + (X m - X n) * Y n\<bar>"
   231       unfolding mult_diff_mult ..
   232     also have "\<dots> \<le> \<bar>X m * (Y m - Y n)\<bar> + \<bar>(X m - X n) * Y n\<bar>"
   233       by (rule abs_triangle_ineq)
   234     also have "\<dots> = \<bar>X m\<bar> * \<bar>Y m - Y n\<bar> + \<bar>X m - X n\<bar> * \<bar>Y n\<bar>"
   235       unfolding abs_mult ..
   236     also have "\<dots> < a * t + s * b"
   237       by (simp_all add: add_strict_mono mult_strict_mono' a b i j *)
   238     finally show "\<bar>X m * Y m - X n * Y n\<bar> < r" unfolding r .
   239   qed
   240   thus "\<exists>k. \<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>X m * Y m - X n * Y n\<bar> < r" ..
   241 qed
   242 
   243 lemma cauchy_not_vanishes_cases:
   244   assumes X: "cauchy X"
   245   assumes nz: "\<not> vanishes X"
   246   shows "\<exists>b>0. \<exists>k. (\<forall>n\<ge>k. b < - X n) \<or> (\<forall>n\<ge>k. b < X n)"
   247 proof -
   248   obtain r where "0 < r" and r: "\<forall>k. \<exists>n\<ge>k. r \<le> \<bar>X n\<bar>"
   249     using nz unfolding vanishes_def by (auto simp add: not_less)
   250   obtain s t where s: "0 < s" and t: "0 < t" and "r = s + t"
   251     using `0 < r` by (rule obtain_pos_sum)
   252   obtain i where i: "\<forall>m\<ge>i. \<forall>n\<ge>i. \<bar>X m - X n\<bar> < s"
   253     using cauchyD [OF X s] ..
   254   obtain k where "i \<le> k" and "r \<le> \<bar>X k\<bar>"
   255     using r by fast
   256   have k: "\<forall>n\<ge>k. \<bar>X n - X k\<bar> < s"
   257     using i `i \<le> k` by auto
   258   have "X k \<le> - r \<or> r \<le> X k"
   259     using `r \<le> \<bar>X k\<bar>` by auto
   260   hence "(\<forall>n\<ge>k. t < - X n) \<or> (\<forall>n\<ge>k. t < X n)"
   261     unfolding `r = s + t` using k by auto
   262   hence "\<exists>k. (\<forall>n\<ge>k. t < - X n) \<or> (\<forall>n\<ge>k. t < X n)" ..
   263   thus "\<exists>t>0. \<exists>k. (\<forall>n\<ge>k. t < - X n) \<or> (\<forall>n\<ge>k. t < X n)"
   264     using t by auto
   265 qed
   266 
   267 lemma cauchy_not_vanishes:
   268   assumes X: "cauchy X"
   269   assumes nz: "\<not> vanishes X"
   270   shows "\<exists>b>0. \<exists>k. \<forall>n\<ge>k. b < \<bar>X n\<bar>"
   271 using cauchy_not_vanishes_cases [OF assms]
   272 by clarify (rule exI, erule conjI, rule_tac x=k in exI, auto)
   273 
   274 lemma cauchy_inverse [simp]:
   275   assumes X: "cauchy X"
   276   assumes nz: "\<not> vanishes X"
   277   shows "cauchy (\<lambda>n. inverse (X n))"
   278 proof (rule cauchyI)
   279   fix r :: rat assume "0 < r"
   280   obtain b i where b: "0 < b" and i: "\<forall>n\<ge>i. b < \<bar>X n\<bar>"
   281     using cauchy_not_vanishes [OF X nz] by fast
   282   from b i have nz: "\<forall>n\<ge>i. X n \<noteq> 0" by auto
   283   obtain s where s: "0 < s" and r: "r = inverse b * s * inverse b"
   284   proof
   285     show "0 < b * r * b" by (simp add: `0 < r` b)
   286     show "r = inverse b * (b * r * b) * inverse b"
   287       using b by simp
   288   qed
   289   obtain j where j: "\<forall>m\<ge>j. \<forall>n\<ge>j. \<bar>X m - X n\<bar> < s"
   290     using cauchyD [OF X s] ..
   291   have "\<forall>m\<ge>max i j. \<forall>n\<ge>max i j. \<bar>inverse (X m) - inverse (X n)\<bar> < r"
   292   proof (clarsimp)
   293     fix m n assume *: "i \<le> m" "j \<le> m" "i \<le> n" "j \<le> n"
   294     have "\<bar>inverse (X m) - inverse (X n)\<bar> =
   295           inverse \<bar>X m\<bar> * \<bar>X m - X n\<bar> * inverse \<bar>X n\<bar>"
   296       by (simp add: inverse_diff_inverse nz * abs_mult)
   297     also have "\<dots> < inverse b * s * inverse b"
   298       by (simp add: mult_strict_mono less_imp_inverse_less
   299                     i j b * s)
   300     finally show "\<bar>inverse (X m) - inverse (X n)\<bar> < r" unfolding r .
   301   qed
   302   thus "\<exists>k. \<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>inverse (X m) - inverse (X n)\<bar> < r" ..
   303 qed
   304 
   305 lemma vanishes_diff_inverse:
   306   assumes X: "cauchy X" "\<not> vanishes X"
   307   assumes Y: "cauchy Y" "\<not> vanishes Y"
   308   assumes XY: "vanishes (\<lambda>n. X n - Y n)"
   309   shows "vanishes (\<lambda>n. inverse (X n) - inverse (Y n))"
   310 proof (rule vanishesI)
   311   fix r :: rat assume r: "0 < r"
   312   obtain a i where a: "0 < a" and i: "\<forall>n\<ge>i. a < \<bar>X n\<bar>"
   313     using cauchy_not_vanishes [OF X] by fast
   314   obtain b j where b: "0 < b" and j: "\<forall>n\<ge>j. b < \<bar>Y n\<bar>"
   315     using cauchy_not_vanishes [OF Y] by fast
   316   obtain s where s: "0 < s" and "inverse a * s * inverse b = r"
   317   proof
   318     show "0 < a * r * b"
   319       using a r b by simp
   320     show "inverse a * (a * r * b) * inverse b = r"
   321       using a r b by simp
   322   qed
   323   obtain k where k: "\<forall>n\<ge>k. \<bar>X n - Y n\<bar> < s"
   324     using vanishesD [OF XY s] ..
   325   have "\<forall>n\<ge>max (max i j) k. \<bar>inverse (X n) - inverse (Y n)\<bar> < r"
   326   proof (clarsimp)
   327     fix n assume n: "i \<le> n" "j \<le> n" "k \<le> n"
   328     have "X n \<noteq> 0" and "Y n \<noteq> 0"
   329       using i j a b n by auto
   330     hence "\<bar>inverse (X n) - inverse (Y n)\<bar> =
   331         inverse \<bar>X n\<bar> * \<bar>X n - Y n\<bar> * inverse \<bar>Y n\<bar>"
   332       by (simp add: inverse_diff_inverse abs_mult)
   333     also have "\<dots> < inverse a * s * inverse b"
   334       apply (intro mult_strict_mono' less_imp_inverse_less)
   335       apply (simp_all add: a b i j k n)
   336       done
   337     also note `inverse a * s * inverse b = r`
   338     finally show "\<bar>inverse (X n) - inverse (Y n)\<bar> < r" .
   339   qed
   340   thus "\<exists>k. \<forall>n\<ge>k. \<bar>inverse (X n) - inverse (Y n)\<bar> < r" ..
   341 qed
   342 
   343 subsection {* Equivalence relation on Cauchy sequences *}
   344 
   345 definition realrel :: "(nat \<Rightarrow> rat) \<Rightarrow> (nat \<Rightarrow> rat) \<Rightarrow> bool"
   346   where "realrel = (\<lambda>X Y. cauchy X \<and> cauchy Y \<and> vanishes (\<lambda>n. X n - Y n))"
   347 
   348 lemma realrelI [intro?]:
   349   assumes "cauchy X" and "cauchy Y" and "vanishes (\<lambda>n. X n - Y n)"
   350   shows "realrel X Y"
   351   using assms unfolding realrel_def by simp
   352 
   353 lemma realrel_refl: "cauchy X \<Longrightarrow> realrel X X"
   354   unfolding realrel_def by simp
   355 
   356 lemma symp_realrel: "symp realrel"
   357   unfolding realrel_def
   358   by (rule sympI, clarify, drule vanishes_minus, simp)
   359 
   360 lemma transp_realrel: "transp realrel"
   361   unfolding realrel_def
   362   apply (rule transpI, clarify)
   363   apply (drule (1) vanishes_add)
   364   apply (simp add: algebra_simps)
   365   done
   366 
   367 lemma part_equivp_realrel: "part_equivp realrel"
   368   by (fast intro: part_equivpI symp_realrel transp_realrel
   369     realrel_refl cauchy_const)
   370 
   371 subsection {* The field of real numbers *}
   372 
   373 quotient_type real = "nat \<Rightarrow> rat" / partial: realrel
   374   morphisms rep_real Real
   375   by (rule part_equivp_realrel)
   376 
   377 lemma cr_real_eq: "pcr_real = (\<lambda>x y. cauchy x \<and> Real x = y)"
   378   unfolding real.pcr_cr_eq cr_real_def realrel_def by auto
   379 
   380 lemma Real_induct [induct type: real]: (* TODO: generate automatically *)
   381   assumes "\<And>X. cauchy X \<Longrightarrow> P (Real X)" shows "P x"
   382 proof (induct x)
   383   case (1 X)
   384   hence "cauchy X" by (simp add: realrel_def)
   385   thus "P (Real X)" by (rule assms)
   386 qed
   387 
   388 lemma eq_Real:
   389   "cauchy X \<Longrightarrow> cauchy Y \<Longrightarrow> Real X = Real Y \<longleftrightarrow> vanishes (\<lambda>n. X n - Y n)"
   390   using real.rel_eq_transfer
   391   unfolding real.pcr_cr_eq cr_real_def rel_fun_def realrel_def by simp
   392 
   393 lemma Domainp_pcr_real [transfer_domain_rule]: "Domainp pcr_real = cauchy"
   394 by (simp add: real.domain_eq realrel_def)
   395 
   396 instantiation real :: field_inverse_zero
   397 begin
   398 
   399 lift_definition zero_real :: "real" is "\<lambda>n. 0"
   400   by (simp add: realrel_refl)
   401 
   402 lift_definition one_real :: "real" is "\<lambda>n. 1"
   403   by (simp add: realrel_refl)
   404 
   405 lift_definition plus_real :: "real \<Rightarrow> real \<Rightarrow> real" is "\<lambda>X Y n. X n + Y n"
   406   unfolding realrel_def add_diff_add
   407   by (simp only: cauchy_add vanishes_add simp_thms)
   408 
   409 lift_definition uminus_real :: "real \<Rightarrow> real" is "\<lambda>X n. - X n"
   410   unfolding realrel_def minus_diff_minus
   411   by (simp only: cauchy_minus vanishes_minus simp_thms)
   412 
   413 lift_definition times_real :: "real \<Rightarrow> real \<Rightarrow> real" is "\<lambda>X Y n. X n * Y n"
   414   unfolding realrel_def mult_diff_mult
   415   by (subst (4) mult_commute, simp only: cauchy_mult vanishes_add
   416     vanishes_mult_bounded cauchy_imp_bounded simp_thms)
   417 
   418 lift_definition inverse_real :: "real \<Rightarrow> real"
   419   is "\<lambda>X. if vanishes X then (\<lambda>n. 0) else (\<lambda>n. inverse (X n))"
   420 proof -
   421   fix X Y assume "realrel X Y"
   422   hence X: "cauchy X" and Y: "cauchy Y" and XY: "vanishes (\<lambda>n. X n - Y n)"
   423     unfolding realrel_def by simp_all
   424   have "vanishes X \<longleftrightarrow> vanishes Y"
   425   proof
   426     assume "vanishes X"
   427     from vanishes_diff [OF this XY] show "vanishes Y" by simp
   428   next
   429     assume "vanishes Y"
   430     from vanishes_add [OF this XY] show "vanishes X" by simp
   431   qed
   432   thus "?thesis X Y"
   433     unfolding realrel_def
   434     by (simp add: vanishes_diff_inverse X Y XY)
   435 qed
   436 
   437 definition
   438   "x - y = (x::real) + - y"
   439 
   440 definition
   441   "x / y = (x::real) * inverse y"
   442 
   443 lemma add_Real:
   444   assumes X: "cauchy X" and Y: "cauchy Y"
   445   shows "Real X + Real Y = Real (\<lambda>n. X n + Y n)"
   446   using assms plus_real.transfer
   447   unfolding cr_real_eq rel_fun_def by simp
   448 
   449 lemma minus_Real:
   450   assumes X: "cauchy X"
   451   shows "- Real X = Real (\<lambda>n. - X n)"
   452   using assms uminus_real.transfer
   453   unfolding cr_real_eq rel_fun_def by simp
   454 
   455 lemma diff_Real:
   456   assumes X: "cauchy X" and Y: "cauchy Y"
   457   shows "Real X - Real Y = Real (\<lambda>n. X n - Y n)"
   458   unfolding minus_real_def
   459   by (simp add: minus_Real add_Real X Y)
   460 
   461 lemma mult_Real:
   462   assumes X: "cauchy X" and Y: "cauchy Y"
   463   shows "Real X * Real Y = Real (\<lambda>n. X n * Y n)"
   464   using assms times_real.transfer
   465   unfolding cr_real_eq rel_fun_def by simp
   466 
   467 lemma inverse_Real:
   468   assumes X: "cauchy X"
   469   shows "inverse (Real X) =
   470     (if vanishes X then 0 else Real (\<lambda>n. inverse (X n)))"
   471   using assms inverse_real.transfer zero_real.transfer
   472   unfolding cr_real_eq rel_fun_def by (simp split: split_if_asm, metis)
   473 
   474 instance proof
   475   fix a b c :: real
   476   show "a + b = b + a"
   477     by transfer (simp add: add_ac realrel_def)
   478   show "(a + b) + c = a + (b + c)"
   479     by transfer (simp add: add_ac realrel_def)
   480   show "0 + a = a"
   481     by transfer (simp add: realrel_def)
   482   show "- a + a = 0"
   483     by transfer (simp add: realrel_def)
   484   show "a - b = a + - b"
   485     by (rule minus_real_def)
   486   show "(a * b) * c = a * (b * c)"
   487     by transfer (simp add: mult_ac realrel_def)
   488   show "a * b = b * a"
   489     by transfer (simp add: mult_ac realrel_def)
   490   show "1 * a = a"
   491     by transfer (simp add: mult_ac realrel_def)
   492   show "(a + b) * c = a * c + b * c"
   493     by transfer (simp add: distrib_right realrel_def)
   494   show "(0\<Colon>real) \<noteq> (1\<Colon>real)"
   495     by transfer (simp add: realrel_def)
   496   show "a \<noteq> 0 \<Longrightarrow> inverse a * a = 1"
   497     apply transfer
   498     apply (simp add: realrel_def)
   499     apply (rule vanishesI)
   500     apply (frule (1) cauchy_not_vanishes, clarify)
   501     apply (rule_tac x=k in exI, clarify)
   502     apply (drule_tac x=n in spec, simp)
   503     done
   504   show "a / b = a * inverse b"
   505     by (rule divide_real_def)
   506   show "inverse (0::real) = 0"
   507     by transfer (simp add: realrel_def)
   508 qed
   509 
   510 end
   511 
   512 subsection {* Positive reals *}
   513 
   514 lift_definition positive :: "real \<Rightarrow> bool"
   515   is "\<lambda>X. \<exists>r>0. \<exists>k. \<forall>n\<ge>k. r < X n"
   516 proof -
   517   { fix X Y
   518     assume "realrel X Y"
   519     hence XY: "vanishes (\<lambda>n. X n - Y n)"
   520       unfolding realrel_def by simp_all
   521     assume "\<exists>r>0. \<exists>k. \<forall>n\<ge>k. r < X n"
   522     then obtain r i where "0 < r" and i: "\<forall>n\<ge>i. r < X n"
   523       by fast
   524     obtain s t where s: "0 < s" and t: "0 < t" and r: "r = s + t"
   525       using `0 < r` by (rule obtain_pos_sum)
   526     obtain j where j: "\<forall>n\<ge>j. \<bar>X n - Y n\<bar> < s"
   527       using vanishesD [OF XY s] ..
   528     have "\<forall>n\<ge>max i j. t < Y n"
   529     proof (clarsimp)
   530       fix n assume n: "i \<le> n" "j \<le> n"
   531       have "\<bar>X n - Y n\<bar> < s" and "r < X n"
   532         using i j n by simp_all
   533       thus "t < Y n" unfolding r by simp
   534     qed
   535     hence "\<exists>r>0. \<exists>k. \<forall>n\<ge>k. r < Y n" using t by fast
   536   } note 1 = this
   537   fix X Y assume "realrel X Y"
   538   hence "realrel X Y" and "realrel Y X"
   539     using symp_realrel unfolding symp_def by auto
   540   thus "?thesis X Y"
   541     by (safe elim!: 1)
   542 qed
   543 
   544 lemma positive_Real:
   545   assumes X: "cauchy X"
   546   shows "positive (Real X) \<longleftrightarrow> (\<exists>r>0. \<exists>k. \<forall>n\<ge>k. r < X n)"
   547   using assms positive.transfer
   548   unfolding cr_real_eq rel_fun_def by simp
   549 
   550 lemma positive_zero: "\<not> positive 0"
   551   by transfer auto
   552 
   553 lemma positive_add:
   554   "positive x \<Longrightarrow> positive y \<Longrightarrow> positive (x + y)"
   555 apply transfer
   556 apply (clarify, rename_tac a b i j)
   557 apply (rule_tac x="a + b" in exI, simp)
   558 apply (rule_tac x="max i j" in exI, clarsimp)
   559 apply (simp add: add_strict_mono)
   560 done
   561 
   562 lemma positive_mult:
   563   "positive x \<Longrightarrow> positive y \<Longrightarrow> positive (x * y)"
   564 apply transfer
   565 apply (clarify, rename_tac a b i j)
   566 apply (rule_tac x="a * b" in exI, simp)
   567 apply (rule_tac x="max i j" in exI, clarsimp)
   568 apply (rule mult_strict_mono, auto)
   569 done
   570 
   571 lemma positive_minus:
   572   "\<not> positive x \<Longrightarrow> x \<noteq> 0 \<Longrightarrow> positive (- x)"
   573 apply transfer
   574 apply (simp add: realrel_def)
   575 apply (drule (1) cauchy_not_vanishes_cases, safe, fast, fast)
   576 done
   577 
   578 instantiation real :: linordered_field_inverse_zero
   579 begin
   580 
   581 definition
   582   "x < y \<longleftrightarrow> positive (y - x)"
   583 
   584 definition
   585   "x \<le> (y::real) \<longleftrightarrow> x < y \<or> x = y"
   586 
   587 definition
   588   "abs (a::real) = (if a < 0 then - a else a)"
   589 
   590 definition
   591   "sgn (a::real) = (if a = 0 then 0 else if 0 < a then 1 else - 1)"
   592 
   593 instance proof
   594   fix a b c :: real
   595   show "\<bar>a\<bar> = (if a < 0 then - a else a)"
   596     by (rule abs_real_def)
   597   show "a < b \<longleftrightarrow> a \<le> b \<and> \<not> b \<le> a"
   598     unfolding less_eq_real_def less_real_def
   599     by (auto, drule (1) positive_add, simp_all add: positive_zero)
   600   show "a \<le> a"
   601     unfolding less_eq_real_def by simp
   602   show "a \<le> b \<Longrightarrow> b \<le> c \<Longrightarrow> a \<le> c"
   603     unfolding less_eq_real_def less_real_def
   604     by (auto, drule (1) positive_add, simp add: algebra_simps)
   605   show "a \<le> b \<Longrightarrow> b \<le> a \<Longrightarrow> a = b"
   606     unfolding less_eq_real_def less_real_def
   607     by (auto, drule (1) positive_add, simp add: positive_zero)
   608   show "a \<le> b \<Longrightarrow> c + a \<le> c + b"
   609     unfolding less_eq_real_def less_real_def by auto
   610     (* FIXME: Procedure int_combine_numerals: c + b - (c + a) \<equiv> b + - a *)
   611     (* Should produce c + b - (c + a) \<equiv> b - a *)
   612   show "sgn a = (if a = 0 then 0 else if 0 < a then 1 else - 1)"
   613     by (rule sgn_real_def)
   614   show "a \<le> b \<or> b \<le> a"
   615     unfolding less_eq_real_def less_real_def
   616     by (auto dest!: positive_minus)
   617   show "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   618     unfolding less_real_def
   619     by (drule (1) positive_mult, simp add: algebra_simps)
   620 qed
   621 
   622 end
   623 
   624 instantiation real :: distrib_lattice
   625 begin
   626 
   627 definition
   628   "(inf :: real \<Rightarrow> real \<Rightarrow> real) = min"
   629 
   630 definition
   631   "(sup :: real \<Rightarrow> real \<Rightarrow> real) = max"
   632 
   633 instance proof
   634 qed (auto simp add: inf_real_def sup_real_def max_min_distrib2)
   635 
   636 end
   637 
   638 lemma of_nat_Real: "of_nat x = Real (\<lambda>n. of_nat x)"
   639 apply (induct x)
   640 apply (simp add: zero_real_def)
   641 apply (simp add: one_real_def add_Real)
   642 done
   643 
   644 lemma of_int_Real: "of_int x = Real (\<lambda>n. of_int x)"
   645 apply (cases x rule: int_diff_cases)
   646 apply (simp add: of_nat_Real diff_Real)
   647 done
   648 
   649 lemma of_rat_Real: "of_rat x = Real (\<lambda>n. x)"
   650 apply (induct x)
   651 apply (simp add: Fract_of_int_quotient of_rat_divide)
   652 apply (simp add: of_int_Real divide_inverse)
   653 apply (simp add: inverse_Real mult_Real)
   654 done
   655 
   656 instance real :: archimedean_field
   657 proof
   658   fix x :: real
   659   show "\<exists>z. x \<le> of_int z"
   660     apply (induct x)
   661     apply (frule cauchy_imp_bounded, clarify)
   662     apply (rule_tac x="ceiling b + 1" in exI)
   663     apply (rule less_imp_le)
   664     apply (simp add: of_int_Real less_real_def diff_Real positive_Real)
   665     apply (rule_tac x=1 in exI, simp add: algebra_simps)
   666     apply (rule_tac x=0 in exI, clarsimp)
   667     apply (rule le_less_trans [OF abs_ge_self])
   668     apply (rule less_le_trans [OF _ le_of_int_ceiling])
   669     apply simp
   670     done
   671 qed
   672 
   673 instantiation real :: floor_ceiling
   674 begin
   675 
   676 definition [code del]:
   677   "floor (x::real) = (THE z. of_int z \<le> x \<and> x < of_int (z + 1))"
   678 
   679 instance proof
   680   fix x :: real
   681   show "of_int (floor x) \<le> x \<and> x < of_int (floor x + 1)"
   682     unfolding floor_real_def using floor_exists1 by (rule theI')
   683 qed
   684 
   685 end
   686 
   687 subsection {* Completeness *}
   688 
   689 lemma not_positive_Real:
   690   assumes X: "cauchy X"
   691   shows "\<not> positive (Real X) \<longleftrightarrow> (\<forall>r>0. \<exists>k. \<forall>n\<ge>k. X n \<le> r)"
   692 unfolding positive_Real [OF X]
   693 apply (auto, unfold not_less)
   694 apply (erule obtain_pos_sum)
   695 apply (drule_tac x=s in spec, simp)
   696 apply (drule_tac r=t in cauchyD [OF X], clarify)
   697 apply (drule_tac x=k in spec, clarsimp)
   698 apply (rule_tac x=n in exI, clarify, rename_tac m)
   699 apply (drule_tac x=m in spec, simp)
   700 apply (drule_tac x=n in spec, simp)
   701 apply (drule spec, drule (1) mp, clarify, rename_tac i)
   702 apply (rule_tac x="max i k" in exI, simp)
   703 done
   704 
   705 lemma le_Real:
   706   assumes X: "cauchy X" and Y: "cauchy Y"
   707   shows "Real X \<le> Real Y = (\<forall>r>0. \<exists>k. \<forall>n\<ge>k. X n \<le> Y n + r)"
   708 unfolding not_less [symmetric, where 'a=real] less_real_def
   709 apply (simp add: diff_Real not_positive_Real X Y)
   710 apply (simp add: diff_le_eq add_ac)
   711 done
   712 
   713 lemma le_RealI:
   714   assumes Y: "cauchy Y"
   715   shows "\<forall>n. x \<le> of_rat (Y n) \<Longrightarrow> x \<le> Real Y"
   716 proof (induct x)
   717   fix X assume X: "cauchy X" and "\<forall>n. Real X \<le> of_rat (Y n)"
   718   hence le: "\<And>m r. 0 < r \<Longrightarrow> \<exists>k. \<forall>n\<ge>k. X n \<le> Y m + r"
   719     by (simp add: of_rat_Real le_Real)
   720   {
   721     fix r :: rat assume "0 < r"
   722     then obtain s t where s: "0 < s" and t: "0 < t" and r: "r = s + t"
   723       by (rule obtain_pos_sum)
   724     obtain i where i: "\<forall>m\<ge>i. \<forall>n\<ge>i. \<bar>Y m - Y n\<bar> < s"
   725       using cauchyD [OF Y s] ..
   726     obtain j where j: "\<forall>n\<ge>j. X n \<le> Y i + t"
   727       using le [OF t] ..
   728     have "\<forall>n\<ge>max i j. X n \<le> Y n + r"
   729     proof (clarsimp)
   730       fix n assume n: "i \<le> n" "j \<le> n"
   731       have "X n \<le> Y i + t" using n j by simp
   732       moreover have "\<bar>Y i - Y n\<bar> < s" using n i by simp
   733       ultimately show "X n \<le> Y n + r" unfolding r by simp
   734     qed
   735     hence "\<exists>k. \<forall>n\<ge>k. X n \<le> Y n + r" ..
   736   }
   737   thus "Real X \<le> Real Y"
   738     by (simp add: of_rat_Real le_Real X Y)
   739 qed
   740 
   741 lemma Real_leI:
   742   assumes X: "cauchy X"
   743   assumes le: "\<forall>n. of_rat (X n) \<le> y"
   744   shows "Real X \<le> y"
   745 proof -
   746   have "- y \<le> - Real X"
   747     by (simp add: minus_Real X le_RealI of_rat_minus le)
   748   thus ?thesis by simp
   749 qed
   750 
   751 lemma less_RealD:
   752   assumes Y: "cauchy Y"
   753   shows "x < Real Y \<Longrightarrow> \<exists>n. x < of_rat (Y n)"
   754 by (erule contrapos_pp, simp add: not_less, erule Real_leI [OF Y])
   755 
   756 lemma of_nat_less_two_power:
   757   "of_nat n < (2::'a::linordered_idom) ^ n"
   758 apply (induct n)
   759 apply simp
   760 apply (subgoal_tac "(1::'a) \<le> 2 ^ n")
   761 apply (drule (1) add_le_less_mono, simp)
   762 apply simp
   763 done
   764 
   765 lemma complete_real:
   766   fixes S :: "real set"
   767   assumes "\<exists>x. x \<in> S" and "\<exists>z. \<forall>x\<in>S. x \<le> z"
   768   shows "\<exists>y. (\<forall>x\<in>S. x \<le> y) \<and> (\<forall>z. (\<forall>x\<in>S. x \<le> z) \<longrightarrow> y \<le> z)"
   769 proof -
   770   obtain x where x: "x \<in> S" using assms(1) ..
   771   obtain z where z: "\<forall>x\<in>S. x \<le> z" using assms(2) ..
   772 
   773   def P \<equiv> "\<lambda>x. \<forall>y\<in>S. y \<le> of_rat x"
   774   obtain a where a: "\<not> P a"
   775   proof
   776     have "of_int (floor (x - 1)) \<le> x - 1" by (rule of_int_floor_le)
   777     also have "x - 1 < x" by simp
   778     finally have "of_int (floor (x - 1)) < x" .
   779     hence "\<not> x \<le> of_int (floor (x - 1))" by (simp only: not_le)
   780     then show "\<not> P (of_int (floor (x - 1)))"
   781       unfolding P_def of_rat_of_int_eq using x by fast
   782   qed
   783   obtain b where b: "P b"
   784   proof
   785     show "P (of_int (ceiling z))"
   786     unfolding P_def of_rat_of_int_eq
   787     proof
   788       fix y assume "y \<in> S"
   789       hence "y \<le> z" using z by simp
   790       also have "z \<le> of_int (ceiling z)" by (rule le_of_int_ceiling)
   791       finally show "y \<le> of_int (ceiling z)" .
   792     qed
   793   qed
   794 
   795   def avg \<equiv> "\<lambda>x y :: rat. x/2 + y/2"
   796   def bisect \<equiv> "\<lambda>(x, y). if P (avg x y) then (x, avg x y) else (avg x y, y)"
   797   def A \<equiv> "\<lambda>n. fst ((bisect ^^ n) (a, b))"
   798   def B \<equiv> "\<lambda>n. snd ((bisect ^^ n) (a, b))"
   799   def C \<equiv> "\<lambda>n. avg (A n) (B n)"
   800   have A_0 [simp]: "A 0 = a" unfolding A_def by simp
   801   have B_0 [simp]: "B 0 = b" unfolding B_def by simp
   802   have A_Suc [simp]: "\<And>n. A (Suc n) = (if P (C n) then A n else C n)"
   803     unfolding A_def B_def C_def bisect_def split_def by simp
   804   have B_Suc [simp]: "\<And>n. B (Suc n) = (if P (C n) then C n else B n)"
   805     unfolding A_def B_def C_def bisect_def split_def by simp
   806 
   807   have width: "\<And>n. B n - A n = (b - a) / 2^n"
   808     apply (simp add: eq_divide_eq)
   809     apply (induct_tac n, simp)
   810     apply (simp add: C_def avg_def algebra_simps)
   811     done
   812 
   813   have twos: "\<And>y r :: rat. 0 < r \<Longrightarrow> \<exists>n. y / 2 ^ n < r"
   814     apply (simp add: divide_less_eq)
   815     apply (subst mult_commute)
   816     apply (frule_tac y=y in ex_less_of_nat_mult)
   817     apply clarify
   818     apply (rule_tac x=n in exI)
   819     apply (erule less_trans)
   820     apply (rule mult_strict_right_mono)
   821     apply (rule le_less_trans [OF _ of_nat_less_two_power])
   822     apply simp
   823     apply assumption
   824     done
   825 
   826   have PA: "\<And>n. \<not> P (A n)"
   827     by (induct_tac n, simp_all add: a)
   828   have PB: "\<And>n. P (B n)"
   829     by (induct_tac n, simp_all add: b)
   830   have ab: "a < b"
   831     using a b unfolding P_def
   832     apply (clarsimp simp add: not_le)
   833     apply (drule (1) bspec)
   834     apply (drule (1) less_le_trans)
   835     apply (simp add: of_rat_less)
   836     done
   837   have AB: "\<And>n. A n < B n"
   838     by (induct_tac n, simp add: ab, simp add: C_def avg_def)
   839   have A_mono: "\<And>i j. i \<le> j \<Longrightarrow> A i \<le> A j"
   840     apply (auto simp add: le_less [where 'a=nat])
   841     apply (erule less_Suc_induct)
   842     apply (clarsimp simp add: C_def avg_def)
   843     apply (simp add: add_divide_distrib [symmetric])
   844     apply (rule AB [THEN less_imp_le])
   845     apply simp
   846     done
   847   have B_mono: "\<And>i j. i \<le> j \<Longrightarrow> B j \<le> B i"
   848     apply (auto simp add: le_less [where 'a=nat])
   849     apply (erule less_Suc_induct)
   850     apply (clarsimp simp add: C_def avg_def)
   851     apply (simp add: add_divide_distrib [symmetric])
   852     apply (rule AB [THEN less_imp_le])
   853     apply simp
   854     done
   855   have cauchy_lemma:
   856     "\<And>X. \<forall>n. \<forall>i\<ge>n. A n \<le> X i \<and> X i \<le> B n \<Longrightarrow> cauchy X"
   857     apply (rule cauchyI)
   858     apply (drule twos [where y="b - a"])
   859     apply (erule exE)
   860     apply (rule_tac x=n in exI, clarify, rename_tac i j)
   861     apply (rule_tac y="B n - A n" in le_less_trans) defer
   862     apply (simp add: width)
   863     apply (drule_tac x=n in spec)
   864     apply (frule_tac x=i in spec, drule (1) mp)
   865     apply (frule_tac x=j in spec, drule (1) mp)
   866     apply (frule A_mono, drule B_mono)
   867     apply (frule A_mono, drule B_mono)
   868     apply arith
   869     done
   870   have "cauchy A"
   871     apply (rule cauchy_lemma [rule_format])
   872     apply (simp add: A_mono)
   873     apply (erule order_trans [OF less_imp_le [OF AB] B_mono])
   874     done
   875   have "cauchy B"
   876     apply (rule cauchy_lemma [rule_format])
   877     apply (simp add: B_mono)
   878     apply (erule order_trans [OF A_mono less_imp_le [OF AB]])
   879     done
   880   have 1: "\<forall>x\<in>S. x \<le> Real B"
   881   proof
   882     fix x assume "x \<in> S"
   883     then show "x \<le> Real B"
   884       using PB [unfolded P_def] `cauchy B`
   885       by (simp add: le_RealI)
   886   qed
   887   have 2: "\<forall>z. (\<forall>x\<in>S. x \<le> z) \<longrightarrow> Real A \<le> z"
   888     apply clarify
   889     apply (erule contrapos_pp)
   890     apply (simp add: not_le)
   891     apply (drule less_RealD [OF `cauchy A`], clarify)
   892     apply (subgoal_tac "\<not> P (A n)")
   893     apply (simp add: P_def not_le, clarify)
   894     apply (erule rev_bexI)
   895     apply (erule (1) less_trans)
   896     apply (simp add: PA)
   897     done
   898   have "vanishes (\<lambda>n. (b - a) / 2 ^ n)"
   899   proof (rule vanishesI)
   900     fix r :: rat assume "0 < r"
   901     then obtain k where k: "\<bar>b - a\<bar> / 2 ^ k < r"
   902       using twos by fast
   903     have "\<forall>n\<ge>k. \<bar>(b - a) / 2 ^ n\<bar> < r"
   904     proof (clarify)
   905       fix n assume n: "k \<le> n"
   906       have "\<bar>(b - a) / 2 ^ n\<bar> = \<bar>b - a\<bar> / 2 ^ n"
   907         by simp
   908       also have "\<dots> \<le> \<bar>b - a\<bar> / 2 ^ k"
   909         using n by (simp add: divide_left_mono)
   910       also note k
   911       finally show "\<bar>(b - a) / 2 ^ n\<bar> < r" .
   912     qed
   913     thus "\<exists>k. \<forall>n\<ge>k. \<bar>(b - a) / 2 ^ n\<bar> < r" ..
   914   qed
   915   hence 3: "Real B = Real A"
   916     by (simp add: eq_Real `cauchy A` `cauchy B` width)
   917   show "\<exists>y. (\<forall>x\<in>S. x \<le> y) \<and> (\<forall>z. (\<forall>x\<in>S. x \<le> z) \<longrightarrow> y \<le> z)"
   918     using 1 2 3 by (rule_tac x="Real B" in exI, simp)
   919 qed
   920 
   921 instantiation real :: linear_continuum
   922 begin
   923 
   924 subsection{*Supremum of a set of reals*}
   925 
   926 definition "Sup X = (LEAST z::real. \<forall>x\<in>X. x \<le> z)"
   927 definition "Inf (X::real set) = - Sup (uminus ` X)"
   928 
   929 instance
   930 proof
   931   { fix x :: real and X :: "real set"
   932     assume x: "x \<in> X" "bdd_above X"
   933     then obtain s where s: "\<forall>y\<in>X. y \<le> s" "\<And>z. \<forall>y\<in>X. y \<le> z \<Longrightarrow> s \<le> z"
   934       using complete_real[of X] unfolding bdd_above_def by blast
   935     then show "x \<le> Sup X"
   936       unfolding Sup_real_def by (rule LeastI2_order) (auto simp: x) }
   937   note Sup_upper = this
   938 
   939   { fix z :: real and X :: "real set"
   940     assume x: "X \<noteq> {}" and z: "\<And>x. x \<in> X \<Longrightarrow> x \<le> z"
   941     then obtain s where s: "\<forall>y\<in>X. y \<le> s" "\<And>z. \<forall>y\<in>X. y \<le> z \<Longrightarrow> s \<le> z"
   942       using complete_real[of X] by blast
   943     then have "Sup X = s"
   944       unfolding Sup_real_def by (best intro: Least_equality)  
   945     also from s z have "... \<le> z"
   946       by blast
   947     finally show "Sup X \<le> z" . }
   948   note Sup_least = this
   949 
   950   { fix x :: real and X :: "real set" assume x: "x \<in> X" "bdd_below X" then show "Inf X \<le> x"
   951       using Sup_upper[of "-x" "uminus ` X"] by (auto simp: Inf_real_def) }
   952   { fix z :: real and X :: "real set" assume "X \<noteq> {}" "\<And>x. x \<in> X \<Longrightarrow> z \<le> x" then show "z \<le> Inf X"
   953       using Sup_least[of "uminus ` X" "- z"] by (force simp: Inf_real_def) }
   954   show "\<exists>a b::real. a \<noteq> b"
   955     using zero_neq_one by blast
   956 qed
   957 end
   958 
   959 
   960 subsection {* Hiding implementation details *}
   961 
   962 hide_const (open) vanishes cauchy positive Real
   963 
   964 declare Real_induct [induct del]
   965 declare Abs_real_induct [induct del]
   966 declare Abs_real_cases [cases del]
   967 
   968 lifting_update real.lifting
   969 lifting_forget real.lifting
   970   
   971 subsection{*More Lemmas*}
   972 
   973 text {* BH: These lemmas should not be necessary; they should be
   974 covered by existing simp rules and simplification procedures. *}
   975 
   976 lemma real_mult_less_iff1 [simp]: "(0::real) < z ==> (x*z < y*z) = (x < y)"
   977 by simp (* solved by linordered_ring_less_cancel_factor simproc *)
   978 
   979 lemma real_mult_le_cancel_iff1 [simp]: "(0::real) < z ==> (x*z \<le> y*z) = (x\<le>y)"
   980 by simp (* solved by linordered_ring_le_cancel_factor simproc *)
   981 
   982 lemma real_mult_le_cancel_iff2 [simp]: "(0::real) < z ==> (z*x \<le> z*y) = (x\<le>y)"
   983 by simp (* solved by linordered_ring_le_cancel_factor simproc *)
   984 
   985 
   986 subsection {* Embedding numbers into the Reals *}
   987 
   988 abbreviation
   989   real_of_nat :: "nat \<Rightarrow> real"
   990 where
   991   "real_of_nat \<equiv> of_nat"
   992 
   993 abbreviation
   994   real_of_int :: "int \<Rightarrow> real"
   995 where
   996   "real_of_int \<equiv> of_int"
   997 
   998 abbreviation
   999   real_of_rat :: "rat \<Rightarrow> real"
  1000 where
  1001   "real_of_rat \<equiv> of_rat"
  1002 
  1003 consts
  1004   (*overloaded constant for injecting other types into "real"*)
  1005   real :: "'a => real"
  1006 
  1007 defs (overloaded)
  1008   real_of_nat_def [code_unfold]: "real == real_of_nat"
  1009   real_of_int_def [code_unfold]: "real == real_of_int"
  1010 
  1011 declare [[coercion_enabled]]
  1012 declare [[coercion "real::nat\<Rightarrow>real"]]
  1013 declare [[coercion "real::int\<Rightarrow>real"]]
  1014 declare [[coercion "int"]]
  1015 
  1016 declare [[coercion_map map]]
  1017 declare [[coercion_map "% f g h x. g (h (f x))"]]
  1018 declare [[coercion_map "% f g (x,y) . (f x, g y)"]]
  1019 
  1020 lemma real_eq_of_nat: "real = of_nat"
  1021   unfolding real_of_nat_def ..
  1022 
  1023 lemma real_eq_of_int: "real = of_int"
  1024   unfolding real_of_int_def ..
  1025 
  1026 lemma real_of_int_zero [simp]: "real (0::int) = 0"  
  1027 by (simp add: real_of_int_def) 
  1028 
  1029 lemma real_of_one [simp]: "real (1::int) = (1::real)"
  1030 by (simp add: real_of_int_def) 
  1031 
  1032 lemma real_of_int_add [simp]: "real(x + y) = real (x::int) + real y"
  1033 by (simp add: real_of_int_def) 
  1034 
  1035 lemma real_of_int_minus [simp]: "real(-x) = -real (x::int)"
  1036 by (simp add: real_of_int_def) 
  1037 
  1038 lemma real_of_int_diff [simp]: "real(x - y) = real (x::int) - real y"
  1039 by (simp add: real_of_int_def) 
  1040 
  1041 lemma real_of_int_mult [simp]: "real(x * y) = real (x::int) * real y"
  1042 by (simp add: real_of_int_def) 
  1043 
  1044 lemma real_of_int_power [simp]: "real (x ^ n) = real (x::int) ^ n"
  1045 by (simp add: real_of_int_def of_int_power)
  1046 
  1047 lemmas power_real_of_int = real_of_int_power [symmetric]
  1048 
  1049 lemma real_of_int_setsum [simp]: "real ((SUM x:A. f x)::int) = (SUM x:A. real(f x))"
  1050   apply (subst real_eq_of_int)+
  1051   apply (rule of_int_setsum)
  1052 done
  1053 
  1054 lemma real_of_int_setprod [simp]: "real ((PROD x:A. f x)::int) = 
  1055     (PROD x:A. real(f x))"
  1056   apply (subst real_eq_of_int)+
  1057   apply (rule of_int_setprod)
  1058 done
  1059 
  1060 lemma real_of_int_zero_cancel [simp, algebra, presburger]: "(real x = 0) = (x = (0::int))"
  1061 by (simp add: real_of_int_def) 
  1062 
  1063 lemma real_of_int_inject [iff, algebra, presburger]: "(real (x::int) = real y) = (x = y)"
  1064 by (simp add: real_of_int_def) 
  1065 
  1066 lemma real_of_int_less_iff [iff, presburger]: "(real (x::int) < real y) = (x < y)"
  1067 by (simp add: real_of_int_def) 
  1068 
  1069 lemma real_of_int_le_iff [simp, presburger]: "(real (x::int) \<le> real y) = (x \<le> y)"
  1070 by (simp add: real_of_int_def) 
  1071 
  1072 lemma real_of_int_gt_zero_cancel_iff [simp, presburger]: "(0 < real (n::int)) = (0 < n)"
  1073 by (simp add: real_of_int_def) 
  1074 
  1075 lemma real_of_int_ge_zero_cancel_iff [simp, presburger]: "(0 <= real (n::int)) = (0 <= n)"
  1076 by (simp add: real_of_int_def) 
  1077 
  1078 lemma real_of_int_lt_zero_cancel_iff [simp, presburger]: "(real (n::int) < 0) = (n < 0)" 
  1079 by (simp add: real_of_int_def)
  1080 
  1081 lemma real_of_int_le_zero_cancel_iff [simp, presburger]: "(real (n::int) <= 0) = (n <= 0)"
  1082 by (simp add: real_of_int_def)
  1083 
  1084 lemma one_less_real_of_int_cancel_iff: "1 < real (i :: int) \<longleftrightarrow> 1 < i"
  1085   unfolding real_of_one[symmetric] real_of_int_less_iff ..
  1086 
  1087 lemma one_le_real_of_int_cancel_iff: "1 \<le> real (i :: int) \<longleftrightarrow> 1 \<le> i"
  1088   unfolding real_of_one[symmetric] real_of_int_le_iff ..
  1089 
  1090 lemma real_of_int_less_one_cancel_iff: "real (i :: int) < 1 \<longleftrightarrow> i < 1"
  1091   unfolding real_of_one[symmetric] real_of_int_less_iff ..
  1092 
  1093 lemma real_of_int_le_one_cancel_iff: "real (i :: int) \<le> 1 \<longleftrightarrow> i \<le> 1"
  1094   unfolding real_of_one[symmetric] real_of_int_le_iff ..
  1095 
  1096 lemma real_of_int_abs [simp]: "real (abs x) = abs(real (x::int))"
  1097 by (auto simp add: abs_if)
  1098 
  1099 lemma int_less_real_le: "((n::int) < m) = (real n + 1 <= real m)"
  1100   apply (subgoal_tac "real n + 1 = real (n + 1)")
  1101   apply (simp del: real_of_int_add)
  1102   apply auto
  1103 done
  1104 
  1105 lemma int_le_real_less: "((n::int) <= m) = (real n < real m + 1)"
  1106   apply (subgoal_tac "real m + 1 = real (m + 1)")
  1107   apply (simp del: real_of_int_add)
  1108   apply simp
  1109 done
  1110 
  1111 lemma real_of_int_div_aux: "(real (x::int)) / (real d) = 
  1112     real (x div d) + (real (x mod d)) / (real d)"
  1113 proof -
  1114   have "x = (x div d) * d + x mod d"
  1115     by auto
  1116   then have "real x = real (x div d) * real d + real(x mod d)"
  1117     by (simp only: real_of_int_mult [THEN sym] real_of_int_add [THEN sym])
  1118   then have "real x / real d = ... / real d"
  1119     by simp
  1120   then show ?thesis
  1121     by (auto simp add: add_divide_distrib algebra_simps)
  1122 qed
  1123 
  1124 lemma real_of_int_div: "(d :: int) dvd n ==>
  1125     real(n div d) = real n / real d"
  1126   apply (subst real_of_int_div_aux)
  1127   apply simp
  1128   apply (simp add: dvd_eq_mod_eq_0)
  1129 done
  1130 
  1131 lemma real_of_int_div2:
  1132   "0 <= real (n::int) / real (x) - real (n div x)"
  1133   apply (case_tac "x = 0")
  1134   apply simp
  1135   apply (case_tac "0 < x")
  1136   apply (simp add: algebra_simps)
  1137   apply (subst real_of_int_div_aux)
  1138   apply simp
  1139   apply (simp add: algebra_simps)
  1140   apply (subst real_of_int_div_aux)
  1141   apply simp
  1142   apply (subst zero_le_divide_iff)
  1143   apply auto
  1144 done
  1145 
  1146 lemma real_of_int_div3:
  1147   "real (n::int) / real (x) - real (n div x) <= 1"
  1148   apply (simp add: algebra_simps)
  1149   apply (subst real_of_int_div_aux)
  1150   apply (auto simp add: divide_le_eq intro: order_less_imp_le)
  1151 done
  1152 
  1153 lemma real_of_int_div4: "real (n div x) <= real (n::int) / real x" 
  1154 by (insert real_of_int_div2 [of n x], simp)
  1155 
  1156 lemma Ints_real_of_int [simp]: "real (x::int) \<in> Ints"
  1157 unfolding real_of_int_def by (rule Ints_of_int)
  1158 
  1159 
  1160 subsection{*Embedding the Naturals into the Reals*}
  1161 
  1162 lemma real_of_nat_zero [simp]: "real (0::nat) = 0"
  1163 by (simp add: real_of_nat_def)
  1164 
  1165 lemma real_of_nat_1 [simp]: "real (1::nat) = 1"
  1166 by (simp add: real_of_nat_def)
  1167 
  1168 lemma real_of_nat_one [simp]: "real (Suc 0) = (1::real)"
  1169 by (simp add: real_of_nat_def)
  1170 
  1171 lemma real_of_nat_add [simp]: "real (m + n) = real (m::nat) + real n"
  1172 by (simp add: real_of_nat_def)
  1173 
  1174 (*Not for addsimps: often the LHS is used to represent a positive natural*)
  1175 lemma real_of_nat_Suc: "real (Suc n) = real n + (1::real)"
  1176 by (simp add: real_of_nat_def)
  1177 
  1178 lemma real_of_nat_less_iff [iff]: 
  1179      "(real (n::nat) < real m) = (n < m)"
  1180 by (simp add: real_of_nat_def)
  1181 
  1182 lemma real_of_nat_le_iff [iff]: "(real (n::nat) \<le> real m) = (n \<le> m)"
  1183 by (simp add: real_of_nat_def)
  1184 
  1185 lemma real_of_nat_ge_zero [iff]: "0 \<le> real (n::nat)"
  1186 by (simp add: real_of_nat_def)
  1187 
  1188 lemma real_of_nat_Suc_gt_zero: "0 < real (Suc n)"
  1189 by (simp add: real_of_nat_def del: of_nat_Suc)
  1190 
  1191 lemma real_of_nat_mult [simp]: "real (m * n) = real (m::nat) * real n"
  1192 by (simp add: real_of_nat_def of_nat_mult)
  1193 
  1194 lemma real_of_nat_power [simp]: "real (m ^ n) = real (m::nat) ^ n"
  1195 by (simp add: real_of_nat_def of_nat_power)
  1196 
  1197 lemmas power_real_of_nat = real_of_nat_power [symmetric]
  1198 
  1199 lemma real_of_nat_setsum [simp]: "real ((SUM x:A. f x)::nat) = 
  1200     (SUM x:A. real(f x))"
  1201   apply (subst real_eq_of_nat)+
  1202   apply (rule of_nat_setsum)
  1203 done
  1204 
  1205 lemma real_of_nat_setprod [simp]: "real ((PROD x:A. f x)::nat) = 
  1206     (PROD x:A. real(f x))"
  1207   apply (subst real_eq_of_nat)+
  1208   apply (rule of_nat_setprod)
  1209 done
  1210 
  1211 lemma real_of_card: "real (card A) = setsum (%x.1) A"
  1212   apply (subst card_eq_setsum)
  1213   apply (subst real_of_nat_setsum)
  1214   apply simp
  1215 done
  1216 
  1217 lemma real_of_nat_inject [iff]: "(real (n::nat) = real m) = (n = m)"
  1218 by (simp add: real_of_nat_def)
  1219 
  1220 lemma real_of_nat_zero_iff [iff]: "(real (n::nat) = 0) = (n = 0)"
  1221 by (simp add: real_of_nat_def)
  1222 
  1223 lemma real_of_nat_diff: "n \<le> m ==> real (m - n) = real (m::nat) - real n"
  1224 by (simp add: add: real_of_nat_def of_nat_diff)
  1225 
  1226 lemma real_of_nat_gt_zero_cancel_iff [simp]: "(0 < real (n::nat)) = (0 < n)"
  1227 by (auto simp: real_of_nat_def)
  1228 
  1229 lemma real_of_nat_le_zero_cancel_iff [simp]: "(real (n::nat) \<le> 0) = (n = 0)"
  1230 by (simp add: add: real_of_nat_def)
  1231 
  1232 lemma not_real_of_nat_less_zero [simp]: "~ real (n::nat) < 0"
  1233 by (simp add: add: real_of_nat_def)
  1234 
  1235 lemma nat_less_real_le: "((n::nat) < m) = (real n + 1 <= real m)"
  1236   apply (subgoal_tac "real n + 1 = real (Suc n)")
  1237   apply simp
  1238   apply (auto simp add: real_of_nat_Suc)
  1239 done
  1240 
  1241 lemma nat_le_real_less: "((n::nat) <= m) = (real n < real m + 1)"
  1242   apply (subgoal_tac "real m + 1 = real (Suc m)")
  1243   apply (simp add: less_Suc_eq_le)
  1244   apply (simp add: real_of_nat_Suc)
  1245 done
  1246 
  1247 lemma real_of_nat_div_aux: "(real (x::nat)) / (real d) = 
  1248     real (x div d) + (real (x mod d)) / (real d)"
  1249 proof -
  1250   have "x = (x div d) * d + x mod d"
  1251     by auto
  1252   then have "real x = real (x div d) * real d + real(x mod d)"
  1253     by (simp only: real_of_nat_mult [THEN sym] real_of_nat_add [THEN sym])
  1254   then have "real x / real d = \<dots> / real d"
  1255     by simp
  1256   then show ?thesis
  1257     by (auto simp add: add_divide_distrib algebra_simps)
  1258 qed
  1259 
  1260 lemma real_of_nat_div: "(d :: nat) dvd n ==>
  1261     real(n div d) = real n / real d"
  1262   by (subst real_of_nat_div_aux)
  1263     (auto simp add: dvd_eq_mod_eq_0 [symmetric])
  1264 
  1265 lemma real_of_nat_div2:
  1266   "0 <= real (n::nat) / real (x) - real (n div x)"
  1267 apply (simp add: algebra_simps)
  1268 apply (subst real_of_nat_div_aux)
  1269 apply simp
  1270 done
  1271 
  1272 lemma real_of_nat_div3:
  1273   "real (n::nat) / real (x) - real (n div x) <= 1"
  1274 apply(case_tac "x = 0")
  1275 apply (simp)
  1276 apply (simp add: algebra_simps)
  1277 apply (subst real_of_nat_div_aux)
  1278 apply simp
  1279 done
  1280 
  1281 lemma real_of_nat_div4: "real (n div x) <= real (n::nat) / real x" 
  1282 by (insert real_of_nat_div2 [of n x], simp)
  1283 
  1284 lemma real_of_int_of_nat_eq [simp]: "real (of_nat n :: int) = real n"
  1285 by (simp add: real_of_int_def real_of_nat_def)
  1286 
  1287 lemma real_nat_eq_real [simp]: "0 <= x ==> real(nat x) = real x"
  1288   apply (subgoal_tac "real(int(nat x)) = real(nat x)")
  1289   apply force
  1290   apply (simp only: real_of_int_of_nat_eq)
  1291 done
  1292 
  1293 lemma Nats_real_of_nat [simp]: "real (n::nat) \<in> Nats"
  1294 unfolding real_of_nat_def by (rule of_nat_in_Nats)
  1295 
  1296 lemma Ints_real_of_nat [simp]: "real (n::nat) \<in> Ints"
  1297 unfolding real_of_nat_def by (rule Ints_of_nat)
  1298 
  1299 subsection {* The Archimedean Property of the Reals *}
  1300 
  1301 theorem reals_Archimedean:
  1302   assumes x_pos: "0 < x"
  1303   shows "\<exists>n. inverse (real (Suc n)) < x"
  1304   unfolding real_of_nat_def using x_pos
  1305   by (rule ex_inverse_of_nat_Suc_less)
  1306 
  1307 lemma reals_Archimedean2: "\<exists>n. (x::real) < real (n::nat)"
  1308   unfolding real_of_nat_def by (rule ex_less_of_nat)
  1309 
  1310 lemma reals_Archimedean3:
  1311   assumes x_greater_zero: "0 < x"
  1312   shows "\<forall>(y::real). \<exists>(n::nat). y < real n * x"
  1313   unfolding real_of_nat_def using `0 < x`
  1314   by (auto intro: ex_less_of_nat_mult)
  1315 
  1316 
  1317 subsection{* Rationals *}
  1318 
  1319 lemma Rats_real_nat[simp]: "real(n::nat) \<in> \<rat>"
  1320 by (simp add: real_eq_of_nat)
  1321 
  1322 
  1323 lemma Rats_eq_int_div_int:
  1324   "\<rat> = { real(i::int)/real(j::int) |i j. j \<noteq> 0}" (is "_ = ?S")
  1325 proof
  1326   show "\<rat> \<subseteq> ?S"
  1327   proof
  1328     fix x::real assume "x : \<rat>"
  1329     then obtain r where "x = of_rat r" unfolding Rats_def ..
  1330     have "of_rat r : ?S"
  1331       by (cases r)(auto simp add:of_rat_rat real_eq_of_int)
  1332     thus "x : ?S" using `x = of_rat r` by simp
  1333   qed
  1334 next
  1335   show "?S \<subseteq> \<rat>"
  1336   proof(auto simp:Rats_def)
  1337     fix i j :: int assume "j \<noteq> 0"
  1338     hence "real i / real j = of_rat(Fract i j)"
  1339       by (simp add:of_rat_rat real_eq_of_int)
  1340     thus "real i / real j \<in> range of_rat" by blast
  1341   qed
  1342 qed
  1343 
  1344 lemma Rats_eq_int_div_nat:
  1345   "\<rat> = { real(i::int)/real(n::nat) |i n. n \<noteq> 0}"
  1346 proof(auto simp:Rats_eq_int_div_int)
  1347   fix i j::int assume "j \<noteq> 0"
  1348   show "EX (i'::int) (n::nat). real i/real j = real i'/real n \<and> 0<n"
  1349   proof cases
  1350     assume "j>0"
  1351     hence "real i/real j = real i/real(nat j) \<and> 0<nat j"
  1352       by (simp add: real_eq_of_int real_eq_of_nat of_nat_nat)
  1353     thus ?thesis by blast
  1354   next
  1355     assume "~ j>0"
  1356     hence "real i/real j = real(-i)/real(nat(-j)) \<and> 0<nat(-j)" using `j\<noteq>0`
  1357       by (simp add: real_eq_of_int real_eq_of_nat of_nat_nat)
  1358     thus ?thesis by blast
  1359   qed
  1360 next
  1361   fix i::int and n::nat assume "0 < n"
  1362   hence "real i/real n = real i/real(int n) \<and> int n \<noteq> 0" by simp
  1363   thus "\<exists>(i'::int) j::int. real i/real n = real i'/real j \<and> j \<noteq> 0" by blast
  1364 qed
  1365 
  1366 lemma Rats_abs_nat_div_natE:
  1367   assumes "x \<in> \<rat>"
  1368   obtains m n :: nat
  1369   where "n \<noteq> 0" and "\<bar>x\<bar> = real m / real n" and "gcd m n = 1"
  1370 proof -
  1371   from `x \<in> \<rat>` obtain i::int and n::nat where "n \<noteq> 0" and "x = real i / real n"
  1372     by(auto simp add: Rats_eq_int_div_nat)
  1373   hence "\<bar>x\<bar> = real(nat(abs i)) / real n" by simp
  1374   then obtain m :: nat where x_rat: "\<bar>x\<bar> = real m / real n" by blast
  1375   let ?gcd = "gcd m n"
  1376   from `n\<noteq>0` have gcd: "?gcd \<noteq> 0" by simp
  1377   let ?k = "m div ?gcd"
  1378   let ?l = "n div ?gcd"
  1379   let ?gcd' = "gcd ?k ?l"
  1380   have "?gcd dvd m" .. then have gcd_k: "?gcd * ?k = m"
  1381     by (rule dvd_mult_div_cancel)
  1382   have "?gcd dvd n" .. then have gcd_l: "?gcd * ?l = n"
  1383     by (rule dvd_mult_div_cancel)
  1384   from `n\<noteq>0` and gcd_l have "?l \<noteq> 0" by (auto iff del: neq0_conv)
  1385   moreover
  1386   have "\<bar>x\<bar> = real ?k / real ?l"
  1387   proof -
  1388     from gcd have "real ?k / real ?l =
  1389         real (?gcd * ?k) / real (?gcd * ?l)" by simp
  1390     also from gcd_k and gcd_l have "\<dots> = real m / real n" by simp
  1391     also from x_rat have "\<dots> = \<bar>x\<bar>" ..
  1392     finally show ?thesis ..
  1393   qed
  1394   moreover
  1395   have "?gcd' = 1"
  1396   proof -
  1397     have "?gcd * ?gcd' = gcd (?gcd * ?k) (?gcd * ?l)"
  1398       by (rule gcd_mult_distrib_nat)
  1399     with gcd_k gcd_l have "?gcd * ?gcd' = ?gcd" by simp
  1400     with gcd show ?thesis by auto
  1401   qed
  1402   ultimately show ?thesis ..
  1403 qed
  1404 
  1405 subsection{*Density of the Rational Reals in the Reals*}
  1406 
  1407 text{* This density proof is due to Stefan Richter and was ported by TN.  The
  1408 original source is \emph{Real Analysis} by H.L. Royden.
  1409 It employs the Archimedean property of the reals. *}
  1410 
  1411 lemma Rats_dense_in_real:
  1412   fixes x :: real
  1413   assumes "x < y" shows "\<exists>r\<in>\<rat>. x < r \<and> r < y"
  1414 proof -
  1415   from `x<y` have "0 < y-x" by simp
  1416   with reals_Archimedean obtain q::nat 
  1417     where q: "inverse (real q) < y-x" and "0 < q" by auto
  1418   def p \<equiv> "ceiling (y * real q) - 1"
  1419   def r \<equiv> "of_int p / real q"
  1420   from q have "x < y - inverse (real q)" by simp
  1421   also have "y - inverse (real q) \<le> r"
  1422     unfolding r_def p_def
  1423     by (simp add: le_divide_eq left_diff_distrib le_of_int_ceiling `0 < q`)
  1424   finally have "x < r" .
  1425   moreover have "r < y"
  1426     unfolding r_def p_def
  1427     by (simp add: divide_less_eq diff_less_eq `0 < q`
  1428       less_ceiling_iff [symmetric])
  1429   moreover from r_def have "r \<in> \<rat>" by simp
  1430   ultimately show ?thesis by fast
  1431 qed
  1432 
  1433 
  1434 
  1435 subsection{*Numerals and Arithmetic*}
  1436 
  1437 lemma [code_abbrev]:
  1438   "real_of_int (numeral k) = numeral k"
  1439   "real_of_int (- numeral k) = - numeral k"
  1440   by simp_all
  1441 
  1442 text{*Collapse applications of @{const real} to @{const numeral}*}
  1443 lemma real_numeral [simp]:
  1444   "real (numeral v :: int) = numeral v"
  1445   "real (- numeral v :: int) = - numeral v"
  1446 by (simp_all add: real_of_int_def)
  1447 
  1448 lemma real_of_nat_numeral [simp]:
  1449   "real (numeral v :: nat) = numeral v"
  1450 by (simp add: real_of_nat_def)
  1451 
  1452 declaration {*
  1453   K (Lin_Arith.add_inj_thms [@{thm real_of_nat_le_iff} RS iffD2, @{thm real_of_nat_inject} RS iffD2]
  1454     (* not needed because x < (y::nat) can be rewritten as Suc x <= y: real_of_nat_less_iff RS iffD2 *)
  1455   #> Lin_Arith.add_inj_thms [@{thm real_of_int_le_iff} RS iffD2, @{thm real_of_int_inject} RS iffD2]
  1456     (* not needed because x < (y::int) can be rewritten as x + 1 <= y: real_of_int_less_iff RS iffD2 *)
  1457   #> Lin_Arith.add_simps [@{thm real_of_nat_zero}, @{thm real_of_nat_Suc}, @{thm real_of_nat_add},
  1458       @{thm real_of_nat_mult}, @{thm real_of_int_zero}, @{thm real_of_one},
  1459       @{thm real_of_int_add}, @{thm real_of_int_minus}, @{thm real_of_int_diff},
  1460       @{thm real_of_int_mult}, @{thm real_of_int_of_nat_eq},
  1461       @{thm real_of_nat_numeral}, @{thm real_numeral(1)}, @{thm real_numeral(2)}]
  1462   #> Lin_Arith.add_inj_const (@{const_name real}, @{typ "nat \<Rightarrow> real"})
  1463   #> Lin_Arith.add_inj_const (@{const_name real}, @{typ "int \<Rightarrow> real"}))
  1464 *}
  1465 
  1466 
  1467 subsection{* Simprules combining x+y and 0: ARE THEY NEEDED?*}
  1468 
  1469 lemma real_add_minus_iff [simp]: "(x + - a = (0::real)) = (x=a)" 
  1470 by arith
  1471 
  1472 text {* FIXME: redundant with @{text add_eq_0_iff} below *}
  1473 lemma real_add_eq_0_iff: "(x+y = (0::real)) = (y = -x)"
  1474 by auto
  1475 
  1476 lemma real_add_less_0_iff: "(x+y < (0::real)) = (y < -x)"
  1477 by auto
  1478 
  1479 lemma real_0_less_add_iff: "((0::real) < x+y) = (-x < y)"
  1480 by auto
  1481 
  1482 lemma real_add_le_0_iff: "(x+y \<le> (0::real)) = (y \<le> -x)"
  1483 by auto
  1484 
  1485 lemma real_0_le_add_iff: "((0::real) \<le> x+y) = (-x \<le> y)"
  1486 by auto
  1487 
  1488 subsection {* Lemmas about powers *}
  1489 
  1490 text {* FIXME: declare this in Rings.thy or not at all *}
  1491 declare abs_mult_self [simp]
  1492 
  1493 (* used by Import/HOL/real.imp *)
  1494 lemma two_realpow_ge_one: "(1::real) \<le> 2 ^ n"
  1495 by simp
  1496 
  1497 lemma two_realpow_gt [simp]: "real (n::nat) < 2 ^ n"
  1498 apply (induct "n")
  1499 apply (auto simp add: real_of_nat_Suc)
  1500 apply (subst mult_2)
  1501 apply (erule add_less_le_mono)
  1502 apply (rule two_realpow_ge_one)
  1503 done
  1504 
  1505 text {* TODO: no longer real-specific; rename and move elsewhere *}
  1506 lemma realpow_Suc_le_self:
  1507   fixes r :: "'a::linordered_semidom"
  1508   shows "[| 0 \<le> r; r \<le> 1 |] ==> r ^ Suc n \<le> r"
  1509 by (insert power_decreasing [of 1 "Suc n" r], simp)
  1510 
  1511 text {* TODO: no longer real-specific; rename and move elsewhere *}
  1512 lemma realpow_minus_mult:
  1513   fixes x :: "'a::monoid_mult"
  1514   shows "0 < n \<Longrightarrow> x ^ (n - 1) * x = x ^ n"
  1515 by (simp add: power_commutes split add: nat_diff_split)
  1516 
  1517 text {* FIXME: declare this [simp] for all types, or not at all *}
  1518 lemma real_two_squares_add_zero_iff [simp]:
  1519   "(x * x + y * y = 0) = ((x::real) = 0 \<and> y = 0)"
  1520 by (rule sum_squares_eq_zero_iff)
  1521 
  1522 text {* FIXME: declare this [simp] for all types, or not at all *}
  1523 lemma realpow_two_sum_zero_iff [simp]:
  1524      "(x\<^sup>2 + y\<^sup>2 = (0::real)) = (x = 0 & y = 0)"
  1525 by (rule sum_power2_eq_zero_iff)
  1526 
  1527 lemma real_minus_mult_self_le [simp]: "-(u * u) \<le> (x * (x::real))"
  1528 by (rule_tac y = 0 in order_trans, auto)
  1529 
  1530 lemma realpow_square_minus_le [simp]: "- u\<^sup>2 \<le> (x::real)\<^sup>2"
  1531 by (auto simp add: power2_eq_square)
  1532 
  1533 
  1534 lemma numeral_power_le_real_of_nat_cancel_iff[simp]:
  1535   "(numeral x::real) ^ n \<le> real a \<longleftrightarrow> (numeral x::nat) ^ n \<le> a"
  1536   unfolding real_of_nat_le_iff[symmetric] by simp
  1537 
  1538 lemma real_of_nat_le_numeral_power_cancel_iff[simp]:
  1539   "real a \<le> (numeral x::real) ^ n \<longleftrightarrow> a \<le> (numeral x::nat) ^ n"
  1540   unfolding real_of_nat_le_iff[symmetric] by simp
  1541 
  1542 lemma numeral_power_le_real_of_int_cancel_iff[simp]:
  1543   "(numeral x::real) ^ n \<le> real a \<longleftrightarrow> (numeral x::int) ^ n \<le> a"
  1544   unfolding real_of_int_le_iff[symmetric] by simp
  1545 
  1546 lemma real_of_int_le_numeral_power_cancel_iff[simp]:
  1547   "real a \<le> (numeral x::real) ^ n \<longleftrightarrow> a \<le> (numeral x::int) ^ n"
  1548   unfolding real_of_int_le_iff[symmetric] by simp
  1549 
  1550 lemma neg_numeral_power_le_real_of_int_cancel_iff[simp]:
  1551   "(- numeral x::real) ^ n \<le> real a \<longleftrightarrow> (- numeral x::int) ^ n \<le> a"
  1552   unfolding real_of_int_le_iff[symmetric] by simp
  1553 
  1554 lemma real_of_int_le_neg_numeral_power_cancel_iff[simp]:
  1555   "real a \<le> (- numeral x::real) ^ n \<longleftrightarrow> a \<le> (- numeral x::int) ^ n"
  1556   unfolding real_of_int_le_iff[symmetric] by simp
  1557 
  1558 
  1559 subsection{*Density of the Reals*}
  1560 
  1561 lemma real_lbound_gt_zero:
  1562      "[| (0::real) < d1; 0 < d2 |] ==> \<exists>e. 0 < e & e < d1 & e < d2"
  1563 apply (rule_tac x = " (min d1 d2) /2" in exI)
  1564 apply (simp add: min_def)
  1565 done
  1566 
  1567 
  1568 text{*Similar results are proved in @{text Fields}*}
  1569 lemma real_less_half_sum: "x < y ==> x < (x+y) / (2::real)"
  1570   by auto
  1571 
  1572 lemma real_gt_half_sum: "x < y ==> (x+y)/(2::real) < y"
  1573   by auto
  1574 
  1575 lemma real_sum_of_halves: "x/2 + x/2 = (x::real)"
  1576   by simp
  1577 
  1578 subsection{*Absolute Value Function for the Reals*}
  1579 
  1580 lemma abs_minus_add_cancel: "abs(x + (-y)) = abs (y + (-(x::real)))"
  1581 by (simp add: abs_if)
  1582 
  1583 (* FIXME: redundant, but used by Integration/RealRandVar.thy in AFP *)
  1584 lemma abs_le_interval_iff: "(abs x \<le> r) = (-r\<le>x & x\<le>(r::real))"
  1585 by (force simp add: abs_le_iff)
  1586 
  1587 lemma abs_add_one_gt_zero: "(0::real) < 1 + abs(x)"
  1588 by (simp add: abs_if)
  1589 
  1590 lemma abs_real_of_nat_cancel [simp]: "abs (real x) = real (x::nat)"
  1591 by (rule abs_of_nonneg [OF real_of_nat_ge_zero])
  1592 
  1593 lemma abs_add_one_not_less_self: "~ abs(x) + (1::real) < x"
  1594 by simp
  1595  
  1596 lemma abs_sum_triangle_ineq: "abs ((x::real) + y + (-l + -m)) \<le> abs(x + -l) + abs(y + -m)"
  1597 by simp
  1598 
  1599 
  1600 subsection{*Floor and Ceiling Functions from the Reals to the Integers*}
  1601 
  1602 (* FIXME: theorems for negative numerals *)
  1603 lemma numeral_less_real_of_int_iff [simp]:
  1604      "((numeral n) < real (m::int)) = (numeral n < m)"
  1605 apply auto
  1606 apply (rule real_of_int_less_iff [THEN iffD1])
  1607 apply (drule_tac [2] real_of_int_less_iff [THEN iffD2], auto)
  1608 done
  1609 
  1610 lemma numeral_less_real_of_int_iff2 [simp]:
  1611      "(real (m::int) < (numeral n)) = (m < numeral n)"
  1612 apply auto
  1613 apply (rule real_of_int_less_iff [THEN iffD1])
  1614 apply (drule_tac [2] real_of_int_less_iff [THEN iffD2], auto)
  1615 done
  1616 
  1617 lemma real_of_nat_less_numeral_iff [simp]:
  1618   "real (n::nat) < numeral w \<longleftrightarrow> n < numeral w"
  1619   using real_of_nat_less_iff[of n "numeral w"] by simp
  1620 
  1621 lemma numeral_less_real_of_nat_iff [simp]:
  1622   "numeral w < real (n::nat) \<longleftrightarrow> numeral w < n"
  1623   using real_of_nat_less_iff[of "numeral w" n] by simp
  1624 
  1625 lemma numeral_le_real_of_int_iff [simp]:
  1626      "((numeral n) \<le> real (m::int)) = (numeral n \<le> m)"
  1627 by (simp add: linorder_not_less [symmetric])
  1628 
  1629 lemma numeral_le_real_of_int_iff2 [simp]:
  1630      "(real (m::int) \<le> (numeral n)) = (m \<le> numeral n)"
  1631 by (simp add: linorder_not_less [symmetric])
  1632 
  1633 lemma floor_real_of_nat [simp]: "floor (real (n::nat)) = int n"
  1634 unfolding real_of_nat_def by simp
  1635 
  1636 lemma floor_minus_real_of_nat [simp]: "floor (- real (n::nat)) = - int n"
  1637 unfolding real_of_nat_def by (simp add: floor_minus)
  1638 
  1639 lemma floor_real_of_int [simp]: "floor (real (n::int)) = n"
  1640 unfolding real_of_int_def by simp
  1641 
  1642 lemma floor_minus_real_of_int [simp]: "floor (- real (n::int)) = - n"
  1643 unfolding real_of_int_def by (simp add: floor_minus)
  1644 
  1645 lemma real_lb_ub_int: " \<exists>n::int. real n \<le> r & r < real (n+1)"
  1646 unfolding real_of_int_def by (rule floor_exists)
  1647 
  1648 lemma lemma_floor:
  1649   assumes a1: "real m \<le> r" and a2: "r < real n + 1"
  1650   shows "m \<le> (n::int)"
  1651 proof -
  1652   have "real m < real n + 1" using a1 a2 by (rule order_le_less_trans)
  1653   also have "... = real (n + 1)" by simp
  1654   finally have "m < n + 1" by (simp only: real_of_int_less_iff)
  1655   thus ?thesis by arith
  1656 qed
  1657 
  1658 lemma real_of_int_floor_le [simp]: "real (floor r) \<le> r"
  1659 unfolding real_of_int_def by (rule of_int_floor_le)
  1660 
  1661 lemma lemma_floor2: "real n < real (x::int) + 1 ==> n \<le> x"
  1662 by (auto intro: lemma_floor)
  1663 
  1664 lemma real_of_int_floor_cancel [simp]:
  1665     "(real (floor x) = x) = (\<exists>n::int. x = real n)"
  1666   using floor_real_of_int by metis
  1667 
  1668 lemma floor_eq: "[| real n < x; x < real n + 1 |] ==> floor x = n"
  1669   unfolding real_of_int_def using floor_unique [of n x] by simp
  1670 
  1671 lemma floor_eq2: "[| real n \<le> x; x < real n + 1 |] ==> floor x = n"
  1672   unfolding real_of_int_def by (rule floor_unique)
  1673 
  1674 lemma floor_eq3: "[| real n < x; x < real (Suc n) |] ==> nat(floor x) = n"
  1675 apply (rule inj_int [THEN injD])
  1676 apply (simp add: real_of_nat_Suc)
  1677 apply (simp add: real_of_nat_Suc floor_eq floor_eq [where n = "int n"])
  1678 done
  1679 
  1680 lemma floor_eq4: "[| real n \<le> x; x < real (Suc n) |] ==> nat(floor x) = n"
  1681 apply (drule order_le_imp_less_or_eq)
  1682 apply (auto intro: floor_eq3)
  1683 done
  1684 
  1685 lemma real_of_int_floor_ge_diff_one [simp]: "r - 1 \<le> real(floor r)"
  1686   unfolding real_of_int_def using floor_correct [of r] by simp
  1687 
  1688 lemma real_of_int_floor_gt_diff_one [simp]: "r - 1 < real(floor r)"
  1689   unfolding real_of_int_def using floor_correct [of r] by simp
  1690 
  1691 lemma real_of_int_floor_add_one_ge [simp]: "r \<le> real(floor r) + 1"
  1692   unfolding real_of_int_def using floor_correct [of r] by simp
  1693 
  1694 lemma real_of_int_floor_add_one_gt [simp]: "r < real(floor r) + 1"
  1695   unfolding real_of_int_def using floor_correct [of r] by simp
  1696 
  1697 lemma le_floor: "real a <= x ==> a <= floor x"
  1698   unfolding real_of_int_def by (simp add: le_floor_iff)
  1699 
  1700 lemma real_le_floor: "a <= floor x ==> real a <= x"
  1701   unfolding real_of_int_def by (simp add: le_floor_iff)
  1702 
  1703 lemma le_floor_eq: "(a <= floor x) = (real a <= x)"
  1704   unfolding real_of_int_def by (rule le_floor_iff)
  1705 
  1706 lemma floor_less_eq: "(floor x < a) = (x < real a)"
  1707   unfolding real_of_int_def by (rule floor_less_iff)
  1708 
  1709 lemma less_floor_eq: "(a < floor x) = (real a + 1 <= x)"
  1710   unfolding real_of_int_def by (rule less_floor_iff)
  1711 
  1712 lemma floor_le_eq: "(floor x <= a) = (x < real a + 1)"
  1713   unfolding real_of_int_def by (rule floor_le_iff)
  1714 
  1715 lemma floor_add [simp]: "floor (x + real a) = floor x + a"
  1716   unfolding real_of_int_def by (rule floor_add_of_int)
  1717 
  1718 lemma floor_subtract [simp]: "floor (x - real a) = floor x - a"
  1719   unfolding real_of_int_def by (rule floor_diff_of_int)
  1720 
  1721 lemma le_mult_floor:
  1722   assumes "0 \<le> (a :: real)" and "0 \<le> b"
  1723   shows "floor a * floor b \<le> floor (a * b)"
  1724 proof -
  1725   have "real (floor a) \<le> a"
  1726     and "real (floor b) \<le> b" by auto
  1727   hence "real (floor a * floor b) \<le> a * b"
  1728     using assms by (auto intro!: mult_mono)
  1729   also have "a * b < real (floor (a * b) + 1)" by auto
  1730   finally show ?thesis unfolding real_of_int_less_iff by simp
  1731 qed
  1732 
  1733 lemma floor_divide_eq_div:
  1734   "floor (real a / real b) = a div b"
  1735 proof cases
  1736   assume "b \<noteq> 0 \<or> b dvd a"
  1737   with real_of_int_div3[of a b] show ?thesis
  1738     by (auto simp: real_of_int_div[symmetric] intro!: floor_eq2 real_of_int_div4 neq_le_trans)
  1739        (metis add_left_cancel zero_neq_one real_of_int_div_aux real_of_int_inject
  1740               real_of_int_zero_cancel right_inverse_eq div_self mod_div_trivial)
  1741 qed (auto simp: real_of_int_div)
  1742 
  1743 lemma ceiling_real_of_nat [simp]: "ceiling (real (n::nat)) = int n"
  1744   unfolding real_of_nat_def by simp
  1745 
  1746 lemma real_of_int_ceiling_ge [simp]: "r \<le> real (ceiling r)"
  1747   unfolding real_of_int_def by (rule le_of_int_ceiling)
  1748 
  1749 lemma ceiling_real_of_int [simp]: "ceiling (real (n::int)) = n"
  1750   unfolding real_of_int_def by simp
  1751 
  1752 lemma real_of_int_ceiling_cancel [simp]:
  1753      "(real (ceiling x) = x) = (\<exists>n::int. x = real n)"
  1754   using ceiling_real_of_int by metis
  1755 
  1756 lemma ceiling_eq: "[| real n < x; x < real n + 1 |] ==> ceiling x = n + 1"
  1757   unfolding real_of_int_def using ceiling_unique [of "n + 1" x] by simp
  1758 
  1759 lemma ceiling_eq2: "[| real n < x; x \<le> real n + 1 |] ==> ceiling x = n + 1"
  1760   unfolding real_of_int_def using ceiling_unique [of "n + 1" x] by simp
  1761 
  1762 lemma ceiling_eq3: "[| real n - 1 < x; x \<le> real n  |] ==> ceiling x = n"
  1763   unfolding real_of_int_def using ceiling_unique [of n x] by simp
  1764 
  1765 lemma real_of_int_ceiling_diff_one_le [simp]: "real (ceiling r) - 1 \<le> r"
  1766   unfolding real_of_int_def using ceiling_correct [of r] by simp
  1767 
  1768 lemma real_of_int_ceiling_le_add_one [simp]: "real (ceiling r) \<le> r + 1"
  1769   unfolding real_of_int_def using ceiling_correct [of r] by simp
  1770 
  1771 lemma ceiling_le: "x <= real a ==> ceiling x <= a"
  1772   unfolding real_of_int_def by (simp add: ceiling_le_iff)
  1773 
  1774 lemma ceiling_le_real: "ceiling x <= a ==> x <= real a"
  1775   unfolding real_of_int_def by (simp add: ceiling_le_iff)
  1776 
  1777 lemma ceiling_le_eq: "(ceiling x <= a) = (x <= real a)"
  1778   unfolding real_of_int_def by (rule ceiling_le_iff)
  1779 
  1780 lemma less_ceiling_eq: "(a < ceiling x) = (real a < x)"
  1781   unfolding real_of_int_def by (rule less_ceiling_iff)
  1782 
  1783 lemma ceiling_less_eq: "(ceiling x < a) = (x <= real a - 1)"
  1784   unfolding real_of_int_def by (rule ceiling_less_iff)
  1785 
  1786 lemma le_ceiling_eq: "(a <= ceiling x) = (real a - 1 < x)"
  1787   unfolding real_of_int_def by (rule le_ceiling_iff)
  1788 
  1789 lemma ceiling_add [simp]: "ceiling (x + real a) = ceiling x + a"
  1790   unfolding real_of_int_def by (rule ceiling_add_of_int)
  1791 
  1792 lemma ceiling_subtract [simp]: "ceiling (x - real a) = ceiling x - a"
  1793   unfolding real_of_int_def by (rule ceiling_diff_of_int)
  1794 
  1795 
  1796 subsubsection {* Versions for the natural numbers *}
  1797 
  1798 definition
  1799   natfloor :: "real => nat" where
  1800   "natfloor x = nat(floor x)"
  1801 
  1802 definition
  1803   natceiling :: "real => nat" where
  1804   "natceiling x = nat(ceiling x)"
  1805 
  1806 lemma natfloor_zero [simp]: "natfloor 0 = 0"
  1807   by (unfold natfloor_def, simp)
  1808 
  1809 lemma natfloor_one [simp]: "natfloor 1 = 1"
  1810   by (unfold natfloor_def, simp)
  1811 
  1812 lemma zero_le_natfloor [simp]: "0 <= natfloor x"
  1813   by (unfold natfloor_def, simp)
  1814 
  1815 lemma natfloor_numeral_eq [simp]: "natfloor (numeral n) = numeral n"
  1816   by (unfold natfloor_def, simp)
  1817 
  1818 lemma natfloor_real_of_nat [simp]: "natfloor(real n) = n"
  1819   by (unfold natfloor_def, simp)
  1820 
  1821 lemma real_natfloor_le: "0 <= x ==> real(natfloor x) <= x"
  1822   by (unfold natfloor_def, simp)
  1823 
  1824 lemma natfloor_neg: "x <= 0 ==> natfloor x = 0"
  1825   unfolding natfloor_def by simp
  1826 
  1827 lemma natfloor_mono: "x <= y ==> natfloor x <= natfloor y"
  1828   unfolding natfloor_def by (intro nat_mono floor_mono)
  1829 
  1830 lemma le_natfloor: "real x <= a ==> x <= natfloor a"
  1831   apply (unfold natfloor_def)
  1832   apply (subst nat_int [THEN sym])
  1833   apply (rule nat_mono)
  1834   apply (rule le_floor)
  1835   apply simp
  1836 done
  1837 
  1838 lemma natfloor_less_iff: "0 \<le> x \<Longrightarrow> natfloor x < n \<longleftrightarrow> x < real n"
  1839   unfolding natfloor_def real_of_nat_def
  1840   by (simp add: nat_less_iff floor_less_iff)
  1841 
  1842 lemma less_natfloor:
  1843   assumes "0 \<le> x" and "x < real (n :: nat)"
  1844   shows "natfloor x < n"
  1845   using assms by (simp add: natfloor_less_iff)
  1846 
  1847 lemma le_natfloor_eq: "0 <= x ==> (a <= natfloor x) = (real a <= x)"
  1848   apply (rule iffI)
  1849   apply (rule order_trans)
  1850   prefer 2
  1851   apply (erule real_natfloor_le)
  1852   apply (subst real_of_nat_le_iff)
  1853   apply assumption
  1854   apply (erule le_natfloor)
  1855 done
  1856 
  1857 lemma le_natfloor_eq_numeral [simp]:
  1858     "~ neg((numeral n)::int) ==> 0 <= x ==>
  1859       (numeral n <= natfloor x) = (numeral n <= x)"
  1860   apply (subst le_natfloor_eq, assumption)
  1861   apply simp
  1862 done
  1863 
  1864 lemma le_natfloor_eq_one [simp]: "(1 <= natfloor x) = (1 <= x)"
  1865   apply (case_tac "0 <= x")
  1866   apply (subst le_natfloor_eq, assumption, simp)
  1867   apply (rule iffI)
  1868   apply (subgoal_tac "natfloor x <= natfloor 0")
  1869   apply simp
  1870   apply (rule natfloor_mono)
  1871   apply simp
  1872   apply simp
  1873 done
  1874 
  1875 lemma natfloor_eq: "real n <= x ==> x < real n + 1 ==> natfloor x = n"
  1876   unfolding natfloor_def by (simp add: floor_eq2 [where n="int n"])
  1877 
  1878 lemma real_natfloor_add_one_gt: "x < real(natfloor x) + 1"
  1879   apply (case_tac "0 <= x")
  1880   apply (unfold natfloor_def)
  1881   apply simp
  1882   apply simp_all
  1883 done
  1884 
  1885 lemma real_natfloor_gt_diff_one: "x - 1 < real(natfloor x)"
  1886 using real_natfloor_add_one_gt by (simp add: algebra_simps)
  1887 
  1888 lemma ge_natfloor_plus_one_imp_gt: "natfloor z + 1 <= n ==> z < real n"
  1889   apply (subgoal_tac "z < real(natfloor z) + 1")
  1890   apply arith
  1891   apply (rule real_natfloor_add_one_gt)
  1892 done
  1893 
  1894 lemma natfloor_add [simp]: "0 <= x ==> natfloor (x + real a) = natfloor x + a"
  1895   unfolding natfloor_def
  1896   unfolding real_of_int_of_nat_eq [symmetric] floor_add
  1897   by (simp add: nat_add_distrib)
  1898 
  1899 lemma natfloor_add_numeral [simp]:
  1900     "~neg ((numeral n)::int) ==> 0 <= x ==>
  1901       natfloor (x + numeral n) = natfloor x + numeral n"
  1902   by (simp add: natfloor_add [symmetric])
  1903 
  1904 lemma natfloor_add_one: "0 <= x ==> natfloor(x + 1) = natfloor x + 1"
  1905   by (simp add: natfloor_add [symmetric] del: One_nat_def)
  1906 
  1907 lemma natfloor_subtract [simp]:
  1908     "natfloor(x - real a) = natfloor x - a"
  1909   unfolding natfloor_def real_of_int_of_nat_eq [symmetric] floor_subtract
  1910   by simp
  1911 
  1912 lemma natfloor_div_nat:
  1913   assumes "1 <= x" and "y > 0"
  1914   shows "natfloor (x / real y) = natfloor x div y"
  1915 proof (rule natfloor_eq)
  1916   have "(natfloor x) div y * y \<le> natfloor x"
  1917     by (rule add_leD1 [where k="natfloor x mod y"], simp)
  1918   thus "real (natfloor x div y) \<le> x / real y"
  1919     using assms by (simp add: le_divide_eq le_natfloor_eq)
  1920   have "natfloor x < (natfloor x) div y * y + y"
  1921     apply (subst mod_div_equality [symmetric])
  1922     apply (rule add_strict_left_mono)
  1923     apply (rule mod_less_divisor)
  1924     apply fact
  1925     done
  1926   thus "x / real y < real (natfloor x div y) + 1"
  1927     using assms
  1928     by (simp add: divide_less_eq natfloor_less_iff distrib_right)
  1929 qed
  1930 
  1931 lemma le_mult_natfloor:
  1932   shows "natfloor a * natfloor b \<le> natfloor (a * b)"
  1933   by (cases "0 <= a & 0 <= b")
  1934     (auto simp add: le_natfloor_eq mult_mono' real_natfloor_le natfloor_neg)
  1935 
  1936 lemma natceiling_zero [simp]: "natceiling 0 = 0"
  1937   by (unfold natceiling_def, simp)
  1938 
  1939 lemma natceiling_one [simp]: "natceiling 1 = 1"
  1940   by (unfold natceiling_def, simp)
  1941 
  1942 lemma zero_le_natceiling [simp]: "0 <= natceiling x"
  1943   by (unfold natceiling_def, simp)
  1944 
  1945 lemma natceiling_numeral_eq [simp]: "natceiling (numeral n) = numeral n"
  1946   by (unfold natceiling_def, simp)
  1947 
  1948 lemma natceiling_real_of_nat [simp]: "natceiling(real n) = n"
  1949   by (unfold natceiling_def, simp)
  1950 
  1951 lemma real_natceiling_ge: "x <= real(natceiling x)"
  1952   unfolding natceiling_def by (cases "x < 0", simp_all)
  1953 
  1954 lemma natceiling_neg: "x <= 0 ==> natceiling x = 0"
  1955   unfolding natceiling_def by simp
  1956 
  1957 lemma natceiling_mono: "x <= y ==> natceiling x <= natceiling y"
  1958   unfolding natceiling_def by (intro nat_mono ceiling_mono)
  1959 
  1960 lemma natceiling_le: "x <= real a ==> natceiling x <= a"
  1961   unfolding natceiling_def real_of_nat_def
  1962   by (simp add: nat_le_iff ceiling_le_iff)
  1963 
  1964 lemma natceiling_le_eq: "(natceiling x <= a) = (x <= real a)"
  1965   unfolding natceiling_def real_of_nat_def
  1966   by (simp add: nat_le_iff ceiling_le_iff)
  1967 
  1968 lemma natceiling_le_eq_numeral [simp]:
  1969     "~ neg((numeral n)::int) ==>
  1970       (natceiling x <= numeral n) = (x <= numeral n)"
  1971   by (simp add: natceiling_le_eq)
  1972 
  1973 lemma natceiling_le_eq_one: "(natceiling x <= 1) = (x <= 1)"
  1974   unfolding natceiling_def
  1975   by (simp add: nat_le_iff ceiling_le_iff)
  1976 
  1977 lemma natceiling_eq: "real n < x ==> x <= real n + 1 ==> natceiling x = n + 1"
  1978   unfolding natceiling_def
  1979   by (simp add: ceiling_eq2 [where n="int n"])
  1980 
  1981 lemma natceiling_add [simp]: "0 <= x ==>
  1982     natceiling (x + real a) = natceiling x + a"
  1983   unfolding natceiling_def
  1984   unfolding real_of_int_of_nat_eq [symmetric] ceiling_add
  1985   by (simp add: nat_add_distrib)
  1986 
  1987 lemma natceiling_add_numeral [simp]:
  1988     "~ neg ((numeral n)::int) ==> 0 <= x ==>
  1989       natceiling (x + numeral n) = natceiling x + numeral n"
  1990   by (simp add: natceiling_add [symmetric])
  1991 
  1992 lemma natceiling_add_one: "0 <= x ==> natceiling(x + 1) = natceiling x + 1"
  1993   by (simp add: natceiling_add [symmetric] del: One_nat_def)
  1994 
  1995 lemma natceiling_subtract [simp]: "natceiling(x - real a) = natceiling x - a"
  1996   unfolding natceiling_def real_of_int_of_nat_eq [symmetric] ceiling_subtract
  1997   by simp
  1998 
  1999 subsection {* Exponentiation with floor *}
  2000 
  2001 lemma floor_power:
  2002   assumes "x = real (floor x)"
  2003   shows "floor (x ^ n) = floor x ^ n"
  2004 proof -
  2005   have *: "x ^ n = real (floor x ^ n)"
  2006     using assms by (induct n arbitrary: x) simp_all
  2007   show ?thesis unfolding real_of_int_inject[symmetric]
  2008     unfolding * floor_real_of_int ..
  2009 qed
  2010 
  2011 lemma natfloor_power:
  2012   assumes "x = real (natfloor x)"
  2013   shows "natfloor (x ^ n) = natfloor x ^ n"
  2014 proof -
  2015   from assms have "0 \<le> floor x" by auto
  2016   note assms[unfolded natfloor_def real_nat_eq_real[OF `0 \<le> floor x`]]
  2017   from floor_power[OF this]
  2018   show ?thesis unfolding natfloor_def nat_power_eq[OF `0 \<le> floor x`, symmetric]
  2019     by simp
  2020 qed
  2021 
  2022 
  2023 subsection {* Implementation of rational real numbers *}
  2024 
  2025 text {* Formal constructor *}
  2026 
  2027 definition Ratreal :: "rat \<Rightarrow> real" where
  2028   [code_abbrev, simp]: "Ratreal = of_rat"
  2029 
  2030 code_datatype Ratreal
  2031 
  2032 
  2033 text {* Numerals *}
  2034 
  2035 lemma [code_abbrev]:
  2036   "(of_rat (of_int a) :: real) = of_int a"
  2037   by simp
  2038 
  2039 lemma [code_abbrev]:
  2040   "(of_rat 0 :: real) = 0"
  2041   by simp
  2042 
  2043 lemma [code_abbrev]:
  2044   "(of_rat 1 :: real) = 1"
  2045   by simp
  2046 
  2047 lemma [code_abbrev]:
  2048   "(of_rat (numeral k) :: real) = numeral k"
  2049   by simp
  2050 
  2051 lemma [code_abbrev]:
  2052   "(of_rat (- numeral k) :: real) = - numeral k"
  2053   by simp
  2054 
  2055 lemma [code_post]:
  2056   "(of_rat (0 / r)  :: real) = 0"
  2057   "(of_rat (r / 0)  :: real) = 0"
  2058   "(of_rat (1 / 1)  :: real) = 1"
  2059   "(of_rat (numeral k / 1) :: real) = numeral k"
  2060   "(of_rat (- numeral k / 1) :: real) = - numeral k"
  2061   "(of_rat (1 / numeral k) :: real) = 1 / numeral k"
  2062   "(of_rat (1 / - numeral k) :: real) = 1 / - numeral k"
  2063   "(of_rat (numeral k / numeral l)  :: real) = numeral k / numeral l"
  2064   "(of_rat (numeral k / - numeral l)  :: real) = numeral k / - numeral l"
  2065   "(of_rat (- numeral k / numeral l)  :: real) = - numeral k / numeral l"
  2066   "(of_rat (- numeral k / - numeral l)  :: real) = - numeral k / - numeral l"
  2067   by (simp_all add: of_rat_divide of_rat_minus)
  2068 
  2069 
  2070 text {* Operations *}
  2071 
  2072 lemma zero_real_code [code]:
  2073   "0 = Ratreal 0"
  2074 by simp
  2075 
  2076 lemma one_real_code [code]:
  2077   "1 = Ratreal 1"
  2078 by simp
  2079 
  2080 instantiation real :: equal
  2081 begin
  2082 
  2083 definition "HOL.equal (x\<Colon>real) y \<longleftrightarrow> x - y = 0"
  2084 
  2085 instance proof
  2086 qed (simp add: equal_real_def)
  2087 
  2088 lemma real_equal_code [code]:
  2089   "HOL.equal (Ratreal x) (Ratreal y) \<longleftrightarrow> HOL.equal x y"
  2090   by (simp add: equal_real_def equal)
  2091 
  2092 lemma [code nbe]:
  2093   "HOL.equal (x::real) x \<longleftrightarrow> True"
  2094   by (rule equal_refl)
  2095 
  2096 end
  2097 
  2098 lemma real_less_eq_code [code]: "Ratreal x \<le> Ratreal y \<longleftrightarrow> x \<le> y"
  2099   by (simp add: of_rat_less_eq)
  2100 
  2101 lemma real_less_code [code]: "Ratreal x < Ratreal y \<longleftrightarrow> x < y"
  2102   by (simp add: of_rat_less)
  2103 
  2104 lemma real_plus_code [code]: "Ratreal x + Ratreal y = Ratreal (x + y)"
  2105   by (simp add: of_rat_add)
  2106 
  2107 lemma real_times_code [code]: "Ratreal x * Ratreal y = Ratreal (x * y)"
  2108   by (simp add: of_rat_mult)
  2109 
  2110 lemma real_uminus_code [code]: "- Ratreal x = Ratreal (- x)"
  2111   by (simp add: of_rat_minus)
  2112 
  2113 lemma real_minus_code [code]: "Ratreal x - Ratreal y = Ratreal (x - y)"
  2114   by (simp add: of_rat_diff)
  2115 
  2116 lemma real_inverse_code [code]: "inverse (Ratreal x) = Ratreal (inverse x)"
  2117   by (simp add: of_rat_inverse)
  2118  
  2119 lemma real_divide_code [code]: "Ratreal x / Ratreal y = Ratreal (x / y)"
  2120   by (simp add: of_rat_divide)
  2121 
  2122 lemma real_floor_code [code]: "floor (Ratreal x) = floor x"
  2123   by (metis Ratreal_def floor_le_iff floor_unique le_floor_iff of_int_floor_le of_rat_of_int_eq real_less_eq_code)
  2124 
  2125 
  2126 text {* Quickcheck *}
  2127 
  2128 definition (in term_syntax)
  2129   valterm_ratreal :: "rat \<times> (unit \<Rightarrow> Code_Evaluation.term) \<Rightarrow> real \<times> (unit \<Rightarrow> Code_Evaluation.term)" where
  2130   [code_unfold]: "valterm_ratreal k = Code_Evaluation.valtermify Ratreal {\<cdot>} k"
  2131 
  2132 notation fcomp (infixl "\<circ>>" 60)
  2133 notation scomp (infixl "\<circ>\<rightarrow>" 60)
  2134 
  2135 instantiation real :: random
  2136 begin
  2137 
  2138 definition
  2139   "Quickcheck_Random.random i = Quickcheck_Random.random i \<circ>\<rightarrow> (\<lambda>r. Pair (valterm_ratreal r))"
  2140 
  2141 instance ..
  2142 
  2143 end
  2144 
  2145 no_notation fcomp (infixl "\<circ>>" 60)
  2146 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
  2147 
  2148 instantiation real :: exhaustive
  2149 begin
  2150 
  2151 definition
  2152   "exhaustive_real f d = Quickcheck_Exhaustive.exhaustive (%r. f (Ratreal r)) d"
  2153 
  2154 instance ..
  2155 
  2156 end
  2157 
  2158 instantiation real :: full_exhaustive
  2159 begin
  2160 
  2161 definition
  2162   "full_exhaustive_real f d = Quickcheck_Exhaustive.full_exhaustive (%r. f (valterm_ratreal r)) d"
  2163 
  2164 instance ..
  2165 
  2166 end
  2167 
  2168 instantiation real :: narrowing
  2169 begin
  2170 
  2171 definition
  2172   "narrowing = Quickcheck_Narrowing.apply (Quickcheck_Narrowing.cons Ratreal) narrowing"
  2173 
  2174 instance ..
  2175 
  2176 end
  2177 
  2178 
  2179 subsection {* Setup for Nitpick *}
  2180 
  2181 declaration {*
  2182   Nitpick_HOL.register_frac_type @{type_name real}
  2183    [(@{const_name zero_real_inst.zero_real}, @{const_name Nitpick.zero_frac}),
  2184     (@{const_name one_real_inst.one_real}, @{const_name Nitpick.one_frac}),
  2185     (@{const_name plus_real_inst.plus_real}, @{const_name Nitpick.plus_frac}),
  2186     (@{const_name times_real_inst.times_real}, @{const_name Nitpick.times_frac}),
  2187     (@{const_name uminus_real_inst.uminus_real}, @{const_name Nitpick.uminus_frac}),
  2188     (@{const_name inverse_real_inst.inverse_real}, @{const_name Nitpick.inverse_frac}),
  2189     (@{const_name ord_real_inst.less_real}, @{const_name Nitpick.less_frac}),
  2190     (@{const_name ord_real_inst.less_eq_real}, @{const_name Nitpick.less_eq_frac})]
  2191 *}
  2192 
  2193 lemmas [nitpick_unfold] = inverse_real_inst.inverse_real one_real_inst.one_real
  2194     ord_real_inst.less_real ord_real_inst.less_eq_real plus_real_inst.plus_real
  2195     times_real_inst.times_real uminus_real_inst.uminus_real
  2196     zero_real_inst.zero_real
  2197 
  2198 
  2199 subsection {* Setup for SMT *}
  2200 
  2201 ML_file "Tools/SMT/smt_real.ML"
  2202 setup SMT_Real.setup
  2203 ML_file "Tools/SMT2/smt2_real.ML"
  2204 ML_file "Tools/SMT2/z3_new_real.ML"
  2205 
  2206 lemma [z3_new_rule]:
  2207   "0 + (x::real) = x"
  2208   "x + 0 = x"
  2209   "0 * x = 0"
  2210   "1 * x = x"
  2211   "x + y = y + x"
  2212   by auto
  2213 
  2214 end