src/HOL/Real_Vector_Spaces.thy
author hoelzl
Wed May 07 12:25:35 2014 +0200 (2014-05-07)
changeset 56889 48a745e1bde7
parent 56479 91958d4b30f7
child 57275 0ddb5b755cdc
permissions -rw-r--r--
avoid the Complex constructor, use the more natural Re/Im view; moved csqrt to Complex.
     1 (*  Title:      HOL/Real_Vector_Spaces.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 header {* Vector Spaces and Algebras over the Reals *}
     7 
     8 theory Real_Vector_Spaces
     9 imports Real Topological_Spaces
    10 begin
    11 
    12 subsection {* Locale for additive functions *}
    13 
    14 locale additive =
    15   fixes f :: "'a::ab_group_add \<Rightarrow> 'b::ab_group_add"
    16   assumes add: "f (x + y) = f x + f y"
    17 begin
    18 
    19 lemma zero: "f 0 = 0"
    20 proof -
    21   have "f 0 = f (0 + 0)" by simp
    22   also have "\<dots> = f 0 + f 0" by (rule add)
    23   finally show "f 0 = 0" by simp
    24 qed
    25 
    26 lemma minus: "f (- x) = - f x"
    27 proof -
    28   have "f (- x) + f x = f (- x + x)" by (rule add [symmetric])
    29   also have "\<dots> = - f x + f x" by (simp add: zero)
    30   finally show "f (- x) = - f x" by (rule add_right_imp_eq)
    31 qed
    32 
    33 lemma diff: "f (x - y) = f x - f y"
    34   using add [of x "- y"] by (simp add: minus)
    35 
    36 lemma setsum: "f (setsum g A) = (\<Sum>x\<in>A. f (g x))"
    37 apply (cases "finite A")
    38 apply (induct set: finite)
    39 apply (simp add: zero)
    40 apply (simp add: add)
    41 apply (simp add: zero)
    42 done
    43 
    44 end
    45 
    46 subsection {* Vector spaces *}
    47 
    48 locale vector_space =
    49   fixes scale :: "'a::field \<Rightarrow> 'b::ab_group_add \<Rightarrow> 'b"
    50   assumes scale_right_distrib [algebra_simps]:
    51     "scale a (x + y) = scale a x + scale a y"
    52   and scale_left_distrib [algebra_simps]:
    53     "scale (a + b) x = scale a x + scale b x"
    54   and scale_scale [simp]: "scale a (scale b x) = scale (a * b) x"
    55   and scale_one [simp]: "scale 1 x = x"
    56 begin
    57 
    58 lemma scale_left_commute:
    59   "scale a (scale b x) = scale b (scale a x)"
    60 by (simp add: mult_commute)
    61 
    62 lemma scale_zero_left [simp]: "scale 0 x = 0"
    63   and scale_minus_left [simp]: "scale (- a) x = - (scale a x)"
    64   and scale_left_diff_distrib [algebra_simps]:
    65         "scale (a - b) x = scale a x - scale b x"
    66   and scale_setsum_left: "scale (setsum f A) x = (\<Sum>a\<in>A. scale (f a) x)"
    67 proof -
    68   interpret s: additive "\<lambda>a. scale a x"
    69     proof qed (rule scale_left_distrib)
    70   show "scale 0 x = 0" by (rule s.zero)
    71   show "scale (- a) x = - (scale a x)" by (rule s.minus)
    72   show "scale (a - b) x = scale a x - scale b x" by (rule s.diff)
    73   show "scale (setsum f A) x = (\<Sum>a\<in>A. scale (f a) x)" by (rule s.setsum)
    74 qed
    75 
    76 lemma scale_zero_right [simp]: "scale a 0 = 0"
    77   and scale_minus_right [simp]: "scale a (- x) = - (scale a x)"
    78   and scale_right_diff_distrib [algebra_simps]:
    79         "scale a (x - y) = scale a x - scale a y"
    80   and scale_setsum_right: "scale a (setsum f A) = (\<Sum>x\<in>A. scale a (f x))"
    81 proof -
    82   interpret s: additive "\<lambda>x. scale a x"
    83     proof qed (rule scale_right_distrib)
    84   show "scale a 0 = 0" by (rule s.zero)
    85   show "scale a (- x) = - (scale a x)" by (rule s.minus)
    86   show "scale a (x - y) = scale a x - scale a y" by (rule s.diff)
    87   show "scale a (setsum f A) = (\<Sum>x\<in>A. scale a (f x))" by (rule s.setsum)
    88 qed
    89 
    90 lemma scale_eq_0_iff [simp]:
    91   "scale a x = 0 \<longleftrightarrow> a = 0 \<or> x = 0"
    92 proof cases
    93   assume "a = 0" thus ?thesis by simp
    94 next
    95   assume anz [simp]: "a \<noteq> 0"
    96   { assume "scale a x = 0"
    97     hence "scale (inverse a) (scale a x) = 0" by simp
    98     hence "x = 0" by simp }
    99   thus ?thesis by force
   100 qed
   101 
   102 lemma scale_left_imp_eq:
   103   "\<lbrakk>a \<noteq> 0; scale a x = scale a y\<rbrakk> \<Longrightarrow> x = y"
   104 proof -
   105   assume nonzero: "a \<noteq> 0"
   106   assume "scale a x = scale a y"
   107   hence "scale a (x - y) = 0"
   108      by (simp add: scale_right_diff_distrib)
   109   hence "x - y = 0" by (simp add: nonzero)
   110   thus "x = y" by (simp only: right_minus_eq)
   111 qed
   112 
   113 lemma scale_right_imp_eq:
   114   "\<lbrakk>x \<noteq> 0; scale a x = scale b x\<rbrakk> \<Longrightarrow> a = b"
   115 proof -
   116   assume nonzero: "x \<noteq> 0"
   117   assume "scale a x = scale b x"
   118   hence "scale (a - b) x = 0"
   119      by (simp add: scale_left_diff_distrib)
   120   hence "a - b = 0" by (simp add: nonzero)
   121   thus "a = b" by (simp only: right_minus_eq)
   122 qed
   123 
   124 lemma scale_cancel_left [simp]:
   125   "scale a x = scale a y \<longleftrightarrow> x = y \<or> a = 0"
   126 by (auto intro: scale_left_imp_eq)
   127 
   128 lemma scale_cancel_right [simp]:
   129   "scale a x = scale b x \<longleftrightarrow> a = b \<or> x = 0"
   130 by (auto intro: scale_right_imp_eq)
   131 
   132 end
   133 
   134 subsection {* Real vector spaces *}
   135 
   136 class scaleR =
   137   fixes scaleR :: "real \<Rightarrow> 'a \<Rightarrow> 'a" (infixr "*\<^sub>R" 75)
   138 begin
   139 
   140 abbreviation
   141   divideR :: "'a \<Rightarrow> real \<Rightarrow> 'a" (infixl "'/\<^sub>R" 70)
   142 where
   143   "x /\<^sub>R r == scaleR (inverse r) x"
   144 
   145 end
   146 
   147 class real_vector = scaleR + ab_group_add +
   148   assumes scaleR_add_right: "scaleR a (x + y) = scaleR a x + scaleR a y"
   149   and scaleR_add_left: "scaleR (a + b) x = scaleR a x + scaleR b x"
   150   and scaleR_scaleR: "scaleR a (scaleR b x) = scaleR (a * b) x"
   151   and scaleR_one: "scaleR 1 x = x"
   152 
   153 interpretation real_vector:
   154   vector_space "scaleR :: real \<Rightarrow> 'a \<Rightarrow> 'a::real_vector"
   155 apply unfold_locales
   156 apply (rule scaleR_add_right)
   157 apply (rule scaleR_add_left)
   158 apply (rule scaleR_scaleR)
   159 apply (rule scaleR_one)
   160 done
   161 
   162 text {* Recover original theorem names *}
   163 
   164 lemmas scaleR_left_commute = real_vector.scale_left_commute
   165 lemmas scaleR_zero_left = real_vector.scale_zero_left
   166 lemmas scaleR_minus_left = real_vector.scale_minus_left
   167 lemmas scaleR_diff_left = real_vector.scale_left_diff_distrib
   168 lemmas scaleR_setsum_left = real_vector.scale_setsum_left
   169 lemmas scaleR_zero_right = real_vector.scale_zero_right
   170 lemmas scaleR_minus_right = real_vector.scale_minus_right
   171 lemmas scaleR_diff_right = real_vector.scale_right_diff_distrib
   172 lemmas scaleR_setsum_right = real_vector.scale_setsum_right
   173 lemmas scaleR_eq_0_iff = real_vector.scale_eq_0_iff
   174 lemmas scaleR_left_imp_eq = real_vector.scale_left_imp_eq
   175 lemmas scaleR_right_imp_eq = real_vector.scale_right_imp_eq
   176 lemmas scaleR_cancel_left = real_vector.scale_cancel_left
   177 lemmas scaleR_cancel_right = real_vector.scale_cancel_right
   178 
   179 text {* Legacy names *}
   180 
   181 lemmas scaleR_left_distrib = scaleR_add_left
   182 lemmas scaleR_right_distrib = scaleR_add_right
   183 lemmas scaleR_left_diff_distrib = scaleR_diff_left
   184 lemmas scaleR_right_diff_distrib = scaleR_diff_right
   185 
   186 lemma scaleR_minus1_left [simp]:
   187   fixes x :: "'a::real_vector"
   188   shows "scaleR (-1) x = - x"
   189   using scaleR_minus_left [of 1 x] by simp
   190 
   191 class real_algebra = real_vector + ring +
   192   assumes mult_scaleR_left [simp]: "scaleR a x * y = scaleR a (x * y)"
   193   and mult_scaleR_right [simp]: "x * scaleR a y = scaleR a (x * y)"
   194 
   195 class real_algebra_1 = real_algebra + ring_1
   196 
   197 class real_div_algebra = real_algebra_1 + division_ring
   198 
   199 class real_field = real_div_algebra + field
   200 
   201 instantiation real :: real_field
   202 begin
   203 
   204 definition
   205   real_scaleR_def [simp]: "scaleR a x = a * x"
   206 
   207 instance proof
   208 qed (simp_all add: algebra_simps)
   209 
   210 end
   211 
   212 interpretation scaleR_left: additive "(\<lambda>a. scaleR a x::'a::real_vector)"
   213 proof qed (rule scaleR_left_distrib)
   214 
   215 interpretation scaleR_right: additive "(\<lambda>x. scaleR a x::'a::real_vector)"
   216 proof qed (rule scaleR_right_distrib)
   217 
   218 lemma nonzero_inverse_scaleR_distrib:
   219   fixes x :: "'a::real_div_algebra" shows
   220   "\<lbrakk>a \<noteq> 0; x \<noteq> 0\<rbrakk> \<Longrightarrow> inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
   221 by (rule inverse_unique, simp)
   222 
   223 lemma inverse_scaleR_distrib:
   224   fixes x :: "'a::{real_div_algebra, division_ring_inverse_zero}"
   225   shows "inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
   226 apply (case_tac "a = 0", simp)
   227 apply (case_tac "x = 0", simp)
   228 apply (erule (1) nonzero_inverse_scaleR_distrib)
   229 done
   230 
   231 
   232 subsection {* Embedding of the Reals into any @{text real_algebra_1}:
   233 @{term of_real} *}
   234 
   235 definition
   236   of_real :: "real \<Rightarrow> 'a::real_algebra_1" where
   237   "of_real r = scaleR r 1"
   238 
   239 lemma scaleR_conv_of_real: "scaleR r x = of_real r * x"
   240 by (simp add: of_real_def)
   241 
   242 lemma of_real_0 [simp]: "of_real 0 = 0"
   243 by (simp add: of_real_def)
   244 
   245 lemma of_real_1 [simp]: "of_real 1 = 1"
   246 by (simp add: of_real_def)
   247 
   248 lemma of_real_add [simp]: "of_real (x + y) = of_real x + of_real y"
   249 by (simp add: of_real_def scaleR_left_distrib)
   250 
   251 lemma of_real_minus [simp]: "of_real (- x) = - of_real x"
   252 by (simp add: of_real_def)
   253 
   254 lemma of_real_diff [simp]: "of_real (x - y) = of_real x - of_real y"
   255 by (simp add: of_real_def scaleR_left_diff_distrib)
   256 
   257 lemma of_real_mult [simp]: "of_real (x * y) = of_real x * of_real y"
   258 by (simp add: of_real_def mult_commute)
   259 
   260 lemma of_real_setsum[simp]: "of_real (setsum f s) = (\<Sum>x\<in>s. of_real (f x))"
   261   by (induct s rule: infinite_finite_induct) auto
   262 
   263 lemma of_real_setprod[simp]: "of_real (setprod f s) = (\<Prod>x\<in>s. of_real (f x))"
   264   by (induct s rule: infinite_finite_induct) auto
   265 
   266 lemma nonzero_of_real_inverse:
   267   "x \<noteq> 0 \<Longrightarrow> of_real (inverse x) =
   268    inverse (of_real x :: 'a::real_div_algebra)"
   269 by (simp add: of_real_def nonzero_inverse_scaleR_distrib)
   270 
   271 lemma of_real_inverse [simp]:
   272   "of_real (inverse x) =
   273    inverse (of_real x :: 'a::{real_div_algebra, division_ring_inverse_zero})"
   274 by (simp add: of_real_def inverse_scaleR_distrib)
   275 
   276 lemma nonzero_of_real_divide:
   277   "y \<noteq> 0 \<Longrightarrow> of_real (x / y) =
   278    (of_real x / of_real y :: 'a::real_field)"
   279 by (simp add: divide_inverse nonzero_of_real_inverse)
   280 
   281 lemma of_real_divide [simp]:
   282   "of_real (x / y) =
   283    (of_real x / of_real y :: 'a::{real_field, field_inverse_zero})"
   284 by (simp add: divide_inverse)
   285 
   286 lemma of_real_power [simp]:
   287   "of_real (x ^ n) = (of_real x :: 'a::{real_algebra_1}) ^ n"
   288 by (induct n) simp_all
   289 
   290 lemma of_real_eq_iff [simp]: "(of_real x = of_real y) = (x = y)"
   291 by (simp add: of_real_def)
   292 
   293 lemma inj_of_real:
   294   "inj of_real"
   295   by (auto intro: injI)
   296 
   297 lemmas of_real_eq_0_iff [simp] = of_real_eq_iff [of _ 0, simplified]
   298 
   299 lemma of_real_eq_id [simp]: "of_real = (id :: real \<Rightarrow> real)"
   300 proof
   301   fix r
   302   show "of_real r = id r"
   303     by (simp add: of_real_def)
   304 qed
   305 
   306 text{*Collapse nested embeddings*}
   307 lemma of_real_of_nat_eq [simp]: "of_real (of_nat n) = of_nat n"
   308 by (induct n) auto
   309 
   310 lemma of_real_of_int_eq [simp]: "of_real (of_int z) = of_int z"
   311 by (cases z rule: int_diff_cases, simp)
   312 
   313 lemma of_real_real_of_nat_eq [simp]: "of_real (real n) = of_nat n"
   314   by (simp add: real_of_nat_def)
   315 
   316 lemma of_real_real_of_int_eq [simp]: "of_real (real z) = of_int z"
   317   by (simp add: real_of_int_def)
   318 
   319 lemma of_real_numeral: "of_real (numeral w) = numeral w"
   320 using of_real_of_int_eq [of "numeral w"] by simp
   321 
   322 lemma of_real_neg_numeral: "of_real (- numeral w) = - numeral w"
   323 using of_real_of_int_eq [of "- numeral w"] by simp
   324 
   325 text{*Every real algebra has characteristic zero*}
   326 
   327 instance real_algebra_1 < ring_char_0
   328 proof
   329   from inj_of_real inj_of_nat have "inj (of_real \<circ> of_nat)" by (rule inj_comp)
   330   then show "inj (of_nat :: nat \<Rightarrow> 'a)" by (simp add: comp_def)
   331 qed
   332 
   333 instance real_field < field_char_0 ..
   334 
   335 
   336 subsection {* The Set of Real Numbers *}
   337 
   338 definition Reals :: "'a::real_algebra_1 set" where
   339   "Reals = range of_real"
   340 
   341 notation (xsymbols)
   342   Reals  ("\<real>")
   343 
   344 lemma Reals_of_real [simp]: "of_real r \<in> Reals"
   345 by (simp add: Reals_def)
   346 
   347 lemma Reals_of_int [simp]: "of_int z \<in> Reals"
   348 by (subst of_real_of_int_eq [symmetric], rule Reals_of_real)
   349 
   350 lemma Reals_of_nat [simp]: "of_nat n \<in> Reals"
   351 by (subst of_real_of_nat_eq [symmetric], rule Reals_of_real)
   352 
   353 lemma Reals_numeral [simp]: "numeral w \<in> Reals"
   354 by (subst of_real_numeral [symmetric], rule Reals_of_real)
   355 
   356 lemma Reals_0 [simp]: "0 \<in> Reals"
   357 apply (unfold Reals_def)
   358 apply (rule range_eqI)
   359 apply (rule of_real_0 [symmetric])
   360 done
   361 
   362 lemma Reals_1 [simp]: "1 \<in> Reals"
   363 apply (unfold Reals_def)
   364 apply (rule range_eqI)
   365 apply (rule of_real_1 [symmetric])
   366 done
   367 
   368 lemma Reals_add [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a + b \<in> Reals"
   369 apply (auto simp add: Reals_def)
   370 apply (rule range_eqI)
   371 apply (rule of_real_add [symmetric])
   372 done
   373 
   374 lemma Reals_minus [simp]: "a \<in> Reals \<Longrightarrow> - a \<in> Reals"
   375 apply (auto simp add: Reals_def)
   376 apply (rule range_eqI)
   377 apply (rule of_real_minus [symmetric])
   378 done
   379 
   380 lemma Reals_diff [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a - b \<in> Reals"
   381 apply (auto simp add: Reals_def)
   382 apply (rule range_eqI)
   383 apply (rule of_real_diff [symmetric])
   384 done
   385 
   386 lemma Reals_mult [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a * b \<in> Reals"
   387 apply (auto simp add: Reals_def)
   388 apply (rule range_eqI)
   389 apply (rule of_real_mult [symmetric])
   390 done
   391 
   392 lemma nonzero_Reals_inverse:
   393   fixes a :: "'a::real_div_algebra"
   394   shows "\<lbrakk>a \<in> Reals; a \<noteq> 0\<rbrakk> \<Longrightarrow> inverse a \<in> Reals"
   395 apply (auto simp add: Reals_def)
   396 apply (rule range_eqI)
   397 apply (erule nonzero_of_real_inverse [symmetric])
   398 done
   399 
   400 lemma Reals_inverse:
   401   fixes a :: "'a::{real_div_algebra, division_ring_inverse_zero}"
   402   shows "a \<in> Reals \<Longrightarrow> inverse a \<in> Reals"
   403 apply (auto simp add: Reals_def)
   404 apply (rule range_eqI)
   405 apply (rule of_real_inverse [symmetric])
   406 done
   407 
   408 lemma Reals_inverse_iff [simp]: 
   409   fixes x:: "'a :: {real_div_algebra, division_ring_inverse_zero}"
   410   shows "inverse x \<in> \<real> \<longleftrightarrow> x \<in> \<real>"
   411 by (metis Reals_inverse inverse_inverse_eq)
   412 
   413 lemma nonzero_Reals_divide:
   414   fixes a b :: "'a::real_field"
   415   shows "\<lbrakk>a \<in> Reals; b \<in> Reals; b \<noteq> 0\<rbrakk> \<Longrightarrow> a / b \<in> Reals"
   416 apply (auto simp add: Reals_def)
   417 apply (rule range_eqI)
   418 apply (erule nonzero_of_real_divide [symmetric])
   419 done
   420 
   421 lemma Reals_divide [simp]:
   422   fixes a b :: "'a::{real_field, field_inverse_zero}"
   423   shows "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a / b \<in> Reals"
   424 apply (auto simp add: Reals_def)
   425 apply (rule range_eqI)
   426 apply (rule of_real_divide [symmetric])
   427 done
   428 
   429 lemma Reals_power [simp]:
   430   fixes a :: "'a::{real_algebra_1}"
   431   shows "a \<in> Reals \<Longrightarrow> a ^ n \<in> Reals"
   432 apply (auto simp add: Reals_def)
   433 apply (rule range_eqI)
   434 apply (rule of_real_power [symmetric])
   435 done
   436 
   437 lemma Reals_cases [cases set: Reals]:
   438   assumes "q \<in> \<real>"
   439   obtains (of_real) r where "q = of_real r"
   440   unfolding Reals_def
   441 proof -
   442   from `q \<in> \<real>` have "q \<in> range of_real" unfolding Reals_def .
   443   then obtain r where "q = of_real r" ..
   444   then show thesis ..
   445 qed
   446 
   447 lemma setsum_in_Reals: assumes "\<And>i. i \<in> s \<Longrightarrow> f i \<in> \<real>" shows "setsum f s \<in> \<real>"
   448 proof (cases "finite s")
   449   case True then show ?thesis using assms
   450     by (induct s rule: finite_induct) auto
   451 next
   452   case False then show ?thesis using assms
   453     by (metis Reals_0 setsum_infinite)
   454 qed
   455 
   456 lemma setprod_in_Reals: assumes "\<And>i. i \<in> s \<Longrightarrow> f i \<in> \<real>" shows "setprod f s \<in> \<real>"
   457 proof (cases "finite s")
   458   case True then show ?thesis using assms
   459     by (induct s rule: finite_induct) auto
   460 next
   461   case False then show ?thesis using assms
   462     by (metis Reals_1 setprod_infinite)
   463 qed
   464 
   465 lemma Reals_induct [case_names of_real, induct set: Reals]:
   466   "q \<in> \<real> \<Longrightarrow> (\<And>r. P (of_real r)) \<Longrightarrow> P q"
   467   by (rule Reals_cases) auto
   468 
   469 subsection {* Ordered real vector spaces *}
   470 
   471 class ordered_real_vector = real_vector + ordered_ab_group_add +
   472   assumes scaleR_left_mono: "x \<le> y \<Longrightarrow> 0 \<le> a \<Longrightarrow> a *\<^sub>R x \<le> a *\<^sub>R y"
   473   assumes scaleR_right_mono: "a \<le> b \<Longrightarrow> 0 \<le> x \<Longrightarrow> a *\<^sub>R x \<le> b *\<^sub>R x"
   474 begin
   475 
   476 lemma scaleR_mono:
   477   "a \<le> b \<Longrightarrow> x \<le> y \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> x \<Longrightarrow> a *\<^sub>R x \<le> b *\<^sub>R y"
   478 apply (erule scaleR_right_mono [THEN order_trans], assumption)
   479 apply (erule scaleR_left_mono, assumption)
   480 done
   481 
   482 lemma scaleR_mono':
   483   "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> c \<Longrightarrow> a *\<^sub>R c \<le> b *\<^sub>R d"
   484   by (rule scaleR_mono) (auto intro: order.trans)
   485 
   486 lemma pos_le_divideRI:
   487   assumes "0 < c"
   488   assumes "c *\<^sub>R a \<le> b"
   489   shows "a \<le> b /\<^sub>R c"
   490 proof -
   491   from scaleR_left_mono[OF assms(2)] assms(1)
   492   have "c *\<^sub>R a /\<^sub>R c \<le> b /\<^sub>R c"
   493     by simp
   494   with assms show ?thesis
   495     by (simp add: scaleR_one scaleR_scaleR inverse_eq_divide)
   496 qed
   497 
   498 lemma pos_le_divideR_eq:
   499   assumes "0 < c"
   500   shows "a \<le> b /\<^sub>R c \<longleftrightarrow> c *\<^sub>R a \<le> b"
   501 proof rule
   502   assume "a \<le> b /\<^sub>R c"
   503   from scaleR_left_mono[OF this] assms
   504   have "c *\<^sub>R a \<le> c *\<^sub>R (b /\<^sub>R c)"
   505     by simp
   506   with assms show "c *\<^sub>R a \<le> b"
   507     by (simp add: scaleR_one scaleR_scaleR inverse_eq_divide)
   508 qed (rule pos_le_divideRI[OF assms])
   509 
   510 lemma scaleR_image_atLeastAtMost:
   511   "c > 0 \<Longrightarrow> scaleR c ` {x..y} = {c *\<^sub>R x..c *\<^sub>R y}"
   512   apply (auto intro!: scaleR_left_mono)
   513   apply (rule_tac x = "inverse c *\<^sub>R xa" in image_eqI)
   514   apply (simp_all add: pos_le_divideR_eq[symmetric] scaleR_scaleR scaleR_one)
   515   done
   516 
   517 end
   518 
   519 lemma scaleR_nonneg_nonneg: "0 \<le> a \<Longrightarrow> 0 \<le> (x::'a::ordered_real_vector) \<Longrightarrow> 0 \<le> a *\<^sub>R x"
   520   using scaleR_left_mono [of 0 x a]
   521   by simp
   522 
   523 lemma scaleR_nonneg_nonpos: "0 \<le> a \<Longrightarrow> (x::'a::ordered_real_vector) \<le> 0 \<Longrightarrow> a *\<^sub>R x \<le> 0"
   524   using scaleR_left_mono [of x 0 a] by simp
   525 
   526 lemma scaleR_nonpos_nonneg: "a \<le> 0 \<Longrightarrow> 0 \<le> (x::'a::ordered_real_vector) \<Longrightarrow> a *\<^sub>R x \<le> 0"
   527   using scaleR_right_mono [of a 0 x] by simp
   528 
   529 lemma split_scaleR_neg_le: "(0 \<le> a & x \<le> 0) | (a \<le> 0 & 0 \<le> x) \<Longrightarrow>
   530   a *\<^sub>R (x::'a::ordered_real_vector) \<le> 0"
   531   by (auto simp add: scaleR_nonneg_nonpos scaleR_nonpos_nonneg)
   532 
   533 lemma le_add_iff1:
   534   fixes c d e::"'a::ordered_real_vector"
   535   shows "a *\<^sub>R e + c \<le> b *\<^sub>R e + d \<longleftrightarrow> (a - b) *\<^sub>R e + c \<le> d"
   536   by (simp add: algebra_simps)
   537 
   538 lemma le_add_iff2:
   539   fixes c d e::"'a::ordered_real_vector"
   540   shows "a *\<^sub>R e + c \<le> b *\<^sub>R e + d \<longleftrightarrow> c \<le> (b - a) *\<^sub>R e + d"
   541   by (simp add: algebra_simps)
   542 
   543 lemma scaleR_left_mono_neg:
   544   fixes a b::"'a::ordered_real_vector"
   545   shows "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> c *\<^sub>R a \<le> c *\<^sub>R b"
   546   apply (drule scaleR_left_mono [of _ _ "- c"])
   547   apply simp_all
   548   done
   549 
   550 lemma scaleR_right_mono_neg:
   551   fixes c::"'a::ordered_real_vector"
   552   shows "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> a *\<^sub>R c \<le> b *\<^sub>R c"
   553   apply (drule scaleR_right_mono [of _ _ "- c"])
   554   apply simp_all
   555   done
   556 
   557 lemma scaleR_nonpos_nonpos: "a \<le> 0 \<Longrightarrow> (b::'a::ordered_real_vector) \<le> 0 \<Longrightarrow> 0 \<le> a *\<^sub>R b"
   558 using scaleR_right_mono_neg [of a 0 b] by simp
   559 
   560 lemma split_scaleR_pos_le:
   561   fixes b::"'a::ordered_real_vector"
   562   shows "(0 \<le> a \<and> 0 \<le> b) \<or> (a \<le> 0 \<and> b \<le> 0) \<Longrightarrow> 0 \<le> a *\<^sub>R b"
   563   by (auto simp add: scaleR_nonneg_nonneg scaleR_nonpos_nonpos)
   564 
   565 lemma zero_le_scaleR_iff:
   566   fixes b::"'a::ordered_real_vector"
   567   shows "0 \<le> a *\<^sub>R b \<longleftrightarrow> 0 < a \<and> 0 \<le> b \<or> a < 0 \<and> b \<le> 0 \<or> a = 0" (is "?lhs = ?rhs")
   568 proof cases
   569   assume "a \<noteq> 0"
   570   show ?thesis
   571   proof
   572     assume lhs: ?lhs
   573     {
   574       assume "0 < a"
   575       with lhs have "inverse a *\<^sub>R 0 \<le> inverse a *\<^sub>R (a *\<^sub>R b)"
   576         by (intro scaleR_mono) auto
   577       hence ?rhs using `0 < a`
   578         by simp
   579     } moreover {
   580       assume "0 > a"
   581       with lhs have "- inverse a *\<^sub>R 0 \<le> - inverse a *\<^sub>R (a *\<^sub>R b)"
   582         by (intro scaleR_mono) auto
   583       hence ?rhs using `0 > a`
   584         by simp
   585     } ultimately show ?rhs using `a \<noteq> 0` by arith
   586   qed (auto simp: not_le `a \<noteq> 0` intro!: split_scaleR_pos_le)
   587 qed simp
   588 
   589 lemma scaleR_le_0_iff:
   590   fixes b::"'a::ordered_real_vector"
   591   shows "a *\<^sub>R b \<le> 0 \<longleftrightarrow> 0 < a \<and> b \<le> 0 \<or> a < 0 \<and> 0 \<le> b \<or> a = 0"
   592   by (insert zero_le_scaleR_iff [of "-a" b]) force
   593 
   594 lemma scaleR_le_cancel_left:
   595   fixes b::"'a::ordered_real_vector"
   596   shows "c *\<^sub>R a \<le> c *\<^sub>R b \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
   597   by (auto simp add: neq_iff scaleR_left_mono scaleR_left_mono_neg
   598     dest: scaleR_left_mono[where a="inverse c"] scaleR_left_mono_neg[where c="inverse c"])
   599 
   600 lemma scaleR_le_cancel_left_pos:
   601   fixes b::"'a::ordered_real_vector"
   602   shows "0 < c \<Longrightarrow> c *\<^sub>R a \<le> c *\<^sub>R b \<longleftrightarrow> a \<le> b"
   603   by (auto simp: scaleR_le_cancel_left)
   604 
   605 lemma scaleR_le_cancel_left_neg:
   606   fixes b::"'a::ordered_real_vector"
   607   shows "c < 0 \<Longrightarrow> c *\<^sub>R a \<le> c *\<^sub>R b \<longleftrightarrow> b \<le> a"
   608   by (auto simp: scaleR_le_cancel_left)
   609 
   610 lemma scaleR_left_le_one_le:
   611   fixes x::"'a::ordered_real_vector" and a::real
   612   shows "0 \<le> x \<Longrightarrow> a \<le> 1 \<Longrightarrow> a *\<^sub>R x \<le> x"
   613   using scaleR_right_mono[of a 1 x] by simp
   614 
   615 
   616 subsection {* Real normed vector spaces *}
   617 
   618 class dist =
   619   fixes dist :: "'a \<Rightarrow> 'a \<Rightarrow> real"
   620 
   621 class norm =
   622   fixes norm :: "'a \<Rightarrow> real"
   623 
   624 class sgn_div_norm = scaleR + norm + sgn +
   625   assumes sgn_div_norm: "sgn x = x /\<^sub>R norm x"
   626 
   627 class dist_norm = dist + norm + minus +
   628   assumes dist_norm: "dist x y = norm (x - y)"
   629 
   630 class open_dist = "open" + dist +
   631   assumes open_dist: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   632 
   633 class real_normed_vector = real_vector + sgn_div_norm + dist_norm + open_dist +
   634   assumes norm_eq_zero [simp]: "norm x = 0 \<longleftrightarrow> x = 0"
   635   and norm_triangle_ineq: "norm (x + y) \<le> norm x + norm y"
   636   and norm_scaleR [simp]: "norm (scaleR a x) = \<bar>a\<bar> * norm x"
   637 begin
   638 
   639 lemma norm_ge_zero [simp]: "0 \<le> norm x"
   640 proof -
   641   have "0 = norm (x + -1 *\<^sub>R x)" 
   642     using scaleR_add_left[of 1 "-1" x] norm_scaleR[of 0 x] by (simp add: scaleR_one)
   643   also have "\<dots> \<le> norm x + norm (-1 *\<^sub>R x)" by (rule norm_triangle_ineq)
   644   finally show ?thesis by simp
   645 qed
   646 
   647 end
   648 
   649 class real_normed_algebra = real_algebra + real_normed_vector +
   650   assumes norm_mult_ineq: "norm (x * y) \<le> norm x * norm y"
   651 
   652 class real_normed_algebra_1 = real_algebra_1 + real_normed_algebra +
   653   assumes norm_one [simp]: "norm 1 = 1"
   654 
   655 class real_normed_div_algebra = real_div_algebra + real_normed_vector +
   656   assumes norm_mult: "norm (x * y) = norm x * norm y"
   657 
   658 class real_normed_field = real_field + real_normed_div_algebra
   659 
   660 instance real_normed_div_algebra < real_normed_algebra_1
   661 proof
   662   fix x y :: 'a
   663   show "norm (x * y) \<le> norm x * norm y"
   664     by (simp add: norm_mult)
   665 next
   666   have "norm (1 * 1::'a) = norm (1::'a) * norm (1::'a)"
   667     by (rule norm_mult)
   668   thus "norm (1::'a) = 1" by simp
   669 qed
   670 
   671 lemma norm_zero [simp]: "norm (0::'a::real_normed_vector) = 0"
   672 by simp
   673 
   674 lemma zero_less_norm_iff [simp]:
   675   fixes x :: "'a::real_normed_vector"
   676   shows "(0 < norm x) = (x \<noteq> 0)"
   677 by (simp add: order_less_le)
   678 
   679 lemma norm_not_less_zero [simp]:
   680   fixes x :: "'a::real_normed_vector"
   681   shows "\<not> norm x < 0"
   682 by (simp add: linorder_not_less)
   683 
   684 lemma norm_le_zero_iff [simp]:
   685   fixes x :: "'a::real_normed_vector"
   686   shows "(norm x \<le> 0) = (x = 0)"
   687 by (simp add: order_le_less)
   688 
   689 lemma norm_minus_cancel [simp]:
   690   fixes x :: "'a::real_normed_vector"
   691   shows "norm (- x) = norm x"
   692 proof -
   693   have "norm (- x) = norm (scaleR (- 1) x)"
   694     by (simp only: scaleR_minus_left scaleR_one)
   695   also have "\<dots> = \<bar>- 1\<bar> * norm x"
   696     by (rule norm_scaleR)
   697   finally show ?thesis by simp
   698 qed
   699 
   700 lemma norm_minus_commute:
   701   fixes a b :: "'a::real_normed_vector"
   702   shows "norm (a - b) = norm (b - a)"
   703 proof -
   704   have "norm (- (b - a)) = norm (b - a)"
   705     by (rule norm_minus_cancel)
   706   thus ?thesis by simp
   707 qed
   708 
   709 lemma norm_triangle_ineq2:
   710   fixes a b :: "'a::real_normed_vector"
   711   shows "norm a - norm b \<le> norm (a - b)"
   712 proof -
   713   have "norm (a - b + b) \<le> norm (a - b) + norm b"
   714     by (rule norm_triangle_ineq)
   715   thus ?thesis by simp
   716 qed
   717 
   718 lemma norm_triangle_ineq3:
   719   fixes a b :: "'a::real_normed_vector"
   720   shows "\<bar>norm a - norm b\<bar> \<le> norm (a - b)"
   721 apply (subst abs_le_iff)
   722 apply auto
   723 apply (rule norm_triangle_ineq2)
   724 apply (subst norm_minus_commute)
   725 apply (rule norm_triangle_ineq2)
   726 done
   727 
   728 lemma norm_triangle_ineq4:
   729   fixes a b :: "'a::real_normed_vector"
   730   shows "norm (a - b) \<le> norm a + norm b"
   731 proof -
   732   have "norm (a + - b) \<le> norm a + norm (- b)"
   733     by (rule norm_triangle_ineq)
   734   then show ?thesis by simp
   735 qed
   736 
   737 lemma norm_diff_ineq:
   738   fixes a b :: "'a::real_normed_vector"
   739   shows "norm a - norm b \<le> norm (a + b)"
   740 proof -
   741   have "norm a - norm (- b) \<le> norm (a - - b)"
   742     by (rule norm_triangle_ineq2)
   743   thus ?thesis by simp
   744 qed
   745 
   746 lemma norm_diff_triangle_ineq:
   747   fixes a b c d :: "'a::real_normed_vector"
   748   shows "norm ((a + b) - (c + d)) \<le> norm (a - c) + norm (b - d)"
   749 proof -
   750   have "norm ((a + b) - (c + d)) = norm ((a - c) + (b - d))"
   751     by (simp add: algebra_simps)
   752   also have "\<dots> \<le> norm (a - c) + norm (b - d)"
   753     by (rule norm_triangle_ineq)
   754   finally show ?thesis .
   755 qed
   756 
   757 lemma norm_triangle_mono: 
   758   fixes a b :: "'a::real_normed_vector"
   759   shows "\<lbrakk>norm a \<le> r; norm b \<le> s\<rbrakk> \<Longrightarrow> norm (a + b) \<le> r + s"
   760 by (metis add_mono_thms_linordered_semiring(1) norm_triangle_ineq order.trans)
   761 
   762 lemma norm_setsum:
   763   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
   764   shows "norm (setsum f A) \<le> (\<Sum>i\<in>A. norm (f i))"
   765   by (induct A rule: infinite_finite_induct) (auto intro: norm_triangle_mono)
   766 
   767 lemma setsum_norm_le:
   768   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
   769   assumes fg: "\<forall>x \<in> S. norm (f x) \<le> g x"
   770   shows "norm (setsum f S) \<le> setsum g S"
   771   by (rule order_trans [OF norm_setsum setsum_mono]) (simp add: fg)
   772 
   773 lemma abs_norm_cancel [simp]:
   774   fixes a :: "'a::real_normed_vector"
   775   shows "\<bar>norm a\<bar> = norm a"
   776 by (rule abs_of_nonneg [OF norm_ge_zero])
   777 
   778 lemma norm_add_less:
   779   fixes x y :: "'a::real_normed_vector"
   780   shows "\<lbrakk>norm x < r; norm y < s\<rbrakk> \<Longrightarrow> norm (x + y) < r + s"
   781 by (rule order_le_less_trans [OF norm_triangle_ineq add_strict_mono])
   782 
   783 lemma norm_mult_less:
   784   fixes x y :: "'a::real_normed_algebra"
   785   shows "\<lbrakk>norm x < r; norm y < s\<rbrakk> \<Longrightarrow> norm (x * y) < r * s"
   786 apply (rule order_le_less_trans [OF norm_mult_ineq])
   787 apply (simp add: mult_strict_mono')
   788 done
   789 
   790 lemma norm_of_real [simp]:
   791   "norm (of_real r :: 'a::real_normed_algebra_1) = \<bar>r\<bar>"
   792 unfolding of_real_def by simp
   793 
   794 lemma norm_numeral [simp]:
   795   "norm (numeral w::'a::real_normed_algebra_1) = numeral w"
   796 by (subst of_real_numeral [symmetric], subst norm_of_real, simp)
   797 
   798 lemma norm_neg_numeral [simp]:
   799   "norm (- numeral w::'a::real_normed_algebra_1) = numeral w"
   800 by (subst of_real_neg_numeral [symmetric], subst norm_of_real, simp)
   801 
   802 lemma norm_of_int [simp]:
   803   "norm (of_int z::'a::real_normed_algebra_1) = \<bar>of_int z\<bar>"
   804 by (subst of_real_of_int_eq [symmetric], rule norm_of_real)
   805 
   806 lemma norm_of_nat [simp]:
   807   "norm (of_nat n::'a::real_normed_algebra_1) = of_nat n"
   808 apply (subst of_real_of_nat_eq [symmetric])
   809 apply (subst norm_of_real, simp)
   810 done
   811 
   812 lemma nonzero_norm_inverse:
   813   fixes a :: "'a::real_normed_div_algebra"
   814   shows "a \<noteq> 0 \<Longrightarrow> norm (inverse a) = inverse (norm a)"
   815 apply (rule inverse_unique [symmetric])
   816 apply (simp add: norm_mult [symmetric])
   817 done
   818 
   819 lemma norm_inverse:
   820   fixes a :: "'a::{real_normed_div_algebra, division_ring_inverse_zero}"
   821   shows "norm (inverse a) = inverse (norm a)"
   822 apply (case_tac "a = 0", simp)
   823 apply (erule nonzero_norm_inverse)
   824 done
   825 
   826 lemma nonzero_norm_divide:
   827   fixes a b :: "'a::real_normed_field"
   828   shows "b \<noteq> 0 \<Longrightarrow> norm (a / b) = norm a / norm b"
   829 by (simp add: divide_inverse norm_mult nonzero_norm_inverse)
   830 
   831 lemma norm_divide:
   832   fixes a b :: "'a::{real_normed_field, field_inverse_zero}"
   833   shows "norm (a / b) = norm a / norm b"
   834 by (simp add: divide_inverse norm_mult norm_inverse)
   835 
   836 lemma norm_power_ineq:
   837   fixes x :: "'a::{real_normed_algebra_1}"
   838   shows "norm (x ^ n) \<le> norm x ^ n"
   839 proof (induct n)
   840   case 0 show "norm (x ^ 0) \<le> norm x ^ 0" by simp
   841 next
   842   case (Suc n)
   843   have "norm (x * x ^ n) \<le> norm x * norm (x ^ n)"
   844     by (rule norm_mult_ineq)
   845   also from Suc have "\<dots> \<le> norm x * norm x ^ n"
   846     using norm_ge_zero by (rule mult_left_mono)
   847   finally show "norm (x ^ Suc n) \<le> norm x ^ Suc n"
   848     by simp
   849 qed
   850 
   851 lemma norm_power:
   852   fixes x :: "'a::{real_normed_div_algebra}"
   853   shows "norm (x ^ n) = norm x ^ n"
   854 by (induct n) (simp_all add: norm_mult)
   855 
   856 lemma setprod_norm:
   857   fixes f :: "'a \<Rightarrow> 'b::{comm_semiring_1,real_normed_div_algebra}"
   858   shows "setprod (\<lambda>x. norm(f x)) A = norm (setprod f A)"
   859 proof (cases "finite A")
   860   case True then show ?thesis 
   861     by (induct A rule: finite_induct) (auto simp: norm_mult)
   862 next
   863   case False then show ?thesis
   864     by (metis norm_one setprod.infinite) 
   865 qed
   866 
   867 
   868 subsection {* Metric spaces *}
   869 
   870 class metric_space = open_dist +
   871   assumes dist_eq_0_iff [simp]: "dist x y = 0 \<longleftrightarrow> x = y"
   872   assumes dist_triangle2: "dist x y \<le> dist x z + dist y z"
   873 begin
   874 
   875 lemma dist_self [simp]: "dist x x = 0"
   876 by simp
   877 
   878 lemma zero_le_dist [simp]: "0 \<le> dist x y"
   879 using dist_triangle2 [of x x y] by simp
   880 
   881 lemma zero_less_dist_iff: "0 < dist x y \<longleftrightarrow> x \<noteq> y"
   882 by (simp add: less_le)
   883 
   884 lemma dist_not_less_zero [simp]: "\<not> dist x y < 0"
   885 by (simp add: not_less)
   886 
   887 lemma dist_le_zero_iff [simp]: "dist x y \<le> 0 \<longleftrightarrow> x = y"
   888 by (simp add: le_less)
   889 
   890 lemma dist_commute: "dist x y = dist y x"
   891 proof (rule order_antisym)
   892   show "dist x y \<le> dist y x"
   893     using dist_triangle2 [of x y x] by simp
   894   show "dist y x \<le> dist x y"
   895     using dist_triangle2 [of y x y] by simp
   896 qed
   897 
   898 lemma dist_triangle: "dist x z \<le> dist x y + dist y z"
   899 using dist_triangle2 [of x z y] by (simp add: dist_commute)
   900 
   901 lemma dist_triangle3: "dist x y \<le> dist a x + dist a y"
   902 using dist_triangle2 [of x y a] by (simp add: dist_commute)
   903 
   904 lemma dist_triangle_alt:
   905   shows "dist y z <= dist x y + dist x z"
   906 by (rule dist_triangle3)
   907 
   908 lemma dist_pos_lt:
   909   shows "x \<noteq> y ==> 0 < dist x y"
   910 by (simp add: zero_less_dist_iff)
   911 
   912 lemma dist_nz:
   913   shows "x \<noteq> y \<longleftrightarrow> 0 < dist x y"
   914 by (simp add: zero_less_dist_iff)
   915 
   916 lemma dist_triangle_le:
   917   shows "dist x z + dist y z <= e \<Longrightarrow> dist x y <= e"
   918 by (rule order_trans [OF dist_triangle2])
   919 
   920 lemma dist_triangle_lt:
   921   shows "dist x z + dist y z < e ==> dist x y < e"
   922 by (rule le_less_trans [OF dist_triangle2])
   923 
   924 lemma dist_triangle_half_l:
   925   shows "dist x1 y < e / 2 \<Longrightarrow> dist x2 y < e / 2 \<Longrightarrow> dist x1 x2 < e"
   926 by (rule dist_triangle_lt [where z=y], simp)
   927 
   928 lemma dist_triangle_half_r:
   929   shows "dist y x1 < e / 2 \<Longrightarrow> dist y x2 < e / 2 \<Longrightarrow> dist x1 x2 < e"
   930 by (rule dist_triangle_half_l, simp_all add: dist_commute)
   931 
   932 subclass topological_space
   933 proof
   934   have "\<exists>e::real. 0 < e"
   935     by (fast intro: zero_less_one)
   936   then show "open UNIV"
   937     unfolding open_dist by simp
   938 next
   939   fix S T assume "open S" "open T"
   940   then show "open (S \<inter> T)"
   941     unfolding open_dist
   942     apply clarify
   943     apply (drule (1) bspec)+
   944     apply (clarify, rename_tac r s)
   945     apply (rule_tac x="min r s" in exI, simp)
   946     done
   947 next
   948   fix K assume "\<forall>S\<in>K. open S" thus "open (\<Union>K)"
   949     unfolding open_dist by fast
   950 qed
   951 
   952 lemma open_ball: "open {y. dist x y < d}"
   953 proof (unfold open_dist, intro ballI)
   954   fix y assume *: "y \<in> {y. dist x y < d}"
   955   then show "\<exists>e>0. \<forall>z. dist z y < e \<longrightarrow> z \<in> {y. dist x y < d}"
   956     by (auto intro!: exI[of _ "d - dist x y"] simp: field_simps dist_triangle_lt)
   957 qed
   958 
   959 subclass first_countable_topology
   960 proof
   961   fix x 
   962   show "\<exists>A::nat \<Rightarrow> 'a set. (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
   963   proof (safe intro!: exI[of _ "\<lambda>n. {y. dist x y < inverse (Suc n)}"])
   964     fix S assume "open S" "x \<in> S"
   965     then obtain e where e: "0 < e" and "{y. dist x y < e} \<subseteq> S"
   966       by (auto simp: open_dist subset_eq dist_commute)
   967     moreover
   968     from e obtain i where "inverse (Suc i) < e"
   969       by (auto dest!: reals_Archimedean)
   970     then have "{y. dist x y < inverse (Suc i)} \<subseteq> {y. dist x y < e}"
   971       by auto
   972     ultimately show "\<exists>i. {y. dist x y < inverse (Suc i)} \<subseteq> S"
   973       by blast
   974   qed (auto intro: open_ball)
   975 qed
   976 
   977 end
   978 
   979 instance metric_space \<subseteq> t2_space
   980 proof
   981   fix x y :: "'a::metric_space"
   982   assume xy: "x \<noteq> y"
   983   let ?U = "{y'. dist x y' < dist x y / 2}"
   984   let ?V = "{x'. dist y x' < dist x y / 2}"
   985   have th0: "\<And>d x y z. (d x z :: real) \<le> d x y + d y z \<Longrightarrow> d y z = d z y
   986                \<Longrightarrow> \<not>(d x y * 2 < d x z \<and> d z y * 2 < d x z)" by arith
   987   have "open ?U \<and> open ?V \<and> x \<in> ?U \<and> y \<in> ?V \<and> ?U \<inter> ?V = {}"
   988     using dist_pos_lt[OF xy] th0[of dist, OF dist_triangle dist_commute]
   989     using open_ball[of _ "dist x y / 2"] by auto
   990   then show "\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   991     by blast
   992 qed
   993 
   994 text {* Every normed vector space is a metric space. *}
   995 
   996 instance real_normed_vector < metric_space
   997 proof
   998   fix x y :: 'a show "dist x y = 0 \<longleftrightarrow> x = y"
   999     unfolding dist_norm by simp
  1000 next
  1001   fix x y z :: 'a show "dist x y \<le> dist x z + dist y z"
  1002     unfolding dist_norm
  1003     using norm_triangle_ineq4 [of "x - z" "y - z"] by simp
  1004 qed
  1005 
  1006 subsection {* Class instances for real numbers *}
  1007 
  1008 instantiation real :: real_normed_field
  1009 begin
  1010 
  1011 definition dist_real_def:
  1012   "dist x y = \<bar>x - y\<bar>"
  1013 
  1014 definition open_real_def [code del]:
  1015   "open (S :: real set) \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
  1016 
  1017 definition real_norm_def [simp]:
  1018   "norm r = \<bar>r\<bar>"
  1019 
  1020 instance
  1021 apply (intro_classes, unfold real_norm_def real_scaleR_def)
  1022 apply (rule dist_real_def)
  1023 apply (rule open_real_def)
  1024 apply (simp add: sgn_real_def)
  1025 apply (rule abs_eq_0)
  1026 apply (rule abs_triangle_ineq)
  1027 apply (rule abs_mult)
  1028 apply (rule abs_mult)
  1029 done
  1030 
  1031 end
  1032 
  1033 declare [[code abort: "open :: real set \<Rightarrow> bool"]]
  1034 
  1035 instance real :: linorder_topology
  1036 proof
  1037   show "(open :: real set \<Rightarrow> bool) = generate_topology (range lessThan \<union> range greaterThan)"
  1038   proof (rule ext, safe)
  1039     fix S :: "real set" assume "open S"
  1040     then obtain f where "\<forall>x\<in>S. 0 < f x \<and> (\<forall>y. dist y x < f x \<longrightarrow> y \<in> S)"
  1041       unfolding open_real_def bchoice_iff ..
  1042     then have *: "S = (\<Union>x\<in>S. {x - f x <..} \<inter> {..< x + f x})"
  1043       by (fastforce simp: dist_real_def)
  1044     show "generate_topology (range lessThan \<union> range greaterThan) S"
  1045       apply (subst *)
  1046       apply (intro generate_topology_Union generate_topology.Int)
  1047       apply (auto intro: generate_topology.Basis)
  1048       done
  1049   next
  1050     fix S :: "real set" assume "generate_topology (range lessThan \<union> range greaterThan) S"
  1051     moreover have "\<And>a::real. open {..<a}"
  1052       unfolding open_real_def dist_real_def
  1053     proof clarify
  1054       fix x a :: real assume "x < a"
  1055       hence "0 < a - x \<and> (\<forall>y. \<bar>y - x\<bar> < a - x \<longrightarrow> y \<in> {..<a})" by auto
  1056       thus "\<exists>e>0. \<forall>y. \<bar>y - x\<bar> < e \<longrightarrow> y \<in> {..<a}" ..
  1057     qed
  1058     moreover have "\<And>a::real. open {a <..}"
  1059       unfolding open_real_def dist_real_def
  1060     proof clarify
  1061       fix x a :: real assume "a < x"
  1062       hence "0 < x - a \<and> (\<forall>y. \<bar>y - x\<bar> < x - a \<longrightarrow> y \<in> {a<..})" by auto
  1063       thus "\<exists>e>0. \<forall>y. \<bar>y - x\<bar> < e \<longrightarrow> y \<in> {a<..}" ..
  1064     qed
  1065     ultimately show "open S"
  1066       by induct auto
  1067   qed
  1068 qed
  1069 
  1070 instance real :: linear_continuum_topology ..
  1071 
  1072 lemmas open_real_greaterThan = open_greaterThan[where 'a=real]
  1073 lemmas open_real_lessThan = open_lessThan[where 'a=real]
  1074 lemmas open_real_greaterThanLessThan = open_greaterThanLessThan[where 'a=real]
  1075 lemmas closed_real_atMost = closed_atMost[where 'a=real]
  1076 lemmas closed_real_atLeast = closed_atLeast[where 'a=real]
  1077 lemmas closed_real_atLeastAtMost = closed_atLeastAtMost[where 'a=real]
  1078 
  1079 subsection {* Extra type constraints *}
  1080 
  1081 text {* Only allow @{term "open"} in class @{text topological_space}. *}
  1082 
  1083 setup {* Sign.add_const_constraint
  1084   (@{const_name "open"}, SOME @{typ "'a::topological_space set \<Rightarrow> bool"}) *}
  1085 
  1086 text {* Only allow @{term dist} in class @{text metric_space}. *}
  1087 
  1088 setup {* Sign.add_const_constraint
  1089   (@{const_name dist}, SOME @{typ "'a::metric_space \<Rightarrow> 'a \<Rightarrow> real"}) *}
  1090 
  1091 text {* Only allow @{term norm} in class @{text real_normed_vector}. *}
  1092 
  1093 setup {* Sign.add_const_constraint
  1094   (@{const_name norm}, SOME @{typ "'a::real_normed_vector \<Rightarrow> real"}) *}
  1095 
  1096 subsection {* Sign function *}
  1097 
  1098 lemma norm_sgn:
  1099   "norm (sgn(x::'a::real_normed_vector)) = (if x = 0 then 0 else 1)"
  1100 by (simp add: sgn_div_norm)
  1101 
  1102 lemma sgn_zero [simp]: "sgn(0::'a::real_normed_vector) = 0"
  1103 by (simp add: sgn_div_norm)
  1104 
  1105 lemma sgn_zero_iff: "(sgn(x::'a::real_normed_vector) = 0) = (x = 0)"
  1106 by (simp add: sgn_div_norm)
  1107 
  1108 lemma sgn_minus: "sgn (- x) = - sgn(x::'a::real_normed_vector)"
  1109 by (simp add: sgn_div_norm)
  1110 
  1111 lemma sgn_scaleR:
  1112   "sgn (scaleR r x) = scaleR (sgn r) (sgn(x::'a::real_normed_vector))"
  1113 by (simp add: sgn_div_norm mult_ac)
  1114 
  1115 lemma sgn_one [simp]: "sgn (1::'a::real_normed_algebra_1) = 1"
  1116 by (simp add: sgn_div_norm)
  1117 
  1118 lemma sgn_of_real:
  1119   "sgn (of_real r::'a::real_normed_algebra_1) = of_real (sgn r)"
  1120 unfolding of_real_def by (simp only: sgn_scaleR sgn_one)
  1121 
  1122 lemma sgn_mult:
  1123   fixes x y :: "'a::real_normed_div_algebra"
  1124   shows "sgn (x * y) = sgn x * sgn y"
  1125 by (simp add: sgn_div_norm norm_mult mult_commute)
  1126 
  1127 lemma real_sgn_eq: "sgn (x::real) = x / \<bar>x\<bar>"
  1128 by (simp add: sgn_div_norm divide_inverse)
  1129 
  1130 lemma real_sgn_pos: "0 < (x::real) \<Longrightarrow> sgn x = 1"
  1131 unfolding real_sgn_eq by simp
  1132 
  1133 lemma real_sgn_neg: "(x::real) < 0 \<Longrightarrow> sgn x = -1"
  1134 unfolding real_sgn_eq by simp
  1135 
  1136 lemma zero_le_sgn_iff [simp]: "0 \<le> sgn x \<longleftrightarrow> 0 \<le> (x::real)"
  1137   by (cases "0::real" x rule: linorder_cases) simp_all
  1138   
  1139 lemma zero_less_sgn_iff [simp]: "0 < sgn x \<longleftrightarrow> 0 < (x::real)"
  1140   by (cases "0::real" x rule: linorder_cases) simp_all
  1141 
  1142 lemma sgn_le_0_iff [simp]: "sgn x \<le> 0 \<longleftrightarrow> (x::real) \<le> 0"
  1143   by (cases "0::real" x rule: linorder_cases) simp_all
  1144   
  1145 lemma sgn_less_0_iff [simp]: "sgn x < 0 \<longleftrightarrow> (x::real) < 0"
  1146   by (cases "0::real" x rule: linorder_cases) simp_all
  1147 
  1148 lemma norm_conv_dist: "norm x = dist x 0"
  1149   unfolding dist_norm by simp
  1150 
  1151 subsection {* Bounded Linear and Bilinear Operators *}
  1152 
  1153 locale linear = additive f for f :: "'a::real_vector \<Rightarrow> 'b::real_vector" +
  1154   assumes scaleR: "f (scaleR r x) = scaleR r (f x)"
  1155 
  1156 lemma linearI:
  1157   assumes "\<And>x y. f (x + y) = f x + f y"
  1158   assumes "\<And>c x. f (c *\<^sub>R x) = c *\<^sub>R f x"
  1159   shows "linear f"
  1160   by default (rule assms)+
  1161 
  1162 locale bounded_linear = linear f for f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_vector" +
  1163   assumes bounded: "\<exists>K. \<forall>x. norm (f x) \<le> norm x * K"
  1164 begin
  1165 
  1166 lemma pos_bounded:
  1167   "\<exists>K>0. \<forall>x. norm (f x) \<le> norm x * K"
  1168 proof -
  1169   obtain K where K: "\<And>x. norm (f x) \<le> norm x * K"
  1170     using bounded by fast
  1171   show ?thesis
  1172   proof (intro exI impI conjI allI)
  1173     show "0 < max 1 K"
  1174       by (rule order_less_le_trans [OF zero_less_one max.cobounded1])
  1175   next
  1176     fix x
  1177     have "norm (f x) \<le> norm x * K" using K .
  1178     also have "\<dots> \<le> norm x * max 1 K"
  1179       by (rule mult_left_mono [OF max.cobounded2 norm_ge_zero])
  1180     finally show "norm (f x) \<le> norm x * max 1 K" .
  1181   qed
  1182 qed
  1183 
  1184 lemma nonneg_bounded:
  1185   "\<exists>K\<ge>0. \<forall>x. norm (f x) \<le> norm x * K"
  1186 proof -
  1187   from pos_bounded
  1188   show ?thesis by (auto intro: order_less_imp_le)
  1189 qed
  1190 
  1191 lemma linear: "linear f" ..
  1192 
  1193 end
  1194 
  1195 lemma bounded_linear_intro:
  1196   assumes "\<And>x y. f (x + y) = f x + f y"
  1197   assumes "\<And>r x. f (scaleR r x) = scaleR r (f x)"
  1198   assumes "\<And>x. norm (f x) \<le> norm x * K"
  1199   shows "bounded_linear f"
  1200   by default (fast intro: assms)+
  1201 
  1202 locale bounded_bilinear =
  1203   fixes prod :: "['a::real_normed_vector, 'b::real_normed_vector]
  1204                  \<Rightarrow> 'c::real_normed_vector"
  1205     (infixl "**" 70)
  1206   assumes add_left: "prod (a + a') b = prod a b + prod a' b"
  1207   assumes add_right: "prod a (b + b') = prod a b + prod a b'"
  1208   assumes scaleR_left: "prod (scaleR r a) b = scaleR r (prod a b)"
  1209   assumes scaleR_right: "prod a (scaleR r b) = scaleR r (prod a b)"
  1210   assumes bounded: "\<exists>K. \<forall>a b. norm (prod a b) \<le> norm a * norm b * K"
  1211 begin
  1212 
  1213 lemma pos_bounded:
  1214   "\<exists>K>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
  1215 apply (cut_tac bounded, erule exE)
  1216 apply (rule_tac x="max 1 K" in exI, safe)
  1217 apply (rule order_less_le_trans [OF zero_less_one max.cobounded1])
  1218 apply (drule spec, drule spec, erule order_trans)
  1219 apply (rule mult_left_mono [OF max.cobounded2])
  1220 apply (intro mult_nonneg_nonneg norm_ge_zero)
  1221 done
  1222 
  1223 lemma nonneg_bounded:
  1224   "\<exists>K\<ge>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
  1225 proof -
  1226   from pos_bounded
  1227   show ?thesis by (auto intro: order_less_imp_le)
  1228 qed
  1229 
  1230 lemma additive_right: "additive (\<lambda>b. prod a b)"
  1231 by (rule additive.intro, rule add_right)
  1232 
  1233 lemma additive_left: "additive (\<lambda>a. prod a b)"
  1234 by (rule additive.intro, rule add_left)
  1235 
  1236 lemma zero_left: "prod 0 b = 0"
  1237 by (rule additive.zero [OF additive_left])
  1238 
  1239 lemma zero_right: "prod a 0 = 0"
  1240 by (rule additive.zero [OF additive_right])
  1241 
  1242 lemma minus_left: "prod (- a) b = - prod a b"
  1243 by (rule additive.minus [OF additive_left])
  1244 
  1245 lemma minus_right: "prod a (- b) = - prod a b"
  1246 by (rule additive.minus [OF additive_right])
  1247 
  1248 lemma diff_left:
  1249   "prod (a - a') b = prod a b - prod a' b"
  1250 by (rule additive.diff [OF additive_left])
  1251 
  1252 lemma diff_right:
  1253   "prod a (b - b') = prod a b - prod a b'"
  1254 by (rule additive.diff [OF additive_right])
  1255 
  1256 lemma bounded_linear_left:
  1257   "bounded_linear (\<lambda>a. a ** b)"
  1258 apply (cut_tac bounded, safe)
  1259 apply (rule_tac K="norm b * K" in bounded_linear_intro)
  1260 apply (rule add_left)
  1261 apply (rule scaleR_left)
  1262 apply (simp add: mult_ac)
  1263 done
  1264 
  1265 lemma bounded_linear_right:
  1266   "bounded_linear (\<lambda>b. a ** b)"
  1267 apply (cut_tac bounded, safe)
  1268 apply (rule_tac K="norm a * K" in bounded_linear_intro)
  1269 apply (rule add_right)
  1270 apply (rule scaleR_right)
  1271 apply (simp add: mult_ac)
  1272 done
  1273 
  1274 lemma prod_diff_prod:
  1275   "(x ** y - a ** b) = (x - a) ** (y - b) + (x - a) ** b + a ** (y - b)"
  1276 by (simp add: diff_left diff_right)
  1277 
  1278 end
  1279 
  1280 lemma bounded_linear_ident[simp]: "bounded_linear (\<lambda>x. x)"
  1281   by default (auto intro!: exI[of _ 1])
  1282 
  1283 lemma bounded_linear_zero[simp]: "bounded_linear (\<lambda>x. 0)"
  1284   by default (auto intro!: exI[of _ 1])
  1285 
  1286 lemma bounded_linear_add:
  1287   assumes "bounded_linear f"
  1288   assumes "bounded_linear g"
  1289   shows "bounded_linear (\<lambda>x. f x + g x)"
  1290 proof -
  1291   interpret f: bounded_linear f by fact
  1292   interpret g: bounded_linear g by fact
  1293   show ?thesis
  1294   proof
  1295     from f.bounded obtain Kf where Kf: "\<And>x. norm (f x) \<le> norm x * Kf" by blast
  1296     from g.bounded obtain Kg where Kg: "\<And>x. norm (g x) \<le> norm x * Kg" by blast
  1297     show "\<exists>K. \<forall>x. norm (f x + g x) \<le> norm x * K"
  1298       using add_mono[OF Kf Kg]
  1299       by (intro exI[of _ "Kf + Kg"]) (auto simp: field_simps intro: norm_triangle_ineq order_trans)
  1300   qed (simp_all add: f.add g.add f.scaleR g.scaleR scaleR_right_distrib)
  1301 qed
  1302 
  1303 lemma bounded_linear_minus:
  1304   assumes "bounded_linear f"
  1305   shows "bounded_linear (\<lambda>x. - f x)"
  1306 proof -
  1307   interpret f: bounded_linear f by fact
  1308   show ?thesis apply (unfold_locales)
  1309     apply (simp add: f.add)
  1310     apply (simp add: f.scaleR)
  1311     apply (simp add: f.bounded)
  1312     done
  1313 qed
  1314 
  1315 lemma bounded_linear_compose:
  1316   assumes "bounded_linear f"
  1317   assumes "bounded_linear g"
  1318   shows "bounded_linear (\<lambda>x. f (g x))"
  1319 proof -
  1320   interpret f: bounded_linear f by fact
  1321   interpret g: bounded_linear g by fact
  1322   show ?thesis proof (unfold_locales)
  1323     fix x y show "f (g (x + y)) = f (g x) + f (g y)"
  1324       by (simp only: f.add g.add)
  1325   next
  1326     fix r x show "f (g (scaleR r x)) = scaleR r (f (g x))"
  1327       by (simp only: f.scaleR g.scaleR)
  1328   next
  1329     from f.pos_bounded
  1330     obtain Kf where f: "\<And>x. norm (f x) \<le> norm x * Kf" and Kf: "0 < Kf" by fast
  1331     from g.pos_bounded
  1332     obtain Kg where g: "\<And>x. norm (g x) \<le> norm x * Kg" by fast
  1333     show "\<exists>K. \<forall>x. norm (f (g x)) \<le> norm x * K"
  1334     proof (intro exI allI)
  1335       fix x
  1336       have "norm (f (g x)) \<le> norm (g x) * Kf"
  1337         using f .
  1338       also have "\<dots> \<le> (norm x * Kg) * Kf"
  1339         using g Kf [THEN order_less_imp_le] by (rule mult_right_mono)
  1340       also have "(norm x * Kg) * Kf = norm x * (Kg * Kf)"
  1341         by (rule mult_assoc)
  1342       finally show "norm (f (g x)) \<le> norm x * (Kg * Kf)" .
  1343     qed
  1344   qed
  1345 qed
  1346 
  1347 lemma bounded_bilinear_mult:
  1348   "bounded_bilinear (op * :: 'a \<Rightarrow> 'a \<Rightarrow> 'a::real_normed_algebra)"
  1349 apply (rule bounded_bilinear.intro)
  1350 apply (rule distrib_right)
  1351 apply (rule distrib_left)
  1352 apply (rule mult_scaleR_left)
  1353 apply (rule mult_scaleR_right)
  1354 apply (rule_tac x="1" in exI)
  1355 apply (simp add: norm_mult_ineq)
  1356 done
  1357 
  1358 lemma bounded_linear_mult_left:
  1359   "bounded_linear (\<lambda>x::'a::real_normed_algebra. x * y)"
  1360   using bounded_bilinear_mult
  1361   by (rule bounded_bilinear.bounded_linear_left)
  1362 
  1363 lemma bounded_linear_mult_right:
  1364   "bounded_linear (\<lambda>y::'a::real_normed_algebra. x * y)"
  1365   using bounded_bilinear_mult
  1366   by (rule bounded_bilinear.bounded_linear_right)
  1367 
  1368 lemmas bounded_linear_mult_const =
  1369   bounded_linear_mult_left [THEN bounded_linear_compose]
  1370 
  1371 lemmas bounded_linear_const_mult =
  1372   bounded_linear_mult_right [THEN bounded_linear_compose]
  1373 
  1374 lemma bounded_linear_divide:
  1375   "bounded_linear (\<lambda>x::'a::real_normed_field. x / y)"
  1376   unfolding divide_inverse by (rule bounded_linear_mult_left)
  1377 
  1378 lemma bounded_bilinear_scaleR: "bounded_bilinear scaleR"
  1379 apply (rule bounded_bilinear.intro)
  1380 apply (rule scaleR_left_distrib)
  1381 apply (rule scaleR_right_distrib)
  1382 apply simp
  1383 apply (rule scaleR_left_commute)
  1384 apply (rule_tac x="1" in exI, simp)
  1385 done
  1386 
  1387 lemma bounded_linear_scaleR_left: "bounded_linear (\<lambda>r. scaleR r x)"
  1388   using bounded_bilinear_scaleR
  1389   by (rule bounded_bilinear.bounded_linear_left)
  1390 
  1391 lemma bounded_linear_scaleR_right: "bounded_linear (\<lambda>x. scaleR r x)"
  1392   using bounded_bilinear_scaleR
  1393   by (rule bounded_bilinear.bounded_linear_right)
  1394 
  1395 lemma bounded_linear_of_real: "bounded_linear (\<lambda>r. of_real r)"
  1396   unfolding of_real_def by (rule bounded_linear_scaleR_left)
  1397 
  1398 lemma real_bounded_linear:
  1399   fixes f :: "real \<Rightarrow> real"
  1400   shows "bounded_linear f \<longleftrightarrow> (\<exists>c::real. f = (\<lambda>x. x * c))"
  1401 proof -
  1402   { fix x assume "bounded_linear f"
  1403     then interpret bounded_linear f .
  1404     from scaleR[of x 1] have "f x = x * f 1"
  1405       by simp }
  1406   then show ?thesis
  1407     by (auto intro: exI[of _ "f 1"] bounded_linear_mult_left)
  1408 qed
  1409 
  1410 instance real_normed_algebra_1 \<subseteq> perfect_space
  1411 proof
  1412   fix x::'a
  1413   show "\<not> open {x}"
  1414     unfolding open_dist dist_norm
  1415     by (clarsimp, rule_tac x="x + of_real (e/2)" in exI, simp)
  1416 qed
  1417 
  1418 subsection {* Filters and Limits on Metric Space *}
  1419 
  1420 lemma eventually_nhds_metric:
  1421   fixes a :: "'a :: metric_space"
  1422   shows "eventually P (nhds a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. dist x a < d \<longrightarrow> P x)"
  1423 unfolding eventually_nhds open_dist
  1424 apply safe
  1425 apply fast
  1426 apply (rule_tac x="{x. dist x a < d}" in exI, simp)
  1427 apply clarsimp
  1428 apply (rule_tac x="d - dist x a" in exI, clarsimp)
  1429 apply (simp only: less_diff_eq)
  1430 apply (erule le_less_trans [OF dist_triangle])
  1431 done
  1432 
  1433 lemma eventually_at:
  1434   fixes a :: "'a :: metric_space"
  1435   shows "eventually P (at a within S) \<longleftrightarrow> (\<exists>d>0. \<forall>x\<in>S. x \<noteq> a \<and> dist x a < d \<longrightarrow> P x)"
  1436   unfolding eventually_at_filter eventually_nhds_metric by (auto simp: dist_nz)
  1437 
  1438 lemma eventually_at_le:
  1439   fixes a :: "'a::metric_space"
  1440   shows "eventually P (at a within S) \<longleftrightarrow> (\<exists>d>0. \<forall>x\<in>S. x \<noteq> a \<and> dist x a \<le> d \<longrightarrow> P x)"
  1441   unfolding eventually_at_filter eventually_nhds_metric
  1442   apply auto
  1443   apply (rule_tac x="d / 2" in exI)
  1444   apply auto
  1445   done
  1446 
  1447 lemma tendstoI:
  1448   fixes l :: "'a :: metric_space"
  1449   assumes "\<And>e. 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
  1450   shows "(f ---> l) F"
  1451   apply (rule topological_tendstoI)
  1452   apply (simp add: open_dist)
  1453   apply (drule (1) bspec, clarify)
  1454   apply (drule assms)
  1455   apply (erule eventually_elim1, simp)
  1456   done
  1457 
  1458 lemma tendstoD:
  1459   fixes l :: "'a :: metric_space"
  1460   shows "(f ---> l) F \<Longrightarrow> 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
  1461   apply (drule_tac S="{x. dist x l < e}" in topological_tendstoD)
  1462   apply (clarsimp simp add: open_dist)
  1463   apply (rule_tac x="e - dist x l" in exI, clarsimp)
  1464   apply (simp only: less_diff_eq)
  1465   apply (erule le_less_trans [OF dist_triangle])
  1466   apply simp
  1467   apply simp
  1468   done
  1469 
  1470 lemma tendsto_iff:
  1471   fixes l :: "'a :: metric_space"
  1472   shows "(f ---> l) F \<longleftrightarrow> (\<forall>e>0. eventually (\<lambda>x. dist (f x) l < e) F)"
  1473   using tendstoI tendstoD by fast
  1474 
  1475 lemma metric_tendsto_imp_tendsto:
  1476   fixes a :: "'a :: metric_space" and b :: "'b :: metric_space"
  1477   assumes f: "(f ---> a) F"
  1478   assumes le: "eventually (\<lambda>x. dist (g x) b \<le> dist (f x) a) F"
  1479   shows "(g ---> b) F"
  1480 proof (rule tendstoI)
  1481   fix e :: real assume "0 < e"
  1482   with f have "eventually (\<lambda>x. dist (f x) a < e) F" by (rule tendstoD)
  1483   with le show "eventually (\<lambda>x. dist (g x) b < e) F"
  1484     using le_less_trans by (rule eventually_elim2)
  1485 qed
  1486 
  1487 lemma filterlim_real_sequentially: "LIM x sequentially. real x :> at_top"
  1488   unfolding filterlim_at_top
  1489   apply (intro allI)
  1490   apply (rule_tac c="natceiling (Z + 1)" in eventually_sequentiallyI)
  1491   apply (auto simp: natceiling_le_eq)
  1492   done
  1493 
  1494 subsubsection {* Limits of Sequences *}
  1495 
  1496 lemma LIMSEQ_def: "X ----> (L::'a::metric_space) \<longleftrightarrow> (\<forall>r>0. \<exists>no. \<forall>n\<ge>no. dist (X n) L < r)"
  1497   unfolding tendsto_iff eventually_sequentially ..
  1498 
  1499 lemma LIMSEQ_iff_nz: "X ----> (L::'a::metric_space) = (\<forall>r>0. \<exists>no>0. \<forall>n\<ge>no. dist (X n) L < r)"
  1500   unfolding LIMSEQ_def by (metis Suc_leD zero_less_Suc)
  1501 
  1502 lemma metric_LIMSEQ_I:
  1503   "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r) \<Longrightarrow> X ----> (L::'a::metric_space)"
  1504 by (simp add: LIMSEQ_def)
  1505 
  1506 lemma metric_LIMSEQ_D:
  1507   "\<lbrakk>X ----> (L::'a::metric_space); 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r"
  1508 by (simp add: LIMSEQ_def)
  1509 
  1510 
  1511 subsubsection {* Limits of Functions *}
  1512 
  1513 lemma LIM_def: "f -- (a::'a::metric_space) --> (L::'b::metric_space) =
  1514      (\<forall>r > 0. \<exists>s > 0. \<forall>x. x \<noteq> a & dist x a < s
  1515         --> dist (f x) L < r)"
  1516   unfolding tendsto_iff eventually_at by simp
  1517 
  1518 lemma metric_LIM_I:
  1519   "(\<And>r. 0 < r \<Longrightarrow> \<exists>s>0. \<forall>x. x \<noteq> a \<and> dist x a < s \<longrightarrow> dist (f x) L < r)
  1520     \<Longrightarrow> f -- (a::'a::metric_space) --> (L::'b::metric_space)"
  1521 by (simp add: LIM_def)
  1522 
  1523 lemma metric_LIM_D:
  1524   "\<lbrakk>f -- (a::'a::metric_space) --> (L::'b::metric_space); 0 < r\<rbrakk>
  1525     \<Longrightarrow> \<exists>s>0. \<forall>x. x \<noteq> a \<and> dist x a < s \<longrightarrow> dist (f x) L < r"
  1526 by (simp add: LIM_def)
  1527 
  1528 lemma metric_LIM_imp_LIM:
  1529   assumes f: "f -- a --> (l::'a::metric_space)"
  1530   assumes le: "\<And>x. x \<noteq> a \<Longrightarrow> dist (g x) m \<le> dist (f x) l"
  1531   shows "g -- a --> (m::'b::metric_space)"
  1532   by (rule metric_tendsto_imp_tendsto [OF f]) (auto simp add: eventually_at_topological le)
  1533 
  1534 lemma metric_LIM_equal2:
  1535   assumes 1: "0 < R"
  1536   assumes 2: "\<And>x. \<lbrakk>x \<noteq> a; dist x a < R\<rbrakk> \<Longrightarrow> f x = g x"
  1537   shows "g -- a --> l \<Longrightarrow> f -- (a::'a::metric_space) --> l"
  1538 apply (rule topological_tendstoI)
  1539 apply (drule (2) topological_tendstoD)
  1540 apply (simp add: eventually_at, safe)
  1541 apply (rule_tac x="min d R" in exI, safe)
  1542 apply (simp add: 1)
  1543 apply (simp add: 2)
  1544 done
  1545 
  1546 lemma metric_LIM_compose2:
  1547   assumes f: "f -- (a::'a::metric_space) --> b"
  1548   assumes g: "g -- b --> c"
  1549   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> f x \<noteq> b"
  1550   shows "(\<lambda>x. g (f x)) -- a --> c"
  1551   using inj
  1552   by (intro tendsto_compose_eventually[OF g f]) (auto simp: eventually_at)
  1553 
  1554 lemma metric_isCont_LIM_compose2:
  1555   fixes f :: "'a :: metric_space \<Rightarrow> _"
  1556   assumes f [unfolded isCont_def]: "isCont f a"
  1557   assumes g: "g -- f a --> l"
  1558   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> f x \<noteq> f a"
  1559   shows "(\<lambda>x. g (f x)) -- a --> l"
  1560 by (rule metric_LIM_compose2 [OF f g inj])
  1561 
  1562 subsection {* Complete metric spaces *}
  1563 
  1564 subsection {* Cauchy sequences *}
  1565 
  1566 definition (in metric_space) Cauchy :: "(nat \<Rightarrow> 'a) \<Rightarrow> bool" where
  1567   "Cauchy X = (\<forall>e>0. \<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. dist (X m) (X n) < e)"
  1568 
  1569 subsection {* Cauchy Sequences *}
  1570 
  1571 lemma metric_CauchyI:
  1572   "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e) \<Longrightarrow> Cauchy X"
  1573   by (simp add: Cauchy_def)
  1574 
  1575 lemma metric_CauchyD:
  1576   "Cauchy X \<Longrightarrow> 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e"
  1577   by (simp add: Cauchy_def)
  1578 
  1579 lemma metric_Cauchy_iff2:
  1580   "Cauchy X = (\<forall>j. (\<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. dist (X m) (X n) < inverse(real (Suc j))))"
  1581 apply (simp add: Cauchy_def, auto)
  1582 apply (drule reals_Archimedean, safe)
  1583 apply (drule_tac x = n in spec, auto)
  1584 apply (rule_tac x = M in exI, auto)
  1585 apply (drule_tac x = m in spec, simp)
  1586 apply (drule_tac x = na in spec, auto)
  1587 done
  1588 
  1589 lemma Cauchy_iff2:
  1590   "Cauchy X = (\<forall>j. (\<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. \<bar>X m - X n\<bar> < inverse(real (Suc j))))"
  1591   unfolding metric_Cauchy_iff2 dist_real_def ..
  1592 
  1593 lemma Cauchy_subseq_Cauchy:
  1594   "\<lbrakk> Cauchy X; subseq f \<rbrakk> \<Longrightarrow> Cauchy (X o f)"
  1595 apply (auto simp add: Cauchy_def)
  1596 apply (drule_tac x=e in spec, clarify)
  1597 apply (rule_tac x=M in exI, clarify)
  1598 apply (blast intro: le_trans [OF _ seq_suble] dest!: spec)
  1599 done
  1600 
  1601 theorem LIMSEQ_imp_Cauchy:
  1602   assumes X: "X ----> a" shows "Cauchy X"
  1603 proof (rule metric_CauchyI)
  1604   fix e::real assume "0 < e"
  1605   hence "0 < e/2" by simp
  1606   with X have "\<exists>N. \<forall>n\<ge>N. dist (X n) a < e/2" by (rule metric_LIMSEQ_D)
  1607   then obtain N where N: "\<forall>n\<ge>N. dist (X n) a < e/2" ..
  1608   show "\<exists>N. \<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m) (X n) < e"
  1609   proof (intro exI allI impI)
  1610     fix m assume "N \<le> m"
  1611     hence m: "dist (X m) a < e/2" using N by fast
  1612     fix n assume "N \<le> n"
  1613     hence n: "dist (X n) a < e/2" using N by fast
  1614     have "dist (X m) (X n) \<le> dist (X m) a + dist (X n) a"
  1615       by (rule dist_triangle2)
  1616     also from m n have "\<dots> < e" by simp
  1617     finally show "dist (X m) (X n) < e" .
  1618   qed
  1619 qed
  1620 
  1621 lemma convergent_Cauchy: "convergent X \<Longrightarrow> Cauchy X"
  1622 unfolding convergent_def
  1623 by (erule exE, erule LIMSEQ_imp_Cauchy)
  1624 
  1625 subsubsection {* Cauchy Sequences are Convergent *}
  1626 
  1627 class complete_space = metric_space +
  1628   assumes Cauchy_convergent: "Cauchy X \<Longrightarrow> convergent X"
  1629 
  1630 lemma Cauchy_convergent_iff:
  1631   fixes X :: "nat \<Rightarrow> 'a::complete_space"
  1632   shows "Cauchy X = convergent X"
  1633 by (fast intro: Cauchy_convergent convergent_Cauchy)
  1634 
  1635 subsection {* The set of real numbers is a complete metric space *}
  1636 
  1637 text {*
  1638 Proof that Cauchy sequences converge based on the one from
  1639 @{url "http://pirate.shu.edu/~wachsmut/ira/numseq/proofs/cauconv.html"}
  1640 *}
  1641 
  1642 text {*
  1643   If sequence @{term "X"} is Cauchy, then its limit is the lub of
  1644   @{term "{r::real. \<exists>N. \<forall>n\<ge>N. r < X n}"}
  1645 *}
  1646 
  1647 lemma increasing_LIMSEQ:
  1648   fixes f :: "nat \<Rightarrow> real"
  1649   assumes inc: "\<And>n. f n \<le> f (Suc n)"
  1650       and bdd: "\<And>n. f n \<le> l"
  1651       and en: "\<And>e. 0 < e \<Longrightarrow> \<exists>n. l \<le> f n + e"
  1652   shows "f ----> l"
  1653 proof (rule increasing_tendsto)
  1654   fix x assume "x < l"
  1655   with dense[of 0 "l - x"] obtain e where "0 < e" "e < l - x"
  1656     by auto
  1657   from en[OF `0 < e`] obtain n where "l - e \<le> f n"
  1658     by (auto simp: field_simps)
  1659   with `e < l - x` `0 < e` have "x < f n" by simp
  1660   with incseq_SucI[of f, OF inc] show "eventually (\<lambda>n. x < f n) sequentially"
  1661     by (auto simp: eventually_sequentially incseq_def intro: less_le_trans)
  1662 qed (insert bdd, auto)
  1663 
  1664 lemma real_Cauchy_convergent:
  1665   fixes X :: "nat \<Rightarrow> real"
  1666   assumes X: "Cauchy X"
  1667   shows "convergent X"
  1668 proof -
  1669   def S \<equiv> "{x::real. \<exists>N. \<forall>n\<ge>N. x < X n}"
  1670   then have mem_S: "\<And>N x. \<forall>n\<ge>N. x < X n \<Longrightarrow> x \<in> S" by auto
  1671 
  1672   { fix N x assume N: "\<forall>n\<ge>N. X n < x"
  1673   fix y::real assume "y \<in> S"
  1674   hence "\<exists>M. \<forall>n\<ge>M. y < X n"
  1675     by (simp add: S_def)
  1676   then obtain M where "\<forall>n\<ge>M. y < X n" ..
  1677   hence "y < X (max M N)" by simp
  1678   also have "\<dots> < x" using N by simp
  1679   finally have "y \<le> x"
  1680     by (rule order_less_imp_le) }
  1681   note bound_isUb = this 
  1682 
  1683   obtain N where "\<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m) (X n) < 1"
  1684     using X[THEN metric_CauchyD, OF zero_less_one] by auto
  1685   hence N: "\<forall>n\<ge>N. dist (X n) (X N) < 1" by simp
  1686   have [simp]: "S \<noteq> {}"
  1687   proof (intro exI ex_in_conv[THEN iffD1])
  1688     from N have "\<forall>n\<ge>N. X N - 1 < X n"
  1689       by (simp add: abs_diff_less_iff dist_real_def)
  1690     thus "X N - 1 \<in> S" by (rule mem_S)
  1691   qed
  1692   have [simp]: "bdd_above S"
  1693   proof
  1694     from N have "\<forall>n\<ge>N. X n < X N + 1"
  1695       by (simp add: abs_diff_less_iff dist_real_def)
  1696     thus "\<And>s. s \<in> S \<Longrightarrow>  s \<le> X N + 1"
  1697       by (rule bound_isUb)
  1698   qed
  1699   have "X ----> Sup S"
  1700   proof (rule metric_LIMSEQ_I)
  1701   fix r::real assume "0 < r"
  1702   hence r: "0 < r/2" by simp
  1703   obtain N where "\<forall>n\<ge>N. \<forall>m\<ge>N. dist (X n) (X m) < r/2"
  1704     using metric_CauchyD [OF X r] by auto
  1705   hence "\<forall>n\<ge>N. dist (X n) (X N) < r/2" by simp
  1706   hence N: "\<forall>n\<ge>N. X N - r/2 < X n \<and> X n < X N + r/2"
  1707     by (simp only: dist_real_def abs_diff_less_iff)
  1708 
  1709   from N have "\<forall>n\<ge>N. X N - r/2 < X n" by fast
  1710   hence "X N - r/2 \<in> S" by (rule mem_S)
  1711   hence 1: "X N - r/2 \<le> Sup S" by (simp add: cSup_upper)
  1712 
  1713   from N have "\<forall>n\<ge>N. X n < X N + r/2" by fast
  1714   from bound_isUb[OF this]
  1715   have 2: "Sup S \<le> X N + r/2"
  1716     by (intro cSup_least) simp_all
  1717 
  1718   show "\<exists>N. \<forall>n\<ge>N. dist (X n) (Sup S) < r"
  1719   proof (intro exI allI impI)
  1720     fix n assume n: "N \<le> n"
  1721     from N n have "X n < X N + r/2" and "X N - r/2 < X n" by simp+
  1722     thus "dist (X n) (Sup S) < r" using 1 2
  1723       by (simp add: abs_diff_less_iff dist_real_def)
  1724   qed
  1725   qed
  1726   then show ?thesis unfolding convergent_def by auto
  1727 qed
  1728 
  1729 instance real :: complete_space
  1730   by intro_classes (rule real_Cauchy_convergent)
  1731 
  1732 class banach = real_normed_vector + complete_space
  1733 
  1734 instance real :: banach by default
  1735 
  1736 lemma tendsto_at_topI_sequentially:
  1737   fixes f :: "real \<Rightarrow> real"
  1738   assumes mono: "mono f"
  1739   assumes limseq: "(\<lambda>n. f (real n)) ----> y"
  1740   shows "(f ---> y) at_top"
  1741 proof (rule tendstoI)
  1742   fix e :: real assume "0 < e"
  1743   with limseq obtain N :: nat where N: "\<And>n. N \<le> n \<Longrightarrow> \<bar>f (real n) - y\<bar> < e"
  1744     by (auto simp: LIMSEQ_def dist_real_def)
  1745   { fix x :: real
  1746     obtain n where "x \<le> real_of_nat n"
  1747       using ex_le_of_nat[of x] ..
  1748     note monoD[OF mono this]
  1749     also have "f (real_of_nat n) \<le> y"
  1750       by (rule LIMSEQ_le_const[OF limseq])
  1751          (auto intro: exI[of _ n] monoD[OF mono] simp: real_eq_of_nat[symmetric])
  1752     finally have "f x \<le> y" . }
  1753   note le = this
  1754   have "eventually (\<lambda>x. real N \<le> x) at_top"
  1755     by (rule eventually_ge_at_top)
  1756   then show "eventually (\<lambda>x. dist (f x) y < e) at_top"
  1757   proof eventually_elim
  1758     fix x assume N': "real N \<le> x"
  1759     with N[of N] le have "y - f (real N) < e" by auto
  1760     moreover note monoD[OF mono N']
  1761     ultimately show "dist (f x) y < e"
  1762       using le[of x] by (auto simp: dist_real_def field_simps)
  1763   qed
  1764 qed
  1765 
  1766 end