src/HOL/Deriv.thy
author wenzelm
Sat Nov 04 15:24:40 2017 +0100 (19 months ago)
changeset 67003 49850a679c2c
parent 64272 f76b6dda2e56
child 67149 e61557884799
permissions -rw-r--r--
more robust sorted_entries;
     1 (*  Title:      HOL/Deriv.thy
     2     Author:     Jacques D. Fleuriot, University of Cambridge, 1998
     3     Author:     Brian Huffman
     4     Author:     Lawrence C Paulson, 2004
     5     Author:     Benjamin Porter, 2005
     6 *)
     7 
     8 section \<open>Differentiation\<close>
     9 
    10 theory Deriv
    11   imports Limits
    12 begin
    13 
    14 subsection \<open>Frechet derivative\<close>
    15 
    16 definition has_derivative :: "('a::real_normed_vector \<Rightarrow> 'b::real_normed_vector) \<Rightarrow>
    17     ('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow> bool"  (infix "(has'_derivative)" 50)
    18   where "(f has_derivative f') F \<longleftrightarrow>
    19     bounded_linear f' \<and>
    20     ((\<lambda>y. ((f y - f (Lim F (\<lambda>x. x))) - f' (y - Lim F (\<lambda>x. x))) /\<^sub>R norm (y - Lim F (\<lambda>x. x))) \<longlongrightarrow> 0) F"
    21 
    22 text \<open>
    23   Usually the filter @{term F} is @{term "at x within s"}.  @{term "(f has_derivative D)
    24   (at x within s)"} means: @{term D} is the derivative of function @{term f} at point @{term x}
    25   within the set @{term s}. Where @{term s} is used to express left or right sided derivatives. In
    26   most cases @{term s} is either a variable or @{term UNIV}.
    27 \<close>
    28 
    29 lemma has_derivative_eq_rhs: "(f has_derivative f') F \<Longrightarrow> f' = g' \<Longrightarrow> (f has_derivative g') F"
    30   by simp
    31 
    32 definition has_field_derivative :: "('a::real_normed_field \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a filter \<Rightarrow> bool"
    33     (infix "(has'_field'_derivative)" 50)
    34   where "(f has_field_derivative D) F \<longleftrightarrow> (f has_derivative op * D) F"
    35 
    36 lemma DERIV_cong: "(f has_field_derivative X) F \<Longrightarrow> X = Y \<Longrightarrow> (f has_field_derivative Y) F"
    37   by simp
    38 
    39 definition has_vector_derivative :: "(real \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'b \<Rightarrow> real filter \<Rightarrow> bool"
    40     (infix "has'_vector'_derivative" 50)
    41   where "(f has_vector_derivative f') net \<longleftrightarrow> (f has_derivative (\<lambda>x. x *\<^sub>R f')) net"
    42 
    43 lemma has_vector_derivative_eq_rhs:
    44   "(f has_vector_derivative X) F \<Longrightarrow> X = Y \<Longrightarrow> (f has_vector_derivative Y) F"
    45   by simp
    46 
    47 named_theorems derivative_intros "structural introduction rules for derivatives"
    48 setup \<open>
    49   let
    50     val eq_thms = @{thms has_derivative_eq_rhs DERIV_cong has_vector_derivative_eq_rhs}
    51     fun eq_rule thm = get_first (try (fn eq_thm => eq_thm OF [thm])) eq_thms
    52   in
    53     Global_Theory.add_thms_dynamic
    54       (@{binding derivative_eq_intros},
    55         fn context =>
    56           Named_Theorems.get (Context.proof_of context) @{named_theorems derivative_intros}
    57           |> map_filter eq_rule)
    58   end;
    59 \<close>
    60 
    61 text \<open>
    62   The following syntax is only used as a legacy syntax.
    63 \<close>
    64 abbreviation (input)
    65   FDERIV :: "('a::real_normed_vector \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a \<Rightarrow>  ('a \<Rightarrow> 'b) \<Rightarrow> bool"
    66   ("(FDERIV (_)/ (_)/ :> (_))" [1000, 1000, 60] 60)
    67   where "FDERIV f x :> f' \<equiv> (f has_derivative f') (at x)"
    68 
    69 lemma has_derivative_bounded_linear: "(f has_derivative f') F \<Longrightarrow> bounded_linear f'"
    70   by (simp add: has_derivative_def)
    71 
    72 lemma has_derivative_linear: "(f has_derivative f') F \<Longrightarrow> linear f'"
    73   using bounded_linear.linear[OF has_derivative_bounded_linear] .
    74 
    75 lemma has_derivative_ident[derivative_intros, simp]: "((\<lambda>x. x) has_derivative (\<lambda>x. x)) F"
    76   by (simp add: has_derivative_def)
    77 
    78 lemma has_derivative_id [derivative_intros, simp]: "(id has_derivative id) (at a)"
    79   by (metis eq_id_iff has_derivative_ident)
    80 
    81 lemma has_derivative_const[derivative_intros, simp]: "((\<lambda>x. c) has_derivative (\<lambda>x. 0)) F"
    82   by (simp add: has_derivative_def)
    83 
    84 lemma (in bounded_linear) bounded_linear: "bounded_linear f" ..
    85 
    86 lemma (in bounded_linear) has_derivative:
    87   "(g has_derivative g') F \<Longrightarrow> ((\<lambda>x. f (g x)) has_derivative (\<lambda>x. f (g' x))) F"
    88   unfolding has_derivative_def
    89   apply safe
    90    apply (erule bounded_linear_compose [OF bounded_linear])
    91   apply (drule tendsto)
    92   apply (simp add: scaleR diff add zero)
    93   done
    94 
    95 lemmas has_derivative_scaleR_right [derivative_intros] =
    96   bounded_linear.has_derivative [OF bounded_linear_scaleR_right]
    97 
    98 lemmas has_derivative_scaleR_left [derivative_intros] =
    99   bounded_linear.has_derivative [OF bounded_linear_scaleR_left]
   100 
   101 lemmas has_derivative_mult_right [derivative_intros] =
   102   bounded_linear.has_derivative [OF bounded_linear_mult_right]
   103 
   104 lemmas has_derivative_mult_left [derivative_intros] =
   105   bounded_linear.has_derivative [OF bounded_linear_mult_left]
   106 
   107 lemma has_derivative_add[simp, derivative_intros]:
   108   assumes f: "(f has_derivative f') F"
   109     and g: "(g has_derivative g') F"
   110   shows "((\<lambda>x. f x + g x) has_derivative (\<lambda>x. f' x + g' x)) F"
   111   unfolding has_derivative_def
   112 proof safe
   113   let ?x = "Lim F (\<lambda>x. x)"
   114   let ?D = "\<lambda>f f' y. ((f y - f ?x) - f' (y - ?x)) /\<^sub>R norm (y - ?x)"
   115   have "((\<lambda>x. ?D f f' x + ?D g g' x) \<longlongrightarrow> (0 + 0)) F"
   116     using f g by (intro tendsto_add) (auto simp: has_derivative_def)
   117   then show "(?D (\<lambda>x. f x + g x) (\<lambda>x. f' x + g' x) \<longlongrightarrow> 0) F"
   118     by (simp add: field_simps scaleR_add_right scaleR_diff_right)
   119 qed (blast intro: bounded_linear_add f g has_derivative_bounded_linear)
   120 
   121 lemma has_derivative_sum[simp, derivative_intros]:
   122   "(\<And>i. i \<in> I \<Longrightarrow> (f i has_derivative f' i) F) \<Longrightarrow>
   123     ((\<lambda>x. \<Sum>i\<in>I. f i x) has_derivative (\<lambda>x. \<Sum>i\<in>I. f' i x)) F"
   124   by (induct I rule: infinite_finite_induct) simp_all
   125 
   126 lemma has_derivative_minus[simp, derivative_intros]:
   127   "(f has_derivative f') F \<Longrightarrow> ((\<lambda>x. - f x) has_derivative (\<lambda>x. - f' x)) F"
   128   using has_derivative_scaleR_right[of f f' F "-1"] by simp
   129 
   130 lemma has_derivative_diff[simp, derivative_intros]:
   131   "(f has_derivative f') F \<Longrightarrow> (g has_derivative g') F \<Longrightarrow>
   132     ((\<lambda>x. f x - g x) has_derivative (\<lambda>x. f' x - g' x)) F"
   133   by (simp only: diff_conv_add_uminus has_derivative_add has_derivative_minus)
   134 
   135 lemma has_derivative_at_within:
   136   "(f has_derivative f') (at x within s) \<longleftrightarrow>
   137     (bounded_linear f' \<and> ((\<lambda>y. ((f y - f x) - f' (y - x)) /\<^sub>R norm (y - x)) \<longlongrightarrow> 0) (at x within s))"
   138   by (cases "at x within s = bot") (simp_all add: has_derivative_def Lim_ident_at)
   139 
   140 lemma has_derivative_iff_norm:
   141   "(f has_derivative f') (at x within s) \<longleftrightarrow>
   142     bounded_linear f' \<and> ((\<lambda>y. norm ((f y - f x) - f' (y - x)) / norm (y - x)) \<longlongrightarrow> 0) (at x within s)"
   143   using tendsto_norm_zero_iff[of _ "at x within s", where 'b="'b", symmetric]
   144   by (simp add: has_derivative_at_within divide_inverse ac_simps)
   145 
   146 lemma has_derivative_at:
   147   "(f has_derivative D) (at x) \<longleftrightarrow>
   148     (bounded_linear D \<and> (\<lambda>h. norm (f (x + h) - f x - D h) / norm h) \<midarrow>0\<rightarrow> 0)"
   149   unfolding has_derivative_iff_norm LIM_offset_zero_iff[of _ _ x] by simp
   150 
   151 lemma field_has_derivative_at:
   152   fixes x :: "'a::real_normed_field"
   153   shows "(f has_derivative op * D) (at x) \<longleftrightarrow> (\<lambda>h. (f (x + h) - f x) / h) \<midarrow>0\<rightarrow> D"
   154   apply (unfold has_derivative_at)
   155   apply (simp add: bounded_linear_mult_right)
   156   apply (simp cong: LIM_cong add: nonzero_norm_divide [symmetric])
   157   apply (subst diff_divide_distrib)
   158   apply (subst times_divide_eq_left [symmetric])
   159   apply (simp cong: LIM_cong)
   160   apply (simp add: tendsto_norm_zero_iff LIM_zero_iff)
   161   done
   162 
   163 lemma has_derivativeI:
   164   "bounded_linear f' \<Longrightarrow>
   165     ((\<lambda>y. ((f y - f x) - f' (y - x)) /\<^sub>R norm (y - x)) \<longlongrightarrow> 0) (at x within s) \<Longrightarrow>
   166     (f has_derivative f') (at x within s)"
   167   by (simp add: has_derivative_at_within)
   168 
   169 lemma has_derivativeI_sandwich:
   170   assumes e: "0 < e"
   171     and bounded: "bounded_linear f'"
   172     and sandwich: "(\<And>y. y \<in> s \<Longrightarrow> y \<noteq> x \<Longrightarrow> dist y x < e \<Longrightarrow>
   173       norm ((f y - f x) - f' (y - x)) / norm (y - x) \<le> H y)"
   174     and "(H \<longlongrightarrow> 0) (at x within s)"
   175   shows "(f has_derivative f') (at x within s)"
   176   unfolding has_derivative_iff_norm
   177 proof safe
   178   show "((\<lambda>y. norm (f y - f x - f' (y - x)) / norm (y - x)) \<longlongrightarrow> 0) (at x within s)"
   179   proof (rule tendsto_sandwich[where f="\<lambda>x. 0"])
   180     show "(H \<longlongrightarrow> 0) (at x within s)" by fact
   181     show "eventually (\<lambda>n. norm (f n - f x - f' (n - x)) / norm (n - x) \<le> H n) (at x within s)"
   182       unfolding eventually_at using e sandwich by auto
   183   qed (auto simp: le_divide_eq)
   184 qed fact
   185 
   186 lemma has_derivative_subset:
   187   "(f has_derivative f') (at x within s) \<Longrightarrow> t \<subseteq> s \<Longrightarrow> (f has_derivative f') (at x within t)"
   188   by (auto simp add: has_derivative_iff_norm intro: tendsto_within_subset)
   189 
   190 lemmas has_derivative_within_subset = has_derivative_subset
   191 
   192 
   193 subsection \<open>Continuity\<close>
   194 
   195 lemma has_derivative_continuous:
   196   assumes f: "(f has_derivative f') (at x within s)"
   197   shows "continuous (at x within s) f"
   198 proof -
   199   from f interpret F: bounded_linear f'
   200     by (rule has_derivative_bounded_linear)
   201   note F.tendsto[tendsto_intros]
   202   let ?L = "\<lambda>f. (f \<longlongrightarrow> 0) (at x within s)"
   203   have "?L (\<lambda>y. norm ((f y - f x) - f' (y - x)) / norm (y - x))"
   204     using f unfolding has_derivative_iff_norm by blast
   205   then have "?L (\<lambda>y. norm ((f y - f x) - f' (y - x)) / norm (y - x) * norm (y - x))" (is ?m)
   206     by (rule tendsto_mult_zero) (auto intro!: tendsto_eq_intros)
   207   also have "?m \<longleftrightarrow> ?L (\<lambda>y. norm ((f y - f x) - f' (y - x)))"
   208     by (intro filterlim_cong) (simp_all add: eventually_at_filter)
   209   finally have "?L (\<lambda>y. (f y - f x) - f' (y - x))"
   210     by (rule tendsto_norm_zero_cancel)
   211   then have "?L (\<lambda>y. ((f y - f x) - f' (y - x)) + f' (y - x))"
   212     by (rule tendsto_eq_intros) (auto intro!: tendsto_eq_intros simp: F.zero)
   213   then have "?L (\<lambda>y. f y - f x)"
   214     by simp
   215   from tendsto_add[OF this tendsto_const, of "f x"] show ?thesis
   216     by (simp add: continuous_within)
   217 qed
   218 
   219 
   220 subsection \<open>Composition\<close>
   221 
   222 lemma tendsto_at_iff_tendsto_nhds_within:
   223   "f x = y \<Longrightarrow> (f \<longlongrightarrow> y) (at x within s) \<longleftrightarrow> (f \<longlongrightarrow> y) (inf (nhds x) (principal s))"
   224   unfolding tendsto_def eventually_inf_principal eventually_at_filter
   225   by (intro ext all_cong imp_cong) (auto elim!: eventually_mono)
   226 
   227 lemma has_derivative_in_compose:
   228   assumes f: "(f has_derivative f') (at x within s)"
   229     and g: "(g has_derivative g') (at (f x) within (f`s))"
   230   shows "((\<lambda>x. g (f x)) has_derivative (\<lambda>x. g' (f' x))) (at x within s)"
   231 proof -
   232   from f interpret F: bounded_linear f'
   233     by (rule has_derivative_bounded_linear)
   234   from g interpret G: bounded_linear g'
   235     by (rule has_derivative_bounded_linear)
   236   from F.bounded obtain kF where kF: "\<And>x. norm (f' x) \<le> norm x * kF"
   237     by fast
   238   from G.bounded obtain kG where kG: "\<And>x. norm (g' x) \<le> norm x * kG"
   239     by fast
   240   note G.tendsto[tendsto_intros]
   241 
   242   let ?L = "\<lambda>f. (f \<longlongrightarrow> 0) (at x within s)"
   243   let ?D = "\<lambda>f f' x y. (f y - f x) - f' (y - x)"
   244   let ?N = "\<lambda>f f' x y. norm (?D f f' x y) / norm (y - x)"
   245   let ?gf = "\<lambda>x. g (f x)" and ?gf' = "\<lambda>x. g' (f' x)"
   246   define Nf where "Nf = ?N f f' x"
   247   define Ng where [abs_def]: "Ng y = ?N g g' (f x) (f y)" for y
   248 
   249   show ?thesis
   250   proof (rule has_derivativeI_sandwich[of 1])
   251     show "bounded_linear (\<lambda>x. g' (f' x))"
   252       using f g by (blast intro: bounded_linear_compose has_derivative_bounded_linear)
   253   next
   254     fix y :: 'a
   255     assume neq: "y \<noteq> x"
   256     have "?N ?gf ?gf' x y = norm (g' (?D f f' x y) + ?D g g' (f x) (f y)) / norm (y - x)"
   257       by (simp add: G.diff G.add field_simps)
   258     also have "\<dots> \<le> norm (g' (?D f f' x y)) / norm (y - x) + Ng y * (norm (f y - f x) / norm (y - x))"
   259       by (simp add: add_divide_distrib[symmetric] divide_right_mono norm_triangle_ineq G.zero Ng_def)
   260     also have "\<dots> \<le> Nf y * kG + Ng y * (Nf y + kF)"
   261     proof (intro add_mono mult_left_mono)
   262       have "norm (f y - f x) = norm (?D f f' x y + f' (y - x))"
   263         by simp
   264       also have "\<dots> \<le> norm (?D f f' x y) + norm (f' (y - x))"
   265         by (rule norm_triangle_ineq)
   266       also have "\<dots> \<le> norm (?D f f' x y) + norm (y - x) * kF"
   267         using kF by (intro add_mono) simp
   268       finally show "norm (f y - f x) / norm (y - x) \<le> Nf y + kF"
   269         by (simp add: neq Nf_def field_simps)
   270     qed (use kG in \<open>simp_all add: Ng_def Nf_def neq zero_le_divide_iff field_simps\<close>)
   271     finally show "?N ?gf ?gf' x y \<le> Nf y * kG + Ng y * (Nf y + kF)" .
   272   next
   273     have [tendsto_intros]: "?L Nf"
   274       using f unfolding has_derivative_iff_norm Nf_def ..
   275     from f have "(f \<longlongrightarrow> f x) (at x within s)"
   276       by (blast intro: has_derivative_continuous continuous_within[THEN iffD1])
   277     then have f': "LIM x at x within s. f x :> inf (nhds (f x)) (principal (f`s))"
   278       unfolding filterlim_def
   279       by (simp add: eventually_filtermap eventually_at_filter le_principal)
   280 
   281     have "((?N g  g' (f x)) \<longlongrightarrow> 0) (at (f x) within f`s)"
   282       using g unfolding has_derivative_iff_norm ..
   283     then have g': "((?N g  g' (f x)) \<longlongrightarrow> 0) (inf (nhds (f x)) (principal (f`s)))"
   284       by (rule tendsto_at_iff_tendsto_nhds_within[THEN iffD1, rotated]) simp
   285 
   286     have [tendsto_intros]: "?L Ng"
   287       unfolding Ng_def by (rule filterlim_compose[OF g' f'])
   288     show "((\<lambda>y. Nf y * kG + Ng y * (Nf y + kF)) \<longlongrightarrow> 0) (at x within s)"
   289       by (intro tendsto_eq_intros) auto
   290   qed simp
   291 qed
   292 
   293 lemma has_derivative_compose:
   294   "(f has_derivative f') (at x within s) \<Longrightarrow> (g has_derivative g') (at (f x)) \<Longrightarrow>
   295   ((\<lambda>x. g (f x)) has_derivative (\<lambda>x. g' (f' x))) (at x within s)"
   296   by (blast intro: has_derivative_in_compose has_derivative_subset)
   297 
   298 lemma (in bounded_bilinear) FDERIV:
   299   assumes f: "(f has_derivative f') (at x within s)" and g: "(g has_derivative g') (at x within s)"
   300   shows "((\<lambda>x. f x ** g x) has_derivative (\<lambda>h. f x ** g' h + f' h ** g x)) (at x within s)"
   301 proof -
   302   from bounded_linear.bounded [OF has_derivative_bounded_linear [OF f]]
   303   obtain KF where norm_F: "\<And>x. norm (f' x) \<le> norm x * KF" by fast
   304 
   305   from pos_bounded obtain K
   306     where K: "0 < K" and norm_prod: "\<And>a b. norm (a ** b) \<le> norm a * norm b * K"
   307     by fast
   308   let ?D = "\<lambda>f f' y. f y - f x - f' (y - x)"
   309   let ?N = "\<lambda>f f' y. norm (?D f f' y) / norm (y - x)"
   310   define Ng where "Ng = ?N g g'"
   311   define Nf where "Nf = ?N f f'"
   312 
   313   let ?fun1 = "\<lambda>y. norm (f y ** g y - f x ** g x - (f x ** g' (y - x) + f' (y - x) ** g x)) / norm (y - x)"
   314   let ?fun2 = "\<lambda>y. norm (f x) * Ng y * K + Nf y * norm (g y) * K + KF * norm (g y - g x) * K"
   315   let ?F = "at x within s"
   316 
   317   show ?thesis
   318   proof (rule has_derivativeI_sandwich[of 1])
   319     show "bounded_linear (\<lambda>h. f x ** g' h + f' h ** g x)"
   320       by (intro bounded_linear_add
   321         bounded_linear_compose [OF bounded_linear_right] bounded_linear_compose [OF bounded_linear_left]
   322         has_derivative_bounded_linear [OF g] has_derivative_bounded_linear [OF f])
   323   next
   324     from g have "(g \<longlongrightarrow> g x) ?F"
   325       by (intro continuous_within[THEN iffD1] has_derivative_continuous)
   326     moreover from f g have "(Nf \<longlongrightarrow> 0) ?F" "(Ng \<longlongrightarrow> 0) ?F"
   327       by (simp_all add: has_derivative_iff_norm Ng_def Nf_def)
   328     ultimately have "(?fun2 \<longlongrightarrow> norm (f x) * 0 * K + 0 * norm (g x) * K + KF * norm (0::'b) * K) ?F"
   329       by (intro tendsto_intros) (simp_all add: LIM_zero_iff)
   330     then show "(?fun2 \<longlongrightarrow> 0) ?F"
   331       by simp
   332   next
   333     fix y :: 'd
   334     assume "y \<noteq> x"
   335     have "?fun1 y =
   336         norm (f x ** ?D g g' y + ?D f f' y ** g y + f' (y - x) ** (g y - g x)) / norm (y - x)"
   337       by (simp add: diff_left diff_right add_left add_right field_simps)
   338     also have "\<dots> \<le> (norm (f x) * norm (?D g g' y) * K + norm (?D f f' y) * norm (g y) * K +
   339         norm (y - x) * KF * norm (g y - g x) * K) / norm (y - x)"
   340       by (intro divide_right_mono mult_mono'
   341                 order_trans [OF norm_triangle_ineq add_mono]
   342                 order_trans [OF norm_prod mult_right_mono]
   343                 mult_nonneg_nonneg order_refl norm_ge_zero norm_F
   344                 K [THEN order_less_imp_le])
   345     also have "\<dots> = ?fun2 y"
   346       by (simp add: add_divide_distrib Ng_def Nf_def)
   347     finally show "?fun1 y \<le> ?fun2 y" .
   348   qed simp
   349 qed
   350 
   351 lemmas has_derivative_mult[simp, derivative_intros] = bounded_bilinear.FDERIV[OF bounded_bilinear_mult]
   352 lemmas has_derivative_scaleR[simp, derivative_intros] = bounded_bilinear.FDERIV[OF bounded_bilinear_scaleR]
   353 
   354 lemma has_derivative_prod[simp, derivative_intros]:
   355   fixes f :: "'i \<Rightarrow> 'a::real_normed_vector \<Rightarrow> 'b::real_normed_field"
   356   shows "(\<And>i. i \<in> I \<Longrightarrow> (f i has_derivative f' i) (at x within s)) \<Longrightarrow>
   357     ((\<lambda>x. \<Prod>i\<in>I. f i x) has_derivative (\<lambda>y. \<Sum>i\<in>I. f' i y * (\<Prod>j\<in>I - {i}. f j x))) (at x within s)"
   358 proof (induct I rule: infinite_finite_induct)
   359   case infinite
   360   then show ?case by simp
   361 next
   362   case empty
   363   then show ?case by simp
   364 next
   365   case (insert i I)
   366   let ?P = "\<lambda>y. f i x * (\<Sum>i\<in>I. f' i y * (\<Prod>j\<in>I - {i}. f j x)) + (f' i y) * (\<Prod>i\<in>I. f i x)"
   367   have "((\<lambda>x. f i x * (\<Prod>i\<in>I. f i x)) has_derivative ?P) (at x within s)"
   368     using insert by (intro has_derivative_mult) auto
   369   also have "?P = (\<lambda>y. \<Sum>i'\<in>insert i I. f' i' y * (\<Prod>j\<in>insert i I - {i'}. f j x))"
   370     using insert(1,2)
   371     by (auto simp add: sum_distrib_left insert_Diff_if intro!: ext sum.cong)
   372   finally show ?case
   373     using insert by simp
   374 qed
   375 
   376 lemma has_derivative_power[simp, derivative_intros]:
   377   fixes f :: "'a :: real_normed_vector \<Rightarrow> 'b :: real_normed_field"
   378   assumes f: "(f has_derivative f') (at x within s)"
   379   shows "((\<lambda>x. f x^n) has_derivative (\<lambda>y. of_nat n * f' y * f x^(n - 1))) (at x within s)"
   380   using has_derivative_prod[OF f, of "{..< n}"] by (simp add: prod_constant ac_simps)
   381 
   382 lemma has_derivative_inverse':
   383   fixes x :: "'a::real_normed_div_algebra"
   384   assumes x: "x \<noteq> 0"
   385   shows "(inverse has_derivative (\<lambda>h. - (inverse x * h * inverse x))) (at x within s)"
   386     (is "(?inv has_derivative ?f) _")
   387 proof (rule has_derivativeI_sandwich)
   388   show "bounded_linear (\<lambda>h. - (?inv x * h * ?inv x))"
   389     apply (rule bounded_linear_minus)
   390     apply (rule bounded_linear_mult_const)
   391     apply (rule bounded_linear_const_mult)
   392     apply (rule bounded_linear_ident)
   393     done
   394   show "0 < norm x" using x by simp
   395   show "((\<lambda>y. norm (?inv y - ?inv x) * norm (?inv x)) \<longlongrightarrow> 0) (at x within s)"
   396     apply (rule tendsto_mult_left_zero)
   397     apply (rule tendsto_norm_zero)
   398     apply (rule LIM_zero)
   399     apply (rule tendsto_inverse)
   400      apply (rule tendsto_ident_at)
   401     apply (rule x)
   402     done
   403 next
   404   fix y :: 'a
   405   assume h: "y \<noteq> x" "dist y x < norm x"
   406   then have "y \<noteq> 0" by auto
   407   have "norm (?inv y - ?inv x - ?f (y -x)) / norm (y - x) =
   408       norm ((?inv y - ?inv x) * (y - x) * ?inv x) / norm (y - x)"
   409     apply (subst inverse_diff_inverse [OF \<open>y \<noteq> 0\<close> x])
   410     apply (subst minus_diff_minus)
   411     apply (subst norm_minus_cancel)
   412     apply (simp add: left_diff_distrib)
   413     done
   414   also have "\<dots> \<le> norm (?inv y - ?inv x) * norm (y - x) * norm (?inv x) / norm (y - x)"
   415     apply (rule divide_right_mono [OF _ norm_ge_zero])
   416     apply (rule order_trans [OF norm_mult_ineq])
   417     apply (rule mult_right_mono [OF _ norm_ge_zero])
   418     apply (rule norm_mult_ineq)
   419     done
   420   also have "\<dots> = norm (?inv y - ?inv x) * norm (?inv x)"
   421     by simp
   422   finally show "norm (?inv y - ?inv x - ?f (y -x)) / norm (y - x) \<le>
   423     norm (?inv y - ?inv x) * norm (?inv x)" .
   424 qed
   425 
   426 lemma has_derivative_inverse[simp, derivative_intros]:
   427   fixes f :: "_ \<Rightarrow> 'a::real_normed_div_algebra"
   428   assumes x:  "f x \<noteq> 0"
   429     and f: "(f has_derivative f') (at x within s)"
   430   shows "((\<lambda>x. inverse (f x)) has_derivative (\<lambda>h. - (inverse (f x) * f' h * inverse (f x))))
   431     (at x within s)"
   432   using has_derivative_compose[OF f has_derivative_inverse', OF x] .
   433 
   434 lemma has_derivative_divide[simp, derivative_intros]:
   435   fixes f :: "_ \<Rightarrow> 'a::real_normed_div_algebra"
   436   assumes f: "(f has_derivative f') (at x within s)"
   437     and g: "(g has_derivative g') (at x within s)"
   438   assumes x: "g x \<noteq> 0"
   439   shows "((\<lambda>x. f x / g x) has_derivative
   440                 (\<lambda>h. - f x * (inverse (g x) * g' h * inverse (g x)) + f' h / g x)) (at x within s)"
   441   using has_derivative_mult[OF f has_derivative_inverse[OF x g]]
   442   by (simp add: field_simps)
   443 
   444 
   445 text \<open>Conventional form requires mult-AC laws. Types real and complex only.\<close>
   446 
   447 lemma has_derivative_divide'[derivative_intros]:
   448   fixes f :: "_ \<Rightarrow> 'a::real_normed_field"
   449   assumes f: "(f has_derivative f') (at x within s)"
   450     and g: "(g has_derivative g') (at x within s)"
   451     and x: "g x \<noteq> 0"
   452   shows "((\<lambda>x. f x / g x) has_derivative (\<lambda>h. (f' h * g x - f x * g' h) / (g x * g x))) (at x within s)"
   453 proof -
   454   have "f' h / g x - f x * (inverse (g x) * g' h * inverse (g x)) =
   455       (f' h * g x - f x * g' h) / (g x * g x)" for h
   456     by (simp add: field_simps x)
   457   then show ?thesis
   458     using has_derivative_divide [OF f g] x
   459     by simp
   460 qed
   461 
   462 
   463 subsection \<open>Uniqueness\<close>
   464 
   465 text \<open>
   466 This can not generally shown for @{const has_derivative}, as we need to approach the point from
   467 all directions. There is a proof in \<open>Analysis\<close> for \<open>euclidean_space\<close>.
   468 \<close>
   469 
   470 lemma has_derivative_zero_unique:
   471   assumes "((\<lambda>x. 0) has_derivative F) (at x)"
   472   shows "F = (\<lambda>h. 0)"
   473 proof -
   474   interpret F: bounded_linear F
   475     using assms by (rule has_derivative_bounded_linear)
   476   let ?r = "\<lambda>h. norm (F h) / norm h"
   477   have *: "?r \<midarrow>0\<rightarrow> 0"
   478     using assms unfolding has_derivative_at by simp
   479   show "F = (\<lambda>h. 0)"
   480   proof
   481     show "F h = 0" for h
   482     proof (rule ccontr)
   483       assume **: "\<not> ?thesis"
   484       then have h: "h \<noteq> 0"
   485         by (auto simp add: F.zero)
   486       with ** have "0 < ?r h"
   487         by simp
   488       from LIM_D [OF * this] obtain s
   489         where s: "0 < s" and r: "\<And>x. x \<noteq> 0 \<Longrightarrow> norm x < s \<Longrightarrow> ?r x < ?r h"
   490         by auto
   491       from dense [OF s] obtain t where t: "0 < t \<and> t < s" ..
   492       let ?x = "scaleR (t / norm h) h"
   493       have "?x \<noteq> 0" and "norm ?x < s"
   494         using t h by simp_all
   495       then have "?r ?x < ?r h"
   496         by (rule r)
   497       then show False
   498         using t h by (simp add: F.scaleR)
   499     qed
   500   qed
   501 qed
   502 
   503 lemma has_derivative_unique:
   504   assumes "(f has_derivative F) (at x)"
   505     and "(f has_derivative F') (at x)"
   506   shows "F = F'"
   507 proof -
   508   have "((\<lambda>x. 0) has_derivative (\<lambda>h. F h - F' h)) (at x)"
   509     using has_derivative_diff [OF assms] by simp
   510   then have "(\<lambda>h. F h - F' h) = (\<lambda>h. 0)"
   511     by (rule has_derivative_zero_unique)
   512   then show "F = F'"
   513     unfolding fun_eq_iff right_minus_eq .
   514 qed
   515 
   516 
   517 subsection \<open>Differentiability predicate\<close>
   518 
   519 definition differentiable :: "('a::real_normed_vector \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   520     (infix "differentiable" 50)
   521   where "f differentiable F \<longleftrightarrow> (\<exists>D. (f has_derivative D) F)"
   522 
   523 lemma differentiable_subset:
   524   "f differentiable (at x within s) \<Longrightarrow> t \<subseteq> s \<Longrightarrow> f differentiable (at x within t)"
   525   unfolding differentiable_def by (blast intro: has_derivative_subset)
   526 
   527 lemmas differentiable_within_subset = differentiable_subset
   528 
   529 lemma differentiable_ident [simp, derivative_intros]: "(\<lambda>x. x) differentiable F"
   530   unfolding differentiable_def by (blast intro: has_derivative_ident)
   531 
   532 lemma differentiable_const [simp, derivative_intros]: "(\<lambda>z. a) differentiable F"
   533   unfolding differentiable_def by (blast intro: has_derivative_const)
   534 
   535 lemma differentiable_in_compose:
   536   "f differentiable (at (g x) within (g`s)) \<Longrightarrow> g differentiable (at x within s) \<Longrightarrow>
   537     (\<lambda>x. f (g x)) differentiable (at x within s)"
   538   unfolding differentiable_def by (blast intro: has_derivative_in_compose)
   539 
   540 lemma differentiable_compose:
   541   "f differentiable (at (g x)) \<Longrightarrow> g differentiable (at x within s) \<Longrightarrow>
   542     (\<lambda>x. f (g x)) differentiable (at x within s)"
   543   by (blast intro: differentiable_in_compose differentiable_subset)
   544 
   545 lemma differentiable_sum [simp, derivative_intros]:
   546   "f differentiable F \<Longrightarrow> g differentiable F \<Longrightarrow> (\<lambda>x. f x + g x) differentiable F"
   547   unfolding differentiable_def by (blast intro: has_derivative_add)
   548 
   549 lemma differentiable_minus [simp, derivative_intros]:
   550   "f differentiable F \<Longrightarrow> (\<lambda>x. - f x) differentiable F"
   551   unfolding differentiable_def by (blast intro: has_derivative_minus)
   552 
   553 lemma differentiable_diff [simp, derivative_intros]:
   554   "f differentiable F \<Longrightarrow> g differentiable F \<Longrightarrow> (\<lambda>x. f x - g x) differentiable F"
   555   unfolding differentiable_def by (blast intro: has_derivative_diff)
   556 
   557 lemma differentiable_mult [simp, derivative_intros]:
   558   fixes f g :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_algebra"
   559   shows "f differentiable (at x within s) \<Longrightarrow> g differentiable (at x within s) \<Longrightarrow>
   560     (\<lambda>x. f x * g x) differentiable (at x within s)"
   561   unfolding differentiable_def by (blast intro: has_derivative_mult)
   562 
   563 lemma differentiable_inverse [simp, derivative_intros]:
   564   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_field"
   565   shows "f differentiable (at x within s) \<Longrightarrow> f x \<noteq> 0 \<Longrightarrow>
   566     (\<lambda>x. inverse (f x)) differentiable (at x within s)"
   567   unfolding differentiable_def by (blast intro: has_derivative_inverse)
   568 
   569 lemma differentiable_divide [simp, derivative_intros]:
   570   fixes f g :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_field"
   571   shows "f differentiable (at x within s) \<Longrightarrow> g differentiable (at x within s) \<Longrightarrow>
   572     g x \<noteq> 0 \<Longrightarrow> (\<lambda>x. f x / g x) differentiable (at x within s)"
   573   unfolding divide_inverse by simp
   574 
   575 lemma differentiable_power [simp, derivative_intros]:
   576   fixes f g :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_field"
   577   shows "f differentiable (at x within s) \<Longrightarrow> (\<lambda>x. f x ^ n) differentiable (at x within s)"
   578   unfolding differentiable_def by (blast intro: has_derivative_power)
   579 
   580 lemma differentiable_scaleR [simp, derivative_intros]:
   581   "f differentiable (at x within s) \<Longrightarrow> g differentiable (at x within s) \<Longrightarrow>
   582     (\<lambda>x. f x *\<^sub>R g x) differentiable (at x within s)"
   583   unfolding differentiable_def by (blast intro: has_derivative_scaleR)
   584 
   585 lemma has_derivative_imp_has_field_derivative:
   586   "(f has_derivative D) F \<Longrightarrow> (\<And>x. x * D' = D x) \<Longrightarrow> (f has_field_derivative D') F"
   587   unfolding has_field_derivative_def
   588   by (rule has_derivative_eq_rhs[of f D]) (simp_all add: fun_eq_iff mult.commute)
   589 
   590 lemma has_field_derivative_imp_has_derivative:
   591   "(f has_field_derivative D) F \<Longrightarrow> (f has_derivative op * D) F"
   592   by (simp add: has_field_derivative_def)
   593 
   594 lemma DERIV_subset:
   595   "(f has_field_derivative f') (at x within s) \<Longrightarrow> t \<subseteq> s \<Longrightarrow>
   596     (f has_field_derivative f') (at x within t)"
   597   by (simp add: has_field_derivative_def has_derivative_within_subset)
   598 
   599 lemma has_field_derivative_at_within:
   600   "(f has_field_derivative f') (at x) \<Longrightarrow> (f has_field_derivative f') (at x within s)"
   601   using DERIV_subset by blast
   602 
   603 abbreviation (input)
   604   DERIV :: "('a::real_normed_field \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> bool"
   605     ("(DERIV (_)/ (_)/ :> (_))" [1000, 1000, 60] 60)
   606   where "DERIV f x :> D \<equiv> (f has_field_derivative D) (at x)"
   607 
   608 abbreviation has_real_derivative :: "(real \<Rightarrow> real) \<Rightarrow> real \<Rightarrow> real filter \<Rightarrow> bool"
   609     (infix "(has'_real'_derivative)" 50)
   610   where "(f has_real_derivative D) F \<equiv> (f has_field_derivative D) F"
   611 
   612 lemma real_differentiable_def:
   613   "f differentiable at x within s \<longleftrightarrow> (\<exists>D. (f has_real_derivative D) (at x within s))"
   614 proof safe
   615   assume "f differentiable at x within s"
   616   then obtain f' where *: "(f has_derivative f') (at x within s)"
   617     unfolding differentiable_def by auto
   618   then obtain c where "f' = (op * c)"
   619     by (metis real_bounded_linear has_derivative_bounded_linear mult.commute fun_eq_iff)
   620   with * show "\<exists>D. (f has_real_derivative D) (at x within s)"
   621     unfolding has_field_derivative_def by auto
   622 qed (auto simp: differentiable_def has_field_derivative_def)
   623 
   624 lemma real_differentiableE [elim?]:
   625   assumes f: "f differentiable (at x within s)"
   626   obtains df where "(f has_real_derivative df) (at x within s)"
   627   using assms by (auto simp: real_differentiable_def)
   628 
   629 lemma differentiableD:
   630   "f differentiable (at x within s) \<Longrightarrow> \<exists>D. (f has_real_derivative D) (at x within s)"
   631   by (auto elim: real_differentiableE)
   632 
   633 lemma differentiableI:
   634   "(f has_real_derivative D) (at x within s) \<Longrightarrow> f differentiable (at x within s)"
   635   by (force simp add: real_differentiable_def)
   636 
   637 lemma has_field_derivative_iff:
   638   "(f has_field_derivative D) (at x within S) \<longleftrightarrow>
   639     ((\<lambda>y. (f y - f x) / (y - x)) \<longlongrightarrow> D) (at x within S)"
   640   apply (simp add: has_field_derivative_def has_derivative_iff_norm bounded_linear_mult_right
   641       LIM_zero_iff[symmetric, of _ D])
   642   apply (subst (2) tendsto_norm_zero_iff[symmetric])
   643   apply (rule filterlim_cong)
   644     apply (simp_all add: eventually_at_filter field_simps nonzero_norm_divide)
   645   done
   646 
   647 lemma DERIV_def: "DERIV f x :> D \<longleftrightarrow> (\<lambda>h. (f (x + h) - f x) / h) \<midarrow>0\<rightarrow> D"
   648   unfolding field_has_derivative_at has_field_derivative_def has_field_derivative_iff ..
   649 
   650 lemma mult_commute_abs: "(\<lambda>x. x * c) = op * c"
   651   for c :: "'a::ab_semigroup_mult"
   652   by (simp add: fun_eq_iff mult.commute)
   653 
   654 
   655 subsection \<open>Vector derivative\<close>
   656 
   657 lemma has_field_derivative_iff_has_vector_derivative:
   658   "(f has_field_derivative y) F \<longleftrightarrow> (f has_vector_derivative y) F"
   659   unfolding has_vector_derivative_def has_field_derivative_def real_scaleR_def mult_commute_abs ..
   660 
   661 lemma has_field_derivative_subset:
   662   "(f has_field_derivative y) (at x within s) \<Longrightarrow> t \<subseteq> s \<Longrightarrow>
   663     (f has_field_derivative y) (at x within t)"
   664   unfolding has_field_derivative_def by (rule has_derivative_subset)
   665 
   666 lemma has_vector_derivative_const[simp, derivative_intros]: "((\<lambda>x. c) has_vector_derivative 0) net"
   667   by (auto simp: has_vector_derivative_def)
   668 
   669 lemma has_vector_derivative_id[simp, derivative_intros]: "((\<lambda>x. x) has_vector_derivative 1) net"
   670   by (auto simp: has_vector_derivative_def)
   671 
   672 lemma has_vector_derivative_minus[derivative_intros]:
   673   "(f has_vector_derivative f') net \<Longrightarrow> ((\<lambda>x. - f x) has_vector_derivative (- f')) net"
   674   by (auto simp: has_vector_derivative_def)
   675 
   676 lemma has_vector_derivative_add[derivative_intros]:
   677   "(f has_vector_derivative f') net \<Longrightarrow> (g has_vector_derivative g') net \<Longrightarrow>
   678     ((\<lambda>x. f x + g x) has_vector_derivative (f' + g')) net"
   679   by (auto simp: has_vector_derivative_def scaleR_right_distrib)
   680 
   681 lemma has_vector_derivative_sum[derivative_intros]:
   682   "(\<And>i. i \<in> I \<Longrightarrow> (f i has_vector_derivative f' i) net) \<Longrightarrow>
   683     ((\<lambda>x. \<Sum>i\<in>I. f i x) has_vector_derivative (\<Sum>i\<in>I. f' i)) net"
   684   by (auto simp: has_vector_derivative_def fun_eq_iff scaleR_sum_right intro!: derivative_eq_intros)
   685 
   686 lemma has_vector_derivative_diff[derivative_intros]:
   687   "(f has_vector_derivative f') net \<Longrightarrow> (g has_vector_derivative g') net \<Longrightarrow>
   688     ((\<lambda>x. f x - g x) has_vector_derivative (f' - g')) net"
   689   by (auto simp: has_vector_derivative_def scaleR_diff_right)
   690 
   691 lemma has_vector_derivative_add_const:
   692   "((\<lambda>t. g t + z) has_vector_derivative f') net = ((\<lambda>t. g t) has_vector_derivative f') net"
   693   apply (intro iffI)
   694    apply (drule has_vector_derivative_diff [where g = "\<lambda>t. z", OF _ has_vector_derivative_const])
   695    apply simp
   696   apply (drule has_vector_derivative_add [OF _ has_vector_derivative_const])
   697   apply simp
   698   done
   699 
   700 lemma has_vector_derivative_diff_const:
   701   "((\<lambda>t. g t - z) has_vector_derivative f') net = ((\<lambda>t. g t) has_vector_derivative f') net"
   702   using has_vector_derivative_add_const [where z = "-z"]
   703   by simp
   704 
   705 lemma (in bounded_linear) has_vector_derivative:
   706   assumes "(g has_vector_derivative g') F"
   707   shows "((\<lambda>x. f (g x)) has_vector_derivative f g') F"
   708   using has_derivative[OF assms[unfolded has_vector_derivative_def]]
   709   by (simp add: has_vector_derivative_def scaleR)
   710 
   711 lemma (in bounded_bilinear) has_vector_derivative:
   712   assumes "(f has_vector_derivative f') (at x within s)"
   713     and "(g has_vector_derivative g') (at x within s)"
   714   shows "((\<lambda>x. f x ** g x) has_vector_derivative (f x ** g' + f' ** g x)) (at x within s)"
   715   using FDERIV[OF assms(1-2)[unfolded has_vector_derivative_def]]
   716   by (simp add: has_vector_derivative_def scaleR_right scaleR_left scaleR_right_distrib)
   717 
   718 lemma has_vector_derivative_scaleR[derivative_intros]:
   719   "(f has_field_derivative f') (at x within s) \<Longrightarrow> (g has_vector_derivative g') (at x within s) \<Longrightarrow>
   720     ((\<lambda>x. f x *\<^sub>R g x) has_vector_derivative (f x *\<^sub>R g' + f' *\<^sub>R g x)) (at x within s)"
   721   unfolding has_field_derivative_iff_has_vector_derivative
   722   by (rule bounded_bilinear.has_vector_derivative[OF bounded_bilinear_scaleR])
   723 
   724 lemma has_vector_derivative_mult[derivative_intros]:
   725   "(f has_vector_derivative f') (at x within s) \<Longrightarrow> (g has_vector_derivative g') (at x within s) \<Longrightarrow>
   726     ((\<lambda>x. f x * g x) has_vector_derivative (f x * g' + f' * g x)) (at x within s)"
   727   for f g :: "real \<Rightarrow> 'a::real_normed_algebra"
   728   by (rule bounded_bilinear.has_vector_derivative[OF bounded_bilinear_mult])
   729 
   730 lemma has_vector_derivative_of_real[derivative_intros]:
   731   "(f has_field_derivative D) F \<Longrightarrow> ((\<lambda>x. of_real (f x)) has_vector_derivative (of_real D)) F"
   732   by (rule bounded_linear.has_vector_derivative[OF bounded_linear_of_real])
   733     (simp add: has_field_derivative_iff_has_vector_derivative)
   734 
   735 lemma has_vector_derivative_continuous:
   736   "(f has_vector_derivative D) (at x within s) \<Longrightarrow> continuous (at x within s) f"
   737   by (auto intro: has_derivative_continuous simp: has_vector_derivative_def)
   738 
   739 lemma has_vector_derivative_mult_right[derivative_intros]:
   740   fixes a :: "'a::real_normed_algebra"
   741   shows "(f has_vector_derivative x) F \<Longrightarrow> ((\<lambda>x. a * f x) has_vector_derivative (a * x)) F"
   742   by (rule bounded_linear.has_vector_derivative[OF bounded_linear_mult_right])
   743 
   744 lemma has_vector_derivative_mult_left[derivative_intros]:
   745   fixes a :: "'a::real_normed_algebra"
   746   shows "(f has_vector_derivative x) F \<Longrightarrow> ((\<lambda>x. f x * a) has_vector_derivative (x * a)) F"
   747   by (rule bounded_linear.has_vector_derivative[OF bounded_linear_mult_left])
   748 
   749 
   750 subsection \<open>Derivatives\<close>
   751 
   752 lemma DERIV_D: "DERIV f x :> D \<Longrightarrow> (\<lambda>h. (f (x + h) - f x) / h) \<midarrow>0\<rightarrow> D"
   753   by (simp add: DERIV_def)
   754 
   755 lemma has_field_derivativeD:
   756   "(f has_field_derivative D) (at x within S) \<Longrightarrow>
   757     ((\<lambda>y. (f y - f x) / (y - x)) \<longlongrightarrow> D) (at x within S)"
   758   by (simp add: has_field_derivative_iff)
   759 
   760 lemma DERIV_const [simp, derivative_intros]: "((\<lambda>x. k) has_field_derivative 0) F"
   761   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_const]) auto
   762 
   763 lemma DERIV_ident [simp, derivative_intros]: "((\<lambda>x. x) has_field_derivative 1) F"
   764   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_ident]) auto
   765 
   766 lemma field_differentiable_add[derivative_intros]:
   767   "(f has_field_derivative f') F \<Longrightarrow> (g has_field_derivative g') F \<Longrightarrow>
   768     ((\<lambda>z. f z + g z) has_field_derivative f' + g') F"
   769   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_add])
   770      (auto simp: has_field_derivative_def field_simps mult_commute_abs)
   771 
   772 corollary DERIV_add:
   773   "(f has_field_derivative D) (at x within s) \<Longrightarrow> (g has_field_derivative E) (at x within s) \<Longrightarrow>
   774     ((\<lambda>x. f x + g x) has_field_derivative D + E) (at x within s)"
   775   by (rule field_differentiable_add)
   776 
   777 lemma field_differentiable_minus[derivative_intros]:
   778   "(f has_field_derivative f') F \<Longrightarrow> ((\<lambda>z. - (f z)) has_field_derivative -f') F"
   779   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_minus])
   780      (auto simp: has_field_derivative_def field_simps mult_commute_abs)
   781 
   782 corollary DERIV_minus:
   783   "(f has_field_derivative D) (at x within s) \<Longrightarrow>
   784     ((\<lambda>x. - f x) has_field_derivative -D) (at x within s)"
   785   by (rule field_differentiable_minus)
   786 
   787 lemma field_differentiable_diff[derivative_intros]:
   788   "(f has_field_derivative f') F \<Longrightarrow>
   789     (g has_field_derivative g') F \<Longrightarrow> ((\<lambda>z. f z - g z) has_field_derivative f' - g') F"
   790   by (simp only: diff_conv_add_uminus field_differentiable_add field_differentiable_minus)
   791 
   792 corollary DERIV_diff:
   793   "(f has_field_derivative D) (at x within s) \<Longrightarrow>
   794     (g has_field_derivative E) (at x within s) \<Longrightarrow>
   795     ((\<lambda>x. f x - g x) has_field_derivative D - E) (at x within s)"
   796   by (rule field_differentiable_diff)
   797 
   798 lemma DERIV_continuous: "(f has_field_derivative D) (at x within s) \<Longrightarrow> continuous (at x within s) f"
   799   by (drule has_derivative_continuous[OF has_field_derivative_imp_has_derivative]) simp
   800 
   801 corollary DERIV_isCont: "DERIV f x :> D \<Longrightarrow> isCont f x"
   802   by (rule DERIV_continuous)
   803 
   804 lemma DERIV_continuous_on:
   805   "(\<And>x. x \<in> s \<Longrightarrow> (f has_field_derivative (D x)) (at x within s)) \<Longrightarrow> continuous_on s f"
   806   unfolding continuous_on_eq_continuous_within
   807   by (intro continuous_at_imp_continuous_on ballI DERIV_continuous)
   808 
   809 lemma DERIV_mult':
   810   "(f has_field_derivative D) (at x within s) \<Longrightarrow> (g has_field_derivative E) (at x within s) \<Longrightarrow>
   811     ((\<lambda>x. f x * g x) has_field_derivative f x * E + D * g x) (at x within s)"
   812   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_mult])
   813      (auto simp: field_simps mult_commute_abs dest: has_field_derivative_imp_has_derivative)
   814 
   815 lemma DERIV_mult[derivative_intros]:
   816   "(f has_field_derivative Da) (at x within s) \<Longrightarrow> (g has_field_derivative Db) (at x within s) \<Longrightarrow>
   817     ((\<lambda>x. f x * g x) has_field_derivative Da * g x + Db * f x) (at x within s)"
   818   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_mult])
   819      (auto simp: field_simps dest: has_field_derivative_imp_has_derivative)
   820 
   821 text \<open>Derivative of linear multiplication\<close>
   822 
   823 lemma DERIV_cmult:
   824   "(f has_field_derivative D) (at x within s) \<Longrightarrow>
   825     ((\<lambda>x. c * f x) has_field_derivative c * D) (at x within s)"
   826   by (drule DERIV_mult' [OF DERIV_const]) simp
   827 
   828 lemma DERIV_cmult_right:
   829   "(f has_field_derivative D) (at x within s) \<Longrightarrow>
   830     ((\<lambda>x. f x * c) has_field_derivative D * c) (at x within s)"
   831   using DERIV_cmult by (auto simp add: ac_simps)
   832 
   833 lemma DERIV_cmult_Id [simp]: "(op * c has_field_derivative c) (at x within s)"
   834   using DERIV_ident [THEN DERIV_cmult, where c = c and x = x] by simp
   835 
   836 lemma DERIV_cdivide:
   837   "(f has_field_derivative D) (at x within s) \<Longrightarrow>
   838     ((\<lambda>x. f x / c) has_field_derivative D / c) (at x within s)"
   839   using DERIV_cmult_right[of f D x s "1 / c"] by simp
   840 
   841 lemma DERIV_unique: "DERIV f x :> D \<Longrightarrow> DERIV f x :> E \<Longrightarrow> D = E"
   842   unfolding DERIV_def by (rule LIM_unique)
   843 
   844 lemma DERIV_sum[derivative_intros]:
   845   "(\<And> n. n \<in> S \<Longrightarrow> ((\<lambda>x. f x n) has_field_derivative (f' x n)) F) \<Longrightarrow>
   846     ((\<lambda>x. sum (f x) S) has_field_derivative sum (f' x) S) F"
   847   by (rule has_derivative_imp_has_field_derivative [OF has_derivative_sum])
   848      (auto simp: sum_distrib_left mult_commute_abs dest: has_field_derivative_imp_has_derivative)
   849 
   850 lemma DERIV_inverse'[derivative_intros]:
   851   assumes "(f has_field_derivative D) (at x within s)"
   852     and "f x \<noteq> 0"
   853   shows "((\<lambda>x. inverse (f x)) has_field_derivative - (inverse (f x) * D * inverse (f x)))
   854     (at x within s)"
   855 proof -
   856   have "(f has_derivative (\<lambda>x. x * D)) = (f has_derivative op * D)"
   857     by (rule arg_cong [of "\<lambda>x. x * D"]) (simp add: fun_eq_iff)
   858   with assms have "(f has_derivative (\<lambda>x. x * D)) (at x within s)"
   859     by (auto dest!: has_field_derivative_imp_has_derivative)
   860   then show ?thesis using \<open>f x \<noteq> 0\<close>
   861     by (auto intro: has_derivative_imp_has_field_derivative has_derivative_inverse)
   862 qed
   863 
   864 text \<open>Power of \<open>-1\<close>\<close>
   865 
   866 lemma DERIV_inverse:
   867   "x \<noteq> 0 \<Longrightarrow> ((\<lambda>x. inverse(x)) has_field_derivative - (inverse x ^ Suc (Suc 0))) (at x within s)"
   868   by (drule DERIV_inverse' [OF DERIV_ident]) simp
   869 
   870 text \<open>Derivative of inverse\<close>
   871 
   872 lemma DERIV_inverse_fun:
   873   "(f has_field_derivative d) (at x within s) \<Longrightarrow> f x \<noteq> 0 \<Longrightarrow>
   874     ((\<lambda>x. inverse (f x)) has_field_derivative (- (d * inverse(f x ^ Suc (Suc 0))))) (at x within s)"
   875   by (drule (1) DERIV_inverse') (simp add: ac_simps nonzero_inverse_mult_distrib)
   876 
   877 text \<open>Derivative of quotient\<close>
   878 
   879 lemma DERIV_divide[derivative_intros]:
   880   "(f has_field_derivative D) (at x within s) \<Longrightarrow>
   881     (g has_field_derivative E) (at x within s) \<Longrightarrow> g x \<noteq> 0 \<Longrightarrow>
   882     ((\<lambda>x. f x / g x) has_field_derivative (D * g x - f x * E) / (g x * g x)) (at x within s)"
   883   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_divide])
   884      (auto dest: has_field_derivative_imp_has_derivative simp: field_simps)
   885 
   886 lemma DERIV_quotient:
   887   "(f has_field_derivative d) (at x within s) \<Longrightarrow>
   888     (g has_field_derivative e) (at x within s)\<Longrightarrow> g x \<noteq> 0 \<Longrightarrow>
   889     ((\<lambda>y. f y / g y) has_field_derivative (d * g x - (e * f x)) / (g x ^ Suc (Suc 0))) (at x within s)"
   890   by (drule (2) DERIV_divide) (simp add: mult.commute)
   891 
   892 lemma DERIV_power_Suc:
   893   "(f has_field_derivative D) (at x within s) \<Longrightarrow>
   894     ((\<lambda>x. f x ^ Suc n) has_field_derivative (1 + of_nat n) * (D * f x ^ n)) (at x within s)"
   895   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_power])
   896      (auto simp: has_field_derivative_def)
   897 
   898 lemma DERIV_power[derivative_intros]:
   899   "(f has_field_derivative D) (at x within s) \<Longrightarrow>
   900     ((\<lambda>x. f x ^ n) has_field_derivative of_nat n * (D * f x ^ (n - Suc 0))) (at x within s)"
   901   by (rule has_derivative_imp_has_field_derivative[OF has_derivative_power])
   902      (auto simp: has_field_derivative_def)
   903 
   904 lemma DERIV_pow: "((\<lambda>x. x ^ n) has_field_derivative real n * (x ^ (n - Suc 0))) (at x within s)"
   905   using DERIV_power [OF DERIV_ident] by simp
   906 
   907 lemma DERIV_chain': "(f has_field_derivative D) (at x within s) \<Longrightarrow> DERIV g (f x) :> E \<Longrightarrow>
   908   ((\<lambda>x. g (f x)) has_field_derivative E * D) (at x within s)"
   909   using has_derivative_compose[of f "op * D" x s g "op * E"]
   910   by (simp only: has_field_derivative_def mult_commute_abs ac_simps)
   911 
   912 corollary DERIV_chain2: "DERIV f (g x) :> Da \<Longrightarrow> (g has_field_derivative Db) (at x within s) \<Longrightarrow>
   913   ((\<lambda>x. f (g x)) has_field_derivative Da * Db) (at x within s)"
   914   by (rule DERIV_chain')
   915 
   916 text \<open>Standard version\<close>
   917 
   918 lemma DERIV_chain:
   919   "DERIV f (g x) :> Da \<Longrightarrow> (g has_field_derivative Db) (at x within s) \<Longrightarrow>
   920     (f \<circ> g has_field_derivative Da * Db) (at x within s)"
   921   by (drule (1) DERIV_chain', simp add: o_def mult.commute)
   922 
   923 lemma DERIV_image_chain:
   924   "(f has_field_derivative Da) (at (g x) within (g ` s)) \<Longrightarrow>
   925     (g has_field_derivative Db) (at x within s) \<Longrightarrow>
   926     (f \<circ> g has_field_derivative Da * Db) (at x within s)"
   927   using has_derivative_in_compose [of g "op * Db" x s f "op * Da "]
   928   by (simp add: has_field_derivative_def o_def mult_commute_abs ac_simps)
   929 
   930 (*These two are from HOL Light: HAS_COMPLEX_DERIVATIVE_CHAIN*)
   931 lemma DERIV_chain_s:
   932   assumes "(\<And>x. x \<in> s \<Longrightarrow> DERIV g x :> g'(x))"
   933     and "DERIV f x :> f'"
   934     and "f x \<in> s"
   935   shows "DERIV (\<lambda>x. g(f x)) x :> f' * g'(f x)"
   936   by (metis (full_types) DERIV_chain' mult.commute assms)
   937 
   938 lemma DERIV_chain3: (*HAS_COMPLEX_DERIVATIVE_CHAIN_UNIV*)
   939   assumes "(\<And>x. DERIV g x :> g'(x))"
   940     and "DERIV f x :> f'"
   941   shows "DERIV (\<lambda>x. g(f x)) x :> f' * g'(f x)"
   942   by (metis UNIV_I DERIV_chain_s [of UNIV] assms)
   943 
   944 text \<open>Alternative definition for differentiability\<close>
   945 
   946 lemma DERIV_LIM_iff:
   947   fixes f :: "'a::{real_normed_vector,inverse} \<Rightarrow> 'a"
   948   shows "((\<lambda>h. (f (a + h) - f a) / h) \<midarrow>0\<rightarrow> D) = ((\<lambda>x. (f x - f a) / (x - a)) \<midarrow>a\<rightarrow> D)"
   949   apply (rule iffI)
   950    apply (drule_tac k="- a" in LIM_offset)
   951    apply simp
   952   apply (drule_tac k="a" in LIM_offset)
   953   apply (simp add: add.commute)
   954   done
   955 
   956 lemmas DERIV_iff2 = has_field_derivative_iff
   957 
   958 lemma has_field_derivative_cong_ev:
   959   assumes "x = y"
   960     and *: "eventually (\<lambda>x. x \<in> s \<longrightarrow> f x = g x) (nhds x)"
   961     and "u = v" "s = t" "x \<in> s"
   962   shows "(f has_field_derivative u) (at x within s) = (g has_field_derivative v) (at y within t)"
   963   unfolding DERIV_iff2
   964 proof (rule filterlim_cong)
   965   from assms have "f y = g y"
   966     by (auto simp: eventually_nhds)
   967   with * show "\<forall>\<^sub>F xa in at x within s. (f xa - f x) / (xa - x) = (g xa - g y) / (xa - y)"
   968     unfolding eventually_at_filter
   969     by eventually_elim (auto simp: assms \<open>f y = g y\<close>)
   970 qed (simp_all add: assms)
   971 
   972 lemma DERIV_cong_ev:
   973   "x = y \<Longrightarrow> eventually (\<lambda>x. f x = g x) (nhds x) \<Longrightarrow> u = v \<Longrightarrow>
   974     DERIV f x :> u \<longleftrightarrow> DERIV g y :> v"
   975   by (rule has_field_derivative_cong_ev) simp_all
   976 
   977 lemma DERIV_shift:
   978   "(f has_field_derivative y) (at (x + z)) = ((\<lambda>x. f (x + z)) has_field_derivative y) (at x)"
   979   by (simp add: DERIV_def field_simps)
   980 
   981 lemma DERIV_mirror: "(DERIV f (- x) :> y) \<longleftrightarrow> (DERIV (\<lambda>x. f (- x)) x :> - y)"
   982   for f :: "real \<Rightarrow> real" and x y :: real
   983   by (simp add: DERIV_def filterlim_at_split filterlim_at_left_to_right
   984       tendsto_minus_cancel_left field_simps conj_commute)
   985 
   986 lemma floor_has_real_derivative:
   987   fixes f :: "real \<Rightarrow> 'a::{floor_ceiling,order_topology}"
   988   assumes "isCont f x"
   989     and "f x \<notin> \<int>"
   990   shows "((\<lambda>x. floor (f x)) has_real_derivative 0) (at x)"
   991 proof (subst DERIV_cong_ev[OF refl _ refl])
   992   show "((\<lambda>_. floor (f x)) has_real_derivative 0) (at x)"
   993     by simp
   994   have "\<forall>\<^sub>F y in at x. \<lfloor>f y\<rfloor> = \<lfloor>f x\<rfloor>"
   995     by (rule eventually_floor_eq[OF assms[unfolded continuous_at]])
   996   then show "\<forall>\<^sub>F y in nhds x. real_of_int \<lfloor>f y\<rfloor> = real_of_int \<lfloor>f x\<rfloor>"
   997     unfolding eventually_at_filter
   998     by eventually_elim auto
   999 qed
  1000 
  1001 
  1002 text \<open>Caratheodory formulation of derivative at a point\<close>
  1003 
  1004 lemma CARAT_DERIV: (*FIXME: SUPERSEDED BY THE ONE IN Deriv.thy. But still used by NSA/HDeriv.thy*)
  1005   "(DERIV f x :> l) \<longleftrightarrow> (\<exists>g. (\<forall>z. f z - f x = g z * (z - x)) \<and> isCont g x \<and> g x = l)"
  1006   (is "?lhs = ?rhs")
  1007 proof
  1008   assume ?lhs
  1009   show "\<exists>g. (\<forall>z. f z - f x = g z * (z - x)) \<and> isCont g x \<and> g x = l"
  1010   proof (intro exI conjI)
  1011     let ?g = "(\<lambda>z. if z = x then l else (f z - f x) / (z-x))"
  1012     show "\<forall>z. f z - f x = ?g z * (z - x)"
  1013       by simp
  1014     show "isCont ?g x"
  1015       using \<open>?lhs\<close> by (simp add: isCont_iff DERIV_def cong: LIM_equal [rule_format])
  1016     show "?g x = l"
  1017       by simp
  1018   qed
  1019 next
  1020   assume ?rhs
  1021   then obtain g where "(\<forall>z. f z - f x = g z * (z - x))" and "isCont g x" and "g x = l"
  1022     by blast
  1023   then show ?lhs
  1024     by (auto simp add: isCont_iff DERIV_def cong: LIM_cong)
  1025 qed
  1026 
  1027 
  1028 subsection \<open>Local extrema\<close>
  1029 
  1030 text \<open>If @{term "0 < f' x"} then @{term x} is Locally Strictly Increasing At The Right.\<close>
  1031 
  1032 lemma has_real_derivative_pos_inc_right:
  1033   fixes f :: "real \<Rightarrow> real"
  1034   assumes der: "(f has_real_derivative l) (at x within S)"
  1035     and l: "0 < l"
  1036   shows "\<exists>d > 0. \<forall>h > 0. x + h \<in> S \<longrightarrow> h < d \<longrightarrow> f x < f (x + h)"
  1037   using assms
  1038 proof -
  1039   from der [THEN has_field_derivativeD, THEN tendstoD, OF l, unfolded eventually_at]
  1040   obtain s where s: "0 < s"
  1041     and all: "\<And>xa. xa\<in>S \<Longrightarrow> xa \<noteq> x \<and> dist xa x < s \<longrightarrow> \<bar>(f xa - f x) / (xa - x) - l\<bar> < l"
  1042     by (auto simp: dist_real_def)
  1043   then show ?thesis
  1044   proof (intro exI conjI strip)
  1045     show "0 < s" by (rule s)
  1046   next
  1047     fix h :: real
  1048     assume "0 < h" "h < s" "x + h \<in> S"
  1049     with all [of "x + h"] show "f x < f (x+h)"
  1050     proof (simp add: abs_if dist_real_def pos_less_divide_eq split: if_split_asm)
  1051       assume "\<not> (f (x + h) - f x) / h < l" and h: "0 < h"
  1052       with l have "0 < (f (x + h) - f x) / h"
  1053         by arith
  1054       then show "f x < f (x + h)"
  1055         by (simp add: pos_less_divide_eq h)
  1056     qed
  1057   qed
  1058 qed
  1059 
  1060 lemma DERIV_pos_inc_right:
  1061   fixes f :: "real \<Rightarrow> real"
  1062   assumes der: "DERIV f x :> l"
  1063     and l: "0 < l"
  1064   shows "\<exists>d > 0. \<forall>h > 0. h < d \<longrightarrow> f x < f (x + h)"
  1065   using has_real_derivative_pos_inc_right[OF assms]
  1066   by auto
  1067 
  1068 lemma has_real_derivative_neg_dec_left:
  1069   fixes f :: "real \<Rightarrow> real"
  1070   assumes der: "(f has_real_derivative l) (at x within S)"
  1071     and "l < 0"
  1072   shows "\<exists>d > 0. \<forall>h > 0. x - h \<in> S \<longrightarrow> h < d \<longrightarrow> f x < f (x - h)"
  1073 proof -
  1074   from \<open>l < 0\<close> have l: "- l > 0"
  1075     by simp
  1076   from der [THEN has_field_derivativeD, THEN tendstoD, OF l, unfolded eventually_at]
  1077   obtain s where s: "0 < s"
  1078     and all: "\<And>xa. xa\<in>S \<Longrightarrow> xa \<noteq> x \<and> dist xa x < s \<longrightarrow> \<bar>(f xa - f x) / (xa - x) - l\<bar> < - l"
  1079     by (auto simp: dist_real_def)
  1080   then show ?thesis
  1081   proof (intro exI conjI strip)
  1082     show "0 < s" by (rule s)
  1083   next
  1084     fix h :: real
  1085     assume "0 < h" "h < s" "x - h \<in> S"
  1086     with all [of "x - h"] show "f x < f (x-h)"
  1087     proof (simp add: abs_if pos_less_divide_eq dist_real_def split: if_split_asm)
  1088       assume "- ((f (x-h) - f x) / h) < l" and h: "0 < h"
  1089       with l have "0 < (f (x-h) - f x) / h"
  1090         by arith
  1091       then show "f x < f (x - h)"
  1092         by (simp add: pos_less_divide_eq h)
  1093     qed
  1094   qed
  1095 qed
  1096 
  1097 lemma DERIV_neg_dec_left:
  1098   fixes f :: "real \<Rightarrow> real"
  1099   assumes der: "DERIV f x :> l"
  1100     and l: "l < 0"
  1101   shows "\<exists>d > 0. \<forall>h > 0. h < d \<longrightarrow> f x < f (x - h)"
  1102   using has_real_derivative_neg_dec_left[OF assms]
  1103   by auto
  1104 
  1105 lemma has_real_derivative_pos_inc_left:
  1106   fixes f :: "real \<Rightarrow> real"
  1107   shows "(f has_real_derivative l) (at x within S) \<Longrightarrow> 0 < l \<Longrightarrow>
  1108     \<exists>d>0. \<forall>h>0. x - h \<in> S \<longrightarrow> h < d \<longrightarrow> f (x - h) < f x"
  1109   by (rule has_real_derivative_neg_dec_left [of "\<lambda>x. - f x" "-l" x S, simplified])
  1110       (auto simp add: DERIV_minus)
  1111 
  1112 lemma DERIV_pos_inc_left:
  1113   fixes f :: "real \<Rightarrow> real"
  1114   shows "DERIV f x :> l \<Longrightarrow> 0 < l \<Longrightarrow> \<exists>d > 0. \<forall>h > 0. h < d \<longrightarrow> f (x - h) < f x"
  1115   using has_real_derivative_pos_inc_left
  1116   by blast
  1117 
  1118 lemma has_real_derivative_neg_dec_right:
  1119   fixes f :: "real \<Rightarrow> real"
  1120   shows "(f has_real_derivative l) (at x within S) \<Longrightarrow> l < 0 \<Longrightarrow>
  1121     \<exists>d > 0. \<forall>h > 0. x + h \<in> S \<longrightarrow> h < d \<longrightarrow> f x > f (x + h)"
  1122   by (rule has_real_derivative_pos_inc_right [of "\<lambda>x. - f x" "-l" x S, simplified])
  1123       (auto simp add: DERIV_minus)
  1124 
  1125 lemma DERIV_neg_dec_right:
  1126   fixes f :: "real \<Rightarrow> real"
  1127   shows "DERIV f x :> l \<Longrightarrow> l < 0 \<Longrightarrow> \<exists>d > 0. \<forall>h > 0. h < d \<longrightarrow> f x > f (x + h)"
  1128   using has_real_derivative_neg_dec_right by blast
  1129 
  1130 lemma DERIV_local_max:
  1131   fixes f :: "real \<Rightarrow> real"
  1132   assumes der: "DERIV f x :> l"
  1133     and d: "0 < d"
  1134     and le: "\<forall>y. \<bar>x - y\<bar> < d \<longrightarrow> f y \<le> f x"
  1135   shows "l = 0"
  1136 proof (cases rule: linorder_cases [of l 0])
  1137   case equal
  1138   then show ?thesis .
  1139 next
  1140   case less
  1141   from DERIV_neg_dec_left [OF der less]
  1142   obtain d' where d': "0 < d'" and lt: "\<forall>h > 0. h < d' \<longrightarrow> f x < f (x - h)"
  1143     by blast
  1144   obtain e where "0 < e \<and> e < d \<and> e < d'"
  1145     using real_lbound_gt_zero [OF d d']  ..
  1146   with lt le [THEN spec [where x="x - e"]] show ?thesis
  1147     by (auto simp add: abs_if)
  1148 next
  1149   case greater
  1150   from DERIV_pos_inc_right [OF der greater]
  1151   obtain d' where d': "0 < d'" and lt: "\<forall>h > 0. h < d' \<longrightarrow> f x < f (x + h)"
  1152     by blast
  1153   obtain e where "0 < e \<and> e < d \<and> e < d'"
  1154     using real_lbound_gt_zero [OF d d'] ..
  1155   with lt le [THEN spec [where x="x + e"]] show ?thesis
  1156     by (auto simp add: abs_if)
  1157 qed
  1158 
  1159 text \<open>Similar theorem for a local minimum\<close>
  1160 lemma DERIV_local_min:
  1161   fixes f :: "real \<Rightarrow> real"
  1162   shows "DERIV f x :> l \<Longrightarrow> 0 < d \<Longrightarrow> \<forall>y. \<bar>x - y\<bar> < d \<longrightarrow> f x \<le> f y \<Longrightarrow> l = 0"
  1163   by (drule DERIV_minus [THEN DERIV_local_max]) auto
  1164 
  1165 
  1166 text\<open>In particular, if a function is locally flat\<close>
  1167 lemma DERIV_local_const:
  1168   fixes f :: "real \<Rightarrow> real"
  1169   shows "DERIV f x :> l \<Longrightarrow> 0 < d \<Longrightarrow> \<forall>y. \<bar>x - y\<bar> < d \<longrightarrow> f x = f y \<Longrightarrow> l = 0"
  1170   by (auto dest!: DERIV_local_max)
  1171 
  1172 
  1173 subsection \<open>Rolle's Theorem\<close>
  1174 
  1175 text \<open>Lemma about introducing open ball in open interval\<close>
  1176 lemma lemma_interval_lt: "a < x \<Longrightarrow> x < b \<Longrightarrow> \<exists>d. 0 < d \<and> (\<forall>y. \<bar>x - y\<bar> < d \<longrightarrow> a < y \<and> y < b)"
  1177   for a b x :: real
  1178   apply (simp add: abs_less_iff)
  1179   apply (insert linorder_linear [of "x - a" "b - x"])
  1180   apply safe
  1181    apply (rule_tac x = "x - a" in exI)
  1182    apply (rule_tac [2] x = "b - x" in exI)
  1183    apply auto
  1184   done
  1185 
  1186 lemma lemma_interval: "a < x \<Longrightarrow> x < b \<Longrightarrow> \<exists>d. 0 < d \<and> (\<forall>y. \<bar>x - y\<bar> < d \<longrightarrow> a \<le> y \<and> y \<le> b)"
  1187   for a b x :: real
  1188   apply (drule lemma_interval_lt)
  1189    apply auto
  1190   apply force
  1191   done
  1192 
  1193 text \<open>Rolle's Theorem.
  1194    If @{term f} is defined and continuous on the closed interval
  1195    \<open>[a,b]\<close> and differentiable on the open interval \<open>(a,b)\<close>,
  1196    and @{term "f a = f b"},
  1197    then there exists \<open>x0 \<in> (a,b)\<close> such that @{term "f' x0 = 0"}\<close>
  1198 theorem Rolle:
  1199   fixes a b :: real
  1200   assumes lt: "a < b"
  1201     and eq: "f a = f b"
  1202     and con: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x"
  1203     and dif [rule_format]: "\<forall>x. a < x \<and> x < b \<longrightarrow> f differentiable (at x)"
  1204   shows "\<exists>z. a < z \<and> z < b \<and> DERIV f z :> 0"
  1205 proof -
  1206   have le: "a \<le> b"
  1207     using lt by simp
  1208   from isCont_eq_Ub [OF le con]
  1209   obtain x where x_max: "\<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> f z \<le> f x" and "a \<le> x" "x \<le> b"
  1210     by blast
  1211   from isCont_eq_Lb [OF le con]
  1212   obtain x' where x'_min: "\<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> f x' \<le> f z" and "a \<le> x'" "x' \<le> b"
  1213     by blast
  1214   consider "a < x" "x < b" | "x = a \<or> x = b"
  1215     using \<open>a \<le> x\<close> \<open>x \<le> b\<close> by arith
  1216   then show ?thesis
  1217   proof cases
  1218     case 1
  1219     \<comment>\<open>@{term f} attains its maximum within the interval\<close>
  1220     obtain d where d: "0 < d" and bound: "\<forall>y. \<bar>x - y\<bar> < d \<longrightarrow> a \<le> y \<and> y \<le> b"
  1221       using lemma_interval [OF 1] by blast
  1222     then have bound': "\<forall>y. \<bar>x - y\<bar> < d \<longrightarrow> f y \<le> f x"
  1223       using x_max by blast
  1224     obtain l where der: "DERIV f x :> l"
  1225       using differentiableD [OF dif [OF conjI [OF 1]]] ..
  1226     \<comment>\<open>the derivative at a local maximum is zero\<close>
  1227     have "l = 0"
  1228       by (rule DERIV_local_max [OF der d bound'])
  1229     with 1 der show ?thesis by auto
  1230   next
  1231     case 2
  1232     then have fx: "f b = f x" by (auto simp add: eq)
  1233     consider "a < x'" "x' < b" | "x' = a \<or> x' = b"
  1234       using \<open>a \<le> x'\<close> \<open>x' \<le> b\<close> by arith
  1235     then show ?thesis
  1236     proof cases
  1237       case 1
  1238         \<comment> \<open>@{term f} attains its minimum within the interval\<close>
  1239       from lemma_interval [OF 1]
  1240       obtain d where d: "0<d" and bound: "\<forall>y. \<bar>x'-y\<bar> < d \<longrightarrow> a \<le> y \<and> y \<le> b"
  1241         by blast
  1242       then have bound': "\<forall>y. \<bar>x' - y\<bar> < d \<longrightarrow> f x' \<le> f y"
  1243         using x'_min by blast
  1244       from differentiableD [OF dif [OF conjI [OF 1]]]
  1245       obtain l where der: "DERIV f x' :> l" ..
  1246       have "l = 0" by (rule DERIV_local_min [OF der d bound'])
  1247         \<comment> \<open>the derivative at a local minimum is zero\<close>
  1248       then show ?thesis using 1 der by auto
  1249     next
  1250       case 2
  1251         \<comment> \<open>@{term f} is constant throughout the interval\<close>
  1252       then have fx': "f b = f x'" by (auto simp: eq)
  1253       from dense [OF lt] obtain r where r: "a < r" "r < b" by blast
  1254       obtain d where d: "0 < d" and bound: "\<forall>y. \<bar>r - y\<bar> < d \<longrightarrow> a \<le> y \<and> y \<le> b"
  1255         using lemma_interval [OF r] by blast
  1256       have eq_fb: "f z = f b" if "a \<le> z" and "z \<le> b" for z
  1257       proof (rule order_antisym)
  1258         show "f z \<le> f b" by (simp add: fx x_max that)
  1259         show "f b \<le> f z" by (simp add: fx' x'_min that)
  1260       qed
  1261       have bound': "\<forall>y. \<bar>r - y\<bar> < d \<longrightarrow> f r = f y"
  1262       proof (intro strip)
  1263         fix y :: real
  1264         assume lt: "\<bar>r - y\<bar> < d"
  1265         then have "f y = f b" by (simp add: eq_fb bound)
  1266         then show "f r = f y" by (simp add: eq_fb r order_less_imp_le)
  1267       qed
  1268       obtain l where der: "DERIV f r :> l"
  1269         using differentiableD [OF dif [OF conjI [OF r]]] ..
  1270       have "l = 0"
  1271         by (rule DERIV_local_const [OF der d bound'])
  1272         \<comment> \<open>the derivative of a constant function is zero\<close>
  1273       with r der show ?thesis by auto
  1274     qed
  1275   qed
  1276 qed
  1277 
  1278 
  1279 subsection \<open>Mean Value Theorem\<close>
  1280 
  1281 lemma lemma_MVT: "f a - (f b - f a) / (b - a) * a = f b - (f b - f a) / (b - a) * b"
  1282   for a b :: real
  1283   by (cases "a = b") (simp_all add: field_simps)
  1284 
  1285 theorem MVT:
  1286   fixes a b :: real
  1287   assumes lt: "a < b"
  1288     and con: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x"
  1289     and dif [rule_format]: "\<forall>x. a < x \<and> x < b \<longrightarrow> f differentiable (at x)"
  1290   shows "\<exists>l z. a < z \<and> z < b \<and> DERIV f z :> l \<and> f b - f a = (b - a) * l"
  1291 proof -
  1292   let ?F = "\<lambda>x. f x - ((f b - f a) / (b - a)) * x"
  1293   have cont_f: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont ?F x"
  1294     using con by (fast intro: continuous_intros)
  1295   have dif_f: "\<forall>x. a < x \<and> x < b \<longrightarrow> ?F differentiable (at x)"
  1296   proof clarify
  1297     fix x :: real
  1298     assume x: "a < x" "x < b"
  1299     obtain l where der: "DERIV f x :> l"
  1300       using differentiableD [OF dif [OF conjI [OF x]]] ..
  1301     show "?F differentiable (at x)"
  1302       by (rule differentiableI [where D = "l - (f b - f a) / (b - a)"],
  1303           blast intro: DERIV_diff DERIV_cmult_Id der)
  1304   qed
  1305   from Rolle [where f = ?F, OF lt lemma_MVT cont_f dif_f]
  1306   obtain z where z: "a < z" "z < b" and der: "DERIV ?F z :> 0"
  1307     by blast
  1308   have "DERIV (\<lambda>x. ((f b - f a) / (b - a)) * x) z :> (f b - f a) / (b - a)"
  1309     by (rule DERIV_cmult_Id)
  1310   then have der_f: "DERIV (\<lambda>x. ?F x + (f b - f a) / (b - a) * x) z :> 0 + (f b - f a) / (b - a)"
  1311     by (rule DERIV_add [OF der])
  1312   show ?thesis
  1313   proof (intro exI conjI)
  1314     show "a < z" and "z < b" using z .
  1315     show "f b - f a = (b - a) * ((f b - f a) / (b - a))" by simp
  1316     show "DERIV f z :> ((f b - f a) / (b - a))" using der_f by simp
  1317   qed
  1318 qed
  1319 
  1320 lemma MVT2:
  1321   "a < b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> DERIV f x :> f' x \<Longrightarrow>
  1322     \<exists>z::real. a < z \<and> z < b \<and> (f b - f a = (b - a) * f' z)"
  1323   apply (drule MVT)
  1324     apply (blast intro: DERIV_isCont)
  1325    apply (force dest: order_less_imp_le simp add: real_differentiable_def)
  1326   apply (blast dest: DERIV_unique order_less_imp_le)
  1327   done
  1328 
  1329 
  1330 text \<open>A function is constant if its derivative is 0 over an interval.\<close>
  1331 
  1332 lemma DERIV_isconst_end:
  1333   fixes f :: "real \<Rightarrow> real"
  1334   shows "a < b \<Longrightarrow>
  1335     \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1336     \<forall>x. a < x \<and> x < b \<longrightarrow> DERIV f x :> 0 \<Longrightarrow> f b = f a"
  1337   apply (drule (1) MVT)
  1338    apply (blast intro: differentiableI)
  1339   apply (auto dest!: DERIV_unique simp add: diff_eq_eq)
  1340   done
  1341 
  1342 lemma DERIV_isconst1:
  1343   fixes f :: "real \<Rightarrow> real"
  1344   shows "a < b \<Longrightarrow>
  1345     \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1346     \<forall>x. a < x \<and> x < b \<longrightarrow> DERIV f x :> 0 \<Longrightarrow>
  1347     \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x = f a"
  1348   apply safe
  1349   apply (drule_tac x = a in order_le_imp_less_or_eq)
  1350   apply safe
  1351   apply (drule_tac b = x in DERIV_isconst_end)
  1352     apply auto
  1353   done
  1354 
  1355 lemma DERIV_isconst2:
  1356   fixes f :: "real \<Rightarrow> real"
  1357   shows "a < b \<Longrightarrow>
  1358     \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1359     \<forall>x. a < x \<and> x < b \<longrightarrow> DERIV f x :> 0 \<Longrightarrow>
  1360     a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> f x = f a"
  1361   by (blast dest: DERIV_isconst1)
  1362 
  1363 lemma DERIV_isconst3:
  1364   fixes a b x y :: real
  1365   assumes "a < b"
  1366     and "x \<in> {a <..< b}"
  1367     and "y \<in> {a <..< b}"
  1368     and derivable: "\<And>x. x \<in> {a <..< b} \<Longrightarrow> DERIV f x :> 0"
  1369   shows "f x = f y"
  1370 proof (cases "x = y")
  1371   case False
  1372   let ?a = "min x y"
  1373   let ?b = "max x y"
  1374 
  1375   have "\<forall>z. ?a \<le> z \<and> z \<le> ?b \<longrightarrow> DERIV f z :> 0"
  1376   proof (rule allI, rule impI)
  1377     fix z :: real
  1378     assume "?a \<le> z \<and> z \<le> ?b"
  1379     then have "a < z" and "z < b"
  1380       using \<open>x \<in> {a <..< b}\<close> and \<open>y \<in> {a <..< b}\<close> by auto
  1381     then have "z \<in> {a<..<b}" by auto
  1382     then show "DERIV f z :> 0" by (rule derivable)
  1383   qed
  1384   then have isCont: "\<forall>z. ?a \<le> z \<and> z \<le> ?b \<longrightarrow> isCont f z"
  1385     and DERIV: "\<forall>z. ?a < z \<and> z < ?b \<longrightarrow> DERIV f z :> 0"
  1386     using DERIV_isCont by auto
  1387 
  1388   have "?a < ?b" using \<open>x \<noteq> y\<close> by auto
  1389   from DERIV_isconst2[OF this isCont DERIV, of x] and DERIV_isconst2[OF this isCont DERIV, of y]
  1390   show ?thesis by auto
  1391 qed auto
  1392 
  1393 lemma DERIV_isconst_all:
  1394   fixes f :: "real \<Rightarrow> real"
  1395   shows "\<forall>x. DERIV f x :> 0 \<Longrightarrow> f x = f y"
  1396   apply (rule linorder_cases [of x y])
  1397     apply (blast intro: sym DERIV_isCont DERIV_isconst_end)+
  1398   done
  1399 
  1400 lemma DERIV_const_ratio_const:
  1401   fixes f :: "real \<Rightarrow> real"
  1402   shows "a \<noteq> b \<Longrightarrow> \<forall>x. DERIV f x :> k \<Longrightarrow> f b - f a = (b - a) * k"
  1403   apply (rule linorder_cases [of a b])
  1404     apply auto
  1405    apply (drule_tac [!] f = f in MVT)
  1406        apply (auto dest: DERIV_isCont DERIV_unique simp: real_differentiable_def)
  1407   apply (auto dest: DERIV_unique simp: ring_distribs)
  1408   done
  1409 
  1410 lemma DERIV_const_ratio_const2:
  1411   fixes f :: "real \<Rightarrow> real"
  1412   shows "a \<noteq> b \<Longrightarrow> \<forall>x. DERIV f x :> k \<Longrightarrow> (f b - f a) / (b - a) = k"
  1413   apply (rule_tac c1 = "b-a" in mult_right_cancel [THEN iffD1])
  1414    apply (auto dest!: DERIV_const_ratio_const simp add: mult.assoc)
  1415   done
  1416 
  1417 lemma real_average_minus_first [simp]: "(a + b) / 2 - a = (b - a) / 2"
  1418   for a b :: real
  1419   by simp
  1420 
  1421 lemma real_average_minus_second [simp]: "(b + a) / 2 - a = (b - a) / 2"
  1422   for a b :: real
  1423   by simp
  1424 
  1425 text \<open>Gallileo's "trick": average velocity = av. of end velocities.\<close>
  1426 
  1427 lemma DERIV_const_average:
  1428   fixes v :: "real \<Rightarrow> real"
  1429     and a b :: real
  1430   assumes neq: "a \<noteq> b"
  1431     and der: "\<forall>x. DERIV v x :> k"
  1432   shows "v ((a + b) / 2) = (v a + v b) / 2"
  1433 proof (cases rule: linorder_cases [of a b])
  1434   case equal
  1435   with neq show ?thesis by simp
  1436 next
  1437   case less
  1438   have "(v b - v a) / (b - a) = k"
  1439     by (rule DERIV_const_ratio_const2 [OF neq der])
  1440   then have "(b - a) * ((v b - v a) / (b - a)) = (b - a) * k"
  1441     by simp
  1442   moreover have "(v ((a + b) / 2) - v a) / ((a + b) / 2 - a) = k"
  1443     by (rule DERIV_const_ratio_const2 [OF _ der]) (simp add: neq)
  1444   ultimately show ?thesis
  1445     using neq by force
  1446 next
  1447   case greater
  1448   have "(v b - v a) / (b - a) = k"
  1449     by (rule DERIV_const_ratio_const2 [OF neq der])
  1450   then have "(b - a) * ((v b - v a) / (b - a)) = (b - a) * k"
  1451     by simp
  1452   moreover have " (v ((b + a) / 2) - v a) / ((b + a) / 2 - a) = k"
  1453     by (rule DERIV_const_ratio_const2 [OF _ der]) (simp add: neq)
  1454   ultimately show ?thesis
  1455     using neq by (force simp add: add.commute)
  1456 qed
  1457 
  1458 text \<open>
  1459   A function with positive derivative is increasing.
  1460   A simple proof using the MVT, by Jeremy Avigad. And variants.
  1461 \<close>
  1462 lemma DERIV_pos_imp_increasing_open:
  1463   fixes a b :: real
  1464     and f :: "real \<Rightarrow> real"
  1465   assumes "a < b"
  1466     and "\<And>x. a < x \<Longrightarrow> x < b \<Longrightarrow> (\<exists>y. DERIV f x :> y \<and> y > 0)"
  1467     and con: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> isCont f x"
  1468   shows "f a < f b"
  1469 proof (rule ccontr)
  1470   assume f: "\<not> ?thesis"
  1471   have "\<exists>l z. a < z \<and> z < b \<and> DERIV f z :> l \<and> f b - f a = (b - a) * l"
  1472     by (rule MVT) (use assms Deriv.differentiableI in \<open>force+\<close>)
  1473   then obtain l z where z: "a < z" "z < b" "DERIV f z :> l" and "f b - f a = (b - a) * l"
  1474     by auto
  1475   with assms f have "\<not> l > 0"
  1476     by (metis linorder_not_le mult_le_0_iff diff_le_0_iff_le)
  1477   with assms z show False
  1478     by (metis DERIV_unique)
  1479 qed
  1480 
  1481 lemma DERIV_pos_imp_increasing:
  1482   fixes a b :: real
  1483     and f :: "real \<Rightarrow> real"
  1484   assumes "a < b"
  1485     and "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> (\<exists>y. DERIV f x :> y \<and> y > 0)"
  1486   shows "f a < f b"
  1487   by (metis DERIV_pos_imp_increasing_open [of a b f] assms DERIV_continuous less_imp_le)
  1488 
  1489 lemma DERIV_nonneg_imp_nondecreasing:
  1490   fixes a b :: real
  1491     and f :: "real \<Rightarrow> real"
  1492   assumes "a \<le> b"
  1493     and "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> (\<exists>y. DERIV f x :> y \<and> y \<ge> 0)"
  1494   shows "f a \<le> f b"
  1495 proof (rule ccontr, cases "a = b")
  1496   assume "\<not> ?thesis" and "a = b"
  1497   then show False by auto
  1498 next
  1499   assume *: "\<not> ?thesis"
  1500   assume "a \<noteq> b"
  1501   with assms have "\<exists>l z. a < z \<and> z < b \<and> DERIV f z :> l \<and> f b - f a = (b - a) * l"
  1502     apply -
  1503     apply (rule MVT)
  1504       apply auto
  1505      apply (metis DERIV_isCont)
  1506     apply (metis differentiableI less_le)
  1507     done
  1508   then obtain l z where lz: "a < z" "z < b" "DERIV f z :> l" and **: "f b - f a = (b - a) * l"
  1509     by auto
  1510   with * have "a < b" "f b < f a" by auto
  1511   with ** have "\<not> l \<ge> 0" by (auto simp add: not_le algebra_simps)
  1512     (metis * add_le_cancel_right assms(1) less_eq_real_def mult_right_mono add_left_mono linear order_refl)
  1513   with assms lz show False
  1514     by (metis DERIV_unique order_less_imp_le)
  1515 qed
  1516 
  1517 lemma DERIV_neg_imp_decreasing_open:
  1518   fixes a b :: real
  1519     and f :: "real \<Rightarrow> real"
  1520   assumes "a < b"
  1521     and "\<And>x. a < x \<Longrightarrow> x < b \<Longrightarrow> (\<exists>y. DERIV f x :> y \<and> y < 0)"
  1522     and con: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> isCont f x"
  1523   shows "f a > f b"
  1524 proof -
  1525   have "(\<lambda>x. -f x) a < (\<lambda>x. -f x) b"
  1526     apply (rule DERIV_pos_imp_increasing_open [of a b "\<lambda>x. -f x"])
  1527     using assms
  1528       apply auto
  1529     apply (metis field_differentiable_minus neg_0_less_iff_less)
  1530     done
  1531   then show ?thesis
  1532     by simp
  1533 qed
  1534 
  1535 lemma DERIV_neg_imp_decreasing:
  1536   fixes a b :: real
  1537     and f :: "real \<Rightarrow> real"
  1538   assumes "a < b"
  1539     and "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> (\<exists>y. DERIV f x :> y \<and> y < 0)"
  1540   shows "f a > f b"
  1541   by (metis DERIV_neg_imp_decreasing_open [of a b f] assms DERIV_continuous less_imp_le)
  1542 
  1543 lemma DERIV_nonpos_imp_nonincreasing:
  1544   fixes a b :: real
  1545     and f :: "real \<Rightarrow> real"
  1546   assumes "a \<le> b"
  1547     and "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> (\<exists>y. DERIV f x :> y \<and> y \<le> 0)"
  1548   shows "f a \<ge> f b"
  1549 proof -
  1550   have "(\<lambda>x. -f x) a \<le> (\<lambda>x. -f x) b"
  1551     apply (rule DERIV_nonneg_imp_nondecreasing [of a b "\<lambda>x. -f x"])
  1552     using assms
  1553      apply auto
  1554     apply (metis DERIV_minus neg_0_le_iff_le)
  1555     done
  1556   then show ?thesis
  1557     by simp
  1558 qed
  1559 
  1560 lemma DERIV_pos_imp_increasing_at_bot:
  1561   fixes f :: "real \<Rightarrow> real"
  1562   assumes "\<And>x. x \<le> b \<Longrightarrow> (\<exists>y. DERIV f x :> y \<and> y > 0)"
  1563     and lim: "(f \<longlongrightarrow> flim) at_bot"
  1564   shows "flim < f b"
  1565 proof -
  1566   have "\<exists>N. \<forall>n\<le>N. f n \<le> f (b - 1)"
  1567     apply (rule_tac x="b - 2" in exI)
  1568     apply (force intro: order.strict_implies_order DERIV_pos_imp_increasing [where f=f] assms)
  1569     done
  1570   then have "flim \<le> f (b - 1)"
  1571      by (auto simp: trivial_limit_at_bot_linorder eventually_at_bot_linorder tendsto_upperbound [OF lim])
  1572   also have "\<dots> < f b"
  1573     by (force intro: DERIV_pos_imp_increasing [where f=f] assms)
  1574   finally show ?thesis .
  1575 qed
  1576 
  1577 lemma DERIV_neg_imp_decreasing_at_top:
  1578   fixes f :: "real \<Rightarrow> real"
  1579   assumes der: "\<And>x. x \<ge> b \<Longrightarrow> (\<exists>y. DERIV f x :> y \<and> y < 0)"
  1580     and lim: "(f \<longlongrightarrow> flim) at_top"
  1581   shows "flim < f b"
  1582   apply (rule DERIV_pos_imp_increasing_at_bot [where f = "\<lambda>i. f (-i)" and b = "-b", simplified])
  1583    apply (metis DERIV_mirror der le_minus_iff neg_0_less_iff_less)
  1584   apply (metis filterlim_at_top_mirror lim)
  1585   done
  1586 
  1587 text \<open>Derivative of inverse function\<close>
  1588 
  1589 lemma DERIV_inverse_function:
  1590   fixes f g :: "real \<Rightarrow> real"
  1591   assumes der: "DERIV f (g x) :> D"
  1592     and neq: "D \<noteq> 0"
  1593     and x: "a < x" "x < b"
  1594     and inj: "\<forall>y. a < y \<and> y < b \<longrightarrow> f (g y) = y"
  1595     and cont: "isCont g x"
  1596   shows "DERIV g x :> inverse D"
  1597 unfolding DERIV_iff2
  1598 proof (rule LIM_equal2)
  1599   show "0 < min (x - a) (b - x)"
  1600     using x by arith
  1601 next
  1602   fix y
  1603   assume "norm (y - x) < min (x - a) (b - x)"
  1604   then have "a < y" and "y < b"
  1605     by (simp_all add: abs_less_iff)
  1606   then show "(g y - g x) / (y - x) = inverse ((f (g y) - x) / (g y - g x))"
  1607     by (simp add: inj)
  1608 next
  1609   have "(\<lambda>z. (f z - f (g x)) / (z - g x)) \<midarrow>g x\<rightarrow> D"
  1610     by (rule der [unfolded DERIV_iff2])
  1611   then have 1: "(\<lambda>z. (f z - x) / (z - g x)) \<midarrow>g x\<rightarrow> D"
  1612     using inj x by simp
  1613   have 2: "\<exists>d>0. \<forall>y. y \<noteq> x \<and> norm (y - x) < d \<longrightarrow> g y \<noteq> g x"
  1614   proof (rule exI, safe)
  1615     show "0 < min (x - a) (b - x)"
  1616       using x by simp
  1617   next
  1618     fix y
  1619     assume "norm (y - x) < min (x - a) (b - x)"
  1620     then have y: "a < y" "y < b"
  1621       by (simp_all add: abs_less_iff)
  1622     assume "g y = g x"
  1623     then have "f (g y) = f (g x)" by simp
  1624     then have "y = x" using inj y x by simp
  1625     also assume "y \<noteq> x"
  1626     finally show False by simp
  1627   qed
  1628   have "(\<lambda>y. (f (g y) - x) / (g y - g x)) \<midarrow>x\<rightarrow> D"
  1629     using cont 1 2 by (rule isCont_LIM_compose2)
  1630   then show "(\<lambda>y. inverse ((f (g y) - x) / (g y - g x))) \<midarrow>x\<rightarrow> inverse D"
  1631     using neq by (rule tendsto_inverse)
  1632 qed
  1633 
  1634 subsection \<open>Generalized Mean Value Theorem\<close>
  1635 
  1636 theorem GMVT:
  1637   fixes a b :: real
  1638   assumes alb: "a < b"
  1639     and fc: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x"
  1640     and fd: "\<forall>x. a < x \<and> x < b \<longrightarrow> f differentiable (at x)"
  1641     and gc: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont g x"
  1642     and gd: "\<forall>x. a < x \<and> x < b \<longrightarrow> g differentiable (at x)"
  1643   shows "\<exists>g'c f'c c.
  1644     DERIV g c :> g'c \<and> DERIV f c :> f'c \<and> a < c \<and> c < b \<and> (f b - f a) * g'c = (g b - g a) * f'c"
  1645 proof -
  1646   let ?h = "\<lambda>x. (f b - f a) * g x - (g b - g a) * f x"
  1647   have "\<exists>l z. a < z \<and> z < b \<and> DERIV ?h z :> l \<and> ?h b - ?h a = (b - a) * l"
  1648   proof (rule MVT)
  1649     from assms show "a < b" by simp
  1650     show "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont ?h x"
  1651       using fc gc by simp
  1652     show "\<forall>x. a < x \<and> x < b \<longrightarrow> ?h differentiable (at x)"
  1653       using fd gd by simp
  1654   qed
  1655   then obtain l where l: "\<exists>z. a < z \<and> z < b \<and> DERIV ?h z :> l \<and> ?h b - ?h a = (b - a) * l" ..
  1656   then obtain c where c: "a < c \<and> c < b \<and> DERIV ?h c :> l \<and> ?h b - ?h a = (b - a) * l" ..
  1657 
  1658   from c have cint: "a < c \<and> c < b" by auto
  1659   with gd have "g differentiable (at c)" by simp
  1660   then have "\<exists>D. DERIV g c :> D" by (rule differentiableD)
  1661   then obtain g'c where g'c: "DERIV g c :> g'c" ..
  1662 
  1663   from c have "a < c \<and> c < b" by auto
  1664   with fd have "f differentiable (at c)" by simp
  1665   then have "\<exists>D. DERIV f c :> D" by (rule differentiableD)
  1666   then obtain f'c where f'c: "DERIV f c :> f'c" ..
  1667 
  1668   from c have "DERIV ?h c :> l" by auto
  1669   moreover have "DERIV ?h c :>  g'c * (f b - f a) - f'c * (g b - g a)"
  1670     using g'c f'c by (auto intro!: derivative_eq_intros)
  1671   ultimately have leq: "l =  g'c * (f b - f a) - f'c * (g b - g a)" by (rule DERIV_unique)
  1672 
  1673   have "?h b - ?h a = (b - a) * (g'c * (f b - f a) - f'c * (g b - g a))"
  1674   proof -
  1675     from c have "?h b - ?h a = (b - a) * l" by auto
  1676     also from leq have "\<dots> = (b - a) * (g'c * (f b - f a) - f'c * (g b - g a))" by simp
  1677     finally show ?thesis by simp
  1678   qed
  1679   moreover have "?h b - ?h a = 0"
  1680   proof -
  1681     have "?h b - ?h a =
  1682       ((f b)*(g b) - (f a)*(g b) - (g b)*(f b) + (g a)*(f b)) -
  1683       ((f b)*(g a) - (f a)*(g a) - (g b)*(f a) + (g a)*(f a))"
  1684       by (simp add: algebra_simps)
  1685     then show ?thesis  by auto
  1686   qed
  1687   ultimately have "(b - a) * (g'c * (f b - f a) - f'c * (g b - g a)) = 0" by auto
  1688   with alb have "g'c * (f b - f a) - f'c * (g b - g a) = 0" by simp
  1689   then have "g'c * (f b - f a) = f'c * (g b - g a)" by simp
  1690   then have "(f b - f a) * g'c = (g b - g a) * f'c" by (simp add: ac_simps)
  1691   with g'c f'c cint show ?thesis by auto
  1692 qed
  1693 
  1694 lemma GMVT':
  1695   fixes f g :: "real \<Rightarrow> real"
  1696   assumes "a < b"
  1697     and isCont_f: "\<And>z. a \<le> z \<Longrightarrow> z \<le> b \<Longrightarrow> isCont f z"
  1698     and isCont_g: "\<And>z. a \<le> z \<Longrightarrow> z \<le> b \<Longrightarrow> isCont g z"
  1699     and DERIV_g: "\<And>z. a < z \<Longrightarrow> z < b \<Longrightarrow> DERIV g z :> (g' z)"
  1700     and DERIV_f: "\<And>z. a < z \<Longrightarrow> z < b \<Longrightarrow> DERIV f z :> (f' z)"
  1701   shows "\<exists>c. a < c \<and> c < b \<and> (f b - f a) * g' c = (g b - g a) * f' c"
  1702 proof -
  1703   have "\<exists>g'c f'c c. DERIV g c :> g'c \<and> DERIV f c :> f'c \<and>
  1704       a < c \<and> c < b \<and> (f b - f a) * g'c = (g b - g a) * f'c"
  1705     using assms by (intro GMVT) (force simp: real_differentiable_def)+
  1706   then obtain c where "a < c" "c < b" "(f b - f a) * g' c = (g b - g a) * f' c"
  1707     using DERIV_f DERIV_g by (force dest: DERIV_unique)
  1708   then show ?thesis
  1709     by auto
  1710 qed
  1711 
  1712 
  1713 subsection \<open>L'Hopitals rule\<close>
  1714 
  1715 lemma isCont_If_ge:
  1716   fixes a :: "'a :: linorder_topology"
  1717   shows "continuous (at_left a) g \<Longrightarrow> (f \<longlongrightarrow> g a) (at_right a) \<Longrightarrow>
  1718     isCont (\<lambda>x. if x \<le> a then g x else f x) a"
  1719   unfolding isCont_def continuous_within
  1720   apply (intro filterlim_split_at)
  1721    apply (subst filterlim_cong[OF refl refl, where g=g])
  1722     apply (simp_all add: eventually_at_filter less_le)
  1723   apply (subst filterlim_cong[OF refl refl, where g=f])
  1724    apply (simp_all add: eventually_at_filter less_le)
  1725   done
  1726 
  1727 lemma lhopital_right_0:
  1728   fixes f0 g0 :: "real \<Rightarrow> real"
  1729   assumes f_0: "(f0 \<longlongrightarrow> 0) (at_right 0)"
  1730     and g_0: "(g0 \<longlongrightarrow> 0) (at_right 0)"
  1731     and ev:
  1732       "eventually (\<lambda>x. g0 x \<noteq> 0) (at_right 0)"
  1733       "eventually (\<lambda>x. g' x \<noteq> 0) (at_right 0)"
  1734       "eventually (\<lambda>x. DERIV f0 x :> f' x) (at_right 0)"
  1735       "eventually (\<lambda>x. DERIV g0 x :> g' x) (at_right 0)"
  1736     and lim: "filterlim (\<lambda> x. (f' x / g' x)) F (at_right 0)"
  1737   shows "filterlim (\<lambda> x. f0 x / g0 x) F (at_right 0)"
  1738 proof -
  1739   define f where [abs_def]: "f x = (if x \<le> 0 then 0 else f0 x)" for x
  1740   then have "f 0 = 0" by simp
  1741 
  1742   define g where [abs_def]: "g x = (if x \<le> 0 then 0 else g0 x)" for x
  1743   then have "g 0 = 0" by simp
  1744 
  1745   have "eventually (\<lambda>x. g0 x \<noteq> 0 \<and> g' x \<noteq> 0 \<and>
  1746       DERIV f0 x :> (f' x) \<and> DERIV g0 x :> (g' x)) (at_right 0)"
  1747     using ev by eventually_elim auto
  1748   then obtain a where [arith]: "0 < a"
  1749     and g0_neq_0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> g0 x \<noteq> 0"
  1750     and g'_neq_0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> g' x \<noteq> 0"
  1751     and f0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> DERIV f0 x :> (f' x)"
  1752     and g0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> DERIV g0 x :> (g' x)"
  1753     unfolding eventually_at by (auto simp: dist_real_def)
  1754 
  1755   have g_neq_0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> g x \<noteq> 0"
  1756     using g0_neq_0 by (simp add: g_def)
  1757 
  1758   have f: "DERIV f x :> (f' x)" if x: "0 < x" "x < a" for x
  1759     using that
  1760     by (intro DERIV_cong_ev[THEN iffD1, OF _ _ _ f0[OF x]])
  1761       (auto simp: f_def eventually_nhds_metric dist_real_def intro!: exI[of _ x])
  1762 
  1763   have g: "DERIV g x :> (g' x)" if x: "0 < x" "x < a" for x
  1764     using that
  1765     by (intro DERIV_cong_ev[THEN iffD1, OF _ _ _ g0[OF x]])
  1766          (auto simp: g_def eventually_nhds_metric dist_real_def intro!: exI[of _ x])
  1767 
  1768   have "isCont f 0"
  1769     unfolding f_def by (intro isCont_If_ge f_0 continuous_const)
  1770 
  1771   have "isCont g 0"
  1772     unfolding g_def by (intro isCont_If_ge g_0 continuous_const)
  1773 
  1774   have "\<exists>\<zeta>. \<forall>x\<in>{0 <..< a}. 0 < \<zeta> x \<and> \<zeta> x < x \<and> f x / g x = f' (\<zeta> x) / g' (\<zeta> x)"
  1775   proof (rule bchoice, rule ballI)
  1776     fix x
  1777     assume "x \<in> {0 <..< a}"
  1778     then have x[arith]: "0 < x" "x < a" by auto
  1779     with g'_neq_0 g_neq_0 \<open>g 0 = 0\<close> have g': "\<And>x. 0 < x \<Longrightarrow> x < a  \<Longrightarrow> 0 \<noteq> g' x" "g 0 \<noteq> g x"
  1780       by auto
  1781     have "\<And>x. 0 \<le> x \<Longrightarrow> x < a \<Longrightarrow> isCont f x"
  1782       using \<open>isCont f 0\<close> f by (auto intro: DERIV_isCont simp: le_less)
  1783     moreover have "\<And>x. 0 \<le> x \<Longrightarrow> x < a \<Longrightarrow> isCont g x"
  1784       using \<open>isCont g 0\<close> g by (auto intro: DERIV_isCont simp: le_less)
  1785     ultimately have "\<exists>c. 0 < c \<and> c < x \<and> (f x - f 0) * g' c = (g x - g 0) * f' c"
  1786       using f g \<open>x < a\<close> by (intro GMVT') auto
  1787     then obtain c where *: "0 < c" "c < x" "(f x - f 0) * g' c = (g x - g 0) * f' c"
  1788       by blast
  1789     moreover
  1790     from * g'(1)[of c] g'(2) have "(f x - f 0)  / (g x - g 0) = f' c / g' c"
  1791       by (simp add: field_simps)
  1792     ultimately show "\<exists>y. 0 < y \<and> y < x \<and> f x / g x = f' y / g' y"
  1793       using \<open>f 0 = 0\<close> \<open>g 0 = 0\<close> by (auto intro!: exI[of _ c])
  1794   qed
  1795   then obtain \<zeta> where "\<forall>x\<in>{0 <..< a}. 0 < \<zeta> x \<and> \<zeta> x < x \<and> f x / g x = f' (\<zeta> x) / g' (\<zeta> x)" ..
  1796   then have \<zeta>: "eventually (\<lambda>x. 0 < \<zeta> x \<and> \<zeta> x < x \<and> f x / g x = f' (\<zeta> x) / g' (\<zeta> x)) (at_right 0)"
  1797     unfolding eventually_at by (intro exI[of _ a]) (auto simp: dist_real_def)
  1798   moreover
  1799   from \<zeta> have "eventually (\<lambda>x. norm (\<zeta> x) \<le> x) (at_right 0)"
  1800     by eventually_elim auto
  1801   then have "((\<lambda>x. norm (\<zeta> x)) \<longlongrightarrow> 0) (at_right 0)"
  1802     by (rule_tac real_tendsto_sandwich[where f="\<lambda>x. 0" and h="\<lambda>x. x"]) auto
  1803   then have "(\<zeta> \<longlongrightarrow> 0) (at_right 0)"
  1804     by (rule tendsto_norm_zero_cancel)
  1805   with \<zeta> have "filterlim \<zeta> (at_right 0) (at_right 0)"
  1806     by (auto elim!: eventually_mono simp: filterlim_at)
  1807   from this lim have "filterlim (\<lambda>t. f' (\<zeta> t) / g' (\<zeta> t)) F (at_right 0)"
  1808     by (rule_tac filterlim_compose[of _ _ _ \<zeta>])
  1809   ultimately have "filterlim (\<lambda>t. f t / g t) F (at_right 0)" (is ?P)
  1810     by (rule_tac filterlim_cong[THEN iffD1, OF refl refl])
  1811        (auto elim: eventually_mono)
  1812   also have "?P \<longleftrightarrow> ?thesis"
  1813     by (rule filterlim_cong) (auto simp: f_def g_def eventually_at_filter)
  1814   finally show ?thesis .
  1815 qed
  1816 
  1817 lemma lhopital_right:
  1818   "(f \<longlongrightarrow> 0) (at_right x) \<Longrightarrow> (g \<longlongrightarrow> 0) (at_right x) \<Longrightarrow>
  1819     eventually (\<lambda>x. g x \<noteq> 0) (at_right x) \<Longrightarrow>
  1820     eventually (\<lambda>x. g' x \<noteq> 0) (at_right x) \<Longrightarrow>
  1821     eventually (\<lambda>x. DERIV f x :> f' x) (at_right x) \<Longrightarrow>
  1822     eventually (\<lambda>x. DERIV g x :> g' x) (at_right x) \<Longrightarrow>
  1823     filterlim (\<lambda> x. (f' x / g' x)) F (at_right x) \<Longrightarrow>
  1824   filterlim (\<lambda> x. f x / g x) F (at_right x)"
  1825   for x :: real
  1826   unfolding eventually_at_right_to_0[of _ x] filterlim_at_right_to_0[of _ _ x] DERIV_shift
  1827   by (rule lhopital_right_0)
  1828 
  1829 lemma lhopital_left:
  1830   "(f \<longlongrightarrow> 0) (at_left x) \<Longrightarrow> (g \<longlongrightarrow> 0) (at_left x) \<Longrightarrow>
  1831     eventually (\<lambda>x. g x \<noteq> 0) (at_left x) \<Longrightarrow>
  1832     eventually (\<lambda>x. g' x \<noteq> 0) (at_left x) \<Longrightarrow>
  1833     eventually (\<lambda>x. DERIV f x :> f' x) (at_left x) \<Longrightarrow>
  1834     eventually (\<lambda>x. DERIV g x :> g' x) (at_left x) \<Longrightarrow>
  1835     filterlim (\<lambda> x. (f' x / g' x)) F (at_left x) \<Longrightarrow>
  1836   filterlim (\<lambda> x. f x / g x) F (at_left x)"
  1837   for x :: real
  1838   unfolding eventually_at_left_to_right filterlim_at_left_to_right DERIV_mirror
  1839   by (rule lhopital_right[where f'="\<lambda>x. - f' (- x)"]) (auto simp: DERIV_mirror)
  1840 
  1841 lemma lhopital:
  1842   "(f \<longlongrightarrow> 0) (at x) \<Longrightarrow> (g \<longlongrightarrow> 0) (at x) \<Longrightarrow>
  1843     eventually (\<lambda>x. g x \<noteq> 0) (at x) \<Longrightarrow>
  1844     eventually (\<lambda>x. g' x \<noteq> 0) (at x) \<Longrightarrow>
  1845     eventually (\<lambda>x. DERIV f x :> f' x) (at x) \<Longrightarrow>
  1846     eventually (\<lambda>x. DERIV g x :> g' x) (at x) \<Longrightarrow>
  1847     filterlim (\<lambda> x. (f' x / g' x)) F (at x) \<Longrightarrow>
  1848   filterlim (\<lambda> x. f x / g x) F (at x)"
  1849   for x :: real
  1850   unfolding eventually_at_split filterlim_at_split
  1851   by (auto intro!: lhopital_right[of f x g g' f'] lhopital_left[of f x g g' f'])
  1852 
  1853 
  1854 lemma lhopital_right_0_at_top:
  1855   fixes f g :: "real \<Rightarrow> real"
  1856   assumes g_0: "LIM x at_right 0. g x :> at_top"
  1857     and ev:
  1858       "eventually (\<lambda>x. g' x \<noteq> 0) (at_right 0)"
  1859       "eventually (\<lambda>x. DERIV f x :> f' x) (at_right 0)"
  1860       "eventually (\<lambda>x. DERIV g x :> g' x) (at_right 0)"
  1861     and lim: "((\<lambda> x. (f' x / g' x)) \<longlongrightarrow> x) (at_right 0)"
  1862   shows "((\<lambda> x. f x / g x) \<longlongrightarrow> x) (at_right 0)"
  1863   unfolding tendsto_iff
  1864 proof safe
  1865   fix e :: real
  1866   assume "0 < e"
  1867   with lim[unfolded tendsto_iff, rule_format, of "e / 4"]
  1868   have "eventually (\<lambda>t. dist (f' t / g' t) x < e / 4) (at_right 0)"
  1869     by simp
  1870   from eventually_conj[OF eventually_conj[OF ev(1) ev(2)] eventually_conj[OF ev(3) this]]
  1871   obtain a where [arith]: "0 < a"
  1872     and g'_neq_0: "\<And>x. 0 < x \<Longrightarrow> x < a \<Longrightarrow> g' x \<noteq> 0"
  1873     and f0: "\<And>x. 0 < x \<Longrightarrow> x \<le> a \<Longrightarrow> DERIV f x :> (f' x)"
  1874     and g0: "\<And>x. 0 < x \<Longrightarrow> x \<le> a \<Longrightarrow> DERIV g x :> (g' x)"
  1875     and Df: "\<And>t. 0 < t \<Longrightarrow> t < a \<Longrightarrow> dist (f' t / g' t) x < e / 4"
  1876     unfolding eventually_at_le by (auto simp: dist_real_def)
  1877 
  1878   from Df have "eventually (\<lambda>t. t < a) (at_right 0)" "eventually (\<lambda>t::real. 0 < t) (at_right 0)"
  1879     unfolding eventually_at by (auto intro!: exI[of _ a] simp: dist_real_def)
  1880 
  1881   moreover
  1882   have "eventually (\<lambda>t. 0 < g t) (at_right 0)" "eventually (\<lambda>t. g a < g t) (at_right 0)"
  1883     using g_0 by (auto elim: eventually_mono simp: filterlim_at_top_dense)
  1884 
  1885   moreover
  1886   have inv_g: "((\<lambda>x. inverse (g x)) \<longlongrightarrow> 0) (at_right 0)"
  1887     using tendsto_inverse_0 filterlim_mono[OF g_0 at_top_le_at_infinity order_refl]
  1888     by (rule filterlim_compose)
  1889   then have "((\<lambda>x. norm (1 - g a * inverse (g x))) \<longlongrightarrow> norm (1 - g a * 0)) (at_right 0)"
  1890     by (intro tendsto_intros)
  1891   then have "((\<lambda>x. norm (1 - g a / g x)) \<longlongrightarrow> 1) (at_right 0)"
  1892     by (simp add: inverse_eq_divide)
  1893   from this[unfolded tendsto_iff, rule_format, of 1]
  1894   have "eventually (\<lambda>x. norm (1 - g a / g x) < 2) (at_right 0)"
  1895     by (auto elim!: eventually_mono simp: dist_real_def)
  1896 
  1897   moreover
  1898   from inv_g have "((\<lambda>t. norm ((f a - x * g a) * inverse (g t))) \<longlongrightarrow> norm ((f a - x * g a) * 0))
  1899       (at_right 0)"
  1900     by (intro tendsto_intros)
  1901   then have "((\<lambda>t. norm (f a - x * g a) / norm (g t)) \<longlongrightarrow> 0) (at_right 0)"
  1902     by (simp add: inverse_eq_divide)
  1903   from this[unfolded tendsto_iff, rule_format, of "e / 2"] \<open>0 < e\<close>
  1904   have "eventually (\<lambda>t. norm (f a - x * g a) / norm (g t) < e / 2) (at_right 0)"
  1905     by (auto simp: dist_real_def)
  1906 
  1907   ultimately show "eventually (\<lambda>t. dist (f t / g t) x < e) (at_right 0)"
  1908   proof eventually_elim
  1909     fix t assume t[arith]: "0 < t" "t < a" "g a < g t" "0 < g t"
  1910     assume ineq: "norm (1 - g a / g t) < 2" "norm (f a - x * g a) / norm (g t) < e / 2"
  1911 
  1912     have "\<exists>y. t < y \<and> y < a \<and> (g a - g t) * f' y = (f a - f t) * g' y"
  1913       using f0 g0 t(1,2) by (intro GMVT') (force intro!: DERIV_isCont)+
  1914     then obtain y where [arith]: "t < y" "y < a"
  1915       and D_eq0: "(g a - g t) * f' y = (f a - f t) * g' y"
  1916       by blast
  1917     from D_eq0 have D_eq: "(f t - f a) / (g t - g a) = f' y / g' y"
  1918       using \<open>g a < g t\<close> g'_neq_0[of y] by (auto simp add: field_simps)
  1919 
  1920     have *: "f t / g t - x = ((f t - f a) / (g t - g a) - x) * (1 - g a / g t) + (f a - x * g a) / g t"
  1921       by (simp add: field_simps)
  1922     have "norm (f t / g t - x) \<le>
  1923         norm (((f t - f a) / (g t - g a) - x) * (1 - g a / g t)) + norm ((f a - x * g a) / g t)"
  1924       unfolding * by (rule norm_triangle_ineq)
  1925     also have "\<dots> = dist (f' y / g' y) x * norm (1 - g a / g t) + norm (f a - x * g a) / norm (g t)"
  1926       by (simp add: abs_mult D_eq dist_real_def)
  1927     also have "\<dots> < (e / 4) * 2 + e / 2"
  1928       using ineq Df[of y] \<open>0 < e\<close> by (intro add_le_less_mono mult_mono) auto
  1929     finally show "dist (f t / g t) x < e"
  1930       by (simp add: dist_real_def)
  1931   qed
  1932 qed
  1933 
  1934 lemma lhopital_right_at_top:
  1935   "LIM x at_right x. (g::real \<Rightarrow> real) x :> at_top \<Longrightarrow>
  1936     eventually (\<lambda>x. g' x \<noteq> 0) (at_right x) \<Longrightarrow>
  1937     eventually (\<lambda>x. DERIV f x :> f' x) (at_right x) \<Longrightarrow>
  1938     eventually (\<lambda>x. DERIV g x :> g' x) (at_right x) \<Longrightarrow>
  1939     ((\<lambda> x. (f' x / g' x)) \<longlongrightarrow> y) (at_right x) \<Longrightarrow>
  1940     ((\<lambda> x. f x / g x) \<longlongrightarrow> y) (at_right x)"
  1941   unfolding eventually_at_right_to_0[of _ x] filterlim_at_right_to_0[of _ _ x] DERIV_shift
  1942   by (rule lhopital_right_0_at_top)
  1943 
  1944 lemma lhopital_left_at_top:
  1945   "LIM x at_left x. g x :> at_top \<Longrightarrow>
  1946     eventually (\<lambda>x. g' x \<noteq> 0) (at_left x) \<Longrightarrow>
  1947     eventually (\<lambda>x. DERIV f x :> f' x) (at_left x) \<Longrightarrow>
  1948     eventually (\<lambda>x. DERIV g x :> g' x) (at_left x) \<Longrightarrow>
  1949     ((\<lambda> x. (f' x / g' x)) \<longlongrightarrow> y) (at_left x) \<Longrightarrow>
  1950     ((\<lambda> x. f x / g x) \<longlongrightarrow> y) (at_left x)"
  1951   for x :: real
  1952   unfolding eventually_at_left_to_right filterlim_at_left_to_right DERIV_mirror
  1953   by (rule lhopital_right_at_top[where f'="\<lambda>x. - f' (- x)"]) (auto simp: DERIV_mirror)
  1954 
  1955 lemma lhopital_at_top:
  1956   "LIM x at x. (g::real \<Rightarrow> real) x :> at_top \<Longrightarrow>
  1957     eventually (\<lambda>x. g' x \<noteq> 0) (at x) \<Longrightarrow>
  1958     eventually (\<lambda>x. DERIV f x :> f' x) (at x) \<Longrightarrow>
  1959     eventually (\<lambda>x. DERIV g x :> g' x) (at x) \<Longrightarrow>
  1960     ((\<lambda> x. (f' x / g' x)) \<longlongrightarrow> y) (at x) \<Longrightarrow>
  1961     ((\<lambda> x. f x / g x) \<longlongrightarrow> y) (at x)"
  1962   unfolding eventually_at_split filterlim_at_split
  1963   by (auto intro!: lhopital_right_at_top[of g x g' f f'] lhopital_left_at_top[of g x g' f f'])
  1964 
  1965 lemma lhospital_at_top_at_top:
  1966   fixes f g :: "real \<Rightarrow> real"
  1967   assumes g_0: "LIM x at_top. g x :> at_top"
  1968     and g': "eventually (\<lambda>x. g' x \<noteq> 0) at_top"
  1969     and Df: "eventually (\<lambda>x. DERIV f x :> f' x) at_top"
  1970     and Dg: "eventually (\<lambda>x. DERIV g x :> g' x) at_top"
  1971     and lim: "((\<lambda> x. (f' x / g' x)) \<longlongrightarrow> x) at_top"
  1972   shows "((\<lambda> x. f x / g x) \<longlongrightarrow> x) at_top"
  1973   unfolding filterlim_at_top_to_right
  1974 proof (rule lhopital_right_0_at_top)
  1975   let ?F = "\<lambda>x. f (inverse x)"
  1976   let ?G = "\<lambda>x. g (inverse x)"
  1977   let ?R = "at_right (0::real)"
  1978   let ?D = "\<lambda>f' x. f' (inverse x) * - (inverse x ^ Suc (Suc 0))"
  1979   show "LIM x ?R. ?G x :> at_top"
  1980     using g_0 unfolding filterlim_at_top_to_right .
  1981   show "eventually (\<lambda>x. DERIV ?G x  :> ?D g' x) ?R"
  1982     unfolding eventually_at_right_to_top
  1983     using Dg eventually_ge_at_top[where c=1]
  1984     apply eventually_elim
  1985     apply (rule DERIV_cong)
  1986      apply (rule DERIV_chain'[where f=inverse])
  1987       apply (auto intro!:  DERIV_inverse)
  1988     done
  1989   show "eventually (\<lambda>x. DERIV ?F x  :> ?D f' x) ?R"
  1990     unfolding eventually_at_right_to_top
  1991     using Df eventually_ge_at_top[where c=1]
  1992     apply eventually_elim
  1993     apply (rule DERIV_cong)
  1994      apply (rule DERIV_chain'[where f=inverse])
  1995       apply (auto intro!:  DERIV_inverse)
  1996     done
  1997   show "eventually (\<lambda>x. ?D g' x \<noteq> 0) ?R"
  1998     unfolding eventually_at_right_to_top
  1999     using g' eventually_ge_at_top[where c=1]
  2000     by eventually_elim auto
  2001   show "((\<lambda>x. ?D f' x / ?D g' x) \<longlongrightarrow> x) ?R"
  2002     unfolding filterlim_at_right_to_top
  2003     apply (intro filterlim_cong[THEN iffD2, OF refl refl _ lim])
  2004     using eventually_ge_at_top[where c=1]
  2005     by eventually_elim simp
  2006 qed
  2007 
  2008 lemma lhopital_right_at_top_at_top:
  2009   fixes f g :: "real \<Rightarrow> real"
  2010   assumes f_0: "LIM x at_right a. f x :> at_top"
  2011   assumes g_0: "LIM x at_right a. g x :> at_top"
  2012     and ev:
  2013       "eventually (\<lambda>x. DERIV f x :> f' x) (at_right a)"
  2014       "eventually (\<lambda>x. DERIV g x :> g' x) (at_right a)"
  2015     and lim: "filterlim (\<lambda> x. (f' x / g' x)) at_top (at_right a)"
  2016   shows "filterlim (\<lambda> x. f x / g x) at_top (at_right a)"
  2017 proof -
  2018   from lim have pos: "eventually (\<lambda>x. f' x / g' x > 0) (at_right a)"
  2019     unfolding filterlim_at_top_dense by blast
  2020   have "((\<lambda>x. g x / f x) \<longlongrightarrow> 0) (at_right a)"
  2021   proof (rule lhopital_right_at_top)
  2022     from pos show "eventually (\<lambda>x. f' x \<noteq> 0) (at_right a)" by eventually_elim auto
  2023     from tendsto_inverse_0_at_top[OF lim]
  2024       show "((\<lambda>x. g' x / f' x) \<longlongrightarrow> 0) (at_right a)" by simp
  2025   qed fact+
  2026   moreover from f_0 g_0 
  2027     have "eventually (\<lambda>x. f x > 0) (at_right a)" "eventually (\<lambda>x. g x > 0) (at_right a)"
  2028     unfolding filterlim_at_top_dense by blast+
  2029   hence "eventually (\<lambda>x. g x / f x > 0) (at_right a)" by eventually_elim simp
  2030   ultimately have "filterlim (\<lambda>x. inverse (g x / f x)) at_top (at_right a)"
  2031     by (rule filterlim_inverse_at_top)
  2032   thus ?thesis by simp
  2033 qed
  2034 
  2035 lemma lhopital_right_at_top_at_bot:
  2036   fixes f g :: "real \<Rightarrow> real"
  2037   assumes f_0: "LIM x at_right a. f x :> at_top"
  2038   assumes g_0: "LIM x at_right a. g x :> at_bot"
  2039     and ev:
  2040       "eventually (\<lambda>x. DERIV f x :> f' x) (at_right a)"
  2041       "eventually (\<lambda>x. DERIV g x :> g' x) (at_right a)"
  2042     and lim: "filterlim (\<lambda> x. (f' x / g' x)) at_bot (at_right a)"
  2043   shows "filterlim (\<lambda> x. f x / g x) at_bot (at_right a)"
  2044 proof -
  2045   from ev(2) have ev': "eventually (\<lambda>x. DERIV (\<lambda>x. -g x) x :> -g' x) (at_right a)"
  2046     by eventually_elim (auto intro: derivative_intros)
  2047   have "filterlim (\<lambda>x. f x / (-g x)) at_top (at_right a)"
  2048     by (rule lhopital_right_at_top_at_top[where f' = f' and g' = "\<lambda>x. -g' x"])
  2049        (insert assms ev', auto simp: filterlim_uminus_at_bot)
  2050   hence "filterlim (\<lambda>x. -(f x / g x)) at_top (at_right a)" by simp
  2051   thus ?thesis by (simp add: filterlim_uminus_at_bot)
  2052 qed
  2053 
  2054 lemma lhopital_left_at_top_at_top:
  2055   fixes f g :: "real \<Rightarrow> real"
  2056   assumes f_0: "LIM x at_left a. f x :> at_top"
  2057   assumes g_0: "LIM x at_left a. g x :> at_top"
  2058     and ev:
  2059       "eventually (\<lambda>x. DERIV f x :> f' x) (at_left a)"
  2060       "eventually (\<lambda>x. DERIV g x :> g' x) (at_left a)"
  2061     and lim: "filterlim (\<lambda> x. (f' x / g' x)) at_top (at_left a)"
  2062   shows "filterlim (\<lambda> x. f x / g x) at_top (at_left a)"
  2063   by (insert assms, unfold eventually_at_left_to_right filterlim_at_left_to_right DERIV_mirror,
  2064       rule lhopital_right_at_top_at_top[where f'="\<lambda>x. - f' (- x)"]) 
  2065      (insert assms, auto simp: DERIV_mirror)
  2066 
  2067 lemma lhopital_left_at_top_at_bot:
  2068   fixes f g :: "real \<Rightarrow> real"
  2069   assumes f_0: "LIM x at_left a. f x :> at_top"
  2070   assumes g_0: "LIM x at_left a. g x :> at_bot"
  2071     and ev:
  2072       "eventually (\<lambda>x. DERIV f x :> f' x) (at_left a)"
  2073       "eventually (\<lambda>x. DERIV g x :> g' x) (at_left a)"
  2074     and lim: "filterlim (\<lambda> x. (f' x / g' x)) at_bot (at_left a)"
  2075   shows "filterlim (\<lambda> x. f x / g x) at_bot (at_left a)"
  2076   by (insert assms, unfold eventually_at_left_to_right filterlim_at_left_to_right DERIV_mirror,
  2077       rule lhopital_right_at_top_at_bot[where f'="\<lambda>x. - f' (- x)"]) 
  2078      (insert assms, auto simp: DERIV_mirror)
  2079 
  2080 lemma lhopital_at_top_at_top:
  2081   fixes f g :: "real \<Rightarrow> real"
  2082   assumes f_0: "LIM x at a. f x :> at_top"
  2083   assumes g_0: "LIM x at a. g x :> at_top"
  2084     and ev:
  2085       "eventually (\<lambda>x. DERIV f x :> f' x) (at a)"
  2086       "eventually (\<lambda>x. DERIV g x :> g' x) (at a)"
  2087     and lim: "filterlim (\<lambda> x. (f' x / g' x)) at_top (at a)"
  2088   shows "filterlim (\<lambda> x. f x / g x) at_top (at a)"
  2089   using assms unfolding eventually_at_split filterlim_at_split
  2090   by (auto intro!: lhopital_right_at_top_at_top[of f a g f' g'] 
  2091                    lhopital_left_at_top_at_top[of f a g f' g'])
  2092 
  2093 lemma lhopital_at_top_at_bot:
  2094   fixes f g :: "real \<Rightarrow> real"
  2095   assumes f_0: "LIM x at a. f x :> at_top"
  2096   assumes g_0: "LIM x at a. g x :> at_bot"
  2097     and ev:
  2098       "eventually (\<lambda>x. DERIV f x :> f' x) (at a)"
  2099       "eventually (\<lambda>x. DERIV g x :> g' x) (at a)"
  2100     and lim: "filterlim (\<lambda> x. (f' x / g' x)) at_bot (at a)"
  2101   shows "filterlim (\<lambda> x. f x / g x) at_bot (at a)"
  2102   using assms unfolding eventually_at_split filterlim_at_split
  2103   by (auto intro!: lhopital_right_at_top_at_bot[of f a g f' g'] 
  2104                    lhopital_left_at_top_at_bot[of f a g f' g'])
  2105 
  2106 end