src/HOL/Library/Permutations.thy
 author haftmann Fri Mar 22 19:18:08 2019 +0000 (4 months ago) changeset 69946 494934c30f38 parent 69895 6b03a8cf092d permissions -rw-r--r--
improved code equations taken over from AFP
```     1 (*  Title:      HOL/Library/Permutations.thy
```
```     2     Author:     Amine Chaieb, University of Cambridge
```
```     3 *)
```
```     4
```
```     5 section \<open>Permutations, both general and specifically on finite sets.\<close>
```
```     6
```
```     7 theory Permutations
```
```     8   imports Multiset Disjoint_Sets
```
```     9 begin
```
```    10
```
```    11 subsection \<open>Transpositions\<close>
```
```    12
```
```    13 lemma swap_id_idempotent [simp]: "Fun.swap a b id \<circ> Fun.swap a b id = id"
```
```    14   by (rule ext) (auto simp add: Fun.swap_def)
```
```    15
```
```    16 lemma inv_swap_id: "inv (Fun.swap a b id) = Fun.swap a b id"
```
```    17   by (rule inv_unique_comp) simp_all
```
```    18
```
```    19 lemma swap_id_eq: "Fun.swap a b id x = (if x = a then b else if x = b then a else x)"
```
```    20   by (simp add: Fun.swap_def)
```
```    21
```
```    22 lemma bij_swap_comp:
```
```    23   assumes "bij p"
```
```    24   shows "Fun.swap a b id \<circ> p = Fun.swap (inv p a) (inv p b) p"
```
```    25   using surj_f_inv_f[OF bij_is_surj[OF \<open>bij p\<close>]]
```
```    26   by (simp add: fun_eq_iff Fun.swap_def bij_inv_eq_iff[OF \<open>bij p\<close>])
```
```    27
```
```    28 lemma bij_swap_compose_bij:
```
```    29   assumes "bij p"
```
```    30   shows "bij (Fun.swap a b id \<circ> p)"
```
```    31   by (simp only: bij_swap_comp[OF \<open>bij p\<close>] bij_swap_iff \<open>bij p\<close>)
```
```    32
```
```    33
```
```    34 subsection \<open>Basic consequences of the definition\<close>
```
```    35
```
```    36 definition permutes  (infixr "permutes" 41)
```
```    37   where "(p permutes S) \<longleftrightarrow> (\<forall>x. x \<notin> S \<longrightarrow> p x = x) \<and> (\<forall>y. \<exists>!x. p x = y)"
```
```    38
```
```    39 lemma permutes_in_image: "p permutes S \<Longrightarrow> p x \<in> S \<longleftrightarrow> x \<in> S"
```
```    40   unfolding permutes_def by metis
```
```    41
```
```    42 lemma permutes_not_in: "f permutes S \<Longrightarrow> x \<notin> S \<Longrightarrow> f x = x"
```
```    43   by (auto simp: permutes_def)
```
```    44
```
```    45 lemma permutes_image: "p permutes S \<Longrightarrow> p ` S = S"
```
```    46   unfolding permutes_def
```
```    47   apply (rule set_eqI)
```
```    48   apply (simp add: image_iff)
```
```    49   apply metis
```
```    50   done
```
```    51
```
```    52 lemma permutes_inj: "p permutes S \<Longrightarrow> inj p"
```
```    53   unfolding permutes_def inj_def by blast
```
```    54
```
```    55 lemma permutes_inj_on: "f permutes S \<Longrightarrow> inj_on f A"
```
```    56   by (auto simp: permutes_def inj_on_def)
```
```    57
```
```    58 lemma permutes_surj: "p permutes s \<Longrightarrow> surj p"
```
```    59   unfolding permutes_def surj_def by metis
```
```    60
```
```    61 lemma permutes_bij: "p permutes s \<Longrightarrow> bij p"
```
```    62   unfolding bij_def by (metis permutes_inj permutes_surj)
```
```    63
```
```    64 lemma permutes_imp_bij: "p permutes S \<Longrightarrow> bij_betw p S S"
```
```    65   by (metis UNIV_I bij_betw_subset permutes_bij permutes_image subsetI)
```
```    66
```
```    67 lemma bij_imp_permutes: "bij_betw p S S \<Longrightarrow> (\<And>x. x \<notin> S \<Longrightarrow> p x = x) \<Longrightarrow> p permutes S"
```
```    68   unfolding permutes_def bij_betw_def inj_on_def
```
```    69   by auto (metis image_iff)+
```
```    70
```
```    71 lemma permutes_inv_o:
```
```    72   assumes permutes: "p permutes S"
```
```    73   shows "p \<circ> inv p = id"
```
```    74     and "inv p \<circ> p = id"
```
```    75   using permutes_inj[OF permutes] permutes_surj[OF permutes]
```
```    76   unfolding inj_iff[symmetric] surj_iff[symmetric] by blast+
```
```    77
```
```    78 lemma permutes_inverses:
```
```    79   fixes p :: "'a \<Rightarrow> 'a"
```
```    80   assumes permutes: "p permutes S"
```
```    81   shows "p (inv p x) = x"
```
```    82     and "inv p (p x) = x"
```
```    83   using permutes_inv_o[OF permutes, unfolded fun_eq_iff o_def] by auto
```
```    84
```
```    85 lemma permutes_subset: "p permutes S \<Longrightarrow> S \<subseteq> T \<Longrightarrow> p permutes T"
```
```    86   unfolding permutes_def by blast
```
```    87
```
```    88 lemma permutes_empty[simp]: "p permutes {} \<longleftrightarrow> p = id"
```
```    89   by (auto simp add: fun_eq_iff permutes_def)
```
```    90
```
```    91 lemma permutes_sing[simp]: "p permutes {a} \<longleftrightarrow> p = id"
```
```    92   by (simp add: fun_eq_iff permutes_def) metis  (*somewhat slow*)
```
```    93
```
```    94 lemma permutes_univ: "p permutes UNIV \<longleftrightarrow> (\<forall>y. \<exists>!x. p x = y)"
```
```    95   by (simp add: permutes_def)
```
```    96
```
```    97 lemma permutes_inv_eq: "p permutes S \<Longrightarrow> inv p y = x \<longleftrightarrow> p x = y"
```
```    98   unfolding permutes_def inv_def
```
```    99   apply auto
```
```   100   apply (erule allE[where x=y])
```
```   101   apply (erule allE[where x=y])
```
```   102   apply (rule someI_ex)
```
```   103   apply blast
```
```   104   apply (rule some1_equality)
```
```   105   apply blast
```
```   106   apply blast
```
```   107   done
```
```   108
```
```   109 lemma permutes_swap_id: "a \<in> S \<Longrightarrow> b \<in> S \<Longrightarrow> Fun.swap a b id permutes S"
```
```   110   unfolding permutes_def Fun.swap_def fun_upd_def by auto metis
```
```   111
```
```   112 lemma permutes_superset: "p permutes S \<Longrightarrow> (\<forall>x \<in> S - T. p x = x) \<Longrightarrow> p permutes T"
```
```   113   by (simp add: Ball_def permutes_def) metis
```
```   114
```
```   115 lemma permutes_bij_inv_into: \<^marker>\<open>contributor \<open>Lukas Bulwahn\<close>\<close>
```
```   116   fixes A :: "'a set"
```
```   117     and B :: "'b set"
```
```   118   assumes "p permutes A"
```
```   119     and "bij_betw f A B"
```
```   120   shows "(\<lambda>x. if x \<in> B then f (p (inv_into A f x)) else x) permutes B"
```
```   121 proof (rule bij_imp_permutes)
```
```   122   from assms have "bij_betw p A A" "bij_betw f A B" "bij_betw (inv_into A f) B A"
```
```   123     by (auto simp add: permutes_imp_bij bij_betw_inv_into)
```
```   124   then have "bij_betw (f \<circ> p \<circ> inv_into A f) B B"
```
```   125     by (simp add: bij_betw_trans)
```
```   126   then show "bij_betw (\<lambda>x. if x \<in> B then f (p (inv_into A f x)) else x) B B"
```
```   127     by (subst bij_betw_cong[where g="f \<circ> p \<circ> inv_into A f"]) auto
```
```   128 next
```
```   129   fix x
```
```   130   assume "x \<notin> B"
```
```   131   then show "(if x \<in> B then f (p (inv_into A f x)) else x) = x" by auto
```
```   132 qed
```
```   133
```
```   134 lemma permutes_image_mset: \<^marker>\<open>contributor \<open>Lukas Bulwahn\<close>\<close>
```
```   135   assumes "p permutes A"
```
```   136   shows "image_mset p (mset_set A) = mset_set A"
```
```   137   using assms by (metis image_mset_mset_set bij_betw_imp_inj_on permutes_imp_bij permutes_image)
```
```   138
```
```   139 lemma permutes_implies_image_mset_eq: \<^marker>\<open>contributor \<open>Lukas Bulwahn\<close>\<close>
```
```   140   assumes "p permutes A" "\<And>x. x \<in> A \<Longrightarrow> f x = f' (p x)"
```
```   141   shows "image_mset f' (mset_set A) = image_mset f (mset_set A)"
```
```   142 proof -
```
```   143   have "f x = f' (p x)" if "x \<in># mset_set A" for x
```
```   144     using assms(2)[of x] that by (cases "finite A") auto
```
```   145   with assms have "image_mset f (mset_set A) = image_mset (f' \<circ> p) (mset_set A)"
```
```   146     by (auto intro!: image_mset_cong)
```
```   147   also have "\<dots> = image_mset f' (image_mset p (mset_set A))"
```
```   148     by (simp add: image_mset.compositionality)
```
```   149   also have "\<dots> = image_mset f' (mset_set A)"
```
```   150   proof -
```
```   151     from assms permutes_image_mset have "image_mset p (mset_set A) = mset_set A"
```
```   152       by blast
```
```   153     then show ?thesis by simp
```
```   154   qed
```
```   155   finally show ?thesis ..
```
```   156 qed
```
```   157
```
```   158
```
```   159 subsection \<open>Group properties\<close>
```
```   160
```
```   161 lemma permutes_id: "id permutes S"
```
```   162   by (simp add: permutes_def)
```
```   163
```
```   164 lemma permutes_compose: "p permutes S \<Longrightarrow> q permutes S \<Longrightarrow> q \<circ> p permutes S"
```
```   165   unfolding permutes_def o_def by metis
```
```   166
```
```   167 lemma permutes_inv:
```
```   168   assumes "p permutes S"
```
```   169   shows "inv p permutes S"
```
```   170   using assms unfolding permutes_def permutes_inv_eq[OF assms] by metis
```
```   171
```
```   172 lemma permutes_inv_inv:
```
```   173   assumes "p permutes S"
```
```   174   shows "inv (inv p) = p"
```
```   175   unfolding fun_eq_iff permutes_inv_eq[OF assms] permutes_inv_eq[OF permutes_inv[OF assms]]
```
```   176   by blast
```
```   177
```
```   178 lemma permutes_invI:
```
```   179   assumes perm: "p permutes S"
```
```   180     and inv: "\<And>x. x \<in> S \<Longrightarrow> p' (p x) = x"
```
```   181     and outside: "\<And>x. x \<notin> S \<Longrightarrow> p' x = x"
```
```   182   shows "inv p = p'"
```
```   183 proof
```
```   184   show "inv p x = p' x" for x
```
```   185   proof (cases "x \<in> S")
```
```   186     case True
```
```   187     from assms have "p' x = p' (p (inv p x))"
```
```   188       by (simp add: permutes_inverses)
```
```   189     also from permutes_inv[OF perm] True have "\<dots> = inv p x"
```
```   190       by (subst inv) (simp_all add: permutes_in_image)
```
```   191     finally show ?thesis ..
```
```   192   next
```
```   193     case False
```
```   194     with permutes_inv[OF perm] show ?thesis
```
```   195       by (simp_all add: outside permutes_not_in)
```
```   196   qed
```
```   197 qed
```
```   198
```
```   199 lemma permutes_vimage: "f permutes A \<Longrightarrow> f -` A = A"
```
```   200   by (simp add: bij_vimage_eq_inv_image permutes_bij permutes_image[OF permutes_inv])
```
```   201
```
```   202
```
```   203 subsection \<open>Mapping permutations with bijections\<close>
```
```   204
```
```   205 lemma bij_betw_permutations:
```
```   206   assumes "bij_betw f A B"
```
```   207   shows   "bij_betw (\<lambda>\<pi> x. if x \<in> B then f (\<pi> (inv_into A f x)) else x)
```
```   208              {\<pi>. \<pi> permutes A} {\<pi>. \<pi> permutes B}" (is "bij_betw ?f _ _")
```
```   209 proof -
```
```   210   let ?g = "(\<lambda>\<pi> x. if x \<in> A then inv_into A f (\<pi> (f x)) else x)"
```
```   211   show ?thesis
```
```   212   proof (rule bij_betw_byWitness [of _ ?g], goal_cases)
```
```   213     case 3
```
```   214     show ?case using permutes_bij_inv_into[OF _ assms] by auto
```
```   215   next
```
```   216     case 4
```
```   217     have bij_inv: "bij_betw (inv_into A f) B A" by (intro bij_betw_inv_into assms)
```
```   218     {
```
```   219       fix \<pi> assume "\<pi> permutes B"
```
```   220       from permutes_bij_inv_into[OF this bij_inv] and assms
```
```   221         have "(\<lambda>x. if x \<in> A then inv_into A f (\<pi> (f x)) else x) permutes A"
```
```   222         by (simp add: inv_into_inv_into_eq cong: if_cong)
```
```   223     }
```
```   224     from this show ?case by (auto simp: permutes_inv)
```
```   225   next
```
```   226     case 1
```
```   227     thus ?case using assms
```
```   228       by (auto simp: fun_eq_iff permutes_not_in permutes_in_image bij_betw_inv_into_left
```
```   229                dest: bij_betwE)
```
```   230   next
```
```   231     case 2
```
```   232     moreover have "bij_betw (inv_into A f) B A"
```
```   233       by (intro bij_betw_inv_into assms)
```
```   234     ultimately show ?case using assms
```
```   235       by (auto simp: fun_eq_iff permutes_not_in permutes_in_image bij_betw_inv_into_right
```
```   236                dest: bij_betwE)
```
```   237   qed
```
```   238 qed
```
```   239
```
```   240 lemma bij_betw_derangements:
```
```   241   assumes "bij_betw f A B"
```
```   242   shows   "bij_betw (\<lambda>\<pi> x. if x \<in> B then f (\<pi> (inv_into A f x)) else x)
```
```   243              {\<pi>. \<pi> permutes A \<and> (\<forall>x\<in>A. \<pi> x \<noteq> x)} {\<pi>. \<pi> permutes B \<and> (\<forall>x\<in>B. \<pi> x \<noteq> x)}"
```
```   244            (is "bij_betw ?f _ _")
```
```   245 proof -
```
```   246   let ?g = "(\<lambda>\<pi> x. if x \<in> A then inv_into A f (\<pi> (f x)) else x)"
```
```   247   show ?thesis
```
```   248   proof (rule bij_betw_byWitness [of _ ?g], goal_cases)
```
```   249     case 3
```
```   250     have "?f \<pi> x \<noteq> x" if "\<pi> permutes A" "\<And>x. x \<in> A \<Longrightarrow> \<pi> x \<noteq> x" "x \<in> B" for \<pi> x
```
```   251       using that and assms by (metis bij_betwE bij_betw_imp_inj_on bij_betw_imp_surj_on
```
```   252                                      inv_into_f_f inv_into_into permutes_imp_bij)
```
```   253     with permutes_bij_inv_into[OF _ assms] show ?case by auto
```
```   254   next
```
```   255     case 4
```
```   256     have bij_inv: "bij_betw (inv_into A f) B A" by (intro bij_betw_inv_into assms)
```
```   257     have "?g \<pi> permutes A" if "\<pi> permutes B" for \<pi>
```
```   258       using permutes_bij_inv_into[OF that bij_inv] and assms
```
```   259       by (simp add: inv_into_inv_into_eq cong: if_cong)
```
```   260     moreover have "?g \<pi> x \<noteq> x" if "\<pi> permutes B" "\<And>x. x \<in> B \<Longrightarrow> \<pi> x \<noteq> x" "x \<in> A" for \<pi> x
```
```   261       using that and assms by (metis bij_betwE bij_betw_imp_surj_on f_inv_into_f permutes_imp_bij)
```
```   262     ultimately show ?case by auto
```
```   263   next
```
```   264     case 1
```
```   265     thus ?case using assms
```
```   266       by (force simp: fun_eq_iff permutes_not_in permutes_in_image bij_betw_inv_into_left
```
```   267                 dest: bij_betwE)
```
```   268   next
```
```   269     case 2
```
```   270     moreover have "bij_betw (inv_into A f) B A"
```
```   271       by (intro bij_betw_inv_into assms)
```
```   272     ultimately show ?case using assms
```
```   273       by (force simp: fun_eq_iff permutes_not_in permutes_in_image bij_betw_inv_into_right
```
```   274                 dest: bij_betwE)
```
```   275   qed
```
```   276 qed
```
```   277
```
```   278
```
```   279 subsection \<open>The number of permutations on a finite set\<close>
```
```   280
```
```   281 lemma permutes_insert_lemma:
```
```   282   assumes "p permutes (insert a S)"
```
```   283   shows "Fun.swap a (p a) id \<circ> p permutes S"
```
```   284   apply (rule permutes_superset[where S = "insert a S"])
```
```   285   apply (rule permutes_compose[OF assms])
```
```   286   apply (rule permutes_swap_id, simp)
```
```   287   using permutes_in_image[OF assms, of a]
```
```   288   apply simp
```
```   289   apply (auto simp add: Ball_def Fun.swap_def)
```
```   290   done
```
```   291
```
```   292 lemma permutes_insert: "{p. p permutes (insert a S)} =
```
```   293   (\<lambda>(b, p). Fun.swap a b id \<circ> p) ` {(b, p). b \<in> insert a S \<and> p \<in> {p. p permutes S}}"
```
```   294 proof -
```
```   295   have "p permutes insert a S \<longleftrightarrow>
```
```   296     (\<exists>b q. p = Fun.swap a b id \<circ> q \<and> b \<in> insert a S \<and> q permutes S)" for p
```
```   297   proof -
```
```   298     have "\<exists>b q. p = Fun.swap a b id \<circ> q \<and> b \<in> insert a S \<and> q permutes S"
```
```   299       if p: "p permutes insert a S"
```
```   300     proof -
```
```   301       let ?b = "p a"
```
```   302       let ?q = "Fun.swap a (p a) id \<circ> p"
```
```   303       have *: "p = Fun.swap a ?b id \<circ> ?q"
```
```   304         by (simp add: fun_eq_iff o_assoc)
```
```   305       have **: "?b \<in> insert a S"
```
```   306         unfolding permutes_in_image[OF p] by simp
```
```   307       from permutes_insert_lemma[OF p] * ** show ?thesis
```
```   308        by blast
```
```   309     qed
```
```   310     moreover have "p permutes insert a S"
```
```   311       if bq: "p = Fun.swap a b id \<circ> q" "b \<in> insert a S" "q permutes S" for b q
```
```   312     proof -
```
```   313       from permutes_subset[OF bq(3), of "insert a S"] have q: "q permutes insert a S"
```
```   314         by auto
```
```   315       have a: "a \<in> insert a S"
```
```   316         by simp
```
```   317       from bq(1) permutes_compose[OF q permutes_swap_id[OF a bq(2)]] show ?thesis
```
```   318         by simp
```
```   319     qed
```
```   320     ultimately show ?thesis by blast
```
```   321   qed
```
```   322   then show ?thesis by auto
```
```   323 qed
```
```   324
```
```   325 lemma card_permutations:
```
```   326   assumes "card S = n"
```
```   327     and "finite S"
```
```   328   shows "card {p. p permutes S} = fact n"
```
```   329   using assms(2,1)
```
```   330 proof (induct arbitrary: n)
```
```   331   case empty
```
```   332   then show ?case by simp
```
```   333 next
```
```   334   case (insert x F)
```
```   335   {
```
```   336     fix n
```
```   337     assume card_insert: "card (insert x F) = n"
```
```   338     let ?xF = "{p. p permutes insert x F}"
```
```   339     let ?pF = "{p. p permutes F}"
```
```   340     let ?pF' = "{(b, p). b \<in> insert x F \<and> p \<in> ?pF}"
```
```   341     let ?g = "(\<lambda>(b, p). Fun.swap x b id \<circ> p)"
```
```   342     have xfgpF': "?xF = ?g ` ?pF'"
```
```   343       by (rule permutes_insert[of x F])
```
```   344     from \<open>x \<notin> F\<close> \<open>finite F\<close> card_insert have Fs: "card F = n - 1"
```
```   345       by auto
```
```   346     from \<open>finite F\<close> insert.hyps Fs have pFs: "card ?pF = fact (n - 1)"
```
```   347       by auto
```
```   348     then have "finite ?pF"
```
```   349       by (auto intro: card_ge_0_finite)
```
```   350     with \<open>finite F\<close> card_insert have pF'f: "finite ?pF'"
```
```   351       apply (simp only: Collect_case_prod Collect_mem_eq)
```
```   352       apply (rule finite_cartesian_product)
```
```   353       apply simp_all
```
```   354       done
```
```   355
```
```   356     have ginj: "inj_on ?g ?pF'"
```
```   357     proof -
```
```   358       {
```
```   359         fix b p c q
```
```   360         assume bp: "(b, p) \<in> ?pF'"
```
```   361         assume cq: "(c, q) \<in> ?pF'"
```
```   362         assume eq: "?g (b, p) = ?g (c, q)"
```
```   363         from bp cq have pF: "p permutes F" and qF: "q permutes F"
```
```   364           by auto
```
```   365         from pF \<open>x \<notin> F\<close> eq have "b = ?g (b, p) x"
```
```   366           by (auto simp: permutes_def Fun.swap_def fun_upd_def fun_eq_iff)
```
```   367         also from qF \<open>x \<notin> F\<close> eq have "\<dots> = ?g (c, q) x"
```
```   368           by (auto simp: swap_def fun_upd_def fun_eq_iff)
```
```   369         also from qF \<open>x \<notin> F\<close> have "\<dots> = c"
```
```   370           by (auto simp: permutes_def Fun.swap_def fun_upd_def fun_eq_iff)
```
```   371         finally have "b = c" .
```
```   372         then have "Fun.swap x b id = Fun.swap x c id"
```
```   373           by simp
```
```   374         with eq have "Fun.swap x b id \<circ> p = Fun.swap x b id \<circ> q"
```
```   375           by simp
```
```   376         then have "Fun.swap x b id \<circ> (Fun.swap x b id \<circ> p) = Fun.swap x b id \<circ> (Fun.swap x b id \<circ> q)"
```
```   377           by simp
```
```   378         then have "p = q"
```
```   379           by (simp add: o_assoc)
```
```   380         with \<open>b = c\<close> have "(b, p) = (c, q)"
```
```   381           by simp
```
```   382       }
```
```   383       then show ?thesis
```
```   384         unfolding inj_on_def by blast
```
```   385     qed
```
```   386     from \<open>x \<notin> F\<close> \<open>finite F\<close> card_insert have "n \<noteq> 0"
```
```   387       by auto
```
```   388     then have "\<exists>m. n = Suc m"
```
```   389       by presburger
```
```   390     then obtain m where n: "n = Suc m"
```
```   391       by blast
```
```   392     from pFs card_insert have *: "card ?xF = fact n"
```
```   393       unfolding xfgpF' card_image[OF ginj]
```
```   394       using \<open>finite F\<close> \<open>finite ?pF\<close>
```
```   395       by (simp only: Collect_case_prod Collect_mem_eq card_cartesian_product) (simp add: n)
```
```   396     from finite_imageI[OF pF'f, of ?g] have xFf: "finite ?xF"
```
```   397       by (simp add: xfgpF' n)
```
```   398     from * have "card ?xF = fact n"
```
```   399       unfolding xFf by blast
```
```   400   }
```
```   401   with insert show ?case by simp
```
```   402 qed
```
```   403
```
```   404 lemma finite_permutations:
```
```   405   assumes "finite S"
```
```   406   shows "finite {p. p permutes S}"
```
```   407   using card_permutations[OF refl assms] by (auto intro: card_ge_0_finite)
```
```   408
```
```   409
```
```   410 subsection \<open>Permutations of index set for iterated operations\<close>
```
```   411
```
```   412 lemma (in comm_monoid_set) permute:
```
```   413   assumes "p permutes S"
```
```   414   shows "F g S = F (g \<circ> p) S"
```
```   415 proof -
```
```   416   from \<open>p permutes S\<close> have "inj p"
```
```   417     by (rule permutes_inj)
```
```   418   then have "inj_on p S"
```
```   419     by (auto intro: subset_inj_on)
```
```   420   then have "F g (p ` S) = F (g \<circ> p) S"
```
```   421     by (rule reindex)
```
```   422   moreover from \<open>p permutes S\<close> have "p ` S = S"
```
```   423     by (rule permutes_image)
```
```   424   ultimately show ?thesis
```
```   425     by simp
```
```   426 qed
```
```   427
```
```   428
```
```   429 subsection \<open>Various combinations of transpositions with 2, 1 and 0 common elements\<close>
```
```   430
```
```   431 lemma swap_id_common:" a \<noteq> c \<Longrightarrow> b \<noteq> c \<Longrightarrow>
```
```   432   Fun.swap a b id \<circ> Fun.swap a c id = Fun.swap b c id \<circ> Fun.swap a b id"
```
```   433   by (simp add: fun_eq_iff Fun.swap_def)
```
```   434
```
```   435 lemma swap_id_common': "a \<noteq> b \<Longrightarrow> a \<noteq> c \<Longrightarrow>
```
```   436   Fun.swap a c id \<circ> Fun.swap b c id = Fun.swap b c id \<circ> Fun.swap a b id"
```
```   437   by (simp add: fun_eq_iff Fun.swap_def)
```
```   438
```
```   439 lemma swap_id_independent: "a \<noteq> c \<Longrightarrow> a \<noteq> d \<Longrightarrow> b \<noteq> c \<Longrightarrow> b \<noteq> d \<Longrightarrow>
```
```   440   Fun.swap a b id \<circ> Fun.swap c d id = Fun.swap c d id \<circ> Fun.swap a b id"
```
```   441   by (simp add: fun_eq_iff Fun.swap_def)
```
```   442
```
```   443
```
```   444 subsection \<open>Permutations as transposition sequences\<close>
```
```   445
```
```   446 inductive swapidseq :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> bool"
```
```   447   where
```
```   448     id[simp]: "swapidseq 0 id"
```
```   449   | comp_Suc: "swapidseq n p \<Longrightarrow> a \<noteq> b \<Longrightarrow> swapidseq (Suc n) (Fun.swap a b id \<circ> p)"
```
```   450
```
```   451 declare id[unfolded id_def, simp]
```
```   452
```
```   453 definition "permutation p \<longleftrightarrow> (\<exists>n. swapidseq n p)"
```
```   454
```
```   455
```
```   456 subsection \<open>Some closure properties of the set of permutations, with lengths\<close>
```
```   457
```
```   458 lemma permutation_id[simp]: "permutation id"
```
```   459   unfolding permutation_def by (rule exI[where x=0]) simp
```
```   460
```
```   461 declare permutation_id[unfolded id_def, simp]
```
```   462
```
```   463 lemma swapidseq_swap: "swapidseq (if a = b then 0 else 1) (Fun.swap a b id)"
```
```   464   apply clarsimp
```
```   465   using comp_Suc[of 0 id a b]
```
```   466   apply simp
```
```   467   done
```
```   468
```
```   469 lemma permutation_swap_id: "permutation (Fun.swap a b id)"
```
```   470 proof (cases "a = b")
```
```   471   case True
```
```   472   then show ?thesis by simp
```
```   473 next
```
```   474   case False
```
```   475   then show ?thesis
```
```   476     unfolding permutation_def
```
```   477     using swapidseq_swap[of a b] by blast
```
```   478 qed
```
```   479
```
```   480
```
```   481 lemma swapidseq_comp_add: "swapidseq n p \<Longrightarrow> swapidseq m q \<Longrightarrow> swapidseq (n + m) (p \<circ> q)"
```
```   482 proof (induct n p arbitrary: m q rule: swapidseq.induct)
```
```   483   case (id m q)
```
```   484   then show ?case by simp
```
```   485 next
```
```   486   case (comp_Suc n p a b m q)
```
```   487   have eq: "Suc n + m = Suc (n + m)"
```
```   488     by arith
```
```   489   show ?case
```
```   490     apply (simp only: eq comp_assoc)
```
```   491     apply (rule swapidseq.comp_Suc)
```
```   492     using comp_Suc.hyps(2)[OF comp_Suc.prems] comp_Suc.hyps(3)
```
```   493      apply blast+
```
```   494     done
```
```   495 qed
```
```   496
```
```   497 lemma permutation_compose: "permutation p \<Longrightarrow> permutation q \<Longrightarrow> permutation (p \<circ> q)"
```
```   498   unfolding permutation_def using swapidseq_comp_add[of _ p _ q] by metis
```
```   499
```
```   500 lemma swapidseq_endswap: "swapidseq n p \<Longrightarrow> a \<noteq> b \<Longrightarrow> swapidseq (Suc n) (p \<circ> Fun.swap a b id)"
```
```   501   by (induct n p rule: swapidseq.induct)
```
```   502     (use swapidseq_swap[of a b] in \<open>auto simp add: comp_assoc intro: swapidseq.comp_Suc\<close>)
```
```   503
```
```   504 lemma swapidseq_inverse_exists: "swapidseq n p \<Longrightarrow> \<exists>q. swapidseq n q \<and> p \<circ> q = id \<and> q \<circ> p = id"
```
```   505 proof (induct n p rule: swapidseq.induct)
```
```   506   case id
```
```   507   then show ?case
```
```   508     by (rule exI[where x=id]) simp
```
```   509 next
```
```   510   case (comp_Suc n p a b)
```
```   511   from comp_Suc.hyps obtain q where q: "swapidseq n q" "p \<circ> q = id" "q \<circ> p = id"
```
```   512     by blast
```
```   513   let ?q = "q \<circ> Fun.swap a b id"
```
```   514   note H = comp_Suc.hyps
```
```   515   from swapidseq_swap[of a b] H(3) have *: "swapidseq 1 (Fun.swap a b id)"
```
```   516     by simp
```
```   517   from swapidseq_comp_add[OF q(1) *] have **: "swapidseq (Suc n) ?q"
```
```   518     by simp
```
```   519   have "Fun.swap a b id \<circ> p \<circ> ?q = Fun.swap a b id \<circ> (p \<circ> q) \<circ> Fun.swap a b id"
```
```   520     by (simp add: o_assoc)
```
```   521   also have "\<dots> = id"
```
```   522     by (simp add: q(2))
```
```   523   finally have ***: "Fun.swap a b id \<circ> p \<circ> ?q = id" .
```
```   524   have "?q \<circ> (Fun.swap a b id \<circ> p) = q \<circ> (Fun.swap a b id \<circ> Fun.swap a b id) \<circ> p"
```
```   525     by (simp only: o_assoc)
```
```   526   then have "?q \<circ> (Fun.swap a b id \<circ> p) = id"
```
```   527     by (simp add: q(3))
```
```   528   with ** *** show ?case
```
```   529     by blast
```
```   530 qed
```
```   531
```
```   532 lemma swapidseq_inverse:
```
```   533   assumes "swapidseq n p"
```
```   534   shows "swapidseq n (inv p)"
```
```   535   using swapidseq_inverse_exists[OF assms] inv_unique_comp[of p] by auto
```
```   536
```
```   537 lemma permutation_inverse: "permutation p \<Longrightarrow> permutation (inv p)"
```
```   538   using permutation_def swapidseq_inverse by blast
```
```   539
```
```   540
```
```   541 subsection \<open>The identity map only has even transposition sequences\<close>
```
```   542
```
```   543 lemma symmetry_lemma:
```
```   544   assumes "\<And>a b c d. P a b c d \<Longrightarrow> P a b d c"
```
```   545     and "\<And>a b c d. a \<noteq> b \<Longrightarrow> c \<noteq> d \<Longrightarrow>
```
```   546       a = c \<and> b = d \<or> a = c \<and> b \<noteq> d \<or> a \<noteq> c \<and> b = d \<or> a \<noteq> c \<and> a \<noteq> d \<and> b \<noteq> c \<and> b \<noteq> d \<Longrightarrow>
```
```   547       P a b c d"
```
```   548   shows "\<And>a b c d. a \<noteq> b \<longrightarrow> c \<noteq> d \<longrightarrow>  P a b c d"
```
```   549   using assms by metis
```
```   550
```
```   551 lemma swap_general: "a \<noteq> b \<Longrightarrow> c \<noteq> d \<Longrightarrow>
```
```   552   Fun.swap a b id \<circ> Fun.swap c d id = id \<or>
```
```   553   (\<exists>x y z. x \<noteq> a \<and> y \<noteq> a \<and> z \<noteq> a \<and> x \<noteq> y \<and>
```
```   554     Fun.swap a b id \<circ> Fun.swap c d id = Fun.swap x y id \<circ> Fun.swap a z id)"
```
```   555 proof -
```
```   556   assume neq: "a \<noteq> b" "c \<noteq> d"
```
```   557   have "a \<noteq> b \<longrightarrow> c \<noteq> d \<longrightarrow>
```
```   558     (Fun.swap a b id \<circ> Fun.swap c d id = id \<or>
```
```   559       (\<exists>x y z. x \<noteq> a \<and> y \<noteq> a \<and> z \<noteq> a \<and> x \<noteq> y \<and>
```
```   560         Fun.swap a b id \<circ> Fun.swap c d id = Fun.swap x y id \<circ> Fun.swap a z id))"
```
```   561     apply (rule symmetry_lemma[where a=a and b=b and c=c and d=d])
```
```   562      apply (simp_all only: swap_commute)
```
```   563     apply (case_tac "a = c \<and> b = d")
```
```   564      apply (clarsimp simp only: swap_commute swap_id_idempotent)
```
```   565     apply (case_tac "a = c \<and> b \<noteq> d")
```
```   566      apply (rule disjI2)
```
```   567      apply (rule_tac x="b" in exI)
```
```   568      apply (rule_tac x="d" in exI)
```
```   569      apply (rule_tac x="b" in exI)
```
```   570      apply (clarsimp simp add: fun_eq_iff Fun.swap_def)
```
```   571     apply (case_tac "a \<noteq> c \<and> b = d")
```
```   572      apply (rule disjI2)
```
```   573      apply (rule_tac x="c" in exI)
```
```   574      apply (rule_tac x="d" in exI)
```
```   575      apply (rule_tac x="c" in exI)
```
```   576      apply (clarsimp simp add: fun_eq_iff Fun.swap_def)
```
```   577     apply (rule disjI2)
```
```   578     apply (rule_tac x="c" in exI)
```
```   579     apply (rule_tac x="d" in exI)
```
```   580     apply (rule_tac x="b" in exI)
```
```   581     apply (clarsimp simp add: fun_eq_iff Fun.swap_def)
```
```   582     done
```
```   583   with neq show ?thesis by metis
```
```   584 qed
```
```   585
```
```   586 lemma swapidseq_id_iff[simp]: "swapidseq 0 p \<longleftrightarrow> p = id"
```
```   587   using swapidseq.cases[of 0 p "p = id"] by auto
```
```   588
```
```   589 lemma swapidseq_cases: "swapidseq n p \<longleftrightarrow>
```
```   590     n = 0 \<and> p = id \<or> (\<exists>a b q m. n = Suc m \<and> p = Fun.swap a b id \<circ> q \<and> swapidseq m q \<and> a \<noteq> b)"
```
```   591   apply (rule iffI)
```
```   592    apply (erule swapidseq.cases[of n p])
```
```   593     apply simp
```
```   594    apply (rule disjI2)
```
```   595    apply (rule_tac x= "a" in exI)
```
```   596    apply (rule_tac x= "b" in exI)
```
```   597    apply (rule_tac x= "pa" in exI)
```
```   598    apply (rule_tac x= "na" in exI)
```
```   599    apply simp
```
```   600   apply auto
```
```   601   apply (rule comp_Suc, simp_all)
```
```   602   done
```
```   603
```
```   604 lemma fixing_swapidseq_decrease:
```
```   605   assumes "swapidseq n p"
```
```   606     and "a \<noteq> b"
```
```   607     and "(Fun.swap a b id \<circ> p) a = a"
```
```   608   shows "n \<noteq> 0 \<and> swapidseq (n - 1) (Fun.swap a b id \<circ> p)"
```
```   609   using assms
```
```   610 proof (induct n arbitrary: p a b)
```
```   611   case 0
```
```   612   then show ?case
```
```   613     by (auto simp add: Fun.swap_def fun_upd_def)
```
```   614 next
```
```   615   case (Suc n p a b)
```
```   616   from Suc.prems(1) swapidseq_cases[of "Suc n" p]
```
```   617   obtain c d q m where
```
```   618     cdqm: "Suc n = Suc m" "p = Fun.swap c d id \<circ> q" "swapidseq m q" "c \<noteq> d" "n = m"
```
```   619     by auto
```
```   620   consider "Fun.swap a b id \<circ> Fun.swap c d id = id"
```
```   621     | x y z where "x \<noteq> a" "y \<noteq> a" "z \<noteq> a" "x \<noteq> y"
```
```   622       "Fun.swap a b id \<circ> Fun.swap c d id = Fun.swap x y id \<circ> Fun.swap a z id"
```
```   623     using swap_general[OF Suc.prems(2) cdqm(4)] by metis
```
```   624   then show ?case
```
```   625   proof cases
```
```   626     case 1
```
```   627     then show ?thesis
```
```   628       by (simp only: cdqm o_assoc) (simp add: cdqm)
```
```   629   next
```
```   630     case prems: 2
```
```   631     then have az: "a \<noteq> z"
```
```   632       by simp
```
```   633     from prems have *: "(Fun.swap x y id \<circ> h) a = a \<longleftrightarrow> h a = a" for h
```
```   634       by (simp add: Fun.swap_def)
```
```   635     from cdqm(2) have "Fun.swap a b id \<circ> p = Fun.swap a b id \<circ> (Fun.swap c d id \<circ> q)"
```
```   636       by simp
```
```   637     then have "Fun.swap a b id \<circ> p = Fun.swap x y id \<circ> (Fun.swap a z id \<circ> q)"
```
```   638       by (simp add: o_assoc prems)
```
```   639     then have "(Fun.swap a b id \<circ> p) a = (Fun.swap x y id \<circ> (Fun.swap a z id \<circ> q)) a"
```
```   640       by simp
```
```   641     then have "(Fun.swap x y id \<circ> (Fun.swap a z id \<circ> q)) a = a"
```
```   642       unfolding Suc by metis
```
```   643     then have "(Fun.swap a z id \<circ> q) a = a"
```
```   644       by (simp only: *)
```
```   645     from Suc.hyps[OF cdqm(3)[ unfolded cdqm(5)[symmetric]] az this]
```
```   646     have **: "swapidseq (n - 1) (Fun.swap a z id \<circ> q)" "n \<noteq> 0"
```
```   647       by blast+
```
```   648     from \<open>n \<noteq> 0\<close> have ***: "Suc n - 1 = Suc (n - 1)"
```
```   649       by auto
```
```   650     show ?thesis
```
```   651       apply (simp only: cdqm(2) prems o_assoc ***)
```
```   652       apply (simp only: Suc_not_Zero simp_thms comp_assoc)
```
```   653       apply (rule comp_Suc)
```
```   654       using ** prems
```
```   655        apply blast+
```
```   656       done
```
```   657   qed
```
```   658 qed
```
```   659
```
```   660 lemma swapidseq_identity_even:
```
```   661   assumes "swapidseq n (id :: 'a \<Rightarrow> 'a)"
```
```   662   shows "even n"
```
```   663   using \<open>swapidseq n id\<close>
```
```   664 proof (induct n rule: nat_less_induct)
```
```   665   case H: (1 n)
```
```   666   consider "n = 0"
```
```   667     | a b :: 'a and q m where "n = Suc m" "id = Fun.swap a b id \<circ> q" "swapidseq m q" "a \<noteq> b"
```
```   668     using H(2)[unfolded swapidseq_cases[of n id]] by auto
```
```   669   then show ?case
```
```   670   proof cases
```
```   671     case 1
```
```   672     then show ?thesis by presburger
```
```   673   next
```
```   674     case h: 2
```
```   675     from fixing_swapidseq_decrease[OF h(3,4), unfolded h(2)[symmetric]]
```
```   676     have m: "m \<noteq> 0" "swapidseq (m - 1) (id :: 'a \<Rightarrow> 'a)"
```
```   677       by auto
```
```   678     from h m have mn: "m - 1 < n"
```
```   679       by arith
```
```   680     from H(1)[rule_format, OF mn m(2)] h(1) m(1) show ?thesis
```
```   681       by presburger
```
```   682   qed
```
```   683 qed
```
```   684
```
```   685
```
```   686 subsection \<open>Therefore we have a welldefined notion of parity\<close>
```
```   687
```
```   688 definition "evenperm p = even (SOME n. swapidseq n p)"
```
```   689
```
```   690 lemma swapidseq_even_even:
```
```   691   assumes m: "swapidseq m p"
```
```   692     and n: "swapidseq n p"
```
```   693   shows "even m \<longleftrightarrow> even n"
```
```   694 proof -
```
```   695   from swapidseq_inverse_exists[OF n] obtain q where q: "swapidseq n q" "p \<circ> q = id" "q \<circ> p = id"
```
```   696     by blast
```
```   697   from swapidseq_identity_even[OF swapidseq_comp_add[OF m q(1), unfolded q]] show ?thesis
```
```   698     by arith
```
```   699 qed
```
```   700
```
```   701 lemma evenperm_unique:
```
```   702   assumes p: "swapidseq n p"
```
```   703     and n:"even n = b"
```
```   704   shows "evenperm p = b"
```
```   705   unfolding n[symmetric] evenperm_def
```
```   706   apply (rule swapidseq_even_even[where p = p])
```
```   707    apply (rule someI[where x = n])
```
```   708   using p
```
```   709    apply blast+
```
```   710   done
```
```   711
```
```   712
```
```   713 subsection \<open>And it has the expected composition properties\<close>
```
```   714
```
```   715 lemma evenperm_id[simp]: "evenperm id = True"
```
```   716   by (rule evenperm_unique[where n = 0]) simp_all
```
```   717
```
```   718 lemma evenperm_swap: "evenperm (Fun.swap a b id) = (a = b)"
```
```   719   by (rule evenperm_unique[where n="if a = b then 0 else 1"]) (simp_all add: swapidseq_swap)
```
```   720
```
```   721 lemma evenperm_comp:
```
```   722   assumes "permutation p" "permutation q"
```
```   723   shows "evenperm (p \<circ> q) \<longleftrightarrow> evenperm p = evenperm q"
```
```   724 proof -
```
```   725   from assms obtain n m where n: "swapidseq n p" and m: "swapidseq m q"
```
```   726     unfolding permutation_def by blast
```
```   727   have "even (n + m) \<longleftrightarrow> (even n \<longleftrightarrow> even m)"
```
```   728     by arith
```
```   729   from evenperm_unique[OF n refl] evenperm_unique[OF m refl]
```
```   730     and evenperm_unique[OF swapidseq_comp_add[OF n m] this] show ?thesis
```
```   731     by blast
```
```   732 qed
```
```   733
```
```   734 lemma evenperm_inv:
```
```   735   assumes "permutation p"
```
```   736   shows "evenperm (inv p) = evenperm p"
```
```   737 proof -
```
```   738   from assms obtain n where n: "swapidseq n p"
```
```   739     unfolding permutation_def by blast
```
```   740   show ?thesis
```
```   741     by (rule evenperm_unique[OF swapidseq_inverse[OF n] evenperm_unique[OF n refl, symmetric]])
```
```   742 qed
```
```   743
```
```   744
```
```   745 subsection \<open>A more abstract characterization of permutations\<close>
```
```   746
```
```   747 lemma bij_iff: "bij f \<longleftrightarrow> (\<forall>x. \<exists>!y. f y = x)"
```
```   748   unfolding bij_def inj_def surj_def
```
```   749   apply auto
```
```   750    apply metis
```
```   751   apply metis
```
```   752   done
```
```   753
```
```   754 lemma permutation_bijective:
```
```   755   assumes "permutation p"
```
```   756   shows "bij p"
```
```   757 proof -
```
```   758   from assms obtain n where n: "swapidseq n p"
```
```   759     unfolding permutation_def by blast
```
```   760   from swapidseq_inverse_exists[OF n] obtain q where q: "swapidseq n q" "p \<circ> q = id" "q \<circ> p = id"
```
```   761     by blast
```
```   762   then show ?thesis
```
```   763     unfolding bij_iff
```
```   764     apply (auto simp add: fun_eq_iff)
```
```   765     apply metis
```
```   766     done
```
```   767 qed
```
```   768
```
```   769 lemma permutation_finite_support:
```
```   770   assumes "permutation p"
```
```   771   shows "finite {x. p x \<noteq> x}"
```
```   772 proof -
```
```   773   from assms obtain n where "swapidseq n p"
```
```   774     unfolding permutation_def by blast
```
```   775   then show ?thesis
```
```   776   proof (induct n p rule: swapidseq.induct)
```
```   777     case id
```
```   778     then show ?case by simp
```
```   779   next
```
```   780     case (comp_Suc n p a b)
```
```   781     let ?S = "insert a (insert b {x. p x \<noteq> x})"
```
```   782     from comp_Suc.hyps(2) have *: "finite ?S"
```
```   783       by simp
```
```   784     from \<open>a \<noteq> b\<close> have **: "{x. (Fun.swap a b id \<circ> p) x \<noteq> x} \<subseteq> ?S"
```
```   785       by (auto simp: Fun.swap_def)
```
```   786     show ?case
```
```   787       by (rule finite_subset[OF ** *])
```
```   788   qed
```
```   789 qed
```
```   790
```
```   791 lemma permutation_lemma:
```
```   792   assumes "finite S"
```
```   793     and "bij p"
```
```   794     and "\<forall>x. x\<notin> S \<longrightarrow> p x = x"
```
```   795   shows "permutation p"
```
```   796   using assms
```
```   797 proof (induct S arbitrary: p rule: finite_induct)
```
```   798   case empty
```
```   799   then show ?case
```
```   800     by simp
```
```   801 next
```
```   802   case (insert a F p)
```
```   803   let ?r = "Fun.swap a (p a) id \<circ> p"
```
```   804   let ?q = "Fun.swap a (p a) id \<circ> ?r"
```
```   805   have *: "?r a = a"
```
```   806     by (simp add: Fun.swap_def)
```
```   807   from insert * have **: "\<forall>x. x \<notin> F \<longrightarrow> ?r x = x"
```
```   808     by (metis bij_pointE comp_apply id_apply insert_iff swap_apply(3))
```
```   809   have "bij ?r"
```
```   810     by (rule bij_swap_compose_bij[OF insert(4)])
```
```   811   have "permutation ?r"
```
```   812     by (rule insert(3)[OF \<open>bij ?r\<close> **])
```
```   813   then have "permutation ?q"
```
```   814     by (simp add: permutation_compose permutation_swap_id)
```
```   815   then show ?case
```
```   816     by (simp add: o_assoc)
```
```   817 qed
```
```   818
```
```   819 lemma permutation: "permutation p \<longleftrightarrow> bij p \<and> finite {x. p x \<noteq> x}"
```
```   820   (is "?lhs \<longleftrightarrow> ?b \<and> ?f")
```
```   821 proof
```
```   822   assume ?lhs
```
```   823   with permutation_bijective permutation_finite_support show "?b \<and> ?f"
```
```   824     by auto
```
```   825 next
```
```   826   assume "?b \<and> ?f"
```
```   827   then have "?f" "?b" by blast+
```
```   828   from permutation_lemma[OF this] show ?lhs
```
```   829     by blast
```
```   830 qed
```
```   831
```
```   832 lemma permutation_inverse_works:
```
```   833   assumes "permutation p"
```
```   834   shows "inv p \<circ> p = id"
```
```   835     and "p \<circ> inv p = id"
```
```   836   using permutation_bijective [OF assms] by (auto simp: bij_def inj_iff surj_iff)
```
```   837
```
```   838 lemma permutation_inverse_compose:
```
```   839   assumes p: "permutation p"
```
```   840     and q: "permutation q"
```
```   841   shows "inv (p \<circ> q) = inv q \<circ> inv p"
```
```   842 proof -
```
```   843   note ps = permutation_inverse_works[OF p]
```
```   844   note qs = permutation_inverse_works[OF q]
```
```   845   have "p \<circ> q \<circ> (inv q \<circ> inv p) = p \<circ> (q \<circ> inv q) \<circ> inv p"
```
```   846     by (simp add: o_assoc)
```
```   847   also have "\<dots> = id"
```
```   848     by (simp add: ps qs)
```
```   849   finally have *: "p \<circ> q \<circ> (inv q \<circ> inv p) = id" .
```
```   850   have "inv q \<circ> inv p \<circ> (p \<circ> q) = inv q \<circ> (inv p \<circ> p) \<circ> q"
```
```   851     by (simp add: o_assoc)
```
```   852   also have "\<dots> = id"
```
```   853     by (simp add: ps qs)
```
```   854   finally have **: "inv q \<circ> inv p \<circ> (p \<circ> q) = id" .
```
```   855   show ?thesis
```
```   856     by (rule inv_unique_comp[OF * **])
```
```   857 qed
```
```   858
```
```   859
```
```   860 subsection \<open>Relation to \<open>permutes\<close>\<close>
```
```   861
```
```   862 lemma permutation_permutes: "permutation p \<longleftrightarrow> (\<exists>S. finite S \<and> p permutes S)"
```
```   863   unfolding permutation permutes_def bij_iff[symmetric]
```
```   864   apply (rule iffI, clarify)
```
```   865    apply (rule exI[where x="{x. p x \<noteq> x}"])
```
```   866    apply simp
```
```   867   apply clarsimp
```
```   868   apply (rule_tac B="S" in finite_subset)
```
```   869    apply auto
```
```   870   done
```
```   871
```
```   872
```
```   873 subsection \<open>Hence a sort of induction principle composing by swaps\<close>
```
```   874
```
```   875 lemma permutes_induct: "finite S \<Longrightarrow> P id \<Longrightarrow>
```
```   876   (\<And>a b p. a \<in> S \<Longrightarrow> b \<in> S \<Longrightarrow> P p \<Longrightarrow> P p \<Longrightarrow> permutation p \<Longrightarrow> P (Fun.swap a b id \<circ> p)) \<Longrightarrow>
```
```   877   (\<And>p. p permutes S \<Longrightarrow> P p)"
```
```   878 proof (induct S rule: finite_induct)
```
```   879   case empty
```
```   880   then show ?case by auto
```
```   881 next
```
```   882   case (insert x F p)
```
```   883   let ?r = "Fun.swap x (p x) id \<circ> p"
```
```   884   let ?q = "Fun.swap x (p x) id \<circ> ?r"
```
```   885   have qp: "?q = p"
```
```   886     by (simp add: o_assoc)
```
```   887   from permutes_insert_lemma[OF insert.prems(3)] insert have Pr: "P ?r"
```
```   888     by blast
```
```   889   from permutes_in_image[OF insert.prems(3), of x]
```
```   890   have pxF: "p x \<in> insert x F"
```
```   891     by simp
```
```   892   have xF: "x \<in> insert x F"
```
```   893     by simp
```
```   894   have rp: "permutation ?r"
```
```   895     unfolding permutation_permutes
```
```   896     using insert.hyps(1) permutes_insert_lemma[OF insert.prems(3)]
```
```   897     by blast
```
```   898   from insert.prems(2)[OF xF pxF Pr Pr rp] qp show ?case
```
```   899     by (simp only:)
```
```   900 qed
```
```   901
```
```   902
```
```   903 subsection \<open>Sign of a permutation as a real number\<close>
```
```   904
```
```   905 definition "sign p = (if evenperm p then (1::int) else -1)"
```
```   906
```
```   907 lemma sign_nz: "sign p \<noteq> 0"
```
```   908   by (simp add: sign_def)
```
```   909
```
```   910 lemma sign_id: "sign id = 1"
```
```   911   by (simp add: sign_def)
```
```   912
```
```   913 lemma sign_inverse: "permutation p \<Longrightarrow> sign (inv p) = sign p"
```
```   914   by (simp add: sign_def evenperm_inv)
```
```   915
```
```   916 lemma sign_compose: "permutation p \<Longrightarrow> permutation q \<Longrightarrow> sign (p \<circ> q) = sign p * sign q"
```
```   917   by (simp add: sign_def evenperm_comp)
```
```   918
```
```   919 lemma sign_swap_id: "sign (Fun.swap a b id) = (if a = b then 1 else -1)"
```
```   920   by (simp add: sign_def evenperm_swap)
```
```   921
```
```   922 lemma sign_idempotent: "sign p * sign p = 1"
```
```   923   by (simp add: sign_def)
```
```   924
```
```   925
```
```   926 subsection \<open>Permuting a list\<close>
```
```   927
```
```   928 text \<open>This function permutes a list by applying a permutation to the indices.\<close>
```
```   929
```
```   930 definition permute_list :: "(nat \<Rightarrow> nat) \<Rightarrow> 'a list \<Rightarrow> 'a list"
```
```   931   where "permute_list f xs = map (\<lambda>i. xs ! (f i)) [0..<length xs]"
```
```   932
```
```   933 lemma permute_list_map:
```
```   934   assumes "f permutes {..<length xs}"
```
```   935   shows "permute_list f (map g xs) = map g (permute_list f xs)"
```
```   936   using permutes_in_image[OF assms] by (auto simp: permute_list_def)
```
```   937
```
```   938 lemma permute_list_nth:
```
```   939   assumes "f permutes {..<length xs}" "i < length xs"
```
```   940   shows "permute_list f xs ! i = xs ! f i"
```
```   941   using permutes_in_image[OF assms(1)] assms(2)
```
```   942   by (simp add: permute_list_def)
```
```   943
```
```   944 lemma permute_list_Nil [simp]: "permute_list f [] = []"
```
```   945   by (simp add: permute_list_def)
```
```   946
```
```   947 lemma length_permute_list [simp]: "length (permute_list f xs) = length xs"
```
```   948   by (simp add: permute_list_def)
```
```   949
```
```   950 lemma permute_list_compose:
```
```   951   assumes "g permutes {..<length xs}"
```
```   952   shows "permute_list (f \<circ> g) xs = permute_list g (permute_list f xs)"
```
```   953   using assms[THEN permutes_in_image] by (auto simp add: permute_list_def)
```
```   954
```
```   955 lemma permute_list_ident [simp]: "permute_list (\<lambda>x. x) xs = xs"
```
```   956   by (simp add: permute_list_def map_nth)
```
```   957
```
```   958 lemma permute_list_id [simp]: "permute_list id xs = xs"
```
```   959   by (simp add: id_def)
```
```   960
```
```   961 lemma mset_permute_list [simp]:
```
```   962   fixes xs :: "'a list"
```
```   963   assumes "f permutes {..<length xs}"
```
```   964   shows "mset (permute_list f xs) = mset xs"
```
```   965 proof (rule multiset_eqI)
```
```   966   fix y :: 'a
```
```   967   from assms have [simp]: "f x < length xs \<longleftrightarrow> x < length xs" for x
```
```   968     using permutes_in_image[OF assms] by auto
```
```   969   have "count (mset (permute_list f xs)) y = card ((\<lambda>i. xs ! f i) -` {y} \<inter> {..<length xs})"
```
```   970     by (simp add: permute_list_def count_image_mset atLeast0LessThan)
```
```   971   also have "(\<lambda>i. xs ! f i) -` {y} \<inter> {..<length xs} = f -` {i. i < length xs \<and> y = xs ! i}"
```
```   972     by auto
```
```   973   also from assms have "card \<dots> = card {i. i < length xs \<and> y = xs ! i}"
```
```   974     by (intro card_vimage_inj) (auto simp: permutes_inj permutes_surj)
```
```   975   also have "\<dots> = count (mset xs) y"
```
```   976     by (simp add: count_mset length_filter_conv_card)
```
```   977   finally show "count (mset (permute_list f xs)) y = count (mset xs) y"
```
```   978     by simp
```
```   979 qed
```
```   980
```
```   981 lemma set_permute_list [simp]:
```
```   982   assumes "f permutes {..<length xs}"
```
```   983   shows "set (permute_list f xs) = set xs"
```
```   984   by (rule mset_eq_setD[OF mset_permute_list]) fact
```
```   985
```
```   986 lemma distinct_permute_list [simp]:
```
```   987   assumes "f permutes {..<length xs}"
```
```   988   shows "distinct (permute_list f xs) = distinct xs"
```
```   989   by (simp add: distinct_count_atmost_1 assms)
```
```   990
```
```   991 lemma permute_list_zip:
```
```   992   assumes "f permutes A" "A = {..<length xs}"
```
```   993   assumes [simp]: "length xs = length ys"
```
```   994   shows "permute_list f (zip xs ys) = zip (permute_list f xs) (permute_list f ys)"
```
```   995 proof -
```
```   996   from permutes_in_image[OF assms(1)] assms(2) have *: "f i < length ys \<longleftrightarrow> i < length ys" for i
```
```   997     by simp
```
```   998   have "permute_list f (zip xs ys) = map (\<lambda>i. zip xs ys ! f i) [0..<length ys]"
```
```   999     by (simp_all add: permute_list_def zip_map_map)
```
```  1000   also have "\<dots> = map (\<lambda>(x, y). (xs ! f x, ys ! f y)) (zip [0..<length ys] [0..<length ys])"
```
```  1001     by (intro nth_equalityI) (simp_all add: *)
```
```  1002   also have "\<dots> = zip (permute_list f xs) (permute_list f ys)"
```
```  1003     by (simp_all add: permute_list_def zip_map_map)
```
```  1004   finally show ?thesis .
```
```  1005 qed
```
```  1006
```
```  1007 lemma map_of_permute:
```
```  1008   assumes "\<sigma> permutes fst ` set xs"
```
```  1009   shows "map_of xs \<circ> \<sigma> = map_of (map (\<lambda>(x,y). (inv \<sigma> x, y)) xs)"
```
```  1010     (is "_ = map_of (map ?f _)")
```
```  1011 proof
```
```  1012   from assms have "inj \<sigma>" "surj \<sigma>"
```
```  1013     by (simp_all add: permutes_inj permutes_surj)
```
```  1014   then show "(map_of xs \<circ> \<sigma>) x = map_of (map ?f xs) x" for x
```
```  1015     by (induct xs) (auto simp: inv_f_f surj_f_inv_f)
```
```  1016 qed
```
```  1017
```
```  1018
```
```  1019 subsection \<open>More lemmas about permutations\<close>
```
```  1020
```
```  1021 text \<open>The following few lemmas were contributed by Lukas Bulwahn.\<close>
```
```  1022
```
```  1023 lemma count_image_mset_eq_card_vimage:
```
```  1024   assumes "finite A"
```
```  1025   shows "count (image_mset f (mset_set A)) b = card {a \<in> A. f a = b}"
```
```  1026   using assms
```
```  1027 proof (induct A)
```
```  1028   case empty
```
```  1029   show ?case by simp
```
```  1030 next
```
```  1031   case (insert x F)
```
```  1032   show ?case
```
```  1033   proof (cases "f x = b")
```
```  1034     case True
```
```  1035     with insert.hyps
```
```  1036     have "count (image_mset f (mset_set (insert x F))) b = Suc (card {a \<in> F. f a = f x})"
```
```  1037       by auto
```
```  1038     also from insert.hyps(1,2) have "\<dots> = card (insert x {a \<in> F. f a = f x})"
```
```  1039       by simp
```
```  1040     also from \<open>f x = b\<close> have "card (insert x {a \<in> F. f a = f x}) = card {a \<in> insert x F. f a = b}"
```
```  1041       by (auto intro: arg_cong[where f="card"])
```
```  1042     finally show ?thesis
```
```  1043       using insert by auto
```
```  1044   next
```
```  1045     case False
```
```  1046     then have "{a \<in> F. f a = b} = {a \<in> insert x F. f a = b}"
```
```  1047       by auto
```
```  1048     with insert False show ?thesis
```
```  1049       by simp
```
```  1050   qed
```
```  1051 qed
```
```  1052
```
```  1053 \<comment> \<open>Prove \<open>image_mset_eq_implies_permutes\<close> ...\<close>
```
```  1054 lemma image_mset_eq_implies_permutes:
```
```  1055   fixes f :: "'a \<Rightarrow> 'b"
```
```  1056   assumes "finite A"
```
```  1057     and mset_eq: "image_mset f (mset_set A) = image_mset f' (mset_set A)"
```
```  1058   obtains p where "p permutes A" and "\<forall>x\<in>A. f x = f' (p x)"
```
```  1059 proof -
```
```  1060   from \<open>finite A\<close> have [simp]: "finite {a \<in> A. f a = (b::'b)}" for f b by auto
```
```  1061   have "f ` A = f' ` A"
```
```  1062   proof -
```
```  1063     from \<open>finite A\<close> have "f ` A = f ` (set_mset (mset_set A))"
```
```  1064       by simp
```
```  1065     also have "\<dots> = f' ` set_mset (mset_set A)"
```
```  1066       by (metis mset_eq multiset.set_map)
```
```  1067     also from \<open>finite A\<close> have "\<dots> = f' ` A"
```
```  1068       by simp
```
```  1069     finally show ?thesis .
```
```  1070   qed
```
```  1071   have "\<forall>b\<in>(f ` A). \<exists>p. bij_betw p {a \<in> A. f a = b} {a \<in> A. f' a = b}"
```
```  1072   proof
```
```  1073     fix b
```
```  1074     from mset_eq have "count (image_mset f (mset_set A)) b = count (image_mset f' (mset_set A)) b"
```
```  1075       by simp
```
```  1076     with \<open>finite A\<close> have "card {a \<in> A. f a = b} = card {a \<in> A. f' a = b}"
```
```  1077       by (simp add: count_image_mset_eq_card_vimage)
```
```  1078     then show "\<exists>p. bij_betw p {a\<in>A. f a = b} {a \<in> A. f' a = b}"
```
```  1079       by (intro finite_same_card_bij) simp_all
```
```  1080   qed
```
```  1081   then have "\<exists>p. \<forall>b\<in>f ` A. bij_betw (p b) {a \<in> A. f a = b} {a \<in> A. f' a = b}"
```
```  1082     by (rule bchoice)
```
```  1083   then obtain p where p: "\<forall>b\<in>f ` A. bij_betw (p b) {a \<in> A. f a = b} {a \<in> A. f' a = b}" ..
```
```  1084   define p' where "p' = (\<lambda>a. if a \<in> A then p (f a) a else a)"
```
```  1085   have "p' permutes A"
```
```  1086   proof (rule bij_imp_permutes)
```
```  1087     have "disjoint_family_on (\<lambda>i. {a \<in> A. f' a = i}) (f ` A)"
```
```  1088       by (auto simp: disjoint_family_on_def)
```
```  1089     moreover
```
```  1090     have "bij_betw (\<lambda>a. p (f a) a) {a \<in> A. f a = b} {a \<in> A. f' a = b}" if "b \<in> f ` A" for b
```
```  1091       using p that by (subst bij_betw_cong[where g="p b"]) auto
```
```  1092     ultimately
```
```  1093     have "bij_betw (\<lambda>a. p (f a) a) (\<Union>b\<in>f ` A. {a \<in> A. f a = b}) (\<Union>b\<in>f ` A. {a \<in> A. f' a = b})"
```
```  1094       by (rule bij_betw_UNION_disjoint)
```
```  1095     moreover have "(\<Union>b\<in>f ` A. {a \<in> A. f a = b}) = A"
```
```  1096       by auto
```
```  1097     moreover from \<open>f ` A = f' ` A\<close> have "(\<Union>b\<in>f ` A. {a \<in> A. f' a = b}) = A"
```
```  1098       by auto
```
```  1099     ultimately show "bij_betw p' A A"
```
```  1100       unfolding p'_def by (subst bij_betw_cong[where g="(\<lambda>a. p (f a) a)"]) auto
```
```  1101   next
```
```  1102     show "\<And>x. x \<notin> A \<Longrightarrow> p' x = x"
```
```  1103       by (simp add: p'_def)
```
```  1104   qed
```
```  1105   moreover from p have "\<forall>x\<in>A. f x = f' (p' x)"
```
```  1106     unfolding p'_def using bij_betwE by fastforce
```
```  1107   ultimately show ?thesis ..
```
```  1108 qed
```
```  1109
```
```  1110 lemma mset_set_upto_eq_mset_upto: "mset_set {..<n} = mset [0..<n]"
```
```  1111   by (induct n) (auto simp: add.commute lessThan_Suc)
```
```  1112
```
```  1113 \<comment> \<open>... and derive the existing property:\<close>
```
```  1114 lemma mset_eq_permutation:
```
```  1115   fixes xs ys :: "'a list"
```
```  1116   assumes mset_eq: "mset xs = mset ys"
```
```  1117   obtains p where "p permutes {..<length ys}" "permute_list p ys = xs"
```
```  1118 proof -
```
```  1119   from mset_eq have length_eq: "length xs = length ys"
```
```  1120     by (rule mset_eq_length)
```
```  1121   have "mset_set {..<length ys} = mset [0..<length ys]"
```
```  1122     by (rule mset_set_upto_eq_mset_upto)
```
```  1123   with mset_eq length_eq have "image_mset (\<lambda>i. xs ! i) (mset_set {..<length ys}) =
```
```  1124     image_mset (\<lambda>i. ys ! i) (mset_set {..<length ys})"
```
```  1125     by (metis map_nth mset_map)
```
```  1126   from image_mset_eq_implies_permutes[OF _ this]
```
```  1127   obtain p where p: "p permutes {..<length ys}" and "\<forall>i\<in>{..<length ys}. xs ! i = ys ! (p i)"
```
```  1128     by auto
```
```  1129   with length_eq have "permute_list p ys = xs"
```
```  1130     by (auto intro!: nth_equalityI simp: permute_list_nth)
```
```  1131   with p show thesis ..
```
```  1132 qed
```
```  1133
```
```  1134 lemma permutes_natset_le:
```
```  1135   fixes S :: "'a::wellorder set"
```
```  1136   assumes "p permutes S"
```
```  1137     and "\<forall>i \<in> S. p i \<le> i"
```
```  1138   shows "p = id"
```
```  1139 proof -
```
```  1140   have "p n = n" for n
```
```  1141     using assms
```
```  1142   proof (induct n arbitrary: S rule: less_induct)
```
```  1143     case (less n)
```
```  1144     show ?case
```
```  1145     proof (cases "n \<in> S")
```
```  1146       case False
```
```  1147       with less(2) show ?thesis
```
```  1148         unfolding permutes_def by metis
```
```  1149     next
```
```  1150       case True
```
```  1151       with less(3) have "p n < n \<or> p n = n"
```
```  1152         by auto
```
```  1153       then show ?thesis
```
```  1154       proof
```
```  1155         assume "p n < n"
```
```  1156         with less have "p (p n) = p n"
```
```  1157           by metis
```
```  1158         with permutes_inj[OF less(2)] have "p n = n"
```
```  1159           unfolding inj_def by blast
```
```  1160         with \<open>p n < n\<close> have False
```
```  1161           by simp
```
```  1162         then show ?thesis ..
```
```  1163       qed
```
```  1164     qed
```
```  1165   qed
```
```  1166   then show ?thesis by (auto simp: fun_eq_iff)
```
```  1167 qed
```
```  1168
```
```  1169 lemma permutes_natset_ge:
```
```  1170   fixes S :: "'a::wellorder set"
```
```  1171   assumes p: "p permutes S"
```
```  1172     and le: "\<forall>i \<in> S. p i \<ge> i"
```
```  1173   shows "p = id"
```
```  1174 proof -
```
```  1175   have "i \<ge> inv p i" if "i \<in> S" for i
```
```  1176   proof -
```
```  1177     from that permutes_in_image[OF permutes_inv[OF p]] have "inv p i \<in> S"
```
```  1178       by simp
```
```  1179     with le have "p (inv p i) \<ge> inv p i"
```
```  1180       by blast
```
```  1181     with permutes_inverses[OF p] show ?thesis
```
```  1182       by simp
```
```  1183   qed
```
```  1184   then have "\<forall>i\<in>S. inv p i \<le> i"
```
```  1185     by blast
```
```  1186   from permutes_natset_le[OF permutes_inv[OF p] this] have "inv p = inv id"
```
```  1187     by simp
```
```  1188   then show ?thesis
```
```  1189     apply (subst permutes_inv_inv[OF p, symmetric])
```
```  1190     apply (rule inv_unique_comp)
```
```  1191      apply simp_all
```
```  1192     done
```
```  1193 qed
```
```  1194
```
```  1195 lemma image_inverse_permutations: "{inv p |p. p permutes S} = {p. p permutes S}"
```
```  1196   apply (rule set_eqI)
```
```  1197   apply auto
```
```  1198   using permutes_inv_inv permutes_inv
```
```  1199    apply auto
```
```  1200   apply (rule_tac x="inv x" in exI)
```
```  1201   apply auto
```
```  1202   done
```
```  1203
```
```  1204 lemma image_compose_permutations_left:
```
```  1205   assumes "q permutes S"
```
```  1206   shows "{q \<circ> p |p. p permutes S} = {p. p permutes S}"
```
```  1207   apply (rule set_eqI)
```
```  1208   apply auto
```
```  1209    apply (rule permutes_compose)
```
```  1210   using assms
```
```  1211     apply auto
```
```  1212   apply (rule_tac x = "inv q \<circ> x" in exI)
```
```  1213   apply (simp add: o_assoc permutes_inv permutes_compose permutes_inv_o)
```
```  1214   done
```
```  1215
```
```  1216 lemma image_compose_permutations_right:
```
```  1217   assumes "q permutes S"
```
```  1218   shows "{p \<circ> q | p. p permutes S} = {p . p permutes S}"
```
```  1219   apply (rule set_eqI)
```
```  1220   apply auto
```
```  1221    apply (rule permutes_compose)
```
```  1222   using assms
```
```  1223     apply auto
```
```  1224   apply (rule_tac x = "x \<circ> inv q" in exI)
```
```  1225   apply (simp add: o_assoc permutes_inv permutes_compose permutes_inv_o comp_assoc)
```
```  1226   done
```
```  1227
```
```  1228 lemma permutes_in_seg: "p permutes {1 ..n} \<Longrightarrow> i \<in> {1..n} \<Longrightarrow> 1 \<le> p i \<and> p i \<le> n"
```
```  1229   by (simp add: permutes_def) metis
```
```  1230
```
```  1231 lemma sum_permutations_inverse: "sum f {p. p permutes S} = sum (\<lambda>p. f(inv p)) {p. p permutes S}"
```
```  1232   (is "?lhs = ?rhs")
```
```  1233 proof -
```
```  1234   let ?S = "{p . p permutes S}"
```
```  1235   have *: "inj_on inv ?S"
```
```  1236   proof (auto simp add: inj_on_def)
```
```  1237     fix q r
```
```  1238     assume q: "q permutes S"
```
```  1239       and r: "r permutes S"
```
```  1240       and qr: "inv q = inv r"
```
```  1241     then have "inv (inv q) = inv (inv r)"
```
```  1242       by simp
```
```  1243     with permutes_inv_inv[OF q] permutes_inv_inv[OF r] show "q = r"
```
```  1244       by metis
```
```  1245   qed
```
```  1246   have **: "inv ` ?S = ?S"
```
```  1247     using image_inverse_permutations by blast
```
```  1248   have ***: "?rhs = sum (f \<circ> inv) ?S"
```
```  1249     by (simp add: o_def)
```
```  1250   from sum.reindex[OF *, of f] show ?thesis
```
```  1251     by (simp only: ** ***)
```
```  1252 qed
```
```  1253
```
```  1254 lemma setum_permutations_compose_left:
```
```  1255   assumes q: "q permutes S"
```
```  1256   shows "sum f {p. p permutes S} = sum (\<lambda>p. f(q \<circ> p)) {p. p permutes S}"
```
```  1257   (is "?lhs = ?rhs")
```
```  1258 proof -
```
```  1259   let ?S = "{p. p permutes S}"
```
```  1260   have *: "?rhs = sum (f \<circ> ((\<circ>) q)) ?S"
```
```  1261     by (simp add: o_def)
```
```  1262   have **: "inj_on ((\<circ>) q) ?S"
```
```  1263   proof (auto simp add: inj_on_def)
```
```  1264     fix p r
```
```  1265     assume "p permutes S"
```
```  1266       and r: "r permutes S"
```
```  1267       and rp: "q \<circ> p = q \<circ> r"
```
```  1268     then have "inv q \<circ> q \<circ> p = inv q \<circ> q \<circ> r"
```
```  1269       by (simp add: comp_assoc)
```
```  1270     with permutes_inj[OF q, unfolded inj_iff] show "p = r"
```
```  1271       by simp
```
```  1272   qed
```
```  1273   have "((\<circ>) q) ` ?S = ?S"
```
```  1274     using image_compose_permutations_left[OF q] by auto
```
```  1275   with * sum.reindex[OF **, of f] show ?thesis
```
```  1276     by (simp only:)
```
```  1277 qed
```
```  1278
```
```  1279 lemma sum_permutations_compose_right:
```
```  1280   assumes q: "q permutes S"
```
```  1281   shows "sum f {p. p permutes S} = sum (\<lambda>p. f(p \<circ> q)) {p. p permutes S}"
```
```  1282   (is "?lhs = ?rhs")
```
```  1283 proof -
```
```  1284   let ?S = "{p. p permutes S}"
```
```  1285   have *: "?rhs = sum (f \<circ> (\<lambda>p. p \<circ> q)) ?S"
```
```  1286     by (simp add: o_def)
```
```  1287   have **: "inj_on (\<lambda>p. p \<circ> q) ?S"
```
```  1288   proof (auto simp add: inj_on_def)
```
```  1289     fix p r
```
```  1290     assume "p permutes S"
```
```  1291       and r: "r permutes S"
```
```  1292       and rp: "p \<circ> q = r \<circ> q"
```
```  1293     then have "p \<circ> (q \<circ> inv q) = r \<circ> (q \<circ> inv q)"
```
```  1294       by (simp add: o_assoc)
```
```  1295     with permutes_surj[OF q, unfolded surj_iff] show "p = r"
```
```  1296       by simp
```
```  1297   qed
```
```  1298   from image_compose_permutations_right[OF q] have "(\<lambda>p. p \<circ> q) ` ?S = ?S"
```
```  1299     by auto
```
```  1300   with * sum.reindex[OF **, of f] show ?thesis
```
```  1301     by (simp only:)
```
```  1302 qed
```
```  1303
```
```  1304
```
```  1305 subsection \<open>Sum over a set of permutations (could generalize to iteration)\<close>
```
```  1306
```
```  1307 lemma sum_over_permutations_insert:
```
```  1308   assumes fS: "finite S"
```
```  1309     and aS: "a \<notin> S"
```
```  1310   shows "sum f {p. p permutes (insert a S)} =
```
```  1311     sum (\<lambda>b. sum (\<lambda>q. f (Fun.swap a b id \<circ> q)) {p. p permutes S}) (insert a S)"
```
```  1312 proof -
```
```  1313   have *: "\<And>f a b. (\<lambda>(b, p). f (Fun.swap a b id \<circ> p)) = f \<circ> (\<lambda>(b,p). Fun.swap a b id \<circ> p)"
```
```  1314     by (simp add: fun_eq_iff)
```
```  1315   have **: "\<And>P Q. {(a, b). a \<in> P \<and> b \<in> Q} = P \<times> Q"
```
```  1316     by blast
```
```  1317   show ?thesis
```
```  1318     unfolding * ** sum.cartesian_product permutes_insert
```
```  1319   proof (rule sum.reindex)
```
```  1320     let ?f = "(\<lambda>(b, y). Fun.swap a b id \<circ> y)"
```
```  1321     let ?P = "{p. p permutes S}"
```
```  1322     {
```
```  1323       fix b c p q
```
```  1324       assume b: "b \<in> insert a S"
```
```  1325       assume c: "c \<in> insert a S"
```
```  1326       assume p: "p permutes S"
```
```  1327       assume q: "q permutes S"
```
```  1328       assume eq: "Fun.swap a b id \<circ> p = Fun.swap a c id \<circ> q"
```
```  1329       from p q aS have pa: "p a = a" and qa: "q a = a"
```
```  1330         unfolding permutes_def by metis+
```
```  1331       from eq have "(Fun.swap a b id \<circ> p) a  = (Fun.swap a c id \<circ> q) a"
```
```  1332         by simp
```
```  1333       then have bc: "b = c"
```
```  1334         by (simp add: permutes_def pa qa o_def fun_upd_def Fun.swap_def id_def
```
```  1335             cong del: if_weak_cong split: if_split_asm)
```
```  1336       from eq[unfolded bc] have "(\<lambda>p. Fun.swap a c id \<circ> p) (Fun.swap a c id \<circ> p) =
```
```  1337         (\<lambda>p. Fun.swap a c id \<circ> p) (Fun.swap a c id \<circ> q)" by simp
```
```  1338       then have "p = q"
```
```  1339         unfolding o_assoc swap_id_idempotent by simp
```
```  1340       with bc have "b = c \<and> p = q"
```
```  1341         by blast
```
```  1342     }
```
```  1343     then show "inj_on ?f (insert a S \<times> ?P)"
```
```  1344       unfolding inj_on_def by clarify metis
```
```  1345   qed
```
```  1346 qed
```
```  1347
```
```  1348
```
```  1349 subsection \<open>Constructing permutations from association lists\<close>
```
```  1350
```
```  1351 definition list_permutes :: "('a \<times> 'a) list \<Rightarrow> 'a set \<Rightarrow> bool"
```
```  1352   where "list_permutes xs A \<longleftrightarrow>
```
```  1353     set (map fst xs) \<subseteq> A \<and>
```
```  1354     set (map snd xs) = set (map fst xs) \<and>
```
```  1355     distinct (map fst xs) \<and>
```
```  1356     distinct (map snd xs)"
```
```  1357
```
```  1358 lemma list_permutesI [simp]:
```
```  1359   assumes "set (map fst xs) \<subseteq> A" "set (map snd xs) = set (map fst xs)" "distinct (map fst xs)"
```
```  1360   shows "list_permutes xs A"
```
```  1361 proof -
```
```  1362   from assms(2,3) have "distinct (map snd xs)"
```
```  1363     by (intro card_distinct) (simp_all add: distinct_card del: set_map)
```
```  1364   with assms show ?thesis
```
```  1365     by (simp add: list_permutes_def)
```
```  1366 qed
```
```  1367
```
```  1368 definition permutation_of_list :: "('a \<times> 'a) list \<Rightarrow> 'a \<Rightarrow> 'a"
```
```  1369   where "permutation_of_list xs x = (case map_of xs x of None \<Rightarrow> x | Some y \<Rightarrow> y)"
```
```  1370
```
```  1371 lemma permutation_of_list_Cons:
```
```  1372   "permutation_of_list ((x, y) # xs) x' = (if x = x' then y else permutation_of_list xs x')"
```
```  1373   by (simp add: permutation_of_list_def)
```
```  1374
```
```  1375 fun inverse_permutation_of_list :: "('a \<times> 'a) list \<Rightarrow> 'a \<Rightarrow> 'a"
```
```  1376   where
```
```  1377     "inverse_permutation_of_list [] x = x"
```
```  1378   | "inverse_permutation_of_list ((y, x') # xs) x =
```
```  1379       (if x = x' then y else inverse_permutation_of_list xs x)"
```
```  1380
```
```  1381 declare inverse_permutation_of_list.simps [simp del]
```
```  1382
```
```  1383 lemma inj_on_map_of:
```
```  1384   assumes "distinct (map snd xs)"
```
```  1385   shows "inj_on (map_of xs) (set (map fst xs))"
```
```  1386 proof (rule inj_onI)
```
```  1387   fix x y
```
```  1388   assume xy: "x \<in> set (map fst xs)" "y \<in> set (map fst xs)"
```
```  1389   assume eq: "map_of xs x = map_of xs y"
```
```  1390   from xy obtain x' y' where x'y': "map_of xs x = Some x'" "map_of xs y = Some y'"
```
```  1391     by (cases "map_of xs x"; cases "map_of xs y") (simp_all add: map_of_eq_None_iff)
```
```  1392   moreover from x'y' have *: "(x, x') \<in> set xs" "(y, y') \<in> set xs"
```
```  1393     by (force dest: map_of_SomeD)+
```
```  1394   moreover from * eq x'y' have "x' = y'"
```
```  1395     by simp
```
```  1396   ultimately show "x = y"
```
```  1397     using assms by (force simp: distinct_map dest: inj_onD[of _ _ "(x,x')" "(y,y')"])
```
```  1398 qed
```
```  1399
```
```  1400 lemma inj_on_the: "None \<notin> A \<Longrightarrow> inj_on the A"
```
```  1401   by (auto simp: inj_on_def option.the_def split: option.splits)
```
```  1402
```
```  1403 lemma inj_on_map_of':
```
```  1404   assumes "distinct (map snd xs)"
```
```  1405   shows "inj_on (the \<circ> map_of xs) (set (map fst xs))"
```
```  1406   by (intro comp_inj_on inj_on_map_of assms inj_on_the)
```
```  1407     (force simp: eq_commute[of None] map_of_eq_None_iff)
```
```  1408
```
```  1409 lemma image_map_of:
```
```  1410   assumes "distinct (map fst xs)"
```
```  1411   shows "map_of xs ` set (map fst xs) = Some ` set (map snd xs)"
```
```  1412   using assms by (auto simp: rev_image_eqI)
```
```  1413
```
```  1414 lemma the_Some_image [simp]: "the ` Some ` A = A"
```
```  1415   by (subst image_image) simp
```
```  1416
```
```  1417 lemma image_map_of':
```
```  1418   assumes "distinct (map fst xs)"
```
```  1419   shows "(the \<circ> map_of xs) ` set (map fst xs) = set (map snd xs)"
```
```  1420   by (simp only: image_comp [symmetric] image_map_of assms the_Some_image)
```
```  1421
```
```  1422 lemma permutation_of_list_permutes [simp]:
```
```  1423   assumes "list_permutes xs A"
```
```  1424   shows "permutation_of_list xs permutes A"
```
```  1425     (is "?f permutes _")
```
```  1426 proof (rule permutes_subset[OF bij_imp_permutes])
```
```  1427   from assms show "set (map fst xs) \<subseteq> A"
```
```  1428     by (simp add: list_permutes_def)
```
```  1429   from assms have "inj_on (the \<circ> map_of xs) (set (map fst xs))" (is ?P)
```
```  1430     by (intro inj_on_map_of') (simp_all add: list_permutes_def)
```
```  1431   also have "?P \<longleftrightarrow> inj_on ?f (set (map fst xs))"
```
```  1432     by (intro inj_on_cong)
```
```  1433       (auto simp: permutation_of_list_def map_of_eq_None_iff split: option.splits)
```
```  1434   finally have "bij_betw ?f (set (map fst xs)) (?f ` set (map fst xs))"
```
```  1435     by (rule inj_on_imp_bij_betw)
```
```  1436   also from assms have "?f ` set (map fst xs) = (the \<circ> map_of xs) ` set (map fst xs)"
```
```  1437     by (intro image_cong refl)
```
```  1438       (auto simp: permutation_of_list_def map_of_eq_None_iff split: option.splits)
```
```  1439   also from assms have "\<dots> = set (map fst xs)"
```
```  1440     by (subst image_map_of') (simp_all add: list_permutes_def)
```
```  1441   finally show "bij_betw ?f (set (map fst xs)) (set (map fst xs))" .
```
```  1442 qed (force simp: permutation_of_list_def dest!: map_of_SomeD split: option.splits)+
```
```  1443
```
```  1444 lemma eval_permutation_of_list [simp]:
```
```  1445   "permutation_of_list [] x = x"
```
```  1446   "x = x' \<Longrightarrow> permutation_of_list ((x',y)#xs) x = y"
```
```  1447   "x \<noteq> x' \<Longrightarrow> permutation_of_list ((x',y')#xs) x = permutation_of_list xs x"
```
```  1448   by (simp_all add: permutation_of_list_def)
```
```  1449
```
```  1450 lemma eval_inverse_permutation_of_list [simp]:
```
```  1451   "inverse_permutation_of_list [] x = x"
```
```  1452   "x = x' \<Longrightarrow> inverse_permutation_of_list ((y,x')#xs) x = y"
```
```  1453   "x \<noteq> x' \<Longrightarrow> inverse_permutation_of_list ((y',x')#xs) x = inverse_permutation_of_list xs x"
```
```  1454   by (simp_all add: inverse_permutation_of_list.simps)
```
```  1455
```
```  1456 lemma permutation_of_list_id: "x \<notin> set (map fst xs) \<Longrightarrow> permutation_of_list xs x = x"
```
```  1457   by (induct xs) (auto simp: permutation_of_list_Cons)
```
```  1458
```
```  1459 lemma permutation_of_list_unique':
```
```  1460   "distinct (map fst xs) \<Longrightarrow> (x, y) \<in> set xs \<Longrightarrow> permutation_of_list xs x = y"
```
```  1461   by (induct xs) (force simp: permutation_of_list_Cons)+
```
```  1462
```
```  1463 lemma permutation_of_list_unique:
```
```  1464   "list_permutes xs A \<Longrightarrow> (x, y) \<in> set xs \<Longrightarrow> permutation_of_list xs x = y"
```
```  1465   by (intro permutation_of_list_unique') (simp_all add: list_permutes_def)
```
```  1466
```
```  1467 lemma inverse_permutation_of_list_id:
```
```  1468   "x \<notin> set (map snd xs) \<Longrightarrow> inverse_permutation_of_list xs x = x"
```
```  1469   by (induct xs) auto
```
```  1470
```
```  1471 lemma inverse_permutation_of_list_unique':
```
```  1472   "distinct (map snd xs) \<Longrightarrow> (x, y) \<in> set xs \<Longrightarrow> inverse_permutation_of_list xs y = x"
```
```  1473   by (induct xs) (force simp: inverse_permutation_of_list.simps)+
```
```  1474
```
```  1475 lemma inverse_permutation_of_list_unique:
```
```  1476   "list_permutes xs A \<Longrightarrow> (x,y) \<in> set xs \<Longrightarrow> inverse_permutation_of_list xs y = x"
```
```  1477   by (intro inverse_permutation_of_list_unique') (simp_all add: list_permutes_def)
```
```  1478
```
```  1479 lemma inverse_permutation_of_list_correct:
```
```  1480   fixes A :: "'a set"
```
```  1481   assumes "list_permutes xs A"
```
```  1482   shows "inverse_permutation_of_list xs = inv (permutation_of_list xs)"
```
```  1483 proof (rule ext, rule sym, subst permutes_inv_eq)
```
```  1484   from assms show "permutation_of_list xs permutes A"
```
```  1485     by simp
```
```  1486   show "permutation_of_list xs (inverse_permutation_of_list xs x) = x" for x
```
```  1487   proof (cases "x \<in> set (map snd xs)")
```
```  1488     case True
```
```  1489     then obtain y where "(y, x) \<in> set xs" by auto
```
```  1490     with assms show ?thesis
```
```  1491       by (simp add: inverse_permutation_of_list_unique permutation_of_list_unique)
```
```  1492   next
```
```  1493     case False
```
```  1494     with assms show ?thesis
```
```  1495       by (auto simp: list_permutes_def inverse_permutation_of_list_id permutation_of_list_id)
```
```  1496   qed
```
```  1497 qed
```
```  1498
```
```  1499 end
```