src/HOL/Binomial.thy
author wenzelm
Sat Nov 04 15:24:40 2017 +0100 (19 months ago)
changeset 67003 49850a679c2c
parent 66806 a4e82b58d833
child 67299 ba52a058942f
permissions -rw-r--r--
more robust sorted_entries;
     1 (*  Title:      HOL/Binomial.thy
     2     Author:     Jacques D. Fleuriot
     3     Author:     Lawrence C Paulson
     4     Author:     Jeremy Avigad
     5     Author:     Chaitanya Mangla
     6     Author:     Manuel Eberl
     7 *)
     8 
     9 section \<open>Binomial Coefficients and Binomial Theorem\<close>
    10 
    11 theory Binomial
    12   imports Presburger Factorial
    13 begin
    14 
    15 subsection \<open>Binomial coefficients\<close>
    16 
    17 text \<open>This development is based on the work of Andy Gordon and Florian Kammueller.\<close>
    18 
    19 text \<open>Combinatorial definition\<close>
    20 
    21 definition binomial :: "nat \<Rightarrow> nat \<Rightarrow> nat"  (infixl "choose" 65)
    22   where "n choose k = card {K\<in>Pow {0..<n}. card K = k}"
    23 
    24 theorem n_subsets:
    25   assumes "finite A"
    26   shows "card {B. B \<subseteq> A \<and> card B = k} = card A choose k"
    27 proof -
    28   from assms obtain f where bij: "bij_betw f {0..<card A} A"
    29     by (blast dest: ex_bij_betw_nat_finite)
    30   then have [simp]: "card (f ` C) = card C" if "C \<subseteq> {0..<card A}" for C
    31     by (meson bij_betw_imp_inj_on bij_betw_subset card_image that)
    32   from bij have "bij_betw (image f) (Pow {0..<card A}) (Pow A)"
    33     by (rule bij_betw_Pow)
    34   then have "inj_on (image f) (Pow {0..<card A})"
    35     by (rule bij_betw_imp_inj_on)
    36   moreover have "{K. K \<subseteq> {0..<card A} \<and> card K = k} \<subseteq> Pow {0..<card A}"
    37     by auto
    38   ultimately have "inj_on (image f) {K. K \<subseteq> {0..<card A} \<and> card K = k}"
    39     by (rule inj_on_subset)
    40   then have "card {K. K \<subseteq> {0..<card A} \<and> card K = k} =
    41       card (image f ` {K. K \<subseteq> {0..<card A} \<and> card K = k})" (is "_ = card ?C")
    42     by (simp add: card_image)
    43   also have "?C = {K. K \<subseteq> f ` {0..<card A} \<and> card K = k}"
    44     by (auto elim!: subset_imageE)
    45   also have "f ` {0..<card A} = A"
    46     by (meson bij bij_betw_def)
    47   finally show ?thesis
    48     by (simp add: binomial_def)
    49 qed
    50 
    51 text \<open>Recursive characterization\<close>
    52 
    53 lemma binomial_n_0 [simp, code]: "n choose 0 = 1"
    54 proof -
    55   have "{K \<in> Pow {0..<n}. card K = 0} = {{}}"
    56     by (auto dest: finite_subset)
    57   then show ?thesis
    58     by (simp add: binomial_def)
    59 qed
    60 
    61 lemma binomial_0_Suc [simp, code]: "0 choose Suc k = 0"
    62   by (simp add: binomial_def)
    63 
    64 lemma binomial_Suc_Suc [simp, code]: "Suc n choose Suc k = (n choose k) + (n choose Suc k)"
    65 proof -
    66   let ?P = "\<lambda>n k. {K. K \<subseteq> {0..<n} \<and> card K = k}"
    67   let ?Q = "?P (Suc n) (Suc k)"
    68   have inj: "inj_on (insert n) (?P n k)"
    69     by rule (auto; metis atLeastLessThan_iff insert_iff less_irrefl subsetCE)
    70   have disjoint: "insert n ` ?P n k \<inter> ?P n (Suc k) = {}"
    71     by auto
    72   have "?Q = {K\<in>?Q. n \<in> K} \<union> {K\<in>?Q. n \<notin> K}"
    73     by auto
    74   also have "{K\<in>?Q. n \<in> K} = insert n ` ?P n k" (is "?A = ?B")
    75   proof (rule set_eqI)
    76     fix K
    77     have K_finite: "finite K" if "K \<subseteq> insert n {0..<n}"
    78       using that by (rule finite_subset) simp_all
    79     have Suc_card_K: "Suc (card K - Suc 0) = card K" if "n \<in> K"
    80       and "finite K"
    81     proof -
    82       from \<open>n \<in> K\<close> obtain L where "K = insert n L" and "n \<notin> L"
    83         by (blast elim: Set.set_insert)
    84       with that show ?thesis by (simp add: card_insert)
    85     qed
    86     show "K \<in> ?A \<longleftrightarrow> K \<in> ?B"
    87       by (subst in_image_insert_iff)
    88         (auto simp add: card_insert subset_eq_atLeast0_lessThan_finite
    89           Diff_subset_conv K_finite Suc_card_K)
    90   qed
    91   also have "{K\<in>?Q. n \<notin> K} = ?P n (Suc k)"
    92     by (auto simp add: atLeast0_lessThan_Suc)
    93   finally show ?thesis using inj disjoint
    94     by (simp add: binomial_def card_Un_disjoint card_image)
    95 qed
    96 
    97 lemma binomial_eq_0: "n < k \<Longrightarrow> n choose k = 0"
    98   by (auto simp add: binomial_def dest: subset_eq_atLeast0_lessThan_card)
    99 
   100 lemma zero_less_binomial: "k \<le> n \<Longrightarrow> n choose k > 0"
   101   by (induct n k rule: diff_induct) simp_all
   102 
   103 lemma binomial_eq_0_iff [simp]: "n choose k = 0 \<longleftrightarrow> n < k"
   104   by (metis binomial_eq_0 less_numeral_extra(3) not_less zero_less_binomial)
   105 
   106 lemma zero_less_binomial_iff [simp]: "n choose k > 0 \<longleftrightarrow> k \<le> n"
   107   by (metis binomial_eq_0_iff not_less0 not_less zero_less_binomial)
   108 
   109 lemma binomial_n_n [simp]: "n choose n = 1"
   110   by (induct n) (simp_all add: binomial_eq_0)
   111 
   112 lemma binomial_Suc_n [simp]: "Suc n choose n = Suc n"
   113   by (induct n) simp_all
   114 
   115 lemma binomial_1 [simp]: "n choose Suc 0 = n"
   116   by (induct n) simp_all
   117 
   118 lemma choose_reduce_nat:
   119   "0 < n \<Longrightarrow> 0 < k \<Longrightarrow>
   120     n choose k = ((n - 1) choose (k - 1)) + ((n - 1) choose k)"
   121   using binomial_Suc_Suc [of "n - 1" "k - 1"] by simp
   122 
   123 lemma Suc_times_binomial_eq: "Suc n * (n choose k) = (Suc n choose Suc k) * Suc k"
   124   apply (induct n arbitrary: k)
   125    apply simp
   126    apply arith
   127   apply (case_tac k)
   128    apply (auto simp add: add_mult_distrib add_mult_distrib2 le_Suc_eq binomial_eq_0)
   129   done
   130 
   131 lemma binomial_le_pow2: "n choose k \<le> 2^n"
   132   apply (induct n arbitrary: k)
   133    apply (case_tac k)
   134     apply simp_all
   135   apply (case_tac k)
   136    apply auto
   137   apply (simp add: add_le_mono mult_2)
   138   done
   139 
   140 text \<open>The absorption property.\<close>
   141 lemma Suc_times_binomial: "Suc k * (Suc n choose Suc k) = Suc n * (n choose k)"
   142   using Suc_times_binomial_eq by auto
   143 
   144 text \<open>This is the well-known version of absorption, but it's harder to use
   145   because of the need to reason about division.\<close>
   146 lemma binomial_Suc_Suc_eq_times: "(Suc n choose Suc k) = (Suc n * (n choose k)) div Suc k"
   147   by (simp add: Suc_times_binomial_eq del: mult_Suc mult_Suc_right)
   148 
   149 text \<open>Another version of absorption, with \<open>-1\<close> instead of \<open>Suc\<close>.\<close>
   150 lemma times_binomial_minus1_eq: "0 < k \<Longrightarrow> k * (n choose k) = n * ((n - 1) choose (k - 1))"
   151   using Suc_times_binomial_eq [where n = "n - 1" and k = "k - 1"]
   152   by (auto split: nat_diff_split)
   153 
   154 
   155 subsection \<open>The binomial theorem (courtesy of Tobias Nipkow):\<close>
   156 
   157 text \<open>Avigad's version, generalized to any commutative ring\<close>
   158 theorem binomial_ring: "(a + b :: 'a::{comm_ring_1,power})^n =
   159   (\<Sum>k=0..n. (of_nat (n choose k)) * a^k * b^(n-k))"
   160 proof (induct n)
   161   case 0
   162   then show ?case by simp
   163 next
   164   case (Suc n)
   165   have decomp: "{0..n+1} = {0} \<union> {n + 1} \<union> {1..n}"
   166     by auto
   167   have decomp2: "{0..n} = {0} \<union> {1..n}"
   168     by auto
   169   have "(a + b)^(n+1) = (a + b) * (\<Sum>k=0..n. of_nat (n choose k) * a^k * b^(n - k))"
   170     using Suc.hyps by simp
   171   also have "\<dots> = a * (\<Sum>k=0..n. of_nat (n choose k) * a^k * b^(n-k)) +
   172       b * (\<Sum>k=0..n. of_nat (n choose k) * a^k * b^(n-k))"
   173     by (rule distrib_right)
   174   also have "\<dots> = (\<Sum>k=0..n. of_nat (n choose k) * a^(k+1) * b^(n-k)) +
   175       (\<Sum>k=0..n. of_nat (n choose k) * a^k * b^(n - k + 1))"
   176     by (auto simp add: sum_distrib_left ac_simps)
   177   also have "\<dots> = (\<Sum>k=0..n. of_nat (n choose k) * a^k * b^(n + 1 - k)) +
   178       (\<Sum>k=1..n+1. of_nat (n choose (k - 1)) * a^k * b^(n + 1 - k))"
   179     by (simp add:sum_shift_bounds_cl_Suc_ivl Suc_diff_le field_simps del: sum_cl_ivl_Suc)
   180   also have "\<dots> = a^(n + 1) + b^(n + 1) +
   181       (\<Sum>k=1..n. of_nat (n choose (k - 1)) * a^k * b^(n + 1 - k)) +
   182       (\<Sum>k=1..n. of_nat (n choose k) * a^k * b^(n + 1 - k))"
   183     by (simp add: decomp2)
   184   also have "\<dots> = a^(n + 1) + b^(n + 1) +
   185       (\<Sum>k=1..n. of_nat (n + 1 choose k) * a^k * b^(n + 1 - k))"
   186     by (auto simp add: field_simps sum.distrib [symmetric] choose_reduce_nat)
   187   also have "\<dots> = (\<Sum>k=0..n+1. of_nat (n + 1 choose k) * a^k * b^(n + 1 - k))"
   188     using decomp by (simp add: field_simps)
   189   finally show ?case
   190     by simp
   191 qed
   192 
   193 text \<open>Original version for the naturals.\<close>
   194 corollary binomial: "(a + b :: nat)^n = (\<Sum>k=0..n. (of_nat (n choose k)) * a^k * b^(n - k))"
   195   using binomial_ring [of "int a" "int b" n]
   196   by (simp only: of_nat_add [symmetric] of_nat_mult [symmetric] of_nat_power [symmetric]
   197       of_nat_sum [symmetric] of_nat_eq_iff of_nat_id)
   198 
   199 lemma binomial_fact_lemma: "k \<le> n \<Longrightarrow> fact k * fact (n - k) * (n choose k) = fact n"
   200 proof (induct n arbitrary: k rule: nat_less_induct)
   201   fix n k
   202   assume H: "\<forall>m<n. \<forall>x\<le>m. fact x * fact (m - x) * (m choose x) = fact m"
   203   assume kn: "k \<le> n"
   204   let ?ths = "fact k * fact (n - k) * (n choose k) = fact n"
   205   consider "n = 0 \<or> k = 0 \<or> n = k" | m h where "n = Suc m" "k = Suc h" "h < m"
   206     using kn by atomize_elim presburger
   207   then show "fact k * fact (n - k) * (n choose k) = fact n"
   208   proof cases
   209     case 1
   210     with kn show ?thesis by auto
   211   next
   212     case 2
   213     note n = \<open>n = Suc m\<close>
   214     note k = \<open>k = Suc h\<close>
   215     note hm = \<open>h < m\<close>
   216     have mn: "m < n"
   217       using n by arith
   218     have hm': "h \<le> m"
   219       using hm by arith
   220     have km: "k \<le> m"
   221       using hm k n kn by arith
   222     have "m - h = Suc (m - Suc h)"
   223       using  k km hm by arith
   224     with km k have "fact (m - h) = (m - h) * fact (m - k)"
   225       by simp
   226     with n k have "fact k * fact (n - k) * (n choose k) =
   227         k * (fact h * fact (m - h) * (m choose h)) +
   228         (m - h) * (fact k * fact (m - k) * (m choose k))"
   229       by (simp add: field_simps)
   230     also have "\<dots> = (k + (m - h)) * fact m"
   231       using H[rule_format, OF mn hm'] H[rule_format, OF mn km]
   232       by (simp add: field_simps)
   233     finally show ?thesis
   234       using k n km by simp
   235   qed
   236 qed
   237 
   238 lemma binomial_fact':
   239   assumes "k \<le> n"
   240   shows "n choose k = fact n div (fact k * fact (n - k))"
   241   using binomial_fact_lemma [OF assms]
   242   by (metis fact_nonzero mult_eq_0_iff nonzero_mult_div_cancel_left)
   243 
   244 lemma binomial_fact:
   245   assumes kn: "k \<le> n"
   246   shows "(of_nat (n choose k) :: 'a::field_char_0) = fact n / (fact k * fact (n - k))"
   247   using binomial_fact_lemma[OF kn]
   248   apply (simp add: field_simps)
   249   apply (metis mult.commute of_nat_fact of_nat_mult)
   250   done
   251 
   252 lemma fact_binomial:
   253   assumes "k \<le> n"
   254   shows "fact k * of_nat (n choose k) = (fact n / fact (n - k) :: 'a::field_char_0)"
   255   unfolding binomial_fact [OF assms] by (simp add: field_simps)
   256 
   257 lemma choose_two: "n choose 2 = n * (n - 1) div 2"
   258 proof (cases "n \<ge> 2")
   259   case False
   260   then have "n = 0 \<or> n = 1"
   261     by auto
   262   then show ?thesis by auto
   263 next
   264   case True
   265   define m where "m = n - 2"
   266   with True have "n = m + 2"
   267     by simp
   268   then have "fact n = n * (n - 1) * fact (n - 2)"
   269     by (simp add: fact_prod_Suc atLeast0_lessThan_Suc algebra_simps)
   270   with True show ?thesis
   271     by (simp add: binomial_fact')
   272 qed
   273 
   274 lemma choose_row_sum: "(\<Sum>k=0..n. n choose k) = 2^n"
   275   using binomial [of 1 "1" n] by (simp add: numeral_2_eq_2)
   276 
   277 lemma sum_choose_lower: "(\<Sum>k=0..n. (r+k) choose k) = Suc (r+n) choose n"
   278   by (induct n) auto
   279 
   280 lemma sum_choose_upper: "(\<Sum>k=0..n. k choose m) = Suc n choose Suc m"
   281   by (induct n) auto
   282 
   283 lemma choose_alternating_sum:
   284   "n > 0 \<Longrightarrow> (\<Sum>i\<le>n. (-1)^i * of_nat (n choose i)) = (0 :: 'a::comm_ring_1)"
   285   using binomial_ring[of "-1 :: 'a" 1 n]
   286   by (simp add: atLeast0AtMost mult_of_nat_commute zero_power)
   287 
   288 lemma choose_even_sum:
   289   assumes "n > 0"
   290   shows "2 * (\<Sum>i\<le>n. if even i then of_nat (n choose i) else 0) = (2 ^ n :: 'a::comm_ring_1)"
   291 proof -
   292   have "2 ^ n = (\<Sum>i\<le>n. of_nat (n choose i)) + (\<Sum>i\<le>n. (-1) ^ i * of_nat (n choose i) :: 'a)"
   293     using choose_row_sum[of n]
   294     by (simp add: choose_alternating_sum assms atLeast0AtMost of_nat_sum[symmetric])
   295   also have "\<dots> = (\<Sum>i\<le>n. of_nat (n choose i) + (-1) ^ i * of_nat (n choose i))"
   296     by (simp add: sum.distrib)
   297   also have "\<dots> = 2 * (\<Sum>i\<le>n. if even i then of_nat (n choose i) else 0)"
   298     by (subst sum_distrib_left, intro sum.cong) simp_all
   299   finally show ?thesis ..
   300 qed
   301 
   302 lemma choose_odd_sum:
   303   assumes "n > 0"
   304   shows "2 * (\<Sum>i\<le>n. if odd i then of_nat (n choose i) else 0) = (2 ^ n :: 'a::comm_ring_1)"
   305 proof -
   306   have "2 ^ n = (\<Sum>i\<le>n. of_nat (n choose i)) - (\<Sum>i\<le>n. (-1) ^ i * of_nat (n choose i) :: 'a)"
   307     using choose_row_sum[of n]
   308     by (simp add: choose_alternating_sum assms atLeast0AtMost of_nat_sum[symmetric])
   309   also have "\<dots> = (\<Sum>i\<le>n. of_nat (n choose i) - (-1) ^ i * of_nat (n choose i))"
   310     by (simp add: sum_subtractf)
   311   also have "\<dots> = 2 * (\<Sum>i\<le>n. if odd i then of_nat (n choose i) else 0)"
   312     by (subst sum_distrib_left, intro sum.cong) simp_all
   313   finally show ?thesis ..
   314 qed
   315 
   316 lemma choose_row_sum': "(\<Sum>k\<le>n. (n choose k)) = 2 ^ n"
   317   using choose_row_sum[of n] by (simp add: atLeast0AtMost)
   318 
   319 text\<open>NW diagonal sum property\<close>
   320 lemma sum_choose_diagonal:
   321   assumes "m \<le> n"
   322   shows "(\<Sum>k=0..m. (n - k) choose (m - k)) = Suc n choose m"
   323 proof -
   324   have "(\<Sum>k=0..m. (n-k) choose (m - k)) = (\<Sum>k=0..m. (n - m + k) choose k)"
   325     using sum.atLeast_atMost_rev [of "\<lambda>k. (n - k) choose (m - k)" 0 m] assms
   326       by simp
   327   also have "\<dots> = Suc (n - m + m) choose m"
   328     by (rule sum_choose_lower)
   329   also have "\<dots> = Suc n choose m"
   330     using assms by simp
   331   finally show ?thesis .
   332 qed
   333 
   334 
   335 subsection \<open>Generalized binomial coefficients\<close>
   336 
   337 definition gbinomial :: "'a::{semidom_divide,semiring_char_0} \<Rightarrow> nat \<Rightarrow> 'a"  (infixl "gchoose" 65)
   338   where gbinomial_prod_rev: "a gchoose n = prod (\<lambda>i. a - of_nat i) {0..<n} div fact n"
   339 
   340 lemma gbinomial_0 [simp]:
   341   "a gchoose 0 = 1"
   342   "0 gchoose (Suc n) = 0"
   343   by (simp_all add: gbinomial_prod_rev prod.atLeast0_lessThan_Suc_shift)
   344 
   345 lemma gbinomial_Suc: "a gchoose (Suc k) = prod (\<lambda>i. a - of_nat i) {0..k} div fact (Suc k)"
   346   by (simp add: gbinomial_prod_rev atLeastLessThanSuc_atLeastAtMost)
   347 
   348 lemma gbinomial_mult_fact: "fact n * (a gchoose n) = (\<Prod>i = 0..<n. a - of_nat i)"
   349   for a :: "'a::field_char_0"
   350   by (simp_all add: gbinomial_prod_rev field_simps)
   351 
   352 lemma gbinomial_mult_fact': "(a gchoose n) * fact n = (\<Prod>i = 0..<n. a - of_nat i)"
   353   for a :: "'a::field_char_0"
   354   using gbinomial_mult_fact [of n a] by (simp add: ac_simps)
   355 
   356 lemma gbinomial_pochhammer: "a gchoose n = (- 1) ^ n * pochhammer (- a) n / fact n"
   357   for a :: "'a::field_char_0"
   358   by (cases n)
   359     (simp_all add: pochhammer_minus,
   360      simp_all add: gbinomial_prod_rev pochhammer_prod_rev
   361        power_mult_distrib [symmetric] atLeastLessThanSuc_atLeastAtMost
   362        prod.atLeast_Suc_atMost_Suc_shift of_nat_diff)
   363 
   364 lemma gbinomial_pochhammer': "s gchoose n = pochhammer (s - of_nat n + 1) n / fact n"
   365   for s :: "'a::field_char_0"
   366 proof -
   367   have "s gchoose n = ((-1)^n * (-1)^n) * pochhammer (s - of_nat n + 1) n / fact n"
   368     by (simp add: gbinomial_pochhammer pochhammer_minus mult_ac)
   369   also have "(-1 :: 'a)^n * (-1)^n = 1"
   370     by (subst power_add [symmetric]) simp
   371   finally show ?thesis
   372     by simp
   373 qed
   374 
   375 lemma gbinomial_binomial: "n gchoose k = n choose k"
   376 proof (cases "k \<le> n")
   377   case False
   378   then have "n < k"
   379     by (simp add: not_le)
   380   then have "0 \<in> (op - n) ` {0..<k}"
   381     by auto
   382   then have "prod (op - n) {0..<k} = 0"
   383     by (auto intro: prod_zero)
   384   with \<open>n < k\<close> show ?thesis
   385     by (simp add: binomial_eq_0 gbinomial_prod_rev prod_zero)
   386 next
   387   case True
   388   from True have *: "prod (op - n) {0..<k} = \<Prod>{Suc (n - k)..n}"
   389     by (intro prod.reindex_bij_witness[of _ "\<lambda>i. n - i" "\<lambda>i. n - i"]) auto
   390   from True have "n choose k = fact n div (fact k * fact (n - k))"
   391     by (rule binomial_fact')
   392   with * show ?thesis
   393     by (simp add: gbinomial_prod_rev mult.commute [of "fact k"] div_mult2_eq fact_div_fact)
   394 qed
   395 
   396 lemma of_nat_gbinomial: "of_nat (n gchoose k) = (of_nat n gchoose k :: 'a::field_char_0)"
   397 proof (cases "k \<le> n")
   398   case False
   399   then show ?thesis
   400     by (simp add: not_le gbinomial_binomial binomial_eq_0 gbinomial_prod_rev)
   401 next
   402   case True
   403   define m where "m = n - k"
   404   with True have n: "n = m + k"
   405     by arith
   406   from n have "fact n = ((\<Prod>i = 0..<m + k. of_nat (m + k - i) ):: 'a)"
   407     by (simp add: fact_prod_rev)
   408   also have "\<dots> = ((\<Prod>i\<in>{0..<k} \<union> {k..<m + k}. of_nat (m + k - i)) :: 'a)"
   409     by (simp add: ivl_disj_un)
   410   finally have "fact n = (fact m * (\<Prod>i = 0..<k. of_nat m + of_nat k - of_nat i) :: 'a)"
   411     using prod_shift_bounds_nat_ivl [of "\<lambda>i. of_nat (m + k - i) :: 'a" 0 k m]
   412     by (simp add: fact_prod_rev [of m] prod.union_disjoint of_nat_diff)
   413   then have "fact n / fact (n - k) = ((\<Prod>i = 0..<k. of_nat n - of_nat i) :: 'a)"
   414     by (simp add: n)
   415   with True have "fact k * of_nat (n gchoose k) = (fact k * (of_nat n gchoose k) :: 'a)"
   416     by (simp only: gbinomial_mult_fact [of k "of_nat n"] gbinomial_binomial [of n k] fact_binomial)
   417   then show ?thesis
   418     by simp
   419 qed
   420 
   421 lemma binomial_gbinomial: "of_nat (n choose k) = (of_nat n gchoose k :: 'a::field_char_0)"
   422   by (simp add: gbinomial_binomial [symmetric] of_nat_gbinomial)
   423 
   424 setup
   425   \<open>Sign.add_const_constraint (@{const_name gbinomial}, SOME @{typ "'a::field_char_0 \<Rightarrow> nat \<Rightarrow> 'a"})\<close>
   426 
   427 lemma gbinomial_1[simp]: "a gchoose 1 = a"
   428   by (simp add: gbinomial_prod_rev lessThan_Suc)
   429 
   430 lemma gbinomial_Suc0[simp]: "a gchoose (Suc 0) = a"
   431   by (simp add: gbinomial_prod_rev lessThan_Suc)
   432 
   433 lemma gbinomial_mult_1:
   434   fixes a :: "'a::field_char_0"
   435   shows "a * (a gchoose n) = of_nat n * (a gchoose n) + of_nat (Suc n) * (a gchoose (Suc n))"
   436   (is "?l = ?r")
   437 proof -
   438   have "?r = ((- 1) ^n * pochhammer (- a) n / (fact n)) * (of_nat n - (- a + of_nat n))"
   439     apply (simp only: gbinomial_pochhammer pochhammer_Suc right_diff_distrib power_Suc)
   440     apply (simp del: of_nat_Suc fact_Suc)
   441     apply (auto simp add: field_simps simp del: of_nat_Suc)
   442     done
   443   also have "\<dots> = ?l"
   444     by (simp add: field_simps gbinomial_pochhammer)
   445   finally show ?thesis ..
   446 qed
   447 
   448 lemma gbinomial_mult_1':
   449   "(a gchoose n) * a = of_nat n * (a gchoose n) + of_nat (Suc n) * (a gchoose (Suc n))"
   450   for a :: "'a::field_char_0"
   451   by (simp add: mult.commute gbinomial_mult_1)
   452 
   453 lemma gbinomial_Suc_Suc: "(a + 1) gchoose (Suc k) = a gchoose k + (a gchoose (Suc k))"
   454   for a :: "'a::field_char_0"
   455 proof (cases k)
   456   case 0
   457   then show ?thesis by simp
   458 next
   459   case (Suc h)
   460   have eq0: "(\<Prod>i\<in>{1..k}. (a + 1) - of_nat i) = (\<Prod>i\<in>{0..h}. a - of_nat i)"
   461     apply (rule prod.reindex_cong [where l = Suc])
   462       using Suc
   463       apply (auto simp add: image_Suc_atMost)
   464     done
   465   have "fact (Suc k) * (a gchoose k + (a gchoose (Suc k))) =
   466       (a gchoose Suc h) * (fact (Suc (Suc h))) +
   467       (a gchoose Suc (Suc h)) * (fact (Suc (Suc h)))"
   468     by (simp add: Suc field_simps del: fact_Suc)
   469   also have "\<dots> =
   470     (a gchoose Suc h) * of_nat (Suc (Suc h) * fact (Suc h)) + (\<Prod>i=0..Suc h. a - of_nat i)"
   471     apply (simp del: fact_Suc add: gbinomial_mult_fact field_simps mult.left_commute [of _ "2"])
   472     apply (simp del: fact_Suc add: fact_Suc [of "Suc h"] field_simps gbinomial_mult_fact
   473       mult.left_commute [of _ "2"] atLeastLessThanSuc_atLeastAtMost)
   474     done
   475   also have "\<dots> =
   476     (fact (Suc h) * (a gchoose Suc h)) * of_nat (Suc (Suc h)) + (\<Prod>i=0..Suc h. a - of_nat i)"
   477     by (simp only: fact_Suc mult.commute mult.left_commute of_nat_fact of_nat_id of_nat_mult)
   478   also have "\<dots> =
   479     of_nat (Suc (Suc h)) * (\<Prod>i=0..h. a - of_nat i) + (\<Prod>i=0..Suc h. a - of_nat i)"
   480     unfolding gbinomial_mult_fact atLeastLessThanSuc_atLeastAtMost by auto
   481   also have "\<dots> =
   482     (\<Prod>i=0..Suc h. a - of_nat i) + (of_nat h * (\<Prod>i=0..h. a - of_nat i) + 2 * (\<Prod>i=0..h. a - of_nat i))"
   483     by (simp add: field_simps)
   484   also have "\<dots> =
   485     ((a gchoose Suc h) * (fact (Suc h)) * of_nat (Suc k)) + (\<Prod>i\<in>{0..Suc h}. a - of_nat i)"
   486     unfolding gbinomial_mult_fact'
   487     by (simp add: comm_semiring_class.distrib field_simps Suc atLeastLessThanSuc_atLeastAtMost)
   488   also have "\<dots> = (\<Prod>i\<in>{0..h}. a - of_nat i) * (a + 1)"
   489     unfolding gbinomial_mult_fact' atLeast0_atMost_Suc
   490     by (simp add: field_simps Suc atLeastLessThanSuc_atLeastAtMost)
   491   also have "\<dots> = (\<Prod>i\<in>{0..k}. (a + 1) - of_nat i)"
   492     using eq0
   493     by (simp add: Suc prod.atLeast0_atMost_Suc_shift)
   494   also have "\<dots> = (fact (Suc k)) * ((a + 1) gchoose (Suc k))"
   495     by (simp only: gbinomial_mult_fact atLeastLessThanSuc_atLeastAtMost)
   496   finally show ?thesis
   497     using fact_nonzero [of "Suc k"] by auto
   498 qed
   499 
   500 lemma gbinomial_reduce_nat: "0 < k \<Longrightarrow> a gchoose k = (a - 1) gchoose (k - 1) + ((a - 1) gchoose k)"
   501   for a :: "'a::field_char_0"
   502   by (metis Suc_pred' diff_add_cancel gbinomial_Suc_Suc)
   503 
   504 lemma gchoose_row_sum_weighted:
   505   "(\<Sum>k = 0..m. (r gchoose k) * (r/2 - of_nat k)) = of_nat(Suc m) / 2 * (r gchoose (Suc m))"
   506   for r :: "'a::field_char_0"
   507   by (induct m) (simp_all add: field_simps distrib gbinomial_mult_1)
   508 
   509 lemma binomial_symmetric:
   510   assumes kn: "k \<le> n"
   511   shows "n choose k = n choose (n - k)"
   512 proof -
   513   have kn': "n - k \<le> n"
   514     using kn by arith
   515   from binomial_fact_lemma[OF kn] binomial_fact_lemma[OF kn']
   516   have "fact k * fact (n - k) * (n choose k) = fact (n - k) * fact (n - (n - k)) * (n choose (n - k))"
   517     by simp
   518   then show ?thesis
   519     using kn by simp
   520 qed
   521 
   522 lemma choose_rising_sum:
   523   "(\<Sum>j\<le>m. ((n + j) choose n)) = ((n + m + 1) choose (n + 1))"
   524   "(\<Sum>j\<le>m. ((n + j) choose n)) = ((n + m + 1) choose m)"
   525 proof -
   526   show "(\<Sum>j\<le>m. ((n + j) choose n)) = ((n + m + 1) choose (n + 1))"
   527     by (induct m) simp_all
   528   also have "\<dots> = (n + m + 1) choose m"
   529     by (subst binomial_symmetric) simp_all
   530   finally show "(\<Sum>j\<le>m. ((n + j) choose n)) = (n + m + 1) choose m" .
   531 qed
   532 
   533 lemma choose_linear_sum: "(\<Sum>i\<le>n. i * (n choose i)) = n * 2 ^ (n - 1)"
   534 proof (cases n)
   535   case 0
   536   then show ?thesis by simp
   537 next
   538   case (Suc m)
   539   have "(\<Sum>i\<le>n. i * (n choose i)) = (\<Sum>i\<le>Suc m. i * (Suc m choose i))"
   540     by (simp add: Suc)
   541   also have "\<dots> = Suc m * 2 ^ m"
   542     by (simp only: sum_atMost_Suc_shift Suc_times_binomial sum_distrib_left[symmetric])
   543        (simp add: choose_row_sum')
   544   finally show ?thesis
   545     using Suc by simp
   546 qed
   547 
   548 lemma choose_alternating_linear_sum:
   549   assumes "n \<noteq> 1"
   550   shows "(\<Sum>i\<le>n. (-1)^i * of_nat i * of_nat (n choose i) :: 'a::comm_ring_1) = 0"
   551 proof (cases n)
   552   case 0
   553   then show ?thesis by simp
   554 next
   555   case (Suc m)
   556   with assms have "m > 0"
   557     by simp
   558   have "(\<Sum>i\<le>n. (-1) ^ i * of_nat i * of_nat (n choose i) :: 'a) =
   559       (\<Sum>i\<le>Suc m. (-1) ^ i * of_nat i * of_nat (Suc m choose i))"
   560     by (simp add: Suc)
   561   also have "\<dots> = (\<Sum>i\<le>m. (-1) ^ (Suc i) * of_nat (Suc i * (Suc m choose Suc i)))"
   562     by (simp only: sum_atMost_Suc_shift sum_distrib_left[symmetric] mult_ac of_nat_mult) simp
   563   also have "\<dots> = - of_nat (Suc m) * (\<Sum>i\<le>m. (-1) ^ i * of_nat (m choose i))"
   564     by (subst sum_distrib_left, rule sum.cong[OF refl], subst Suc_times_binomial)
   565        (simp add: algebra_simps)
   566   also have "(\<Sum>i\<le>m. (-1 :: 'a) ^ i * of_nat ((m choose i))) = 0"
   567     using choose_alternating_sum[OF \<open>m > 0\<close>] by simp
   568   finally show ?thesis
   569     by simp
   570 qed
   571 
   572 lemma vandermonde: "(\<Sum>k\<le>r. (m choose k) * (n choose (r - k))) = (m + n) choose r"
   573 proof (induct n arbitrary: r)
   574   case 0
   575   have "(\<Sum>k\<le>r. (m choose k) * (0 choose (r - k))) = (\<Sum>k\<le>r. if k = r then (m choose k) else 0)"
   576     by (intro sum.cong) simp_all
   577   also have "\<dots> = m choose r"
   578     by (simp add: sum.delta)
   579   finally show ?case
   580     by simp
   581 next
   582   case (Suc n r)
   583   show ?case
   584     by (cases r) (simp_all add: Suc [symmetric] algebra_simps sum.distrib Suc_diff_le)
   585 qed
   586 
   587 lemma choose_square_sum: "(\<Sum>k\<le>n. (n choose k)^2) = ((2*n) choose n)"
   588   using vandermonde[of n n n]
   589   by (simp add: power2_eq_square mult_2 binomial_symmetric [symmetric])
   590 
   591 lemma pochhammer_binomial_sum:
   592   fixes a b :: "'a::comm_ring_1"
   593   shows "pochhammer (a + b) n = (\<Sum>k\<le>n. of_nat (n choose k) * pochhammer a k * pochhammer b (n - k))"
   594 proof (induction n arbitrary: a b)
   595   case 0
   596   then show ?case by simp
   597 next
   598   case (Suc n a b)
   599   have "(\<Sum>k\<le>Suc n. of_nat (Suc n choose k) * pochhammer a k * pochhammer b (Suc n - k)) =
   600       (\<Sum>i\<le>n. of_nat (n choose i) * pochhammer a (Suc i) * pochhammer b (n - i)) +
   601       ((\<Sum>i\<le>n. of_nat (n choose Suc i) * pochhammer a (Suc i) * pochhammer b (n - i)) +
   602       pochhammer b (Suc n))"
   603     by (subst sum_atMost_Suc_shift) (simp add: ring_distribs sum.distrib)
   604   also have "(\<Sum>i\<le>n. of_nat (n choose i) * pochhammer a (Suc i) * pochhammer b (n - i)) =
   605       a * pochhammer ((a + 1) + b) n"
   606     by (subst Suc) (simp add: sum_distrib_left pochhammer_rec mult_ac)
   607   also have "(\<Sum>i\<le>n. of_nat (n choose Suc i) * pochhammer a (Suc i) * pochhammer b (n - i)) +
   608         pochhammer b (Suc n) =
   609       (\<Sum>i=0..Suc n. of_nat (n choose i) * pochhammer a i * pochhammer b (Suc n - i))"
   610     apply (subst sum_head_Suc)
   611     apply simp
   612     apply (subst sum_shift_bounds_cl_Suc_ivl)
   613     apply (simp add: atLeast0AtMost)
   614     done
   615   also have "\<dots> = (\<Sum>i\<le>n. of_nat (n choose i) * pochhammer a i * pochhammer b (Suc n - i))"
   616     using Suc by (intro sum.mono_neutral_right) (auto simp: not_le binomial_eq_0)
   617   also have "\<dots> = (\<Sum>i\<le>n. of_nat (n choose i) * pochhammer a i * pochhammer b (Suc (n - i)))"
   618     by (intro sum.cong) (simp_all add: Suc_diff_le)
   619   also have "\<dots> = b * pochhammer (a + (b + 1)) n"
   620     by (subst Suc) (simp add: sum_distrib_left mult_ac pochhammer_rec)
   621   also have "a * pochhammer ((a + 1) + b) n + b * pochhammer (a + (b + 1)) n =
   622       pochhammer (a + b) (Suc n)"
   623     by (simp add: pochhammer_rec algebra_simps)
   624   finally show ?case ..
   625 qed
   626 
   627 text \<open>Contributed by Manuel Eberl, generalised by LCP.
   628   Alternative definition of the binomial coefficient as @{term "\<Prod>i<k. (n - i) / (k - i)"}.\<close>
   629 lemma gbinomial_altdef_of_nat: "x gchoose k = (\<Prod>i = 0..<k. (x - of_nat i) / of_nat (k - i) :: 'a)"
   630   for k :: nat and x :: "'a::field_char_0"
   631   by (simp add: prod_dividef gbinomial_prod_rev fact_prod_rev)
   632 
   633 lemma gbinomial_ge_n_over_k_pow_k:
   634   fixes k :: nat
   635     and x :: "'a::linordered_field"
   636   assumes "of_nat k \<le> x"
   637   shows "(x / of_nat k :: 'a) ^ k \<le> x gchoose k"
   638 proof -
   639   have x: "0 \<le> x"
   640     using assms of_nat_0_le_iff order_trans by blast
   641   have "(x / of_nat k :: 'a) ^ k = (\<Prod>i = 0..<k. x / of_nat k :: 'a)"
   642     by (simp add: prod_constant)
   643   also have "\<dots> \<le> x gchoose k" (* FIXME *)
   644     unfolding gbinomial_altdef_of_nat
   645     apply (safe intro!: prod_mono)
   646     apply simp_all
   647     prefer 2
   648     subgoal premises for i
   649     proof -
   650       from assms have "x * of_nat i \<ge> of_nat (i * k)"
   651         by (metis mult.commute mult_le_cancel_right of_nat_less_0_iff of_nat_mult)
   652       then have "x * of_nat k - x * of_nat i \<le> x * of_nat k - of_nat (i * k)"
   653         by arith
   654       then have "x * of_nat (k - i) \<le> (x - of_nat i) * of_nat k"
   655         using \<open>i < k\<close> by (simp add: algebra_simps zero_less_mult_iff of_nat_diff)
   656       then have "x * of_nat (k - i) \<le> (x - of_nat i) * (of_nat k :: 'a)"
   657         by (simp only: of_nat_mult[symmetric] of_nat_le_iff)
   658       with assms show ?thesis
   659         using \<open>i < k\<close> by (simp add: field_simps)
   660     qed
   661     apply (simp add: x zero_le_divide_iff)
   662     done
   663   finally show ?thesis .
   664 qed
   665 
   666 lemma gbinomial_negated_upper: "(a gchoose b) = (-1) ^ b * ((of_nat b - a - 1) gchoose b)"
   667   by (simp add: gbinomial_pochhammer pochhammer_minus algebra_simps)
   668 
   669 lemma gbinomial_minus: "((-a) gchoose b) = (-1) ^ b * ((a + of_nat b - 1) gchoose b)"
   670   by (subst gbinomial_negated_upper) (simp add: add_ac)
   671 
   672 lemma Suc_times_gbinomial: "of_nat (Suc b) * ((a + 1) gchoose (Suc b)) = (a + 1) * (a gchoose b)"
   673 proof (cases b)
   674   case 0
   675   then show ?thesis by simp
   676 next
   677   case (Suc b)
   678   then have "((a + 1) gchoose (Suc (Suc b))) = (\<Prod>i = 0..Suc b. a + (1 - of_nat i)) / fact (b + 2)"
   679     by (simp add: field_simps gbinomial_prod_rev atLeastLessThanSuc_atLeastAtMost)
   680   also have "(\<Prod>i = 0..Suc b. a + (1 - of_nat i)) = (a + 1) * (\<Prod>i = 0..b. a - of_nat i)"
   681     by (simp add: prod.atLeast0_atMost_Suc_shift)
   682   also have "\<dots> / fact (b + 2) = (a + 1) / of_nat (Suc (Suc b)) * (a gchoose Suc b)"
   683     by (simp_all add: gbinomial_prod_rev atLeastLessThanSuc_atLeastAtMost)
   684   finally show ?thesis by (simp add: Suc field_simps del: of_nat_Suc)
   685 qed
   686 
   687 lemma gbinomial_factors: "((a + 1) gchoose (Suc b)) = (a + 1) / of_nat (Suc b) * (a gchoose b)"
   688 proof (cases b)
   689   case 0
   690   then show ?thesis by simp
   691 next
   692   case (Suc b)
   693   then have "((a + 1) gchoose (Suc (Suc b))) = (\<Prod>i = 0 .. Suc b. a + (1 - of_nat i)) / fact (b + 2)"
   694     by (simp add: field_simps gbinomial_prod_rev atLeastLessThanSuc_atLeastAtMost)
   695   also have "(\<Prod>i = 0 .. Suc b. a + (1 - of_nat i)) = (a + 1) * (\<Prod>i = 0..b. a - of_nat i)"
   696     by (simp add: prod.atLeast0_atMost_Suc_shift)
   697   also have "\<dots> / fact (b + 2) = (a + 1) / of_nat (Suc (Suc b)) * (a gchoose Suc b)"
   698     by (simp_all add: gbinomial_prod_rev atLeastLessThanSuc_atLeastAtMost atLeast0AtMost)
   699   finally show ?thesis
   700     by (simp add: Suc)
   701 qed
   702 
   703 lemma gbinomial_rec: "((r + 1) gchoose (Suc k)) = (r gchoose k) * ((r + 1) / of_nat (Suc k))"
   704   using gbinomial_mult_1[of r k]
   705   by (subst gbinomial_Suc_Suc) (simp add: field_simps del: of_nat_Suc, simp add: algebra_simps)
   706 
   707 lemma gbinomial_of_nat_symmetric: "k \<le> n \<Longrightarrow> (of_nat n) gchoose k = (of_nat n) gchoose (n - k)"
   708   using binomial_symmetric[of k n] by (simp add: binomial_gbinomial [symmetric])
   709 
   710 
   711 text \<open>The absorption identity (equation 5.5 \cite[p.~157]{GKP}):
   712 \[
   713 {r \choose k} = \frac{r}{k}{r - 1 \choose k - 1},\quad \textnormal{integer } k \neq 0.
   714 \]\<close>
   715 lemma gbinomial_absorption': "k > 0 \<Longrightarrow> r gchoose k = (r / of_nat k) * (r - 1 gchoose (k - 1))"
   716   using gbinomial_rec[of "r - 1" "k - 1"]
   717   by (simp_all add: gbinomial_rec field_simps del: of_nat_Suc)
   718 
   719 text \<open>The absorption identity is written in the following form to avoid
   720 division by $k$ (the lower index) and therefore remove the $k \neq 0$
   721 restriction\cite[p.~157]{GKP}:
   722 \[
   723 k{r \choose k} = r{r - 1 \choose k - 1}, \quad \textnormal{integer } k.
   724 \]\<close>
   725 lemma gbinomial_absorption: "of_nat (Suc k) * (r gchoose Suc k) = r * ((r - 1) gchoose k)"
   726   using gbinomial_absorption'[of "Suc k" r] by (simp add: field_simps del: of_nat_Suc)
   727 
   728 text \<open>The absorption identity for natural number binomial coefficients:\<close>
   729 lemma binomial_absorption: "Suc k * (n choose Suc k) = n * ((n - 1) choose k)"
   730   by (cases n) (simp_all add: binomial_eq_0 Suc_times_binomial del: binomial_Suc_Suc mult_Suc)
   731 
   732 text \<open>The absorption companion identity for natural number coefficients,
   733   following the proof by GKP \cite[p.~157]{GKP}:\<close>
   734 lemma binomial_absorb_comp: "(n - k) * (n choose k) = n * ((n - 1) choose k)"
   735   (is "?lhs = ?rhs")
   736 proof (cases "n \<le> k")
   737   case True
   738   then show ?thesis by auto
   739 next
   740   case False
   741   then have "?rhs = Suc ((n - 1) - k) * (n choose Suc ((n - 1) - k))"
   742     using binomial_symmetric[of k "n - 1"] binomial_absorption[of "(n - 1) - k" n]
   743     by simp
   744   also have "Suc ((n - 1) - k) = n - k"
   745     using False by simp
   746   also have "n choose \<dots> = n choose k"
   747     using False by (intro binomial_symmetric [symmetric]) simp_all
   748   finally show ?thesis ..
   749 qed
   750 
   751 text \<open>The generalised absorption companion identity:\<close>
   752 lemma gbinomial_absorb_comp: "(r - of_nat k) * (r gchoose k) = r * ((r - 1) gchoose k)"
   753   using pochhammer_absorb_comp[of r k] by (simp add: gbinomial_pochhammer)
   754 
   755 lemma gbinomial_addition_formula:
   756   "r gchoose (Suc k) = ((r - 1) gchoose (Suc k)) + ((r - 1) gchoose k)"
   757   using gbinomial_Suc_Suc[of "r - 1" k] by (simp add: algebra_simps)
   758 
   759 lemma binomial_addition_formula:
   760   "0 < n \<Longrightarrow> n choose (Suc k) = ((n - 1) choose (Suc k)) + ((n - 1) choose k)"
   761   by (subst choose_reduce_nat) simp_all
   762 
   763 text \<open>
   764   Equation 5.9 of the reference material \cite[p.~159]{GKP} is a useful
   765   summation formula, operating on both indices:
   766   \[
   767    \sum\limits_{k \leq n}{r + k \choose k} = {r + n + 1 \choose n},
   768    \quad \textnormal{integer } n.
   769   \]
   770 \<close>
   771 lemma gbinomial_parallel_sum: "(\<Sum>k\<le>n. (r + of_nat k) gchoose k) = (r + of_nat n + 1) gchoose n"
   772 proof (induct n)
   773   case 0
   774   then show ?case by simp
   775 next
   776   case (Suc m)
   777   then show ?case
   778     using gbinomial_Suc_Suc[of "(r + of_nat m + 1)" m]
   779     by (simp add: add_ac)
   780 qed
   781 
   782 
   783 subsubsection \<open>Summation on the upper index\<close>
   784 
   785 text \<open>
   786   Another summation formula is equation 5.10 of the reference material \cite[p.~160]{GKP},
   787   aptly named \emph{summation on the upper index}:\[\sum_{0 \leq k \leq n} {k \choose m} =
   788   {n + 1 \choose m + 1}, \quad \textnormal{integers } m, n \geq 0.\]
   789 \<close>
   790 lemma gbinomial_sum_up_index:
   791   "(\<Sum>k = 0..n. (of_nat k gchoose m) :: 'a::field_char_0) = (of_nat n + 1) gchoose (m + 1)"
   792 proof (induct n)
   793   case 0
   794   show ?case
   795     using gbinomial_Suc_Suc[of 0 m]
   796     by (cases m) auto
   797 next
   798   case (Suc n)
   799   then show ?case
   800     using gbinomial_Suc_Suc[of "of_nat (Suc n) :: 'a" m]
   801     by (simp add: add_ac)
   802 qed
   803 
   804 lemma gbinomial_index_swap:
   805   "((-1) ^ m) * ((- (of_nat n) - 1) gchoose m) = ((-1) ^ n) * ((- (of_nat m) - 1) gchoose n)"
   806   (is "?lhs = ?rhs")
   807 proof -
   808   have "?lhs = (of_nat (m + n) gchoose m)"
   809     by (subst gbinomial_negated_upper) (simp add: power_mult_distrib [symmetric])
   810   also have "\<dots> = (of_nat (m + n) gchoose n)"
   811     by (subst gbinomial_of_nat_symmetric) simp_all
   812   also have "\<dots> = ?rhs"
   813     by (subst gbinomial_negated_upper) simp
   814   finally show ?thesis .
   815 qed
   816 
   817 lemma gbinomial_sum_lower_neg: "(\<Sum>k\<le>m. (r gchoose k) * (- 1) ^ k) = (- 1) ^ m * (r - 1 gchoose m)"
   818   (is "?lhs = ?rhs")
   819 proof -
   820   have "?lhs = (\<Sum>k\<le>m. -(r + 1) + of_nat k gchoose k)"
   821     by (intro sum.cong[OF refl]) (subst gbinomial_negated_upper, simp add: power_mult_distrib)
   822   also have "\<dots>  = - r + of_nat m gchoose m"
   823     by (subst gbinomial_parallel_sum) simp
   824   also have "\<dots> = ?rhs"
   825     by (subst gbinomial_negated_upper) (simp add: power_mult_distrib)
   826   finally show ?thesis .
   827 qed
   828 
   829 lemma gbinomial_partial_row_sum:
   830   "(\<Sum>k\<le>m. (r gchoose k) * ((r / 2) - of_nat k)) = ((of_nat m + 1)/2) * (r gchoose (m + 1))"
   831 proof (induct m)
   832   case 0
   833   then show ?case by simp
   834 next
   835   case (Suc mm)
   836   then have "(\<Sum>k\<le>Suc mm. (r gchoose k) * (r / 2 - of_nat k)) =
   837       (r - of_nat (Suc mm)) * (r gchoose Suc mm) / 2"
   838     by (simp add: field_simps)
   839   also have "\<dots> = r * (r - 1 gchoose Suc mm) / 2"
   840     by (subst gbinomial_absorb_comp) (rule refl)
   841   also have "\<dots> = (of_nat (Suc mm) + 1) / 2 * (r gchoose (Suc mm + 1))"
   842     by (subst gbinomial_absorption [symmetric]) simp
   843   finally show ?case .
   844 qed
   845 
   846 lemma sum_bounds_lt_plus1: "(\<Sum>k<mm. f (Suc k)) = (\<Sum>k=1..mm. f k)"
   847   by (induct mm) simp_all
   848 
   849 lemma gbinomial_partial_sum_poly:
   850   "(\<Sum>k\<le>m. (of_nat m + r gchoose k) * x^k * y^(m-k)) =
   851     (\<Sum>k\<le>m. (-r gchoose k) * (-x)^k * (x + y)^(m-k))"
   852   (is "?lhs m = ?rhs m")
   853 proof (induction m)
   854   case 0
   855   then show ?case by simp
   856 next
   857   case (Suc mm)
   858   define G where "G i k = (of_nat i + r gchoose k) * x^k * y^(i - k)" for i k
   859   define S where "S = ?lhs"
   860   have SG_def: "S = (\<lambda>i. (\<Sum>k\<le>i. (G i k)))"
   861     unfolding S_def G_def ..
   862 
   863   have "S (Suc mm) = G (Suc mm) 0 + (\<Sum>k=Suc 0..Suc mm. G (Suc mm) k)"
   864     using SG_def by (simp add: sum_head_Suc atLeast0AtMost [symmetric])
   865   also have "(\<Sum>k=Suc 0..Suc mm. G (Suc mm) k) = (\<Sum>k=0..mm. G (Suc mm) (Suc k))"
   866     by (subst sum_shift_bounds_cl_Suc_ivl) simp
   867   also have "\<dots> = (\<Sum>k=0..mm. ((of_nat mm + r gchoose (Suc k)) +
   868       (of_nat mm + r gchoose k)) * x^(Suc k) * y^(mm - k))"
   869     unfolding G_def by (subst gbinomial_addition_formula) simp
   870   also have "\<dots> = (\<Sum>k=0..mm. (of_nat mm + r gchoose (Suc k)) * x^(Suc k) * y^(mm - k)) +
   871       (\<Sum>k=0..mm. (of_nat mm + r gchoose k) * x^(Suc k) * y^(mm - k))"
   872     by (subst sum.distrib [symmetric]) (simp add: algebra_simps)
   873   also have "(\<Sum>k=0..mm. (of_nat mm + r gchoose (Suc k)) * x^(Suc k) * y^(mm - k)) =
   874       (\<Sum>k<Suc mm. (of_nat mm + r gchoose (Suc k)) * x^(Suc k) * y^(mm - k))"
   875     by (simp only: atLeast0AtMost lessThan_Suc_atMost)
   876   also have "\<dots> = (\<Sum>k<mm. (of_nat mm + r gchoose Suc k) * x^(Suc k) * y^(mm-k)) +
   877       (of_nat mm + r gchoose (Suc mm)) * x^(Suc mm)"
   878     (is "_ = ?A + ?B")
   879     by (subst sum_lessThan_Suc) simp
   880   also have "?A = (\<Sum>k=1..mm. (of_nat mm + r gchoose k) * x^k * y^(mm - k + 1))"
   881   proof (subst sum_bounds_lt_plus1 [symmetric], intro sum.cong[OF refl], clarify)
   882     fix k
   883     assume "k < mm"
   884     then have "mm - k = mm - Suc k + 1"
   885       by linarith
   886     then show "(of_nat mm + r gchoose Suc k) * x ^ Suc k * y ^ (mm - k) =
   887         (of_nat mm + r gchoose Suc k) * x ^ Suc k * y ^ (mm - Suc k + 1)"
   888       by (simp only:)
   889   qed
   890   also have "\<dots> + ?B = y * (\<Sum>k=1..mm. (G mm k)) + (of_nat mm + r gchoose (Suc mm)) * x^(Suc mm)"
   891     unfolding G_def by (subst sum_distrib_left) (simp add: algebra_simps)
   892   also have "(\<Sum>k=0..mm. (of_nat mm + r gchoose k) * x^(Suc k) * y^(mm - k)) = x * (S mm)"
   893     unfolding S_def by (subst sum_distrib_left) (simp add: atLeast0AtMost algebra_simps)
   894   also have "(G (Suc mm) 0) = y * (G mm 0)"
   895     by (simp add: G_def)
   896   finally have "S (Suc mm) =
   897       y * (G mm 0 + (\<Sum>k=1..mm. (G mm k))) + (of_nat mm + r gchoose (Suc mm)) * x^(Suc mm) + x * (S mm)"
   898     by (simp add: ring_distribs)
   899   also have "G mm 0 + (\<Sum>k=1..mm. (G mm k)) = S mm"
   900     by (simp add: sum_head_Suc[symmetric] SG_def atLeast0AtMost)
   901   finally have "S (Suc mm) = (x + y) * (S mm) + (of_nat mm + r gchoose (Suc mm)) * x^(Suc mm)"
   902     by (simp add: algebra_simps)
   903   also have "(of_nat mm + r gchoose (Suc mm)) = (-1) ^ (Suc mm) * (- r gchoose (Suc mm))"
   904     by (subst gbinomial_negated_upper) simp
   905   also have "(-1) ^ Suc mm * (- r gchoose Suc mm) * x ^ Suc mm =
   906       (- r gchoose (Suc mm)) * (-x) ^ Suc mm"
   907     by (simp add: power_minus[of x])
   908   also have "(x + y) * S mm + \<dots> = (x + y) * ?rhs mm + (- r gchoose (Suc mm)) * (- x)^Suc mm"
   909     unfolding S_def by (subst Suc.IH) simp
   910   also have "(x + y) * ?rhs mm = (\<Sum>n\<le>mm. ((- r gchoose n) * (- x) ^ n * (x + y) ^ (Suc mm - n)))"
   911     by (subst sum_distrib_left, rule sum.cong) (simp_all add: Suc_diff_le)
   912   also have "\<dots> + (-r gchoose (Suc mm)) * (-x)^Suc mm =
   913       (\<Sum>n\<le>Suc mm. (- r gchoose n) * (- x) ^ n * (x + y) ^ (Suc mm - n))"
   914     by simp
   915   finally show ?case
   916     by (simp only: S_def)
   917 qed
   918 
   919 lemma gbinomial_partial_sum_poly_xpos:
   920   "(\<Sum>k\<le>m. (of_nat m + r gchoose k) * x^k * y^(m-k)) =
   921      (\<Sum>k\<le>m. (of_nat k + r - 1 gchoose k) * x^k * (x + y)^(m-k))"
   922   apply (subst gbinomial_partial_sum_poly)
   923   apply (subst gbinomial_negated_upper)
   924   apply (intro sum.cong, rule refl)
   925   apply (simp add: power_mult_distrib [symmetric])
   926   done
   927 
   928 lemma binomial_r_part_sum: "(\<Sum>k\<le>m. (2 * m + 1 choose k)) = 2 ^ (2 * m)"
   929 proof -
   930   have "2 * 2^(2*m) = (\<Sum>k = 0..(2 * m + 1). (2 * m + 1 choose k))"
   931     using choose_row_sum[where n="2 * m + 1"] by simp
   932   also have "(\<Sum>k = 0..(2 * m + 1). (2 * m + 1 choose k)) =
   933       (\<Sum>k = 0..m. (2 * m + 1 choose k)) +
   934       (\<Sum>k = m+1..2*m+1. (2 * m + 1 choose k))"
   935     using sum_ub_add_nat[of 0 m "\<lambda>k. 2 * m + 1 choose k" "m+1"]
   936     by (simp add: mult_2)
   937   also have "(\<Sum>k = m+1..2*m+1. (2 * m + 1 choose k)) =
   938       (\<Sum>k = 0..m. (2 * m + 1 choose (k + (m + 1))))"
   939     by (subst sum_shift_bounds_cl_nat_ivl [symmetric]) (simp add: mult_2)
   940   also have "\<dots> = (\<Sum>k = 0..m. (2 * m + 1 choose (m - k)))"
   941     by (intro sum.cong[OF refl], subst binomial_symmetric) simp_all
   942   also have "\<dots> = (\<Sum>k = 0..m. (2 * m + 1 choose k))"
   943     using sum.atLeast_atMost_rev [of "\<lambda>k. 2 * m + 1 choose (m - k)" 0 m]
   944     by simp
   945   also have "\<dots> + \<dots> = 2 * \<dots>"
   946     by simp
   947   finally show ?thesis
   948     by (subst (asm) mult_cancel1) (simp add: atLeast0AtMost)
   949 qed
   950 
   951 lemma gbinomial_r_part_sum: "(\<Sum>k\<le>m. (2 * (of_nat m) + 1 gchoose k)) = 2 ^ (2 * m)"
   952   (is "?lhs = ?rhs")
   953 proof -
   954   have "?lhs = of_nat (\<Sum>k\<le>m. (2 * m + 1) choose k)"
   955     by (simp add: binomial_gbinomial add_ac)
   956   also have "\<dots> = of_nat (2 ^ (2 * m))"
   957     by (subst binomial_r_part_sum) (rule refl)
   958   finally show ?thesis by simp
   959 qed
   960 
   961 lemma gbinomial_sum_nat_pow2:
   962   "(\<Sum>k\<le>m. (of_nat (m + k) gchoose k :: 'a::field_char_0) / 2 ^ k) = 2 ^ m"
   963   (is "?lhs = ?rhs")
   964 proof -
   965   have "2 ^ m * 2 ^ m = (2 ^ (2*m) :: 'a)"
   966     by (induct m) simp_all
   967   also have "\<dots> = (\<Sum>k\<le>m. (2 * (of_nat m) + 1 gchoose k))"
   968     using gbinomial_r_part_sum ..
   969   also have "\<dots> = (\<Sum>k\<le>m. (of_nat (m + k) gchoose k) * 2 ^ (m - k))"
   970     using gbinomial_partial_sum_poly_xpos[where x="1" and y="1" and r="of_nat m + 1" and m="m"]
   971     by (simp add: add_ac)
   972   also have "\<dots> = 2 ^ m * (\<Sum>k\<le>m. (of_nat (m + k) gchoose k) / 2 ^ k)"
   973     by (subst sum_distrib_left) (simp add: algebra_simps power_diff)
   974   finally show ?thesis
   975     by (subst (asm) mult_left_cancel) simp_all
   976 qed
   977 
   978 lemma gbinomial_trinomial_revision:
   979   assumes "k \<le> m"
   980   shows "(r gchoose m) * (of_nat m gchoose k) = (r gchoose k) * (r - of_nat k gchoose (m - k))"
   981 proof -
   982   have "(r gchoose m) * (of_nat m gchoose k) = (r gchoose m) * fact m / (fact k * fact (m - k))"
   983     using assms by (simp add: binomial_gbinomial [symmetric] binomial_fact)
   984   also have "\<dots> = (r gchoose k) * (r - of_nat k gchoose (m - k))"
   985     using assms by (simp add: gbinomial_pochhammer power_diff pochhammer_product)
   986   finally show ?thesis .
   987 qed
   988 
   989 text \<open>Versions of the theorems above for the natural-number version of "choose"\<close>
   990 lemma binomial_altdef_of_nat:
   991   "k \<le> n \<Longrightarrow> of_nat (n choose k) = (\<Prod>i = 0..<k. of_nat (n - i) / of_nat (k - i) :: 'a)"
   992   for n k :: nat and x :: "'a::field_char_0"
   993   by (simp add: gbinomial_altdef_of_nat binomial_gbinomial of_nat_diff)
   994 
   995 lemma binomial_ge_n_over_k_pow_k: "k \<le> n \<Longrightarrow> (of_nat n / of_nat k :: 'a) ^ k \<le> of_nat (n choose k)"
   996   for k n :: nat and x :: "'a::linordered_field"
   997   by (simp add: gbinomial_ge_n_over_k_pow_k binomial_gbinomial of_nat_diff)
   998 
   999 lemma binomial_le_pow:
  1000   assumes "r \<le> n"
  1001   shows "n choose r \<le> n ^ r"
  1002 proof -
  1003   have "n choose r \<le> fact n div fact (n - r)"
  1004     using assms by (subst binomial_fact_lemma[symmetric]) auto
  1005   with fact_div_fact_le_pow [OF assms] show ?thesis
  1006     by auto
  1007 qed
  1008 
  1009 lemma binomial_altdef_nat: "k \<le> n \<Longrightarrow> n choose k = fact n div (fact k * fact (n - k))"
  1010   for k n :: nat
  1011   by (subst binomial_fact_lemma [symmetric]) auto
  1012 
  1013 lemma choose_dvd:
  1014   "k \<le> n \<Longrightarrow> fact k * fact (n - k) dvd (fact n :: 'a::linordered_semidom)"
  1015   unfolding dvd_def
  1016   apply (rule exI [where x="of_nat (n choose k)"])
  1017   using binomial_fact_lemma [of k n, THEN arg_cong [where f = of_nat and 'b='a]]
  1018   apply auto
  1019   done
  1020 
  1021 lemma fact_fact_dvd_fact:
  1022   "fact k * fact n dvd (fact (k + n) :: 'a::linordered_semidom)"
  1023   by (metis add.commute add_diff_cancel_left' choose_dvd le_add2)
  1024 
  1025 lemma choose_mult_lemma:
  1026   "((m + r + k) choose (m + k)) * ((m + k) choose k) = ((m + r + k) choose k) * ((m + r) choose m)"
  1027   (is "?lhs = _")
  1028 proof -
  1029   have "?lhs =
  1030       fact (m + r + k) div (fact (m + k) * fact (m + r - m)) * (fact (m + k) div (fact k * fact m))"
  1031     by (simp add: binomial_altdef_nat)
  1032   also have "\<dots> = fact (m + r + k) div (fact r * (fact k * fact m))"
  1033     apply (subst div_mult_div_if_dvd)
  1034     apply (auto simp: algebra_simps fact_fact_dvd_fact)
  1035     apply (metis add.assoc add.commute fact_fact_dvd_fact)
  1036     done
  1037   also have "\<dots> = (fact (m + r + k) * fact (m + r)) div (fact r * (fact k * fact m) * fact (m + r))"
  1038     apply (subst div_mult_div_if_dvd [symmetric])
  1039     apply (auto simp add: algebra_simps)
  1040     apply (metis fact_fact_dvd_fact dvd_trans nat_mult_dvd_cancel_disj)
  1041     done
  1042   also have "\<dots> =
  1043       (fact (m + r + k) div (fact k * fact (m + r)) * (fact (m + r) div (fact r * fact m)))"
  1044     apply (subst div_mult_div_if_dvd)
  1045     apply (auto simp: fact_fact_dvd_fact algebra_simps)
  1046     done
  1047   finally show ?thesis
  1048     by (simp add: binomial_altdef_nat mult.commute)
  1049 qed
  1050 
  1051 text \<open>The "Subset of a Subset" identity.\<close>
  1052 lemma choose_mult:
  1053   "k \<le> m \<Longrightarrow> m \<le> n \<Longrightarrow> (n choose m) * (m choose k) = (n choose k) * ((n - k) choose (m - k))"
  1054   using choose_mult_lemma [of "m-k" "n-m" k] by simp
  1055 
  1056 
  1057 subsection \<open>More on Binomial Coefficients\<close>
  1058 
  1059 lemma choose_one: "n choose 1 = n" for n :: nat
  1060   by simp
  1061 
  1062 lemma card_UNION:
  1063   assumes "finite A"
  1064     and "\<forall>k \<in> A. finite k"
  1065   shows "card (\<Union>A) = nat (\<Sum>I | I \<subseteq> A \<and> I \<noteq> {}. (- 1) ^ (card I + 1) * int (card (\<Inter>I)))"
  1066   (is "?lhs = ?rhs")
  1067 proof -
  1068   have "?rhs = nat (\<Sum>I | I \<subseteq> A \<and> I \<noteq> {}. (- 1) ^ (card I + 1) * (\<Sum>_\<in>\<Inter>I. 1))"
  1069     by simp
  1070   also have "\<dots> = nat (\<Sum>I | I \<subseteq> A \<and> I \<noteq> {}. (\<Sum>_\<in>\<Inter>I. (- 1) ^ (card I + 1)))"
  1071     (is "_ = nat ?rhs")
  1072     by (subst sum_distrib_left) simp
  1073   also have "?rhs = (\<Sum>(I, _)\<in>Sigma {I. I \<subseteq> A \<and> I \<noteq> {}} Inter. (- 1) ^ (card I + 1))"
  1074     using assms by (subst sum.Sigma) auto
  1075   also have "\<dots> = (\<Sum>(x, I)\<in>(SIGMA x:UNIV. {I. I \<subseteq> A \<and> I \<noteq> {} \<and> x \<in> \<Inter>I}). (- 1) ^ (card I + 1))"
  1076     by (rule sum.reindex_cong [where l = "\<lambda>(x, y). (y, x)"]) (auto intro: inj_onI simp add: split_beta)
  1077   also have "\<dots> = (\<Sum>(x, I)\<in>(SIGMA x:\<Union>A. {I. I \<subseteq> A \<and> I \<noteq> {} \<and> x \<in> \<Inter>I}). (- 1) ^ (card I + 1))"
  1078     using assms
  1079     by (auto intro!: sum.mono_neutral_cong_right finite_SigmaI2 intro: finite_subset[where B="\<Union>A"])
  1080   also have "\<dots> = (\<Sum>x\<in>\<Union>A. (\<Sum>I|I \<subseteq> A \<and> I \<noteq> {} \<and> x \<in> \<Inter>I. (- 1) ^ (card I + 1)))"
  1081     using assms by (subst sum.Sigma) auto
  1082   also have "\<dots> = (\<Sum>_\<in>\<Union>A. 1)" (is "sum ?lhs _ = _")
  1083   proof (rule sum.cong[OF refl])
  1084     fix x
  1085     assume x: "x \<in> \<Union>A"
  1086     define K where "K = {X \<in> A. x \<in> X}"
  1087     with \<open>finite A\<close> have K: "finite K"
  1088       by auto
  1089     let ?I = "\<lambda>i. {I. I \<subseteq> A \<and> card I = i \<and> x \<in> \<Inter>I}"
  1090     have "inj_on snd (SIGMA i:{1..card A}. ?I i)"
  1091       using assms by (auto intro!: inj_onI)
  1092     moreover have [symmetric]: "snd ` (SIGMA i:{1..card A}. ?I i) = {I. I \<subseteq> A \<and> I \<noteq> {} \<and> x \<in> \<Inter>I}"
  1093       using assms
  1094       by (auto intro!: rev_image_eqI[where x="(card a, a)" for a]
  1095         simp add: card_gt_0_iff[folded Suc_le_eq]
  1096         dest: finite_subset intro: card_mono)
  1097     ultimately have "?lhs x = (\<Sum>(i, I)\<in>(SIGMA i:{1..card A}. ?I i). (- 1) ^ (i + 1))"
  1098       by (rule sum.reindex_cong [where l = snd]) fastforce
  1099     also have "\<dots> = (\<Sum>i=1..card A. (\<Sum>I|I \<subseteq> A \<and> card I = i \<and> x \<in> \<Inter>I. (- 1) ^ (i + 1)))"
  1100       using assms by (subst sum.Sigma) auto
  1101     also have "\<dots> = (\<Sum>i=1..card A. (- 1) ^ (i + 1) * (\<Sum>I|I \<subseteq> A \<and> card I = i \<and> x \<in> \<Inter>I. 1))"
  1102       by (subst sum_distrib_left) simp
  1103     also have "\<dots> = (\<Sum>i=1..card K. (- 1) ^ (i + 1) * (\<Sum>I|I \<subseteq> K \<and> card I = i. 1))"
  1104       (is "_ = ?rhs")
  1105     proof (rule sum.mono_neutral_cong_right[rule_format])
  1106       show "finite {1..card A}"
  1107         by simp
  1108       show "{1..card K} \<subseteq> {1..card A}"
  1109         using \<open>finite A\<close> by (auto simp add: K_def intro: card_mono)
  1110     next
  1111       fix i
  1112       assume "i \<in> {1..card A} - {1..card K}"
  1113       then have i: "i \<le> card A" "card K < i"
  1114         by auto
  1115       have "{I. I \<subseteq> A \<and> card I = i \<and> x \<in> \<Inter>I} = {I. I \<subseteq> K \<and> card I = i}"
  1116         by (auto simp add: K_def)
  1117       also have "\<dots> = {}"
  1118         using \<open>finite A\<close> i by (auto simp add: K_def dest: card_mono[rotated 1])
  1119       finally show "(- 1) ^ (i + 1) * (\<Sum>I | I \<subseteq> A \<and> card I = i \<and> x \<in> \<Inter>I. 1 :: int) = 0"
  1120         by (simp only:) simp
  1121     next
  1122       fix i
  1123       have "(\<Sum>I | I \<subseteq> A \<and> card I = i \<and> x \<in> \<Inter>I. 1) = (\<Sum>I | I \<subseteq> K \<and> card I = i. 1 :: int)"
  1124         (is "?lhs = ?rhs")
  1125         by (rule sum.cong) (auto simp add: K_def)
  1126       then show "(- 1) ^ (i + 1) * ?lhs = (- 1) ^ (i + 1) * ?rhs"
  1127         by simp
  1128     qed
  1129     also have "{I. I \<subseteq> K \<and> card I = 0} = {{}}"
  1130       using assms by (auto simp add: card_eq_0_iff K_def dest: finite_subset)
  1131     then have "?rhs = (\<Sum>i = 0..card K. (- 1) ^ (i + 1) * (\<Sum>I | I \<subseteq> K \<and> card I = i. 1 :: int)) + 1"
  1132       by (subst (2) sum_head_Suc) simp_all
  1133     also have "\<dots> = (\<Sum>i = 0..card K. (- 1) * ((- 1) ^ i * int (card K choose i))) + 1"
  1134       using K by (subst n_subsets[symmetric]) simp_all
  1135     also have "\<dots> = - (\<Sum>i = 0..card K. (- 1) ^ i * int (card K choose i)) + 1"
  1136       by (subst sum_distrib_left[symmetric]) simp
  1137     also have "\<dots> =  - ((-1 + 1) ^ card K) + 1"
  1138       by (subst binomial_ring) (simp add: ac_simps)
  1139     also have "\<dots> = 1"
  1140       using x K by (auto simp add: K_def card_gt_0_iff)
  1141     finally show "?lhs x = 1" .
  1142   qed
  1143   also have "nat \<dots> = card (\<Union>A)"
  1144     by simp
  1145   finally show ?thesis ..
  1146 qed
  1147 
  1148 text \<open>The number of nat lists of length \<open>m\<close> summing to \<open>N\<close> is @{term "(N + m - 1) choose N"}:\<close>
  1149 lemma card_length_sum_list_rec:
  1150   assumes "m \<ge> 1"
  1151   shows "card {l::nat list. length l = m \<and> sum_list l = N} =
  1152       card {l. length l = (m - 1) \<and> sum_list l = N} +
  1153       card {l. length l = m \<and> sum_list l + 1 = N}"
  1154     (is "card ?C = card ?A + card ?B")
  1155 proof -
  1156   let ?A' = "{l. length l = m \<and> sum_list l = N \<and> hd l = 0}"
  1157   let ?B' = "{l. length l = m \<and> sum_list l = N \<and> hd l \<noteq> 0}"
  1158   let ?f = "\<lambda>l. 0 # l"
  1159   let ?g = "\<lambda>l. (hd l + 1) # tl l"
  1160   have 1: "xs \<noteq> [] \<Longrightarrow> x = hd xs \<Longrightarrow> x # tl xs = xs" for x :: nat and xs
  1161     by simp
  1162   have 2: "xs \<noteq> [] \<Longrightarrow> sum_list(tl xs) = sum_list xs - hd xs" for xs :: "nat list"
  1163     by (auto simp add: neq_Nil_conv)
  1164   have f: "bij_betw ?f ?A ?A'"
  1165     apply (rule bij_betw_byWitness[where f' = tl])
  1166     using assms
  1167     apply (auto simp: 2 length_0_conv[symmetric] 1 simp del: length_0_conv)
  1168     done
  1169   have 3: "xs \<noteq> [] \<Longrightarrow> hd xs + (sum_list xs - hd xs) = sum_list xs" for xs :: "nat list"
  1170     by (metis 1 sum_list_simps(2) 2)
  1171   have g: "bij_betw ?g ?B ?B'"
  1172     apply (rule bij_betw_byWitness[where f' = "\<lambda>l. (hd l - 1) # tl l"])
  1173     using assms
  1174     by (auto simp: 2 length_0_conv[symmetric] intro!: 3
  1175         simp del: length_greater_0_conv length_0_conv)
  1176   have fin: "finite {xs. size xs = M \<and> set xs \<subseteq> {0..<N}}" for M N :: nat
  1177     using finite_lists_length_eq[OF finite_atLeastLessThan] conj_commute by auto
  1178   have fin_A: "finite ?A" using fin[of _ "N+1"]
  1179     by (intro finite_subset[where ?A = "?A" and ?B = "{xs. size xs = m - 1 \<and> set xs \<subseteq> {0..<N+1}}"])
  1180       (auto simp: member_le_sum_list less_Suc_eq_le)
  1181   have fin_B: "finite ?B"
  1182     by (intro finite_subset[where ?A = "?B" and ?B = "{xs. size xs = m \<and> set xs \<subseteq> {0..<N}}"])
  1183       (auto simp: member_le_sum_list less_Suc_eq_le fin)
  1184   have uni: "?C = ?A' \<union> ?B'"
  1185     by auto
  1186   have disj: "?A' \<inter> ?B' = {}" by blast
  1187   have "card ?C = card(?A' \<union> ?B')"
  1188     using uni by simp
  1189   also have "\<dots> = card ?A + card ?B"
  1190     using card_Un_disjoint[OF _ _ disj] bij_betw_finite[OF f] bij_betw_finite[OF g]
  1191       bij_betw_same_card[OF f] bij_betw_same_card[OF g] fin_A fin_B
  1192     by presburger
  1193   finally show ?thesis .
  1194 qed
  1195 
  1196 lemma card_length_sum_list: "card {l::nat list. size l = m \<and> sum_list l = N} = (N + m - 1) choose N"
  1197   \<comment> "by Holden Lee, tidied by Tobias Nipkow"
  1198 proof (cases m)
  1199   case 0
  1200   then show ?thesis
  1201     by (cases N) (auto cong: conj_cong)
  1202 next
  1203   case (Suc m')
  1204   have m: "m \<ge> 1"
  1205     by (simp add: Suc)
  1206   then show ?thesis
  1207   proof (induct "N + m - 1" arbitrary: N m)
  1208     case 0  \<comment> "In the base case, the only solution is [0]."
  1209     have [simp]: "{l::nat list. length l = Suc 0 \<and> (\<forall>n\<in>set l. n = 0)} = {[0]}"
  1210       by (auto simp: length_Suc_conv)
  1211     have "m = 1 \<and> N = 0"
  1212       using 0 by linarith
  1213     then show ?case
  1214       by simp
  1215   next
  1216     case (Suc k)
  1217     have c1: "card {l::nat list. size l = (m - 1) \<and> sum_list l =  N} = (N + (m - 1) - 1) choose N"
  1218     proof (cases "m = 1")
  1219       case True
  1220       with Suc.hyps have "N \<ge> 1"
  1221         by auto
  1222       with True show ?thesis
  1223         by (simp add: binomial_eq_0)
  1224     next
  1225       case False
  1226       then show ?thesis
  1227         using Suc by fastforce
  1228     qed
  1229     from Suc have c2: "card {l::nat list. size l = m \<and> sum_list l + 1 = N} =
  1230       (if N > 0 then ((N - 1) + m - 1) choose (N - 1) else 0)"
  1231     proof -
  1232       have *: "n > 0 \<Longrightarrow> Suc m = n \<longleftrightarrow> m = n - 1" for m n
  1233         by arith
  1234       from Suc have "N > 0 \<Longrightarrow>
  1235         card {l::nat list. size l = m \<and> sum_list l + 1 = N} =
  1236           ((N - 1) + m - 1) choose (N - 1)"
  1237         by (simp add: *)
  1238       then show ?thesis
  1239         by auto
  1240     qed
  1241     from Suc.prems have "(card {l::nat list. size l = (m - 1) \<and> sum_list l = N} +
  1242           card {l::nat list. size l = m \<and> sum_list l + 1 = N}) = (N + m - 1) choose N"
  1243       by (auto simp: c1 c2 choose_reduce_nat[of "N + m - 1" N] simp del: One_nat_def)
  1244     then show ?case
  1245       using card_length_sum_list_rec[OF Suc.prems] by auto
  1246   qed
  1247 qed
  1248 
  1249 lemma card_disjoint_shuffle:
  1250   assumes "set xs \<inter> set ys = {}"
  1251   shows   "card (shuffle xs ys) = (length xs + length ys) choose length xs"
  1252 using assms
  1253 proof (induction xs ys rule: shuffle.induct)
  1254   case (3 x xs y ys)
  1255   have "shuffle (x # xs) (y # ys) = op # x ` shuffle xs (y # ys) \<union> op # y ` shuffle (x # xs) ys"
  1256     by (rule shuffle.simps)
  1257   also have "card \<dots> = card (op # x ` shuffle xs (y # ys)) + card (op # y ` shuffle (x # xs) ys)"
  1258     by (rule card_Un_disjoint) (insert "3.prems", auto)
  1259   also have "card (op # x ` shuffle xs (y # ys)) = card (shuffle xs (y # ys))"
  1260     by (rule card_image) auto
  1261   also have "\<dots> = (length xs + length (y # ys)) choose length xs"
  1262     using "3.prems" by (intro "3.IH") auto
  1263   also have "card (op # y ` shuffle (x # xs) ys) = card (shuffle (x # xs) ys)"
  1264     by (rule card_image) auto
  1265   also have "\<dots> = (length (x # xs) + length ys) choose length (x # xs)"
  1266     using "3.prems" by (intro "3.IH") auto
  1267   also have "length xs + length (y # ys) choose length xs + \<dots> =
  1268                (length (x # xs) + length (y # ys)) choose length (x # xs)" by simp
  1269   finally show ?case .
  1270 qed auto
  1271 
  1272 lemma Suc_times_binomial_add: "Suc a * (Suc (a + b) choose Suc a) = Suc b * (Suc (a + b) choose a)"
  1273   \<comment> \<open>by Lukas Bulwahn\<close>
  1274 proof -
  1275   have dvd: "Suc a * (fact a * fact b) dvd fact (Suc (a + b))" for a b
  1276     using fact_fact_dvd_fact[of "Suc a" "b", where 'a=nat]
  1277     by (simp only: fact_Suc add_Suc[symmetric] of_nat_id mult.assoc)
  1278   have "Suc a * (fact (Suc (a + b)) div (Suc a * fact a * fact b)) =
  1279       Suc a * fact (Suc (a + b)) div (Suc a * (fact a * fact b))"
  1280     by (subst div_mult_swap[symmetric]; simp only: mult.assoc dvd)
  1281   also have "\<dots> = Suc b * fact (Suc (a + b)) div (Suc b * (fact a * fact b))"
  1282     by (simp only: div_mult_mult1)
  1283   also have "\<dots> = Suc b * (fact (Suc (a + b)) div (Suc b * (fact a * fact b)))"
  1284     using dvd[of b a] by (subst div_mult_swap[symmetric]; simp only: ac_simps dvd)
  1285   finally show ?thesis
  1286     by (subst (1 2) binomial_altdef_nat)
  1287       (simp_all only: ac_simps diff_Suc_Suc Suc_diff_le diff_add_inverse fact_Suc of_nat_id)
  1288 qed
  1289 
  1290 
  1291 subsection \<open>Misc\<close>
  1292 
  1293 lemma gbinomial_code [code]:
  1294   "a gchoose n =
  1295     (if n = 0 then 1
  1296      else fold_atLeastAtMost_nat (\<lambda>n acc. (a - of_nat n) * acc) 0 (n - 1) 1 / fact n)"
  1297   by (cases n)
  1298     (simp_all add: gbinomial_prod_rev prod_atLeastAtMost_code [symmetric]
  1299       atLeastLessThanSuc_atLeastAtMost)
  1300 
  1301 declare [[code drop: binomial]]
  1302     
  1303 lemma binomial_code [code]:
  1304   "(n choose k) =
  1305       (if k > n then 0
  1306        else if 2 * k > n then (n choose (n - k))
  1307        else (fold_atLeastAtMost_nat (op * ) (n-k+1) n 1 div fact k))"
  1308 proof -
  1309   {
  1310     assume "k \<le> n"
  1311     then have "{1..n} = {1..n-k} \<union> {n-k+1..n}" by auto
  1312     then have "(fact n :: nat) = fact (n-k) * \<Prod>{n-k+1..n}"
  1313       by (simp add: prod.union_disjoint fact_prod)
  1314   }
  1315   then show ?thesis by (auto simp: binomial_altdef_nat mult_ac prod_atLeastAtMost_code)
  1316 qed
  1317 
  1318 end