src/HOL/NthRoot.thy
author blanchet
Tue Nov 07 15:16:42 2017 +0100 (19 months ago)
changeset 67022 49309fe530fd
parent 66815 93c6632ddf44
child 67685 bdff8bf0a75b
permissions -rw-r--r--
more robust parsing for THF proofs (esp. polymorphic Leo-III proofs)
     1 (*  Title:      HOL/NthRoot.thy
     2     Author:     Jacques D. Fleuriot, 1998
     3     Author:     Lawrence C Paulson, 2004
     4 *)
     5 
     6 section \<open>Nth Roots of Real Numbers\<close>
     7 
     8 theory NthRoot
     9   imports Deriv
    10 begin
    11 
    12 
    13 subsection \<open>Existence of Nth Root\<close>
    14 
    15 text \<open>Existence follows from the Intermediate Value Theorem\<close>
    16 
    17 lemma realpow_pos_nth:
    18   fixes a :: real
    19   assumes n: "0 < n"
    20     and a: "0 < a"
    21   shows "\<exists>r>0. r ^ n = a"
    22 proof -
    23   have "\<exists>r\<ge>0. r \<le> (max 1 a) \<and> r ^ n = a"
    24   proof (rule IVT)
    25     show "0 ^ n \<le> a"
    26       using n a by (simp add: power_0_left)
    27     show "0 \<le> max 1 a"
    28       by simp
    29     from n have n1: "1 \<le> n"
    30       by simp
    31     have "a \<le> max 1 a ^ 1"
    32       by simp
    33     also have "max 1 a ^ 1 \<le> max 1 a ^ n"
    34       using n1 by (rule power_increasing) simp
    35     finally show "a \<le> max 1 a ^ n" .
    36     show "\<forall>r. 0 \<le> r \<and> r \<le> max 1 a \<longrightarrow> isCont (\<lambda>x. x ^ n) r"
    37       by simp
    38   qed
    39   then obtain r where r: "0 \<le> r \<and> r ^ n = a"
    40     by fast
    41   with n a have "r \<noteq> 0"
    42     by (auto simp add: power_0_left)
    43   with r have "0 < r \<and> r ^ n = a"
    44     by simp
    45   then show ?thesis ..
    46 qed
    47 
    48 (* Used by Integration/RealRandVar.thy in AFP *)
    49 lemma realpow_pos_nth2: "(0::real) < a \<Longrightarrow> \<exists>r>0. r ^ Suc n = a"
    50   by (blast intro: realpow_pos_nth)
    51 
    52 text \<open>Uniqueness of nth positive root.\<close>
    53 lemma realpow_pos_nth_unique: "0 < n \<Longrightarrow> 0 < a \<Longrightarrow> \<exists>!r. 0 < r \<and> r ^ n = a" for a :: real
    54   by (auto intro!: realpow_pos_nth simp: power_eq_iff_eq_base)
    55 
    56 
    57 subsection \<open>Nth Root\<close>
    58 
    59 text \<open>
    60   We define roots of negative reals such that \<open>root n (- x) = - root n x\<close>.
    61   This allows us to omit side conditions from many theorems.
    62 \<close>
    63 
    64 lemma inj_sgn_power:
    65   assumes "0 < n"
    66   shows "inj (\<lambda>y. sgn y * \<bar>y\<bar>^n :: real)"
    67     (is "inj ?f")
    68 proof (rule injI)
    69   have x: "(0 < a \<and> b < 0) \<or> (a < 0 \<and> 0 < b) \<Longrightarrow> a \<noteq> b" for a b :: real
    70     by auto
    71   fix x y
    72   assume "?f x = ?f y"
    73   with power_eq_iff_eq_base[of n "\<bar>x\<bar>" "\<bar>y\<bar>"] \<open>0 < n\<close> show "x = y"
    74     by (cases rule: linorder_cases[of 0 x, case_product linorder_cases[of 0 y]])
    75        (simp_all add: x)
    76 qed
    77 
    78 lemma sgn_power_injE:
    79   "sgn a * \<bar>a\<bar> ^ n = x \<Longrightarrow> x = sgn b * \<bar>b\<bar> ^ n \<Longrightarrow> 0 < n \<Longrightarrow> a = b"
    80   for a b :: real
    81   using inj_sgn_power[THEN injD, of n a b] by simp
    82 
    83 definition root :: "nat \<Rightarrow> real \<Rightarrow> real"
    84   where "root n x = (if n = 0 then 0 else the_inv (\<lambda>y. sgn y * \<bar>y\<bar>^n) x)"
    85 
    86 lemma root_0 [simp]: "root 0 x = 0"
    87   by (simp add: root_def)
    88 
    89 lemma root_sgn_power: "0 < n \<Longrightarrow> root n (sgn y * \<bar>y\<bar>^n) = y"
    90   using the_inv_f_f[OF inj_sgn_power] by (simp add: root_def)
    91 
    92 lemma sgn_power_root:
    93   assumes "0 < n"
    94   shows "sgn (root n x) * \<bar>(root n x)\<bar>^n = x"
    95     (is "?f (root n x) = x")
    96 proof (cases "x = 0")
    97   case True
    98   with assms root_sgn_power[of n 0] show ?thesis
    99     by simp
   100 next
   101   case False
   102   with realpow_pos_nth[OF \<open>0 < n\<close>, of "\<bar>x\<bar>"]
   103   obtain r where "0 < r" "r ^ n = \<bar>x\<bar>"
   104     by auto
   105   with \<open>x \<noteq> 0\<close> have S: "x \<in> range ?f"
   106     by (intro image_eqI[of _ _ "sgn x * r"])
   107        (auto simp: abs_mult sgn_mult power_mult_distrib abs_sgn_eq mult_sgn_abs)
   108   from \<open>0 < n\<close> f_the_inv_into_f[OF inj_sgn_power[OF \<open>0 < n\<close>] this]  show ?thesis
   109     by (simp add: root_def)
   110 qed
   111 
   112 lemma split_root: "P (root n x) \<longleftrightarrow> (n = 0 \<longrightarrow> P 0) \<and> (0 < n \<longrightarrow> (\<forall>y. sgn y * \<bar>y\<bar>^n = x \<longrightarrow> P y))"
   113 proof (cases "n = 0")
   114   case True
   115   then show ?thesis by simp
   116 next
   117   case False
   118   then show ?thesis
   119     by simp (metis root_sgn_power sgn_power_root)
   120 qed
   121 
   122 lemma real_root_zero [simp]: "root n 0 = 0"
   123   by (simp split: split_root add: sgn_zero_iff)
   124 
   125 lemma real_root_minus: "root n (- x) = - root n x"
   126   by (clarsimp split: split_root elim!: sgn_power_injE simp: sgn_minus)
   127 
   128 lemma real_root_less_mono: "0 < n \<Longrightarrow> x < y \<Longrightarrow> root n x < root n y"
   129 proof (clarsimp split: split_root)
   130   have *: "0 < b \<Longrightarrow> a < 0 \<Longrightarrow> \<not> a > b" for a b :: real
   131     by auto
   132   fix a b :: real
   133   assume "0 < n" "sgn a * \<bar>a\<bar> ^ n < sgn b * \<bar>b\<bar> ^ n"
   134   then show "a < b"
   135     using power_less_imp_less_base[of a n b]
   136       power_less_imp_less_base[of "- b" n "- a"]
   137     by (simp add: sgn_real_def * [of "a ^ n" "- ((- b) ^ n)"]
   138         split: if_split_asm)
   139 qed
   140 
   141 lemma real_root_gt_zero: "0 < n \<Longrightarrow> 0 < x \<Longrightarrow> 0 < root n x"
   142   using real_root_less_mono[of n 0 x] by simp
   143 
   144 lemma real_root_ge_zero: "0 \<le> x \<Longrightarrow> 0 \<le> root n x"
   145   using real_root_gt_zero[of n x]
   146   by (cases "n = 0") (auto simp add: le_less)
   147 
   148 lemma real_root_pow_pos: "0 < n \<Longrightarrow> 0 < x \<Longrightarrow> root n x ^ n = x"  (* TODO: rename *)
   149   using sgn_power_root[of n x] real_root_gt_zero[of n x] by simp
   150 
   151 lemma real_root_pow_pos2 [simp]: "0 < n \<Longrightarrow> 0 \<le> x \<Longrightarrow> root n x ^ n = x"  (* TODO: rename *)
   152   by (auto simp add: order_le_less real_root_pow_pos)
   153 
   154 lemma sgn_root: "0 < n \<Longrightarrow> sgn (root n x) = sgn x"
   155   by (auto split: split_root simp: sgn_real_def)
   156 
   157 lemma odd_real_root_pow: "odd n \<Longrightarrow> root n x ^ n = x"
   158   using sgn_power_root[of n x]
   159   by (simp add: odd_pos sgn_real_def split: if_split_asm)
   160 
   161 lemma real_root_power_cancel: "0 < n \<Longrightarrow> 0 \<le> x \<Longrightarrow> root n (x ^ n) = x"
   162   using root_sgn_power[of n x] by (auto simp add: le_less power_0_left)
   163 
   164 lemma odd_real_root_power_cancel: "odd n \<Longrightarrow> root n (x ^ n) = x"
   165   using root_sgn_power[of n x]
   166   by (simp add: odd_pos sgn_real_def power_0_left split: if_split_asm)
   167 
   168 lemma real_root_pos_unique: "0 < n \<Longrightarrow> 0 \<le> y \<Longrightarrow> y ^ n = x \<Longrightarrow> root n x = y"
   169   using root_sgn_power[of n y] by (auto simp add: le_less power_0_left)
   170 
   171 lemma odd_real_root_unique: "odd n \<Longrightarrow> y ^ n = x \<Longrightarrow> root n x = y"
   172   by (erule subst, rule odd_real_root_power_cancel)
   173 
   174 lemma real_root_one [simp]: "0 < n \<Longrightarrow> root n 1 = 1"
   175   by (simp add: real_root_pos_unique)
   176 
   177 text \<open>Root function is strictly monotonic, hence injective.\<close>
   178 
   179 lemma real_root_le_mono: "0 < n \<Longrightarrow> x \<le> y \<Longrightarrow> root n x \<le> root n y"
   180   by (auto simp add: order_le_less real_root_less_mono)
   181 
   182 lemma real_root_less_iff [simp]: "0 < n \<Longrightarrow> root n x < root n y \<longleftrightarrow> x < y"
   183   by (cases "x < y") (simp_all add: real_root_less_mono linorder_not_less real_root_le_mono)
   184 
   185 lemma real_root_le_iff [simp]: "0 < n \<Longrightarrow> root n x \<le> root n y \<longleftrightarrow> x \<le> y"
   186   by (cases "x \<le> y") (simp_all add: real_root_le_mono linorder_not_le real_root_less_mono)
   187 
   188 lemma real_root_eq_iff [simp]: "0 < n \<Longrightarrow> root n x = root n y \<longleftrightarrow> x = y"
   189   by (simp add: order_eq_iff)
   190 
   191 lemmas real_root_gt_0_iff [simp] = real_root_less_iff [where x=0, simplified]
   192 lemmas real_root_lt_0_iff [simp] = real_root_less_iff [where y=0, simplified]
   193 lemmas real_root_ge_0_iff [simp] = real_root_le_iff [where x=0, simplified]
   194 lemmas real_root_le_0_iff [simp] = real_root_le_iff [where y=0, simplified]
   195 lemmas real_root_eq_0_iff [simp] = real_root_eq_iff [where y=0, simplified]
   196 
   197 lemma real_root_gt_1_iff [simp]: "0 < n \<Longrightarrow> 1 < root n y \<longleftrightarrow> 1 < y"
   198   using real_root_less_iff [where x=1] by simp
   199 
   200 lemma real_root_lt_1_iff [simp]: "0 < n \<Longrightarrow> root n x < 1 \<longleftrightarrow> x < 1"
   201   using real_root_less_iff [where y=1] by simp
   202 
   203 lemma real_root_ge_1_iff [simp]: "0 < n \<Longrightarrow> 1 \<le> root n y \<longleftrightarrow> 1 \<le> y"
   204   using real_root_le_iff [where x=1] by simp
   205 
   206 lemma real_root_le_1_iff [simp]: "0 < n \<Longrightarrow> root n x \<le> 1 \<longleftrightarrow> x \<le> 1"
   207   using real_root_le_iff [where y=1] by simp
   208 
   209 lemma real_root_eq_1_iff [simp]: "0 < n \<Longrightarrow> root n x = 1 \<longleftrightarrow> x = 1"
   210   using real_root_eq_iff [where y=1] by simp
   211 
   212 
   213 text \<open>Roots of multiplication and division.\<close>
   214 
   215 lemma real_root_mult: "root n (x * y) = root n x * root n y"
   216   by (auto split: split_root elim!: sgn_power_injE
   217       simp: sgn_mult abs_mult power_mult_distrib)
   218 
   219 lemma real_root_inverse: "root n (inverse x) = inverse (root n x)"
   220   by (auto split: split_root elim!: sgn_power_injE
   221       simp: power_inverse)
   222 
   223 lemma real_root_divide: "root n (x / y) = root n x / root n y"
   224   by (simp add: divide_inverse real_root_mult real_root_inverse)
   225 
   226 lemma real_root_abs: "0 < n \<Longrightarrow> root n \<bar>x\<bar> = \<bar>root n x\<bar>"
   227   by (simp add: abs_if real_root_minus)
   228 
   229 lemma real_root_power: "0 < n \<Longrightarrow> root n (x ^ k) = root n x ^ k"
   230   by (induct k) (simp_all add: real_root_mult)
   231 
   232 
   233 text \<open>Roots of roots.\<close>
   234 
   235 lemma real_root_Suc_0 [simp]: "root (Suc 0) x = x"
   236   by (simp add: odd_real_root_unique)
   237 
   238 lemma real_root_mult_exp: "root (m * n) x = root m (root n x)"
   239   by (auto split: split_root elim!: sgn_power_injE
   240       simp: sgn_zero_iff sgn_mult power_mult[symmetric]
   241       abs_mult power_mult_distrib abs_sgn_eq)
   242 
   243 lemma real_root_commute: "root m (root n x) = root n (root m x)"
   244   by (simp add: real_root_mult_exp [symmetric] mult.commute)
   245 
   246 
   247 text \<open>Monotonicity in first argument.\<close>
   248 
   249 lemma real_root_strict_decreasing:
   250   assumes "0 < n" "n < N" "1 < x"
   251   shows "root N x < root n x"
   252 proof -
   253   from assms have "root n (root N x) ^ n < root N (root n x) ^ N"
   254     by (simp add: real_root_commute power_strict_increasing del: real_root_pow_pos2)
   255   with assms show ?thesis by simp
   256 qed
   257 
   258 lemma real_root_strict_increasing:
   259   assumes "0 < n" "n < N" "0 < x" "x < 1"
   260   shows "root n x < root N x"
   261 proof -
   262   from assms have "root N (root n x) ^ N < root n (root N x) ^ n"
   263     by (simp add: real_root_commute power_strict_decreasing del: real_root_pow_pos2)
   264   with assms show ?thesis by simp
   265 qed
   266 
   267 lemma real_root_decreasing: "0 < n \<Longrightarrow> n < N \<Longrightarrow> 1 \<le> x \<Longrightarrow> root N x \<le> root n x"
   268   by (auto simp add: order_le_less real_root_strict_decreasing)
   269 
   270 lemma real_root_increasing: "0 < n \<Longrightarrow> n < N \<Longrightarrow> 0 \<le> x \<Longrightarrow> x \<le> 1 \<Longrightarrow> root n x \<le> root N x"
   271   by (auto simp add: order_le_less real_root_strict_increasing)
   272 
   273 
   274 text \<open>Continuity and derivatives.\<close>
   275 
   276 lemma isCont_real_root: "isCont (root n) x"
   277 proof (cases "n > 0")
   278   case True
   279   let ?f = "\<lambda>y::real. sgn y * \<bar>y\<bar>^n"
   280   have "continuous_on ({0..} \<union> {.. 0}) (\<lambda>x. if 0 < x then x ^ n else - ((-x) ^ n) :: real)"
   281     using True by (intro continuous_on_If continuous_intros) auto
   282   then have "continuous_on UNIV ?f"
   283     by (rule continuous_on_cong[THEN iffD1, rotated 2]) (auto simp: not_less le_less True)
   284   then have [simp]: "isCont ?f x" for x
   285     by (simp add: continuous_on_eq_continuous_at)
   286   have "isCont (root n) (?f (root n x))"
   287     by (rule isCont_inverse_function [where f="?f" and d=1]) (auto simp: root_sgn_power True)
   288   then show ?thesis
   289     by (simp add: sgn_power_root True)
   290 next
   291   case False
   292   then show ?thesis
   293     by (simp add: root_def[abs_def])
   294 qed
   295 
   296 lemma tendsto_real_root [tendsto_intros]:
   297   "(f \<longlongrightarrow> x) F \<Longrightarrow> ((\<lambda>x. root n (f x)) \<longlongrightarrow> root n x) F"
   298   using isCont_tendsto_compose[OF isCont_real_root, of f x F] .
   299 
   300 lemma continuous_real_root [continuous_intros]:
   301   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. root n (f x))"
   302   unfolding continuous_def by (rule tendsto_real_root)
   303 
   304 lemma continuous_on_real_root [continuous_intros]:
   305   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. root n (f x))"
   306   unfolding continuous_on_def by (auto intro: tendsto_real_root)
   307 
   308 lemma DERIV_real_root:
   309   assumes n: "0 < n"
   310     and x: "0 < x"
   311   shows "DERIV (root n) x :> inverse (real n * root n x ^ (n - Suc 0))"
   312 proof (rule DERIV_inverse_function)
   313   show "0 < x"
   314     using x .
   315   show "x < x + 1"
   316     by simp
   317   show "\<forall>y. 0 < y \<and> y < x + 1 \<longrightarrow> root n y ^ n = y"
   318     using n by simp
   319   show "DERIV (\<lambda>x. x ^ n) (root n x) :> real n * root n x ^ (n - Suc 0)"
   320     by (rule DERIV_pow)
   321   show "real n * root n x ^ (n - Suc 0) \<noteq> 0"
   322     using n x by simp
   323   show "isCont (root n) x"
   324     by (rule isCont_real_root)
   325 qed
   326 
   327 lemma DERIV_odd_real_root:
   328   assumes n: "odd n"
   329     and x: "x \<noteq> 0"
   330   shows "DERIV (root n) x :> inverse (real n * root n x ^ (n - Suc 0))"
   331 proof (rule DERIV_inverse_function)
   332   show "x - 1 < x"
   333     by simp
   334   show "x < x + 1"
   335     by simp
   336   show "\<forall>y. x - 1 < y \<and> y < x + 1 \<longrightarrow> root n y ^ n = y"
   337     using n by (simp add: odd_real_root_pow)
   338   show "DERIV (\<lambda>x. x ^ n) (root n x) :> real n * root n x ^ (n - Suc 0)"
   339     by (rule DERIV_pow)
   340   show "real n * root n x ^ (n - Suc 0) \<noteq> 0"
   341     using odd_pos [OF n] x by simp
   342   show "isCont (root n) x"
   343     by (rule isCont_real_root)
   344 qed
   345 
   346 lemma DERIV_even_real_root:
   347   assumes n: "0 < n"
   348     and "even n"
   349     and x: "x < 0"
   350   shows "DERIV (root n) x :> inverse (- real n * root n x ^ (n - Suc 0))"
   351 proof (rule DERIV_inverse_function)
   352   show "x - 1 < x"
   353     by simp
   354   show "x < 0"
   355     using x .
   356   show "\<forall>y. x - 1 < y \<and> y < 0 \<longrightarrow> - (root n y ^ n) = y"
   357   proof (rule allI, rule impI, erule conjE)
   358     fix y assume "x - 1 < y" and "y < 0"
   359     then have "root n (-y) ^ n = -y" using \<open>0 < n\<close> by simp
   360     with real_root_minus and \<open>even n\<close>
   361     show "- (root n y ^ n) = y" by simp
   362   qed
   363   show "DERIV (\<lambda>x. - (x ^ n)) (root n x) :> - real n * root n x ^ (n - Suc 0)"
   364     by  (auto intro!: derivative_eq_intros)
   365   show "- real n * root n x ^ (n - Suc 0) \<noteq> 0"
   366     using n x by simp
   367   show "isCont (root n) x"
   368     by (rule isCont_real_root)
   369 qed
   370 
   371 lemma DERIV_real_root_generic:
   372   assumes "0 < n"
   373     and "x \<noteq> 0"
   374     and "even n \<Longrightarrow> 0 < x \<Longrightarrow> D = inverse (real n * root n x ^ (n - Suc 0))"
   375     and "even n \<Longrightarrow> x < 0 \<Longrightarrow> D = - inverse (real n * root n x ^ (n - Suc 0))"
   376     and "odd n \<Longrightarrow> D = inverse (real n * root n x ^ (n - Suc 0))"
   377   shows "DERIV (root n) x :> D"
   378   using assms
   379   by (cases "even n", cases "0 < x")
   380     (auto intro: DERIV_real_root[THEN DERIV_cong]
   381       DERIV_odd_real_root[THEN DERIV_cong]
   382       DERIV_even_real_root[THEN DERIV_cong])
   383 
   384 
   385 subsection \<open>Square Root\<close>
   386 
   387 definition sqrt :: "real \<Rightarrow> real"
   388   where "sqrt = root 2"
   389 
   390 lemma pos2: "0 < (2::nat)"
   391   by simp
   392 
   393 lemma real_sqrt_unique: "y\<^sup>2 = x \<Longrightarrow> 0 \<le> y \<Longrightarrow> sqrt x = y"
   394   unfolding sqrt_def by (rule real_root_pos_unique [OF pos2])
   395 
   396 lemma real_sqrt_abs [simp]: "sqrt (x\<^sup>2) = \<bar>x\<bar>"
   397   apply (rule real_sqrt_unique)
   398    apply (rule power2_abs)
   399   apply (rule abs_ge_zero)
   400   done
   401 
   402 lemma real_sqrt_pow2 [simp]: "0 \<le> x \<Longrightarrow> (sqrt x)\<^sup>2 = x"
   403   unfolding sqrt_def by (rule real_root_pow_pos2 [OF pos2])
   404 
   405 lemma real_sqrt_pow2_iff [simp]: "(sqrt x)\<^sup>2 = x \<longleftrightarrow> 0 \<le> x"
   406   apply (rule iffI)
   407    apply (erule subst)
   408    apply (rule zero_le_power2)
   409   apply (erule real_sqrt_pow2)
   410   done
   411 
   412 lemma real_sqrt_zero [simp]: "sqrt 0 = 0"
   413   unfolding sqrt_def by (rule real_root_zero)
   414 
   415 lemma real_sqrt_one [simp]: "sqrt 1 = 1"
   416   unfolding sqrt_def by (rule real_root_one [OF pos2])
   417 
   418 lemma real_sqrt_four [simp]: "sqrt 4 = 2"
   419   using real_sqrt_abs[of 2] by simp
   420 
   421 lemma real_sqrt_minus: "sqrt (- x) = - sqrt x"
   422   unfolding sqrt_def by (rule real_root_minus)
   423 
   424 lemma real_sqrt_mult: "sqrt (x * y) = sqrt x * sqrt y"
   425   unfolding sqrt_def by (rule real_root_mult)
   426 
   427 lemma real_sqrt_mult_self[simp]: "sqrt a * sqrt a = \<bar>a\<bar>"
   428   using real_sqrt_abs[of a] unfolding power2_eq_square real_sqrt_mult .
   429 
   430 lemma real_sqrt_inverse: "sqrt (inverse x) = inverse (sqrt x)"
   431   unfolding sqrt_def by (rule real_root_inverse)
   432 
   433 lemma real_sqrt_divide: "sqrt (x / y) = sqrt x / sqrt y"
   434   unfolding sqrt_def by (rule real_root_divide)
   435 
   436 lemma real_sqrt_power: "sqrt (x ^ k) = sqrt x ^ k"
   437   unfolding sqrt_def by (rule real_root_power [OF pos2])
   438 
   439 lemma real_sqrt_gt_zero: "0 < x \<Longrightarrow> 0 < sqrt x"
   440   unfolding sqrt_def by (rule real_root_gt_zero [OF pos2])
   441 
   442 lemma real_sqrt_ge_zero: "0 \<le> x \<Longrightarrow> 0 \<le> sqrt x"
   443   unfolding sqrt_def by (rule real_root_ge_zero)
   444 
   445 lemma real_sqrt_less_mono: "x < y \<Longrightarrow> sqrt x < sqrt y"
   446   unfolding sqrt_def by (rule real_root_less_mono [OF pos2])
   447 
   448 lemma real_sqrt_le_mono: "x \<le> y \<Longrightarrow> sqrt x \<le> sqrt y"
   449   unfolding sqrt_def by (rule real_root_le_mono [OF pos2])
   450 
   451 lemma real_sqrt_less_iff [simp]: "sqrt x < sqrt y \<longleftrightarrow> x < y"
   452   unfolding sqrt_def by (rule real_root_less_iff [OF pos2])
   453 
   454 lemma real_sqrt_le_iff [simp]: "sqrt x \<le> sqrt y \<longleftrightarrow> x \<le> y"
   455   unfolding sqrt_def by (rule real_root_le_iff [OF pos2])
   456 
   457 lemma real_sqrt_eq_iff [simp]: "sqrt x = sqrt y \<longleftrightarrow> x = y"
   458   unfolding sqrt_def by (rule real_root_eq_iff [OF pos2])
   459 
   460 lemma real_less_lsqrt: "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> x < y\<^sup>2 \<Longrightarrow> sqrt x < y"
   461   using real_sqrt_less_iff[of x "y\<^sup>2"] by simp
   462 
   463 lemma real_le_lsqrt: "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> x \<le> y\<^sup>2 \<Longrightarrow> sqrt x \<le> y"
   464   using real_sqrt_le_iff[of x "y\<^sup>2"] by simp
   465 
   466 lemma real_le_rsqrt: "x\<^sup>2 \<le> y \<Longrightarrow> x \<le> sqrt y"
   467   using real_sqrt_le_mono[of "x\<^sup>2" y] by simp
   468 
   469 lemma real_less_rsqrt: "x\<^sup>2 < y \<Longrightarrow> x < sqrt y"
   470   using real_sqrt_less_mono[of "x\<^sup>2" y] by simp
   471 
   472 lemma real_sqrt_power_even:
   473   assumes "even n" "x \<ge> 0"
   474   shows   "sqrt x ^ n = x ^ (n div 2)"
   475 proof -
   476   from assms obtain k where "n = 2*k" by (auto elim!: evenE)
   477   with assms show ?thesis by (simp add: power_mult)
   478 qed
   479 
   480 lemma sqrt_le_D: "sqrt x \<le> y \<Longrightarrow> x \<le> y\<^sup>2"
   481   by (meson not_le real_less_rsqrt)
   482 
   483 lemma sqrt_even_pow2:
   484   assumes n: "even n"
   485   shows "sqrt (2 ^ n) = 2 ^ (n div 2)"
   486 proof -
   487   from n obtain m where m: "n = 2 * m" ..
   488   from m have "sqrt (2 ^ n) = sqrt ((2 ^ m)\<^sup>2)"
   489     by (simp only: power_mult[symmetric] mult.commute)
   490   then show ?thesis
   491     using m by simp
   492 qed
   493 
   494 lemmas real_sqrt_gt_0_iff [simp] = real_sqrt_less_iff [where x=0, unfolded real_sqrt_zero]
   495 lemmas real_sqrt_lt_0_iff [simp] = real_sqrt_less_iff [where y=0, unfolded real_sqrt_zero]
   496 lemmas real_sqrt_ge_0_iff [simp] = real_sqrt_le_iff [where x=0, unfolded real_sqrt_zero]
   497 lemmas real_sqrt_le_0_iff [simp] = real_sqrt_le_iff [where y=0, unfolded real_sqrt_zero]
   498 lemmas real_sqrt_eq_0_iff [simp] = real_sqrt_eq_iff [where y=0, unfolded real_sqrt_zero]
   499 
   500 lemmas real_sqrt_gt_1_iff [simp] = real_sqrt_less_iff [where x=1, unfolded real_sqrt_one]
   501 lemmas real_sqrt_lt_1_iff [simp] = real_sqrt_less_iff [where y=1, unfolded real_sqrt_one]
   502 lemmas real_sqrt_ge_1_iff [simp] = real_sqrt_le_iff [where x=1, unfolded real_sqrt_one]
   503 lemmas real_sqrt_le_1_iff [simp] = real_sqrt_le_iff [where y=1, unfolded real_sqrt_one]
   504 lemmas real_sqrt_eq_1_iff [simp] = real_sqrt_eq_iff [where y=1, unfolded real_sqrt_one]
   505 
   506 lemma sqrt_add_le_add_sqrt:
   507   assumes "0 \<le> x" "0 \<le> y"
   508   shows "sqrt (x + y) \<le> sqrt x + sqrt y"
   509   by (rule power2_le_imp_le) (simp_all add: power2_sum assms)
   510 
   511 lemma isCont_real_sqrt: "isCont sqrt x"
   512   unfolding sqrt_def by (rule isCont_real_root)
   513 
   514 lemma tendsto_real_sqrt [tendsto_intros]:
   515   "(f \<longlongrightarrow> x) F \<Longrightarrow> ((\<lambda>x. sqrt (f x)) \<longlongrightarrow> sqrt x) F"
   516   unfolding sqrt_def by (rule tendsto_real_root)
   517 
   518 lemma continuous_real_sqrt [continuous_intros]:
   519   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. sqrt (f x))"
   520   unfolding sqrt_def by (rule continuous_real_root)
   521 
   522 lemma continuous_on_real_sqrt [continuous_intros]:
   523   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. sqrt (f x))"
   524   unfolding sqrt_def by (rule continuous_on_real_root)
   525 
   526 lemma DERIV_real_sqrt_generic:
   527   assumes "x \<noteq> 0"
   528     and "x > 0 \<Longrightarrow> D = inverse (sqrt x) / 2"
   529     and "x < 0 \<Longrightarrow> D = - inverse (sqrt x) / 2"
   530   shows "DERIV sqrt x :> D"
   531   using assms unfolding sqrt_def
   532   by (auto intro!: DERIV_real_root_generic)
   533 
   534 lemma DERIV_real_sqrt: "0 < x \<Longrightarrow> DERIV sqrt x :> inverse (sqrt x) / 2"
   535   using DERIV_real_sqrt_generic by simp
   536 
   537 declare
   538   DERIV_real_sqrt_generic[THEN DERIV_chain2, derivative_intros]
   539   DERIV_real_root_generic[THEN DERIV_chain2, derivative_intros]
   540 
   541 lemma not_real_square_gt_zero [simp]: "\<not> 0 < x * x \<longleftrightarrow> x = 0"
   542   for x :: real
   543   apply auto
   544   using linorder_less_linear [where x = x and y = 0]
   545   apply (simp add: zero_less_mult_iff)
   546   done
   547 
   548 lemma real_sqrt_abs2 [simp]: "sqrt (x * x) = \<bar>x\<bar>"
   549   apply (subst power2_eq_square [symmetric])
   550   apply (rule real_sqrt_abs)
   551   done
   552 
   553 lemma real_inv_sqrt_pow2: "0 < x \<Longrightarrow> (inverse (sqrt x))\<^sup>2 = inverse x"
   554   by (simp add: power_inverse)
   555 
   556 lemma real_sqrt_eq_zero_cancel: "0 \<le> x \<Longrightarrow> sqrt x = 0 \<Longrightarrow> x = 0"
   557   by simp
   558 
   559 lemma real_sqrt_ge_one: "1 \<le> x \<Longrightarrow> 1 \<le> sqrt x"
   560   by simp
   561 
   562 lemma sqrt_divide_self_eq:
   563   assumes nneg: "0 \<le> x"
   564   shows "sqrt x / x = inverse (sqrt x)"
   565 proof (cases "x = 0")
   566   case True
   567   then show ?thesis by simp
   568 next
   569   case False
   570   then have pos: "0 < x"
   571     using nneg by arith
   572   show ?thesis
   573   proof (rule right_inverse_eq [THEN iffD1, symmetric])
   574     show "sqrt x / x \<noteq> 0"
   575       by (simp add: divide_inverse nneg False)
   576     show "inverse (sqrt x) / (sqrt x / x) = 1"
   577       by (simp add: divide_inverse mult.assoc [symmetric]
   578           power2_eq_square [symmetric] real_inv_sqrt_pow2 pos False)
   579   qed
   580 qed
   581 
   582 lemma real_div_sqrt: "0 \<le> x \<Longrightarrow> x / sqrt x = sqrt x"
   583   by (cases "x = 0") (simp_all add: sqrt_divide_self_eq [of x] field_simps)
   584 
   585 lemma real_divide_square_eq [simp]: "(r * a) / (r * r) = a / r"
   586   for a r :: real
   587   by (cases "r = 0") (simp_all add: divide_inverse ac_simps)
   588 
   589 lemma lemma_real_divide_sqrt_less: "0 < u \<Longrightarrow> u / sqrt 2 < u"
   590   by (simp add: divide_less_eq)
   591 
   592 lemma four_x_squared: "4 * x\<^sup>2 = (2 * x)\<^sup>2"
   593   for x :: real
   594   by (simp add: power2_eq_square)
   595 
   596 lemma sqrt_at_top: "LIM x at_top. sqrt x :: real :> at_top"
   597   by (rule filterlim_at_top_at_top[where Q="\<lambda>x. True" and P="\<lambda>x. 0 < x" and g="power2"])
   598      (auto intro: eventually_gt_at_top)
   599 
   600 
   601 subsection \<open>Square Root of Sum of Squares\<close>
   602 
   603 lemma sum_squares_bound: "2 * x * y \<le> x\<^sup>2 + y\<^sup>2"
   604   for x y :: "'a::linordered_field"
   605 proof -
   606   have "(x - y)\<^sup>2 = x * x - 2 * x * y + y * y"
   607     by algebra
   608   then have "0 \<le> x\<^sup>2 - 2 * x * y + y\<^sup>2"
   609     by (metis sum_power2_ge_zero zero_le_double_add_iff_zero_le_single_add power2_eq_square)
   610   then show ?thesis
   611     by arith
   612 qed
   613 
   614 lemma arith_geo_mean:
   615   fixes u :: "'a::linordered_field"
   616   assumes "u\<^sup>2 = x * y" "x \<ge> 0" "y \<ge> 0"
   617   shows "u \<le> (x + y)/2"
   618   apply (rule power2_le_imp_le)
   619   using sum_squares_bound assms
   620   apply (auto simp: zero_le_mult_iff)
   621   apply (auto simp: algebra_simps power2_eq_square)
   622   done
   623 
   624 lemma arith_geo_mean_sqrt:
   625   fixes x :: real
   626   assumes "x \<ge> 0" "y \<ge> 0"
   627   shows "sqrt (x * y) \<le> (x + y)/2"
   628   apply (rule arith_geo_mean)
   629   using assms
   630   apply (auto simp: zero_le_mult_iff)
   631   done
   632 
   633 lemma real_sqrt_sum_squares_mult_ge_zero [simp]: "0 \<le> sqrt ((x\<^sup>2 + y\<^sup>2) * (xa\<^sup>2 + ya\<^sup>2))"
   634   by (metis real_sqrt_ge_0_iff split_mult_pos_le sum_power2_ge_zero)
   635 
   636 lemma real_sqrt_sum_squares_mult_squared_eq [simp]:
   637   "(sqrt ((x\<^sup>2 + y\<^sup>2) * (xa\<^sup>2 + ya\<^sup>2)))\<^sup>2 = (x\<^sup>2 + y\<^sup>2) * (xa\<^sup>2 + ya\<^sup>2)"
   638   by (simp add: zero_le_mult_iff)
   639 
   640 lemma real_sqrt_sum_squares_eq_cancel: "sqrt (x\<^sup>2 + y\<^sup>2) = x \<Longrightarrow> y = 0"
   641   by (drule arg_cong [where f = "\<lambda>x. x\<^sup>2"]) simp
   642 
   643 lemma real_sqrt_sum_squares_eq_cancel2: "sqrt (x\<^sup>2 + y\<^sup>2) = y \<Longrightarrow> x = 0"
   644   by (drule arg_cong [where f = "\<lambda>x. x\<^sup>2"]) simp
   645 
   646 lemma real_sqrt_sum_squares_ge1 [simp]: "x \<le> sqrt (x\<^sup>2 + y\<^sup>2)"
   647   by (rule power2_le_imp_le) simp_all
   648 
   649 lemma real_sqrt_sum_squares_ge2 [simp]: "y \<le> sqrt (x\<^sup>2 + y\<^sup>2)"
   650   by (rule power2_le_imp_le) simp_all
   651 
   652 lemma real_sqrt_ge_abs1 [simp]: "\<bar>x\<bar> \<le> sqrt (x\<^sup>2 + y\<^sup>2)"
   653   by (rule power2_le_imp_le) simp_all
   654 
   655 lemma real_sqrt_ge_abs2 [simp]: "\<bar>y\<bar> \<le> sqrt (x\<^sup>2 + y\<^sup>2)"
   656   by (rule power2_le_imp_le) simp_all
   657 
   658 lemma le_real_sqrt_sumsq [simp]: "x \<le> sqrt (x * x + y * y)"
   659   by (simp add: power2_eq_square [symmetric])
   660 
   661 lemma real_sqrt_sum_squares_triangle_ineq:
   662   "sqrt ((a + c)\<^sup>2 + (b + d)\<^sup>2) \<le> sqrt (a\<^sup>2 + b\<^sup>2) + sqrt (c\<^sup>2 + d\<^sup>2)"
   663   apply (rule power2_le_imp_le)
   664    apply simp
   665    apply (simp add: power2_sum)
   666    apply (simp only: mult.assoc distrib_left [symmetric])
   667    apply (rule mult_left_mono)
   668     apply (rule power2_le_imp_le)
   669      apply (simp add: power2_sum power_mult_distrib)
   670      apply (simp add: ring_distribs)
   671      apply (subgoal_tac "0 \<le> b\<^sup>2 * c\<^sup>2 + a\<^sup>2 * d\<^sup>2 - 2 * (a * c) * (b * d)")
   672       apply simp
   673      apply (rule_tac b="(a * d - b * c)\<^sup>2" in ord_le_eq_trans)
   674       apply (rule zero_le_power2)
   675      apply (simp add: power2_diff power_mult_distrib)
   676     apply simp
   677    apply simp
   678   apply (simp add: add_increasing)
   679   done
   680 
   681 lemma real_sqrt_sum_squares_less: "\<bar>x\<bar> < u / sqrt 2 \<Longrightarrow> \<bar>y\<bar> < u / sqrt 2 \<Longrightarrow> sqrt (x\<^sup>2 + y\<^sup>2) < u"
   682   apply (rule power2_less_imp_less)
   683    apply simp
   684    apply (drule power_strict_mono [OF _ abs_ge_zero pos2])
   685    apply (drule power_strict_mono [OF _ abs_ge_zero pos2])
   686    apply (simp add: power_divide)
   687   apply (drule order_le_less_trans [OF abs_ge_zero])
   688   apply (simp add: zero_less_divide_iff)
   689   done
   690 
   691 lemma sqrt2_less_2: "sqrt 2 < (2::real)"
   692   by (metis not_less not_less_iff_gr_or_eq numeral_less_iff real_sqrt_four
   693       real_sqrt_le_iff semiring_norm(75) semiring_norm(78) semiring_norm(85))
   694 
   695 lemma sqrt_sum_squares_half_less:
   696   "x < u/2 \<Longrightarrow> y < u/2 \<Longrightarrow> 0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> sqrt (x\<^sup>2 + y\<^sup>2) < u"
   697   apply (rule real_sqrt_sum_squares_less)
   698    apply (auto simp add: abs_if field_simps)
   699    apply (rule le_less_trans [where y = "x*2"])
   700   using less_eq_real_def sqrt2_less_2 apply force
   701    apply assumption
   702   apply (rule le_less_trans [where y = "y*2"])
   703   using less_eq_real_def sqrt2_less_2 mult_le_cancel_left
   704    apply auto
   705   done
   706 
   707 lemma LIMSEQ_root: "(\<lambda>n. root n n) \<longlonglongrightarrow> 1"
   708 proof -
   709   define x where "x n = root n n - 1" for n
   710   have "x \<longlonglongrightarrow> sqrt 0"
   711   proof (rule tendsto_sandwich[OF _ _ tendsto_const])
   712     show "(\<lambda>x. sqrt (2 / x)) \<longlonglongrightarrow> sqrt 0"
   713       by (intro tendsto_intros tendsto_divide_0[OF tendsto_const] filterlim_mono[OF filterlim_real_sequentially])
   714          (simp_all add: at_infinity_eq_at_top_bot)
   715     have "x n \<le> sqrt (2 / real n)" if "2 < n" for n :: nat
   716     proof -
   717       have "1 + (real (n - 1) * n) / 2 * (x n)\<^sup>2 = 1 + of_nat (n choose 2) * (x n)\<^sup>2"
   718         by (auto simp add: choose_two field_char_0_class.of_nat_div mod_eq_0_iff_dvd)
   719       also have "\<dots> \<le> (\<Sum>k\<in>{0, 2}. of_nat (n choose k) * x n^k)"
   720         by (simp add: x_def)
   721       also have "\<dots> \<le> (\<Sum>k=0..n. of_nat (n choose k) * x n^k)"
   722         using \<open>2 < n\<close>
   723         by (intro sum_mono2) (auto intro!: mult_nonneg_nonneg zero_le_power simp: x_def le_diff_eq)
   724       also have "\<dots> = (x n + 1) ^ n"
   725         by (simp add: binomial_ring)
   726       also have "\<dots> = n"
   727         using \<open>2 < n\<close> by (simp add: x_def)
   728       finally have "real (n - 1) * (real n / 2 * (x n)\<^sup>2) \<le> real (n - 1) * 1"
   729         by simp
   730       then have "(x n)\<^sup>2 \<le> 2 / real n"
   731         using \<open>2 < n\<close> unfolding mult_le_cancel_left by (simp add: field_simps)
   732       from real_sqrt_le_mono[OF this] show ?thesis
   733         by simp
   734     qed
   735     then show "eventually (\<lambda>n. x n \<le> sqrt (2 / real n)) sequentially"
   736       by (auto intro!: exI[of _ 3] simp: eventually_sequentially)
   737     show "eventually (\<lambda>n. sqrt 0 \<le> x n) sequentially"
   738       by (auto intro!: exI[of _ 1] simp: eventually_sequentially le_diff_eq x_def)
   739   qed
   740   from tendsto_add[OF this tendsto_const[of 1]] show ?thesis
   741     by (simp add: x_def)
   742 qed
   743 
   744 lemma LIMSEQ_root_const:
   745   assumes "0 < c"
   746   shows "(\<lambda>n. root n c) \<longlonglongrightarrow> 1"
   747 proof -
   748   have ge_1: "(\<lambda>n. root n c) \<longlonglongrightarrow> 1" if "1 \<le> c" for c :: real
   749   proof -
   750     define x where "x n = root n c - 1" for n
   751     have "x \<longlonglongrightarrow> 0"
   752     proof (rule tendsto_sandwich[OF _ _ tendsto_const])
   753       show "(\<lambda>n. c / n) \<longlonglongrightarrow> 0"
   754         by (intro tendsto_divide_0[OF tendsto_const] filterlim_mono[OF filterlim_real_sequentially])
   755           (simp_all add: at_infinity_eq_at_top_bot)
   756       have "x n \<le> c / n" if "1 < n" for n :: nat
   757       proof -
   758         have "1 + x n * n = 1 + of_nat (n choose 1) * x n^1"
   759           by (simp add: choose_one)
   760         also have "\<dots> \<le> (\<Sum>k\<in>{0, 1}. of_nat (n choose k) * x n^k)"
   761           by (simp add: x_def)
   762         also have "\<dots> \<le> (\<Sum>k=0..n. of_nat (n choose k) * x n^k)"
   763           using \<open>1 < n\<close> \<open>1 \<le> c\<close>
   764           by (intro sum_mono2)
   765             (auto intro!: mult_nonneg_nonneg zero_le_power simp: x_def le_diff_eq)
   766         also have "\<dots> = (x n + 1) ^ n"
   767           by (simp add: binomial_ring)
   768         also have "\<dots> = c"
   769           using \<open>1 < n\<close> \<open>1 \<le> c\<close> by (simp add: x_def)
   770         finally show ?thesis
   771           using \<open>1 \<le> c\<close> \<open>1 < n\<close> by (simp add: field_simps)
   772       qed
   773       then show "eventually (\<lambda>n. x n \<le> c / n) sequentially"
   774         by (auto intro!: exI[of _ 3] simp: eventually_sequentially)
   775       show "eventually (\<lambda>n. 0 \<le> x n) sequentially"
   776         using \<open>1 \<le> c\<close>
   777         by (auto intro!: exI[of _ 1] simp: eventually_sequentially le_diff_eq x_def)
   778     qed
   779     from tendsto_add[OF this tendsto_const[of 1]] show ?thesis
   780       by (simp add: x_def)
   781   qed
   782   show ?thesis
   783   proof (cases "1 \<le> c")
   784     case True
   785     with ge_1 show ?thesis by blast
   786   next
   787     case False
   788     with \<open>0 < c\<close> have "1 \<le> 1 / c"
   789       by simp
   790     then have "(\<lambda>n. 1 / root n (1 / c)) \<longlonglongrightarrow> 1 / 1"
   791       by (intro tendsto_divide tendsto_const ge_1 \<open>1 \<le> 1 / c\<close> one_neq_zero)
   792     then show ?thesis
   793       by (rule filterlim_cong[THEN iffD1, rotated 3])
   794         (auto intro!: exI[of _ 1] simp: eventually_sequentially real_root_divide)
   795   qed
   796 qed
   797 
   798 
   799 text "Legacy theorem names:"
   800 lemmas real_root_pos2 = real_root_power_cancel
   801 lemmas real_root_pos_pos = real_root_gt_zero [THEN order_less_imp_le]
   802 lemmas real_root_pos_pos_le = real_root_ge_zero
   803 lemmas real_sqrt_mult_distrib = real_sqrt_mult
   804 lemmas real_sqrt_mult_distrib2 = real_sqrt_mult
   805 lemmas real_sqrt_eq_zero_cancel_iff = real_sqrt_eq_0_iff
   806 
   807 end