src/HOL/Predicate.thy
author wenzelm
Sat Nov 04 15:24:40 2017 +0100 (19 months ago)
changeset 67003 49850a679c2c
parent 66251 cd935b7cb3fb
child 67091 1393c2340eec
permissions -rw-r--r--
more robust sorted_entries;
     1 (*  Title:      HOL/Predicate.thy
     2     Author:     Lukas Bulwahn and Florian Haftmann, TU Muenchen
     3 *)
     4 
     5 section \<open>Predicates as enumerations\<close>
     6 
     7 theory Predicate
     8 imports String
     9 begin
    10 
    11 subsection \<open>The type of predicate enumerations (a monad)\<close>
    12 
    13 datatype (plugins only: extraction) (dead 'a) pred = Pred (eval: "'a \<Rightarrow> bool")
    14 
    15 lemma pred_eqI:
    16   "(\<And>w. eval P w \<longleftrightarrow> eval Q w) \<Longrightarrow> P = Q"
    17   by (cases P, cases Q) (auto simp add: fun_eq_iff)
    18 
    19 lemma pred_eq_iff:
    20   "P = Q \<Longrightarrow> (\<And>w. eval P w \<longleftrightarrow> eval Q w)"
    21   by (simp add: pred_eqI)
    22 
    23 instantiation pred :: (type) complete_lattice
    24 begin
    25 
    26 definition
    27   "P \<le> Q \<longleftrightarrow> eval P \<le> eval Q"
    28 
    29 definition
    30   "P < Q \<longleftrightarrow> eval P < eval Q"
    31 
    32 definition
    33   "\<bottom> = Pred \<bottom>"
    34 
    35 lemma eval_bot [simp]:
    36   "eval \<bottom>  = \<bottom>"
    37   by (simp add: bot_pred_def)
    38 
    39 definition
    40   "\<top> = Pred \<top>"
    41 
    42 lemma eval_top [simp]:
    43   "eval \<top>  = \<top>"
    44   by (simp add: top_pred_def)
    45 
    46 definition
    47   "P \<sqinter> Q = Pred (eval P \<sqinter> eval Q)"
    48 
    49 lemma eval_inf [simp]:
    50   "eval (P \<sqinter> Q) = eval P \<sqinter> eval Q"
    51   by (simp add: inf_pred_def)
    52 
    53 definition
    54   "P \<squnion> Q = Pred (eval P \<squnion> eval Q)"
    55 
    56 lemma eval_sup [simp]:
    57   "eval (P \<squnion> Q) = eval P \<squnion> eval Q"
    58   by (simp add: sup_pred_def)
    59 
    60 definition
    61   "\<Sqinter>A = Pred (INFIMUM A eval)"
    62 
    63 lemma eval_Inf [simp]:
    64   "eval (\<Sqinter>A) = INFIMUM A eval"
    65   by (simp add: Inf_pred_def)
    66 
    67 definition
    68   "\<Squnion>A = Pred (SUPREMUM A eval)"
    69 
    70 lemma eval_Sup [simp]:
    71   "eval (\<Squnion>A) = SUPREMUM A eval"
    72   by (simp add: Sup_pred_def)
    73 
    74 instance proof
    75 qed (auto intro!: pred_eqI simp add: less_eq_pred_def less_pred_def le_fun_def less_fun_def)
    76 
    77 end
    78 
    79 lemma eval_INF [simp]:
    80   "eval (INFIMUM A f) = INFIMUM A (eval \<circ> f)"
    81   using eval_Inf [of "f ` A"] by simp
    82 
    83 lemma eval_SUP [simp]:
    84   "eval (SUPREMUM A f) = SUPREMUM A (eval \<circ> f)"
    85   using eval_Sup [of "f ` A"] by simp
    86 
    87 instantiation pred :: (type) complete_boolean_algebra
    88 begin
    89 
    90 definition
    91   "- P = Pred (- eval P)"
    92 
    93 lemma eval_compl [simp]:
    94   "eval (- P) = - eval P"
    95   by (simp add: uminus_pred_def)
    96 
    97 definition
    98   "P - Q = Pred (eval P - eval Q)"
    99 
   100 lemma eval_minus [simp]:
   101   "eval (P - Q) = eval P - eval Q"
   102   by (simp add: minus_pred_def)
   103 
   104 instance proof
   105 qed (auto intro!: pred_eqI)
   106 
   107 end
   108 
   109 definition single :: "'a \<Rightarrow> 'a pred" where
   110   "single x = Pred ((op =) x)"
   111 
   112 lemma eval_single [simp]:
   113   "eval (single x) = (op =) x"
   114   by (simp add: single_def)
   115 
   116 definition bind :: "'a pred \<Rightarrow> ('a \<Rightarrow> 'b pred) \<Rightarrow> 'b pred" (infixl "\<bind>" 70) where
   117   "P \<bind> f = (SUPREMUM {x. eval P x} f)"
   118 
   119 lemma eval_bind [simp]:
   120   "eval (P \<bind> f) = eval (SUPREMUM {x. eval P x} f)"
   121   by (simp add: bind_def)
   122 
   123 lemma bind_bind:
   124   "(P \<bind> Q) \<bind> R = P \<bind> (\<lambda>x. Q x \<bind> R)"
   125   by (rule pred_eqI) auto
   126 
   127 lemma bind_single:
   128   "P \<bind> single = P"
   129   by (rule pred_eqI) auto
   130 
   131 lemma single_bind:
   132   "single x \<bind> P = P x"
   133   by (rule pred_eqI) auto
   134 
   135 lemma bottom_bind:
   136   "\<bottom> \<bind> P = \<bottom>"
   137   by (rule pred_eqI) auto
   138 
   139 lemma sup_bind:
   140   "(P \<squnion> Q) \<bind> R = P \<bind> R \<squnion> Q \<bind> R"
   141   by (rule pred_eqI) auto
   142 
   143 lemma Sup_bind:
   144   "(\<Squnion>A \<bind> f) = \<Squnion>((\<lambda>x. x \<bind> f) ` A)"
   145   by (rule pred_eqI) auto
   146 
   147 lemma pred_iffI:
   148   assumes "\<And>x. eval A x \<Longrightarrow> eval B x"
   149   and "\<And>x. eval B x \<Longrightarrow> eval A x"
   150   shows "A = B"
   151   using assms by (auto intro: pred_eqI)
   152   
   153 lemma singleI: "eval (single x) x"
   154   by simp
   155 
   156 lemma singleI_unit: "eval (single ()) x"
   157   by simp
   158 
   159 lemma singleE: "eval (single x) y \<Longrightarrow> (y = x \<Longrightarrow> P) \<Longrightarrow> P"
   160   by simp
   161 
   162 lemma singleE': "eval (single x) y \<Longrightarrow> (x = y \<Longrightarrow> P) \<Longrightarrow> P"
   163   by simp
   164 
   165 lemma bindI: "eval P x \<Longrightarrow> eval (Q x) y \<Longrightarrow> eval (P \<bind> Q) y"
   166   by auto
   167 
   168 lemma bindE: "eval (R \<bind> Q) y \<Longrightarrow> (\<And>x. eval R x \<Longrightarrow> eval (Q x) y \<Longrightarrow> P) \<Longrightarrow> P"
   169   by auto
   170 
   171 lemma botE: "eval \<bottom> x \<Longrightarrow> P"
   172   by auto
   173 
   174 lemma supI1: "eval A x \<Longrightarrow> eval (A \<squnion> B) x"
   175   by auto
   176 
   177 lemma supI2: "eval B x \<Longrightarrow> eval (A \<squnion> B) x" 
   178   by auto
   179 
   180 lemma supE: "eval (A \<squnion> B) x \<Longrightarrow> (eval A x \<Longrightarrow> P) \<Longrightarrow> (eval B x \<Longrightarrow> P) \<Longrightarrow> P"
   181   by auto
   182 
   183 lemma single_not_bot [simp]:
   184   "single x \<noteq> \<bottom>"
   185   by (auto simp add: single_def bot_pred_def fun_eq_iff)
   186 
   187 lemma not_bot:
   188   assumes "A \<noteq> \<bottom>"
   189   obtains x where "eval A x"
   190   using assms by (cases A) (auto simp add: bot_pred_def)
   191 
   192 
   193 subsection \<open>Emptiness check and definite choice\<close>
   194 
   195 definition is_empty :: "'a pred \<Rightarrow> bool" where
   196   "is_empty A \<longleftrightarrow> A = \<bottom>"
   197 
   198 lemma is_empty_bot:
   199   "is_empty \<bottom>"
   200   by (simp add: is_empty_def)
   201 
   202 lemma not_is_empty_single:
   203   "\<not> is_empty (single x)"
   204   by (auto simp add: is_empty_def single_def bot_pred_def fun_eq_iff)
   205 
   206 lemma is_empty_sup:
   207   "is_empty (A \<squnion> B) \<longleftrightarrow> is_empty A \<and> is_empty B"
   208   by (auto simp add: is_empty_def)
   209 
   210 definition singleton :: "(unit \<Rightarrow> 'a) \<Rightarrow> 'a pred \<Rightarrow> 'a" where
   211   "singleton default A = (if \<exists>!x. eval A x then THE x. eval A x else default ())" for default
   212 
   213 lemma singleton_eqI:
   214   "\<exists>!x. eval A x \<Longrightarrow> eval A x \<Longrightarrow> singleton default A = x" for default
   215   by (auto simp add: singleton_def)
   216 
   217 lemma eval_singletonI:
   218   "\<exists>!x. eval A x \<Longrightarrow> eval A (singleton default A)" for default
   219 proof -
   220   assume assm: "\<exists>!x. eval A x"
   221   then obtain x where x: "eval A x" ..
   222   with assm have "singleton default A = x" by (rule singleton_eqI)
   223   with x show ?thesis by simp
   224 qed
   225 
   226 lemma single_singleton:
   227   "\<exists>!x. eval A x \<Longrightarrow> single (singleton default A) = A" for default
   228 proof -
   229   assume assm: "\<exists>!x. eval A x"
   230   then have "eval A (singleton default A)"
   231     by (rule eval_singletonI)
   232   moreover from assm have "\<And>x. eval A x \<Longrightarrow> singleton default A = x"
   233     by (rule singleton_eqI)
   234   ultimately have "eval (single (singleton default A)) = eval A"
   235     by (simp (no_asm_use) add: single_def fun_eq_iff) blast
   236   then have "\<And>x. eval (single (singleton default A)) x = eval A x"
   237     by simp
   238   then show ?thesis by (rule pred_eqI)
   239 qed
   240 
   241 lemma singleton_undefinedI:
   242   "\<not> (\<exists>!x. eval A x) \<Longrightarrow> singleton default A = default ()" for default
   243   by (simp add: singleton_def)
   244 
   245 lemma singleton_bot:
   246   "singleton default \<bottom> = default ()" for default
   247   by (auto simp add: bot_pred_def intro: singleton_undefinedI)
   248 
   249 lemma singleton_single:
   250   "singleton default (single x) = x" for default
   251   by (auto simp add: intro: singleton_eqI singleI elim: singleE)
   252 
   253 lemma singleton_sup_single_single:
   254   "singleton default (single x \<squnion> single y) = (if x = y then x else default ())" for default
   255 proof (cases "x = y")
   256   case True then show ?thesis by (simp add: singleton_single)
   257 next
   258   case False
   259   have "eval (single x \<squnion> single y) x"
   260     and "eval (single x \<squnion> single y) y"
   261   by (auto intro: supI1 supI2 singleI)
   262   with False have "\<not> (\<exists>!z. eval (single x \<squnion> single y) z)"
   263     by blast
   264   then have "singleton default (single x \<squnion> single y) = default ()"
   265     by (rule singleton_undefinedI)
   266   with False show ?thesis by simp
   267 qed
   268 
   269 lemma singleton_sup_aux:
   270   "singleton default (A \<squnion> B) = (if A = \<bottom> then singleton default B
   271     else if B = \<bottom> then singleton default A
   272     else singleton default
   273       (single (singleton default A) \<squnion> single (singleton default B)))" for default
   274 proof (cases "(\<exists>!x. eval A x) \<and> (\<exists>!y. eval B y)")
   275   case True then show ?thesis by (simp add: single_singleton)
   276 next
   277   case False
   278   from False have A_or_B:
   279     "singleton default A = default () \<or> singleton default B = default ()"
   280     by (auto intro!: singleton_undefinedI)
   281   then have rhs: "singleton default
   282     (single (singleton default A) \<squnion> single (singleton default B)) = default ()"
   283     by (auto simp add: singleton_sup_single_single singleton_single)
   284   from False have not_unique:
   285     "\<not> (\<exists>!x. eval A x) \<or> \<not> (\<exists>!y. eval B y)" by simp
   286   show ?thesis proof (cases "A \<noteq> \<bottom> \<and> B \<noteq> \<bottom>")
   287     case True
   288     then obtain a b where a: "eval A a" and b: "eval B b"
   289       by (blast elim: not_bot)
   290     with True not_unique have "\<not> (\<exists>!x. eval (A \<squnion> B) x)"
   291       by (auto simp add: sup_pred_def bot_pred_def)
   292     then have "singleton default (A \<squnion> B) = default ()" by (rule singleton_undefinedI)
   293     with True rhs show ?thesis by simp
   294   next
   295     case False then show ?thesis by auto
   296   qed
   297 qed
   298 
   299 lemma singleton_sup:
   300   "singleton default (A \<squnion> B) = (if A = \<bottom> then singleton default B
   301     else if B = \<bottom> then singleton default A
   302     else if singleton default A = singleton default B then singleton default A else default ())" for default
   303   using singleton_sup_aux [of default A B] by (simp only: singleton_sup_single_single)
   304 
   305 
   306 subsection \<open>Derived operations\<close>
   307 
   308 definition if_pred :: "bool \<Rightarrow> unit pred" where
   309   if_pred_eq: "if_pred b = (if b then single () else \<bottom>)"
   310 
   311 definition holds :: "unit pred \<Rightarrow> bool" where
   312   holds_eq: "holds P = eval P ()"
   313 
   314 definition not_pred :: "unit pred \<Rightarrow> unit pred" where
   315   not_pred_eq: "not_pred P = (if eval P () then \<bottom> else single ())"
   316 
   317 lemma if_predI: "P \<Longrightarrow> eval (if_pred P) ()"
   318   unfolding if_pred_eq by (auto intro: singleI)
   319 
   320 lemma if_predE: "eval (if_pred b) x \<Longrightarrow> (b \<Longrightarrow> x = () \<Longrightarrow> P) \<Longrightarrow> P"
   321   unfolding if_pred_eq by (cases b) (auto elim: botE)
   322 
   323 lemma not_predI: "\<not> P \<Longrightarrow> eval (not_pred (Pred (\<lambda>u. P))) ()"
   324   unfolding not_pred_eq by (auto intro: singleI)
   325 
   326 lemma not_predI': "\<not> eval P () \<Longrightarrow> eval (not_pred P) ()"
   327   unfolding not_pred_eq by (auto intro: singleI)
   328 
   329 lemma not_predE: "eval (not_pred (Pred (\<lambda>u. P))) x \<Longrightarrow> (\<not> P \<Longrightarrow> thesis) \<Longrightarrow> thesis"
   330   unfolding not_pred_eq
   331   by (auto split: if_split_asm elim: botE)
   332 
   333 lemma not_predE': "eval (not_pred P) x \<Longrightarrow> (\<not> eval P x \<Longrightarrow> thesis) \<Longrightarrow> thesis"
   334   unfolding not_pred_eq
   335   by (auto split: if_split_asm elim: botE)
   336 lemma "f () = False \<or> f () = True"
   337 by simp
   338 
   339 lemma closure_of_bool_cases [no_atp]:
   340   fixes f :: "unit \<Rightarrow> bool"
   341   assumes "f = (\<lambda>u. False) \<Longrightarrow> P f"
   342   assumes "f = (\<lambda>u. True) \<Longrightarrow> P f"
   343   shows "P f"
   344 proof -
   345   have "f = (\<lambda>u. False) \<or> f = (\<lambda>u. True)"
   346     apply (cases "f ()")
   347     apply (rule disjI2)
   348     apply (rule ext)
   349     apply (simp add: unit_eq)
   350     apply (rule disjI1)
   351     apply (rule ext)
   352     apply (simp add: unit_eq)
   353     done
   354   from this assms show ?thesis by blast
   355 qed
   356 
   357 lemma unit_pred_cases:
   358   assumes "P \<bottom>"
   359   assumes "P (single ())"
   360   shows "P Q"
   361 using assms unfolding bot_pred_def bot_fun_def bot_bool_def empty_def single_def proof (cases Q)
   362   fix f
   363   assume "P (Pred (\<lambda>u. False))" "P (Pred (\<lambda>u. () = u))"
   364   then have "P (Pred f)" 
   365     by (cases _ f rule: closure_of_bool_cases) simp_all
   366   moreover assume "Q = Pred f"
   367   ultimately show "P Q" by simp
   368 qed
   369   
   370 lemma holds_if_pred:
   371   "holds (if_pred b) = b"
   372 unfolding if_pred_eq holds_eq
   373 by (cases b) (auto intro: singleI elim: botE)
   374 
   375 lemma if_pred_holds:
   376   "if_pred (holds P) = P"
   377 unfolding if_pred_eq holds_eq
   378 by (rule unit_pred_cases) (auto intro: singleI elim: botE)
   379 
   380 lemma is_empty_holds:
   381   "is_empty P \<longleftrightarrow> \<not> holds P"
   382 unfolding is_empty_def holds_eq
   383 by (rule unit_pred_cases) (auto elim: botE intro: singleI)
   384 
   385 definition map :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a pred \<Rightarrow> 'b pred" where
   386   "map f P = P \<bind> (single o f)"
   387 
   388 lemma eval_map [simp]:
   389   "eval (map f P) = (\<Squnion>x\<in>{x. eval P x}. (\<lambda>y. f x = y))"
   390   by (auto simp add: map_def comp_def)
   391 
   392 functor map: map
   393   by (rule ext, rule pred_eqI, auto)+
   394 
   395 
   396 subsection \<open>Implementation\<close>
   397 
   398 datatype (plugins only: code extraction) (dead 'a) seq =
   399   Empty
   400 | Insert "'a" "'a pred"
   401 | Join "'a pred" "'a seq"
   402 
   403 primrec pred_of_seq :: "'a seq \<Rightarrow> 'a pred" where
   404   "pred_of_seq Empty = \<bottom>"
   405 | "pred_of_seq (Insert x P) = single x \<squnion> P"
   406 | "pred_of_seq (Join P xq) = P \<squnion> pred_of_seq xq"
   407 
   408 definition Seq :: "(unit \<Rightarrow> 'a seq) \<Rightarrow> 'a pred" where
   409   "Seq f = pred_of_seq (f ())"
   410 
   411 code_datatype Seq
   412 
   413 primrec member :: "'a seq \<Rightarrow> 'a \<Rightarrow> bool"  where
   414   "member Empty x \<longleftrightarrow> False"
   415 | "member (Insert y P) x \<longleftrightarrow> x = y \<or> eval P x"
   416 | "member (Join P xq) x \<longleftrightarrow> eval P x \<or> member xq x"
   417 
   418 lemma eval_member:
   419   "member xq = eval (pred_of_seq xq)"
   420 proof (induct xq)
   421   case Empty show ?case
   422   by (auto simp add: fun_eq_iff elim: botE)
   423 next
   424   case Insert show ?case
   425   by (auto simp add: fun_eq_iff elim: supE singleE intro: supI1 supI2 singleI)
   426 next
   427   case Join then show ?case
   428   by (auto simp add: fun_eq_iff elim: supE intro: supI1 supI2)
   429 qed
   430 
   431 lemma eval_code [(* FIXME declare simp *)code]: "eval (Seq f) = member (f ())"
   432   unfolding Seq_def by (rule sym, rule eval_member)
   433 
   434 lemma single_code [code]:
   435   "single x = Seq (\<lambda>u. Insert x \<bottom>)"
   436   unfolding Seq_def by simp
   437 
   438 primrec "apply" :: "('a \<Rightarrow> 'b pred) \<Rightarrow> 'a seq \<Rightarrow> 'b seq" where
   439   "apply f Empty = Empty"
   440 | "apply f (Insert x P) = Join (f x) (Join (P \<bind> f) Empty)"
   441 | "apply f (Join P xq) = Join (P \<bind> f) (apply f xq)"
   442 
   443 lemma apply_bind:
   444   "pred_of_seq (apply f xq) = pred_of_seq xq \<bind> f"
   445 proof (induct xq)
   446   case Empty show ?case
   447     by (simp add: bottom_bind)
   448 next
   449   case Insert show ?case
   450     by (simp add: single_bind sup_bind)
   451 next
   452   case Join then show ?case
   453     by (simp add: sup_bind)
   454 qed
   455   
   456 lemma bind_code [code]:
   457   "Seq g \<bind> f = Seq (\<lambda>u. apply f (g ()))"
   458   unfolding Seq_def by (rule sym, rule apply_bind)
   459 
   460 lemma bot_set_code [code]:
   461   "\<bottom> = Seq (\<lambda>u. Empty)"
   462   unfolding Seq_def by simp
   463 
   464 primrec adjunct :: "'a pred \<Rightarrow> 'a seq \<Rightarrow> 'a seq" where
   465   "adjunct P Empty = Join P Empty"
   466 | "adjunct P (Insert x Q) = Insert x (Q \<squnion> P)"
   467 | "adjunct P (Join Q xq) = Join Q (adjunct P xq)"
   468 
   469 lemma adjunct_sup:
   470   "pred_of_seq (adjunct P xq) = P \<squnion> pred_of_seq xq"
   471   by (induct xq) (simp_all add: sup_assoc sup_commute sup_left_commute)
   472 
   473 lemma sup_code [code]:
   474   "Seq f \<squnion> Seq g = Seq (\<lambda>u. case f ()
   475     of Empty \<Rightarrow> g ()
   476      | Insert x P \<Rightarrow> Insert x (P \<squnion> Seq g)
   477      | Join P xq \<Rightarrow> adjunct (Seq g) (Join P xq))"
   478 proof (cases "f ()")
   479   case Empty
   480   thus ?thesis
   481     unfolding Seq_def by (simp add: sup_commute [of "\<bottom>"])
   482 next
   483   case Insert
   484   thus ?thesis
   485     unfolding Seq_def by (simp add: sup_assoc)
   486 next
   487   case Join
   488   thus ?thesis
   489     unfolding Seq_def
   490     by (simp add: adjunct_sup sup_assoc sup_commute sup_left_commute)
   491 qed
   492 
   493 primrec contained :: "'a seq \<Rightarrow> 'a pred \<Rightarrow> bool" where
   494   "contained Empty Q \<longleftrightarrow> True"
   495 | "contained (Insert x P) Q \<longleftrightarrow> eval Q x \<and> P \<le> Q"
   496 | "contained (Join P xq) Q \<longleftrightarrow> P \<le> Q \<and> contained xq Q"
   497 
   498 lemma single_less_eq_eval:
   499   "single x \<le> P \<longleftrightarrow> eval P x"
   500   by (auto simp add: less_eq_pred_def le_fun_def)
   501 
   502 lemma contained_less_eq:
   503   "contained xq Q \<longleftrightarrow> pred_of_seq xq \<le> Q"
   504   by (induct xq) (simp_all add: single_less_eq_eval)
   505 
   506 lemma less_eq_pred_code [code]:
   507   "Seq f \<le> Q = (case f ()
   508    of Empty \<Rightarrow> True
   509     | Insert x P \<Rightarrow> eval Q x \<and> P \<le> Q
   510     | Join P xq \<Rightarrow> P \<le> Q \<and> contained xq Q)"
   511   by (cases "f ()")
   512     (simp_all add: Seq_def single_less_eq_eval contained_less_eq)
   513 
   514 instantiation pred :: (type) equal
   515 begin
   516 
   517 definition equal_pred
   518   where [simp]: "HOL.equal P Q \<longleftrightarrow> P = (Q :: 'a pred)"
   519 
   520 instance by standard simp
   521 
   522 end
   523     
   524 lemma [code]:
   525   "HOL.equal P Q \<longleftrightarrow> P \<le> Q \<and> Q \<le> P" for P Q :: "'a pred"
   526   by auto
   527 
   528 lemma [code nbe]:
   529   "HOL.equal P P \<longleftrightarrow> True" for P :: "'a pred"
   530   by (fact equal_refl)
   531 
   532 lemma [code]:
   533   "case_pred f P = f (eval P)"
   534   by (fact pred.case_eq_if)
   535 
   536 lemma [code]:
   537   "rec_pred f P = f (eval P)"
   538   by (cases P) simp
   539 
   540 inductive eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool" where "eq x x"
   541 
   542 lemma eq_is_eq: "eq x y \<equiv> (x = y)"
   543   by (rule eq_reflection) (auto intro: eq.intros elim: eq.cases)
   544 
   545 primrec null :: "'a seq \<Rightarrow> bool" where
   546   "null Empty \<longleftrightarrow> True"
   547 | "null (Insert x P) \<longleftrightarrow> False"
   548 | "null (Join P xq) \<longleftrightarrow> is_empty P \<and> null xq"
   549 
   550 lemma null_is_empty:
   551   "null xq \<longleftrightarrow> is_empty (pred_of_seq xq)"
   552   by (induct xq) (simp_all add: is_empty_bot not_is_empty_single is_empty_sup)
   553 
   554 lemma is_empty_code [code]:
   555   "is_empty (Seq f) \<longleftrightarrow> null (f ())"
   556   by (simp add: null_is_empty Seq_def)
   557 
   558 primrec the_only :: "(unit \<Rightarrow> 'a) \<Rightarrow> 'a seq \<Rightarrow> 'a" where
   559   "the_only default Empty = default ()" for default
   560 | "the_only default (Insert x P) =
   561     (if is_empty P then x else let y = singleton default P in if x = y then x else default ())" for default
   562 | "the_only default (Join P xq) =
   563     (if is_empty P then the_only default xq else if null xq then singleton default P
   564        else let x = singleton default P; y = the_only default xq in
   565        if x = y then x else default ())" for default
   566 
   567 lemma the_only_singleton:
   568   "the_only default xq = singleton default (pred_of_seq xq)" for default
   569   by (induct xq)
   570     (auto simp add: singleton_bot singleton_single is_empty_def
   571     null_is_empty Let_def singleton_sup)
   572 
   573 lemma singleton_code [code]:
   574   "singleton default (Seq f) =
   575     (case f () of
   576       Empty \<Rightarrow> default ()
   577     | Insert x P \<Rightarrow> if is_empty P then x
   578         else let y = singleton default P in
   579           if x = y then x else default ()
   580     | Join P xq \<Rightarrow> if is_empty P then the_only default xq
   581         else if null xq then singleton default P
   582         else let x = singleton default P; y = the_only default xq in
   583           if x = y then x else default ())" for default
   584   by (cases "f ()")
   585    (auto simp add: Seq_def the_only_singleton is_empty_def
   586       null_is_empty singleton_bot singleton_single singleton_sup Let_def)
   587 
   588 definition the :: "'a pred \<Rightarrow> 'a" where
   589   "the A = (THE x. eval A x)"
   590 
   591 lemma the_eqI:
   592   "(THE x. eval P x) = x \<Longrightarrow> the P = x"
   593   by (simp add: the_def)
   594 
   595 lemma the_eq [code]: "the A = singleton (\<lambda>x. Code.abort (STR ''not_unique'') (\<lambda>_. the A)) A"
   596   by (rule the_eqI) (simp add: singleton_def the_def)
   597 
   598 code_reflect Predicate
   599   datatypes pred = Seq and seq = Empty | Insert | Join
   600 
   601 ML \<open>
   602 signature PREDICATE =
   603 sig
   604   val anamorph: ('a -> ('b * 'a) option) -> int -> 'a -> 'b list * 'a
   605   datatype 'a pred = Seq of (unit -> 'a seq)
   606   and 'a seq = Empty | Insert of 'a * 'a pred | Join of 'a pred * 'a seq
   607   val map: ('a -> 'b) -> 'a pred -> 'b pred
   608   val yield: 'a pred -> ('a * 'a pred) option
   609   val yieldn: int -> 'a pred -> 'a list * 'a pred
   610 end;
   611 
   612 structure Predicate : PREDICATE =
   613 struct
   614 
   615 fun anamorph f k x =
   616  (if k = 0 then ([], x)
   617   else case f x
   618    of NONE => ([], x)
   619     | SOME (v, y) => let
   620         val k' = k - 1;
   621         val (vs, z) = anamorph f k' y
   622       in (v :: vs, z) end);
   623 
   624 datatype pred = datatype Predicate.pred
   625 datatype seq = datatype Predicate.seq
   626 
   627 fun map f = @{code Predicate.map} f;
   628 
   629 fun yield (Seq f) = next (f ())
   630 and next Empty = NONE
   631   | next (Insert (x, P)) = SOME (x, P)
   632   | next (Join (P, xq)) = (case yield P
   633      of NONE => next xq
   634       | SOME (x, Q) => SOME (x, Seq (fn _ => Join (Q, xq))));
   635 
   636 fun yieldn k = anamorph yield k;
   637 
   638 end;
   639 \<close>
   640 
   641 text \<open>Conversion from and to sets\<close>
   642 
   643 definition pred_of_set :: "'a set \<Rightarrow> 'a pred" where
   644   "pred_of_set = Pred \<circ> (\<lambda>A x. x \<in> A)"
   645 
   646 lemma eval_pred_of_set [simp]:
   647   "eval (pred_of_set A) x \<longleftrightarrow> x \<in>A"
   648   by (simp add: pred_of_set_def)
   649 
   650 definition set_of_pred :: "'a pred \<Rightarrow> 'a set" where
   651   "set_of_pred = Collect \<circ> eval"
   652 
   653 lemma member_set_of_pred [simp]:
   654   "x \<in> set_of_pred P \<longleftrightarrow> Predicate.eval P x"
   655   by (simp add: set_of_pred_def)
   656 
   657 definition set_of_seq :: "'a seq \<Rightarrow> 'a set" where
   658   "set_of_seq = set_of_pred \<circ> pred_of_seq"
   659 
   660 lemma member_set_of_seq [simp]:
   661   "x \<in> set_of_seq xq = Predicate.member xq x"
   662   by (simp add: set_of_seq_def eval_member)
   663 
   664 lemma of_pred_code [code]:
   665   "set_of_pred (Predicate.Seq f) = (case f () of
   666      Predicate.Empty \<Rightarrow> {}
   667    | Predicate.Insert x P \<Rightarrow> insert x (set_of_pred P)
   668    | Predicate.Join P xq \<Rightarrow> set_of_pred P \<union> set_of_seq xq)"
   669   by (auto split: seq.split simp add: eval_code)
   670 
   671 lemma of_seq_code [code]:
   672   "set_of_seq Predicate.Empty = {}"
   673   "set_of_seq (Predicate.Insert x P) = insert x (set_of_pred P)"
   674   "set_of_seq (Predicate.Join P xq) = set_of_pred P \<union> set_of_seq xq"
   675   by auto
   676 
   677 text \<open>Lazy Evaluation of an indexed function\<close>
   678 
   679 function iterate_upto :: "(natural \<Rightarrow> 'a) \<Rightarrow> natural \<Rightarrow> natural \<Rightarrow> 'a Predicate.pred"
   680 where
   681   "iterate_upto f n m =
   682     Predicate.Seq (%u. if n > m then Predicate.Empty
   683      else Predicate.Insert (f n) (iterate_upto f (n + 1) m))"
   684 by pat_completeness auto
   685 
   686 termination by (relation "measure (%(f, n, m). nat_of_natural (m + 1 - n))")
   687   (auto simp add: less_natural_def)
   688 
   689 text \<open>Misc\<close>
   690 
   691 declare Inf_set_fold [where 'a = "'a Predicate.pred", code]
   692 declare Sup_set_fold [where 'a = "'a Predicate.pred", code]
   693 
   694 (* FIXME: better implement conversion by bisection *)
   695 
   696 lemma pred_of_set_fold_sup:
   697   assumes "finite A"
   698   shows "pred_of_set A = Finite_Set.fold sup bot (Predicate.single ` A)" (is "?lhs = ?rhs")
   699 proof (rule sym)
   700   interpret comp_fun_idem "sup :: 'a Predicate.pred \<Rightarrow> 'a Predicate.pred \<Rightarrow> 'a Predicate.pred"
   701     by (fact comp_fun_idem_sup)
   702   from \<open>finite A\<close> show "?rhs = ?lhs" by (induct A) (auto intro!: pred_eqI)
   703 qed
   704 
   705 lemma pred_of_set_set_fold_sup:
   706   "pred_of_set (set xs) = fold sup (List.map Predicate.single xs) bot"
   707 proof -
   708   interpret comp_fun_idem "sup :: 'a Predicate.pred \<Rightarrow> 'a Predicate.pred \<Rightarrow> 'a Predicate.pred"
   709     by (fact comp_fun_idem_sup)
   710   show ?thesis by (simp add: pred_of_set_fold_sup fold_set_fold [symmetric])
   711 qed
   712 
   713 lemma pred_of_set_set_foldr_sup [code]:
   714   "pred_of_set (set xs) = foldr sup (List.map Predicate.single xs) bot"
   715   by (simp add: pred_of_set_set_fold_sup ac_simps foldr_fold fun_eq_iff)
   716 
   717 no_notation
   718   bind (infixl "\<bind>" 70)
   719 
   720 hide_type (open) pred seq
   721 hide_const (open) Pred eval single bind is_empty singleton if_pred not_pred holds
   722   Empty Insert Join Seq member pred_of_seq "apply" adjunct null the_only eq map the
   723   iterate_upto
   724 hide_fact (open) null_def member_def
   725 
   726 end