src/Pure/sign.ML
author wenzelm
Wed Aug 27 11:48:54 2008 +0200 (2008-08-27)
changeset 28017 4919bd124a58
parent 27302 8d12ac6a3e1c
child 28111 ea22fd4685fb
permissions -rw-r--r--
type Properties.T;
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical signature content: naming conventions, concrete syntax, type
     6 signature, polymorphic constants.
     7 *)
     8 
     9 signature SIGN =
    10 sig
    11   val rep_sg: theory ->
    12    {naming: NameSpace.naming,
    13     syn: Syntax.syntax,
    14     tsig: Type.tsig,
    15     consts: Consts.T}
    16   val naming_of: theory -> NameSpace.naming
    17   val base_name: string -> bstring
    18   val full_name: theory -> bstring -> string
    19   val full_name_path: theory -> string -> bstring -> string
    20   val declare_name: theory -> string -> NameSpace.T -> NameSpace.T
    21   val syn_of: theory -> Syntax.syntax
    22   val tsig_of: theory -> Type.tsig
    23   val classes_of: theory -> Sorts.algebra
    24   val all_classes: theory -> class list
    25   val super_classes: theory -> class -> class list
    26   val minimize_sort: theory -> sort -> sort
    27   val complete_sort: theory -> sort -> sort
    28   val defaultS: theory -> sort
    29   val subsort: theory -> sort * sort -> bool
    30   val of_sort: theory -> typ * sort -> bool
    31   val witness_sorts: theory -> sort list -> sort list -> (typ * sort) list
    32   val is_logtype: theory -> string -> bool
    33   val typ_instance: theory -> typ * typ -> bool
    34   val typ_equiv: theory -> typ * typ -> bool
    35   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    36   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    37   val consts_of: theory -> Consts.T
    38   val the_const_constraint: theory -> string -> typ
    39   val const_type: theory -> string -> typ option
    40   val the_const_type: theory -> string -> typ
    41   val declared_tyname: theory -> string -> bool
    42   val declared_const: theory -> string -> bool
    43   val const_monomorphic: theory -> string -> bool
    44   val const_syntax_name: theory -> string -> string
    45   val const_typargs: theory -> string * typ -> typ list
    46   val const_instance: theory -> string * typ list -> typ
    47   val mk_const: theory -> string * typ list -> term
    48   val class_space: theory -> NameSpace.T
    49   val type_space: theory -> NameSpace.T
    50   val const_space: theory -> NameSpace.T
    51   val intern_class: theory -> xstring -> string
    52   val extern_class: theory -> string -> xstring
    53   val intern_type: theory -> xstring -> string
    54   val extern_type: theory -> string -> xstring
    55   val intern_const: theory -> xstring -> string
    56   val extern_const: theory -> string -> xstring
    57   val intern_sort: theory -> sort -> sort
    58   val extern_sort: theory -> sort -> sort
    59   val intern_typ: theory -> typ -> typ
    60   val extern_typ: theory -> typ -> typ
    61   val intern_term: theory -> term -> term
    62   val extern_term: (string -> xstring) -> theory -> term -> term
    63   val intern_tycons: theory -> typ -> typ
    64   val arity_number: theory -> string -> int
    65   val arity_sorts: theory -> string -> sort -> sort list
    66   val certify_class: theory -> class -> class
    67   val certify_sort: theory -> sort -> sort
    68   val certify_typ: theory -> typ -> typ
    69   val certify_typ_mode: Type.mode -> theory -> typ -> typ
    70   val certify': bool -> Pretty.pp -> bool -> Consts.T -> theory -> term -> term * typ * int
    71   val certify_term: theory -> term -> term * typ * int
    72   val certify_prop: theory -> term -> term * typ * int
    73   val cert_term: theory -> term -> term
    74   val cert_prop: theory -> term -> term
    75   val no_frees: Pretty.pp -> term -> term
    76   val no_vars: Pretty.pp -> term -> term
    77   val cert_def: Proof.context -> term -> (string * typ) * term
    78   val read_class: theory -> xstring -> class
    79   val read_arity: theory -> xstring * string list * string -> arity
    80   val cert_arity: theory -> arity -> arity
    81   val add_defsort: string -> theory -> theory
    82   val add_defsort_i: sort -> theory -> theory
    83   val add_types: (bstring * int * mixfix) list -> theory -> theory
    84   val add_nonterminals: bstring list -> theory -> theory
    85   val add_tyabbrs: (bstring * string list * string * mixfix) list -> theory -> theory
    86   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> theory -> theory
    87   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    88   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    89   val add_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    90   val add_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    91   val del_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    92   val del_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    93   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
    94   val add_consts: (bstring * string * mixfix) list -> theory -> theory
    95   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
    96   val declare_const: Properties.T -> bstring * typ * mixfix -> theory -> term * theory
    97   val add_abbrev: string -> Properties.T -> bstring * term -> theory -> (term * term) * theory
    98   val revert_abbrev: string -> string -> theory -> theory
    99   val add_const_constraint: string * typ option -> theory -> theory
   100   val primitive_class: string * class list -> theory -> theory
   101   val primitive_classrel: class * class -> theory -> theory
   102   val primitive_arity: arity -> theory -> theory
   103   val add_trfuns:
   104     (string * (ast list -> ast)) list *
   105     (string * (term list -> term)) list *
   106     (string * (term list -> term)) list *
   107     (string * (ast list -> ast)) list -> theory -> theory
   108   val add_trfunsT:
   109     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
   110   val add_advanced_trfuns:
   111     (string * (Proof.context -> ast list -> ast)) list *
   112     (string * (Proof.context -> term list -> term)) list *
   113     (string * (Proof.context -> term list -> term)) list *
   114     (string * (Proof.context -> ast list -> ast)) list -> theory -> theory
   115   val add_advanced_trfunsT:
   116     (string * (Proof.context -> bool -> typ -> term list -> term)) list -> theory -> theory
   117   val add_tokentrfuns:
   118     (string * string * (Proof.context -> string -> Pretty.T)) list -> theory -> theory
   119   val add_mode_tokentrfuns: string -> (string * (Proof.context -> string -> Pretty.T)) list
   120     -> theory -> theory
   121   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   122   val del_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   123   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
   124   val del_trrules_i: ast Syntax.trrule list -> theory -> theory
   125   val add_path: string -> theory -> theory
   126   val parent_path: theory -> theory
   127   val root_path: theory -> theory
   128   val absolute_path: theory -> theory
   129   val local_path: theory -> theory
   130   val no_base_names: theory -> theory
   131   val qualified_names: theory -> theory
   132   val sticky_prefix: string -> theory -> theory
   133   val restore_naming: theory -> theory -> theory
   134   val hide_class: bool -> string -> theory -> theory
   135   val hide_type: bool -> string -> theory -> theory
   136   val hide_const: bool -> string -> theory -> theory
   137 end
   138 
   139 structure Sign: SIGN =
   140 struct
   141 
   142 (** datatype sign **)
   143 
   144 datatype sign = Sign of
   145  {naming: NameSpace.naming,     (*common naming conventions*)
   146   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   147   tsig: Type.tsig,              (*order-sorted signature of types*)
   148   consts: Consts.T};            (*polymorphic constants*)
   149 
   150 fun make_sign (naming, syn, tsig, consts) =
   151   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   152 
   153 structure SignData = TheoryDataFun
   154 (
   155   type T = sign;
   156   val copy = I;
   157   fun extend (Sign {syn, tsig, consts, ...}) =
   158     make_sign (NameSpace.default_naming, syn, tsig, consts);
   159 
   160   val empty =
   161     make_sign (NameSpace.default_naming, Syntax.basic_syn, Type.empty_tsig, Consts.empty);
   162 
   163   fun merge pp (sign1, sign2) =
   164     let
   165       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   166       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   167 
   168       val naming = NameSpace.default_naming;
   169       val syn = Syntax.merge_syntaxes syn1 syn2;
   170       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   171       val consts = Consts.merge (consts1, consts2);
   172     in make_sign (naming, syn, tsig, consts) end;
   173 );
   174 
   175 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   176 
   177 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   178   make_sign (f (naming, syn, tsig, consts)));
   179 
   180 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   181 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   182 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   183 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   184 
   185 
   186 (* naming *)
   187 
   188 val naming_of = #naming o rep_sg;
   189 val base_name = NameSpace.base;
   190 val full_name = NameSpace.full o naming_of;
   191 fun full_name_path thy elems = NameSpace.full (NameSpace.add_path elems (naming_of thy));
   192 val declare_name = NameSpace.declare o naming_of;
   193 
   194 
   195 (* syntax *)
   196 
   197 val syn_of = #syn o rep_sg;
   198 
   199 
   200 (* type signature *)
   201 
   202 val tsig_of = #tsig o rep_sg;
   203 
   204 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   205 val all_classes = Sorts.all_classes o classes_of;
   206 val super_classes = Sorts.super_classes o classes_of;
   207 val minimize_sort = Sorts.minimize_sort o classes_of;
   208 val complete_sort = Sorts.complete_sort o classes_of;
   209 
   210 val defaultS = Type.defaultS o tsig_of;
   211 val subsort = Type.subsort o tsig_of;
   212 val of_sort = Type.of_sort o tsig_of;
   213 val witness_sorts = Type.witness_sorts o tsig_of;
   214 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   215 
   216 val typ_instance = Type.typ_instance o tsig_of;
   217 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   218 val typ_match = Type.typ_match o tsig_of;
   219 val typ_unify = Type.unify o tsig_of;
   220 
   221 
   222 (* polymorphic constants *)
   223 
   224 val consts_of = #consts o rep_sg;
   225 val the_const_constraint = Consts.the_constraint o consts_of;
   226 val the_const_type = Consts.the_type o consts_of;
   227 val const_type = try o the_const_type;
   228 val const_monomorphic = Consts.is_monomorphic o consts_of;
   229 val const_syntax_name = Consts.syntax_name o consts_of;
   230 val const_typargs = Consts.typargs o consts_of;
   231 val const_instance = Consts.instance o consts_of;
   232 
   233 fun mk_const thy (c, Ts) = Const (c, const_instance thy (c, Ts));
   234 
   235 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   236 val declared_const = can o the_const_constraint;
   237 
   238 
   239 
   240 (** intern / extern names **)
   241 
   242 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   243 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   244 val const_space = Consts.space_of o consts_of;
   245 
   246 val intern_class = NameSpace.intern o class_space;
   247 val extern_class = NameSpace.extern o class_space;
   248 val intern_type = NameSpace.intern o type_space;
   249 val extern_type = NameSpace.extern o type_space;
   250 val intern_const = NameSpace.intern o const_space;
   251 val extern_const = NameSpace.extern o const_space;
   252 
   253 val intern_sort = map o intern_class;
   254 val extern_sort = map o extern_class;
   255 
   256 local
   257 
   258 fun map_typ f g (Type (c, Ts)) = Type (g c, map (map_typ f g) Ts)
   259   | map_typ f _ (TFree (x, S)) = TFree (x, map f S)
   260   | map_typ f _ (TVar (xi, S)) = TVar (xi, map f S);
   261 
   262 fun map_term f g h (Const (c, T)) = Const (h c, map_typ f g T)
   263   | map_term f g _ (Free (x, T)) = Free (x, map_typ f g T)
   264   | map_term f g _ (Var (xi, T)) = Var (xi, map_typ f g T)
   265   | map_term _ _ _ (t as Bound _) = t
   266   | map_term f g h (Abs (x, T, t)) = Abs (x, map_typ f g T, map_term f g h t)
   267   | map_term f g h (t $ u) = map_term f g h t $ map_term f g h u;
   268 
   269 val add_classesT = Term.fold_atyps
   270   (fn TFree (_, S) => fold (insert (op =)) S
   271     | TVar (_, S) => fold (insert (op =)) S
   272     | _ => I);
   273 
   274 fun add_tyconsT (Type (c, Ts)) = insert (op =) c #> fold add_tyconsT Ts
   275   | add_tyconsT _ = I;
   276 
   277 val add_consts = Term.fold_aterms (fn Const (c, _) => insert (op =) c | _ => I);
   278 
   279 fun mapping add_names f t =
   280   let
   281     fun f' (x: string) = let val y = f x in if x = y then NONE else SOME (x, y) end;
   282     val tab = map_filter f' (add_names t []);
   283     fun get x = the_default x (AList.lookup (op =) tab x);
   284   in get end;
   285 
   286 fun typ_mapping f g thy T =
   287   T |> map_typ
   288     (mapping add_classesT (f thy) T)
   289     (mapping add_tyconsT (g thy) T);
   290 
   291 fun term_mapping f g h thy t =
   292   t |> map_term
   293     (mapping (Term.fold_types add_classesT) (f thy) t)
   294     (mapping (Term.fold_types add_tyconsT) (g thy) t)
   295     (mapping add_consts (h thy) t);
   296 
   297 in
   298 
   299 val intern_typ = typ_mapping intern_class intern_type;
   300 val extern_typ = typ_mapping extern_class extern_type;
   301 val intern_term = term_mapping intern_class intern_type intern_const;
   302 fun extern_term h = term_mapping extern_class extern_type (K h);
   303 val intern_tycons = typ_mapping (K I) intern_type;
   304 
   305 end;
   306 
   307 
   308 
   309 (** certify entities **)    (*exception TYPE*)
   310 
   311 (* certify wrt. type signature *)
   312 
   313 val arity_number = Type.arity_number o tsig_of;
   314 fun arity_sorts thy = Type.arity_sorts (Syntax.pp_global thy) (tsig_of thy);
   315 
   316 val certify_class         = Type.cert_class o tsig_of;
   317 val certify_sort          = Type.cert_sort o tsig_of;
   318 val certify_typ           = Type.cert_typ o tsig_of;
   319 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   320 
   321 
   322 (* certify term/prop *)
   323 
   324 local
   325 
   326 fun type_check pp tm =
   327   let
   328     fun err_appl why bs t T u U =
   329       let
   330         val xs = map Free bs;           (*we do not rename here*)
   331         val t' = subst_bounds (xs, t);
   332         val u' = subst_bounds (xs, u);
   333         val msg = cat_lines
   334           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   335       in raise TYPE (msg, [T, U], [t', u']) end;
   336 
   337     fun typ_of (_, Const (_, T)) = T
   338       | typ_of (_, Free  (_, T)) = T
   339       | typ_of (_, Var (_, T)) = T
   340       | typ_of (bs, Bound i) = snd (List.nth (bs, i) handle Subscript =>
   341           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   342       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   343       | typ_of (bs, t $ u) =
   344           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   345             (case T of
   346               Type ("fun", [T1, T2]) =>
   347                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   348             | _ => err_appl "Operator not of function type" bs t T u U)
   349           end;
   350   in typ_of ([], tm) end;
   351 
   352 fun err msg = raise TYPE (msg, [], []);
   353 
   354 fun check_vars (t $ u) = (check_vars t; check_vars u)
   355   | check_vars (Abs (_, _, t)) = check_vars t
   356   | check_vars (Free (x, _)) =
   357       if NameSpace.is_qualified x then err ("Malformed variable: " ^ quote x) else ()
   358   | check_vars (Var (xi as (_, i), _)) =
   359       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   360   | check_vars _ = ();
   361 
   362 in
   363 
   364 fun certify' prop pp do_expand consts thy tm =
   365   let
   366     val _ = check_vars tm;
   367     val tm' = Term.map_types (certify_typ thy) tm;
   368     val T = type_check pp tm';
   369     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   370     val tm'' = Consts.certify pp (tsig_of thy) do_expand consts tm';
   371   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   372 
   373 fun certify_term thy = certify' false (Syntax.pp_global thy) true (consts_of thy) thy;
   374 fun certify_prop thy = certify' true (Syntax.pp_global thy) true (consts_of thy) thy;
   375 
   376 fun cert_term_abbrev thy = #1 o certify' false (Syntax.pp_global thy) false (consts_of thy) thy;
   377 val cert_term = #1 oo certify_term;
   378 val cert_prop = #1 oo certify_prop;
   379 
   380 end;
   381 
   382 
   383 (* specifications *)
   384 
   385 fun no_variables kind add addT mk mkT pp tm =
   386   (case (add tm [], addT tm []) of
   387     ([], []) => tm
   388   | (frees, tfrees) => error (Pretty.string_of (Pretty.block
   389       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") :: Pretty.brk 1 ::
   390        Pretty.commas (map (Pretty.term pp o mk) frees @ map (Pretty.typ pp o mkT) tfrees)))));
   391 
   392 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   393 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   394 
   395 fun cert_def ctxt tm =
   396   let val ((lhs, rhs), _) = tm
   397     |> no_vars (Syntax.pp ctxt)
   398     |> Logic.strip_imp_concl
   399     |> PrimitiveDefs.dest_def ctxt Term.is_Const (K false) (K false)
   400   in (Term.dest_Const (Term.head_of lhs), rhs) end
   401   handle TERM (msg, _) => error msg;
   402 
   403 
   404 
   405 (** read and certify entities **)    (*exception ERROR*)
   406 
   407 (* classes *)
   408 
   409 fun read_class thy c = certify_class thy (intern_class thy c)
   410   handle TYPE (msg, _, _) => error msg;
   411 
   412 
   413 (* type arities *)
   414 
   415 fun prep_arity prep_tycon prep_sort thy (t, Ss, S) =
   416   let val arity = (prep_tycon thy t, map (prep_sort thy) Ss, prep_sort thy S)
   417   in Type.add_arity (Syntax.pp_global thy) arity (tsig_of thy); arity end;
   418 
   419 val read_arity = prep_arity intern_type Syntax.read_sort_global;
   420 val cert_arity = prep_arity (K I) certify_sort;
   421 
   422 
   423 
   424 (** signature extension functions **)  (*exception ERROR/TYPE*)
   425 
   426 (* add default sort *)
   427 
   428 fun gen_add_defsort prep_sort s thy =
   429   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   430 
   431 val add_defsort = gen_add_defsort Syntax.read_sort_global;
   432 val add_defsort_i = gen_add_defsort certify_sort;
   433 
   434 
   435 (* add type constructors *)
   436 
   437 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   438   let
   439     val syn' = Syntax.update_type_gram types syn;
   440     val decls = map (fn (a, n, mx) => (Syntax.type_name a mx, n)) types;
   441     val tags = [(Markup.theory_nameN, Context.theory_name thy)];
   442     val tsig' = fold (Type.add_type naming tags) decls tsig;
   443   in (naming, syn', tsig', consts) end);
   444 
   445 
   446 (* add nonterminals *)
   447 
   448 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   449   let
   450     val syn' = Syntax.update_consts ns syn;
   451     val tsig' = fold (Type.add_nonterminal naming []) ns tsig;
   452   in (naming, syn', tsig', consts) end);
   453 
   454 
   455 (* add type abbreviations *)
   456 
   457 fun gen_add_tyabbr parse_typ (a, vs, rhs, mx) thy =
   458   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   459     let
   460       val ctxt = ProofContext.init thy;
   461       val syn' = Syntax.update_type_gram [(a, length vs, mx)] syn;
   462       val a' = Syntax.type_name a mx;
   463       val abbr = (a', vs, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt rhs))
   464         handle ERROR msg => cat_error msg ("in type abbreviation " ^ quote a');
   465       val tsig' = Type.add_abbrev naming [] abbr tsig;
   466     in (naming, syn', tsig', consts) end);
   467 
   468 val add_tyabbrs = fold (gen_add_tyabbr Syntax.parse_typ);
   469 val add_tyabbrs_i = fold (gen_add_tyabbr (K I));
   470 
   471 
   472 (* modify syntax *)
   473 
   474 fun gen_syntax change_gram parse_typ mode args thy =
   475   let
   476     val ctxt = ProofContext.init thy;
   477     fun prep (c, T, mx) = (c, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt T), mx)
   478       handle ERROR msg =>
   479         cat_error msg ("in syntax declaration " ^ quote (Syntax.const_name c mx));
   480   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   481 
   482 fun gen_add_syntax x = gen_syntax Syntax.update_const_gram x;
   483 
   484 val add_modesyntax = gen_add_syntax Syntax.parse_typ;
   485 val add_modesyntax_i = gen_add_syntax (K I);
   486 val add_syntax = add_modesyntax Syntax.mode_default;
   487 val add_syntax_i = add_modesyntax_i Syntax.mode_default;
   488 val del_modesyntax = gen_syntax Syntax.remove_const_gram Syntax.parse_typ;
   489 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram (K I);
   490 
   491 fun notation add mode args thy =
   492   let
   493     val change_gram = if add then Syntax.update_const_gram else Syntax.remove_const_gram;
   494     fun const_syntax (Const (c, _), mx) = try (Consts.syntax (consts_of thy)) (c, mx)
   495       | const_syntax _ = NONE;
   496   in gen_syntax change_gram (K I) mode (map_filter const_syntax args) thy end;
   497 
   498 
   499 (* add constants *)
   500 
   501 local
   502 
   503 fun gen_add_consts parse_typ authentic tags raw_args thy =
   504   let
   505     val ctxt = ProofContext.init thy;
   506     val prepT = Type.no_tvars o Term.no_dummyT o certify_typ thy o parse_typ ctxt;
   507     fun prep (raw_c, raw_T, raw_mx) =
   508       let
   509         val (c, mx) = Syntax.const_mixfix raw_c raw_mx;
   510         val full_c = full_name thy c;
   511         val c' = if authentic then Syntax.constN ^ full_c else c;
   512         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   513           cat_error msg ("in declaration of constant " ^ quote c);
   514         val T' = Logic.varifyT T;
   515       in ((c, T'), (c', T', mx), Const (full_c, T)) end;
   516     val args = map prep raw_args;
   517     val tags' = tags |> Properties.put (Markup.theory_nameN, Context.theory_name thy);
   518   in
   519     thy
   520     |> map_consts (fold (Consts.declare authentic (naming_of thy) tags' o #1) args)
   521     |> add_syntax_i (map #2 args)
   522     |> pair (map #3 args)
   523   end;
   524 
   525 in
   526 
   527 val add_consts = snd oo gen_add_consts Syntax.parse_typ false [];
   528 val add_consts_i = snd oo gen_add_consts (K I) false [];
   529 
   530 fun declare_const tags arg = gen_add_consts (K I) true tags [arg] #>> the_single;
   531 
   532 end;
   533 
   534 
   535 (* abbreviations *)
   536 
   537 fun add_abbrev mode tags (c, raw_t) thy =
   538   let
   539     val pp = Syntax.pp_global thy;
   540     val prep_tm = no_frees pp o Term.no_dummy_patterns o cert_term_abbrev thy;
   541     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   542       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote c);
   543     val (res, consts') = consts_of thy
   544       |> Consts.abbreviate pp (tsig_of thy) (naming_of thy) mode tags (c, t);
   545   in (res, thy |> map_consts (K consts')) end;
   546 
   547 fun revert_abbrev mode c = map_consts (Consts.revert_abbrev mode c);
   548 
   549 
   550 (* add constraints *)
   551 
   552 fun add_const_constraint (c, opt_T) thy =
   553   let
   554     fun prepT raw_T =
   555       let val T = Logic.varifyT (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   556       in cert_term thy (Const (c, T)); T end
   557       handle TYPE (msg, _, _) => error msg;
   558   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   559 
   560 
   561 (* primitive classes and arities *)
   562 
   563 fun primitive_class (bclass, classes) thy =
   564   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   565     let
   566       val syn' = Syntax.update_consts [bclass] syn;
   567       val tsig' = Type.add_class (Syntax.pp_global thy) naming (bclass, classes) tsig;
   568     in (naming, syn', tsig', consts) end)
   569   |> add_consts_i [(Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   570 
   571 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (Syntax.pp_global thy) arg);
   572 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (Syntax.pp_global thy) arg);
   573 
   574 
   575 (* add translation functions *)
   576 
   577 local
   578 
   579 fun mk trs = map Syntax.mk_trfun trs;
   580 
   581 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   582   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   583 
   584 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   585 
   586 in
   587 
   588 val add_trfuns = gen_add_trfuns Syntax.update_trfuns Syntax.non_typed_tr';
   589 val add_trfunsT = gen_add_trfunsT Syntax.update_trfuns;
   590 val add_advanced_trfuns = gen_add_trfuns Syntax.update_advanced_trfuns Syntax.non_typed_tr'';
   591 val add_advanced_trfunsT = gen_add_trfunsT Syntax.update_advanced_trfuns;
   592 
   593 end;
   594 
   595 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   596 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   597 
   598 
   599 (* translation rules *)
   600 
   601 fun gen_trrules f args thy = thy |> map_syn (fn syn =>
   602   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   603   in f (ProofContext.init thy) (is_logtype thy) syn rules syn end);
   604 
   605 val add_trrules = gen_trrules Syntax.update_trrules;
   606 val del_trrules = gen_trrules Syntax.remove_trrules;
   607 val add_trrules_i = map_syn o Syntax.update_trrules_i;
   608 val del_trrules_i = map_syn o Syntax.remove_trrules_i;
   609 
   610 
   611 (* naming *)
   612 
   613 val add_path        = map_naming o NameSpace.add_path;
   614 val no_base_names   = map_naming NameSpace.no_base_names;
   615 val qualified_names = map_naming NameSpace.qualified_names;
   616 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   617 val restore_naming  = map_naming o K o naming_of;
   618 
   619 val parent_path   = add_path "..";
   620 val root_path     = add_path "/";
   621 val absolute_path = add_path "//";
   622 
   623 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   624 
   625 
   626 (* hide names *)
   627 
   628 val hide_class = map_tsig oo Type.hide_class;
   629 val hide_type = map_tsig oo Type.hide_type;
   630 val hide_const = map_consts oo Consts.hide;
   631 
   632 end;