src/HOL/Transfer.thy
author blanchet
Tue Nov 07 15:16:42 2017 +0100 (19 months ago)
changeset 67022 49309fe530fd
parent 64425 b17acc1834e3
child 67399 eab6ce8368fa
permissions -rw-r--r--
more robust parsing for THF proofs (esp. polymorphic Leo-III proofs)
     1 (*  Title:      HOL/Transfer.thy
     2     Author:     Brian Huffman, TU Muenchen
     3     Author:     Ondrej Kuncar, TU Muenchen
     4 *)
     5 
     6 section \<open>Generic theorem transfer using relations\<close>
     7 
     8 theory Transfer
     9 imports Basic_BNF_LFPs Hilbert_Choice Metis
    10 begin
    11 
    12 subsection \<open>Relator for function space\<close>
    13 
    14 bundle lifting_syntax
    15 begin
    16   notation rel_fun  (infixr "===>" 55)
    17   notation map_fun  (infixr "--->" 55)
    18 end
    19 
    20 context includes lifting_syntax
    21 begin
    22 
    23 lemma rel_funD2:
    24   assumes "rel_fun A B f g" and "A x x"
    25   shows "B (f x) (g x)"
    26   using assms by (rule rel_funD)
    27 
    28 lemma rel_funE:
    29   assumes "rel_fun A B f g" and "A x y"
    30   obtains "B (f x) (g y)"
    31   using assms by (simp add: rel_fun_def)
    32 
    33 lemmas rel_fun_eq = fun.rel_eq
    34 
    35 lemma rel_fun_eq_rel:
    36 shows "rel_fun (op =) R = (\<lambda>f g. \<forall>x. R (f x) (g x))"
    37   by (simp add: rel_fun_def)
    38 
    39 
    40 subsection \<open>Transfer method\<close>
    41 
    42 text \<open>Explicit tag for relation membership allows for
    43   backward proof methods.\<close>
    44 
    45 definition Rel :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool"
    46   where "Rel r \<equiv> r"
    47 
    48 text \<open>Handling of equality relations\<close>
    49 
    50 definition is_equality :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
    51   where "is_equality R \<longleftrightarrow> R = (op =)"
    52 
    53 lemma is_equality_eq: "is_equality (op =)"
    54   unfolding is_equality_def by simp
    55 
    56 text \<open>Reverse implication for monotonicity rules\<close>
    57 
    58 definition rev_implies where
    59   "rev_implies x y \<longleftrightarrow> (y \<longrightarrow> x)"
    60 
    61 text \<open>Handling of meta-logic connectives\<close>
    62 
    63 definition transfer_forall where
    64   "transfer_forall \<equiv> All"
    65 
    66 definition transfer_implies where
    67   "transfer_implies \<equiv> op \<longrightarrow>"
    68 
    69 definition transfer_bforall :: "('a \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> bool"
    70   where "transfer_bforall \<equiv> (\<lambda>P Q. \<forall>x. P x \<longrightarrow> Q x)"
    71 
    72 lemma transfer_forall_eq: "(\<And>x. P x) \<equiv> Trueprop (transfer_forall (\<lambda>x. P x))"
    73   unfolding atomize_all transfer_forall_def ..
    74 
    75 lemma transfer_implies_eq: "(A \<Longrightarrow> B) \<equiv> Trueprop (transfer_implies A B)"
    76   unfolding atomize_imp transfer_implies_def ..
    77 
    78 lemma transfer_bforall_unfold:
    79   "Trueprop (transfer_bforall P (\<lambda>x. Q x)) \<equiv> (\<And>x. P x \<Longrightarrow> Q x)"
    80   unfolding transfer_bforall_def atomize_imp atomize_all ..
    81 
    82 lemma transfer_start: "\<lbrakk>P; Rel (op =) P Q\<rbrakk> \<Longrightarrow> Q"
    83   unfolding Rel_def by simp
    84 
    85 lemma transfer_start': "\<lbrakk>P; Rel (op \<longrightarrow>) P Q\<rbrakk> \<Longrightarrow> Q"
    86   unfolding Rel_def by simp
    87 
    88 lemma transfer_prover_start: "\<lbrakk>x = x'; Rel R x' y\<rbrakk> \<Longrightarrow> Rel R x y"
    89   by simp
    90 
    91 lemma untransfer_start: "\<lbrakk>Q; Rel (op =) P Q\<rbrakk> \<Longrightarrow> P"
    92   unfolding Rel_def by simp
    93 
    94 lemma Rel_eq_refl: "Rel (op =) x x"
    95   unfolding Rel_def ..
    96 
    97 lemma Rel_app:
    98   assumes "Rel (A ===> B) f g" and "Rel A x y"
    99   shows "Rel B (f x) (g y)"
   100   using assms unfolding Rel_def rel_fun_def by fast
   101 
   102 lemma Rel_abs:
   103   assumes "\<And>x y. Rel A x y \<Longrightarrow> Rel B (f x) (g y)"
   104   shows "Rel (A ===> B) (\<lambda>x. f x) (\<lambda>y. g y)"
   105   using assms unfolding Rel_def rel_fun_def by fast
   106 
   107 subsection \<open>Predicates on relations, i.e. ``class constraints''\<close>
   108 
   109 definition left_total :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool"
   110   where "left_total R \<longleftrightarrow> (\<forall>x. \<exists>y. R x y)"
   111 
   112 definition left_unique :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool"
   113   where "left_unique R \<longleftrightarrow> (\<forall>x y z. R x z \<longrightarrow> R y z \<longrightarrow> x = y)"
   114 
   115 definition right_total :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool"
   116   where "right_total R \<longleftrightarrow> (\<forall>y. \<exists>x. R x y)"
   117 
   118 definition right_unique :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool"
   119   where "right_unique R \<longleftrightarrow> (\<forall>x y z. R x y \<longrightarrow> R x z \<longrightarrow> y = z)"
   120 
   121 definition bi_total :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool"
   122   where "bi_total R \<longleftrightarrow> (\<forall>x. \<exists>y. R x y) \<and> (\<forall>y. \<exists>x. R x y)"
   123 
   124 definition bi_unique :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool"
   125   where "bi_unique R \<longleftrightarrow>
   126     (\<forall>x y z. R x y \<longrightarrow> R x z \<longrightarrow> y = z) \<and>
   127     (\<forall>x y z. R x z \<longrightarrow> R y z \<longrightarrow> x = y)"
   128 
   129 lemma left_uniqueI: "(\<And>x y z. \<lbrakk> A x z; A y z \<rbrakk> \<Longrightarrow> x = y) \<Longrightarrow> left_unique A"
   130 unfolding left_unique_def by blast
   131 
   132 lemma left_uniqueD: "\<lbrakk> left_unique A; A x z; A y z \<rbrakk> \<Longrightarrow> x = y"
   133 unfolding left_unique_def by blast
   134 
   135 lemma left_totalI:
   136   "(\<And>x. \<exists>y. R x y) \<Longrightarrow> left_total R"
   137 unfolding left_total_def by blast
   138 
   139 lemma left_totalE:
   140   assumes "left_total R"
   141   obtains "(\<And>x. \<exists>y. R x y)"
   142 using assms unfolding left_total_def by blast
   143 
   144 lemma bi_uniqueDr: "\<lbrakk> bi_unique A; A x y; A x z \<rbrakk> \<Longrightarrow> y = z"
   145 by(simp add: bi_unique_def)
   146 
   147 lemma bi_uniqueDl: "\<lbrakk> bi_unique A; A x y; A z y \<rbrakk> \<Longrightarrow> x = z"
   148 by(simp add: bi_unique_def)
   149 
   150 lemma right_uniqueI: "(\<And>x y z. \<lbrakk> A x y; A x z \<rbrakk> \<Longrightarrow> y = z) \<Longrightarrow> right_unique A"
   151 unfolding right_unique_def by fast
   152 
   153 lemma right_uniqueD: "\<lbrakk> right_unique A; A x y; A x z \<rbrakk> \<Longrightarrow> y = z"
   154 unfolding right_unique_def by fast
   155 
   156 lemma right_totalI: "(\<And>y. \<exists>x. A x y) \<Longrightarrow> right_total A"
   157 by(simp add: right_total_def)
   158 
   159 lemma right_totalE:
   160   assumes "right_total A"
   161   obtains x where "A x y"
   162 using assms by(auto simp add: right_total_def)
   163 
   164 lemma right_total_alt_def2:
   165   "right_total R \<longleftrightarrow> ((R ===> op \<longrightarrow>) ===> op \<longrightarrow>) All All"
   166   unfolding right_total_def rel_fun_def
   167   apply (rule iffI, fast)
   168   apply (rule allI)
   169   apply (drule_tac x="\<lambda>x. True" in spec)
   170   apply (drule_tac x="\<lambda>y. \<exists>x. R x y" in spec)
   171   apply fast
   172   done
   173 
   174 lemma right_unique_alt_def2:
   175   "right_unique R \<longleftrightarrow> (R ===> R ===> op \<longrightarrow>) (op =) (op =)"
   176   unfolding right_unique_def rel_fun_def by auto
   177 
   178 lemma bi_total_alt_def2:
   179   "bi_total R \<longleftrightarrow> ((R ===> op =) ===> op =) All All"
   180   unfolding bi_total_def rel_fun_def
   181   apply (rule iffI, fast)
   182   apply safe
   183   apply (drule_tac x="\<lambda>x. \<exists>y. R x y" in spec)
   184   apply (drule_tac x="\<lambda>y. True" in spec)
   185   apply fast
   186   apply (drule_tac x="\<lambda>x. True" in spec)
   187   apply (drule_tac x="\<lambda>y. \<exists>x. R x y" in spec)
   188   apply fast
   189   done
   190 
   191 lemma bi_unique_alt_def2:
   192   "bi_unique R \<longleftrightarrow> (R ===> R ===> op =) (op =) (op =)"
   193   unfolding bi_unique_def rel_fun_def by auto
   194 
   195 lemma [simp]:
   196   shows left_unique_conversep: "left_unique A\<inverse>\<inverse> \<longleftrightarrow> right_unique A"
   197   and right_unique_conversep: "right_unique A\<inverse>\<inverse> \<longleftrightarrow> left_unique A"
   198 by(auto simp add: left_unique_def right_unique_def)
   199 
   200 lemma [simp]:
   201   shows left_total_conversep: "left_total A\<inverse>\<inverse> \<longleftrightarrow> right_total A"
   202   and right_total_conversep: "right_total A\<inverse>\<inverse> \<longleftrightarrow> left_total A"
   203 by(simp_all add: left_total_def right_total_def)
   204 
   205 lemma bi_unique_conversep [simp]: "bi_unique R\<inverse>\<inverse> = bi_unique R"
   206 by(auto simp add: bi_unique_def)
   207 
   208 lemma bi_total_conversep [simp]: "bi_total R\<inverse>\<inverse> = bi_total R"
   209 by(auto simp add: bi_total_def)
   210 
   211 lemma right_unique_alt_def: "right_unique R = (conversep R OO R \<le> op=)" unfolding right_unique_def by blast
   212 lemma left_unique_alt_def: "left_unique R = (R OO (conversep R) \<le> op=)" unfolding left_unique_def by blast
   213 
   214 lemma right_total_alt_def: "right_total R = (conversep R OO R \<ge> op=)" unfolding right_total_def by blast
   215 lemma left_total_alt_def: "left_total R = (R OO conversep R \<ge> op=)" unfolding left_total_def by blast
   216 
   217 lemma bi_total_alt_def: "bi_total A = (left_total A \<and> right_total A)"
   218 unfolding left_total_def right_total_def bi_total_def by blast
   219 
   220 lemma bi_unique_alt_def: "bi_unique A = (left_unique A \<and> right_unique A)"
   221 unfolding left_unique_def right_unique_def bi_unique_def by blast
   222 
   223 lemma bi_totalI: "left_total R \<Longrightarrow> right_total R \<Longrightarrow> bi_total R"
   224 unfolding bi_total_alt_def ..
   225 
   226 lemma bi_uniqueI: "left_unique R \<Longrightarrow> right_unique R \<Longrightarrow> bi_unique R"
   227 unfolding bi_unique_alt_def ..
   228 
   229 end
   230 
   231 
   232 
   233 ML_file "Tools/Transfer/transfer.ML"
   234 declare refl [transfer_rule]
   235 
   236 hide_const (open) Rel
   237 
   238 context includes lifting_syntax
   239 begin
   240 
   241 text \<open>Handling of domains\<close>
   242 
   243 lemma Domainp_iff: "Domainp T x \<longleftrightarrow> (\<exists>y. T x y)"
   244   by auto
   245 
   246 lemma Domainp_refl[transfer_domain_rule]:
   247   "Domainp T = Domainp T" ..
   248 
   249 lemma Domain_eq_top[transfer_domain_rule]: "Domainp op= = top" by auto
   250 
   251 lemma Domainp_pred_fun_eq[relator_domain]:
   252   assumes "left_unique T"
   253   shows "Domainp (T ===> S) = pred_fun (Domainp T) (Domainp S)"
   254   using assms unfolding rel_fun_def Domainp_iff[abs_def] left_unique_def fun_eq_iff pred_fun_def
   255   apply safe
   256    apply blast
   257   apply (subst all_comm)
   258   apply (rule choice)
   259   apply blast
   260   done
   261 
   262 text \<open>Properties are preserved by relation composition.\<close>
   263 
   264 lemma OO_def: "R OO S = (\<lambda>x z. \<exists>y. R x y \<and> S y z)"
   265   by auto
   266 
   267 lemma bi_total_OO: "\<lbrakk>bi_total A; bi_total B\<rbrakk> \<Longrightarrow> bi_total (A OO B)"
   268   unfolding bi_total_def OO_def by fast
   269 
   270 lemma bi_unique_OO: "\<lbrakk>bi_unique A; bi_unique B\<rbrakk> \<Longrightarrow> bi_unique (A OO B)"
   271   unfolding bi_unique_def OO_def by blast
   272 
   273 lemma right_total_OO:
   274   "\<lbrakk>right_total A; right_total B\<rbrakk> \<Longrightarrow> right_total (A OO B)"
   275   unfolding right_total_def OO_def by fast
   276 
   277 lemma right_unique_OO:
   278   "\<lbrakk>right_unique A; right_unique B\<rbrakk> \<Longrightarrow> right_unique (A OO B)"
   279   unfolding right_unique_def OO_def by fast
   280 
   281 lemma left_total_OO: "left_total R \<Longrightarrow> left_total S \<Longrightarrow> left_total (R OO S)"
   282 unfolding left_total_def OO_def by fast
   283 
   284 lemma left_unique_OO: "left_unique R \<Longrightarrow> left_unique S \<Longrightarrow> left_unique (R OO S)"
   285 unfolding left_unique_def OO_def by blast
   286 
   287 
   288 subsection \<open>Properties of relators\<close>
   289 
   290 lemma left_total_eq[transfer_rule]: "left_total op="
   291   unfolding left_total_def by blast
   292 
   293 lemma left_unique_eq[transfer_rule]: "left_unique op="
   294   unfolding left_unique_def by blast
   295 
   296 lemma right_total_eq [transfer_rule]: "right_total op="
   297   unfolding right_total_def by simp
   298 
   299 lemma right_unique_eq [transfer_rule]: "right_unique op="
   300   unfolding right_unique_def by simp
   301 
   302 lemma bi_total_eq[transfer_rule]: "bi_total (op =)"
   303   unfolding bi_total_def by simp
   304 
   305 lemma bi_unique_eq[transfer_rule]: "bi_unique (op =)"
   306   unfolding bi_unique_def by simp
   307 
   308 lemma left_total_fun[transfer_rule]:
   309   "\<lbrakk>left_unique A; left_total B\<rbrakk> \<Longrightarrow> left_total (A ===> B)"
   310   unfolding left_total_def rel_fun_def
   311   apply (rule allI, rename_tac f)
   312   apply (rule_tac x="\<lambda>y. SOME z. B (f (THE x. A x y)) z" in exI)
   313   apply clarify
   314   apply (subgoal_tac "(THE x. A x y) = x", simp)
   315   apply (rule someI_ex)
   316   apply (simp)
   317   apply (rule the_equality)
   318   apply assumption
   319   apply (simp add: left_unique_def)
   320   done
   321 
   322 lemma left_unique_fun[transfer_rule]:
   323   "\<lbrakk>left_total A; left_unique B\<rbrakk> \<Longrightarrow> left_unique (A ===> B)"
   324   unfolding left_total_def left_unique_def rel_fun_def
   325   by (clarify, rule ext, fast)
   326 
   327 lemma right_total_fun [transfer_rule]:
   328   "\<lbrakk>right_unique A; right_total B\<rbrakk> \<Longrightarrow> right_total (A ===> B)"
   329   unfolding right_total_def rel_fun_def
   330   apply (rule allI, rename_tac g)
   331   apply (rule_tac x="\<lambda>x. SOME z. B z (g (THE y. A x y))" in exI)
   332   apply clarify
   333   apply (subgoal_tac "(THE y. A x y) = y", simp)
   334   apply (rule someI_ex)
   335   apply (simp)
   336   apply (rule the_equality)
   337   apply assumption
   338   apply (simp add: right_unique_def)
   339   done
   340 
   341 lemma right_unique_fun [transfer_rule]:
   342   "\<lbrakk>right_total A; right_unique B\<rbrakk> \<Longrightarrow> right_unique (A ===> B)"
   343   unfolding right_total_def right_unique_def rel_fun_def
   344   by (clarify, rule ext, fast)
   345 
   346 lemma bi_total_fun[transfer_rule]:
   347   "\<lbrakk>bi_unique A; bi_total B\<rbrakk> \<Longrightarrow> bi_total (A ===> B)"
   348   unfolding bi_unique_alt_def bi_total_alt_def
   349   by (blast intro: right_total_fun left_total_fun)
   350 
   351 lemma bi_unique_fun[transfer_rule]:
   352   "\<lbrakk>bi_total A; bi_unique B\<rbrakk> \<Longrightarrow> bi_unique (A ===> B)"
   353   unfolding bi_unique_alt_def bi_total_alt_def
   354   by (blast intro: right_unique_fun left_unique_fun)
   355 
   356 end
   357 
   358 lemma if_conn:
   359   "(if P \<and> Q then t else e) = (if P then if Q then t else e else e)"
   360   "(if P \<or> Q then t else e) = (if P then t else if Q then t else e)"
   361   "(if P \<longrightarrow> Q then t else e) = (if P then if Q then t else e else t)"
   362   "(if \<not> P then t else e) = (if P then e else t)"
   363 by auto
   364 
   365 ML_file "Tools/Transfer/transfer_bnf.ML"
   366 ML_file "Tools/BNF/bnf_fp_rec_sugar_transfer.ML"
   367 
   368 declare pred_fun_def [simp]
   369 declare rel_fun_eq [relator_eq]
   370 
   371 (* Delete the automated generated rule from the bnf command;
   372   we have a more general rule (Domainp_pred_fun_eq) that subsumes it. *)
   373 declare fun.Domainp_rel[relator_domain del]
   374 
   375 subsection \<open>Transfer rules\<close>
   376 
   377 context includes lifting_syntax
   378 begin
   379 
   380 lemma Domainp_forall_transfer [transfer_rule]:
   381   assumes "right_total A"
   382   shows "((A ===> op =) ===> op =)
   383     (transfer_bforall (Domainp A)) transfer_forall"
   384   using assms unfolding right_total_def
   385   unfolding transfer_forall_def transfer_bforall_def rel_fun_def Domainp_iff
   386   by fast
   387 
   388 text \<open>Transfer rules using implication instead of equality on booleans.\<close>
   389 
   390 lemma transfer_forall_transfer [transfer_rule]:
   391   "bi_total A \<Longrightarrow> ((A ===> op =) ===> op =) transfer_forall transfer_forall"
   392   "right_total A \<Longrightarrow> ((A ===> op =) ===> implies) transfer_forall transfer_forall"
   393   "right_total A \<Longrightarrow> ((A ===> implies) ===> implies) transfer_forall transfer_forall"
   394   "bi_total A \<Longrightarrow> ((A ===> op =) ===> rev_implies) transfer_forall transfer_forall"
   395   "bi_total A \<Longrightarrow> ((A ===> rev_implies) ===> rev_implies) transfer_forall transfer_forall"
   396   unfolding transfer_forall_def rev_implies_def rel_fun_def right_total_def bi_total_def
   397   by fast+
   398 
   399 lemma transfer_implies_transfer [transfer_rule]:
   400   "(op =        ===> op =        ===> op =       ) transfer_implies transfer_implies"
   401   "(rev_implies ===> implies     ===> implies    ) transfer_implies transfer_implies"
   402   "(rev_implies ===> op =        ===> implies    ) transfer_implies transfer_implies"
   403   "(op =        ===> implies     ===> implies    ) transfer_implies transfer_implies"
   404   "(op =        ===> op =        ===> implies    ) transfer_implies transfer_implies"
   405   "(implies     ===> rev_implies ===> rev_implies) transfer_implies transfer_implies"
   406   "(implies     ===> op =        ===> rev_implies) transfer_implies transfer_implies"
   407   "(op =        ===> rev_implies ===> rev_implies) transfer_implies transfer_implies"
   408   "(op =        ===> op =        ===> rev_implies) transfer_implies transfer_implies"
   409   unfolding transfer_implies_def rev_implies_def rel_fun_def by auto
   410 
   411 lemma eq_imp_transfer [transfer_rule]:
   412   "right_unique A \<Longrightarrow> (A ===> A ===> op \<longrightarrow>) (op =) (op =)"
   413   unfolding right_unique_alt_def2 .
   414 
   415 text \<open>Transfer rules using equality.\<close>
   416 
   417 lemma left_unique_transfer [transfer_rule]:
   418   assumes "right_total A"
   419   assumes "right_total B"
   420   assumes "bi_unique A"
   421   shows "((A ===> B ===> op=) ===> implies) left_unique left_unique"
   422 using assms unfolding left_unique_def[abs_def] right_total_def bi_unique_def rel_fun_def
   423 by metis
   424 
   425 lemma eq_transfer [transfer_rule]:
   426   assumes "bi_unique A"
   427   shows "(A ===> A ===> op =) (op =) (op =)"
   428   using assms unfolding bi_unique_def rel_fun_def by auto
   429 
   430 lemma right_total_Ex_transfer[transfer_rule]:
   431   assumes "right_total A"
   432   shows "((A ===> op=) ===> op=) (Bex (Collect (Domainp A))) Ex"
   433 using assms unfolding right_total_def Bex_def rel_fun_def Domainp_iff[abs_def]
   434 by fast
   435 
   436 lemma right_total_All_transfer[transfer_rule]:
   437   assumes "right_total A"
   438   shows "((A ===> op =) ===> op =) (Ball (Collect (Domainp A))) All"
   439 using assms unfolding right_total_def Ball_def rel_fun_def Domainp_iff[abs_def]
   440 by fast
   441 
   442 lemma All_transfer [transfer_rule]:
   443   assumes "bi_total A"
   444   shows "((A ===> op =) ===> op =) All All"
   445   using assms unfolding bi_total_def rel_fun_def by fast
   446 
   447 lemma Ex_transfer [transfer_rule]:
   448   assumes "bi_total A"
   449   shows "((A ===> op =) ===> op =) Ex Ex"
   450   using assms unfolding bi_total_def rel_fun_def by fast
   451 
   452 lemma Ex1_parametric [transfer_rule]:
   453   assumes [transfer_rule]: "bi_unique A" "bi_total A"
   454   shows "((A ===> op =) ===> op =) Ex1 Ex1"
   455 unfolding Ex1_def[abs_def] by transfer_prover
   456 
   457 declare If_transfer [transfer_rule]
   458 
   459 lemma Let_transfer [transfer_rule]: "(A ===> (A ===> B) ===> B) Let Let"
   460   unfolding rel_fun_def by simp
   461 
   462 declare id_transfer [transfer_rule]
   463 
   464 declare comp_transfer [transfer_rule]
   465 
   466 lemma curry_transfer [transfer_rule]:
   467   "((rel_prod A B ===> C) ===> A ===> B ===> C) curry curry"
   468   unfolding curry_def by transfer_prover
   469 
   470 lemma fun_upd_transfer [transfer_rule]:
   471   assumes [transfer_rule]: "bi_unique A"
   472   shows "((A ===> B) ===> A ===> B ===> A ===> B) fun_upd fun_upd"
   473   unfolding fun_upd_def [abs_def] by transfer_prover
   474 
   475 lemma case_nat_transfer [transfer_rule]:
   476   "(A ===> (op = ===> A) ===> op = ===> A) case_nat case_nat"
   477   unfolding rel_fun_def by (simp split: nat.split)
   478 
   479 lemma rec_nat_transfer [transfer_rule]:
   480   "(A ===> (op = ===> A ===> A) ===> op = ===> A) rec_nat rec_nat"
   481   unfolding rel_fun_def by (clarsimp, rename_tac n, induct_tac n, simp_all)
   482 
   483 lemma funpow_transfer [transfer_rule]:
   484   "(op = ===> (A ===> A) ===> (A ===> A)) compow compow"
   485   unfolding funpow_def by transfer_prover
   486 
   487 lemma mono_transfer[transfer_rule]:
   488   assumes [transfer_rule]: "bi_total A"
   489   assumes [transfer_rule]: "(A ===> A ===> op=) op\<le> op\<le>"
   490   assumes [transfer_rule]: "(B ===> B ===> op=) op\<le> op\<le>"
   491   shows "((A ===> B) ===> op=) mono mono"
   492 unfolding mono_def[abs_def] by transfer_prover
   493 
   494 lemma right_total_relcompp_transfer[transfer_rule]:
   495   assumes [transfer_rule]: "right_total B"
   496   shows "((A ===> B ===> op=) ===> (B ===> C ===> op=) ===> A ===> C ===> op=)
   497     (\<lambda>R S x z. \<exists>y\<in>Collect (Domainp B). R x y \<and> S y z) op OO"
   498 unfolding OO_def[abs_def] by transfer_prover
   499 
   500 lemma relcompp_transfer[transfer_rule]:
   501   assumes [transfer_rule]: "bi_total B"
   502   shows "((A ===> B ===> op=) ===> (B ===> C ===> op=) ===> A ===> C ===> op=) op OO op OO"
   503 unfolding OO_def[abs_def] by transfer_prover
   504 
   505 lemma right_total_Domainp_transfer[transfer_rule]:
   506   assumes [transfer_rule]: "right_total B"
   507   shows "((A ===> B ===> op=) ===> A ===> op=) (\<lambda>T x. \<exists>y\<in>Collect(Domainp B). T x y) Domainp"
   508 apply(subst(2) Domainp_iff[abs_def]) by transfer_prover
   509 
   510 lemma Domainp_transfer[transfer_rule]:
   511   assumes [transfer_rule]: "bi_total B"
   512   shows "((A ===> B ===> op=) ===> A ===> op=) Domainp Domainp"
   513 unfolding Domainp_iff[abs_def] by transfer_prover
   514 
   515 lemma reflp_transfer[transfer_rule]:
   516   "bi_total A \<Longrightarrow> ((A ===> A ===> op=) ===> op=) reflp reflp"
   517   "right_total A \<Longrightarrow> ((A ===> A ===> implies) ===> implies) reflp reflp"
   518   "right_total A \<Longrightarrow> ((A ===> A ===> op=) ===> implies) reflp reflp"
   519   "bi_total A \<Longrightarrow> ((A ===> A ===> rev_implies) ===> rev_implies) reflp reflp"
   520   "bi_total A \<Longrightarrow> ((A ===> A ===> op=) ===> rev_implies) reflp reflp"
   521 unfolding reflp_def[abs_def] rev_implies_def bi_total_def right_total_def rel_fun_def
   522 by fast+
   523 
   524 lemma right_unique_transfer [transfer_rule]:
   525   "\<lbrakk> right_total A; right_total B; bi_unique B \<rbrakk>
   526   \<Longrightarrow> ((A ===> B ===> op=) ===> implies) right_unique right_unique"
   527 unfolding right_unique_def[abs_def] right_total_def bi_unique_def rel_fun_def
   528 by metis
   529 
   530 lemma left_total_parametric [transfer_rule]:
   531   assumes [transfer_rule]: "bi_total A" "bi_total B"
   532   shows "((A ===> B ===> op =) ===> op =) left_total left_total"
   533 unfolding left_total_def[abs_def] by transfer_prover
   534 
   535 lemma right_total_parametric [transfer_rule]:
   536   assumes [transfer_rule]: "bi_total A" "bi_total B"
   537   shows "((A ===> B ===> op =) ===> op =) right_total right_total"
   538 unfolding right_total_def[abs_def] by transfer_prover
   539 
   540 lemma left_unique_parametric [transfer_rule]:
   541   assumes [transfer_rule]: "bi_unique A" "bi_total A" "bi_total B"
   542   shows "((A ===> B ===> op =) ===> op =) left_unique left_unique"
   543 unfolding left_unique_def[abs_def] by transfer_prover
   544 
   545 lemma prod_pred_parametric [transfer_rule]:
   546   "((A ===> op =) ===> (B ===> op =) ===> rel_prod A B ===> op =) pred_prod pred_prod"
   547 unfolding prod.pred_set[abs_def] Basic_BNFs.fsts_def Basic_BNFs.snds_def fstsp.simps sndsp.simps 
   548 by simp transfer_prover
   549 
   550 lemma apfst_parametric [transfer_rule]:
   551   "((A ===> B) ===> rel_prod A C ===> rel_prod B C) apfst apfst"
   552 unfolding apfst_def[abs_def] by transfer_prover
   553 
   554 lemma rel_fun_eq_eq_onp: "(op= ===> eq_onp P) = eq_onp (\<lambda>f. \<forall>x. P(f x))"
   555 unfolding eq_onp_def rel_fun_def by auto
   556 
   557 lemma rel_fun_eq_onp_rel:
   558   shows "((eq_onp R) ===> S) = (\<lambda>f g. \<forall>x. R x \<longrightarrow> S (f x) (g x))"
   559 by (auto simp add: eq_onp_def rel_fun_def)
   560 
   561 lemma eq_onp_transfer [transfer_rule]:
   562   assumes [transfer_rule]: "bi_unique A"
   563   shows "((A ===> op=) ===> A ===> A ===> op=) eq_onp eq_onp"
   564 unfolding eq_onp_def[abs_def] by transfer_prover
   565 
   566 lemma rtranclp_parametric [transfer_rule]:
   567   assumes "bi_unique A" "bi_total A"
   568   shows "((A ===> A ===> op =) ===> A ===> A ===> op =) rtranclp rtranclp"
   569 proof(rule rel_funI iffI)+
   570   fix R :: "'a \<Rightarrow> 'a \<Rightarrow> bool" and R' x y x' y'
   571   assume R: "(A ===> A ===> op =) R R'" and "A x x'"
   572   {
   573     assume "R\<^sup>*\<^sup>* x y" "A y y'"
   574     thus "R'\<^sup>*\<^sup>* x' y'"
   575     proof(induction arbitrary: y')
   576       case base
   577       with \<open>bi_unique A\<close> \<open>A x x'\<close> have "x' = y'" by(rule bi_uniqueDr)
   578       thus ?case by simp
   579     next
   580       case (step y z z')
   581       from \<open>bi_total A\<close> obtain y' where "A y y'" unfolding bi_total_def by blast
   582       hence "R'\<^sup>*\<^sup>* x' y'" by(rule step.IH)
   583       moreover from R \<open>A y y'\<close> \<open>A z z'\<close> \<open>R y z\<close>
   584       have "R' y' z'" by(auto dest: rel_funD)
   585       ultimately show ?case ..
   586     qed
   587   next
   588     assume "R'\<^sup>*\<^sup>* x' y'" "A y y'"
   589     thus "R\<^sup>*\<^sup>* x y"
   590     proof(induction arbitrary: y)
   591       case base
   592       with \<open>bi_unique A\<close> \<open>A x x'\<close> have "x = y" by(rule bi_uniqueDl)
   593       thus ?case by simp
   594     next
   595       case (step y' z' z)
   596       from \<open>bi_total A\<close> obtain y where "A y y'" unfolding bi_total_def by blast
   597       hence "R\<^sup>*\<^sup>* x y" by(rule step.IH)
   598       moreover from R \<open>A y y'\<close> \<open>A z z'\<close> \<open>R' y' z'\<close>
   599       have "R y z" by(auto dest: rel_funD)
   600       ultimately show ?case ..
   601     qed
   602   }
   603 qed
   604 
   605 lemma right_unique_parametric [transfer_rule]:
   606   assumes [transfer_rule]: "bi_total A" "bi_unique B" "bi_total B"
   607   shows "((A ===> B ===> op =) ===> op =) right_unique right_unique"
   608 unfolding right_unique_def[abs_def] by transfer_prover
   609 
   610 lemma map_fun_parametric [transfer_rule]:
   611   "((A ===> B) ===> (C ===> D) ===> (B ===> C) ===> A ===> D) map_fun map_fun"
   612 unfolding map_fun_def[abs_def] by transfer_prover
   613 
   614 end
   615 
   616 
   617 subsection \<open>@{const of_nat}\<close>
   618 
   619 lemma transfer_rule_of_nat:
   620   fixes R :: "'a::semiring_1 \<Rightarrow> 'b::semiring_1 \<Rightarrow> bool"
   621   assumes [transfer_rule]: "R 0 0" "R 1 1"
   622     "rel_fun R (rel_fun R R) plus plus"
   623   shows "rel_fun HOL.eq R of_nat of_nat"
   624   by (unfold of_nat_def [abs_def]) transfer_prover
   625 
   626 end