src/Pure/type_infer.ML
author wenzelm
Thu Jul 23 16:53:00 2009 +0200 (2009-07-23)
changeset 32146 4937d9836824
parent 32141 31cd1ea502aa
child 35013 f3d491658893
permissions -rw-r--r--
paramify_vars: Term_Subst.map_atypsT_same
recovered coding conventions of this module;
     1 (*  Title:      Pure/type_infer.ML
     2     Author:     Stefan Berghofer and Markus Wenzel, TU Muenchen
     3 
     4 Simple type inference.
     5 *)
     6 
     7 signature TYPE_INFER =
     8 sig
     9   val anyT: sort -> typ
    10   val polymorphicT: typ -> typ
    11   val constrain: typ -> term -> term
    12   val is_param: indexname -> bool
    13   val param: int -> string * sort -> typ
    14   val paramify_vars: typ -> typ
    15   val paramify_dummies: typ -> int -> typ * int
    16   val fixate_params: Name.context -> term list -> term list
    17   val appl_error: Pretty.pp -> string -> term -> typ -> term -> typ -> string list
    18   val infer_types: Pretty.pp -> Type.tsig -> (typ list -> typ list) ->
    19     (string -> typ option) -> (indexname -> typ option) -> Name.context -> int ->
    20     term list -> term list
    21 end;
    22 
    23 structure TypeInfer: TYPE_INFER =
    24 struct
    25 
    26 
    27 (** type parameters and constraints **)
    28 
    29 fun anyT S = TFree ("'_dummy_", S);
    30 
    31 (*indicate polymorphic Vars*)
    32 fun polymorphicT T = Type ("_polymorphic_", [T]);
    33 
    34 val constrain = Syntax.type_constraint;
    35 
    36 
    37 (* user parameters *)
    38 
    39 fun is_param (x, _: int) = String.isPrefix "?" x;
    40 fun param i (x, S) = TVar (("?" ^ x, i), S);
    41 
    42 val paramify_vars =
    43   Same.commit
    44     (Term_Subst.map_atypsT_same
    45       (fn TVar ((x, i), S) => (param i (x, S)) | _ => raise Same.SAME));
    46 
    47 val paramify_dummies =
    48   let
    49     fun dummy S maxidx = (param (maxidx + 1) ("'dummy", S), maxidx + 1);
    50 
    51     fun paramify (TFree ("'_dummy_", S)) maxidx = dummy S maxidx
    52       | paramify (Type ("dummy", _)) maxidx = dummy [] maxidx
    53       | paramify (Type (a, Ts)) maxidx =
    54           let val (Ts', maxidx') = fold_map paramify Ts maxidx
    55           in (Type (a, Ts'), maxidx') end
    56       | paramify T maxidx = (T, maxidx);
    57   in paramify end;
    58 
    59 fun fixate_params name_context ts =
    60   let
    61     fun subst_param (xi, S) (inst, used) =
    62       if is_param xi then
    63         let
    64           val [a] = Name.invents used Name.aT 1;
    65           val used' = Name.declare a used;
    66         in (((xi, S), TFree (a, S)) :: inst, used') end
    67       else (inst, used);
    68     val name_context' = (fold o fold_types) Term.declare_typ_names ts name_context;
    69     val (inst, _) = fold_rev subst_param (fold Term.add_tvars ts []) ([], name_context');
    70   in (map o map_types) (Term_Subst.instantiateT inst) ts end;
    71 
    72 
    73 
    74 (** pretyps and preterms **)
    75 
    76 (*parameters may get instantiated, anything else is rigid*)
    77 datatype pretyp =
    78   PType of string * pretyp list |
    79   PTFree of string * sort |
    80   PTVar of indexname * sort |
    81   Param of int * sort;
    82 
    83 datatype preterm =
    84   PConst of string * pretyp |
    85   PFree of string * pretyp |
    86   PVar of indexname * pretyp |
    87   PBound of int |
    88   PAbs of string * pretyp * preterm |
    89   PAppl of preterm * preterm |
    90   Constraint of preterm * pretyp;
    91 
    92 
    93 (* utils *)
    94 
    95 fun deref tye (T as Param (i, S)) =
    96       (case Inttab.lookup tye i of
    97         NONE => T
    98       | SOME U => deref tye U)
    99   | deref tye T = T;
   100 
   101 fun fold_pretyps f (PConst (_, T)) x = f T x
   102   | fold_pretyps f (PFree (_, T)) x = f T x
   103   | fold_pretyps f (PVar (_, T)) x = f T x
   104   | fold_pretyps _ (PBound _) x = x
   105   | fold_pretyps f (PAbs (_, T, t)) x = fold_pretyps f t (f T x)
   106   | fold_pretyps f (PAppl (t, u)) x = fold_pretyps f u (fold_pretyps f t x)
   107   | fold_pretyps f (Constraint (t, T)) x = f T (fold_pretyps f t x);
   108 
   109 
   110 
   111 (** raw typs/terms to pretyps/preterms **)
   112 
   113 (* pretyp_of *)
   114 
   115 fun pretyp_of is_para typ params_idx =
   116   let
   117     val (params', idx) = fold_atyps
   118       (fn TVar (xi as (x, _), S) =>
   119           (fn ps_idx as (ps, idx) =>
   120             if is_para xi andalso not (Vartab.defined ps xi)
   121             then (Vartab.update (xi, Param (idx, S)) ps, idx + 1) else ps_idx)
   122         | _ => I) typ params_idx;
   123 
   124     fun pre_of (TVar (v as (xi, _))) idx =
   125           (case Vartab.lookup params' xi of
   126             NONE => PTVar v
   127           | SOME p => p, idx)
   128       | pre_of (TFree ("'_dummy_", S)) idx = (Param (idx, S), idx + 1)
   129       | pre_of (TFree v) idx = (PTFree v, idx)
   130       | pre_of (T as Type (a, Ts)) idx =
   131           if T = dummyT then (Param (idx, []), idx + 1)
   132           else
   133             let val (Ts', idx') = fold_map pre_of Ts idx
   134             in (PType (a, Ts'), idx') end;
   135 
   136     val (ptyp, idx') = pre_of typ idx;
   137   in (ptyp, (params', idx')) end;
   138 
   139 
   140 (* preterm_of *)
   141 
   142 fun preterm_of const_type is_para tm (vparams, params, idx) =
   143   let
   144     fun add_vparm xi (ps_idx as (ps, idx)) =
   145       if not (Vartab.defined ps xi) then
   146         (Vartab.update (xi, Param (idx, [])) ps, idx + 1)
   147       else ps_idx;
   148 
   149     val (vparams', idx') = fold_aterms
   150       (fn Var (_, Type ("_polymorphic_", _)) => I
   151         | Var (xi, _) => add_vparm xi
   152         | Free (x, _) => add_vparm (x, ~1)
   153         | _ => I)
   154       tm (vparams, idx);
   155     fun var_param xi = the (Vartab.lookup vparams' xi);
   156 
   157     val preT_of = pretyp_of is_para;
   158     fun polyT_of T idx = apsnd snd (pretyp_of (K true) T (Vartab.empty, idx));
   159 
   160     fun constraint T t ps =
   161       if T = dummyT then (t, ps)
   162       else
   163         let val (T', ps') = preT_of T ps
   164         in (Constraint (t, T'), ps') end;
   165 
   166     fun pre_of (Const (c, T)) (ps, idx) =
   167           (case const_type c of
   168             SOME U =>
   169               let val (pU, idx') = polyT_of U idx
   170               in constraint T (PConst (c, pU)) (ps, idx') end
   171           | NONE => raise TYPE ("No such constant: " ^ quote c, [], []))
   172       | pre_of (Var (xi, Type ("_polymorphic_", [T]))) (ps, idx) =
   173           let val (pT, idx') = polyT_of T idx
   174           in (PVar (xi, pT), (ps, idx')) end
   175       | pre_of (Var (xi, T)) ps_idx = constraint T (PVar (xi, var_param xi)) ps_idx
   176       | pre_of (Free (x, T)) ps_idx = constraint T (PFree (x, var_param (x, ~1))) ps_idx
   177       | pre_of (Const ("_type_constraint_", Type ("fun", [T, _])) $ t) ps_idx =
   178           pre_of t ps_idx |-> constraint T
   179       | pre_of (Bound i) ps_idx = (PBound i, ps_idx)
   180       | pre_of (Abs (x, T, t)) ps_idx =
   181           let
   182             val (T', ps_idx') = preT_of T ps_idx;
   183             val (t', ps_idx'') = pre_of t ps_idx';
   184           in (PAbs (x, T', t'), ps_idx'') end
   185       | pre_of (t $ u) ps_idx =
   186           let
   187             val (t', ps_idx') = pre_of t ps_idx;
   188             val (u', ps_idx'') = pre_of u ps_idx';
   189           in (PAppl (t', u'), ps_idx'') end;
   190 
   191     val (tm', (params', idx'')) = pre_of tm (params, idx');
   192   in (tm', (vparams', params', idx'')) end;
   193 
   194 
   195 
   196 (** pretyps/terms to typs/terms **)
   197 
   198 (* add_parms *)
   199 
   200 fun add_parmsT tye T =
   201   (case deref tye T of
   202     PType (_, Ts) => fold (add_parmsT tye) Ts
   203   | Param (i, _) => insert (op =) i
   204   | _ => I);
   205 
   206 fun add_parms tye = fold_pretyps (add_parmsT tye);
   207 
   208 
   209 (* add_names *)
   210 
   211 fun add_namesT tye T =
   212   (case deref tye T of
   213     PType (_, Ts) => fold (add_namesT tye) Ts
   214   | PTFree (x, _) => Name.declare x
   215   | PTVar ((x, _), _) => Name.declare x
   216   | Param _ => I);
   217 
   218 fun add_names tye = fold_pretyps (add_namesT tye);
   219 
   220 
   221 (* simple_typ/term_of *)
   222 
   223 fun simple_typ_of tye f T =
   224   (case deref tye T of
   225     PType (a, Ts) => Type (a, map (simple_typ_of tye f) Ts)
   226   | PTFree v => TFree v
   227   | PTVar v => TVar v
   228   | Param (i, S) => TVar (f i, S));
   229 
   230 (*convert types, drop constraints*)
   231 fun simple_term_of tye f (PConst (c, T)) = Const (c, simple_typ_of tye f T)
   232   | simple_term_of tye f (PFree (x, T)) = Free (x, simple_typ_of tye f T)
   233   | simple_term_of tye f (PVar (xi, T)) = Var (xi, simple_typ_of tye f T)
   234   | simple_term_of tye f (PBound i) = Bound i
   235   | simple_term_of tye f (PAbs (x, T, t)) =
   236       Abs (x, simple_typ_of tye f T, simple_term_of tye f t)
   237   | simple_term_of tye f (PAppl (t, u)) =
   238       simple_term_of tye f t $ simple_term_of tye f u
   239   | simple_term_of tye f (Constraint (t, _)) = simple_term_of tye f t;
   240 
   241 
   242 (* typs_terms_of *)
   243 
   244 fun typs_terms_of tye used maxidx (Ts, ts) =
   245   let
   246     val used' = fold (add_names tye) ts (fold (add_namesT tye) Ts used);
   247     val parms = rev (fold (add_parms tye) ts (fold (add_parmsT tye) Ts []));
   248     val names = Name.invents used' ("?" ^ Name.aT) (length parms);
   249     val tab = Inttab.make (parms ~~ names);
   250     fun f i = (the (Inttab.lookup tab i), maxidx + 1);
   251   in (map (simple_typ_of tye f) Ts, map (simple_term_of tye f) ts) end;
   252 
   253 
   254 
   255 (** order-sorted unification of types **)
   256 
   257 exception NO_UNIFIER of string * pretyp Inttab.table;
   258 
   259 fun unify pp tsig =
   260   let
   261 
   262     (* adjust sorts of parameters *)
   263 
   264     fun not_of_sort x S' S =
   265       "Variable " ^ x ^ "::" ^ Pretty.string_of_sort pp S' ^ " not of sort " ^
   266         Pretty.string_of_sort pp S;
   267 
   268     fun meet (_, []) tye_idx = tye_idx
   269       | meet (Param (i, S'), S) (tye_idx as (tye, idx)) =
   270           if Type.subsort tsig (S', S) then tye_idx
   271           else (Inttab.update_new (i,
   272             Param (idx, Type.inter_sort tsig (S', S))) tye, idx + 1)
   273       | meet (PType (a, Ts), S) (tye_idx as (tye, _)) =
   274           meets (Ts, Type.arity_sorts pp tsig a S
   275             handle ERROR msg => raise NO_UNIFIER (msg, tye)) tye_idx
   276       | meet (PTFree (x, S'), S) (tye_idx as (tye, _)) =
   277           if Type.subsort tsig (S', S) then tye_idx
   278           else raise NO_UNIFIER (not_of_sort x S' S, tye)
   279       | meet (PTVar (xi, S'), S) (tye_idx as (tye, _)) =
   280           if Type.subsort tsig (S', S) then tye_idx
   281           else raise NO_UNIFIER (not_of_sort (Term.string_of_vname xi) S' S, tye)
   282     and meets (T :: Ts, S :: Ss) (tye_idx as (tye, _)) =
   283           meets (Ts, Ss) (meet (deref tye T, S) tye_idx)
   284       | meets _ tye_idx = tye_idx;
   285 
   286 
   287     (* occurs check and assigment *)
   288 
   289     fun occurs_check tye i (Param (i', S)) =
   290           if i = i' then raise NO_UNIFIER ("Occurs check!", tye)
   291           else
   292             (case Inttab.lookup tye i' of
   293               NONE => ()
   294             | SOME T => occurs_check tye i T)
   295       | occurs_check tye i (PType (_, Ts)) = List.app (occurs_check tye i) Ts
   296       | occurs_check _ _ _ = ();
   297 
   298     fun assign i (T as Param (i', _)) S (tye_idx as (tye, idx)) =
   299           if i = i' then tye_idx
   300           else meet (T, S) (Inttab.update_new (i, T) tye, idx)
   301       | assign i T S (tye, idx) =
   302           (occurs_check tye i T; meet (T, S) (Inttab.update_new (i, T) tye, idx));
   303 
   304 
   305     (* unification *)
   306 
   307     fun unif (T1, T2) (tye_idx as (tye, idx)) =
   308       (case (deref tye T1, deref tye T2) of
   309         (Param (i, S), T) => assign i T S tye_idx
   310       | (T, Param (i, S)) => assign i T S tye_idx
   311       | (PType (a, Ts), PType (b, Us)) =>
   312           if a <> b then
   313             raise NO_UNIFIER ("Clash of types " ^ quote a ^ " and " ^ quote b, tye)
   314           else fold unif (Ts ~~ Us) tye_idx
   315       | (T, U) => if T = U then tye_idx else raise NO_UNIFIER ("", tye));
   316 
   317   in unif end;
   318 
   319 
   320 
   321 (** type inference **)
   322 
   323 (* appl_error *)
   324 
   325 fun appl_error pp why t T u U =
   326  ["Type error in application: " ^ why,
   327   "",
   328   Pretty.string_of (Pretty.block
   329     [Pretty.str "Operator:", Pretty.brk 2, Pretty.term pp t,
   330       Pretty.str " ::", Pretty.brk 1, Pretty.typ pp T]),
   331   Pretty.string_of (Pretty.block
   332     [Pretty.str "Operand:", Pretty.brk 3, Pretty.term pp u,
   333       Pretty.str " ::", Pretty.brk 1, Pretty.typ pp U]),
   334   ""];
   335 
   336 
   337 (* infer *)
   338 
   339 fun infer pp tsig =
   340   let
   341     (* errors *)
   342 
   343     fun unif_failed msg =
   344       "Type unification failed" ^ (if msg = "" then "" else ": " ^ msg) ^ "\n";
   345 
   346     fun prep_output tye bs ts Ts =
   347       let
   348         val (Ts_bTs', ts') = typs_terms_of tye Name.context ~1 (Ts @ map snd bs, ts);
   349         val (Ts', Ts'') = chop (length Ts) Ts_bTs';
   350         fun prep t =
   351           let val xs = rev (Term.variant_frees t (rev (map fst bs ~~ Ts'')))
   352           in Term.subst_bounds (map Syntax.mark_boundT xs, t) end;
   353       in (map prep ts', Ts') end;
   354 
   355     fun err_loose i =
   356       raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], []);
   357 
   358     fun err_appl msg tye bs t T u U =
   359       let
   360         val ([t', u'], [T', U']) = prep_output tye bs [t, u] [T, U];
   361         val why =
   362           (case T' of
   363             Type ("fun", _) => "Incompatible operand type"
   364           | _ => "Operator not of function type");
   365         val text = unif_failed msg ^ cat_lines (appl_error pp why t' T' u' U');
   366       in raise TYPE (text, [T', U'], [t', u']) end;
   367 
   368     fun err_constraint msg tye bs t T U =
   369       let
   370         val ([t'], [T', U']) = prep_output tye bs [t] [T, U];
   371         val text = cat_lines
   372          [unif_failed msg,
   373           "Cannot meet type constraint:", "",
   374           Pretty.string_of (Pretty.block
   375            [Pretty.str "Term:", Pretty.brk 2, Pretty.term pp t',
   376             Pretty.str " ::", Pretty.brk 1, Pretty.typ pp T']),
   377           Pretty.string_of (Pretty.block
   378            [Pretty.str "Type:", Pretty.brk 2, Pretty.typ pp U']), ""];
   379       in raise TYPE (text, [T', U'], [t']) end;
   380 
   381 
   382     (* main *)
   383 
   384     val unif = unify pp tsig;
   385 
   386     fun inf _ (PConst (_, T)) tye_idx = (T, tye_idx)
   387       | inf _ (PFree (_, T)) tye_idx = (T, tye_idx)
   388       | inf _ (PVar (_, T)) tye_idx = (T, tye_idx)
   389       | inf bs (PBound i) tye_idx =
   390           (snd (nth bs i handle Subscript => err_loose i), tye_idx)
   391       | inf bs (PAbs (x, T, t)) tye_idx =
   392           let val (U, tye_idx') = inf ((x, T) :: bs) t tye_idx
   393           in (PType ("fun", [T, U]), tye_idx') end
   394       | inf bs (PAppl (t, u)) tye_idx =
   395           let
   396             val (T, tye_idx') = inf bs t tye_idx;
   397             val (U, (tye, idx)) = inf bs u tye_idx';
   398             val V = Param (idx, []);
   399             val U_to_V = PType ("fun", [U, V]);
   400             val tye_idx'' = unif (U_to_V, T) (tye, idx + 1)
   401               handle NO_UNIFIER (msg, tye') => err_appl msg tye' bs t T u U;
   402           in (V, tye_idx'') end
   403       | inf bs (Constraint (t, U)) tye_idx =
   404           let val (T, tye_idx') = inf bs t tye_idx in
   405             (T,
   406              unif (T, U) tye_idx'
   407                handle NO_UNIFIER (msg, tye) => err_constraint msg tye bs t T U)
   408           end;
   409 
   410   in inf [] end;
   411 
   412 
   413 (* infer_types *)
   414 
   415 fun infer_types pp tsig check_typs const_type var_type used maxidx raw_ts =
   416   let
   417     (*constrain vars*)
   418     val get_type = the_default dummyT o var_type;
   419     val constrain_vars = Term.map_aterms
   420       (fn Free (x, T) => constrain T (Free (x, get_type (x, ~1)))
   421         | Var (xi, T) => constrain T (Var (xi, get_type xi))
   422         | t => t);
   423 
   424     (*convert to preterms*)
   425     val ts = burrow_types check_typs raw_ts;
   426     val (ts', (_, _, idx)) =
   427       fold_map (preterm_of const_type is_param o constrain_vars) ts
   428       (Vartab.empty, Vartab.empty, 0);
   429 
   430     (*do type inference*)
   431     val (tye, _) = fold (snd oo infer pp tsig) ts' (Inttab.empty, idx);
   432   in #2 (typs_terms_of tye used maxidx ([], ts')) end;
   433 
   434 end;