src/HOL/HOLCF/Completion.thy
author blanchet
Tue Nov 07 15:16:42 2017 +0100 (20 months ago)
changeset 67022 49309fe530fd
parent 65380 ae93953746fc
child 68383 93a42bd62ede
permissions -rw-r--r--
more robust parsing for THF proofs (esp. polymorphic Leo-III proofs)
     1 (*  Title:      HOL/HOLCF/Completion.thy
     2     Author:     Brian Huffman
     3 *)
     4 
     5 section \<open>Defining algebraic domains by ideal completion\<close>
     6 
     7 theory Completion
     8 imports Cfun
     9 begin
    10 
    11 subsection \<open>Ideals over a preorder\<close>
    12 
    13 locale preorder =
    14   fixes r :: "'a::type \<Rightarrow> 'a \<Rightarrow> bool" (infix "\<preceq>" 50)
    15   assumes r_refl: "x \<preceq> x"
    16   assumes r_trans: "\<lbrakk>x \<preceq> y; y \<preceq> z\<rbrakk> \<Longrightarrow> x \<preceq> z"
    17 begin
    18 
    19 definition
    20   ideal :: "'a set \<Rightarrow> bool" where
    21   "ideal A = ((\<exists>x. x \<in> A) \<and> (\<forall>x\<in>A. \<forall>y\<in>A. \<exists>z\<in>A. x \<preceq> z \<and> y \<preceq> z) \<and>
    22     (\<forall>x y. x \<preceq> y \<longrightarrow> y \<in> A \<longrightarrow> x \<in> A))"
    23 
    24 lemma idealI:
    25   assumes "\<exists>x. x \<in> A"
    26   assumes "\<And>x y. \<lbrakk>x \<in> A; y \<in> A\<rbrakk> \<Longrightarrow> \<exists>z\<in>A. x \<preceq> z \<and> y \<preceq> z"
    27   assumes "\<And>x y. \<lbrakk>x \<preceq> y; y \<in> A\<rbrakk> \<Longrightarrow> x \<in> A"
    28   shows "ideal A"
    29 unfolding ideal_def using assms by fast
    30 
    31 lemma idealD1:
    32   "ideal A \<Longrightarrow> \<exists>x. x \<in> A"
    33 unfolding ideal_def by fast
    34 
    35 lemma idealD2:
    36   "\<lbrakk>ideal A; x \<in> A; y \<in> A\<rbrakk> \<Longrightarrow> \<exists>z\<in>A. x \<preceq> z \<and> y \<preceq> z"
    37 unfolding ideal_def by fast
    38 
    39 lemma idealD3:
    40   "\<lbrakk>ideal A; x \<preceq> y; y \<in> A\<rbrakk> \<Longrightarrow> x \<in> A"
    41 unfolding ideal_def by fast
    42 
    43 lemma ideal_principal: "ideal {x. x \<preceq> z}"
    44 apply (rule idealI)
    45 apply (rule_tac x=z in exI)
    46 apply (fast intro: r_refl)
    47 apply (rule_tac x=z in bexI, fast)
    48 apply (fast intro: r_refl)
    49 apply (fast intro: r_trans)
    50 done
    51 
    52 lemma ex_ideal: "\<exists>A. A \<in> {A. ideal A}"
    53 by (fast intro: ideal_principal)
    54 
    55 text \<open>The set of ideals is a cpo\<close>
    56 
    57 lemma ideal_UN:
    58   fixes A :: "nat \<Rightarrow> 'a set"
    59   assumes ideal_A: "\<And>i. ideal (A i)"
    60   assumes chain_A: "\<And>i j. i \<le> j \<Longrightarrow> A i \<subseteq> A j"
    61   shows "ideal (\<Union>i. A i)"
    62  apply (rule idealI)
    63    apply (cut_tac idealD1 [OF ideal_A], fast)
    64   apply (clarify, rename_tac i j)
    65   apply (drule subsetD [OF chain_A [OF max.cobounded1]])
    66   apply (drule subsetD [OF chain_A [OF max.cobounded2]])
    67   apply (drule (1) idealD2 [OF ideal_A])
    68   apply blast
    69  apply clarify
    70  apply (drule (1) idealD3 [OF ideal_A])
    71  apply fast
    72 done
    73 
    74 lemma typedef_ideal_po:
    75   fixes Abs :: "'a set \<Rightarrow> 'b::below"
    76   assumes type: "type_definition Rep Abs {S. ideal S}"
    77   assumes below: "\<And>x y. x \<sqsubseteq> y \<longleftrightarrow> Rep x \<subseteq> Rep y"
    78   shows "OFCLASS('b, po_class)"
    79  apply (intro_classes, unfold below)
    80    apply (rule subset_refl)
    81   apply (erule (1) subset_trans)
    82  apply (rule type_definition.Rep_inject [OF type, THEN iffD1])
    83  apply (erule (1) subset_antisym)
    84 done
    85 
    86 lemma
    87   fixes Abs :: "'a set \<Rightarrow> 'b::po"
    88   assumes type: "type_definition Rep Abs {S. ideal S}"
    89   assumes below: "\<And>x y. x \<sqsubseteq> y \<longleftrightarrow> Rep x \<subseteq> Rep y"
    90   assumes S: "chain S"
    91   shows typedef_ideal_lub: "range S <<| Abs (\<Union>i. Rep (S i))"
    92     and typedef_ideal_rep_lub: "Rep (\<Squnion>i. S i) = (\<Union>i. Rep (S i))"
    93 proof -
    94   have 1: "ideal (\<Union>i. Rep (S i))"
    95     apply (rule ideal_UN)
    96      apply (rule type_definition.Rep [OF type, unfolded mem_Collect_eq])
    97     apply (subst below [symmetric])
    98     apply (erule chain_mono [OF S])
    99     done
   100   hence 2: "Rep (Abs (\<Union>i. Rep (S i))) = (\<Union>i. Rep (S i))"
   101     by (simp add: type_definition.Abs_inverse [OF type])
   102   show 3: "range S <<| Abs (\<Union>i. Rep (S i))"
   103     apply (rule is_lubI)
   104      apply (rule is_ubI)
   105      apply (simp add: below 2, fast)
   106     apply (simp add: below 2 is_ub_def, fast)
   107     done
   108   hence 4: "(\<Squnion>i. S i) = Abs (\<Union>i. Rep (S i))"
   109     by (rule lub_eqI)
   110   show 5: "Rep (\<Squnion>i. S i) = (\<Union>i. Rep (S i))"
   111     by (simp add: 4 2)
   112 qed
   113 
   114 lemma typedef_ideal_cpo:
   115   fixes Abs :: "'a set \<Rightarrow> 'b::po"
   116   assumes type: "type_definition Rep Abs {S. ideal S}"
   117   assumes below: "\<And>x y. x \<sqsubseteq> y \<longleftrightarrow> Rep x \<subseteq> Rep y"
   118   shows "OFCLASS('b, cpo_class)"
   119   by standard (rule exI, erule typedef_ideal_lub [OF type below])
   120 
   121 end
   122 
   123 interpretation below: preorder "below :: 'a::po \<Rightarrow> 'a \<Rightarrow> bool"
   124 apply unfold_locales
   125 apply (rule below_refl)
   126 apply (erule (1) below_trans)
   127 done
   128 
   129 subsection \<open>Lemmas about least upper bounds\<close>
   130 
   131 lemma is_ub_thelub_ex: "\<lbrakk>\<exists>u. S <<| u; x \<in> S\<rbrakk> \<Longrightarrow> x \<sqsubseteq> lub S"
   132 apply (erule exE, drule is_lub_lub)
   133 apply (drule is_lubD1)
   134 apply (erule (1) is_ubD)
   135 done
   136 
   137 lemma is_lub_thelub_ex: "\<lbrakk>\<exists>u. S <<| u; S <| x\<rbrakk> \<Longrightarrow> lub S \<sqsubseteq> x"
   138 by (erule exE, drule is_lub_lub, erule is_lubD2)
   139 
   140 
   141 subsection \<open>Locale for ideal completion\<close>
   142 
   143 hide_const (open) Filter.principal
   144 
   145 locale ideal_completion = preorder +
   146   fixes principal :: "'a::type \<Rightarrow> 'b::cpo"
   147   fixes rep :: "'b::cpo \<Rightarrow> 'a::type set"
   148   assumes ideal_rep: "\<And>x. ideal (rep x)"
   149   assumes rep_lub: "\<And>Y. chain Y \<Longrightarrow> rep (\<Squnion>i. Y i) = (\<Union>i. rep (Y i))"
   150   assumes rep_principal: "\<And>a. rep (principal a) = {b. b \<preceq> a}"
   151   assumes belowI: "\<And>x y. rep x \<subseteq> rep y \<Longrightarrow> x \<sqsubseteq> y"
   152   assumes countable: "\<exists>f::'a \<Rightarrow> nat. inj f"
   153 begin
   154 
   155 lemma rep_mono: "x \<sqsubseteq> y \<Longrightarrow> rep x \<subseteq> rep y"
   156 apply (frule bin_chain)
   157 apply (drule rep_lub)
   158 apply (simp only: lub_eqI [OF is_lub_bin_chain])
   159 apply (rule subsetI, rule UN_I [where a=0], simp_all)
   160 done
   161 
   162 lemma below_def: "x \<sqsubseteq> y \<longleftrightarrow> rep x \<subseteq> rep y"
   163 by (rule iffI [OF rep_mono belowI])
   164 
   165 lemma principal_below_iff_mem_rep: "principal a \<sqsubseteq> x \<longleftrightarrow> a \<in> rep x"
   166 unfolding below_def rep_principal
   167 by (auto intro: r_refl elim: idealD3 [OF ideal_rep])
   168 
   169 lemma principal_below_iff [simp]: "principal a \<sqsubseteq> principal b \<longleftrightarrow> a \<preceq> b"
   170 by (simp add: principal_below_iff_mem_rep rep_principal)
   171 
   172 lemma principal_eq_iff: "principal a = principal b \<longleftrightarrow> a \<preceq> b \<and> b \<preceq> a"
   173 unfolding po_eq_conv [where 'a='b] principal_below_iff ..
   174 
   175 lemma eq_iff: "x = y \<longleftrightarrow> rep x = rep y"
   176 unfolding po_eq_conv below_def by auto
   177 
   178 lemma principal_mono: "a \<preceq> b \<Longrightarrow> principal a \<sqsubseteq> principal b"
   179 by (simp only: principal_below_iff)
   180 
   181 lemma ch2ch_principal [simp]:
   182   "\<forall>i. Y i \<preceq> Y (Suc i) \<Longrightarrow> chain (\<lambda>i. principal (Y i))"
   183 by (simp add: chainI principal_mono)
   184 
   185 subsubsection \<open>Principal ideals approximate all elements\<close>
   186 
   187 lemma compact_principal [simp]: "compact (principal a)"
   188 by (rule compactI2, simp add: principal_below_iff_mem_rep rep_lub)
   189 
   190 text \<open>Construct a chain whose lub is the same as a given ideal\<close>
   191 
   192 lemma obtain_principal_chain:
   193   obtains Y where "\<forall>i. Y i \<preceq> Y (Suc i)" and "x = (\<Squnion>i. principal (Y i))"
   194 proof -
   195   obtain count :: "'a \<Rightarrow> nat" where inj: "inj count"
   196     using countable ..
   197   define enum where "enum i = (THE a. count a = i)" for i
   198   have enum_count [simp]: "\<And>x. enum (count x) = x"
   199     unfolding enum_def by (simp add: inj_eq [OF inj])
   200   define a where "a = (LEAST i. enum i \<in> rep x)"
   201   define b where "b i = (LEAST j. enum j \<in> rep x \<and> \<not> enum j \<preceq> enum i)" for i
   202   define c where "c i j = (LEAST k. enum k \<in> rep x \<and> enum i \<preceq> enum k \<and> enum j \<preceq> enum k)" for i j
   203   define P where "P i \<longleftrightarrow> (\<exists>j. enum j \<in> rep x \<and> \<not> enum j \<preceq> enum i)" for i
   204   define X where "X = rec_nat a (\<lambda>n i. if P i then c i (b i) else i)"
   205   have X_0: "X 0 = a" unfolding X_def by simp
   206   have X_Suc: "\<And>n. X (Suc n) = (if P (X n) then c (X n) (b (X n)) else X n)"
   207     unfolding X_def by simp
   208   have a_mem: "enum a \<in> rep x"
   209     unfolding a_def
   210     apply (rule LeastI_ex)
   211     apply (cut_tac ideal_rep [of x])
   212     apply (drule idealD1)
   213     apply (clarify, rename_tac a)
   214     apply (rule_tac x="count a" in exI, simp)
   215     done
   216   have b: "\<And>i. P i \<Longrightarrow> enum i \<in> rep x
   217     \<Longrightarrow> enum (b i) \<in> rep x \<and> \<not> enum (b i) \<preceq> enum i"
   218     unfolding P_def b_def by (erule LeastI2_ex, simp)
   219   have c: "\<And>i j. enum i \<in> rep x \<Longrightarrow> enum j \<in> rep x
   220     \<Longrightarrow> enum (c i j) \<in> rep x \<and> enum i \<preceq> enum (c i j) \<and> enum j \<preceq> enum (c i j)"
   221     unfolding c_def
   222     apply (drule (1) idealD2 [OF ideal_rep], clarify)
   223     apply (rule_tac a="count z" in LeastI2, simp, simp)
   224     done
   225   have X_mem: "\<And>n. enum (X n) \<in> rep x"
   226     apply (induct_tac n)
   227     apply (simp add: X_0 a_mem)
   228     apply (clarsimp simp add: X_Suc, rename_tac n)
   229     apply (simp add: b c)
   230     done
   231   have X_chain: "\<And>n. enum (X n) \<preceq> enum (X (Suc n))"
   232     apply (clarsimp simp add: X_Suc r_refl)
   233     apply (simp add: b c X_mem)
   234     done
   235   have less_b: "\<And>n i. n < b i \<Longrightarrow> enum n \<in> rep x \<Longrightarrow> enum n \<preceq> enum i"
   236     unfolding b_def by (drule not_less_Least, simp)
   237   have X_covers: "\<And>n. \<forall>k\<le>n. enum k \<in> rep x \<longrightarrow> enum k \<preceq> enum (X n)"
   238     apply (induct_tac n)
   239     apply (clarsimp simp add: X_0 a_def)
   240     apply (drule_tac k=0 in Least_le, simp add: r_refl)
   241     apply (clarsimp, rename_tac n k)
   242     apply (erule le_SucE)
   243     apply (rule r_trans [OF _ X_chain], simp)
   244     apply (case_tac "P (X n)", simp add: X_Suc)
   245     apply (rule_tac x="b (X n)" and y="Suc n" in linorder_cases)
   246     apply (simp only: less_Suc_eq_le)
   247     apply (drule spec, drule (1) mp, simp add: b X_mem)
   248     apply (simp add: c X_mem)
   249     apply (drule (1) less_b)
   250     apply (erule r_trans)
   251     apply (simp add: b c X_mem)
   252     apply (simp add: X_Suc)
   253     apply (simp add: P_def)
   254     done
   255   have 1: "\<forall>i. enum (X i) \<preceq> enum (X (Suc i))"
   256     by (simp add: X_chain)
   257   have 2: "x = (\<Squnion>n. principal (enum (X n)))"
   258     apply (simp add: eq_iff rep_lub 1 rep_principal)
   259     apply (auto, rename_tac a)
   260     apply (subgoal_tac "\<exists>i. a = enum i", erule exE)
   261     apply (rule_tac x=i in exI, simp add: X_covers)
   262     apply (rule_tac x="count a" in exI, simp)
   263     apply (erule idealD3 [OF ideal_rep])
   264     apply (rule X_mem)
   265     done
   266   from 1 2 show ?thesis ..
   267 qed
   268 
   269 lemma principal_induct:
   270   assumes adm: "adm P"
   271   assumes P: "\<And>a. P (principal a)"
   272   shows "P x"
   273 apply (rule obtain_principal_chain [of x])
   274 apply (simp add: admD [OF adm] P)
   275 done
   276 
   277 lemma compact_imp_principal: "compact x \<Longrightarrow> \<exists>a. x = principal a"
   278 apply (rule obtain_principal_chain [of x])
   279 apply (drule adm_compact_neq [OF _ cont_id])
   280 apply (subgoal_tac "chain (\<lambda>i. principal (Y i))")
   281 apply (drule (2) admD2, fast, simp)
   282 done
   283 
   284 subsection \<open>Defining functions in terms of basis elements\<close>
   285 
   286 definition
   287   extension :: "('a::type \<Rightarrow> 'c::cpo) \<Rightarrow> 'b \<rightarrow> 'c" where
   288   "extension = (\<lambda>f. (\<Lambda> x. lub (f ` rep x)))"
   289 
   290 lemma extension_lemma:
   291   fixes f :: "'a::type \<Rightarrow> 'c::cpo"
   292   assumes f_mono: "\<And>a b. a \<preceq> b \<Longrightarrow> f a \<sqsubseteq> f b"
   293   shows "\<exists>u. f ` rep x <<| u"
   294 proof -
   295   obtain Y where Y: "\<forall>i. Y i \<preceq> Y (Suc i)"
   296   and x: "x = (\<Squnion>i. principal (Y i))"
   297     by (rule obtain_principal_chain [of x])
   298   have chain: "chain (\<lambda>i. f (Y i))"
   299     by (rule chainI, simp add: f_mono Y)
   300   have rep_x: "rep x = (\<Union>n. {a. a \<preceq> Y n})"
   301     by (simp add: x rep_lub Y rep_principal)
   302   have "f ` rep x <<| (\<Squnion>n. f (Y n))"
   303     apply (rule is_lubI)
   304     apply (rule ub_imageI, rename_tac a)
   305     apply (clarsimp simp add: rep_x)
   306     apply (drule f_mono)
   307     apply (erule below_lub [OF chain])
   308     apply (rule lub_below [OF chain])
   309     apply (drule_tac x="Y n" in ub_imageD)
   310     apply (simp add: rep_x, fast intro: r_refl)
   311     apply assumption
   312     done
   313   thus ?thesis ..
   314 qed
   315 
   316 lemma extension_beta:
   317   fixes f :: "'a::type \<Rightarrow> 'c::cpo"
   318   assumes f_mono: "\<And>a b. a \<preceq> b \<Longrightarrow> f a \<sqsubseteq> f b"
   319   shows "extension f\<cdot>x = lub (f ` rep x)"
   320 unfolding extension_def
   321 proof (rule beta_cfun)
   322   have lub: "\<And>x. \<exists>u. f ` rep x <<| u"
   323     using f_mono by (rule extension_lemma)
   324   show cont: "cont (\<lambda>x. lub (f ` rep x))"
   325     apply (rule contI2)
   326      apply (rule monofunI)
   327      apply (rule is_lub_thelub_ex [OF lub ub_imageI])
   328      apply (rule is_ub_thelub_ex [OF lub imageI])
   329      apply (erule (1) subsetD [OF rep_mono])
   330     apply (rule is_lub_thelub_ex [OF lub ub_imageI])
   331     apply (simp add: rep_lub, clarify)
   332     apply (erule rev_below_trans [OF is_ub_thelub])
   333     apply (erule is_ub_thelub_ex [OF lub imageI])
   334     done
   335 qed
   336 
   337 lemma extension_principal:
   338   fixes f :: "'a::type \<Rightarrow> 'c::cpo"
   339   assumes f_mono: "\<And>a b. a \<preceq> b \<Longrightarrow> f a \<sqsubseteq> f b"
   340   shows "extension f\<cdot>(principal a) = f a"
   341 apply (subst extension_beta, erule f_mono)
   342 apply (subst rep_principal)
   343 apply (rule lub_eqI)
   344 apply (rule is_lub_maximal)
   345 apply (rule ub_imageI)
   346 apply (simp add: f_mono)
   347 apply (rule imageI)
   348 apply (simp add: r_refl)
   349 done
   350 
   351 lemma extension_mono:
   352   assumes f_mono: "\<And>a b. a \<preceq> b \<Longrightarrow> f a \<sqsubseteq> f b"
   353   assumes g_mono: "\<And>a b. a \<preceq> b \<Longrightarrow> g a \<sqsubseteq> g b"
   354   assumes below: "\<And>a. f a \<sqsubseteq> g a"
   355   shows "extension f \<sqsubseteq> extension g"
   356  apply (rule cfun_belowI)
   357  apply (simp only: extension_beta f_mono g_mono)
   358  apply (rule is_lub_thelub_ex)
   359   apply (rule extension_lemma, erule f_mono)
   360  apply (rule ub_imageI, rename_tac a)
   361  apply (rule below_trans [OF below])
   362  apply (rule is_ub_thelub_ex)
   363   apply (rule extension_lemma, erule g_mono)
   364  apply (erule imageI)
   365 done
   366 
   367 lemma cont_extension:
   368   assumes f_mono: "\<And>a b x. a \<preceq> b \<Longrightarrow> f x a \<sqsubseteq> f x b"
   369   assumes f_cont: "\<And>a. cont (\<lambda>x. f x a)"
   370   shows "cont (\<lambda>x. extension (\<lambda>a. f x a))"
   371  apply (rule contI2)
   372   apply (rule monofunI)
   373   apply (rule extension_mono, erule f_mono, erule f_mono)
   374   apply (erule cont2monofunE [OF f_cont])
   375  apply (rule cfun_belowI)
   376  apply (rule principal_induct, simp)
   377  apply (simp only: contlub_cfun_fun)
   378  apply (simp only: extension_principal f_mono)
   379  apply (simp add: cont2contlubE [OF f_cont])
   380 done
   381 
   382 end
   383 
   384 lemma (in preorder) typedef_ideal_completion:
   385   fixes Abs :: "'a set \<Rightarrow> 'b::cpo"
   386   assumes type: "type_definition Rep Abs {S. ideal S}"
   387   assumes below: "\<And>x y. x \<sqsubseteq> y \<longleftrightarrow> Rep x \<subseteq> Rep y"
   388   assumes principal: "\<And>a. principal a = Abs {b. b \<preceq> a}"
   389   assumes countable: "\<exists>f::'a \<Rightarrow> nat. inj f"
   390   shows "ideal_completion r principal Rep"
   391 proof
   392   interpret type_definition Rep Abs "{S. ideal S}" by fact
   393   fix a b :: 'a and x y :: 'b and Y :: "nat \<Rightarrow> 'b"
   394   show "ideal (Rep x)"
   395     using Rep [of x] by simp
   396   show "chain Y \<Longrightarrow> Rep (\<Squnion>i. Y i) = (\<Union>i. Rep (Y i))"
   397     using type below by (rule typedef_ideal_rep_lub)
   398   show "Rep (principal a) = {b. b \<preceq> a}"
   399     by (simp add: principal Abs_inverse ideal_principal)
   400   show "Rep x \<subseteq> Rep y \<Longrightarrow> x \<sqsubseteq> y"
   401     by (simp only: below)
   402   show "\<exists>f::'a \<Rightarrow> nat. inj f"
   403     by (rule countable)
   404 qed
   405 
   406 end