src/HOL/Analysis/Linear_Algebra.thy
author immler
Wed May 02 13:49:38 2018 +0200 (12 months ago)
changeset 68072 493b818e8e10
parent 67982 7643b005b29a
child 68073 fad29d2a17a5
permissions -rw-r--r--
added Johannes' generalizations Modules.thy and Vector_Spaces.thy; adapted HOL and HOL-Analysis accordingly
     1 (*  Title:      HOL/Analysis/Linear_Algebra.thy
     2     Author:     Amine Chaieb, University of Cambridge
     3 *)
     4 
     5 section \<open>Elementary linear algebra on Euclidean spaces\<close>
     6 
     7 theory Linear_Algebra
     8 imports
     9   Euclidean_Space
    10   "HOL-Library.Infinite_Set"
    11 begin
    12 
    13 lemma linear_simps:
    14   assumes "bounded_linear f"
    15   shows
    16     "f (a + b) = f a + f b"
    17     "f (a - b) = f a - f b"
    18     "f 0 = 0"
    19     "f (- a) = - f a"
    20     "f (s *\<^sub>R v) = s *\<^sub>R (f v)"
    21 proof -
    22   interpret f: bounded_linear f by fact
    23   show "f (a + b) = f a + f b" by (rule f.add)
    24   show "f (a - b) = f a - f b" by (rule f.diff)
    25   show "f 0 = 0" by (rule f.zero)
    26   show "f (- a) = - f a" by (rule f.neg)
    27   show "f (s *\<^sub>R v) = s *\<^sub>R (f v)" by (rule f.scale)
    28 qed
    29 
    30 lemma bounded_linearI:
    31   assumes "\<And>x y. f (x + y) = f x + f y"
    32     and "\<And>r x. f (r *\<^sub>R x) = r *\<^sub>R f x"
    33     and "\<And>x. norm (f x) \<le> norm x * K"
    34   shows "bounded_linear f"
    35   using assms by (rule bounded_linear_intro) (* FIXME: duplicate *)
    36 
    37 lemma finite_Atleast_Atmost_nat[simp]: "finite {f x |x. x\<in> (UNIV::'a::finite set)}"
    38 proof -
    39   have eq: "{f x |x. x\<in> UNIV} = f ` UNIV"
    40     by auto
    41   show ?thesis unfolding eq
    42     apply (rule finite_imageI)
    43     apply (rule finite)
    44     done
    45 qed
    46 
    47 
    48 subsection%unimportant \<open>More interesting properties of the norm.\<close>
    49 
    50 notation inner (infix "\<bullet>" 70)
    51 
    52 text\<open>Equality of vectors in terms of @{term "(\<bullet>)"} products.\<close>
    53 
    54 lemma linear_componentwise:
    55   fixes f:: "'a::euclidean_space \<Rightarrow> 'b::real_inner"
    56   assumes lf: "linear f"
    57   shows "(f x) \<bullet> j = (\<Sum>i\<in>Basis. (x\<bullet>i) * (f i\<bullet>j))" (is "?lhs = ?rhs")
    58 proof -
    59   interpret linear f by fact
    60   have "?rhs = (\<Sum>i\<in>Basis. (x\<bullet>i) *\<^sub>R (f i))\<bullet>j"
    61     by (simp add: inner_sum_left)
    62   then show ?thesis
    63     by (simp add: euclidean_representation sum[symmetric] scale[symmetric])
    64 qed
    65 
    66 lemma vector_eq: "x = y \<longleftrightarrow> x \<bullet> x = x \<bullet> y \<and> y \<bullet> y = x \<bullet> x"
    67   (is "?lhs \<longleftrightarrow> ?rhs")
    68 proof
    69   assume ?lhs
    70   then show ?rhs by simp
    71 next
    72   assume ?rhs
    73   then have "x \<bullet> x - x \<bullet> y = 0 \<and> x \<bullet> y - y \<bullet> y = 0"
    74     by simp
    75   then have "x \<bullet> (x - y) = 0 \<and> y \<bullet> (x - y) = 0"
    76     by (simp add: inner_diff inner_commute)
    77   then have "(x - y) \<bullet> (x - y) = 0"
    78     by (simp add: field_simps inner_diff inner_commute)
    79   then show "x = y" by simp
    80 qed
    81 
    82 lemma norm_triangle_half_r:
    83   "norm (y - x1) < e / 2 \<Longrightarrow> norm (y - x2) < e / 2 \<Longrightarrow> norm (x1 - x2) < e"
    84   using dist_triangle_half_r unfolding dist_norm[symmetric] by auto
    85 
    86 lemma norm_triangle_half_l:
    87   assumes "norm (x - y) < e / 2"
    88     and "norm (x' - y) < e / 2"
    89   shows "norm (x - x') < e"
    90   using dist_triangle_half_l[OF assms[unfolded dist_norm[symmetric]]]
    91   unfolding dist_norm[symmetric] .
    92 
    93 lemma norm_triangle_le: "norm x + norm y \<le> e \<Longrightarrow> norm (x + y) \<le> e"
    94   by (rule norm_triangle_ineq [THEN order_trans])
    95 
    96 lemma norm_triangle_lt: "norm x + norm y < e \<Longrightarrow> norm (x + y) < e"
    97   by (rule norm_triangle_ineq [THEN le_less_trans])
    98 
    99 lemma abs_triangle_half_r:
   100   fixes y :: "'a::linordered_field"
   101   shows "abs (y - x1) < e / 2 \<Longrightarrow> abs (y - x2) < e / 2 \<Longrightarrow> abs (x1 - x2) < e"
   102   by linarith
   103 
   104 lemma abs_triangle_half_l:
   105   fixes y :: "'a::linordered_field"
   106   assumes "abs (x - y) < e / 2"
   107     and "abs (x' - y) < e / 2"
   108   shows "abs (x - x') < e"
   109   using assms by linarith
   110 
   111 lemma sum_clauses:
   112   shows "sum f {} = 0"
   113     and "finite S \<Longrightarrow> sum f (insert x S) = (if x \<in> S then sum f S else f x + sum f S)"
   114   by (auto simp add: insert_absorb)
   115 
   116 lemma sum_norm_bound:
   117   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
   118   assumes K: "\<And>x. x \<in> S \<Longrightarrow> norm (f x) \<le> K"
   119   shows "norm (sum f S) \<le> of_nat (card S)*K"
   120   using sum_norm_le[OF K] sum_constant[symmetric]
   121   by simp
   122 
   123 lemma sum_group:
   124   assumes fS: "finite S" and fT: "finite T" and fST: "f ` S \<subseteq> T"
   125   shows "sum (\<lambda>y. sum g {x. x \<in> S \<and> f x = y}) T = sum g S"
   126   apply (subst sum_image_gen[OF fS, of g f])
   127   apply (rule sum.mono_neutral_right[OF fT fST])
   128   apply (auto intro: sum.neutral)
   129   done
   130 
   131 lemma vector_eq_ldot: "(\<forall>x. x \<bullet> y = x \<bullet> z) \<longleftrightarrow> y = z"
   132 proof
   133   assume "\<forall>x. x \<bullet> y = x \<bullet> z"
   134   then have "\<forall>x. x \<bullet> (y - z) = 0"
   135     by (simp add: inner_diff)
   136   then have "(y - z) \<bullet> (y - z) = 0" ..
   137   then show "y = z" by simp
   138 qed simp
   139 
   140 lemma vector_eq_rdot: "(\<forall>z. x \<bullet> z = y \<bullet> z) \<longleftrightarrow> x = y"
   141 proof
   142   assume "\<forall>z. x \<bullet> z = y \<bullet> z"
   143   then have "\<forall>z. (x - y) \<bullet> z = 0"
   144     by (simp add: inner_diff)
   145   then have "(x - y) \<bullet> (x - y) = 0" ..
   146   then show "x = y" by simp
   147 qed simp
   148 
   149 
   150 subsection \<open>Orthogonality.\<close>
   151 
   152 definition%important (in real_inner) "orthogonal x y \<longleftrightarrow> x \<bullet> y = 0"
   153 
   154 context real_inner
   155 begin
   156 
   157 lemma orthogonal_self: "orthogonal x x \<longleftrightarrow> x = 0"
   158   by (simp add: orthogonal_def)
   159 
   160 lemma orthogonal_clauses:
   161   "orthogonal a 0"
   162   "orthogonal a x \<Longrightarrow> orthogonal a (c *\<^sub>R x)"
   163   "orthogonal a x \<Longrightarrow> orthogonal a (- x)"
   164   "orthogonal a x \<Longrightarrow> orthogonal a y \<Longrightarrow> orthogonal a (x + y)"
   165   "orthogonal a x \<Longrightarrow> orthogonal a y \<Longrightarrow> orthogonal a (x - y)"
   166   "orthogonal 0 a"
   167   "orthogonal x a \<Longrightarrow> orthogonal (c *\<^sub>R x) a"
   168   "orthogonal x a \<Longrightarrow> orthogonal (- x) a"
   169   "orthogonal x a \<Longrightarrow> orthogonal y a \<Longrightarrow> orthogonal (x + y) a"
   170   "orthogonal x a \<Longrightarrow> orthogonal y a \<Longrightarrow> orthogonal (x - y) a"
   171   unfolding orthogonal_def inner_add inner_diff by auto
   172 
   173 end
   174 
   175 lemma orthogonal_commute: "orthogonal x y \<longleftrightarrow> orthogonal y x"
   176   by (simp add: orthogonal_def inner_commute)
   177 
   178 lemma orthogonal_scaleR [simp]: "c \<noteq> 0 \<Longrightarrow> orthogonal (c *\<^sub>R x) = orthogonal x"
   179   by (rule ext) (simp add: orthogonal_def)
   180 
   181 lemma pairwise_ortho_scaleR:
   182     "pairwise (\<lambda>i j. orthogonal (f i) (g j)) B
   183     \<Longrightarrow> pairwise (\<lambda>i j. orthogonal (a i *\<^sub>R f i) (a j *\<^sub>R g j)) B"
   184   by (auto simp: pairwise_def orthogonal_clauses)
   185 
   186 lemma orthogonal_rvsum:
   187     "\<lbrakk>finite s; \<And>y. y \<in> s \<Longrightarrow> orthogonal x (f y)\<rbrakk> \<Longrightarrow> orthogonal x (sum f s)"
   188   by (induction s rule: finite_induct) (auto simp: orthogonal_clauses)
   189 
   190 lemma orthogonal_lvsum:
   191     "\<lbrakk>finite s; \<And>x. x \<in> s \<Longrightarrow> orthogonal (f x) y\<rbrakk> \<Longrightarrow> orthogonal (sum f s) y"
   192   by (induction s rule: finite_induct) (auto simp: orthogonal_clauses)
   193 
   194 lemma norm_add_Pythagorean:
   195   assumes "orthogonal a b"
   196     shows "norm(a + b) ^ 2 = norm a ^ 2 + norm b ^ 2"
   197 proof -
   198   from assms have "(a - (0 - b)) \<bullet> (a - (0 - b)) = a \<bullet> a - (0 - b \<bullet> b)"
   199     by (simp add: algebra_simps orthogonal_def inner_commute)
   200   then show ?thesis
   201     by (simp add: power2_norm_eq_inner)
   202 qed
   203 
   204 lemma norm_sum_Pythagorean:
   205   assumes "finite I" "pairwise (\<lambda>i j. orthogonal (f i) (f j)) I"
   206     shows "(norm (sum f I))\<^sup>2 = (\<Sum>i\<in>I. (norm (f i))\<^sup>2)"
   207 using assms
   208 proof (induction I rule: finite_induct)
   209   case empty then show ?case by simp
   210 next
   211   case (insert x I)
   212   then have "orthogonal (f x) (sum f I)"
   213     by (metis pairwise_insert orthogonal_rvsum)
   214   with insert show ?case
   215     by (simp add: pairwise_insert norm_add_Pythagorean)
   216 qed
   217 
   218 
   219 subsection \<open>Bilinear functions.\<close>
   220 
   221 definition%important "bilinear f \<longleftrightarrow> (\<forall>x. linear (\<lambda>y. f x y)) \<and> (\<forall>y. linear (\<lambda>x. f x y))"
   222 
   223 lemma bilinear_ladd: "bilinear h \<Longrightarrow> h (x + y) z = h x z + h y z"
   224   by (simp add: bilinear_def linear_iff)
   225 
   226 lemma bilinear_radd: "bilinear h \<Longrightarrow> h x (y + z) = h x y + h x z"
   227   by (simp add: bilinear_def linear_iff)
   228 
   229 lemma bilinear_lmul: "bilinear h \<Longrightarrow> h (c *\<^sub>R x) y = c *\<^sub>R h x y"
   230   by (simp add: bilinear_def linear_iff)
   231 
   232 lemma bilinear_rmul: "bilinear h \<Longrightarrow> h x (c *\<^sub>R y) = c *\<^sub>R h x y"
   233   by (simp add: bilinear_def linear_iff)
   234 
   235 lemma bilinear_lneg: "bilinear h \<Longrightarrow> h (- x) y = - h x y"
   236   by (drule bilinear_lmul [of _ "- 1"]) simp
   237 
   238 lemma bilinear_rneg: "bilinear h \<Longrightarrow> h x (- y) = - h x y"
   239   by (drule bilinear_rmul [of _ _ "- 1"]) simp
   240 
   241 lemma (in ab_group_add) eq_add_iff: "x = x + y \<longleftrightarrow> y = 0"
   242   using add_left_imp_eq[of x y 0] by auto
   243 
   244 lemma bilinear_lzero:
   245   assumes "bilinear h"
   246   shows "h 0 x = 0"
   247   using bilinear_ladd [OF assms, of 0 0 x] by (simp add: eq_add_iff field_simps)
   248 
   249 lemma bilinear_rzero:
   250   assumes "bilinear h"
   251   shows "h x 0 = 0"
   252   using bilinear_radd [OF assms, of x 0 0 ] by (simp add: eq_add_iff field_simps)
   253 
   254 lemma bilinear_lsub: "bilinear h \<Longrightarrow> h (x - y) z = h x z - h y z"
   255   using bilinear_ladd [of h x "- y"] by (simp add: bilinear_lneg)
   256 
   257 lemma bilinear_rsub: "bilinear h \<Longrightarrow> h z (x - y) = h z x - h z y"
   258   using bilinear_radd [of h _ x "- y"] by (simp add: bilinear_rneg)
   259 
   260 lemma bilinear_sum:
   261   assumes "bilinear h"
   262   shows "h (sum f S) (sum g T) = sum (\<lambda>(i,j). h (f i) (g j)) (S \<times> T) "
   263 proof -
   264   interpret l: linear "\<lambda>x. h x y" for y using assms by (simp add: bilinear_def)
   265   interpret r: linear "\<lambda>y. h x y" for x using assms by (simp add: bilinear_def)
   266   have "h (sum f S) (sum g T) = sum (\<lambda>x. h (f x) (sum g T)) S"
   267     by (simp add: l.sum)
   268   also have "\<dots> = sum (\<lambda>x. sum (\<lambda>y. h (f x) (g y)) T) S"
   269     by (rule sum.cong) (simp_all add: r.sum)
   270   finally show ?thesis
   271     unfolding sum.cartesian_product .
   272 qed
   273 
   274 
   275 subsection \<open>Adjoints.\<close>
   276 
   277 definition%important "adjoint f = (SOME f'. \<forall>x y. f x \<bullet> y = x \<bullet> f' y)"
   278 
   279 lemma adjoint_unique:
   280   assumes "\<forall>x y. inner (f x) y = inner x (g y)"
   281   shows "adjoint f = g"
   282   unfolding adjoint_def
   283 proof (rule some_equality)
   284   show "\<forall>x y. inner (f x) y = inner x (g y)"
   285     by (rule assms)
   286 next
   287   fix h
   288   assume "\<forall>x y. inner (f x) y = inner x (h y)"
   289   then have "\<forall>x y. inner x (g y) = inner x (h y)"
   290     using assms by simp
   291   then have "\<forall>x y. inner x (g y - h y) = 0"
   292     by (simp add: inner_diff_right)
   293   then have "\<forall>y. inner (g y - h y) (g y - h y) = 0"
   294     by simp
   295   then have "\<forall>y. h y = g y"
   296     by simp
   297   then show "h = g" by (simp add: ext)
   298 qed
   299 
   300 text \<open>TODO: The following lemmas about adjoints should hold for any
   301   Hilbert space (i.e. complete inner product space).
   302   (see \<^url>\<open>http://en.wikipedia.org/wiki/Hermitian_adjoint\<close>)
   303 \<close>
   304 
   305 lemma adjoint_works:
   306   fixes f :: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
   307   assumes lf: "linear f"
   308   shows "x \<bullet> adjoint f y = f x \<bullet> y"
   309 proof -
   310   interpret linear f by fact
   311   have "\<forall>y. \<exists>w. \<forall>x. f x \<bullet> y = x \<bullet> w"
   312   proof (intro allI exI)
   313     fix y :: "'m" and x
   314     let ?w = "(\<Sum>i\<in>Basis. (f i \<bullet> y) *\<^sub>R i) :: 'n"
   315     have "f x \<bullet> y = f (\<Sum>i\<in>Basis. (x \<bullet> i) *\<^sub>R i) \<bullet> y"
   316       by (simp add: euclidean_representation)
   317     also have "\<dots> = (\<Sum>i\<in>Basis. (x \<bullet> i) *\<^sub>R f i) \<bullet> y"
   318       by (simp add: sum scale)
   319     finally show "f x \<bullet> y = x \<bullet> ?w"
   320       by (simp add: inner_sum_left inner_sum_right mult.commute)
   321   qed
   322   then show ?thesis
   323     unfolding adjoint_def choice_iff
   324     by (intro someI2_ex[where Q="\<lambda>f'. x \<bullet> f' y = f x \<bullet> y"]) auto
   325 qed
   326 
   327 lemma adjoint_clauses:
   328   fixes f :: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
   329   assumes lf: "linear f"
   330   shows "x \<bullet> adjoint f y = f x \<bullet> y"
   331     and "adjoint f y \<bullet> x = y \<bullet> f x"
   332   by (simp_all add: adjoint_works[OF lf] inner_commute)
   333 
   334 lemma adjoint_linear:
   335   fixes f :: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
   336   assumes lf: "linear f"
   337   shows "linear (adjoint f)"
   338   by (simp add: lf linear_iff euclidean_eq_iff[where 'a='n] euclidean_eq_iff[where 'a='m]
   339     adjoint_clauses[OF lf] inner_distrib)
   340 
   341 lemma adjoint_adjoint:
   342   fixes f :: "'n::euclidean_space \<Rightarrow> 'm::euclidean_space"
   343   assumes lf: "linear f"
   344   shows "adjoint (adjoint f) = f"
   345   by (rule adjoint_unique, simp add: adjoint_clauses [OF lf])
   346 
   347 
   348 subsection%unimportant \<open>Interlude: Some properties of real sets\<close>
   349 
   350 lemma seq_mono_lemma:
   351   assumes "\<forall>(n::nat) \<ge> m. (d n :: real) < e n"
   352     and "\<forall>n \<ge> m. e n \<le> e m"
   353   shows "\<forall>n \<ge> m. d n < e m"
   354   using assms
   355   apply auto
   356   apply (erule_tac x="n" in allE)
   357   apply (erule_tac x="n" in allE)
   358   apply auto
   359   done
   360 
   361 lemma infinite_enumerate:
   362   assumes fS: "infinite S"
   363   shows "\<exists>r::nat\<Rightarrow>nat. strict_mono r \<and> (\<forall>n. r n \<in> S)"
   364   unfolding strict_mono_def
   365   using enumerate_in_set[OF fS] enumerate_mono[of _ _ S] fS by auto
   366 
   367 lemma approachable_lt_le: "(\<exists>(d::real) > 0. \<forall>x. f x < d \<longrightarrow> P x) \<longleftrightarrow> (\<exists>d>0. \<forall>x. f x \<le> d \<longrightarrow> P x)"
   368   apply auto
   369   apply (rule_tac x="d/2" in exI)
   370   apply auto
   371   done
   372 
   373 lemma approachable_lt_le2:  \<comment> \<open>like the above, but pushes aside an extra formula\<close>
   374     "(\<exists>(d::real) > 0. \<forall>x. Q x \<longrightarrow> f x < d \<longrightarrow> P x) \<longleftrightarrow> (\<exists>d>0. \<forall>x. f x \<le> d \<longrightarrow> Q x \<longrightarrow> P x)"
   375   apply auto
   376   apply (rule_tac x="d/2" in exI, auto)
   377   done
   378 
   379 lemma triangle_lemma:
   380   fixes x y z :: real
   381   assumes x: "0 \<le> x"
   382     and y: "0 \<le> y"
   383     and z: "0 \<le> z"
   384     and xy: "x\<^sup>2 \<le> y\<^sup>2 + z\<^sup>2"
   385   shows "x \<le> y + z"
   386 proof -
   387   have "y\<^sup>2 + z\<^sup>2 \<le> y\<^sup>2 + 2 * y * z + z\<^sup>2"
   388     using z y by simp
   389   with xy have th: "x\<^sup>2 \<le> (y + z)\<^sup>2"
   390     by (simp add: power2_eq_square field_simps)
   391   from y z have yz: "y + z \<ge> 0"
   392     by arith
   393   from power2_le_imp_le[OF th yz] show ?thesis .
   394 qed
   395 
   396 
   397 
   398 subsection \<open>Archimedean properties and useful consequences\<close>
   399 
   400 text\<open>Bernoulli's inequality\<close>
   401 proposition%important Bernoulli_inequality:
   402   fixes x :: real
   403   assumes "-1 \<le> x"
   404     shows "1 + n * x \<le> (1 + x) ^ n"
   405 proof%unimportant (induct n)
   406   case 0
   407   then show ?case by simp
   408 next
   409   case (Suc n)
   410   have "1 + Suc n * x \<le> 1 + (Suc n)*x + n * x^2"
   411     by (simp add: algebra_simps)
   412   also have "... = (1 + x) * (1 + n*x)"
   413     by (auto simp: power2_eq_square algebra_simps  of_nat_Suc)
   414   also have "... \<le> (1 + x) ^ Suc n"
   415     using Suc.hyps assms mult_left_mono by fastforce
   416   finally show ?case .
   417 qed
   418 
   419 corollary Bernoulli_inequality_even:
   420   fixes x :: real
   421   assumes "even n"
   422     shows "1 + n * x \<le> (1 + x) ^ n"
   423 proof (cases "-1 \<le> x \<or> n=0")
   424   case True
   425   then show ?thesis
   426     by (auto simp: Bernoulli_inequality)
   427 next
   428   case False
   429   then have "real n \<ge> 1"
   430     by simp
   431   with False have "n * x \<le> -1"
   432     by (metis linear minus_zero mult.commute mult.left_neutral mult_left_mono_neg neg_le_iff_le order_trans zero_le_one)
   433   then have "1 + n * x \<le> 0"
   434     by auto
   435   also have "... \<le> (1 + x) ^ n"
   436     using assms
   437     using zero_le_even_power by blast
   438   finally show ?thesis .
   439 qed
   440 
   441 corollary real_arch_pow:
   442   fixes x :: real
   443   assumes x: "1 < x"
   444   shows "\<exists>n. y < x^n"
   445 proof -
   446   from x have x0: "x - 1 > 0"
   447     by arith
   448   from reals_Archimedean3[OF x0, rule_format, of y]
   449   obtain n :: nat where n: "y < real n * (x - 1)" by metis
   450   from x0 have x00: "x- 1 \<ge> -1" by arith
   451   from Bernoulli_inequality[OF x00, of n] n
   452   have "y < x^n" by auto
   453   then show ?thesis by metis
   454 qed
   455 
   456 corollary real_arch_pow_inv:
   457   fixes x y :: real
   458   assumes y: "y > 0"
   459     and x1: "x < 1"
   460   shows "\<exists>n. x^n < y"
   461 proof (cases "x > 0")
   462   case True
   463   with x1 have ix: "1 < 1/x" by (simp add: field_simps)
   464   from real_arch_pow[OF ix, of "1/y"]
   465   obtain n where n: "1/y < (1/x)^n" by blast
   466   then show ?thesis using y \<open>x > 0\<close>
   467     by (auto simp add: field_simps)
   468 next
   469   case False
   470   with y x1 show ?thesis
   471     apply auto
   472     apply (rule exI[where x=1])
   473     apply auto
   474     done
   475 qed
   476 
   477 lemma forall_pos_mono:
   478   "(\<And>d e::real. d < e \<Longrightarrow> P d \<Longrightarrow> P e) \<Longrightarrow>
   479     (\<And>n::nat. n \<noteq> 0 \<Longrightarrow> P (inverse (real n))) \<Longrightarrow> (\<And>e. 0 < e \<Longrightarrow> P e)"
   480   by (metis real_arch_inverse)
   481 
   482 lemma forall_pos_mono_1:
   483   "(\<And>d e::real. d < e \<Longrightarrow> P d \<Longrightarrow> P e) \<Longrightarrow>
   484     (\<And>n. P (inverse (real (Suc n)))) \<Longrightarrow> 0 < e \<Longrightarrow> P e"
   485   apply (rule forall_pos_mono)
   486   apply auto
   487   apply (metis Suc_pred of_nat_Suc)
   488   done
   489 
   490 
   491 subsection%unimportant \<open>Euclidean Spaces as Typeclass\<close>
   492 
   493 lemma independent_Basis: "independent Basis"
   494   by (rule independent_Basis)
   495 
   496 lemma span_Basis [simp]: "span Basis = UNIV"
   497   by (rule span_Basis)
   498 
   499 lemma in_span_Basis: "x \<in> span Basis"
   500   unfolding span_Basis ..
   501 
   502 
   503 subsection%unimportant \<open>Linearity and Bilinearity continued\<close>
   504 
   505 lemma linear_bounded:
   506   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
   507   assumes lf: "linear f"
   508   shows "\<exists>B. \<forall>x. norm (f x) \<le> B * norm x"
   509 proof
   510   interpret linear f by fact
   511   let ?B = "\<Sum>b\<in>Basis. norm (f b)"
   512   show "\<forall>x. norm (f x) \<le> ?B * norm x"
   513   proof
   514     fix x :: 'a
   515     let ?g = "\<lambda>b. (x \<bullet> b) *\<^sub>R f b"
   516     have "norm (f x) = norm (f (\<Sum>b\<in>Basis. (x \<bullet> b) *\<^sub>R b))"
   517       unfolding euclidean_representation ..
   518     also have "\<dots> = norm (sum ?g Basis)"
   519       by (simp add: sum scale)
   520     finally have th0: "norm (f x) = norm (sum ?g Basis)" .
   521     have th: "norm (?g i) \<le> norm (f i) * norm x" if "i \<in> Basis" for i
   522     proof -
   523       from Basis_le_norm[OF that, of x]
   524       show "norm (?g i) \<le> norm (f i) * norm x"
   525         unfolding norm_scaleR
   526         apply (subst mult.commute)
   527         apply (rule mult_mono)
   528         apply (auto simp add: field_simps)
   529         done
   530     qed
   531     from sum_norm_le[of _ ?g, OF th]
   532     show "norm (f x) \<le> ?B * norm x"
   533       unfolding th0 sum_distrib_right by metis
   534   qed
   535 qed
   536 
   537 lemma linear_conv_bounded_linear:
   538   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
   539   shows "linear f \<longleftrightarrow> bounded_linear f"
   540 proof
   541   assume "linear f"
   542   then interpret f: linear f .
   543   show "bounded_linear f"
   544   proof
   545     have "\<exists>B. \<forall>x. norm (f x) \<le> B * norm x"
   546       using \<open>linear f\<close> by (rule linear_bounded)
   547     then show "\<exists>K. \<forall>x. norm (f x) \<le> norm x * K"
   548       by (simp add: mult.commute)
   549   qed
   550 next
   551   assume "bounded_linear f"
   552   then interpret f: bounded_linear f .
   553   show "linear f" ..
   554 qed
   555 
   556 lemmas linear_linear = linear_conv_bounded_linear[symmetric]
   557 
   558 lemma linear_bounded_pos:
   559   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
   560   assumes lf: "linear f"
   561  obtains B where "B > 0" "\<And>x. norm (f x) \<le> B * norm x"
   562 proof -
   563   have "\<exists>B > 0. \<forall>x. norm (f x) \<le> norm x * B"
   564     using lf unfolding linear_conv_bounded_linear
   565     by (rule bounded_linear.pos_bounded)
   566   with that show ?thesis
   567     by (auto simp: mult.commute)
   568 qed
   569 
   570 lemma linear_invertible_bounded_below_pos:
   571   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::euclidean_space"
   572   assumes "linear f" "linear g" "g \<circ> f = id"
   573   obtains B where "B > 0" "\<And>x. B * norm x \<le> norm(f x)"
   574 proof -
   575   obtain B where "B > 0" and B: "\<And>x. norm (g x) \<le> B * norm x"
   576     using linear_bounded_pos [OF \<open>linear g\<close>] by blast
   577   show thesis
   578   proof
   579     show "0 < 1/B"
   580       by (simp add: \<open>B > 0\<close>)
   581     show "1/B * norm x \<le> norm (f x)" for x
   582     proof -
   583       have "1/B * norm x = 1/B * norm (g (f x))"
   584         using assms by (simp add: pointfree_idE)
   585       also have "\<dots> \<le> norm (f x)"
   586         using B [of "f x"] by (simp add: \<open>B > 0\<close> mult.commute pos_divide_le_eq)
   587       finally show ?thesis .
   588     qed
   589   qed
   590 qed
   591 
   592 lemma linear_inj_bounded_below_pos:
   593   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::euclidean_space"
   594   assumes "linear f" "inj f"
   595   obtains B where "B > 0" "\<And>x. B * norm x \<le> norm(f x)"
   596   using linear_injective_left_inverse [OF assms]
   597     linear_invertible_bounded_below_pos assms by blast
   598 
   599 lemma bounded_linearI':
   600   fixes f ::"'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
   601   assumes "\<And>x y. f (x + y) = f x + f y"
   602     and "\<And>c x. f (c *\<^sub>R x) = c *\<^sub>R f x"
   603   shows "bounded_linear f"
   604   using assms linearI linear_conv_bounded_linear by blast
   605 
   606 lemma bilinear_bounded:
   607   fixes h :: "'m::euclidean_space \<Rightarrow> 'n::euclidean_space \<Rightarrow> 'k::real_normed_vector"
   608   assumes bh: "bilinear h"
   609   shows "\<exists>B. \<forall>x y. norm (h x y) \<le> B * norm x * norm y"
   610 proof (clarify intro!: exI[of _ "\<Sum>i\<in>Basis. \<Sum>j\<in>Basis. norm (h i j)"])
   611   fix x :: 'm
   612   fix y :: 'n
   613   have "norm (h x y) = norm (h (sum (\<lambda>i. (x \<bullet> i) *\<^sub>R i) Basis) (sum (\<lambda>i. (y \<bullet> i) *\<^sub>R i) Basis))"
   614     apply (subst euclidean_representation[where 'a='m])
   615     apply (subst euclidean_representation[where 'a='n])
   616     apply rule
   617     done
   618   also have "\<dots> = norm (sum (\<lambda> (i,j). h ((x \<bullet> i) *\<^sub>R i) ((y \<bullet> j) *\<^sub>R j)) (Basis \<times> Basis))"
   619     unfolding bilinear_sum[OF bh] ..
   620   finally have th: "norm (h x y) = \<dots>" .
   621   show "norm (h x y) \<le> (\<Sum>i\<in>Basis. \<Sum>j\<in>Basis. norm (h i j)) * norm x * norm y"
   622     apply (auto simp add: sum_distrib_right th sum.cartesian_product)
   623     apply (rule sum_norm_le)
   624     apply (auto simp add: bilinear_rmul[OF bh] bilinear_lmul[OF bh]
   625       field_simps simp del: scaleR_scaleR)
   626     apply (rule mult_mono)
   627     apply (auto simp add: zero_le_mult_iff Basis_le_norm)
   628     apply (rule mult_mono)
   629     apply (auto simp add: zero_le_mult_iff Basis_le_norm)
   630     done
   631 qed
   632 
   633 lemma bilinear_conv_bounded_bilinear:
   634   fixes h :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space \<Rightarrow> 'c::real_normed_vector"
   635   shows "bilinear h \<longleftrightarrow> bounded_bilinear h"
   636 proof
   637   assume "bilinear h"
   638   show "bounded_bilinear h"
   639   proof
   640     fix x y z
   641     show "h (x + y) z = h x z + h y z"
   642       using \<open>bilinear h\<close> unfolding bilinear_def linear_iff by simp
   643   next
   644     fix x y z
   645     show "h x (y + z) = h x y + h x z"
   646       using \<open>bilinear h\<close> unfolding bilinear_def linear_iff by simp
   647   next
   648     fix r x y
   649     show "h (scaleR r x) y = scaleR r (h x y)"
   650       using \<open>bilinear h\<close> unfolding bilinear_def linear_iff
   651       by simp
   652   next
   653     fix r x y
   654     show "h x (scaleR r y) = scaleR r (h x y)"
   655       using \<open>bilinear h\<close> unfolding bilinear_def linear_iff
   656       by simp
   657   next
   658     have "\<exists>B. \<forall>x y. norm (h x y) \<le> B * norm x * norm y"
   659       using \<open>bilinear h\<close> by (rule bilinear_bounded)
   660     then show "\<exists>K. \<forall>x y. norm (h x y) \<le> norm x * norm y * K"
   661       by (simp add: ac_simps)
   662   qed
   663 next
   664   assume "bounded_bilinear h"
   665   then interpret h: bounded_bilinear h .
   666   show "bilinear h"
   667     unfolding bilinear_def linear_conv_bounded_linear
   668     using h.bounded_linear_left h.bounded_linear_right by simp
   669 qed
   670 
   671 lemma bilinear_bounded_pos:
   672   fixes h :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space \<Rightarrow> 'c::real_normed_vector"
   673   assumes bh: "bilinear h"
   674   shows "\<exists>B > 0. \<forall>x y. norm (h x y) \<le> B * norm x * norm y"
   675 proof -
   676   have "\<exists>B > 0. \<forall>x y. norm (h x y) \<le> norm x * norm y * B"
   677     using bh [unfolded bilinear_conv_bounded_bilinear]
   678     by (rule bounded_bilinear.pos_bounded)
   679   then show ?thesis
   680     by (simp only: ac_simps)
   681 qed
   682 
   683 lemma bounded_linear_imp_has_derivative: "bounded_linear f \<Longrightarrow> (f has_derivative f) net"
   684   by (auto simp add: has_derivative_def linear_diff linear_linear linear_def
   685       dest: bounded_linear.linear)
   686 
   687 lemma linear_imp_has_derivative:
   688   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
   689   shows "linear f \<Longrightarrow> (f has_derivative f) net"
   690   by (simp add: bounded_linear_imp_has_derivative linear_conv_bounded_linear)
   691 
   692 lemma bounded_linear_imp_differentiable: "bounded_linear f \<Longrightarrow> f differentiable net"
   693   using bounded_linear_imp_has_derivative differentiable_def by blast
   694 
   695 lemma linear_imp_differentiable:
   696   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::real_normed_vector"
   697   shows "linear f \<Longrightarrow> f differentiable net"
   698   by (metis linear_imp_has_derivative differentiable_def)
   699 
   700 
   701 subsection%unimportant \<open>We continue.\<close>
   702 
   703 lemma independent_bound:
   704   fixes S :: "'a::euclidean_space set"
   705   shows "independent S \<Longrightarrow> finite S \<and> card S \<le> DIM('a)"
   706   by (metis dim_subset_UNIV finiteI_independent dim_span_eq_card_independent)
   707 
   708 lemmas independent_imp_finite = finiteI_independent
   709 
   710 corollary
   711   fixes S :: "'a::euclidean_space set"
   712   assumes "independent S"
   713   shows independent_card_le:"card S \<le> DIM('a)"
   714   using assms independent_bound by auto
   715 
   716 lemma dependent_biggerset:
   717   fixes S :: "'a::euclidean_space set"
   718   shows "(finite S \<Longrightarrow> card S > DIM('a)) \<Longrightarrow> dependent S"
   719   by (metis independent_bound not_less)
   720 
   721 text \<open>Picking an orthogonal replacement for a spanning set.\<close>
   722 
   723 lemma vector_sub_project_orthogonal:
   724   fixes b x :: "'a::euclidean_space"
   725   shows "b \<bullet> (x - ((b \<bullet> x) / (b \<bullet> b)) *\<^sub>R b) = 0"
   726   unfolding inner_simps by auto
   727 
   728 lemma pairwise_orthogonal_insert:
   729   assumes "pairwise orthogonal S"
   730     and "\<And>y. y \<in> S \<Longrightarrow> orthogonal x y"
   731   shows "pairwise orthogonal (insert x S)"
   732   using assms unfolding pairwise_def
   733   by (auto simp add: orthogonal_commute)
   734 
   735 lemma basis_orthogonal:
   736   fixes B :: "'a::real_inner set"
   737   assumes fB: "finite B"
   738   shows "\<exists>C. finite C \<and> card C \<le> card B \<and> span C = span B \<and> pairwise orthogonal C"
   739   (is " \<exists>C. ?P B C")
   740   using fB
   741 proof (induct rule: finite_induct)
   742   case empty
   743   then show ?case
   744     apply (rule exI[where x="{}"])
   745     apply (auto simp add: pairwise_def)
   746     done
   747 next
   748   case (insert a B)
   749   note fB = \<open>finite B\<close> and aB = \<open>a \<notin> B\<close>
   750   from \<open>\<exists>C. finite C \<and> card C \<le> card B \<and> span C = span B \<and> pairwise orthogonal C\<close>
   751   obtain C where C: "finite C" "card C \<le> card B"
   752     "span C = span B" "pairwise orthogonal C" by blast
   753   let ?a = "a - sum (\<lambda>x. (x \<bullet> a / (x \<bullet> x)) *\<^sub>R x) C"
   754   let ?C = "insert ?a C"
   755   from C(1) have fC: "finite ?C"
   756     by simp
   757   from fB aB C(1,2) have cC: "card ?C \<le> card (insert a B)"
   758     by (simp add: card_insert_if)
   759   {
   760     fix x k
   761     have th0: "\<And>(a::'a) b c. a - (b - c) = c + (a - b)"
   762       by (simp add: field_simps)
   763     have "x - k *\<^sub>R (a - (\<Sum>x\<in>C. (x \<bullet> a / (x \<bullet> x)) *\<^sub>R x)) \<in> span C \<longleftrightarrow> x - k *\<^sub>R a \<in> span C"
   764       apply (simp only: scaleR_right_diff_distrib th0)
   765       apply (rule span_add_eq)
   766       apply (rule span_scale)
   767       apply (rule span_sum)
   768       apply (rule span_scale)
   769       apply (rule span_base)
   770       apply assumption
   771       done
   772   }
   773   then have SC: "span ?C = span (insert a B)"
   774     unfolding set_eq_iff span_breakdown_eq C(3)[symmetric] by auto
   775   {
   776     fix y
   777     assume yC: "y \<in> C"
   778     then have Cy: "C = insert y (C - {y})"
   779       by blast
   780     have fth: "finite (C - {y})"
   781       using C by simp
   782     have "orthogonal ?a y"
   783       unfolding orthogonal_def
   784       unfolding inner_diff inner_sum_left right_minus_eq
   785       unfolding sum.remove [OF \<open>finite C\<close> \<open>y \<in> C\<close>]
   786       apply (clarsimp simp add: inner_commute[of y a])
   787       apply (rule sum.neutral)
   788       apply clarsimp
   789       apply (rule C(4)[unfolded pairwise_def orthogonal_def, rule_format])
   790       using \<open>y \<in> C\<close> by auto
   791   }
   792   with \<open>pairwise orthogonal C\<close> have CPO: "pairwise orthogonal ?C"
   793     by (rule pairwise_orthogonal_insert)
   794   from fC cC SC CPO have "?P (insert a B) ?C"
   795     by blast
   796   then show ?case by blast
   797 qed
   798 
   799 lemma orthogonal_basis_exists:
   800   fixes V :: "('a::euclidean_space) set"
   801   shows "\<exists>B. independent B \<and> B \<subseteq> span V \<and> V \<subseteq> span B \<and>
   802   (card B = dim V) \<and> pairwise orthogonal B"
   803 proof -
   804   from basis_exists[of V] obtain B where
   805     B: "B \<subseteq> V" "independent B" "V \<subseteq> span B" "card B = dim V"
   806     by blast
   807   from B have fB: "finite B" "card B = dim V"
   808     using independent_bound by auto
   809   from basis_orthogonal[OF fB(1)] obtain C where
   810     C: "finite C" "card C \<le> card B" "span C = span B" "pairwise orthogonal C"
   811     by blast
   812   from C B have CSV: "C \<subseteq> span V"
   813     by (metis span_superset span_mono subset_trans)
   814   from span_mono[OF B(3)] C have SVC: "span V \<subseteq> span C"
   815     by (simp add: span_span)
   816   from card_le_dim_spanning[OF CSV SVC C(1)] C(2,3) fB
   817   have iC: "independent C"
   818     by (simp add: dim_span)
   819   from C fB have "card C \<le> dim V"
   820     by simp
   821   moreover have "dim V \<le> card C"
   822     using span_card_ge_dim[OF CSV SVC C(1)]
   823     by simp
   824   ultimately have CdV: "card C = dim V"
   825     using C(1) by simp
   826   from C B CSV CdV iC show ?thesis
   827     by auto
   828 qed
   829 
   830 text \<open>Low-dimensional subset is in a hyperplane (weak orthogonal complement).\<close>
   831 
   832 lemma span_not_univ_orthogonal:
   833   fixes S :: "'a::euclidean_space set"
   834   assumes sU: "span S \<noteq> UNIV"
   835   shows "\<exists>a::'a. a \<noteq> 0 \<and> (\<forall>x \<in> span S. a \<bullet> x = 0)"
   836 proof -
   837   from sU obtain a where a: "a \<notin> span S"
   838     by blast
   839   from orthogonal_basis_exists obtain B where
   840     B: "independent B" "B \<subseteq> span S" "S \<subseteq> span B"
   841     "card B = dim S" "pairwise orthogonal B"
   842     by blast
   843   from B have fB: "finite B" "card B = dim S"
   844     using independent_bound by auto
   845   from span_mono[OF B(2)] span_mono[OF B(3)]
   846   have sSB: "span S = span B"
   847     by (simp add: span_span)
   848   let ?a = "a - sum (\<lambda>b. (a \<bullet> b / (b \<bullet> b)) *\<^sub>R b) B"
   849   have "sum (\<lambda>b. (a \<bullet> b / (b \<bullet> b)) *\<^sub>R b) B \<in> span S"
   850     unfolding sSB
   851     apply (rule span_sum)
   852     apply (rule span_scale)
   853     apply (rule span_base)
   854     apply assumption
   855     done
   856   with a have a0:"?a  \<noteq> 0"
   857     by auto
   858   have "\<forall>x\<in>span B. ?a \<bullet> x = 0"
   859   proof (rule span_induct')
   860     show "subspace {x. ?a \<bullet> x = 0}"
   861       by (auto simp add: subspace_def inner_add)
   862   next
   863     {
   864       fix x
   865       assume x: "x \<in> B"
   866       from x have B': "B = insert x (B - {x})"
   867         by blast
   868       have fth: "finite (B - {x})"
   869         using fB by simp
   870       have "?a \<bullet> x = 0"
   871         apply (subst B')
   872         using fB fth
   873         unfolding sum_clauses(2)[OF fth]
   874         apply simp unfolding inner_simps
   875         apply (clarsimp simp add: inner_add inner_sum_left)
   876         apply (rule sum.neutral, rule ballI)
   877         apply (simp only: inner_commute)
   878         apply (auto simp add: x field_simps
   879           intro: B(5)[unfolded pairwise_def orthogonal_def, rule_format])
   880         done
   881     }
   882     then show "\<forall>x \<in> B. ?a \<bullet> x = 0"
   883       by blast
   884   qed
   885   with a0 show ?thesis
   886     unfolding sSB by (auto intro: exI[where x="?a"])
   887 qed
   888 
   889 lemma span_not_univ_subset_hyperplane:
   890   fixes S :: "'a::euclidean_space set"
   891   assumes SU: "span S \<noteq> UNIV"
   892   shows "\<exists> a. a \<noteq>0 \<and> span S \<subseteq> {x. a \<bullet> x = 0}"
   893   using span_not_univ_orthogonal[OF SU] by auto
   894 
   895 lemma lowdim_subset_hyperplane:
   896   fixes S :: "'a::euclidean_space set"
   897   assumes d: "dim S < DIM('a)"
   898   shows "\<exists>a::'a. a \<noteq> 0 \<and> span S \<subseteq> {x. a \<bullet> x = 0}"
   899 proof -
   900   {
   901     assume "span S = UNIV"
   902     then have "dim (span S) = dim (UNIV :: ('a) set)"
   903       by simp
   904     then have "dim S = DIM('a)"
   905       by (metis Euclidean_Space.dim_UNIV dim_span)
   906     with d have False by arith
   907   }
   908   then have th: "span S \<noteq> UNIV"
   909     by blast
   910   from span_not_univ_subset_hyperplane[OF th] show ?thesis .
   911 qed
   912 
   913 lemma linear_eq_stdbasis:
   914   fixes f :: "'a::euclidean_space \<Rightarrow> _"
   915   assumes lf: "linear f"
   916     and lg: "linear g"
   917     and fg: "\<And>b. b \<in> Basis \<Longrightarrow> f b = g b"
   918   shows "f = g"
   919   using linear_eq_on_span[OF lf lg, of Basis] fg
   920   by auto
   921 
   922 
   923 text \<open>Similar results for bilinear functions.\<close>
   924 
   925 lemma bilinear_eq:
   926   assumes bf: "bilinear f"
   927     and bg: "bilinear g"
   928     and SB: "S \<subseteq> span B"
   929     and TC: "T \<subseteq> span C"
   930     and fg: "\<forall>x\<in> B. \<forall>y\<in> C. f x y = g x y"
   931   shows "\<forall>x\<in>S. \<forall>y\<in>T. f x y = g x y "
   932 proof -
   933   let ?P = "{x. \<forall>y\<in> span C. f x y = g x y}"
   934   from bf bg have sp: "subspace ?P"
   935     unfolding bilinear_def linear_iff subspace_def bf bg
   936     by (auto simp add: span_zero bilinear_lzero[OF bf] bilinear_lzero[OF bg]
   937         span_add Ball_def
   938       intro: bilinear_ladd[OF bf])
   939 
   940   have "\<forall>x \<in> span B. \<forall>y\<in> span C. f x y = g x y"
   941     apply (rule span_induct' [OF _ sp])
   942     apply (rule ballI)
   943     apply (rule span_induct')
   944     apply (simp add: fg)
   945     apply (auto simp add: subspace_def)
   946     using bf bg unfolding bilinear_def linear_iff
   947       apply (auto simp add: span_zero bilinear_rzero[OF bf] bilinear_rzero[OF bg]
   948         span_add Ball_def
   949       intro: bilinear_ladd[OF bf])
   950     done
   951   then show ?thesis
   952     using SB TC by auto
   953 qed
   954 
   955 lemma bilinear_eq_stdbasis:
   956   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space \<Rightarrow> _"
   957   assumes bf: "bilinear f"
   958     and bg: "bilinear g"
   959     and fg: "\<forall>i\<in>Basis. \<forall>j\<in>Basis. f i j = g i j"
   960   shows "f = g"
   961   using bilinear_eq[OF bf bg equalityD2[OF span_Basis] equalityD2[OF span_Basis] fg] by blast
   962 
   963 subsection \<open>Infinity norm\<close>
   964 
   965 definition%important "infnorm (x::'a::euclidean_space) = Sup {\<bar>x \<bullet> b\<bar> |b. b \<in> Basis}"
   966 
   967 lemma infnorm_set_image:
   968   fixes x :: "'a::euclidean_space"
   969   shows "{\<bar>x \<bullet> i\<bar> |i. i \<in> Basis} = (\<lambda>i. \<bar>x \<bullet> i\<bar>) ` Basis"
   970   by blast
   971 
   972 lemma infnorm_Max:
   973   fixes x :: "'a::euclidean_space"
   974   shows "infnorm x = Max ((\<lambda>i. \<bar>x \<bullet> i\<bar>) ` Basis)"
   975   by (simp add: infnorm_def infnorm_set_image cSup_eq_Max)
   976 
   977 lemma infnorm_set_lemma:
   978   fixes x :: "'a::euclidean_space"
   979   shows "finite {\<bar>x \<bullet> i\<bar> |i. i \<in> Basis}"
   980     and "{\<bar>x \<bullet> i\<bar> |i. i \<in> Basis} \<noteq> {}"
   981   unfolding infnorm_set_image
   982   by auto
   983 
   984 lemma infnorm_pos_le:
   985   fixes x :: "'a::euclidean_space"
   986   shows "0 \<le> infnorm x"
   987   by (simp add: infnorm_Max Max_ge_iff ex_in_conv)
   988 
   989 lemma infnorm_triangle:
   990   fixes x :: "'a::euclidean_space"
   991   shows "infnorm (x + y) \<le> infnorm x + infnorm y"
   992 proof -
   993   have *: "\<And>a b c d :: real. \<bar>a\<bar> \<le> c \<Longrightarrow> \<bar>b\<bar> \<le> d \<Longrightarrow> \<bar>a + b\<bar> \<le> c + d"
   994     by simp
   995   show ?thesis
   996     by (auto simp: infnorm_Max inner_add_left intro!: *)
   997 qed
   998 
   999 lemma infnorm_eq_0:
  1000   fixes x :: "'a::euclidean_space"
  1001   shows "infnorm x = 0 \<longleftrightarrow> x = 0"
  1002 proof -
  1003   have "infnorm x \<le> 0 \<longleftrightarrow> x = 0"
  1004     unfolding infnorm_Max by (simp add: euclidean_all_zero_iff)
  1005   then show ?thesis
  1006     using infnorm_pos_le[of x] by simp
  1007 qed
  1008 
  1009 lemma infnorm_0: "infnorm 0 = 0"
  1010   by (simp add: infnorm_eq_0)
  1011 
  1012 lemma infnorm_neg: "infnorm (- x) = infnorm x"
  1013   unfolding infnorm_def
  1014   apply (rule cong[of "Sup" "Sup"])
  1015   apply blast
  1016   apply auto
  1017   done
  1018 
  1019 lemma infnorm_sub: "infnorm (x - y) = infnorm (y - x)"
  1020 proof -
  1021   have "y - x = - (x - y)" by simp
  1022   then show ?thesis
  1023     by (metis infnorm_neg)
  1024 qed
  1025 
  1026 lemma real_abs_sub_infnorm: "\<bar>infnorm x - infnorm y\<bar> \<le> infnorm (x - y)"
  1027 proof -
  1028   have th: "\<And>(nx::real) n ny. nx \<le> n + ny \<Longrightarrow> ny \<le> n + nx \<Longrightarrow> \<bar>nx - ny\<bar> \<le> n"
  1029     by arith
  1030   from infnorm_triangle[of "x - y" " y"] infnorm_triangle[of "x - y" "-x"]
  1031   have ths: "infnorm x \<le> infnorm (x - y) + infnorm y"
  1032     "infnorm y \<le> infnorm (x - y) + infnorm x"
  1033     by (simp_all add: field_simps infnorm_neg)
  1034   from th[OF ths] show ?thesis .
  1035 qed
  1036 
  1037 lemma real_abs_infnorm: "\<bar>infnorm x\<bar> = infnorm x"
  1038   using infnorm_pos_le[of x] by arith
  1039 
  1040 lemma Basis_le_infnorm:
  1041   fixes x :: "'a::euclidean_space"
  1042   shows "b \<in> Basis \<Longrightarrow> \<bar>x \<bullet> b\<bar> \<le> infnorm x"
  1043   by (simp add: infnorm_Max)
  1044 
  1045 lemma infnorm_mul: "infnorm (a *\<^sub>R x) = \<bar>a\<bar> * infnorm x"
  1046   unfolding infnorm_Max
  1047 proof (safe intro!: Max_eqI)
  1048   let ?B = "(\<lambda>i. \<bar>x \<bullet> i\<bar>) ` Basis"
  1049   {
  1050     fix b :: 'a
  1051     assume "b \<in> Basis"
  1052     then show "\<bar>a *\<^sub>R x \<bullet> b\<bar> \<le> \<bar>a\<bar> * Max ?B"
  1053       by (simp add: abs_mult mult_left_mono)
  1054   next
  1055     from Max_in[of ?B] obtain b where "b \<in> Basis" "Max ?B = \<bar>x \<bullet> b\<bar>"
  1056       by (auto simp del: Max_in)
  1057     then show "\<bar>a\<bar> * Max ((\<lambda>i. \<bar>x \<bullet> i\<bar>) ` Basis) \<in> (\<lambda>i. \<bar>a *\<^sub>R x \<bullet> i\<bar>) ` Basis"
  1058       by (intro image_eqI[where x=b]) (auto simp: abs_mult)
  1059   }
  1060 qed simp
  1061 
  1062 lemma infnorm_mul_lemma: "infnorm (a *\<^sub>R x) \<le> \<bar>a\<bar> * infnorm x"
  1063   unfolding infnorm_mul ..
  1064 
  1065 lemma infnorm_pos_lt: "infnorm x > 0 \<longleftrightarrow> x \<noteq> 0"
  1066   using infnorm_pos_le[of x] infnorm_eq_0[of x] by arith
  1067 
  1068 text \<open>Prove that it differs only up to a bound from Euclidean norm.\<close>
  1069 
  1070 lemma infnorm_le_norm: "infnorm x \<le> norm x"
  1071   by (simp add: Basis_le_norm infnorm_Max)
  1072 
  1073 lemma norm_le_infnorm:
  1074   fixes x :: "'a::euclidean_space"
  1075   shows "norm x \<le> sqrt DIM('a) * infnorm x"
  1076 proof -
  1077   let ?d = "DIM('a)"
  1078   have "real ?d \<ge> 0"
  1079     by simp
  1080   then have d2: "(sqrt (real ?d))\<^sup>2 = real ?d"
  1081     by (auto intro: real_sqrt_pow2)
  1082   have th: "sqrt (real ?d) * infnorm x \<ge> 0"
  1083     by (simp add: zero_le_mult_iff infnorm_pos_le)
  1084   have th1: "x \<bullet> x \<le> (sqrt (real ?d) * infnorm x)\<^sup>2"
  1085     unfolding power_mult_distrib d2
  1086     apply (subst euclidean_inner)
  1087     apply (subst power2_abs[symmetric])
  1088     apply (rule order_trans[OF sum_bounded_above[where K="\<bar>infnorm x\<bar>\<^sup>2"]])
  1089     apply (auto simp add: power2_eq_square[symmetric])
  1090     apply (subst power2_abs[symmetric])
  1091     apply (rule power_mono)
  1092     apply (auto simp: infnorm_Max)
  1093     done
  1094   from real_le_lsqrt[OF inner_ge_zero th th1]
  1095   show ?thesis
  1096     unfolding norm_eq_sqrt_inner id_def .
  1097 qed
  1098 
  1099 lemma tendsto_infnorm [tendsto_intros]:
  1100   assumes "(f \<longlongrightarrow> a) F"
  1101   shows "((\<lambda>x. infnorm (f x)) \<longlongrightarrow> infnorm a) F"
  1102 proof (rule tendsto_compose [OF LIM_I assms])
  1103   fix r :: real
  1104   assume "r > 0"
  1105   then show "\<exists>s>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < s \<longrightarrow> norm (infnorm x - infnorm a) < r"
  1106     by (metis real_norm_def le_less_trans real_abs_sub_infnorm infnorm_le_norm)
  1107 qed
  1108 
  1109 text \<open>Equality in Cauchy-Schwarz and triangle inequalities.\<close>
  1110 
  1111 lemma norm_cauchy_schwarz_eq: "x \<bullet> y = norm x * norm y \<longleftrightarrow> norm x *\<^sub>R y = norm y *\<^sub>R x"
  1112   (is "?lhs \<longleftrightarrow> ?rhs")
  1113 proof -
  1114   {
  1115     assume h: "x = 0"
  1116     then have ?thesis by simp
  1117   }
  1118   moreover
  1119   {
  1120     assume h: "y = 0"
  1121     then have ?thesis by simp
  1122   }
  1123   moreover
  1124   {
  1125     assume x: "x \<noteq> 0" and y: "y \<noteq> 0"
  1126     from inner_eq_zero_iff[of "norm y *\<^sub>R x - norm x *\<^sub>R y"]
  1127     have "?rhs \<longleftrightarrow>
  1128       (norm y * (norm y * norm x * norm x - norm x * (x \<bullet> y)) -
  1129         norm x * (norm y * (y \<bullet> x) - norm x * norm y * norm y) =  0)"
  1130       using x y
  1131       unfolding inner_simps
  1132       unfolding power2_norm_eq_inner[symmetric] power2_eq_square right_minus_eq
  1133       apply (simp add: inner_commute)
  1134       apply (simp add: field_simps)
  1135       apply metis
  1136       done
  1137     also have "\<dots> \<longleftrightarrow> (2 * norm x * norm y * (norm x * norm y - x \<bullet> y) = 0)" using x y
  1138       by (simp add: field_simps inner_commute)
  1139     also have "\<dots> \<longleftrightarrow> ?lhs" using x y
  1140       apply simp
  1141       apply metis
  1142       done
  1143     finally have ?thesis by blast
  1144   }
  1145   ultimately show ?thesis by blast
  1146 qed
  1147 
  1148 lemma norm_cauchy_schwarz_abs_eq:
  1149   "\<bar>x \<bullet> y\<bar> = norm x * norm y \<longleftrightarrow>
  1150     norm x *\<^sub>R y = norm y *\<^sub>R x \<or> norm x *\<^sub>R y = - norm y *\<^sub>R x"
  1151   (is "?lhs \<longleftrightarrow> ?rhs")
  1152 proof -
  1153   have th: "\<And>(x::real) a. a \<ge> 0 \<Longrightarrow> \<bar>x\<bar> = a \<longleftrightarrow> x = a \<or> x = - a"
  1154     by arith
  1155   have "?rhs \<longleftrightarrow> norm x *\<^sub>R y = norm y *\<^sub>R x \<or> norm (- x) *\<^sub>R y = norm y *\<^sub>R (- x)"
  1156     by simp
  1157   also have "\<dots> \<longleftrightarrow>(x \<bullet> y = norm x * norm y \<or> (- x) \<bullet> y = norm x * norm y)"
  1158     unfolding norm_cauchy_schwarz_eq[symmetric]
  1159     unfolding norm_minus_cancel norm_scaleR ..
  1160   also have "\<dots> \<longleftrightarrow> ?lhs"
  1161     unfolding th[OF mult_nonneg_nonneg, OF norm_ge_zero[of x] norm_ge_zero[of y]] inner_simps
  1162     by auto
  1163   finally show ?thesis ..
  1164 qed
  1165 
  1166 lemma norm_triangle_eq:
  1167   fixes x y :: "'a::real_inner"
  1168   shows "norm (x + y) = norm x + norm y \<longleftrightarrow> norm x *\<^sub>R y = norm y *\<^sub>R x"
  1169 proof -
  1170   {
  1171     assume x: "x = 0 \<or> y = 0"
  1172     then have ?thesis
  1173       by (cases "x = 0") simp_all
  1174   }
  1175   moreover
  1176   {
  1177     assume x: "x \<noteq> 0" and y: "y \<noteq> 0"
  1178     then have "norm x \<noteq> 0" "norm y \<noteq> 0"
  1179       by simp_all
  1180     then have n: "norm x > 0" "norm y > 0"
  1181       using norm_ge_zero[of x] norm_ge_zero[of y] by arith+
  1182     have th: "\<And>(a::real) b c. a + b + c \<noteq> 0 \<Longrightarrow> a = b + c \<longleftrightarrow> a\<^sup>2 = (b + c)\<^sup>2"
  1183       by algebra
  1184     have "norm (x + y) = norm x + norm y \<longleftrightarrow> (norm (x + y))\<^sup>2 = (norm x + norm y)\<^sup>2"
  1185       apply (rule th)
  1186       using n norm_ge_zero[of "x + y"]
  1187       apply arith
  1188       done
  1189     also have "\<dots> \<longleftrightarrow> norm x *\<^sub>R y = norm y *\<^sub>R x"
  1190       unfolding norm_cauchy_schwarz_eq[symmetric]
  1191       unfolding power2_norm_eq_inner inner_simps
  1192       by (simp add: power2_norm_eq_inner[symmetric] power2_eq_square inner_commute field_simps)
  1193     finally have ?thesis .
  1194   }
  1195   ultimately show ?thesis by blast
  1196 qed
  1197 
  1198 
  1199 subsection \<open>Collinearity\<close>
  1200 
  1201 definition%important collinear :: "'a::real_vector set \<Rightarrow> bool"
  1202   where "collinear S \<longleftrightarrow> (\<exists>u. \<forall>x \<in> S. \<forall> y \<in> S. \<exists>c. x - y = c *\<^sub>R u)"
  1203 
  1204 lemma collinear_alt:
  1205      "collinear S \<longleftrightarrow> (\<exists>u v. \<forall>x \<in> S. \<exists>c. x = u + c *\<^sub>R v)" (is "?lhs = ?rhs")
  1206 proof
  1207   assume ?lhs
  1208   then show ?rhs
  1209     unfolding collinear_def by (metis Groups.add_ac(2) diff_add_cancel)
  1210 next
  1211   assume ?rhs
  1212   then obtain u v where *: "\<And>x. x \<in> S \<Longrightarrow> \<exists>c. x = u + c *\<^sub>R v"
  1213     by (auto simp: )
  1214   have "\<exists>c. x - y = c *\<^sub>R v" if "x \<in> S" "y \<in> S" for x y
  1215         by (metis *[OF \<open>x \<in> S\<close>] *[OF \<open>y \<in> S\<close>] scaleR_left.diff add_diff_cancel_left)
  1216   then show ?lhs
  1217     using collinear_def by blast
  1218 qed
  1219 
  1220 lemma collinear:
  1221   fixes S :: "'a::{perfect_space,real_vector} set"
  1222   shows "collinear S \<longleftrightarrow> (\<exists>u. u \<noteq> 0 \<and> (\<forall>x \<in> S. \<forall> y \<in> S. \<exists>c. x - y = c *\<^sub>R u))"
  1223 proof -
  1224   have "\<exists>v. v \<noteq> 0 \<and> (\<forall>x\<in>S. \<forall>y\<in>S. \<exists>c. x - y = c *\<^sub>R v)"
  1225     if "\<forall>x\<in>S. \<forall>y\<in>S. \<exists>c. x - y = c *\<^sub>R u" "u=0" for u
  1226   proof -
  1227     have "\<forall>x\<in>S. \<forall>y\<in>S. x = y"
  1228       using that by auto
  1229     moreover
  1230     obtain v::'a where "v \<noteq> 0"
  1231       using UNIV_not_singleton [of 0] by auto
  1232     ultimately have "\<forall>x\<in>S. \<forall>y\<in>S. \<exists>c. x - y = c *\<^sub>R v"
  1233       by auto
  1234     then show ?thesis
  1235       using \<open>v \<noteq> 0\<close> by blast
  1236   qed
  1237   then show ?thesis
  1238     apply (clarsimp simp: collinear_def)
  1239     by (metis scaleR_zero_right vector_fraction_eq_iff)
  1240 qed
  1241 
  1242 lemma collinear_subset: "\<lbrakk>collinear T; S \<subseteq> T\<rbrakk> \<Longrightarrow> collinear S"
  1243   by (meson collinear_def subsetCE)
  1244 
  1245 lemma collinear_empty [iff]: "collinear {}"
  1246   by (simp add: collinear_def)
  1247 
  1248 lemma collinear_sing [iff]: "collinear {x}"
  1249   by (simp add: collinear_def)
  1250 
  1251 lemma collinear_2 [iff]: "collinear {x, y}"
  1252   apply (simp add: collinear_def)
  1253   apply (rule exI[where x="x - y"])
  1254   apply auto
  1255   apply (rule exI[where x=1], simp)
  1256   apply (rule exI[where x="- 1"], simp)
  1257   done
  1258 
  1259 lemma collinear_lemma: "collinear {0, x, y} \<longleftrightarrow> x = 0 \<or> y = 0 \<or> (\<exists>c. y = c *\<^sub>R x)"
  1260   (is "?lhs \<longleftrightarrow> ?rhs")
  1261 proof -
  1262   {
  1263     assume "x = 0 \<or> y = 0"
  1264     then have ?thesis
  1265       by (cases "x = 0") (simp_all add: collinear_2 insert_commute)
  1266   }
  1267   moreover
  1268   {
  1269     assume x: "x \<noteq> 0" and y: "y \<noteq> 0"
  1270     have ?thesis
  1271     proof
  1272       assume h: "?lhs"
  1273       then obtain u where u: "\<forall> x\<in> {0,x,y}. \<forall>y\<in> {0,x,y}. \<exists>c. x - y = c *\<^sub>R u"
  1274         unfolding collinear_def by blast
  1275       from u[rule_format, of x 0] u[rule_format, of y 0]
  1276       obtain cx and cy where
  1277         cx: "x = cx *\<^sub>R u" and cy: "y = cy *\<^sub>R u"
  1278         by auto
  1279       from cx x have cx0: "cx \<noteq> 0" by auto
  1280       from cy y have cy0: "cy \<noteq> 0" by auto
  1281       let ?d = "cy / cx"
  1282       from cx cy cx0 have "y = ?d *\<^sub>R x"
  1283         by simp
  1284       then show ?rhs using x y by blast
  1285     next
  1286       assume h: "?rhs"
  1287       then obtain c where c: "y = c *\<^sub>R x"
  1288         using x y by blast
  1289       show ?lhs
  1290         unfolding collinear_def c
  1291         apply (rule exI[where x=x])
  1292         apply auto
  1293         apply (rule exI[where x="- 1"], simp)
  1294         apply (rule exI[where x= "-c"], simp)
  1295         apply (rule exI[where x=1], simp)
  1296         apply (rule exI[where x="1 - c"], simp add: scaleR_left_diff_distrib)
  1297         apply (rule exI[where x="c - 1"], simp add: scaleR_left_diff_distrib)
  1298         done
  1299     qed
  1300   }
  1301   ultimately show ?thesis by blast
  1302 qed
  1303 
  1304 lemma norm_cauchy_schwarz_equal: "\<bar>x \<bullet> y\<bar> = norm x * norm y \<longleftrightarrow> collinear {0, x, y}"
  1305   unfolding norm_cauchy_schwarz_abs_eq
  1306   apply (cases "x=0", simp_all)
  1307   apply (cases "y=0", simp_all add: insert_commute)
  1308   unfolding collinear_lemma
  1309   apply simp
  1310   apply (subgoal_tac "norm x \<noteq> 0")
  1311   apply (subgoal_tac "norm y \<noteq> 0")
  1312   apply (rule iffI)
  1313   apply (cases "norm x *\<^sub>R y = norm y *\<^sub>R x")
  1314   apply (rule exI[where x="(1/norm x) * norm y"])
  1315   apply (drule sym)
  1316   unfolding scaleR_scaleR[symmetric]
  1317   apply (simp add: field_simps)
  1318   apply (rule exI[where x="(1/norm x) * - norm y"])
  1319   apply clarify
  1320   apply (drule sym)
  1321   unfolding scaleR_scaleR[symmetric]
  1322   apply (simp add: field_simps)
  1323   apply (erule exE)
  1324   apply (erule ssubst)
  1325   unfolding scaleR_scaleR
  1326   unfolding norm_scaleR
  1327   apply (subgoal_tac "norm x * c = \<bar>c\<bar> * norm x \<or> norm x * c = - \<bar>c\<bar> * norm x")
  1328   apply (auto simp add: field_simps)
  1329   done
  1330 
  1331 end