src/Pure/library.ML
author wenzelm
Wed Aug 13 20:57:20 2008 +0200 (2008-08-13)
changeset 27850 49503146b853
parent 26449 283107142592
child 28022 2cc19d1d4a42
permissions -rw-r--r--
removed obsolete untabify (superceded by SymbolPos.tabify_content);
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, orders, current directory, misc.
     8 
     9 See also General/basics.ML for the most fundamental concepts.
    10 *)
    11 
    12 infix 1 |>>>
    13 infix 2 ?
    14 infix 3 o oo ooo oooo
    15 infix 4 ~~ upto downto
    16 infix orf andf \ \\ mem mem_int mem_string union union_int
    17   union_string inter inter_int inter_string subset subset_int subset_string
    18 
    19 signature BASIC_LIBRARY =
    20 sig
    21   (*functions*)
    22   val undefined: 'a -> 'b
    23   val I: 'a -> 'a
    24   val K: 'a -> 'b -> 'a
    25   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    26   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    27   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    28   val ? : bool * ('a -> 'a) -> 'a -> 'a
    29   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    30   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    31   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    32   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    33 
    34   (*errors*)
    35   exception SYS_ERROR of string
    36   val sys_error: string -> 'a
    37   exception ERROR of string
    38   val error: string -> 'a
    39   val cat_error: string -> string -> 'a
    40   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    41 
    42   (*pairs*)
    43   val pair: 'a -> 'b -> 'a * 'b
    44   val rpair: 'a -> 'b -> 'b * 'a
    45   val fst: 'a * 'b -> 'a
    46   val snd: 'a * 'b -> 'b
    47   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    48   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    49   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    50   val swap: 'a * 'b -> 'b * 'a
    51   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    52   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    53   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    54 
    55   (*booleans*)
    56   val equal: ''a -> ''a -> bool
    57   val not_equal: ''a -> ''a -> bool
    58   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    59   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    60   val exists: ('a -> bool) -> 'a list -> bool
    61   val forall: ('a -> bool) -> 'a list -> bool
    62   val set: bool ref -> bool
    63   val reset: bool ref -> bool
    64   val toggle: bool ref -> bool
    65   val change: 'a ref -> ('a -> 'a) -> unit
    66   val setmp_noncritical: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    67   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    68   val setmp_thread_data: 'a Universal.tag -> 'a -> 'a -> ('b -> 'c) -> 'b -> 'c
    69 
    70   (*lists*)
    71   exception UnequalLengths
    72   val single: 'a -> 'a list
    73   val the_single: 'a list -> 'a
    74   val singleton: ('a list -> 'b list) -> 'a -> 'b
    75   val yield_singleton: ('a list -> 'c -> 'b list * 'c) -> 'a -> 'c -> 'b * 'c
    76   val apply: ('a -> 'a) list -> 'a -> 'a
    77   val perhaps_apply: ('a -> 'a option) list -> 'a -> 'a option
    78   val perhaps_loop: ('a -> 'a option) -> 'a -> 'a option
    79   val foldl1: ('a * 'a -> 'a) -> 'a list -> 'a
    80   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    81   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    82   val flat: 'a list list -> 'a list
    83   val unflat: 'a list list -> 'b list -> 'b list list
    84   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
    85   val burrow_options: ('a list -> 'b list) -> 'a option list -> 'b option list
    86   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
    87   val maps: ('a -> 'b list) -> 'a list -> 'b list
    88   val filter: ('a -> bool) -> 'a list -> 'a list
    89   val filter_out: ('a -> bool) -> 'a list -> 'a list
    90   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
    91   val chop: int -> 'a list -> 'a list * 'a list
    92   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    93   val nth: 'a list -> int -> 'a
    94   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
    95   val nth_drop: int -> 'a list -> 'a list
    96   val nth_list: 'a list list -> int -> 'a list
    97   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
    98   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    99   val split_last: 'a list -> 'a list * 'a
   100   val find_index: ('a -> bool) -> 'a list -> int
   101   val find_index_eq: ''a -> ''a list -> int
   102   val find_first: ('a -> bool) -> 'a list -> 'a option
   103   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
   104   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   105   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   106   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   107   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   108   val zip_options: 'a list -> 'b option list -> ('a * 'b) list
   109   val ~~ : 'a list * 'b list -> ('a * 'b) list
   110   val map_split: ('a -> 'b * 'c) -> 'a list -> 'b list * 'c list
   111   val split_list: ('a * 'b) list -> 'a list * 'b list
   112   val map_product: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   113   val fold_product: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   114   val separate: 'a -> 'a list -> 'a list
   115   val surround: 'a -> 'a list -> 'a list
   116   val replicate: int -> 'a -> 'a list
   117   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   118   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   119   val chop_prefix: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list * ('a list * 'b list)
   120   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   121   val prefixes1: 'a list -> 'a list list
   122   val prefixes: 'a list -> 'a list list
   123   val suffixes1: 'a list -> 'a list list
   124   val suffixes: 'a list -> 'a list list
   125 
   126   (*integers*)
   127   val inc: int ref -> int
   128   val dec: int ref -> int
   129   val upto: int * int -> int list
   130   val downto: int * int -> int list
   131   val radixpand: int * int -> int list
   132   val radixstring: int * string * int -> string
   133   val string_of_int: int -> string
   134   val signed_string_of_int: int -> string
   135   val string_of_indexname: string * int -> string
   136   val read_radix_int: int -> string list -> int * string list
   137   val read_int: string list -> int * string list
   138   val oct_char: string -> string
   139 
   140   (*strings*)
   141   val nth_string: string -> int -> string
   142   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   143   val exists_string: (string -> bool) -> string -> bool
   144   val forall_string: (string -> bool) -> string -> bool
   145   val enclose: string -> string -> string -> string
   146   val unenclose: string -> string
   147   val quote: string -> string
   148   val space_implode: string -> string list -> string
   149   val commas: string list -> string
   150   val commas_quote: string list -> string
   151   val cat_lines: string list -> string
   152   val space_explode: string -> string -> string list
   153   val split_lines: string -> string list
   154   val prefix_lines: string -> string -> string
   155   val prefix: string -> string -> string
   156   val suffix: string -> string -> string
   157   val unprefix: string -> string -> string
   158   val unsuffix: string -> string -> string
   159   val replicate_string: int -> string -> string
   160   val translate_string: (string -> string) -> string -> string
   161   val multiply: 'a list -> 'a list list -> 'a list list
   162 
   163   (*lists as sets -- see also Pure/General/ord_list.ML*)
   164   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   165   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   166   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   167   val update: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   168   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   169   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   170   val mem: ''a * ''a list -> bool
   171   val mem_int: int * int list -> bool
   172   val mem_string: string * string list -> bool
   173   val union: ''a list * ''a list -> ''a list
   174   val union_int: int list * int list -> int list
   175   val union_string: string list * string list -> string list
   176   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   177   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   178   val inter: ''a list * ''a list -> ''a list
   179   val inter_int: int list * int list -> int list
   180   val inter_string: string list * string list -> string list
   181   val subset: ''a list * ''a list -> bool
   182   val subset_int: int list * int list -> bool
   183   val subset_string: string list * string list -> bool
   184   val eq_set: ''a list * ''a list -> bool
   185   val eq_set_string: string list * string list -> bool
   186   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   187   val gen_eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   188   val \ : ''a list * ''a -> ''a list
   189   val \\ : ''a list * ''a list -> ''a list
   190   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   191   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   192   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   193 
   194   (*lists as multisets*)
   195   val remove1: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   196   val submultiset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   197 
   198   (*orders*)
   199   val is_equal: order -> bool
   200   val rev_order: order -> order
   201   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   202   val bool_ord: bool * bool -> order
   203   val int_ord: int * int -> order
   204   val string_ord: string * string -> order
   205   val fast_string_ord: string * string -> order
   206   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   207   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   208   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   209   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   210   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   211   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   212   val sort_strings: string list -> string list
   213   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   214 
   215   (*random numbers*)
   216   exception RANDOM
   217   val random: unit -> real
   218   val random_range: int -> int -> int
   219   val one_of: 'a list -> 'a
   220   val frequency: (int * 'a) list -> 'a
   221 
   222   (*misc*)
   223   val divide_and_conquer: ('a -> 'a list * ('b list -> 'b)) -> 'a -> 'b
   224   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   225   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   226   val gensym: string -> string
   227   type stamp
   228   val stamp: unit -> stamp
   229   type serial
   230   val serial: unit -> serial
   231   val serial_string: unit -> string
   232   structure Object: sig type T end
   233 end;
   234 
   235 signature LIBRARY =
   236 sig
   237   include BASIC_LIBRARY
   238   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   239   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   240   val take: int * 'a list -> 'a list
   241   val drop: int * 'a list -> 'a list
   242   val last_elem: 'a list -> 'a
   243 end;
   244 
   245 structure Library: LIBRARY =
   246 struct
   247 
   248 (* functions *)
   249 
   250 fun undefined _ = raise Match;
   251 
   252 fun I x = x;
   253 fun K x = fn _ => x;
   254 fun curry f x y = f (x, y);
   255 fun uncurry f (x, y) = f x y;
   256 
   257 (*application and structured results -- old version*)
   258 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   259 
   260 (*conditional application*)
   261 fun b ? f = fn x => if b then f x else x;
   262 
   263 (*composition with multiple args*)
   264 fun (f oo g) x y = f (g x y);
   265 fun (f ooo g) x y z = f (g x y z);
   266 fun (f oooo g) x y z w = f (g x y z w);
   267 
   268 (*function exponentiation: f(...(f x)...) with n applications of f*)
   269 fun funpow (0: int) _ x = x
   270   | funpow n f x = funpow (n - 1) f (f x);
   271 
   272 
   273 (* errors *)
   274 
   275 exception SYS_ERROR of string;
   276 fun sys_error msg = raise SYS_ERROR msg;
   277 
   278 exception ERROR of string;
   279 fun error msg = raise ERROR msg;
   280 
   281 fun cat_error "" msg = error msg
   282   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   283 
   284 fun assert_all pred list msg =
   285   let
   286     fun ass [] = ()
   287       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   288   in ass list end;
   289 
   290 
   291 (* pairs *)
   292 
   293 fun pair x y = (x, y);
   294 fun rpair x y = (y, x);
   295 
   296 fun fst (x, y) = x;
   297 fun snd (x, y) = y;
   298 
   299 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   300 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   301 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   302 
   303 fun swap (x, y) = (y, x);
   304 
   305 fun apfst f (x, y) = (f x, y);
   306 fun apsnd f (x, y) = (x, f y);
   307 fun pairself f (x, y) = (f x, f y);
   308 
   309 
   310 (* booleans *)
   311 
   312 (*polymorphic equality*)
   313 fun equal x y = x = y;
   314 fun not_equal x y = x <> y;
   315 
   316 (*combining predicates*)
   317 fun p orf q = fn x => p x orelse q x;
   318 fun p andf q = fn x => p x andalso q x;
   319 
   320 val exists = List.exists;
   321 val forall = List.all;
   322 
   323 
   324 (* flags *)
   325 
   326 fun set flag = (flag := true; true);
   327 fun reset flag = (flag := false; false);
   328 fun toggle flag = (flag := not (! flag); ! flag);
   329 
   330 fun change r f = r := f (! r);
   331 
   332 (*temporarily set flag during execution*)
   333 fun setmp_noncritical flag value f x =
   334   uninterruptible (fn restore_attributes => fn () =>
   335     let
   336       val orig_value = ! flag;
   337       val _ = flag := value;
   338       val result = Exn.capture (restore_attributes f) x;
   339       val _ = flag := orig_value;
   340     in Exn.release result end) ();
   341 
   342 fun setmp flag value f x =
   343   NAMED_CRITICAL "setmp" (fn () => setmp_noncritical flag value f x);
   344 
   345 fun setmp_thread_data tag orig_data data f x =
   346   uninterruptible (fn restore_attributes => fn () =>
   347     let
   348       val _ = Multithreading.put_data (tag, data);
   349       val result = Exn.capture (restore_attributes f) x;
   350       val _ = Multithreading.put_data (tag, orig_data);
   351     in Exn.release result end) ();
   352 
   353 
   354 
   355 (** lists **)
   356 
   357 exception UnequalLengths;
   358 
   359 fun single x = [x];
   360 
   361 fun the_single [x] = x
   362   | the_single _ = raise Empty;
   363 
   364 fun singleton f x = the_single (f [x]);
   365 
   366 fun yield_singleton f x = f [x] #>> the_single;
   367 
   368 fun apply [] x = x
   369   | apply (f :: fs) x = apply fs (f x);
   370 
   371 fun perhaps_apply funs arg =
   372   let
   373     fun app [] res = res
   374       | app (f :: fs) (changed, x) =
   375           (case f x of
   376             NONE => app fs (changed, x)
   377           | SOME x' => app fs (true, x'));
   378   in (case app funs (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   379 
   380 fun perhaps_loop f arg =
   381   let
   382     fun loop (changed, x) =
   383       (case f x of
   384         NONE => (changed, x)
   385       | SOME x' => loop (true, x'));
   386   in (case loop (false, arg) of (false, _) => NONE | (true, arg') => SOME arg') end;
   387 
   388 
   389 (* fold -- old versions *)
   390 
   391 (*the following versions of fold are designed to fit nicely with infixes*)
   392 
   393 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   394     for operators that associate to the left (TAIL RECURSIVE)*)
   395 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   396   let fun itl (e, [])  = e
   397         | itl (e, a::l) = itl (f(e, a), l)
   398   in  itl end;
   399 
   400 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   401     for operators that associate to the right (not tail recursive)*)
   402 fun foldr f (l, e) =
   403   let fun itr [] = e
   404         | itr (a::l) = f(a, itr l)
   405   in  itr l  end;
   406 
   407 (*  (op @) [x1, ..., xn]  ===>  ((x1 @ x2) @ x3) ... @ xn
   408     for operators that associate to the left (TAIL RECURSIVE)*)
   409 fun foldl1 f [] = raise Empty
   410   | foldl1 f (x :: xs) = foldl f (x, xs);
   411 
   412 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   413     for n > 0, operators that associate to the right (not tail recursive)*)
   414 fun foldr1 f [] = raise Empty
   415   | foldr1 f l =
   416       let fun itr [x] = x
   417             | itr (x::l) = f(x, itr l)
   418       in  itr l  end;
   419 
   420 fun foldl_map f =
   421   let
   422     fun fold_aux (x, []) = (x, [])
   423       | fold_aux (x, y :: ys) =
   424           let
   425             val (x', y') = f (x, y);
   426             val (x'', ys') = fold_aux (x', ys);
   427           in (x'', y' :: ys') end;
   428   in fold_aux end;
   429 
   430 
   431 (* basic list functions *)
   432 
   433 fun eq_list eq (list1, list2) =
   434   let
   435     fun eq_lst (x :: xs, y :: ys) = eq (x, y) andalso eq_lst (xs, ys)
   436       | eq_lst _ = true;
   437   in length list1 = length list2 andalso eq_lst (list1, list2) end;
   438 
   439 fun maps f [] = []
   440   | maps f (x :: xs) = f x @ maps f xs;
   441 
   442 val filter = List.filter;
   443 fun filter_out f = filter (not o f);
   444 val map_filter = List.mapPartial;
   445 
   446 fun chop (0: int) xs = ([], xs)
   447   | chop _ [] = ([], [])
   448   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   449 
   450 (*take the first n elements from a list*)
   451 fun take (n: int, []) = []
   452   | take (n, x :: xs) =
   453       if n > 0 then x :: take (n - 1, xs) else [];
   454 
   455 (*drop the first n elements from a list*)
   456 fun drop (n: int, []) = []
   457   | drop (n, x :: xs) =
   458       if n > 0 then drop (n - 1, xs) else x :: xs;
   459 
   460 fun dropwhile P [] = []
   461   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   462 
   463 (*return nth element of a list, where 0 designates the first element;
   464   raise Subscript if list too short*)
   465 fun nth xs i = List.nth (xs, i);
   466 
   467 fun nth_list xss i = nth xss i handle Subscript => [];
   468 
   469 fun nth_map 0 f (x :: xs) = f x :: xs
   470   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   471   | nth_map (_: int) _ [] = raise Subscript;
   472 
   473 fun nth_drop n xs =
   474   List.take (xs, n) @ List.drop (xs, n + 1);
   475 
   476 fun map_index f =
   477   let
   478     fun mapp (_: int) [] = []
   479       | mapp i (x :: xs) = f (i, x) :: mapp (i + 1) xs
   480   in mapp 0 end;
   481 
   482 fun fold_index f =
   483   let
   484     fun fold_aux (_: int) [] y = y
   485       | fold_aux i (x :: xs) y = fold_aux (i + 1) xs (f (i, x) y);
   486   in fold_aux 0 end;
   487 
   488 val last_elem = List.last;
   489 
   490 (*rear decomposition*)
   491 fun split_last [] = raise Empty
   492   | split_last [x] = ([], x)
   493   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   494 
   495 (*find the position of an element in a list*)
   496 fun find_index pred =
   497   let fun find (_: int) [] = ~1
   498         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   499   in find 0 end;
   500 
   501 fun find_index_eq x = find_index (equal x);
   502 
   503 (*find first element satisfying predicate*)
   504 val find_first = List.find;
   505 
   506 (*get first element by lookup function*)
   507 fun get_first _ [] = NONE
   508   | get_first f (x :: xs) =
   509       (case f x of
   510         NONE => get_first f xs
   511       | some => some);
   512 
   513 fun get_index f =
   514   let
   515     fun get (_: int) [] = NONE
   516       | get i (x :: xs) =
   517           case f x
   518            of NONE => get (i + 1) xs
   519             | SOME y => SOME (i, y)
   520   in get 0 end;
   521 
   522 val flat = List.concat;
   523 
   524 fun unflat (xs :: xss) ys =
   525       let val (ps, qs) = chop (length xs) ys
   526       in ps :: unflat xss qs end
   527   | unflat [] [] = []
   528   | unflat _ _ = raise UnequalLengths;
   529 
   530 fun burrow f xss = unflat xss (f (flat xss));
   531 
   532 fun burrow_options f os = map (try hd) (burrow f (map the_list os));
   533 
   534 fun fold_burrow f xss s =
   535   apfst (unflat xss) (f (flat xss) s);
   536 
   537 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   538 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   539   | separate _ xs = xs;
   540 
   541 fun surround s (x :: xs) = s :: x :: surround s xs
   542   | surround s [] = [s];
   543 
   544 (*make the list [x, x, ..., x] of length n*)
   545 fun replicate (n: int) x =
   546   let fun rep (0, xs) = xs
   547         | rep (n, xs) = rep (n - 1, x :: xs)
   548   in
   549     if n < 0 then raise Subscript
   550     else rep (n, [])
   551   end;
   552 
   553 fun translate_string f = String.translate (f o String.str);
   554 
   555 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   556 fun multiply [] _ = []
   557   | multiply (x :: xs) yss = map (cons x) yss @ multiply xs yss;
   558 
   559 
   560 (* direct product *)
   561 
   562 fun map_product f _ [] = []
   563   | map_product f [] _ = []
   564   | map_product f (x :: xs) ys = map (f x) ys @ map_product f xs ys;
   565 
   566 fun fold_product f _ [] z = z
   567   | fold_product f [] _ z = z
   568   | fold_product f (x :: xs) ys z = z |> fold (f x) ys |> fold_product f xs ys;
   569 
   570 
   571 (* lists of pairs *)
   572 
   573 exception UnequalLengths;
   574 
   575 fun map2 _ [] [] = []
   576   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   577   | map2 _ _ _ = raise UnequalLengths;
   578 
   579 fun fold2 f [] [] z = z
   580   | fold2 f (x :: xs) (y :: ys) z = fold2 f xs ys (f x y z)
   581   | fold2 f _ _ _ = raise UnequalLengths;
   582 
   583 fun map_split f [] = ([], [])
   584   | map_split f (x :: xs) =
   585       let
   586         val (y, w) = f x;
   587         val (ys, ws) = map_split f xs;
   588       in (y :: ys, w :: ws) end;
   589 
   590 fun zip_options (x :: xs) (SOME y :: ys) = (x, y) :: zip_options xs ys
   591   | zip_options (_ :: xs) (NONE :: ys) = zip_options xs ys
   592   | zip_options _ [] = []
   593   | zip_options [] _ = raise UnequalLengths;
   594 
   595 (*combine two lists forming a list of pairs:
   596   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   597 fun [] ~~ [] = []
   598   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   599   | _ ~~ _ = raise UnequalLengths;
   600 
   601 (*inverse of ~~; the old 'split':
   602   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   603 val split_list = ListPair.unzip;
   604 
   605 
   606 (* prefixes, suffixes *)
   607 
   608 fun is_prefix _ [] _ = true
   609   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   610   | is_prefix eq _ _ = false;
   611 
   612 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   613    where xi is the first element that does not satisfy the predicate*)
   614 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   615   let fun take (rxs, []) = (rev rxs, [])
   616         | take (rxs, x :: xs) =
   617             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   618   in  take([], xs)  end;
   619 
   620 fun chop_prefix eq ([], ys) = ([], ([], ys))
   621   | chop_prefix eq (xs, []) = ([], (xs, []))
   622   | chop_prefix eq (xs as x :: xs', ys as y :: ys') =
   623       if eq (x, y) then
   624         let val (ps', xys'') = chop_prefix eq (xs', ys')
   625         in (x :: ps', xys'') end
   626       else ([], (xs, ys));
   627 
   628 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   629    where xi is the last element that does not satisfy the predicate*)
   630 fun take_suffix _ [] = ([], [])
   631   | take_suffix pred (x :: xs) =
   632       (case take_suffix pred xs of
   633         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   634       | (prfx, sffx) => (x :: prfx, sffx));
   635 
   636 fun prefixes1 [] = []
   637   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   638 
   639 fun prefixes xs = [] :: prefixes1 xs;
   640 
   641 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   642 fun suffixes xs = [] :: suffixes1 xs;
   643 
   644 
   645 
   646 (** integers **)
   647 
   648 fun inc i = (i := ! i + (1: int); ! i);
   649 fun dec i = (i := ! i - (1: int); ! i);
   650 
   651 
   652 (* lists of integers *)
   653 
   654 (*make the list [from, from + 1, ..., to]*)
   655 fun ((i: int) upto j) =
   656   if i > j then [] else i :: (i + 1 upto j);
   657 
   658 (*make the list [from, from - 1, ..., to]*)
   659 fun ((i: int) downto j) =
   660   if i < j then [] else i :: (i - 1 downto j);
   661 
   662 
   663 (* convert integers to strings *)
   664 
   665 (*expand the number in the given base;
   666   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   667 fun radixpand (base, num) : int list =
   668   let
   669     fun radix (n, tail) =
   670       if n < base then n :: tail
   671       else radix (n div base, (n mod base) :: tail)
   672   in radix (num, []) end;
   673 
   674 (*expands a number into a string of characters starting from "zerochar";
   675   example: radixstring (2, "0", 8) gives "1000"*)
   676 fun radixstring (base, zerochar, num) =
   677   let val offset = ord zerochar;
   678       fun chrof n = chr (offset + n)
   679   in implode (map chrof (radixpand (base, num))) end;
   680 
   681 
   682 val string_of_int = Int.toString;
   683 
   684 fun signed_string_of_int i =
   685   if i < 0 then "-" ^ string_of_int (~ i) else string_of_int i;
   686 
   687 fun string_of_indexname (a, 0) = a
   688   | string_of_indexname (a, i) = a ^ "_" ^ string_of_int i;
   689 
   690 
   691 (* read integers *)
   692 
   693 fun read_radix_int radix cs =
   694   let
   695     val zero = ord "0";
   696     val limit = zero + radix;
   697     fun scan (num, []) = (num, [])
   698       | scan (num, c :: cs) =
   699         if zero <= ord c andalso ord c < limit then
   700           scan (radix * num + (ord c - zero), cs)
   701         else (num, c :: cs);
   702   in scan (0, cs) end;
   703 
   704 val read_int = read_radix_int 10;
   705 
   706 fun oct_char s = chr (#1 (read_radix_int 8 (explode s)));
   707 
   708 
   709 
   710 (** strings **)
   711 
   712 (* functions tuned for strings, avoiding explode *)
   713 
   714 fun nth_string str i =
   715   (case try String.substring (str, i, 1) of
   716     SOME s => s
   717   | NONE => raise Subscript);
   718 
   719 fun fold_string f str x0 =
   720   let
   721     val n = size str;
   722     fun iter (x, i) =
   723       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   724   in iter (x0, 0) end;
   725 
   726 fun exists_string pred str =
   727   let
   728     val n = size str;
   729     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   730   in ex 0 end;
   731 
   732 fun forall_string pred = not o exists_string (not o pred);
   733 
   734 (*enclose in brackets*)
   735 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   736 fun unenclose str = String.substring (str, 1, size str - 2);
   737 
   738 (*simple quoting (does not escape special chars)*)
   739 val quote = enclose "\"" "\"";
   740 
   741 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   742 fun space_implode a bs = implode (separate a bs);
   743 
   744 val commas = space_implode ", ";
   745 val commas_quote = commas o map quote;
   746 
   747 (*concatenate messages, one per line, into a string*)
   748 val cat_lines = space_implode "\n";
   749 
   750 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   751 fun space_explode _ "" = []
   752   | space_explode sep s = String.fields (fn c => str c = sep) s;
   753 
   754 val split_lines = space_explode "\n";
   755 
   756 fun prefix_lines "" txt = txt
   757   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   758 
   759 fun prefix prfx s = prfx ^ s;
   760 fun suffix sffx s = s ^ sffx;
   761 
   762 fun unprefix prfx s =
   763   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   764   else raise Fail "unprefix";
   765 
   766 fun unsuffix sffx s =
   767   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   768   else raise Fail "unsuffix";
   769 
   770 fun replicate_string (0: int) _ = ""
   771   | replicate_string 1 a = a
   772   | replicate_string k a =
   773       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   774       else replicate_string (k div 2) (a ^ a) ^ a;
   775 
   776 
   777 
   778 (** lists as sets -- see also Pure/General/ord_list.ML **)
   779 
   780 (* canonical operations *)
   781 
   782 fun member eq list x =
   783   let
   784     fun memb [] = false
   785       | memb (y :: ys) = eq (x, y) orelse memb ys;
   786   in memb list end;
   787 
   788 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   789 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   790 fun update eq x xs = cons x (remove eq x xs);
   791 
   792 fun subtract eq = fold (remove eq);
   793 
   794 fun merge _ ([], ys) = ys
   795   | merge eq (xs, ys) = fold_rev (insert eq) ys xs;
   796 
   797 
   798 (* old-style infixes *)
   799 
   800 fun x mem xs = member (op =) xs x;
   801 fun (x: int) mem_int xs = member (op =) xs x;
   802 fun (x: string) mem_string xs = member (op =) xs x;
   803 
   804 (*union of sets represented as lists: no repetitions*)
   805 fun xs union [] = xs
   806   | [] union ys = ys
   807   | (x :: xs) union ys = xs union (insert (op =) x ys);
   808 
   809 (*union of sets, optimized version for ints*)
   810 fun (xs:int list) union_int [] = xs
   811   | [] union_int ys = ys
   812   | (x :: xs) union_int ys = xs union_int (insert (op =) x ys);
   813 
   814 (*union of sets, optimized version for strings*)
   815 fun (xs:string list) union_string [] = xs
   816   | [] union_string ys = ys
   817   | (x :: xs) union_string ys = xs union_string (insert (op =) x ys);
   818 
   819 (*generalized union*)
   820 fun gen_union eq (xs, []) = xs
   821   | gen_union eq ([], ys) = ys
   822   | gen_union eq (x :: xs, ys) = gen_union eq (xs, insert eq x ys);
   823 
   824 
   825 (*intersection*)
   826 fun [] inter ys = []
   827   | (x :: xs) inter ys =
   828       if x mem ys then x :: (xs inter ys) else xs inter ys;
   829 
   830 (*intersection, optimized version for ints*)
   831 fun ([]:int list) inter_int ys = []
   832   | (x :: xs) inter_int ys =
   833       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   834 
   835 (*intersection, optimized version for strings *)
   836 fun ([]:string list) inter_string ys = []
   837   | (x :: xs) inter_string ys =
   838       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   839 
   840 (*generalized intersection*)
   841 fun gen_inter eq ([], ys) = []
   842   | gen_inter eq (x::xs, ys) =
   843       if member eq ys x then x :: gen_inter eq (xs, ys)
   844       else gen_inter eq (xs, ys);
   845 
   846 
   847 (*subset*)
   848 fun [] subset ys = true
   849   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   850 
   851 (*subset, optimized version for ints*)
   852 fun ([]: int list) subset_int ys = true
   853   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   854 
   855 (*subset, optimized version for strings*)
   856 fun ([]: string list) subset_string ys = true
   857   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   858 
   859 (*set equality*)
   860 fun eq_set (xs, ys) =
   861   xs = ys orelse (xs subset ys andalso ys subset xs);
   862 
   863 (*set equality for strings*)
   864 fun eq_set_string ((xs: string list), ys) =
   865   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   866 
   867 fun gen_subset eq (xs, ys) = forall (member eq ys) xs;
   868 
   869 fun gen_eq_set eq (xs, ys) =
   870   eq_list eq (xs, ys) orelse
   871     (gen_subset eq (xs, ys) andalso gen_subset (eq o swap) (ys, xs));
   872 
   873 
   874 (*removing an element from a list WITHOUT duplicates*)
   875 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   876   | [] \ x = [];
   877 fun ys \\ xs = foldl (op \) (ys,xs);
   878 
   879 
   880 (*makes a list of the distinct members of the input; preserves order, takes
   881   first of equal elements*)
   882 fun distinct eq lst =
   883   let
   884     fun dist (rev_seen, []) = rev rev_seen
   885       | dist (rev_seen, x :: xs) =
   886           if member eq rev_seen x then dist (rev_seen, xs)
   887           else dist (x :: rev_seen, xs);
   888   in dist ([], lst) end;
   889 
   890 (*returns a list containing all repeated elements exactly once; preserves
   891   order, takes first of equal elements*)
   892 fun duplicates eq lst =
   893   let
   894     fun dups (rev_dups, []) = rev rev_dups
   895       | dups (rev_dups, x :: xs) =
   896           if member eq rev_dups x orelse not (member eq xs x) then
   897             dups (rev_dups, xs)
   898           else dups (x :: rev_dups, xs);
   899   in dups ([], lst) end;
   900 
   901 fun has_duplicates eq =
   902   let
   903     fun dups [] = false
   904       | dups (x :: xs) = member eq xs x orelse dups xs;
   905   in dups end;
   906 
   907 
   908 
   909 (** lists as multisets **)
   910 
   911 fun remove1 _ _ [] = raise Empty
   912   | remove1 eq y (x::xs) = if eq (y, x) then xs else x :: remove1 eq y xs;
   913 
   914 fun submultiset _ ([], _)  = true
   915   | submultiset eq (x :: xs, ys) = member eq ys x andalso submultiset eq (xs, remove1 eq x ys);
   916 
   917 
   918 
   919 (** orders **)
   920 
   921 fun is_equal EQUAL = true
   922   | is_equal _ = false;
   923 
   924 fun rev_order LESS = GREATER
   925   | rev_order EQUAL = EQUAL
   926   | rev_order GREATER = LESS;
   927 
   928 (*assume rel is a linear strict order*)
   929 fun make_ord rel (x, y) =
   930   if rel (x, y) then LESS
   931   else if rel (y, x) then GREATER
   932   else EQUAL;
   933 
   934 fun bool_ord (false, true) = LESS
   935   | bool_ord (true, false) = GREATER
   936   | bool_ord _ = EQUAL;
   937 
   938 val int_ord = Int.compare;
   939 val string_ord = String.compare;
   940 
   941 fun fast_string_ord (s1, s2) =
   942   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
   943 
   944 fun option_ord ord (SOME x, SOME y) = ord (x, y)
   945   | option_ord _ (NONE, NONE) = EQUAL
   946   | option_ord _ (NONE, SOME _) = LESS
   947   | option_ord _ (SOME _, NONE) = GREATER;
   948 
   949 (*lexicographic product*)
   950 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
   951   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
   952 
   953 (*dictionary order -- in general NOT well-founded!*)
   954 fun dict_ord elem_ord (x :: xs, y :: ys) =
   955       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
   956   | dict_ord _ ([], []) = EQUAL
   957   | dict_ord _ ([], _ :: _) = LESS
   958   | dict_ord _ (_ :: _, []) = GREATER;
   959 
   960 (*lexicographic product of lists*)
   961 fun list_ord elem_ord (xs, ys) =
   962   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
   963 
   964 
   965 (* sorting *)
   966 
   967 (*quicksort -- stable, i.e. does not reorder equal elements*)
   968 fun quicksort unique ord =
   969   let
   970     fun qsort [] = []
   971       | qsort (xs as [_]) = xs
   972       | qsort (xs as [x, y]) =
   973           (case ord (x, y) of
   974             LESS => xs
   975           | EQUAL => if unique then [x] else xs
   976           | GREATER => [y, x])
   977       | qsort xs =
   978           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
   979           in qsort lts @ eqs @ qsort gts end
   980     and part _ [] = ([], [], [])
   981       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
   982     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
   983       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
   984       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
   985       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
   986   in qsort end;
   987 
   988 fun sort ord = quicksort false ord;
   989 fun sort_distinct ord = quicksort true ord;
   990 
   991 val sort_strings = sort string_ord;
   992 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
   993 
   994 
   995 
   996 (** random numbers **)
   997 
   998 exception RANDOM;
   999 
  1000 fun rmod x y = x - y * Real.realFloor (x / y);
  1001 
  1002 local
  1003   val a = 16807.0;
  1004   val m = 2147483647.0;
  1005   val random_seed = ref 1.0;
  1006 in
  1007 
  1008 fun random () = CRITICAL (fn () =>
  1009   let val r = rmod (a * ! random_seed) m
  1010   in (random_seed := r; r) end);
  1011 
  1012 end;
  1013 
  1014 fun random_range l h =
  1015   if h < l orelse l < 0 then raise RANDOM
  1016   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1017 
  1018 fun one_of xs = nth xs (random_range 0 (length xs - 1));
  1019 
  1020 fun frequency xs =
  1021   let
  1022     val sum = foldl op + (0, map fst xs);
  1023     fun pick n ((k: int, x) :: xs) =
  1024       if n <= k then x else pick (n - k) xs
  1025   in pick (random_range 1 sum) xs end;
  1026 
  1027 
  1028 
  1029 (** misc **)
  1030 
  1031 fun divide_and_conquer decomp x =
  1032   let val (ys, recomb) = decomp x
  1033   in recomb (map (divide_and_conquer decomp) ys) end;
  1034 
  1035 
  1036 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1037    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1038 fun partition_list p i j =
  1039   let fun part k xs =
  1040             if k>j then
  1041               (case xs of [] => []
  1042                          | _ => raise Fail "partition_list")
  1043             else
  1044             let val (ns, rest) = List.partition (p k) xs;
  1045             in  ns :: part(k+1)rest  end
  1046   in  part (i: int) end;
  1047 
  1048 fun partition_eq (eq:'a * 'a -> bool) =
  1049   let
  1050     fun part [] = []
  1051       | part (x :: ys) =
  1052           let val (xs, xs') = List.partition (fn y => eq (x, y)) ys
  1053           in (x::xs)::(part xs') end
  1054   in part end;
  1055 
  1056 
  1057 
  1058 (* generating identifiers *)
  1059 
  1060 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1061 local
  1062 (*Maps 0-61 to A-Z, a-z, 0-9; exclude _ or ' to avoid clash with internal/unusual indentifiers*)
  1063 fun gensym_char i =
  1064   if i<26 then chr (ord "A" + i)
  1065   else if i<52 then chr (ord "a" + i - 26)
  1066   else chr (ord "0" + i - 52);
  1067 
  1068 val char_vec = Vector.tabulate (62, gensym_char);
  1069 fun newid n = implode (map (fn i => Vector.sub (char_vec, i)) (radixpand (62, n)));
  1070 
  1071 val gensym_seed = ref (0: int);
  1072 
  1073 in
  1074   fun gensym pre = pre ^ newid (NAMED_CRITICAL "gensym" (fn () => inc gensym_seed));
  1075 end;
  1076 
  1077 
  1078 (* stamps and serial numbers *)
  1079 
  1080 type stamp = unit ref;
  1081 val stamp: unit -> stamp = ref;
  1082 
  1083 type serial = int;
  1084 val serial = Multithreading.serial;
  1085 val serial_string = string_of_int o serial;
  1086 
  1087 
  1088 (* generic objects *)
  1089 
  1090 (*note that the builtin exception datatype may be extended by new
  1091   constructors at any time*)
  1092 structure Object = struct type T = exn end;
  1093 
  1094 end;
  1095 
  1096 structure BasicLibrary: BASIC_LIBRARY = Library;
  1097 open BasicLibrary;