src/HOL/Int.thy
author blanchet
Tue Nov 07 15:16:42 2017 +0100 (19 months ago)
changeset 67022 49309fe530fd
parent 66912 a99a7cbf0fb5
child 67116 7397a6df81d8
permissions -rw-r--r--
more robust parsing for THF proofs (esp. polymorphic Leo-III proofs)
     1 (*  Title:      HOL/Int.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Tobias Nipkow, Florian Haftmann, TU Muenchen
     4 *)
     5 
     6 section \<open>The Integers as Equivalence Classes over Pairs of Natural Numbers\<close>
     7 
     8 theory Int
     9   imports Equiv_Relations Power Quotient Fun_Def
    10 begin
    11 
    12 subsection \<open>Definition of integers as a quotient type\<close>
    13 
    14 definition intrel :: "(nat \<times> nat) \<Rightarrow> (nat \<times> nat) \<Rightarrow> bool"
    15   where "intrel = (\<lambda>(x, y) (u, v). x + v = u + y)"
    16 
    17 lemma intrel_iff [simp]: "intrel (x, y) (u, v) \<longleftrightarrow> x + v = u + y"
    18   by (simp add: intrel_def)
    19 
    20 quotient_type int = "nat \<times> nat" / "intrel"
    21   morphisms Rep_Integ Abs_Integ
    22 proof (rule equivpI)
    23   show "reflp intrel" by (auto simp: reflp_def)
    24   show "symp intrel" by (auto simp: symp_def)
    25   show "transp intrel" by (auto simp: transp_def)
    26 qed
    27 
    28 lemma eq_Abs_Integ [case_names Abs_Integ, cases type: int]:
    29   "(\<And>x y. z = Abs_Integ (x, y) \<Longrightarrow> P) \<Longrightarrow> P"
    30   by (induct z) auto
    31 
    32 
    33 subsection \<open>Integers form a commutative ring\<close>
    34 
    35 instantiation int :: comm_ring_1
    36 begin
    37 
    38 lift_definition zero_int :: "int" is "(0, 0)" .
    39 
    40 lift_definition one_int :: "int" is "(1, 0)" .
    41 
    42 lift_definition plus_int :: "int \<Rightarrow> int \<Rightarrow> int"
    43   is "\<lambda>(x, y) (u, v). (x + u, y + v)"
    44   by clarsimp
    45 
    46 lift_definition uminus_int :: "int \<Rightarrow> int"
    47   is "\<lambda>(x, y). (y, x)"
    48   by clarsimp
    49 
    50 lift_definition minus_int :: "int \<Rightarrow> int \<Rightarrow> int"
    51   is "\<lambda>(x, y) (u, v). (x + v, y + u)"
    52   by clarsimp
    53 
    54 lift_definition times_int :: "int \<Rightarrow> int \<Rightarrow> int"
    55   is "\<lambda>(x, y) (u, v). (x*u + y*v, x*v + y*u)"
    56 proof (clarsimp)
    57   fix s t u v w x y z :: nat
    58   assume "s + v = u + t" and "w + z = y + x"
    59   then have "(s + v) * w + (u + t) * x + u * (w + z) + v * (y + x) =
    60     (u + t) * w + (s + v) * x + u * (y + x) + v * (w + z)"
    61     by simp
    62   then show "(s * w + t * x) + (u * z + v * y) = (u * y + v * z) + (s * x + t * w)"
    63     by (simp add: algebra_simps)
    64 qed
    65 
    66 instance
    67   by standard (transfer; clarsimp simp: algebra_simps)+
    68 
    69 end
    70 
    71 abbreviation int :: "nat \<Rightarrow> int"
    72   where "int \<equiv> of_nat"
    73 
    74 lemma int_def: "int n = Abs_Integ (n, 0)"
    75   by (induct n) (simp add: zero_int.abs_eq, simp add: one_int.abs_eq plus_int.abs_eq)
    76 
    77 lemma int_transfer [transfer_rule]: "(rel_fun (op =) pcr_int) (\<lambda>n. (n, 0)) int"
    78   by (simp add: rel_fun_def int.pcr_cr_eq cr_int_def int_def)
    79 
    80 lemma int_diff_cases: obtains (diff) m n where "z = int m - int n"
    81   by transfer clarsimp
    82 
    83 
    84 subsection \<open>Integers are totally ordered\<close>
    85 
    86 instantiation int :: linorder
    87 begin
    88 
    89 lift_definition less_eq_int :: "int \<Rightarrow> int \<Rightarrow> bool"
    90   is "\<lambda>(x, y) (u, v). x + v \<le> u + y"
    91   by auto
    92 
    93 lift_definition less_int :: "int \<Rightarrow> int \<Rightarrow> bool"
    94   is "\<lambda>(x, y) (u, v). x + v < u + y"
    95   by auto
    96 
    97 instance
    98   by standard (transfer, force)+
    99 
   100 end
   101 
   102 instantiation int :: distrib_lattice
   103 begin
   104 
   105 definition "(inf :: int \<Rightarrow> int \<Rightarrow> int) = min"
   106 
   107 definition "(sup :: int \<Rightarrow> int \<Rightarrow> int) = max"
   108 
   109 instance
   110   by standard (auto simp add: inf_int_def sup_int_def max_min_distrib2)
   111 
   112 end
   113 
   114 
   115 subsection \<open>Ordering properties of arithmetic operations\<close>
   116 
   117 instance int :: ordered_cancel_ab_semigroup_add
   118 proof
   119   fix i j k :: int
   120   show "i \<le> j \<Longrightarrow> k + i \<le> k + j"
   121     by transfer clarsimp
   122 qed
   123 
   124 text \<open>Strict Monotonicity of Multiplication.\<close>
   125 
   126 text \<open>Strict, in 1st argument; proof is by induction on \<open>k > 0\<close>.\<close>
   127 lemma zmult_zless_mono2_lemma: "i < j \<Longrightarrow> 0 < k \<Longrightarrow> int k * i < int k * j"
   128   for i j :: int
   129 proof (induct k)
   130   case 0
   131   then show ?case by simp
   132 next
   133   case (Suc k)
   134   then show ?case
   135     by (cases "k = 0") (simp_all add: distrib_right add_strict_mono)
   136 qed
   137 
   138 lemma zero_le_imp_eq_int: "0 \<le> k \<Longrightarrow> \<exists>n. k = int n"
   139   for k :: int
   140   apply transfer
   141   apply clarsimp
   142   apply (rule_tac x="a - b" in exI)
   143   apply simp
   144   done
   145 
   146 lemma zero_less_imp_eq_int: "0 < k \<Longrightarrow> \<exists>n>0. k = int n"
   147   for k :: int
   148   apply transfer
   149   apply clarsimp
   150   apply (rule_tac x="a - b" in exI)
   151   apply simp
   152   done
   153 
   154 lemma zmult_zless_mono2: "i < j \<Longrightarrow> 0 < k \<Longrightarrow> k * i < k * j"
   155   for i j k :: int
   156   by (drule zero_less_imp_eq_int) (auto simp add: zmult_zless_mono2_lemma)
   157 
   158 
   159 text \<open>The integers form an ordered integral domain.\<close>
   160 
   161 instantiation int :: linordered_idom
   162 begin
   163 
   164 definition zabs_def: "\<bar>i::int\<bar> = (if i < 0 then - i else i)"
   165 
   166 definition zsgn_def: "sgn (i::int) = (if i = 0 then 0 else if 0 < i then 1 else - 1)"
   167 
   168 instance
   169 proof
   170   fix i j k :: int
   171   show "i < j \<Longrightarrow> 0 < k \<Longrightarrow> k * i < k * j"
   172     by (rule zmult_zless_mono2)
   173   show "\<bar>i\<bar> = (if i < 0 then -i else i)"
   174     by (simp only: zabs_def)
   175   show "sgn (i::int) = (if i=0 then 0 else if 0<i then 1 else - 1)"
   176     by (simp only: zsgn_def)
   177 qed
   178 
   179 end
   180 
   181 lemma zless_imp_add1_zle: "w < z \<Longrightarrow> w + 1 \<le> z"
   182   for w z :: int
   183   by transfer clarsimp
   184 
   185 lemma zless_iff_Suc_zadd: "w < z \<longleftrightarrow> (\<exists>n. z = w + int (Suc n))"
   186   for w z :: int
   187   apply transfer
   188   apply auto
   189   apply (rename_tac a b c d)
   190   apply (rule_tac x="c+b - Suc(a+d)" in exI)
   191   apply arith
   192   done
   193 
   194 lemma zabs_less_one_iff [simp]: "\<bar>z\<bar> < 1 \<longleftrightarrow> z = 0" (is "?lhs \<longleftrightarrow> ?rhs")
   195   for z :: int
   196 proof
   197   assume ?rhs
   198   then show ?lhs by simp
   199 next
   200   assume ?lhs
   201   with zless_imp_add1_zle [of "\<bar>z\<bar>" 1] have "\<bar>z\<bar> + 1 \<le> 1" by simp
   202   then have "\<bar>z\<bar> \<le> 0" by simp
   203   then show ?rhs by simp
   204 qed
   205 
   206 lemmas int_distrib =
   207   distrib_right [of z1 z2 w]
   208   distrib_left [of w z1 z2]
   209   left_diff_distrib [of z1 z2 w]
   210   right_diff_distrib [of w z1 z2]
   211   for z1 z2 w :: int
   212 
   213 
   214 subsection \<open>Embedding of the Integers into any \<open>ring_1\<close>: \<open>of_int\<close>\<close>
   215 
   216 context ring_1
   217 begin
   218 
   219 lift_definition of_int :: "int \<Rightarrow> 'a"
   220   is "\<lambda>(i, j). of_nat i - of_nat j"
   221   by (clarsimp simp add: diff_eq_eq eq_diff_eq diff_add_eq
   222       of_nat_add [symmetric] simp del: of_nat_add)
   223 
   224 lemma of_int_0 [simp]: "of_int 0 = 0"
   225   by transfer simp
   226 
   227 lemma of_int_1 [simp]: "of_int 1 = 1"
   228   by transfer simp
   229 
   230 lemma of_int_add [simp]: "of_int (w + z) = of_int w + of_int z"
   231   by transfer (clarsimp simp add: algebra_simps)
   232 
   233 lemma of_int_minus [simp]: "of_int (- z) = - (of_int z)"
   234   by (transfer fixing: uminus) clarsimp
   235 
   236 lemma of_int_diff [simp]: "of_int (w - z) = of_int w - of_int z"
   237   using of_int_add [of w "- z"] by simp
   238 
   239 lemma of_int_mult [simp]: "of_int (w*z) = of_int w * of_int z"
   240   by (transfer fixing: times) (clarsimp simp add: algebra_simps)
   241 
   242 lemma mult_of_int_commute: "of_int x * y = y * of_int x"
   243   by (transfer fixing: times) (auto simp: algebra_simps mult_of_nat_commute)
   244 
   245 text \<open>Collapse nested embeddings.\<close>
   246 lemma of_int_of_nat_eq [simp]: "of_int (int n) = of_nat n"
   247   by (induct n) auto
   248 
   249 lemma of_int_numeral [simp, code_post]: "of_int (numeral k) = numeral k"
   250   by (simp add: of_nat_numeral [symmetric] of_int_of_nat_eq [symmetric])
   251 
   252 lemma of_int_neg_numeral [code_post]: "of_int (- numeral k) = - numeral k"
   253   by simp
   254 
   255 lemma of_int_power [simp]: "of_int (z ^ n) = of_int z ^ n"
   256   by (induct n) simp_all
   257 
   258 lemma of_int_of_bool [simp]:
   259   "of_int (of_bool P) = of_bool P"
   260   by auto
   261 
   262 end
   263 
   264 context ring_char_0
   265 begin
   266 
   267 lemma of_int_eq_iff [simp]: "of_int w = of_int z \<longleftrightarrow> w = z"
   268   by transfer (clarsimp simp add: algebra_simps of_nat_add [symmetric] simp del: of_nat_add)
   269 
   270 text \<open>Special cases where either operand is zero.\<close>
   271 lemma of_int_eq_0_iff [simp]: "of_int z = 0 \<longleftrightarrow> z = 0"
   272   using of_int_eq_iff [of z 0] by simp
   273 
   274 lemma of_int_0_eq_iff [simp]: "0 = of_int z \<longleftrightarrow> z = 0"
   275   using of_int_eq_iff [of 0 z] by simp
   276 
   277 lemma of_int_eq_1_iff [iff]: "of_int z = 1 \<longleftrightarrow> z = 1"
   278   using of_int_eq_iff [of z 1] by simp
   279 
   280 lemma numeral_power_eq_of_int_cancel_iff [simp]:
   281   "numeral x ^ n = of_int y \<longleftrightarrow> numeral x ^ n = y"
   282   using of_int_eq_iff[of "numeral x ^ n" y, unfolded of_int_numeral of_int_power] .
   283 
   284 lemma of_int_eq_numeral_power_cancel_iff [simp]:
   285   "of_int y = numeral x ^ n \<longleftrightarrow> y = numeral x ^ n"
   286   using numeral_power_eq_of_int_cancel_iff [of x n y] by (metis (mono_tags))
   287 
   288 lemma neg_numeral_power_eq_of_int_cancel_iff [simp]:
   289   "(- numeral x) ^ n = of_int y \<longleftrightarrow> (- numeral x) ^ n = y"
   290   using of_int_eq_iff[of "(- numeral x) ^ n" y]
   291   by simp
   292 
   293 lemma of_int_eq_neg_numeral_power_cancel_iff [simp]:
   294   "of_int y = (- numeral x) ^ n \<longleftrightarrow> y = (- numeral x) ^ n"
   295   using neg_numeral_power_eq_of_int_cancel_iff[of x n y] by (metis (mono_tags))
   296 
   297 lemma of_int_eq_of_int_power_cancel_iff[simp]: "(of_int b) ^ w = of_int x \<longleftrightarrow> b ^ w = x"
   298   by (metis of_int_power of_int_eq_iff)
   299 
   300 lemma of_int_power_eq_of_int_cancel_iff[simp]: "of_int x = (of_int b) ^ w \<longleftrightarrow> x = b ^ w"
   301   by (metis of_int_eq_of_int_power_cancel_iff)
   302 
   303 end
   304 
   305 context linordered_idom
   306 begin
   307 
   308 text \<open>Every \<open>linordered_idom\<close> has characteristic zero.\<close>
   309 subclass ring_char_0 ..
   310 
   311 lemma of_int_le_iff [simp]: "of_int w \<le> of_int z \<longleftrightarrow> w \<le> z"
   312   by (transfer fixing: less_eq)
   313     (clarsimp simp add: algebra_simps of_nat_add [symmetric] simp del: of_nat_add)
   314 
   315 lemma of_int_less_iff [simp]: "of_int w < of_int z \<longleftrightarrow> w < z"
   316   by (simp add: less_le order_less_le)
   317 
   318 lemma of_int_0_le_iff [simp]: "0 \<le> of_int z \<longleftrightarrow> 0 \<le> z"
   319   using of_int_le_iff [of 0 z] by simp
   320 
   321 lemma of_int_le_0_iff [simp]: "of_int z \<le> 0 \<longleftrightarrow> z \<le> 0"
   322   using of_int_le_iff [of z 0] by simp
   323 
   324 lemma of_int_0_less_iff [simp]: "0 < of_int z \<longleftrightarrow> 0 < z"
   325   using of_int_less_iff [of 0 z] by simp
   326 
   327 lemma of_int_less_0_iff [simp]: "of_int z < 0 \<longleftrightarrow> z < 0"
   328   using of_int_less_iff [of z 0] by simp
   329 
   330 lemma of_int_1_le_iff [simp]: "1 \<le> of_int z \<longleftrightarrow> 1 \<le> z"
   331   using of_int_le_iff [of 1 z] by simp
   332 
   333 lemma of_int_le_1_iff [simp]: "of_int z \<le> 1 \<longleftrightarrow> z \<le> 1"
   334   using of_int_le_iff [of z 1] by simp
   335 
   336 lemma of_int_1_less_iff [simp]: "1 < of_int z \<longleftrightarrow> 1 < z"
   337   using of_int_less_iff [of 1 z] by simp
   338 
   339 lemma of_int_less_1_iff [simp]: "of_int z < 1 \<longleftrightarrow> z < 1"
   340   using of_int_less_iff [of z 1] by simp
   341 
   342 lemma of_int_pos: "z > 0 \<Longrightarrow> of_int z > 0"
   343   by simp
   344 
   345 lemma of_int_nonneg: "z \<ge> 0 \<Longrightarrow> of_int z \<ge> 0"
   346   by simp
   347 
   348 lemma of_int_abs [simp]: "of_int \<bar>x\<bar> = \<bar>of_int x\<bar>"
   349   by (auto simp add: abs_if)
   350 
   351 lemma of_int_lessD:
   352   assumes "\<bar>of_int n\<bar> < x"
   353   shows "n = 0 \<or> x > 1"
   354 proof (cases "n = 0")
   355   case True
   356   then show ?thesis by simp
   357 next
   358   case False
   359   then have "\<bar>n\<bar> \<noteq> 0" by simp
   360   then have "\<bar>n\<bar> > 0" by simp
   361   then have "\<bar>n\<bar> \<ge> 1"
   362     using zless_imp_add1_zle [of 0 "\<bar>n\<bar>"] by simp
   363   then have "\<bar>of_int n\<bar> \<ge> 1"
   364     unfolding of_int_1_le_iff [of "\<bar>n\<bar>", symmetric] by simp
   365   then have "1 < x" using assms by (rule le_less_trans)
   366   then show ?thesis ..
   367 qed
   368 
   369 lemma of_int_leD:
   370   assumes "\<bar>of_int n\<bar> \<le> x"
   371   shows "n = 0 \<or> 1 \<le> x"
   372 proof (cases "n = 0")
   373   case True
   374   then show ?thesis by simp
   375 next
   376   case False
   377   then have "\<bar>n\<bar> \<noteq> 0" by simp
   378   then have "\<bar>n\<bar> > 0" by simp
   379   then have "\<bar>n\<bar> \<ge> 1"
   380     using zless_imp_add1_zle [of 0 "\<bar>n\<bar>"] by simp
   381   then have "\<bar>of_int n\<bar> \<ge> 1"
   382     unfolding of_int_1_le_iff [of "\<bar>n\<bar>", symmetric] by simp
   383   then have "1 \<le> x" using assms by (rule order_trans)
   384   then show ?thesis ..
   385 qed
   386 
   387 lemma numeral_power_le_of_int_cancel_iff [simp]:
   388   "numeral x ^ n \<le> of_int a \<longleftrightarrow> numeral x ^ n \<le> a"
   389   by (metis (mono_tags) local.of_int_eq_numeral_power_cancel_iff of_int_le_iff)
   390 
   391 lemma of_int_le_numeral_power_cancel_iff [simp]:
   392   "of_int a \<le> numeral x ^ n \<longleftrightarrow> a \<le> numeral x ^ n"
   393   by (metis (mono_tags) local.numeral_power_eq_of_int_cancel_iff of_int_le_iff)
   394 
   395 lemma numeral_power_less_of_int_cancel_iff [simp]:
   396   "numeral x ^ n < of_int a \<longleftrightarrow> numeral x ^ n < a"
   397   by (metis (mono_tags) local.of_int_eq_numeral_power_cancel_iff of_int_less_iff)
   398 
   399 lemma of_int_less_numeral_power_cancel_iff [simp]:
   400   "of_int a < numeral x ^ n \<longleftrightarrow> a < numeral x ^ n"
   401   by (metis (mono_tags) local.of_int_eq_numeral_power_cancel_iff of_int_less_iff)
   402 
   403 lemma neg_numeral_power_le_of_int_cancel_iff [simp]:
   404   "(- numeral x) ^ n \<le> of_int a \<longleftrightarrow> (- numeral x) ^ n \<le> a"
   405   by (metis (mono_tags) of_int_le_iff of_int_neg_numeral of_int_power)
   406 
   407 lemma of_int_le_neg_numeral_power_cancel_iff [simp]:
   408   "of_int a \<le> (- numeral x) ^ n \<longleftrightarrow> a \<le> (- numeral x) ^ n"
   409   by (metis (mono_tags) of_int_le_iff of_int_neg_numeral of_int_power)
   410 
   411 lemma neg_numeral_power_less_of_int_cancel_iff [simp]:
   412   "(- numeral x) ^ n < of_int a \<longleftrightarrow> (- numeral x) ^ n < a"
   413   using of_int_less_iff[of "(- numeral x) ^ n" a]
   414   by simp
   415 
   416 lemma of_int_less_neg_numeral_power_cancel_iff [simp]:
   417   "of_int a < (- numeral x) ^ n \<longleftrightarrow> a < (- numeral x::int) ^ n"
   418   using of_int_less_iff[of a "(- numeral x) ^ n"]
   419   by simp
   420 
   421 lemma of_int_le_of_int_power_cancel_iff[simp]: "(of_int b) ^ w \<le> of_int x \<longleftrightarrow> b ^ w \<le> x"
   422   by (metis (mono_tags) of_int_le_iff of_int_power)
   423 
   424 lemma of_int_power_le_of_int_cancel_iff[simp]: "of_int x \<le> (of_int b) ^ w\<longleftrightarrow> x \<le> b ^ w"
   425   by (metis (mono_tags) of_int_le_iff of_int_power)
   426 
   427 lemma of_int_less_of_int_power_cancel_iff[simp]: "(of_int b) ^ w < of_int x \<longleftrightarrow> b ^ w < x"
   428   by (metis (mono_tags) of_int_less_iff of_int_power)
   429 
   430 lemma of_int_power_less_of_int_cancel_iff[simp]: "of_int x < (of_int b) ^ w\<longleftrightarrow> x < b ^ w"
   431   by (metis (mono_tags) of_int_less_iff of_int_power)
   432 
   433 end
   434 
   435 text \<open>Comparisons involving @{term of_int}.\<close>
   436 
   437 lemma of_int_eq_numeral_iff [iff]: "of_int z = (numeral n :: 'a::ring_char_0) \<longleftrightarrow> z = numeral n"
   438   using of_int_eq_iff by fastforce
   439 
   440 lemma of_int_le_numeral_iff [simp]:
   441   "of_int z \<le> (numeral n :: 'a::linordered_idom) \<longleftrightarrow> z \<le> numeral n"
   442   using of_int_le_iff [of z "numeral n"] by simp
   443 
   444 lemma of_int_numeral_le_iff [simp]:
   445   "(numeral n :: 'a::linordered_idom) \<le> of_int z \<longleftrightarrow> numeral n \<le> z"
   446   using of_int_le_iff [of "numeral n"] by simp
   447 
   448 lemma of_int_less_numeral_iff [simp]:
   449   "of_int z < (numeral n :: 'a::linordered_idom) \<longleftrightarrow> z < numeral n"
   450   using of_int_less_iff [of z "numeral n"] by simp
   451 
   452 lemma of_int_numeral_less_iff [simp]:
   453   "(numeral n :: 'a::linordered_idom) < of_int z \<longleftrightarrow> numeral n < z"
   454   using of_int_less_iff [of "numeral n" z] by simp
   455 
   456 lemma of_nat_less_of_int_iff: "(of_nat n::'a::linordered_idom) < of_int x \<longleftrightarrow> int n < x"
   457   by (metis of_int_of_nat_eq of_int_less_iff)
   458 
   459 lemma of_int_eq_id [simp]: "of_int = id"
   460 proof
   461   show "of_int z = id z" for z
   462     by (cases z rule: int_diff_cases) simp
   463 qed
   464 
   465 instance int :: no_top
   466   apply standard
   467   apply (rule_tac x="x + 1" in exI)
   468   apply simp
   469   done
   470 
   471 instance int :: no_bot
   472   apply standard
   473   apply (rule_tac x="x - 1" in exI)
   474   apply simp
   475   done
   476 
   477 
   478 subsection \<open>Magnitude of an Integer, as a Natural Number: \<open>nat\<close>\<close>
   479 
   480 lift_definition nat :: "int \<Rightarrow> nat" is "\<lambda>(x, y). x - y"
   481   by auto
   482 
   483 lemma nat_int [simp]: "nat (int n) = n"
   484   by transfer simp
   485 
   486 lemma int_nat_eq [simp]: "int (nat z) = (if 0 \<le> z then z else 0)"
   487   by transfer clarsimp
   488 
   489 lemma nat_0_le: "0 \<le> z \<Longrightarrow> int (nat z) = z"
   490   by simp
   491 
   492 lemma nat_le_0 [simp]: "z \<le> 0 \<Longrightarrow> nat z = 0"
   493   by transfer clarsimp
   494 
   495 lemma nat_le_eq_zle: "0 < w \<or> 0 \<le> z \<Longrightarrow> nat w \<le> nat z \<longleftrightarrow> w \<le> z"
   496   by transfer (clarsimp, arith)
   497 
   498 text \<open>An alternative condition is @{term "0 \<le> w"}.\<close>
   499 lemma nat_mono_iff: "0 < z \<Longrightarrow> nat w < nat z \<longleftrightarrow> w < z"
   500   by (simp add: nat_le_eq_zle linorder_not_le [symmetric])
   501 
   502 lemma nat_less_eq_zless: "0 \<le> w \<Longrightarrow> nat w < nat z \<longleftrightarrow> w < z"
   503   by (simp add: nat_le_eq_zle linorder_not_le [symmetric])
   504 
   505 lemma zless_nat_conj [simp]: "nat w < nat z \<longleftrightarrow> 0 < z \<and> w < z"
   506   by transfer (clarsimp, arith)
   507 
   508 lemma nonneg_int_cases:
   509   assumes "0 \<le> k"
   510   obtains n where "k = int n"
   511 proof -
   512   from assms have "k = int (nat k)"
   513     by simp
   514   then show thesis
   515     by (rule that)
   516 qed
   517 
   518 lemma pos_int_cases:
   519   assumes "0 < k"
   520   obtains n where "k = int n" and "n > 0"
   521 proof -
   522   from assms have "0 \<le> k"
   523     by simp
   524   then obtain n where "k = int n"
   525     by (rule nonneg_int_cases)
   526   moreover have "n > 0"
   527     using \<open>k = int n\<close> assms by simp
   528   ultimately show thesis
   529     by (rule that)
   530 qed
   531 
   532 lemma nonpos_int_cases:
   533   assumes "k \<le> 0"
   534   obtains n where "k = - int n"
   535 proof -
   536   from assms have "- k \<ge> 0"
   537     by simp
   538   then obtain n where "- k = int n"
   539     by (rule nonneg_int_cases)
   540   then have "k = - int n"
   541     by simp
   542   then show thesis
   543     by (rule that)
   544 qed
   545 
   546 lemma neg_int_cases:
   547   assumes "k < 0"
   548   obtains n where "k = - int n" and "n > 0"
   549 proof -
   550   from assms have "- k > 0"
   551     by simp
   552   then obtain n where "- k = int n" and "- k > 0"
   553     by (blast elim: pos_int_cases)
   554   then have "k = - int n" and "n > 0"
   555     by simp_all
   556   then show thesis
   557     by (rule that)
   558 qed
   559 
   560 lemma nat_eq_iff: "nat w = m \<longleftrightarrow> (if 0 \<le> w then w = int m else m = 0)"
   561   by transfer (clarsimp simp add: le_imp_diff_is_add)
   562 
   563 lemma nat_eq_iff2: "m = nat w \<longleftrightarrow> (if 0 \<le> w then w = int m else m = 0)"
   564   using nat_eq_iff [of w m] by auto
   565 
   566 lemma nat_0 [simp]: "nat 0 = 0"
   567   by (simp add: nat_eq_iff)
   568 
   569 lemma nat_1 [simp]: "nat 1 = Suc 0"
   570   by (simp add: nat_eq_iff)
   571 
   572 lemma nat_numeral [simp]: "nat (numeral k) = numeral k"
   573   by (simp add: nat_eq_iff)
   574 
   575 lemma nat_neg_numeral [simp]: "nat (- numeral k) = 0"
   576   by simp
   577 
   578 lemma nat_2: "nat 2 = Suc (Suc 0)"
   579   by simp
   580 
   581 lemma nat_less_iff: "0 \<le> w \<Longrightarrow> nat w < m \<longleftrightarrow> w < of_nat m"
   582   by transfer (clarsimp, arith)
   583 
   584 lemma nat_le_iff: "nat x \<le> n \<longleftrightarrow> x \<le> int n"
   585   by transfer (clarsimp simp add: le_diff_conv)
   586 
   587 lemma nat_mono: "x \<le> y \<Longrightarrow> nat x \<le> nat y"
   588   by transfer auto
   589 
   590 lemma nat_0_iff[simp]: "nat i = 0 \<longleftrightarrow> i \<le> 0"
   591   for i :: int
   592   by transfer clarsimp
   593 
   594 lemma int_eq_iff: "of_nat m = z \<longleftrightarrow> m = nat z \<and> 0 \<le> z"
   595   by (auto simp add: nat_eq_iff2)
   596 
   597 lemma zero_less_nat_eq [simp]: "0 < nat z \<longleftrightarrow> 0 < z"
   598   using zless_nat_conj [of 0] by auto
   599 
   600 lemma nat_add_distrib: "0 \<le> z \<Longrightarrow> 0 \<le> z' \<Longrightarrow> nat (z + z') = nat z + nat z'"
   601   by transfer clarsimp
   602 
   603 lemma nat_diff_distrib': "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> nat (x - y) = nat x - nat y"
   604   by transfer clarsimp
   605 
   606 lemma nat_diff_distrib: "0 \<le> z' \<Longrightarrow> z' \<le> z \<Longrightarrow> nat (z - z') = nat z - nat z'"
   607   by (rule nat_diff_distrib') auto
   608 
   609 lemma nat_zminus_int [simp]: "nat (- int n) = 0"
   610   by transfer simp
   611 
   612 lemma le_nat_iff: "k \<ge> 0 \<Longrightarrow> n \<le> nat k \<longleftrightarrow> int n \<le> k"
   613   by transfer auto
   614 
   615 lemma zless_nat_eq_int_zless: "m < nat z \<longleftrightarrow> int m < z"
   616   by transfer (clarsimp simp add: less_diff_conv)
   617 
   618 lemma (in ring_1) of_nat_nat [simp]: "0 \<le> z \<Longrightarrow> of_nat (nat z) = of_int z"
   619   by transfer (clarsimp simp add: of_nat_diff)
   620 
   621 lemma diff_nat_numeral [simp]: "(numeral v :: nat) - numeral v' = nat (numeral v - numeral v')"
   622   by (simp only: nat_diff_distrib' zero_le_numeral nat_numeral)
   623 
   624 lemma nat_abs_triangle_ineq:
   625   "nat \<bar>k + l\<bar> \<le> nat \<bar>k\<bar> + nat \<bar>l\<bar>"
   626   by (simp add: nat_add_distrib [symmetric] nat_le_eq_zle abs_triangle_ineq)
   627 
   628 lemma nat_of_bool [simp]:
   629   "nat (of_bool P) = of_bool P"
   630   by auto
   631 
   632 lemma split_nat [arith_split]: "P (nat i) \<longleftrightarrow> ((\<forall>n. i = int n \<longrightarrow> P n) \<and> (i < 0 \<longrightarrow> P 0))"
   633   (is "?P = (?L \<and> ?R)")
   634   for i :: int
   635 proof (cases "i < 0")
   636   case True
   637   then show ?thesis
   638     by auto
   639 next
   640   case False
   641   have "?P = ?L"
   642   proof
   643     assume ?P
   644     then show ?L using False by auto
   645   next
   646     assume ?L
   647     moreover from False have "int (nat i) = i"
   648       by (simp add: not_less)
   649     ultimately show ?P
   650       by simp
   651   qed
   652   with False show ?thesis by simp
   653 qed
   654 
   655 lemma all_nat: "(\<forall>x. P x) \<longleftrightarrow> (\<forall>x\<ge>0. P (nat x))"
   656   by (auto split: split_nat)
   657 
   658 lemma ex_nat: "(\<exists>x. P x) \<longleftrightarrow> (\<exists>x. 0 \<le> x \<and> P (nat x))"
   659 proof
   660   assume "\<exists>x. P x"
   661   then obtain x where "P x" ..
   662   then have "int x \<ge> 0 \<and> P (nat (int x))" by simp
   663   then show "\<exists>x\<ge>0. P (nat x)" ..
   664 next
   665   assume "\<exists>x\<ge>0. P (nat x)"
   666   then show "\<exists>x. P x" by auto
   667 qed
   668 
   669 
   670 text \<open>For termination proofs:\<close>
   671 lemma measure_function_int[measure_function]: "is_measure (nat \<circ> abs)" ..
   672 
   673 
   674 subsection \<open>Lemmas about the Function @{term of_nat} and Orderings\<close>
   675 
   676 lemma negative_zless_0: "- (int (Suc n)) < (0 :: int)"
   677   by (simp add: order_less_le del: of_nat_Suc)
   678 
   679 lemma negative_zless [iff]: "- (int (Suc n)) < int m"
   680   by (rule negative_zless_0 [THEN order_less_le_trans], simp)
   681 
   682 lemma negative_zle_0: "- int n \<le> 0"
   683   by (simp add: minus_le_iff)
   684 
   685 lemma negative_zle [iff]: "- int n \<le> int m"
   686   by (rule order_trans [OF negative_zle_0 of_nat_0_le_iff])
   687 
   688 lemma not_zle_0_negative [simp]: "\<not> 0 \<le> - int (Suc n)"
   689   by (subst le_minus_iff) (simp del: of_nat_Suc)
   690 
   691 lemma int_zle_neg: "int n \<le> - int m \<longleftrightarrow> n = 0 \<and> m = 0"
   692   by transfer simp
   693 
   694 lemma not_int_zless_negative [simp]: "\<not> int n < - int m"
   695   by (simp add: linorder_not_less)
   696 
   697 lemma negative_eq_positive [simp]: "- int n = of_nat m \<longleftrightarrow> n = 0 \<and> m = 0"
   698   by (force simp add: order_eq_iff [of "- of_nat n"] int_zle_neg)
   699 
   700 lemma zle_iff_zadd: "w \<le> z \<longleftrightarrow> (\<exists>n. z = w + int n)"
   701   (is "?lhs \<longleftrightarrow> ?rhs")
   702 proof
   703   assume ?rhs
   704   then show ?lhs by auto
   705 next
   706   assume ?lhs
   707   then have "0 \<le> z - w" by simp
   708   then obtain n where "z - w = int n"
   709     using zero_le_imp_eq_int [of "z - w"] by blast
   710   then have "z = w + int n" by simp
   711   then show ?rhs ..
   712 qed
   713 
   714 lemma zadd_int_left: "int m + (int n + z) = int (m + n) + z"
   715   by simp
   716 
   717 text \<open>
   718   This version is proved for all ordered rings, not just integers!
   719   It is proved here because attribute \<open>arith_split\<close> is not available
   720   in theory \<open>Rings\<close>.
   721   But is it really better than just rewriting with \<open>abs_if\<close>?
   722 \<close>
   723 lemma abs_split [arith_split, no_atp]: "P \<bar>a\<bar> \<longleftrightarrow> (0 \<le> a \<longrightarrow> P a) \<and> (a < 0 \<longrightarrow> P (- a))"
   724   for a :: "'a::linordered_idom"
   725   by (force dest: order_less_le_trans simp add: abs_if linorder_not_less)
   726 
   727 lemma negD: "x < 0 \<Longrightarrow> \<exists>n. x = - (int (Suc n))"
   728   apply transfer
   729   apply clarsimp
   730   apply (rule_tac x="b - Suc a" in exI)
   731   apply arith
   732   done
   733 
   734 
   735 subsection \<open>Cases and induction\<close>
   736 
   737 text \<open>
   738   Now we replace the case analysis rule by a more conventional one:
   739   whether an integer is negative or not.
   740 \<close>
   741 
   742 text \<open>This version is symmetric in the two subgoals.\<close>
   743 lemma int_cases2 [case_names nonneg nonpos, cases type: int]:
   744   "(\<And>n. z = int n \<Longrightarrow> P) \<Longrightarrow> (\<And>n. z = - (int n) \<Longrightarrow> P) \<Longrightarrow> P"
   745   by (cases "z < 0") (auto simp add: linorder_not_less dest!: negD nat_0_le [THEN sym])
   746 
   747 text \<open>This is the default, with a negative case.\<close>
   748 lemma int_cases [case_names nonneg neg, cases type: int]:
   749   "(\<And>n. z = int n \<Longrightarrow> P) \<Longrightarrow> (\<And>n. z = - (int (Suc n)) \<Longrightarrow> P) \<Longrightarrow> P"
   750   apply (cases "z < 0")
   751    apply (blast dest!: negD)
   752   apply (simp add: linorder_not_less del: of_nat_Suc)
   753   apply auto
   754   apply (blast dest: nat_0_le [THEN sym])
   755   done
   756 
   757 lemma int_cases3 [case_names zero pos neg]:
   758   fixes k :: int
   759   assumes "k = 0 \<Longrightarrow> P" and "\<And>n. k = int n \<Longrightarrow> n > 0 \<Longrightarrow> P"
   760     and "\<And>n. k = - int n \<Longrightarrow> n > 0 \<Longrightarrow> P"
   761   shows "P"
   762 proof (cases k "0::int" rule: linorder_cases)
   763   case equal
   764   with assms(1) show P by simp
   765 next
   766   case greater
   767   then have *: "nat k > 0" by simp
   768   moreover from * have "k = int (nat k)" by auto
   769   ultimately show P using assms(2) by blast
   770 next
   771   case less
   772   then have *: "nat (- k) > 0" by simp
   773   moreover from * have "k = - int (nat (- k))" by auto
   774   ultimately show P using assms(3) by blast
   775 qed
   776 
   777 lemma int_of_nat_induct [case_names nonneg neg, induct type: int]:
   778   "(\<And>n. P (int n)) \<Longrightarrow> (\<And>n. P (- (int (Suc n)))) \<Longrightarrow> P z"
   779   by (cases z) auto
   780 
   781 lemma Let_numeral [simp]: "Let (numeral v) f = f (numeral v)"
   782   \<comment> \<open>Unfold all \<open>let\<close>s involving constants\<close>
   783   by (fact Let_numeral) \<comment> \<open>FIXME drop\<close>
   784 
   785 lemma Let_neg_numeral [simp]: "Let (- numeral v) f = f (- numeral v)"
   786   \<comment> \<open>Unfold all \<open>let\<close>s involving constants\<close>
   787   by (fact Let_neg_numeral) \<comment> \<open>FIXME drop\<close>
   788 
   789 lemma sgn_mult_dvd_iff [simp]:
   790   "sgn r * l dvd k \<longleftrightarrow> l dvd k \<and> (r = 0 \<longrightarrow> k = 0)" for k l r :: int
   791   by (cases r rule: int_cases3) auto
   792 
   793 lemma mult_sgn_dvd_iff [simp]:
   794   "l * sgn r dvd k \<longleftrightarrow> l dvd k \<and> (r = 0 \<longrightarrow> k = 0)" for k l r :: int
   795   using sgn_mult_dvd_iff [of r l k] by (simp add: ac_simps)
   796 
   797 lemma dvd_sgn_mult_iff [simp]:
   798   "l dvd sgn r * k \<longleftrightarrow> l dvd k \<or> r = 0" for k l r :: int
   799   by (cases r rule: int_cases3) simp_all
   800 
   801 lemma dvd_mult_sgn_iff [simp]:
   802   "l dvd k * sgn r \<longleftrightarrow> l dvd k \<or> r = 0" for k l r :: int
   803   using dvd_sgn_mult_iff [of l r k] by (simp add: ac_simps)
   804 
   805 lemma int_sgnE:
   806   fixes k :: int
   807   obtains n and l where "k = sgn l * int n"
   808 proof -
   809   have "k = sgn k * int (nat \<bar>k\<bar>)"
   810     by (simp add: sgn_mult_abs)
   811   then show ?thesis ..
   812 qed
   813 
   814 text \<open>Unfold \<open>min\<close> and \<open>max\<close> on numerals.\<close>
   815 
   816 lemmas max_number_of [simp] =
   817   max_def [of "numeral u" "numeral v"]
   818   max_def [of "numeral u" "- numeral v"]
   819   max_def [of "- numeral u" "numeral v"]
   820   max_def [of "- numeral u" "- numeral v"] for u v
   821 
   822 lemmas min_number_of [simp] =
   823   min_def [of "numeral u" "numeral v"]
   824   min_def [of "numeral u" "- numeral v"]
   825   min_def [of "- numeral u" "numeral v"]
   826   min_def [of "- numeral u" "- numeral v"] for u v
   827 
   828 
   829 subsubsection \<open>Binary comparisons\<close>
   830 
   831 text \<open>Preliminaries\<close>
   832 
   833 lemma le_imp_0_less:
   834   fixes z :: int
   835   assumes le: "0 \<le> z"
   836   shows "0 < 1 + z"
   837 proof -
   838   have "0 \<le> z" by fact
   839   also have "\<dots> < z + 1" by (rule less_add_one)
   840   also have "\<dots> = 1 + z" by (simp add: ac_simps)
   841   finally show "0 < 1 + z" .
   842 qed
   843 
   844 lemma odd_less_0_iff: "1 + z + z < 0 \<longleftrightarrow> z < 0"
   845   for z :: int
   846 proof (cases z)
   847   case (nonneg n)
   848   then show ?thesis
   849     by (simp add: linorder_not_less add.assoc add_increasing le_imp_0_less [THEN order_less_imp_le])
   850 next
   851   case (neg n)
   852   then show ?thesis
   853     by (simp del: of_nat_Suc of_nat_add of_nat_1
   854         add: algebra_simps of_nat_1 [where 'a=int, symmetric] of_nat_add [symmetric])
   855 qed
   856 
   857 
   858 subsubsection \<open>Comparisons, for Ordered Rings\<close>
   859 
   860 lemmas double_eq_0_iff = double_zero
   861 
   862 lemma odd_nonzero: "1 + z + z \<noteq> 0"
   863   for z :: int
   864 proof (cases z)
   865   case (nonneg n)
   866   have le: "0 \<le> z + z"
   867     by (simp add: nonneg add_increasing)
   868   then show ?thesis
   869     using  le_imp_0_less [OF le] by (auto simp: add.assoc)
   870 next
   871   case (neg n)
   872   show ?thesis
   873   proof
   874     assume eq: "1 + z + z = 0"
   875     have "0 < 1 + (int n + int n)"
   876       by (simp add: le_imp_0_less add_increasing)
   877     also have "\<dots> = - (1 + z + z)"
   878       by (simp add: neg add.assoc [symmetric])
   879     also have "\<dots> = 0" by (simp add: eq)
   880     finally have "0<0" ..
   881     then show False by blast
   882   qed
   883 qed
   884 
   885 
   886 subsection \<open>The Set of Integers\<close>
   887 
   888 context ring_1
   889 begin
   890 
   891 definition Ints :: "'a set"  ("\<int>")
   892   where "\<int> = range of_int"
   893 
   894 lemma Ints_of_int [simp]: "of_int z \<in> \<int>"
   895   by (simp add: Ints_def)
   896 
   897 lemma Ints_of_nat [simp]: "of_nat n \<in> \<int>"
   898   using Ints_of_int [of "of_nat n"] by simp
   899 
   900 lemma Ints_0 [simp]: "0 \<in> \<int>"
   901   using Ints_of_int [of "0"] by simp
   902 
   903 lemma Ints_1 [simp]: "1 \<in> \<int>"
   904   using Ints_of_int [of "1"] by simp
   905 
   906 lemma Ints_numeral [simp]: "numeral n \<in> \<int>"
   907   by (subst of_nat_numeral [symmetric], rule Ints_of_nat)
   908 
   909 lemma Ints_add [simp]: "a \<in> \<int> \<Longrightarrow> b \<in> \<int> \<Longrightarrow> a + b \<in> \<int>"
   910   apply (auto simp add: Ints_def)
   911   apply (rule range_eqI)
   912   apply (rule of_int_add [symmetric])
   913   done
   914 
   915 lemma Ints_minus [simp]: "a \<in> \<int> \<Longrightarrow> -a \<in> \<int>"
   916   apply (auto simp add: Ints_def)
   917   apply (rule range_eqI)
   918   apply (rule of_int_minus [symmetric])
   919   done
   920 
   921 lemma Ints_diff [simp]: "a \<in> \<int> \<Longrightarrow> b \<in> \<int> \<Longrightarrow> a - b \<in> \<int>"
   922   apply (auto simp add: Ints_def)
   923   apply (rule range_eqI)
   924   apply (rule of_int_diff [symmetric])
   925   done
   926 
   927 lemma Ints_mult [simp]: "a \<in> \<int> \<Longrightarrow> b \<in> \<int> \<Longrightarrow> a * b \<in> \<int>"
   928   apply (auto simp add: Ints_def)
   929   apply (rule range_eqI)
   930   apply (rule of_int_mult [symmetric])
   931   done
   932 
   933 lemma Ints_power [simp]: "a \<in> \<int> \<Longrightarrow> a ^ n \<in> \<int>"
   934   by (induct n) simp_all
   935 
   936 lemma Ints_cases [cases set: Ints]:
   937   assumes "q \<in> \<int>"
   938   obtains (of_int) z where "q = of_int z"
   939   unfolding Ints_def
   940 proof -
   941   from \<open>q \<in> \<int>\<close> have "q \<in> range of_int" unfolding Ints_def .
   942   then obtain z where "q = of_int z" ..
   943   then show thesis ..
   944 qed
   945 
   946 lemma Ints_induct [case_names of_int, induct set: Ints]:
   947   "q \<in> \<int> \<Longrightarrow> (\<And>z. P (of_int z)) \<Longrightarrow> P q"
   948   by (rule Ints_cases) auto
   949 
   950 lemma Nats_subset_Ints: "\<nat> \<subseteq> \<int>"
   951   unfolding Nats_def Ints_def
   952   by (rule subsetI, elim imageE, hypsubst, subst of_int_of_nat_eq[symmetric], rule imageI) simp_all
   953 
   954 lemma Nats_altdef1: "\<nat> = {of_int n |n. n \<ge> 0}"
   955 proof (intro subsetI equalityI)
   956   fix x :: 'a
   957   assume "x \<in> {of_int n |n. n \<ge> 0}"
   958   then obtain n where "x = of_int n" "n \<ge> 0"
   959     by (auto elim!: Ints_cases)
   960   then have "x = of_nat (nat n)"
   961     by (subst of_nat_nat) simp_all
   962   then show "x \<in> \<nat>"
   963     by simp
   964 next
   965   fix x :: 'a
   966   assume "x \<in> \<nat>"
   967   then obtain n where "x = of_nat n"
   968     by (auto elim!: Nats_cases)
   969   then have "x = of_int (int n)" by simp
   970   also have "int n \<ge> 0" by simp
   971   then have "of_int (int n) \<in> {of_int n |n. n \<ge> 0}" by blast
   972   finally show "x \<in> {of_int n |n. n \<ge> 0}" .
   973 qed
   974 
   975 end
   976 
   977 lemma (in linordered_idom) Ints_abs [simp]:
   978   shows "a \<in> \<int> \<Longrightarrow> abs a \<in> \<int>"
   979   by (auto simp: abs_if)
   980 
   981 lemma (in linordered_idom) Nats_altdef2: "\<nat> = {n \<in> \<int>. n \<ge> 0}"
   982 proof (intro subsetI equalityI)
   983   fix x :: 'a
   984   assume "x \<in> {n \<in> \<int>. n \<ge> 0}"
   985   then obtain n where "x = of_int n" "n \<ge> 0"
   986     by (auto elim!: Ints_cases)
   987   then have "x = of_nat (nat n)"
   988     by (subst of_nat_nat) simp_all
   989   then show "x \<in> \<nat>"
   990     by simp
   991 qed (auto elim!: Nats_cases)
   992 
   993 lemma (in idom_divide) of_int_divide_in_Ints: 
   994   "of_int a div of_int b \<in> \<int>" if "b dvd a"
   995 proof -
   996   from that obtain c where "a = b * c" ..
   997   then show ?thesis
   998     by (cases "of_int b = 0") simp_all
   999 qed
  1000 
  1001 text \<open>The premise involving @{term Ints} prevents @{term "a = 1/2"}.\<close>
  1002 
  1003 lemma Ints_double_eq_0_iff:
  1004   fixes a :: "'a::ring_char_0"
  1005   assumes in_Ints: "a \<in> \<int>"
  1006   shows "a + a = 0 \<longleftrightarrow> a = 0"
  1007     (is "?lhs \<longleftrightarrow> ?rhs")
  1008 proof -
  1009   from in_Ints have "a \<in> range of_int"
  1010     unfolding Ints_def [symmetric] .
  1011   then obtain z where a: "a = of_int z" ..
  1012   show ?thesis
  1013   proof
  1014     assume ?rhs
  1015     then show ?lhs by simp
  1016   next
  1017     assume ?lhs
  1018     with a have "of_int (z + z) = (of_int 0 :: 'a)" by simp
  1019     then have "z + z = 0" by (simp only: of_int_eq_iff)
  1020     then have "z = 0" by (simp only: double_eq_0_iff)
  1021     with a show ?rhs by simp
  1022   qed
  1023 qed
  1024 
  1025 lemma Ints_odd_nonzero:
  1026   fixes a :: "'a::ring_char_0"
  1027   assumes in_Ints: "a \<in> \<int>"
  1028   shows "1 + a + a \<noteq> 0"
  1029 proof -
  1030   from in_Ints have "a \<in> range of_int"
  1031     unfolding Ints_def [symmetric] .
  1032   then obtain z where a: "a = of_int z" ..
  1033   show ?thesis
  1034   proof
  1035     assume "1 + a + a = 0"
  1036     with a have "of_int (1 + z + z) = (of_int 0 :: 'a)" by simp
  1037     then have "1 + z + z = 0" by (simp only: of_int_eq_iff)
  1038     with odd_nonzero show False by blast
  1039   qed
  1040 qed
  1041 
  1042 lemma Nats_numeral [simp]: "numeral w \<in> \<nat>"
  1043   using of_nat_in_Nats [of "numeral w"] by simp
  1044 
  1045 lemma Ints_odd_less_0:
  1046   fixes a :: "'a::linordered_idom"
  1047   assumes in_Ints: "a \<in> \<int>"
  1048   shows "1 + a + a < 0 \<longleftrightarrow> a < 0"
  1049 proof -
  1050   from in_Ints have "a \<in> range of_int"
  1051     unfolding Ints_def [symmetric] .
  1052   then obtain z where a: "a = of_int z" ..
  1053   with a have "1 + a + a < 0 \<longleftrightarrow> of_int (1 + z + z) < (of_int 0 :: 'a)"
  1054     by simp
  1055   also have "\<dots> \<longleftrightarrow> z < 0"
  1056     by (simp only: of_int_less_iff odd_less_0_iff)
  1057   also have "\<dots> \<longleftrightarrow> a < 0"
  1058     by (simp add: a)
  1059   finally show ?thesis .
  1060 qed
  1061 
  1062 
  1063 subsection \<open>@{term sum} and @{term prod}\<close>
  1064 
  1065 lemma of_nat_sum [simp]: "of_nat (sum f A) = (\<Sum>x\<in>A. of_nat(f x))"
  1066   by (induct A rule: infinite_finite_induct) auto
  1067 
  1068 lemma of_int_sum [simp]: "of_int (sum f A) = (\<Sum>x\<in>A. of_int(f x))"
  1069   by (induct A rule: infinite_finite_induct) auto
  1070 
  1071 lemma of_nat_prod [simp]: "of_nat (prod f A) = (\<Prod>x\<in>A. of_nat(f x))"
  1072   by (induct A rule: infinite_finite_induct) auto
  1073 
  1074 lemma of_int_prod [simp]: "of_int (prod f A) = (\<Prod>x\<in>A. of_int(f x))"
  1075   by (induct A rule: infinite_finite_induct) auto
  1076 
  1077 
  1078 text \<open>Legacy theorems\<close>
  1079 
  1080 lemmas int_sum = of_nat_sum [where 'a=int]
  1081 lemmas int_prod = of_nat_prod [where 'a=int]
  1082 lemmas zle_int = of_nat_le_iff [where 'a=int]
  1083 lemmas int_int_eq = of_nat_eq_iff [where 'a=int]
  1084 lemmas nonneg_eq_int = nonneg_int_cases
  1085 
  1086 
  1087 subsection \<open>Setting up simplification procedures\<close>
  1088 
  1089 lemmas of_int_simps =
  1090   of_int_0 of_int_1 of_int_add of_int_mult
  1091 
  1092 ML_file "Tools/int_arith.ML"
  1093 declaration \<open>K Int_Arith.setup\<close>
  1094 
  1095 simproc_setup fast_arith
  1096   ("(m::'a::linordered_idom) < n" |
  1097     "(m::'a::linordered_idom) \<le> n" |
  1098     "(m::'a::linordered_idom) = n") =
  1099   \<open>K Lin_Arith.simproc\<close>
  1100 
  1101 
  1102 subsection\<open>More Inequality Reasoning\<close>
  1103 
  1104 lemma zless_add1_eq: "w < z + 1 \<longleftrightarrow> w < z \<or> w = z"
  1105   for w z :: int
  1106   by arith
  1107 
  1108 lemma add1_zle_eq: "w + 1 \<le> z \<longleftrightarrow> w < z"
  1109   for w z :: int
  1110   by arith
  1111 
  1112 lemma zle_diff1_eq [simp]: "w \<le> z - 1 \<longleftrightarrow> w < z"
  1113   for w z :: int
  1114   by arith
  1115 
  1116 lemma zle_add1_eq_le [simp]: "w < z + 1 \<longleftrightarrow> w \<le> z"
  1117   for w z :: int
  1118   by arith
  1119 
  1120 lemma int_one_le_iff_zero_less: "1 \<le> z \<longleftrightarrow> 0 < z"
  1121   for z :: int
  1122   by arith
  1123 
  1124 lemma Ints_nonzero_abs_ge1:
  1125   fixes x:: "'a :: linordered_idom"
  1126     assumes "x \<in> Ints" "x \<noteq> 0"
  1127     shows "1 \<le> abs x"
  1128 proof (rule Ints_cases [OF \<open>x \<in> Ints\<close>])
  1129   fix z::int
  1130   assume "x = of_int z"
  1131     with \<open>x \<noteq> 0\<close> 
  1132   show "1 \<le> \<bar>x\<bar>"
  1133     apply (auto simp add: abs_if)
  1134     by (metis diff_0 of_int_1 of_int_le_iff of_int_minus zle_diff1_eq)
  1135 qed
  1136   
  1137 lemma Ints_nonzero_abs_less1:
  1138   fixes x:: "'a :: linordered_idom"
  1139   shows "\<lbrakk>x \<in> Ints; abs x < 1\<rbrakk> \<Longrightarrow> x = 0"
  1140     using Ints_nonzero_abs_ge1 [of x] by auto
  1141     
  1142 
  1143 subsection \<open>The functions @{term nat} and @{term int}\<close>
  1144 
  1145 text \<open>Simplify the term @{term "w + - z"}.\<close>
  1146 
  1147 lemma one_less_nat_eq [simp]: "Suc 0 < nat z \<longleftrightarrow> 1 < z"
  1148   using zless_nat_conj [of 1 z] by auto
  1149 
  1150 text \<open>
  1151   This simplifies expressions of the form @{term "int n = z"} where
  1152   \<open>z\<close> is an integer literal.
  1153 \<close>
  1154 lemmas int_eq_iff_numeral [simp] = int_eq_iff [of _ "numeral v"] for v
  1155 
  1156 lemma nat_abs_int_diff: "nat \<bar>int a - int b\<bar> = (if a \<le> b then b - a else a - b)"
  1157   by auto
  1158 
  1159 lemma nat_int_add: "nat (int a + int b) = a + b"
  1160   by auto
  1161 
  1162 context ring_1
  1163 begin
  1164 
  1165 lemma of_int_of_nat [nitpick_simp]:
  1166   "of_int k = (if k < 0 then - of_nat (nat (- k)) else of_nat (nat k))"
  1167 proof (cases "k < 0")
  1168   case True
  1169   then have "0 \<le> - k" by simp
  1170   then have "of_nat (nat (- k)) = of_int (- k)" by (rule of_nat_nat)
  1171   with True show ?thesis by simp
  1172 next
  1173   case False
  1174   then show ?thesis by (simp add: not_less)
  1175 qed
  1176 
  1177 end
  1178 
  1179 lemma transfer_rule_of_int:
  1180   fixes R :: "'a::ring_1 \<Rightarrow> 'b::ring_1 \<Rightarrow> bool"
  1181   assumes [transfer_rule]: "R 0 0" "R 1 1"
  1182     "rel_fun R (rel_fun R R) plus plus"
  1183     "rel_fun R R uminus uminus"
  1184   shows "rel_fun HOL.eq R of_int of_int"
  1185 proof -
  1186   note transfer_rule_of_nat [transfer_rule]
  1187   have [transfer_rule]: "rel_fun HOL.eq R of_nat of_nat"
  1188     by transfer_prover
  1189   show ?thesis
  1190     by (unfold of_int_of_nat [abs_def]) transfer_prover
  1191 qed
  1192 
  1193 lemma nat_mult_distrib:
  1194   fixes z z' :: int
  1195   assumes "0 \<le> z"
  1196   shows "nat (z * z') = nat z * nat z'"
  1197 proof (cases "0 \<le> z'")
  1198   case False
  1199   with assms have "z * z' \<le> 0"
  1200     by (simp add: not_le mult_le_0_iff)
  1201   then have "nat (z * z') = 0" by simp
  1202   moreover from False have "nat z' = 0" by simp
  1203   ultimately show ?thesis by simp
  1204 next
  1205   case True
  1206   with assms have ge_0: "z * z' \<ge> 0" by (simp add: zero_le_mult_iff)
  1207   show ?thesis
  1208     by (rule injD [of "of_nat :: nat \<Rightarrow> int", OF inj_of_nat])
  1209       (simp only: of_nat_mult of_nat_nat [OF True]
  1210          of_nat_nat [OF assms] of_nat_nat [OF ge_0], simp)
  1211 qed
  1212 
  1213 lemma nat_mult_distrib_neg: "z \<le> 0 \<Longrightarrow> nat (z * z') = nat (- z) * nat (- z')"
  1214   for z z' :: int
  1215   apply (rule trans)
  1216    apply (rule_tac [2] nat_mult_distrib)
  1217    apply auto
  1218   done
  1219 
  1220 lemma nat_abs_mult_distrib: "nat \<bar>w * z\<bar> = nat \<bar>w\<bar> * nat \<bar>z\<bar>"
  1221   by (cases "z = 0 \<or> w = 0")
  1222     (auto simp add: abs_if nat_mult_distrib [symmetric]
  1223       nat_mult_distrib_neg [symmetric] mult_less_0_iff)
  1224 
  1225 lemma int_in_range_abs [simp]: "int n \<in> range abs"
  1226 proof (rule range_eqI)
  1227   show "int n = \<bar>int n\<bar>" by simp
  1228 qed
  1229 
  1230 lemma range_abs_Nats [simp]: "range abs = (\<nat> :: int set)"
  1231 proof -
  1232   have "\<bar>k\<bar> \<in> \<nat>" for k :: int
  1233     by (cases k) simp_all
  1234   moreover have "k \<in> range abs" if "k \<in> \<nat>" for k :: int
  1235     using that by induct simp
  1236   ultimately show ?thesis by blast
  1237 qed
  1238 
  1239 lemma Suc_nat_eq_nat_zadd1: "0 \<le> z \<Longrightarrow> Suc (nat z) = nat (1 + z)"
  1240   for z :: int
  1241   by (rule sym) (simp add: nat_eq_iff)
  1242 
  1243 lemma diff_nat_eq_if:
  1244   "nat z - nat z' =
  1245     (if z' < 0 then nat z
  1246      else
  1247       let d = z - z'
  1248       in if d < 0 then 0 else nat d)"
  1249   by (simp add: Let_def nat_diff_distrib [symmetric])
  1250 
  1251 lemma nat_numeral_diff_1 [simp]: "numeral v - (1::nat) = nat (numeral v - 1)"
  1252   using diff_nat_numeral [of v Num.One] by simp
  1253 
  1254 
  1255 subsection \<open>Induction principles for int\<close>
  1256 
  1257 text \<open>Well-founded segments of the integers.\<close>
  1258 
  1259 definition int_ge_less_than :: "int \<Rightarrow> (int \<times> int) set"
  1260   where "int_ge_less_than d = {(z', z). d \<le> z' \<and> z' < z}"
  1261 
  1262 lemma wf_int_ge_less_than: "wf (int_ge_less_than d)"
  1263 proof -
  1264   have "int_ge_less_than d \<subseteq> measure (\<lambda>z. nat (z - d))"
  1265     by (auto simp add: int_ge_less_than_def)
  1266   then show ?thesis
  1267     by (rule wf_subset [OF wf_measure])
  1268 qed
  1269 
  1270 text \<open>
  1271   This variant looks odd, but is typical of the relations suggested
  1272   by RankFinder.\<close>
  1273 
  1274 definition int_ge_less_than2 :: "int \<Rightarrow> (int \<times> int) set"
  1275   where "int_ge_less_than2 d = {(z',z). d \<le> z \<and> z' < z}"
  1276 
  1277 lemma wf_int_ge_less_than2: "wf (int_ge_less_than2 d)"
  1278 proof -
  1279   have "int_ge_less_than2 d \<subseteq> measure (\<lambda>z. nat (1 + z - d))"
  1280     by (auto simp add: int_ge_less_than2_def)
  1281   then show ?thesis
  1282     by (rule wf_subset [OF wf_measure])
  1283 qed
  1284 
  1285 (* `set:int': dummy construction *)
  1286 theorem int_ge_induct [case_names base step, induct set: int]:
  1287   fixes i :: int
  1288   assumes ge: "k \<le> i"
  1289     and base: "P k"
  1290     and step: "\<And>i. k \<le> i \<Longrightarrow> P i \<Longrightarrow> P (i + 1)"
  1291   shows "P i"
  1292 proof -
  1293   have "\<And>i::int. n = nat (i - k) \<Longrightarrow> k \<le> i \<Longrightarrow> P i" for n
  1294   proof (induct n)
  1295     case 0
  1296     then have "i = k" by arith
  1297     with base show "P i" by simp
  1298   next
  1299     case (Suc n)
  1300     then have "n = nat ((i - 1) - k)" by arith
  1301     moreover have k: "k \<le> i - 1" using Suc.prems by arith
  1302     ultimately have "P (i - 1)" by (rule Suc.hyps)
  1303     from step [OF k this] show ?case by simp
  1304   qed
  1305   with ge show ?thesis by fast
  1306 qed
  1307 
  1308 (* `set:int': dummy construction *)
  1309 theorem int_gr_induct [case_names base step, induct set: int]:
  1310   fixes i k :: int
  1311   assumes gr: "k < i"
  1312     and base: "P (k + 1)"
  1313     and step: "\<And>i. k < i \<Longrightarrow> P i \<Longrightarrow> P (i + 1)"
  1314   shows "P i"
  1315   apply (rule int_ge_induct[of "k + 1"])
  1316   using gr apply arith
  1317    apply (rule base)
  1318   apply (rule step)
  1319    apply simp_all
  1320   done
  1321 
  1322 theorem int_le_induct [consumes 1, case_names base step]:
  1323   fixes i k :: int
  1324   assumes le: "i \<le> k"
  1325     and base: "P k"
  1326     and step: "\<And>i. i \<le> k \<Longrightarrow> P i \<Longrightarrow> P (i - 1)"
  1327   shows "P i"
  1328 proof -
  1329   have "\<And>i::int. n = nat(k-i) \<Longrightarrow> i \<le> k \<Longrightarrow> P i" for n
  1330   proof (induct n)
  1331     case 0
  1332     then have "i = k" by arith
  1333     with base show "P i" by simp
  1334   next
  1335     case (Suc n)
  1336     then have "n = nat (k - (i + 1))" by arith
  1337     moreover have k: "i + 1 \<le> k" using Suc.prems by arith
  1338     ultimately have "P (i + 1)" by (rule Suc.hyps)
  1339     from step[OF k this] show ?case by simp
  1340   qed
  1341   with le show ?thesis by fast
  1342 qed
  1343 
  1344 theorem int_less_induct [consumes 1, case_names base step]:
  1345   fixes i k :: int
  1346   assumes less: "i < k"
  1347     and base: "P (k - 1)"
  1348     and step: "\<And>i. i < k \<Longrightarrow> P i \<Longrightarrow> P (i - 1)"
  1349   shows "P i"
  1350   apply (rule int_le_induct[of _ "k - 1"])
  1351   using less apply arith
  1352    apply (rule base)
  1353   apply (rule step)
  1354    apply simp_all
  1355   done
  1356 
  1357 theorem int_induct [case_names base step1 step2]:
  1358   fixes k :: int
  1359   assumes base: "P k"
  1360     and step1: "\<And>i. k \<le> i \<Longrightarrow> P i \<Longrightarrow> P (i + 1)"
  1361     and step2: "\<And>i. k \<ge> i \<Longrightarrow> P i \<Longrightarrow> P (i - 1)"
  1362   shows "P i"
  1363 proof -
  1364   have "i \<le> k \<or> i \<ge> k" by arith
  1365   then show ?thesis
  1366   proof
  1367     assume "i \<ge> k"
  1368     then show ?thesis
  1369       using base by (rule int_ge_induct) (fact step1)
  1370   next
  1371     assume "i \<le> k"
  1372     then show ?thesis
  1373       using base by (rule int_le_induct) (fact step2)
  1374   qed
  1375 qed
  1376 
  1377 
  1378 subsection \<open>Intermediate value theorems\<close>
  1379 
  1380 lemma int_val_lemma: "(\<forall>i<n. \<bar>f (i + 1) - f i\<bar> \<le> 1) \<longrightarrow> f 0 \<le> k \<longrightarrow> k \<le> f n \<longrightarrow> (\<exists>i \<le> n. f i = k)"
  1381   for n :: nat and k :: int
  1382   unfolding One_nat_def
  1383   apply (induct n)
  1384    apply simp
  1385   apply (intro strip)
  1386   apply (erule impE)
  1387    apply simp
  1388   apply (erule_tac x = n in allE)
  1389   apply simp
  1390   apply (case_tac "k = f (Suc n)")
  1391    apply force
  1392   apply (erule impE)
  1393    apply (simp add: abs_if split: if_split_asm)
  1394   apply (blast intro: le_SucI)
  1395   done
  1396 
  1397 lemmas nat0_intermed_int_val = int_val_lemma [rule_format (no_asm)]
  1398 
  1399 lemma nat_intermed_int_val:
  1400   "\<forall>i. m \<le> i \<and> i < n \<longrightarrow> \<bar>f (i + 1) - f i\<bar> \<le> 1 \<Longrightarrow> m < n \<Longrightarrow>
  1401     f m \<le> k \<Longrightarrow> k \<le> f n \<Longrightarrow> \<exists>i. m \<le> i \<and> i \<le> n \<and> f i = k"
  1402     for f :: "nat \<Rightarrow> int" and k :: int
  1403   apply (cut_tac n = "n-m" and f = "\<lambda>i. f (i + m)" and k = k in int_val_lemma)
  1404   unfolding One_nat_def
  1405   apply simp
  1406   apply (erule exE)
  1407   apply (rule_tac x = "i+m" in exI)
  1408   apply arith
  1409   done
  1410 
  1411 
  1412 subsection \<open>Products and 1, by T. M. Rasmussen\<close>
  1413 
  1414 lemma abs_zmult_eq_1:
  1415   fixes m n :: int
  1416   assumes mn: "\<bar>m * n\<bar> = 1"
  1417   shows "\<bar>m\<bar> = 1"
  1418 proof -
  1419   from mn have 0: "m \<noteq> 0" "n \<noteq> 0" by auto
  1420   have "\<not> 2 \<le> \<bar>m\<bar>"
  1421   proof
  1422     assume "2 \<le> \<bar>m\<bar>"
  1423     then have "2 * \<bar>n\<bar> \<le> \<bar>m\<bar> * \<bar>n\<bar>" by (simp add: mult_mono 0)
  1424     also have "\<dots> = \<bar>m * n\<bar>" by (simp add: abs_mult)
  1425     also from mn have "\<dots> = 1" by simp
  1426     finally have "2 * \<bar>n\<bar> \<le> 1" .
  1427     with 0 show "False" by arith
  1428   qed
  1429   with 0 show ?thesis by auto
  1430 qed
  1431 
  1432 lemma pos_zmult_eq_1_iff_lemma: "m * n = 1 \<Longrightarrow> m = 1 \<or> m = - 1"
  1433   for m n :: int
  1434   using abs_zmult_eq_1 [of m n] by arith
  1435 
  1436 lemma pos_zmult_eq_1_iff:
  1437   fixes m n :: int
  1438   assumes "0 < m"
  1439   shows "m * n = 1 \<longleftrightarrow> m = 1 \<and> n = 1"
  1440 proof -
  1441   from assms have "m * n = 1 \<Longrightarrow> m = 1"
  1442     by (auto dest: pos_zmult_eq_1_iff_lemma)
  1443   then show ?thesis
  1444     by (auto dest: pos_zmult_eq_1_iff_lemma)
  1445 qed
  1446 
  1447 lemma zmult_eq_1_iff: "m * n = 1 \<longleftrightarrow> (m = 1 \<and> n = 1) \<or> (m = - 1 \<and> n = - 1)"
  1448   for m n :: int
  1449   apply (rule iffI)
  1450    apply (frule pos_zmult_eq_1_iff_lemma)
  1451    apply (simp add: mult.commute [of m])
  1452    apply (frule pos_zmult_eq_1_iff_lemma)
  1453    apply auto
  1454   done
  1455 
  1456 lemma infinite_UNIV_int: "\<not> finite (UNIV::int set)"
  1457 proof
  1458   assume "finite (UNIV::int set)"
  1459   moreover have "inj (\<lambda>i::int. 2 * i)"
  1460     by (rule injI) simp
  1461   ultimately have "surj (\<lambda>i::int. 2 * i)"
  1462     by (rule finite_UNIV_inj_surj)
  1463   then obtain i :: int where "1 = 2 * i" by (rule surjE)
  1464   then show False by (simp add: pos_zmult_eq_1_iff)
  1465 qed
  1466 
  1467 
  1468 subsection \<open>Further theorems on numerals\<close>
  1469 
  1470 subsubsection \<open>Special Simplification for Constants\<close>
  1471 
  1472 text \<open>These distributive laws move literals inside sums and differences.\<close>
  1473 
  1474 lemmas distrib_right_numeral [simp] = distrib_right [of _ _ "numeral v"] for v
  1475 lemmas distrib_left_numeral [simp] = distrib_left [of "numeral v"] for v
  1476 lemmas left_diff_distrib_numeral [simp] = left_diff_distrib [of _ _ "numeral v"] for v
  1477 lemmas right_diff_distrib_numeral [simp] = right_diff_distrib [of "numeral v"] for v
  1478 
  1479 text \<open>These are actually for fields, like real: but where else to put them?\<close>
  1480 
  1481 lemmas zero_less_divide_iff_numeral [simp, no_atp] = zero_less_divide_iff [of "numeral w"] for w
  1482 lemmas divide_less_0_iff_numeral [simp, no_atp] = divide_less_0_iff [of "numeral w"] for w
  1483 lemmas zero_le_divide_iff_numeral [simp, no_atp] = zero_le_divide_iff [of "numeral w"] for w
  1484 lemmas divide_le_0_iff_numeral [simp, no_atp] = divide_le_0_iff [of "numeral w"] for w
  1485 
  1486 
  1487 text \<open>Replaces \<open>inverse #nn\<close> by \<open>1/#nn\<close>.  It looks
  1488   strange, but then other simprocs simplify the quotient.\<close>
  1489 
  1490 lemmas inverse_eq_divide_numeral [simp] =
  1491   inverse_eq_divide [of "numeral w"] for w
  1492 
  1493 lemmas inverse_eq_divide_neg_numeral [simp] =
  1494   inverse_eq_divide [of "- numeral w"] for w
  1495 
  1496 text \<open>These laws simplify inequalities, moving unary minus from a term
  1497   into the literal.\<close>
  1498 
  1499 lemmas equation_minus_iff_numeral [no_atp] =
  1500   equation_minus_iff [of "numeral v"] for v
  1501 
  1502 lemmas minus_equation_iff_numeral [no_atp] =
  1503   minus_equation_iff [of _ "numeral v"] for v
  1504 
  1505 lemmas le_minus_iff_numeral [no_atp] =
  1506   le_minus_iff [of "numeral v"] for v
  1507 
  1508 lemmas minus_le_iff_numeral [no_atp] =
  1509   minus_le_iff [of _ "numeral v"] for v
  1510 
  1511 lemmas less_minus_iff_numeral [no_atp] =
  1512   less_minus_iff [of "numeral v"] for v
  1513 
  1514 lemmas minus_less_iff_numeral [no_atp] =
  1515   minus_less_iff [of _ "numeral v"] for v
  1516 
  1517 (* FIXME maybe simproc *)
  1518 
  1519 
  1520 text \<open>Cancellation of constant factors in comparisons (\<open><\<close> and \<open>\<le>\<close>)\<close>
  1521 
  1522 lemmas mult_less_cancel_left_numeral [simp, no_atp] = mult_less_cancel_left [of "numeral v"] for v
  1523 lemmas mult_less_cancel_right_numeral [simp, no_atp] = mult_less_cancel_right [of _ "numeral v"] for v
  1524 lemmas mult_le_cancel_left_numeral [simp, no_atp] = mult_le_cancel_left [of "numeral v"] for v
  1525 lemmas mult_le_cancel_right_numeral [simp, no_atp] = mult_le_cancel_right [of _ "numeral v"] for v
  1526 
  1527 
  1528 text \<open>Multiplying out constant divisors in comparisons (\<open><\<close>, \<open>\<le>\<close> and \<open>=\<close>)\<close>
  1529 
  1530 named_theorems divide_const_simps "simplification rules to simplify comparisons involving constant divisors"
  1531 
  1532 lemmas le_divide_eq_numeral1 [simp,divide_const_simps] =
  1533   pos_le_divide_eq [of "numeral w", OF zero_less_numeral]
  1534   neg_le_divide_eq [of "- numeral w", OF neg_numeral_less_zero] for w
  1535 
  1536 lemmas divide_le_eq_numeral1 [simp,divide_const_simps] =
  1537   pos_divide_le_eq [of "numeral w", OF zero_less_numeral]
  1538   neg_divide_le_eq [of "- numeral w", OF neg_numeral_less_zero] for w
  1539 
  1540 lemmas less_divide_eq_numeral1 [simp,divide_const_simps] =
  1541   pos_less_divide_eq [of "numeral w", OF zero_less_numeral]
  1542   neg_less_divide_eq [of "- numeral w", OF neg_numeral_less_zero] for w
  1543 
  1544 lemmas divide_less_eq_numeral1 [simp,divide_const_simps] =
  1545   pos_divide_less_eq [of "numeral w", OF zero_less_numeral]
  1546   neg_divide_less_eq [of "- numeral w", OF neg_numeral_less_zero] for w
  1547 
  1548 lemmas eq_divide_eq_numeral1 [simp,divide_const_simps] =
  1549   eq_divide_eq [of _ _ "numeral w"]
  1550   eq_divide_eq [of _ _ "- numeral w"] for w
  1551 
  1552 lemmas divide_eq_eq_numeral1 [simp,divide_const_simps] =
  1553   divide_eq_eq [of _ "numeral w"]
  1554   divide_eq_eq [of _ "- numeral w"] for w
  1555 
  1556 
  1557 subsubsection \<open>Optional Simplification Rules Involving Constants\<close>
  1558 
  1559 text \<open>Simplify quotients that are compared with a literal constant.\<close>
  1560 
  1561 lemmas le_divide_eq_numeral [divide_const_simps] =
  1562   le_divide_eq [of "numeral w"]
  1563   le_divide_eq [of "- numeral w"] for w
  1564 
  1565 lemmas divide_le_eq_numeral [divide_const_simps] =
  1566   divide_le_eq [of _ _ "numeral w"]
  1567   divide_le_eq [of _ _ "- numeral w"] for w
  1568 
  1569 lemmas less_divide_eq_numeral [divide_const_simps] =
  1570   less_divide_eq [of "numeral w"]
  1571   less_divide_eq [of "- numeral w"] for w
  1572 
  1573 lemmas divide_less_eq_numeral [divide_const_simps] =
  1574   divide_less_eq [of _ _ "numeral w"]
  1575   divide_less_eq [of _ _ "- numeral w"] for w
  1576 
  1577 lemmas eq_divide_eq_numeral [divide_const_simps] =
  1578   eq_divide_eq [of "numeral w"]
  1579   eq_divide_eq [of "- numeral w"] for w
  1580 
  1581 lemmas divide_eq_eq_numeral [divide_const_simps] =
  1582   divide_eq_eq [of _ _ "numeral w"]
  1583   divide_eq_eq [of _ _ "- numeral w"] for w
  1584 
  1585 
  1586 text \<open>Not good as automatic simprules because they cause case splits.\<close>
  1587 lemmas [divide_const_simps] =
  1588   le_divide_eq_1 divide_le_eq_1 less_divide_eq_1 divide_less_eq_1
  1589 
  1590 
  1591 subsection \<open>The divides relation\<close>
  1592 
  1593 lemma zdvd_antisym_nonneg: "0 \<le> m \<Longrightarrow> 0 \<le> n \<Longrightarrow> m dvd n \<Longrightarrow> n dvd m \<Longrightarrow> m = n"
  1594   for m n :: int
  1595   by (auto simp add: dvd_def mult.assoc zero_le_mult_iff zmult_eq_1_iff)
  1596 
  1597 lemma zdvd_antisym_abs:
  1598   fixes a b :: int
  1599   assumes "a dvd b" and "b dvd a"
  1600   shows "\<bar>a\<bar> = \<bar>b\<bar>"
  1601 proof (cases "a = 0")
  1602   case True
  1603   with assms show ?thesis by simp
  1604 next
  1605   case False
  1606   from \<open>a dvd b\<close> obtain k where k: "b = a * k"
  1607     unfolding dvd_def by blast
  1608   from \<open>b dvd a\<close> obtain k' where k': "a = b * k'"
  1609     unfolding dvd_def by blast
  1610   from k k' have "a = a * k * k'" by simp
  1611   with mult_cancel_left1[where c="a" and b="k*k'"] have kk': "k * k' = 1"
  1612     using \<open>a \<noteq> 0\<close> by (simp add: mult.assoc)
  1613   then have "k = 1 \<and> k' = 1 \<or> k = -1 \<and> k' = -1"
  1614     by (simp add: zmult_eq_1_iff)
  1615   with k k' show ?thesis by auto
  1616 qed
  1617 
  1618 lemma zdvd_zdiffD: "k dvd m - n \<Longrightarrow> k dvd n \<Longrightarrow> k dvd m"
  1619   for k m n :: int
  1620   using dvd_add_right_iff [of k "- n" m] by simp
  1621 
  1622 lemma zdvd_reduce: "k dvd n + k * m \<longleftrightarrow> k dvd n"
  1623   for k m n :: int
  1624   using dvd_add_times_triv_right_iff [of k n m] by (simp add: ac_simps)
  1625 
  1626 lemma dvd_imp_le_int:
  1627   fixes d i :: int
  1628   assumes "i \<noteq> 0" and "d dvd i"
  1629   shows "\<bar>d\<bar> \<le> \<bar>i\<bar>"
  1630 proof -
  1631   from \<open>d dvd i\<close> obtain k where "i = d * k" ..
  1632   with \<open>i \<noteq> 0\<close> have "k \<noteq> 0" by auto
  1633   then have "1 \<le> \<bar>k\<bar>" and "0 \<le> \<bar>d\<bar>" by auto
  1634   then have "\<bar>d\<bar> * 1 \<le> \<bar>d\<bar> * \<bar>k\<bar>" by (rule mult_left_mono)
  1635   with \<open>i = d * k\<close> show ?thesis by (simp add: abs_mult)
  1636 qed
  1637 
  1638 lemma zdvd_not_zless:
  1639   fixes m n :: int
  1640   assumes "0 < m" and "m < n"
  1641   shows "\<not> n dvd m"
  1642 proof
  1643   from assms have "0 < n" by auto
  1644   assume "n dvd m" then obtain k where k: "m = n * k" ..
  1645   with \<open>0 < m\<close> have "0 < n * k" by auto
  1646   with \<open>0 < n\<close> have "0 < k" by (simp add: zero_less_mult_iff)
  1647   with k \<open>0 < n\<close> \<open>m < n\<close> have "n * k < n * 1" by simp
  1648   with \<open>0 < n\<close> \<open>0 < k\<close> show False unfolding mult_less_cancel_left by auto
  1649 qed
  1650 
  1651 lemma zdvd_mult_cancel:
  1652   fixes k m n :: int
  1653   assumes d: "k * m dvd k * n"
  1654     and "k \<noteq> 0"
  1655   shows "m dvd n"
  1656 proof -
  1657   from d obtain h where h: "k * n = k * m * h"
  1658     unfolding dvd_def by blast
  1659   have "n = m * h"
  1660   proof (rule ccontr)
  1661     assume "\<not> ?thesis"
  1662     with \<open>k \<noteq> 0\<close> have "k * n \<noteq> k * (m * h)" by simp
  1663     with h show False
  1664       by (simp add: mult.assoc)
  1665   qed
  1666   then show ?thesis by simp
  1667 qed
  1668 
  1669 theorem zdvd_int: "x dvd y \<longleftrightarrow> int x dvd int y"
  1670 proof -
  1671   have "x dvd y" if "int y = int x * k" for k
  1672   proof (cases k)
  1673     case (nonneg n)
  1674     with that have "y = x * n"
  1675       by (simp del: of_nat_mult add: of_nat_mult [symmetric])
  1676     then show ?thesis ..
  1677   next
  1678     case (neg n)
  1679     with that have "int y = int x * (- int (Suc n))"
  1680       by simp
  1681     also have "\<dots> = - (int x * int (Suc n))"
  1682       by (simp only: mult_minus_right)
  1683     also have "\<dots> = - int (x * Suc n)"
  1684       by (simp only: of_nat_mult [symmetric])
  1685     finally have "- int (x * Suc n) = int y" ..
  1686     then show ?thesis
  1687       by (simp only: negative_eq_positive) auto
  1688   qed
  1689   then show ?thesis
  1690     by (auto elim!: dvdE simp only: dvd_triv_left of_nat_mult)
  1691 qed
  1692 
  1693 lemma zdvd1_eq[simp]: "x dvd 1 \<longleftrightarrow> \<bar>x\<bar> = 1"
  1694   (is "?lhs \<longleftrightarrow> ?rhs")
  1695   for x :: int
  1696 proof
  1697   assume ?lhs
  1698   then have "int (nat \<bar>x\<bar>) dvd int (nat 1)" by simp
  1699   then have "nat \<bar>x\<bar> dvd 1" by (simp add: zdvd_int)
  1700   then have "nat \<bar>x\<bar> = 1" by simp
  1701   then show ?rhs by (cases "x < 0") auto
  1702 next
  1703   assume ?rhs
  1704   then have "x = 1 \<or> x = - 1" by auto
  1705   then show ?lhs by (auto intro: dvdI)
  1706 qed
  1707 
  1708 lemma zdvd_mult_cancel1:
  1709   fixes m :: int
  1710   assumes mp: "m \<noteq> 0"
  1711   shows "m * n dvd m \<longleftrightarrow> \<bar>n\<bar> = 1"
  1712     (is "?lhs \<longleftrightarrow> ?rhs")
  1713 proof
  1714   assume ?rhs
  1715   then show ?lhs
  1716     by (cases "n > 0") (auto simp add: minus_equation_iff)
  1717 next
  1718   assume ?lhs
  1719   then have "m * n dvd m * 1" by simp
  1720   from zdvd_mult_cancel[OF this mp] show ?rhs
  1721     by (simp only: zdvd1_eq)
  1722 qed
  1723 
  1724 lemma int_dvd_iff: "int m dvd z \<longleftrightarrow> m dvd nat \<bar>z\<bar>"
  1725   by (cases "z \<ge> 0") (simp_all add: zdvd_int)
  1726 
  1727 lemma dvd_int_iff: "z dvd int m \<longleftrightarrow> nat \<bar>z\<bar> dvd m"
  1728   by (cases "z \<ge> 0") (simp_all add: zdvd_int)
  1729 
  1730 lemma dvd_int_unfold_dvd_nat: "k dvd l \<longleftrightarrow> nat \<bar>k\<bar> dvd nat \<bar>l\<bar>"
  1731   by (simp add: dvd_int_iff [symmetric])
  1732 
  1733 lemma nat_dvd_iff: "nat z dvd m \<longleftrightarrow> (if 0 \<le> z then z dvd int m else m = 0)"
  1734   by (auto simp add: dvd_int_iff)
  1735 
  1736 lemma eq_nat_nat_iff: "0 \<le> z \<Longrightarrow> 0 \<le> z' \<Longrightarrow> nat z = nat z' \<longleftrightarrow> z = z'"
  1737   by (auto elim!: nonneg_eq_int)
  1738 
  1739 lemma nat_power_eq: "0 \<le> z \<Longrightarrow> nat (z ^ n) = nat z ^ n"
  1740   by (induct n) (simp_all add: nat_mult_distrib)
  1741 
  1742 lemma numeral_power_eq_nat_cancel_iff [simp]:
  1743   "numeral x ^ n = nat y \<longleftrightarrow> numeral x ^ n = y"
  1744   using nat_eq_iff2 by auto
  1745 
  1746 lemma nat_eq_numeral_power_cancel_iff [simp]:
  1747   "nat y = numeral x ^ n \<longleftrightarrow> y = numeral x ^ n"
  1748   using numeral_power_eq_nat_cancel_iff[of x n y]
  1749   by (metis (mono_tags))
  1750 
  1751 lemma numeral_power_le_nat_cancel_iff [simp]:
  1752   "numeral x ^ n \<le> nat a \<longleftrightarrow> numeral x ^ n \<le> a"
  1753   using nat_le_eq_zle[of "numeral x ^ n" a]
  1754   by (auto simp: nat_power_eq)
  1755 
  1756 lemma nat_le_numeral_power_cancel_iff [simp]:
  1757   "nat a \<le> numeral x ^ n \<longleftrightarrow> a \<le> numeral x ^ n"
  1758   by (simp add: nat_le_iff)
  1759 
  1760 lemma numeral_power_less_nat_cancel_iff [simp]:
  1761   "numeral x ^ n < nat a \<longleftrightarrow> numeral x ^ n < a"
  1762   using nat_less_eq_zless[of "numeral x ^ n" a]
  1763   by (auto simp: nat_power_eq)
  1764 
  1765 lemma nat_less_numeral_power_cancel_iff [simp]:
  1766   "nat a < numeral x ^ n \<longleftrightarrow> a < numeral x ^ n"
  1767   using nat_less_eq_zless[of a "numeral x ^ n"]
  1768   by (cases "a < 0") (auto simp: nat_power_eq less_le_trans[where y=0])
  1769 
  1770 lemma zdvd_imp_le: "z dvd n \<Longrightarrow> 0 < n \<Longrightarrow> z \<le> n"
  1771   for n z :: int
  1772   apply (cases n)
  1773    apply (auto simp add: dvd_int_iff)
  1774   apply (cases z)
  1775    apply (auto simp add: dvd_imp_le)
  1776   done
  1777 
  1778 lemma zdvd_period:
  1779   fixes a d :: int
  1780   assumes "a dvd d"
  1781   shows "a dvd (x + t) \<longleftrightarrow> a dvd ((x + c * d) + t)"
  1782     (is "?lhs \<longleftrightarrow> ?rhs")
  1783 proof -
  1784   from assms have "a dvd (x + t) \<longleftrightarrow> a dvd ((x + t) + c * d)"
  1785     by (simp add: dvd_add_left_iff)
  1786   then show ?thesis
  1787     by (simp add: ac_simps)
  1788 qed
  1789 
  1790 
  1791 subsection \<open>Finiteness of intervals\<close>
  1792 
  1793 lemma finite_interval_int1 [iff]: "finite {i :: int. a \<le> i \<and> i \<le> b}"
  1794 proof (cases "a \<le> b")
  1795   case True
  1796   then show ?thesis
  1797   proof (induct b rule: int_ge_induct)
  1798     case base
  1799     have "{i. a \<le> i \<and> i \<le> a} = {a}" by auto
  1800     then show ?case by simp
  1801   next
  1802     case (step b)
  1803     then have "{i. a \<le> i \<and> i \<le> b + 1} = {i. a \<le> i \<and> i \<le> b} \<union> {b + 1}" by auto
  1804     with step show ?case by simp
  1805   qed
  1806 next
  1807   case False
  1808   then show ?thesis
  1809     by (metis (lifting, no_types) Collect_empty_eq finite.emptyI order_trans)
  1810 qed
  1811 
  1812 lemma finite_interval_int2 [iff]: "finite {i :: int. a \<le> i \<and> i < b}"
  1813   by (rule rev_finite_subset[OF finite_interval_int1[of "a" "b"]]) auto
  1814 
  1815 lemma finite_interval_int3 [iff]: "finite {i :: int. a < i \<and> i \<le> b}"
  1816   by (rule rev_finite_subset[OF finite_interval_int1[of "a" "b"]]) auto
  1817 
  1818 lemma finite_interval_int4 [iff]: "finite {i :: int. a < i \<and> i < b}"
  1819   by (rule rev_finite_subset[OF finite_interval_int1[of "a" "b"]]) auto
  1820 
  1821 
  1822 subsection \<open>Configuration of the code generator\<close>
  1823 
  1824 text \<open>Constructors\<close>
  1825 
  1826 definition Pos :: "num \<Rightarrow> int"
  1827   where [simp, code_abbrev]: "Pos = numeral"
  1828 
  1829 definition Neg :: "num \<Rightarrow> int"
  1830   where [simp, code_abbrev]: "Neg n = - (Pos n)"
  1831 
  1832 code_datatype "0::int" Pos Neg
  1833 
  1834 
  1835 text \<open>Auxiliary operations.\<close>
  1836 
  1837 definition dup :: "int \<Rightarrow> int"
  1838   where [simp]: "dup k = k + k"
  1839 
  1840 lemma dup_code [code]:
  1841   "dup 0 = 0"
  1842   "dup (Pos n) = Pos (Num.Bit0 n)"
  1843   "dup (Neg n) = Neg (Num.Bit0 n)"
  1844   by (simp_all add: numeral_Bit0)
  1845 
  1846 definition sub :: "num \<Rightarrow> num \<Rightarrow> int"
  1847   where [simp]: "sub m n = numeral m - numeral n"
  1848 
  1849 lemma sub_code [code]:
  1850   "sub Num.One Num.One = 0"
  1851   "sub (Num.Bit0 m) Num.One = Pos (Num.BitM m)"
  1852   "sub (Num.Bit1 m) Num.One = Pos (Num.Bit0 m)"
  1853   "sub Num.One (Num.Bit0 n) = Neg (Num.BitM n)"
  1854   "sub Num.One (Num.Bit1 n) = Neg (Num.Bit0 n)"
  1855   "sub (Num.Bit0 m) (Num.Bit0 n) = dup (sub m n)"
  1856   "sub (Num.Bit1 m) (Num.Bit1 n) = dup (sub m n)"
  1857   "sub (Num.Bit1 m) (Num.Bit0 n) = dup (sub m n) + 1"
  1858   "sub (Num.Bit0 m) (Num.Bit1 n) = dup (sub m n) - 1"
  1859   by (simp_all only: sub_def dup_def numeral.simps Pos_def Neg_def numeral_BitM)
  1860 
  1861 text \<open>Implementations.\<close>
  1862 
  1863 lemma one_int_code [code]: "1 = Pos Num.One"
  1864   by simp
  1865 
  1866 lemma plus_int_code [code]:
  1867   "k + 0 = k"
  1868   "0 + l = l"
  1869   "Pos m + Pos n = Pos (m + n)"
  1870   "Pos m + Neg n = sub m n"
  1871   "Neg m + Pos n = sub n m"
  1872   "Neg m + Neg n = Neg (m + n)"
  1873   for k l :: int
  1874   by simp_all
  1875 
  1876 lemma uminus_int_code [code]:
  1877   "uminus 0 = (0::int)"
  1878   "uminus (Pos m) = Neg m"
  1879   "uminus (Neg m) = Pos m"
  1880   by simp_all
  1881 
  1882 lemma minus_int_code [code]:
  1883   "k - 0 = k"
  1884   "0 - l = uminus l"
  1885   "Pos m - Pos n = sub m n"
  1886   "Pos m - Neg n = Pos (m + n)"
  1887   "Neg m - Pos n = Neg (m + n)"
  1888   "Neg m - Neg n = sub n m"
  1889   for k l :: int
  1890   by simp_all
  1891 
  1892 lemma times_int_code [code]:
  1893   "k * 0 = 0"
  1894   "0 * l = 0"
  1895   "Pos m * Pos n = Pos (m * n)"
  1896   "Pos m * Neg n = Neg (m * n)"
  1897   "Neg m * Pos n = Neg (m * n)"
  1898   "Neg m * Neg n = Pos (m * n)"
  1899   for k l :: int
  1900   by simp_all
  1901 
  1902 instantiation int :: equal
  1903 begin
  1904 
  1905 definition "HOL.equal k l \<longleftrightarrow> k = (l::int)"
  1906 
  1907 instance
  1908   by standard (rule equal_int_def)
  1909 
  1910 end
  1911 
  1912 lemma equal_int_code [code]:
  1913   "HOL.equal 0 (0::int) \<longleftrightarrow> True"
  1914   "HOL.equal 0 (Pos l) \<longleftrightarrow> False"
  1915   "HOL.equal 0 (Neg l) \<longleftrightarrow> False"
  1916   "HOL.equal (Pos k) 0 \<longleftrightarrow> False"
  1917   "HOL.equal (Pos k) (Pos l) \<longleftrightarrow> HOL.equal k l"
  1918   "HOL.equal (Pos k) (Neg l) \<longleftrightarrow> False"
  1919   "HOL.equal (Neg k) 0 \<longleftrightarrow> False"
  1920   "HOL.equal (Neg k) (Pos l) \<longleftrightarrow> False"
  1921   "HOL.equal (Neg k) (Neg l) \<longleftrightarrow> HOL.equal k l"
  1922   by (auto simp add: equal)
  1923 
  1924 lemma equal_int_refl [code nbe]: "HOL.equal k k \<longleftrightarrow> True"
  1925   for k :: int
  1926   by (fact equal_refl)
  1927 
  1928 lemma less_eq_int_code [code]:
  1929   "0 \<le> (0::int) \<longleftrightarrow> True"
  1930   "0 \<le> Pos l \<longleftrightarrow> True"
  1931   "0 \<le> Neg l \<longleftrightarrow> False"
  1932   "Pos k \<le> 0 \<longleftrightarrow> False"
  1933   "Pos k \<le> Pos l \<longleftrightarrow> k \<le> l"
  1934   "Pos k \<le> Neg l \<longleftrightarrow> False"
  1935   "Neg k \<le> 0 \<longleftrightarrow> True"
  1936   "Neg k \<le> Pos l \<longleftrightarrow> True"
  1937   "Neg k \<le> Neg l \<longleftrightarrow> l \<le> k"
  1938   by simp_all
  1939 
  1940 lemma less_int_code [code]:
  1941   "0 < (0::int) \<longleftrightarrow> False"
  1942   "0 < Pos l \<longleftrightarrow> True"
  1943   "0 < Neg l \<longleftrightarrow> False"
  1944   "Pos k < 0 \<longleftrightarrow> False"
  1945   "Pos k < Pos l \<longleftrightarrow> k < l"
  1946   "Pos k < Neg l \<longleftrightarrow> False"
  1947   "Neg k < 0 \<longleftrightarrow> True"
  1948   "Neg k < Pos l \<longleftrightarrow> True"
  1949   "Neg k < Neg l \<longleftrightarrow> l < k"
  1950   by simp_all
  1951 
  1952 lemma nat_code [code]:
  1953   "nat (Int.Neg k) = 0"
  1954   "nat 0 = 0"
  1955   "nat (Int.Pos k) = nat_of_num k"
  1956   by (simp_all add: nat_of_num_numeral)
  1957 
  1958 lemma (in ring_1) of_int_code [code]:
  1959   "of_int (Int.Neg k) = - numeral k"
  1960   "of_int 0 = 0"
  1961   "of_int (Int.Pos k) = numeral k"
  1962   by simp_all
  1963 
  1964 
  1965 text \<open>Serializer setup.\<close>
  1966 
  1967 code_identifier
  1968   code_module Int \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
  1969 
  1970 quickcheck_params [default_type = int]
  1971 
  1972 hide_const (open) Pos Neg sub dup
  1973 
  1974 
  1975 text \<open>De-register \<open>int\<close> as a quotient type:\<close>
  1976 
  1977 lifting_update int.lifting
  1978 lifting_forget int.lifting
  1979 
  1980 end