author haftmann
Fri Mar 22 19:18:08 2019 +0000 (3 months ago)
changeset 69946 494934c30f38
parent 69939 812ce526da33
child 70063 adaa0a6ea4fe
permissions -rw-r--r--
improved code equations taken over from AFP
     1 (*  Title:      HOL/Library/FuncSet.thy
     2     Author:     Florian Kammueller and Lawrence C Paulson, Lukas Bulwahn
     3 *)
     5 section \<open>Pi and Function Sets\<close>
     7 theory FuncSet
     8   imports Main
     9   abbrevs PiE = "Pi\<^sub>E"
    10     and PIE = "\<Pi>\<^sub>E"
    11 begin
    13 definition Pi :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<Rightarrow> 'b) set"
    14   where "Pi A B = {f. \<forall>x. x \<in> A \<longrightarrow> f x \<in> B x}"
    16 definition extensional :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b) set"
    17   where "extensional A = {f. \<forall>x. x \<notin> A \<longrightarrow> f x = undefined}"
    19 definition "restrict" :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b"
    20   where "restrict f A = (\<lambda>x. if x \<in> A then f x else undefined)"
    22 abbreviation funcset :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  (infixr "\<rightarrow>" 60)
    23   where "A \<rightarrow> B \<equiv> Pi A (\<lambda>_. B)"
    25 syntax
    26   "_Pi" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    27   "_lam" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    28 translations
    29   "\<Pi> x\<in>A. B" \<rightleftharpoons> "CONST Pi A (\<lambda>x. B)"
    30   "\<lambda>x\<in>A. f" \<rightleftharpoons> "CONST restrict (\<lambda>x. f) A"
    32 definition "compose" :: "'a set \<Rightarrow> ('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'c)"
    33   where "compose A g f = (\<lambda>x\<in>A. g (f x))"
    36 subsection \<open>Basic Properties of \<^term>\<open>Pi\<close>\<close>
    38 lemma Pi_I[intro!]: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B x) \<Longrightarrow> f \<in> Pi A B"
    39   by (simp add: Pi_def)
    41 lemma Pi_I'[simp]: "(\<And>x. x \<in> A \<longrightarrow> f x \<in> B x) \<Longrightarrow> f \<in> Pi A B"
    42   by (simp add:Pi_def)
    44 lemma funcsetI: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B) \<Longrightarrow> f \<in> A \<rightarrow> B"
    45   by (simp add: Pi_def)
    47 lemma Pi_mem: "f \<in> Pi A B \<Longrightarrow> x \<in> A \<Longrightarrow> f x \<in> B x"
    48   by (simp add: Pi_def)
    50 lemma Pi_iff: "f \<in> Pi I X \<longleftrightarrow> (\<forall>i\<in>I. f i \<in> X i)"
    51   unfolding Pi_def by auto
    53 lemma PiE [elim]: "f \<in> Pi A B \<Longrightarrow> (f x \<in> B x \<Longrightarrow> Q) \<Longrightarrow> (x \<notin> A \<Longrightarrow> Q) \<Longrightarrow> Q"
    54   by (auto simp: Pi_def)
    56 lemma Pi_cong: "(\<And>w. w \<in> A \<Longrightarrow> f w = g w) \<Longrightarrow> f \<in> Pi A B \<longleftrightarrow> g \<in> Pi A B"
    57   by (auto simp: Pi_def)
    59 lemma funcset_id [simp]: "(\<lambda>x. x) \<in> A \<rightarrow> A"
    60   by auto
    62 lemma funcset_mem: "f \<in> A \<rightarrow> B \<Longrightarrow> x \<in> A \<Longrightarrow> f x \<in> B"
    63   by (simp add: Pi_def)
    65 lemma funcset_image: "f \<in> A \<rightarrow> B \<Longrightarrow> f ` A \<subseteq> B"
    66   by auto
    68 lemma image_subset_iff_funcset: "F ` A \<subseteq> B \<longleftrightarrow> F \<in> A \<rightarrow> B"
    69   by auto
    71 lemma Pi_eq_empty[simp]: "(\<Pi> x \<in> A. B x) = {} \<longleftrightarrow> (\<exists>x\<in>A. B x = {})"
    72   apply (simp add: Pi_def)
    73   apply auto
    74   txt \<open>Converse direction requires Axiom of Choice to exhibit a function
    75   picking an element from each non-empty \<^term>\<open>B x\<close>\<close>
    76   apply (drule_tac x = "\<lambda>u. SOME y. y \<in> B u" in spec)
    77   apply auto
    78   apply (cut_tac P = "\<lambda>y. y \<in> B x" in some_eq_ex)
    79   apply auto
    80   done
    82 lemma Pi_empty [simp]: "Pi {} B = UNIV"
    83   by (simp add: Pi_def)
    85 lemma Pi_Int: "Pi I E \<inter> Pi I F = (\<Pi> i\<in>I. E i \<inter> F i)"
    86   by auto
    88 lemma Pi_UN:
    89   fixes A :: "nat \<Rightarrow> 'i \<Rightarrow> 'a set"
    90   assumes "finite I"
    91     and mono: "\<And>i n m. i \<in> I \<Longrightarrow> n \<le> m \<Longrightarrow> A n i \<subseteq> A m i"
    92   shows "(\<Union>n. Pi I (A n)) = (\<Pi> i\<in>I. \<Union>n. A n i)"
    93 proof (intro set_eqI iffI)
    94   fix f
    95   assume "f \<in> (\<Pi> i\<in>I. \<Union>n. A n i)"
    96   then have "\<forall>i\<in>I. \<exists>n. f i \<in> A n i"
    97     by auto
    98   from bchoice[OF this] obtain n where n: "f i \<in> A (n i) i" if "i \<in> I" for i
    99     by auto
   100   obtain k where k: "n i \<le> k" if "i \<in> I" for i
   101     using \<open>finite I\<close> finite_nat_set_iff_bounded_le[of "n`I"] by auto
   102   have "f \<in> Pi I (A k)"
   103   proof (intro Pi_I)
   104     fix i
   105     assume "i \<in> I"
   106     from mono[OF this, of "n i" k] k[OF this] n[OF this]
   107     show "f i \<in> A k i" by auto
   108   qed
   109   then show "f \<in> (\<Union>n. Pi I (A n))"
   110     by auto
   111 qed auto
   113 lemma Pi_UNIV [simp]: "A \<rightarrow> UNIV = UNIV"
   114   by (simp add: Pi_def)
   116 text \<open>Covariance of Pi-sets in their second argument\<close>
   117 lemma Pi_mono: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C x) \<Longrightarrow> Pi A B \<subseteq> Pi A C"
   118   by auto
   120 text \<open>Contravariance of Pi-sets in their first argument\<close>
   121 lemma Pi_anti_mono: "A' \<subseteq> A \<Longrightarrow> Pi A B \<subseteq> Pi A' B"
   122   by auto
   124 lemma prod_final:
   125   assumes 1: "fst \<circ> f \<in> Pi A B"
   126     and 2: "snd \<circ> f \<in> Pi A C"
   127   shows "f \<in> (\<Pi> z \<in> A. B z \<times> C z)"
   128 proof (rule Pi_I)
   129   fix z
   130   assume z: "z \<in> A"
   131   have "f z = (fst (f z), snd (f z))"
   132     by simp
   133   also have "\<dots> \<in> B z \<times> C z"
   134     by (metis SigmaI PiE o_apply 1 2 z)
   135   finally show "f z \<in> B z \<times> C z" .
   136 qed
   138 lemma Pi_split_domain[simp]: "x \<in> Pi (I \<union> J) X \<longleftrightarrow> x \<in> Pi I X \<and> x \<in> Pi J X"
   139   by (auto simp: Pi_def)
   141 lemma Pi_split_insert_domain[simp]: "x \<in> Pi (insert i I) X \<longleftrightarrow> x \<in> Pi I X \<and> x i \<in> X i"
   142   by (auto simp: Pi_def)
   144 lemma Pi_cancel_fupd_range[simp]: "i \<notin> I \<Longrightarrow> x \<in> Pi I (B(i := b)) \<longleftrightarrow> x \<in> Pi I B"
   145   by (auto simp: Pi_def)
   147 lemma Pi_cancel_fupd[simp]: "i \<notin> I \<Longrightarrow> x(i := a) \<in> Pi I B \<longleftrightarrow> x \<in> Pi I B"
   148   by (auto simp: Pi_def)
   150 lemma Pi_fupd_iff: "i \<in> I \<Longrightarrow> f \<in> Pi I (B(i := A)) \<longleftrightarrow> f \<in> Pi (I - {i}) B \<and> f i \<in> A"
   151   apply auto
   152   apply (drule_tac x=x in Pi_mem)
   153   apply (simp_all split: if_split_asm)
   154   apply (drule_tac x=i in Pi_mem)
   155   apply (auto dest!: Pi_mem)
   156   done
   159 subsection \<open>Composition With a Restricted Domain: \<^term>\<open>compose\<close>\<close>
   161 lemma funcset_compose: "f \<in> A \<rightarrow> B \<Longrightarrow> g \<in> B \<rightarrow> C \<Longrightarrow> compose A g f \<in> A \<rightarrow> C"
   162   by (simp add: Pi_def compose_def restrict_def)
   164 lemma compose_assoc:
   165   assumes "f \<in> A \<rightarrow> B"
   166   shows "compose A h (compose A g f) = compose A (compose B h g) f"
   167   using assms by (simp add: fun_eq_iff Pi_def compose_def restrict_def)
   169 lemma compose_eq: "x \<in> A \<Longrightarrow> compose A g f x = g (f x)"
   170   by (simp add: compose_def restrict_def)
   172 lemma surj_compose: "f ` A = B \<Longrightarrow> g ` B = C \<Longrightarrow> compose A g f ` A = C"
   173   by (auto simp add: image_def compose_eq)
   176 subsection \<open>Bounded Abstraction: \<^term>\<open>restrict\<close>\<close>
   178 lemma restrict_cong: "I = J \<Longrightarrow> (\<And>i. i \<in> J =simp=> f i = g i) \<Longrightarrow> restrict f I = restrict g J"
   179   by (auto simp: restrict_def fun_eq_iff simp_implies_def)
   181 lemma restrict_in_funcset: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B) \<Longrightarrow> (\<lambda>x\<in>A. f x) \<in> A \<rightarrow> B"
   182   by (simp add: Pi_def restrict_def)
   184 lemma restrictI[intro!]: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B x) \<Longrightarrow> (\<lambda>x\<in>A. f x) \<in> Pi A B"
   185   by (simp add: Pi_def restrict_def)
   187 lemma restrict_apply[simp]: "(\<lambda>y\<in>A. f y) x = (if x \<in> A then f x else undefined)"
   188   by (simp add: restrict_def)
   190 lemma restrict_apply': "x \<in> A \<Longrightarrow> (\<lambda>y\<in>A. f y) x = f x"
   191   by simp
   193 lemma restrict_ext: "(\<And>x. x \<in> A \<Longrightarrow> f x = g x) \<Longrightarrow> (\<lambda>x\<in>A. f x) = (\<lambda>x\<in>A. g x)"
   194   by (simp add: fun_eq_iff Pi_def restrict_def)
   196 lemma restrict_UNIV: "restrict f UNIV = f"
   197   by (simp add: restrict_def)
   199 lemma inj_on_restrict_eq [simp]: "inj_on (restrict f A) A = inj_on f A"
   200   by (simp add: inj_on_def restrict_def)
   202 lemma Id_compose: "f \<in> A \<rightarrow> B \<Longrightarrow> f \<in> extensional A \<Longrightarrow> compose A (\<lambda>y\<in>B. y) f = f"
   203   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
   205 lemma compose_Id: "g \<in> A \<rightarrow> B \<Longrightarrow> g \<in> extensional A \<Longrightarrow> compose A g (\<lambda>x\<in>A. x) = g"
   206   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
   208 lemma image_restrict_eq [simp]: "(restrict f A) ` A = f ` A"
   209   by (auto simp add: restrict_def)
   211 lemma restrict_restrict[simp]: "restrict (restrict f A) B = restrict f (A \<inter> B)"
   212   unfolding restrict_def by (simp add: fun_eq_iff)
   214 lemma restrict_fupd[simp]: "i \<notin> I \<Longrightarrow> restrict (f (i := x)) I = restrict f I"
   215   by (auto simp: restrict_def)
   217 lemma restrict_upd[simp]: "i \<notin> I \<Longrightarrow> (restrict f I)(i := y) = restrict (f(i := y)) (insert i I)"
   218   by (auto simp: fun_eq_iff)
   220 lemma restrict_Pi_cancel: "restrict x I \<in> Pi I A \<longleftrightarrow> x \<in> Pi I A"
   221   by (auto simp: restrict_def Pi_def)
   224 subsection \<open>Bijections Between Sets\<close>
   226 text \<open>The definition of \<^const>\<open>bij_betw\<close> is in \<open>Fun.thy\<close>, but most of
   227 the theorems belong here, or need at least \<^term>\<open>Hilbert_Choice\<close>.\<close>
   229 lemma bij_betwI:
   230   assumes "f \<in> A \<rightarrow> B"
   231     and "g \<in> B \<rightarrow> A"
   232     and g_f: "\<And>x. x\<in>A \<Longrightarrow> g (f x) = x"
   233     and f_g: "\<And>y. y\<in>B \<Longrightarrow> f (g y) = y"
   234   shows "bij_betw f A B"
   235   unfolding bij_betw_def
   236 proof
   237   show "inj_on f A"
   238     by (metis g_f inj_on_def)
   239   have "f ` A \<subseteq> B"
   240     using \<open>f \<in> A \<rightarrow> B\<close> by auto
   241   moreover
   242   have "B \<subseteq> f ` A"
   243     by auto (metis Pi_mem \<open>g \<in> B \<rightarrow> A\<close> f_g image_iff)
   244   ultimately show "f ` A = B"
   245     by blast
   246 qed
   248 lemma bij_betw_imp_funcset: "bij_betw f A B \<Longrightarrow> f \<in> A \<rightarrow> B"
   249   by (auto simp add: bij_betw_def)
   251 lemma inj_on_compose: "bij_betw f A B \<Longrightarrow> inj_on g B \<Longrightarrow> inj_on (compose A g f) A"
   252   by (auto simp add: bij_betw_def inj_on_def compose_eq)
   254 lemma bij_betw_compose: "bij_betw f A B \<Longrightarrow> bij_betw g B C \<Longrightarrow> bij_betw (compose A g f) A C"
   255   apply (simp add: bij_betw_def compose_eq inj_on_compose)
   256   apply (auto simp add: compose_def image_def)
   257   done
   259 lemma bij_betw_restrict_eq [simp]: "bij_betw (restrict f A) A B = bij_betw f A B"
   260   by (simp add: bij_betw_def)
   263 subsection \<open>Extensionality\<close>
   265 lemma extensional_empty[simp]: "extensional {} = {\<lambda>x. undefined}"
   266   unfolding extensional_def by auto
   268 lemma extensional_arb: "f \<in> extensional A \<Longrightarrow> x \<notin> A \<Longrightarrow> f x = undefined"
   269   by (simp add: extensional_def)
   271 lemma restrict_extensional [simp]: "restrict f A \<in> extensional A"
   272   by (simp add: restrict_def extensional_def)
   274 lemma compose_extensional [simp]: "compose A f g \<in> extensional A"
   275   by (simp add: compose_def)
   277 lemma extensionalityI:
   278   assumes "f \<in> extensional A"
   279     and "g \<in> extensional A"
   280     and "\<And>x. x \<in> A \<Longrightarrow> f x = g x"
   281   shows "f = g"
   282   using assms by (force simp add: fun_eq_iff extensional_def)
   284 lemma extensional_restrict:  "f \<in> extensional A \<Longrightarrow> restrict f A = f"
   285   by (rule extensionalityI[OF restrict_extensional]) auto
   287 lemma extensional_subset: "f \<in> extensional A \<Longrightarrow> A \<subseteq> B \<Longrightarrow> f \<in> extensional B"
   288   unfolding extensional_def by auto
   290 lemma inv_into_funcset: "f ` A = B \<Longrightarrow> (\<lambda>x\<in>B. inv_into A f x) \<in> B \<rightarrow> A"
   291   by (unfold inv_into_def) (fast intro: someI2)
   293 lemma compose_inv_into_id: "bij_betw f A B \<Longrightarrow> compose A (\<lambda>y\<in>B. inv_into A f y) f = (\<lambda>x\<in>A. x)"
   294   apply (simp add: bij_betw_def compose_def)
   295   apply (rule restrict_ext, auto)
   296   done
   298 lemma compose_id_inv_into: "f ` A = B \<Longrightarrow> compose B f (\<lambda>y\<in>B. inv_into A f y) = (\<lambda>x\<in>B. x)"
   299   apply (simp add: compose_def)
   300   apply (rule restrict_ext)
   301   apply (simp add: f_inv_into_f)
   302   done
   304 lemma extensional_insert[intro, simp]:
   305   assumes "a \<in> extensional (insert i I)"
   306   shows "a(i := b) \<in> extensional (insert i I)"
   307   using assms unfolding extensional_def by auto
   309 lemma extensional_Int[simp]: "extensional I \<inter> extensional I' = extensional (I \<inter> I')"
   310   unfolding extensional_def by auto
   312 lemma extensional_UNIV[simp]: "extensional UNIV = UNIV"
   313   by (auto simp: extensional_def)
   315 lemma restrict_extensional_sub[intro]: "A \<subseteq> B \<Longrightarrow> restrict f A \<in> extensional B"
   316   unfolding restrict_def extensional_def by auto
   318 lemma extensional_insert_undefined[intro, simp]:
   319   "a \<in> extensional (insert i I) \<Longrightarrow> a(i := undefined) \<in> extensional I"
   320   unfolding extensional_def by auto
   322 lemma extensional_insert_cancel[intro, simp]:
   323   "a \<in> extensional I \<Longrightarrow> a \<in> extensional (insert i I)"
   324   unfolding extensional_def by auto
   327 subsection \<open>Cardinality\<close>
   329 lemma card_inj: "f \<in> A \<rightarrow> B \<Longrightarrow> inj_on f A \<Longrightarrow> finite B \<Longrightarrow> card A \<le> card B"
   330   by (rule card_inj_on_le) auto
   332 lemma card_bij:
   333   assumes "f \<in> A \<rightarrow> B" "inj_on f A"
   334     and "g \<in> B \<rightarrow> A" "inj_on g B"
   335     and "finite A" "finite B"
   336   shows "card A = card B"
   337   using assms by (blast intro: card_inj order_antisym)
   340 subsection \<open>Extensional Function Spaces\<close>
   342 definition PiE :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<Rightarrow> 'b) set"
   343   where "PiE S T = Pi S T \<inter> extensional S"
   345 abbreviation "Pi\<^sub>E A B \<equiv> PiE A B"
   347 syntax
   348   "_PiE" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3\<Pi>\<^sub>E _\<in>_./ _)" 10)
   349 translations
   350   "\<Pi>\<^sub>E x\<in>A. B" \<rightleftharpoons> "CONST Pi\<^sub>E A (\<lambda>x. B)"
   352 abbreviation extensional_funcset :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set" (infixr "\<rightarrow>\<^sub>E" 60)
   353   where "A \<rightarrow>\<^sub>E B \<equiv> (\<Pi>\<^sub>E i\<in>A. B)"
   355 lemma extensional_funcset_def: "extensional_funcset S T = (S \<rightarrow> T) \<inter> extensional S"
   356   by (simp add: PiE_def)
   358 lemma PiE_empty_domain[simp]: "Pi\<^sub>E {} T = {\<lambda>x. undefined}"
   359   unfolding PiE_def by simp
   361 lemma PiE_UNIV_domain: "Pi\<^sub>E UNIV T = Pi UNIV T"
   362   unfolding PiE_def by simp
   364 lemma PiE_empty_range[simp]: "i \<in> I \<Longrightarrow> F i = {} \<Longrightarrow> (\<Pi>\<^sub>E i\<in>I. F i) = {}"
   365   unfolding PiE_def by auto
   367 lemma PiE_eq_empty_iff: "Pi\<^sub>E I F = {} \<longleftrightarrow> (\<exists>i\<in>I. F i = {})"
   368 proof
   369   assume "Pi\<^sub>E I F = {}"
   370   show "\<exists>i\<in>I. F i = {}"
   371   proof (rule ccontr)
   372     assume "\<not> ?thesis"
   373     then have "\<forall>i. \<exists>y. (i \<in> I \<longrightarrow> y \<in> F i) \<and> (i \<notin> I \<longrightarrow> y = undefined)"
   374       by auto
   375     from choice[OF this]
   376     obtain f where " \<forall>x. (x \<in> I \<longrightarrow> f x \<in> F x) \<and> (x \<notin> I \<longrightarrow> f x = undefined)" ..
   377     then have "f \<in> Pi\<^sub>E I F"
   378       by (auto simp: extensional_def PiE_def)
   379     with \<open>Pi\<^sub>E I F = {}\<close> show False
   380       by auto
   381   qed
   382 qed (auto simp: PiE_def)
   384 lemma PiE_arb: "f \<in> Pi\<^sub>E S T \<Longrightarrow> x \<notin> S \<Longrightarrow> f x = undefined"
   385   unfolding PiE_def by auto (auto dest!: extensional_arb)
   387 lemma PiE_mem: "f \<in> Pi\<^sub>E S T \<Longrightarrow> x \<in> S \<Longrightarrow> f x \<in> T x"
   388   unfolding PiE_def by auto
   390 lemma PiE_fun_upd: "y \<in> T x \<Longrightarrow> f \<in> Pi\<^sub>E S T \<Longrightarrow> f(x := y) \<in> Pi\<^sub>E (insert x S) T"
   391   unfolding PiE_def extensional_def by auto
   393 lemma fun_upd_in_PiE: "x \<notin> S \<Longrightarrow> f \<in> Pi\<^sub>E (insert x S) T \<Longrightarrow> f(x := undefined) \<in> Pi\<^sub>E S T"
   394   unfolding PiE_def extensional_def by auto
   396 lemma PiE_insert_eq: "Pi\<^sub>E (insert x S) T = (\<lambda>(y, g). g(x := y)) ` (T x \<times> Pi\<^sub>E S T)"
   397 proof -
   398   {
   399     fix f assume "f \<in> Pi\<^sub>E (insert x S) T" "x \<notin> S"
   400     then have "f \<in> (\<lambda>(y, g). g(x := y)) ` (T x \<times> Pi\<^sub>E S T)"
   401       by (auto intro!: image_eqI[where x="(f x, f(x := undefined))"] intro: fun_upd_in_PiE PiE_mem)
   402   }
   403   moreover
   404   {
   405     fix f assume "f \<in> Pi\<^sub>E (insert x S) T" "x \<in> S"
   406     then have "f \<in> (\<lambda>(y, g). g(x := y)) ` (T x \<times> Pi\<^sub>E S T)"
   407       by (auto intro!: image_eqI[where x="(f x, f)"] intro: fun_upd_in_PiE PiE_mem simp: insert_absorb)
   408   }
   409   ultimately show ?thesis
   410     by (auto intro: PiE_fun_upd)
   411 qed
   413 lemma PiE_Int: "Pi\<^sub>E I A \<inter> Pi\<^sub>E I B = Pi\<^sub>E I (\<lambda>x. A x \<inter> B x)"
   414   by (auto simp: PiE_def)
   416 lemma PiE_cong: "(\<And>i. i\<in>I \<Longrightarrow> A i = B i) \<Longrightarrow> Pi\<^sub>E I A = Pi\<^sub>E I B"
   417   unfolding PiE_def by (auto simp: Pi_cong)
   419 lemma PiE_E [elim]:
   420   assumes "f \<in> Pi\<^sub>E A B"
   421   obtains "x \<in> A" and "f x \<in> B x"
   422     | "x \<notin> A" and "f x = undefined"
   423   using assms by (auto simp: Pi_def PiE_def extensional_def)
   425 lemma PiE_I[intro!]:
   426   "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B x) \<Longrightarrow> (\<And>x. x \<notin> A \<Longrightarrow> f x = undefined) \<Longrightarrow> f \<in> Pi\<^sub>E A B"
   427   by (simp add: PiE_def extensional_def)
   429 lemma PiE_mono: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C x) \<Longrightarrow> Pi\<^sub>E A B \<subseteq> Pi\<^sub>E A C"
   430   by auto
   432 lemma PiE_iff: "f \<in> Pi\<^sub>E I X \<longleftrightarrow> (\<forall>i\<in>I. f i \<in> X i) \<and> f \<in> extensional I"
   433   by (simp add: PiE_def Pi_iff)
   435 lemma PiE_restrict[simp]:  "f \<in> Pi\<^sub>E A B \<Longrightarrow> restrict f A = f"
   436   by (simp add: extensional_restrict PiE_def)
   438 lemma restrict_PiE[simp]: "restrict f I \<in> Pi\<^sub>E I S \<longleftrightarrow> f \<in> Pi I S"
   439   by (auto simp: PiE_iff)
   441 lemma PiE_eq_subset:
   442   assumes ne: "\<And>i. i \<in> I \<Longrightarrow> F i \<noteq> {}" "\<And>i. i \<in> I \<Longrightarrow> F' i \<noteq> {}"
   443     and eq: "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   444     and "i \<in> I"
   445   shows "F i \<subseteq> F' i"
   446 proof
   447   fix x
   448   assume "x \<in> F i"
   449   with ne have "\<forall>j. \<exists>y. (j \<in> I \<longrightarrow> y \<in> F j \<and> (i = j \<longrightarrow> x = y)) \<and> (j \<notin> I \<longrightarrow> y = undefined)"
   450     by auto
   451   from choice[OF this] obtain f
   452     where f: " \<forall>j. (j \<in> I \<longrightarrow> f j \<in> F j \<and> (i = j \<longrightarrow> x = f j)) \<and> (j \<notin> I \<longrightarrow> f j = undefined)" ..
   453   then have "f \<in> Pi\<^sub>E I F"
   454     by (auto simp: extensional_def PiE_def)
   455   then have "f \<in> Pi\<^sub>E I F'"
   456     using assms by simp
   457   then show "x \<in> F' i"
   458     using f \<open>i \<in> I\<close> by (auto simp: PiE_def)
   459 qed
   461 lemma PiE_eq_iff_not_empty:
   462   assumes ne: "\<And>i. i \<in> I \<Longrightarrow> F i \<noteq> {}" "\<And>i. i \<in> I \<Longrightarrow> F' i \<noteq> {}"
   463   shows "Pi\<^sub>E I F = Pi\<^sub>E I F' \<longleftrightarrow> (\<forall>i\<in>I. F i = F' i)"
   464 proof (intro iffI ballI)
   465   fix i
   466   assume eq: "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   467   assume i: "i \<in> I"
   468   show "F i = F' i"
   469     using PiE_eq_subset[of I F F', OF ne eq i]
   470     using PiE_eq_subset[of I F' F, OF ne(2,1) eq[symmetric] i]
   471     by auto
   472 qed (auto simp: PiE_def)
   474 lemma PiE_eq_iff:
   475   "Pi\<^sub>E I F = Pi\<^sub>E I F' \<longleftrightarrow> (\<forall>i\<in>I. F i = F' i) \<or> ((\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {}))"
   476 proof (intro iffI disjCI)
   477   assume eq[simp]: "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   478   assume "\<not> ((\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {}))"
   479   then have "(\<forall>i\<in>I. F i \<noteq> {}) \<and> (\<forall>i\<in>I. F' i \<noteq> {})"
   480     using PiE_eq_empty_iff[of I F] PiE_eq_empty_iff[of I F'] by auto
   481   with PiE_eq_iff_not_empty[of I F F'] show "\<forall>i\<in>I. F i = F' i"
   482     by auto
   483 next
   484   assume "(\<forall>i\<in>I. F i = F' i) \<or> (\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {})"
   485   then show "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   486     using PiE_eq_empty_iff[of I F] PiE_eq_empty_iff[of I F'] by (auto simp: PiE_def)
   487 qed
   489 lemma extensional_funcset_fun_upd_restricts_rangeI:
   490   "\<forall>y \<in> S. f x \<noteq> f y \<Longrightarrow> f \<in> (insert x S) \<rightarrow>\<^sub>E T \<Longrightarrow> f(x := undefined) \<in> S \<rightarrow>\<^sub>E (T - {f x})"
   491   unfolding extensional_funcset_def extensional_def
   492   apply auto
   493   apply (case_tac "x = xa")
   494   apply auto
   495   done
   497 lemma extensional_funcset_fun_upd_extends_rangeI:
   498   assumes "a \<in> T" "f \<in> S \<rightarrow>\<^sub>E (T - {a})"
   499   shows "f(x := a) \<in> insert x S \<rightarrow>\<^sub>E  T"
   500   using assms unfolding extensional_funcset_def extensional_def by auto
   502 lemma subset_PiE:
   503    "PiE I S \<subseteq> PiE I T \<longleftrightarrow> PiE I S = {} \<or> (\<forall>i \<in> I. S i \<subseteq> T i)" (is "?lhs \<longleftrightarrow> _ \<or> ?rhs")
   504 proof (cases "PiE I S = {}")
   505   case False
   506   moreover have "?lhs = ?rhs"
   507   proof
   508     assume L: ?lhs
   509     have "\<And>i. i\<in>I \<Longrightarrow> S i \<noteq> {}"
   510       using False PiE_eq_empty_iff by blast
   511     with L show ?rhs
   512       by (simp add: PiE_Int PiE_eq_iff inf.absorb_iff2)
   513   qed auto
   514   ultimately show ?thesis
   515     by simp
   516 qed simp
   518 lemma PiE_eq:
   519    "PiE I S = PiE I T \<longleftrightarrow> PiE I S = {} \<and> PiE I T = {} \<or> (\<forall>i \<in> I. S i = T i)"
   520   by (auto simp: PiE_eq_iff PiE_eq_empty_iff)
   522 lemma PiE_UNIV [simp]: "PiE UNIV (\<lambda>i. UNIV) = UNIV"
   523   by blast
   525 lemma image_projection_PiE:
   526   "(\<lambda>f. f i) ` (PiE I S) = (if PiE I S = {} then {} else if i \<in> I then S i else {undefined})"
   527 proof -
   528   have "(\<lambda>f. f i) ` Pi\<^sub>E I S = S i" if "i \<in> I" "f \<in> PiE I S" for f
   529     using that apply auto
   530     by (rule_tac x="(\<lambda>k. if k=i then x else f k)" in image_eqI) auto
   531   moreover have "(\<lambda>f. f i) ` Pi\<^sub>E I S = {undefined}" if "f \<in> PiE I S" "i \<notin> I" for f
   532     using that by (blast intro: PiE_arb [OF that, symmetric])
   533   ultimately show ?thesis
   534     by auto
   535 qed
   537 lemma PiE_singleton: 
   538   assumes "f \<in> extensional A"
   539   shows   "PiE A (\<lambda>x. {f x}) = {f}"
   540 proof -
   541   {
   542     fix g assume "g \<in> PiE A (\<lambda>x. {f x})"
   543     hence "g x = f x" for x
   544       using assms by (cases "x \<in> A") (auto simp: extensional_def)
   545     hence "g = f" by (simp add: fun_eq_iff)
   546   }
   547   thus ?thesis using assms by (auto simp: extensional_def)
   548 qed
   550 lemma PiE_eq_singleton: "(\<Pi>\<^sub>E i\<in>I. S i) = {\<lambda>i\<in>I. f i} \<longleftrightarrow> (\<forall>i\<in>I. S i = {f i})"
   551   by (metis (mono_tags, lifting) PiE_eq PiE_singleton insert_not_empty restrict_apply' restrict_extensional)
   553 lemma PiE_over_singleton_iff: "(\<Pi>\<^sub>E x\<in>{a}. B x) = (\<Union>b \<in> B a. {\<lambda>x \<in> {a}. b})"
   554   apply (auto simp: PiE_iff split: if_split_asm)
   555   apply (metis (no_types, lifting) extensionalityI restrict_apply' restrict_extensional singletonD)
   556   done
   558 lemma all_PiE_elements:
   559    "(\<forall>z \<in> PiE I S. \<forall>i \<in> I. P i (z i)) \<longleftrightarrow> PiE I S = {} \<or> (\<forall>i \<in> I. \<forall>x \<in> S i. P i x)" (is "?lhs = ?rhs")
   560 proof (cases "PiE I S = {}")
   561   case False
   562   then obtain f where f: "\<And>i. i \<in> I \<Longrightarrow> f i \<in> S i"
   563     by fastforce
   564   show ?thesis
   565   proof
   566     assume L: ?lhs
   567     have "P i x"
   568       if "i \<in> I" "x \<in> S i" for i x
   569     proof -
   570       have "(\<lambda>j \<in> I. if j=i then x else f j) \<in> PiE I S"
   571         by (simp add: f that(2))
   572       then have "P i ((\<lambda>j \<in> I. if j=i then x else f j) i)"
   573         using L that(1) by blast
   574       with that show ?thesis
   575         by simp
   576     qed
   577     then show ?rhs
   578       by (simp add: False)
   579   qed fastforce
   580 qed simp
   582 lemma PiE_ext: "\<lbrakk>x \<in> PiE k s; y \<in> PiE k s; \<And>i. i \<in> k \<Longrightarrow> x i = y i\<rbrakk> \<Longrightarrow> x = y"
   583   by (metis ext PiE_E)
   586 subsubsection \<open>Injective Extensional Function Spaces\<close>
   588 lemma extensional_funcset_fun_upd_inj_onI:
   589   assumes "f \<in> S \<rightarrow>\<^sub>E (T - {a})"
   590     and "inj_on f S"
   591   shows "inj_on (f(x := a)) S"
   592   using assms
   593   unfolding extensional_funcset_def by (auto intro!: inj_on_fun_updI)
   595 lemma extensional_funcset_extend_domain_inj_on_eq:
   596   assumes "x \<notin> S"
   597   shows "{f. f \<in> (insert x S) \<rightarrow>\<^sub>E T \<and> inj_on f (insert x S)} =
   598     (\<lambda>(y, g). g(x:=y)) ` {(y, g). y \<in> T \<and> g \<in> S \<rightarrow>\<^sub>E (T - {y}) \<and> inj_on g S}"
   599   using assms
   600   apply (auto del: PiE_I PiE_E)
   601   apply (auto intro: extensional_funcset_fun_upd_inj_onI
   602     extensional_funcset_fun_upd_extends_rangeI del: PiE_I PiE_E)
   603   apply (auto simp add: image_iff inj_on_def)
   604   apply (rule_tac x="xa x" in exI)
   605   apply (auto intro: PiE_mem del: PiE_I PiE_E)
   606   apply (rule_tac x="xa(x := undefined)" in exI)
   607   apply (auto intro!: extensional_funcset_fun_upd_restricts_rangeI)
   608   apply (auto dest!: PiE_mem split: if_split_asm)
   609   done
   611 lemma extensional_funcset_extend_domain_inj_onI:
   612   assumes "x \<notin> S"
   613   shows "inj_on (\<lambda>(y, g). g(x := y)) {(y, g). y \<in> T \<and> g \<in> S \<rightarrow>\<^sub>E (T - {y}) \<and> inj_on g S}"
   614   using assms
   615   apply (auto intro!: inj_onI)
   616   apply (metis fun_upd_same)
   617   apply (metis assms PiE_arb fun_upd_triv fun_upd_upd)
   618   done
   621 subsubsection \<open>Misc properties of functions, composition and restriction from HOL Light\<close>
   623 lemma function_factors_left_gen:
   624   "(\<forall>x y. P x \<and> P y \<and> g x = g y \<longrightarrow> f x = f y) \<longleftrightarrow> (\<exists>h. \<forall>x. P x \<longrightarrow> f x = h(g x))"
   625   (is "?lhs = ?rhs")
   626 proof
   627   assume L: ?lhs
   628   then show ?rhs
   629     apply (rule_tac x="f \<circ> inv_into (Collect P) g" in exI)
   630     unfolding o_def
   631     by (metis (mono_tags, hide_lams) f_inv_into_f imageI inv_into_into mem_Collect_eq)
   632 qed auto
   634 lemma function_factors_left:
   635   "(\<forall>x y. (g x = g y) \<longrightarrow> (f x = f y)) \<longleftrightarrow> (\<exists>h. f = h \<circ> g)"
   636   using function_factors_left_gen [of "\<lambda>x. True" g f] unfolding o_def by blast
   638 lemma function_factors_right_gen:
   639   "(\<forall>x. P x \<longrightarrow> (\<exists>y. g y = f x)) \<longleftrightarrow> (\<exists>h. \<forall>x. P x \<longrightarrow> f x = g(h x))"
   640   by metis
   642 lemma function_factors_right:
   643   "(\<forall>x. \<exists>y. g y = f x) \<longleftrightarrow> (\<exists>h. f = g \<circ> h)"
   644   unfolding o_def by metis
   646 lemma restrict_compose_right:
   647    "restrict (g \<circ> restrict f S) S = restrict (g \<circ> f) S"
   648   by auto
   650 lemma restrict_compose_left:
   651    "f ` S \<subseteq> T \<Longrightarrow> restrict (restrict g T \<circ> f) S = restrict (g \<circ> f) S"
   652   by fastforce
   655 subsubsection \<open>Cardinality\<close>
   657 lemma finite_PiE: "finite S \<Longrightarrow> (\<And>i. i \<in> S \<Longrightarrow> finite (T i)) \<Longrightarrow> finite (\<Pi>\<^sub>E i \<in> S. T i)"
   658   by (induct S arbitrary: T rule: finite_induct) (simp_all add: PiE_insert_eq)
   660 lemma inj_combinator: "x \<notin> S \<Longrightarrow> inj_on (\<lambda>(y, g). g(x := y)) (T x \<times> Pi\<^sub>E S T)"
   661 proof (safe intro!: inj_onI ext)
   662   fix f y g z
   663   assume "x \<notin> S"
   664   assume fg: "f \<in> Pi\<^sub>E S T" "g \<in> Pi\<^sub>E S T"
   665   assume "f(x := y) = g(x := z)"
   666   then have *: "\<And>i. (f(x := y)) i = (g(x := z)) i"
   667     unfolding fun_eq_iff by auto
   668   from this[of x] show "y = z" by simp
   669   fix i from *[of i] \<open>x \<notin> S\<close> fg show "f i = g i"
   670     by (auto split: if_split_asm simp: PiE_def extensional_def)
   671 qed
   673 lemma card_PiE: "finite S \<Longrightarrow> card (\<Pi>\<^sub>E i \<in> S. T i) = (\<Prod> i\<in>S. card (T i))"
   674 proof (induct rule: finite_induct)
   675   case empty
   676   then show ?case by auto
   677 next
   678   case (insert x S)
   679   then show ?case
   680     by (simp add: PiE_insert_eq inj_combinator card_image card_cartesian_product)
   681 qed
   683 end