src/HOL/Orderings.thy
author wenzelm
Sat Nov 04 15:24:40 2017 +0100 (19 months ago)
changeset 67003 49850a679c2c
parent 66936 cf8d8fc23891
child 67091 1393c2340eec
permissions -rw-r--r--
more robust sorted_entries;
     1 (*  Title:      HOL/Orderings.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     3 *)
     4 
     5 section \<open>Abstract orderings\<close>
     6 
     7 theory Orderings
     8 imports HOL
     9 keywords "print_orders" :: diag
    10 begin
    11 
    12 ML_file "~~/src/Provers/order.ML"
    13 ML_file "~~/src/Provers/quasi.ML"  (* FIXME unused? *)
    14 
    15 subsection \<open>Abstract ordering\<close>
    16 
    17 locale ordering =
    18   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool" (infix "\<^bold>\<le>" 50)
    19    and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool" (infix "\<^bold><" 50)
    20   assumes strict_iff_order: "a \<^bold>< b \<longleftrightarrow> a \<^bold>\<le> b \<and> a \<noteq> b"
    21   assumes refl: "a \<^bold>\<le> a" \<comment> \<open>not \<open>iff\<close>: makes problems due to multiple (dual) interpretations\<close>
    22     and antisym: "a \<^bold>\<le> b \<Longrightarrow> b \<^bold>\<le> a \<Longrightarrow> a = b"
    23     and trans: "a \<^bold>\<le> b \<Longrightarrow> b \<^bold>\<le> c \<Longrightarrow> a \<^bold>\<le> c"
    24 begin
    25 
    26 lemma strict_implies_order:
    27   "a \<^bold>< b \<Longrightarrow> a \<^bold>\<le> b"
    28   by (simp add: strict_iff_order)
    29 
    30 lemma strict_implies_not_eq:
    31   "a \<^bold>< b \<Longrightarrow> a \<noteq> b"
    32   by (simp add: strict_iff_order)
    33 
    34 lemma not_eq_order_implies_strict:
    35   "a \<noteq> b \<Longrightarrow> a \<^bold>\<le> b \<Longrightarrow> a \<^bold>< b"
    36   by (simp add: strict_iff_order)
    37 
    38 lemma order_iff_strict:
    39   "a \<^bold>\<le> b \<longleftrightarrow> a \<^bold>< b \<or> a = b"
    40   by (auto simp add: strict_iff_order refl)
    41 
    42 lemma irrefl: \<comment> \<open>not \<open>iff\<close>: makes problems due to multiple (dual) interpretations\<close>
    43   "\<not> a \<^bold>< a"
    44   by (simp add: strict_iff_order)
    45 
    46 lemma asym:
    47   "a \<^bold>< b \<Longrightarrow> b \<^bold>< a \<Longrightarrow> False"
    48   by (auto simp add: strict_iff_order intro: antisym)
    49 
    50 lemma strict_trans1:
    51   "a \<^bold>\<le> b \<Longrightarrow> b \<^bold>< c \<Longrightarrow> a \<^bold>< c"
    52   by (auto simp add: strict_iff_order intro: trans antisym)
    53 
    54 lemma strict_trans2:
    55   "a \<^bold>< b \<Longrightarrow> b \<^bold>\<le> c \<Longrightarrow> a \<^bold>< c"
    56   by (auto simp add: strict_iff_order intro: trans antisym)
    57 
    58 lemma strict_trans:
    59   "a \<^bold>< b \<Longrightarrow> b \<^bold>< c \<Longrightarrow> a \<^bold>< c"
    60   by (auto intro: strict_trans1 strict_implies_order)
    61 
    62 end
    63 
    64 text \<open>Alternative introduction rule with bias towards strict order\<close>
    65 
    66 lemma ordering_strictI:
    67   fixes less_eq (infix "\<^bold>\<le>" 50)
    68     and less (infix "\<^bold><" 50)
    69   assumes less_eq_less: "\<And>a b. a \<^bold>\<le> b \<longleftrightarrow> a \<^bold>< b \<or> a = b"
    70     assumes asym: "\<And>a b. a \<^bold>< b \<Longrightarrow> \<not> b \<^bold>< a"
    71   assumes irrefl: "\<And>a. \<not> a \<^bold>< a"
    72   assumes trans: "\<And>a b c. a \<^bold>< b \<Longrightarrow> b \<^bold>< c \<Longrightarrow> a \<^bold>< c"
    73   shows "ordering less_eq less"
    74 proof
    75   fix a b
    76   show "a \<^bold>< b \<longleftrightarrow> a \<^bold>\<le> b \<and> a \<noteq> b"
    77     by (auto simp add: less_eq_less asym irrefl)
    78 next
    79   fix a
    80   show "a \<^bold>\<le> a"
    81     by (auto simp add: less_eq_less)
    82 next
    83   fix a b c
    84   assume "a \<^bold>\<le> b" and "b \<^bold>\<le> c" then show "a \<^bold>\<le> c"
    85     by (auto simp add: less_eq_less intro: trans)
    86 next
    87   fix a b
    88   assume "a \<^bold>\<le> b" and "b \<^bold>\<le> a" then show "a = b"
    89     by (auto simp add: less_eq_less asym)
    90 qed
    91 
    92 lemma ordering_dualI:
    93   fixes less_eq (infix "\<^bold>\<le>" 50)
    94     and less (infix "\<^bold><" 50)
    95   assumes "ordering (\<lambda>a b. b \<^bold>\<le> a) (\<lambda>a b. b \<^bold>< a)"
    96   shows "ordering less_eq less"
    97 proof -
    98   from assms interpret ordering "\<lambda>a b. b \<^bold>\<le> a" "\<lambda>a b. b \<^bold>< a" .
    99   show ?thesis
   100     by standard (auto simp: strict_iff_order refl intro: antisym trans)
   101 qed
   102 
   103 locale ordering_top = ordering +
   104   fixes top :: "'a"  ("\<^bold>\<top>")
   105   assumes extremum [simp]: "a \<^bold>\<le> \<^bold>\<top>"
   106 begin
   107 
   108 lemma extremum_uniqueI:
   109   "\<^bold>\<top> \<^bold>\<le> a \<Longrightarrow> a = \<^bold>\<top>"
   110   by (rule antisym) auto
   111 
   112 lemma extremum_unique:
   113   "\<^bold>\<top> \<^bold>\<le> a \<longleftrightarrow> a = \<^bold>\<top>"
   114   by (auto intro: antisym)
   115 
   116 lemma extremum_strict [simp]:
   117   "\<not> (\<^bold>\<top> \<^bold>< a)"
   118   using extremum [of a] by (auto simp add: order_iff_strict intro: asym irrefl)
   119 
   120 lemma not_eq_extremum:
   121   "a \<noteq> \<^bold>\<top> \<longleftrightarrow> a \<^bold>< \<^bold>\<top>"
   122   by (auto simp add: order_iff_strict intro: not_eq_order_implies_strict extremum)
   123 
   124 end
   125 
   126 
   127 subsection \<open>Syntactic orders\<close>
   128 
   129 class ord =
   130   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   131     and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   132 begin
   133 
   134 notation
   135   less_eq  ("op \<le>") and
   136   less_eq  ("(_/ \<le> _)"  [51, 51] 50) and
   137   less  ("op <") and
   138   less  ("(_/ < _)"  [51, 51] 50)
   139 
   140 abbreviation (input)
   141   greater_eq  (infix "\<ge>" 50)
   142   where "x \<ge> y \<equiv> y \<le> x"
   143 
   144 abbreviation (input)
   145   greater  (infix ">" 50)
   146   where "x > y \<equiv> y < x"
   147 
   148 notation (ASCII)
   149   less_eq  ("op <=") and
   150   less_eq  ("(_/ <= _)" [51, 51] 50)
   151 
   152 notation (input)
   153   greater_eq  (infix ">=" 50)
   154 
   155 end
   156 
   157 
   158 subsection \<open>Quasi orders\<close>
   159 
   160 class preorder = ord +
   161   assumes less_le_not_le: "x < y \<longleftrightarrow> x \<le> y \<and> \<not> (y \<le> x)"
   162   and order_refl [iff]: "x \<le> x"
   163   and order_trans: "x \<le> y \<Longrightarrow> y \<le> z \<Longrightarrow> x \<le> z"
   164 begin
   165 
   166 text \<open>Reflexivity.\<close>
   167 
   168 lemma eq_refl: "x = y \<Longrightarrow> x \<le> y"
   169     \<comment> \<open>This form is useful with the classical reasoner.\<close>
   170 by (erule ssubst) (rule order_refl)
   171 
   172 lemma less_irrefl [iff]: "\<not> x < x"
   173 by (simp add: less_le_not_le)
   174 
   175 lemma less_imp_le: "x < y \<Longrightarrow> x \<le> y"
   176 by (simp add: less_le_not_le)
   177 
   178 
   179 text \<open>Asymmetry.\<close>
   180 
   181 lemma less_not_sym: "x < y \<Longrightarrow> \<not> (y < x)"
   182 by (simp add: less_le_not_le)
   183 
   184 lemma less_asym: "x < y \<Longrightarrow> (\<not> P \<Longrightarrow> y < x) \<Longrightarrow> P"
   185 by (drule less_not_sym, erule contrapos_np) simp
   186 
   187 
   188 text \<open>Transitivity.\<close>
   189 
   190 lemma less_trans: "x < y \<Longrightarrow> y < z \<Longrightarrow> x < z"
   191 by (auto simp add: less_le_not_le intro: order_trans)
   192 
   193 lemma le_less_trans: "x \<le> y \<Longrightarrow> y < z \<Longrightarrow> x < z"
   194 by (auto simp add: less_le_not_le intro: order_trans)
   195 
   196 lemma less_le_trans: "x < y \<Longrightarrow> y \<le> z \<Longrightarrow> x < z"
   197 by (auto simp add: less_le_not_le intro: order_trans)
   198 
   199 
   200 text \<open>Useful for simplification, but too risky to include by default.\<close>
   201 
   202 lemma less_imp_not_less: "x < y \<Longrightarrow> (\<not> y < x) \<longleftrightarrow> True"
   203 by (blast elim: less_asym)
   204 
   205 lemma less_imp_triv: "x < y \<Longrightarrow> (y < x \<longrightarrow> P) \<longleftrightarrow> True"
   206 by (blast elim: less_asym)
   207 
   208 
   209 text \<open>Transitivity rules for calculational reasoning\<close>
   210 
   211 lemma less_asym': "a < b \<Longrightarrow> b < a \<Longrightarrow> P"
   212 by (rule less_asym)
   213 
   214 
   215 text \<open>Dual order\<close>
   216 
   217 lemma dual_preorder:
   218   "class.preorder (op \<ge>) (op >)"
   219   by standard (auto simp add: less_le_not_le intro: order_trans)
   220 
   221 end
   222 
   223 
   224 subsection \<open>Partial orders\<close>
   225 
   226 class order = preorder +
   227   assumes antisym: "x \<le> y \<Longrightarrow> y \<le> x \<Longrightarrow> x = y"
   228 begin
   229 
   230 lemma less_le: "x < y \<longleftrightarrow> x \<le> y \<and> x \<noteq> y"
   231   by (auto simp add: less_le_not_le intro: antisym)
   232 
   233 sublocale order: ordering less_eq less + dual_order: ordering greater_eq greater
   234 proof -
   235   interpret ordering less_eq less
   236     by standard (auto intro: antisym order_trans simp add: less_le)
   237   show "ordering less_eq less"
   238     by (fact ordering_axioms)
   239   then show "ordering greater_eq greater"
   240     by (rule ordering_dualI)
   241 qed
   242 
   243 text \<open>Reflexivity.\<close>
   244 
   245 lemma le_less: "x \<le> y \<longleftrightarrow> x < y \<or> x = y"
   246     \<comment> \<open>NOT suitable for iff, since it can cause PROOF FAILED.\<close>
   247 by (fact order.order_iff_strict)
   248 
   249 lemma le_imp_less_or_eq: "x \<le> y \<Longrightarrow> x < y \<or> x = y"
   250 by (simp add: less_le)
   251 
   252 
   253 text \<open>Useful for simplification, but too risky to include by default.\<close>
   254 
   255 lemma less_imp_not_eq: "x < y \<Longrightarrow> (x = y) \<longleftrightarrow> False"
   256 by auto
   257 
   258 lemma less_imp_not_eq2: "x < y \<Longrightarrow> (y = x) \<longleftrightarrow> False"
   259 by auto
   260 
   261 
   262 text \<open>Transitivity rules for calculational reasoning\<close>
   263 
   264 lemma neq_le_trans: "a \<noteq> b \<Longrightarrow> a \<le> b \<Longrightarrow> a < b"
   265 by (fact order.not_eq_order_implies_strict)
   266 
   267 lemma le_neq_trans: "a \<le> b \<Longrightarrow> a \<noteq> b \<Longrightarrow> a < b"
   268 by (rule order.not_eq_order_implies_strict)
   269 
   270 
   271 text \<open>Asymmetry.\<close>
   272 
   273 lemma eq_iff: "x = y \<longleftrightarrow> x \<le> y \<and> y \<le> x"
   274 by (blast intro: antisym)
   275 
   276 lemma antisym_conv: "y \<le> x \<Longrightarrow> x \<le> y \<longleftrightarrow> x = y"
   277 by (blast intro: antisym)
   278 
   279 lemma less_imp_neq: "x < y \<Longrightarrow> x \<noteq> y"
   280 by (fact order.strict_implies_not_eq)
   281 
   282 
   283 text \<open>Least value operator\<close>
   284 
   285 definition (in ord)
   286   Least :: "('a \<Rightarrow> bool) \<Rightarrow> 'a" (binder "LEAST " 10) where
   287   "Least P = (THE x. P x \<and> (\<forall>y. P y \<longrightarrow> x \<le> y))"
   288 
   289 lemma Least_equality:
   290   assumes "P x"
   291     and "\<And>y. P y \<Longrightarrow> x \<le> y"
   292   shows "Least P = x"
   293 unfolding Least_def by (rule the_equality)
   294   (blast intro: assms antisym)+
   295 
   296 lemma LeastI2_order:
   297   assumes "P x"
   298     and "\<And>y. P y \<Longrightarrow> x \<le> y"
   299     and "\<And>x. P x \<Longrightarrow> \<forall>y. P y \<longrightarrow> x \<le> y \<Longrightarrow> Q x"
   300   shows "Q (Least P)"
   301 unfolding Least_def by (rule theI2)
   302   (blast intro: assms antisym)+
   303 
   304 text \<open>Greatest value operator\<close>
   305 
   306 definition Greatest :: "('a \<Rightarrow> bool) \<Rightarrow> 'a" (binder "GREATEST " 10) where
   307 "Greatest P = (THE x. P x \<and> (\<forall>y. P y \<longrightarrow> x \<ge> y))"
   308 
   309 lemma GreatestI2_order:
   310   "\<lbrakk> P x;
   311     \<And>y. P y \<Longrightarrow> x \<ge> y;
   312     \<And>x. \<lbrakk> P x; \<forall>y. P y \<longrightarrow> x \<ge> y \<rbrakk> \<Longrightarrow> Q x \<rbrakk>
   313   \<Longrightarrow> Q (Greatest P)"
   314 unfolding Greatest_def
   315 by (rule theI2) (blast intro: antisym)+
   316 
   317 lemma Greatest_equality:
   318   "\<lbrakk> P x;  \<And>y. P y \<Longrightarrow> x \<ge> y \<rbrakk> \<Longrightarrow> Greatest P = x"
   319 unfolding Greatest_def
   320 by (rule the_equality) (blast intro: antisym)+
   321 
   322 end
   323 
   324 lemma ordering_orderI:
   325   fixes less_eq (infix "\<^bold>\<le>" 50)
   326     and less (infix "\<^bold><" 50)
   327   assumes "ordering less_eq less"
   328   shows "class.order less_eq less"
   329 proof -
   330   from assms interpret ordering less_eq less .
   331   show ?thesis
   332     by standard (auto intro: antisym trans simp add: refl strict_iff_order)
   333 qed
   334 
   335 lemma order_strictI:
   336   fixes less (infix "\<sqsubset>" 50)
   337     and less_eq (infix "\<sqsubseteq>" 50)
   338   assumes "\<And>a b. a \<sqsubseteq> b \<longleftrightarrow> a \<sqsubset> b \<or> a = b"
   339     assumes "\<And>a b. a \<sqsubset> b \<Longrightarrow> \<not> b \<sqsubset> a"
   340   assumes "\<And>a. \<not> a \<sqsubset> a"
   341   assumes "\<And>a b c. a \<sqsubset> b \<Longrightarrow> b \<sqsubset> c \<Longrightarrow> a \<sqsubset> c"
   342   shows "class.order less_eq less"
   343   by (rule ordering_orderI) (rule ordering_strictI, (fact assms)+)
   344 
   345 context order
   346 begin
   347 
   348 text \<open>Dual order\<close>
   349 
   350 lemma dual_order:
   351   "class.order (op \<ge>) (op >)"
   352   using dual_order.ordering_axioms by (rule ordering_orderI)
   353 
   354 end
   355 
   356 
   357 subsection \<open>Linear (total) orders\<close>
   358 
   359 class linorder = order +
   360   assumes linear: "x \<le> y \<or> y \<le> x"
   361 begin
   362 
   363 lemma less_linear: "x < y \<or> x = y \<or> y < x"
   364 unfolding less_le using less_le linear by blast
   365 
   366 lemma le_less_linear: "x \<le> y \<or> y < x"
   367 by (simp add: le_less less_linear)
   368 
   369 lemma le_cases [case_names le ge]:
   370   "(x \<le> y \<Longrightarrow> P) \<Longrightarrow> (y \<le> x \<Longrightarrow> P) \<Longrightarrow> P"
   371 using linear by blast
   372 
   373 lemma (in linorder) le_cases3:
   374   "\<lbrakk>\<lbrakk>x \<le> y; y \<le> z\<rbrakk> \<Longrightarrow> P; \<lbrakk>y \<le> x; x \<le> z\<rbrakk> \<Longrightarrow> P; \<lbrakk>x \<le> z; z \<le> y\<rbrakk> \<Longrightarrow> P;
   375     \<lbrakk>z \<le> y; y \<le> x\<rbrakk> \<Longrightarrow> P; \<lbrakk>y \<le> z; z \<le> x\<rbrakk> \<Longrightarrow> P; \<lbrakk>z \<le> x; x \<le> y\<rbrakk> \<Longrightarrow> P\<rbrakk> \<Longrightarrow> P"
   376 by (blast intro: le_cases)
   377 
   378 lemma linorder_cases [case_names less equal greater]:
   379   "(x < y \<Longrightarrow> P) \<Longrightarrow> (x = y \<Longrightarrow> P) \<Longrightarrow> (y < x \<Longrightarrow> P) \<Longrightarrow> P"
   380 using less_linear by blast
   381 
   382 lemma linorder_wlog[case_names le sym]:
   383   "(\<And>a b. a \<le> b \<Longrightarrow> P a b) \<Longrightarrow> (\<And>a b. P b a \<Longrightarrow> P a b) \<Longrightarrow> P a b"
   384   by (cases rule: le_cases[of a b]) blast+
   385 
   386 lemma not_less: "\<not> x < y \<longleftrightarrow> y \<le> x"
   387 apply (simp add: less_le)
   388 using linear apply (blast intro: antisym)
   389 done
   390 
   391 lemma not_less_iff_gr_or_eq:
   392  "\<not>(x < y) \<longleftrightarrow> (x > y | x = y)"
   393 apply(simp add:not_less le_less)
   394 apply blast
   395 done
   396 
   397 lemma not_le: "\<not> x \<le> y \<longleftrightarrow> y < x"
   398 apply (simp add: less_le)
   399 using linear apply (blast intro: antisym)
   400 done
   401 
   402 lemma neq_iff: "x \<noteq> y \<longleftrightarrow> x < y \<or> y < x"
   403 by (cut_tac x = x and y = y in less_linear, auto)
   404 
   405 lemma neqE: "x \<noteq> y \<Longrightarrow> (x < y \<Longrightarrow> R) \<Longrightarrow> (y < x \<Longrightarrow> R) \<Longrightarrow> R"
   406 by (simp add: neq_iff) blast
   407 
   408 lemma antisym_conv1: "\<not> x < y \<Longrightarrow> x \<le> y \<longleftrightarrow> x = y"
   409 by (blast intro: antisym dest: not_less [THEN iffD1])
   410 
   411 lemma antisym_conv2: "x \<le> y \<Longrightarrow> \<not> x < y \<longleftrightarrow> x = y"
   412 by (blast intro: antisym dest: not_less [THEN iffD1])
   413 
   414 lemma antisym_conv3: "\<not> y < x \<Longrightarrow> \<not> x < y \<longleftrightarrow> x = y"
   415 by (blast intro: antisym dest: not_less [THEN iffD1])
   416 
   417 lemma leI: "\<not> x < y \<Longrightarrow> y \<le> x"
   418 unfolding not_less .
   419 
   420 lemma leD: "y \<le> x \<Longrightarrow> \<not> x < y"
   421 unfolding not_less .
   422 
   423 lemma not_le_imp_less: "\<not> y \<le> x \<Longrightarrow> x < y"
   424 unfolding not_le .
   425 
   426 lemma linorder_less_wlog[case_names less refl sym]:
   427      "\<lbrakk>\<And>a b. a < b \<Longrightarrow> P a b;  \<And>a. P a a;  \<And>a b. P b a \<Longrightarrow> P a b\<rbrakk> \<Longrightarrow> P a b"
   428   using antisym_conv3 by blast
   429 
   430 text \<open>Dual order\<close>
   431 
   432 lemma dual_linorder:
   433   "class.linorder (op \<ge>) (op >)"
   434 by (rule class.linorder.intro, rule dual_order) (unfold_locales, rule linear)
   435 
   436 end
   437 
   438 
   439 text \<open>Alternative introduction rule with bias towards strict order\<close>
   440 
   441 lemma linorder_strictI:
   442   fixes less_eq (infix "\<^bold>\<le>" 50)
   443     and less (infix "\<^bold><" 50)
   444   assumes "class.order less_eq less"
   445   assumes trichotomy: "\<And>a b. a \<^bold>< b \<or> a = b \<or> b \<^bold>< a"
   446   shows "class.linorder less_eq less"
   447 proof -
   448   interpret order less_eq less
   449     by (fact \<open>class.order less_eq less\<close>)
   450   show ?thesis
   451   proof
   452     fix a b
   453     show "a \<^bold>\<le> b \<or> b \<^bold>\<le> a"
   454       using trichotomy by (auto simp add: le_less)
   455   qed
   456 qed
   457 
   458 
   459 subsection \<open>Reasoning tools setup\<close>
   460 
   461 ML \<open>
   462 signature ORDERS =
   463 sig
   464   val print_structures: Proof.context -> unit
   465   val order_tac: Proof.context -> thm list -> int -> tactic
   466   val add_struct: string * term list -> string -> attribute
   467   val del_struct: string * term list -> attribute
   468 end;
   469 
   470 structure Orders: ORDERS =
   471 struct
   472 
   473 (* context data *)
   474 
   475 fun struct_eq ((s1: string, ts1), (s2, ts2)) =
   476   s1 = s2 andalso eq_list (op aconv) (ts1, ts2);
   477 
   478 structure Data = Generic_Data
   479 (
   480   type T = ((string * term list) * Order_Tac.less_arith) list;
   481     (* Order structures:
   482        identifier of the structure, list of operations and record of theorems
   483        needed to set up the transitivity reasoner,
   484        identifier and operations identify the structure uniquely. *)
   485   val empty = [];
   486   val extend = I;
   487   fun merge data = AList.join struct_eq (K fst) data;
   488 );
   489 
   490 fun print_structures ctxt =
   491   let
   492     val structs = Data.get (Context.Proof ctxt);
   493     fun pretty_term t = Pretty.block
   494       [Pretty.quote (Syntax.pretty_term ctxt t), Pretty.brk 1,
   495         Pretty.str "::", Pretty.brk 1,
   496         Pretty.quote (Syntax.pretty_typ ctxt (type_of t))];
   497     fun pretty_struct ((s, ts), _) = Pretty.block
   498       [Pretty.str s, Pretty.str ":", Pretty.brk 1,
   499        Pretty.enclose "(" ")" (Pretty.breaks (map pretty_term ts))];
   500   in
   501     Pretty.writeln (Pretty.big_list "order structures:" (map pretty_struct structs))
   502   end;
   503 
   504 val _ =
   505   Outer_Syntax.command @{command_keyword print_orders}
   506     "print order structures available to transitivity reasoner"
   507     (Scan.succeed (Toplevel.keep (print_structures o Toplevel.context_of)));
   508 
   509 
   510 (* tactics *)
   511 
   512 fun struct_tac ((s, ops), thms) ctxt facts =
   513   let
   514     val [eq, le, less] = ops;
   515     fun decomp thy (@{const Trueprop} $ t) =
   516           let
   517             fun excluded t =
   518               (* exclude numeric types: linear arithmetic subsumes transitivity *)
   519               let val T = type_of t
   520               in
   521                 T = HOLogic.natT orelse T = HOLogic.intT orelse T = HOLogic.realT
   522               end;
   523             fun rel (bin_op $ t1 $ t2) =
   524                   if excluded t1 then NONE
   525                   else if Pattern.matches thy (eq, bin_op) then SOME (t1, "=", t2)
   526                   else if Pattern.matches thy (le, bin_op) then SOME (t1, "<=", t2)
   527                   else if Pattern.matches thy (less, bin_op) then SOME (t1, "<", t2)
   528                   else NONE
   529               | rel _ = NONE;
   530             fun dec (Const (@{const_name Not}, _) $ t) =
   531                   (case rel t of NONE =>
   532                     NONE
   533                   | SOME (t1, rel, t2) => SOME (t1, "~" ^ rel, t2))
   534               | dec x = rel x;
   535           in dec t end
   536       | decomp _ _ = NONE;
   537   in
   538     (case s of
   539       "order" => Order_Tac.partial_tac decomp thms ctxt facts
   540     | "linorder" => Order_Tac.linear_tac decomp thms ctxt facts
   541     | _ => error ("Unknown order kind " ^ quote s ^ " encountered in transitivity reasoner"))
   542   end
   543 
   544 fun order_tac ctxt facts =
   545   FIRST' (map (fn s => CHANGED o struct_tac s ctxt facts) (Data.get (Context.Proof ctxt)));
   546 
   547 
   548 (* attributes *)
   549 
   550 fun add_struct s tag =
   551   Thm.declaration_attribute
   552     (fn thm => Data.map (AList.map_default struct_eq (s, Order_Tac.empty TrueI) (Order_Tac.update tag thm)));
   553 fun del_struct s =
   554   Thm.declaration_attribute
   555     (fn _ => Data.map (AList.delete struct_eq s));
   556 
   557 end;
   558 \<close>
   559 
   560 attribute_setup order = \<open>
   561   Scan.lift ((Args.add -- Args.name >> (fn (_, s) => SOME s) || Args.del >> K NONE) --|
   562     Args.colon (* FIXME || Scan.succeed true *) ) -- Scan.lift Args.name --
   563     Scan.repeat Args.term
   564     >> (fn ((SOME tag, n), ts) => Orders.add_struct (n, ts) tag
   565          | ((NONE, n), ts) => Orders.del_struct (n, ts))
   566 \<close> "theorems controlling transitivity reasoner"
   567 
   568 method_setup order = \<open>
   569   Scan.succeed (fn ctxt => SIMPLE_METHOD' (Orders.order_tac ctxt []))
   570 \<close> "transitivity reasoner"
   571 
   572 
   573 text \<open>Declarations to set up transitivity reasoner of partial and linear orders.\<close>
   574 
   575 context order
   576 begin
   577 
   578 (* The type constraint on @{term op =} below is necessary since the operation
   579    is not a parameter of the locale. *)
   580 
   581 declare less_irrefl [THEN notE, order add less_reflE: order "op = :: 'a \<Rightarrow> 'a \<Rightarrow> bool" "op <=" "op <"]
   582 
   583 declare order_refl  [order add le_refl: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   584 
   585 declare less_imp_le [order add less_imp_le: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   586 
   587 declare antisym [order add eqI: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   588 
   589 declare eq_refl [order add eqD1: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   590 
   591 declare sym [THEN eq_refl, order add eqD2: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   592 
   593 declare less_trans [order add less_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   594 
   595 declare less_le_trans [order add less_le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   596 
   597 declare le_less_trans [order add le_less_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   598 
   599 declare order_trans [order add le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   600 
   601 declare le_neq_trans [order add le_neq_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   602 
   603 declare neq_le_trans [order add neq_le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   604 
   605 declare less_imp_neq [order add less_imp_neq: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   606 
   607 declare eq_neq_eq_imp_neq [order add eq_neq_eq_imp_neq: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   608 
   609 declare not_sym [order add not_sym: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   610 
   611 end
   612 
   613 context linorder
   614 begin
   615 
   616 declare [[order del: order "op = :: 'a => 'a => bool" "op <=" "op <"]]
   617 
   618 declare less_irrefl [THEN notE, order add less_reflE: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   619 
   620 declare order_refl [order add le_refl: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   621 
   622 declare less_imp_le [order add less_imp_le: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   623 
   624 declare not_less [THEN iffD2, order add not_lessI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   625 
   626 declare not_le [THEN iffD2, order add not_leI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   627 
   628 declare not_less [THEN iffD1, order add not_lessD: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   629 
   630 declare not_le [THEN iffD1, order add not_leD: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   631 
   632 declare antisym [order add eqI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   633 
   634 declare eq_refl [order add eqD1: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   635 
   636 declare sym [THEN eq_refl, order add eqD2: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   637 
   638 declare less_trans [order add less_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   639 
   640 declare less_le_trans [order add less_le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   641 
   642 declare le_less_trans [order add le_less_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   643 
   644 declare order_trans [order add le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   645 
   646 declare le_neq_trans [order add le_neq_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   647 
   648 declare neq_le_trans [order add neq_le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   649 
   650 declare less_imp_neq [order add less_imp_neq: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   651 
   652 declare eq_neq_eq_imp_neq [order add eq_neq_eq_imp_neq: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   653 
   654 declare not_sym [order add not_sym: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   655 
   656 end
   657 
   658 setup \<open>
   659   map_theory_simpset (fn ctxt0 => ctxt0 addSolver
   660     mk_solver "Transitivity" (fn ctxt => Orders.order_tac ctxt (Simplifier.prems_of ctxt)))
   661   (*Adding the transitivity reasoners also as safe solvers showed a slight
   662     speed up, but the reasoning strength appears to be not higher (at least
   663     no breaking of additional proofs in the entire HOL distribution, as
   664     of 5 March 2004, was observed).*)
   665 \<close>
   666 
   667 ML \<open>
   668 local
   669   fun prp t thm = Thm.prop_of thm = t;  (* FIXME proper aconv!? *)
   670 in
   671 
   672 fun antisym_le_simproc ctxt ct =
   673   (case Thm.term_of ct of
   674     (le as Const (_, T)) $ r $ s =>
   675      (let
   676         val prems = Simplifier.prems_of ctxt;
   677         val less = Const (@{const_name less}, T);
   678         val t = HOLogic.mk_Trueprop(le $ s $ r);
   679       in
   680         (case find_first (prp t) prems of
   681           NONE =>
   682             let val t = HOLogic.mk_Trueprop(HOLogic.Not $ (less $ r $ s)) in
   683               (case find_first (prp t) prems of
   684                 NONE => NONE
   685               | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv1})))
   686              end
   687          | SOME thm => SOME (mk_meta_eq (thm RS @{thm order_class.antisym_conv})))
   688       end handle THM _ => NONE)
   689   | _ => NONE);
   690 
   691 fun antisym_less_simproc ctxt ct =
   692   (case Thm.term_of ct of
   693     NotC $ ((less as Const(_,T)) $ r $ s) =>
   694      (let
   695        val prems = Simplifier.prems_of ctxt;
   696        val le = Const (@{const_name less_eq}, T);
   697        val t = HOLogic.mk_Trueprop(le $ r $ s);
   698       in
   699         (case find_first (prp t) prems of
   700           NONE =>
   701             let val t = HOLogic.mk_Trueprop (NotC $ (less $ s $ r)) in
   702               (case find_first (prp t) prems of
   703                 NONE => NONE
   704               | SOME thm => SOME (mk_meta_eq(thm RS @{thm linorder_class.antisym_conv3})))
   705             end
   706         | SOME thm => SOME (mk_meta_eq (thm RS @{thm linorder_class.antisym_conv2})))
   707       end handle THM _ => NONE)
   708   | _ => NONE);
   709 
   710 end;
   711 \<close>
   712 
   713 simproc_setup antisym_le ("(x::'a::order) \<le> y") = "K antisym_le_simproc"
   714 simproc_setup antisym_less ("\<not> (x::'a::linorder) < y") = "K antisym_less_simproc"
   715 
   716 
   717 subsection \<open>Bounded quantifiers\<close>
   718 
   719 syntax (ASCII)
   720   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   721   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3EX _<_./ _)"  [0, 0, 10] 10)
   722   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   723   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _<=_./ _)" [0, 0, 10] 10)
   724 
   725   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3ALL _>_./ _)"  [0, 0, 10] 10)
   726   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3EX _>_./ _)"  [0, 0, 10] 10)
   727   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _>=_./ _)" [0, 0, 10] 10)
   728   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _>=_./ _)" [0, 0, 10] 10)
   729 
   730 syntax
   731   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   732   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   733   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   734   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   735 
   736   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   737   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   738   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   739   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   740 
   741 syntax (input)
   742   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3! _<_./ _)"  [0, 0, 10] 10)
   743   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3? _<_./ _)"  [0, 0, 10] 10)
   744   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3! _<=_./ _)" [0, 0, 10] 10)
   745   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3? _<=_./ _)" [0, 0, 10] 10)
   746 
   747 translations
   748   "ALL x<y. P"   =>  "ALL x. x < y \<longrightarrow> P"
   749   "EX x<y. P"    =>  "EX x. x < y \<and> P"
   750   "ALL x<=y. P"  =>  "ALL x. x <= y \<longrightarrow> P"
   751   "EX x<=y. P"   =>  "EX x. x <= y \<and> P"
   752   "ALL x>y. P"   =>  "ALL x. x > y \<longrightarrow> P"
   753   "EX x>y. P"    =>  "EX x. x > y \<and> P"
   754   "ALL x>=y. P"  =>  "ALL x. x >= y \<longrightarrow> P"
   755   "EX x>=y. P"   =>  "EX x. x >= y \<and> P"
   756 
   757 print_translation \<open>
   758 let
   759   val All_binder = Mixfix.binder_name @{const_syntax All};
   760   val Ex_binder = Mixfix.binder_name @{const_syntax Ex};
   761   val impl = @{const_syntax HOL.implies};
   762   val conj = @{const_syntax HOL.conj};
   763   val less = @{const_syntax less};
   764   val less_eq = @{const_syntax less_eq};
   765 
   766   val trans =
   767    [((All_binder, impl, less),
   768     (@{syntax_const "_All_less"}, @{syntax_const "_All_greater"})),
   769     ((All_binder, impl, less_eq),
   770     (@{syntax_const "_All_less_eq"}, @{syntax_const "_All_greater_eq"})),
   771     ((Ex_binder, conj, less),
   772     (@{syntax_const "_Ex_less"}, @{syntax_const "_Ex_greater"})),
   773     ((Ex_binder, conj, less_eq),
   774     (@{syntax_const "_Ex_less_eq"}, @{syntax_const "_Ex_greater_eq"}))];
   775 
   776   fun matches_bound v t =
   777     (case t of
   778       Const (@{syntax_const "_bound"}, _) $ Free (v', _) => v = v'
   779     | _ => false);
   780   fun contains_var v = Term.exists_subterm (fn Free (x, _) => x = v | _ => false);
   781   fun mk x c n P = Syntax.const c $ Syntax_Trans.mark_bound_body x $ n $ P;
   782 
   783   fun tr' q = (q, fn _ =>
   784     (fn [Const (@{syntax_const "_bound"}, _) $ Free (v, T),
   785         Const (c, _) $ (Const (d, _) $ t $ u) $ P] =>
   786         (case AList.lookup (op =) trans (q, c, d) of
   787           NONE => raise Match
   788         | SOME (l, g) =>
   789             if matches_bound v t andalso not (contains_var v u) then mk (v, T) l u P
   790             else if matches_bound v u andalso not (contains_var v t) then mk (v, T) g t P
   791             else raise Match)
   792       | _ => raise Match));
   793 in [tr' All_binder, tr' Ex_binder] end
   794 \<close>
   795 
   796 
   797 subsection \<open>Transitivity reasoning\<close>
   798 
   799 context ord
   800 begin
   801 
   802 lemma ord_le_eq_trans: "a \<le> b \<Longrightarrow> b = c \<Longrightarrow> a \<le> c"
   803   by (rule subst)
   804 
   805 lemma ord_eq_le_trans: "a = b \<Longrightarrow> b \<le> c \<Longrightarrow> a \<le> c"
   806   by (rule ssubst)
   807 
   808 lemma ord_less_eq_trans: "a < b \<Longrightarrow> b = c \<Longrightarrow> a < c"
   809   by (rule subst)
   810 
   811 lemma ord_eq_less_trans: "a = b \<Longrightarrow> b < c \<Longrightarrow> a < c"
   812   by (rule ssubst)
   813 
   814 end
   815 
   816 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
   817   (!!x y. x < y ==> f x < f y) ==> f a < c"
   818 proof -
   819   assume r: "!!x y. x < y ==> f x < f y"
   820   assume "a < b" hence "f a < f b" by (rule r)
   821   also assume "f b < c"
   822   finally (less_trans) show ?thesis .
   823 qed
   824 
   825 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
   826   (!!x y. x < y ==> f x < f y) ==> a < f c"
   827 proof -
   828   assume r: "!!x y. x < y ==> f x < f y"
   829   assume "a < f b"
   830   also assume "b < c" hence "f b < f c" by (rule r)
   831   finally (less_trans) show ?thesis .
   832 qed
   833 
   834 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
   835   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
   836 proof -
   837   assume r: "!!x y. x <= y ==> f x <= f y"
   838   assume "a <= b" hence "f a <= f b" by (rule r)
   839   also assume "f b < c"
   840   finally (le_less_trans) show ?thesis .
   841 qed
   842 
   843 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
   844   (!!x y. x < y ==> f x < f y) ==> a < f c"
   845 proof -
   846   assume r: "!!x y. x < y ==> f x < f y"
   847   assume "a <= f b"
   848   also assume "b < c" hence "f b < f c" by (rule r)
   849   finally (le_less_trans) show ?thesis .
   850 qed
   851 
   852 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
   853   (!!x y. x < y ==> f x < f y) ==> f a < c"
   854 proof -
   855   assume r: "!!x y. x < y ==> f x < f y"
   856   assume "a < b" hence "f a < f b" by (rule r)
   857   also assume "f b <= c"
   858   finally (less_le_trans) show ?thesis .
   859 qed
   860 
   861 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
   862   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
   863 proof -
   864   assume r: "!!x y. x <= y ==> f x <= f y"
   865   assume "a < f b"
   866   also assume "b <= c" hence "f b <= f c" by (rule r)
   867   finally (less_le_trans) show ?thesis .
   868 qed
   869 
   870 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
   871   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   872 proof -
   873   assume r: "!!x y. x <= y ==> f x <= f y"
   874   assume "a <= f b"
   875   also assume "b <= c" hence "f b <= f c" by (rule r)
   876   finally (order_trans) show ?thesis .
   877 qed
   878 
   879 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
   880   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   881 proof -
   882   assume r: "!!x y. x <= y ==> f x <= f y"
   883   assume "a <= b" hence "f a <= f b" by (rule r)
   884   also assume "f b <= c"
   885   finally (order_trans) show ?thesis .
   886 qed
   887 
   888 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
   889   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   890 proof -
   891   assume r: "!!x y. x <= y ==> f x <= f y"
   892   assume "a <= b" hence "f a <= f b" by (rule r)
   893   also assume "f b = c"
   894   finally (ord_le_eq_trans) show ?thesis .
   895 qed
   896 
   897 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
   898   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   899 proof -
   900   assume r: "!!x y. x <= y ==> f x <= f y"
   901   assume "a = f b"
   902   also assume "b <= c" hence "f b <= f c" by (rule r)
   903   finally (ord_eq_le_trans) show ?thesis .
   904 qed
   905 
   906 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
   907   (!!x y. x < y ==> f x < f y) ==> f a < c"
   908 proof -
   909   assume r: "!!x y. x < y ==> f x < f y"
   910   assume "a < b" hence "f a < f b" by (rule r)
   911   also assume "f b = c"
   912   finally (ord_less_eq_trans) show ?thesis .
   913 qed
   914 
   915 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
   916   (!!x y. x < y ==> f x < f y) ==> a < f c"
   917 proof -
   918   assume r: "!!x y. x < y ==> f x < f y"
   919   assume "a = f b"
   920   also assume "b < c" hence "f b < f c" by (rule r)
   921   finally (ord_eq_less_trans) show ?thesis .
   922 qed
   923 
   924 text \<open>
   925   Note that this list of rules is in reverse order of priorities.
   926 \<close>
   927 
   928 lemmas [trans] =
   929   order_less_subst2
   930   order_less_subst1
   931   order_le_less_subst2
   932   order_le_less_subst1
   933   order_less_le_subst2
   934   order_less_le_subst1
   935   order_subst2
   936   order_subst1
   937   ord_le_eq_subst
   938   ord_eq_le_subst
   939   ord_less_eq_subst
   940   ord_eq_less_subst
   941   forw_subst
   942   back_subst
   943   rev_mp
   944   mp
   945 
   946 lemmas (in order) [trans] =
   947   neq_le_trans
   948   le_neq_trans
   949 
   950 lemmas (in preorder) [trans] =
   951   less_trans
   952   less_asym'
   953   le_less_trans
   954   less_le_trans
   955   order_trans
   956 
   957 lemmas (in order) [trans] =
   958   antisym
   959 
   960 lemmas (in ord) [trans] =
   961   ord_le_eq_trans
   962   ord_eq_le_trans
   963   ord_less_eq_trans
   964   ord_eq_less_trans
   965 
   966 lemmas [trans] =
   967   trans
   968 
   969 lemmas order_trans_rules =
   970   order_less_subst2
   971   order_less_subst1
   972   order_le_less_subst2
   973   order_le_less_subst1
   974   order_less_le_subst2
   975   order_less_le_subst1
   976   order_subst2
   977   order_subst1
   978   ord_le_eq_subst
   979   ord_eq_le_subst
   980   ord_less_eq_subst
   981   ord_eq_less_subst
   982   forw_subst
   983   back_subst
   984   rev_mp
   985   mp
   986   neq_le_trans
   987   le_neq_trans
   988   less_trans
   989   less_asym'
   990   le_less_trans
   991   less_le_trans
   992   order_trans
   993   antisym
   994   ord_le_eq_trans
   995   ord_eq_le_trans
   996   ord_less_eq_trans
   997   ord_eq_less_trans
   998   trans
   999 
  1000 text \<open>These support proving chains of decreasing inequalities
  1001     a >= b >= c ... in Isar proofs.\<close>
  1002 
  1003 lemma xt1 [no_atp]:
  1004   "a = b ==> b > c ==> a > c"
  1005   "a > b ==> b = c ==> a > c"
  1006   "a = b ==> b >= c ==> a >= c"
  1007   "a >= b ==> b = c ==> a >= c"
  1008   "(x::'a::order) >= y ==> y >= x ==> x = y"
  1009   "(x::'a::order) >= y ==> y >= z ==> x >= z"
  1010   "(x::'a::order) > y ==> y >= z ==> x > z"
  1011   "(x::'a::order) >= y ==> y > z ==> x > z"
  1012   "(a::'a::order) > b ==> b > a ==> P"
  1013   "(x::'a::order) > y ==> y > z ==> x > z"
  1014   "(a::'a::order) >= b ==> a ~= b ==> a > b"
  1015   "(a::'a::order) ~= b ==> a >= b ==> a > b"
  1016   "a = f b ==> b > c ==> (!!x y. x > y ==> f x > f y) ==> a > f c"
  1017   "a > b ==> f b = c ==> (!!x y. x > y ==> f x > f y) ==> f a > c"
  1018   "a = f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
  1019   "a >= b ==> f b = c ==> (!! x y. x >= y ==> f x >= f y) ==> f a >= c"
  1020   by auto
  1021 
  1022 lemma xt2 [no_atp]:
  1023   "(a::'a::order) >= f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
  1024 by (subgoal_tac "f b >= f c", force, force)
  1025 
  1026 lemma xt3 [no_atp]: "(a::'a::order) >= b ==> (f b::'b::order) >= c ==>
  1027     (!!x y. x >= y ==> f x >= f y) ==> f a >= c"
  1028 by (subgoal_tac "f a >= f b", force, force)
  1029 
  1030 lemma xt4 [no_atp]: "(a::'a::order) > f b ==> (b::'b::order) >= c ==>
  1031   (!!x y. x >= y ==> f x >= f y) ==> a > f c"
  1032 by (subgoal_tac "f b >= f c", force, force)
  1033 
  1034 lemma xt5 [no_atp]: "(a::'a::order) > b ==> (f b::'b::order) >= c==>
  1035     (!!x y. x > y ==> f x > f y) ==> f a > c"
  1036 by (subgoal_tac "f a > f b", force, force)
  1037 
  1038 lemma xt6 [no_atp]: "(a::'a::order) >= f b ==> b > c ==>
  1039     (!!x y. x > y ==> f x > f y) ==> a > f c"
  1040 by (subgoal_tac "f b > f c", force, force)
  1041 
  1042 lemma xt7 [no_atp]: "(a::'a::order) >= b ==> (f b::'b::order) > c ==>
  1043     (!!x y. x >= y ==> f x >= f y) ==> f a > c"
  1044 by (subgoal_tac "f a >= f b", force, force)
  1045 
  1046 lemma xt8 [no_atp]: "(a::'a::order) > f b ==> (b::'b::order) > c ==>
  1047     (!!x y. x > y ==> f x > f y) ==> a > f c"
  1048 by (subgoal_tac "f b > f c", force, force)
  1049 
  1050 lemma xt9 [no_atp]: "(a::'a::order) > b ==> (f b::'b::order) > c ==>
  1051     (!!x y. x > y ==> f x > f y) ==> f a > c"
  1052 by (subgoal_tac "f a > f b", force, force)
  1053 
  1054 lemmas xtrans = xt1 xt2 xt3 xt4 xt5 xt6 xt7 xt8 xt9
  1055 
  1056 (*
  1057   Since "a >= b" abbreviates "b <= a", the abbreviation "..." stands
  1058   for the wrong thing in an Isar proof.
  1059 
  1060   The extra transitivity rules can be used as follows:
  1061 
  1062 lemma "(a::'a::order) > z"
  1063 proof -
  1064   have "a >= b" (is "_ >= ?rhs")
  1065     sorry
  1066   also have "?rhs >= c" (is "_ >= ?rhs")
  1067     sorry
  1068   also (xtrans) have "?rhs = d" (is "_ = ?rhs")
  1069     sorry
  1070   also (xtrans) have "?rhs >= e" (is "_ >= ?rhs")
  1071     sorry
  1072   also (xtrans) have "?rhs > f" (is "_ > ?rhs")
  1073     sorry
  1074   also (xtrans) have "?rhs > z"
  1075     sorry
  1076   finally (xtrans) show ?thesis .
  1077 qed
  1078 
  1079   Alternatively, one can use "declare xtrans [trans]" and then
  1080   leave out the "(xtrans)" above.
  1081 *)
  1082 
  1083 
  1084 subsection \<open>Monotonicity\<close>
  1085 
  1086 context order
  1087 begin
  1088 
  1089 definition mono :: "('a \<Rightarrow> 'b::order) \<Rightarrow> bool" where
  1090   "mono f \<longleftrightarrow> (\<forall>x y. x \<le> y \<longrightarrow> f x \<le> f y)"
  1091 
  1092 lemma monoI [intro?]:
  1093   fixes f :: "'a \<Rightarrow> 'b::order"
  1094   shows "(\<And>x y. x \<le> y \<Longrightarrow> f x \<le> f y) \<Longrightarrow> mono f"
  1095   unfolding mono_def by iprover
  1096 
  1097 lemma monoD [dest?]:
  1098   fixes f :: "'a \<Rightarrow> 'b::order"
  1099   shows "mono f \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1100   unfolding mono_def by iprover
  1101 
  1102 lemma monoE:
  1103   fixes f :: "'a \<Rightarrow> 'b::order"
  1104   assumes "mono f"
  1105   assumes "x \<le> y"
  1106   obtains "f x \<le> f y"
  1107 proof
  1108   from assms show "f x \<le> f y" by (simp add: mono_def)
  1109 qed
  1110 
  1111 definition antimono :: "('a \<Rightarrow> 'b::order) \<Rightarrow> bool" where
  1112   "antimono f \<longleftrightarrow> (\<forall>x y. x \<le> y \<longrightarrow> f x \<ge> f y)"
  1113 
  1114 lemma antimonoI [intro?]:
  1115   fixes f :: "'a \<Rightarrow> 'b::order"
  1116   shows "(\<And>x y. x \<le> y \<Longrightarrow> f x \<ge> f y) \<Longrightarrow> antimono f"
  1117   unfolding antimono_def by iprover
  1118 
  1119 lemma antimonoD [dest?]:
  1120   fixes f :: "'a \<Rightarrow> 'b::order"
  1121   shows "antimono f \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<ge> f y"
  1122   unfolding antimono_def by iprover
  1123 
  1124 lemma antimonoE:
  1125   fixes f :: "'a \<Rightarrow> 'b::order"
  1126   assumes "antimono f"
  1127   assumes "x \<le> y"
  1128   obtains "f x \<ge> f y"
  1129 proof
  1130   from assms show "f x \<ge> f y" by (simp add: antimono_def)
  1131 qed
  1132 
  1133 definition strict_mono :: "('a \<Rightarrow> 'b::order) \<Rightarrow> bool" where
  1134   "strict_mono f \<longleftrightarrow> (\<forall>x y. x < y \<longrightarrow> f x < f y)"
  1135 
  1136 lemma strict_monoI [intro?]:
  1137   assumes "\<And>x y. x < y \<Longrightarrow> f x < f y"
  1138   shows "strict_mono f"
  1139   using assms unfolding strict_mono_def by auto
  1140 
  1141 lemma strict_monoD [dest?]:
  1142   "strict_mono f \<Longrightarrow> x < y \<Longrightarrow> f x < f y"
  1143   unfolding strict_mono_def by auto
  1144 
  1145 lemma strict_mono_mono [dest?]:
  1146   assumes "strict_mono f"
  1147   shows "mono f"
  1148 proof (rule monoI)
  1149   fix x y
  1150   assume "x \<le> y"
  1151   show "f x \<le> f y"
  1152   proof (cases "x = y")
  1153     case True then show ?thesis by simp
  1154   next
  1155     case False with \<open>x \<le> y\<close> have "x < y" by simp
  1156     with assms strict_monoD have "f x < f y" by auto
  1157     then show ?thesis by simp
  1158   qed
  1159 qed
  1160 
  1161 end
  1162 
  1163 context linorder
  1164 begin
  1165 
  1166 lemma mono_invE:
  1167   fixes f :: "'a \<Rightarrow> 'b::order"
  1168   assumes "mono f"
  1169   assumes "f x < f y"
  1170   obtains "x \<le> y"
  1171 proof
  1172   show "x \<le> y"
  1173   proof (rule ccontr)
  1174     assume "\<not> x \<le> y"
  1175     then have "y \<le> x" by simp
  1176     with \<open>mono f\<close> obtain "f y \<le> f x" by (rule monoE)
  1177     with \<open>f x < f y\<close> show False by simp
  1178   qed
  1179 qed
  1180 
  1181 lemma mono_strict_invE:
  1182   fixes f :: "'a \<Rightarrow> 'b::order"
  1183   assumes "mono f"
  1184   assumes "f x < f y"
  1185   obtains "x < y"
  1186 proof
  1187   show "x < y"
  1188   proof (rule ccontr)
  1189     assume "\<not> x < y"
  1190     then have "y \<le> x" by simp
  1191     with \<open>mono f\<close> obtain "f y \<le> f x" by (rule monoE)
  1192     with \<open>f x < f y\<close> show False by simp
  1193   qed
  1194 qed
  1195 
  1196 lemma strict_mono_eq:
  1197   assumes "strict_mono f"
  1198   shows "f x = f y \<longleftrightarrow> x = y"
  1199 proof
  1200   assume "f x = f y"
  1201   show "x = y" proof (cases x y rule: linorder_cases)
  1202     case less with assms strict_monoD have "f x < f y" by auto
  1203     with \<open>f x = f y\<close> show ?thesis by simp
  1204   next
  1205     case equal then show ?thesis .
  1206   next
  1207     case greater with assms strict_monoD have "f y < f x" by auto
  1208     with \<open>f x = f y\<close> show ?thesis by simp
  1209   qed
  1210 qed simp
  1211 
  1212 lemma strict_mono_less_eq:
  1213   assumes "strict_mono f"
  1214   shows "f x \<le> f y \<longleftrightarrow> x \<le> y"
  1215 proof
  1216   assume "x \<le> y"
  1217   with assms strict_mono_mono monoD show "f x \<le> f y" by auto
  1218 next
  1219   assume "f x \<le> f y"
  1220   show "x \<le> y" proof (rule ccontr)
  1221     assume "\<not> x \<le> y" then have "y < x" by simp
  1222     with assms strict_monoD have "f y < f x" by auto
  1223     with \<open>f x \<le> f y\<close> show False by simp
  1224   qed
  1225 qed
  1226 
  1227 lemma strict_mono_less:
  1228   assumes "strict_mono f"
  1229   shows "f x < f y \<longleftrightarrow> x < y"
  1230   using assms
  1231     by (auto simp add: less_le Orderings.less_le strict_mono_eq strict_mono_less_eq)
  1232 
  1233 end
  1234 
  1235 
  1236 subsection \<open>min and max -- fundamental\<close>
  1237 
  1238 definition (in ord) min :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
  1239   "min a b = (if a \<le> b then a else b)"
  1240 
  1241 definition (in ord) max :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
  1242   "max a b = (if a \<le> b then b else a)"
  1243 
  1244 lemma min_absorb1: "x \<le> y \<Longrightarrow> min x y = x"
  1245   by (simp add: min_def)
  1246 
  1247 lemma max_absorb2: "x \<le> y \<Longrightarrow> max x y = y"
  1248   by (simp add: max_def)
  1249 
  1250 lemma min_absorb2: "(y::'a::order) \<le> x \<Longrightarrow> min x y = y"
  1251   by (simp add:min_def)
  1252 
  1253 lemma max_absorb1: "(y::'a::order) \<le> x \<Longrightarrow> max x y = x"
  1254   by (simp add: max_def)
  1255 
  1256 lemma max_min_same [simp]:
  1257   fixes x y :: "'a :: linorder"
  1258   shows "max x (min x y) = x" "max (min x y) x = x" "max (min x y) y = y" "max y (min x y) = y"
  1259 by(auto simp add: max_def min_def)
  1260 
  1261 
  1262 subsection \<open>(Unique) top and bottom elements\<close>
  1263 
  1264 class bot =
  1265   fixes bot :: 'a ("\<bottom>")
  1266 
  1267 class order_bot = order + bot +
  1268   assumes bot_least: "\<bottom> \<le> a"
  1269 begin
  1270 
  1271 sublocale bot: ordering_top greater_eq greater bot
  1272   by standard (fact bot_least)
  1273 
  1274 lemma le_bot:
  1275   "a \<le> \<bottom> \<Longrightarrow> a = \<bottom>"
  1276   by (fact bot.extremum_uniqueI)
  1277 
  1278 lemma bot_unique:
  1279   "a \<le> \<bottom> \<longleftrightarrow> a = \<bottom>"
  1280   by (fact bot.extremum_unique)
  1281 
  1282 lemma not_less_bot:
  1283   "\<not> a < \<bottom>"
  1284   by (fact bot.extremum_strict)
  1285 
  1286 lemma bot_less:
  1287   "a \<noteq> \<bottom> \<longleftrightarrow> \<bottom> < a"
  1288   by (fact bot.not_eq_extremum)
  1289 
  1290 end
  1291 
  1292 class top =
  1293   fixes top :: 'a ("\<top>")
  1294 
  1295 class order_top = order + top +
  1296   assumes top_greatest: "a \<le> \<top>"
  1297 begin
  1298 
  1299 sublocale top: ordering_top less_eq less top
  1300   by standard (fact top_greatest)
  1301 
  1302 lemma top_le:
  1303   "\<top> \<le> a \<Longrightarrow> a = \<top>"
  1304   by (fact top.extremum_uniqueI)
  1305 
  1306 lemma top_unique:
  1307   "\<top> \<le> a \<longleftrightarrow> a = \<top>"
  1308   by (fact top.extremum_unique)
  1309 
  1310 lemma not_top_less:
  1311   "\<not> \<top> < a"
  1312   by (fact top.extremum_strict)
  1313 
  1314 lemma less_top:
  1315   "a \<noteq> \<top> \<longleftrightarrow> a < \<top>"
  1316   by (fact top.not_eq_extremum)
  1317 
  1318 end
  1319 
  1320 
  1321 subsection \<open>Dense orders\<close>
  1322 
  1323 class dense_order = order +
  1324   assumes dense: "x < y \<Longrightarrow> (\<exists>z. x < z \<and> z < y)"
  1325 
  1326 class dense_linorder = linorder + dense_order
  1327 begin
  1328 
  1329 lemma dense_le:
  1330   fixes y z :: 'a
  1331   assumes "\<And>x. x < y \<Longrightarrow> x \<le> z"
  1332   shows "y \<le> z"
  1333 proof (rule ccontr)
  1334   assume "\<not> ?thesis"
  1335   hence "z < y" by simp
  1336   from dense[OF this]
  1337   obtain x where "x < y" and "z < x" by safe
  1338   moreover have "x \<le> z" using assms[OF \<open>x < y\<close>] .
  1339   ultimately show False by auto
  1340 qed
  1341 
  1342 lemma dense_le_bounded:
  1343   fixes x y z :: 'a
  1344   assumes "x < y"
  1345   assumes *: "\<And>w. \<lbrakk> x < w ; w < y \<rbrakk> \<Longrightarrow> w \<le> z"
  1346   shows "y \<le> z"
  1347 proof (rule dense_le)
  1348   fix w assume "w < y"
  1349   from dense[OF \<open>x < y\<close>] obtain u where "x < u" "u < y" by safe
  1350   from linear[of u w]
  1351   show "w \<le> z"
  1352   proof (rule disjE)
  1353     assume "u \<le> w"
  1354     from less_le_trans[OF \<open>x < u\<close> \<open>u \<le> w\<close>] \<open>w < y\<close>
  1355     show "w \<le> z" by (rule *)
  1356   next
  1357     assume "w \<le> u"
  1358     from \<open>w \<le> u\<close> *[OF \<open>x < u\<close> \<open>u < y\<close>]
  1359     show "w \<le> z" by (rule order_trans)
  1360   qed
  1361 qed
  1362 
  1363 lemma dense_ge:
  1364   fixes y z :: 'a
  1365   assumes "\<And>x. z < x \<Longrightarrow> y \<le> x"
  1366   shows "y \<le> z"
  1367 proof (rule ccontr)
  1368   assume "\<not> ?thesis"
  1369   hence "z < y" by simp
  1370   from dense[OF this]
  1371   obtain x where "x < y" and "z < x" by safe
  1372   moreover have "y \<le> x" using assms[OF \<open>z < x\<close>] .
  1373   ultimately show False by auto
  1374 qed
  1375 
  1376 lemma dense_ge_bounded:
  1377   fixes x y z :: 'a
  1378   assumes "z < x"
  1379   assumes *: "\<And>w. \<lbrakk> z < w ; w < x \<rbrakk> \<Longrightarrow> y \<le> w"
  1380   shows "y \<le> z"
  1381 proof (rule dense_ge)
  1382   fix w assume "z < w"
  1383   from dense[OF \<open>z < x\<close>] obtain u where "z < u" "u < x" by safe
  1384   from linear[of u w]
  1385   show "y \<le> w"
  1386   proof (rule disjE)
  1387     assume "w \<le> u"
  1388     from \<open>z < w\<close> le_less_trans[OF \<open>w \<le> u\<close> \<open>u < x\<close>]
  1389     show "y \<le> w" by (rule *)
  1390   next
  1391     assume "u \<le> w"
  1392     from *[OF \<open>z < u\<close> \<open>u < x\<close>] \<open>u \<le> w\<close>
  1393     show "y \<le> w" by (rule order_trans)
  1394   qed
  1395 qed
  1396 
  1397 end
  1398 
  1399 class no_top = order +
  1400   assumes gt_ex: "\<exists>y. x < y"
  1401 
  1402 class no_bot = order +
  1403   assumes lt_ex: "\<exists>y. y < x"
  1404 
  1405 class unbounded_dense_linorder = dense_linorder + no_top + no_bot
  1406 
  1407 
  1408 subsection \<open>Wellorders\<close>
  1409 
  1410 class wellorder = linorder +
  1411   assumes less_induct [case_names less]: "(\<And>x. (\<And>y. y < x \<Longrightarrow> P y) \<Longrightarrow> P x) \<Longrightarrow> P a"
  1412 begin
  1413 
  1414 lemma wellorder_Least_lemma:
  1415   fixes k :: 'a
  1416   assumes "P k"
  1417   shows LeastI: "P (LEAST x. P x)" and Least_le: "(LEAST x. P x) \<le> k"
  1418 proof -
  1419   have "P (LEAST x. P x) \<and> (LEAST x. P x) \<le> k"
  1420   using assms proof (induct k rule: less_induct)
  1421     case (less x) then have "P x" by simp
  1422     show ?case proof (rule classical)
  1423       assume assm: "\<not> (P (LEAST a. P a) \<and> (LEAST a. P a) \<le> x)"
  1424       have "\<And>y. P y \<Longrightarrow> x \<le> y"
  1425       proof (rule classical)
  1426         fix y
  1427         assume "P y" and "\<not> x \<le> y"
  1428         with less have "P (LEAST a. P a)" and "(LEAST a. P a) \<le> y"
  1429           by (auto simp add: not_le)
  1430         with assm have "x < (LEAST a. P a)" and "(LEAST a. P a) \<le> y"
  1431           by auto
  1432         then show "x \<le> y" by auto
  1433       qed
  1434       with \<open>P x\<close> have Least: "(LEAST a. P a) = x"
  1435         by (rule Least_equality)
  1436       with \<open>P x\<close> show ?thesis by simp
  1437     qed
  1438   qed
  1439   then show "P (LEAST x. P x)" and "(LEAST x. P x) \<le> k" by auto
  1440 qed
  1441 
  1442 \<comment> "The following 3 lemmas are due to Brian Huffman"
  1443 lemma LeastI_ex: "\<exists>x. P x \<Longrightarrow> P (Least P)"
  1444   by (erule exE) (erule LeastI)
  1445 
  1446 lemma LeastI2:
  1447   "P a \<Longrightarrow> (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> Q (Least P)"
  1448   by (blast intro: LeastI)
  1449 
  1450 lemma LeastI2_ex:
  1451   "\<exists>a. P a \<Longrightarrow> (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> Q (Least P)"
  1452   by (blast intro: LeastI_ex)
  1453 
  1454 lemma LeastI2_wellorder:
  1455   assumes "P a"
  1456   and "\<And>a. \<lbrakk> P a; \<forall>b. P b \<longrightarrow> a \<le> b \<rbrakk> \<Longrightarrow> Q a"
  1457   shows "Q (Least P)"
  1458 proof (rule LeastI2_order)
  1459   show "P (Least P)" using \<open>P a\<close> by (rule LeastI)
  1460 next
  1461   fix y assume "P y" thus "Least P \<le> y" by (rule Least_le)
  1462 next
  1463   fix x assume "P x" "\<forall>y. P y \<longrightarrow> x \<le> y" thus "Q x" by (rule assms(2))
  1464 qed
  1465 
  1466 lemma LeastI2_wellorder_ex:
  1467   assumes "\<exists>x. P x"
  1468   and "\<And>a. \<lbrakk> P a; \<forall>b. P b \<longrightarrow> a \<le> b \<rbrakk> \<Longrightarrow> Q a"
  1469   shows "Q (Least P)"
  1470 using assms by clarify (blast intro!: LeastI2_wellorder)
  1471 
  1472 lemma not_less_Least: "k < (LEAST x. P x) \<Longrightarrow> \<not> P k"
  1473 apply (simp add: not_le [symmetric])
  1474 apply (erule contrapos_nn)
  1475 apply (erule Least_le)
  1476 done
  1477 
  1478 lemma exists_least_iff: "(\<exists>n. P n) \<longleftrightarrow> (\<exists>n. P n \<and> (\<forall>m < n. \<not> P m))" (is "?lhs \<longleftrightarrow> ?rhs")
  1479 proof
  1480   assume ?rhs thus ?lhs by blast
  1481 next
  1482   assume H: ?lhs then obtain n where n: "P n" by blast
  1483   let ?x = "Least P"
  1484   { fix m assume m: "m < ?x"
  1485     from not_less_Least[OF m] have "\<not> P m" . }
  1486   with LeastI_ex[OF H] show ?rhs by blast
  1487 qed
  1488 
  1489 end
  1490 
  1491 
  1492 subsection \<open>Order on @{typ bool}\<close>
  1493 
  1494 instantiation bool :: "{order_bot, order_top, linorder}"
  1495 begin
  1496 
  1497 definition
  1498   le_bool_def [simp]: "P \<le> Q \<longleftrightarrow> P \<longrightarrow> Q"
  1499 
  1500 definition
  1501   [simp]: "(P::bool) < Q \<longleftrightarrow> \<not> P \<and> Q"
  1502 
  1503 definition
  1504   [simp]: "\<bottom> \<longleftrightarrow> False"
  1505 
  1506 definition
  1507   [simp]: "\<top> \<longleftrightarrow> True"
  1508 
  1509 instance proof
  1510 qed auto
  1511 
  1512 end
  1513 
  1514 lemma le_boolI: "(P \<Longrightarrow> Q) \<Longrightarrow> P \<le> Q"
  1515   by simp
  1516 
  1517 lemma le_boolI': "P \<longrightarrow> Q \<Longrightarrow> P \<le> Q"
  1518   by simp
  1519 
  1520 lemma le_boolE: "P \<le> Q \<Longrightarrow> P \<Longrightarrow> (Q \<Longrightarrow> R) \<Longrightarrow> R"
  1521   by simp
  1522 
  1523 lemma le_boolD: "P \<le> Q \<Longrightarrow> P \<longrightarrow> Q"
  1524   by simp
  1525 
  1526 lemma bot_boolE: "\<bottom> \<Longrightarrow> P"
  1527   by simp
  1528 
  1529 lemma top_boolI: \<top>
  1530   by simp
  1531 
  1532 lemma [code]:
  1533   "False \<le> b \<longleftrightarrow> True"
  1534   "True \<le> b \<longleftrightarrow> b"
  1535   "False < b \<longleftrightarrow> b"
  1536   "True < b \<longleftrightarrow> False"
  1537   by simp_all
  1538 
  1539 
  1540 subsection \<open>Order on @{typ "_ \<Rightarrow> _"}\<close>
  1541 
  1542 instantiation "fun" :: (type, ord) ord
  1543 begin
  1544 
  1545 definition
  1546   le_fun_def: "f \<le> g \<longleftrightarrow> (\<forall>x. f x \<le> g x)"
  1547 
  1548 definition
  1549   "(f::'a \<Rightarrow> 'b) < g \<longleftrightarrow> f \<le> g \<and> \<not> (g \<le> f)"
  1550 
  1551 instance ..
  1552 
  1553 end
  1554 
  1555 instance "fun" :: (type, preorder) preorder proof
  1556 qed (auto simp add: le_fun_def less_fun_def
  1557   intro: order_trans antisym)
  1558 
  1559 instance "fun" :: (type, order) order proof
  1560 qed (auto simp add: le_fun_def intro: antisym)
  1561 
  1562 instantiation "fun" :: (type, bot) bot
  1563 begin
  1564 
  1565 definition
  1566   "\<bottom> = (\<lambda>x. \<bottom>)"
  1567 
  1568 instance ..
  1569 
  1570 end
  1571 
  1572 instantiation "fun" :: (type, order_bot) order_bot
  1573 begin
  1574 
  1575 lemma bot_apply [simp, code]:
  1576   "\<bottom> x = \<bottom>"
  1577   by (simp add: bot_fun_def)
  1578 
  1579 instance proof
  1580 qed (simp add: le_fun_def)
  1581 
  1582 end
  1583 
  1584 instantiation "fun" :: (type, top) top
  1585 begin
  1586 
  1587 definition
  1588   [no_atp]: "\<top> = (\<lambda>x. \<top>)"
  1589 
  1590 instance ..
  1591 
  1592 end
  1593 
  1594 instantiation "fun" :: (type, order_top) order_top
  1595 begin
  1596 
  1597 lemma top_apply [simp, code]:
  1598   "\<top> x = \<top>"
  1599   by (simp add: top_fun_def)
  1600 
  1601 instance proof
  1602 qed (simp add: le_fun_def)
  1603 
  1604 end
  1605 
  1606 lemma le_funI: "(\<And>x. f x \<le> g x) \<Longrightarrow> f \<le> g"
  1607   unfolding le_fun_def by simp
  1608 
  1609 lemma le_funE: "f \<le> g \<Longrightarrow> (f x \<le> g x \<Longrightarrow> P) \<Longrightarrow> P"
  1610   unfolding le_fun_def by simp
  1611 
  1612 lemma le_funD: "f \<le> g \<Longrightarrow> f x \<le> g x"
  1613   by (rule le_funE)
  1614 
  1615 lemma mono_compose: "mono Q \<Longrightarrow> mono (\<lambda>i x. Q i (f x))"
  1616   unfolding mono_def le_fun_def by auto
  1617 
  1618 
  1619 subsection \<open>Order on unary and binary predicates\<close>
  1620 
  1621 lemma predicate1I:
  1622   assumes PQ: "\<And>x. P x \<Longrightarrow> Q x"
  1623   shows "P \<le> Q"
  1624   apply (rule le_funI)
  1625   apply (rule le_boolI)
  1626   apply (rule PQ)
  1627   apply assumption
  1628   done
  1629 
  1630 lemma predicate1D:
  1631   "P \<le> Q \<Longrightarrow> P x \<Longrightarrow> Q x"
  1632   apply (erule le_funE)
  1633   apply (erule le_boolE)
  1634   apply assumption+
  1635   done
  1636 
  1637 lemma rev_predicate1D:
  1638   "P x \<Longrightarrow> P \<le> Q \<Longrightarrow> Q x"
  1639   by (rule predicate1D)
  1640 
  1641 lemma predicate2I:
  1642   assumes PQ: "\<And>x y. P x y \<Longrightarrow> Q x y"
  1643   shows "P \<le> Q"
  1644   apply (rule le_funI)+
  1645   apply (rule le_boolI)
  1646   apply (rule PQ)
  1647   apply assumption
  1648   done
  1649 
  1650 lemma predicate2D:
  1651   "P \<le> Q \<Longrightarrow> P x y \<Longrightarrow> Q x y"
  1652   apply (erule le_funE)+
  1653   apply (erule le_boolE)
  1654   apply assumption+
  1655   done
  1656 
  1657 lemma rev_predicate2D:
  1658   "P x y \<Longrightarrow> P \<le> Q \<Longrightarrow> Q x y"
  1659   by (rule predicate2D)
  1660 
  1661 lemma bot1E [no_atp]: "\<bottom> x \<Longrightarrow> P"
  1662   by (simp add: bot_fun_def)
  1663 
  1664 lemma bot2E: "\<bottom> x y \<Longrightarrow> P"
  1665   by (simp add: bot_fun_def)
  1666 
  1667 lemma top1I: "\<top> x"
  1668   by (simp add: top_fun_def)
  1669 
  1670 lemma top2I: "\<top> x y"
  1671   by (simp add: top_fun_def)
  1672 
  1673 
  1674 subsection \<open>Name duplicates\<close>
  1675 
  1676 lemmas order_eq_refl = preorder_class.eq_refl
  1677 lemmas order_less_irrefl = preorder_class.less_irrefl
  1678 lemmas order_less_imp_le = preorder_class.less_imp_le
  1679 lemmas order_less_not_sym = preorder_class.less_not_sym
  1680 lemmas order_less_asym = preorder_class.less_asym
  1681 lemmas order_less_trans = preorder_class.less_trans
  1682 lemmas order_le_less_trans = preorder_class.le_less_trans
  1683 lemmas order_less_le_trans = preorder_class.less_le_trans
  1684 lemmas order_less_imp_not_less = preorder_class.less_imp_not_less
  1685 lemmas order_less_imp_triv = preorder_class.less_imp_triv
  1686 lemmas order_less_asym' = preorder_class.less_asym'
  1687 
  1688 lemmas order_less_le = order_class.less_le
  1689 lemmas order_le_less = order_class.le_less
  1690 lemmas order_le_imp_less_or_eq = order_class.le_imp_less_or_eq
  1691 lemmas order_less_imp_not_eq = order_class.less_imp_not_eq
  1692 lemmas order_less_imp_not_eq2 = order_class.less_imp_not_eq2
  1693 lemmas order_neq_le_trans = order_class.neq_le_trans
  1694 lemmas order_le_neq_trans = order_class.le_neq_trans
  1695 lemmas order_antisym = order_class.antisym
  1696 lemmas order_eq_iff = order_class.eq_iff
  1697 lemmas order_antisym_conv = order_class.antisym_conv
  1698 
  1699 lemmas linorder_linear = linorder_class.linear
  1700 lemmas linorder_less_linear = linorder_class.less_linear
  1701 lemmas linorder_le_less_linear = linorder_class.le_less_linear
  1702 lemmas linorder_le_cases = linorder_class.le_cases
  1703 lemmas linorder_not_less = linorder_class.not_less
  1704 lemmas linorder_not_le = linorder_class.not_le
  1705 lemmas linorder_neq_iff = linorder_class.neq_iff
  1706 lemmas linorder_neqE = linorder_class.neqE
  1707 lemmas linorder_antisym_conv1 = linorder_class.antisym_conv1
  1708 lemmas linorder_antisym_conv2 = linorder_class.antisym_conv2
  1709 lemmas linorder_antisym_conv3 = linorder_class.antisym_conv3
  1710 
  1711 end