src/HOL/Power.thy
author huffman
Sun May 13 19:15:36 2007 +0200 (2007-05-13)
changeset 22955 48dc37776d1e
parent 22853 7f000a385606
child 22957 82a799ae7579
permissions -rw-r--r--
add lemma power_eq_imp_eq_base
     1 (*  Title:      HOL/Power.thy
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1997  University of Cambridge
     5 
     6 *)
     7 
     8 header{*Exponentiation*}
     9 
    10 theory Power
    11 imports Nat
    12 begin
    13 
    14 subsection{*Powers for Arbitrary Monoids*}
    15 
    16 class recpower = monoid_mult + power +
    17   assumes power_0 [simp]: "a \<^loc>^ 0       = \<^loc>1"
    18   assumes power_Suc:      "a \<^loc>^ Suc n = a \<^loc>* (a \<^loc>^ n)"
    19 
    20 lemma power_0_Suc [simp]: "(0::'a::{recpower,semiring_0}) ^ (Suc n) = 0"
    21 by (simp add: power_Suc)
    22 
    23 text{*It looks plausible as a simprule, but its effect can be strange.*}
    24 lemma power_0_left: "0^n = (if n=0 then 1 else (0::'a::{recpower,semiring_0}))"
    25 by (induct "n", auto)
    26 
    27 lemma power_one [simp]: "1^n = (1::'a::recpower)"
    28 apply (induct "n")
    29 apply (auto simp add: power_Suc)
    30 done
    31 
    32 lemma power_one_right [simp]: "(a::'a::recpower) ^ 1 = a"
    33 by (simp add: power_Suc)
    34 
    35 lemma power_commutes: "(a::'a::recpower) ^ n * a = a * a ^ n"
    36 by (induct "n") (simp_all add:power_Suc mult_assoc)
    37 
    38 lemma power_add: "(a::'a::recpower) ^ (m+n) = (a^m) * (a^n)"
    39 apply (induct "m")
    40 apply (simp_all add: power_Suc mult_ac)
    41 done
    42 
    43 lemma power_mult: "(a::'a::recpower) ^ (m*n) = (a^m) ^ n"
    44 apply (induct "n") 
    45 apply (simp_all add: power_Suc power_add)
    46 done
    47 
    48 lemma power_mult_distrib: "((a::'a::{recpower,comm_monoid_mult}) * b) ^ n = (a^n) * (b^n)"
    49 apply (induct "n")
    50 apply (auto simp add: power_Suc mult_ac)
    51 done
    52 
    53 lemma zero_less_power:
    54      "0 < (a::'a::{ordered_semidom,recpower}) ==> 0 < a^n"
    55 apply (induct "n")
    56 apply (simp_all add: power_Suc zero_less_one mult_pos_pos)
    57 done
    58 
    59 lemma zero_le_power:
    60      "0 \<le> (a::'a::{ordered_semidom,recpower}) ==> 0 \<le> a^n"
    61 apply (simp add: order_le_less)
    62 apply (erule disjE)
    63 apply (simp_all add: zero_less_power zero_less_one power_0_left)
    64 done
    65 
    66 lemma one_le_power:
    67      "1 \<le> (a::'a::{ordered_semidom,recpower}) ==> 1 \<le> a^n"
    68 apply (induct "n")
    69 apply (simp_all add: power_Suc)
    70 apply (rule order_trans [OF _ mult_mono [of 1 _ 1]])
    71 apply (simp_all add: zero_le_one order_trans [OF zero_le_one])
    72 done
    73 
    74 lemma gt1_imp_ge0: "1 < a ==> 0 \<le> (a::'a::ordered_semidom)"
    75   by (simp add: order_trans [OF zero_le_one order_less_imp_le])
    76 
    77 lemma power_gt1_lemma:
    78   assumes gt1: "1 < (a::'a::{ordered_semidom,recpower})"
    79   shows "1 < a * a^n"
    80 proof -
    81   have "1*1 < a*1" using gt1 by simp
    82   also have "\<dots> \<le> a * a^n" using gt1
    83     by (simp only: mult_mono gt1_imp_ge0 one_le_power order_less_imp_le
    84         zero_le_one order_refl)
    85   finally show ?thesis by simp
    86 qed
    87 
    88 lemma power_gt1:
    89      "1 < (a::'a::{ordered_semidom,recpower}) ==> 1 < a ^ (Suc n)"
    90 by (simp add: power_gt1_lemma power_Suc)
    91 
    92 lemma power_le_imp_le_exp:
    93   assumes gt1: "(1::'a::{recpower,ordered_semidom}) < a"
    94   shows "!!n. a^m \<le> a^n ==> m \<le> n"
    95 proof (induct m)
    96   case 0
    97   show ?case by simp
    98 next
    99   case (Suc m)
   100   show ?case
   101   proof (cases n)
   102     case 0
   103     from prems have "a * a^m \<le> 1" by (simp add: power_Suc)
   104     with gt1 show ?thesis
   105       by (force simp only: power_gt1_lemma
   106           linorder_not_less [symmetric])
   107   next
   108     case (Suc n)
   109     from prems show ?thesis
   110       by (force dest: mult_left_le_imp_le
   111           simp add: power_Suc order_less_trans [OF zero_less_one gt1])
   112   qed
   113 qed
   114 
   115 text{*Surely we can strengthen this? It holds for @{text "0<a<1"} too.*}
   116 lemma power_inject_exp [simp]:
   117      "1 < (a::'a::{ordered_semidom,recpower}) ==> (a^m = a^n) = (m=n)"
   118   by (force simp add: order_antisym power_le_imp_le_exp)
   119 
   120 text{*Can relax the first premise to @{term "0<a"} in the case of the
   121 natural numbers.*}
   122 lemma power_less_imp_less_exp:
   123      "[| (1::'a::{recpower,ordered_semidom}) < a; a^m < a^n |] ==> m < n"
   124 by (simp add: order_less_le [of m n] order_less_le [of "a^m" "a^n"]
   125               power_le_imp_le_exp)
   126 
   127 
   128 lemma power_mono:
   129      "[|a \<le> b; (0::'a::{recpower,ordered_semidom}) \<le> a|] ==> a^n \<le> b^n"
   130 apply (induct "n")
   131 apply (simp_all add: power_Suc)
   132 apply (auto intro: mult_mono zero_le_power order_trans [of 0 a b])
   133 done
   134 
   135 lemma power_strict_mono [rule_format]:
   136      "[|a < b; (0::'a::{recpower,ordered_semidom}) \<le> a|]
   137       ==> 0 < n --> a^n < b^n"
   138 apply (induct "n")
   139 apply (auto simp add: mult_strict_mono zero_le_power power_Suc
   140                       order_le_less_trans [of 0 a b])
   141 done
   142 
   143 lemma power_eq_0_iff [simp]:
   144      "(a^n = 0) = (a = (0::'a::{ordered_idom,recpower}) & 0<n)"
   145 apply (induct "n")
   146 apply (auto simp add: power_Suc zero_neq_one [THEN not_sym])
   147 done
   148 
   149 lemma field_power_eq_0_iff [simp]:
   150      "(a^n = 0) = (a = (0::'a::{field,recpower}) & 0<n)"
   151 apply (induct "n")
   152 apply (auto simp add: power_Suc field_mult_eq_0_iff zero_neq_one[THEN not_sym])
   153 done
   154 
   155 lemma field_power_not_zero: "a \<noteq> (0::'a::{field,recpower}) ==> a^n \<noteq> 0"
   156 by force
   157 
   158 lemma nonzero_power_inverse:
   159   "a \<noteq> 0 ==> inverse ((a::'a::{field,recpower}) ^ n) = (inverse a) ^ n"
   160 apply (induct "n")
   161 apply (auto simp add: power_Suc nonzero_inverse_mult_distrib mult_commute)
   162 done
   163 
   164 text{*Perhaps these should be simprules.*}
   165 lemma power_inverse:
   166   "inverse ((a::'a::{field,division_by_zero,recpower}) ^ n) = (inverse a) ^ n"
   167 apply (induct "n")
   168 apply (auto simp add: power_Suc inverse_mult_distrib)
   169 done
   170 
   171 lemma power_one_over: "1 / (a::'a::{field,division_by_zero,recpower})^n = 
   172     (1 / a)^n"
   173 apply (simp add: divide_inverse)
   174 apply (rule power_inverse)
   175 done
   176 
   177 lemma nonzero_power_divide:
   178     "b \<noteq> 0 ==> (a/b) ^ n = ((a::'a::{field,recpower}) ^ n) / (b ^ n)"
   179 by (simp add: divide_inverse power_mult_distrib nonzero_power_inverse)
   180 
   181 lemma power_divide:
   182     "(a/b) ^ n = ((a::'a::{field,division_by_zero,recpower}) ^ n / b ^ n)"
   183 apply (case_tac "b=0", simp add: power_0_left)
   184 apply (rule nonzero_power_divide)
   185 apply assumption
   186 done
   187 
   188 lemma power_abs: "abs(a ^ n) = abs(a::'a::{ordered_idom,recpower}) ^ n"
   189 apply (induct "n")
   190 apply (auto simp add: power_Suc abs_mult)
   191 done
   192 
   193 lemma zero_less_power_abs_iff [simp]:
   194      "(0 < (abs a)^n) = (a \<noteq> (0::'a::{ordered_idom,recpower}) | n=0)"
   195 proof (induct "n")
   196   case 0
   197     show ?case by (simp add: zero_less_one)
   198 next
   199   case (Suc n)
   200     show ?case by (force simp add: prems power_Suc zero_less_mult_iff)
   201 qed
   202 
   203 lemma zero_le_power_abs [simp]:
   204      "(0::'a::{ordered_idom,recpower}) \<le> (abs a)^n"
   205 apply (induct "n")
   206 apply (auto simp add: zero_le_one zero_le_power)
   207 done
   208 
   209 lemma power_minus: "(-a) ^ n = (- 1)^n * (a::'a::{comm_ring_1,recpower}) ^ n"
   210 proof -
   211   have "-a = (- 1) * a"  by (simp add: minus_mult_left [symmetric])
   212   thus ?thesis by (simp only: power_mult_distrib)
   213 qed
   214 
   215 text{*Lemma for @{text power_strict_decreasing}*}
   216 lemma power_Suc_less:
   217      "[|(0::'a::{ordered_semidom,recpower}) < a; a < 1|]
   218       ==> a * a^n < a^n"
   219 apply (induct n)
   220 apply (auto simp add: power_Suc mult_strict_left_mono)
   221 done
   222 
   223 lemma power_strict_decreasing:
   224      "[|n < N; 0 < a; a < (1::'a::{ordered_semidom,recpower})|]
   225       ==> a^N < a^n"
   226 apply (erule rev_mp)
   227 apply (induct "N")
   228 apply (auto simp add: power_Suc power_Suc_less less_Suc_eq)
   229 apply (rename_tac m)
   230 apply (subgoal_tac "a * a^m < 1 * a^n", simp)
   231 apply (rule mult_strict_mono)
   232 apply (auto simp add: zero_le_power zero_less_one order_less_imp_le)
   233 done
   234 
   235 text{*Proof resembles that of @{text power_strict_decreasing}*}
   236 lemma power_decreasing:
   237      "[|n \<le> N; 0 \<le> a; a \<le> (1::'a::{ordered_semidom,recpower})|]
   238       ==> a^N \<le> a^n"
   239 apply (erule rev_mp)
   240 apply (induct "N")
   241 apply (auto simp add: power_Suc  le_Suc_eq)
   242 apply (rename_tac m)
   243 apply (subgoal_tac "a * a^m \<le> 1 * a^n", simp)
   244 apply (rule mult_mono)
   245 apply (auto simp add: zero_le_power zero_le_one)
   246 done
   247 
   248 lemma power_Suc_less_one:
   249      "[| 0 < a; a < (1::'a::{ordered_semidom,recpower}) |] ==> a ^ Suc n < 1"
   250 apply (insert power_strict_decreasing [of 0 "Suc n" a], simp)
   251 done
   252 
   253 text{*Proof again resembles that of @{text power_strict_decreasing}*}
   254 lemma power_increasing:
   255      "[|n \<le> N; (1::'a::{ordered_semidom,recpower}) \<le> a|] ==> a^n \<le> a^N"
   256 apply (erule rev_mp)
   257 apply (induct "N")
   258 apply (auto simp add: power_Suc le_Suc_eq)
   259 apply (rename_tac m)
   260 apply (subgoal_tac "1 * a^n \<le> a * a^m", simp)
   261 apply (rule mult_mono)
   262 apply (auto simp add: order_trans [OF zero_le_one] zero_le_power)
   263 done
   264 
   265 text{*Lemma for @{text power_strict_increasing}*}
   266 lemma power_less_power_Suc:
   267      "(1::'a::{ordered_semidom,recpower}) < a ==> a^n < a * a^n"
   268 apply (induct n)
   269 apply (auto simp add: power_Suc mult_strict_left_mono order_less_trans [OF zero_less_one])
   270 done
   271 
   272 lemma power_strict_increasing:
   273      "[|n < N; (1::'a::{ordered_semidom,recpower}) < a|] ==> a^n < a^N"
   274 apply (erule rev_mp)
   275 apply (induct "N")
   276 apply (auto simp add: power_less_power_Suc power_Suc less_Suc_eq)
   277 apply (rename_tac m)
   278 apply (subgoal_tac "1 * a^n < a * a^m", simp)
   279 apply (rule mult_strict_mono)
   280 apply (auto simp add: order_less_trans [OF zero_less_one] zero_le_power
   281                  order_less_imp_le)
   282 done
   283 
   284 lemma power_increasing_iff [simp]: 
   285      "1 < (b::'a::{ordered_semidom,recpower}) ==> (b ^ x \<le> b ^ y) = (x \<le> y)"
   286   by (blast intro: power_le_imp_le_exp power_increasing order_less_imp_le) 
   287 
   288 lemma power_strict_increasing_iff [simp]:
   289      "1 < (b::'a::{ordered_semidom,recpower}) ==> (b ^ x < b ^ y) = (x < y)"
   290   by (blast intro: power_less_imp_less_exp power_strict_increasing) 
   291 
   292 lemma power_le_imp_le_base:
   293   assumes le: "a ^ Suc n \<le> b ^ Suc n"
   294       and ynonneg: "(0::'a::{ordered_semidom,recpower}) \<le> b"
   295   shows "a \<le> b"
   296  proof (rule ccontr)
   297    assume "~ a \<le> b"
   298    then have "b < a" by (simp only: linorder_not_le)
   299    then have "b ^ Suc n < a ^ Suc n"
   300      by (simp only: prems power_strict_mono)
   301    from le and this show "False"
   302       by (simp add: linorder_not_less [symmetric])
   303  qed
   304 
   305 lemma power_less_imp_less_base:
   306   fixes a b :: "'a::{ordered_semidom,recpower}"
   307   assumes less: "a ^ n < b ^ n"
   308   assumes nonneg: "0 \<le> b"
   309   shows "a < b"
   310 proof (rule contrapos_pp [OF less])
   311   assume "~ a < b"
   312   hence "b \<le> a" by (simp only: linorder_not_less)
   313   hence "b ^ n \<le> a ^ n" using nonneg by (rule power_mono)
   314   thus "~ a ^ n < b ^ n" by (simp only: linorder_not_less)
   315 qed
   316 
   317 lemma power_inject_base:
   318      "[| a ^ Suc n = b ^ Suc n; 0 \<le> a; 0 \<le> b |]
   319       ==> a = (b::'a::{ordered_semidom,recpower})"
   320 by (blast intro: power_le_imp_le_base order_antisym order_eq_refl sym)
   321 
   322 lemma power_eq_imp_eq_base:
   323   fixes a b :: "'a::{ordered_semidom,recpower}"
   324   shows "\<lbrakk>a ^ n = b ^ n; 0 \<le> a; 0 \<le> b; 0 < n\<rbrakk> \<Longrightarrow> a = b"
   325 by (cases n, simp_all, rule power_inject_base)
   326 
   327 
   328 subsection{*Exponentiation for the Natural Numbers*}
   329 
   330 instance nat :: power ..
   331 
   332 primrec (power)
   333   "p ^ 0 = 1"
   334   "p ^ (Suc n) = (p::nat) * (p ^ n)"
   335 
   336 instance nat :: recpower
   337 proof
   338   fix z n :: nat
   339   show "z^0 = 1" by simp
   340   show "z^(Suc n) = z * (z^n)" by simp
   341 qed
   342 
   343 lemma nat_one_le_power [simp]: "1 \<le> i ==> Suc 0 \<le> i^n"
   344 by (insert one_le_power [of i n], simp)
   345 
   346 lemma nat_zero_less_power_iff [simp]: "(0 < x^n) = (x \<noteq> (0::nat) | n=0)"
   347 by (induct "n", auto)
   348 
   349 text{*Valid for the naturals, but what if @{text"0<i<1"}?
   350 Premises cannot be weakened: consider the case where @{term "i=0"},
   351 @{term "m=1"} and @{term "n=0"}.*}
   352 lemma nat_power_less_imp_less:
   353   assumes nonneg: "0 < (i\<Colon>nat)"
   354   assumes less: "i^m < i^n"
   355   shows "m < n"
   356 proof (cases "i = 1")
   357   case True with less power_one [where 'a = nat] show ?thesis by simp
   358 next
   359   case False with nonneg have "1 < i" by auto
   360   from power_strict_increasing_iff [OF this] less show ?thesis ..
   361 qed
   362 
   363 lemma power_diff:
   364   assumes nz: "a ~= 0"
   365   shows "n <= m ==> (a::'a::{recpower, field}) ^ (m-n) = (a^m) / (a^n)"
   366   by (induct m n rule: diff_induct)
   367     (simp_all add: power_Suc nonzero_mult_divide_cancel_left nz)
   368 
   369 
   370 text{*ML bindings for the general exponentiation theorems*}
   371 ML
   372 {*
   373 val power_0 = thm"power_0";
   374 val power_Suc = thm"power_Suc";
   375 val power_0_Suc = thm"power_0_Suc";
   376 val power_0_left = thm"power_0_left";
   377 val power_one = thm"power_one";
   378 val power_one_right = thm"power_one_right";
   379 val power_add = thm"power_add";
   380 val power_mult = thm"power_mult";
   381 val power_mult_distrib = thm"power_mult_distrib";
   382 val zero_less_power = thm"zero_less_power";
   383 val zero_le_power = thm"zero_le_power";
   384 val one_le_power = thm"one_le_power";
   385 val gt1_imp_ge0 = thm"gt1_imp_ge0";
   386 val power_gt1_lemma = thm"power_gt1_lemma";
   387 val power_gt1 = thm"power_gt1";
   388 val power_le_imp_le_exp = thm"power_le_imp_le_exp";
   389 val power_inject_exp = thm"power_inject_exp";
   390 val power_less_imp_less_exp = thm"power_less_imp_less_exp";
   391 val power_mono = thm"power_mono";
   392 val power_strict_mono = thm"power_strict_mono";
   393 val power_eq_0_iff = thm"power_eq_0_iff";
   394 val field_power_eq_0_iff = thm"field_power_eq_0_iff";
   395 val field_power_not_zero = thm"field_power_not_zero";
   396 val power_inverse = thm"power_inverse";
   397 val nonzero_power_divide = thm"nonzero_power_divide";
   398 val power_divide = thm"power_divide";
   399 val power_abs = thm"power_abs";
   400 val zero_less_power_abs_iff = thm"zero_less_power_abs_iff";
   401 val zero_le_power_abs = thm "zero_le_power_abs";
   402 val power_minus = thm"power_minus";
   403 val power_Suc_less = thm"power_Suc_less";
   404 val power_strict_decreasing = thm"power_strict_decreasing";
   405 val power_decreasing = thm"power_decreasing";
   406 val power_Suc_less_one = thm"power_Suc_less_one";
   407 val power_increasing = thm"power_increasing";
   408 val power_strict_increasing = thm"power_strict_increasing";
   409 val power_le_imp_le_base = thm"power_le_imp_le_base";
   410 val power_inject_base = thm"power_inject_base";
   411 *}
   412 
   413 text{*ML bindings for the remaining theorems*}
   414 ML
   415 {*
   416 val nat_one_le_power = thm"nat_one_le_power";
   417 val nat_power_less_imp_less = thm"nat_power_less_imp_less";
   418 val nat_zero_less_power_iff = thm"nat_zero_less_power_iff";
   419 *}
   420 
   421 end
   422