src/Pure/sign.ML
author wenzelm
Sat Dec 04 18:41:12 2010 +0100 (2010-12-04)
changeset 40959 49765c1104d4
parent 39507 839873937ddd
child 42204 b3277168c1e7
permissions -rw-r--r--
added Syntax.default_root;
simplified Syntax.parse operations;
clarified treatment of syntax root for translation rules -- refrain from logical_type replacement;
tuned error message;
     1 (*  Title:      Pure/sign.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Logical signature content: naming conventions, concrete syntax, type
     5 signature, polymorphic constants.
     6 *)
     7 
     8 signature SIGN =
     9 sig
    10   val rep_sg: theory ->
    11    {naming: Name_Space.naming,
    12     syn: Syntax.syntax,
    13     tsig: Type.tsig,
    14     consts: Consts.T}
    15   val map_naming: (Name_Space.naming -> Name_Space.naming) -> theory -> theory
    16   val naming_of: theory -> Name_Space.naming
    17   val full_name: theory -> binding -> string
    18   val full_name_path: theory -> string -> binding -> string
    19   val full_bname: theory -> bstring -> string
    20   val full_bname_path: theory -> string -> bstring -> string
    21   val syn_of: theory -> Syntax.syntax
    22   val tsig_of: theory -> Type.tsig
    23   val classes_of: theory -> Sorts.algebra
    24   val all_classes: theory -> class list
    25   val super_classes: theory -> class -> class list
    26   val minimize_sort: theory -> sort -> sort
    27   val complete_sort: theory -> sort -> sort
    28   val set_defsort: sort -> theory -> theory
    29   val defaultS: theory -> sort
    30   val subsort: theory -> sort * sort -> bool
    31   val of_sort: theory -> typ * sort -> bool
    32   val inter_sort: theory -> sort * sort -> sort
    33   val witness_sorts: theory -> (typ * sort) list -> sort list -> (typ * sort) list
    34   val is_logtype: theory -> string -> bool
    35   val typ_instance: theory -> typ * typ -> bool
    36   val typ_equiv: theory -> typ * typ -> bool
    37   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    38   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    39   val consts_of: theory -> Consts.T
    40   val the_const_constraint: theory -> string -> typ
    41   val const_type: theory -> string -> typ option
    42   val the_const_type: theory -> string -> typ
    43   val declared_tyname: theory -> string -> bool
    44   val declared_const: theory -> string -> bool
    45   val const_monomorphic: theory -> string -> bool
    46   val const_typargs: theory -> string * typ -> typ list
    47   val const_instance: theory -> string * typ list -> typ
    48   val mk_const: theory -> string * typ list -> term
    49   val class_space: theory -> Name_Space.T
    50   val type_space: theory -> Name_Space.T
    51   val const_space: theory -> Name_Space.T
    52   val class_alias: binding -> class -> theory -> theory
    53   val type_alias: binding -> string -> theory -> theory
    54   val const_alias: binding -> string -> theory -> theory
    55   val intern_class: theory -> xstring -> string
    56   val extern_class: theory -> string -> xstring
    57   val intern_type: theory -> xstring -> string
    58   val extern_type: theory -> string -> xstring
    59   val intern_const: theory -> xstring -> string
    60   val extern_const: theory -> string -> xstring
    61   val arity_number: theory -> string -> int
    62   val arity_sorts: theory -> string -> sort -> sort list
    63   val certify_class: theory -> class -> class
    64   val certify_sort: theory -> sort -> sort
    65   val certify_typ: theory -> typ -> typ
    66   val certify_typ_mode: Type.mode -> theory -> typ -> typ
    67   val certify': bool -> Pretty.pp -> bool -> Consts.T -> theory -> term -> term * typ * int
    68   val certify_term: theory -> term -> term * typ * int
    69   val cert_term: theory -> term -> term
    70   val cert_prop: theory -> term -> term
    71   val no_frees: Proof.context -> term -> term
    72   val no_vars: Proof.context -> term -> term
    73   val add_types: (binding * int * mixfix) list -> theory -> theory
    74   val add_nonterminals: binding list -> theory -> theory
    75   val add_type_abbrev: binding * string list * typ -> theory -> theory
    76   val add_syntax: (string * string * mixfix) list -> theory -> theory
    77   val add_syntax_i: (string * typ * mixfix) list -> theory -> theory
    78   val add_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    79   val add_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    80   val del_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    81   val del_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    82   val type_notation: bool -> Syntax.mode -> (typ * mixfix) list -> theory -> theory
    83   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
    84   val declare_const: (binding * typ) * mixfix -> theory -> term * theory
    85   val add_consts: (binding * string * mixfix) list -> theory -> theory
    86   val add_consts_i: (binding * typ * mixfix) list -> theory -> theory
    87   val add_abbrev: string -> binding * term -> theory -> (term * term) * theory
    88   val revert_abbrev: string -> string -> theory -> theory
    89   val add_const_constraint: string * typ option -> theory -> theory
    90   val primitive_class: binding * class list -> theory -> theory
    91   val primitive_classrel: class * class -> theory -> theory
    92   val primitive_arity: arity -> theory -> theory
    93   val add_trfuns:
    94     (string * (ast list -> ast)) list *
    95     (string * (term list -> term)) list *
    96     (string * (term list -> term)) list *
    97     (string * (ast list -> ast)) list -> theory -> theory
    98   val add_trfunsT:
    99     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
   100   val add_advanced_trfuns:
   101     (string * (Proof.context -> ast list -> ast)) list *
   102     (string * (Proof.context -> term list -> term)) list *
   103     (string * (Proof.context -> term list -> term)) list *
   104     (string * (Proof.context -> ast list -> ast)) list -> theory -> theory
   105   val add_advanced_trfunsT:
   106     (string * (Proof.context -> bool -> typ -> term list -> term)) list -> theory -> theory
   107   val add_tokentrfuns:
   108     (string * string * (Proof.context -> string -> Pretty.T)) list -> theory -> theory
   109   val add_mode_tokentrfuns: string -> (string * (Proof.context -> string -> Pretty.T)) list
   110     -> theory -> theory
   111   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   112   val del_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   113   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
   114   val del_trrules_i: ast Syntax.trrule list -> theory -> theory
   115   val new_group: theory -> theory
   116   val reset_group: theory -> theory
   117   val add_path: string -> theory -> theory
   118   val root_path: theory -> theory
   119   val parent_path: theory -> theory
   120   val mandatory_path: string -> theory -> theory
   121   val qualified_path: bool -> binding -> theory -> theory
   122   val local_path: theory -> theory
   123   val restore_naming: theory -> theory -> theory
   124   val hide_class: bool -> string -> theory -> theory
   125   val hide_type: bool -> string -> theory -> theory
   126   val hide_const: bool -> string -> theory -> theory
   127 end
   128 
   129 structure Sign: SIGN =
   130 struct
   131 
   132 (** datatype sign **)
   133 
   134 datatype sign = Sign of
   135  {naming: Name_Space.naming,    (*common naming conventions*)
   136   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   137   tsig: Type.tsig,              (*order-sorted signature of types*)
   138   consts: Consts.T};            (*polymorphic constants*)
   139 
   140 fun make_sign (naming, syn, tsig, consts) =
   141   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   142 
   143 structure Data = Theory_Data_PP
   144 (
   145   type T = sign;
   146   fun extend (Sign {syn, tsig, consts, ...}) =
   147     make_sign (Name_Space.default_naming, syn, tsig, consts);
   148 
   149   val empty =
   150     make_sign (Name_Space.default_naming, Syntax.basic_syntax, Type.empty_tsig, Consts.empty);
   151 
   152   fun merge pp (sign1, sign2) =
   153     let
   154       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   155       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   156 
   157       val naming = Name_Space.default_naming;
   158       val syn = Syntax.merge_syntaxes syn1 syn2;
   159       val tsig = Type.merge_tsig pp (tsig1, tsig2);
   160       val consts = Consts.merge (consts1, consts2);
   161     in make_sign (naming, syn, tsig, consts) end;
   162 );
   163 
   164 fun rep_sg thy = Data.get thy |> (fn Sign args => args);
   165 
   166 fun map_sign f = Data.map (fn Sign {naming, syn, tsig, consts} =>
   167   make_sign (f (naming, syn, tsig, consts)));
   168 
   169 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   170 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   171 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   172 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   173 
   174 
   175 (* naming *)
   176 
   177 val naming_of = #naming o rep_sg;
   178 
   179 val full_name = Name_Space.full_name o naming_of;
   180 fun full_name_path thy path = Name_Space.full_name (Name_Space.add_path path (naming_of thy));
   181 
   182 fun full_bname thy = Name_Space.full_name (naming_of thy) o Binding.name;
   183 fun full_bname_path thy path = full_name_path thy path o Binding.name;
   184 
   185 
   186 (* syntax *)
   187 
   188 val syn_of = #syn o rep_sg;
   189 
   190 
   191 (* type signature *)
   192 
   193 val tsig_of = #tsig o rep_sg;
   194 
   195 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   196 val all_classes = Sorts.all_classes o classes_of;
   197 val super_classes = Sorts.super_classes o classes_of;
   198 val minimize_sort = Sorts.minimize_sort o classes_of;
   199 val complete_sort = Sorts.complete_sort o classes_of;
   200 
   201 val set_defsort = map_tsig o Type.set_defsort;
   202 val defaultS = Type.defaultS o tsig_of;
   203 val subsort = Type.subsort o tsig_of;
   204 val of_sort = Type.of_sort o tsig_of;
   205 val inter_sort = Type.inter_sort o tsig_of;
   206 val witness_sorts = Type.witness_sorts o tsig_of;
   207 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   208 
   209 val typ_instance = Type.typ_instance o tsig_of;
   210 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   211 val typ_match = Type.typ_match o tsig_of;
   212 val typ_unify = Type.unify o tsig_of;
   213 
   214 
   215 (* polymorphic constants *)
   216 
   217 val consts_of = #consts o rep_sg;
   218 val the_const_constraint = Consts.the_constraint o consts_of;
   219 val the_const_type = Consts.the_type o consts_of;
   220 val const_type = try o the_const_type;
   221 val const_monomorphic = Consts.is_monomorphic o consts_of;
   222 val const_typargs = Consts.typargs o consts_of;
   223 val const_instance = Consts.instance o consts_of;
   224 
   225 fun mk_const thy (c, Ts) = Const (c, const_instance thy (c, Ts));
   226 
   227 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   228 val declared_const = can o the_const_constraint;
   229 
   230 
   231 
   232 (** intern / extern names **)
   233 
   234 val class_space = Type.class_space o tsig_of;
   235 val type_space = Type.type_space o tsig_of;
   236 val const_space = Consts.space_of o consts_of;
   237 
   238 fun class_alias b c thy = map_tsig (Type.class_alias (naming_of thy) b c) thy;
   239 fun type_alias b c thy = map_tsig (Type.type_alias (naming_of thy) b c) thy;
   240 fun const_alias b c thy = map_consts (Consts.alias (naming_of thy) b c) thy;
   241 
   242 val intern_class = Name_Space.intern o class_space;
   243 val extern_class = Name_Space.extern o class_space;
   244 val intern_type = Name_Space.intern o type_space;
   245 val extern_type = Name_Space.extern o type_space;
   246 val intern_const = Name_Space.intern o const_space;
   247 val extern_const = Name_Space.extern o const_space;
   248 
   249 
   250 
   251 (** certify entities **)    (*exception TYPE*)
   252 
   253 (* certify wrt. type signature *)
   254 
   255 val arity_number = Type.arity_number o tsig_of;
   256 fun arity_sorts thy = Type.arity_sorts (Syntax.pp_global thy) (tsig_of thy);
   257 
   258 val certify_class         = Type.cert_class o tsig_of;
   259 val certify_sort          = Type.cert_sort o tsig_of;
   260 val certify_typ           = Type.cert_typ o tsig_of;
   261 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   262 
   263 
   264 (* certify term/prop *)
   265 
   266 local
   267 
   268 fun type_check pp tm =
   269   let
   270     fun err_appl bs t T u U =
   271       let
   272         val xs = map Free bs;           (*we do not rename here*)
   273         val t' = subst_bounds (xs, t);
   274         val u' = subst_bounds (xs, u);
   275         val msg = Type.appl_error pp t' T u' U;
   276       in raise TYPE (msg, [T, U], [t', u']) end;
   277 
   278     fun typ_of (_, Const (_, T)) = T
   279       | typ_of (_, Free  (_, T)) = T
   280       | typ_of (_, Var (_, T)) = T
   281       | typ_of (bs, Bound i) = snd (nth bs i handle Subscript =>
   282           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   283       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   284       | typ_of (bs, t $ u) =
   285           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   286             (case T of
   287               Type ("fun", [T1, T2]) =>
   288                 if T1 = U then T2 else err_appl bs t T u U
   289             | _ => err_appl bs t T u U)
   290           end;
   291   in typ_of ([], tm) end;
   292 
   293 fun err msg = raise TYPE (msg, [], []);
   294 
   295 fun check_vars (t $ u) = (check_vars t; check_vars u)
   296   | check_vars (Abs (_, _, t)) = check_vars t
   297   | check_vars (Free (x, _)) =
   298       if Long_Name.is_qualified x then err ("Malformed variable: " ^ quote x) else ()
   299   | check_vars (Var (xi as (_, i), _)) =
   300       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   301   | check_vars _ = ();
   302 
   303 in
   304 
   305 fun certify' prop pp do_expand consts thy tm =
   306   let
   307     val _ = check_vars tm;
   308     val tm' = Term.map_types (certify_typ thy) tm;
   309     val T = type_check pp tm';
   310     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   311     val tm'' = Consts.certify pp (tsig_of thy) do_expand consts tm';
   312   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   313 
   314 fun certify_term thy = certify' false (Syntax.pp_global thy) true (consts_of thy) thy;
   315 fun cert_term_abbrev thy = #1 o certify' false (Syntax.pp_global thy) false (consts_of thy) thy;
   316 val cert_term = #1 oo certify_term;
   317 fun cert_prop thy = #1 o certify' true (Syntax.pp_global thy) true (consts_of thy) thy;
   318 
   319 end;
   320 
   321 
   322 (* specifications *)
   323 
   324 fun no_variables kind add addT mk mkT ctxt tm =
   325   (case (add tm [], addT tm []) of
   326     ([], []) => tm
   327   | (frees, tfrees) => error (Pretty.string_of (Pretty.block
   328       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") :: Pretty.brk 1 ::
   329        Pretty.commas
   330         (map (Syntax.pretty_term ctxt o mk) frees @ map (Syntax.pretty_typ ctxt o mkT) tfrees)))));
   331 
   332 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   333 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   334 
   335 
   336 
   337 (** signature extension functions **)  (*exception ERROR/TYPE*)
   338 
   339 (* add type constructors *)
   340 
   341 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   342   let
   343     fun type_syntax (b, n, mx) =
   344       (Syntax.mark_type (Name_Space.full_name naming b), Syntax.make_type n, mx);
   345     val syn' = Syntax.update_type_gram true Syntax.mode_default (map type_syntax types) syn;
   346     val tsig' = fold (fn (a, n, _) => Type.add_type naming (a, n)) types tsig;
   347   in (naming, syn', tsig', consts) end);
   348 
   349 
   350 (* add nonterminals *)
   351 
   352 fun add_nonterminals ns = map_sign (fn (naming, syn, tsig, consts) =>
   353   (naming, syn, fold (Type.add_nonterminal naming) ns tsig, consts));
   354 
   355 
   356 (* add type abbreviations *)
   357 
   358 fun add_type_abbrev abbr = map_sign (fn (naming, syn, tsig, consts) =>
   359   (naming, syn, Type.add_abbrev naming abbr tsig, consts));
   360 
   361 
   362 (* modify syntax *)
   363 
   364 fun gen_syntax change_gram parse_typ mode args thy =
   365   let
   366     val ctxt = ProofContext.init_global thy;
   367     fun prep (c, T, mx) = (c, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt T), mx)
   368       handle ERROR msg => cat_error msg ("in syntax declaration " ^ quote c);
   369   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   370 
   371 fun gen_add_syntax x = gen_syntax (Syntax.update_const_gram true) x;
   372 
   373 val add_modesyntax = gen_add_syntax Syntax.parse_typ;
   374 val add_modesyntax_i = gen_add_syntax (K I);
   375 val add_syntax = add_modesyntax Syntax.mode_default;
   376 val add_syntax_i = add_modesyntax_i Syntax.mode_default;
   377 val del_modesyntax = gen_syntax (Syntax.update_const_gram false) Syntax.parse_typ;
   378 val del_modesyntax_i = gen_syntax (Syntax.update_const_gram false) (K I);
   379 
   380 fun type_notation add mode args =
   381   let
   382     fun type_syntax (Type (c, args), mx) =
   383           SOME (Syntax.mark_type c, Syntax.make_type (length args), mx)
   384       | type_syntax _ = NONE;
   385   in map_syn (Syntax.update_type_gram add mode (map_filter type_syntax args)) end;
   386 
   387 fun notation add mode args thy =
   388   let
   389     fun const_syntax (Const (c, _), mx) =
   390           (case try (Consts.type_scheme (consts_of thy)) c of
   391             SOME T => SOME (Syntax.mark_const c, T, mx)
   392           | NONE => NONE)
   393       | const_syntax _ = NONE;
   394   in gen_syntax (Syntax.update_const_gram add) (K I) mode (map_filter const_syntax args) thy end;
   395 
   396 
   397 (* add constants *)
   398 
   399 local
   400 
   401 fun gen_add_consts parse_typ raw_args thy =
   402   let
   403     val ctxt = ProofContext.init_global thy;
   404     val prepT = Type.no_tvars o Term.no_dummyT o certify_typ thy o parse_typ ctxt;
   405     fun prep (b, raw_T, mx) =
   406       let
   407         val c = full_name thy b;
   408         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   409           cat_error msg ("in declaration of constant " ^ quote (Binding.str_of b));
   410         val T' = Logic.varifyT_global T;
   411       in ((b, T'), (Syntax.mark_const c, T', mx), Const (c, T)) end;
   412     val args = map prep raw_args;
   413   in
   414     thy
   415     |> map_consts (fold (Consts.declare (naming_of thy) o #1) args)
   416     |> add_syntax_i (map #2 args)
   417     |> pair (map #3 args)
   418   end;
   419 
   420 in
   421 
   422 fun add_consts args = snd o gen_add_consts Syntax.parse_typ args;
   423 fun add_consts_i args = snd o gen_add_consts (K I) args;
   424 
   425 fun declare_const ((b, T), mx) thy =
   426   let
   427     val pos = Binding.pos_of b;
   428     val ([const as Const (c, _)], thy') = gen_add_consts (K I) [(b, T, mx)] thy;
   429     val _ = Position.report pos (Markup.const_decl c);
   430   in (const, thy') end;
   431 
   432 end;
   433 
   434 
   435 (* abbreviations *)
   436 
   437 fun add_abbrev mode (b, raw_t) thy =
   438   let
   439     val ctxt = Syntax.init_pretty_global thy;
   440     val prep_tm = no_frees ctxt o Term.no_dummy_patterns o cert_term_abbrev thy;
   441     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   442       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote (Binding.str_of b));
   443     val (res, consts') = consts_of thy
   444       |> Consts.abbreviate (Syntax.pp ctxt) (tsig_of thy) (naming_of thy) mode (b, t);
   445   in (res, thy |> map_consts (K consts')) end;
   446 
   447 fun revert_abbrev mode c = map_consts (Consts.revert_abbrev mode c);
   448 
   449 
   450 (* add constraints *)
   451 
   452 fun add_const_constraint (c, opt_T) thy =
   453   let
   454     fun prepT raw_T =
   455       let val T = Logic.varifyT_global (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   456       in cert_term thy (Const (c, T)); T end
   457       handle TYPE (msg, _, _) => error msg;
   458   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   459 
   460 
   461 (* primitive classes and arities *)
   462 
   463 fun primitive_class (bclass, classes) thy =
   464   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   465     let
   466       val tsig' = Type.add_class (Syntax.pp_global thy) naming (bclass, classes) tsig;
   467     in (naming, syn, tsig', consts) end)
   468   |> add_consts_i [(Binding.map_name Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   469 
   470 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (Syntax.pp_global thy) arg);
   471 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (Syntax.pp_global thy) arg);
   472 
   473 
   474 (* add translation functions *)
   475 
   476 local
   477 
   478 fun mk trs = map Syntax.mk_trfun trs;
   479 
   480 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   481   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   482 
   483 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   484 
   485 in
   486 
   487 val add_trfuns = gen_add_trfuns Syntax.update_trfuns Syntax.non_typed_tr';
   488 val add_trfunsT = gen_add_trfunsT Syntax.update_trfuns;
   489 val add_advanced_trfuns = gen_add_trfuns Syntax.update_advanced_trfuns Syntax.non_typed_tr'';
   490 val add_advanced_trfunsT = gen_add_trfunsT Syntax.update_advanced_trfuns;
   491 
   492 end;
   493 
   494 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   495 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   496 
   497 
   498 (* translation rules *)
   499 
   500 fun gen_trrules f args thy = thy |> map_syn (fn syn =>
   501   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   502   in f (ProofContext.init_global thy) syn rules syn end);
   503 
   504 val add_trrules = gen_trrules Syntax.update_trrules;
   505 val del_trrules = gen_trrules Syntax.remove_trrules;
   506 val add_trrules_i = map_syn o Syntax.update_trrules_i;
   507 val del_trrules_i = map_syn o Syntax.remove_trrules_i;
   508 
   509 
   510 (* naming *)
   511 
   512 val new_group = map_naming Name_Space.new_group;
   513 val reset_group = map_naming Name_Space.reset_group;
   514 
   515 val add_path = map_naming o Name_Space.add_path;
   516 val root_path = map_naming Name_Space.root_path;
   517 val parent_path = map_naming Name_Space.parent_path;
   518 val mandatory_path = map_naming o Name_Space.mandatory_path;
   519 val qualified_path = map_naming oo Name_Space.qualified_path;
   520 
   521 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   522 
   523 val restore_naming = map_naming o K o naming_of;
   524 
   525 
   526 (* hide names *)
   527 
   528 val hide_class = map_tsig oo Type.hide_class;
   529 val hide_type = map_tsig oo Type.hide_type;
   530 val hide_const = map_consts oo Consts.hide;
   531 
   532 end;