src/HOL/Filter.thy
author blanchet
Tue Nov 07 15:16:42 2017 +0100 (19 months ago)
changeset 67022 49309fe530fd
parent 66171 454abfe923fe
child 67399 eab6ce8368fa
permissions -rw-r--r--
more robust parsing for THF proofs (esp. polymorphic Leo-III proofs)
     1 (*  Title:      HOL/Filter.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 section \<open>Filters on predicates\<close>
     7 
     8 theory Filter
     9 imports Set_Interval Lifting_Set
    10 begin
    11 
    12 subsection \<open>Filters\<close>
    13 
    14 text \<open>
    15   This definition also allows non-proper filters.
    16 \<close>
    17 
    18 locale is_filter =
    19   fixes F :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
    20   assumes True: "F (\<lambda>x. True)"
    21   assumes conj: "F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x) \<Longrightarrow> F (\<lambda>x. P x \<and> Q x)"
    22   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x)"
    23 
    24 typedef 'a filter = "{F :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter F}"
    25 proof
    26   show "(\<lambda>x. True) \<in> ?filter" by (auto intro: is_filter.intro)
    27 qed
    28 
    29 lemma is_filter_Rep_filter: "is_filter (Rep_filter F)"
    30   using Rep_filter [of F] by simp
    31 
    32 lemma Abs_filter_inverse':
    33   assumes "is_filter F" shows "Rep_filter (Abs_filter F) = F"
    34   using assms by (simp add: Abs_filter_inverse)
    35 
    36 
    37 subsubsection \<open>Eventually\<close>
    38 
    39 definition eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
    40   where "eventually P F \<longleftrightarrow> Rep_filter F P"
    41 
    42 syntax
    43   "_eventually" :: "pttrn => 'a filter => bool => bool"  ("(3\<forall>\<^sub>F _ in _./ _)" [0, 0, 10] 10)
    44 translations
    45   "\<forall>\<^sub>Fx in F. P" == "CONST eventually (\<lambda>x. P) F"
    46 
    47 lemma eventually_Abs_filter:
    48   assumes "is_filter F" shows "eventually P (Abs_filter F) = F P"
    49   unfolding eventually_def using assms by (simp add: Abs_filter_inverse)
    50 
    51 lemma filter_eq_iff:
    52   shows "F = F' \<longleftrightarrow> (\<forall>P. eventually P F = eventually P F')"
    53   unfolding Rep_filter_inject [symmetric] fun_eq_iff eventually_def ..
    54 
    55 lemma eventually_True [simp]: "eventually (\<lambda>x. True) F"
    56   unfolding eventually_def
    57   by (rule is_filter.True [OF is_filter_Rep_filter])
    58 
    59 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P F"
    60 proof -
    61   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
    62   thus "eventually P F" by simp
    63 qed
    64 
    65 lemma eventuallyI: "(\<And>x. P x) \<Longrightarrow> eventually P F"
    66   by (auto intro: always_eventually)
    67 
    68 lemma eventually_mono:
    69   "\<lbrakk>eventually P F; \<And>x. P x \<Longrightarrow> Q x\<rbrakk> \<Longrightarrow> eventually Q F"
    70   unfolding eventually_def
    71   by (blast intro: is_filter.mono [OF is_filter_Rep_filter])
    72 
    73 lemma eventually_conj:
    74   assumes P: "eventually (\<lambda>x. P x) F"
    75   assumes Q: "eventually (\<lambda>x. Q x) F"
    76   shows "eventually (\<lambda>x. P x \<and> Q x) F"
    77   using assms unfolding eventually_def
    78   by (rule is_filter.conj [OF is_filter_Rep_filter])
    79 
    80 lemma eventually_mp:
    81   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
    82   assumes "eventually (\<lambda>x. P x) F"
    83   shows "eventually (\<lambda>x. Q x) F"
    84 proof -
    85   have "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) F"
    86     using assms by (rule eventually_conj)
    87   then show ?thesis
    88     by (blast intro: eventually_mono)
    89 qed
    90 
    91 lemma eventually_rev_mp:
    92   assumes "eventually (\<lambda>x. P x) F"
    93   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
    94   shows "eventually (\<lambda>x. Q x) F"
    95 using assms(2) assms(1) by (rule eventually_mp)
    96 
    97 lemma eventually_conj_iff:
    98   "eventually (\<lambda>x. P x \<and> Q x) F \<longleftrightarrow> eventually P F \<and> eventually Q F"
    99   by (auto intro: eventually_conj elim: eventually_rev_mp)
   100 
   101 lemma eventually_elim2:
   102   assumes "eventually (\<lambda>i. P i) F"
   103   assumes "eventually (\<lambda>i. Q i) F"
   104   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
   105   shows "eventually (\<lambda>i. R i) F"
   106   using assms by (auto elim!: eventually_rev_mp)
   107 
   108 lemma eventually_ball_finite_distrib:
   109   "finite A \<Longrightarrow> (eventually (\<lambda>x. \<forall>y\<in>A. P x y) net) \<longleftrightarrow> (\<forall>y\<in>A. eventually (\<lambda>x. P x y) net)"
   110   by (induction A rule: finite_induct) (auto simp: eventually_conj_iff)
   111 
   112 lemma eventually_ball_finite:
   113   "finite A \<Longrightarrow> \<forall>y\<in>A. eventually (\<lambda>x. P x y) net \<Longrightarrow> eventually (\<lambda>x. \<forall>y\<in>A. P x y) net"
   114   by (auto simp: eventually_ball_finite_distrib)
   115 
   116 lemma eventually_all_finite:
   117   fixes P :: "'a \<Rightarrow> 'b::finite \<Rightarrow> bool"
   118   assumes "\<And>y. eventually (\<lambda>x. P x y) net"
   119   shows "eventually (\<lambda>x. \<forall>y. P x y) net"
   120 using eventually_ball_finite [of UNIV P] assms by simp
   121 
   122 lemma eventually_ex: "(\<forall>\<^sub>Fx in F. \<exists>y. P x y) \<longleftrightarrow> (\<exists>Y. \<forall>\<^sub>Fx in F. P x (Y x))"
   123 proof
   124   assume "\<forall>\<^sub>Fx in F. \<exists>y. P x y"
   125   then have "\<forall>\<^sub>Fx in F. P x (SOME y. P x y)"
   126     by (auto intro: someI_ex eventually_mono)
   127   then show "\<exists>Y. \<forall>\<^sub>Fx in F. P x (Y x)"
   128     by auto
   129 qed (auto intro: eventually_mono)
   130 
   131 lemma not_eventually_impI: "eventually P F \<Longrightarrow> \<not> eventually Q F \<Longrightarrow> \<not> eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   132   by (auto intro: eventually_mp)
   133 
   134 lemma not_eventuallyD: "\<not> eventually P F \<Longrightarrow> \<exists>x. \<not> P x"
   135   by (metis always_eventually)
   136 
   137 lemma eventually_subst:
   138   assumes "eventually (\<lambda>n. P n = Q n) F"
   139   shows "eventually P F = eventually Q F" (is "?L = ?R")
   140 proof -
   141   from assms have "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   142       and "eventually (\<lambda>x. Q x \<longrightarrow> P x) F"
   143     by (auto elim: eventually_mono)
   144   then show ?thesis by (auto elim: eventually_elim2)
   145 qed
   146 
   147 subsection \<open> Frequently as dual to eventually \<close>
   148 
   149 definition frequently :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
   150   where "frequently P F \<longleftrightarrow> \<not> eventually (\<lambda>x. \<not> P x) F"
   151 
   152 syntax
   153   "_frequently" :: "pttrn \<Rightarrow> 'a filter \<Rightarrow> bool \<Rightarrow> bool"  ("(3\<exists>\<^sub>F _ in _./ _)" [0, 0, 10] 10)
   154 translations
   155   "\<exists>\<^sub>Fx in F. P" == "CONST frequently (\<lambda>x. P) F"
   156 
   157 lemma not_frequently_False [simp]: "\<not> (\<exists>\<^sub>Fx in F. False)"
   158   by (simp add: frequently_def)
   159 
   160 lemma frequently_ex: "\<exists>\<^sub>Fx in F. P x \<Longrightarrow> \<exists>x. P x"
   161   by (auto simp: frequently_def dest: not_eventuallyD)
   162 
   163 lemma frequentlyE: assumes "frequently P F" obtains x where "P x"
   164   using frequently_ex[OF assms] by auto
   165 
   166 lemma frequently_mp:
   167   assumes ev: "\<forall>\<^sub>Fx in F. P x \<longrightarrow> Q x" and P: "\<exists>\<^sub>Fx in F. P x" shows "\<exists>\<^sub>Fx in F. Q x"
   168 proof -
   169   from ev have "eventually (\<lambda>x. \<not> Q x \<longrightarrow> \<not> P x) F"
   170     by (rule eventually_rev_mp) (auto intro!: always_eventually)
   171   from eventually_mp[OF this] P show ?thesis
   172     by (auto simp: frequently_def)
   173 qed
   174 
   175 lemma frequently_rev_mp:
   176   assumes "\<exists>\<^sub>Fx in F. P x"
   177   assumes "\<forall>\<^sub>Fx in F. P x \<longrightarrow> Q x"
   178   shows "\<exists>\<^sub>Fx in F. Q x"
   179 using assms(2) assms(1) by (rule frequently_mp)
   180 
   181 lemma frequently_mono: "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> frequently P F \<Longrightarrow> frequently Q F"
   182   using frequently_mp[of P Q] by (simp add: always_eventually)
   183 
   184 lemma frequently_elim1: "\<exists>\<^sub>Fx in F. P x \<Longrightarrow> (\<And>i. P i \<Longrightarrow> Q i) \<Longrightarrow> \<exists>\<^sub>Fx in F. Q x"
   185   by (metis frequently_mono)
   186 
   187 lemma frequently_disj_iff: "(\<exists>\<^sub>Fx in F. P x \<or> Q x) \<longleftrightarrow> (\<exists>\<^sub>Fx in F. P x) \<or> (\<exists>\<^sub>Fx in F. Q x)"
   188   by (simp add: frequently_def eventually_conj_iff)
   189 
   190 lemma frequently_disj: "\<exists>\<^sub>Fx in F. P x \<Longrightarrow> \<exists>\<^sub>Fx in F. Q x \<Longrightarrow> \<exists>\<^sub>Fx in F. P x \<or> Q x"
   191   by (simp add: frequently_disj_iff)
   192 
   193 lemma frequently_bex_finite_distrib:
   194   assumes "finite A" shows "(\<exists>\<^sub>Fx in F. \<exists>y\<in>A. P x y) \<longleftrightarrow> (\<exists>y\<in>A. \<exists>\<^sub>Fx in F. P x y)"
   195   using assms by induction (auto simp: frequently_disj_iff)
   196 
   197 lemma frequently_bex_finite: "finite A \<Longrightarrow> \<exists>\<^sub>Fx in F. \<exists>y\<in>A. P x y \<Longrightarrow> \<exists>y\<in>A. \<exists>\<^sub>Fx in F. P x y"
   198   by (simp add: frequently_bex_finite_distrib)
   199 
   200 lemma frequently_all: "(\<exists>\<^sub>Fx in F. \<forall>y. P x y) \<longleftrightarrow> (\<forall>Y. \<exists>\<^sub>Fx in F. P x (Y x))"
   201   using eventually_ex[of "\<lambda>x y. \<not> P x y" F] by (simp add: frequently_def)
   202 
   203 lemma
   204   shows not_eventually: "\<not> eventually P F \<longleftrightarrow> (\<exists>\<^sub>Fx in F. \<not> P x)"
   205     and not_frequently: "\<not> frequently P F \<longleftrightarrow> (\<forall>\<^sub>Fx in F. \<not> P x)"
   206   by (auto simp: frequently_def)
   207 
   208 lemma frequently_imp_iff:
   209   "(\<exists>\<^sub>Fx in F. P x \<longrightarrow> Q x) \<longleftrightarrow> (eventually P F \<longrightarrow> frequently Q F)"
   210   unfolding imp_conv_disj frequently_disj_iff not_eventually[symmetric] ..
   211 
   212 lemma eventually_frequently_const_simps:
   213   "(\<exists>\<^sub>Fx in F. P x \<and> C) \<longleftrightarrow> (\<exists>\<^sub>Fx in F. P x) \<and> C"
   214   "(\<exists>\<^sub>Fx in F. C \<and> P x) \<longleftrightarrow> C \<and> (\<exists>\<^sub>Fx in F. P x)"
   215   "(\<forall>\<^sub>Fx in F. P x \<or> C) \<longleftrightarrow> (\<forall>\<^sub>Fx in F. P x) \<or> C"
   216   "(\<forall>\<^sub>Fx in F. C \<or> P x) \<longleftrightarrow> C \<or> (\<forall>\<^sub>Fx in F. P x)"
   217   "(\<forall>\<^sub>Fx in F. P x \<longrightarrow> C) \<longleftrightarrow> ((\<exists>\<^sub>Fx in F. P x) \<longrightarrow> C)"
   218   "(\<forall>\<^sub>Fx in F. C \<longrightarrow> P x) \<longleftrightarrow> (C \<longrightarrow> (\<forall>\<^sub>Fx in F. P x))"
   219   by (cases C; simp add: not_frequently)+
   220 
   221 lemmas eventually_frequently_simps =
   222   eventually_frequently_const_simps
   223   not_eventually
   224   eventually_conj_iff
   225   eventually_ball_finite_distrib
   226   eventually_ex
   227   not_frequently
   228   frequently_disj_iff
   229   frequently_bex_finite_distrib
   230   frequently_all
   231   frequently_imp_iff
   232 
   233 ML \<open>
   234   fun eventually_elim_tac facts =
   235     CONTEXT_SUBGOAL (fn (goal, i) => fn (ctxt, st) =>
   236       let
   237         val mp_thms = facts RL @{thms eventually_rev_mp}
   238         val raw_elim_thm =
   239           (@{thm allI} RS @{thm always_eventually})
   240           |> fold (fn thm1 => fn thm2 => thm2 RS thm1) mp_thms
   241           |> fold (fn _ => fn thm => @{thm impI} RS thm) facts
   242         val cases_prop =
   243           Thm.prop_of
   244             (Rule_Cases.internalize_params (raw_elim_thm RS Goal.init (Thm.cterm_of ctxt goal)))
   245         val cases = Rule_Cases.make_common ctxt cases_prop [(("elim", []), [])]
   246       in CONTEXT_CASES cases (resolve_tac ctxt [raw_elim_thm] i) (ctxt, st) end)
   247 \<close>
   248 
   249 method_setup eventually_elim = \<open>
   250   Scan.succeed (fn _ => CONTEXT_METHOD (fn facts => eventually_elim_tac facts 1))
   251 \<close> "elimination of eventually quantifiers"
   252 
   253 subsubsection \<open>Finer-than relation\<close>
   254 
   255 text \<open>@{term "F \<le> F'"} means that filter @{term F} is finer than
   256 filter @{term F'}.\<close>
   257 
   258 instantiation filter :: (type) complete_lattice
   259 begin
   260 
   261 definition le_filter_def:
   262   "F \<le> F' \<longleftrightarrow> (\<forall>P. eventually P F' \<longrightarrow> eventually P F)"
   263 
   264 definition
   265   "(F :: 'a filter) < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   266 
   267 definition
   268   "top = Abs_filter (\<lambda>P. \<forall>x. P x)"
   269 
   270 definition
   271   "bot = Abs_filter (\<lambda>P. True)"
   272 
   273 definition
   274   "sup F F' = Abs_filter (\<lambda>P. eventually P F \<and> eventually P F')"
   275 
   276 definition
   277   "inf F F' = Abs_filter
   278       (\<lambda>P. \<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   279 
   280 definition
   281   "Sup S = Abs_filter (\<lambda>P. \<forall>F\<in>S. eventually P F)"
   282 
   283 definition
   284   "Inf S = Sup {F::'a filter. \<forall>F'\<in>S. F \<le> F'}"
   285 
   286 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
   287   unfolding top_filter_def
   288   by (rule eventually_Abs_filter, rule is_filter.intro, auto)
   289 
   290 lemma eventually_bot [simp]: "eventually P bot"
   291   unfolding bot_filter_def
   292   by (subst eventually_Abs_filter, rule is_filter.intro, auto)
   293 
   294 lemma eventually_sup:
   295   "eventually P (sup F F') \<longleftrightarrow> eventually P F \<and> eventually P F'"
   296   unfolding sup_filter_def
   297   by (rule eventually_Abs_filter, rule is_filter.intro)
   298      (auto elim!: eventually_rev_mp)
   299 
   300 lemma eventually_inf:
   301   "eventually P (inf F F') \<longleftrightarrow>
   302    (\<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   303   unfolding inf_filter_def
   304   apply (rule eventually_Abs_filter, rule is_filter.intro)
   305   apply (fast intro: eventually_True)
   306   apply clarify
   307   apply (intro exI conjI)
   308   apply (erule (1) eventually_conj)
   309   apply (erule (1) eventually_conj)
   310   apply simp
   311   apply auto
   312   done
   313 
   314 lemma eventually_Sup:
   315   "eventually P (Sup S) \<longleftrightarrow> (\<forall>F\<in>S. eventually P F)"
   316   unfolding Sup_filter_def
   317   apply (rule eventually_Abs_filter, rule is_filter.intro)
   318   apply (auto intro: eventually_conj elim!: eventually_rev_mp)
   319   done
   320 
   321 instance proof
   322   fix F F' F'' :: "'a filter" and S :: "'a filter set"
   323   { show "F < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   324     by (rule less_filter_def) }
   325   { show "F \<le> F"
   326     unfolding le_filter_def by simp }
   327   { assume "F \<le> F'" and "F' \<le> F''" thus "F \<le> F''"
   328     unfolding le_filter_def by simp }
   329   { assume "F \<le> F'" and "F' \<le> F" thus "F = F'"
   330     unfolding le_filter_def filter_eq_iff by fast }
   331   { show "inf F F' \<le> F" and "inf F F' \<le> F'"
   332     unfolding le_filter_def eventually_inf by (auto intro: eventually_True) }
   333   { assume "F \<le> F'" and "F \<le> F''" thus "F \<le> inf F' F''"
   334     unfolding le_filter_def eventually_inf
   335     by (auto intro: eventually_mono [OF eventually_conj]) }
   336   { show "F \<le> sup F F'" and "F' \<le> sup F F'"
   337     unfolding le_filter_def eventually_sup by simp_all }
   338   { assume "F \<le> F''" and "F' \<le> F''" thus "sup F F' \<le> F''"
   339     unfolding le_filter_def eventually_sup by simp }
   340   { assume "F'' \<in> S" thus "Inf S \<le> F''"
   341     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   342   { assume "\<And>F'. F' \<in> S \<Longrightarrow> F \<le> F'" thus "F \<le> Inf S"
   343     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   344   { assume "F \<in> S" thus "F \<le> Sup S"
   345     unfolding le_filter_def eventually_Sup by simp }
   346   { assume "\<And>F. F \<in> S \<Longrightarrow> F \<le> F'" thus "Sup S \<le> F'"
   347     unfolding le_filter_def eventually_Sup by simp }
   348   { show "Inf {} = (top::'a filter)"
   349     by (auto simp: top_filter_def Inf_filter_def Sup_filter_def)
   350       (metis (full_types) top_filter_def always_eventually eventually_top) }
   351   { show "Sup {} = (bot::'a filter)"
   352     by (auto simp: bot_filter_def Sup_filter_def) }
   353 qed
   354 
   355 end
   356 
   357 instance filter :: (type) distrib_lattice
   358 proof
   359   fix F G H :: "'a filter"
   360   show "sup F (inf G H) = inf (sup F G) (sup F H)"
   361   proof (rule order.antisym)
   362     show "inf (sup F G) (sup F H) \<le> sup F (inf G H)" 
   363       unfolding le_filter_def eventually_sup
   364     proof safe
   365       fix P assume 1: "eventually P F" and 2: "eventually P (inf G H)"
   366       from 2 obtain Q R 
   367         where QR: "eventually Q G" "eventually R H" "\<And>x. Q x \<Longrightarrow> R x \<Longrightarrow> P x"
   368         by (auto simp: eventually_inf)
   369       define Q' where "Q' = (\<lambda>x. Q x \<or> P x)"
   370       define R' where "R' = (\<lambda>x. R x \<or> P x)"
   371       from 1 have "eventually Q' F" 
   372         by (elim eventually_mono) (auto simp: Q'_def)
   373       moreover from 1 have "eventually R' F" 
   374         by (elim eventually_mono) (auto simp: R'_def)
   375       moreover from QR(1) have "eventually Q' G" 
   376         by (elim eventually_mono) (auto simp: Q'_def)
   377       moreover from QR(2) have "eventually R' H" 
   378         by (elim eventually_mono)(auto simp: R'_def)
   379       moreover from QR have "P x" if "Q' x" "R' x" for x 
   380         using that by (auto simp: Q'_def R'_def)
   381       ultimately show "eventually P (inf (sup F G) (sup F H))"
   382         by (auto simp: eventually_inf eventually_sup)
   383     qed
   384   qed (auto intro: inf.coboundedI1 inf.coboundedI2)
   385 qed
   386 
   387 
   388 lemma filter_leD:
   389   "F \<le> F' \<Longrightarrow> eventually P F' \<Longrightarrow> eventually P F"
   390   unfolding le_filter_def by simp
   391 
   392 lemma filter_leI:
   393   "(\<And>P. eventually P F' \<Longrightarrow> eventually P F) \<Longrightarrow> F \<le> F'"
   394   unfolding le_filter_def by simp
   395 
   396 lemma eventually_False:
   397   "eventually (\<lambda>x. False) F \<longleftrightarrow> F = bot"
   398   unfolding filter_eq_iff by (auto elim: eventually_rev_mp)
   399 
   400 lemma eventually_frequently: "F \<noteq> bot \<Longrightarrow> eventually P F \<Longrightarrow> frequently P F"
   401   using eventually_conj[of P F "\<lambda>x. \<not> P x"]
   402   by (auto simp add: frequently_def eventually_False)
   403 
   404 lemma eventually_const_iff: "eventually (\<lambda>x. P) F \<longleftrightarrow> P \<or> F = bot"
   405   by (cases P) (auto simp: eventually_False)
   406 
   407 lemma eventually_const[simp]: "F \<noteq> bot \<Longrightarrow> eventually (\<lambda>x. P) F \<longleftrightarrow> P"
   408   by (simp add: eventually_const_iff)
   409 
   410 lemma frequently_const_iff: "frequently (\<lambda>x. P) F \<longleftrightarrow> P \<and> F \<noteq> bot"
   411   by (simp add: frequently_def eventually_const_iff)
   412 
   413 lemma frequently_const[simp]: "F \<noteq> bot \<Longrightarrow> frequently (\<lambda>x. P) F \<longleftrightarrow> P"
   414   by (simp add: frequently_const_iff)
   415 
   416 lemma eventually_happens: "eventually P net \<Longrightarrow> net = bot \<or> (\<exists>x. P x)"
   417   by (metis frequentlyE eventually_frequently)
   418 
   419 lemma eventually_happens':
   420   assumes "F \<noteq> bot" "eventually P F"
   421   shows   "\<exists>x. P x"
   422   using assms eventually_frequently frequentlyE by blast
   423 
   424 abbreviation (input) trivial_limit :: "'a filter \<Rightarrow> bool"
   425   where "trivial_limit F \<equiv> F = bot"
   426 
   427 lemma trivial_limit_def: "trivial_limit F \<longleftrightarrow> eventually (\<lambda>x. False) F"
   428   by (rule eventually_False [symmetric])
   429 
   430 lemma False_imp_not_eventually: "(\<forall>x. \<not> P x ) \<Longrightarrow> \<not> trivial_limit net \<Longrightarrow> \<not> eventually (\<lambda>x. P x) net"
   431   by (simp add: eventually_False)
   432 
   433 lemma eventually_Inf: "eventually P (Inf B) \<longleftrightarrow> (\<exists>X\<subseteq>B. finite X \<and> eventually P (Inf X))"
   434 proof -
   435   let ?F = "\<lambda>P. \<exists>X\<subseteq>B. finite X \<and> eventually P (Inf X)"
   436 
   437   { fix P have "eventually P (Abs_filter ?F) \<longleftrightarrow> ?F P"
   438     proof (rule eventually_Abs_filter is_filter.intro)+
   439       show "?F (\<lambda>x. True)"
   440         by (rule exI[of _ "{}"]) (simp add: le_fun_def)
   441     next
   442       fix P Q
   443       assume "?F P" then guess X ..
   444       moreover
   445       assume "?F Q" then guess Y ..
   446       ultimately show "?F (\<lambda>x. P x \<and> Q x)"
   447         by (intro exI[of _ "X \<union> Y"])
   448            (auto simp: Inf_union_distrib eventually_inf)
   449     next
   450       fix P Q
   451       assume "?F P" then guess X ..
   452       moreover assume "\<forall>x. P x \<longrightarrow> Q x"
   453       ultimately show "?F Q"
   454         by (intro exI[of _ X]) (auto elim: eventually_mono)
   455     qed }
   456   note eventually_F = this
   457 
   458   have "Inf B = Abs_filter ?F"
   459   proof (intro antisym Inf_greatest)
   460     show "Inf B \<le> Abs_filter ?F"
   461       by (auto simp: le_filter_def eventually_F dest: Inf_superset_mono)
   462   next
   463     fix F assume "F \<in> B" then show "Abs_filter ?F \<le> F"
   464       by (auto simp add: le_filter_def eventually_F intro!: exI[of _ "{F}"])
   465   qed
   466   then show ?thesis
   467     by (simp add: eventually_F)
   468 qed
   469 
   470 lemma eventually_INF: "eventually P (INF b:B. F b) \<longleftrightarrow> (\<exists>X\<subseteq>B. finite X \<and> eventually P (INF b:X. F b))"
   471   unfolding eventually_Inf [of P "F`B"]
   472   by (metis finite_imageI image_mono finite_subset_image)
   473 
   474 lemma Inf_filter_not_bot:
   475   fixes B :: "'a filter set"
   476   shows "(\<And>X. X \<subseteq> B \<Longrightarrow> finite X \<Longrightarrow> Inf X \<noteq> bot) \<Longrightarrow> Inf B \<noteq> bot"
   477   unfolding trivial_limit_def eventually_Inf[of _ B]
   478     bot_bool_def [symmetric] bot_fun_def [symmetric] bot_unique by simp
   479 
   480 lemma INF_filter_not_bot:
   481   fixes F :: "'i \<Rightarrow> 'a filter"
   482   shows "(\<And>X. X \<subseteq> B \<Longrightarrow> finite X \<Longrightarrow> (INF b:X. F b) \<noteq> bot) \<Longrightarrow> (INF b:B. F b) \<noteq> bot"
   483   unfolding trivial_limit_def eventually_INF [of _ _ B]
   484     bot_bool_def [symmetric] bot_fun_def [symmetric] bot_unique by simp
   485 
   486 lemma eventually_Inf_base:
   487   assumes "B \<noteq> {}" and base: "\<And>F G. F \<in> B \<Longrightarrow> G \<in> B \<Longrightarrow> \<exists>x\<in>B. x \<le> inf F G"
   488   shows "eventually P (Inf B) \<longleftrightarrow> (\<exists>b\<in>B. eventually P b)"
   489 proof (subst eventually_Inf, safe)
   490   fix X assume "finite X" "X \<subseteq> B"
   491   then have "\<exists>b\<in>B. \<forall>x\<in>X. b \<le> x"
   492   proof induct
   493     case empty then show ?case
   494       using \<open>B \<noteq> {}\<close> by auto
   495   next
   496     case (insert x X)
   497     then obtain b where "b \<in> B" "\<And>x. x \<in> X \<Longrightarrow> b \<le> x"
   498       by auto
   499     with \<open>insert x X \<subseteq> B\<close> base[of b x] show ?case
   500       by (auto intro: order_trans)
   501   qed
   502   then obtain b where "b \<in> B" "b \<le> Inf X"
   503     by (auto simp: le_Inf_iff)
   504   then show "eventually P (Inf X) \<Longrightarrow> Bex B (eventually P)"
   505     by (intro bexI[of _ b]) (auto simp: le_filter_def)
   506 qed (auto intro!: exI[of _ "{x}" for x])
   507 
   508 lemma eventually_INF_base:
   509   "B \<noteq> {} \<Longrightarrow> (\<And>a b. a \<in> B \<Longrightarrow> b \<in> B \<Longrightarrow> \<exists>x\<in>B. F x \<le> inf (F a) (F b)) \<Longrightarrow>
   510     eventually P (INF b:B. F b) \<longleftrightarrow> (\<exists>b\<in>B. eventually P (F b))"
   511   by (subst eventually_Inf_base) auto
   512 
   513 lemma eventually_INF1: "i \<in> I \<Longrightarrow> eventually P (F i) \<Longrightarrow> eventually P (INF i:I. F i)"
   514   using filter_leD[OF INF_lower] .
   515 
   516 lemma eventually_INF_mono:
   517   assumes *: "\<forall>\<^sub>F x in \<Sqinter>i\<in>I. F i. P x"
   518   assumes T1: "\<And>Q R P. (\<And>x. Q x \<and> R x \<longrightarrow> P x) \<Longrightarrow> (\<And>x. T Q x \<Longrightarrow> T R x \<Longrightarrow> T P x)"
   519   assumes T2: "\<And>P. (\<And>x. P x) \<Longrightarrow> (\<And>x. T P x)"
   520   assumes **: "\<And>i P. i \<in> I \<Longrightarrow> \<forall>\<^sub>F x in F i. P x \<Longrightarrow> \<forall>\<^sub>F x in F' i. T P x"
   521   shows "\<forall>\<^sub>F x in \<Sqinter>i\<in>I. F' i. T P x"
   522 proof -
   523   from * obtain X where X: "finite X" "X \<subseteq> I" "\<forall>\<^sub>F x in \<Sqinter>i\<in>X. F i. P x"
   524     unfolding eventually_INF[of _ _ I] by auto
   525   then have "eventually (T P) (INFIMUM X F')"
   526     apply (induction X arbitrary: P)
   527     apply (auto simp: eventually_inf T2)
   528     subgoal for x S P Q R
   529       apply (intro exI[of _ "T Q"])
   530       apply (auto intro!: **) []
   531       apply (intro exI[of _ "T R"])
   532       apply (auto intro: T1) []
   533       done
   534     done
   535   with X show "\<forall>\<^sub>F x in \<Sqinter>i\<in>I. F' i. T P x"
   536     by (subst eventually_INF) auto
   537 qed
   538 
   539 
   540 subsubsection \<open>Map function for filters\<close>
   541 
   542 definition filtermap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow> 'b filter"
   543   where "filtermap f F = Abs_filter (\<lambda>P. eventually (\<lambda>x. P (f x)) F)"
   544 
   545 lemma eventually_filtermap:
   546   "eventually P (filtermap f F) = eventually (\<lambda>x. P (f x)) F"
   547   unfolding filtermap_def
   548   apply (rule eventually_Abs_filter)
   549   apply (rule is_filter.intro)
   550   apply (auto elim!: eventually_rev_mp)
   551   done
   552 
   553 lemma filtermap_ident: "filtermap (\<lambda>x. x) F = F"
   554   by (simp add: filter_eq_iff eventually_filtermap)
   555 
   556 lemma filtermap_filtermap:
   557   "filtermap f (filtermap g F) = filtermap (\<lambda>x. f (g x)) F"
   558   by (simp add: filter_eq_iff eventually_filtermap)
   559 
   560 lemma filtermap_mono: "F \<le> F' \<Longrightarrow> filtermap f F \<le> filtermap f F'"
   561   unfolding le_filter_def eventually_filtermap by simp
   562 
   563 lemma filtermap_bot [simp]: "filtermap f bot = bot"
   564   by (simp add: filter_eq_iff eventually_filtermap)
   565 
   566 lemma filtermap_sup: "filtermap f (sup F1 F2) = sup (filtermap f F1) (filtermap f F2)"
   567   by (auto simp: filter_eq_iff eventually_filtermap eventually_sup)
   568 
   569 lemma filtermap_inf: "filtermap f (inf F1 F2) \<le> inf (filtermap f F1) (filtermap f F2)"
   570   by (auto simp: le_filter_def eventually_filtermap eventually_inf)
   571 
   572 lemma filtermap_INF: "filtermap f (INF b:B. F b) \<le> (INF b:B. filtermap f (F b))"
   573 proof -
   574   { fix X :: "'c set" assume "finite X"
   575     then have "filtermap f (INFIMUM X F) \<le> (INF b:X. filtermap f (F b))"
   576     proof induct
   577       case (insert x X)
   578       have "filtermap f (INF a:insert x X. F a) \<le> inf (filtermap f (F x)) (filtermap f (INF a:X. F a))"
   579         by (rule order_trans[OF _ filtermap_inf]) simp
   580       also have "\<dots> \<le> inf (filtermap f (F x)) (INF a:X. filtermap f (F a))"
   581         by (intro inf_mono insert order_refl)
   582       finally show ?case
   583         by simp
   584     qed simp }
   585   then show ?thesis
   586     unfolding le_filter_def eventually_filtermap
   587     by (subst (1 2) eventually_INF) auto
   588 qed
   589 
   590 
   591 subsubsection \<open>Contravariant map function for filters\<close>
   592 
   593 definition filtercomap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'b filter \<Rightarrow> 'a filter" where
   594   "filtercomap f F = Abs_filter (\<lambda>P. \<exists>Q. eventually Q F \<and> (\<forall>x. Q (f x) \<longrightarrow> P x))"
   595 
   596 lemma eventually_filtercomap:
   597   "eventually P (filtercomap f F) \<longleftrightarrow> (\<exists>Q. eventually Q F \<and> (\<forall>x. Q (f x) \<longrightarrow> P x))"
   598   unfolding filtercomap_def
   599 proof (intro eventually_Abs_filter, unfold_locales, goal_cases)
   600   case 1
   601   show ?case by (auto intro!: exI[of _ "\<lambda>_. True"])
   602 next
   603   case (2 P Q)
   604   from 2(1) guess P' by (elim exE conjE) note P' = this
   605   from 2(2) guess Q' by (elim exE conjE) note Q' = this
   606   show ?case
   607     by (rule exI[of _ "\<lambda>x. P' x \<and> Q' x"])
   608        (insert P' Q', auto intro!: eventually_conj)
   609 next
   610   case (3 P Q)
   611   thus ?case by blast
   612 qed
   613 
   614 lemma filtercomap_ident: "filtercomap (\<lambda>x. x) F = F"
   615   by (auto simp: filter_eq_iff eventually_filtercomap elim!: eventually_mono)
   616 
   617 lemma filtercomap_filtercomap: "filtercomap f (filtercomap g F) = filtercomap (\<lambda>x. g (f x)) F"
   618   unfolding filter_eq_iff by (auto simp: eventually_filtercomap)
   619   
   620 lemma filtercomap_mono: "F \<le> F' \<Longrightarrow> filtercomap f F \<le> filtercomap f F'"
   621   by (auto simp: eventually_filtercomap le_filter_def)
   622 
   623 lemma filtercomap_bot [simp]: "filtercomap f bot = bot"
   624   by (auto simp: filter_eq_iff eventually_filtercomap)
   625 
   626 lemma filtercomap_top [simp]: "filtercomap f top = top"
   627   by (auto simp: filter_eq_iff eventually_filtercomap)
   628 
   629 lemma filtercomap_inf: "filtercomap f (inf F1 F2) = inf (filtercomap f F1) (filtercomap f F2)"
   630   unfolding filter_eq_iff
   631 proof safe
   632   fix P
   633   assume "eventually P (filtercomap f (F1 \<sqinter> F2))"
   634   then obtain Q R S where *:
   635     "eventually Q F1" "eventually R F2" "\<And>x. Q x \<Longrightarrow> R x \<Longrightarrow> S x" "\<And>x. S (f x) \<Longrightarrow> P x"
   636     unfolding eventually_filtercomap eventually_inf by blast
   637   from * have "eventually (\<lambda>x. Q (f x)) (filtercomap f F1)" 
   638               "eventually (\<lambda>x. R (f x)) (filtercomap f F2)"
   639     by (auto simp: eventually_filtercomap)
   640   with * show "eventually P (filtercomap f F1 \<sqinter> filtercomap f F2)"
   641     unfolding eventually_inf by blast
   642 next
   643   fix P
   644   assume "eventually P (inf (filtercomap f F1) (filtercomap f F2))"
   645   then obtain Q Q' R R' where *:
   646     "eventually Q F1" "eventually R F2" "\<And>x. Q (f x) \<Longrightarrow> Q' x" "\<And>x. R (f x) \<Longrightarrow> R' x" 
   647     "\<And>x. Q' x \<Longrightarrow> R' x \<Longrightarrow> P x"
   648     unfolding eventually_filtercomap eventually_inf by blast
   649   from * have "eventually (\<lambda>x. Q x \<and> R x) (F1 \<sqinter> F2)" by (auto simp: eventually_inf)
   650   with * show "eventually P (filtercomap f (F1 \<sqinter> F2))"
   651     by (auto simp: eventually_filtercomap)
   652 qed
   653 
   654 lemma filtercomap_sup: "filtercomap f (sup F1 F2) \<ge> sup (filtercomap f F1) (filtercomap f F2)"
   655   unfolding le_filter_def
   656 proof safe
   657   fix P
   658   assume "eventually P (filtercomap f (sup F1 F2))"
   659   thus "eventually P (sup (filtercomap f F1) (filtercomap f F2))"
   660     by (auto simp: filter_eq_iff eventually_filtercomap eventually_sup)
   661 qed
   662 
   663 lemma filtercomap_INF: "filtercomap f (INF b:B. F b) = (INF b:B. filtercomap f (F b))"
   664 proof -
   665   have *: "filtercomap f (INF b:B. F b) = (INF b:B. filtercomap f (F b))" if "finite B" for B
   666     using that by induction (simp_all add: filtercomap_inf)
   667   show ?thesis unfolding filter_eq_iff
   668   proof
   669     fix P
   670     have "eventually P (INF b:B. filtercomap f (F b)) \<longleftrightarrow> 
   671             (\<exists>X. (X \<subseteq> B \<and> finite X) \<and> eventually P (\<Sqinter>b\<in>X. filtercomap f (F b)))"
   672       by (subst eventually_INF) blast
   673     also have "\<dots> \<longleftrightarrow> (\<exists>X. (X \<subseteq> B \<and> finite X) \<and> eventually P (filtercomap f (INF b:X. F b)))"
   674       by (rule ex_cong) (simp add: *)
   675     also have "\<dots> \<longleftrightarrow> eventually P (filtercomap f (INFIMUM B F))"
   676       unfolding eventually_filtercomap by (subst eventually_INF) blast
   677     finally show "eventually P (filtercomap f (INFIMUM B F)) = 
   678                     eventually P (\<Sqinter>b\<in>B. filtercomap f (F b))" ..
   679   qed
   680 qed
   681 
   682 lemma filtercomap_SUP_finite: 
   683   "finite B \<Longrightarrow> filtercomap f (SUP b:B. F b) \<ge> (SUP b:B. filtercomap f (F b))"
   684   by (induction B rule: finite_induct)
   685      (auto intro: order_trans[OF _ order_trans[OF _ filtercomap_sup]] filtercomap_mono)
   686      
   687 lemma eventually_filtercomapI [intro]:
   688   assumes "eventually P F"
   689   shows   "eventually (\<lambda>x. P (f x)) (filtercomap f F)"
   690   using assms by (auto simp: eventually_filtercomap)
   691 
   692 lemma filtermap_filtercomap: "filtermap f (filtercomap f F) \<le> F"
   693   by (auto simp: le_filter_def eventually_filtermap eventually_filtercomap)
   694     
   695 lemma filtercomap_filtermap: "filtercomap f (filtermap f F) \<ge> F"
   696   unfolding le_filter_def eventually_filtermap eventually_filtercomap
   697   by (auto elim!: eventually_mono)
   698 
   699 
   700 subsubsection \<open>Standard filters\<close>
   701 
   702 definition principal :: "'a set \<Rightarrow> 'a filter" where
   703   "principal S = Abs_filter (\<lambda>P. \<forall>x\<in>S. P x)"
   704 
   705 lemma eventually_principal: "eventually P (principal S) \<longleftrightarrow> (\<forall>x\<in>S. P x)"
   706   unfolding principal_def
   707   by (rule eventually_Abs_filter, rule is_filter.intro) auto
   708 
   709 lemma eventually_inf_principal: "eventually P (inf F (principal s)) \<longleftrightarrow> eventually (\<lambda>x. x \<in> s \<longrightarrow> P x) F"
   710   unfolding eventually_inf eventually_principal by (auto elim: eventually_mono)
   711 
   712 lemma principal_UNIV[simp]: "principal UNIV = top"
   713   by (auto simp: filter_eq_iff eventually_principal)
   714 
   715 lemma principal_empty[simp]: "principal {} = bot"
   716   by (auto simp: filter_eq_iff eventually_principal)
   717 
   718 lemma principal_eq_bot_iff: "principal X = bot \<longleftrightarrow> X = {}"
   719   by (auto simp add: filter_eq_iff eventually_principal)
   720 
   721 lemma principal_le_iff[iff]: "principal A \<le> principal B \<longleftrightarrow> A \<subseteq> B"
   722   by (auto simp: le_filter_def eventually_principal)
   723 
   724 lemma le_principal: "F \<le> principal A \<longleftrightarrow> eventually (\<lambda>x. x \<in> A) F"
   725   unfolding le_filter_def eventually_principal
   726   apply safe
   727   apply (erule_tac x="\<lambda>x. x \<in> A" in allE)
   728   apply (auto elim: eventually_mono)
   729   done
   730 
   731 lemma principal_inject[iff]: "principal A = principal B \<longleftrightarrow> A = B"
   732   unfolding eq_iff by simp
   733 
   734 lemma sup_principal[simp]: "sup (principal A) (principal B) = principal (A \<union> B)"
   735   unfolding filter_eq_iff eventually_sup eventually_principal by auto
   736 
   737 lemma inf_principal[simp]: "inf (principal A) (principal B) = principal (A \<inter> B)"
   738   unfolding filter_eq_iff eventually_inf eventually_principal
   739   by (auto intro: exI[of _ "\<lambda>x. x \<in> A"] exI[of _ "\<lambda>x. x \<in> B"])
   740 
   741 lemma SUP_principal[simp]: "(SUP i : I. principal (A i)) = principal (\<Union>i\<in>I. A i)"
   742   unfolding filter_eq_iff eventually_Sup by (auto simp: eventually_principal)
   743 
   744 lemma INF_principal_finite: "finite X \<Longrightarrow> (INF x:X. principal (f x)) = principal (\<Inter>x\<in>X. f x)"
   745   by (induct X rule: finite_induct) auto
   746 
   747 lemma filtermap_principal[simp]: "filtermap f (principal A) = principal (f ` A)"
   748   unfolding filter_eq_iff eventually_filtermap eventually_principal by simp
   749     
   750 lemma filtercomap_principal[simp]: "filtercomap f (principal A) = principal (f -` A)"
   751   unfolding filter_eq_iff eventually_filtercomap eventually_principal by fast
   752 
   753 subsubsection \<open>Order filters\<close>
   754 
   755 definition at_top :: "('a::order) filter"
   756   where "at_top = (INF k. principal {k ..})"
   757 
   758 lemma at_top_sub: "at_top = (INF k:{c::'a::linorder..}. principal {k ..})"
   759   by (auto intro!: INF_eq max.cobounded1 max.cobounded2 simp: at_top_def)
   760 
   761 lemma eventually_at_top_linorder: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::linorder. \<forall>n\<ge>N. P n)"
   762   unfolding at_top_def
   763   by (subst eventually_INF_base) (auto simp: eventually_principal intro: max.cobounded1 max.cobounded2)
   764 
   765 lemma eventually_filtercomap_at_top_linorder: 
   766   "eventually P (filtercomap f at_top) \<longleftrightarrow> (\<exists>N::'a::linorder. \<forall>x. f x \<ge> N \<longrightarrow> P x)"
   767   by (auto simp: eventually_filtercomap eventually_at_top_linorder)
   768 
   769 lemma eventually_at_top_linorderI:
   770   fixes c::"'a::linorder"
   771   assumes "\<And>x. c \<le> x \<Longrightarrow> P x"
   772   shows "eventually P at_top"
   773   using assms by (auto simp: eventually_at_top_linorder)
   774 
   775 lemma eventually_ge_at_top [simp]:
   776   "eventually (\<lambda>x. (c::_::linorder) \<le> x) at_top"
   777   unfolding eventually_at_top_linorder by auto
   778 
   779 lemma eventually_at_top_dense: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::{no_top, linorder}. \<forall>n>N. P n)"
   780 proof -
   781   have "eventually P (INF k. principal {k <..}) \<longleftrightarrow> (\<exists>N::'a. \<forall>n>N. P n)"
   782     by (subst eventually_INF_base) (auto simp: eventually_principal intro: max.cobounded1 max.cobounded2)
   783   also have "(INF k. principal {k::'a <..}) = at_top"
   784     unfolding at_top_def
   785     by (intro INF_eq) (auto intro: less_imp_le simp: Ici_subset_Ioi_iff gt_ex)
   786   finally show ?thesis .
   787 qed
   788   
   789 lemma eventually_filtercomap_at_top_dense: 
   790   "eventually P (filtercomap f at_top) \<longleftrightarrow> (\<exists>N::'a::{no_top, linorder}. \<forall>x. f x > N \<longrightarrow> P x)"
   791   by (auto simp: eventually_filtercomap eventually_at_top_dense)
   792 
   793 lemma eventually_at_top_not_equal [simp]: "eventually (\<lambda>x::'a::{no_top, linorder}. x \<noteq> c) at_top"
   794   unfolding eventually_at_top_dense by auto
   795 
   796 lemma eventually_gt_at_top [simp]: "eventually (\<lambda>x. (c::_::{no_top, linorder}) < x) at_top"
   797   unfolding eventually_at_top_dense by auto
   798 
   799 lemma eventually_all_ge_at_top:
   800   assumes "eventually P (at_top :: ('a :: linorder) filter)"
   801   shows   "eventually (\<lambda>x. \<forall>y\<ge>x. P y) at_top"
   802 proof -
   803   from assms obtain x where "\<And>y. y \<ge> x \<Longrightarrow> P y" by (auto simp: eventually_at_top_linorder)
   804   hence "\<forall>z\<ge>y. P z" if "y \<ge> x" for y using that by simp
   805   thus ?thesis by (auto simp: eventually_at_top_linorder)
   806 qed
   807 
   808 definition at_bot :: "('a::order) filter"
   809   where "at_bot = (INF k. principal {.. k})"
   810 
   811 lemma at_bot_sub: "at_bot = (INF k:{.. c::'a::linorder}. principal {.. k})"
   812   by (auto intro!: INF_eq min.cobounded1 min.cobounded2 simp: at_bot_def)
   813 
   814 lemma eventually_at_bot_linorder:
   815   fixes P :: "'a::linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n\<le>N. P n)"
   816   unfolding at_bot_def
   817   by (subst eventually_INF_base) (auto simp: eventually_principal intro: min.cobounded1 min.cobounded2)
   818 
   819 lemma eventually_filtercomap_at_bot_linorder: 
   820   "eventually P (filtercomap f at_bot) \<longleftrightarrow> (\<exists>N::'a::linorder. \<forall>x. f x \<le> N \<longrightarrow> P x)"
   821   by (auto simp: eventually_filtercomap eventually_at_bot_linorder)
   822 
   823 lemma eventually_le_at_bot [simp]:
   824   "eventually (\<lambda>x. x \<le> (c::_::linorder)) at_bot"
   825   unfolding eventually_at_bot_linorder by auto
   826 
   827 lemma eventually_at_bot_dense: "eventually P at_bot \<longleftrightarrow> (\<exists>N::'a::{no_bot, linorder}. \<forall>n<N. P n)"
   828 proof -
   829   have "eventually P (INF k. principal {..< k}) \<longleftrightarrow> (\<exists>N::'a. \<forall>n<N. P n)"
   830     by (subst eventually_INF_base) (auto simp: eventually_principal intro: min.cobounded1 min.cobounded2)
   831   also have "(INF k. principal {..< k::'a}) = at_bot"
   832     unfolding at_bot_def
   833     by (intro INF_eq) (auto intro: less_imp_le simp: Iic_subset_Iio_iff lt_ex)
   834   finally show ?thesis .
   835 qed
   836 
   837 lemma eventually_filtercomap_at_bot_dense: 
   838   "eventually P (filtercomap f at_bot) \<longleftrightarrow> (\<exists>N::'a::{no_bot, linorder}. \<forall>x. f x < N \<longrightarrow> P x)"
   839   by (auto simp: eventually_filtercomap eventually_at_bot_dense)
   840 
   841 lemma eventually_at_bot_not_equal [simp]: "eventually (\<lambda>x::'a::{no_bot, linorder}. x \<noteq> c) at_bot"
   842   unfolding eventually_at_bot_dense by auto
   843 
   844 lemma eventually_gt_at_bot [simp]:
   845   "eventually (\<lambda>x. x < (c::_::unbounded_dense_linorder)) at_bot"
   846   unfolding eventually_at_bot_dense by auto
   847 
   848 lemma trivial_limit_at_bot_linorder [simp]: "\<not> trivial_limit (at_bot ::('a::linorder) filter)"
   849   unfolding trivial_limit_def
   850   by (metis eventually_at_bot_linorder order_refl)
   851 
   852 lemma trivial_limit_at_top_linorder [simp]: "\<not> trivial_limit (at_top ::('a::linorder) filter)"
   853   unfolding trivial_limit_def
   854   by (metis eventually_at_top_linorder order_refl)
   855 
   856 subsection \<open>Sequentially\<close>
   857 
   858 abbreviation sequentially :: "nat filter"
   859   where "sequentially \<equiv> at_top"
   860 
   861 lemma eventually_sequentially:
   862   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   863   by (rule eventually_at_top_linorder)
   864 
   865 lemma sequentially_bot [simp, intro]: "sequentially \<noteq> bot"
   866   unfolding filter_eq_iff eventually_sequentially by auto
   867 
   868 lemmas trivial_limit_sequentially = sequentially_bot
   869 
   870 lemma eventually_False_sequentially [simp]:
   871   "\<not> eventually (\<lambda>n. False) sequentially"
   872   by (simp add: eventually_False)
   873 
   874 lemma le_sequentially:
   875   "F \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) F)"
   876   by (simp add: at_top_def le_INF_iff le_principal)
   877 
   878 lemma eventually_sequentiallyI [intro?]:
   879   assumes "\<And>x. c \<le> x \<Longrightarrow> P x"
   880   shows "eventually P sequentially"
   881 using assms by (auto simp: eventually_sequentially)
   882 
   883 lemma eventually_sequentially_Suc [simp]: "eventually (\<lambda>i. P (Suc i)) sequentially \<longleftrightarrow> eventually P sequentially"
   884   unfolding eventually_sequentially by (metis Suc_le_D Suc_le_mono le_Suc_eq)
   885 
   886 lemma eventually_sequentially_seg [simp]: "eventually (\<lambda>n. P (n + k)) sequentially \<longleftrightarrow> eventually P sequentially"
   887   using eventually_sequentially_Suc[of "\<lambda>n. P (n + k)" for k] by (induction k) auto
   888 
   889 
   890 subsection \<open>The cofinite filter\<close>
   891 
   892 definition "cofinite = Abs_filter (\<lambda>P. finite {x. \<not> P x})"
   893 
   894 abbreviation Inf_many :: "('a \<Rightarrow> bool) \<Rightarrow> bool"  (binder "\<exists>\<^sub>\<infinity>" 10)
   895   where "Inf_many P \<equiv> frequently P cofinite"
   896 
   897 abbreviation Alm_all :: "('a \<Rightarrow> bool) \<Rightarrow> bool"  (binder "\<forall>\<^sub>\<infinity>" 10)
   898   where "Alm_all P \<equiv> eventually P cofinite"
   899 
   900 notation (ASCII)
   901   Inf_many  (binder "INFM " 10) and
   902   Alm_all  (binder "MOST " 10)
   903 
   904 lemma eventually_cofinite: "eventually P cofinite \<longleftrightarrow> finite {x. \<not> P x}"
   905   unfolding cofinite_def
   906 proof (rule eventually_Abs_filter, rule is_filter.intro)
   907   fix P Q :: "'a \<Rightarrow> bool" assume "finite {x. \<not> P x}" "finite {x. \<not> Q x}"
   908   from finite_UnI[OF this] show "finite {x. \<not> (P x \<and> Q x)}"
   909     by (rule rev_finite_subset) auto
   910 next
   911   fix P Q :: "'a \<Rightarrow> bool" assume P: "finite {x. \<not> P x}" and *: "\<forall>x. P x \<longrightarrow> Q x"
   912   from * show "finite {x. \<not> Q x}"
   913     by (intro finite_subset[OF _ P]) auto
   914 qed simp
   915 
   916 lemma frequently_cofinite: "frequently P cofinite \<longleftrightarrow> \<not> finite {x. P x}"
   917   by (simp add: frequently_def eventually_cofinite)
   918 
   919 lemma cofinite_bot[simp]: "cofinite = (bot::'a filter) \<longleftrightarrow> finite (UNIV :: 'a set)"
   920   unfolding trivial_limit_def eventually_cofinite by simp
   921 
   922 lemma cofinite_eq_sequentially: "cofinite = sequentially"
   923   unfolding filter_eq_iff eventually_sequentially eventually_cofinite
   924 proof safe
   925   fix P :: "nat \<Rightarrow> bool" assume [simp]: "finite {x. \<not> P x}"
   926   show "\<exists>N. \<forall>n\<ge>N. P n"
   927   proof cases
   928     assume "{x. \<not> P x} \<noteq> {}" then show ?thesis
   929       by (intro exI[of _ "Suc (Max {x. \<not> P x})"]) (auto simp: Suc_le_eq)
   930   qed auto
   931 next
   932   fix P :: "nat \<Rightarrow> bool" and N :: nat assume "\<forall>n\<ge>N. P n"
   933   then have "{x. \<not> P x} \<subseteq> {..< N}"
   934     by (auto simp: not_le)
   935   then show "finite {x. \<not> P x}"
   936     by (blast intro: finite_subset)
   937 qed
   938 
   939 subsubsection \<open>Product of filters\<close>
   940 
   941 lemma filtermap_sequentually_ne_bot: "filtermap f sequentially \<noteq> bot"
   942   by (auto simp add: filter_eq_iff eventually_filtermap eventually_sequentially)
   943 
   944 definition prod_filter :: "'a filter \<Rightarrow> 'b filter \<Rightarrow> ('a \<times> 'b) filter" (infixr "\<times>\<^sub>F" 80) where
   945   "prod_filter F G =
   946     (INF (P, Q):{(P, Q). eventually P F \<and> eventually Q G}. principal {(x, y). P x \<and> Q y})"
   947 
   948 lemma eventually_prod_filter: "eventually P (F \<times>\<^sub>F G) \<longleftrightarrow>
   949   (\<exists>Pf Pg. eventually Pf F \<and> eventually Pg G \<and> (\<forall>x y. Pf x \<longrightarrow> Pg y \<longrightarrow> P (x, y)))"
   950   unfolding prod_filter_def
   951 proof (subst eventually_INF_base, goal_cases)
   952   case 2
   953   moreover have "eventually Pf F \<Longrightarrow> eventually Qf F \<Longrightarrow> eventually Pg G \<Longrightarrow> eventually Qg G \<Longrightarrow>
   954     \<exists>P Q. eventually P F \<and> eventually Q G \<and>
   955       Collect P \<times> Collect Q \<subseteq> Collect Pf \<times> Collect Pg \<inter> Collect Qf \<times> Collect Qg" for Pf Pg Qf Qg
   956     by (intro conjI exI[of _ "inf Pf Qf"] exI[of _ "inf Pg Qg"])
   957        (auto simp: inf_fun_def eventually_conj)
   958   ultimately show ?case
   959     by auto
   960 qed (auto simp: eventually_principal intro: eventually_True)
   961 
   962 lemma eventually_prod1:
   963   assumes "B \<noteq> bot"
   964   shows "(\<forall>\<^sub>F (x, y) in A \<times>\<^sub>F B. P x) \<longleftrightarrow> (\<forall>\<^sub>F x in A. P x)"
   965   unfolding eventually_prod_filter
   966 proof safe
   967   fix R Q
   968   assume *: "\<forall>\<^sub>F x in A. R x" "\<forall>\<^sub>F x in B. Q x" "\<forall>x y. R x \<longrightarrow> Q y \<longrightarrow> P x"
   969   with \<open>B \<noteq> bot\<close> obtain y where "Q y" by (auto dest: eventually_happens)
   970   with * show "eventually P A"
   971     by (force elim: eventually_mono)
   972 next
   973   assume "eventually P A"
   974   then show "\<exists>Pf Pg. eventually Pf A \<and> eventually Pg B \<and> (\<forall>x y. Pf x \<longrightarrow> Pg y \<longrightarrow> P x)"
   975     by (intro exI[of _ P] exI[of _ "\<lambda>x. True"]) auto
   976 qed
   977 
   978 lemma eventually_prod2:
   979   assumes "A \<noteq> bot"
   980   shows "(\<forall>\<^sub>F (x, y) in A \<times>\<^sub>F B. P y) \<longleftrightarrow> (\<forall>\<^sub>F y in B. P y)"
   981   unfolding eventually_prod_filter
   982 proof safe
   983   fix R Q
   984   assume *: "\<forall>\<^sub>F x in A. R x" "\<forall>\<^sub>F x in B. Q x" "\<forall>x y. R x \<longrightarrow> Q y \<longrightarrow> P y"
   985   with \<open>A \<noteq> bot\<close> obtain x where "R x" by (auto dest: eventually_happens)
   986   with * show "eventually P B"
   987     by (force elim: eventually_mono)
   988 next
   989   assume "eventually P B"
   990   then show "\<exists>Pf Pg. eventually Pf A \<and> eventually Pg B \<and> (\<forall>x y. Pf x \<longrightarrow> Pg y \<longrightarrow> P y)"
   991     by (intro exI[of _ P] exI[of _ "\<lambda>x. True"]) auto
   992 qed
   993 
   994 lemma INF_filter_bot_base:
   995   fixes F :: "'a \<Rightarrow> 'b filter"
   996   assumes *: "\<And>i j. i \<in> I \<Longrightarrow> j \<in> I \<Longrightarrow> \<exists>k\<in>I. F k \<le> F i \<sqinter> F j"
   997   shows "(INF i:I. F i) = bot \<longleftrightarrow> (\<exists>i\<in>I. F i = bot)"
   998 proof (cases "\<exists>i\<in>I. F i = bot")
   999   case True
  1000   then have "(INF i:I. F i) \<le> bot"
  1001     by (auto intro: INF_lower2)
  1002   with True show ?thesis
  1003     by (auto simp: bot_unique)
  1004 next
  1005   case False
  1006   moreover have "(INF i:I. F i) \<noteq> bot"
  1007   proof (cases "I = {}")
  1008     case True
  1009     then show ?thesis
  1010       by (auto simp add: filter_eq_iff)
  1011   next
  1012     case False': False
  1013     show ?thesis
  1014     proof (rule INF_filter_not_bot)
  1015       fix J
  1016       assume "finite J" "J \<subseteq> I"
  1017       then have "\<exists>k\<in>I. F k \<le> (\<Sqinter>i\<in>J. F i)"
  1018       proof (induct J)
  1019         case empty
  1020         then show ?case
  1021           using \<open>I \<noteq> {}\<close> by auto
  1022       next
  1023         case (insert i J)
  1024         then obtain k where "k \<in> I" "F k \<le> (\<Sqinter>i\<in>J. F i)" by auto
  1025         with insert *[of i k] show ?case
  1026           by auto
  1027       qed
  1028       with False show "(\<Sqinter>i\<in>J. F i) \<noteq> \<bottom>"
  1029         by (auto simp: bot_unique)
  1030     qed
  1031   qed
  1032   ultimately show ?thesis
  1033     by auto
  1034 qed
  1035 
  1036 lemma Collect_empty_eq_bot: "Collect P = {} \<longleftrightarrow> P = \<bottom>"
  1037   by auto
  1038 
  1039 lemma prod_filter_eq_bot: "A \<times>\<^sub>F B = bot \<longleftrightarrow> A = bot \<or> B = bot"
  1040   unfolding prod_filter_def
  1041 proof (subst INF_filter_bot_base; clarsimp simp: principal_eq_bot_iff Collect_empty_eq_bot bot_fun_def simp del: Collect_empty_eq)
  1042   fix A1 A2 B1 B2 assume "\<forall>\<^sub>F x in A. A1 x" "\<forall>\<^sub>F x in A. A2 x" "\<forall>\<^sub>F x in B. B1 x" "\<forall>\<^sub>F x in B. B2 x"
  1043   then show "\<exists>x. eventually x A \<and> (\<exists>y. eventually y B \<and> Collect x \<times> Collect y \<subseteq> Collect A1 \<times> Collect B1 \<and> Collect x \<times> Collect y \<subseteq> Collect A2 \<times> Collect B2)"
  1044     by (intro exI[of _ "\<lambda>x. A1 x \<and> A2 x"] exI[of _ "\<lambda>x. B1 x \<and> B2 x"] conjI)
  1045        (auto simp: eventually_conj_iff)
  1046 next
  1047   show "(\<exists>x. eventually x A \<and> (\<exists>y. eventually y B \<and> (x = (\<lambda>x. False) \<or> y = (\<lambda>x. False)))) = (A = \<bottom> \<or> B = \<bottom>)"
  1048     by (auto simp: trivial_limit_def intro: eventually_True)
  1049 qed
  1050 
  1051 lemma prod_filter_mono: "F \<le> F' \<Longrightarrow> G \<le> G' \<Longrightarrow> F \<times>\<^sub>F G \<le> F' \<times>\<^sub>F G'"
  1052   by (auto simp: le_filter_def eventually_prod_filter)
  1053 
  1054 lemma prod_filter_mono_iff:
  1055   assumes nAB: "A \<noteq> bot" "B \<noteq> bot"
  1056   shows "A \<times>\<^sub>F B \<le> C \<times>\<^sub>F D \<longleftrightarrow> A \<le> C \<and> B \<le> D"
  1057 proof safe
  1058   assume *: "A \<times>\<^sub>F B \<le> C \<times>\<^sub>F D"
  1059   with assms have "A \<times>\<^sub>F B \<noteq> bot"
  1060     by (auto simp: bot_unique prod_filter_eq_bot)
  1061   with * have "C \<times>\<^sub>F D \<noteq> bot"
  1062     by (auto simp: bot_unique)
  1063   then have nCD: "C \<noteq> bot" "D \<noteq> bot"
  1064     by (auto simp: prod_filter_eq_bot)
  1065 
  1066   show "A \<le> C"
  1067   proof (rule filter_leI)
  1068     fix P assume "eventually P C" with *[THEN filter_leD, of "\<lambda>(x, y). P x"] show "eventually P A"
  1069       using nAB nCD by (simp add: eventually_prod1 eventually_prod2)
  1070   qed
  1071 
  1072   show "B \<le> D"
  1073   proof (rule filter_leI)
  1074     fix P assume "eventually P D" with *[THEN filter_leD, of "\<lambda>(x, y). P y"] show "eventually P B"
  1075       using nAB nCD by (simp add: eventually_prod1 eventually_prod2)
  1076   qed
  1077 qed (intro prod_filter_mono)
  1078 
  1079 lemma eventually_prod_same: "eventually P (F \<times>\<^sub>F F) \<longleftrightarrow>
  1080     (\<exists>Q. eventually Q F \<and> (\<forall>x y. Q x \<longrightarrow> Q y \<longrightarrow> P (x, y)))"
  1081   unfolding eventually_prod_filter
  1082   apply safe
  1083   apply (rule_tac x="inf Pf Pg" in exI)
  1084   apply (auto simp: inf_fun_def intro!: eventually_conj)
  1085   done
  1086 
  1087 lemma eventually_prod_sequentially:
  1088   "eventually P (sequentially \<times>\<^sub>F sequentially) \<longleftrightarrow> (\<exists>N. \<forall>m \<ge> N. \<forall>n \<ge> N. P (n, m))"
  1089   unfolding eventually_prod_same eventually_sequentially by auto
  1090 
  1091 lemma principal_prod_principal: "principal A \<times>\<^sub>F principal B = principal (A \<times> B)"
  1092   apply (simp add: filter_eq_iff eventually_prod_filter eventually_principal)
  1093   apply safe
  1094   apply blast
  1095   apply (intro conjI exI[of _ "\<lambda>x. x \<in> A"] exI[of _ "\<lambda>x. x \<in> B"])
  1096   apply auto
  1097   done
  1098 
  1099 lemma prod_filter_INF:
  1100   assumes "I \<noteq> {}" "J \<noteq> {}"
  1101   shows "(INF i:I. A i) \<times>\<^sub>F (INF j:J. B j) = (INF i:I. INF j:J. A i \<times>\<^sub>F B j)"
  1102 proof (safe intro!: antisym INF_greatest)
  1103   from \<open>I \<noteq> {}\<close> obtain i where "i \<in> I" by auto
  1104   from \<open>J \<noteq> {}\<close> obtain j where "j \<in> J" by auto
  1105 
  1106   show "(\<Sqinter>i\<in>I. \<Sqinter>j\<in>J. A i \<times>\<^sub>F B j) \<le> (\<Sqinter>i\<in>I. A i) \<times>\<^sub>F (\<Sqinter>j\<in>J. B j)"
  1107     unfolding prod_filter_def
  1108   proof (safe intro!: INF_greatest)
  1109     fix P Q assume P: "\<forall>\<^sub>F x in \<Sqinter>i\<in>I. A i. P x" and Q: "\<forall>\<^sub>F x in \<Sqinter>j\<in>J. B j. Q x"
  1110     let ?X = "(\<Sqinter>i\<in>I. \<Sqinter>j\<in>J. \<Sqinter>(P, Q)\<in>{(P, Q). (\<forall>\<^sub>F x in A i. P x) \<and> (\<forall>\<^sub>F x in B j. Q x)}. principal {(x, y). P x \<and> Q y})"
  1111     have "?X \<le> principal {x. P (fst x)} \<sqinter> principal {x. Q (snd x)}"
  1112     proof (intro inf_greatest)
  1113       have "?X \<le> (\<Sqinter>i\<in>I. \<Sqinter>P\<in>{P. eventually P (A i)}. principal {x. P (fst x)})"
  1114         by (auto intro!: INF_greatest INF_lower2[of j] INF_lower2 \<open>j\<in>J\<close> INF_lower2[of "(_, \<lambda>x. True)"])
  1115       also have "\<dots> \<le> principal {x. P (fst x)}"
  1116         unfolding le_principal
  1117       proof (rule eventually_INF_mono[OF P])
  1118         fix i P assume "i \<in> I" "eventually P (A i)"
  1119         then show "\<forall>\<^sub>F x in \<Sqinter>P\<in>{P. eventually P (A i)}. principal {x. P (fst x)}. x \<in> {x. P (fst x)}"
  1120           unfolding le_principal[symmetric] by (auto intro!: INF_lower)
  1121       qed auto
  1122       finally show "?X \<le> principal {x. P (fst x)}" .
  1123 
  1124       have "?X \<le> (\<Sqinter>i\<in>J. \<Sqinter>P\<in>{P. eventually P (B i)}. principal {x. P (snd x)})"
  1125         by (auto intro!: INF_greatest INF_lower2[of i] INF_lower2 \<open>i\<in>I\<close> INF_lower2[of "(\<lambda>x. True, _)"])
  1126       also have "\<dots> \<le> principal {x. Q (snd x)}"
  1127         unfolding le_principal
  1128       proof (rule eventually_INF_mono[OF Q])
  1129         fix j Q assume "j \<in> J" "eventually Q (B j)"
  1130         then show "\<forall>\<^sub>F x in \<Sqinter>P\<in>{P. eventually P (B j)}. principal {x. P (snd x)}. x \<in> {x. Q (snd x)}"
  1131           unfolding le_principal[symmetric] by (auto intro!: INF_lower)
  1132       qed auto
  1133       finally show "?X \<le> principal {x. Q (snd x)}" .
  1134     qed
  1135     also have "\<dots> = principal {(x, y). P x \<and> Q y}"
  1136       by auto
  1137     finally show "?X \<le> principal {(x, y). P x \<and> Q y}" .
  1138   qed
  1139 qed (intro prod_filter_mono INF_lower)
  1140 
  1141 lemma filtermap_Pair: "filtermap (\<lambda>x. (f x, g x)) F \<le> filtermap f F \<times>\<^sub>F filtermap g F"
  1142   by (simp add: le_filter_def eventually_filtermap eventually_prod_filter)
  1143      (auto elim: eventually_elim2)
  1144 
  1145 lemma eventually_prodI: "eventually P F \<Longrightarrow> eventually Q G \<Longrightarrow> eventually (\<lambda>x. P (fst x) \<and> Q (snd x)) (F \<times>\<^sub>F G)"
  1146   unfolding prod_filter_def
  1147   by (intro eventually_INF1[of "(P, Q)"]) (auto simp: eventually_principal)
  1148 
  1149 lemma prod_filter_INF1: "I \<noteq> {} \<Longrightarrow> (INF i:I. A i) \<times>\<^sub>F B = (INF i:I. A i \<times>\<^sub>F B)"
  1150   using prod_filter_INF[of I "{B}" A "\<lambda>x. x"] by simp
  1151 
  1152 lemma prod_filter_INF2: "J \<noteq> {} \<Longrightarrow> A \<times>\<^sub>F (INF i:J. B i) = (INF i:J. A \<times>\<^sub>F B i)"
  1153   using prod_filter_INF[of "{A}" J "\<lambda>x. x" B] by simp
  1154 
  1155 subsection \<open>Limits\<close>
  1156 
  1157 definition filterlim :: "('a \<Rightarrow> 'b) \<Rightarrow> 'b filter \<Rightarrow> 'a filter \<Rightarrow> bool" where
  1158   "filterlim f F2 F1 \<longleftrightarrow> filtermap f F1 \<le> F2"
  1159 
  1160 syntax
  1161   "_LIM" :: "pttrns \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> bool" ("(3LIM (_)/ (_)./ (_) :> (_))" [1000, 10, 0, 10] 10)
  1162 
  1163 translations
  1164   "LIM x F1. f :> F2" == "CONST filterlim (\<lambda>x. f) F2 F1"
  1165 
  1166 lemma filterlim_top [simp]: "filterlim f top F"
  1167   by (simp add: filterlim_def)
  1168 
  1169 lemma filterlim_iff:
  1170   "(LIM x F1. f x :> F2) \<longleftrightarrow> (\<forall>P. eventually P F2 \<longrightarrow> eventually (\<lambda>x. P (f x)) F1)"
  1171   unfolding filterlim_def le_filter_def eventually_filtermap ..
  1172 
  1173 lemma filterlim_compose:
  1174   "filterlim g F3 F2 \<Longrightarrow> filterlim f F2 F1 \<Longrightarrow> filterlim (\<lambda>x. g (f x)) F3 F1"
  1175   unfolding filterlim_def filtermap_filtermap[symmetric] by (metis filtermap_mono order_trans)
  1176 
  1177 lemma filterlim_mono:
  1178   "filterlim f F2 F1 \<Longrightarrow> F2 \<le> F2' \<Longrightarrow> F1' \<le> F1 \<Longrightarrow> filterlim f F2' F1'"
  1179   unfolding filterlim_def by (metis filtermap_mono order_trans)
  1180 
  1181 lemma filterlim_ident: "LIM x F. x :> F"
  1182   by (simp add: filterlim_def filtermap_ident)
  1183 
  1184 lemma filterlim_cong:
  1185   "F1 = F1' \<Longrightarrow> F2 = F2' \<Longrightarrow> eventually (\<lambda>x. f x = g x) F2 \<Longrightarrow> filterlim f F1 F2 = filterlim g F1' F2'"
  1186   by (auto simp: filterlim_def le_filter_def eventually_filtermap elim: eventually_elim2)
  1187 
  1188 lemma filterlim_mono_eventually:
  1189   assumes "filterlim f F G" and ord: "F \<le> F'" "G' \<le> G"
  1190   assumes eq: "eventually (\<lambda>x. f x = f' x) G'"
  1191   shows "filterlim f' F' G'"
  1192   apply (rule filterlim_cong[OF refl refl eq, THEN iffD1])
  1193   apply (rule filterlim_mono[OF _ ord])
  1194   apply fact
  1195   done
  1196 
  1197 lemma filtermap_mono_strong: "inj f \<Longrightarrow> filtermap f F \<le> filtermap f G \<longleftrightarrow> F \<le> G"
  1198   apply (auto intro!: filtermap_mono) []
  1199   apply (auto simp: le_filter_def eventually_filtermap)
  1200   apply (erule_tac x="\<lambda>x. P (inv f x)" in allE)
  1201   apply auto
  1202   done
  1203 
  1204 lemma filtermap_eq_strong: "inj f \<Longrightarrow> filtermap f F = filtermap f G \<longleftrightarrow> F = G"
  1205   by (simp add: filtermap_mono_strong eq_iff)
  1206 
  1207 lemma filtermap_fun_inverse:
  1208   assumes g: "filterlim g F G"
  1209   assumes f: "filterlim f G F"
  1210   assumes ev: "eventually (\<lambda>x. f (g x) = x) G"
  1211   shows "filtermap f F = G"
  1212 proof (rule antisym)
  1213   show "filtermap f F \<le> G"
  1214     using f unfolding filterlim_def .
  1215   have "G = filtermap f (filtermap g G)"
  1216     using ev by (auto elim: eventually_elim2 simp: filter_eq_iff eventually_filtermap)
  1217   also have "\<dots> \<le> filtermap f F"
  1218     using g by (intro filtermap_mono) (simp add: filterlim_def)
  1219   finally show "G \<le> filtermap f F" .
  1220 qed
  1221 
  1222 lemma filterlim_principal:
  1223   "(LIM x F. f x :> principal S) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> S) F)"
  1224   unfolding filterlim_def eventually_filtermap le_principal ..
  1225 
  1226 lemma filterlim_inf:
  1227   "(LIM x F1. f x :> inf F2 F3) \<longleftrightarrow> ((LIM x F1. f x :> F2) \<and> (LIM x F1. f x :> F3))"
  1228   unfolding filterlim_def by simp
  1229 
  1230 lemma filterlim_INF:
  1231   "(LIM x F. f x :> (INF b:B. G b)) \<longleftrightarrow> (\<forall>b\<in>B. LIM x F. f x :> G b)"
  1232   unfolding filterlim_def le_INF_iff ..
  1233 
  1234 lemma filterlim_INF_INF:
  1235   "(\<And>m. m \<in> J \<Longrightarrow> \<exists>i\<in>I. filtermap f (F i) \<le> G m) \<Longrightarrow> LIM x (INF i:I. F i). f x :> (INF j:J. G j)"
  1236   unfolding filterlim_def by (rule order_trans[OF filtermap_INF INF_mono])
  1237 
  1238 lemma filterlim_base:
  1239   "(\<And>m x. m \<in> J \<Longrightarrow> i m \<in> I) \<Longrightarrow> (\<And>m x. m \<in> J \<Longrightarrow> x \<in> F (i m) \<Longrightarrow> f x \<in> G m) \<Longrightarrow>
  1240     LIM x (INF i:I. principal (F i)). f x :> (INF j:J. principal (G j))"
  1241   by (force intro!: filterlim_INF_INF simp: image_subset_iff)
  1242 
  1243 lemma filterlim_base_iff:
  1244   assumes "I \<noteq> {}" and chain: "\<And>i j. i \<in> I \<Longrightarrow> j \<in> I \<Longrightarrow> F i \<subseteq> F j \<or> F j \<subseteq> F i"
  1245   shows "(LIM x (INF i:I. principal (F i)). f x :> INF j:J. principal (G j)) \<longleftrightarrow>
  1246     (\<forall>j\<in>J. \<exists>i\<in>I. \<forall>x\<in>F i. f x \<in> G j)"
  1247   unfolding filterlim_INF filterlim_principal
  1248 proof (subst eventually_INF_base)
  1249   fix i j assume "i \<in> I" "j \<in> I"
  1250   with chain[OF this] show "\<exists>x\<in>I. principal (F x) \<le> inf (principal (F i)) (principal (F j))"
  1251     by auto
  1252 qed (auto simp: eventually_principal \<open>I \<noteq> {}\<close>)
  1253 
  1254 lemma filterlim_filtermap: "filterlim f F1 (filtermap g F2) = filterlim (\<lambda>x. f (g x)) F1 F2"
  1255   unfolding filterlim_def filtermap_filtermap ..
  1256 
  1257 lemma filterlim_sup:
  1258   "filterlim f F F1 \<Longrightarrow> filterlim f F F2 \<Longrightarrow> filterlim f F (sup F1 F2)"
  1259   unfolding filterlim_def filtermap_sup by auto
  1260 
  1261 lemma filterlim_sequentially_Suc:
  1262   "(LIM x sequentially. f (Suc x) :> F) \<longleftrightarrow> (LIM x sequentially. f x :> F)"
  1263   unfolding filterlim_iff by (subst eventually_sequentially_Suc) simp
  1264 
  1265 lemma filterlim_Suc: "filterlim Suc sequentially sequentially"
  1266   by (simp add: filterlim_iff eventually_sequentially)
  1267 
  1268 lemma filterlim_If:
  1269   "LIM x inf F (principal {x. P x}). f x :> G \<Longrightarrow>
  1270     LIM x inf F (principal {x. \<not> P x}). g x :> G \<Longrightarrow>
  1271     LIM x F. if P x then f x else g x :> G"
  1272   unfolding filterlim_iff eventually_inf_principal by (auto simp: eventually_conj_iff)
  1273 
  1274 lemma filterlim_Pair:
  1275   "LIM x F. f x :> G \<Longrightarrow> LIM x F. g x :> H \<Longrightarrow> LIM x F. (f x, g x) :> G \<times>\<^sub>F H"
  1276   unfolding filterlim_def
  1277   by (rule order_trans[OF filtermap_Pair prod_filter_mono])
  1278 
  1279 subsection \<open>Limits to @{const at_top} and @{const at_bot}\<close>
  1280 
  1281 lemma filterlim_at_top:
  1282   fixes f :: "'a \<Rightarrow> ('b::linorder)"
  1283   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z \<le> f x) F)"
  1284   by (auto simp: filterlim_iff eventually_at_top_linorder elim!: eventually_mono)
  1285 
  1286 lemma filterlim_at_top_mono:
  1287   "LIM x F. f x :> at_top \<Longrightarrow> eventually (\<lambda>x. f x \<le> (g x::'a::linorder)) F \<Longrightarrow>
  1288     LIM x F. g x :> at_top"
  1289   by (auto simp: filterlim_at_top elim: eventually_elim2 intro: order_trans)
  1290 
  1291 lemma filterlim_at_top_dense:
  1292   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)"
  1293   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z < f x) F)"
  1294   by (metis eventually_mono[of _ F] eventually_gt_at_top order_less_imp_le
  1295             filterlim_at_top[of f F] filterlim_iff[of f at_top F])
  1296 
  1297 lemma filterlim_at_top_ge:
  1298   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
  1299   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z\<ge>c. eventually (\<lambda>x. Z \<le> f x) F)"
  1300   unfolding at_top_sub[of c] filterlim_INF by (auto simp add: filterlim_principal)
  1301 
  1302 lemma filterlim_at_top_at_top:
  1303   fixes f :: "'a::linorder \<Rightarrow> 'b::linorder"
  1304   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1305   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1306   assumes Q: "eventually Q at_top"
  1307   assumes P: "eventually P at_top"
  1308   shows "filterlim f at_top at_top"
  1309 proof -
  1310   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
  1311     unfolding eventually_at_top_linorder by auto
  1312   show ?thesis
  1313   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
  1314     fix z assume "x \<le> z"
  1315     with x have "P z" by auto
  1316     have "eventually (\<lambda>x. g z \<le> x) at_top"
  1317       by (rule eventually_ge_at_top)
  1318     with Q show "eventually (\<lambda>x. z \<le> f x) at_top"
  1319       by eventually_elim (metis mono bij \<open>P z\<close>)
  1320   qed
  1321 qed
  1322 
  1323 lemma filterlim_at_top_gt:
  1324   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
  1325   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z>c. eventually (\<lambda>x. Z \<le> f x) F)"
  1326   by (metis filterlim_at_top order_less_le_trans gt_ex filterlim_at_top_ge)
  1327 
  1328 lemma filterlim_at_bot:
  1329   fixes f :: "'a \<Rightarrow> ('b::linorder)"
  1330   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F)"
  1331   by (auto simp: filterlim_iff eventually_at_bot_linorder elim!: eventually_mono)
  1332 
  1333 lemma filterlim_at_bot_dense:
  1334   fixes f :: "'a \<Rightarrow> ('b::{dense_linorder, no_bot})"
  1335   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x < Z) F)"
  1336 proof (auto simp add: filterlim_at_bot[of f F])
  1337   fix Z :: 'b
  1338   from lt_ex [of Z] obtain Z' where 1: "Z' < Z" ..
  1339   assume "\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F"
  1340   hence "eventually (\<lambda>x. f x \<le> Z') F" by auto
  1341   thus "eventually (\<lambda>x. f x < Z) F"
  1342     apply (rule eventually_mono)
  1343     using 1 by auto
  1344   next
  1345     fix Z :: 'b
  1346     show "\<forall>Z. eventually (\<lambda>x. f x < Z) F \<Longrightarrow> eventually (\<lambda>x. f x \<le> Z) F"
  1347       by (drule spec [of _ Z], erule eventually_mono, auto simp add: less_imp_le)
  1348 qed
  1349 
  1350 lemma filterlim_at_bot_le:
  1351   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
  1352   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F)"
  1353   unfolding filterlim_at_bot
  1354 proof safe
  1355   fix Z assume *: "\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F"
  1356   with *[THEN spec, of "min Z c"] show "eventually (\<lambda>x. Z \<ge> f x) F"
  1357     by (auto elim!: eventually_mono)
  1358 qed simp
  1359 
  1360 lemma filterlim_at_bot_lt:
  1361   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
  1362   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z<c. eventually (\<lambda>x. Z \<ge> f x) F)"
  1363   by (metis filterlim_at_bot filterlim_at_bot_le lt_ex order_le_less_trans)
  1364     
  1365 lemma filterlim_filtercomap [intro]: "filterlim f F (filtercomap f F)"
  1366   unfolding filterlim_def by (rule filtermap_filtercomap)
  1367 
  1368 
  1369 subsection \<open>Setup @{typ "'a filter"} for lifting and transfer\<close>
  1370 
  1371 context includes lifting_syntax
  1372 begin
  1373 
  1374 definition rel_filter :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> 'b filter \<Rightarrow> bool"
  1375 where "rel_filter R F G = ((R ===> op =) ===> op =) (Rep_filter F) (Rep_filter G)"
  1376 
  1377 lemma rel_filter_eventually:
  1378   "rel_filter R F G \<longleftrightarrow>
  1379   ((R ===> op =) ===> op =) (\<lambda>P. eventually P F) (\<lambda>P. eventually P G)"
  1380 by(simp add: rel_filter_def eventually_def)
  1381 
  1382 lemma filtermap_id [simp, id_simps]: "filtermap id = id"
  1383 by(simp add: fun_eq_iff id_def filtermap_ident)
  1384 
  1385 lemma filtermap_id' [simp]: "filtermap (\<lambda>x. x) = (\<lambda>F. F)"
  1386 using filtermap_id unfolding id_def .
  1387 
  1388 lemma Quotient_filter [quot_map]:
  1389   assumes Q: "Quotient R Abs Rep T"
  1390   shows "Quotient (rel_filter R) (filtermap Abs) (filtermap Rep) (rel_filter T)"
  1391 unfolding Quotient_alt_def
  1392 proof(intro conjI strip)
  1393   from Q have *: "\<And>x y. T x y \<Longrightarrow> Abs x = y"
  1394     unfolding Quotient_alt_def by blast
  1395 
  1396   fix F G
  1397   assume "rel_filter T F G"
  1398   thus "filtermap Abs F = G" unfolding filter_eq_iff
  1399     by(auto simp add: eventually_filtermap rel_filter_eventually * rel_funI del: iffI elim!: rel_funD)
  1400 next
  1401   from Q have *: "\<And>x. T (Rep x) x" unfolding Quotient_alt_def by blast
  1402 
  1403   fix F
  1404   show "rel_filter T (filtermap Rep F) F"
  1405     by(auto elim: rel_funD intro: * intro!: ext arg_cong[where f="\<lambda>P. eventually P F"] rel_funI
  1406             del: iffI simp add: eventually_filtermap rel_filter_eventually)
  1407 qed(auto simp add: map_fun_def o_def eventually_filtermap filter_eq_iff fun_eq_iff rel_filter_eventually
  1408          fun_quotient[OF fun_quotient[OF Q identity_quotient] identity_quotient, unfolded Quotient_alt_def])
  1409 
  1410 lemma eventually_parametric [transfer_rule]:
  1411   "((A ===> op =) ===> rel_filter A ===> op =) eventually eventually"
  1412 by(simp add: rel_fun_def rel_filter_eventually)
  1413 
  1414 lemma frequently_parametric [transfer_rule]:
  1415   "((A ===> op =) ===> rel_filter A ===> op =) frequently frequently"
  1416   unfolding frequently_def[abs_def] by transfer_prover
  1417 
  1418 lemma rel_filter_eq [relator_eq]: "rel_filter op = = op ="
  1419 by(auto simp add: rel_filter_eventually rel_fun_eq fun_eq_iff filter_eq_iff)
  1420 
  1421 lemma rel_filter_mono [relator_mono]:
  1422   "A \<le> B \<Longrightarrow> rel_filter A \<le> rel_filter B"
  1423 unfolding rel_filter_eventually[abs_def]
  1424 by(rule le_funI)+(intro fun_mono fun_mono[THEN le_funD, THEN le_funD] order.refl)
  1425 
  1426 lemma rel_filter_conversep [simp]: "rel_filter A\<inverse>\<inverse> = (rel_filter A)\<inverse>\<inverse>"
  1427 apply (simp add: rel_filter_eventually fun_eq_iff rel_fun_def)
  1428 apply (safe; metis)
  1429 done
  1430 
  1431 lemma is_filter_parametric_aux:
  1432   assumes "is_filter F"
  1433   assumes [transfer_rule]: "bi_total A" "bi_unique A"
  1434   and [transfer_rule]: "((A ===> op =) ===> op =) F G"
  1435   shows "is_filter G"
  1436 proof -
  1437   interpret is_filter F by fact
  1438   show ?thesis
  1439   proof
  1440     have "F (\<lambda>_. True) = G (\<lambda>x. True)" by transfer_prover
  1441     thus "G (\<lambda>x. True)" by(simp add: True)
  1442   next
  1443     fix P' Q'
  1444     assume "G P'" "G Q'"
  1445     moreover
  1446     from bi_total_fun[OF \<open>bi_unique A\<close> bi_total_eq, unfolded bi_total_def]
  1447     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
  1448     have "F P = G P'" "F Q = G Q'" by transfer_prover+
  1449     ultimately have "F (\<lambda>x. P x \<and> Q x)" by(simp add: conj)
  1450     moreover have "F (\<lambda>x. P x \<and> Q x) = G (\<lambda>x. P' x \<and> Q' x)" by transfer_prover
  1451     ultimately show "G (\<lambda>x. P' x \<and> Q' x)" by simp
  1452   next
  1453     fix P' Q'
  1454     assume "\<forall>x. P' x \<longrightarrow> Q' x" "G P'"
  1455     moreover
  1456     from bi_total_fun[OF \<open>bi_unique A\<close> bi_total_eq, unfolded bi_total_def]
  1457     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
  1458     have "F P = G P'" by transfer_prover
  1459     moreover have "(\<forall>x. P x \<longrightarrow> Q x) \<longleftrightarrow> (\<forall>x. P' x \<longrightarrow> Q' x)" by transfer_prover
  1460     ultimately have "F Q" by(simp add: mono)
  1461     moreover have "F Q = G Q'" by transfer_prover
  1462     ultimately show "G Q'" by simp
  1463   qed
  1464 qed
  1465 
  1466 lemma is_filter_parametric [transfer_rule]:
  1467   "\<lbrakk> bi_total A; bi_unique A \<rbrakk>
  1468   \<Longrightarrow> (((A ===> op =) ===> op =) ===> op =) is_filter is_filter"
  1469 apply(rule rel_funI)
  1470 apply(rule iffI)
  1471  apply(erule (3) is_filter_parametric_aux)
  1472 apply(erule is_filter_parametric_aux[where A="conversep A"])
  1473 apply (simp_all add: rel_fun_def)
  1474 apply metis
  1475 done
  1476 
  1477 lemma left_total_rel_filter [transfer_rule]:
  1478   assumes [transfer_rule]: "bi_total A" "bi_unique A"
  1479   shows "left_total (rel_filter A)"
  1480 proof(rule left_totalI)
  1481   fix F :: "'a filter"
  1482   from bi_total_fun[OF bi_unique_fun[OF \<open>bi_total A\<close> bi_unique_eq] bi_total_eq]
  1483   obtain G where [transfer_rule]: "((A ===> op =) ===> op =) (\<lambda>P. eventually P F) G"
  1484     unfolding  bi_total_def by blast
  1485   moreover have "is_filter (\<lambda>P. eventually P F) \<longleftrightarrow> is_filter G" by transfer_prover
  1486   hence "is_filter G" by(simp add: eventually_def is_filter_Rep_filter)
  1487   ultimately have "rel_filter A F (Abs_filter G)"
  1488     by(simp add: rel_filter_eventually eventually_Abs_filter)
  1489   thus "\<exists>G. rel_filter A F G" ..
  1490 qed
  1491 
  1492 lemma right_total_rel_filter [transfer_rule]:
  1493   "\<lbrakk> bi_total A; bi_unique A \<rbrakk> \<Longrightarrow> right_total (rel_filter A)"
  1494 using left_total_rel_filter[of "A\<inverse>\<inverse>"] by simp
  1495 
  1496 lemma bi_total_rel_filter [transfer_rule]:
  1497   assumes "bi_total A" "bi_unique A"
  1498   shows "bi_total (rel_filter A)"
  1499 unfolding bi_total_alt_def using assms
  1500 by(simp add: left_total_rel_filter right_total_rel_filter)
  1501 
  1502 lemma left_unique_rel_filter [transfer_rule]:
  1503   assumes "left_unique A"
  1504   shows "left_unique (rel_filter A)"
  1505 proof(rule left_uniqueI)
  1506   fix F F' G
  1507   assume [transfer_rule]: "rel_filter A F G" "rel_filter A F' G"
  1508   show "F = F'"
  1509     unfolding filter_eq_iff
  1510   proof
  1511     fix P :: "'a \<Rightarrow> bool"
  1512     obtain P' where [transfer_rule]: "(A ===> op =) P P'"
  1513       using left_total_fun[OF assms left_total_eq] unfolding left_total_def by blast
  1514     have "eventually P F = eventually P' G"
  1515       and "eventually P F' = eventually P' G" by transfer_prover+
  1516     thus "eventually P F = eventually P F'" by simp
  1517   qed
  1518 qed
  1519 
  1520 lemma right_unique_rel_filter [transfer_rule]:
  1521   "right_unique A \<Longrightarrow> right_unique (rel_filter A)"
  1522 using left_unique_rel_filter[of "A\<inverse>\<inverse>"] by simp
  1523 
  1524 lemma bi_unique_rel_filter [transfer_rule]:
  1525   "bi_unique A \<Longrightarrow> bi_unique (rel_filter A)"
  1526 by(simp add: bi_unique_alt_def left_unique_rel_filter right_unique_rel_filter)
  1527 
  1528 lemma top_filter_parametric [transfer_rule]:
  1529   "bi_total A \<Longrightarrow> (rel_filter A) top top"
  1530 by(simp add: rel_filter_eventually All_transfer)
  1531 
  1532 lemma bot_filter_parametric [transfer_rule]: "(rel_filter A) bot bot"
  1533 by(simp add: rel_filter_eventually rel_fun_def)
  1534 
  1535 lemma sup_filter_parametric [transfer_rule]:
  1536   "(rel_filter A ===> rel_filter A ===> rel_filter A) sup sup"
  1537 by(fastforce simp add: rel_filter_eventually[abs_def] eventually_sup dest: rel_funD)
  1538 
  1539 lemma Sup_filter_parametric [transfer_rule]:
  1540   "(rel_set (rel_filter A) ===> rel_filter A) Sup Sup"
  1541 proof(rule rel_funI)
  1542   fix S T
  1543   assume [transfer_rule]: "rel_set (rel_filter A) S T"
  1544   show "rel_filter A (Sup S) (Sup T)"
  1545     by(simp add: rel_filter_eventually eventually_Sup) transfer_prover
  1546 qed
  1547 
  1548 lemma principal_parametric [transfer_rule]:
  1549   "(rel_set A ===> rel_filter A) principal principal"
  1550 proof(rule rel_funI)
  1551   fix S S'
  1552   assume [transfer_rule]: "rel_set A S S'"
  1553   show "rel_filter A (principal S) (principal S')"
  1554     by(simp add: rel_filter_eventually eventually_principal) transfer_prover
  1555 qed
  1556   
  1557 lemma filtermap_parametric [transfer_rule]:
  1558   "((A ===> B) ===> rel_filter A ===> rel_filter B) filtermap filtermap"
  1559 proof (intro rel_funI)
  1560   fix f g F G assume [transfer_rule]: "(A ===> B) f g" "rel_filter A F G"
  1561   show "rel_filter B (filtermap f F) (filtermap g G)"
  1562     unfolding rel_filter_eventually eventually_filtermap by transfer_prover
  1563 qed
  1564 
  1565 (* TODO: Are those assumptions needed? *)
  1566 lemma filtercomap_parametric [transfer_rule]:
  1567   assumes [transfer_rule]: "bi_unique B" "bi_total A"
  1568   shows   "((A ===> B) ===> rel_filter B ===> rel_filter A) filtercomap filtercomap"
  1569 proof (intro rel_funI)
  1570   fix f g F G assume [transfer_rule]: "(A ===> B) f g" "rel_filter B F G"
  1571   show "rel_filter A (filtercomap f F) (filtercomap g G)"
  1572     unfolding rel_filter_eventually eventually_filtercomap by transfer_prover
  1573 qed
  1574     
  1575 
  1576 context
  1577   fixes A :: "'a \<Rightarrow> 'b \<Rightarrow> bool"
  1578   assumes [transfer_rule]: "bi_unique A"
  1579 begin
  1580 
  1581 lemma le_filter_parametric [transfer_rule]:
  1582   "(rel_filter A ===> rel_filter A ===> op =) op \<le> op \<le>"
  1583 unfolding le_filter_def[abs_def] by transfer_prover
  1584 
  1585 lemma less_filter_parametric [transfer_rule]:
  1586   "(rel_filter A ===> rel_filter A ===> op =) op < op <"
  1587 unfolding less_filter_def[abs_def] by transfer_prover
  1588 
  1589 context
  1590   assumes [transfer_rule]: "bi_total A"
  1591 begin
  1592 
  1593 lemma Inf_filter_parametric [transfer_rule]:
  1594   "(rel_set (rel_filter A) ===> rel_filter A) Inf Inf"
  1595 unfolding Inf_filter_def[abs_def] by transfer_prover
  1596 
  1597 lemma inf_filter_parametric [transfer_rule]:
  1598   "(rel_filter A ===> rel_filter A ===> rel_filter A) inf inf"
  1599 proof(intro rel_funI)+
  1600   fix F F' G G'
  1601   assume [transfer_rule]: "rel_filter A F F'" "rel_filter A G G'"
  1602   have "rel_filter A (Inf {F, G}) (Inf {F', G'})" by transfer_prover
  1603   thus "rel_filter A (inf F G) (inf F' G')" by simp
  1604 qed
  1605 
  1606 end
  1607 
  1608 end
  1609 
  1610 end
  1611 
  1612 text \<open>Code generation for filters\<close>
  1613 
  1614 definition abstract_filter :: "(unit \<Rightarrow> 'a filter) \<Rightarrow> 'a filter"
  1615   where [simp]: "abstract_filter f = f ()"
  1616 
  1617 code_datatype principal abstract_filter
  1618 
  1619 hide_const (open) abstract_filter
  1620 
  1621 declare [[code drop: filterlim prod_filter filtermap eventually
  1622   "inf :: _ filter \<Rightarrow> _" "sup :: _ filter \<Rightarrow> _" "less_eq :: _ filter \<Rightarrow> _"
  1623   Abs_filter]]
  1624 
  1625 declare filterlim_principal [code]
  1626 declare principal_prod_principal [code]
  1627 declare filtermap_principal [code]
  1628 declare filtercomap_principal [code]
  1629 declare eventually_principal [code]
  1630 declare inf_principal [code]
  1631 declare sup_principal [code]
  1632 declare principal_le_iff [code]
  1633 
  1634 lemma Rep_filter_iff_eventually [simp, code]:
  1635   "Rep_filter F P \<longleftrightarrow> eventually P F"
  1636   by (simp add: eventually_def)
  1637 
  1638 lemma bot_eq_principal_empty [code]:
  1639   "bot = principal {}"
  1640   by simp
  1641 
  1642 lemma top_eq_principal_UNIV [code]:
  1643   "top = principal UNIV"
  1644   by simp
  1645 
  1646 instantiation filter :: (equal) equal
  1647 begin
  1648 
  1649 definition equal_filter :: "'a filter \<Rightarrow> 'a filter \<Rightarrow> bool"
  1650   where "equal_filter F F' \<longleftrightarrow> F = F'"
  1651 
  1652 lemma equal_filter [code]:
  1653   "HOL.equal (principal A) (principal B) \<longleftrightarrow> A = B"
  1654   by (simp add: equal_filter_def)
  1655 
  1656 instance
  1657   by standard (simp add: equal_filter_def)
  1658 
  1659 end
  1660 
  1661 end