src/HOL/Library/Multiset.thy
author wenzelm
Sat Nov 04 15:24:40 2017 +0100 (21 months ago)
changeset 67003 49850a679c2c
parent 66938 c78ff0aeba4c
child 67051 e7e54a0b9197
permissions -rw-r--r--
more robust sorted_entries;
     1 (*  Title:      HOL/Library/Multiset.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, Lawrence C Paulson, Norbert Voelker
     3     Author:     Andrei Popescu, TU Muenchen
     4     Author:     Jasmin Blanchette, Inria, LORIA, MPII
     5     Author:     Dmitriy Traytel, TU Muenchen
     6     Author:     Mathias Fleury, MPII
     7 *)
     8 
     9 section \<open>(Finite) Multisets\<close>
    10 
    11 theory Multiset
    12 imports Cancellation
    13 begin
    14 
    15 subsection \<open>The type of multisets\<close>
    16 
    17 definition "multiset = {f :: 'a \<Rightarrow> nat. finite {x. f x > 0}}"
    18 
    19 typedef 'a multiset = "multiset :: ('a \<Rightarrow> nat) set"
    20   morphisms count Abs_multiset
    21   unfolding multiset_def
    22 proof
    23   show "(\<lambda>x. 0::nat) \<in> {f. finite {x. f x > 0}}" by simp
    24 qed
    25 
    26 setup_lifting type_definition_multiset
    27 
    28 lemma multiset_eq_iff: "M = N \<longleftrightarrow> (\<forall>a. count M a = count N a)"
    29   by (simp only: count_inject [symmetric] fun_eq_iff)
    30 
    31 lemma multiset_eqI: "(\<And>x. count A x = count B x) \<Longrightarrow> A = B"
    32   using multiset_eq_iff by auto
    33 
    34 text \<open>Preservation of the representing set @{term multiset}.\<close>
    35 
    36 lemma const0_in_multiset: "(\<lambda>a. 0) \<in> multiset"
    37   by (simp add: multiset_def)
    38 
    39 lemma only1_in_multiset: "(\<lambda>b. if b = a then n else 0) \<in> multiset"
    40   by (simp add: multiset_def)
    41 
    42 lemma union_preserves_multiset: "M \<in> multiset \<Longrightarrow> N \<in> multiset \<Longrightarrow> (\<lambda>a. M a + N a) \<in> multiset"
    43   by (simp add: multiset_def)
    44 
    45 lemma diff_preserves_multiset:
    46   assumes "M \<in> multiset"
    47   shows "(\<lambda>a. M a - N a) \<in> multiset"
    48 proof -
    49   have "{x. N x < M x} \<subseteq> {x. 0 < M x}"
    50     by auto
    51   with assms show ?thesis
    52     by (auto simp add: multiset_def intro: finite_subset)
    53 qed
    54 
    55 lemma filter_preserves_multiset:
    56   assumes "M \<in> multiset"
    57   shows "(\<lambda>x. if P x then M x else 0) \<in> multiset"
    58 proof -
    59   have "{x. (P x \<longrightarrow> 0 < M x) \<and> P x} \<subseteq> {x. 0 < M x}"
    60     by auto
    61   with assms show ?thesis
    62     by (auto simp add: multiset_def intro: finite_subset)
    63 qed
    64 
    65 lemmas in_multiset = const0_in_multiset only1_in_multiset
    66   union_preserves_multiset diff_preserves_multiset filter_preserves_multiset
    67 
    68 
    69 subsection \<open>Representing multisets\<close>
    70 
    71 text \<open>Multiset enumeration\<close>
    72 
    73 instantiation multiset :: (type) cancel_comm_monoid_add
    74 begin
    75 
    76 lift_definition zero_multiset :: "'a multiset" is "\<lambda>a. 0"
    77 by (rule const0_in_multiset)
    78 
    79 abbreviation Mempty :: "'a multiset" ("{#}") where
    80   "Mempty \<equiv> 0"
    81 
    82 lift_definition plus_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" is "\<lambda>M N. (\<lambda>a. M a + N a)"
    83 by (rule union_preserves_multiset)
    84 
    85 lift_definition minus_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" is "\<lambda> M N. \<lambda>a. M a - N a"
    86 by (rule diff_preserves_multiset)
    87 
    88 instance
    89   by (standard; transfer; simp add: fun_eq_iff)
    90 
    91 end
    92 
    93 context
    94 begin
    95 
    96 qualified definition is_empty :: "'a multiset \<Rightarrow> bool" where
    97   [code_abbrev]: "is_empty A \<longleftrightarrow> A = {#}"
    98 
    99 end
   100 
   101 lemma add_mset_in_multiset:
   102   assumes M: \<open>M \<in> multiset\<close>
   103   shows \<open>(\<lambda>b. if b = a then Suc (M b) else M b) \<in> multiset\<close>
   104   using assms by (simp add: multiset_def insert_Collect[symmetric])
   105 
   106 lift_definition add_mset :: "'a \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" is
   107   "\<lambda>a M b. if b = a then Suc (M b) else M b"
   108 by (rule add_mset_in_multiset)
   109 
   110 syntax
   111   "_multiset" :: "args \<Rightarrow> 'a multiset"    ("{#(_)#}")
   112 translations
   113   "{#x, xs#}" == "CONST add_mset x {#xs#}"
   114   "{#x#}" == "CONST add_mset x {#}"
   115 
   116 lemma count_empty [simp]: "count {#} a = 0"
   117   by (simp add: zero_multiset.rep_eq)
   118 
   119 lemma count_add_mset [simp]:
   120   "count (add_mset b A) a = (if b = a then Suc (count A a) else count A a)"
   121   by (simp add: add_mset.rep_eq)
   122 
   123 lemma count_single: "count {#b#} a = (if b = a then 1 else 0)"
   124   by simp
   125 
   126 lemma
   127   add_mset_not_empty [simp]: \<open>add_mset a A \<noteq> {#}\<close> and
   128   empty_not_add_mset [simp]: "{#} \<noteq> add_mset a A"
   129   by (auto simp: multiset_eq_iff)
   130 
   131 lemma add_mset_add_mset_same_iff [simp]:
   132   "add_mset a A = add_mset a B \<longleftrightarrow> A = B"
   133   by (auto simp: multiset_eq_iff)
   134 
   135 lemma add_mset_commute:
   136   "add_mset x (add_mset y M) = add_mset y (add_mset x M)"
   137   by (auto simp: multiset_eq_iff)
   138 
   139 
   140 subsection \<open>Basic operations\<close>
   141 
   142 subsubsection \<open>Conversion to set and membership\<close>
   143 
   144 definition set_mset :: "'a multiset \<Rightarrow> 'a set"
   145   where "set_mset M = {x. count M x > 0}"
   146 
   147 abbreviation Melem :: "'a \<Rightarrow> 'a multiset \<Rightarrow> bool"
   148   where "Melem a M \<equiv> a \<in> set_mset M"
   149 
   150 notation
   151   Melem  ("op \<in>#") and
   152   Melem  ("(_/ \<in># _)" [51, 51] 50)
   153 
   154 notation  (ASCII)
   155   Melem  ("op :#") and
   156   Melem  ("(_/ :# _)" [51, 51] 50)
   157 
   158 abbreviation not_Melem :: "'a \<Rightarrow> 'a multiset \<Rightarrow> bool"
   159   where "not_Melem a M \<equiv> a \<notin> set_mset M"
   160 
   161 notation
   162   not_Melem  ("op \<notin>#") and
   163   not_Melem  ("(_/ \<notin># _)" [51, 51] 50)
   164 
   165 notation  (ASCII)
   166   not_Melem  ("op ~:#") and
   167   not_Melem  ("(_/ ~:# _)" [51, 51] 50)
   168 
   169 context
   170 begin
   171 
   172 qualified abbreviation Ball :: "'a multiset \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> bool"
   173   where "Ball M \<equiv> Set.Ball (set_mset M)"
   174 
   175 qualified abbreviation Bex :: "'a multiset \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> bool"
   176   where "Bex M \<equiv> Set.Bex (set_mset M)"
   177 
   178 end
   179 
   180 syntax
   181   "_MBall"       :: "pttrn \<Rightarrow> 'a set \<Rightarrow> bool \<Rightarrow> bool"      ("(3\<forall>_\<in>#_./ _)" [0, 0, 10] 10)
   182   "_MBex"        :: "pttrn \<Rightarrow> 'a set \<Rightarrow> bool \<Rightarrow> bool"      ("(3\<exists>_\<in>#_./ _)" [0, 0, 10] 10)
   183 
   184 syntax  (ASCII)
   185   "_MBall"       :: "pttrn \<Rightarrow> 'a set \<Rightarrow> bool \<Rightarrow> bool"      ("(3\<forall>_:#_./ _)" [0, 0, 10] 10)
   186   "_MBex"        :: "pttrn \<Rightarrow> 'a set \<Rightarrow> bool \<Rightarrow> bool"      ("(3\<exists>_:#_./ _)" [0, 0, 10] 10)
   187 
   188 translations
   189   "\<forall>x\<in>#A. P" \<rightleftharpoons> "CONST Multiset.Ball A (\<lambda>x. P)"
   190   "\<exists>x\<in>#A. P" \<rightleftharpoons> "CONST Multiset.Bex A (\<lambda>x. P)"
   191 
   192 lemma count_eq_zero_iff:
   193   "count M x = 0 \<longleftrightarrow> x \<notin># M"
   194   by (auto simp add: set_mset_def)
   195 
   196 lemma not_in_iff:
   197   "x \<notin># M \<longleftrightarrow> count M x = 0"
   198   by (auto simp add: count_eq_zero_iff)
   199 
   200 lemma count_greater_zero_iff [simp]:
   201   "count M x > 0 \<longleftrightarrow> x \<in># M"
   202   by (auto simp add: set_mset_def)
   203 
   204 lemma count_inI:
   205   assumes "count M x = 0 \<Longrightarrow> False"
   206   shows "x \<in># M"
   207 proof (rule ccontr)
   208   assume "x \<notin># M"
   209   with assms show False by (simp add: not_in_iff)
   210 qed
   211 
   212 lemma in_countE:
   213   assumes "x \<in># M"
   214   obtains n where "count M x = Suc n"
   215 proof -
   216   from assms have "count M x > 0" by simp
   217   then obtain n where "count M x = Suc n"
   218     using gr0_conv_Suc by blast
   219   with that show thesis .
   220 qed
   221 
   222 lemma count_greater_eq_Suc_zero_iff [simp]:
   223   "count M x \<ge> Suc 0 \<longleftrightarrow> x \<in># M"
   224   by (simp add: Suc_le_eq)
   225 
   226 lemma count_greater_eq_one_iff [simp]:
   227   "count M x \<ge> 1 \<longleftrightarrow> x \<in># M"
   228   by simp
   229 
   230 lemma set_mset_empty [simp]:
   231   "set_mset {#} = {}"
   232   by (simp add: set_mset_def)
   233 
   234 lemma set_mset_single:
   235   "set_mset {#b#} = {b}"
   236   by (simp add: set_mset_def)
   237 
   238 lemma set_mset_eq_empty_iff [simp]:
   239   "set_mset M = {} \<longleftrightarrow> M = {#}"
   240   by (auto simp add: multiset_eq_iff count_eq_zero_iff)
   241 
   242 lemma finite_set_mset [iff]:
   243   "finite (set_mset M)"
   244   using count [of M] by (simp add: multiset_def)
   245 
   246 lemma set_mset_add_mset_insert [simp]: \<open>set_mset (add_mset a A) = insert a (set_mset A)\<close>
   247   by (auto simp del: count_greater_eq_Suc_zero_iff
   248       simp: count_greater_eq_Suc_zero_iff[symmetric] split: if_splits)
   249 
   250 lemma multiset_nonemptyE [elim]:
   251   assumes "A \<noteq> {#}"
   252   obtains x where "x \<in># A"
   253 proof -
   254   have "\<exists>x. x \<in># A" by (rule ccontr) (insert assms, auto)
   255   with that show ?thesis by blast
   256 qed
   257 
   258 
   259 subsubsection \<open>Union\<close>
   260 
   261 lemma count_union [simp]:
   262   "count (M + N) a = count M a + count N a"
   263   by (simp add: plus_multiset.rep_eq)
   264 
   265 lemma set_mset_union [simp]:
   266   "set_mset (M + N) = set_mset M \<union> set_mset N"
   267   by (simp only: set_eq_iff count_greater_zero_iff [symmetric] count_union) simp
   268 
   269 lemma union_mset_add_mset_left [simp]:
   270   "add_mset a A + B = add_mset a (A + B)"
   271   by (auto simp: multiset_eq_iff)
   272 
   273 lemma union_mset_add_mset_right [simp]:
   274   "A + add_mset a B = add_mset a (A + B)"
   275   by (auto simp: multiset_eq_iff)
   276 
   277 lemma add_mset_add_single: \<open>add_mset a A = A + {#a#}\<close>
   278   by (subst union_mset_add_mset_right, subst add.comm_neutral) standard
   279 
   280 
   281 subsubsection \<open>Difference\<close>
   282 
   283 instance multiset :: (type) comm_monoid_diff
   284   by standard (transfer; simp add: fun_eq_iff)
   285 
   286 lemma count_diff [simp]:
   287   "count (M - N) a = count M a - count N a"
   288   by (simp add: minus_multiset.rep_eq)
   289 
   290 lemma add_mset_diff_bothsides:
   291   \<open>add_mset a M - add_mset a A = M - A\<close>
   292   by (auto simp: multiset_eq_iff)
   293 
   294 lemma in_diff_count:
   295   "a \<in># M - N \<longleftrightarrow> count N a < count M a"
   296   by (simp add: set_mset_def)
   297 
   298 lemma count_in_diffI:
   299   assumes "\<And>n. count N x = n + count M x \<Longrightarrow> False"
   300   shows "x \<in># M - N"
   301 proof (rule ccontr)
   302   assume "x \<notin># M - N"
   303   then have "count N x = (count N x - count M x) + count M x"
   304     by (simp add: in_diff_count not_less)
   305   with assms show False by auto
   306 qed
   307 
   308 lemma in_diff_countE:
   309   assumes "x \<in># M - N"
   310   obtains n where "count M x = Suc n + count N x"
   311 proof -
   312   from assms have "count M x - count N x > 0" by (simp add: in_diff_count)
   313   then have "count M x > count N x" by simp
   314   then obtain n where "count M x = Suc n + count N x"
   315     using less_iff_Suc_add by auto
   316   with that show thesis .
   317 qed
   318 
   319 lemma in_diffD:
   320   assumes "a \<in># M - N"
   321   shows "a \<in># M"
   322 proof -
   323   have "0 \<le> count N a" by simp
   324   also from assms have "count N a < count M a"
   325     by (simp add: in_diff_count)
   326   finally show ?thesis by simp
   327 qed
   328 
   329 lemma set_mset_diff:
   330   "set_mset (M - N) = {a. count N a < count M a}"
   331   by (simp add: set_mset_def)
   332 
   333 lemma diff_empty [simp]: "M - {#} = M \<and> {#} - M = {#}"
   334   by rule (fact Groups.diff_zero, fact Groups.zero_diff)
   335 
   336 lemma diff_cancel: "A - A = {#}"
   337   by (fact Groups.diff_cancel)
   338 
   339 lemma diff_union_cancelR: "M + N - N = (M::'a multiset)"
   340   by (fact add_diff_cancel_right')
   341 
   342 lemma diff_union_cancelL: "N + M - N = (M::'a multiset)"
   343   by (fact add_diff_cancel_left')
   344 
   345 lemma diff_right_commute:
   346   fixes M N Q :: "'a multiset"
   347   shows "M - N - Q = M - Q - N"
   348   by (fact diff_right_commute)
   349 
   350 lemma diff_add:
   351   fixes M N Q :: "'a multiset"
   352   shows "M - (N + Q) = M - N - Q"
   353   by (rule sym) (fact diff_diff_add)
   354 
   355 lemma insert_DiffM [simp]: "x \<in># M \<Longrightarrow> add_mset x (M - {#x#}) = M"
   356   by (clarsimp simp: multiset_eq_iff)
   357 
   358 lemma insert_DiffM2: "x \<in># M \<Longrightarrow> (M - {#x#}) + {#x#} = M"
   359   by simp
   360 
   361 lemma diff_union_swap: "a \<noteq> b \<Longrightarrow> add_mset b (M - {#a#}) = add_mset b M - {#a#}"
   362   by (auto simp add: multiset_eq_iff)
   363 
   364 lemma diff_add_mset_swap [simp]: "b \<notin># A \<Longrightarrow> add_mset b M - A = add_mset b (M - A)"
   365   by (auto simp add: multiset_eq_iff simp: not_in_iff)
   366 
   367 lemma diff_union_swap2 [simp]: "y \<in># M \<Longrightarrow> add_mset x M - {#y#} = add_mset x (M - {#y#})"
   368   by (metis add_mset_diff_bothsides diff_union_swap diff_zero insert_DiffM)
   369 
   370 lemma diff_diff_add_mset [simp]: "(M::'a multiset) - N - P = M - (N + P)"
   371   by (rule diff_diff_add)
   372 
   373 lemma diff_union_single_conv:
   374   "a \<in># J \<Longrightarrow> I + J - {#a#} = I + (J - {#a#})"
   375   by (simp add: multiset_eq_iff Suc_le_eq)
   376 
   377 lemma mset_add [elim?]:
   378   assumes "a \<in># A"
   379   obtains B where "A = add_mset a B"
   380 proof -
   381   from assms have "A = add_mset a (A - {#a#})"
   382     by simp
   383   with that show thesis .
   384 qed
   385 
   386 lemma union_iff:
   387   "a \<in># A + B \<longleftrightarrow> a \<in># A \<or> a \<in># B"
   388   by auto
   389 
   390 
   391 subsubsection \<open>Min and Max\<close>
   392 
   393 abbreviation Min_mset :: "'a::linorder multiset \<Rightarrow> 'a" where
   394 "Min_mset m \<equiv> Min (set_mset m)"
   395 
   396 abbreviation Max_mset :: "'a::linorder multiset \<Rightarrow> 'a" where
   397 "Max_mset m \<equiv> Max (set_mset m)"
   398 
   399 
   400 subsubsection \<open>Equality of multisets\<close>
   401 
   402 lemma single_eq_single [simp]: "{#a#} = {#b#} \<longleftrightarrow> a = b"
   403   by (auto simp add: multiset_eq_iff)
   404 
   405 lemma union_eq_empty [iff]: "M + N = {#} \<longleftrightarrow> M = {#} \<and> N = {#}"
   406   by (auto simp add: multiset_eq_iff)
   407 
   408 lemma empty_eq_union [iff]: "{#} = M + N \<longleftrightarrow> M = {#} \<and> N = {#}"
   409   by (auto simp add: multiset_eq_iff)
   410 
   411 lemma multi_self_add_other_not_self [simp]: "M = add_mset x M \<longleftrightarrow> False"
   412   by (auto simp add: multiset_eq_iff)
   413 
   414 lemma add_mset_remove_trivial [simp]: \<open>add_mset x M - {#x#} = M\<close>
   415   by (auto simp: multiset_eq_iff)
   416 
   417 lemma diff_single_trivial: "\<not> x \<in># M \<Longrightarrow> M - {#x#} = M"
   418   by (auto simp add: multiset_eq_iff not_in_iff)
   419 
   420 lemma diff_single_eq_union: "x \<in># M \<Longrightarrow> M - {#x#} = N \<longleftrightarrow> M = add_mset x N"
   421   by auto
   422 
   423 lemma union_single_eq_diff: "add_mset x M = N \<Longrightarrow> M = N - {#x#}"
   424   unfolding add_mset_add_single[of _ M] by (fact add_implies_diff)
   425 
   426 lemma union_single_eq_member: "add_mset x M = N \<Longrightarrow> x \<in># N"
   427   by auto
   428 
   429 lemma add_mset_remove_trivial_If:
   430   "add_mset a (N - {#a#}) = (if a \<in># N then N else add_mset a N)"
   431   by (simp add: diff_single_trivial)
   432 
   433 lemma add_mset_remove_trivial_eq: \<open>N = add_mset a (N - {#a#}) \<longleftrightarrow> a \<in># N\<close>
   434   by (auto simp: add_mset_remove_trivial_If)
   435 
   436 lemma union_is_single:
   437   "M + N = {#a#} \<longleftrightarrow> M = {#a#} \<and> N = {#} \<or> M = {#} \<and> N = {#a#}"
   438   (is "?lhs = ?rhs")
   439 proof
   440   show ?lhs if ?rhs using that by auto
   441   show ?rhs if ?lhs
   442     by (metis Multiset.diff_cancel add.commute add_diff_cancel_left' diff_add_zero diff_single_trivial insert_DiffM that)
   443 qed
   444 
   445 lemma single_is_union: "{#a#} = M + N \<longleftrightarrow> {#a#} = M \<and> N = {#} \<or> M = {#} \<and> {#a#} = N"
   446   by (auto simp add: eq_commute [of "{#a#}" "M + N"] union_is_single)
   447 
   448 lemma add_eq_conv_diff:
   449   "add_mset a M = add_mset b N \<longleftrightarrow> M = N \<and> a = b \<or> M = add_mset b (N - {#a#}) \<and> N = add_mset a (M - {#b#})"
   450   (is "?lhs \<longleftrightarrow> ?rhs")
   451 (* shorter: by (simp add: multiset_eq_iff) fastforce *)
   452 proof
   453   show ?lhs if ?rhs
   454     using that
   455     by (auto simp add: add_mset_commute[of a b])
   456   show ?rhs if ?lhs
   457   proof (cases "a = b")
   458     case True with \<open>?lhs\<close> show ?thesis by simp
   459   next
   460     case False
   461     from \<open>?lhs\<close> have "a \<in># add_mset b N" by (rule union_single_eq_member)
   462     with False have "a \<in># N" by auto
   463     moreover from \<open>?lhs\<close> have "M = add_mset b N - {#a#}" by (rule union_single_eq_diff)
   464     moreover note False
   465     ultimately show ?thesis by (auto simp add: diff_right_commute [of _ "{#a#}"])
   466   qed
   467 qed
   468 
   469 lemma add_mset_eq_single [iff]: "add_mset b M = {#a#} \<longleftrightarrow> b = a \<and> M = {#}"
   470   by (auto simp: add_eq_conv_diff)
   471 
   472 lemma single_eq_add_mset [iff]: "{#a#} = add_mset b M \<longleftrightarrow> b = a \<and> M = {#}"
   473   by (auto simp: add_eq_conv_diff)
   474 
   475 lemma insert_noteq_member:
   476   assumes BC: "add_mset b B = add_mset c C"
   477    and bnotc: "b \<noteq> c"
   478   shows "c \<in># B"
   479 proof -
   480   have "c \<in># add_mset c C" by simp
   481   have nc: "\<not> c \<in># {#b#}" using bnotc by simp
   482   then have "c \<in># add_mset b B" using BC by simp
   483   then show "c \<in># B" using nc by simp
   484 qed
   485 
   486 lemma add_eq_conv_ex:
   487   "(add_mset a M = add_mset b N) =
   488     (M = N \<and> a = b \<or> (\<exists>K. M = add_mset b K \<and> N = add_mset a K))"
   489   by (auto simp add: add_eq_conv_diff)
   490 
   491 lemma multi_member_split: "x \<in># M \<Longrightarrow> \<exists>A. M = add_mset x A"
   492   by (rule exI [where x = "M - {#x#}"]) simp
   493 
   494 lemma multiset_add_sub_el_shuffle:
   495   assumes "c \<in># B"
   496     and "b \<noteq> c"
   497   shows "add_mset b (B - {#c#}) = add_mset b B - {#c#}"
   498 proof -
   499   from \<open>c \<in># B\<close> obtain A where B: "B = add_mset c A"
   500     by (blast dest: multi_member_split)
   501   have "add_mset b A = add_mset c (add_mset b A) - {#c#}" by simp
   502   then have "add_mset b A = add_mset b (add_mset c A) - {#c#}"
   503     by (simp add: \<open>b \<noteq> c\<close>)
   504   then show ?thesis using B by simp
   505 qed
   506 
   507 lemma add_mset_eq_singleton_iff[iff]:
   508   "add_mset x M = {#y#} \<longleftrightarrow> M = {#} \<and> x = y"
   509   by auto
   510 
   511 
   512 subsubsection \<open>Pointwise ordering induced by count\<close>
   513 
   514 definition subseteq_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool"  (infix "\<subseteq>#" 50)
   515   where "A \<subseteq># B \<longleftrightarrow> (\<forall>a. count A a \<le> count B a)"
   516 
   517 definition subset_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "\<subset>#" 50)
   518   where "A \<subset># B \<longleftrightarrow> A \<subseteq># B \<and> A \<noteq> B"
   519 
   520 abbreviation (input) supseteq_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool"  (infix "\<supseteq>#" 50)
   521   where "supseteq_mset A B \<equiv> B \<subseteq># A"
   522 
   523 abbreviation (input) supset_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool"  (infix "\<supset>#" 50)
   524   where "supset_mset A B \<equiv> B \<subset># A"
   525 
   526 notation (input)
   527   subseteq_mset  (infix "\<le>#" 50) and
   528   supseteq_mset  (infix "\<ge>#" 50)
   529 
   530 notation (ASCII)
   531   subseteq_mset  (infix "<=#" 50) and
   532   subset_mset  (infix "<#" 50) and
   533   supseteq_mset  (infix ">=#" 50) and
   534   supset_mset  (infix ">#" 50)
   535 
   536 interpretation subset_mset: ordered_ab_semigroup_add_imp_le "op +" "op -" "op \<subseteq>#" "op \<subset>#"
   537   by standard (auto simp add: subset_mset_def subseteq_mset_def multiset_eq_iff intro: order_trans antisym)
   538     \<comment> \<open>FIXME: avoid junk stemming from type class interpretation\<close>
   539 
   540 interpretation subset_mset: ordered_ab_semigroup_monoid_add_imp_le "op +" 0 "op -" "op \<subseteq>#" "op \<subset>#"
   541   by standard
   542     \<comment> \<open>FIXME: avoid junk stemming from type class interpretation\<close>
   543 
   544 lemma mset_subset_eqI:
   545   "(\<And>a. count A a \<le> count B a) \<Longrightarrow> A \<subseteq># B"
   546   by (simp add: subseteq_mset_def)
   547 
   548 lemma mset_subset_eq_count:
   549   "A \<subseteq># B \<Longrightarrow> count A a \<le> count B a"
   550   by (simp add: subseteq_mset_def)
   551 
   552 lemma mset_subset_eq_exists_conv: "(A::'a multiset) \<subseteq># B \<longleftrightarrow> (\<exists>C. B = A + C)"
   553   unfolding subseteq_mset_def
   554   apply (rule iffI)
   555    apply (rule exI [where x = "B - A"])
   556    apply (auto intro: multiset_eq_iff [THEN iffD2])
   557   done
   558 
   559 interpretation subset_mset: ordered_cancel_comm_monoid_diff "op +" 0 "op \<subseteq>#" "op \<subset>#" "op -"
   560   by standard (simp, fact mset_subset_eq_exists_conv)
   561     \<comment> \<open>FIXME: avoid junk stemming from type class interpretation\<close>
   562 
   563 declare subset_mset.add_diff_assoc[simp] subset_mset.add_diff_assoc2[simp]
   564 
   565 lemma mset_subset_eq_mono_add_right_cancel: "(A::'a multiset) + C \<subseteq># B + C \<longleftrightarrow> A \<subseteq># B"
   566    by (fact subset_mset.add_le_cancel_right)
   567 
   568 lemma mset_subset_eq_mono_add_left_cancel: "C + (A::'a multiset) \<subseteq># C + B \<longleftrightarrow> A \<subseteq># B"
   569    by (fact subset_mset.add_le_cancel_left)
   570 
   571 lemma mset_subset_eq_mono_add: "(A::'a multiset) \<subseteq># B \<Longrightarrow> C \<subseteq># D \<Longrightarrow> A + C \<subseteq># B + D"
   572    by (fact subset_mset.add_mono)
   573 
   574 lemma mset_subset_eq_add_left: "(A::'a multiset) \<subseteq># A + B"
   575    by simp
   576 
   577 lemma mset_subset_eq_add_right: "B \<subseteq># (A::'a multiset) + B"
   578    by simp
   579 
   580 lemma single_subset_iff [simp]:
   581   "{#a#} \<subseteq># M \<longleftrightarrow> a \<in># M"
   582   by (auto simp add: subseteq_mset_def Suc_le_eq)
   583 
   584 lemma mset_subset_eq_single: "a \<in># B \<Longrightarrow> {#a#} \<subseteq># B"
   585   by simp
   586 
   587 lemma mset_subset_eq_add_mset_cancel: \<open>add_mset a A \<subseteq># add_mset a B \<longleftrightarrow> A \<subseteq># B\<close>
   588   unfolding add_mset_add_single[of _ A] add_mset_add_single[of _ B]
   589   by (rule mset_subset_eq_mono_add_right_cancel)
   590 
   591 lemma multiset_diff_union_assoc:
   592   fixes A B C D :: "'a multiset"
   593   shows "C \<subseteq># B \<Longrightarrow> A + B - C = A + (B - C)"
   594   by (fact subset_mset.diff_add_assoc)
   595 
   596 lemma mset_subset_eq_multiset_union_diff_commute:
   597   fixes A B C D :: "'a multiset"
   598   shows "B \<subseteq># A \<Longrightarrow> A - B + C = A + C - B"
   599   by (fact subset_mset.add_diff_assoc2)
   600 
   601 lemma diff_subset_eq_self[simp]:
   602   "(M::'a multiset) - N \<subseteq># M"
   603   by (simp add: subseteq_mset_def)
   604 
   605 lemma mset_subset_eqD:
   606   assumes "A \<subseteq># B" and "x \<in># A"
   607   shows "x \<in># B"
   608 proof -
   609   from \<open>x \<in># A\<close> have "count A x > 0" by simp
   610   also from \<open>A \<subseteq># B\<close> have "count A x \<le> count B x"
   611     by (simp add: subseteq_mset_def)
   612   finally show ?thesis by simp
   613 qed
   614 
   615 lemma mset_subsetD:
   616   "A \<subset># B \<Longrightarrow> x \<in># A \<Longrightarrow> x \<in># B"
   617   by (auto intro: mset_subset_eqD [of A])
   618 
   619 lemma set_mset_mono:
   620   "A \<subseteq># B \<Longrightarrow> set_mset A \<subseteq> set_mset B"
   621   by (metis mset_subset_eqD subsetI)
   622 
   623 lemma mset_subset_eq_insertD:
   624   "add_mset x A \<subseteq># B \<Longrightarrow> x \<in># B \<and> A \<subset># B"
   625 apply (rule conjI)
   626  apply (simp add: mset_subset_eqD)
   627  apply (clarsimp simp: subset_mset_def subseteq_mset_def)
   628  apply safe
   629   apply (erule_tac x = a in allE)
   630   apply (auto split: if_split_asm)
   631 done
   632 
   633 lemma mset_subset_insertD:
   634   "add_mset x A \<subset># B \<Longrightarrow> x \<in># B \<and> A \<subset># B"
   635   by (rule mset_subset_eq_insertD) simp
   636 
   637 lemma mset_subset_of_empty[simp]: "A \<subset># {#} \<longleftrightarrow> False"
   638   by (simp only: subset_mset.not_less_zero)
   639 
   640 lemma empty_subset_add_mset[simp]: "{#} \<subset># add_mset x M"
   641   by (auto intro: subset_mset.gr_zeroI)
   642 
   643 lemma empty_le: "{#} \<subseteq># A"
   644   by (fact subset_mset.zero_le)
   645 
   646 lemma insert_subset_eq_iff:
   647   "add_mset a A \<subseteq># B \<longleftrightarrow> a \<in># B \<and> A \<subseteq># B - {#a#}"
   648   using le_diff_conv2 [of "Suc 0" "count B a" "count A a"]
   649   apply (auto simp add: subseteq_mset_def not_in_iff Suc_le_eq)
   650   apply (rule ccontr)
   651   apply (auto simp add: not_in_iff)
   652   done
   653 
   654 lemma insert_union_subset_iff:
   655   "add_mset a A \<subset># B \<longleftrightarrow> a \<in># B \<and> A \<subset># B - {#a#}"
   656   by (auto simp add: insert_subset_eq_iff subset_mset_def)
   657 
   658 lemma subset_eq_diff_conv:
   659   "A - C \<subseteq># B \<longleftrightarrow> A \<subseteq># B + C"
   660   by (simp add: subseteq_mset_def le_diff_conv)
   661 
   662 lemma multi_psub_of_add_self [simp]: "A \<subset># add_mset x A"
   663   by (auto simp: subset_mset_def subseteq_mset_def)
   664 
   665 lemma multi_psub_self: "A \<subset># A = False"
   666   by simp
   667 
   668 lemma mset_subset_add_mset [simp]: "add_mset x N \<subset># add_mset x M \<longleftrightarrow> N \<subset># M"
   669   unfolding add_mset_add_single[of _ N] add_mset_add_single[of _ M]
   670   by (fact subset_mset.add_less_cancel_right)
   671 
   672 lemma mset_subset_diff_self: "c \<in># B \<Longrightarrow> B - {#c#} \<subset># B"
   673   by (auto simp: subset_mset_def elim: mset_add)
   674 
   675 lemma Diff_eq_empty_iff_mset: "A - B = {#} \<longleftrightarrow> A \<subseteq># B"
   676   by (auto simp: multiset_eq_iff subseteq_mset_def)
   677 
   678 lemma add_mset_subseteq_single_iff[iff]: "add_mset a M \<subseteq># {#b#} \<longleftrightarrow> M = {#} \<and> a = b"
   679 proof
   680   assume A: "add_mset a M \<subseteq># {#b#}"
   681   then have \<open>a = b\<close>
   682     by (auto dest: mset_subset_eq_insertD)
   683   then show "M={#} \<and> a=b"
   684     using A by (simp add: mset_subset_eq_add_mset_cancel)
   685 qed simp
   686 
   687 
   688 subsubsection \<open>Intersection and bounded union\<close>
   689 
   690 definition inf_subset_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" (infixl "\<inter>#" 70) where
   691   multiset_inter_def: "inf_subset_mset A B = A - (A - B)"
   692 
   693 interpretation subset_mset: semilattice_inf inf_subset_mset "op \<subseteq>#" "op \<subset>#"
   694 proof -
   695   have [simp]: "m \<le> n \<Longrightarrow> m \<le> q \<Longrightarrow> m \<le> n - (n - q)" for m n q :: nat
   696     by arith
   697   show "class.semilattice_inf op \<inter># op \<subseteq># op \<subset>#"
   698     by standard (auto simp add: multiset_inter_def subseteq_mset_def)
   699 qed \<comment> \<open>FIXME: avoid junk stemming from type class interpretation\<close>
   700 
   701 definition sup_subset_mset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset"(infixl "\<union>#" 70)
   702   where "sup_subset_mset A B = A + (B - A)" \<comment> \<open>FIXME irregular fact name\<close>
   703 
   704 interpretation subset_mset: semilattice_sup sup_subset_mset "op \<subseteq>#" "op \<subset>#"
   705 proof -
   706   have [simp]: "m \<le> n \<Longrightarrow> q \<le> n \<Longrightarrow> m + (q - m) \<le> n" for m n q :: nat
   707     by arith
   708   show "class.semilattice_sup op \<union># op \<subseteq># op \<subset>#"
   709     by standard (auto simp add: sup_subset_mset_def subseteq_mset_def)
   710 qed \<comment> \<open>FIXME: avoid junk stemming from type class interpretation\<close>
   711 
   712 interpretation subset_mset: bounded_lattice_bot "op \<inter>#" "op \<subseteq>#" "op \<subset>#"
   713   "op \<union>#" "{#}"
   714   by standard auto
   715     \<comment> \<open>FIXME: avoid junk stemming from type class interpretation\<close>
   716 
   717 
   718 subsubsection \<open>Additional intersection facts\<close>
   719 
   720 lemma multiset_inter_count [simp]:
   721   fixes A B :: "'a multiset"
   722   shows "count (A \<inter># B) x = min (count A x) (count B x)"
   723   by (simp add: multiset_inter_def)
   724 
   725 lemma set_mset_inter [simp]:
   726   "set_mset (A \<inter># B) = set_mset A \<inter> set_mset B"
   727   by (simp only: set_eq_iff count_greater_zero_iff [symmetric] multiset_inter_count) simp
   728 
   729 lemma diff_intersect_left_idem [simp]:
   730   "M - M \<inter># N = M - N"
   731   by (simp add: multiset_eq_iff min_def)
   732 
   733 lemma diff_intersect_right_idem [simp]:
   734   "M - N \<inter># M = M - N"
   735   by (simp add: multiset_eq_iff min_def)
   736 
   737 lemma multiset_inter_single[simp]: "a \<noteq> b \<Longrightarrow> {#a#} \<inter># {#b#} = {#}"
   738   by (rule multiset_eqI) auto
   739 
   740 lemma multiset_union_diff_commute:
   741   assumes "B \<inter># C = {#}"
   742   shows "A + B - C = A - C + B"
   743 proof (rule multiset_eqI)
   744   fix x
   745   from assms have "min (count B x) (count C x) = 0"
   746     by (auto simp add: multiset_eq_iff)
   747   then have "count B x = 0 \<or> count C x = 0"
   748     unfolding min_def by (auto split: if_splits)
   749   then show "count (A + B - C) x = count (A - C + B) x"
   750     by auto
   751 qed
   752 
   753 lemma disjunct_not_in:
   754   "A \<inter># B = {#} \<longleftrightarrow> (\<forall>a. a \<notin># A \<or> a \<notin># B)" (is "?P \<longleftrightarrow> ?Q")
   755 proof
   756   assume ?P
   757   show ?Q
   758   proof
   759     fix a
   760     from \<open>?P\<close> have "min (count A a) (count B a) = 0"
   761       by (simp add: multiset_eq_iff)
   762     then have "count A a = 0 \<or> count B a = 0"
   763       by (cases "count A a \<le> count B a") (simp_all add: min_def)
   764     then show "a \<notin># A \<or> a \<notin># B"
   765       by (simp add: not_in_iff)
   766   qed
   767 next
   768   assume ?Q
   769   show ?P
   770   proof (rule multiset_eqI)
   771     fix a
   772     from \<open>?Q\<close> have "count A a = 0 \<or> count B a = 0"
   773       by (auto simp add: not_in_iff)
   774     then show "count (A \<inter># B) a = count {#} a"
   775       by auto
   776   qed
   777 qed
   778 
   779 lemma inter_mset_empty_distrib_right: "A \<inter># (B + C) = {#} \<longleftrightarrow> A \<inter># B = {#} \<and> A \<inter># C = {#}"
   780   by (meson disjunct_not_in union_iff)
   781 
   782 lemma inter_mset_empty_distrib_left: "(A + B) \<inter># C = {#} \<longleftrightarrow> A \<inter># C = {#} \<and> B \<inter># C = {#}"
   783   by (meson disjunct_not_in union_iff)
   784 
   785 lemma add_mset_inter_add_mset[simp]:
   786   "add_mset a A \<inter># add_mset a B = add_mset a (A \<inter># B)"
   787   by (metis add_mset_add_single add_mset_diff_bothsides diff_subset_eq_self multiset_inter_def
   788       subset_mset.diff_add_assoc2)
   789 
   790 lemma add_mset_disjoint [simp]:
   791   "add_mset a A \<inter># B = {#} \<longleftrightarrow> a \<notin># B \<and> A \<inter># B = {#}"
   792   "{#} = add_mset a A \<inter># B \<longleftrightarrow> a \<notin># B \<and> {#} = A \<inter># B"
   793   by (auto simp: disjunct_not_in)
   794 
   795 lemma disjoint_add_mset [simp]:
   796   "B \<inter># add_mset a A = {#} \<longleftrightarrow> a \<notin># B \<and> B \<inter># A = {#}"
   797   "{#} = A \<inter># add_mset b B \<longleftrightarrow> b \<notin># A \<and> {#} = A \<inter># B"
   798   by (auto simp: disjunct_not_in)
   799 
   800 lemma inter_add_left1: "\<not> x \<in># N \<Longrightarrow> (add_mset x M) \<inter># N = M \<inter># N"
   801   by (simp add: multiset_eq_iff not_in_iff)
   802 
   803 lemma inter_add_left2: "x \<in># N \<Longrightarrow> (add_mset x M) \<inter># N = add_mset x (M \<inter># (N - {#x#}))"
   804   by (auto simp add: multiset_eq_iff elim: mset_add)
   805 
   806 lemma inter_add_right1: "\<not> x \<in># N \<Longrightarrow> N \<inter># (add_mset x M) = N \<inter># M"
   807   by (simp add: multiset_eq_iff not_in_iff)
   808 
   809 lemma inter_add_right2: "x \<in># N \<Longrightarrow> N \<inter># (add_mset x M) = add_mset x ((N - {#x#}) \<inter># M)"
   810   by (auto simp add: multiset_eq_iff elim: mset_add)
   811 
   812 lemma disjunct_set_mset_diff:
   813   assumes "M \<inter># N = {#}"
   814   shows "set_mset (M - N) = set_mset M"
   815 proof (rule set_eqI)
   816   fix a
   817   from assms have "a \<notin># M \<or> a \<notin># N"
   818     by (simp add: disjunct_not_in)
   819   then show "a \<in># M - N \<longleftrightarrow> a \<in># M"
   820     by (auto dest: in_diffD) (simp add: in_diff_count not_in_iff)
   821 qed
   822 
   823 lemma at_most_one_mset_mset_diff:
   824   assumes "a \<notin># M - {#a#}"
   825   shows "set_mset (M - {#a#}) = set_mset M - {a}"
   826   using assms by (auto simp add: not_in_iff in_diff_count set_eq_iff)
   827 
   828 lemma more_than_one_mset_mset_diff:
   829   assumes "a \<in># M - {#a#}"
   830   shows "set_mset (M - {#a#}) = set_mset M"
   831 proof (rule set_eqI)
   832   fix b
   833   have "Suc 0 < count M b \<Longrightarrow> count M b > 0" by arith
   834   then show "b \<in># M - {#a#} \<longleftrightarrow> b \<in># M"
   835     using assms by (auto simp add: in_diff_count)
   836 qed
   837 
   838 lemma inter_iff:
   839   "a \<in># A \<inter># B \<longleftrightarrow> a \<in># A \<and> a \<in># B"
   840   by simp
   841 
   842 lemma inter_union_distrib_left:
   843   "A \<inter># B + C = (A + C) \<inter># (B + C)"
   844   by (simp add: multiset_eq_iff min_add_distrib_left)
   845 
   846 lemma inter_union_distrib_right:
   847   "C + A \<inter># B = (C + A) \<inter># (C + B)"
   848   using inter_union_distrib_left [of A B C] by (simp add: ac_simps)
   849 
   850 lemma inter_subset_eq_union:
   851   "A \<inter># B \<subseteq># A + B"
   852   by (auto simp add: subseteq_mset_def)
   853 
   854 
   855 subsubsection \<open>Additional bounded union facts\<close>
   856 
   857 lemma sup_subset_mset_count [simp]: \<comment> \<open>FIXME irregular fact name\<close>
   858   "count (A \<union># B) x = max (count A x) (count B x)"
   859   by (simp add: sup_subset_mset_def)
   860 
   861 lemma set_mset_sup [simp]:
   862   "set_mset (A \<union># B) = set_mset A \<union> set_mset B"
   863   by (simp only: set_eq_iff count_greater_zero_iff [symmetric] sup_subset_mset_count)
   864     (auto simp add: not_in_iff elim: mset_add)
   865 
   866 lemma sup_union_left1 [simp]: "\<not> x \<in># N \<Longrightarrow> (add_mset x M) \<union># N = add_mset x (M \<union># N)"
   867   by (simp add: multiset_eq_iff not_in_iff)
   868 
   869 lemma sup_union_left2: "x \<in># N \<Longrightarrow> (add_mset x M) \<union># N = add_mset x (M \<union># (N - {#x#}))"
   870   by (simp add: multiset_eq_iff)
   871 
   872 lemma sup_union_right1 [simp]: "\<not> x \<in># N \<Longrightarrow> N \<union># (add_mset x M) = add_mset x (N \<union># M)"
   873   by (simp add: multiset_eq_iff not_in_iff)
   874 
   875 lemma sup_union_right2: "x \<in># N \<Longrightarrow> N \<union># (add_mset x M) = add_mset x ((N - {#x#}) \<union># M)"
   876   by (simp add: multiset_eq_iff)
   877 
   878 lemma sup_union_distrib_left:
   879   "A \<union># B + C = (A + C) \<union># (B + C)"
   880   by (simp add: multiset_eq_iff max_add_distrib_left)
   881 
   882 lemma union_sup_distrib_right:
   883   "C + A \<union># B = (C + A) \<union># (C + B)"
   884   using sup_union_distrib_left [of A B C] by (simp add: ac_simps)
   885 
   886 lemma union_diff_inter_eq_sup:
   887   "A + B - A \<inter># B = A \<union># B"
   888   by (auto simp add: multiset_eq_iff)
   889 
   890 lemma union_diff_sup_eq_inter:
   891   "A + B - A \<union># B = A \<inter># B"
   892   by (auto simp add: multiset_eq_iff)
   893 
   894 lemma add_mset_union:
   895   \<open>add_mset a A \<union># add_mset a B = add_mset a (A \<union># B)\<close>
   896   by (auto simp: multiset_eq_iff max_def)
   897 
   898 
   899 subsection \<open>Replicate and repeat operations\<close>
   900 
   901 definition replicate_mset :: "nat \<Rightarrow> 'a \<Rightarrow> 'a multiset" where
   902   "replicate_mset n x = (add_mset x ^^ n) {#}"
   903 
   904 lemma replicate_mset_0[simp]: "replicate_mset 0 x = {#}"
   905   unfolding replicate_mset_def by simp
   906 
   907 lemma replicate_mset_Suc [simp]: "replicate_mset (Suc n) x = add_mset x (replicate_mset n x)"
   908   unfolding replicate_mset_def by (induct n) (auto intro: add.commute)
   909 
   910 lemma count_replicate_mset[simp]: "count (replicate_mset n x) y = (if y = x then n else 0)"
   911   unfolding replicate_mset_def by (induct n) auto
   912 
   913 fun repeat_mset :: "nat \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" where
   914   "repeat_mset 0 _ = {#}" |
   915   "repeat_mset (Suc n) A = A + repeat_mset n A"
   916 
   917 lemma count_repeat_mset [simp]: "count (repeat_mset i A) a = i * count A a"
   918   by (induction i) auto
   919 
   920 lemma repeat_mset_right [simp]: "repeat_mset a (repeat_mset b A) = repeat_mset (a * b) A"
   921   by (auto simp: multiset_eq_iff left_diff_distrib')
   922 
   923 lemma left_diff_repeat_mset_distrib': \<open>repeat_mset (i - j) u = repeat_mset i u - repeat_mset j u\<close>
   924   by (auto simp: multiset_eq_iff left_diff_distrib')
   925 
   926 lemma left_add_mult_distrib_mset:
   927   "repeat_mset i u + (repeat_mset j u + k) = repeat_mset (i+j) u + k"
   928   by (auto simp: multiset_eq_iff add_mult_distrib)
   929 
   930 lemma repeat_mset_distrib:
   931   "repeat_mset (m + n) A = repeat_mset m A + repeat_mset n A"
   932   by (auto simp: multiset_eq_iff Nat.add_mult_distrib)
   933 
   934 lemma repeat_mset_distrib2[simp]:
   935   "repeat_mset n (A + B) = repeat_mset n A + repeat_mset n B"
   936   by (auto simp: multiset_eq_iff add_mult_distrib2)
   937 
   938 lemma repeat_mset_replicate_mset[simp]:
   939   "repeat_mset n {#a#} = replicate_mset n a"
   940   by (auto simp: multiset_eq_iff)
   941 
   942 lemma repeat_mset_distrib_add_mset[simp]:
   943   "repeat_mset n (add_mset a A) = replicate_mset n a + repeat_mset n A"
   944   by (auto simp: multiset_eq_iff)
   945 
   946 lemma repeat_mset_empty[simp]: "repeat_mset n {#} = {#}"
   947   by (induction n) simp_all
   948 
   949 
   950 subsubsection \<open>Simprocs\<close>
   951 
   952 lemma repeat_mset_iterate_add: \<open>repeat_mset n M = iterate_add n M\<close>
   953   unfolding iterate_add_def by (induction n) auto
   954 
   955 lemma mset_subseteq_add_iff1:
   956   "j \<le> (i::nat) \<Longrightarrow> (repeat_mset i u + m \<subseteq># repeat_mset j u + n) = (repeat_mset (i-j) u + m \<subseteq># n)"
   957   by (auto simp add: subseteq_mset_def nat_le_add_iff1)
   958 
   959 lemma mset_subseteq_add_iff2:
   960   "i \<le> (j::nat) \<Longrightarrow> (repeat_mset i u + m \<subseteq># repeat_mset j u + n) = (m \<subseteq># repeat_mset (j-i) u + n)"
   961   by (auto simp add: subseteq_mset_def nat_le_add_iff2)
   962 
   963 lemma mset_subset_add_iff1:
   964   "j \<le> (i::nat) \<Longrightarrow> (repeat_mset i u + m \<subset># repeat_mset j u + n) = (repeat_mset (i-j) u + m \<subset># n)"
   965   unfolding subset_mset_def repeat_mset_iterate_add
   966   by (simp add: iterate_add_eq_add_iff1 mset_subseteq_add_iff1[unfolded repeat_mset_iterate_add])
   967 
   968 lemma mset_subset_add_iff2:
   969   "i \<le> (j::nat) \<Longrightarrow> (repeat_mset i u + m \<subset># repeat_mset j u + n) = (m \<subset># repeat_mset (j-i) u + n)"
   970   unfolding subset_mset_def repeat_mset_iterate_add
   971   by (simp add: iterate_add_eq_add_iff2 mset_subseteq_add_iff2[unfolded repeat_mset_iterate_add])
   972 
   973 ML_file "multiset_simprocs.ML"
   974 
   975 lemma add_mset_replicate_mset_safe[cancelation_simproc_pre]: \<open>NO_MATCH {#} M \<Longrightarrow> add_mset a M = {#a#} + M\<close>
   976   by simp
   977 
   978 declare repeat_mset_iterate_add[cancelation_simproc_pre]
   979 
   980 declare iterate_add_distrib[cancelation_simproc_pre]
   981 declare repeat_mset_iterate_add[symmetric, cancelation_simproc_post]
   982 
   983 declare add_mset_not_empty[cancelation_simproc_eq_elim]
   984     empty_not_add_mset[cancelation_simproc_eq_elim]
   985     subset_mset.le_zero_eq[cancelation_simproc_eq_elim]
   986     empty_not_add_mset[cancelation_simproc_eq_elim]
   987     add_mset_not_empty[cancelation_simproc_eq_elim]
   988     subset_mset.le_zero_eq[cancelation_simproc_eq_elim]
   989     le_zero_eq[cancelation_simproc_eq_elim]
   990 
   991 simproc_setup mseteq_cancel
   992   ("(l::'a multiset) + m = n" | "(l::'a multiset) = m + n" |
   993    "add_mset a m = n" | "m = add_mset a n" |
   994    "replicate_mset p a = n" | "m = replicate_mset p a" |
   995    "repeat_mset p m = n" | "m = repeat_mset p m") =
   996   \<open>fn phi => Cancel_Simprocs.eq_cancel\<close>
   997 
   998 simproc_setup msetsubset_cancel
   999   ("(l::'a multiset) + m \<subset># n" | "(l::'a multiset) \<subset># m + n" |
  1000    "add_mset a m \<subset># n" | "m \<subset># add_mset a n" |
  1001    "replicate_mset p r \<subset># n" | "m \<subset># replicate_mset p r" |
  1002    "repeat_mset p m \<subset># n" | "m \<subset># repeat_mset p m") =
  1003   \<open>fn phi => Multiset_Simprocs.subset_cancel_msets\<close>
  1004 
  1005 simproc_setup msetsubset_eq_cancel
  1006   ("(l::'a multiset) + m \<subseteq># n" | "(l::'a multiset) \<subseteq># m + n" |
  1007    "add_mset a m \<subseteq># n" | "m \<subseteq># add_mset a n" |
  1008    "replicate_mset p r \<subseteq># n" | "m \<subseteq># replicate_mset p r" |
  1009    "repeat_mset p m \<subseteq># n" | "m \<subseteq># repeat_mset p m") =
  1010   \<open>fn phi => Multiset_Simprocs.subseteq_cancel_msets\<close>
  1011 
  1012 simproc_setup msetdiff_cancel
  1013   ("((l::'a multiset) + m) - n" | "(l::'a multiset) - (m + n)" |
  1014    "add_mset a m - n" | "m - add_mset a n" |
  1015    "replicate_mset p r - n" | "m - replicate_mset p r" |
  1016    "repeat_mset p m - n" | "m - repeat_mset p m") =
  1017   \<open>fn phi => Cancel_Simprocs.diff_cancel\<close>
  1018 
  1019 
  1020 subsubsection \<open>Conditionally complete lattice\<close>
  1021 
  1022 instantiation multiset :: (type) Inf
  1023 begin
  1024 
  1025 lift_definition Inf_multiset :: "'a multiset set \<Rightarrow> 'a multiset" is
  1026   "\<lambda>A i. if A = {} then 0 else Inf ((\<lambda>f. f i) ` A)"
  1027 proof -
  1028   fix A :: "('a \<Rightarrow> nat) set" assume *: "\<And>x. x \<in> A \<Longrightarrow> x \<in> multiset"
  1029   have "finite {i. (if A = {} then 0 else Inf ((\<lambda>f. f i) ` A)) > 0}" unfolding multiset_def
  1030   proof (cases "A = {}")
  1031     case False
  1032     then obtain f where "f \<in> A" by blast
  1033     hence "{i. Inf ((\<lambda>f. f i) ` A) > 0} \<subseteq> {i. f i > 0}"
  1034       by (auto intro: less_le_trans[OF _ cInf_lower])
  1035     moreover from \<open>f \<in> A\<close> * have "finite \<dots>" by (simp add: multiset_def)
  1036     ultimately have "finite {i. Inf ((\<lambda>f. f i) ` A) > 0}" by (rule finite_subset)
  1037     with False show ?thesis by simp
  1038   qed simp_all
  1039   thus "(\<lambda>i. if A = {} then 0 else INF f:A. f i) \<in> multiset" by (simp add: multiset_def)
  1040 qed
  1041 
  1042 instance ..
  1043 
  1044 end
  1045 
  1046 lemma Inf_multiset_empty: "Inf {} = {#}"
  1047   by transfer simp_all
  1048 
  1049 lemma count_Inf_multiset_nonempty: "A \<noteq> {} \<Longrightarrow> count (Inf A) x = Inf ((\<lambda>X. count X x) ` A)"
  1050   by transfer simp_all
  1051 
  1052 
  1053 instantiation multiset :: (type) Sup
  1054 begin
  1055 
  1056 definition Sup_multiset :: "'a multiset set \<Rightarrow> 'a multiset" where
  1057   "Sup_multiset A = (if A \<noteq> {} \<and> subset_mset.bdd_above A then
  1058            Abs_multiset (\<lambda>i. Sup ((\<lambda>X. count X i) ` A)) else {#})"
  1059 
  1060 lemma Sup_multiset_empty: "Sup {} = {#}"
  1061   by (simp add: Sup_multiset_def)
  1062 
  1063 lemma Sup_multiset_unbounded: "\<not>subset_mset.bdd_above A \<Longrightarrow> Sup A = {#}"
  1064   by (simp add: Sup_multiset_def)
  1065 
  1066 instance ..
  1067 
  1068 end
  1069 
  1070 
  1071 lemma bdd_above_multiset_imp_bdd_above_count:
  1072   assumes "subset_mset.bdd_above (A :: 'a multiset set)"
  1073   shows   "bdd_above ((\<lambda>X. count X x) ` A)"
  1074 proof -
  1075   from assms obtain Y where Y: "\<forall>X\<in>A. X \<subseteq># Y"
  1076     by (auto simp: subset_mset.bdd_above_def)
  1077   hence "count X x \<le> count Y x" if "X \<in> A" for X
  1078     using that by (auto intro: mset_subset_eq_count)
  1079   thus ?thesis by (intro bdd_aboveI[of _ "count Y x"]) auto
  1080 qed
  1081 
  1082 lemma bdd_above_multiset_imp_finite_support:
  1083   assumes "A \<noteq> {}" "subset_mset.bdd_above (A :: 'a multiset set)"
  1084   shows   "finite (\<Union>X\<in>A. {x. count X x > 0})"
  1085 proof -
  1086   from assms obtain Y where Y: "\<forall>X\<in>A. X \<subseteq># Y"
  1087     by (auto simp: subset_mset.bdd_above_def)
  1088   hence "count X x \<le> count Y x" if "X \<in> A" for X x
  1089     using that by (auto intro: mset_subset_eq_count)
  1090   hence "(\<Union>X\<in>A. {x. count X x > 0}) \<subseteq> {x. count Y x > 0}"
  1091     by safe (erule less_le_trans)
  1092   moreover have "finite \<dots>" by simp
  1093   ultimately show ?thesis by (rule finite_subset)
  1094 qed
  1095 
  1096 lemma Sup_multiset_in_multiset:
  1097   assumes "A \<noteq> {}" "subset_mset.bdd_above A"
  1098   shows   "(\<lambda>i. SUP X:A. count X i) \<in> multiset"
  1099   unfolding multiset_def
  1100 proof
  1101   have "{i. Sup ((\<lambda>X. count X i) ` A) > 0} \<subseteq> (\<Union>X\<in>A. {i. 0 < count X i})"
  1102   proof safe
  1103     fix i assume pos: "(SUP X:A. count X i) > 0"
  1104     show "i \<in> (\<Union>X\<in>A. {i. 0 < count X i})"
  1105     proof (rule ccontr)
  1106       assume "i \<notin> (\<Union>X\<in>A. {i. 0 < count X i})"
  1107       hence "\<forall>X\<in>A. count X i \<le> 0" by (auto simp: count_eq_zero_iff)
  1108       with assms have "(SUP X:A. count X i) \<le> 0"
  1109         by (intro cSup_least bdd_above_multiset_imp_bdd_above_count) auto
  1110       with pos show False by simp
  1111     qed
  1112   qed
  1113   moreover from assms have "finite \<dots>" by (rule bdd_above_multiset_imp_finite_support)
  1114   ultimately show "finite {i. Sup ((\<lambda>X. count X i) ` A) > 0}" by (rule finite_subset)
  1115 qed
  1116 
  1117 lemma count_Sup_multiset_nonempty:
  1118   assumes "A \<noteq> {}" "subset_mset.bdd_above A"
  1119   shows   "count (Sup A) x = (SUP X:A. count X x)"
  1120   using assms by (simp add: Sup_multiset_def Abs_multiset_inverse Sup_multiset_in_multiset)
  1121 
  1122 
  1123 interpretation subset_mset: conditionally_complete_lattice Inf Sup "op \<inter>#" "op \<subseteq>#" "op \<subset>#" "op \<union>#"
  1124 proof
  1125   fix X :: "'a multiset" and A
  1126   assume "X \<in> A"
  1127   show "Inf A \<subseteq># X"
  1128   proof (rule mset_subset_eqI)
  1129     fix x
  1130     from \<open>X \<in> A\<close> have "A \<noteq> {}" by auto
  1131     hence "count (Inf A) x = (INF X:A. count X x)"
  1132       by (simp add: count_Inf_multiset_nonempty)
  1133     also from \<open>X \<in> A\<close> have "\<dots> \<le> count X x"
  1134       by (intro cInf_lower) simp_all
  1135     finally show "count (Inf A) x \<le> count X x" .
  1136   qed
  1137 next
  1138   fix X :: "'a multiset" and A
  1139   assume nonempty: "A \<noteq> {}" and le: "\<And>Y. Y \<in> A \<Longrightarrow> X \<subseteq># Y"
  1140   show "X \<subseteq># Inf A"
  1141   proof (rule mset_subset_eqI)
  1142     fix x
  1143     from nonempty have "count X x \<le> (INF X:A. count X x)"
  1144       by (intro cInf_greatest) (auto intro: mset_subset_eq_count le)
  1145     also from nonempty have "\<dots> = count (Inf A) x" by (simp add: count_Inf_multiset_nonempty)
  1146     finally show "count X x \<le> count (Inf A) x" .
  1147   qed
  1148 next
  1149   fix X :: "'a multiset" and A
  1150   assume X: "X \<in> A" and bdd: "subset_mset.bdd_above A"
  1151   show "X \<subseteq># Sup A"
  1152   proof (rule mset_subset_eqI)
  1153     fix x
  1154     from X have "A \<noteq> {}" by auto
  1155     have "count X x \<le> (SUP X:A. count X x)"
  1156       by (intro cSUP_upper X bdd_above_multiset_imp_bdd_above_count bdd)
  1157     also from count_Sup_multiset_nonempty[OF \<open>A \<noteq> {}\<close> bdd]
  1158       have "(SUP X:A. count X x) = count (Sup A) x" by simp
  1159     finally show "count X x \<le> count (Sup A) x" .
  1160   qed
  1161 next
  1162   fix X :: "'a multiset" and A
  1163   assume nonempty: "A \<noteq> {}" and ge: "\<And>Y. Y \<in> A \<Longrightarrow> Y \<subseteq># X"
  1164   from ge have bdd: "subset_mset.bdd_above A" by (rule subset_mset.bdd_aboveI[of _ X])
  1165   show "Sup A \<subseteq># X"
  1166   proof (rule mset_subset_eqI)
  1167     fix x
  1168     from count_Sup_multiset_nonempty[OF \<open>A \<noteq> {}\<close> bdd]
  1169       have "count (Sup A) x = (SUP X:A. count X x)" .
  1170     also from nonempty have "\<dots> \<le> count X x"
  1171       by (intro cSup_least) (auto intro: mset_subset_eq_count ge)
  1172     finally show "count (Sup A) x \<le> count X x" .
  1173   qed
  1174 qed \<comment> \<open>FIXME: avoid junk stemming from type class interpretation\<close>
  1175 
  1176 lemma set_mset_Inf:
  1177   assumes "A \<noteq> {}"
  1178   shows   "set_mset (Inf A) = (\<Inter>X\<in>A. set_mset X)"
  1179 proof safe
  1180   fix x X assume "x \<in># Inf A" "X \<in> A"
  1181   hence nonempty: "A \<noteq> {}" by (auto simp: Inf_multiset_empty)
  1182   from \<open>x \<in># Inf A\<close> have "{#x#} \<subseteq># Inf A" by auto
  1183   also from \<open>X \<in> A\<close> have "\<dots> \<subseteq># X" by (rule subset_mset.cInf_lower) simp_all
  1184   finally show "x \<in># X" by simp
  1185 next
  1186   fix x assume x: "x \<in> (\<Inter>X\<in>A. set_mset X)"
  1187   hence "{#x#} \<subseteq># X" if "X \<in> A" for X using that by auto
  1188   from assms and this have "{#x#} \<subseteq># Inf A" by (rule subset_mset.cInf_greatest)
  1189   thus "x \<in># Inf A" by simp
  1190 qed
  1191 
  1192 lemma in_Inf_multiset_iff:
  1193   assumes "A \<noteq> {}"
  1194   shows   "x \<in># Inf A \<longleftrightarrow> (\<forall>X\<in>A. x \<in># X)"
  1195 proof -
  1196   from assms have "set_mset (Inf A) = (\<Inter>X\<in>A. set_mset X)" by (rule set_mset_Inf)
  1197   also have "x \<in> \<dots> \<longleftrightarrow> (\<forall>X\<in>A. x \<in># X)" by simp
  1198   finally show ?thesis .
  1199 qed
  1200 
  1201 lemma in_Inf_multisetD: "x \<in># Inf A \<Longrightarrow> X \<in> A \<Longrightarrow> x \<in># X"
  1202   by (subst (asm) in_Inf_multiset_iff) auto
  1203 
  1204 lemma set_mset_Sup:
  1205   assumes "subset_mset.bdd_above A"
  1206   shows   "set_mset (Sup A) = (\<Union>X\<in>A. set_mset X)"
  1207 proof safe
  1208   fix x assume "x \<in># Sup A"
  1209   hence nonempty: "A \<noteq> {}" by (auto simp: Sup_multiset_empty)
  1210   show "x \<in> (\<Union>X\<in>A. set_mset X)"
  1211   proof (rule ccontr)
  1212     assume x: "x \<notin> (\<Union>X\<in>A. set_mset X)"
  1213     have "count X x \<le> count (Sup A) x" if "X \<in> A" for X x
  1214       using that by (intro mset_subset_eq_count subset_mset.cSup_upper assms)
  1215     with x have "X \<subseteq># Sup A - {#x#}" if "X \<in> A" for X
  1216       using that by (auto simp: subseteq_mset_def algebra_simps not_in_iff)
  1217     hence "Sup A \<subseteq># Sup A - {#x#}" by (intro subset_mset.cSup_least nonempty)
  1218     with \<open>x \<in># Sup A\<close> show False
  1219       by (auto simp: subseteq_mset_def count_greater_zero_iff [symmetric]
  1220                simp del: count_greater_zero_iff dest!: spec[of _ x])
  1221   qed
  1222 next
  1223   fix x X assume "x \<in> set_mset X" "X \<in> A"
  1224   hence "{#x#} \<subseteq># X" by auto
  1225   also have "X \<subseteq># Sup A" by (intro subset_mset.cSup_upper \<open>X \<in> A\<close> assms)
  1226   finally show "x \<in> set_mset (Sup A)" by simp
  1227 qed
  1228 
  1229 lemma in_Sup_multiset_iff:
  1230   assumes "subset_mset.bdd_above A"
  1231   shows   "x \<in># Sup A \<longleftrightarrow> (\<exists>X\<in>A. x \<in># X)"
  1232 proof -
  1233   from assms have "set_mset (Sup A) = (\<Union>X\<in>A. set_mset X)" by (rule set_mset_Sup)
  1234   also have "x \<in> \<dots> \<longleftrightarrow> (\<exists>X\<in>A. x \<in># X)" by simp
  1235   finally show ?thesis .
  1236 qed
  1237 
  1238 lemma in_Sup_multisetD:
  1239   assumes "x \<in># Sup A"
  1240   shows   "\<exists>X\<in>A. x \<in># X"
  1241 proof -
  1242   have "subset_mset.bdd_above A"
  1243     by (rule ccontr) (insert assms, simp_all add: Sup_multiset_unbounded)
  1244   with assms show ?thesis by (simp add: in_Sup_multiset_iff)
  1245 qed
  1246 
  1247 interpretation subset_mset: distrib_lattice "op \<inter>#" "op \<subseteq>#" "op \<subset>#" "op \<union>#"
  1248 proof
  1249   fix A B C :: "'a multiset"
  1250   show "A \<union># (B \<inter># C) = A \<union># B \<inter># (A \<union># C)"
  1251     by (intro multiset_eqI) simp_all
  1252 qed \<comment> \<open>FIXME: avoid junk stemming from type class interpretation\<close>
  1253 
  1254 
  1255 subsubsection \<open>Filter (with comprehension syntax)\<close>
  1256 
  1257 text \<open>Multiset comprehension\<close>
  1258 
  1259 lift_definition filter_mset :: "('a \<Rightarrow> bool) \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset"
  1260 is "\<lambda>P M. \<lambda>x. if P x then M x else 0"
  1261 by (rule filter_preserves_multiset)
  1262 
  1263 syntax (ASCII)
  1264   "_MCollect" :: "pttrn \<Rightarrow> 'a multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"    ("(1{#_ :# _./ _#})")
  1265 syntax
  1266   "_MCollect" :: "pttrn \<Rightarrow> 'a multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"    ("(1{#_ \<in># _./ _#})")
  1267 translations
  1268   "{#x \<in># M. P#}" == "CONST filter_mset (\<lambda>x. P) M"
  1269 
  1270 lemma count_filter_mset [simp]:
  1271   "count (filter_mset P M) a = (if P a then count M a else 0)"
  1272   by (simp add: filter_mset.rep_eq)
  1273 
  1274 lemma set_mset_filter [simp]:
  1275   "set_mset (filter_mset P M) = {a \<in> set_mset M. P a}"
  1276   by (simp only: set_eq_iff count_greater_zero_iff [symmetric] count_filter_mset) simp
  1277 
  1278 lemma filter_empty_mset [simp]: "filter_mset P {#} = {#}"
  1279   by (rule multiset_eqI) simp
  1280 
  1281 lemma filter_single_mset: "filter_mset P {#x#} = (if P x then {#x#} else {#})"
  1282   by (rule multiset_eqI) simp
  1283 
  1284 lemma filter_union_mset [simp]: "filter_mset P (M + N) = filter_mset P M + filter_mset P N"
  1285   by (rule multiset_eqI) simp
  1286 
  1287 lemma filter_diff_mset [simp]: "filter_mset P (M - N) = filter_mset P M - filter_mset P N"
  1288   by (rule multiset_eqI) simp
  1289 
  1290 lemma filter_inter_mset [simp]: "filter_mset P (M \<inter># N) = filter_mset P M \<inter># filter_mset P N"
  1291   by (rule multiset_eqI) simp
  1292 
  1293 lemma filter_sup_mset[simp]: "filter_mset P (A \<union># B) = filter_mset P A \<union># filter_mset P B"
  1294   by (rule multiset_eqI) simp
  1295 
  1296 lemma filter_mset_add_mset [simp]:
  1297    "filter_mset P (add_mset x A) =
  1298      (if P x then add_mset x (filter_mset P A) else filter_mset P A)"
  1299    by (auto simp: multiset_eq_iff)
  1300 
  1301 lemma multiset_filter_subset[simp]: "filter_mset f M \<subseteq># M"
  1302   by (simp add: mset_subset_eqI)
  1303 
  1304 lemma multiset_filter_mono:
  1305   assumes "A \<subseteq># B"
  1306   shows "filter_mset f A \<subseteq># filter_mset f B"
  1307 proof -
  1308   from assms[unfolded mset_subset_eq_exists_conv]
  1309   obtain C where B: "B = A + C" by auto
  1310   show ?thesis unfolding B by auto
  1311 qed
  1312 
  1313 lemma filter_mset_eq_conv:
  1314   "filter_mset P M = N \<longleftrightarrow> N \<subseteq># M \<and> (\<forall>b\<in>#N. P b) \<and> (\<forall>a\<in>#M - N. \<not> P a)" (is "?P \<longleftrightarrow> ?Q")
  1315 proof
  1316   assume ?P then show ?Q by auto (simp add: multiset_eq_iff in_diff_count)
  1317 next
  1318   assume ?Q
  1319   then obtain Q where M: "M = N + Q"
  1320     by (auto simp add: mset_subset_eq_exists_conv)
  1321   then have MN: "M - N = Q" by simp
  1322   show ?P
  1323   proof (rule multiset_eqI)
  1324     fix a
  1325     from \<open>?Q\<close> MN have *: "\<not> P a \<Longrightarrow> a \<notin># N" "P a \<Longrightarrow> a \<notin># Q"
  1326       by auto
  1327     show "count (filter_mset P M) a = count N a"
  1328     proof (cases "a \<in># M")
  1329       case True
  1330       with * show ?thesis
  1331         by (simp add: not_in_iff M)
  1332     next
  1333       case False then have "count M a = 0"
  1334         by (simp add: not_in_iff)
  1335       with M show ?thesis by simp
  1336     qed
  1337   qed
  1338 qed
  1339 
  1340 lemma filter_filter_mset: "filter_mset P (filter_mset Q M) = {#x \<in># M. Q x \<and> P x#}"
  1341   by (auto simp: multiset_eq_iff)
  1342 
  1343 lemma
  1344   filter_mset_True[simp]: "{#y \<in># M. True#} = M" and
  1345   filter_mset_False[simp]: "{#y \<in># M. False#} = {#}"
  1346   by (auto simp: multiset_eq_iff)
  1347 
  1348 
  1349 subsubsection \<open>Size\<close>
  1350 
  1351 definition wcount where "wcount f M = (\<lambda>x. count M x * Suc (f x))"
  1352 
  1353 lemma wcount_union: "wcount f (M + N) a = wcount f M a + wcount f N a"
  1354   by (auto simp: wcount_def add_mult_distrib)
  1355 
  1356 lemma wcount_add_mset:
  1357   "wcount f (add_mset x M) a = (if x = a then Suc (f a) else 0) + wcount f M a"
  1358   unfolding add_mset_add_single[of _ M] wcount_union by (auto simp: wcount_def)
  1359 
  1360 definition size_multiset :: "('a \<Rightarrow> nat) \<Rightarrow> 'a multiset \<Rightarrow> nat" where
  1361   "size_multiset f M = sum (wcount f M) (set_mset M)"
  1362 
  1363 lemmas size_multiset_eq = size_multiset_def[unfolded wcount_def]
  1364 
  1365 instantiation multiset :: (type) size
  1366 begin
  1367 
  1368 definition size_multiset where
  1369   size_multiset_overloaded_def: "size_multiset = Multiset.size_multiset (\<lambda>_. 0)"
  1370 instance ..
  1371 
  1372 end
  1373 
  1374 lemmas size_multiset_overloaded_eq =
  1375   size_multiset_overloaded_def[THEN fun_cong, unfolded size_multiset_eq, simplified]
  1376 
  1377 lemma size_multiset_empty [simp]: "size_multiset f {#} = 0"
  1378 by (simp add: size_multiset_def)
  1379 
  1380 lemma size_empty [simp]: "size {#} = 0"
  1381 by (simp add: size_multiset_overloaded_def)
  1382 
  1383 lemma size_multiset_single : "size_multiset f {#b#} = Suc (f b)"
  1384 by (simp add: size_multiset_eq)
  1385 
  1386 lemma size_single: "size {#b#} = 1"
  1387 by (simp add: size_multiset_overloaded_def size_multiset_single)
  1388 
  1389 lemma sum_wcount_Int:
  1390   "finite A \<Longrightarrow> sum (wcount f N) (A \<inter> set_mset N) = sum (wcount f N) A"
  1391   by (induct rule: finite_induct)
  1392     (simp_all add: Int_insert_left wcount_def count_eq_zero_iff)
  1393 
  1394 lemma size_multiset_union [simp]:
  1395   "size_multiset f (M + N::'a multiset) = size_multiset f M + size_multiset f N"
  1396 apply (simp add: size_multiset_def sum_Un_nat sum.distrib sum_wcount_Int wcount_union)
  1397 apply (subst Int_commute)
  1398 apply (simp add: sum_wcount_Int)
  1399 done
  1400 
  1401 lemma size_multiset_add_mset [simp]:
  1402   "size_multiset f (add_mset a M) = Suc (f a) + size_multiset f M"
  1403   unfolding add_mset_add_single[of _ M] size_multiset_union by (auto simp: size_multiset_single)
  1404 
  1405 lemma size_add_mset [simp]: "size (add_mset a A) = Suc (size A)"
  1406 by (simp add: size_multiset_overloaded_def wcount_add_mset)
  1407 
  1408 lemma size_union [simp]: "size (M + N::'a multiset) = size M + size N"
  1409 by (auto simp add: size_multiset_overloaded_def)
  1410 
  1411 lemma size_multiset_eq_0_iff_empty [iff]:
  1412   "size_multiset f M = 0 \<longleftrightarrow> M = {#}"
  1413   by (auto simp add: size_multiset_eq count_eq_zero_iff)
  1414 
  1415 lemma size_eq_0_iff_empty [iff]: "(size M = 0) = (M = {#})"
  1416 by (auto simp add: size_multiset_overloaded_def)
  1417 
  1418 lemma nonempty_has_size: "(S \<noteq> {#}) = (0 < size S)"
  1419 by (metis gr0I gr_implies_not0 size_empty size_eq_0_iff_empty)
  1420 
  1421 lemma size_eq_Suc_imp_elem: "size M = Suc n \<Longrightarrow> \<exists>a. a \<in># M"
  1422 apply (unfold size_multiset_overloaded_eq)
  1423 apply (drule sum_SucD)
  1424 apply auto
  1425 done
  1426 
  1427 lemma size_eq_Suc_imp_eq_union:
  1428   assumes "size M = Suc n"
  1429   shows "\<exists>a N. M = add_mset a N"
  1430 proof -
  1431   from assms obtain a where "a \<in># M"
  1432     by (erule size_eq_Suc_imp_elem [THEN exE])
  1433   then have "M = add_mset a (M - {#a#})" by simp
  1434   then show ?thesis by blast
  1435 qed
  1436 
  1437 lemma size_mset_mono:
  1438   fixes A B :: "'a multiset"
  1439   assumes "A \<subseteq># B"
  1440   shows "size A \<le> size B"
  1441 proof -
  1442   from assms[unfolded mset_subset_eq_exists_conv]
  1443   obtain C where B: "B = A + C" by auto
  1444   show ?thesis unfolding B by (induct C) auto
  1445 qed
  1446 
  1447 lemma size_filter_mset_lesseq[simp]: "size (filter_mset f M) \<le> size M"
  1448 by (rule size_mset_mono[OF multiset_filter_subset])
  1449 
  1450 lemma size_Diff_submset:
  1451   "M \<subseteq># M' \<Longrightarrow> size (M' - M) = size M' - size(M::'a multiset)"
  1452 by (metis add_diff_cancel_left' size_union mset_subset_eq_exists_conv)
  1453 
  1454 
  1455 subsection \<open>Induction and case splits\<close>
  1456 
  1457 theorem multiset_induct [case_names empty add, induct type: multiset]:
  1458   assumes empty: "P {#}"
  1459   assumes add: "\<And>x M. P M \<Longrightarrow> P (add_mset x M)"
  1460   shows "P M"
  1461 proof (induct "size M" arbitrary: M)
  1462   case 0 thus "P M" by (simp add: empty)
  1463 next
  1464   case (Suc k)
  1465   obtain N x where "M = add_mset x N"
  1466     using \<open>Suc k = size M\<close> [symmetric]
  1467     using size_eq_Suc_imp_eq_union by fast
  1468   with Suc add show "P M" by simp
  1469 qed
  1470 
  1471 lemma multiset_induct_min[case_names empty add]:
  1472   fixes M :: "'a::linorder multiset"
  1473   assumes
  1474     empty: "P {#}" and
  1475     add: "\<And>x M. P M \<Longrightarrow> (\<forall>y \<in># M. y \<ge> x) \<Longrightarrow> P (add_mset x M)"
  1476   shows "P M"
  1477 proof (induct "size M" arbitrary: M)
  1478   case (Suc k)
  1479   note ih = this(1) and Sk_eq_sz_M = this(2)
  1480 
  1481   let ?y = "Min_mset M"
  1482   let ?N = "M - {#?y#}"
  1483 
  1484   have M: "M = add_mset ?y ?N"
  1485     by (metis Min_in Sk_eq_sz_M finite_set_mset insert_DiffM lessI not_less_zero
  1486       set_mset_eq_empty_iff size_empty)
  1487   show ?case
  1488     by (subst M, rule add, rule ih, metis M Sk_eq_sz_M nat.inject size_add_mset,
  1489       meson Min_le finite_set_mset in_diffD)
  1490 qed (simp add: empty)
  1491 
  1492 lemma multiset_induct_max[case_names empty add]:
  1493   fixes M :: "'a::linorder multiset"
  1494   assumes
  1495     empty: "P {#}" and
  1496     add: "\<And>x M. P M \<Longrightarrow> (\<forall>y \<in># M. y \<le> x) \<Longrightarrow> P (add_mset x M)"
  1497   shows "P M"
  1498 proof (induct "size M" arbitrary: M)
  1499   case (Suc k)
  1500   note ih = this(1) and Sk_eq_sz_M = this(2)
  1501 
  1502   let ?y = "Max_mset M"
  1503   let ?N = "M - {#?y#}"
  1504 
  1505   have M: "M = add_mset ?y ?N"
  1506     by (metis Max_in Sk_eq_sz_M finite_set_mset insert_DiffM lessI not_less_zero
  1507       set_mset_eq_empty_iff size_empty)
  1508   show ?case
  1509     by (subst M, rule add, rule ih, metis M Sk_eq_sz_M nat.inject size_add_mset,
  1510       meson Max_ge finite_set_mset in_diffD)
  1511 qed (simp add: empty)
  1512 
  1513 lemma multi_nonempty_split: "M \<noteq> {#} \<Longrightarrow> \<exists>A a. M = add_mset a A"
  1514 by (induct M) auto
  1515 
  1516 lemma multiset_cases [cases type]:
  1517   obtains (empty) "M = {#}"
  1518     | (add) x N where "M = add_mset x N"
  1519   by (induct M) simp_all
  1520 
  1521 lemma multi_drop_mem_not_eq: "c \<in># B \<Longrightarrow> B - {#c#} \<noteq> B"
  1522 by (cases "B = {#}") (auto dest: multi_member_split)
  1523 
  1524 lemma multiset_partition: "M = {#x \<in># M. P x#} + {#x \<in># M. \<not> P x#}"
  1525   by (subst multiset_eq_iff) auto
  1526 
  1527 lemma mset_subset_size: "A \<subset># B \<Longrightarrow> size A < size B"
  1528 proof (induct A arbitrary: B)
  1529   case empty
  1530   then show ?case
  1531     using nonempty_has_size by auto
  1532 next
  1533   case (add x A)
  1534   have "add_mset x A \<subseteq># B"
  1535     by (meson add.prems subset_mset_def)
  1536   then show ?case
  1537     by (metis (no_types) add.prems add.right_neutral add_diff_cancel_left' leD nat_neq_iff
  1538       size_Diff_submset size_eq_0_iff_empty size_mset_mono subset_mset.le_iff_add subset_mset_def)
  1539 qed
  1540 
  1541 lemma size_1_singleton_mset: "size M = 1 \<Longrightarrow> \<exists>a. M = {#a#}"
  1542   by (cases M) auto
  1543 
  1544 
  1545 subsubsection \<open>Strong induction and subset induction for multisets\<close>
  1546 
  1547 text \<open>Well-foundedness of strict subset relation\<close>
  1548 
  1549 lemma wf_subset_mset_rel: "wf {(M, N :: 'a multiset). M \<subset># N}"
  1550 apply (rule wf_measure [THEN wf_subset, where f1=size])
  1551 apply (clarsimp simp: measure_def inv_image_def mset_subset_size)
  1552 done
  1553 
  1554 lemma full_multiset_induct [case_names less]:
  1555 assumes ih: "\<And>B. \<forall>(A::'a multiset). A \<subset># B \<longrightarrow> P A \<Longrightarrow> P B"
  1556 shows "P B"
  1557 apply (rule wf_subset_mset_rel [THEN wf_induct])
  1558 apply (rule ih, auto)
  1559 done
  1560 
  1561 lemma multi_subset_induct [consumes 2, case_names empty add]:
  1562   assumes "F \<subseteq># A"
  1563     and empty: "P {#}"
  1564     and insert: "\<And>a F. a \<in># A \<Longrightarrow> P F \<Longrightarrow> P (add_mset a F)"
  1565   shows "P F"
  1566 proof -
  1567   from \<open>F \<subseteq># A\<close>
  1568   show ?thesis
  1569   proof (induct F)
  1570     show "P {#}" by fact
  1571   next
  1572     fix x F
  1573     assume P: "F \<subseteq># A \<Longrightarrow> P F" and i: "add_mset x F \<subseteq># A"
  1574     show "P (add_mset x F)"
  1575     proof (rule insert)
  1576       from i show "x \<in># A" by (auto dest: mset_subset_eq_insertD)
  1577       from i have "F \<subseteq># A" by (auto dest: mset_subset_eq_insertD)
  1578       with P show "P F" .
  1579     qed
  1580   qed
  1581 qed
  1582 
  1583 
  1584 subsection \<open>The fold combinator\<close>
  1585 
  1586 definition fold_mset :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a multiset \<Rightarrow> 'b"
  1587 where
  1588   "fold_mset f s M = Finite_Set.fold (\<lambda>x. f x ^^ count M x) s (set_mset M)"
  1589 
  1590 lemma fold_mset_empty [simp]: "fold_mset f s {#} = s"
  1591   by (simp add: fold_mset_def)
  1592 
  1593 context comp_fun_commute
  1594 begin
  1595 
  1596 lemma fold_mset_add_mset [simp]: "fold_mset f s (add_mset x M) = f x (fold_mset f s M)"
  1597 proof -
  1598   interpret mset: comp_fun_commute "\<lambda>y. f y ^^ count M y"
  1599     by (fact comp_fun_commute_funpow)
  1600   interpret mset_union: comp_fun_commute "\<lambda>y. f y ^^ count (add_mset x M) y"
  1601     by (fact comp_fun_commute_funpow)
  1602   show ?thesis
  1603   proof (cases "x \<in> set_mset M")
  1604     case False
  1605     then have *: "count (add_mset x M) x = 1"
  1606       by (simp add: not_in_iff)
  1607     from False have "Finite_Set.fold (\<lambda>y. f y ^^ count (add_mset x M) y) s (set_mset M) =
  1608       Finite_Set.fold (\<lambda>y. f y ^^ count M y) s (set_mset M)"
  1609       by (auto intro!: Finite_Set.fold_cong comp_fun_commute_funpow)
  1610     with False * show ?thesis
  1611       by (simp add: fold_mset_def del: count_add_mset)
  1612   next
  1613     case True
  1614     define N where "N = set_mset M - {x}"
  1615     from N_def True have *: "set_mset M = insert x N" "x \<notin> N" "finite N" by auto
  1616     then have "Finite_Set.fold (\<lambda>y. f y ^^ count (add_mset x M) y) s N =
  1617       Finite_Set.fold (\<lambda>y. f y ^^ count M y) s N"
  1618       by (auto intro!: Finite_Set.fold_cong comp_fun_commute_funpow)
  1619     with * show ?thesis by (simp add: fold_mset_def del: count_add_mset) simp
  1620   qed
  1621 qed
  1622 
  1623 corollary fold_mset_single: "fold_mset f s {#x#} = f x s"
  1624   by simp
  1625 
  1626 lemma fold_mset_fun_left_comm: "f x (fold_mset f s M) = fold_mset f (f x s) M"
  1627   by (induct M) (simp_all add: fun_left_comm)
  1628 
  1629 lemma fold_mset_union [simp]: "fold_mset f s (M + N) = fold_mset f (fold_mset f s M) N"
  1630   by (induct M) (simp_all add: fold_mset_fun_left_comm)
  1631 
  1632 lemma fold_mset_fusion:
  1633   assumes "comp_fun_commute g"
  1634     and *: "\<And>x y. h (g x y) = f x (h y)"
  1635   shows "h (fold_mset g w A) = fold_mset f (h w) A"
  1636 proof -
  1637   interpret comp_fun_commute g by (fact assms)
  1638   from * show ?thesis by (induct A) auto
  1639 qed
  1640 
  1641 end
  1642 
  1643 lemma union_fold_mset_add_mset: "A + B = fold_mset add_mset A B"
  1644 proof -
  1645   interpret comp_fun_commute add_mset
  1646     by standard auto
  1647   show ?thesis
  1648     by (induction B) auto
  1649 qed
  1650 
  1651 text \<open>
  1652   A note on code generation: When defining some function containing a
  1653   subterm @{term "fold_mset F"}, code generation is not automatic. When
  1654   interpreting locale \<open>left_commutative\<close> with \<open>F\<close>, the
  1655   would be code thms for @{const fold_mset} become thms like
  1656   @{term "fold_mset F z {#} = z"} where \<open>F\<close> is not a pattern but
  1657   contains defined symbols, i.e.\ is not a code thm. Hence a separate
  1658   constant with its own code thms needs to be introduced for \<open>F\<close>. See the image operator below.
  1659 \<close>
  1660 
  1661 
  1662 subsection \<open>Image\<close>
  1663 
  1664 definition image_mset :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a multiset \<Rightarrow> 'b multiset" where
  1665   "image_mset f = fold_mset (add_mset \<circ> f) {#}"
  1666 
  1667 lemma comp_fun_commute_mset_image: "comp_fun_commute (add_mset \<circ> f)"
  1668   by unfold_locales (simp add: fun_eq_iff)
  1669 
  1670 lemma image_mset_empty [simp]: "image_mset f {#} = {#}"
  1671   by (simp add: image_mset_def)
  1672 
  1673 lemma image_mset_single: "image_mset f {#x#} = {#f x#}"
  1674   by (simp add: comp_fun_commute.fold_mset_add_mset comp_fun_commute_mset_image image_mset_def)
  1675 
  1676 lemma image_mset_union [simp]: "image_mset f (M + N) = image_mset f M + image_mset f N"
  1677 proof -
  1678   interpret comp_fun_commute "add_mset \<circ> f"
  1679     by (fact comp_fun_commute_mset_image)
  1680   show ?thesis by (induct N) (simp_all add: image_mset_def)
  1681 qed
  1682 
  1683 corollary image_mset_add_mset [simp]:
  1684   "image_mset f (add_mset a M) = add_mset (f a) (image_mset f M)"
  1685   unfolding image_mset_union add_mset_add_single[of a M] by (simp add: image_mset_single)
  1686 
  1687 lemma set_image_mset [simp]: "set_mset (image_mset f M) = image f (set_mset M)"
  1688   by (induct M) simp_all
  1689 
  1690 lemma size_image_mset [simp]: "size (image_mset f M) = size M"
  1691   by (induct M) simp_all
  1692 
  1693 lemma image_mset_is_empty_iff [simp]: "image_mset f M = {#} \<longleftrightarrow> M = {#}"
  1694   by (cases M) auto
  1695 
  1696 lemma image_mset_If:
  1697   "image_mset (\<lambda>x. if P x then f x else g x) A =
  1698      image_mset f (filter_mset P A) + image_mset g (filter_mset (\<lambda>x. \<not>P x) A)"
  1699   by (induction A) auto
  1700 
  1701 lemma image_mset_Diff:
  1702   assumes "B \<subseteq># A"
  1703   shows   "image_mset f (A - B) = image_mset f A - image_mset f B"
  1704 proof -
  1705   have "image_mset f (A - B + B) = image_mset f (A - B) + image_mset f B"
  1706     by simp
  1707   also from assms have "A - B + B = A"
  1708     by (simp add: subset_mset.diff_add)
  1709   finally show ?thesis by simp
  1710 qed
  1711 
  1712 lemma count_image_mset: "count (image_mset f A) x = (\<Sum>y\<in>f -` {x} \<inter> set_mset A. count A y)"
  1713 proof (induction A)
  1714   case empty
  1715   then show ?case by simp
  1716 next
  1717   case (add x A)
  1718   moreover have *: "(if x = y then Suc n else n) = n + (if x = y then 1 else 0)" for n y
  1719     by simp
  1720   ultimately show ?case
  1721     by (auto simp: sum.distrib intro!: sum.mono_neutral_left)
  1722 qed
  1723 
  1724 lemma image_mset_subseteq_mono: "A \<subseteq># B \<Longrightarrow> image_mset f A \<subseteq># image_mset f B"
  1725   by (metis image_mset_union subset_mset.le_iff_add)
  1726 
  1727 lemma image_mset_subset_mono: "M \<subset># N \<Longrightarrow> image_mset f M \<subset># image_mset f N"
  1728   by (metis (no_types) Diff_eq_empty_iff_mset image_mset_Diff image_mset_is_empty_iff
  1729     image_mset_subseteq_mono subset_mset.less_le_not_le)
  1730 
  1731 syntax (ASCII)
  1732   "_comprehension_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> 'a multiset"  ("({#_/. _ :# _#})")
  1733 syntax
  1734   "_comprehension_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> 'a multiset"  ("({#_/. _ \<in># _#})")
  1735 translations
  1736   "{#e. x \<in># M#}" \<rightleftharpoons> "CONST image_mset (\<lambda>x. e) M"
  1737 
  1738 syntax (ASCII)
  1739   "_comprehension_mset'" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"  ("({#_/ | _ :# _./ _#})")
  1740 syntax
  1741   "_comprehension_mset'" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"  ("({#_/ | _ \<in># _./ _#})")
  1742 translations
  1743   "{#e | x\<in>#M. P#}" \<rightharpoonup> "{#e. x \<in># {# x\<in>#M. P#}#}"
  1744 
  1745 text \<open>
  1746   This allows to write not just filters like @{term "{#x\<in>#M. x<c#}"}
  1747   but also images like @{term "{#x+x. x\<in>#M #}"} and @{term [source]
  1748   "{#x+x|x\<in>#M. x<c#}"}, where the latter is currently displayed as
  1749   @{term "{#x+x|x\<in>#M. x<c#}"}.
  1750 \<close>
  1751 
  1752 lemma in_image_mset: "y \<in># {#f x. x \<in># M#} \<longleftrightarrow> y \<in> f ` set_mset M"
  1753   by simp
  1754 
  1755 functor image_mset: image_mset
  1756 proof -
  1757   fix f g show "image_mset f \<circ> image_mset g = image_mset (f \<circ> g)"
  1758   proof
  1759     fix A
  1760     show "(image_mset f \<circ> image_mset g) A = image_mset (f \<circ> g) A"
  1761       by (induct A) simp_all
  1762   qed
  1763   show "image_mset id = id"
  1764   proof
  1765     fix A
  1766     show "image_mset id A = id A"
  1767       by (induct A) simp_all
  1768   qed
  1769 qed
  1770 
  1771 declare
  1772   image_mset.id [simp]
  1773   image_mset.identity [simp]
  1774 
  1775 lemma image_mset_id[simp]: "image_mset id x = x"
  1776   unfolding id_def by auto
  1777 
  1778 lemma image_mset_cong: "(\<And>x. x \<in># M \<Longrightarrow> f x = g x) \<Longrightarrow> {#f x. x \<in># M#} = {#g x. x \<in># M#}"
  1779   by (induct M) auto
  1780 
  1781 lemma image_mset_cong_pair:
  1782   "(\<forall>x y. (x, y) \<in># M \<longrightarrow> f x y = g x y) \<Longrightarrow> {#f x y. (x, y) \<in># M#} = {#g x y. (x, y) \<in># M#}"
  1783   by (metis image_mset_cong split_cong)
  1784 
  1785 lemma image_mset_const_eq:
  1786   "{#c. a \<in># M#} = replicate_mset (size M) c"
  1787   by (induct M) simp_all
  1788 
  1789 
  1790 subsection \<open>Further conversions\<close>
  1791 
  1792 primrec mset :: "'a list \<Rightarrow> 'a multiset" where
  1793   "mset [] = {#}" |
  1794   "mset (a # x) = add_mset a (mset x)"
  1795 
  1796 lemma in_multiset_in_set:
  1797   "x \<in># mset xs \<longleftrightarrow> x \<in> set xs"
  1798   by (induct xs) simp_all
  1799 
  1800 lemma count_mset:
  1801   "count (mset xs) x = length (filter (\<lambda>y. x = y) xs)"
  1802   by (induct xs) simp_all
  1803 
  1804 lemma mset_zero_iff[simp]: "(mset x = {#}) = (x = [])"
  1805   by (induct x) auto
  1806 
  1807 lemma mset_zero_iff_right[simp]: "({#} = mset x) = (x = [])"
  1808 by (induct x) auto
  1809 
  1810 lemma count_mset_gt_0: "x \<in> set xs \<Longrightarrow> count (mset xs) x > 0"
  1811   by (induction xs) auto
  1812 
  1813 lemma count_mset_0_iff [simp]: "count (mset xs) x = 0 \<longleftrightarrow> x \<notin> set xs"
  1814   by (induction xs) auto
  1815 
  1816 lemma mset_single_iff[iff]: "mset xs = {#x#} \<longleftrightarrow> xs = [x]"
  1817   by (cases xs) auto
  1818 
  1819 lemma mset_single_iff_right[iff]: "{#x#} = mset xs \<longleftrightarrow> xs = [x]"
  1820   by (cases xs) auto
  1821 
  1822 lemma set_mset_mset[simp]: "set_mset (mset xs) = set xs"
  1823   by (induct xs) auto
  1824 
  1825 lemma set_mset_comp_mset [simp]: "set_mset \<circ> mset = set"
  1826   by (simp add: fun_eq_iff)
  1827 
  1828 lemma size_mset [simp]: "size (mset xs) = length xs"
  1829   by (induct xs) simp_all
  1830 
  1831 lemma mset_append [simp]: "mset (xs @ ys) = mset xs + mset ys"
  1832   by (induct xs arbitrary: ys) auto
  1833 
  1834 lemma mset_filter: "mset (filter P xs) = {#x \<in># mset xs. P x #}"
  1835   by (induct xs) simp_all
  1836 
  1837 lemma mset_rev [simp]:
  1838   "mset (rev xs) = mset xs"
  1839   by (induct xs) simp_all
  1840 
  1841 lemma surj_mset: "surj mset"
  1842 apply (unfold surj_def)
  1843 apply (rule allI)
  1844 apply (rule_tac M = y in multiset_induct)
  1845  apply auto
  1846 apply (rule_tac x = "x # xa" in exI)
  1847 apply auto
  1848 done
  1849 
  1850 lemma distinct_count_atmost_1:
  1851   "distinct x = (\<forall>a. count (mset x) a = (if a \<in> set x then 1 else 0))"
  1852 proof (induct x)
  1853   case Nil then show ?case by simp
  1854 next
  1855   case (Cons x xs) show ?case (is "?lhs \<longleftrightarrow> ?rhs")
  1856   proof
  1857     assume ?lhs then show ?rhs using Cons by simp
  1858   next
  1859     assume ?rhs then have "x \<notin> set xs"
  1860       by (simp split: if_splits)
  1861     moreover from \<open>?rhs\<close> have "(\<forall>a. count (mset xs) a =
  1862        (if a \<in> set xs then 1 else 0))"
  1863       by (auto split: if_splits simp add: count_eq_zero_iff)
  1864     ultimately show ?lhs using Cons by simp
  1865   qed
  1866 qed
  1867 
  1868 lemma mset_eq_setD:
  1869   assumes "mset xs = mset ys"
  1870   shows "set xs = set ys"
  1871 proof -
  1872   from assms have "set_mset (mset xs) = set_mset (mset ys)"
  1873     by simp
  1874   then show ?thesis by simp
  1875 qed
  1876 
  1877 lemma set_eq_iff_mset_eq_distinct:
  1878   "distinct x \<Longrightarrow> distinct y \<Longrightarrow>
  1879     (set x = set y) = (mset x = mset y)"
  1880 by (auto simp: multiset_eq_iff distinct_count_atmost_1)
  1881 
  1882 lemma set_eq_iff_mset_remdups_eq:
  1883    "(set x = set y) = (mset (remdups x) = mset (remdups y))"
  1884 apply (rule iffI)
  1885 apply (simp add: set_eq_iff_mset_eq_distinct[THEN iffD1])
  1886 apply (drule distinct_remdups [THEN distinct_remdups
  1887       [THEN set_eq_iff_mset_eq_distinct [THEN iffD2]]])
  1888 apply simp
  1889 done
  1890 
  1891 lemma mset_compl_union [simp]: "mset [x\<leftarrow>xs. P x] + mset [x\<leftarrow>xs. \<not>P x] = mset xs"
  1892   by (induct xs) auto
  1893 
  1894 lemma nth_mem_mset: "i < length ls \<Longrightarrow> (ls ! i) \<in># mset ls"
  1895 proof (induct ls arbitrary: i)
  1896   case Nil
  1897   then show ?case by simp
  1898 next
  1899   case Cons
  1900   then show ?case by (cases i) auto
  1901 qed
  1902 
  1903 lemma mset_remove1[simp]: "mset (remove1 a xs) = mset xs - {#a#}"
  1904   by (induct xs) (auto simp add: multiset_eq_iff)
  1905 
  1906 lemma mset_eq_length:
  1907   assumes "mset xs = mset ys"
  1908   shows "length xs = length ys"
  1909   using assms by (metis size_mset)
  1910 
  1911 lemma mset_eq_length_filter:
  1912   assumes "mset xs = mset ys"
  1913   shows "length (filter (\<lambda>x. z = x) xs) = length (filter (\<lambda>y. z = y) ys)"
  1914   using assms by (metis count_mset)
  1915 
  1916 lemma fold_multiset_equiv:
  1917   assumes f: "\<And>x y. x \<in> set xs \<Longrightarrow> y \<in> set xs \<Longrightarrow> f x \<circ> f y = f y \<circ> f x"
  1918     and equiv: "mset xs = mset ys"
  1919   shows "List.fold f xs = List.fold f ys"
  1920   using f equiv [symmetric]
  1921 proof (induct xs arbitrary: ys)
  1922   case Nil
  1923   then show ?case by simp
  1924 next
  1925   case (Cons x xs)
  1926   then have *: "set ys = set (x # xs)"
  1927     by (blast dest: mset_eq_setD)
  1928   have "\<And>x y. x \<in> set ys \<Longrightarrow> y \<in> set ys \<Longrightarrow> f x \<circ> f y = f y \<circ> f x"
  1929     by (rule Cons.prems(1)) (simp_all add: *)
  1930   moreover from * have "x \<in> set ys"
  1931     by simp
  1932   ultimately have "List.fold f ys = List.fold f (remove1 x ys) \<circ> f x"
  1933     by (fact fold_remove1_split)
  1934   moreover from Cons.prems have "List.fold f xs = List.fold f (remove1 x ys)"
  1935     by (auto intro: Cons.hyps)
  1936   ultimately show ?case by simp
  1937 qed
  1938 
  1939 lemma mset_shuffle: "zs \<in> shuffle xs ys \<Longrightarrow> mset zs = mset xs + mset ys"
  1940   by (induction xs ys arbitrary: zs rule: shuffle.induct) auto
  1941 
  1942 lemma mset_insort [simp]: "mset (insort x xs) = add_mset x (mset xs)"
  1943   by (induct xs) simp_all
  1944 
  1945 lemma mset_map[simp]: "mset (map f xs) = image_mset f (mset xs)"
  1946   by (induct xs) simp_all
  1947 
  1948 global_interpretation mset_set: folding add_mset "{#}"
  1949   defines mset_set = "folding.F add_mset {#}"
  1950   by standard (simp add: fun_eq_iff)
  1951 
  1952 lemma sum_multiset_singleton [simp]: "sum (\<lambda>n. {#n#}) A = mset_set A"
  1953   by (induction A rule: infinite_finite_induct) auto
  1954 
  1955 lemma count_mset_set [simp]:
  1956   "finite A \<Longrightarrow> x \<in> A \<Longrightarrow> count (mset_set A) x = 1" (is "PROP ?P")
  1957   "\<not> finite A \<Longrightarrow> count (mset_set A) x = 0" (is "PROP ?Q")
  1958   "x \<notin> A \<Longrightarrow> count (mset_set A) x = 0" (is "PROP ?R")
  1959 proof -
  1960   have *: "count (mset_set A) x = 0" if "x \<notin> A" for A
  1961   proof (cases "finite A")
  1962     case False then show ?thesis by simp
  1963   next
  1964     case True from True \<open>x \<notin> A\<close> show ?thesis by (induct A) auto
  1965   qed
  1966   then show "PROP ?P" "PROP ?Q" "PROP ?R"
  1967   by (auto elim!: Set.set_insert)
  1968 qed \<comment> \<open>TODO: maybe define @{const mset_set} also in terms of @{const Abs_multiset}\<close>
  1969 
  1970 lemma elem_mset_set[simp, intro]: "finite A \<Longrightarrow> x \<in># mset_set A \<longleftrightarrow> x \<in> A"
  1971   by (induct A rule: finite_induct) simp_all
  1972 
  1973 lemma mset_set_Union:
  1974   "finite A \<Longrightarrow> finite B \<Longrightarrow> A \<inter> B = {} \<Longrightarrow> mset_set (A \<union> B) = mset_set A + mset_set B"
  1975   by (induction A rule: finite_induct) auto
  1976 
  1977 lemma filter_mset_mset_set [simp]:
  1978   "finite A \<Longrightarrow> filter_mset P (mset_set A) = mset_set {x\<in>A. P x}"
  1979 proof (induction A rule: finite_induct)
  1980   case (insert x A)
  1981   from insert.hyps have "filter_mset P (mset_set (insert x A)) =
  1982       filter_mset P (mset_set A) + mset_set (if P x then {x} else {})"
  1983     by simp
  1984   also have "filter_mset P (mset_set A) = mset_set {x\<in>A. P x}"
  1985     by (rule insert.IH)
  1986   also from insert.hyps
  1987     have "\<dots> + mset_set (if P x then {x} else {}) =
  1988             mset_set ({x \<in> A. P x} \<union> (if P x then {x} else {}))" (is "_ = mset_set ?A")
  1989      by (intro mset_set_Union [symmetric]) simp_all
  1990   also from insert.hyps have "?A = {y\<in>insert x A. P y}" by auto
  1991   finally show ?case .
  1992 qed simp_all
  1993 
  1994 lemma mset_set_Diff:
  1995   assumes "finite A" "B \<subseteq> A"
  1996   shows  "mset_set (A - B) = mset_set A - mset_set B"
  1997 proof -
  1998   from assms have "mset_set ((A - B) \<union> B) = mset_set (A - B) + mset_set B"
  1999     by (intro mset_set_Union) (auto dest: finite_subset)
  2000   also from assms have "A - B \<union> B = A" by blast
  2001   finally show ?thesis by simp
  2002 qed
  2003 
  2004 lemma mset_set_set: "distinct xs \<Longrightarrow> mset_set (set xs) = mset xs"
  2005   by (induction xs) simp_all
  2006 
  2007 lemma count_mset_set': "count (mset_set A) x = (if finite A \<and> x \<in> A then 1 else 0)"
  2008   by auto
  2009 
  2010 lemma subset_imp_msubset_mset_set: 
  2011   assumes "A \<subseteq> B" "finite B"
  2012   shows   "mset_set A \<subseteq># mset_set B"
  2013 proof (rule mset_subset_eqI)
  2014   fix x :: 'a
  2015   from assms have "finite A" by (rule finite_subset)
  2016   with assms show "count (mset_set A) x \<le> count (mset_set B) x"
  2017     by (cases "x \<in> A"; cases "x \<in> B") auto
  2018 qed
  2019 
  2020 lemma mset_set_set_mset_msubset: "mset_set (set_mset A) \<subseteq># A"
  2021 proof (rule mset_subset_eqI)
  2022   fix x show "count (mset_set (set_mset A)) x \<le> count A x"
  2023     by (cases "x \<in># A") simp_all
  2024 qed
  2025 
  2026 context linorder
  2027 begin
  2028 
  2029 definition sorted_list_of_multiset :: "'a multiset \<Rightarrow> 'a list"
  2030 where
  2031   "sorted_list_of_multiset M = fold_mset insort [] M"
  2032 
  2033 lemma sorted_list_of_multiset_empty [simp]:
  2034   "sorted_list_of_multiset {#} = []"
  2035   by (simp add: sorted_list_of_multiset_def)
  2036 
  2037 lemma sorted_list_of_multiset_singleton [simp]:
  2038   "sorted_list_of_multiset {#x#} = [x]"
  2039 proof -
  2040   interpret comp_fun_commute insort by (fact comp_fun_commute_insort)
  2041   show ?thesis by (simp add: sorted_list_of_multiset_def)
  2042 qed
  2043 
  2044 lemma sorted_list_of_multiset_insert [simp]:
  2045   "sorted_list_of_multiset (add_mset x M) = List.insort x (sorted_list_of_multiset M)"
  2046 proof -
  2047   interpret comp_fun_commute insort by (fact comp_fun_commute_insort)
  2048   show ?thesis by (simp add: sorted_list_of_multiset_def)
  2049 qed
  2050 
  2051 end
  2052 
  2053 lemma mset_sorted_list_of_multiset[simp]: "mset (sorted_list_of_multiset M) = M"
  2054   by (induct M) simp_all
  2055 
  2056 lemma sorted_list_of_multiset_mset[simp]: "sorted_list_of_multiset (mset xs) = sort xs"
  2057   by (induct xs) simp_all
  2058 
  2059 lemma finite_set_mset_mset_set[simp]: "finite A \<Longrightarrow> set_mset (mset_set A) = A"
  2060   by auto
  2061 
  2062 lemma mset_set_empty_iff: "mset_set A = {#} \<longleftrightarrow> A = {} \<or> infinite A"
  2063   using finite_set_mset_mset_set by fastforce
  2064 
  2065 lemma infinite_set_mset_mset_set: "\<not> finite A \<Longrightarrow> set_mset (mset_set A) = {}"
  2066   by simp
  2067 
  2068 lemma set_sorted_list_of_multiset [simp]:
  2069   "set (sorted_list_of_multiset M) = set_mset M"
  2070 by (induct M) (simp_all add: set_insort_key)
  2071 
  2072 lemma sorted_list_of_mset_set [simp]:
  2073   "sorted_list_of_multiset (mset_set A) = sorted_list_of_set A"
  2074 by (cases "finite A") (induct A rule: finite_induct, simp_all)
  2075 
  2076 lemma mset_upt [simp]: "mset [m..<n] = mset_set {m..<n}"
  2077   by (induction n) (simp_all add: atLeastLessThanSuc)
  2078 
  2079 lemma image_mset_map_of:
  2080   "distinct (map fst xs) \<Longrightarrow> {#the (map_of xs i). i \<in># mset (map fst xs)#} = mset (map snd xs)"
  2081 proof (induction xs)
  2082   case (Cons x xs)
  2083   have "{#the (map_of (x # xs) i). i \<in># mset (map fst (x # xs))#} =
  2084           add_mset (snd x) {#the (if i = fst x then Some (snd x) else map_of xs i).
  2085              i \<in># mset (map fst xs)#}" (is "_ = add_mset _ ?A") by simp
  2086   also from Cons.prems have "?A = {#the (map_of xs i). i :# mset (map fst xs)#}"
  2087     by (cases x, intro image_mset_cong) (auto simp: in_multiset_in_set)
  2088   also from Cons.prems have "\<dots> = mset (map snd xs)" by (intro Cons.IH) simp_all
  2089   finally show ?case by simp
  2090 qed simp_all
  2091 
  2092 lemma msubset_mset_set_iff[simp]:
  2093   assumes "finite A" "finite B"
  2094   shows "mset_set A \<subseteq># mset_set B \<longleftrightarrow> A \<subseteq> B"
  2095   using assms set_mset_mono subset_imp_msubset_mset_set by fastforce
  2096 
  2097 lemma mset_set_eq_iff[simp]:
  2098   assumes "finite A" "finite B"
  2099   shows "mset_set A = mset_set B \<longleftrightarrow> A = B"
  2100   using assms by (fastforce dest: finite_set_mset_mset_set)
  2101 
  2102 (* Contributed by Lukas Bulwahn *)
  2103 lemma image_mset_mset_set:
  2104   assumes "inj_on f A"
  2105   shows "image_mset f (mset_set A) = mset_set (f ` A)"
  2106 proof cases
  2107   assume "finite A"
  2108   from this \<open>inj_on f A\<close> show ?thesis
  2109     by (induct A) auto
  2110 next
  2111   assume "infinite A"
  2112   from this \<open>inj_on f A\<close> have "infinite (f ` A)"
  2113     using finite_imageD by blast
  2114   from \<open>infinite A\<close> \<open>infinite (f ` A)\<close> show ?thesis by simp
  2115 qed
  2116 
  2117 
  2118 subsection \<open>More properties of the replicate and repeat operations\<close>
  2119 
  2120 lemma in_replicate_mset[simp]: "x \<in># replicate_mset n y \<longleftrightarrow> n > 0 \<and> x = y"
  2121   unfolding replicate_mset_def by (induct n) auto
  2122 
  2123 lemma set_mset_replicate_mset_subset[simp]: "set_mset (replicate_mset n x) = (if n = 0 then {} else {x})"
  2124   by (auto split: if_splits)
  2125 
  2126 lemma size_replicate_mset[simp]: "size (replicate_mset n M) = n"
  2127   by (induct n, simp_all)
  2128 
  2129 lemma count_le_replicate_mset_subset_eq: "n \<le> count M x \<longleftrightarrow> replicate_mset n x \<subseteq># M"
  2130   by (auto simp add: mset_subset_eqI) (metis count_replicate_mset subseteq_mset_def)
  2131 
  2132 lemma filter_eq_replicate_mset: "{#y \<in># D. y = x#} = replicate_mset (count D x) x"
  2133   by (induct D) simp_all
  2134 
  2135 lemma replicate_count_mset_eq_filter_eq: "replicate (count (mset xs) k) k = filter (HOL.eq k) xs"
  2136   by (induct xs) auto
  2137 
  2138 lemma replicate_mset_eq_empty_iff [simp]: "replicate_mset n a = {#} \<longleftrightarrow> n = 0"
  2139   by (induct n) simp_all
  2140 
  2141 lemma replicate_mset_eq_iff:
  2142   "replicate_mset m a = replicate_mset n b \<longleftrightarrow> m = 0 \<and> n = 0 \<or> m = n \<and> a = b"
  2143   by (auto simp add: multiset_eq_iff)
  2144 
  2145 lemma repeat_mset_cancel1: "repeat_mset a A = repeat_mset a B \<longleftrightarrow> A = B \<or> a = 0"
  2146   by (auto simp: multiset_eq_iff)
  2147 
  2148 lemma repeat_mset_cancel2: "repeat_mset a A = repeat_mset b A \<longleftrightarrow> a = b \<or> A = {#}"
  2149   by (auto simp: multiset_eq_iff)
  2150 
  2151 lemma repeat_mset_eq_empty_iff: "repeat_mset n A = {#} \<longleftrightarrow> n = 0 \<or> A = {#}"
  2152   by (cases n) auto
  2153 
  2154 lemma image_replicate_mset [simp]:
  2155   "image_mset f (replicate_mset n a) = replicate_mset n (f a)"
  2156   by (induct n) simp_all
  2157 
  2158 
  2159 subsection \<open>Big operators\<close>
  2160 
  2161 locale comm_monoid_mset = comm_monoid
  2162 begin
  2163 
  2164 interpretation comp_fun_commute f
  2165   by standard (simp add: fun_eq_iff left_commute)
  2166 
  2167 interpretation comp?: comp_fun_commute "f \<circ> g"
  2168   by (fact comp_comp_fun_commute)
  2169 
  2170 context
  2171 begin
  2172 
  2173 definition F :: "'a multiset \<Rightarrow> 'a"
  2174   where eq_fold: "F M = fold_mset f \<^bold>1 M"
  2175 
  2176 lemma empty [simp]: "F {#} = \<^bold>1"
  2177   by (simp add: eq_fold)
  2178 
  2179 lemma singleton [simp]: "F {#x#} = x"
  2180 proof -
  2181   interpret comp_fun_commute
  2182     by standard (simp add: fun_eq_iff left_commute)
  2183   show ?thesis by (simp add: eq_fold)
  2184 qed
  2185 
  2186 lemma union [simp]: "F (M + N) = F M \<^bold>* F N"
  2187 proof -
  2188   interpret comp_fun_commute f
  2189     by standard (simp add: fun_eq_iff left_commute)
  2190   show ?thesis
  2191     by (induct N) (simp_all add: left_commute eq_fold)
  2192 qed
  2193 
  2194 lemma add_mset [simp]: "F (add_mset x N) = x \<^bold>* F N"
  2195   unfolding add_mset_add_single[of x N] union by (simp add: ac_simps)
  2196 
  2197 lemma insert [simp]:
  2198   shows "F (image_mset g (add_mset x A)) = g x \<^bold>* F (image_mset g A)"
  2199   by (simp add: eq_fold)
  2200 
  2201 lemma remove:
  2202   assumes "x \<in># A"
  2203   shows "F A = x \<^bold>* F (A - {#x#})"
  2204   using multi_member_split[OF assms] by auto
  2205 
  2206 lemma neutral:
  2207   "\<forall>x\<in>#A. x = \<^bold>1 \<Longrightarrow> F A = \<^bold>1"
  2208   by (induct A) simp_all
  2209 
  2210 lemma neutral_const [simp]:
  2211   "F (image_mset (\<lambda>_. \<^bold>1) A) = \<^bold>1"
  2212   by (simp add: neutral)
  2213 
  2214 private lemma F_image_mset_product:
  2215   "F {#g x j \<^bold>* F {#g i j. i \<in># A#}. j \<in># B#} =
  2216     F (image_mset (g x) B) \<^bold>* F {#F {#g i j. i \<in># A#}. j \<in># B#}"
  2217   by (induction B) (simp_all add: left_commute semigroup.assoc semigroup_axioms)
  2218 
  2219 lemma commute:
  2220   "F (image_mset (\<lambda>i. F (image_mset (g i) B)) A) =
  2221     F (image_mset (\<lambda>j. F (image_mset (\<lambda>i. g i j) A)) B)"
  2222   apply (induction A, simp)
  2223   apply (induction B, auto simp add: F_image_mset_product ac_simps)
  2224   done
  2225 
  2226 lemma distrib: "F (image_mset (\<lambda>x. g x \<^bold>* h x) A) = F (image_mset g A) \<^bold>* F (image_mset h A)"
  2227   by (induction A) (auto simp: ac_simps)
  2228 
  2229 lemma union_disjoint:
  2230   "A \<inter># B = {#} \<Longrightarrow> F (image_mset g (A \<union># B)) = F (image_mset g A) \<^bold>* F (image_mset g B)"
  2231   by (induction A) (auto simp: ac_simps)
  2232 
  2233 end
  2234 end
  2235 
  2236 lemma comp_fun_commute_plus_mset[simp]: "comp_fun_commute (op + :: 'a multiset \<Rightarrow> _ \<Rightarrow> _)"
  2237   by standard (simp add: add_ac comp_def)
  2238 
  2239 declare comp_fun_commute.fold_mset_add_mset[OF comp_fun_commute_plus_mset, simp]
  2240 
  2241 lemma in_mset_fold_plus_iff[iff]: "x \<in># fold_mset (op +) M NN \<longleftrightarrow> x \<in># M \<or> (\<exists>N. N \<in># NN \<and> x \<in># N)"
  2242   by (induct NN) auto
  2243 
  2244 context comm_monoid_add
  2245 begin
  2246 
  2247 sublocale sum_mset: comm_monoid_mset plus 0
  2248   defines sum_mset = sum_mset.F ..
  2249 
  2250 lemma sum_unfold_sum_mset:
  2251   "sum f A = sum_mset (image_mset f (mset_set A))"
  2252   by (cases "finite A") (induct A rule: finite_induct, simp_all)
  2253 
  2254 end
  2255 
  2256 syntax (ASCII)
  2257   "_sum_mset_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add"  ("(3SUM _:#_. _)" [0, 51, 10] 10)
  2258 syntax
  2259   "_sum_mset_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_add"  ("(3\<Sum>_\<in>#_. _)" [0, 51, 10] 10)
  2260 translations
  2261   "\<Sum>i \<in># A. b" \<rightleftharpoons> "CONST sum_mset (CONST image_mset (\<lambda>i. b) A)"
  2262 
  2263 context comm_monoid_add
  2264 begin
  2265 
  2266 lemma sum_mset_sum_list:
  2267   "sum_mset (mset xs) = sum_list xs"
  2268   by (induction xs) auto
  2269 
  2270 end
  2271 
  2272 context canonically_ordered_monoid_add
  2273 begin
  2274 
  2275 lemma sum_mset_0_iff [simp]:
  2276   "sum_mset M = 0  \<longleftrightarrow> (\<forall>x \<in> set_mset M. x = 0)"
  2277   by (induction M) auto
  2278 
  2279 end
  2280 
  2281 context ordered_comm_monoid_add
  2282 begin
  2283 
  2284 lemma sum_mset_mono:
  2285   "sum_mset (image_mset f K) \<le> sum_mset (image_mset g K)"
  2286   if "\<And>i. i \<in># K \<Longrightarrow> f i \<le> g i"
  2287   using that by (induction K) (simp_all add: add_mono)
  2288 
  2289 end
  2290 
  2291 context ordered_cancel_comm_monoid_diff
  2292 begin
  2293 
  2294 lemma sum_mset_diff:
  2295   "sum_mset (M - N) = sum_mset M - sum_mset N" if "N \<subseteq># M" for M N :: "'a multiset"
  2296   using that by (auto simp add: subset_mset.le_iff_add)
  2297 
  2298 end
  2299 
  2300 context semiring_0
  2301 begin
  2302 
  2303 lemma sum_mset_distrib_left:
  2304   "c * (\<Sum>x \<in># M. f x) = (\<Sum>x \<in># M. c * f(x))"
  2305   by (induction M) (simp_all add: algebra_simps)
  2306 
  2307 lemma sum_mset_distrib_right:
  2308   "(\<Sum>x \<in># M. f x) * c = (\<Sum>x \<in># M. f x * c)"
  2309   by (induction M) (simp_all add: algebra_simps)
  2310 
  2311 end
  2312 
  2313 lemma sum_mset_product:
  2314   fixes f :: "'a::{comm_monoid_add,times} \<Rightarrow> 'b::semiring_0"
  2315   shows "(\<Sum>i \<in># A. f i) * (\<Sum>i \<in># B. g i) = (\<Sum>i\<in>#A. \<Sum>j\<in>#B. f i * g j)"
  2316   by (subst sum_mset.commute) (simp add: sum_mset_distrib_left sum_mset_distrib_right)
  2317 
  2318 context semiring_1
  2319 begin
  2320 
  2321 lemma sum_mset_replicate_mset [simp]:
  2322   "sum_mset (replicate_mset n a) = of_nat n * a"
  2323   by (induction n) (simp_all add: algebra_simps)
  2324 
  2325 lemma sum_mset_delta:
  2326   "sum_mset (image_mset (\<lambda>x. if x = y then c else 0) A) = c * of_nat (count A y)"
  2327   by (induction A) (simp_all add: algebra_simps)
  2328 
  2329 lemma sum_mset_delta':
  2330   "sum_mset (image_mset (\<lambda>x. if y = x then c else 0) A) = c * of_nat (count A y)"
  2331   by (induction A) (simp_all add: algebra_simps)
  2332 
  2333 end
  2334 
  2335 lemma of_nat_sum_mset [simp]:
  2336   "of_nat (sum_mset A) = sum_mset (image_mset of_nat A)"
  2337   by (induction A) auto
  2338 
  2339 lemma size_eq_sum_mset:
  2340   "size M = (\<Sum>a\<in>#M. 1)"
  2341   using image_mset_const_eq [of "1::nat" M] by simp
  2342 
  2343 lemma size_mset_set [simp]:
  2344   "size (mset_set A) = card A"
  2345   by (simp only: size_eq_sum_mset card_eq_sum sum_unfold_sum_mset)
  2346 
  2347 lemma sum_mset_constant [simp]:
  2348   fixes y :: "'b::semiring_1"
  2349   shows \<open>(\<Sum>x\<in>#A. y) = of_nat (size A) * y\<close>
  2350   by (induction A) (auto simp: algebra_simps)
  2351 
  2352 abbreviation Union_mset :: "'a multiset multiset \<Rightarrow> 'a multiset"  ("\<Union>#_" [900] 900)
  2353   where "\<Union># MM \<equiv> sum_mset MM" \<comment> \<open>FIXME ambiguous notation --
  2354     could likewise refer to \<open>\<Squnion>#\<close>\<close>
  2355 
  2356 lemma set_mset_Union_mset[simp]: "set_mset (\<Union># MM) = (\<Union>M \<in> set_mset MM. set_mset M)"
  2357   by (induct MM) auto
  2358 
  2359 lemma in_Union_mset_iff[iff]: "x \<in># \<Union># MM \<longleftrightarrow> (\<exists>M. M \<in># MM \<and> x \<in># M)"
  2360   by (induct MM) auto
  2361 
  2362 lemma count_sum:
  2363   "count (sum f A) x = sum (\<lambda>a. count (f a) x) A"
  2364   by (induct A rule: infinite_finite_induct) simp_all
  2365 
  2366 lemma sum_eq_empty_iff:
  2367   assumes "finite A"
  2368   shows "sum f A = {#} \<longleftrightarrow> (\<forall>a\<in>A. f a = {#})"
  2369   using assms by induct simp_all
  2370 
  2371 lemma Union_mset_empty_conv[simp]: "\<Union># M = {#} \<longleftrightarrow> (\<forall>i\<in>#M. i = {#})"
  2372   by (induction M) auto
  2373 
  2374 
  2375 context comm_monoid_mult
  2376 begin
  2377 
  2378 sublocale prod_mset: comm_monoid_mset times 1
  2379   defines prod_mset = prod_mset.F ..
  2380 
  2381 lemma prod_mset_empty:
  2382   "prod_mset {#} = 1"
  2383   by (fact prod_mset.empty)
  2384 
  2385 lemma prod_mset_singleton:
  2386   "prod_mset {#x#} = x"
  2387   by (fact prod_mset.singleton)
  2388 
  2389 lemma prod_mset_Un:
  2390   "prod_mset (A + B) = prod_mset A * prod_mset B"
  2391   by (fact prod_mset.union)
  2392 
  2393 lemma prod_mset_prod_list:
  2394   "prod_mset (mset xs) = prod_list xs"
  2395   by (induct xs) auto
  2396 
  2397 lemma prod_mset_replicate_mset [simp]:
  2398   "prod_mset (replicate_mset n a) = a ^ n"
  2399   by (induct n) simp_all
  2400 
  2401 lemma prod_unfold_prod_mset:
  2402   "prod f A = prod_mset (image_mset f (mset_set A))"
  2403   by (cases "finite A") (induct A rule: finite_induct, simp_all)
  2404 
  2405 lemma prod_mset_multiplicity:
  2406   "prod_mset M = prod (\<lambda>x. x ^ count M x) (set_mset M)"
  2407   by (simp add: fold_mset_def prod.eq_fold prod_mset.eq_fold funpow_times_power comp_def)
  2408 
  2409 lemma prod_mset_delta: "prod_mset (image_mset (\<lambda>x. if x = y then c else 1) A) = c ^ count A y"
  2410   by (induction A) simp_all
  2411 
  2412 lemma prod_mset_delta': "prod_mset (image_mset (\<lambda>x. if y = x then c else 1) A) = c ^ count A y"
  2413   by (induction A) simp_all
  2414 
  2415 lemma prod_mset_subset_imp_dvd:
  2416   assumes "A \<subseteq># B"
  2417   shows   "prod_mset A dvd prod_mset B"
  2418 proof -
  2419   from assms have "B = (B - A) + A" by (simp add: subset_mset.diff_add)
  2420   also have "prod_mset \<dots> = prod_mset (B - A) * prod_mset A" by simp
  2421   also have "prod_mset A dvd \<dots>" by simp
  2422   finally show ?thesis .
  2423 qed
  2424 
  2425 lemma dvd_prod_mset:
  2426   assumes "x \<in># A"
  2427   shows "x dvd prod_mset A"
  2428   using assms prod_mset_subset_imp_dvd [of "{#x#}" A] by simp
  2429 
  2430 end
  2431 
  2432 syntax (ASCII)
  2433   "_prod_mset_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult"  ("(3PROD _:#_. _)" [0, 51, 10] 10)
  2434 syntax
  2435   "_prod_mset_image" :: "pttrn \<Rightarrow> 'b set \<Rightarrow> 'a \<Rightarrow> 'a::comm_monoid_mult"  ("(3\<Prod>_\<in>#_. _)" [0, 51, 10] 10)
  2436 translations
  2437   "\<Prod>i \<in># A. b" \<rightleftharpoons> "CONST prod_mset (CONST image_mset (\<lambda>i. b) A)"
  2438 
  2439 lemma prod_mset_constant [simp]: "(\<Prod>_\<in>#A. c) = c ^ size A"
  2440   by (simp add: image_mset_const_eq)
  2441 
  2442 lemma (in semidom) prod_mset_zero_iff [iff]:
  2443   "prod_mset A = 0 \<longleftrightarrow> 0 \<in># A"
  2444   by (induct A) auto
  2445 
  2446 lemma (in semidom_divide) prod_mset_diff:
  2447   assumes "B \<subseteq># A" and "0 \<notin># B"
  2448   shows "prod_mset (A - B) = prod_mset A div prod_mset B"
  2449 proof -
  2450   from assms obtain C where "A = B + C"
  2451     by (metis subset_mset.add_diff_inverse)
  2452   with assms show ?thesis by simp
  2453 qed
  2454 
  2455 lemma (in semidom_divide) prod_mset_minus:
  2456   assumes "a \<in># A" and "a \<noteq> 0"
  2457   shows "prod_mset (A - {#a#}) = prod_mset A div a"
  2458   using assms prod_mset_diff [of "{#a#}" A] by auto
  2459 
  2460 lemma (in algebraic_semidom) is_unit_prod_mset_iff:
  2461   "is_unit (prod_mset A) \<longleftrightarrow> (\<forall>x \<in># A. is_unit x)"
  2462   by (induct A) (auto simp: is_unit_mult_iff)
  2463 
  2464 lemma (in normalization_semidom) normalize_prod_mset:
  2465   "normalize (prod_mset A) = prod_mset (image_mset normalize A)"
  2466   by (induct A) (simp_all add: normalize_mult)
  2467 
  2468 lemma (in normalization_semidom) normalized_prod_msetI:
  2469   assumes "\<And>a. a \<in># A \<Longrightarrow> normalize a = a"
  2470   shows "normalize (prod_mset A) = prod_mset A"
  2471 proof -
  2472   from assms have "image_mset normalize A = A"
  2473     by (induct A) simp_all
  2474   then show ?thesis by (simp add: normalize_prod_mset)
  2475 qed
  2476 
  2477 
  2478 subsection \<open>Alternative representations\<close>
  2479 
  2480 subsubsection \<open>Lists\<close>
  2481 
  2482 context linorder
  2483 begin
  2484 
  2485 lemma mset_insort [simp]:
  2486   "mset (insort_key k x xs) = add_mset x (mset xs)"
  2487   by (induct xs) simp_all
  2488 
  2489 lemma mset_sort [simp]:
  2490   "mset (sort_key k xs) = mset xs"
  2491   by (induct xs) simp_all
  2492 
  2493 text \<open>
  2494   This lemma shows which properties suffice to show that a function
  2495   \<open>f\<close> with \<open>f xs = ys\<close> behaves like sort.
  2496 \<close>
  2497 
  2498 lemma properties_for_sort_key:
  2499   assumes "mset ys = mset xs"
  2500     and "\<And>k. k \<in> set ys \<Longrightarrow> filter (\<lambda>x. f k = f x) ys = filter (\<lambda>x. f k = f x) xs"
  2501     and "sorted (map f ys)"
  2502   shows "sort_key f xs = ys"
  2503   using assms
  2504 proof (induct xs arbitrary: ys)
  2505   case Nil then show ?case by simp
  2506 next
  2507   case (Cons x xs)
  2508   from Cons.prems(2) have
  2509     "\<forall>k \<in> set ys. filter (\<lambda>x. f k = f x) (remove1 x ys) = filter (\<lambda>x. f k = f x) xs"
  2510     by (simp add: filter_remove1)
  2511   with Cons.prems have "sort_key f xs = remove1 x ys"
  2512     by (auto intro!: Cons.hyps simp add: sorted_map_remove1)
  2513   moreover from Cons.prems have "x \<in># mset ys"
  2514     by auto
  2515   then have "x \<in> set ys"
  2516     by simp
  2517   ultimately show ?case using Cons.prems by (simp add: insort_key_remove1)
  2518 qed
  2519 
  2520 lemma properties_for_sort:
  2521   assumes multiset: "mset ys = mset xs"
  2522     and "sorted ys"
  2523   shows "sort xs = ys"
  2524 proof (rule properties_for_sort_key)
  2525   from multiset show "mset ys = mset xs" .
  2526   from \<open>sorted ys\<close> show "sorted (map (\<lambda>x. x) ys)" by simp
  2527   from multiset have "length (filter (\<lambda>y. k = y) ys) = length (filter (\<lambda>x. k = x) xs)" for k
  2528     by (rule mset_eq_length_filter)
  2529   then have "replicate (length (filter (\<lambda>y. k = y) ys)) k =
  2530     replicate (length (filter (\<lambda>x. k = x) xs)) k" for k
  2531     by simp
  2532   then show "k \<in> set ys \<Longrightarrow> filter (\<lambda>y. k = y) ys = filter (\<lambda>x. k = x) xs" for k
  2533     by (simp add: replicate_length_filter)
  2534 qed
  2535 
  2536 lemma sort_key_inj_key_eq:
  2537   assumes mset_equal: "mset xs = mset ys"
  2538     and "inj_on f (set xs)"
  2539     and "sorted (map f ys)"
  2540   shows "sort_key f xs = ys"
  2541 proof (rule properties_for_sort_key)
  2542   from mset_equal
  2543   show "mset ys = mset xs" by simp
  2544   from \<open>sorted (map f ys)\<close>
  2545   show "sorted (map f ys)" .
  2546   show "[x\<leftarrow>ys . f k = f x] = [x\<leftarrow>xs . f k = f x]" if "k \<in> set ys" for k
  2547   proof -
  2548     from mset_equal
  2549     have set_equal: "set xs = set ys" by (rule mset_eq_setD)
  2550     with that have "insert k (set ys) = set ys" by auto
  2551     with \<open>inj_on f (set xs)\<close> have inj: "inj_on f (insert k (set ys))"
  2552       by (simp add: set_equal)
  2553     from inj have "[x\<leftarrow>ys . f k = f x] = filter (HOL.eq k) ys"
  2554       by (auto intro!: inj_on_filter_key_eq)
  2555     also have "\<dots> = replicate (count (mset ys) k) k"
  2556       by (simp add: replicate_count_mset_eq_filter_eq)
  2557     also have "\<dots> = replicate (count (mset xs) k) k"
  2558       using mset_equal by simp
  2559     also have "\<dots> = filter (HOL.eq k) xs"
  2560       by (simp add: replicate_count_mset_eq_filter_eq)
  2561     also have "\<dots> = [x\<leftarrow>xs . f k = f x]"
  2562       using inj by (auto intro!: inj_on_filter_key_eq [symmetric] simp add: set_equal)
  2563     finally show ?thesis .
  2564   qed
  2565 qed
  2566 
  2567 lemma sort_key_eq_sort_key:
  2568   assumes "mset xs = mset ys"
  2569     and "inj_on f (set xs)"
  2570   shows "sort_key f xs = sort_key f ys"
  2571   by (rule sort_key_inj_key_eq) (simp_all add: assms)
  2572 
  2573 lemma sort_key_by_quicksort:
  2574   "sort_key f xs = sort_key f [x\<leftarrow>xs. f x < f (xs ! (length xs div 2))]
  2575     @ [x\<leftarrow>xs. f x = f (xs ! (length xs div 2))]
  2576     @ sort_key f [x\<leftarrow>xs. f x > f (xs ! (length xs div 2))]" (is "sort_key f ?lhs = ?rhs")
  2577 proof (rule properties_for_sort_key)
  2578   show "mset ?rhs = mset ?lhs"
  2579     by (rule multiset_eqI) (auto simp add: mset_filter)
  2580   show "sorted (map f ?rhs)"
  2581     by (auto simp add: sorted_append intro: sorted_map_same)
  2582 next
  2583   fix l
  2584   assume "l \<in> set ?rhs"
  2585   let ?pivot = "f (xs ! (length xs div 2))"
  2586   have *: "\<And>x. f l = f x \<longleftrightarrow> f x = f l" by auto
  2587   have "[x \<leftarrow> sort_key f xs . f x = f l] = [x \<leftarrow> xs. f x = f l]"
  2588     unfolding filter_sort by (rule properties_for_sort_key) (auto intro: sorted_map_same)
  2589   with * have **: "[x \<leftarrow> sort_key f xs . f l = f x] = [x \<leftarrow> xs. f l = f x]" by simp
  2590   have "\<And>x P. P (f x) ?pivot \<and> f l = f x \<longleftrightarrow> P (f l) ?pivot \<and> f l = f x" by auto
  2591   then have "\<And>P. [x \<leftarrow> sort_key f xs . P (f x) ?pivot \<and> f l = f x] =
  2592     [x \<leftarrow> sort_key f xs. P (f l) ?pivot \<and> f l = f x]" by simp
  2593   note *** = this [of "op <"] this [of "op >"] this [of "op ="]
  2594   show "[x \<leftarrow> ?rhs. f l = f x] = [x \<leftarrow> ?lhs. f l = f x]"
  2595   proof (cases "f l" ?pivot rule: linorder_cases)
  2596     case less
  2597     then have "f l \<noteq> ?pivot" and "\<not> f l > ?pivot" by auto
  2598     with less show ?thesis
  2599       by (simp add: filter_sort [symmetric] ** ***)
  2600   next
  2601     case equal then show ?thesis
  2602       by (simp add: * less_le)
  2603   next
  2604     case greater
  2605     then have "f l \<noteq> ?pivot" and "\<not> f l < ?pivot" by auto
  2606     with greater show ?thesis
  2607       by (simp add: filter_sort [symmetric] ** ***)
  2608   qed
  2609 qed
  2610 
  2611 lemma sort_by_quicksort:
  2612   "sort xs = sort [x\<leftarrow>xs. x < xs ! (length xs div 2)]
  2613     @ [x\<leftarrow>xs. x = xs ! (length xs div 2)]
  2614     @ sort [x\<leftarrow>xs. x > xs ! (length xs div 2)]" (is "sort ?lhs = ?rhs")
  2615   using sort_key_by_quicksort [of "\<lambda>x. x", symmetric] by simp
  2616 
  2617 text \<open>A stable parametrized quicksort\<close>
  2618 
  2619 definition part :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b list \<Rightarrow> 'b list \<times> 'b list \<times> 'b list" where
  2620   "part f pivot xs = ([x \<leftarrow> xs. f x < pivot], [x \<leftarrow> xs. f x = pivot], [x \<leftarrow> xs. pivot < f x])"
  2621 
  2622 lemma part_code [code]:
  2623   "part f pivot [] = ([], [], [])"
  2624   "part f pivot (x # xs) = (let (lts, eqs, gts) = part f pivot xs; x' = f x in
  2625      if x' < pivot then (x # lts, eqs, gts)
  2626      else if x' > pivot then (lts, eqs, x # gts)
  2627      else (lts, x # eqs, gts))"
  2628   by (auto simp add: part_def Let_def split_def)
  2629 
  2630 lemma sort_key_by_quicksort_code [code]:
  2631   "sort_key f xs =
  2632     (case xs of
  2633       [] \<Rightarrow> []
  2634     | [x] \<Rightarrow> xs
  2635     | [x, y] \<Rightarrow> (if f x \<le> f y then xs else [y, x])
  2636     | _ \<Rightarrow>
  2637         let (lts, eqs, gts) = part f (f (xs ! (length xs div 2))) xs
  2638         in sort_key f lts @ eqs @ sort_key f gts)"
  2639 proof (cases xs)
  2640   case Nil then show ?thesis by simp
  2641 next
  2642   case (Cons _ ys) note hyps = Cons show ?thesis
  2643   proof (cases ys)
  2644     case Nil with hyps show ?thesis by simp
  2645   next
  2646     case (Cons _ zs) note hyps = hyps Cons show ?thesis
  2647     proof (cases zs)
  2648       case Nil with hyps show ?thesis by auto
  2649     next
  2650       case Cons
  2651       from sort_key_by_quicksort [of f xs]
  2652       have "sort_key f xs = (let (lts, eqs, gts) = part f (f (xs ! (length xs div 2))) xs
  2653         in sort_key f lts @ eqs @ sort_key f gts)"
  2654       by (simp only: split_def Let_def part_def fst_conv snd_conv)
  2655       with hyps Cons show ?thesis by (simp only: list.cases)
  2656     qed
  2657   qed
  2658 qed
  2659 
  2660 end
  2661 
  2662 hide_const (open) part
  2663 
  2664 lemma mset_remdups_subset_eq: "mset (remdups xs) \<subseteq># mset xs"
  2665   by (induct xs) (auto intro: subset_mset.order_trans)
  2666 
  2667 lemma mset_update:
  2668   "i < length ls \<Longrightarrow> mset (ls[i := v]) = add_mset v (mset ls - {#ls ! i#})"
  2669 proof (induct ls arbitrary: i)
  2670   case Nil then show ?case by simp
  2671 next
  2672   case (Cons x xs)
  2673   show ?case
  2674   proof (cases i)
  2675     case 0 then show ?thesis by simp
  2676   next
  2677     case (Suc i')
  2678     with Cons show ?thesis
  2679       by (cases \<open>x = xs ! i'\<close>) auto
  2680   qed
  2681 qed
  2682 
  2683 lemma mset_swap:
  2684   "i < length ls \<Longrightarrow> j < length ls \<Longrightarrow>
  2685     mset (ls[j := ls ! i, i := ls ! j]) = mset ls"
  2686   by (cases "i = j") (simp_all add: mset_update nth_mem_mset)
  2687 
  2688 
  2689 subsection \<open>The multiset order\<close>
  2690 
  2691 subsubsection \<open>Well-foundedness\<close>
  2692 
  2693 definition mult1 :: "('a \<times> 'a) set \<Rightarrow> ('a multiset \<times> 'a multiset) set" where
  2694   "mult1 r = {(N, M). \<exists>a M0 K. M = add_mset a M0 \<and> N = M0 + K \<and>
  2695       (\<forall>b. b \<in># K \<longrightarrow> (b, a) \<in> r)}"
  2696 
  2697 definition mult :: "('a \<times> 'a) set \<Rightarrow> ('a multiset \<times> 'a multiset) set" where
  2698   "mult r = (mult1 r)\<^sup>+"
  2699 
  2700 lemma mult1I:
  2701   assumes "M = add_mset a M0" and "N = M0 + K" and "\<And>b. b \<in># K \<Longrightarrow> (b, a) \<in> r"
  2702   shows "(N, M) \<in> mult1 r"
  2703   using assms unfolding mult1_def by blast
  2704 
  2705 lemma mult1E:
  2706   assumes "(N, M) \<in> mult1 r"
  2707   obtains a M0 K where "M = add_mset a M0" "N = M0 + K" "\<And>b. b \<in># K \<Longrightarrow> (b, a) \<in> r"
  2708   using assms unfolding mult1_def by blast
  2709 
  2710 lemma mono_mult1:
  2711   assumes "r \<subseteq> r'" shows "mult1 r \<subseteq> mult1 r'"
  2712 unfolding mult1_def using assms by blast
  2713 
  2714 lemma mono_mult:
  2715   assumes "r \<subseteq> r'" shows "mult r \<subseteq> mult r'"
  2716 unfolding mult_def using mono_mult1[OF assms] trancl_mono by blast
  2717 
  2718 lemma not_less_empty [iff]: "(M, {#}) \<notin> mult1 r"
  2719 by (simp add: mult1_def)
  2720 
  2721 lemma less_add:
  2722   assumes mult1: "(N, add_mset a M0) \<in> mult1 r"
  2723   shows
  2724     "(\<exists>M. (M, M0) \<in> mult1 r \<and> N = add_mset a M) \<or>
  2725      (\<exists>K. (\<forall>b. b \<in># K \<longrightarrow> (b, a) \<in> r) \<and> N = M0 + K)"
  2726 proof -
  2727   let ?r = "\<lambda>K a. \<forall>b. b \<in># K \<longrightarrow> (b, a) \<in> r"
  2728   let ?R = "\<lambda>N M. \<exists>a M0 K. M = add_mset a M0 \<and> N = M0 + K \<and> ?r K a"
  2729   obtain a' M0' K where M0: "add_mset a M0 = add_mset a' M0'"
  2730     and N: "N = M0' + K"
  2731     and r: "?r K a'"
  2732     using mult1 unfolding mult1_def by auto
  2733   show ?thesis (is "?case1 \<or> ?case2")
  2734   proof -
  2735     from M0 consider "M0 = M0'" "a = a'"
  2736       | K' where "M0 = add_mset a' K'" "M0' = add_mset a K'"
  2737       by atomize_elim (simp only: add_eq_conv_ex)
  2738     then show ?thesis
  2739     proof cases
  2740       case 1
  2741       with N r have "?r K a \<and> N = M0 + K" by simp
  2742       then have ?case2 ..
  2743       then show ?thesis ..
  2744     next
  2745       case 2
  2746       from N 2(2) have n: "N = add_mset a (K' + K)" by simp
  2747       with r 2(1) have "?R (K' + K) M0" by blast
  2748       with n have ?case1 by (simp add: mult1_def)
  2749       then show ?thesis ..
  2750     qed
  2751   qed
  2752 qed
  2753 
  2754 lemma all_accessible:
  2755   assumes "wf r"
  2756   shows "\<forall>M. M \<in> Wellfounded.acc (mult1 r)"
  2757 proof
  2758   let ?R = "mult1 r"
  2759   let ?W = "Wellfounded.acc ?R"
  2760   {
  2761     fix M M0 a
  2762     assume M0: "M0 \<in> ?W"
  2763       and wf_hyp: "\<And>b. (b, a) \<in> r \<Longrightarrow> (\<forall>M \<in> ?W. add_mset b M \<in> ?W)"
  2764       and acc_hyp: "\<forall>M. (M, M0) \<in> ?R \<longrightarrow> add_mset a M \<in> ?W"
  2765     have "add_mset a M0 \<in> ?W"
  2766     proof (rule accI [of "add_mset a M0"])
  2767       fix N
  2768       assume "(N, add_mset a M0) \<in> ?R"
  2769       then consider M where "(M, M0) \<in> ?R" "N = add_mset a M"
  2770         | K where "\<forall>b. b \<in># K \<longrightarrow> (b, a) \<in> r" "N = M0 + K"
  2771         by atomize_elim (rule less_add)
  2772       then show "N \<in> ?W"
  2773       proof cases
  2774         case 1
  2775         from acc_hyp have "(M, M0) \<in> ?R \<longrightarrow> add_mset a M \<in> ?W" ..
  2776         from this and \<open>(M, M0) \<in> ?R\<close> have "add_mset a M \<in> ?W" ..
  2777         then show "N \<in> ?W" by (simp only: \<open>N = add_mset a M\<close>)
  2778       next
  2779         case 2
  2780         from this(1) have "M0 + K \<in> ?W"
  2781         proof (induct K)
  2782           case empty
  2783           from M0 show "M0 + {#} \<in> ?W" by simp
  2784         next
  2785           case (add x K)
  2786           from add.prems have "(x, a) \<in> r" by simp
  2787           with wf_hyp have "\<forall>M \<in> ?W. add_mset x M \<in> ?W" by blast
  2788           moreover from add have "M0 + K \<in> ?W" by simp
  2789           ultimately have "add_mset x (M0 + K) \<in> ?W" ..
  2790           then show "M0 + (add_mset x K) \<in> ?W" by simp
  2791         qed
  2792         then show "N \<in> ?W" by (simp only: 2(2))
  2793       qed
  2794     qed
  2795   } note tedious_reasoning = this
  2796 
  2797   show "M \<in> ?W" for M
  2798   proof (induct M)
  2799     show "{#} \<in> ?W"
  2800     proof (rule accI)
  2801       fix b assume "(b, {#}) \<in> ?R"
  2802       with not_less_empty show "b \<in> ?W" by contradiction
  2803     qed
  2804 
  2805     fix M a assume "M \<in> ?W"
  2806     from \<open>wf r\<close> have "\<forall>M \<in> ?W. add_mset a M \<in> ?W"
  2807     proof induct
  2808       fix a
  2809       assume r: "\<And>b. (b, a) \<in> r \<Longrightarrow> (\<forall>M \<in> ?W. add_mset b M \<in> ?W)"
  2810       show "\<forall>M \<in> ?W. add_mset a M \<in> ?W"
  2811       proof
  2812         fix M assume "M \<in> ?W"
  2813         then show "add_mset a M \<in> ?W"
  2814           by (rule acc_induct) (rule tedious_reasoning [OF _ r])
  2815       qed
  2816     qed
  2817     from this and \<open>M \<in> ?W\<close> show "add_mset a M \<in> ?W" ..
  2818   qed
  2819 qed
  2820 
  2821 theorem wf_mult1: "wf r \<Longrightarrow> wf (mult1 r)"
  2822 by (rule acc_wfI) (rule all_accessible)
  2823 
  2824 theorem wf_mult: "wf r \<Longrightarrow> wf (mult r)"
  2825 unfolding mult_def by (rule wf_trancl) (rule wf_mult1)
  2826 
  2827 
  2828 subsubsection \<open>Closure-free presentation\<close>
  2829 
  2830 text \<open>One direction.\<close>
  2831 lemma mult_implies_one_step:
  2832   assumes
  2833     trans: "trans r" and
  2834     MN: "(M, N) \<in> mult r"
  2835   shows "\<exists>I J K. N = I + J \<and> M = I + K \<and> J \<noteq> {#} \<and> (\<forall>k \<in> set_mset K. \<exists>j \<in> set_mset J. (k, j) \<in> r)"
  2836   using MN unfolding mult_def mult1_def
  2837 proof (induction rule: converse_trancl_induct)
  2838   case (base y)
  2839   then show ?case by force
  2840 next
  2841   case (step y z) note yz = this(1) and zN = this(2) and N_decomp = this(3)
  2842   obtain I J K where
  2843     N: "N = I + J" "z = I + K" "J \<noteq> {#}" "\<forall>k\<in>#K. \<exists>j\<in>#J. (k, j) \<in> r"
  2844     using N_decomp by blast
  2845   obtain a M0 K' where
  2846     z: "z = add_mset a M0" and y: "y = M0 + K'" and K: "\<forall>b. b \<in># K' \<longrightarrow> (b, a) \<in> r"
  2847     using yz by blast
  2848   show ?case
  2849   proof (cases "a \<in># K")
  2850     case True
  2851     moreover have "\<exists>j\<in>#J. (k, j) \<in> r" if "k \<in># K'" for k
  2852       using K N trans True by (meson that transE)
  2853     ultimately show ?thesis
  2854       by (rule_tac x = I in exI, rule_tac x = J in exI, rule_tac x = "(K - {#a#}) + K'" in exI)
  2855         (use z y N in \<open>auto simp del: subset_mset.add_diff_assoc2 dest: in_diffD\<close>)
  2856   next
  2857     case False
  2858     then have "a \<in># I" by (metis N(2) union_iff union_single_eq_member z)
  2859     moreover have "M0 = I + K - {#a#}"
  2860       using N(2) z by force
  2861     ultimately show ?thesis
  2862       by (rule_tac x = "I - {#a#}" in exI, rule_tac x = "add_mset a J" in exI,
  2863           rule_tac x = "K + K'" in exI)
  2864         (use z y N False K in \<open>auto simp: add.assoc\<close>)
  2865   qed
  2866 qed
  2867 
  2868 lemma one_step_implies_mult:
  2869   assumes
  2870     "J \<noteq> {#}" and
  2871     "\<forall>k \<in> set_mset K. \<exists>j \<in> set_mset J. (k, j) \<in> r"
  2872   shows "(I + K, I + J) \<in> mult r"
  2873   using assms
  2874 proof (induction "size J" arbitrary: I J K)
  2875   case 0
  2876   then show ?case by auto
  2877 next
  2878   case (Suc n) note IH = this(1) and size_J = this(2)[THEN sym]
  2879   obtain J' a where J: "J = add_mset a J'"
  2880     using size_J by (blast dest: size_eq_Suc_imp_eq_union)
  2881   show ?case
  2882   proof (cases "J' = {#}")
  2883     case True
  2884     then show ?thesis
  2885       using J Suc by (fastforce simp add: mult_def mult1_def)
  2886   next
  2887     case [simp]: False
  2888     have K: "K = {#x \<in># K. (x, a) \<in> r#} + {#x \<in># K. (x, a) \<notin> r#}"
  2889       by (rule multiset_partition)
  2890     have "(I + K, (I + {# x \<in># K. (x, a) \<in> r #}) + J') \<in> mult r"
  2891       using IH[of J' "{# x \<in># K. (x, a) \<notin> r#}" "I + {# x \<in># K. (x, a) \<in> r#}"]
  2892         J Suc.prems K size_J by (auto simp: ac_simps)
  2893     moreover have "(I + {#x \<in># K. (x, a) \<in> r#} + J', I + J) \<in> mult r"
  2894       by (fastforce simp: J mult1_def mult_def)
  2895     ultimately show ?thesis
  2896       unfolding mult_def by simp
  2897   qed
  2898 qed
  2899 
  2900 lemma subset_implies_mult:
  2901   assumes sub: "A \<subset># B"
  2902   shows "(A, B) \<in> mult r"
  2903 proof -
  2904   have ApBmA: "A + (B - A) = B"
  2905     using sub by simp
  2906   have BmA: "B - A \<noteq> {#}"
  2907     using sub by (simp add: Diff_eq_empty_iff_mset subset_mset.less_le_not_le)
  2908   thus ?thesis
  2909     by (rule one_step_implies_mult[of "B - A" "{#}" _ A, unfolded ApBmA, simplified])
  2910 qed
  2911 
  2912 
  2913 subsection \<open>The multiset extension is cancellative for multiset union\<close>
  2914 
  2915 lemma mult_cancel:
  2916   assumes "trans s" and "irrefl s"
  2917   shows "(X + Z, Y + Z) \<in> mult s \<longleftrightarrow> (X, Y) \<in> mult s" (is "?L \<longleftrightarrow> ?R")
  2918 proof
  2919   assume ?L thus ?R
  2920   proof (induct Z)
  2921     case (add z Z)
  2922     obtain X' Y' Z' where *: "add_mset z X + Z = Z' + X'" "add_mset z Y + Z = Z' + Y'" "Y' \<noteq> {#}"
  2923       "\<forall>x \<in> set_mset X'. \<exists>y \<in> set_mset Y'. (x, y) \<in> s"
  2924       using mult_implies_one_step[OF \<open>trans s\<close> add(2)] by auto
  2925     consider Z2 where "Z' = add_mset z Z2" | X2 Y2 where "X' = add_mset z X2" "Y' = add_mset z Y2"
  2926       using *(1,2) by (metis add_mset_remove_trivial_If insert_iff set_mset_add_mset_insert union_iff)
  2927     thus ?case
  2928     proof (cases)
  2929       case 1 thus ?thesis using * one_step_implies_mult[of Y' X' s Z2]
  2930         by (auto simp: add.commute[of _ "{#_#}"] add.assoc intro: add(1))
  2931     next
  2932       case 2 then obtain y where "y \<in> set_mset Y2" "(z, y) \<in> s" using *(4) \<open>irrefl s\<close>
  2933         by (auto simp: irrefl_def)
  2934       moreover from this transD[OF \<open>trans s\<close> _ this(2)]
  2935       have "x' \<in> set_mset X2 \<Longrightarrow> \<exists>y \<in> set_mset Y2. (x', y) \<in> s" for x'
  2936         using 2 *(4)[rule_format, of x'] by auto
  2937       ultimately show ?thesis using  * one_step_implies_mult[of Y2 X2 s Z'] 2
  2938         by (force simp: add.commute[of "{#_#}"] add.assoc[symmetric] intro: add(1))
  2939     qed
  2940   qed auto
  2941 next
  2942   assume ?R then obtain I J K
  2943     where "Y = I + J" "X = I + K" "J \<noteq> {#}" "\<forall>k \<in> set_mset K. \<exists>j \<in> set_mset J. (k, j) \<in> s"
  2944     using mult_implies_one_step[OF \<open>trans s\<close>] by blast
  2945   thus ?L using one_step_implies_mult[of J K s "I + Z"] by (auto simp: ac_simps)
  2946 qed
  2947 
  2948 lemmas mult_cancel_add_mset =
  2949   mult_cancel[of _ _ "{#_#}", unfolded union_mset_add_mset_right add.comm_neutral]
  2950 
  2951 lemma mult_cancel_max:
  2952   assumes "trans s" and "irrefl s"
  2953   shows "(X, Y) \<in> mult s \<longleftrightarrow> (X - X \<inter># Y, Y - X \<inter># Y) \<in> mult s" (is "?L \<longleftrightarrow> ?R")
  2954 proof -
  2955   have "X - X \<inter># Y + X \<inter># Y = X" "Y - X \<inter># Y + X \<inter># Y = Y" by (auto simp: count_inject[symmetric])
  2956   thus ?thesis using mult_cancel[OF assms, of "X - X \<inter># Y"  "X \<inter># Y" "Y - X \<inter># Y"] by auto
  2957 qed
  2958 
  2959 
  2960 subsection \<open>Quasi-executable version of the multiset extension\<close>
  2961 
  2962 text \<open>
  2963   Predicate variants of \<open>mult\<close> and the reflexive closure of \<open>mult\<close>, which are
  2964   executable whenever the given predicate \<open>P\<close> is. Together with the standard
  2965   code equations for \<open>op \<inter>#\<close> and \<open>op -\<close> this should yield quadratic
  2966   (with respect to calls to \<open>P\<close>) implementations of \<open>multp\<close> and \<open>multeqp\<close>.
  2967 \<close>
  2968 
  2969 definition multp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" where
  2970   "multp P N M =
  2971     (let Z = M \<inter># N; X = M - Z in
  2972     X \<noteq> {#} \<and> (let Y = N - Z in (\<forall>y \<in> set_mset Y. \<exists>x \<in> set_mset X. P y x)))"
  2973 
  2974 definition multeqp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" where
  2975   "multeqp P N M =
  2976     (let Z = M \<inter># N; X = M - Z; Y = N - Z in
  2977     (\<forall>y \<in> set_mset Y. \<exists>x \<in> set_mset X. P y x))"
  2978 
  2979 lemma multp_iff:
  2980   assumes "irrefl R" and "trans R" and [simp]: "\<And>x y. P x y \<longleftrightarrow> (x, y) \<in> R"
  2981   shows "multp P N M \<longleftrightarrow> (N, M) \<in> mult R" (is "?L \<longleftrightarrow> ?R")
  2982 proof -
  2983   have *: "M \<inter># N + (N - M \<inter># N) = N" "M \<inter># N + (M - M \<inter># N) = M"
  2984     "(M - M \<inter># N) \<inter># (N - M \<inter># N) = {#}" by (auto simp: count_inject[symmetric])
  2985   show ?thesis
  2986   proof
  2987     assume ?L thus ?R
  2988       using one_step_implies_mult[of "M - M \<inter># N" "N - M \<inter># N" R "M \<inter># N"] *
  2989       by (auto simp: multp_def Let_def)
  2990   next
  2991     { fix I J K :: "'a multiset" assume "(I + J) \<inter># (I + K) = {#}"
  2992       then have "I = {#}" by (metis inter_union_distrib_right union_eq_empty)
  2993     } note [dest!] = this
  2994     assume ?R thus ?L
  2995       using mult_implies_one_step[OF assms(2), of "N - M \<inter># N" "M - M \<inter># N"]
  2996         mult_cancel_max[OF assms(2,1), of "N" "M"] * by (auto simp: multp_def)
  2997   qed
  2998 qed
  2999 
  3000 lemma multeqp_iff:
  3001   assumes "irrefl R" and "trans R" and "\<And>x y. P x y \<longleftrightarrow> (x, y) \<in> R"
  3002   shows "multeqp P N M \<longleftrightarrow> (N, M) \<in> (mult R)\<^sup>="
  3003 proof -
  3004   { assume "N \<noteq> M" "M - M \<inter># N = {#}"
  3005     then obtain y where "count N y \<noteq> count M y" by (auto simp: count_inject[symmetric])
  3006     then have "\<exists>y. count M y < count N y" using \<open>M - M \<inter># N = {#}\<close>
  3007       by (auto simp: count_inject[symmetric] dest!: le_neq_implies_less fun_cong[of _ _ y])
  3008   }
  3009   then have "multeqp P N M \<longleftrightarrow> multp P N M \<or> N = M"
  3010     by (auto simp: multeqp_def multp_def Let_def in_diff_count)
  3011   thus ?thesis using multp_iff[OF assms] by simp
  3012 qed
  3013 
  3014 
  3015 subsubsection \<open>Partial-order properties\<close>
  3016 
  3017 lemma (in preorder) mult1_lessE:
  3018   assumes "(N, M) \<in> mult1 {(a, b). a < b}"
  3019   obtains a M0 K where "M = add_mset a M0" "N = M0 + K"
  3020     "a \<notin># K" "\<And>b. b \<in># K \<Longrightarrow> b < a"
  3021 proof -
  3022   from assms obtain a M0 K where "M = add_mset a M0" "N = M0 + K" and
  3023     *: "b \<in># K \<Longrightarrow> b < a" for b by (blast elim: mult1E)
  3024   moreover from * [of a] have "a \<notin># K" by auto
  3025   ultimately show thesis by (auto intro: that)
  3026 qed
  3027 
  3028 instantiation multiset :: (preorder) order
  3029 begin
  3030 
  3031 definition less_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool"
  3032   where "M' < M \<longleftrightarrow> (M', M) \<in> mult {(x', x). x' < x}"
  3033 
  3034 definition less_eq_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool"
  3035   where "less_eq_multiset M' M \<longleftrightarrow> M' < M \<or> M' = M"
  3036 
  3037 instance
  3038 proof -
  3039   have irrefl: "\<not> M < M" for M :: "'a multiset"
  3040   proof
  3041     assume "M < M"
  3042     then have MM: "(M, M) \<in> mult {(x, y). x < y}" by (simp add: less_multiset_def)
  3043     have "trans {(x'::'a, x). x' < x}"
  3044       by (metis (mono_tags, lifting) case_prodD case_prodI less_trans mem_Collect_eq transI)
  3045     moreover note MM
  3046     ultimately have "\<exists>I J K. M = I + J \<and> M = I + K
  3047       \<and> J \<noteq> {#} \<and> (\<forall>k\<in>set_mset K. \<exists>j\<in>set_mset J. (k, j) \<in> {(x, y). x < y})"
  3048       by (rule mult_implies_one_step)
  3049     then obtain I J K where "M = I + J" and "M = I + K"
  3050       and "J \<noteq> {#}" and "(\<forall>k\<in>set_mset K. \<exists>j\<in>set_mset J. (k, j) \<in> {(x, y). x < y})" by blast
  3051     then have *: "K \<noteq> {#}" and **: "\<forall>k\<in>set_mset K. \<exists>j\<in>set_mset K. k < j" by auto
  3052     have "finite (set_mset K)" by simp
  3053     moreover note **
  3054     ultimately have "set_mset K = {}"
  3055       by (induct rule: finite_induct) (auto intro: order_less_trans)
  3056     with * show False by simp
  3057   qed
  3058   have trans: "K < M \<Longrightarrow> M < N \<Longrightarrow> K < N" for K M N :: "'a multiset"
  3059     unfolding less_multiset_def mult_def by (blast intro: trancl_trans)
  3060   show "OFCLASS('a multiset, order_class)"
  3061     by standard (auto simp add: less_eq_multiset_def irrefl dest: trans)
  3062 qed
  3063 end \<comment> \<open>FIXME avoid junk stemming from type class interpretation\<close>
  3064 
  3065 lemma mset_le_irrefl [elim!]:
  3066   fixes M :: "'a::preorder multiset"
  3067   shows "M < M \<Longrightarrow> R"
  3068   by simp
  3069 
  3070 
  3071 subsubsection \<open>Monotonicity of multiset union\<close>
  3072 
  3073 lemma mult1_union: "(B, D) \<in> mult1 r \<Longrightarrow> (C + B, C + D) \<in> mult1 r"
  3074   by (force simp: mult1_def)
  3075 
  3076 lemma union_le_mono2: "B < D \<Longrightarrow> C + B < C + (D::'a::preorder multiset)"
  3077 apply (unfold less_multiset_def mult_def)
  3078 apply (erule trancl_induct)
  3079  apply (blast intro: mult1_union)
  3080 apply (blast intro: mult1_union trancl_trans)
  3081 done
  3082 
  3083 lemma union_le_mono1: "B < D \<Longrightarrow> B + C < D + (C::'a::preorder multiset)"
  3084 apply (subst add.commute [of B C])
  3085 apply (subst add.commute [of D C])
  3086 apply (erule union_le_mono2)
  3087 done
  3088 
  3089 lemma union_less_mono:
  3090   fixes A B C D :: "'a::preorder multiset"
  3091   shows "A < C \<Longrightarrow> B < D \<Longrightarrow> A + B < C + D"
  3092   by (blast intro!: union_le_mono1 union_le_mono2 less_trans)
  3093 
  3094 instantiation multiset :: (preorder) ordered_ab_semigroup_add
  3095 begin
  3096 instance
  3097   by standard (auto simp add: less_eq_multiset_def intro: union_le_mono2)
  3098 end
  3099 
  3100 
  3101 subsubsection \<open>Termination proofs with multiset orders\<close>
  3102 
  3103 lemma multi_member_skip: "x \<in># XS \<Longrightarrow> x \<in># {# y #} + XS"
  3104   and multi_member_this: "x \<in># {# x #} + XS"
  3105   and multi_member_last: "x \<in># {# x #}"
  3106   by auto
  3107 
  3108 definition "ms_strict = mult pair_less"
  3109 definition "ms_weak = ms_strict \<union> Id"
  3110 
  3111 lemma ms_reduction_pair: "reduction_pair (ms_strict, ms_weak)"
  3112 unfolding reduction_pair_def ms_strict_def ms_weak_def pair_less_def
  3113 by (auto intro: wf_mult1 wf_trancl simp: mult_def)
  3114 
  3115 lemma smsI:
  3116   "(set_mset A, set_mset B) \<in> max_strict \<Longrightarrow> (Z + A, Z + B) \<in> ms_strict"
  3117   unfolding ms_strict_def
  3118 by (rule one_step_implies_mult) (auto simp add: max_strict_def pair_less_def elim!:max_ext.cases)
  3119 
  3120 lemma wmsI:
  3121   "(set_mset A, set_mset B) \<in> max_strict \<or> A = {#} \<and> B = {#}
  3122   \<Longrightarrow> (Z + A, Z + B) \<in> ms_weak"
  3123 unfolding ms_weak_def ms_strict_def
  3124 by (auto simp add: pair_less_def max_strict_def elim!:max_ext.cases intro: one_step_implies_mult)
  3125 
  3126 inductive pw_leq
  3127 where
  3128   pw_leq_empty: "pw_leq {#} {#}"
  3129 | pw_leq_step:  "\<lbrakk>(x,y) \<in> pair_leq; pw_leq X Y \<rbrakk> \<Longrightarrow> pw_leq ({#x#} + X) ({#y#} + Y)"
  3130 
  3131 lemma pw_leq_lstep:
  3132   "(x, y) \<in> pair_leq \<Longrightarrow> pw_leq {#x#} {#y#}"
  3133 by (drule pw_leq_step) (rule pw_leq_empty, simp)
  3134 
  3135 lemma pw_leq_split:
  3136   assumes "pw_leq X Y"
  3137   shows "\<exists>A B Z. X = A + Z \<and> Y = B + Z \<and> ((set_mset A, set_mset B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
  3138   using assms
  3139 proof induct
  3140   case pw_leq_empty thus ?case by auto
  3141 next
  3142   case (pw_leq_step x y X Y)
  3143   then obtain A B Z where
  3144     [simp]: "X = A + Z" "Y = B + Z"
  3145       and 1[simp]: "(set_mset A, set_mset B) \<in> max_strict \<or> (B = {#} \<and> A = {#})"
  3146     by auto
  3147   from pw_leq_step consider "x = y" | "(x, y) \<in> pair_less"
  3148     unfolding pair_leq_def by auto
  3149   thus ?case
  3150   proof cases
  3151     case [simp]: 1
  3152     have "{#x#} + X = A + ({#y#}+Z) \<and> {#y#} + Y = B + ({#y#}+Z) \<and>
  3153       ((set_mset A, set_mset B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
  3154       by auto
  3155     thus ?thesis by blast
  3156   next
  3157     case 2
  3158     let ?A' = "{#x#} + A" and ?B' = "{#y#} + B"
  3159     have "{#x#} + X = ?A' + Z"
  3160       "{#y#} + Y = ?B' + Z"
  3161       by auto
  3162     moreover have
  3163       "(set_mset ?A', set_mset ?B') \<in> max_strict"
  3164       using 1 2 unfolding max_strict_def
  3165       by (auto elim!: max_ext.cases)
  3166     ultimately show ?thesis by blast
  3167   qed
  3168 qed
  3169 
  3170 lemma
  3171   assumes pwleq: "pw_leq Z Z'"
  3172   shows ms_strictI: "(set_mset A, set_mset B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_strict"
  3173     and ms_weakI1:  "(set_mset A, set_mset B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_weak"
  3174     and ms_weakI2:  "(Z + {#}, Z' + {#}) \<in> ms_weak"
  3175 proof -
  3176   from pw_leq_split[OF pwleq]
  3177   obtain A' B' Z''
  3178     where [simp]: "Z = A' + Z''" "Z' = B' + Z''"
  3179     and mx_or_empty: "(set_mset A', set_mset B') \<in> max_strict \<or> (A' = {#} \<and> B' = {#})"
  3180     by blast
  3181   {
  3182     assume max: "(set_mset A, set_mset B) \<in> max_strict"
  3183     from mx_or_empty
  3184     have "(Z'' + (A + A'), Z'' + (B + B')) \<in> ms_strict"
  3185     proof
  3186       assume max': "(set_mset A', set_mset B') \<in> max_strict"
  3187       with max have "(set_mset (A + A'), set_mset (B + B')) \<in> max_strict"
  3188         by (auto simp: max_strict_def intro: max_ext_additive)
  3189       thus ?thesis by (rule smsI)
  3190     next
  3191       assume [simp]: "A' = {#} \<and> B' = {#}"
  3192       show ?thesis by (rule smsI) (auto intro: max)
  3193     qed
  3194     thus "(Z + A, Z' + B) \<in> ms_strict" by (simp add: ac_simps)
  3195     thus "(Z + A, Z' + B) \<in> ms_weak" by (simp add: ms_weak_def)
  3196   }
  3197   from mx_or_empty
  3198   have "(Z'' + A', Z'' + B') \<in> ms_weak" by (rule wmsI)
  3199   thus "(Z + {#}, Z' + {#}) \<in> ms_weak" by (simp add: ac_simps)
  3200 qed
  3201 
  3202 lemma empty_neutral: "{#} + x = x" "x + {#} = x"
  3203 and nonempty_plus: "{# x #} + rs \<noteq> {#}"
  3204 and nonempty_single: "{# x #} \<noteq> {#}"
  3205 by auto
  3206 
  3207 setup \<open>
  3208   let
  3209     fun msetT T = Type (@{type_name multiset}, [T]);
  3210 
  3211     fun mk_mset T [] = Const (@{const_abbrev Mempty}, msetT T)
  3212       | mk_mset T [x] =
  3213         Const (@{const_name add_mset}, T --> msetT T --> msetT T) $ x $
  3214           Const (@{const_abbrev Mempty}, msetT T)
  3215       | mk_mset T (x :: xs) =
  3216         Const (@{const_name plus}, msetT T --> msetT T --> msetT T) $
  3217           mk_mset T [x] $ mk_mset T xs
  3218 
  3219     fun mset_member_tac ctxt m i =
  3220       if m <= 0 then
  3221         resolve_tac ctxt @{thms multi_member_this} i ORELSE
  3222         resolve_tac ctxt @{thms multi_member_last} i
  3223       else
  3224         resolve_tac ctxt @{thms multi_member_skip} i THEN mset_member_tac ctxt (m - 1) i
  3225 
  3226     fun mset_nonempty_tac ctxt =
  3227       resolve_tac ctxt @{thms nonempty_plus} ORELSE'
  3228       resolve_tac ctxt @{thms nonempty_single}
  3229 
  3230     fun regroup_munion_conv ctxt =
  3231       Function_Lib.regroup_conv ctxt @{const_abbrev Mempty} @{const_name plus}
  3232         (map (fn t => t RS eq_reflection) (@{thms ac_simps} @ @{thms empty_neutral}))
  3233 
  3234     fun unfold_pwleq_tac ctxt i =
  3235       (resolve_tac ctxt @{thms pw_leq_step} i THEN (fn st => unfold_pwleq_tac ctxt (i + 1) st))
  3236         ORELSE (resolve_tac ctxt @{thms pw_leq_lstep} i)
  3237         ORELSE (resolve_tac ctxt @{thms pw_leq_empty} i)
  3238 
  3239     val set_mset_simps = [@{thm set_mset_empty}, @{thm set_mset_single}, @{thm set_mset_union},
  3240                         @{thm Un_insert_left}, @{thm Un_empty_left}]
  3241   in
  3242     ScnpReconstruct.multiset_setup (ScnpReconstruct.Multiset
  3243     {
  3244       msetT=msetT, mk_mset=mk_mset, mset_regroup_conv=regroup_munion_conv,
  3245       mset_member_tac=mset_member_tac, mset_nonempty_tac=mset_nonempty_tac,
  3246       mset_pwleq_tac=unfold_pwleq_tac, set_of_simps=set_mset_simps,
  3247       smsI'= @{thm ms_strictI}, wmsI2''= @{thm ms_weakI2}, wmsI1= @{thm ms_weakI1},
  3248       reduction_pair = @{thm ms_reduction_pair}
  3249     })
  3250   end
  3251 \<close>
  3252 
  3253 
  3254 subsection \<open>Legacy theorem bindings\<close>
  3255 
  3256 lemmas multi_count_eq = multiset_eq_iff [symmetric]
  3257 
  3258 lemma union_commute: "M + N = N + (M::'a multiset)"
  3259   by (fact add.commute)
  3260 
  3261 lemma union_assoc: "(M + N) + K = M + (N + (K::'a multiset))"
  3262   by (fact add.assoc)
  3263 
  3264 lemma union_lcomm: "M + (N + K) = N + (M + (K::'a multiset))"
  3265   by (fact add.left_commute)
  3266 
  3267 lemmas union_ac = union_assoc union_commute union_lcomm add_mset_commute
  3268 
  3269 lemma union_right_cancel: "M + K = N + K \<longleftrightarrow> M = (N::'a multiset)"
  3270   by (fact add_right_cancel)
  3271 
  3272 lemma union_left_cancel: "K + M = K + N \<longleftrightarrow> M = (N::'a multiset)"
  3273   by (fact add_left_cancel)
  3274 
  3275 lemma multi_union_self_other_eq: "(A::'a multiset) + X = A + Y \<Longrightarrow> X = Y"
  3276   by (fact add_left_imp_eq)
  3277 
  3278 lemma mset_subset_trans: "(M::'a multiset) \<subset># K \<Longrightarrow> K \<subset># N \<Longrightarrow> M \<subset># N"
  3279   by (fact subset_mset.less_trans)
  3280 
  3281 lemma multiset_inter_commute: "A \<inter># B = B \<inter># A"
  3282   by (fact subset_mset.inf.commute)
  3283 
  3284 lemma multiset_inter_assoc: "A \<inter># (B \<inter># C) = A \<inter># B \<inter># C"
  3285   by (fact subset_mset.inf.assoc [symmetric])
  3286 
  3287 lemma multiset_inter_left_commute: "A \<inter># (B \<inter># C) = B \<inter># (A \<inter># C)"
  3288   by (fact subset_mset.inf.left_commute)
  3289 
  3290 lemmas multiset_inter_ac =
  3291   multiset_inter_commute
  3292   multiset_inter_assoc
  3293   multiset_inter_left_commute
  3294 
  3295 lemma mset_le_not_refl: "\<not> M < (M::'a::preorder multiset)"
  3296   by (fact less_irrefl)
  3297 
  3298 lemma mset_le_trans: "K < M \<Longrightarrow> M < N \<Longrightarrow> K < (N::'a::preorder multiset)"
  3299   by (fact less_trans)
  3300 
  3301 lemma mset_le_not_sym: "M < N \<Longrightarrow> \<not> N < (M::'a::preorder multiset)"
  3302   by (fact less_not_sym)
  3303 
  3304 lemma mset_le_asym: "M < N \<Longrightarrow> (\<not> P \<Longrightarrow> N < (M::'a::preorder multiset)) \<Longrightarrow> P"
  3305   by (fact less_asym)
  3306 
  3307 declaration \<open>
  3308   let
  3309     fun multiset_postproc _ maybe_name all_values (T as Type (_, [elem_T])) (Const _ $ t') =
  3310           let
  3311             val (maybe_opt, ps) =
  3312               Nitpick_Model.dest_plain_fun t'
  3313               ||> op ~~
  3314               ||> map (apsnd (snd o HOLogic.dest_number))
  3315             fun elems_for t =
  3316               (case AList.lookup (op =) ps t of
  3317                 SOME n => replicate n t
  3318               | NONE => [Const (maybe_name, elem_T --> elem_T) $ t])
  3319           in
  3320             (case maps elems_for (all_values elem_T) @
  3321                  (if maybe_opt then [Const (Nitpick_Model.unrep_mixfix (), elem_T)] else []) of
  3322               [] => Const (@{const_name zero_class.zero}, T)
  3323             | ts =>
  3324                 foldl1 (fn (s, t) => Const (@{const_name add_mset}, elem_T --> T --> T) $ s $ t)
  3325                   ts)
  3326           end
  3327       | multiset_postproc _ _ _ _ t = t
  3328   in Nitpick_Model.register_term_postprocessor @{typ "'a multiset"} multiset_postproc end
  3329 \<close>
  3330 
  3331 
  3332 subsection \<open>Naive implementation using lists\<close>
  3333 
  3334 code_datatype mset
  3335 
  3336 lemma [code]: "{#} = mset []"
  3337   by simp
  3338 
  3339 lemma [code]: "add_mset x (mset xs) = mset (x # xs)"
  3340   by simp
  3341 
  3342 lemma [code]: "Multiset.is_empty (mset xs) \<longleftrightarrow> List.null xs"
  3343   by (simp add: Multiset.is_empty_def List.null_def)
  3344 
  3345 lemma union_code [code]: "mset xs + mset ys = mset (xs @ ys)"
  3346   by simp
  3347 
  3348 lemma [code]: "image_mset f (mset xs) = mset (map f xs)"
  3349   by simp
  3350 
  3351 lemma [code]: "filter_mset f (mset xs) = mset (filter f xs)"
  3352   by (simp add: mset_filter)
  3353 
  3354 lemma [code]: "mset xs - mset ys = mset (fold remove1 ys xs)"
  3355   by (rule sym, induct ys arbitrary: xs) (simp_all add: diff_add diff_right_commute diff_diff_add)
  3356 
  3357 lemma [code]:
  3358   "mset xs \<inter># mset ys =
  3359     mset (snd (fold (\<lambda>x (ys, zs).
  3360       if x \<in> set ys then (remove1 x ys, x # zs) else (ys, zs)) xs (ys, [])))"
  3361 proof -
  3362   have "\<And>zs. mset (snd (fold (\<lambda>x (ys, zs).
  3363     if x \<in> set ys then (remove1 x ys, x # zs) else (ys, zs)) xs (ys, zs))) =
  3364       (mset xs \<inter># mset ys) + mset zs"
  3365     by (induct xs arbitrary: ys)
  3366       (auto simp add: inter_add_right1 inter_add_right2 ac_simps)
  3367   then show ?thesis by simp
  3368 qed
  3369 
  3370 lemma [code]:
  3371   "mset xs \<union># mset ys =
  3372     mset (case_prod append (fold (\<lambda>x (ys, zs). (remove1 x ys, x # zs)) xs (ys, [])))"
  3373 proof -
  3374   have "\<And>zs. mset (case_prod append (fold (\<lambda>x (ys, zs). (remove1 x ys, x # zs)) xs (ys, zs))) =
  3375       (mset xs \<union># mset ys) + mset zs"
  3376     by (induct xs arbitrary: ys) (simp_all add: multiset_eq_iff)
  3377   then show ?thesis by simp
  3378 qed
  3379 
  3380 declare in_multiset_in_set [code_unfold]
  3381 
  3382 lemma [code]: "count (mset xs) x = fold (\<lambda>y. if x = y then Suc else id) xs 0"
  3383 proof -
  3384   have "\<And>n. fold (\<lambda>y. if x = y then Suc else id) xs n = count (mset xs) x + n"
  3385     by (induct xs) simp_all
  3386   then show ?thesis by simp
  3387 qed
  3388 
  3389 declare set_mset_mset [code]
  3390 
  3391 declare sorted_list_of_multiset_mset [code]
  3392 
  3393 lemma [code]: \<comment> \<open>not very efficient, but representation-ignorant!\<close>
  3394   "mset_set A = mset (sorted_list_of_set A)"
  3395   apply (cases "finite A")
  3396   apply simp_all
  3397   apply (induct A rule: finite_induct)
  3398   apply simp_all
  3399   done
  3400 
  3401 declare size_mset [code]
  3402 
  3403 fun subset_eq_mset_impl :: "'a list \<Rightarrow> 'a list \<Rightarrow> bool option" where
  3404   "subset_eq_mset_impl [] ys = Some (ys \<noteq> [])"
  3405 | "subset_eq_mset_impl (Cons x xs) ys = (case List.extract (op = x) ys of
  3406      None \<Rightarrow> None
  3407    | Some (ys1,_,ys2) \<Rightarrow> subset_eq_mset_impl xs (ys1 @ ys2))"
  3408 
  3409 lemma subset_eq_mset_impl: "(subset_eq_mset_impl xs ys = None \<longleftrightarrow> \<not> mset xs \<subseteq># mset ys) \<and>
  3410   (subset_eq_mset_impl xs ys = Some True \<longleftrightarrow> mset xs \<subset># mset ys) \<and>
  3411   (subset_eq_mset_impl xs ys = Some False \<longrightarrow> mset xs = mset ys)"
  3412 proof (induct xs arbitrary: ys)
  3413   case (Nil ys)
  3414   show ?case by (auto simp: subset_mset.zero_less_iff_neq_zero)
  3415 next
  3416   case (Cons x xs ys)
  3417   show ?case
  3418   proof (cases "List.extract (op = x) ys")
  3419     case None
  3420     hence x: "x \<notin> set ys" by (simp add: extract_None_iff)
  3421     {
  3422       assume "mset (x # xs) \<subseteq># mset ys"
  3423       from set_mset_mono[OF this] x have False by simp
  3424     } note nle = this
  3425     moreover
  3426     {
  3427       assume "mset (x # xs) \<subset># mset ys"
  3428       hence "mset (x # xs) \<subseteq># mset ys" by auto
  3429       from nle[OF this] have False .
  3430     }
  3431     ultimately show ?thesis using None by auto
  3432   next
  3433     case (Some res)
  3434     obtain ys1 y ys2 where res: "res = (ys1,y,ys2)" by (cases res, auto)
  3435     note Some = Some[unfolded res]
  3436     from extract_SomeE[OF Some] have "ys = ys1 @ x # ys2" by simp
  3437     hence id: "mset ys = add_mset x (mset (ys1 @ ys2))"
  3438       by auto
  3439     show ?thesis unfolding subset_eq_mset_impl.simps
  3440       unfolding Some option.simps split
  3441       unfolding id
  3442       using Cons[of "ys1 @ ys2"]
  3443       unfolding subset_mset_def subseteq_mset_def by auto
  3444   qed
  3445 qed
  3446 
  3447 lemma [code]: "mset xs \<subseteq># mset ys \<longleftrightarrow> subset_eq_mset_impl xs ys \<noteq> None"
  3448   using subset_eq_mset_impl[of xs ys] by (cases "subset_eq_mset_impl xs ys", auto)
  3449 
  3450 lemma [code]: "mset xs \<subset># mset ys \<longleftrightarrow> subset_eq_mset_impl xs ys = Some True"
  3451   using subset_eq_mset_impl[of xs ys] by (cases "subset_eq_mset_impl xs ys", auto)
  3452 
  3453 instantiation multiset :: (equal) equal
  3454 begin
  3455 
  3456 definition
  3457   [code del]: "HOL.equal A (B :: 'a multiset) \<longleftrightarrow> A = B"
  3458 lemma [code]: "HOL.equal (mset xs) (mset ys) \<longleftrightarrow> subset_eq_mset_impl xs ys = Some False"
  3459   unfolding equal_multiset_def
  3460   using subset_eq_mset_impl[of xs ys] by (cases "subset_eq_mset_impl xs ys", auto)
  3461 
  3462 instance
  3463   by standard (simp add: equal_multiset_def)
  3464 
  3465 end
  3466 
  3467 declare sum_mset_sum_list [code]
  3468 
  3469 lemma [code]: "prod_mset (mset xs) = fold times xs 1"
  3470 proof -
  3471   have "\<And>x. fold times xs x = prod_mset (mset xs) * x"
  3472     by (induct xs) (simp_all add: ac_simps)
  3473   then show ?thesis by simp
  3474 qed
  3475 
  3476 text \<open>
  3477   Exercise for the casual reader: add implementations for @{term "op \<le>"}
  3478   and @{term "op <"} (multiset order).
  3479 \<close>
  3480 
  3481 text \<open>Quickcheck generators\<close>
  3482 
  3483 definition (in term_syntax)
  3484   msetify :: "'a::typerep list \<times> (unit \<Rightarrow> Code_Evaluation.term)
  3485     \<Rightarrow> 'a multiset \<times> (unit \<Rightarrow> Code_Evaluation.term)" where
  3486   [code_unfold]: "msetify xs = Code_Evaluation.valtermify mset {\<cdot>} xs"
  3487 
  3488 notation fcomp (infixl "\<circ>>" 60)
  3489 notation scomp (infixl "\<circ>\<rightarrow>" 60)
  3490 
  3491 instantiation multiset :: (random) random
  3492 begin
  3493 
  3494 definition
  3495   "Quickcheck_Random.random i = Quickcheck_Random.random i \<circ>\<rightarrow> (\<lambda>xs. Pair (msetify xs))"
  3496 
  3497 instance ..
  3498 
  3499 end
  3500 
  3501 no_notation fcomp (infixl "\<circ>>" 60)
  3502 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
  3503 
  3504 instantiation multiset :: (full_exhaustive) full_exhaustive
  3505 begin
  3506 
  3507 definition full_exhaustive_multiset :: "('a multiset \<times> (unit \<Rightarrow> term) \<Rightarrow> (bool \<times> term list) option) \<Rightarrow> natural \<Rightarrow> (bool \<times> term list) option"
  3508 where
  3509   "full_exhaustive_multiset f i = Quickcheck_Exhaustive.full_exhaustive (\<lambda>xs. f (msetify xs)) i"
  3510 
  3511 instance ..
  3512 
  3513 end
  3514 
  3515 hide_const (open) msetify
  3516 
  3517 
  3518 subsection \<open>BNF setup\<close>
  3519 
  3520 definition rel_mset where
  3521   "rel_mset R X Y \<longleftrightarrow> (\<exists>xs ys. mset xs = X \<and> mset ys = Y \<and> list_all2 R xs ys)"
  3522 
  3523 lemma mset_zip_take_Cons_drop_twice:
  3524   assumes "length xs = length ys" "j \<le> length xs"
  3525   shows "mset (zip (take j xs @ x # drop j xs) (take j ys @ y # drop j ys)) =
  3526     add_mset (x,y) (mset (zip xs ys))"
  3527   using assms
  3528 proof (induct xs ys arbitrary: x y j rule: list_induct2)
  3529   case Nil
  3530   thus ?case
  3531     by simp
  3532 next
  3533   case (Cons x xs y ys)
  3534   thus ?case
  3535   proof (cases "j = 0")
  3536     case True
  3537     thus ?thesis
  3538       by simp
  3539   next
  3540     case False
  3541     then obtain k where k: "j = Suc k"
  3542       by (cases j) simp
  3543     hence "k \<le> length xs"
  3544       using Cons.prems by auto
  3545     hence "mset (zip (take k xs @ x # drop k xs) (take k ys @ y # drop k ys)) =
  3546       add_mset (x,y) (mset (zip xs ys))"
  3547       by (rule Cons.hyps(2))
  3548     thus ?thesis
  3549       unfolding k by auto
  3550   qed
  3551 qed
  3552 
  3553 lemma ex_mset_zip_left:
  3554   assumes "length xs = length ys" "mset xs' = mset xs"
  3555   shows "\<exists>ys'. length ys' = length xs' \<and> mset (zip xs' ys') = mset (zip xs ys)"
  3556 using assms
  3557 proof (induct xs ys arbitrary: xs' rule: list_induct2)
  3558   case Nil
  3559   thus ?case
  3560     by auto
  3561 next
  3562   case (Cons x xs y ys xs')
  3563   obtain j where j_len: "j < length xs'" and nth_j: "xs' ! j = x"
  3564     by (metis Cons.prems in_set_conv_nth list.set_intros(1) mset_eq_setD)
  3565 
  3566   define xsa where "xsa = take j xs' @ drop (Suc j) xs'"
  3567   have "mset xs' = {#x#} + mset xsa"
  3568     unfolding xsa_def using j_len nth_j
  3569     by (metis Cons_nth_drop_Suc union_mset_add_mset_right add_mset_remove_trivial add_diff_cancel_left'
  3570         append_take_drop_id mset.simps(2) mset_append)
  3571   hence ms_x: "mset xsa = mset xs"
  3572     by (simp add: Cons.prems)
  3573   then obtain ysa where
  3574     len_a: "length ysa = length xsa" and ms_a: "mset (zip xsa ysa) = mset (zip xs ys)"
  3575     using Cons.hyps(2) by blast
  3576 
  3577   define ys' where "ys' = take j ysa @ y # drop j ysa"
  3578   have xs': "xs' = take j xsa @ x # drop j xsa"
  3579     using ms_x j_len nth_j Cons.prems xsa_def
  3580     by (metis append_eq_append_conv append_take_drop_id diff_Suc_Suc Cons_nth_drop_Suc length_Cons
  3581       length_drop size_mset)
  3582   have j_len': "j \<le> length xsa"
  3583     using j_len xs' xsa_def
  3584     by (metis add_Suc_right append_take_drop_id length_Cons length_append less_eq_Suc_le not_less)
  3585   have "length ys' = length xs'"
  3586     unfolding ys'_def using Cons.prems len_a ms_x
  3587     by (metis add_Suc_right append_take_drop_id length_Cons length_append mset_eq_length)
  3588   moreover have "mset (zip xs' ys') = mset (zip (x # xs) (y # ys))"
  3589     unfolding xs' ys'_def
  3590     by (rule trans[OF mset_zip_take_Cons_drop_twice])
  3591       (auto simp: len_a ms_a j_len')
  3592   ultimately show ?case
  3593     by blast
  3594 qed
  3595 
  3596 lemma list_all2_reorder_left_invariance:
  3597   assumes rel: "list_all2 R xs ys" and ms_x: "mset xs' = mset xs"
  3598   shows "\<exists>ys'. list_all2 R xs' ys' \<and> mset ys' = mset ys"
  3599 proof -
  3600   have len: "length xs = length ys"
  3601     using rel list_all2_conv_all_nth by auto
  3602   obtain ys' where
  3603     len': "length xs' = length ys'" and ms_xy: "mset (zip xs' ys') = mset (zip xs ys)"
  3604     using len ms_x by (metis ex_mset_zip_left)
  3605   have "list_all2 R xs' ys'"
  3606     using assms(1) len' ms_xy unfolding list_all2_iff by (blast dest: mset_eq_setD)
  3607   moreover have "mset ys' = mset ys"
  3608     using len len' ms_xy map_snd_zip mset_map by metis
  3609   ultimately show ?thesis
  3610     by blast
  3611 qed
  3612 
  3613 lemma ex_mset: "\<exists>xs. mset xs = X"
  3614   by (induct X) (simp, metis mset.simps(2))
  3615 
  3616 inductive pred_mset :: "('a \<Rightarrow> bool) \<Rightarrow> 'a multiset \<Rightarrow> bool"
  3617 where
  3618   "pred_mset P {#}"
  3619 | "\<lbrakk>P a; pred_mset P M\<rbrakk> \<Longrightarrow> pred_mset P (add_mset a M)"
  3620 
  3621 bnf "'a multiset"
  3622   map: image_mset
  3623   sets: set_mset
  3624   bd: natLeq
  3625   wits: "{#}"
  3626   rel: rel_mset
  3627   pred: pred_mset
  3628 proof -
  3629   show "image_mset id = id"
  3630     by (rule image_mset.id)
  3631   show "image_mset (g \<circ> f) = image_mset g \<circ> image_mset f" for f g
  3632     unfolding comp_def by (rule ext) (simp add: comp_def image_mset.compositionality)
  3633   show "(\<And>z. z \<in> set_mset X \<Longrightarrow> f z = g z) \<Longrightarrow> image_mset f X = image_mset g X" for f g X
  3634     by (induct X) simp_all
  3635   show "set_mset \<circ> image_mset f = op ` f \<circ> set_mset" for f
  3636     by auto
  3637   show "card_order natLeq"
  3638     by (rule natLeq_card_order)
  3639   show "BNF_Cardinal_Arithmetic.cinfinite natLeq"
  3640     by (rule natLeq_cinfinite)
  3641   show "ordLeq3 (card_of (set_mset X)) natLeq" for X
  3642     by transfer
  3643       (auto intro!: ordLess_imp_ordLeq simp: finite_iff_ordLess_natLeq[symmetric] multiset_def)
  3644   show "rel_mset R OO rel_mset S \<le> rel_mset (R OO S)" for R S
  3645     unfolding rel_mset_def[abs_def] OO_def
  3646     apply clarify
  3647     subgoal for X Z Y xs ys' ys zs
  3648       apply (drule list_all2_reorder_left_invariance [where xs = ys' and ys = zs and xs' = ys])
  3649       apply (auto intro: list_all2_trans)
  3650       done
  3651     done
  3652   show "rel_mset R =
  3653     (\<lambda>x y. \<exists>z. set_mset z \<subseteq> {(x, y). R x y} \<and>
  3654     image_mset fst z = x \<and> image_mset snd z = y)" for R
  3655     unfolding rel_mset_def[abs_def]
  3656     apply (rule ext)+
  3657     apply safe
  3658      apply (rule_tac x = "mset (zip xs ys)" in exI;
  3659        auto simp: in_set_zip list_all2_iff mset_map[symmetric])
  3660     apply (rename_tac XY)
  3661     apply (cut_tac X = XY in ex_mset)
  3662     apply (erule exE)
  3663     apply (rename_tac xys)
  3664     apply (rule_tac x = "map fst xys" in exI)
  3665     apply (auto simp: mset_map)
  3666     apply (rule_tac x = "map snd xys" in exI)
  3667     apply (auto simp: mset_map list_all2I subset_eq zip_map_fst_snd)
  3668     done
  3669   show "z \<in> set_mset {#} \<Longrightarrow> False" for z
  3670     by auto
  3671   show "pred_mset P = (\<lambda>x. Ball (set_mset x) P)" for P
  3672   proof (intro ext iffI)
  3673     fix x
  3674     assume "pred_mset P x"
  3675     then show "Ball (set_mset x) P" by (induct pred: pred_mset; simp)
  3676   next
  3677     fix x
  3678     assume "Ball (set_mset x) P"
  3679     then show "pred_mset P x" by (induct x; auto intro: pred_mset.intros)
  3680   qed
  3681 qed
  3682 
  3683 inductive rel_mset'
  3684 where
  3685   Zero[intro]: "rel_mset' R {#} {#}"
  3686 | Plus[intro]: "\<lbrakk>R a b; rel_mset' R M N\<rbrakk> \<Longrightarrow> rel_mset' R (add_mset a M) (add_mset b N)"
  3687 
  3688 lemma rel_mset_Zero: "rel_mset R {#} {#}"
  3689 unfolding rel_mset_def Grp_def by auto
  3690 
  3691 declare multiset.count[simp]
  3692 declare Abs_multiset_inverse[simp]
  3693 declare multiset.count_inverse[simp]
  3694 declare union_preserves_multiset[simp]
  3695 
  3696 lemma rel_mset_Plus:
  3697   assumes ab: "R a b"
  3698     and MN: "rel_mset R M N"
  3699   shows "rel_mset R (add_mset a M) (add_mset b N)"
  3700 proof -
  3701   have "\<exists>ya. add_mset a (image_mset fst y) = image_mset fst ya \<and>
  3702     add_mset b (image_mset snd y) = image_mset snd ya \<and>
  3703     set_mset ya \<subseteq> {(x, y). R x y}"
  3704     if "R a b" and "set_mset y \<subseteq> {(x, y). R x y}" for y
  3705     using that by (intro exI[of _ "add_mset (a,b) y"]) auto
  3706   thus ?thesis
  3707   using assms
  3708   unfolding multiset.rel_compp_Grp Grp_def by blast
  3709 qed
  3710 
  3711 lemma rel_mset'_imp_rel_mset: "rel_mset' R M N \<Longrightarrow> rel_mset R M N"
  3712   by (induct rule: rel_mset'.induct) (auto simp: rel_mset_Zero rel_mset_Plus)
  3713 
  3714 lemma rel_mset_size: "rel_mset R M N \<Longrightarrow> size M = size N"
  3715   unfolding multiset.rel_compp_Grp Grp_def by auto
  3716 
  3717 lemma multiset_induct2[case_names empty addL addR]:
  3718   assumes empty: "P {#} {#}"
  3719     and addL: "\<And>a M N. P M N \<Longrightarrow> P (add_mset a M) N"
  3720     and addR: "\<And>a M N. P M N \<Longrightarrow> P M (add_mset a N)"
  3721   shows "P M N"
  3722 apply(induct N rule: multiset_induct)
  3723   apply(induct M rule: multiset_induct, rule empty, erule addL)
  3724   apply(induct M rule: multiset_induct, erule addR, erule addR)
  3725 done
  3726 
  3727 lemma multiset_induct2_size[consumes 1, case_names empty add]:
  3728   assumes c: "size M = size N"
  3729     and empty: "P {#} {#}"
  3730     and add: "\<And>a b M N a b. P M N \<Longrightarrow> P (add_mset a M) (add_mset b N)"
  3731   shows "P M N"
  3732   using c
  3733 proof (induct M arbitrary: N rule: measure_induct_rule[of size])
  3734   case (less M)
  3735   show ?case
  3736   proof(cases "M = {#}")
  3737     case True hence "N = {#}" using less.prems by auto
  3738     thus ?thesis using True empty by auto
  3739   next
  3740     case False then obtain M1 a where M: "M = add_mset a M1" by (metis multi_nonempty_split)
  3741     have "N \<noteq> {#}" using False less.prems by auto
  3742     then obtain N1 b where N: "N = add_mset b N1" by (metis multi_nonempty_split)
  3743     have "size M1 = size N1" using less.prems unfolding M N by auto
  3744     thus ?thesis using M N less.hyps add by auto
  3745   qed
  3746 qed
  3747 
  3748 lemma msed_map_invL:
  3749   assumes "image_mset f (add_mset a M) = N"
  3750   shows "\<exists>N1. N = add_mset (f a) N1 \<and> image_mset f M = N1"
  3751 proof -
  3752   have "f a \<in># N"
  3753     using assms multiset.set_map[of f "add_mset a M"] by auto
  3754   then obtain N1 where N: "N = add_mset (f a) N1" using multi_member_split by metis
  3755   have "image_mset f M = N1" using assms unfolding N by simp
  3756   thus ?thesis using N by blast
  3757 qed
  3758 
  3759 lemma msed_map_invR:
  3760   assumes "image_mset f M = add_mset b N"
  3761   shows "\<exists>M1 a. M = add_mset a M1 \<and> f a = b \<and> image_mset f M1 = N"
  3762 proof -
  3763   obtain a where a: "a \<in># M" and fa: "f a = b"
  3764     using multiset.set_map[of f M] unfolding assms
  3765     by (metis image_iff union_single_eq_member)
  3766   then obtain M1 where M: "M = add_mset a M1" using multi_member_split by metis
  3767   have "image_mset f M1 = N" using assms unfolding M fa[symmetric] by simp
  3768   thus ?thesis using M fa by blast
  3769 qed
  3770 
  3771 lemma msed_rel_invL:
  3772   assumes "rel_mset R (add_mset a M) N"
  3773   shows "\<exists>N1 b. N = add_mset b N1 \<and> R a b \<and> rel_mset R M N1"
  3774 proof -
  3775   obtain K where KM: "image_mset fst K = add_mset a M"
  3776     and KN: "image_mset snd K = N" and sK: "set_mset K \<subseteq> {(a, b). R a b}"
  3777     using assms
  3778     unfolding multiset.rel_compp_Grp Grp_def by auto
  3779   obtain K1 ab where K: "K = add_mset ab K1" and a: "fst ab = a"
  3780     and K1M: "image_mset fst K1 = M" using msed_map_invR[OF KM] by auto
  3781   obtain N1 where N: "N = add_mset (snd ab) N1" and K1N1: "image_mset snd K1 = N1"
  3782     using msed_map_invL[OF KN[unfolded K]] by auto
  3783   have Rab: "R a (snd ab)" using sK a unfolding K by auto
  3784   have "rel_mset R M N1" using sK K1M K1N1
  3785     unfolding K multiset.rel_compp_Grp Grp_def by auto
  3786   thus ?thesis using N Rab by auto
  3787 qed
  3788 
  3789 lemma msed_rel_invR:
  3790   assumes "rel_mset R M (add_mset b N)"
  3791   shows "\<exists>M1 a. M = add_mset a M1 \<and> R a b \<and> rel_mset R M1 N"
  3792 proof -
  3793   obtain K where KN: "image_mset snd K = add_mset b N"
  3794     and KM: "image_mset fst K = M" and sK: "set_mset K \<subseteq> {(a, b). R a b}"
  3795     using assms
  3796     unfolding multiset.rel_compp_Grp Grp_def by auto
  3797   obtain K1 ab where K: "K = add_mset ab K1" and b: "snd ab = b"
  3798     and K1N: "image_mset snd K1 = N" using msed_map_invR[OF KN] by auto
  3799   obtain M1 where M: "M = add_mset (fst ab) M1" and K1M1: "image_mset fst K1 = M1"
  3800     using msed_map_invL[OF KM[unfolded K]] by auto
  3801   have Rab: "R (fst ab) b" using sK b unfolding K by auto
  3802   have "rel_mset R M1 N" using sK K1N K1M1
  3803     unfolding K multiset.rel_compp_Grp Grp_def by auto
  3804   thus ?thesis using M Rab by auto
  3805 qed
  3806 
  3807 lemma rel_mset_imp_rel_mset':
  3808   assumes "rel_mset R M N"
  3809   shows "rel_mset' R M N"
  3810 using assms proof(induct M arbitrary: N rule: measure_induct_rule[of size])
  3811   case (less M)
  3812   have c: "size M = size N" using rel_mset_size[OF less.prems] .
  3813   show ?case
  3814   proof(cases "M = {#}")
  3815     case True hence "N = {#}" using c by simp
  3816     thus ?thesis using True rel_mset'.Zero by auto
  3817   next
  3818     case False then obtain M1 a where M: "M = add_mset a M1" by (metis multi_nonempty_split)
  3819     obtain N1 b where N: "N = add_mset b N1" and R: "R a b" and ms: "rel_mset R M1 N1"
  3820       using msed_rel_invL[OF less.prems[unfolded M]] by auto
  3821     have "rel_mset' R M1 N1" using less.hyps[of M1 N1] ms unfolding M by simp
  3822     thus ?thesis using rel_mset'.Plus[of R a b, OF R] unfolding M N by simp
  3823   qed
  3824 qed
  3825 
  3826 lemma rel_mset_rel_mset': "rel_mset R M N = rel_mset' R M N"
  3827   using rel_mset_imp_rel_mset' rel_mset'_imp_rel_mset by auto
  3828 
  3829 text \<open>The main end product for @{const rel_mset}: inductive characterization:\<close>
  3830 lemmas rel_mset_induct[case_names empty add, induct pred: rel_mset] =
  3831   rel_mset'.induct[unfolded rel_mset_rel_mset'[symmetric]]
  3832 
  3833 
  3834 subsection \<open>Size setup\<close>
  3835 
  3836 lemma multiset_size_o_map: "size_multiset g \<circ> image_mset f = size_multiset (g \<circ> f)"
  3837   apply (rule ext)
  3838   subgoal for x by (induct x) auto
  3839   done
  3840 
  3841 setup \<open>
  3842   BNF_LFP_Size.register_size_global @{type_name multiset} @{const_name size_multiset}
  3843     @{thm size_multiset_overloaded_def}
  3844     @{thms size_multiset_empty size_multiset_single size_multiset_union size_empty size_single
  3845       size_union}
  3846     @{thms multiset_size_o_map}
  3847 \<close>
  3848 
  3849 subsection \<open>Lemmas about Size\<close>
  3850 
  3851 lemma size_mset_SucE: "size A = Suc n \<Longrightarrow> (\<And>a B. A = {#a#} + B \<Longrightarrow> size B = n \<Longrightarrow> P) \<Longrightarrow> P"
  3852   by (cases A) (auto simp add: ac_simps)
  3853 
  3854 lemma size_Suc_Diff1: "x \<in># M \<Longrightarrow> Suc (size (M - {#x#})) = size M"
  3855   using arg_cong[OF insert_DiffM, of _ _ size] by simp
  3856 
  3857 lemma size_Diff_singleton: "x \<in># M \<Longrightarrow> size (M - {#x#}) = size M - 1"
  3858   by (simp add: size_Suc_Diff1 [symmetric])
  3859 
  3860 lemma size_Diff_singleton_if: "size (A - {#x#}) = (if x \<in># A then size A - 1 else size A)"
  3861   by (simp add: diff_single_trivial size_Diff_singleton)
  3862 
  3863 lemma size_Un_Int: "size A + size B = size (A \<union># B) + size (A \<inter># B)"
  3864   by (metis inter_subset_eq_union size_union subset_mset.diff_add union_diff_inter_eq_sup)
  3865 
  3866 lemma size_Un_disjoint: "A \<inter># B = {#} \<Longrightarrow> size (A \<union># B) = size A + size B"
  3867   using size_Un_Int[of A B] by simp
  3868 
  3869 lemma size_Diff_subset_Int: "size (M - M') = size M - size (M \<inter># M')"
  3870   by (metis diff_intersect_left_idem size_Diff_submset subset_mset.inf_le1)
  3871 
  3872 lemma diff_size_le_size_Diff: "size (M :: _ multiset) - size M' \<le> size (M - M')"
  3873   by (simp add: diff_le_mono2 size_Diff_subset_Int size_mset_mono)
  3874 
  3875 lemma size_Diff1_less: "x\<in># M \<Longrightarrow> size (M - {#x#}) < size M"
  3876   by (rule Suc_less_SucD) (simp add: size_Suc_Diff1)
  3877 
  3878 lemma size_Diff2_less: "x\<in># M \<Longrightarrow> y\<in># M \<Longrightarrow> size (M - {#x#} - {#y#}) < size M"
  3879   by (metis less_imp_diff_less size_Diff1_less size_Diff_subset_Int)
  3880 
  3881 lemma size_Diff1_le: "size (M - {#x#}) \<le> size M"
  3882   by (cases "x \<in># M") (simp_all add: size_Diff1_less less_imp_le diff_single_trivial)
  3883 
  3884 lemma size_psubset: "M \<subseteq># M' \<Longrightarrow> size M < size M' \<Longrightarrow> M \<subset># M'"
  3885   using less_irrefl subset_mset_def by blast
  3886 
  3887 hide_const (open) wcount
  3888 
  3889 end