src/HOL/Limits.thy
author Manuel Eberl <eberlm@in.tum.de>
Thu Aug 25 15:50:43 2016 +0200 (2016-08-25)
changeset 63721 492bb53c3420
parent 63556 36e9732988ce
child 63915 bab633745c7f
permissions -rw-r--r--
More analysis lemmas
     1 (*  Title:      HOL/Limits.thy
     2     Author:     Brian Huffman
     3     Author:     Jacques D. Fleuriot, University of Cambridge
     4     Author:     Lawrence C Paulson
     5     Author:     Jeremy Avigad
     6 *)
     7 
     8 section \<open>Limits on Real Vector Spaces\<close>
     9 
    10 theory Limits
    11   imports Real_Vector_Spaces
    12 begin
    13 
    14 subsection \<open>Filter going to infinity norm\<close>
    15 
    16 definition at_infinity :: "'a::real_normed_vector filter"
    17   where "at_infinity = (INF r. principal {x. r \<le> norm x})"
    18 
    19 lemma eventually_at_infinity: "eventually P at_infinity \<longleftrightarrow> (\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> P x)"
    20   unfolding at_infinity_def
    21   by (subst eventually_INF_base)
    22      (auto simp: subset_eq eventually_principal intro!: exI[of _ "max a b" for a b])
    23 
    24 corollary eventually_at_infinity_pos:
    25   "eventually p at_infinity \<longleftrightarrow> (\<exists>b. 0 < b \<and> (\<forall>x. norm x \<ge> b \<longrightarrow> p x))"
    26   apply (simp add: eventually_at_infinity)
    27   apply auto
    28   apply (case_tac "b \<le> 0")
    29   using norm_ge_zero order_trans zero_less_one apply blast
    30   apply force
    31   done
    32 
    33 lemma at_infinity_eq_at_top_bot: "(at_infinity :: real filter) = sup at_top at_bot"
    34   apply (simp add: filter_eq_iff eventually_sup eventually_at_infinity
    35       eventually_at_top_linorder eventually_at_bot_linorder)
    36   apply safe
    37     apply (rule_tac x="b" in exI)
    38     apply simp
    39    apply (rule_tac x="- b" in exI)
    40    apply simp
    41   apply (rule_tac x="max (- Na) N" in exI)
    42   apply (auto simp: abs_real_def)
    43   done
    44 
    45 lemma at_top_le_at_infinity: "at_top \<le> (at_infinity :: real filter)"
    46   unfolding at_infinity_eq_at_top_bot by simp
    47 
    48 lemma at_bot_le_at_infinity: "at_bot \<le> (at_infinity :: real filter)"
    49   unfolding at_infinity_eq_at_top_bot by simp
    50 
    51 lemma filterlim_at_top_imp_at_infinity: "filterlim f at_top F \<Longrightarrow> filterlim f at_infinity F"
    52   for f :: "_ \<Rightarrow> real"
    53   by (rule filterlim_mono[OF _ at_top_le_at_infinity order_refl])
    54 
    55 lemma lim_infinity_imp_sequentially: "(f \<longlongrightarrow> l) at_infinity \<Longrightarrow> ((\<lambda>n. f(n)) \<longlongrightarrow> l) sequentially"
    56   by (simp add: filterlim_at_top_imp_at_infinity filterlim_compose filterlim_real_sequentially)
    57 
    58 
    59 subsubsection \<open>Boundedness\<close>
    60 
    61 definition Bfun :: "('a \<Rightarrow> 'b::metric_space) \<Rightarrow> 'a filter \<Rightarrow> bool"
    62   where Bfun_metric_def: "Bfun f F = (\<exists>y. \<exists>K>0. eventually (\<lambda>x. dist (f x) y \<le> K) F)"
    63 
    64 abbreviation Bseq :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool"
    65   where "Bseq X \<equiv> Bfun X sequentially"
    66 
    67 lemma Bseq_conv_Bfun: "Bseq X \<longleftrightarrow> Bfun X sequentially" ..
    68 
    69 lemma Bseq_ignore_initial_segment: "Bseq X \<Longrightarrow> Bseq (\<lambda>n. X (n + k))"
    70   unfolding Bfun_metric_def by (subst eventually_sequentially_seg)
    71 
    72 lemma Bseq_offset: "Bseq (\<lambda>n. X (n + k)) \<Longrightarrow> Bseq X"
    73   unfolding Bfun_metric_def by (subst (asm) eventually_sequentially_seg)
    74 
    75 lemma Bfun_def: "Bfun f F \<longleftrightarrow> (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) F)"
    76   unfolding Bfun_metric_def norm_conv_dist
    77 proof safe
    78   fix y K
    79   assume K: "0 < K" and *: "eventually (\<lambda>x. dist (f x) y \<le> K) F"
    80   moreover have "eventually (\<lambda>x. dist (f x) 0 \<le> dist (f x) y + dist 0 y) F"
    81     by (intro always_eventually) (metis dist_commute dist_triangle)
    82   with * have "eventually (\<lambda>x. dist (f x) 0 \<le> K + dist 0 y) F"
    83     by eventually_elim auto
    84   with \<open>0 < K\<close> show "\<exists>K>0. eventually (\<lambda>x. dist (f x) 0 \<le> K) F"
    85     by (intro exI[of _ "K + dist 0 y"] add_pos_nonneg conjI zero_le_dist) auto
    86 qed (force simp del: norm_conv_dist [symmetric])
    87 
    88 lemma BfunI:
    89   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) F"
    90   shows "Bfun f F"
    91   unfolding Bfun_def
    92 proof (intro exI conjI allI)
    93   show "0 < max K 1" by simp
    94   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) F"
    95     using K by (rule eventually_mono) simp
    96 qed
    97 
    98 lemma BfunE:
    99   assumes "Bfun f F"
   100   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) F"
   101   using assms unfolding Bfun_def by blast
   102 
   103 lemma Cauchy_Bseq: "Cauchy X \<Longrightarrow> Bseq X"
   104   unfolding Cauchy_def Bfun_metric_def eventually_sequentially
   105   apply (erule_tac x=1 in allE)
   106   apply simp
   107   apply safe
   108   apply (rule_tac x="X M" in exI)
   109   apply (rule_tac x=1 in exI)
   110   apply (erule_tac x=M in allE)
   111   apply simp
   112   apply (rule_tac x=M in exI)
   113   apply (auto simp: dist_commute)
   114   done
   115 
   116 
   117 subsubsection \<open>Bounded Sequences\<close>
   118 
   119 lemma BseqI': "(\<And>n. norm (X n) \<le> K) \<Longrightarrow> Bseq X"
   120   by (intro BfunI) (auto simp: eventually_sequentially)
   121 
   122 lemma BseqI2': "\<forall>n\<ge>N. norm (X n) \<le> K \<Longrightarrow> Bseq X"
   123   by (intro BfunI) (auto simp: eventually_sequentially)
   124 
   125 lemma Bseq_def: "Bseq X \<longleftrightarrow> (\<exists>K>0. \<forall>n. norm (X n) \<le> K)"
   126   unfolding Bfun_def eventually_sequentially
   127 proof safe
   128   fix N K
   129   assume "0 < K" "\<forall>n\<ge>N. norm (X n) \<le> K"
   130   then show "\<exists>K>0. \<forall>n. norm (X n) \<le> K"
   131     by (intro exI[of _ "max (Max (norm ` X ` {..N})) K"] max.strict_coboundedI2)
   132        (auto intro!: imageI not_less[where 'a=nat, THEN iffD1] Max_ge simp: le_max_iff_disj)
   133 qed auto
   134 
   135 lemma BseqE: "Bseq X \<Longrightarrow> (\<And>K. 0 < K \<Longrightarrow> \<forall>n. norm (X n) \<le> K \<Longrightarrow> Q) \<Longrightarrow> Q"
   136   unfolding Bseq_def by auto
   137 
   138 lemma BseqD: "Bseq X \<Longrightarrow> \<exists>K. 0 < K \<and> (\<forall>n. norm (X n) \<le> K)"
   139   by (simp add: Bseq_def)
   140 
   141 lemma BseqI: "0 < K \<Longrightarrow> \<forall>n. norm (X n) \<le> K \<Longrightarrow> Bseq X"
   142   by (auto simp add: Bseq_def)
   143 
   144 lemma Bseq_bdd_above: "Bseq X \<Longrightarrow> bdd_above (range X)"
   145   for X :: "nat \<Rightarrow> real"
   146 proof (elim BseqE, intro bdd_aboveI2)
   147   fix K n
   148   assume "0 < K" "\<forall>n. norm (X n) \<le> K"
   149   then show "X n \<le> K"
   150     by (auto elim!: allE[of _ n])
   151 qed
   152 
   153 lemma Bseq_bdd_above': "Bseq X \<Longrightarrow> bdd_above (range (\<lambda>n. norm (X n)))"
   154   for X :: "nat \<Rightarrow> 'a :: real_normed_vector"
   155 proof (elim BseqE, intro bdd_aboveI2)
   156   fix K n
   157   assume "0 < K" "\<forall>n. norm (X n) \<le> K"
   158   then show "norm (X n) \<le> K"
   159     by (auto elim!: allE[of _ n])
   160 qed
   161 
   162 lemma Bseq_bdd_below: "Bseq X \<Longrightarrow> bdd_below (range X)"
   163   for X :: "nat \<Rightarrow> real"
   164 proof (elim BseqE, intro bdd_belowI2)
   165   fix K n
   166   assume "0 < K" "\<forall>n. norm (X n) \<le> K"
   167   then show "- K \<le> X n"
   168     by (auto elim!: allE[of _ n])
   169 qed
   170 
   171 lemma Bseq_eventually_mono:
   172   assumes "eventually (\<lambda>n. norm (f n) \<le> norm (g n)) sequentially" "Bseq g"
   173   shows "Bseq f"
   174 proof -
   175   from assms(1) obtain N where N: "\<And>n. n \<ge> N \<Longrightarrow> norm (f n) \<le> norm (g n)"
   176     by (auto simp: eventually_at_top_linorder)
   177   moreover from assms(2) obtain K where K: "\<And>n. norm (g n) \<le> K"
   178     by (blast elim!: BseqE)
   179   ultimately have "norm (f n) \<le> max K (Max {norm (f n) |n. n < N})" for n
   180     apply (cases "n < N")
   181     subgoal by (rule max.coboundedI2, rule Max.coboundedI) auto
   182     subgoal by (rule max.coboundedI1) (force intro: order.trans[OF N K])
   183     done
   184   then show ?thesis by (blast intro: BseqI')
   185 qed
   186 
   187 lemma lemma_NBseq_def: "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) \<longleftrightarrow> (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   188 proof safe
   189   fix K :: real
   190   from reals_Archimedean2 obtain n :: nat where "K < real n" ..
   191   then have "K \<le> real (Suc n)" by auto
   192   moreover assume "\<forall>m. norm (X m) \<le> K"
   193   ultimately have "\<forall>m. norm (X m) \<le> real (Suc n)"
   194     by (blast intro: order_trans)
   195   then show "\<exists>N. \<forall>n. norm (X n) \<le> real (Suc N)" ..
   196 next
   197   show "\<And>N. \<forall>n. norm (X n) \<le> real (Suc N) \<Longrightarrow> \<exists>K>0. \<forall>n. norm (X n) \<le> K"
   198     using of_nat_0_less_iff by blast
   199 qed
   200 
   201 text \<open>Alternative definition for \<open>Bseq\<close>.\<close>
   202 lemma Bseq_iff: "Bseq X \<longleftrightarrow> (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   203   by (simp add: Bseq_def) (simp add: lemma_NBseq_def)
   204 
   205 lemma lemma_NBseq_def2: "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   206   apply (subst lemma_NBseq_def)
   207   apply auto
   208    apply (rule_tac x = "Suc N" in exI)
   209    apply (rule_tac [2] x = N in exI)
   210    apply auto
   211    prefer 2 apply (blast intro: order_less_imp_le)
   212   apply (drule_tac x = n in spec)
   213   apply simp
   214   done
   215 
   216 text \<open>Yet another definition for Bseq.\<close>
   217 lemma Bseq_iff1a: "Bseq X \<longleftrightarrow> (\<exists>N. \<forall>n. norm (X n) < real (Suc N))"
   218   by (simp add: Bseq_def lemma_NBseq_def2)
   219 
   220 subsubsection \<open>A Few More Equivalence Theorems for Boundedness\<close>
   221 
   222 text \<open>Alternative formulation for boundedness.\<close>
   223 lemma Bseq_iff2: "Bseq X \<longleftrightarrow> (\<exists>k > 0. \<exists>x. \<forall>n. norm (X n + - x) \<le> k)"
   224   apply (unfold Bseq_def)
   225   apply safe
   226    apply (rule_tac [2] x = "k + norm x" in exI)
   227    apply (rule_tac x = K in exI)
   228    apply simp
   229    apply (rule exI [where x = 0])
   230    apply auto
   231    apply (erule order_less_le_trans)
   232    apply simp
   233   apply (drule_tac x=n in spec)
   234   apply (drule order_trans [OF norm_triangle_ineq2])
   235   apply simp
   236   done
   237 
   238 text \<open>Alternative formulation for boundedness.\<close>
   239 lemma Bseq_iff3: "Bseq X \<longleftrightarrow> (\<exists>k>0. \<exists>N. \<forall>n. norm (X n + - X N) \<le> k)"
   240   (is "?P \<longleftrightarrow> ?Q")
   241 proof
   242   assume ?P
   243   then obtain K where *: "0 < K" and **: "\<And>n. norm (X n) \<le> K"
   244     by (auto simp add: Bseq_def)
   245   from * have "0 < K + norm (X 0)" by (rule order_less_le_trans) simp
   246   from ** have "\<forall>n. norm (X n - X 0) \<le> K + norm (X 0)"
   247     by (auto intro: order_trans norm_triangle_ineq4)
   248   then have "\<forall>n. norm (X n + - X 0) \<le> K + norm (X 0)"
   249     by simp
   250   with \<open>0 < K + norm (X 0)\<close> show ?Q by blast
   251 next
   252   assume ?Q
   253   then show ?P by (auto simp add: Bseq_iff2)
   254 qed
   255 
   256 lemma BseqI2: "\<forall>n. k \<le> f n \<and> f n \<le> K \<Longrightarrow> Bseq f"
   257   for k K :: real
   258   apply (simp add: Bseq_def)
   259   apply (rule_tac x = "(\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI)
   260   apply auto
   261   apply (drule_tac x = n in spec)
   262   apply arith
   263   done
   264 
   265 
   266 subsubsection \<open>Upper Bounds and Lubs of Bounded Sequences\<close>
   267 
   268 lemma Bseq_minus_iff: "Bseq (\<lambda>n. - (X n) :: 'a::real_normed_vector) \<longleftrightarrow> Bseq X"
   269   by (simp add: Bseq_def)
   270 
   271 lemma Bseq_add:
   272   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   273   assumes "Bseq f"
   274   shows "Bseq (\<lambda>x. f x + c)"
   275 proof -
   276   from assms obtain K where K: "\<And>x. norm (f x) \<le> K"
   277     unfolding Bseq_def by blast
   278   {
   279     fix x :: nat
   280     have "norm (f x + c) \<le> norm (f x) + norm c" by (rule norm_triangle_ineq)
   281     also have "norm (f x) \<le> K" by (rule K)
   282     finally have "norm (f x + c) \<le> K + norm c" by simp
   283   }
   284   then show ?thesis by (rule BseqI')
   285 qed
   286 
   287 lemma Bseq_add_iff: "Bseq (\<lambda>x. f x + c) \<longleftrightarrow> Bseq f"
   288   for f :: "nat \<Rightarrow> 'a::real_normed_vector"
   289   using Bseq_add[of f c] Bseq_add[of "\<lambda>x. f x + c" "-c"] by auto
   290 
   291 lemma Bseq_mult:
   292   fixes f g :: "nat \<Rightarrow> 'a::real_normed_field"
   293   assumes "Bseq f" and "Bseq g"
   294   shows "Bseq (\<lambda>x. f x * g x)"
   295 proof -
   296   from assms obtain K1 K2 where K: "norm (f x) \<le> K1" "K1 > 0" "norm (g x) \<le> K2" "K2 > 0"
   297     for x
   298     unfolding Bseq_def by blast
   299   then have "norm (f x * g x) \<le> K1 * K2" for x
   300     by (auto simp: norm_mult intro!: mult_mono)
   301   then show ?thesis by (rule BseqI')
   302 qed
   303 
   304 lemma Bfun_const [simp]: "Bfun (\<lambda>_. c) F"
   305   unfolding Bfun_metric_def by (auto intro!: exI[of _ c] exI[of _ "1::real"])
   306 
   307 lemma Bseq_cmult_iff:
   308   fixes c :: "'a::real_normed_field"
   309   assumes "c \<noteq> 0"
   310   shows "Bseq (\<lambda>x. c * f x) \<longleftrightarrow> Bseq f"
   311 proof
   312   assume "Bseq (\<lambda>x. c * f x)"
   313   with Bfun_const have "Bseq (\<lambda>x. inverse c * (c * f x))"
   314     by (rule Bseq_mult)
   315   with \<open>c \<noteq> 0\<close> show "Bseq f"
   316     by (simp add: divide_simps)
   317 qed (intro Bseq_mult Bfun_const)
   318 
   319 lemma Bseq_subseq: "Bseq f \<Longrightarrow> Bseq (\<lambda>x. f (g x))"
   320   for f :: "nat \<Rightarrow> 'a::real_normed_vector"
   321   unfolding Bseq_def by auto
   322 
   323 lemma Bseq_Suc_iff: "Bseq (\<lambda>n. f (Suc n)) \<longleftrightarrow> Bseq f"
   324   for f :: "nat \<Rightarrow> 'a::real_normed_vector"
   325   using Bseq_offset[of f 1] by (auto intro: Bseq_subseq)
   326 
   327 lemma increasing_Bseq_subseq_iff:
   328   assumes "\<And>x y. x \<le> y \<Longrightarrow> norm (f x :: 'a::real_normed_vector) \<le> norm (f y)" "subseq g"
   329   shows "Bseq (\<lambda>x. f (g x)) \<longleftrightarrow> Bseq f"
   330 proof
   331   assume "Bseq (\<lambda>x. f (g x))"
   332   then obtain K where K: "\<And>x. norm (f (g x)) \<le> K"
   333     unfolding Bseq_def by auto
   334   {
   335     fix x :: nat
   336     from filterlim_subseq[OF assms(2)] obtain y where "g y \<ge> x"
   337       by (auto simp: filterlim_at_top eventually_at_top_linorder)
   338     then have "norm (f x) \<le> norm (f (g y))"
   339       using assms(1) by blast
   340     also have "norm (f (g y)) \<le> K" by (rule K)
   341     finally have "norm (f x) \<le> K" .
   342   }
   343   then show "Bseq f" by (rule BseqI')
   344 qed (use Bseq_subseq[of f g] in simp_all)
   345 
   346 lemma nonneg_incseq_Bseq_subseq_iff:
   347   fixes f :: "nat \<Rightarrow> real"
   348     and g :: "nat \<Rightarrow> nat"
   349   assumes "\<And>x. f x \<ge> 0" "incseq f" "subseq g"
   350   shows "Bseq (\<lambda>x. f (g x)) \<longleftrightarrow> Bseq f"
   351   using assms by (intro increasing_Bseq_subseq_iff) (auto simp: incseq_def)
   352 
   353 lemma Bseq_eq_bounded: "range f \<subseteq> {a..b} \<Longrightarrow> Bseq f"
   354   for a b :: real
   355   apply (simp add: subset_eq)
   356   apply (rule BseqI'[where K="max (norm a) (norm b)"])
   357   apply (erule_tac x=n in allE)
   358   apply auto
   359   done
   360 
   361 lemma incseq_bounded: "incseq X \<Longrightarrow> \<forall>i. X i \<le> B \<Longrightarrow> Bseq X"
   362   for B :: real
   363   by (intro Bseq_eq_bounded[of X "X 0" B]) (auto simp: incseq_def)
   364 
   365 lemma decseq_bounded: "decseq X \<Longrightarrow> \<forall>i. B \<le> X i \<Longrightarrow> Bseq X"
   366   for B :: real
   367   by (intro Bseq_eq_bounded[of X B "X 0"]) (auto simp: decseq_def)
   368 
   369 
   370 subsection \<open>Bounded Monotonic Sequences\<close>
   371 
   372 subsubsection \<open>A Bounded and Monotonic Sequence Converges\<close>
   373 
   374 (* TODO: delete *)
   375 (* FIXME: one use in NSA/HSEQ.thy *)
   376 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n \<longrightarrow> X n = X m \<Longrightarrow> \<exists>L. X \<longlonglongrightarrow> L"
   377   apply (rule_tac x="X m" in exI)
   378   apply (rule filterlim_cong[THEN iffD2, OF refl refl _ tendsto_const])
   379   unfolding eventually_sequentially
   380   apply blast
   381   done
   382 
   383 
   384 subsection \<open>Convergence to Zero\<close>
   385 
   386 definition Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   387   where "Zfun f F = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) F)"
   388 
   389 lemma ZfunI: "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F) \<Longrightarrow> Zfun f F"
   390   by (simp add: Zfun_def)
   391 
   392 lemma ZfunD: "Zfun f F \<Longrightarrow> 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F"
   393   by (simp add: Zfun_def)
   394 
   395 lemma Zfun_ssubst: "eventually (\<lambda>x. f x = g x) F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun f F"
   396   unfolding Zfun_def by (auto elim!: eventually_rev_mp)
   397 
   398 lemma Zfun_zero: "Zfun (\<lambda>x. 0) F"
   399   unfolding Zfun_def by simp
   400 
   401 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) F = Zfun (\<lambda>x. f x) F"
   402   unfolding Zfun_def by simp
   403 
   404 lemma Zfun_imp_Zfun:
   405   assumes f: "Zfun f F"
   406     and g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F"
   407   shows "Zfun (\<lambda>x. g x) F"
   408 proof (cases "0 < K")
   409   case K: True
   410   show ?thesis
   411   proof (rule ZfunI)
   412     fix r :: real
   413     assume "0 < r"
   414     then have "0 < r / K" using K by simp
   415     then have "eventually (\<lambda>x. norm (f x) < r / K) F"
   416       using ZfunD [OF f] by blast
   417     with g show "eventually (\<lambda>x. norm (g x) < r) F"
   418     proof eventually_elim
   419       case (elim x)
   420       then have "norm (f x) * K < r"
   421         by (simp add: pos_less_divide_eq K)
   422       then show ?case
   423         by (simp add: order_le_less_trans [OF elim(1)])
   424     qed
   425   qed
   426 next
   427   case False
   428   then have K: "K \<le> 0" by (simp only: not_less)
   429   show ?thesis
   430   proof (rule ZfunI)
   431     fix r :: real
   432     assume "0 < r"
   433     from g show "eventually (\<lambda>x. norm (g x) < r) F"
   434     proof eventually_elim
   435       case (elim x)
   436       also have "norm (f x) * K \<le> norm (f x) * 0"
   437         using K norm_ge_zero by (rule mult_left_mono)
   438       finally show ?case
   439         using \<open>0 < r\<close> by simp
   440     qed
   441   qed
   442 qed
   443 
   444 lemma Zfun_le: "Zfun g F \<Longrightarrow> \<forall>x. norm (f x) \<le> norm (g x) \<Longrightarrow> Zfun f F"
   445   by (erule Zfun_imp_Zfun [where K = 1]) simp
   446 
   447 lemma Zfun_add:
   448   assumes f: "Zfun f F"
   449     and g: "Zfun g F"
   450   shows "Zfun (\<lambda>x. f x + g x) F"
   451 proof (rule ZfunI)
   452   fix r :: real
   453   assume "0 < r"
   454   then have r: "0 < r / 2" by simp
   455   have "eventually (\<lambda>x. norm (f x) < r/2) F"
   456     using f r by (rule ZfunD)
   457   moreover
   458   have "eventually (\<lambda>x. norm (g x) < r/2) F"
   459     using g r by (rule ZfunD)
   460   ultimately
   461   show "eventually (\<lambda>x. norm (f x + g x) < r) F"
   462   proof eventually_elim
   463     case (elim x)
   464     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
   465       by (rule norm_triangle_ineq)
   466     also have "\<dots> < r/2 + r/2"
   467       using elim by (rule add_strict_mono)
   468     finally show ?case
   469       by simp
   470   qed
   471 qed
   472 
   473 lemma Zfun_minus: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. - f x) F"
   474   unfolding Zfun_def by simp
   475 
   476 lemma Zfun_diff: "Zfun f F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun (\<lambda>x. f x - g x) F"
   477   using Zfun_add [of f F "\<lambda>x. - g x"] by (simp add: Zfun_minus)
   478 
   479 lemma (in bounded_linear) Zfun:
   480   assumes g: "Zfun g F"
   481   shows "Zfun (\<lambda>x. f (g x)) F"
   482 proof -
   483   obtain K where "norm (f x) \<le> norm x * K" for x
   484     using bounded by blast
   485   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) F"
   486     by simp
   487   with g show ?thesis
   488     by (rule Zfun_imp_Zfun)
   489 qed
   490 
   491 lemma (in bounded_bilinear) Zfun:
   492   assumes f: "Zfun f F"
   493     and g: "Zfun g F"
   494   shows "Zfun (\<lambda>x. f x ** g x) F"
   495 proof (rule ZfunI)
   496   fix r :: real
   497   assume r: "0 < r"
   498   obtain K where K: "0 < K"
   499     and norm_le: "norm (x ** y) \<le> norm x * norm y * K" for x y
   500     using pos_bounded by blast
   501   from K have K': "0 < inverse K"
   502     by (rule positive_imp_inverse_positive)
   503   have "eventually (\<lambda>x. norm (f x) < r) F"
   504     using f r by (rule ZfunD)
   505   moreover
   506   have "eventually (\<lambda>x. norm (g x) < inverse K) F"
   507     using g K' by (rule ZfunD)
   508   ultimately
   509   show "eventually (\<lambda>x. norm (f x ** g x) < r) F"
   510   proof eventually_elim
   511     case (elim x)
   512     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   513       by (rule norm_le)
   514     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
   515       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero elim K)
   516     also from K have "r * inverse K * K = r"
   517       by simp
   518     finally show ?case .
   519   qed
   520 qed
   521 
   522 lemma (in bounded_bilinear) Zfun_left: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. f x ** a) F"
   523   by (rule bounded_linear_left [THEN bounded_linear.Zfun])
   524 
   525 lemma (in bounded_bilinear) Zfun_right: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. a ** f x) F"
   526   by (rule bounded_linear_right [THEN bounded_linear.Zfun])
   527 
   528 lemmas Zfun_mult = bounded_bilinear.Zfun [OF bounded_bilinear_mult]
   529 lemmas Zfun_mult_right = bounded_bilinear.Zfun_right [OF bounded_bilinear_mult]
   530 lemmas Zfun_mult_left = bounded_bilinear.Zfun_left [OF bounded_bilinear_mult]
   531 
   532 lemma tendsto_Zfun_iff: "(f \<longlongrightarrow> a) F = Zfun (\<lambda>x. f x - a) F"
   533   by (simp only: tendsto_iff Zfun_def dist_norm)
   534 
   535 lemma tendsto_0_le:
   536   "(f \<longlongrightarrow> 0) F \<Longrightarrow> eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F \<Longrightarrow> (g \<longlongrightarrow> 0) F"
   537   by (simp add: Zfun_imp_Zfun tendsto_Zfun_iff)
   538 
   539 
   540 subsubsection \<open>Distance and norms\<close>
   541 
   542 lemma tendsto_dist [tendsto_intros]:
   543   fixes l m :: "'a::metric_space"
   544   assumes f: "(f \<longlongrightarrow> l) F"
   545     and g: "(g \<longlongrightarrow> m) F"
   546   shows "((\<lambda>x. dist (f x) (g x)) \<longlongrightarrow> dist l m) F"
   547 proof (rule tendstoI)
   548   fix e :: real
   549   assume "0 < e"
   550   then have e2: "0 < e/2" by simp
   551   from tendstoD [OF f e2] tendstoD [OF g e2]
   552   show "eventually (\<lambda>x. dist (dist (f x) (g x)) (dist l m) < e) F"
   553   proof (eventually_elim)
   554     case (elim x)
   555     then show "dist (dist (f x) (g x)) (dist l m) < e"
   556       unfolding dist_real_def
   557       using dist_triangle2 [of "f x" "g x" "l"]
   558         and dist_triangle2 [of "g x" "l" "m"]
   559         and dist_triangle3 [of "l" "m" "f x"]
   560         and dist_triangle [of "f x" "m" "g x"]
   561       by arith
   562   qed
   563 qed
   564 
   565 lemma continuous_dist[continuous_intros]:
   566   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   567   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. dist (f x) (g x))"
   568   unfolding continuous_def by (rule tendsto_dist)
   569 
   570 lemma continuous_on_dist[continuous_intros]:
   571   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   572   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. dist (f x) (g x))"
   573   unfolding continuous_on_def by (auto intro: tendsto_dist)
   574 
   575 lemma tendsto_norm [tendsto_intros]: "(f \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. norm (f x)) \<longlongrightarrow> norm a) F"
   576   unfolding norm_conv_dist by (intro tendsto_intros)
   577 
   578 lemma continuous_norm [continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. norm (f x))"
   579   unfolding continuous_def by (rule tendsto_norm)
   580 
   581 lemma continuous_on_norm [continuous_intros]:
   582   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. norm (f x))"
   583   unfolding continuous_on_def by (auto intro: tendsto_norm)
   584 
   585 lemma tendsto_norm_zero: "(f \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. norm (f x)) \<longlongrightarrow> 0) F"
   586   by (drule tendsto_norm) simp
   587 
   588 lemma tendsto_norm_zero_cancel: "((\<lambda>x. norm (f x)) \<longlongrightarrow> 0) F \<Longrightarrow> (f \<longlongrightarrow> 0) F"
   589   unfolding tendsto_iff dist_norm by simp
   590 
   591 lemma tendsto_norm_zero_iff: "((\<lambda>x. norm (f x)) \<longlongrightarrow> 0) F \<longleftrightarrow> (f \<longlongrightarrow> 0) F"
   592   unfolding tendsto_iff dist_norm by simp
   593 
   594 lemma tendsto_rabs [tendsto_intros]: "(f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> \<bar>l\<bar>) F"
   595   for l :: real
   596   by (fold real_norm_def) (rule tendsto_norm)
   597 
   598 lemma continuous_rabs [continuous_intros]:
   599   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. \<bar>f x :: real\<bar>)"
   600   unfolding real_norm_def[symmetric] by (rule continuous_norm)
   601 
   602 lemma continuous_on_rabs [continuous_intros]:
   603   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. \<bar>f x :: real\<bar>)"
   604   unfolding real_norm_def[symmetric] by (rule continuous_on_norm)
   605 
   606 lemma tendsto_rabs_zero: "(f \<longlongrightarrow> (0::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> 0) F"
   607   by (fold real_norm_def) (rule tendsto_norm_zero)
   608 
   609 lemma tendsto_rabs_zero_cancel: "((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> (0::real)) F \<Longrightarrow> (f \<longlongrightarrow> 0) F"
   610   by (fold real_norm_def) (rule tendsto_norm_zero_cancel)
   611 
   612 lemma tendsto_rabs_zero_iff: "((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> (0::real)) F \<longleftrightarrow> (f \<longlongrightarrow> 0) F"
   613   by (fold real_norm_def) (rule tendsto_norm_zero_iff)
   614 
   615 
   616 subsection \<open>Topological Monoid\<close>
   617 
   618 class topological_monoid_add = topological_space + monoid_add +
   619   assumes tendsto_add_Pair: "LIM x (nhds a \<times>\<^sub>F nhds b). fst x + snd x :> nhds (a + b)"
   620 
   621 class topological_comm_monoid_add = topological_monoid_add + comm_monoid_add
   622 
   623 lemma tendsto_add [tendsto_intros]:
   624   fixes a b :: "'a::topological_monoid_add"
   625   shows "(f \<longlongrightarrow> a) F \<Longrightarrow> (g \<longlongrightarrow> b) F \<Longrightarrow> ((\<lambda>x. f x + g x) \<longlongrightarrow> a + b) F"
   626   using filterlim_compose[OF tendsto_add_Pair, of "\<lambda>x. (f x, g x)" a b F]
   627   by (simp add: nhds_prod[symmetric] tendsto_Pair)
   628 
   629 lemma continuous_add [continuous_intros]:
   630   fixes f g :: "_ \<Rightarrow> 'b::topological_monoid_add"
   631   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x + g x)"
   632   unfolding continuous_def by (rule tendsto_add)
   633 
   634 lemma continuous_on_add [continuous_intros]:
   635   fixes f g :: "_ \<Rightarrow> 'b::topological_monoid_add"
   636   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x + g x)"
   637   unfolding continuous_on_def by (auto intro: tendsto_add)
   638 
   639 lemma tendsto_add_zero:
   640   fixes f g :: "_ \<Rightarrow> 'b::topological_monoid_add"
   641   shows "(f \<longlongrightarrow> 0) F \<Longrightarrow> (g \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. f x + g x) \<longlongrightarrow> 0) F"
   642   by (drule (1) tendsto_add) simp
   643 
   644 lemma tendsto_setsum [tendsto_intros]:
   645   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::topological_comm_monoid_add"
   646   assumes "\<And>i. i \<in> I \<Longrightarrow> (f i \<longlongrightarrow> a i) F"
   647   shows "((\<lambda>x. \<Sum>i\<in>I. f i x) \<longlongrightarrow> (\<Sum>i\<in>I. a i)) F"
   648 proof (cases "finite I")
   649   case True
   650   then show ?thesis
   651     using assms by induct (simp_all add: tendsto_add)
   652 next
   653   case False
   654   then show ?thesis
   655     by simp
   656 qed
   657 
   658 lemma continuous_setsum [continuous_intros]:
   659   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::topological_comm_monoid_add"
   660   shows "(\<And>i. i \<in> I \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Sum>i\<in>I. f i x)"
   661   unfolding continuous_def by (rule tendsto_setsum)
   662 
   663 lemma continuous_on_setsum [continuous_intros]:
   664   fixes f :: "'a \<Rightarrow> 'b::topological_space \<Rightarrow> 'c::topological_comm_monoid_add"
   665   shows "(\<And>i. i \<in> I \<Longrightarrow> continuous_on S (f i)) \<Longrightarrow> continuous_on S (\<lambda>x. \<Sum>i\<in>I. f i x)"
   666   unfolding continuous_on_def by (auto intro: tendsto_setsum)
   667 
   668 instance nat :: topological_comm_monoid_add
   669   by standard
   670     (simp add: nhds_discrete principal_prod_principal filterlim_principal eventually_principal)
   671 
   672 instance int :: topological_comm_monoid_add
   673   by standard
   674     (simp add: nhds_discrete principal_prod_principal filterlim_principal eventually_principal)
   675 
   676 
   677 subsubsection \<open>Topological group\<close>
   678 
   679 class topological_group_add = topological_monoid_add + group_add +
   680   assumes tendsto_uminus_nhds: "(uminus \<longlongrightarrow> - a) (nhds a)"
   681 begin
   682 
   683 lemma tendsto_minus [tendsto_intros]: "(f \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. - f x) \<longlongrightarrow> - a) F"
   684   by (rule filterlim_compose[OF tendsto_uminus_nhds])
   685 
   686 end
   687 
   688 class topological_ab_group_add = topological_group_add + ab_group_add
   689 
   690 instance topological_ab_group_add < topological_comm_monoid_add ..
   691 
   692 lemma continuous_minus [continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. - f x)"
   693   for f :: "'a::t2_space \<Rightarrow> 'b::topological_group_add"
   694   unfolding continuous_def by (rule tendsto_minus)
   695 
   696 lemma continuous_on_minus [continuous_intros]: "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. - f x)"
   697   for f :: "_ \<Rightarrow> 'b::topological_group_add"
   698   unfolding continuous_on_def by (auto intro: tendsto_minus)
   699 
   700 lemma tendsto_minus_cancel: "((\<lambda>x. - f x) \<longlongrightarrow> - a) F \<Longrightarrow> (f \<longlongrightarrow> a) F"
   701   for a :: "'a::topological_group_add"
   702   by (drule tendsto_minus) simp
   703 
   704 lemma tendsto_minus_cancel_left:
   705   "(f \<longlongrightarrow> - (y::_::topological_group_add)) F \<longleftrightarrow> ((\<lambda>x. - f x) \<longlongrightarrow> y) F"
   706   using tendsto_minus_cancel[of f "- y" F]  tendsto_minus[of f "- y" F]
   707   by auto
   708 
   709 lemma tendsto_diff [tendsto_intros]:
   710   fixes a b :: "'a::topological_group_add"
   711   shows "(f \<longlongrightarrow> a) F \<Longrightarrow> (g \<longlongrightarrow> b) F \<Longrightarrow> ((\<lambda>x. f x - g x) \<longlongrightarrow> a - b) F"
   712   using tendsto_add [of f a F "\<lambda>x. - g x" "- b"] by (simp add: tendsto_minus)
   713 
   714 lemma continuous_diff [continuous_intros]:
   715   fixes f g :: "'a::t2_space \<Rightarrow> 'b::topological_group_add"
   716   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x - g x)"
   717   unfolding continuous_def by (rule tendsto_diff)
   718 
   719 lemma continuous_on_diff [continuous_intros]:
   720   fixes f g :: "_ \<Rightarrow> 'b::topological_group_add"
   721   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x - g x)"
   722   unfolding continuous_on_def by (auto intro: tendsto_diff)
   723 
   724 lemma continuous_on_op_minus: "continuous_on (s::'a::topological_group_add set) (op - x)"
   725   by (rule continuous_intros | simp)+
   726 
   727 instance real_normed_vector < topological_ab_group_add
   728 proof
   729   fix a b :: 'a
   730   show "((\<lambda>x. fst x + snd x) \<longlongrightarrow> a + b) (nhds a \<times>\<^sub>F nhds b)"
   731     unfolding tendsto_Zfun_iff add_diff_add
   732     using tendsto_fst[OF filterlim_ident, of "(a,b)"] tendsto_snd[OF filterlim_ident, of "(a,b)"]
   733     by (intro Zfun_add)
   734        (auto simp add: tendsto_Zfun_iff[symmetric] nhds_prod[symmetric] intro!: tendsto_fst)
   735   show "(uminus \<longlongrightarrow> - a) (nhds a)"
   736     unfolding tendsto_Zfun_iff minus_diff_minus
   737     using filterlim_ident[of "nhds a"]
   738     by (intro Zfun_minus) (simp add: tendsto_Zfun_iff)
   739 qed
   740 
   741 lemmas real_tendsto_sandwich = tendsto_sandwich[where 'b=real]
   742 
   743 
   744 subsubsection \<open>Linear operators and multiplication\<close>
   745 
   746 lemma linear_times: "linear (\<lambda>x. c * x)"
   747   for c :: "'a::real_algebra"
   748   by (auto simp: linearI distrib_left)
   749 
   750 lemma (in bounded_linear) tendsto: "(g \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. f (g x)) \<longlongrightarrow> f a) F"
   751   by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
   752 
   753 lemma (in bounded_linear) continuous: "continuous F g \<Longrightarrow> continuous F (\<lambda>x. f (g x))"
   754   using tendsto[of g _ F] by (auto simp: continuous_def)
   755 
   756 lemma (in bounded_linear) continuous_on: "continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f (g x))"
   757   using tendsto[of g] by (auto simp: continuous_on_def)
   758 
   759 lemma (in bounded_linear) tendsto_zero: "(g \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. f (g x)) \<longlongrightarrow> 0) F"
   760   by (drule tendsto) (simp only: zero)
   761 
   762 lemma (in bounded_bilinear) tendsto:
   763   "(f \<longlongrightarrow> a) F \<Longrightarrow> (g \<longlongrightarrow> b) F \<Longrightarrow> ((\<lambda>x. f x ** g x) \<longlongrightarrow> a ** b) F"
   764   by (simp only: tendsto_Zfun_iff prod_diff_prod Zfun_add Zfun Zfun_left Zfun_right)
   765 
   766 lemma (in bounded_bilinear) continuous:
   767   "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x ** g x)"
   768   using tendsto[of f _ F g] by (auto simp: continuous_def)
   769 
   770 lemma (in bounded_bilinear) continuous_on:
   771   "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x ** g x)"
   772   using tendsto[of f _ _ g] by (auto simp: continuous_on_def)
   773 
   774 lemma (in bounded_bilinear) tendsto_zero:
   775   assumes f: "(f \<longlongrightarrow> 0) F"
   776     and g: "(g \<longlongrightarrow> 0) F"
   777   shows "((\<lambda>x. f x ** g x) \<longlongrightarrow> 0) F"
   778   using tendsto [OF f g] by (simp add: zero_left)
   779 
   780 lemma (in bounded_bilinear) tendsto_left_zero:
   781   "(f \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. f x ** c) \<longlongrightarrow> 0) F"
   782   by (rule bounded_linear.tendsto_zero [OF bounded_linear_left])
   783 
   784 lemma (in bounded_bilinear) tendsto_right_zero:
   785   "(f \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. c ** f x) \<longlongrightarrow> 0) F"
   786   by (rule bounded_linear.tendsto_zero [OF bounded_linear_right])
   787 
   788 lemmas tendsto_of_real [tendsto_intros] =
   789   bounded_linear.tendsto [OF bounded_linear_of_real]
   790 
   791 lemmas tendsto_scaleR [tendsto_intros] =
   792   bounded_bilinear.tendsto [OF bounded_bilinear_scaleR]
   793 
   794 lemmas tendsto_mult [tendsto_intros] =
   795   bounded_bilinear.tendsto [OF bounded_bilinear_mult]
   796 
   797 lemma tendsto_mult_left: "(f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. c * (f x)) \<longlongrightarrow> c * l) F"
   798   for c :: "'a::real_normed_algebra"
   799   by (rule tendsto_mult [OF tendsto_const])
   800 
   801 lemma tendsto_mult_right: "(f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. (f x) * c) \<longlongrightarrow> l * c) F"
   802   for c :: "'a::real_normed_algebra"
   803   by (rule tendsto_mult [OF _ tendsto_const])
   804 
   805 lemmas continuous_of_real [continuous_intros] =
   806   bounded_linear.continuous [OF bounded_linear_of_real]
   807 
   808 lemmas continuous_scaleR [continuous_intros] =
   809   bounded_bilinear.continuous [OF bounded_bilinear_scaleR]
   810 
   811 lemmas continuous_mult [continuous_intros] =
   812   bounded_bilinear.continuous [OF bounded_bilinear_mult]
   813 
   814 lemmas continuous_on_of_real [continuous_intros] =
   815   bounded_linear.continuous_on [OF bounded_linear_of_real]
   816 
   817 lemmas continuous_on_scaleR [continuous_intros] =
   818   bounded_bilinear.continuous_on [OF bounded_bilinear_scaleR]
   819 
   820 lemmas continuous_on_mult [continuous_intros] =
   821   bounded_bilinear.continuous_on [OF bounded_bilinear_mult]
   822 
   823 lemmas tendsto_mult_zero =
   824   bounded_bilinear.tendsto_zero [OF bounded_bilinear_mult]
   825 
   826 lemmas tendsto_mult_left_zero =
   827   bounded_bilinear.tendsto_left_zero [OF bounded_bilinear_mult]
   828 
   829 lemmas tendsto_mult_right_zero =
   830   bounded_bilinear.tendsto_right_zero [OF bounded_bilinear_mult]
   831 
   832 lemma tendsto_power [tendsto_intros]: "(f \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. f x ^ n) \<longlongrightarrow> a ^ n) F"
   833   for f :: "'a \<Rightarrow> 'b::{power,real_normed_algebra}"
   834   by (induct n) (simp_all add: tendsto_mult)
   835 
   836 lemma continuous_power [continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. (f x)^n)"
   837   for f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
   838   unfolding continuous_def by (rule tendsto_power)
   839 
   840 lemma continuous_on_power [continuous_intros]:
   841   fixes f :: "_ \<Rightarrow> 'b::{power,real_normed_algebra}"
   842   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. (f x)^n)"
   843   unfolding continuous_on_def by (auto intro: tendsto_power)
   844 
   845 lemma tendsto_setprod [tendsto_intros]:
   846   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   847   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i \<longlongrightarrow> L i) F"
   848   shows "((\<lambda>x. \<Prod>i\<in>S. f i x) \<longlongrightarrow> (\<Prod>i\<in>S. L i)) F"
   849 proof (cases "finite S")
   850   case True
   851   then show ?thesis using assms
   852     by induct (simp_all add: tendsto_mult)
   853 next
   854   case False
   855   then show ?thesis by simp
   856 qed
   857 
   858 lemma continuous_setprod [continuous_intros]:
   859   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   860   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Prod>i\<in>S. f i x)"
   861   unfolding continuous_def by (rule tendsto_setprod)
   862 
   863 lemma continuous_on_setprod [continuous_intros]:
   864   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   865   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Prod>i\<in>S. f i x)"
   866   unfolding continuous_on_def by (auto intro: tendsto_setprod)
   867 
   868 lemma tendsto_of_real_iff:
   869   "((\<lambda>x. of_real (f x) :: 'a::real_normed_div_algebra) \<longlongrightarrow> of_real c) F \<longleftrightarrow> (f \<longlongrightarrow> c) F"
   870   unfolding tendsto_iff by simp
   871 
   872 lemma tendsto_add_const_iff:
   873   "((\<lambda>x. c + f x :: 'a::real_normed_vector) \<longlongrightarrow> c + d) F \<longleftrightarrow> (f \<longlongrightarrow> d) F"
   874   using tendsto_add[OF tendsto_const[of c], of f d]
   875     and tendsto_add[OF tendsto_const[of "-c"], of "\<lambda>x. c + f x" "c + d"] by auto
   876 
   877 
   878 subsubsection \<open>Inverse and division\<close>
   879 
   880 lemma (in bounded_bilinear) Zfun_prod_Bfun:
   881   assumes f: "Zfun f F"
   882     and g: "Bfun g F"
   883   shows "Zfun (\<lambda>x. f x ** g x) F"
   884 proof -
   885   obtain K where K: "0 \<le> K"
   886     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   887     using nonneg_bounded by blast
   888   obtain B where B: "0 < B"
   889     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) F"
   890     using g by (rule BfunE)
   891   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) F"
   892   using norm_g proof eventually_elim
   893     case (elim x)
   894     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   895       by (rule norm_le)
   896     also have "\<dots> \<le> norm (f x) * B * K"
   897       by (intro mult_mono' order_refl norm_g norm_ge_zero mult_nonneg_nonneg K elim)
   898     also have "\<dots> = norm (f x) * (B * K)"
   899       by (rule mult.assoc)
   900     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
   901   qed
   902   with f show ?thesis
   903     by (rule Zfun_imp_Zfun)
   904 qed
   905 
   906 lemma (in bounded_bilinear) Bfun_prod_Zfun:
   907   assumes f: "Bfun f F"
   908     and g: "Zfun g F"
   909   shows "Zfun (\<lambda>x. f x ** g x) F"
   910   using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
   911 
   912 lemma Bfun_inverse_lemma:
   913   fixes x :: "'a::real_normed_div_algebra"
   914   shows "r \<le> norm x \<Longrightarrow> 0 < r \<Longrightarrow> norm (inverse x) \<le> inverse r"
   915   apply (subst nonzero_norm_inverse)
   916   apply clarsimp
   917   apply (erule (1) le_imp_inverse_le)
   918   done
   919 
   920 lemma Bfun_inverse:
   921   fixes a :: "'a::real_normed_div_algebra"
   922   assumes f: "(f \<longlongrightarrow> a) F"
   923   assumes a: "a \<noteq> 0"
   924   shows "Bfun (\<lambda>x. inverse (f x)) F"
   925 proof -
   926   from a have "0 < norm a" by simp
   927   then have "\<exists>r>0. r < norm a" by (rule dense)
   928   then obtain r where r1: "0 < r" and r2: "r < norm a"
   929     by blast
   930   have "eventually (\<lambda>x. dist (f x) a < r) F"
   931     using tendstoD [OF f r1] by blast
   932   then have "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) F"
   933   proof eventually_elim
   934     case (elim x)
   935     then have 1: "norm (f x - a) < r"
   936       by (simp add: dist_norm)
   937     then have 2: "f x \<noteq> 0" using r2 by auto
   938     then have "norm (inverse (f x)) = inverse (norm (f x))"
   939       by (rule nonzero_norm_inverse)
   940     also have "\<dots> \<le> inverse (norm a - r)"
   941     proof (rule le_imp_inverse_le)
   942       show "0 < norm a - r"
   943         using r2 by simp
   944       have "norm a - norm (f x) \<le> norm (a - f x)"
   945         by (rule norm_triangle_ineq2)
   946       also have "\<dots> = norm (f x - a)"
   947         by (rule norm_minus_commute)
   948       also have "\<dots> < r" using 1 .
   949       finally show "norm a - r \<le> norm (f x)"
   950         by simp
   951     qed
   952     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
   953   qed
   954   then show ?thesis by (rule BfunI)
   955 qed
   956 
   957 lemma tendsto_inverse [tendsto_intros]:
   958   fixes a :: "'a::real_normed_div_algebra"
   959   assumes f: "(f \<longlongrightarrow> a) F"
   960     and a: "a \<noteq> 0"
   961   shows "((\<lambda>x. inverse (f x)) \<longlongrightarrow> inverse a) F"
   962 proof -
   963   from a have "0 < norm a" by simp
   964   with f have "eventually (\<lambda>x. dist (f x) a < norm a) F"
   965     by (rule tendstoD)
   966   then have "eventually (\<lambda>x. f x \<noteq> 0) F"
   967     unfolding dist_norm by (auto elim!: eventually_mono)
   968   with a have "eventually (\<lambda>x. inverse (f x) - inverse a =
   969     - (inverse (f x) * (f x - a) * inverse a)) F"
   970     by (auto elim!: eventually_mono simp: inverse_diff_inverse)
   971   moreover have "Zfun (\<lambda>x. - (inverse (f x) * (f x - a) * inverse a)) F"
   972     by (intro Zfun_minus Zfun_mult_left
   973       bounded_bilinear.Bfun_prod_Zfun [OF bounded_bilinear_mult]
   974       Bfun_inverse [OF f a] f [unfolded tendsto_Zfun_iff])
   975   ultimately show ?thesis
   976     unfolding tendsto_Zfun_iff by (rule Zfun_ssubst)
   977 qed
   978 
   979 lemma continuous_inverse:
   980   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   981   assumes "continuous F f"
   982     and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   983   shows "continuous F (\<lambda>x. inverse (f x))"
   984   using assms unfolding continuous_def by (rule tendsto_inverse)
   985 
   986 lemma continuous_at_within_inverse[continuous_intros]:
   987   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   988   assumes "continuous (at a within s) f"
   989     and "f a \<noteq> 0"
   990   shows "continuous (at a within s) (\<lambda>x. inverse (f x))"
   991   using assms unfolding continuous_within by (rule tendsto_inverse)
   992 
   993 lemma isCont_inverse[continuous_intros, simp]:
   994   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   995   assumes "isCont f a"
   996     and "f a \<noteq> 0"
   997   shows "isCont (\<lambda>x. inverse (f x)) a"
   998   using assms unfolding continuous_at by (rule tendsto_inverse)
   999 
  1000 lemma continuous_on_inverse[continuous_intros]:
  1001   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_div_algebra"
  1002   assumes "continuous_on s f"
  1003     and "\<forall>x\<in>s. f x \<noteq> 0"
  1004   shows "continuous_on s (\<lambda>x. inverse (f x))"
  1005   using assms unfolding continuous_on_def by (blast intro: tendsto_inverse)
  1006 
  1007 lemma tendsto_divide [tendsto_intros]:
  1008   fixes a b :: "'a::real_normed_field"
  1009   shows "(f \<longlongrightarrow> a) F \<Longrightarrow> (g \<longlongrightarrow> b) F \<Longrightarrow> b \<noteq> 0 \<Longrightarrow> ((\<lambda>x. f x / g x) \<longlongrightarrow> a / b) F"
  1010   by (simp add: tendsto_mult tendsto_inverse divide_inverse)
  1011 
  1012 lemma continuous_divide:
  1013   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
  1014   assumes "continuous F f"
  1015     and "continuous F g"
  1016     and "g (Lim F (\<lambda>x. x)) \<noteq> 0"
  1017   shows "continuous F (\<lambda>x. (f x) / (g x))"
  1018   using assms unfolding continuous_def by (rule tendsto_divide)
  1019 
  1020 lemma continuous_at_within_divide[continuous_intros]:
  1021   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
  1022   assumes "continuous (at a within s) f" "continuous (at a within s) g"
  1023     and "g a \<noteq> 0"
  1024   shows "continuous (at a within s) (\<lambda>x. (f x) / (g x))"
  1025   using assms unfolding continuous_within by (rule tendsto_divide)
  1026 
  1027 lemma isCont_divide[continuous_intros, simp]:
  1028   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
  1029   assumes "isCont f a" "isCont g a" "g a \<noteq> 0"
  1030   shows "isCont (\<lambda>x. (f x) / g x) a"
  1031   using assms unfolding continuous_at by (rule tendsto_divide)
  1032 
  1033 lemma continuous_on_divide[continuous_intros]:
  1034   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_field"
  1035   assumes "continuous_on s f" "continuous_on s g"
  1036     and "\<forall>x\<in>s. g x \<noteq> 0"
  1037   shows "continuous_on s (\<lambda>x. (f x) / (g x))"
  1038   using assms unfolding continuous_on_def by (blast intro: tendsto_divide)
  1039 
  1040 lemma tendsto_sgn [tendsto_intros]: "(f \<longlongrightarrow> l) F \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> ((\<lambda>x. sgn (f x)) \<longlongrightarrow> sgn l) F"
  1041   for l :: "'a::real_normed_vector"
  1042   unfolding sgn_div_norm by (simp add: tendsto_intros)
  1043 
  1044 lemma continuous_sgn:
  1045   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1046   assumes "continuous F f"
  1047     and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
  1048   shows "continuous F (\<lambda>x. sgn (f x))"
  1049   using assms unfolding continuous_def by (rule tendsto_sgn)
  1050 
  1051 lemma continuous_at_within_sgn[continuous_intros]:
  1052   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1053   assumes "continuous (at a within s) f"
  1054     and "f a \<noteq> 0"
  1055   shows "continuous (at a within s) (\<lambda>x. sgn (f x))"
  1056   using assms unfolding continuous_within by (rule tendsto_sgn)
  1057 
  1058 lemma isCont_sgn[continuous_intros]:
  1059   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1060   assumes "isCont f a"
  1061     and "f a \<noteq> 0"
  1062   shows "isCont (\<lambda>x. sgn (f x)) a"
  1063   using assms unfolding continuous_at by (rule tendsto_sgn)
  1064 
  1065 lemma continuous_on_sgn[continuous_intros]:
  1066   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1067   assumes "continuous_on s f"
  1068     and "\<forall>x\<in>s. f x \<noteq> 0"
  1069   shows "continuous_on s (\<lambda>x. sgn (f x))"
  1070   using assms unfolding continuous_on_def by (blast intro: tendsto_sgn)
  1071 
  1072 lemma filterlim_at_infinity:
  1073   fixes f :: "_ \<Rightarrow> 'a::real_normed_vector"
  1074   assumes "0 \<le> c"
  1075   shows "(LIM x F. f x :> at_infinity) \<longleftrightarrow> (\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F)"
  1076   unfolding filterlim_iff eventually_at_infinity
  1077 proof safe
  1078   fix P :: "'a \<Rightarrow> bool"
  1079   fix b
  1080   assume *: "\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F"
  1081   assume P: "\<forall>x. b \<le> norm x \<longrightarrow> P x"
  1082   have "max b (c + 1) > c" by auto
  1083   with * have "eventually (\<lambda>x. max b (c + 1) \<le> norm (f x)) F"
  1084     by auto
  1085   then show "eventually (\<lambda>x. P (f x)) F"
  1086   proof eventually_elim
  1087     case (elim x)
  1088     with P show "P (f x)" by auto
  1089   qed
  1090 qed force
  1091 
  1092 lemma not_tendsto_and_filterlim_at_infinity:
  1093   fixes c :: "'a::real_normed_vector"
  1094   assumes "F \<noteq> bot"
  1095     and "(f \<longlongrightarrow> c) F"
  1096     and "filterlim f at_infinity F"
  1097   shows False
  1098 proof -
  1099   from tendstoD[OF assms(2), of "1/2"]
  1100   have "eventually (\<lambda>x. dist (f x) c < 1/2) F"
  1101     by simp
  1102   moreover
  1103   from filterlim_at_infinity[of "norm c" f F] assms(3)
  1104   have "eventually (\<lambda>x. norm (f x) \<ge> norm c + 1) F" by simp
  1105   ultimately have "eventually (\<lambda>x. False) F"
  1106   proof eventually_elim
  1107     fix x
  1108     assume A: "dist (f x) c < 1/2"
  1109     assume "norm (f x) \<ge> norm c + 1"
  1110     also have "norm (f x) = dist (f x) 0" by simp
  1111     also have "\<dots> \<le> dist (f x) c + dist c 0" by (rule dist_triangle)
  1112     finally show False using A by simp
  1113   qed
  1114   with assms show False by simp
  1115 qed
  1116 
  1117 lemma filterlim_at_infinity_imp_not_convergent:
  1118   assumes "filterlim f at_infinity sequentially"
  1119   shows "\<not> convergent f"
  1120   by (rule notI, rule not_tendsto_and_filterlim_at_infinity[OF _ _ assms])
  1121      (simp_all add: convergent_LIMSEQ_iff)
  1122 
  1123 lemma filterlim_at_infinity_imp_eventually_ne:
  1124   assumes "filterlim f at_infinity F"
  1125   shows "eventually (\<lambda>z. f z \<noteq> c) F"
  1126 proof -
  1127   have "norm c + 1 > 0"
  1128     by (intro add_nonneg_pos) simp_all
  1129   with filterlim_at_infinity[OF order.refl, of f F] assms
  1130   have "eventually (\<lambda>z. norm (f z) \<ge> norm c + 1) F"
  1131     by blast
  1132   then show ?thesis
  1133     by eventually_elim auto
  1134 qed
  1135 
  1136 lemma tendsto_of_nat [tendsto_intros]:
  1137   "filterlim (of_nat :: nat \<Rightarrow> 'a::real_normed_algebra_1) at_infinity sequentially"
  1138 proof (subst filterlim_at_infinity[OF order.refl], intro allI impI)
  1139   fix r :: real
  1140   assume r: "r > 0"
  1141   define n where "n = nat \<lceil>r\<rceil>"
  1142   from r have n: "\<forall>m\<ge>n. of_nat m \<ge> r"
  1143     unfolding n_def by linarith
  1144   from eventually_ge_at_top[of n] show "eventually (\<lambda>m. norm (of_nat m :: 'a) \<ge> r) sequentially"
  1145     by eventually_elim (use n in simp_all)
  1146 qed
  1147 
  1148 
  1149 subsection \<open>Relate @{const at}, @{const at_left} and @{const at_right}\<close>
  1150 
  1151 text \<open>
  1152   This lemmas are useful for conversion between @{term "at x"} to @{term "at_left x"} and
  1153   @{term "at_right x"} and also @{term "at_right 0"}.
  1154 \<close>
  1155 
  1156 lemmas filterlim_split_at_real = filterlim_split_at[where 'a=real]
  1157 
  1158 lemma filtermap_nhds_shift: "filtermap (\<lambda>x. x - d) (nhds a) = nhds (a - d)"
  1159   for a d :: "'a::real_normed_vector"
  1160   by (rule filtermap_fun_inverse[where g="\<lambda>x. x + d"])
  1161     (auto intro!: tendsto_eq_intros filterlim_ident)
  1162 
  1163 lemma filtermap_nhds_minus: "filtermap (\<lambda>x. - x) (nhds a) = nhds (- a)"
  1164   for a :: "'a::real_normed_vector"
  1165   by (rule filtermap_fun_inverse[where g=uminus])
  1166     (auto intro!: tendsto_eq_intros filterlim_ident)
  1167 
  1168 lemma filtermap_at_shift: "filtermap (\<lambda>x. x - d) (at a) = at (a - d)"
  1169   for a d :: "'a::real_normed_vector"
  1170   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
  1171 
  1172 lemma filtermap_at_right_shift: "filtermap (\<lambda>x. x - d) (at_right a) = at_right (a - d)"
  1173   for a d :: "real"
  1174   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
  1175 
  1176 lemma at_right_to_0: "at_right a = filtermap (\<lambda>x. x + a) (at_right 0)"
  1177   for a :: real
  1178   using filtermap_at_right_shift[of "-a" 0] by simp
  1179 
  1180 lemma filterlim_at_right_to_0:
  1181   "filterlim f F (at_right a) \<longleftrightarrow> filterlim (\<lambda>x. f (x + a)) F (at_right 0)"
  1182   for a :: real
  1183   unfolding filterlim_def filtermap_filtermap at_right_to_0[of a] ..
  1184 
  1185 lemma eventually_at_right_to_0:
  1186   "eventually P (at_right a) \<longleftrightarrow> eventually (\<lambda>x. P (x + a)) (at_right 0)"
  1187   for a :: real
  1188   unfolding at_right_to_0[of a] by (simp add: eventually_filtermap)
  1189 
  1190 lemma filtermap_at_minus: "filtermap (\<lambda>x. - x) (at a) = at (- a)"
  1191   for a :: "'a::real_normed_vector"
  1192   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
  1193 
  1194 lemma at_left_minus: "at_left a = filtermap (\<lambda>x. - x) (at_right (- a))"
  1195   for a :: real
  1196   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
  1197 
  1198 lemma at_right_minus: "at_right a = filtermap (\<lambda>x. - x) (at_left (- a))"
  1199   for a :: real
  1200   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
  1201 
  1202 lemma filterlim_at_left_to_right:
  1203   "filterlim f F (at_left a) \<longleftrightarrow> filterlim (\<lambda>x. f (- x)) F (at_right (-a))"
  1204   for a :: real
  1205   unfolding filterlim_def filtermap_filtermap at_left_minus[of a] ..
  1206 
  1207 lemma eventually_at_left_to_right:
  1208   "eventually P (at_left a) \<longleftrightarrow> eventually (\<lambda>x. P (- x)) (at_right (-a))"
  1209   for a :: real
  1210   unfolding at_left_minus[of a] by (simp add: eventually_filtermap)
  1211 
  1212 lemma filterlim_uminus_at_top_at_bot: "LIM x at_bot. - x :: real :> at_top"
  1213   unfolding filterlim_at_top eventually_at_bot_dense
  1214   by (metis leI minus_less_iff order_less_asym)
  1215 
  1216 lemma filterlim_uminus_at_bot_at_top: "LIM x at_top. - x :: real :> at_bot"
  1217   unfolding filterlim_at_bot eventually_at_top_dense
  1218   by (metis leI less_minus_iff order_less_asym)
  1219 
  1220 lemma at_top_mirror: "at_top = filtermap uminus (at_bot :: real filter)"
  1221   by (rule filtermap_fun_inverse[symmetric, of uminus])
  1222      (auto intro: filterlim_uminus_at_bot_at_top filterlim_uminus_at_top_at_bot)
  1223 
  1224 lemma at_bot_mirror: "at_bot = filtermap uminus (at_top :: real filter)"
  1225   unfolding at_top_mirror filtermap_filtermap by (simp add: filtermap_ident)
  1226 
  1227 lemma filterlim_at_top_mirror: "(LIM x at_top. f x :> F) \<longleftrightarrow> (LIM x at_bot. f (-x::real) :> F)"
  1228   unfolding filterlim_def at_top_mirror filtermap_filtermap ..
  1229 
  1230 lemma filterlim_at_bot_mirror: "(LIM x at_bot. f x :> F) \<longleftrightarrow> (LIM x at_top. f (-x::real) :> F)"
  1231   unfolding filterlim_def at_bot_mirror filtermap_filtermap ..
  1232 
  1233 lemma filterlim_uminus_at_top: "(LIM x F. f x :> at_top) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_bot)"
  1234   using filterlim_compose[OF filterlim_uminus_at_bot_at_top, of f F]
  1235     and filterlim_compose[OF filterlim_uminus_at_top_at_bot, of "\<lambda>x. - f x" F]
  1236   by auto
  1237 
  1238 lemma filterlim_uminus_at_bot: "(LIM x F. f x :> at_bot) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_top)"
  1239   unfolding filterlim_uminus_at_top by simp
  1240 
  1241 lemma filterlim_inverse_at_top_right: "LIM x at_right (0::real). inverse x :> at_top"
  1242   unfolding filterlim_at_top_gt[where c=0] eventually_at_filter
  1243 proof safe
  1244   fix Z :: real
  1245   assume [arith]: "0 < Z"
  1246   then have "eventually (\<lambda>x. x < inverse Z) (nhds 0)"
  1247     by (auto simp add: eventually_nhds_metric dist_real_def intro!: exI[of _ "\<bar>inverse Z\<bar>"])
  1248   then show "eventually (\<lambda>x. x \<noteq> 0 \<longrightarrow> x \<in> {0<..} \<longrightarrow> Z \<le> inverse x) (nhds 0)"
  1249     by (auto elim!: eventually_mono simp: inverse_eq_divide field_simps)
  1250 qed
  1251 
  1252 lemma tendsto_inverse_0:
  1253   fixes x :: "_ \<Rightarrow> 'a::real_normed_div_algebra"
  1254   shows "(inverse \<longlongrightarrow> (0::'a)) at_infinity"
  1255   unfolding tendsto_Zfun_iff diff_0_right Zfun_def eventually_at_infinity
  1256 proof safe
  1257   fix r :: real
  1258   assume "0 < r"
  1259   show "\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> norm (inverse x :: 'a) < r"
  1260   proof (intro exI[of _ "inverse (r / 2)"] allI impI)
  1261     fix x :: 'a
  1262     from \<open>0 < r\<close> have "0 < inverse (r / 2)" by simp
  1263     also assume *: "inverse (r / 2) \<le> norm x"
  1264     finally show "norm (inverse x) < r"
  1265       using * \<open>0 < r\<close>
  1266       by (subst nonzero_norm_inverse) (simp_all add: inverse_eq_divide field_simps)
  1267   qed
  1268 qed
  1269 
  1270 lemma tendsto_add_filterlim_at_infinity:
  1271   fixes c :: "'b::real_normed_vector"
  1272     and F :: "'a filter"
  1273   assumes "(f \<longlongrightarrow> c) F"
  1274     and "filterlim g at_infinity F"
  1275   shows "filterlim (\<lambda>x. f x + g x) at_infinity F"
  1276 proof (subst filterlim_at_infinity[OF order_refl], safe)
  1277   fix r :: real
  1278   assume r: "r > 0"
  1279   from assms(1) have "((\<lambda>x. norm (f x)) \<longlongrightarrow> norm c) F"
  1280     by (rule tendsto_norm)
  1281   then have "eventually (\<lambda>x. norm (f x) < norm c + 1) F"
  1282     by (rule order_tendstoD) simp_all
  1283   moreover from r have "r + norm c + 1 > 0"
  1284     by (intro add_pos_nonneg) simp_all
  1285   with assms(2) have "eventually (\<lambda>x. norm (g x) \<ge> r + norm c + 1) F"
  1286     unfolding filterlim_at_infinity[OF order_refl]
  1287     by (elim allE[of _ "r + norm c + 1"]) simp_all
  1288   ultimately show "eventually (\<lambda>x. norm (f x + g x) \<ge> r) F"
  1289   proof eventually_elim
  1290     fix x :: 'a
  1291     assume A: "norm (f x) < norm c + 1" and B: "r + norm c + 1 \<le> norm (g x)"
  1292     from A B have "r \<le> norm (g x) - norm (f x)"
  1293       by simp
  1294     also have "norm (g x) - norm (f x) \<le> norm (g x + f x)"
  1295       by (rule norm_diff_ineq)
  1296     finally show "r \<le> norm (f x + g x)"
  1297       by (simp add: add_ac)
  1298   qed
  1299 qed
  1300 
  1301 lemma tendsto_add_filterlim_at_infinity':
  1302   fixes c :: "'b::real_normed_vector"
  1303     and F :: "'a filter"
  1304   assumes "filterlim f at_infinity F"
  1305     and "(g \<longlongrightarrow> c) F"
  1306   shows "filterlim (\<lambda>x. f x + g x) at_infinity F"
  1307   by (subst add.commute) (rule tendsto_add_filterlim_at_infinity assms)+
  1308 
  1309 lemma filterlim_inverse_at_right_top: "LIM x at_top. inverse x :> at_right (0::real)"
  1310   unfolding filterlim_at
  1311   by (auto simp: eventually_at_top_dense)
  1312      (metis tendsto_inverse_0 filterlim_mono at_top_le_at_infinity order_refl)
  1313 
  1314 lemma filterlim_inverse_at_top:
  1315   "(f \<longlongrightarrow> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. 0 < f x) F \<Longrightarrow> LIM x F. inverse (f x) :> at_top"
  1316   by (intro filterlim_compose[OF filterlim_inverse_at_top_right])
  1317      (simp add: filterlim_def eventually_filtermap eventually_mono at_within_def le_principal)
  1318 
  1319 lemma filterlim_inverse_at_bot_neg:
  1320   "LIM x (at_left (0::real)). inverse x :> at_bot"
  1321   by (simp add: filterlim_inverse_at_top_right filterlim_uminus_at_bot filterlim_at_left_to_right)
  1322 
  1323 lemma filterlim_inverse_at_bot:
  1324   "(f \<longlongrightarrow> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. f x < 0) F \<Longrightarrow> LIM x F. inverse (f x) :> at_bot"
  1325   unfolding filterlim_uminus_at_bot inverse_minus_eq[symmetric]
  1326   by (rule filterlim_inverse_at_top) (simp_all add: tendsto_minus_cancel_left[symmetric])
  1327 
  1328 lemma at_right_to_top: "(at_right (0::real)) = filtermap inverse at_top"
  1329   by (intro filtermap_fun_inverse[symmetric, where g=inverse])
  1330      (auto intro: filterlim_inverse_at_top_right filterlim_inverse_at_right_top)
  1331 
  1332 lemma eventually_at_right_to_top:
  1333   "eventually P (at_right (0::real)) \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) at_top"
  1334   unfolding at_right_to_top eventually_filtermap ..
  1335 
  1336 lemma filterlim_at_right_to_top:
  1337   "filterlim f F (at_right (0::real)) \<longleftrightarrow> (LIM x at_top. f (inverse x) :> F)"
  1338   unfolding filterlim_def at_right_to_top filtermap_filtermap ..
  1339 
  1340 lemma at_top_to_right: "at_top = filtermap inverse (at_right (0::real))"
  1341   unfolding at_right_to_top filtermap_filtermap inverse_inverse_eq filtermap_ident ..
  1342 
  1343 lemma eventually_at_top_to_right:
  1344   "eventually P at_top \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) (at_right (0::real))"
  1345   unfolding at_top_to_right eventually_filtermap ..
  1346 
  1347 lemma filterlim_at_top_to_right:
  1348   "filterlim f F at_top \<longleftrightarrow> (LIM x (at_right (0::real)). f (inverse x) :> F)"
  1349   unfolding filterlim_def at_top_to_right filtermap_filtermap ..
  1350 
  1351 lemma filterlim_inverse_at_infinity:
  1352   fixes x :: "_ \<Rightarrow> 'a::{real_normed_div_algebra, division_ring}"
  1353   shows "filterlim inverse at_infinity (at (0::'a))"
  1354   unfolding filterlim_at_infinity[OF order_refl]
  1355 proof safe
  1356   fix r :: real
  1357   assume "0 < r"
  1358   then show "eventually (\<lambda>x::'a. r \<le> norm (inverse x)) (at 0)"
  1359     unfolding eventually_at norm_inverse
  1360     by (intro exI[of _ "inverse r"])
  1361        (auto simp: norm_conv_dist[symmetric] field_simps inverse_eq_divide)
  1362 qed
  1363 
  1364 lemma filterlim_inverse_at_iff:
  1365   fixes g :: "'a \<Rightarrow> 'b::{real_normed_div_algebra, division_ring}"
  1366   shows "(LIM x F. inverse (g x) :> at 0) \<longleftrightarrow> (LIM x F. g x :> at_infinity)"
  1367   unfolding filterlim_def filtermap_filtermap[symmetric]
  1368 proof
  1369   assume "filtermap g F \<le> at_infinity"
  1370   then have "filtermap inverse (filtermap g F) \<le> filtermap inverse at_infinity"
  1371     by (rule filtermap_mono)
  1372   also have "\<dots> \<le> at 0"
  1373     using tendsto_inverse_0[where 'a='b]
  1374     by (auto intro!: exI[of _ 1]
  1375         simp: le_principal eventually_filtermap filterlim_def at_within_def eventually_at_infinity)
  1376   finally show "filtermap inverse (filtermap g F) \<le> at 0" .
  1377 next
  1378   assume "filtermap inverse (filtermap g F) \<le> at 0"
  1379   then have "filtermap inverse (filtermap inverse (filtermap g F)) \<le> filtermap inverse (at 0)"
  1380     by (rule filtermap_mono)
  1381   with filterlim_inverse_at_infinity show "filtermap g F \<le> at_infinity"
  1382     by (auto intro: order_trans simp: filterlim_def filtermap_filtermap)
  1383 qed
  1384 
  1385 lemma tendsto_mult_filterlim_at_infinity:
  1386   fixes c :: "'a::real_normed_field"
  1387   assumes "F \<noteq> bot" "(f \<longlongrightarrow> c) F" "c \<noteq> 0"
  1388   assumes "filterlim g at_infinity F"
  1389   shows "filterlim (\<lambda>x. f x * g x) at_infinity F"
  1390 proof -
  1391   have "((\<lambda>x. inverse (f x) * inverse (g x)) \<longlongrightarrow> inverse c * 0) F"
  1392     by (intro tendsto_mult tendsto_inverse assms filterlim_compose[OF tendsto_inverse_0])
  1393   then have "filterlim (\<lambda>x. inverse (f x) * inverse (g x)) (at (inverse c * 0)) F"
  1394     unfolding filterlim_at
  1395     using assms
  1396     by (auto intro: filterlim_at_infinity_imp_eventually_ne tendsto_imp_eventually_ne eventually_conj)
  1397   then show ?thesis
  1398     by (subst filterlim_inverse_at_iff[symmetric]) simp_all
  1399 qed
  1400 
  1401 lemma tendsto_inverse_0_at_top: "LIM x F. f x :> at_top \<Longrightarrow> ((\<lambda>x. inverse (f x) :: real) \<longlongrightarrow> 0) F"
  1402  by (metis filterlim_at filterlim_mono[OF _ at_top_le_at_infinity order_refl] filterlim_inverse_at_iff)
  1403 
  1404 lemma real_tendsto_divide_at_top:
  1405   fixes c::"real"
  1406   assumes "(f \<longlongrightarrow> c) F"
  1407   assumes "filterlim g at_top F"
  1408   shows "((\<lambda>x. f x / g x) \<longlongrightarrow> 0) F"
  1409   by (auto simp: divide_inverse_commute
  1410       intro!: tendsto_mult[THEN tendsto_eq_rhs] tendsto_inverse_0_at_top assms)
  1411 
  1412 lemma mult_nat_left_at_top: "c > 0 \<Longrightarrow> filterlim (\<lambda>x. c * x) at_top sequentially"
  1413   for c :: nat
  1414   by (rule filterlim_subseq) (auto simp: subseq_def)
  1415 
  1416 lemma mult_nat_right_at_top: "c > 0 \<Longrightarrow> filterlim (\<lambda>x. x * c) at_top sequentially"
  1417   for c :: nat
  1418   by (rule filterlim_subseq) (auto simp: subseq_def)
  1419 
  1420 lemma at_to_infinity: "(at (0::'a::{real_normed_field,field})) = filtermap inverse at_infinity"
  1421 proof (rule antisym)
  1422   have "(inverse \<longlongrightarrow> (0::'a)) at_infinity"
  1423     by (fact tendsto_inverse_0)
  1424   then show "filtermap inverse at_infinity \<le> at (0::'a)"
  1425     apply (simp add: le_principal eventually_filtermap eventually_at_infinity filterlim_def at_within_def)
  1426     apply (rule_tac x="1" in exI)
  1427     apply auto
  1428     done
  1429 next
  1430   have "filtermap inverse (filtermap inverse (at (0::'a))) \<le> filtermap inverse at_infinity"
  1431     using filterlim_inverse_at_infinity unfolding filterlim_def
  1432     by (rule filtermap_mono)
  1433   then show "at (0::'a) \<le> filtermap inverse at_infinity"
  1434     by (simp add: filtermap_ident filtermap_filtermap)
  1435 qed
  1436 
  1437 lemma lim_at_infinity_0:
  1438   fixes l :: "'a::{real_normed_field,field}"
  1439   shows "(f \<longlongrightarrow> l) at_infinity \<longleftrightarrow> ((f \<circ> inverse) \<longlongrightarrow> l) (at (0::'a))"
  1440   by (simp add: tendsto_compose_filtermap at_to_infinity filtermap_filtermap)
  1441 
  1442 lemma lim_zero_infinity:
  1443   fixes l :: "'a::{real_normed_field,field}"
  1444   shows "((\<lambda>x. f(1 / x)) \<longlongrightarrow> l) (at (0::'a)) \<Longrightarrow> (f \<longlongrightarrow> l) at_infinity"
  1445   by (simp add: inverse_eq_divide lim_at_infinity_0 comp_def)
  1446 
  1447 
  1448 text \<open>
  1449   We only show rules for multiplication and addition when the functions are either against a real
  1450   value or against infinity. Further rules are easy to derive by using @{thm
  1451   filterlim_uminus_at_top}.
  1452 \<close>
  1453 
  1454 lemma filterlim_tendsto_pos_mult_at_top:
  1455   assumes f: "(f \<longlongrightarrow> c) F"
  1456     and c: "0 < c"
  1457     and g: "LIM x F. g x :> at_top"
  1458   shows "LIM x F. (f x * g x :: real) :> at_top"
  1459   unfolding filterlim_at_top_gt[where c=0]
  1460 proof safe
  1461   fix Z :: real
  1462   assume "0 < Z"
  1463   from f \<open>0 < c\<close> have "eventually (\<lambda>x. c / 2 < f x) F"
  1464     by (auto dest!: tendstoD[where e="c / 2"] elim!: eventually_mono
  1465         simp: dist_real_def abs_real_def split: if_split_asm)
  1466   moreover from g have "eventually (\<lambda>x. (Z / c * 2) \<le> g x) F"
  1467     unfolding filterlim_at_top by auto
  1468   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1469   proof eventually_elim
  1470     case (elim x)
  1471     with \<open>0 < Z\<close> \<open>0 < c\<close> have "c / 2 * (Z / c * 2) \<le> f x * g x"
  1472       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1473     with \<open>0 < c\<close> show "Z \<le> f x * g x"
  1474        by simp
  1475   qed
  1476 qed
  1477 
  1478 lemma filterlim_at_top_mult_at_top:
  1479   assumes f: "LIM x F. f x :> at_top"
  1480     and g: "LIM x F. g x :> at_top"
  1481   shows "LIM x F. (f x * g x :: real) :> at_top"
  1482   unfolding filterlim_at_top_gt[where c=0]
  1483 proof safe
  1484   fix Z :: real
  1485   assume "0 < Z"
  1486   from f have "eventually (\<lambda>x. 1 \<le> f x) F"
  1487     unfolding filterlim_at_top by auto
  1488   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1489     unfolding filterlim_at_top by auto
  1490   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1491   proof eventually_elim
  1492     case (elim x)
  1493     with \<open>0 < Z\<close> have "1 * Z \<le> f x * g x"
  1494       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1495     then show "Z \<le> f x * g x"
  1496        by simp
  1497   qed
  1498 qed
  1499 
  1500 lemma filterlim_at_top_mult_tendsto_pos:
  1501   assumes f: "(f \<longlongrightarrow> c) F"
  1502     and c: "0 < c"
  1503     and g: "LIM x F. g x :> at_top"
  1504   shows "LIM x F. (g x * f x:: real) :> at_top"
  1505   by (auto simp: mult.commute intro!: filterlim_tendsto_pos_mult_at_top f c g)
  1506 
  1507 lemma filterlim_tendsto_pos_mult_at_bot:
  1508   fixes c :: real
  1509   assumes "(f \<longlongrightarrow> c) F" "0 < c" "filterlim g at_bot F"
  1510   shows "LIM x F. f x * g x :> at_bot"
  1511   using filterlim_tendsto_pos_mult_at_top[OF assms(1,2), of "\<lambda>x. - g x"] assms(3)
  1512   unfolding filterlim_uminus_at_bot by simp
  1513 
  1514 lemma filterlim_tendsto_neg_mult_at_bot:
  1515   fixes c :: real
  1516   assumes c: "(f \<longlongrightarrow> c) F" "c < 0" and g: "filterlim g at_top F"
  1517   shows "LIM x F. f x * g x :> at_bot"
  1518   using c filterlim_tendsto_pos_mult_at_top[of "\<lambda>x. - f x" "- c" F, OF _ _ g]
  1519   unfolding filterlim_uminus_at_bot tendsto_minus_cancel_left by simp
  1520 
  1521 lemma filterlim_pow_at_top:
  1522   fixes f :: "'a \<Rightarrow> real"
  1523   assumes "0 < n"
  1524     and f: "LIM x F. f x :> at_top"
  1525   shows "LIM x F. (f x)^n :: real :> at_top"
  1526   using \<open>0 < n\<close>
  1527 proof (induct n)
  1528   case 0
  1529   then show ?case by simp
  1530 next
  1531   case (Suc n) with f show ?case
  1532     by (cases "n = 0") (auto intro!: filterlim_at_top_mult_at_top)
  1533 qed
  1534 
  1535 lemma filterlim_pow_at_bot_even:
  1536   fixes f :: "real \<Rightarrow> real"
  1537   shows "0 < n \<Longrightarrow> LIM x F. f x :> at_bot \<Longrightarrow> even n \<Longrightarrow> LIM x F. (f x)^n :> at_top"
  1538   using filterlim_pow_at_top[of n "\<lambda>x. - f x" F] by (simp add: filterlim_uminus_at_top)
  1539 
  1540 lemma filterlim_pow_at_bot_odd:
  1541   fixes f :: "real \<Rightarrow> real"
  1542   shows "0 < n \<Longrightarrow> LIM x F. f x :> at_bot \<Longrightarrow> odd n \<Longrightarrow> LIM x F. (f x)^n :> at_bot"
  1543   using filterlim_pow_at_top[of n "\<lambda>x. - f x" F] by (simp add: filterlim_uminus_at_bot)
  1544 
  1545 lemma filterlim_tendsto_add_at_top:
  1546   assumes f: "(f \<longlongrightarrow> c) F"
  1547     and g: "LIM x F. g x :> at_top"
  1548   shows "LIM x F. (f x + g x :: real) :> at_top"
  1549   unfolding filterlim_at_top_gt[where c=0]
  1550 proof safe
  1551   fix Z :: real
  1552   assume "0 < Z"
  1553   from f have "eventually (\<lambda>x. c - 1 < f x) F"
  1554     by (auto dest!: tendstoD[where e=1] elim!: eventually_mono simp: dist_real_def)
  1555   moreover from g have "eventually (\<lambda>x. Z - (c - 1) \<le> g x) F"
  1556     unfolding filterlim_at_top by auto
  1557   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1558     by eventually_elim simp
  1559 qed
  1560 
  1561 lemma LIM_at_top_divide:
  1562   fixes f g :: "'a \<Rightarrow> real"
  1563   assumes f: "(f \<longlongrightarrow> a) F" "0 < a"
  1564     and g: "(g \<longlongrightarrow> 0) F" "eventually (\<lambda>x. 0 < g x) F"
  1565   shows "LIM x F. f x / g x :> at_top"
  1566   unfolding divide_inverse
  1567   by (rule filterlim_tendsto_pos_mult_at_top[OF f]) (rule filterlim_inverse_at_top[OF g])
  1568 
  1569 lemma filterlim_at_top_add_at_top:
  1570   assumes f: "LIM x F. f x :> at_top"
  1571     and g: "LIM x F. g x :> at_top"
  1572   shows "LIM x F. (f x + g x :: real) :> at_top"
  1573   unfolding filterlim_at_top_gt[where c=0]
  1574 proof safe
  1575   fix Z :: real
  1576   assume "0 < Z"
  1577   from f have "eventually (\<lambda>x. 0 \<le> f x) F"
  1578     unfolding filterlim_at_top by auto
  1579   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1580     unfolding filterlim_at_top by auto
  1581   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1582     by eventually_elim simp
  1583 qed
  1584 
  1585 lemma tendsto_divide_0:
  1586   fixes f :: "_ \<Rightarrow> 'a::{real_normed_div_algebra, division_ring}"
  1587   assumes f: "(f \<longlongrightarrow> c) F"
  1588     and g: "LIM x F. g x :> at_infinity"
  1589   shows "((\<lambda>x. f x / g x) \<longlongrightarrow> 0) F"
  1590   using tendsto_mult[OF f filterlim_compose[OF tendsto_inverse_0 g]]
  1591   by (simp add: divide_inverse)
  1592 
  1593 lemma linear_plus_1_le_power:
  1594   fixes x :: real
  1595   assumes x: "0 \<le> x"
  1596   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1597 proof (induct n)
  1598   case 0
  1599   then show ?case by simp
  1600 next
  1601   case (Suc n)
  1602   from x have "real (Suc n) * x + 1 \<le> (x + 1) * (real n * x + 1)"
  1603     by (simp add: field_simps)
  1604   also have "\<dots> \<le> (x + 1)^Suc n"
  1605     using Suc x by (simp add: mult_left_mono)
  1606   finally show ?case .
  1607 qed
  1608 
  1609 lemma filterlim_realpow_sequentially_gt1:
  1610   fixes x :: "'a :: real_normed_div_algebra"
  1611   assumes x[arith]: "1 < norm x"
  1612   shows "LIM n sequentially. x ^ n :> at_infinity"
  1613 proof (intro filterlim_at_infinity[THEN iffD2] allI impI)
  1614   fix y :: real
  1615   assume "0 < y"
  1616   have "0 < norm x - 1" by simp
  1617   then obtain N :: nat where "y < real N * (norm x - 1)"
  1618     by (blast dest: reals_Archimedean3)
  1619   also have "\<dots> \<le> real N * (norm x - 1) + 1"
  1620     by simp
  1621   also have "\<dots> \<le> (norm x - 1 + 1) ^ N"
  1622     by (rule linear_plus_1_le_power) simp
  1623   also have "\<dots> = norm x ^ N"
  1624     by simp
  1625   finally have "\<forall>n\<ge>N. y \<le> norm x ^ n"
  1626     by (metis order_less_le_trans power_increasing order_less_imp_le x)
  1627   then show "eventually (\<lambda>n. y \<le> norm (x ^ n)) sequentially"
  1628     unfolding eventually_sequentially
  1629     by (auto simp: norm_power)
  1630 qed simp
  1631 
  1632 
  1633 subsection \<open>Floor and Ceiling\<close>
  1634 
  1635 lemma eventually_floor_less:
  1636   fixes f :: "'a \<Rightarrow> 'b::{order_topology,floor_ceiling}"
  1637   assumes f: "(f \<longlongrightarrow> l) F"
  1638     and l: "l \<notin> \<int>"
  1639   shows "\<forall>\<^sub>F x in F. of_int (floor l) < f x"
  1640   by (intro order_tendstoD[OF f]) (metis Ints_of_int antisym_conv2 floor_correct l)
  1641 
  1642 lemma eventually_less_ceiling:
  1643   fixes f :: "'a \<Rightarrow> 'b::{order_topology,floor_ceiling}"
  1644   assumes f: "(f \<longlongrightarrow> l) F"
  1645     and l: "l \<notin> \<int>"
  1646   shows "\<forall>\<^sub>F x in F. f x < of_int (ceiling l)"
  1647   by (intro order_tendstoD[OF f]) (metis Ints_of_int l le_of_int_ceiling less_le)
  1648 
  1649 lemma eventually_floor_eq:
  1650   fixes f::"'a \<Rightarrow> 'b::{order_topology,floor_ceiling}"
  1651   assumes f: "(f \<longlongrightarrow> l) F"
  1652     and l: "l \<notin> \<int>"
  1653   shows "\<forall>\<^sub>F x in F. floor (f x) = floor l"
  1654   using eventually_floor_less[OF assms] eventually_less_ceiling[OF assms]
  1655   by eventually_elim (meson floor_less_iff less_ceiling_iff not_less_iff_gr_or_eq)
  1656 
  1657 lemma eventually_ceiling_eq:
  1658   fixes f::"'a \<Rightarrow> 'b::{order_topology,floor_ceiling}"
  1659   assumes f: "(f \<longlongrightarrow> l) F"
  1660     and l: "l \<notin> \<int>"
  1661   shows "\<forall>\<^sub>F x in F. ceiling (f x) = ceiling l"
  1662   using eventually_floor_less[OF assms] eventually_less_ceiling[OF assms]
  1663   by eventually_elim (meson floor_less_iff less_ceiling_iff not_less_iff_gr_or_eq)
  1664 
  1665 lemma tendsto_of_int_floor:
  1666   fixes f::"'a \<Rightarrow> 'b::{order_topology,floor_ceiling}"
  1667   assumes "(f \<longlongrightarrow> l) F"
  1668     and "l \<notin> \<int>"
  1669   shows "((\<lambda>x. of_int (floor (f x)) :: 'c::{ring_1,topological_space}) \<longlongrightarrow> of_int (floor l)) F"
  1670   using eventually_floor_eq[OF assms]
  1671   by (simp add: eventually_mono topological_tendstoI)
  1672 
  1673 lemma tendsto_of_int_ceiling:
  1674   fixes f::"'a \<Rightarrow> 'b::{order_topology,floor_ceiling}"
  1675   assumes "(f \<longlongrightarrow> l) F"
  1676     and "l \<notin> \<int>"
  1677   shows "((\<lambda>x. of_int (ceiling (f x)):: 'c::{ring_1,topological_space}) \<longlongrightarrow> of_int (ceiling l)) F"
  1678   using eventually_ceiling_eq[OF assms]
  1679   by (simp add: eventually_mono topological_tendstoI)
  1680 
  1681 lemma continuous_on_of_int_floor:
  1682   "continuous_on (UNIV - \<int>::'a::{order_topology, floor_ceiling} set)
  1683     (\<lambda>x. of_int (floor x)::'b::{ring_1, topological_space})"
  1684   unfolding continuous_on_def
  1685   by (auto intro!: tendsto_of_int_floor)
  1686 
  1687 lemma continuous_on_of_int_ceiling:
  1688   "continuous_on (UNIV - \<int>::'a::{order_topology, floor_ceiling} set)
  1689     (\<lambda>x. of_int (ceiling x)::'b::{ring_1, topological_space})"
  1690   unfolding continuous_on_def
  1691   by (auto intro!: tendsto_of_int_ceiling)
  1692 
  1693 
  1694 subsection \<open>Limits of Sequences\<close>
  1695 
  1696 lemma [trans]: "X = Y \<Longrightarrow> Y \<longlonglongrightarrow> z \<Longrightarrow> X \<longlonglongrightarrow> z"
  1697   by simp
  1698 
  1699 lemma LIMSEQ_iff:
  1700   fixes L :: "'a::real_normed_vector"
  1701   shows "(X \<longlonglongrightarrow> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
  1702 unfolding lim_sequentially dist_norm ..
  1703 
  1704 lemma LIMSEQ_I: "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X \<longlonglongrightarrow> L"
  1705   for L :: "'a::real_normed_vector"
  1706   by (simp add: LIMSEQ_iff)
  1707 
  1708 lemma LIMSEQ_D: "X \<longlonglongrightarrow> L \<Longrightarrow> 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
  1709   for L :: "'a::real_normed_vector"
  1710   by (simp add: LIMSEQ_iff)
  1711 
  1712 lemma LIMSEQ_linear: "X \<longlonglongrightarrow> x \<Longrightarrow> l > 0 \<Longrightarrow> (\<lambda> n. X (n * l)) \<longlonglongrightarrow> x"
  1713   unfolding tendsto_def eventually_sequentially
  1714   by (metis div_le_dividend div_mult_self1_is_m le_trans mult.commute)
  1715 
  1716 lemma Bseq_inverse_lemma: "r \<le> norm x \<Longrightarrow> 0 < r \<Longrightarrow> norm (inverse x) \<le> inverse r"
  1717   for x :: "'a::real_normed_div_algebra"
  1718   apply (subst nonzero_norm_inverse, clarsimp)
  1719   apply (erule (1) le_imp_inverse_le)
  1720   done
  1721 
  1722 lemma Bseq_inverse: "X \<longlonglongrightarrow> a \<Longrightarrow> a \<noteq> 0 \<Longrightarrow> Bseq (\<lambda>n. inverse (X n))"
  1723   for a :: "'a::real_normed_div_algebra"
  1724   by (rule Bfun_inverse)
  1725 
  1726 
  1727 text \<open>Transformation of limit.\<close>
  1728 
  1729 lemma Lim_transform: "(g \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. f x - g x) \<longlongrightarrow> 0) F \<Longrightarrow> (f \<longlongrightarrow> a) F"
  1730   for a b :: "'a::real_normed_vector"
  1731   using tendsto_add [of g a F "\<lambda>x. f x - g x" 0] by simp
  1732 
  1733 lemma Lim_transform2: "(f \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. f x - g x) \<longlongrightarrow> 0) F \<Longrightarrow> (g \<longlongrightarrow> a) F"
  1734   for a b :: "'a::real_normed_vector"
  1735   by (erule Lim_transform) (simp add: tendsto_minus_cancel)
  1736 
  1737 proposition Lim_transform_eq: "((\<lambda>x. f x - g x) \<longlongrightarrow> 0) F \<Longrightarrow> (f \<longlongrightarrow> a) F \<longleftrightarrow> (g \<longlongrightarrow> a) F"
  1738   for a :: "'a::real_normed_vector"
  1739   using Lim_transform Lim_transform2 by blast
  1740 
  1741 lemma Lim_transform_eventually:
  1742   "eventually (\<lambda>x. f x = g x) net \<Longrightarrow> (f \<longlongrightarrow> l) net \<Longrightarrow> (g \<longlongrightarrow> l) net"
  1743   apply (rule topological_tendstoI)
  1744   apply (drule (2) topological_tendstoD)
  1745   apply (erule (1) eventually_elim2)
  1746   apply simp
  1747   done
  1748 
  1749 lemma Lim_transform_within:
  1750   assumes "(f \<longlongrightarrow> l) (at x within S)"
  1751     and "0 < d"
  1752     and "\<And>x'. x'\<in>S \<Longrightarrow> 0 < dist x' x \<Longrightarrow> dist x' x < d \<Longrightarrow> f x' = g x'"
  1753   shows "(g \<longlongrightarrow> l) (at x within S)"
  1754 proof (rule Lim_transform_eventually)
  1755   show "eventually (\<lambda>x. f x = g x) (at x within S)"
  1756     using assms by (auto simp: eventually_at)
  1757   show "(f \<longlongrightarrow> l) (at x within S)"
  1758     by fact
  1759 qed
  1760 
  1761 text \<open>Common case assuming being away from some crucial point like 0.\<close>
  1762 lemma Lim_transform_away_within:
  1763   fixes a b :: "'a::t1_space"
  1764   assumes "a \<noteq> b"
  1765     and "\<forall>x\<in>S. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1766     and "(f \<longlongrightarrow> l) (at a within S)"
  1767   shows "(g \<longlongrightarrow> l) (at a within S)"
  1768 proof (rule Lim_transform_eventually)
  1769   show "(f \<longlongrightarrow> l) (at a within S)"
  1770     by fact
  1771   show "eventually (\<lambda>x. f x = g x) (at a within S)"
  1772     unfolding eventually_at_topological
  1773     by (rule exI [where x="- {b}"]) (simp add: open_Compl assms)
  1774 qed
  1775 
  1776 lemma Lim_transform_away_at:
  1777   fixes a b :: "'a::t1_space"
  1778   assumes ab: "a \<noteq> b"
  1779     and fg: "\<forall>x. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1780     and fl: "(f \<longlongrightarrow> l) (at a)"
  1781   shows "(g \<longlongrightarrow> l) (at a)"
  1782   using Lim_transform_away_within[OF ab, of UNIV f g l] fg fl by simp
  1783 
  1784 text \<open>Alternatively, within an open set.\<close>
  1785 lemma Lim_transform_within_open:
  1786   assumes "(f \<longlongrightarrow> l) (at a within T)"
  1787     and "open s" and "a \<in> s"
  1788     and "\<And>x. x\<in>s \<Longrightarrow> x \<noteq> a \<Longrightarrow> f x = g x"
  1789   shows "(g \<longlongrightarrow> l) (at a within T)"
  1790 proof (rule Lim_transform_eventually)
  1791   show "eventually (\<lambda>x. f x = g x) (at a within T)"
  1792     unfolding eventually_at_topological
  1793     using assms by auto
  1794   show "(f \<longlongrightarrow> l) (at a within T)" by fact
  1795 qed
  1796 
  1797 
  1798 text \<open>A congruence rule allowing us to transform limits assuming not at point.\<close>
  1799 
  1800 (* FIXME: Only one congruence rule for tendsto can be used at a time! *)
  1801 
  1802 lemma Lim_cong_within(*[cong add]*):
  1803   assumes "a = b"
  1804     and "x = y"
  1805     and "S = T"
  1806     and "\<And>x. x \<noteq> b \<Longrightarrow> x \<in> T \<Longrightarrow> f x = g x"
  1807   shows "(f \<longlongrightarrow> x) (at a within S) \<longleftrightarrow> (g \<longlongrightarrow> y) (at b within T)"
  1808   unfolding tendsto_def eventually_at_topological
  1809   using assms by simp
  1810 
  1811 lemma Lim_cong_at(*[cong add]*):
  1812   assumes "a = b" "x = y"
  1813     and "\<And>x. x \<noteq> a \<Longrightarrow> f x = g x"
  1814   shows "((\<lambda>x. f x) \<longlongrightarrow> x) (at a) \<longleftrightarrow> ((g \<longlongrightarrow> y) (at a))"
  1815   unfolding tendsto_def eventually_at_topological
  1816   using assms by simp
  1817 
  1818 text \<open>An unbounded sequence's inverse tends to 0.\<close>
  1819 lemma LIMSEQ_inverse_zero: "\<forall>r::real. \<exists>N. \<forall>n\<ge>N. r < X n \<Longrightarrow> (\<lambda>n. inverse (X n)) \<longlonglongrightarrow> 0"
  1820   apply (rule filterlim_compose[OF tendsto_inverse_0])
  1821   apply (simp add: filterlim_at_infinity[OF order_refl] eventually_sequentially)
  1822   apply (metis abs_le_D1 linorder_le_cases linorder_not_le)
  1823   done
  1824 
  1825 text \<open>The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity.\<close>
  1826 lemma LIMSEQ_inverse_real_of_nat: "(\<lambda>n. inverse (real (Suc n))) \<longlonglongrightarrow> 0"
  1827   by (metis filterlim_compose tendsto_inverse_0 filterlim_mono order_refl filterlim_Suc
  1828       filterlim_compose[OF filterlim_real_sequentially] at_top_le_at_infinity)
  1829 
  1830 text \<open>
  1831   The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
  1832   infinity is now easily proved.
  1833 \<close>
  1834 
  1835 lemma LIMSEQ_inverse_real_of_nat_add: "(\<lambda>n. r + inverse (real (Suc n))) \<longlonglongrightarrow> r"
  1836   using tendsto_add [OF tendsto_const LIMSEQ_inverse_real_of_nat] by auto
  1837 
  1838 lemma LIMSEQ_inverse_real_of_nat_add_minus: "(\<lambda>n. r + -inverse (real (Suc n))) \<longlonglongrightarrow> r"
  1839   using tendsto_add [OF tendsto_const tendsto_minus [OF LIMSEQ_inverse_real_of_nat]]
  1840   by auto
  1841 
  1842 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult: "(\<lambda>n. r * (1 + - inverse (real (Suc n)))) \<longlonglongrightarrow> r"
  1843   using tendsto_mult [OF tendsto_const LIMSEQ_inverse_real_of_nat_add_minus [of 1]]
  1844   by auto
  1845 
  1846 lemma lim_inverse_n: "((\<lambda>n. inverse(of_nat n)) \<longlongrightarrow> (0::'a::real_normed_field)) sequentially"
  1847   using lim_1_over_n by (simp add: inverse_eq_divide)
  1848 
  1849 lemma LIMSEQ_Suc_n_over_n: "(\<lambda>n. of_nat (Suc n) / of_nat n :: 'a :: real_normed_field) \<longlonglongrightarrow> 1"
  1850 proof (rule Lim_transform_eventually)
  1851   show "eventually (\<lambda>n. 1 + inverse (of_nat n :: 'a) = of_nat (Suc n) / of_nat n) sequentially"
  1852     using eventually_gt_at_top[of "0::nat"]
  1853     by eventually_elim (simp add: field_simps)
  1854   have "(\<lambda>n. 1 + inverse (of_nat n) :: 'a) \<longlonglongrightarrow> 1 + 0"
  1855     by (intro tendsto_add tendsto_const lim_inverse_n)
  1856   then show "(\<lambda>n. 1 + inverse (of_nat n) :: 'a) \<longlonglongrightarrow> 1"
  1857     by simp
  1858 qed
  1859 
  1860 lemma LIMSEQ_n_over_Suc_n: "(\<lambda>n. of_nat n / of_nat (Suc n) :: 'a :: real_normed_field) \<longlonglongrightarrow> 1"
  1861 proof (rule Lim_transform_eventually)
  1862   show "eventually (\<lambda>n. inverse (of_nat (Suc n) / of_nat n :: 'a) =
  1863       of_nat n / of_nat (Suc n)) sequentially"
  1864     using eventually_gt_at_top[of "0::nat"]
  1865     by eventually_elim (simp add: field_simps del: of_nat_Suc)
  1866   have "(\<lambda>n. inverse (of_nat (Suc n) / of_nat n :: 'a)) \<longlonglongrightarrow> inverse 1"
  1867     by (intro tendsto_inverse LIMSEQ_Suc_n_over_n) simp_all
  1868   then show "(\<lambda>n. inverse (of_nat (Suc n) / of_nat n :: 'a)) \<longlonglongrightarrow> 1"
  1869     by simp
  1870 qed
  1871 
  1872 
  1873 subsection \<open>Convergence on sequences\<close>
  1874 
  1875 lemma convergent_cong:
  1876   assumes "eventually (\<lambda>x. f x = g x) sequentially"
  1877   shows "convergent f \<longleftrightarrow> convergent g"
  1878   unfolding convergent_def
  1879   by (subst filterlim_cong[OF refl refl assms]) (rule refl)
  1880 
  1881 lemma convergent_Suc_iff: "convergent (\<lambda>n. f (Suc n)) \<longleftrightarrow> convergent f"
  1882   by (auto simp: convergent_def LIMSEQ_Suc_iff)
  1883 
  1884 lemma convergent_ignore_initial_segment: "convergent (\<lambda>n. f (n + m)) = convergent f"
  1885 proof (induct m arbitrary: f)
  1886   case 0
  1887   then show ?case by simp
  1888 next
  1889   case (Suc m)
  1890   have "convergent (\<lambda>n. f (n + Suc m)) \<longleftrightarrow> convergent (\<lambda>n. f (Suc n + m))"
  1891     by simp
  1892   also have "\<dots> \<longleftrightarrow> convergent (\<lambda>n. f (n + m))"
  1893     by (rule convergent_Suc_iff)
  1894   also have "\<dots> \<longleftrightarrow> convergent f"
  1895     by (rule Suc)
  1896   finally show ?case .
  1897 qed
  1898 
  1899 lemma convergent_add:
  1900   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
  1901   assumes "convergent (\<lambda>n. X n)"
  1902     and "convergent (\<lambda>n. Y n)"
  1903   shows "convergent (\<lambda>n. X n + Y n)"
  1904   using assms unfolding convergent_def by (blast intro: tendsto_add)
  1905 
  1906 lemma convergent_setsum:
  1907   fixes X :: "'a \<Rightarrow> nat \<Rightarrow> 'b::real_normed_vector"
  1908   assumes "\<And>i. i \<in> A \<Longrightarrow> convergent (\<lambda>n. X i n)"
  1909   shows "convergent (\<lambda>n. \<Sum>i\<in>A. X i n)"
  1910 proof (cases "finite A")
  1911   case True
  1912   then show ?thesis
  1913     using assms by (induct A set: finite) (simp_all add: convergent_const convergent_add)
  1914 next
  1915   case False
  1916   then show ?thesis
  1917     by (simp add: convergent_const)
  1918 qed
  1919 
  1920 lemma (in bounded_linear) convergent:
  1921   assumes "convergent (\<lambda>n. X n)"
  1922   shows "convergent (\<lambda>n. f (X n))"
  1923   using assms unfolding convergent_def by (blast intro: tendsto)
  1924 
  1925 lemma (in bounded_bilinear) convergent:
  1926   assumes "convergent (\<lambda>n. X n)"
  1927     and "convergent (\<lambda>n. Y n)"
  1928   shows "convergent (\<lambda>n. X n ** Y n)"
  1929   using assms unfolding convergent_def by (blast intro: tendsto)
  1930 
  1931 lemma convergent_minus_iff: "convergent X \<longleftrightarrow> convergent (\<lambda>n. - X n)"
  1932   for X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1933   apply (simp add: convergent_def)
  1934   apply (auto dest: tendsto_minus)
  1935   apply (drule tendsto_minus)
  1936   apply auto
  1937   done
  1938 
  1939 lemma convergent_diff:
  1940   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
  1941   assumes "convergent (\<lambda>n. X n)"
  1942   assumes "convergent (\<lambda>n. Y n)"
  1943   shows "convergent (\<lambda>n. X n - Y n)"
  1944   using assms unfolding convergent_def by (blast intro: tendsto_diff)
  1945 
  1946 lemma convergent_norm:
  1947   assumes "convergent f"
  1948   shows "convergent (\<lambda>n. norm (f n))"
  1949 proof -
  1950   from assms have "f \<longlonglongrightarrow> lim f"
  1951     by (simp add: convergent_LIMSEQ_iff)
  1952   then have "(\<lambda>n. norm (f n)) \<longlonglongrightarrow> norm (lim f)"
  1953     by (rule tendsto_norm)
  1954   then show ?thesis
  1955     by (auto simp: convergent_def)
  1956 qed
  1957 
  1958 lemma convergent_of_real:
  1959   "convergent f \<Longrightarrow> convergent (\<lambda>n. of_real (f n) :: 'a::real_normed_algebra_1)"
  1960   unfolding convergent_def by (blast intro!: tendsto_of_real)
  1961 
  1962 lemma convergent_add_const_iff:
  1963   "convergent (\<lambda>n. c + f n :: 'a::real_normed_vector) \<longleftrightarrow> convergent f"
  1964 proof
  1965   assume "convergent (\<lambda>n. c + f n)"
  1966   from convergent_diff[OF this convergent_const[of c]] show "convergent f"
  1967     by simp
  1968 next
  1969   assume "convergent f"
  1970   from convergent_add[OF convergent_const[of c] this] show "convergent (\<lambda>n. c + f n)"
  1971     by simp
  1972 qed
  1973 
  1974 lemma convergent_add_const_right_iff:
  1975   "convergent (\<lambda>n. f n + c :: 'a::real_normed_vector) \<longleftrightarrow> convergent f"
  1976   using convergent_add_const_iff[of c f] by (simp add: add_ac)
  1977 
  1978 lemma convergent_diff_const_right_iff:
  1979   "convergent (\<lambda>n. f n - c :: 'a::real_normed_vector) \<longleftrightarrow> convergent f"
  1980   using convergent_add_const_right_iff[of f "-c"] by (simp add: add_ac)
  1981 
  1982 lemma convergent_mult:
  1983   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_field"
  1984   assumes "convergent (\<lambda>n. X n)"
  1985     and "convergent (\<lambda>n. Y n)"
  1986   shows "convergent (\<lambda>n. X n * Y n)"
  1987   using assms unfolding convergent_def by (blast intro: tendsto_mult)
  1988 
  1989 lemma convergent_mult_const_iff:
  1990   assumes "c \<noteq> 0"
  1991   shows "convergent (\<lambda>n. c * f n :: 'a::real_normed_field) \<longleftrightarrow> convergent f"
  1992 proof
  1993   assume "convergent (\<lambda>n. c * f n)"
  1994   from assms convergent_mult[OF this convergent_const[of "inverse c"]]
  1995     show "convergent f" by (simp add: field_simps)
  1996 next
  1997   assume "convergent f"
  1998   from convergent_mult[OF convergent_const[of c] this] show "convergent (\<lambda>n. c * f n)"
  1999     by simp
  2000 qed
  2001 
  2002 lemma convergent_mult_const_right_iff:
  2003   fixes c :: "'a::real_normed_field"
  2004   assumes "c \<noteq> 0"
  2005   shows "convergent (\<lambda>n. f n * c) \<longleftrightarrow> convergent f"
  2006   using convergent_mult_const_iff[OF assms, of f] by (simp add: mult_ac)
  2007 
  2008 lemma convergent_imp_Bseq: "convergent f \<Longrightarrow> Bseq f"
  2009   by (simp add: Cauchy_Bseq convergent_Cauchy)
  2010 
  2011 
  2012 text \<open>A monotone sequence converges to its least upper bound.\<close>
  2013 
  2014 lemma LIMSEQ_incseq_SUP:
  2015   fixes X :: "nat \<Rightarrow> 'a::{conditionally_complete_linorder,linorder_topology}"
  2016   assumes u: "bdd_above (range X)"
  2017     and X: "incseq X"
  2018   shows "X \<longlonglongrightarrow> (SUP i. X i)"
  2019   by (rule order_tendstoI)
  2020     (auto simp: eventually_sequentially u less_cSUP_iff
  2021       intro: X[THEN incseqD] less_le_trans cSUP_lessD[OF u])
  2022 
  2023 lemma LIMSEQ_decseq_INF:
  2024   fixes X :: "nat \<Rightarrow> 'a::{conditionally_complete_linorder, linorder_topology}"
  2025   assumes u: "bdd_below (range X)"
  2026     and X: "decseq X"
  2027   shows "X \<longlonglongrightarrow> (INF i. X i)"
  2028   by (rule order_tendstoI)
  2029      (auto simp: eventually_sequentially u cINF_less_iff
  2030        intro: X[THEN decseqD] le_less_trans less_cINF_D[OF u])
  2031 
  2032 text \<open>Main monotonicity theorem.\<close>
  2033 
  2034 lemma Bseq_monoseq_convergent: "Bseq X \<Longrightarrow> monoseq X \<Longrightarrow> convergent X"
  2035   for X :: "nat \<Rightarrow> real"
  2036   by (auto simp: monoseq_iff convergent_def intro: LIMSEQ_decseq_INF LIMSEQ_incseq_SUP
  2037       dest: Bseq_bdd_above Bseq_bdd_below)
  2038 
  2039 lemma Bseq_mono_convergent: "Bseq X \<Longrightarrow> (\<forall>m n. m \<le> n \<longrightarrow> X m \<le> X n) \<Longrightarrow> convergent X"
  2040   for X :: "nat \<Rightarrow> real"
  2041   by (auto intro!: Bseq_monoseq_convergent incseq_imp_monoseq simp: incseq_def)
  2042 
  2043 lemma monoseq_imp_convergent_iff_Bseq: "monoseq f \<Longrightarrow> convergent f \<longleftrightarrow> Bseq f"
  2044   for f :: "nat \<Rightarrow> real"
  2045   using Bseq_monoseq_convergent[of f] convergent_imp_Bseq[of f] by blast
  2046 
  2047 lemma Bseq_monoseq_convergent'_inc:
  2048   fixes f :: "nat \<Rightarrow> real"
  2049   shows "Bseq (\<lambda>n. f (n + M)) \<Longrightarrow> (\<And>m n. M \<le> m \<Longrightarrow> m \<le> n \<Longrightarrow> f m \<le> f n) \<Longrightarrow> convergent f"
  2050   by (subst convergent_ignore_initial_segment [symmetric, of _ M])
  2051      (auto intro!: Bseq_monoseq_convergent simp: monoseq_def)
  2052 
  2053 lemma Bseq_monoseq_convergent'_dec:
  2054   fixes f :: "nat \<Rightarrow> real"
  2055   shows "Bseq (\<lambda>n. f (n + M)) \<Longrightarrow> (\<And>m n. M \<le> m \<Longrightarrow> m \<le> n \<Longrightarrow> f m \<ge> f n) \<Longrightarrow> convergent f"
  2056   by (subst convergent_ignore_initial_segment [symmetric, of _ M])
  2057     (auto intro!: Bseq_monoseq_convergent simp: monoseq_def)
  2058 
  2059 lemma Cauchy_iff: "Cauchy X \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e)"
  2060   for X :: "nat \<Rightarrow> 'a::real_normed_vector"
  2061   unfolding Cauchy_def dist_norm ..
  2062 
  2063 lemma CauchyI: "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
  2064   for X :: "nat \<Rightarrow> 'a::real_normed_vector"
  2065   by (simp add: Cauchy_iff)
  2066 
  2067 lemma CauchyD: "Cauchy X \<Longrightarrow> 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
  2068   for X :: "nat \<Rightarrow> 'a::real_normed_vector"
  2069   by (simp add: Cauchy_iff)
  2070 
  2071 lemma incseq_convergent:
  2072   fixes X :: "nat \<Rightarrow> real"
  2073   assumes "incseq X"
  2074     and "\<forall>i. X i \<le> B"
  2075   obtains L where "X \<longlonglongrightarrow> L" "\<forall>i. X i \<le> L"
  2076 proof atomize_elim
  2077   from incseq_bounded[OF assms] \<open>incseq X\<close> Bseq_monoseq_convergent[of X]
  2078   obtain L where "X \<longlonglongrightarrow> L"
  2079     by (auto simp: convergent_def monoseq_def incseq_def)
  2080   with \<open>incseq X\<close> show "\<exists>L. X \<longlonglongrightarrow> L \<and> (\<forall>i. X i \<le> L)"
  2081     by (auto intro!: exI[of _ L] incseq_le)
  2082 qed
  2083 
  2084 lemma decseq_convergent:
  2085   fixes X :: "nat \<Rightarrow> real"
  2086   assumes "decseq X"
  2087     and "\<forall>i. B \<le> X i"
  2088   obtains L where "X \<longlonglongrightarrow> L" "\<forall>i. L \<le> X i"
  2089 proof atomize_elim
  2090   from decseq_bounded[OF assms] \<open>decseq X\<close> Bseq_monoseq_convergent[of X]
  2091   obtain L where "X \<longlonglongrightarrow> L"
  2092     by (auto simp: convergent_def monoseq_def decseq_def)
  2093   with \<open>decseq X\<close> show "\<exists>L. X \<longlonglongrightarrow> L \<and> (\<forall>i. L \<le> X i)"
  2094     by (auto intro!: exI[of _ L] decseq_le)
  2095 qed
  2096 
  2097 
  2098 subsection \<open>Power Sequences\<close>
  2099 
  2100 text \<open>
  2101   The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
  2102   "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
  2103   also fact that bounded and monotonic sequence converges.
  2104 \<close>
  2105 
  2106 lemma Bseq_realpow: "0 \<le> x \<Longrightarrow> x \<le> 1 \<Longrightarrow> Bseq (\<lambda>n. x ^ n)"
  2107   for x :: real
  2108   apply (simp add: Bseq_def)
  2109   apply (rule_tac x = 1 in exI)
  2110   apply (simp add: power_abs)
  2111   apply (auto dest: power_mono)
  2112   done
  2113 
  2114 lemma monoseq_realpow: "0 \<le> x \<Longrightarrow> x \<le> 1 \<Longrightarrow> monoseq (\<lambda>n. x ^ n)"
  2115   for x :: real
  2116   apply (clarify intro!: mono_SucI2)
  2117   apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing)
  2118      apply auto
  2119   done
  2120 
  2121 lemma convergent_realpow: "0 \<le> x \<Longrightarrow> x \<le> 1 \<Longrightarrow> convergent (\<lambda>n. x ^ n)"
  2122   for x :: real
  2123   by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
  2124 
  2125 lemma LIMSEQ_inverse_realpow_zero: "1 < x \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) \<longlonglongrightarrow> 0"
  2126   for x :: real
  2127   by (rule filterlim_compose[OF tendsto_inverse_0 filterlim_realpow_sequentially_gt1]) simp
  2128 
  2129 lemma LIMSEQ_realpow_zero:
  2130   fixes x :: real
  2131   assumes "0 \<le> x" "x < 1"
  2132   shows "(\<lambda>n. x ^ n) \<longlonglongrightarrow> 0"
  2133 proof (cases "x = 0")
  2134   case False
  2135   with \<open>0 \<le> x\<close> have x0: "0 < x" by simp
  2136   then have "1 < inverse x"
  2137     using \<open>x < 1\<close> by (rule one_less_inverse)
  2138   then have "(\<lambda>n. inverse (inverse x ^ n)) \<longlonglongrightarrow> 0"
  2139     by (rule LIMSEQ_inverse_realpow_zero)
  2140   then show ?thesis by (simp add: power_inverse)
  2141 next
  2142   case True
  2143   show ?thesis
  2144     by (rule LIMSEQ_imp_Suc) (simp add: True)
  2145 qed
  2146 
  2147 lemma LIMSEQ_power_zero: "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) \<longlonglongrightarrow> 0"
  2148   for x :: "'a::real_normed_algebra_1"
  2149   apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
  2150   apply (simp only: tendsto_Zfun_iff, erule Zfun_le)
  2151   apply (simp add: power_abs norm_power_ineq)
  2152   done
  2153 
  2154 lemma LIMSEQ_divide_realpow_zero: "1 < x \<Longrightarrow> (\<lambda>n. a / (x ^ n) :: real) \<longlonglongrightarrow> 0"
  2155   by (rule tendsto_divide_0 [OF tendsto_const filterlim_realpow_sequentially_gt1]) simp
  2156 
  2157 lemma
  2158   tendsto_power_zero:
  2159   fixes x::"'a::real_normed_algebra_1"
  2160   assumes "filterlim f at_top F"
  2161   assumes "norm x < 1"
  2162   shows "((\<lambda>y. x ^ (f y)) \<longlongrightarrow> 0) F"
  2163 proof (rule tendstoI)
  2164   fix e::real assume "0 < e"
  2165   from tendstoD[OF LIMSEQ_power_zero[OF \<open>norm x < 1\<close>] \<open>0 < e\<close>]
  2166   have "\<forall>\<^sub>F xa in sequentially. norm (x ^ xa) < e"
  2167     by simp
  2168   then obtain N where N: "norm (x ^ n) < e" if "n \<ge> N" for n
  2169     by (auto simp: eventually_sequentially)
  2170   have "\<forall>\<^sub>F i in F. f i \<ge> N"
  2171     using \<open>filterlim f sequentially F\<close>
  2172     by (simp add: filterlim_at_top)
  2173   then show "\<forall>\<^sub>F i in F. dist (x ^ f i) 0 < e"
  2174     by (eventually_elim) (auto simp: N)
  2175 qed
  2176 
  2177 text \<open>Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}.\<close>
  2178 
  2179 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. \<bar>c\<bar> ^ n :: real) \<longlonglongrightarrow> 0"
  2180   by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
  2181 
  2182 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. c ^ n :: real) \<longlonglongrightarrow> 0"
  2183   by (rule LIMSEQ_power_zero) simp
  2184 
  2185 
  2186 subsection \<open>Limits of Functions\<close>
  2187 
  2188 lemma LIM_eq: "f \<midarrow>a\<rightarrow> L = (\<forall>r>0. \<exists>s>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < s \<longrightarrow> norm (f x - L) < r)"
  2189   for a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  2190   by (simp add: LIM_def dist_norm)
  2191 
  2192 lemma LIM_I:
  2193   "(\<And>r. 0 < r \<Longrightarrow> \<exists>s>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < s \<longrightarrow> norm (f x - L) < r) \<Longrightarrow> f \<midarrow>a\<rightarrow> L"
  2194   for a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  2195   by (simp add: LIM_eq)
  2196 
  2197 lemma LIM_D: "f \<midarrow>a\<rightarrow> L \<Longrightarrow> 0 < r \<Longrightarrow> \<exists>s>0.\<forall>x. x \<noteq> a \<and> norm (x - a) < s \<longrightarrow> norm (f x - L) < r"
  2198   for a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  2199   by (simp add: LIM_eq)
  2200 
  2201 lemma LIM_offset: "f \<midarrow>a\<rightarrow> L \<Longrightarrow> (\<lambda>x. f (x + k)) \<midarrow>(a - k)\<rightarrow> L"
  2202   for a :: "'a::real_normed_vector"
  2203   by (simp add: filtermap_at_shift[symmetric, of a k] filterlim_def filtermap_filtermap)
  2204 
  2205 lemma LIM_offset_zero: "f \<midarrow>a\<rightarrow> L \<Longrightarrow> (\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> L"
  2206   for a :: "'a::real_normed_vector"
  2207   by (drule LIM_offset [where k = a]) (simp add: add.commute)
  2208 
  2209 lemma LIM_offset_zero_cancel: "(\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> L \<Longrightarrow> f \<midarrow>a\<rightarrow> L"
  2210   for a :: "'a::real_normed_vector"
  2211   by (drule LIM_offset [where k = "- a"]) simp
  2212 
  2213 lemma LIM_offset_zero_iff: "f \<midarrow>a\<rightarrow> L \<longleftrightarrow> (\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> L"
  2214   for f :: "'a :: real_normed_vector \<Rightarrow> _"
  2215   using LIM_offset_zero_cancel[of f a L] LIM_offset_zero[of f L a] by auto
  2216 
  2217 lemma LIM_zero: "(f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. f x - l) \<longlongrightarrow> 0) F"
  2218   for f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  2219   unfolding tendsto_iff dist_norm by simp
  2220 
  2221 lemma LIM_zero_cancel:
  2222   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  2223   shows "((\<lambda>x. f x - l) \<longlongrightarrow> 0) F \<Longrightarrow> (f \<longlongrightarrow> l) F"
  2224 unfolding tendsto_iff dist_norm by simp
  2225 
  2226 lemma LIM_zero_iff: "((\<lambda>x. f x - l) \<longlongrightarrow> 0) F = (f \<longlongrightarrow> l) F"
  2227   for f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  2228   unfolding tendsto_iff dist_norm by simp
  2229 
  2230 lemma LIM_imp_LIM:
  2231   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  2232   fixes g :: "'a::topological_space \<Rightarrow> 'c::real_normed_vector"
  2233   assumes f: "f \<midarrow>a\<rightarrow> l"
  2234     and le: "\<And>x. x \<noteq> a \<Longrightarrow> norm (g x - m) \<le> norm (f x - l)"
  2235   shows "g \<midarrow>a\<rightarrow> m"
  2236   by (rule metric_LIM_imp_LIM [OF f]) (simp add: dist_norm le)
  2237 
  2238 lemma LIM_equal2:
  2239   fixes f g :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  2240   assumes "0 < R"
  2241     and "\<And>x. x \<noteq> a \<Longrightarrow> norm (x - a) < R \<Longrightarrow> f x = g x"
  2242   shows "g \<midarrow>a\<rightarrow> l \<Longrightarrow> f \<midarrow>a\<rightarrow> l"
  2243   by (rule metric_LIM_equal2 [OF assms]) (simp_all add: dist_norm)
  2244 
  2245 lemma LIM_compose2:
  2246   fixes a :: "'a::real_normed_vector"
  2247   assumes f: "f \<midarrow>a\<rightarrow> b"
  2248     and g: "g \<midarrow>b\<rightarrow> c"
  2249     and inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> b"
  2250   shows "(\<lambda>x. g (f x)) \<midarrow>a\<rightarrow> c"
  2251   by (rule metric_LIM_compose2 [OF f g inj [folded dist_norm]])
  2252 
  2253 lemma real_LIM_sandwich_zero:
  2254   fixes f g :: "'a::topological_space \<Rightarrow> real"
  2255   assumes f: "f \<midarrow>a\<rightarrow> 0"
  2256     and 1: "\<And>x. x \<noteq> a \<Longrightarrow> 0 \<le> g x"
  2257     and 2: "\<And>x. x \<noteq> a \<Longrightarrow> g x \<le> f x"
  2258   shows "g \<midarrow>a\<rightarrow> 0"
  2259 proof (rule LIM_imp_LIM [OF f]) (* FIXME: use tendsto_sandwich *)
  2260   fix x
  2261   assume x: "x \<noteq> a"
  2262   with 1 have "norm (g x - 0) = g x" by simp
  2263   also have "g x \<le> f x" by (rule 2 [OF x])
  2264   also have "f x \<le> \<bar>f x\<bar>" by (rule abs_ge_self)
  2265   also have "\<bar>f x\<bar> = norm (f x - 0)" by simp
  2266   finally show "norm (g x - 0) \<le> norm (f x - 0)" .
  2267 qed
  2268 
  2269 
  2270 subsection \<open>Continuity\<close>
  2271 
  2272 lemma LIM_isCont_iff: "(f \<midarrow>a\<rightarrow> f a) = ((\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> f a)"
  2273   for f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  2274   by (rule iffI [OF LIM_offset_zero LIM_offset_zero_cancel])
  2275 
  2276 lemma isCont_iff: "isCont f x = (\<lambda>h. f (x + h)) \<midarrow>0\<rightarrow> f x"
  2277   for f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  2278   by (simp add: isCont_def LIM_isCont_iff)
  2279 
  2280 lemma isCont_LIM_compose2:
  2281   fixes a :: "'a::real_normed_vector"
  2282   assumes f [unfolded isCont_def]: "isCont f a"
  2283     and g: "g \<midarrow>f a\<rightarrow> l"
  2284     and inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> f a"
  2285   shows "(\<lambda>x. g (f x)) \<midarrow>a\<rightarrow> l"
  2286   by (rule LIM_compose2 [OF f g inj])
  2287 
  2288 lemma isCont_norm [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. norm (f x)) a"
  2289   for f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  2290   by (fact continuous_norm)
  2291 
  2292 lemma isCont_rabs [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. \<bar>f x\<bar>) a"
  2293   for f :: "'a::t2_space \<Rightarrow> real"
  2294   by (fact continuous_rabs)
  2295 
  2296 lemma isCont_add [simp]: "isCont f a \<Longrightarrow> isCont g a \<Longrightarrow> isCont (\<lambda>x. f x + g x) a"
  2297   for f :: "'a::t2_space \<Rightarrow> 'b::topological_monoid_add"
  2298   by (fact continuous_add)
  2299 
  2300 lemma isCont_minus [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. - f x) a"
  2301   for f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  2302   by (fact continuous_minus)
  2303 
  2304 lemma isCont_diff [simp]: "isCont f a \<Longrightarrow> isCont g a \<Longrightarrow> isCont (\<lambda>x. f x - g x) a"
  2305   for f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  2306   by (fact continuous_diff)
  2307 
  2308 lemma isCont_mult [simp]: "isCont f a \<Longrightarrow> isCont g a \<Longrightarrow> isCont (\<lambda>x. f x * g x) a"
  2309   for f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_algebra"
  2310   by (fact continuous_mult)
  2311 
  2312 lemma (in bounded_linear) isCont: "isCont g a \<Longrightarrow> isCont (\<lambda>x. f (g x)) a"
  2313   by (fact continuous)
  2314 
  2315 lemma (in bounded_bilinear) isCont: "isCont f a \<Longrightarrow> isCont g a \<Longrightarrow> isCont (\<lambda>x. f x ** g x) a"
  2316   by (fact continuous)
  2317 
  2318 lemmas isCont_scaleR [simp] =
  2319   bounded_bilinear.isCont [OF bounded_bilinear_scaleR]
  2320 
  2321 lemmas isCont_of_real [simp] =
  2322   bounded_linear.isCont [OF bounded_linear_of_real]
  2323 
  2324 lemma isCont_power [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. f x ^ n) a"
  2325   for f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
  2326   by (fact continuous_power)
  2327 
  2328 lemma isCont_setsum [simp]: "\<forall>i\<in>A. isCont (f i) a \<Longrightarrow> isCont (\<lambda>x. \<Sum>i\<in>A. f i x) a"
  2329   for f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::topological_comm_monoid_add"
  2330   by (auto intro: continuous_setsum)
  2331 
  2332 
  2333 subsection \<open>Uniform Continuity\<close>
  2334 
  2335 lemma uniformly_continuous_on_def:
  2336   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space"
  2337   shows "uniformly_continuous_on s f \<longleftrightarrow>
  2338     (\<forall>e>0. \<exists>d>0. \<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e)"
  2339   unfolding uniformly_continuous_on_uniformity
  2340     uniformity_dist filterlim_INF filterlim_principal eventually_inf_principal
  2341   by (force simp: Ball_def uniformity_dist[symmetric] eventually_uniformity_metric)
  2342 
  2343 abbreviation isUCont :: "['a::metric_space \<Rightarrow> 'b::metric_space] \<Rightarrow> bool"
  2344   where "isUCont f \<equiv> uniformly_continuous_on UNIV f"
  2345 
  2346 lemma isUCont_def: "isUCont f \<longleftrightarrow> (\<forall>r>0. \<exists>s>0. \<forall>x y. dist x y < s \<longrightarrow> dist (f x) (f y) < r)"
  2347   by (auto simp: uniformly_continuous_on_def dist_commute)
  2348 
  2349 lemma isUCont_isCont: "isUCont f \<Longrightarrow> isCont f x"
  2350   by (drule uniformly_continuous_imp_continuous) (simp add: continuous_on_eq_continuous_at)
  2351 
  2352 lemma uniformly_continuous_on_Cauchy:
  2353   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space"
  2354   assumes "uniformly_continuous_on S f" "Cauchy X" "\<And>n. X n \<in> S"
  2355   shows "Cauchy (\<lambda>n. f (X n))"
  2356   using assms
  2357   apply (simp only: uniformly_continuous_on_def)
  2358   apply (rule metric_CauchyI)
  2359   apply (drule_tac x=e in spec)
  2360   apply safe
  2361   apply (drule_tac e=d in metric_CauchyD)
  2362    apply safe
  2363   apply (rule_tac x=M in exI)
  2364   apply simp
  2365   done
  2366 
  2367 lemma isUCont_Cauchy: "isUCont f \<Longrightarrow> Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  2368   by (rule uniformly_continuous_on_Cauchy[where S=UNIV and f=f]) simp_all
  2369 
  2370 lemma (in bounded_linear) isUCont: "isUCont f"
  2371   unfolding isUCont_def dist_norm
  2372 proof (intro allI impI)
  2373   fix r :: real
  2374   assume r: "0 < r"
  2375   obtain K where K: "0 < K" and norm_le: "norm (f x) \<le> norm x * K" for x
  2376     using pos_bounded by blast
  2377   show "\<exists>s>0. \<forall>x y. norm (x - y) < s \<longrightarrow> norm (f x - f y) < r"
  2378   proof (rule exI, safe)
  2379     from r K show "0 < r / K" by simp
  2380   next
  2381     fix x y :: 'a
  2382     assume xy: "norm (x - y) < r / K"
  2383     have "norm (f x - f y) = norm (f (x - y))" by (simp only: diff)
  2384     also have "\<dots> \<le> norm (x - y) * K" by (rule norm_le)
  2385     also from K xy have "\<dots> < r" by (simp only: pos_less_divide_eq)
  2386     finally show "norm (f x - f y) < r" .
  2387   qed
  2388 qed
  2389 
  2390 lemma (in bounded_linear) Cauchy: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  2391   by (rule isUCont [THEN isUCont_Cauchy])
  2392 
  2393 lemma LIM_less_bound:
  2394   fixes f :: "real \<Rightarrow> real"
  2395   assumes ev: "b < x" "\<forall> x' \<in> { b <..< x}. 0 \<le> f x'" and "isCont f x"
  2396   shows "0 \<le> f x"
  2397 proof (rule tendsto_le_const)
  2398   show "(f \<longlongrightarrow> f x) (at_left x)"
  2399     using \<open>isCont f x\<close> by (simp add: filterlim_at_split isCont_def)
  2400   show "eventually (\<lambda>x. 0 \<le> f x) (at_left x)"
  2401     using ev by (auto simp: eventually_at dist_real_def intro!: exI[of _ "x - b"])
  2402 qed simp
  2403 
  2404 
  2405 subsection \<open>Nested Intervals and Bisection -- Needed for Compactness\<close>
  2406 
  2407 lemma nested_sequence_unique:
  2408   assumes "\<forall>n. f n \<le> f (Suc n)" "\<forall>n. g (Suc n) \<le> g n" "\<forall>n. f n \<le> g n" "(\<lambda>n. f n - g n) \<longlonglongrightarrow> 0"
  2409   shows "\<exists>l::real. ((\<forall>n. f n \<le> l) \<and> f \<longlonglongrightarrow> l) \<and> ((\<forall>n. l \<le> g n) \<and> g \<longlonglongrightarrow> l)"
  2410 proof -
  2411   have "incseq f" unfolding incseq_Suc_iff by fact
  2412   have "decseq g" unfolding decseq_Suc_iff by fact
  2413   have "f n \<le> g 0" for n
  2414   proof -
  2415     from \<open>decseq g\<close> have "g n \<le> g 0"
  2416       by (rule decseqD) simp
  2417     with \<open>\<forall>n. f n \<le> g n\<close>[THEN spec, of n] show ?thesis
  2418       by auto
  2419   qed
  2420   then obtain u where "f \<longlonglongrightarrow> u" "\<forall>i. f i \<le> u"
  2421     using incseq_convergent[OF \<open>incseq f\<close>] by auto
  2422   moreover have "f 0 \<le> g n" for n
  2423   proof -
  2424     from \<open>incseq f\<close> have "f 0 \<le> f n" by (rule incseqD) simp
  2425     with \<open>\<forall>n. f n \<le> g n\<close>[THEN spec, of n] show ?thesis
  2426       by simp
  2427   qed
  2428   then obtain l where "g \<longlonglongrightarrow> l" "\<forall>i. l \<le> g i"
  2429     using decseq_convergent[OF \<open>decseq g\<close>] by auto
  2430   moreover note LIMSEQ_unique[OF assms(4) tendsto_diff[OF \<open>f \<longlonglongrightarrow> u\<close> \<open>g \<longlonglongrightarrow> l\<close>]]
  2431   ultimately show ?thesis by auto
  2432 qed
  2433 
  2434 lemma Bolzano[consumes 1, case_names trans local]:
  2435   fixes P :: "real \<Rightarrow> real \<Rightarrow> bool"
  2436   assumes [arith]: "a \<le> b"
  2437     and trans: "\<And>a b c. P a b \<Longrightarrow> P b c \<Longrightarrow> a \<le> b \<Longrightarrow> b \<le> c \<Longrightarrow> P a c"
  2438     and local: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> \<exists>d>0. \<forall>a b. a \<le> x \<and> x \<le> b \<and> b - a < d \<longrightarrow> P a b"
  2439   shows "P a b"
  2440 proof -
  2441   define bisect where "bisect =
  2442     rec_nat (a, b) (\<lambda>n (x, y). if P x ((x+y) / 2) then ((x+y)/2, y) else (x, (x+y)/2))"
  2443   define l u where "l n = fst (bisect n)" and "u n = snd (bisect n)" for n
  2444   have l[simp]: "l 0 = a" "\<And>n. l (Suc n) = (if P (l n) ((l n + u n) / 2) then (l n + u n) / 2 else l n)"
  2445     and u[simp]: "u 0 = b" "\<And>n. u (Suc n) = (if P (l n) ((l n + u n) / 2) then u n else (l n + u n) / 2)"
  2446     by (simp_all add: l_def u_def bisect_def split: prod.split)
  2447 
  2448   have [simp]: "l n \<le> u n" for n by (induct n) auto
  2449 
  2450   have "\<exists>x. ((\<forall>n. l n \<le> x) \<and> l \<longlonglongrightarrow> x) \<and> ((\<forall>n. x \<le> u n) \<and> u \<longlonglongrightarrow> x)"
  2451   proof (safe intro!: nested_sequence_unique)
  2452     show "l n \<le> l (Suc n)" "u (Suc n) \<le> u n" for n
  2453       by (induct n) auto
  2454   next
  2455     have "l n - u n = (a - b) / 2^n" for n
  2456       by (induct n) (auto simp: field_simps)
  2457     then show "(\<lambda>n. l n - u n) \<longlonglongrightarrow> 0"
  2458       by (simp add: LIMSEQ_divide_realpow_zero)
  2459   qed fact
  2460   then obtain x where x: "\<And>n. l n \<le> x" "\<And>n. x \<le> u n" and "l \<longlonglongrightarrow> x" "u \<longlonglongrightarrow> x"
  2461     by auto
  2462   obtain d where "0 < d" and d: "a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> b - a < d \<Longrightarrow> P a b" for a b
  2463     using \<open>l 0 \<le> x\<close> \<open>x \<le> u 0\<close> local[of x] by auto
  2464 
  2465   show "P a b"
  2466   proof (rule ccontr)
  2467     assume "\<not> P a b"
  2468     have "\<not> P (l n) (u n)" for n
  2469     proof (induct n)
  2470       case 0
  2471       then show ?case
  2472         by (simp add: \<open>\<not> P a b\<close>)
  2473     next
  2474       case (Suc n)
  2475       with trans[of "l n" "(l n + u n) / 2" "u n"] show ?case
  2476         by auto
  2477     qed
  2478     moreover
  2479     {
  2480       have "eventually (\<lambda>n. x - d / 2 < l n) sequentially"
  2481         using \<open>0 < d\<close> \<open>l \<longlonglongrightarrow> x\<close> by (intro order_tendstoD[of _ x]) auto
  2482       moreover have "eventually (\<lambda>n. u n < x + d / 2) sequentially"
  2483         using \<open>0 < d\<close> \<open>u \<longlonglongrightarrow> x\<close> by (intro order_tendstoD[of _ x]) auto
  2484       ultimately have "eventually (\<lambda>n. P (l n) (u n)) sequentially"
  2485       proof eventually_elim
  2486         case (elim n)
  2487         from add_strict_mono[OF this] have "u n - l n < d" by simp
  2488         with x show "P (l n) (u n)" by (rule d)
  2489       qed
  2490     }
  2491     ultimately show False by simp
  2492   qed
  2493 qed
  2494 
  2495 lemma compact_Icc[simp, intro]: "compact {a .. b::real}"
  2496 proof (cases "a \<le> b", rule compactI)
  2497   fix C
  2498   assume C: "a \<le> b" "\<forall>t\<in>C. open t" "{a..b} \<subseteq> \<Union>C"
  2499   define T where "T = {a .. b}"
  2500   from C(1,3) show "\<exists>C'\<subseteq>C. finite C' \<and> {a..b} \<subseteq> \<Union>C'"
  2501   proof (induct rule: Bolzano)
  2502     case (trans a b c)
  2503     then have *: "{a..c} = {a..b} \<union> {b..c}"
  2504       by auto
  2505     with trans obtain C1 C2
  2506       where "C1\<subseteq>C" "finite C1" "{a..b} \<subseteq> \<Union>C1" "C2\<subseteq>C" "finite C2" "{b..c} \<subseteq> \<Union>C2"
  2507       by auto
  2508     with trans show ?case
  2509       unfolding * by (intro exI[of _ "C1 \<union> C2"]) auto
  2510   next
  2511     case (local x)
  2512     with C have "x \<in> \<Union>C" by auto
  2513     with C(2) obtain c where "x \<in> c" "open c" "c \<in> C"
  2514       by auto
  2515     then obtain e where "0 < e" "{x - e <..< x + e} \<subseteq> c"
  2516       by (auto simp: open_dist dist_real_def subset_eq Ball_def abs_less_iff)
  2517     with \<open>c \<in> C\<close> show ?case
  2518       by (safe intro!: exI[of _ "e/2"] exI[of _ "{c}"]) auto
  2519   qed
  2520 qed simp
  2521 
  2522 
  2523 lemma continuous_image_closed_interval:
  2524   fixes a b and f :: "real \<Rightarrow> real"
  2525   defines "S \<equiv> {a..b}"
  2526   assumes "a \<le> b" and f: "continuous_on S f"
  2527   shows "\<exists>c d. f`S = {c..d} \<and> c \<le> d"
  2528 proof -
  2529   have S: "compact S" "S \<noteq> {}"
  2530     using \<open>a \<le> b\<close> by (auto simp: S_def)
  2531   obtain c where "c \<in> S" "\<forall>d\<in>S. f d \<le> f c"
  2532     using continuous_attains_sup[OF S f] by auto
  2533   moreover obtain d where "d \<in> S" "\<forall>c\<in>S. f d \<le> f c"
  2534     using continuous_attains_inf[OF S f] by auto
  2535   moreover have "connected (f`S)"
  2536     using connected_continuous_image[OF f] connected_Icc by (auto simp: S_def)
  2537   ultimately have "f ` S = {f d .. f c} \<and> f d \<le> f c"
  2538     by (auto simp: connected_iff_interval)
  2539   then show ?thesis
  2540     by auto
  2541 qed
  2542 
  2543 lemma open_Collect_positive:
  2544   fixes f :: "'a::t2_space \<Rightarrow> real"
  2545   assumes f: "continuous_on s f"
  2546   shows "\<exists>A. open A \<and> A \<inter> s = {x\<in>s. 0 < f x}"
  2547   using continuous_on_open_invariant[THEN iffD1, OF f, rule_format, of "{0 <..}"]
  2548   by (auto simp: Int_def field_simps)
  2549 
  2550 lemma open_Collect_less_Int:
  2551   fixes f g :: "'a::t2_space \<Rightarrow> real"
  2552   assumes f: "continuous_on s f"
  2553     and g: "continuous_on s g"
  2554   shows "\<exists>A. open A \<and> A \<inter> s = {x\<in>s. f x < g x}"
  2555   using open_Collect_positive[OF continuous_on_diff[OF g f]] by (simp add: field_simps)
  2556 
  2557 
  2558 subsection \<open>Boundedness of continuous functions\<close>
  2559 
  2560 text\<open>By bisection, function continuous on closed interval is bounded above\<close>
  2561 
  2562 lemma isCont_eq_Ub:
  2563   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  2564   shows "a \<le> b \<Longrightarrow> \<forall>x::real. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  2565     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  2566   using continuous_attains_sup[of "{a..b}" f]
  2567   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  2568 
  2569 lemma isCont_eq_Lb:
  2570   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  2571   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  2572     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> M \<le> f x) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  2573   using continuous_attains_inf[of "{a..b}" f]
  2574   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  2575 
  2576 lemma isCont_bounded:
  2577   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  2578   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow> \<exists>M. \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M"
  2579   using isCont_eq_Ub[of a b f] by auto
  2580 
  2581 lemma isCont_has_Ub:
  2582   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  2583   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  2584     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<forall>N. N < M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> N < f x))"
  2585   using isCont_eq_Ub[of a b f] by auto
  2586 
  2587 (*HOL style here: object-level formulations*)
  2588 lemma IVT_objl:
  2589   "(f a \<le> y \<and> y \<le> f b \<and> a \<le> b \<and> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x)) \<longrightarrow>
  2590     (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y)"
  2591   for a y :: real
  2592   by (blast intro: IVT)
  2593 
  2594 lemma IVT2_objl:
  2595   "(f b \<le> y \<and> y \<le> f a \<and> a \<le> b \<and> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x)) \<longrightarrow>
  2596     (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y)"
  2597   for b y :: real
  2598   by (blast intro: IVT2)
  2599 
  2600 lemma isCont_Lb_Ub:
  2601   fixes f :: "real \<Rightarrow> real"
  2602   assumes "a \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x"
  2603   shows "\<exists>L M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> L \<le> f x \<and> f x \<le> M) \<and>
  2604     (\<forall>y. L \<le> y \<and> y \<le> M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> (f x = y)))"
  2605 proof -
  2606   obtain M where M: "a \<le> M" "M \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> f M"
  2607     using isCont_eq_Ub[OF assms] by auto
  2608   obtain L where L: "a \<le> L" "L \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f L \<le> f x"
  2609     using isCont_eq_Lb[OF assms] by auto
  2610   show ?thesis
  2611     using IVT[of f L _ M] IVT2[of f L _ M] M L assms
  2612     apply (rule_tac x="f L" in exI)
  2613     apply (rule_tac x="f M" in exI)
  2614     apply (cases "L \<le> M")
  2615      apply simp
  2616      apply (metis order_trans)
  2617     apply simp
  2618     apply (metis order_trans)
  2619     done
  2620 qed
  2621 
  2622 
  2623 text \<open>Continuity of inverse function.\<close>
  2624 
  2625 lemma isCont_inverse_function:
  2626   fixes f g :: "real \<Rightarrow> real"
  2627   assumes d: "0 < d"
  2628     and inj: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> g (f z) = z"
  2629     and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> isCont f z"
  2630   shows "isCont g (f x)"
  2631 proof -
  2632   let ?A = "f (x - d)"
  2633   let ?B = "f (x + d)"
  2634   let ?D = "{x - d..x + d}"
  2635 
  2636   have f: "continuous_on ?D f"
  2637     using cont by (intro continuous_at_imp_continuous_on ballI) auto
  2638   then have g: "continuous_on (f`?D) g"
  2639     using inj by (intro continuous_on_inv) auto
  2640 
  2641   from d f have "{min ?A ?B <..< max ?A ?B} \<subseteq> f ` ?D"
  2642     by (intro connected_contains_Ioo connected_continuous_image) (auto split: split_min split_max)
  2643   with g have "continuous_on {min ?A ?B <..< max ?A ?B} g"
  2644     by (rule continuous_on_subset)
  2645   moreover
  2646   have "(?A < f x \<and> f x < ?B) \<or> (?B < f x \<and> f x < ?A)"
  2647     using d inj by (intro continuous_inj_imp_mono[OF _ _ f] inj_on_imageI2[of g, OF inj_onI]) auto
  2648   then have "f x \<in> {min ?A ?B <..< max ?A ?B}"
  2649     by auto
  2650   ultimately
  2651   show ?thesis
  2652     by (simp add: continuous_on_eq_continuous_at)
  2653 qed
  2654 
  2655 lemma isCont_inverse_function2:
  2656   fixes f g :: "real \<Rightarrow> real"
  2657   shows
  2658     "a < x \<Longrightarrow> x < b \<Longrightarrow>
  2659       \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> g (f z) = z \<Longrightarrow>
  2660       \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> isCont f z \<Longrightarrow> isCont g (f x)"
  2661   apply (rule isCont_inverse_function [where f=f and d="min (x - a) (b - x)"])
  2662   apply (simp_all add: abs_le_iff)
  2663   done
  2664 
  2665 (* need to rename second isCont_inverse *)
  2666 lemma isCont_inv_fun:
  2667   fixes f g :: "real \<Rightarrow> real"
  2668   shows "0 < d \<Longrightarrow> (\<forall>z. \<bar>z - x\<bar> \<le> d \<longrightarrow> g (f z) = z) \<Longrightarrow>
  2669     \<forall>z. \<bar>z - x\<bar> \<le> d \<longrightarrow> isCont f z \<Longrightarrow> isCont g (f x)"
  2670   by (rule isCont_inverse_function)
  2671 
  2672 text \<open>Bartle/Sherbert: Introduction to Real Analysis, Theorem 4.2.9, p. 110.\<close>
  2673 lemma LIM_fun_gt_zero: "f \<midarrow>c\<rightarrow> l \<Longrightarrow> 0 < l \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> 0 < f x)"
  2674   for f :: "real \<Rightarrow> real"
  2675   apply (drule (1) LIM_D)
  2676   apply clarify
  2677   apply (rule_tac x = s in exI)
  2678   apply (simp add: abs_less_iff)
  2679   done
  2680 
  2681 lemma LIM_fun_less_zero: "f \<midarrow>c\<rightarrow> l \<Longrightarrow> l < 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x < 0)"
  2682   for f :: "real \<Rightarrow> real"
  2683   apply (drule LIM_D [where r="-l"])
  2684    apply simp
  2685   apply clarify
  2686   apply (rule_tac x = s in exI)
  2687   apply (simp add: abs_less_iff)
  2688   done
  2689 
  2690 lemma LIM_fun_not_zero: "f \<midarrow>c\<rightarrow> l \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x \<noteq> 0)"
  2691   for f :: "real \<Rightarrow> real"
  2692   using LIM_fun_gt_zero[of f l c] LIM_fun_less_zero[of f l c] by (auto simp add: neq_iff)
  2693 
  2694 end