src/HOL/Topological_Spaces.thy
author hoelzl
Wed Jun 18 14:31:32 2014 +0200 (2014-06-18)
changeset 57276 49c51eeaa623
parent 57275 0ddb5b755cdc
child 57447 87429bdecad5
permissions -rw-r--r--
filters are easier to define with INF on filters.
     1 (*  Title:      HOL/Topological_Spaces.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 header {* Topological Spaces *}
     7 
     8 theory Topological_Spaces
     9 imports Main Conditionally_Complete_Lattices
    10 begin
    11 
    12 ML {*
    13 
    14 structure Continuous_Intros = Named_Thms
    15 (
    16   val name = @{binding continuous_intros}
    17   val description = "Structural introduction rules for continuity"
    18 )
    19 
    20 *}
    21 
    22 setup Continuous_Intros.setup
    23 
    24 subsection {* Topological space *}
    25 
    26 class "open" =
    27   fixes "open" :: "'a set \<Rightarrow> bool"
    28 
    29 class topological_space = "open" +
    30   assumes open_UNIV [simp, intro]: "open UNIV"
    31   assumes open_Int [intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<inter> T)"
    32   assumes open_Union [intro]: "\<forall>S\<in>K. open S \<Longrightarrow> open (\<Union> K)"
    33 begin
    34 
    35 definition
    36   closed :: "'a set \<Rightarrow> bool" where
    37   "closed S \<longleftrightarrow> open (- S)"
    38 
    39 lemma open_empty [continuous_intros, intro, simp]: "open {}"
    40   using open_Union [of "{}"] by simp
    41 
    42 lemma open_Un [continuous_intros, intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<union> T)"
    43   using open_Union [of "{S, T}"] by simp
    44 
    45 lemma open_UN [continuous_intros, intro]: "\<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Union>x\<in>A. B x)"
    46   using open_Union [of "B ` A"] by simp
    47 
    48 lemma open_Inter [continuous_intros, intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. open T \<Longrightarrow> open (\<Inter>S)"
    49   by (induct set: finite) auto
    50 
    51 lemma open_INT [continuous_intros, intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Inter>x\<in>A. B x)"
    52   using open_Inter [of "B ` A"] by simp
    53 
    54 lemma openI:
    55   assumes "\<And>x. x \<in> S \<Longrightarrow> \<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> S"
    56   shows "open S"
    57 proof -
    58   have "open (\<Union>{T. open T \<and> T \<subseteq> S})" by auto
    59   moreover have "\<Union>{T. open T \<and> T \<subseteq> S} = S" by (auto dest!: assms)
    60   ultimately show "open S" by simp
    61 qed
    62 
    63 lemma closed_empty [continuous_intros, intro, simp]:  "closed {}"
    64   unfolding closed_def by simp
    65 
    66 lemma closed_Un [continuous_intros, intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<union> T)"
    67   unfolding closed_def by auto
    68 
    69 lemma closed_UNIV [continuous_intros, intro, simp]: "closed UNIV"
    70   unfolding closed_def by simp
    71 
    72 lemma closed_Int [continuous_intros, intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<inter> T)"
    73   unfolding closed_def by auto
    74 
    75 lemma closed_INT [continuous_intros, intro]: "\<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Inter>x\<in>A. B x)"
    76   unfolding closed_def by auto
    77 
    78 lemma closed_Inter [continuous_intros, intro]: "\<forall>S\<in>K. closed S \<Longrightarrow> closed (\<Inter> K)"
    79   unfolding closed_def uminus_Inf by auto
    80 
    81 lemma closed_Union [continuous_intros, intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. closed T \<Longrightarrow> closed (\<Union>S)"
    82   by (induct set: finite) auto
    83 
    84 lemma closed_UN [continuous_intros, intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Union>x\<in>A. B x)"
    85   using closed_Union [of "B ` A"] by simp
    86 
    87 lemma open_closed: "open S \<longleftrightarrow> closed (- S)"
    88   unfolding closed_def by simp
    89 
    90 lemma closed_open: "closed S \<longleftrightarrow> open (- S)"
    91   unfolding closed_def by simp
    92 
    93 lemma open_Diff [continuous_intros, intro]: "open S \<Longrightarrow> closed T \<Longrightarrow> open (S - T)"
    94   unfolding closed_open Diff_eq by (rule open_Int)
    95 
    96 lemma closed_Diff [continuous_intros, intro]: "closed S \<Longrightarrow> open T \<Longrightarrow> closed (S - T)"
    97   unfolding open_closed Diff_eq by (rule closed_Int)
    98 
    99 lemma open_Compl [continuous_intros, intro]: "closed S \<Longrightarrow> open (- S)"
   100   unfolding closed_open .
   101 
   102 lemma closed_Compl [continuous_intros, intro]: "open S \<Longrightarrow> closed (- S)"
   103   unfolding open_closed .
   104 
   105 end
   106 
   107 subsection{* Hausdorff and other separation properties *}
   108 
   109 class t0_space = topological_space +
   110   assumes t0_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> \<not> (x \<in> U \<longleftrightarrow> y \<in> U)"
   111 
   112 class t1_space = topological_space +
   113   assumes t1_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> x \<in> U \<and> y \<notin> U"
   114 
   115 instance t1_space \<subseteq> t0_space
   116 proof qed (fast dest: t1_space)
   117 
   118 lemma separation_t1:
   119   fixes x y :: "'a::t1_space"
   120   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> x \<in> U \<and> y \<notin> U)"
   121   using t1_space[of x y] by blast
   122 
   123 lemma closed_singleton:
   124   fixes a :: "'a::t1_space"
   125   shows "closed {a}"
   126 proof -
   127   let ?T = "\<Union>{S. open S \<and> a \<notin> S}"
   128   have "open ?T" by (simp add: open_Union)
   129   also have "?T = - {a}"
   130     by (simp add: set_eq_iff separation_t1, auto)
   131   finally show "closed {a}" unfolding closed_def .
   132 qed
   133 
   134 lemma closed_insert [continuous_intros, simp]:
   135   fixes a :: "'a::t1_space"
   136   assumes "closed S" shows "closed (insert a S)"
   137 proof -
   138   from closed_singleton assms
   139   have "closed ({a} \<union> S)" by (rule closed_Un)
   140   thus "closed (insert a S)" by simp
   141 qed
   142 
   143 lemma finite_imp_closed:
   144   fixes S :: "'a::t1_space set"
   145   shows "finite S \<Longrightarrow> closed S"
   146 by (induct set: finite, simp_all)
   147 
   148 text {* T2 spaces are also known as Hausdorff spaces. *}
   149 
   150 class t2_space = topological_space +
   151   assumes hausdorff: "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   152 
   153 instance t2_space \<subseteq> t1_space
   154 proof qed (fast dest: hausdorff)
   155 
   156 lemma separation_t2:
   157   fixes x y :: "'a::t2_space"
   158   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {})"
   159   using hausdorff[of x y] by blast
   160 
   161 lemma separation_t0:
   162   fixes x y :: "'a::t0_space"
   163   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> ~(x\<in>U \<longleftrightarrow> y\<in>U))"
   164   using t0_space[of x y] by blast
   165 
   166 text {* A perfect space is a topological space with no isolated points. *}
   167 
   168 class perfect_space = topological_space +
   169   assumes not_open_singleton: "\<not> open {x}"
   170 
   171 
   172 subsection {* Generators for toplogies *}
   173 
   174 inductive generate_topology for S where
   175   UNIV: "generate_topology S UNIV"
   176 | Int: "generate_topology S a \<Longrightarrow> generate_topology S b \<Longrightarrow> generate_topology S (a \<inter> b)"
   177 | UN: "(\<And>k. k \<in> K \<Longrightarrow> generate_topology S k) \<Longrightarrow> generate_topology S (\<Union>K)"
   178 | Basis: "s \<in> S \<Longrightarrow> generate_topology S s"
   179 
   180 hide_fact (open) UNIV Int UN Basis 
   181 
   182 lemma generate_topology_Union: 
   183   "(\<And>k. k \<in> I \<Longrightarrow> generate_topology S (K k)) \<Longrightarrow> generate_topology S (\<Union>k\<in>I. K k)"
   184   using generate_topology.UN [of "K ` I"] by auto
   185 
   186 lemma topological_space_generate_topology:
   187   "class.topological_space (generate_topology S)"
   188   by default (auto intro: generate_topology.intros)
   189 
   190 subsection {* Order topologies *}
   191 
   192 class order_topology = order + "open" +
   193   assumes open_generated_order: "open = generate_topology (range (\<lambda>a. {..< a}) \<union> range (\<lambda>a. {a <..}))"
   194 begin
   195 
   196 subclass topological_space
   197   unfolding open_generated_order
   198   by (rule topological_space_generate_topology)
   199 
   200 lemma open_greaterThan [continuous_intros, simp]: "open {a <..}"
   201   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   202 
   203 lemma open_lessThan [continuous_intros, simp]: "open {..< a}"
   204   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   205 
   206 lemma open_greaterThanLessThan [continuous_intros, simp]: "open {a <..< b}"
   207    unfolding greaterThanLessThan_eq by (simp add: open_Int)
   208 
   209 end
   210 
   211 class linorder_topology = linorder + order_topology
   212 
   213 lemma closed_atMost [continuous_intros, simp]: "closed {.. a::'a::linorder_topology}"
   214   by (simp add: closed_open)
   215 
   216 lemma closed_atLeast [continuous_intros, simp]: "closed {a::'a::linorder_topology ..}"
   217   by (simp add: closed_open)
   218 
   219 lemma closed_atLeastAtMost [continuous_intros, simp]: "closed {a::'a::linorder_topology .. b}"
   220 proof -
   221   have "{a .. b} = {a ..} \<inter> {.. b}"
   222     by auto
   223   then show ?thesis
   224     by (simp add: closed_Int)
   225 qed
   226 
   227 lemma (in linorder) less_separate:
   228   assumes "x < y"
   229   shows "\<exists>a b. x \<in> {..< a} \<and> y \<in> {b <..} \<and> {..< a} \<inter> {b <..} = {}"
   230 proof (cases "\<exists>z. x < z \<and> z < y")
   231   case True
   232   then obtain z where "x < z \<and> z < y" ..
   233   then have "x \<in> {..< z} \<and> y \<in> {z <..} \<and> {z <..} \<inter> {..< z} = {}"
   234     by auto
   235   then show ?thesis by blast
   236 next
   237   case False
   238   with `x < y` have "x \<in> {..< y} \<and> y \<in> {x <..} \<and> {x <..} \<inter> {..< y} = {}"
   239     by auto
   240   then show ?thesis by blast
   241 qed
   242 
   243 instance linorder_topology \<subseteq> t2_space
   244 proof
   245   fix x y :: 'a
   246   from less_separate[of x y] less_separate[of y x]
   247   show "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   248     by (elim neqE) (metis open_lessThan open_greaterThan Int_commute)+
   249 qed
   250 
   251 lemma (in linorder_topology) open_right:
   252   assumes "open S" "x \<in> S" and gt_ex: "x < y" shows "\<exists>b>x. {x ..< b} \<subseteq> S"
   253   using assms unfolding open_generated_order
   254 proof induction
   255   case (Int A B)
   256   then obtain a b where "a > x" "{x ..< a} \<subseteq> A"  "b > x" "{x ..< b} \<subseteq> B" by auto
   257   then show ?case by (auto intro!: exI[of _ "min a b"])
   258 next
   259   case (Basis S) then show ?case by (fastforce intro: exI[of _ y] gt_ex)
   260 qed blast+
   261 
   262 lemma (in linorder_topology) open_left:
   263   assumes "open S" "x \<in> S" and lt_ex: "y < x" shows "\<exists>b<x. {b <.. x} \<subseteq> S"
   264   using assms unfolding open_generated_order
   265 proof induction
   266   case (Int A B)
   267   then obtain a b where "a < x" "{a <.. x} \<subseteq> A"  "b < x" "{b <.. x} \<subseteq> B" by auto
   268   then show ?case by (auto intro!: exI[of _ "max a b"])
   269 next
   270   case (Basis S) then show ?case by (fastforce intro: exI[of _ y] lt_ex)
   271 qed blast+
   272 
   273 subsection {* Filters *}
   274 
   275 text {*
   276   This definition also allows non-proper filters.
   277 *}
   278 
   279 locale is_filter =
   280   fixes F :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
   281   assumes True: "F (\<lambda>x. True)"
   282   assumes conj: "F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x) \<Longrightarrow> F (\<lambda>x. P x \<and> Q x)"
   283   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x)"
   284 
   285 typedef 'a filter = "{F :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter F}"
   286 proof
   287   show "(\<lambda>x. True) \<in> ?filter" by (auto intro: is_filter.intro)
   288 qed
   289 
   290 lemma is_filter_Rep_filter: "is_filter (Rep_filter F)"
   291   using Rep_filter [of F] by simp
   292 
   293 lemma Abs_filter_inverse':
   294   assumes "is_filter F" shows "Rep_filter (Abs_filter F) = F"
   295   using assms by (simp add: Abs_filter_inverse)
   296 
   297 
   298 subsubsection {* Eventually *}
   299 
   300 definition eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
   301   where "eventually P F \<longleftrightarrow> Rep_filter F P"
   302 
   303 lemma eventually_Abs_filter:
   304   assumes "is_filter F" shows "eventually P (Abs_filter F) = F P"
   305   unfolding eventually_def using assms by (simp add: Abs_filter_inverse)
   306 
   307 lemma filter_eq_iff:
   308   shows "F = F' \<longleftrightarrow> (\<forall>P. eventually P F = eventually P F')"
   309   unfolding Rep_filter_inject [symmetric] fun_eq_iff eventually_def ..
   310 
   311 lemma eventually_True [simp]: "eventually (\<lambda>x. True) F"
   312   unfolding eventually_def
   313   by (rule is_filter.True [OF is_filter_Rep_filter])
   314 
   315 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P F"
   316 proof -
   317   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
   318   thus "eventually P F" by simp
   319 qed
   320 
   321 lemma eventually_mono:
   322   "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually P F \<Longrightarrow> eventually Q F"
   323   unfolding eventually_def
   324   by (rule is_filter.mono [OF is_filter_Rep_filter])
   325 
   326 lemma eventually_conj:
   327   assumes P: "eventually (\<lambda>x. P x) F"
   328   assumes Q: "eventually (\<lambda>x. Q x) F"
   329   shows "eventually (\<lambda>x. P x \<and> Q x) F"
   330   using assms unfolding eventually_def
   331   by (rule is_filter.conj [OF is_filter_Rep_filter])
   332 
   333 lemma eventually_Ball_finite:
   334   assumes "finite A" and "\<forall>y\<in>A. eventually (\<lambda>x. P x y) net"
   335   shows "eventually (\<lambda>x. \<forall>y\<in>A. P x y) net"
   336 using assms by (induct set: finite, simp, simp add: eventually_conj)
   337 
   338 lemma eventually_all_finite:
   339   fixes P :: "'a \<Rightarrow> 'b::finite \<Rightarrow> bool"
   340   assumes "\<And>y. eventually (\<lambda>x. P x y) net"
   341   shows "eventually (\<lambda>x. \<forall>y. P x y) net"
   342 using eventually_Ball_finite [of UNIV P] assms by simp
   343 
   344 lemma eventually_mp:
   345   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   346   assumes "eventually (\<lambda>x. P x) F"
   347   shows "eventually (\<lambda>x. Q x) F"
   348 proof (rule eventually_mono)
   349   show "\<forall>x. (P x \<longrightarrow> Q x) \<and> P x \<longrightarrow> Q x" by simp
   350   show "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) F"
   351     using assms by (rule eventually_conj)
   352 qed
   353 
   354 lemma eventually_rev_mp:
   355   assumes "eventually (\<lambda>x. P x) F"
   356   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   357   shows "eventually (\<lambda>x. Q x) F"
   358 using assms(2) assms(1) by (rule eventually_mp)
   359 
   360 lemma eventually_conj_iff:
   361   "eventually (\<lambda>x. P x \<and> Q x) F \<longleftrightarrow> eventually P F \<and> eventually Q F"
   362   by (auto intro: eventually_conj elim: eventually_rev_mp)
   363 
   364 lemma eventually_elim1:
   365   assumes "eventually (\<lambda>i. P i) F"
   366   assumes "\<And>i. P i \<Longrightarrow> Q i"
   367   shows "eventually (\<lambda>i. Q i) F"
   368   using assms by (auto elim!: eventually_rev_mp)
   369 
   370 lemma eventually_elim2:
   371   assumes "eventually (\<lambda>i. P i) F"
   372   assumes "eventually (\<lambda>i. Q i) F"
   373   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
   374   shows "eventually (\<lambda>i. R i) F"
   375   using assms by (auto elim!: eventually_rev_mp)
   376 
   377 lemma eventually_subst:
   378   assumes "eventually (\<lambda>n. P n = Q n) F"
   379   shows "eventually P F = eventually Q F" (is "?L = ?R")
   380 proof -
   381   from assms have "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   382       and "eventually (\<lambda>x. Q x \<longrightarrow> P x) F"
   383     by (auto elim: eventually_elim1)
   384   then show ?thesis by (auto elim: eventually_elim2)
   385 qed
   386 
   387 ML {*
   388   fun eventually_elim_tac ctxt thms = SUBGOAL_CASES (fn (_, _, st) =>
   389     let
   390       val thy = Proof_Context.theory_of ctxt
   391       val mp_thms = thms RL [@{thm eventually_rev_mp}]
   392       val raw_elim_thm =
   393         (@{thm allI} RS @{thm always_eventually})
   394         |> fold (fn thm1 => fn thm2 => thm2 RS thm1) mp_thms
   395         |> fold (fn _ => fn thm => @{thm impI} RS thm) thms
   396       val cases_prop = prop_of (raw_elim_thm RS st)
   397       val cases = (Rule_Cases.make_common (thy, cases_prop) [(("elim", []), [])])
   398     in
   399       CASES cases (rtac raw_elim_thm 1)
   400     end) 1
   401 *}
   402 
   403 method_setup eventually_elim = {*
   404   Scan.succeed (fn ctxt => METHOD_CASES (eventually_elim_tac ctxt))
   405 *} "elimination of eventually quantifiers"
   406 
   407 
   408 subsubsection {* Finer-than relation *}
   409 
   410 text {* @{term "F \<le> F'"} means that filter @{term F} is finer than
   411 filter @{term F'}. *}
   412 
   413 instantiation filter :: (type) complete_lattice
   414 begin
   415 
   416 definition le_filter_def:
   417   "F \<le> F' \<longleftrightarrow> (\<forall>P. eventually P F' \<longrightarrow> eventually P F)"
   418 
   419 definition
   420   "(F :: 'a filter) < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   421 
   422 definition
   423   "top = Abs_filter (\<lambda>P. \<forall>x. P x)"
   424 
   425 definition
   426   "bot = Abs_filter (\<lambda>P. True)"
   427 
   428 definition
   429   "sup F F' = Abs_filter (\<lambda>P. eventually P F \<and> eventually P F')"
   430 
   431 definition
   432   "inf F F' = Abs_filter
   433       (\<lambda>P. \<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   434 
   435 definition
   436   "Sup S = Abs_filter (\<lambda>P. \<forall>F\<in>S. eventually P F)"
   437 
   438 definition
   439   "Inf S = Sup {F::'a filter. \<forall>F'\<in>S. F \<le> F'}"
   440 
   441 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
   442   unfolding top_filter_def
   443   by (rule eventually_Abs_filter, rule is_filter.intro, auto)
   444 
   445 lemma eventually_bot [simp]: "eventually P bot"
   446   unfolding bot_filter_def
   447   by (subst eventually_Abs_filter, rule is_filter.intro, auto)
   448 
   449 lemma eventually_sup:
   450   "eventually P (sup F F') \<longleftrightarrow> eventually P F \<and> eventually P F'"
   451   unfolding sup_filter_def
   452   by (rule eventually_Abs_filter, rule is_filter.intro)
   453      (auto elim!: eventually_rev_mp)
   454 
   455 lemma eventually_inf:
   456   "eventually P (inf F F') \<longleftrightarrow>
   457    (\<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   458   unfolding inf_filter_def
   459   apply (rule eventually_Abs_filter, rule is_filter.intro)
   460   apply (fast intro: eventually_True)
   461   apply clarify
   462   apply (intro exI conjI)
   463   apply (erule (1) eventually_conj)
   464   apply (erule (1) eventually_conj)
   465   apply simp
   466   apply auto
   467   done
   468 
   469 lemma eventually_Sup:
   470   "eventually P (Sup S) \<longleftrightarrow> (\<forall>F\<in>S. eventually P F)"
   471   unfolding Sup_filter_def
   472   apply (rule eventually_Abs_filter, rule is_filter.intro)
   473   apply (auto intro: eventually_conj elim!: eventually_rev_mp)
   474   done
   475 
   476 instance proof
   477   fix F F' F'' :: "'a filter" and S :: "'a filter set"
   478   { show "F < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   479     by (rule less_filter_def) }
   480   { show "F \<le> F"
   481     unfolding le_filter_def by simp }
   482   { assume "F \<le> F'" and "F' \<le> F''" thus "F \<le> F''"
   483     unfolding le_filter_def by simp }
   484   { assume "F \<le> F'" and "F' \<le> F" thus "F = F'"
   485     unfolding le_filter_def filter_eq_iff by fast }
   486   { show "inf F F' \<le> F" and "inf F F' \<le> F'"
   487     unfolding le_filter_def eventually_inf by (auto intro: eventually_True) }
   488   { assume "F \<le> F'" and "F \<le> F''" thus "F \<le> inf F' F''"
   489     unfolding le_filter_def eventually_inf
   490     by (auto elim!: eventually_mono intro: eventually_conj) }
   491   { show "F \<le> sup F F'" and "F' \<le> sup F F'"
   492     unfolding le_filter_def eventually_sup by simp_all }
   493   { assume "F \<le> F''" and "F' \<le> F''" thus "sup F F' \<le> F''"
   494     unfolding le_filter_def eventually_sup by simp }
   495   { assume "F'' \<in> S" thus "Inf S \<le> F''"
   496     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   497   { assume "\<And>F'. F' \<in> S \<Longrightarrow> F \<le> F'" thus "F \<le> Inf S"
   498     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   499   { assume "F \<in> S" thus "F \<le> Sup S"
   500     unfolding le_filter_def eventually_Sup by simp }
   501   { assume "\<And>F. F \<in> S \<Longrightarrow> F \<le> F'" thus "Sup S \<le> F'"
   502     unfolding le_filter_def eventually_Sup by simp }
   503   { show "Inf {} = (top::'a filter)"
   504     by (auto simp: top_filter_def Inf_filter_def Sup_filter_def)
   505       (metis (full_types) top_filter_def always_eventually eventually_top) }
   506   { show "Sup {} = (bot::'a filter)"
   507     by (auto simp: bot_filter_def Sup_filter_def) }
   508 qed
   509 
   510 end
   511 
   512 lemma filter_leD:
   513   "F \<le> F' \<Longrightarrow> eventually P F' \<Longrightarrow> eventually P F"
   514   unfolding le_filter_def by simp
   515 
   516 lemma filter_leI:
   517   "(\<And>P. eventually P F' \<Longrightarrow> eventually P F) \<Longrightarrow> F \<le> F'"
   518   unfolding le_filter_def by simp
   519 
   520 lemma eventually_False:
   521   "eventually (\<lambda>x. False) F \<longleftrightarrow> F = bot"
   522   unfolding filter_eq_iff by (auto elim: eventually_rev_mp)
   523 
   524 abbreviation (input) trivial_limit :: "'a filter \<Rightarrow> bool"
   525   where "trivial_limit F \<equiv> F = bot"
   526 
   527 lemma trivial_limit_def: "trivial_limit F \<longleftrightarrow> eventually (\<lambda>x. False) F"
   528   by (rule eventually_False [symmetric])
   529 
   530 lemma eventually_const: "\<not> trivial_limit net \<Longrightarrow> eventually (\<lambda>x. P) net \<longleftrightarrow> P"
   531   by (cases P) (simp_all add: eventually_False)
   532 
   533 lemma eventually_Inf: "eventually P (Inf B) \<longleftrightarrow> (\<exists>X\<subseteq>B. finite X \<and> eventually P (Inf X))"
   534 proof -
   535   let ?F = "\<lambda>P. \<exists>X\<subseteq>B. finite X \<and> eventually P (Inf X)"
   536   
   537   { fix P have "eventually P (Abs_filter ?F) \<longleftrightarrow> ?F P"
   538     proof (rule eventually_Abs_filter is_filter.intro)+
   539       show "?F (\<lambda>x. True)"
   540         by (rule exI[of _ "{}"]) (simp add: le_fun_def)
   541     next
   542       fix P Q
   543       assume "?F P" then guess X ..
   544       moreover
   545       assume "?F Q" then guess Y ..
   546       ultimately show "?F (\<lambda>x. P x \<and> Q x)"
   547         by (intro exI[of _ "X \<union> Y"])
   548            (auto simp: Inf_union_distrib eventually_inf)
   549     next
   550       fix P Q
   551       assume "?F P" then guess X ..
   552       moreover assume "\<forall>x. P x \<longrightarrow> Q x"
   553       ultimately show "?F Q"
   554         by (intro exI[of _ X]) (auto elim: eventually_elim1)
   555     qed }
   556   note eventually_F = this
   557 
   558   have "Inf B = Abs_filter ?F"
   559   proof (intro antisym Inf_greatest)
   560     show "Inf B \<le> Abs_filter ?F"
   561       by (auto simp: le_filter_def eventually_F dest: Inf_superset_mono)
   562   next
   563     fix F assume "F \<in> B" then show "Abs_filter ?F \<le> F"
   564       by (auto simp add: le_filter_def eventually_F intro!: exI[of _ "{F}"])
   565   qed
   566   then show ?thesis
   567     by (simp add: eventually_F)
   568 qed
   569 
   570 lemma eventually_INF: "eventually P (INF b:B. F b) \<longleftrightarrow> (\<exists>X\<subseteq>B. finite X \<and> eventually P (INF b:X. F b))"
   571   unfolding INF_def[of B] eventually_Inf[of P "F`B"]
   572   by (metis Inf_image_eq finite_imageI image_mono finite_subset_image)
   573 
   574 lemma Inf_filter_not_bot:
   575   fixes B :: "'a filter set"
   576   shows "(\<And>X. X \<subseteq> B \<Longrightarrow> finite X \<Longrightarrow> Inf X \<noteq> bot) \<Longrightarrow> Inf B \<noteq> bot"
   577   unfolding trivial_limit_def eventually_Inf[of _ B]
   578     bot_bool_def [symmetric] bot_fun_def [symmetric] bot_unique by simp
   579 
   580 lemma INF_filter_not_bot:
   581   fixes F :: "'i \<Rightarrow> 'a filter"
   582   shows "(\<And>X. X \<subseteq> B \<Longrightarrow> finite X \<Longrightarrow> (INF b:X. F b) \<noteq> bot) \<Longrightarrow> (INF b:B. F b) \<noteq> bot"
   583   unfolding trivial_limit_def eventually_INF[of _ B]
   584     bot_bool_def [symmetric] bot_fun_def [symmetric] bot_unique by simp
   585 
   586 lemma eventually_Inf_base:
   587   assumes "B \<noteq> {}" and base: "\<And>F G. F \<in> B \<Longrightarrow> G \<in> B \<Longrightarrow> \<exists>x\<in>B. x \<le> inf F G"
   588   shows "eventually P (Inf B) \<longleftrightarrow> (\<exists>b\<in>B. eventually P b)"
   589 proof (subst eventually_Inf, safe)
   590   fix X assume "finite X" "X \<subseteq> B"
   591   then have "\<exists>b\<in>B. \<forall>x\<in>X. b \<le> x"
   592   proof induct
   593     case empty then show ?case
   594       using `B \<noteq> {}` by auto
   595   next
   596     case (insert x X)
   597     then obtain b where "b \<in> B" "\<And>x. x \<in> X \<Longrightarrow> b \<le> x"
   598       by auto
   599     with `insert x X \<subseteq> B` base[of b x] show ?case
   600       by (auto intro: order_trans)
   601   qed
   602   then obtain b where "b \<in> B" "b \<le> Inf X"
   603     by (auto simp: le_Inf_iff)
   604   then show "eventually P (Inf X) \<Longrightarrow> Bex B (eventually P)"
   605     by (intro bexI[of _ b]) (auto simp: le_filter_def)
   606 qed (auto intro!: exI[of _ "{x}" for x])
   607 
   608 lemma eventually_INF_base:
   609   "B \<noteq> {} \<Longrightarrow> (\<And>a b. a \<in> B \<Longrightarrow> b \<in> B \<Longrightarrow> \<exists>x\<in>B. F x \<le> inf (F a) (F b)) \<Longrightarrow>
   610     eventually P (INF b:B. F b) \<longleftrightarrow> (\<exists>b\<in>B. eventually P (F b))"
   611   unfolding INF_def by (subst eventually_Inf_base) auto
   612 
   613 
   614 subsubsection {* Map function for filters *}
   615 
   616 definition filtermap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow> 'b filter"
   617   where "filtermap f F = Abs_filter (\<lambda>P. eventually (\<lambda>x. P (f x)) F)"
   618 
   619 lemma eventually_filtermap:
   620   "eventually P (filtermap f F) = eventually (\<lambda>x. P (f x)) F"
   621   unfolding filtermap_def
   622   apply (rule eventually_Abs_filter)
   623   apply (rule is_filter.intro)
   624   apply (auto elim!: eventually_rev_mp)
   625   done
   626 
   627 lemma filtermap_ident: "filtermap (\<lambda>x. x) F = F"
   628   by (simp add: filter_eq_iff eventually_filtermap)
   629 
   630 lemma filtermap_filtermap:
   631   "filtermap f (filtermap g F) = filtermap (\<lambda>x. f (g x)) F"
   632   by (simp add: filter_eq_iff eventually_filtermap)
   633 
   634 lemma filtermap_mono: "F \<le> F' \<Longrightarrow> filtermap f F \<le> filtermap f F'"
   635   unfolding le_filter_def eventually_filtermap by simp
   636 
   637 lemma filtermap_bot [simp]: "filtermap f bot = bot"
   638   by (simp add: filter_eq_iff eventually_filtermap)
   639 
   640 lemma filtermap_sup: "filtermap f (sup F1 F2) = sup (filtermap f F1) (filtermap f F2)"
   641   by (auto simp: filter_eq_iff eventually_filtermap eventually_sup)
   642 
   643 lemma filtermap_inf: "filtermap f (inf F1 F2) \<le> inf (filtermap f F1) (filtermap f F2)"
   644   by (auto simp: le_filter_def eventually_filtermap eventually_inf)
   645 
   646 lemma filtermap_INF: "filtermap f (INF b:B. F b) \<le> (INF b:B. filtermap f (F b))"
   647 proof -
   648   { fix X :: "'c set" assume "finite X"
   649     then have "filtermap f (INFIMUM X F) \<le> (INF b:X. filtermap f (F b))"
   650     proof induct
   651       case (insert x X)
   652       have "filtermap f (INF a:insert x X. F a) \<le> inf (filtermap f (F x)) (filtermap f (INF a:X. F a))"
   653         by (rule order_trans[OF _ filtermap_inf]) simp
   654       also have "\<dots> \<le> inf (filtermap f (F x)) (INF a:X. filtermap f (F a))"
   655         by (intro inf_mono insert order_refl)
   656       finally show ?case
   657         by simp
   658     qed simp }
   659   then show ?thesis
   660     unfolding le_filter_def eventually_filtermap
   661     by (subst (1 2) eventually_INF) auto
   662 qed
   663 subsubsection {* Standard filters *}
   664 
   665 definition principal :: "'a set \<Rightarrow> 'a filter" where
   666   "principal S = Abs_filter (\<lambda>P. \<forall>x\<in>S. P x)"
   667 
   668 lemma eventually_principal: "eventually P (principal S) \<longleftrightarrow> (\<forall>x\<in>S. P x)"
   669   unfolding principal_def
   670   by (rule eventually_Abs_filter, rule is_filter.intro) auto
   671 
   672 lemma eventually_inf_principal: "eventually P (inf F (principal s)) \<longleftrightarrow> eventually (\<lambda>x. x \<in> s \<longrightarrow> P x) F"
   673   unfolding eventually_inf eventually_principal by (auto elim: eventually_elim1)
   674 
   675 lemma principal_UNIV[simp]: "principal UNIV = top"
   676   by (auto simp: filter_eq_iff eventually_principal)
   677 
   678 lemma principal_empty[simp]: "principal {} = bot"
   679   by (auto simp: filter_eq_iff eventually_principal)
   680 
   681 lemma principal_eq_bot_iff: "principal X = bot \<longleftrightarrow> X = {}"
   682   by (auto simp add: filter_eq_iff eventually_principal)
   683 
   684 lemma principal_le_iff[iff]: "principal A \<le> principal B \<longleftrightarrow> A \<subseteq> B"
   685   by (auto simp: le_filter_def eventually_principal)
   686 
   687 lemma le_principal: "F \<le> principal A \<longleftrightarrow> eventually (\<lambda>x. x \<in> A) F"
   688   unfolding le_filter_def eventually_principal
   689   apply safe
   690   apply (erule_tac x="\<lambda>x. x \<in> A" in allE)
   691   apply (auto elim: eventually_elim1)
   692   done
   693 
   694 lemma principal_inject[iff]: "principal A = principal B \<longleftrightarrow> A = B"
   695   unfolding eq_iff by simp
   696 
   697 lemma sup_principal[simp]: "sup (principal A) (principal B) = principal (A \<union> B)"
   698   unfolding filter_eq_iff eventually_sup eventually_principal by auto
   699 
   700 lemma inf_principal[simp]: "inf (principal A) (principal B) = principal (A \<inter> B)"
   701   unfolding filter_eq_iff eventually_inf eventually_principal
   702   by (auto intro: exI[of _ "\<lambda>x. x \<in> A"] exI[of _ "\<lambda>x. x \<in> B"])
   703 
   704 lemma SUP_principal[simp]: "(SUP i : I. principal (A i)) = principal (\<Union>i\<in>I. A i)"
   705   unfolding filter_eq_iff eventually_Sup SUP_def by (auto simp: eventually_principal)
   706 
   707 lemma INF_principal_finite: "finite X \<Longrightarrow> (INF x:X. principal (f x)) = principal (\<Inter>x\<in>X. f x)"
   708   by (induct X rule: finite_induct) auto
   709 
   710 lemma filtermap_principal[simp]: "filtermap f (principal A) = principal (f ` A)"
   711   unfolding filter_eq_iff eventually_filtermap eventually_principal by simp
   712 
   713 subsubsection {* Order filters *}
   714 
   715 definition at_top :: "('a::order) filter"
   716   where "at_top = (INF k. principal {k ..})"
   717 
   718 lemma eventually_at_top_linorder: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::linorder. \<forall>n\<ge>N. P n)"
   719   unfolding at_top_def
   720   by (subst eventually_INF_base) (auto simp: eventually_principal intro: max.cobounded1 max.cobounded2)
   721 
   722 lemma eventually_ge_at_top:
   723   "eventually (\<lambda>x. (c::_::linorder) \<le> x) at_top"
   724   unfolding eventually_at_top_linorder by auto
   725 
   726 lemma (in linorder) Ici_subset_Ioi_iff: "{a ..} \<subseteq> {b <..} \<longleftrightarrow> b < a"
   727   by auto
   728 
   729 lemma (in linorder) Iic_subset_Iio_iff: "{.. a} \<subseteq> {..< b} \<longleftrightarrow> a < b"
   730   by auto
   731 
   732 lemma eventually_at_top_dense: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::{no_top, linorder}. \<forall>n>N. P n)"
   733 proof -
   734   have "eventually P (INF k. principal {k <..}) \<longleftrightarrow> (\<exists>N::'a. \<forall>n>N. P n)"
   735     by (subst eventually_INF_base) (auto simp: eventually_principal intro: max.cobounded1 max.cobounded2)
   736   also have "(INF k. principal {k::'a <..}) = at_top"
   737     unfolding at_top_def 
   738     by (intro INF_eq) (auto intro: less_imp_le simp: Ici_subset_Ioi_iff gt_ex)
   739   finally show ?thesis .
   740 qed
   741 
   742 lemma eventually_gt_at_top:
   743   "eventually (\<lambda>x. (c::_::unbounded_dense_linorder) < x) at_top"
   744   unfolding eventually_at_top_dense by auto
   745 
   746 definition at_bot :: "('a::order) filter"
   747   where "at_bot = (INF k. principal {.. k})"
   748 
   749 lemma eventually_at_bot_linorder:
   750   fixes P :: "'a::linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n\<le>N. P n)"
   751   unfolding at_bot_def
   752   by (subst eventually_INF_base) (auto simp: eventually_principal intro: min.cobounded1 min.cobounded2)
   753 
   754 lemma eventually_le_at_bot:
   755   "eventually (\<lambda>x. x \<le> (c::_::linorder)) at_bot"
   756   unfolding eventually_at_bot_linorder by auto
   757 
   758 lemma eventually_at_bot_dense: "eventually P at_bot \<longleftrightarrow> (\<exists>N::'a::{no_bot, linorder}. \<forall>n<N. P n)"
   759 proof -
   760   have "eventually P (INF k. principal {..< k}) \<longleftrightarrow> (\<exists>N::'a. \<forall>n<N. P n)"
   761     by (subst eventually_INF_base) (auto simp: eventually_principal intro: min.cobounded1 min.cobounded2)
   762   also have "(INF k. principal {..< k::'a}) = at_bot"
   763     unfolding at_bot_def 
   764     by (intro INF_eq) (auto intro: less_imp_le simp: Iic_subset_Iio_iff lt_ex)
   765   finally show ?thesis .
   766 qed
   767 
   768 lemma eventually_gt_at_bot:
   769   "eventually (\<lambda>x. x < (c::_::unbounded_dense_linorder)) at_bot"
   770   unfolding eventually_at_bot_dense by auto
   771 
   772 lemma trivial_limit_at_bot_linorder: "\<not> trivial_limit (at_bot ::('a::linorder) filter)"
   773   unfolding trivial_limit_def
   774   by (metis eventually_at_bot_linorder order_refl)
   775 
   776 lemma trivial_limit_at_top_linorder: "\<not> trivial_limit (at_top ::('a::linorder) filter)"
   777   unfolding trivial_limit_def
   778   by (metis eventually_at_top_linorder order_refl)
   779 
   780 subsection {* Sequentially *}
   781 
   782 abbreviation sequentially :: "nat filter"
   783   where "sequentially \<equiv> at_top"
   784 
   785 lemma eventually_sequentially:
   786   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   787   by (rule eventually_at_top_linorder)
   788 
   789 lemma sequentially_bot [simp, intro]: "sequentially \<noteq> bot"
   790   unfolding filter_eq_iff eventually_sequentially by auto
   791 
   792 lemmas trivial_limit_sequentially = sequentially_bot
   793 
   794 lemma eventually_False_sequentially [simp]:
   795   "\<not> eventually (\<lambda>n. False) sequentially"
   796   by (simp add: eventually_False)
   797 
   798 lemma le_sequentially:
   799   "F \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) F)"
   800   by (simp add: at_top_def le_INF_iff le_principal)
   801 
   802 lemma eventually_sequentiallyI:
   803   assumes "\<And>x. c \<le> x \<Longrightarrow> P x"
   804   shows "eventually P sequentially"
   805 using assms by (auto simp: eventually_sequentially)
   806 
   807 lemma eventually_sequentially_seg:
   808   "eventually (\<lambda>n. P (n + k)) sequentially \<longleftrightarrow> eventually P sequentially"
   809   unfolding eventually_sequentially
   810   apply safe
   811    apply (rule_tac x="N + k" in exI)
   812    apply rule
   813    apply (erule_tac x="n - k" in allE)
   814    apply auto []
   815   apply (rule_tac x=N in exI)
   816   apply auto []
   817   done
   818 
   819 subsubsection {* Topological filters *}
   820 
   821 definition (in topological_space) nhds :: "'a \<Rightarrow> 'a filter"
   822   where "nhds a = (INF S:{S. open S \<and> a \<in> S}. principal S)"
   823 
   824 definition (in topological_space) at_within :: "'a \<Rightarrow> 'a set \<Rightarrow> 'a filter" ("at (_) within (_)" [1000, 60] 60)
   825   where "at a within s = inf (nhds a) (principal (s - {a}))"
   826 
   827 abbreviation (in topological_space) at :: "'a \<Rightarrow> 'a filter" ("at") where
   828   "at x \<equiv> at x within (CONST UNIV)"
   829 
   830 abbreviation (in order_topology) at_right :: "'a \<Rightarrow> 'a filter" where
   831   "at_right x \<equiv> at x within {x <..}"
   832 
   833 abbreviation (in order_topology) at_left :: "'a \<Rightarrow> 'a filter" where
   834   "at_left x \<equiv> at x within {..< x}"
   835 
   836 lemma (in topological_space) eventually_nhds:
   837   "eventually P (nhds a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   838   unfolding nhds_def by (subst eventually_INF_base) (auto simp: eventually_principal)
   839 
   840 lemma nhds_neq_bot [simp]: "nhds a \<noteq> bot"
   841   unfolding trivial_limit_def eventually_nhds by simp
   842 
   843 lemma eventually_at_filter:
   844   "eventually P (at a within s) \<longleftrightarrow> eventually (\<lambda>x. x \<noteq> a \<longrightarrow> x \<in> s \<longrightarrow> P x) (nhds a)"
   845   unfolding at_within_def eventually_inf_principal by (simp add: imp_conjL[symmetric] conj_commute)
   846 
   847 lemma at_le: "s \<subseteq> t \<Longrightarrow> at x within s \<le> at x within t"
   848   unfolding at_within_def by (intro inf_mono) auto
   849 
   850 lemma eventually_at_topological:
   851   "eventually P (at a within s) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> x \<in> s \<longrightarrow> P x))"
   852   unfolding eventually_nhds eventually_at_filter by simp
   853 
   854 lemma at_within_open: "a \<in> S \<Longrightarrow> open S \<Longrightarrow> at a within S = at a"
   855   unfolding filter_eq_iff eventually_at_topological by (metis open_Int Int_iff UNIV_I)
   856 
   857 lemma at_within_empty [simp]: "at a within {} = bot"
   858   unfolding at_within_def by simp
   859 
   860 lemma at_within_union: "at x within (S \<union> T) = sup (at x within S) (at x within T)"
   861   unfolding filter_eq_iff eventually_sup eventually_at_filter
   862   by (auto elim!: eventually_rev_mp)
   863 
   864 lemma at_eq_bot_iff: "at a = bot \<longleftrightarrow> open {a}"
   865   unfolding trivial_limit_def eventually_at_topological
   866   by (safe, case_tac "S = {a}", simp, fast, fast)
   867 
   868 lemma at_neq_bot [simp]: "at (a::'a::perfect_space) \<noteq> bot"
   869   by (simp add: at_eq_bot_iff not_open_singleton)
   870 
   871 lemma eventually_at_right:
   872   fixes x :: "'a :: linorder_topology"
   873   assumes gt_ex: "x < y"
   874   shows "eventually P (at_right x) \<longleftrightarrow> (\<exists>b. x < b \<and> (\<forall>z. x < z \<and> z < b \<longrightarrow> P z))"
   875   unfolding eventually_at_topological
   876 proof safe
   877   note gt_ex
   878   moreover fix S assume "open S" "x \<in> S" note open_right[OF this, of y]
   879   moreover assume "\<forall>s\<in>S. s \<noteq> x \<longrightarrow> s \<in> {x<..} \<longrightarrow> P s"
   880   ultimately show "\<exists>b>x. \<forall>z. x < z \<and> z < b \<longrightarrow> P z"
   881     by (auto simp: subset_eq Ball_def)
   882 next
   883   fix b assume "x < b" "\<forall>z. x < z \<and> z < b \<longrightarrow> P z"
   884   then show "\<exists>S. open S \<and> x \<in> S \<and> (\<forall>xa\<in>S. xa \<noteq> x \<longrightarrow> xa \<in> {x<..} \<longrightarrow> P xa)"
   885     by (intro exI[of _ "{..< b}"]) auto
   886 qed
   887 
   888 lemma eventually_at_left:
   889   fixes x :: "'a :: linorder_topology"
   890   assumes lt_ex: "y < x"
   891   shows "eventually P (at_left x) \<longleftrightarrow> (\<exists>b. x > b \<and> (\<forall>z. b < z \<and> z < x \<longrightarrow> P z))"
   892   unfolding eventually_at_topological
   893 proof safe
   894   note lt_ex
   895   moreover fix S assume "open S" "x \<in> S" note open_left[OF this, of y]
   896   moreover assume "\<forall>s\<in>S. s \<noteq> x \<longrightarrow> s \<in> {..<x} \<longrightarrow> P s"
   897   ultimately show "\<exists>b<x. \<forall>z. b < z \<and> z < x \<longrightarrow> P z"
   898     by (auto simp: subset_eq Ball_def)
   899 next
   900   fix b assume "b < x" "\<forall>z. b < z \<and> z < x \<longrightarrow> P z"
   901   then show "\<exists>S. open S \<and> x \<in> S \<and> (\<forall>s\<in>S. s \<noteq> x \<longrightarrow> s \<in> {..<x} \<longrightarrow> P s)"
   902     by (intro exI[of _ "{b <..}"]) auto
   903 qed
   904 
   905 lemma trivial_limit_at_right_top: "at_right (top::_::{order_top, linorder_topology}) = bot"
   906   unfolding filter_eq_iff eventually_at_topological by auto
   907 
   908 lemma trivial_limit_at_left_bot: "at_left (bot::_::{order_bot, linorder_topology}) = bot"
   909   unfolding filter_eq_iff eventually_at_topological by auto
   910 
   911 lemma trivial_limit_at_left_real [simp]:
   912   "\<not> trivial_limit (at_left (x::'a::{no_bot, dense_order, linorder_topology}))"
   913   using lt_ex[of x]
   914   by safe (auto simp add: trivial_limit_def eventually_at_left dest: dense)
   915 
   916 lemma trivial_limit_at_right_real [simp]:
   917   "\<not> trivial_limit (at_right (x::'a::{no_top, dense_order, linorder_topology}))"
   918   using gt_ex[of x]
   919   by safe (auto simp add: trivial_limit_def eventually_at_right dest: dense)
   920 
   921 lemma at_eq_sup_left_right: "at (x::'a::linorder_topology) = sup (at_left x) (at_right x)"
   922   by (auto simp: eventually_at_filter filter_eq_iff eventually_sup 
   923            elim: eventually_elim2 eventually_elim1)
   924 
   925 lemma eventually_at_split:
   926   "eventually P (at (x::'a::linorder_topology)) \<longleftrightarrow> eventually P (at_left x) \<and> eventually P (at_right x)"
   927   by (subst at_eq_sup_left_right) (simp add: eventually_sup)
   928 
   929 subsection {* Limits *}
   930 
   931 definition filterlim :: "('a \<Rightarrow> 'b) \<Rightarrow> 'b filter \<Rightarrow> 'a filter \<Rightarrow> bool" where
   932   "filterlim f F2 F1 \<longleftrightarrow> filtermap f F1 \<le> F2"
   933 
   934 syntax
   935   "_LIM" :: "pttrns \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> bool" ("(3LIM (_)/ (_)./ (_) :> (_))" [1000, 10, 0, 10] 10)
   936 
   937 translations
   938   "LIM x F1. f :> F2"   == "CONST filterlim (%x. f) F2 F1"
   939 
   940 lemma filterlim_iff:
   941   "(LIM x F1. f x :> F2) \<longleftrightarrow> (\<forall>P. eventually P F2 \<longrightarrow> eventually (\<lambda>x. P (f x)) F1)"
   942   unfolding filterlim_def le_filter_def eventually_filtermap ..
   943 
   944 lemma filterlim_compose:
   945   "filterlim g F3 F2 \<Longrightarrow> filterlim f F2 F1 \<Longrightarrow> filterlim (\<lambda>x. g (f x)) F3 F1"
   946   unfolding filterlim_def filtermap_filtermap[symmetric] by (metis filtermap_mono order_trans)
   947 
   948 lemma filterlim_mono:
   949   "filterlim f F2 F1 \<Longrightarrow> F2 \<le> F2' \<Longrightarrow> F1' \<le> F1 \<Longrightarrow> filterlim f F2' F1'"
   950   unfolding filterlim_def by (metis filtermap_mono order_trans)
   951 
   952 lemma filterlim_ident: "LIM x F. x :> F"
   953   by (simp add: filterlim_def filtermap_ident)
   954 
   955 lemma filterlim_cong:
   956   "F1 = F1' \<Longrightarrow> F2 = F2' \<Longrightarrow> eventually (\<lambda>x. f x = g x) F2 \<Longrightarrow> filterlim f F1 F2 = filterlim g F1' F2'"
   957   by (auto simp: filterlim_def le_filter_def eventually_filtermap elim: eventually_elim2)
   958 
   959 lemma filterlim_mono_eventually:
   960   assumes "filterlim f F G" and ord: "F \<le> F'" "G' \<le> G"
   961   assumes eq: "eventually (\<lambda>x. f x = f' x) G'"
   962   shows "filterlim f' F' G'"
   963   apply (rule filterlim_cong[OF refl refl eq, THEN iffD1])
   964   apply (rule filterlim_mono[OF _ ord])
   965   apply fact
   966   done
   967 
   968 lemma filterlim_principal:
   969   "(LIM x F. f x :> principal S) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> S) F)"
   970   unfolding filterlim_def eventually_filtermap le_principal ..
   971 
   972 lemma filterlim_inf:
   973   "(LIM x F1. f x :> inf F2 F3) \<longleftrightarrow> ((LIM x F1. f x :> F2) \<and> (LIM x F1. f x :> F3))"
   974   unfolding filterlim_def by simp
   975 
   976 lemma filterlim_INF:
   977   "(LIM x F. f x :> (INF b:B. G b)) \<longleftrightarrow> (\<forall>b\<in>B. LIM x F. f x :> G b)"
   978   unfolding filterlim_def le_INF_iff ..
   979 
   980 lemma filterlim_filtermap: "filterlim f F1 (filtermap g F2) = filterlim (\<lambda>x. f (g x)) F1 F2"
   981   unfolding filterlim_def filtermap_filtermap ..
   982 
   983 lemma filterlim_sup:
   984   "filterlim f F F1 \<Longrightarrow> filterlim f F F2 \<Longrightarrow> filterlim f F (sup F1 F2)"
   985   unfolding filterlim_def filtermap_sup by auto
   986 
   987 lemma filterlim_Suc: "filterlim Suc sequentially sequentially"
   988   by (simp add: filterlim_iff eventually_sequentially) (metis le_Suc_eq)
   989 
   990 subsubsection {* Tendsto *}
   991 
   992 abbreviation (in topological_space)
   993   tendsto :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b filter \<Rightarrow> bool" (infixr "--->" 55) where
   994   "(f ---> l) F \<equiv> filterlim f (nhds l) F"
   995 
   996 definition (in t2_space) Lim :: "'f filter \<Rightarrow> ('f \<Rightarrow> 'a) \<Rightarrow> 'a" where
   997   "Lim A f = (THE l. (f ---> l) A)"
   998 
   999 lemma tendsto_eq_rhs: "(f ---> x) F \<Longrightarrow> x = y \<Longrightarrow> (f ---> y) F"
  1000   by simp
  1001 
  1002 ML {*
  1003 
  1004 structure Tendsto_Intros = Named_Thms
  1005 (
  1006   val name = @{binding tendsto_intros}
  1007   val description = "introduction rules for tendsto"
  1008 )
  1009 
  1010 *}
  1011 
  1012 setup {*
  1013   Tendsto_Intros.setup #>
  1014   Global_Theory.add_thms_dynamic (@{binding tendsto_eq_intros},
  1015     map_filter (try (fn thm => @{thm tendsto_eq_rhs} OF [thm])) o Tendsto_Intros.get o Context.proof_of);
  1016 *}
  1017 
  1018 lemma (in topological_space) tendsto_def:
  1019    "(f ---> l) F \<longleftrightarrow> (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) F)"
  1020    unfolding nhds_def filterlim_INF filterlim_principal by auto
  1021 
  1022 lemma tendsto_mono: "F \<le> F' \<Longrightarrow> (f ---> l) F' \<Longrightarrow> (f ---> l) F"
  1023   unfolding tendsto_def le_filter_def by fast
  1024 
  1025 lemma tendsto_within_subset: "(f ---> l) (at x within S) \<Longrightarrow> T \<subseteq> S \<Longrightarrow> (f ---> l) (at x within T)"
  1026   by (blast intro: tendsto_mono at_le)
  1027 
  1028 lemma filterlim_at:
  1029   "(LIM x F. f x :> at b within s) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> s \<and> f x \<noteq> b) F \<and> (f ---> b) F)"
  1030   by (simp add: at_within_def filterlim_inf filterlim_principal conj_commute)
  1031 
  1032 lemma (in topological_space) topological_tendstoI:
  1033   "(\<And>S. open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F) \<Longrightarrow> (f ---> l) F"
  1034   unfolding tendsto_def by auto
  1035 
  1036 lemma (in topological_space) topological_tendstoD:
  1037   "(f ---> l) F \<Longrightarrow> open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F"
  1038   unfolding tendsto_def by auto
  1039 
  1040 lemma order_tendstoI:
  1041   fixes y :: "_ :: order_topology"
  1042   assumes "\<And>a. a < y \<Longrightarrow> eventually (\<lambda>x. a < f x) F"
  1043   assumes "\<And>a. y < a \<Longrightarrow> eventually (\<lambda>x. f x < a) F"
  1044   shows "(f ---> y) F"
  1045 proof (rule topological_tendstoI)
  1046   fix S assume "open S" "y \<in> S"
  1047   then show "eventually (\<lambda>x. f x \<in> S) F"
  1048     unfolding open_generated_order
  1049   proof induct
  1050     case (UN K)
  1051     then obtain k where "y \<in> k" "k \<in> K" by auto
  1052     with UN(2)[of k] show ?case
  1053       by (auto elim: eventually_elim1)
  1054   qed (insert assms, auto elim: eventually_elim2)
  1055 qed
  1056 
  1057 lemma order_tendstoD:
  1058   fixes y :: "_ :: order_topology"
  1059   assumes y: "(f ---> y) F"
  1060   shows "a < y \<Longrightarrow> eventually (\<lambda>x. a < f x) F"
  1061     and "y < a \<Longrightarrow> eventually (\<lambda>x. f x < a) F"
  1062   using topological_tendstoD[OF y, of "{..< a}"] topological_tendstoD[OF y, of "{a <..}"] by auto
  1063 
  1064 lemma order_tendsto_iff: 
  1065   fixes f :: "_ \<Rightarrow> 'a :: order_topology"
  1066   shows "(f ---> x) F \<longleftrightarrow>(\<forall>l<x. eventually (\<lambda>x. l < f x) F) \<and> (\<forall>u>x. eventually (\<lambda>x. f x < u) F)"
  1067   by (metis order_tendstoI order_tendstoD)
  1068 
  1069 lemma tendsto_bot [simp]: "(f ---> a) bot"
  1070   unfolding tendsto_def by simp
  1071 
  1072 lemma tendsto_max:
  1073   fixes x y :: "'a::linorder_topology"
  1074   assumes X: "(X ---> x) net"
  1075   assumes Y: "(Y ---> y) net"
  1076   shows "((\<lambda>x. max (X x) (Y x)) ---> max x y) net"
  1077 proof (rule order_tendstoI)
  1078   fix a assume "a < max x y"
  1079   then show "eventually (\<lambda>x. a < max (X x) (Y x)) net"
  1080     using order_tendstoD(1)[OF X, of a] order_tendstoD(1)[OF Y, of a]
  1081     by (auto simp: less_max_iff_disj elim: eventually_elim1)
  1082 next
  1083   fix a assume "max x y < a"
  1084   then show "eventually (\<lambda>x. max (X x) (Y x) < a) net"
  1085     using order_tendstoD(2)[OF X, of a] order_tendstoD(2)[OF Y, of a]
  1086     by (auto simp: eventually_conj_iff)
  1087 qed
  1088 
  1089 lemma tendsto_min:
  1090   fixes x y :: "'a::linorder_topology"
  1091   assumes X: "(X ---> x) net"
  1092   assumes Y: "(Y ---> y) net"
  1093   shows "((\<lambda>x. min (X x) (Y x)) ---> min x y) net"
  1094 proof (rule order_tendstoI)
  1095   fix a assume "a < min x y"
  1096   then show "eventually (\<lambda>x. a < min (X x) (Y x)) net"
  1097     using order_tendstoD(1)[OF X, of a] order_tendstoD(1)[OF Y, of a]
  1098     by (auto simp: eventually_conj_iff)
  1099 next
  1100   fix a assume "min x y < a"
  1101   then show "eventually (\<lambda>x. min (X x) (Y x) < a) net"
  1102     using order_tendstoD(2)[OF X, of a] order_tendstoD(2)[OF Y, of a]
  1103     by (auto simp: min_less_iff_disj elim: eventually_elim1)
  1104 qed
  1105 
  1106 
  1107 lemma tendsto_ident_at [tendsto_intros]: "((\<lambda>x. x) ---> a) (at a within s)"
  1108   unfolding tendsto_def eventually_at_topological by auto
  1109 
  1110 lemma (in topological_space) tendsto_const [tendsto_intros]: "((\<lambda>x. k) ---> k) F"
  1111   by (simp add: tendsto_def)
  1112 
  1113 lemma (in t2_space) tendsto_unique:
  1114   assumes "\<not> trivial_limit F" and "(f ---> a) F" and "(f ---> b) F"
  1115   shows "a = b"
  1116 proof (rule ccontr)
  1117   assume "a \<noteq> b"
  1118   obtain U V where "open U" "open V" "a \<in> U" "b \<in> V" "U \<inter> V = {}"
  1119     using hausdorff [OF `a \<noteq> b`] by fast
  1120   have "eventually (\<lambda>x. f x \<in> U) F"
  1121     using `(f ---> a) F` `open U` `a \<in> U` by (rule topological_tendstoD)
  1122   moreover
  1123   have "eventually (\<lambda>x. f x \<in> V) F"
  1124     using `(f ---> b) F` `open V` `b \<in> V` by (rule topological_tendstoD)
  1125   ultimately
  1126   have "eventually (\<lambda>x. False) F"
  1127   proof eventually_elim
  1128     case (elim x)
  1129     hence "f x \<in> U \<inter> V" by simp
  1130     with `U \<inter> V = {}` show ?case by simp
  1131   qed
  1132   with `\<not> trivial_limit F` show "False"
  1133     by (simp add: trivial_limit_def)
  1134 qed
  1135 
  1136 lemma (in t2_space) tendsto_const_iff:
  1137   assumes "\<not> trivial_limit F" shows "((\<lambda>x. a :: 'a) ---> b) F \<longleftrightarrow> a = b"
  1138   by (safe intro!: tendsto_const tendsto_unique [OF assms tendsto_const])
  1139 
  1140 lemma increasing_tendsto:
  1141   fixes f :: "_ \<Rightarrow> 'a::order_topology"
  1142   assumes bdd: "eventually (\<lambda>n. f n \<le> l) F"
  1143       and en: "\<And>x. x < l \<Longrightarrow> eventually (\<lambda>n. x < f n) F"
  1144   shows "(f ---> l) F"
  1145   using assms by (intro order_tendstoI) (auto elim!: eventually_elim1)
  1146 
  1147 lemma decreasing_tendsto:
  1148   fixes f :: "_ \<Rightarrow> 'a::order_topology"
  1149   assumes bdd: "eventually (\<lambda>n. l \<le> f n) F"
  1150       and en: "\<And>x. l < x \<Longrightarrow> eventually (\<lambda>n. f n < x) F"
  1151   shows "(f ---> l) F"
  1152   using assms by (intro order_tendstoI) (auto elim!: eventually_elim1)
  1153 
  1154 lemma tendsto_sandwich:
  1155   fixes f g h :: "'a \<Rightarrow> 'b::order_topology"
  1156   assumes ev: "eventually (\<lambda>n. f n \<le> g n) net" "eventually (\<lambda>n. g n \<le> h n) net"
  1157   assumes lim: "(f ---> c) net" "(h ---> c) net"
  1158   shows "(g ---> c) net"
  1159 proof (rule order_tendstoI)
  1160   fix a show "a < c \<Longrightarrow> eventually (\<lambda>x. a < g x) net"
  1161     using order_tendstoD[OF lim(1), of a] ev by (auto elim: eventually_elim2)
  1162 next
  1163   fix a show "c < a \<Longrightarrow> eventually (\<lambda>x. g x < a) net"
  1164     using order_tendstoD[OF lim(2), of a] ev by (auto elim: eventually_elim2)
  1165 qed
  1166 
  1167 lemma tendsto_le:
  1168   fixes f g :: "'a \<Rightarrow> 'b::linorder_topology"
  1169   assumes F: "\<not> trivial_limit F"
  1170   assumes x: "(f ---> x) F" and y: "(g ---> y) F"
  1171   assumes ev: "eventually (\<lambda>x. g x \<le> f x) F"
  1172   shows "y \<le> x"
  1173 proof (rule ccontr)
  1174   assume "\<not> y \<le> x"
  1175   with less_separate[of x y] obtain a b where xy: "x < a" "b < y" "{..<a} \<inter> {b<..} = {}"
  1176     by (auto simp: not_le)
  1177   then have "eventually (\<lambda>x. f x < a) F" "eventually (\<lambda>x. b < g x) F"
  1178     using x y by (auto intro: order_tendstoD)
  1179   with ev have "eventually (\<lambda>x. False) F"
  1180     by eventually_elim (insert xy, fastforce)
  1181   with F show False
  1182     by (simp add: eventually_False)
  1183 qed
  1184 
  1185 lemma tendsto_le_const:
  1186   fixes f :: "'a \<Rightarrow> 'b::linorder_topology"
  1187   assumes F: "\<not> trivial_limit F"
  1188   assumes x: "(f ---> x) F" and a: "eventually (\<lambda>i. a \<le> f i) F"
  1189   shows "a \<le> x"
  1190   using F x tendsto_const a by (rule tendsto_le)
  1191 
  1192 lemma tendsto_ge_const:
  1193   fixes f :: "'a \<Rightarrow> 'b::linorder_topology"
  1194   assumes F: "\<not> trivial_limit F"
  1195   assumes x: "(f ---> x) F" and a: "eventually (\<lambda>i. a \<ge> f i) F"
  1196   shows "a \<ge> x"
  1197   by (rule tendsto_le [OF F tendsto_const x a])
  1198 
  1199 subsubsection {* Rules about @{const Lim} *}
  1200 
  1201 lemma tendsto_Lim:
  1202   "\<not>(trivial_limit net) \<Longrightarrow> (f ---> l) net \<Longrightarrow> Lim net f = l"
  1203   unfolding Lim_def using tendsto_unique[of net f] by auto
  1204 
  1205 lemma Lim_ident_at: "\<not> trivial_limit (at x within s) \<Longrightarrow> Lim (at x within s) (\<lambda>x. x) = x"
  1206   by (rule tendsto_Lim[OF _ tendsto_ident_at]) auto
  1207 
  1208 subsection {* Limits to @{const at_top} and @{const at_bot} *}
  1209 
  1210 lemma filterlim_at_top:
  1211   fixes f :: "'a \<Rightarrow> ('b::linorder)"
  1212   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z \<le> f x) F)"
  1213   by (auto simp: filterlim_iff eventually_at_top_linorder elim!: eventually_elim1)
  1214 
  1215 lemma filterlim_at_top_dense:
  1216   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)"
  1217   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z < f x) F)"
  1218   by (metis eventually_elim1[of _ F] eventually_gt_at_top order_less_imp_le
  1219             filterlim_at_top[of f F] filterlim_iff[of f at_top F])
  1220 
  1221 lemma filterlim_at_top_ge:
  1222   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
  1223   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z\<ge>c. eventually (\<lambda>x. Z \<le> f x) F)"
  1224   unfolding filterlim_at_top
  1225 proof safe
  1226   fix Z assume *: "\<forall>Z\<ge>c. eventually (\<lambda>x. Z \<le> f x) F"
  1227   with *[THEN spec, of "max Z c"] show "eventually (\<lambda>x. Z \<le> f x) F"
  1228     by (auto elim!: eventually_elim1)
  1229 qed simp
  1230 
  1231 lemma filterlim_at_top_at_top:
  1232   fixes f :: "'a::linorder \<Rightarrow> 'b::linorder"
  1233   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1234   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1235   assumes Q: "eventually Q at_top"
  1236   assumes P: "eventually P at_top"
  1237   shows "filterlim f at_top at_top"
  1238 proof -
  1239   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
  1240     unfolding eventually_at_top_linorder by auto
  1241   show ?thesis
  1242   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
  1243     fix z assume "x \<le> z"
  1244     with x have "P z" by auto
  1245     have "eventually (\<lambda>x. g z \<le> x) at_top"
  1246       by (rule eventually_ge_at_top)
  1247     with Q show "eventually (\<lambda>x. z \<le> f x) at_top"
  1248       by eventually_elim (metis mono bij `P z`)
  1249   qed
  1250 qed
  1251 
  1252 lemma filterlim_at_top_gt:
  1253   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
  1254   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z>c. eventually (\<lambda>x. Z \<le> f x) F)"
  1255   by (metis filterlim_at_top order_less_le_trans gt_ex filterlim_at_top_ge)
  1256 
  1257 lemma filterlim_at_bot: 
  1258   fixes f :: "'a \<Rightarrow> ('b::linorder)"
  1259   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F)"
  1260   by (auto simp: filterlim_iff eventually_at_bot_linorder elim!: eventually_elim1)
  1261 
  1262 lemma filterlim_at_bot_le:
  1263   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
  1264   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F)"
  1265   unfolding filterlim_at_bot
  1266 proof safe
  1267   fix Z assume *: "\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F"
  1268   with *[THEN spec, of "min Z c"] show "eventually (\<lambda>x. Z \<ge> f x) F"
  1269     by (auto elim!: eventually_elim1)
  1270 qed simp
  1271 
  1272 lemma filterlim_at_bot_lt:
  1273   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
  1274   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z<c. eventually (\<lambda>x. Z \<ge> f x) F)"
  1275   by (metis filterlim_at_bot filterlim_at_bot_le lt_ex order_le_less_trans)
  1276 
  1277 lemma filterlim_at_bot_at_right:
  1278   fixes f :: "'a::linorder_topology \<Rightarrow> 'b::linorder"
  1279   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1280   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1281   assumes Q: "eventually Q (at_right a)" and bound: "\<And>b. Q b \<Longrightarrow> a < b"
  1282   assumes P: "eventually P at_bot"
  1283   shows "filterlim f at_bot (at_right a)"
  1284 proof -
  1285   from P obtain x where x: "\<And>y. y \<le> x \<Longrightarrow> P y"
  1286     unfolding eventually_at_bot_linorder by auto
  1287   show ?thesis
  1288   proof (intro filterlim_at_bot_le[THEN iffD2] allI impI)
  1289     fix z assume "z \<le> x"
  1290     with x have "P z" by auto
  1291     have "eventually (\<lambda>x. x \<le> g z) (at_right a)"
  1292       using bound[OF bij(2)[OF `P z`]]
  1293       unfolding eventually_at_right[OF bound[OF bij(2)[OF `P z`]]] by (auto intro!: exI[of _ "g z"])
  1294     with Q show "eventually (\<lambda>x. f x \<le> z) (at_right a)"
  1295       by eventually_elim (metis bij `P z` mono)
  1296   qed
  1297 qed
  1298 
  1299 lemma filterlim_at_top_at_left:
  1300   fixes f :: "'a::linorder_topology \<Rightarrow> 'b::linorder"
  1301   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1302   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1303   assumes Q: "eventually Q (at_left a)" and bound: "\<And>b. Q b \<Longrightarrow> b < a"
  1304   assumes P: "eventually P at_top"
  1305   shows "filterlim f at_top (at_left a)"
  1306 proof -
  1307   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
  1308     unfolding eventually_at_top_linorder by auto
  1309   show ?thesis
  1310   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
  1311     fix z assume "x \<le> z"
  1312     with x have "P z" by auto
  1313     have "eventually (\<lambda>x. g z \<le> x) (at_left a)"
  1314       using bound[OF bij(2)[OF `P z`]]
  1315       unfolding eventually_at_left[OF bound[OF bij(2)[OF `P z`]]] by (auto intro!: exI[of _ "g z"])
  1316     with Q show "eventually (\<lambda>x. z \<le> f x) (at_left a)"
  1317       by eventually_elim (metis bij `P z` mono)
  1318   qed
  1319 qed
  1320 
  1321 lemma filterlim_split_at:
  1322   "filterlim f F (at_left x) \<Longrightarrow> filterlim f F (at_right x) \<Longrightarrow> filterlim f F (at (x::'a::linorder_topology))"
  1323   by (subst at_eq_sup_left_right) (rule filterlim_sup)
  1324 
  1325 lemma filterlim_at_split:
  1326   "filterlim f F (at (x::'a::linorder_topology)) \<longleftrightarrow> filterlim f F (at_left x) \<and> filterlim f F (at_right x)"
  1327   by (subst at_eq_sup_left_right) (simp add: filterlim_def filtermap_sup)
  1328 
  1329 lemma eventually_nhds_top:
  1330   fixes P :: "'a :: {order_top, linorder_topology} \<Rightarrow> bool"
  1331   assumes "(b::'a) < top"
  1332   shows "eventually P (nhds top) \<longleftrightarrow> (\<exists>b<top. (\<forall>z. b < z \<longrightarrow> P z))"
  1333   unfolding eventually_nhds
  1334 proof safe
  1335   fix S :: "'a set" assume "open S" "top \<in> S"
  1336   note open_left[OF this `b < top`]
  1337   moreover assume "\<forall>s\<in>S. P s"
  1338   ultimately show "\<exists>b<top. \<forall>z>b. P z"
  1339     by (auto simp: subset_eq Ball_def)
  1340 next
  1341   fix b assume "b < top" "\<forall>z>b. P z"
  1342   then show "\<exists>S. open S \<and> top \<in> S \<and> (\<forall>xa\<in>S. P xa)"
  1343     by (intro exI[of _ "{b <..}"]) auto
  1344 qed
  1345 
  1346 subsection {* Limits on sequences *}
  1347 
  1348 abbreviation (in topological_space)
  1349   LIMSEQ :: "[nat \<Rightarrow> 'a, 'a] \<Rightarrow> bool"
  1350     ("((_)/ ----> (_))" [60, 60] 60) where
  1351   "X ----> L \<equiv> (X ---> L) sequentially"
  1352 
  1353 abbreviation (in t2_space) lim :: "(nat \<Rightarrow> 'a) \<Rightarrow> 'a" where
  1354   "lim X \<equiv> Lim sequentially X"
  1355 
  1356 definition (in topological_space) convergent :: "(nat \<Rightarrow> 'a) \<Rightarrow> bool" where
  1357   "convergent X = (\<exists>L. X ----> L)"
  1358 
  1359 lemma lim_def: "lim X = (THE L. X ----> L)"
  1360   unfolding Lim_def ..
  1361 
  1362 subsubsection {* Monotone sequences and subsequences *}
  1363 
  1364 definition
  1365   monoseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
  1366     --{*Definition of monotonicity.
  1367         The use of disjunction here complicates proofs considerably.
  1368         One alternative is to add a Boolean argument to indicate the direction.
  1369         Another is to develop the notions of increasing and decreasing first.*}
  1370   "monoseq X = ((\<forall>m. \<forall>n\<ge>m. X m \<le> X n) \<or> (\<forall>m. \<forall>n\<ge>m. X n \<le> X m))"
  1371 
  1372 abbreviation incseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
  1373   "incseq X \<equiv> mono X"
  1374 
  1375 lemma incseq_def: "incseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X n \<ge> X m)"
  1376   unfolding mono_def ..
  1377 
  1378 abbreviation decseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
  1379   "decseq X \<equiv> antimono X"
  1380 
  1381 lemma decseq_def: "decseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X n \<le> X m)"
  1382   unfolding antimono_def ..
  1383 
  1384 definition
  1385   subseq :: "(nat \<Rightarrow> nat) \<Rightarrow> bool" where
  1386     --{*Definition of subsequence*}
  1387   "subseq f \<longleftrightarrow> (\<forall>m. \<forall>n>m. f m < f n)"
  1388 
  1389 lemma incseq_SucI:
  1390   "(\<And>n. X n \<le> X (Suc n)) \<Longrightarrow> incseq X"
  1391   using lift_Suc_mono_le[of X]
  1392   by (auto simp: incseq_def)
  1393 
  1394 lemma incseqD: "\<And>i j. incseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f i \<le> f j"
  1395   by (auto simp: incseq_def)
  1396 
  1397 lemma incseq_SucD: "incseq A \<Longrightarrow> A i \<le> A (Suc i)"
  1398   using incseqD[of A i "Suc i"] by auto
  1399 
  1400 lemma incseq_Suc_iff: "incseq f \<longleftrightarrow> (\<forall>n. f n \<le> f (Suc n))"
  1401   by (auto intro: incseq_SucI dest: incseq_SucD)
  1402 
  1403 lemma incseq_const[simp, intro]: "incseq (\<lambda>x. k)"
  1404   unfolding incseq_def by auto
  1405 
  1406 lemma decseq_SucI:
  1407   "(\<And>n. X (Suc n) \<le> X n) \<Longrightarrow> decseq X"
  1408   using order.lift_Suc_mono_le[OF dual_order, of X]
  1409   by (auto simp: decseq_def)
  1410 
  1411 lemma decseqD: "\<And>i j. decseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f j \<le> f i"
  1412   by (auto simp: decseq_def)
  1413 
  1414 lemma decseq_SucD: "decseq A \<Longrightarrow> A (Suc i) \<le> A i"
  1415   using decseqD[of A i "Suc i"] by auto
  1416 
  1417 lemma decseq_Suc_iff: "decseq f \<longleftrightarrow> (\<forall>n. f (Suc n) \<le> f n)"
  1418   by (auto intro: decseq_SucI dest: decseq_SucD)
  1419 
  1420 lemma decseq_const[simp, intro]: "decseq (\<lambda>x. k)"
  1421   unfolding decseq_def by auto
  1422 
  1423 lemma monoseq_iff: "monoseq X \<longleftrightarrow> incseq X \<or> decseq X"
  1424   unfolding monoseq_def incseq_def decseq_def ..
  1425 
  1426 lemma monoseq_Suc:
  1427   "monoseq X \<longleftrightarrow> (\<forall>n. X n \<le> X (Suc n)) \<or> (\<forall>n. X (Suc n) \<le> X n)"
  1428   unfolding monoseq_iff incseq_Suc_iff decseq_Suc_iff ..
  1429 
  1430 lemma monoI1: "\<forall>m. \<forall> n \<ge> m. X m \<le> X n ==> monoseq X"
  1431 by (simp add: monoseq_def)
  1432 
  1433 lemma monoI2: "\<forall>m. \<forall> n \<ge> m. X n \<le> X m ==> monoseq X"
  1434 by (simp add: monoseq_def)
  1435 
  1436 lemma mono_SucI1: "\<forall>n. X n \<le> X (Suc n) ==> monoseq X"
  1437 by (simp add: monoseq_Suc)
  1438 
  1439 lemma mono_SucI2: "\<forall>n. X (Suc n) \<le> X n ==> monoseq X"
  1440 by (simp add: monoseq_Suc)
  1441 
  1442 lemma monoseq_minus:
  1443   fixes a :: "nat \<Rightarrow> 'a::ordered_ab_group_add"
  1444   assumes "monoseq a"
  1445   shows "monoseq (\<lambda> n. - a n)"
  1446 proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
  1447   case True
  1448   hence "\<forall> m. \<forall> n \<ge> m. - a n \<le> - a m" by auto
  1449   thus ?thesis by (rule monoI2)
  1450 next
  1451   case False
  1452   hence "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" using `monoseq a`[unfolded monoseq_def] by auto
  1453   thus ?thesis by (rule monoI1)
  1454 qed
  1455 
  1456 text{*Subsequence (alternative definition, (e.g. Hoskins)*}
  1457 
  1458 lemma subseq_Suc_iff: "subseq f = (\<forall>n. (f n) < (f (Suc n)))"
  1459 apply (simp add: subseq_def)
  1460 apply (auto dest!: less_imp_Suc_add)
  1461 apply (induct_tac k)
  1462 apply (auto intro: less_trans)
  1463 done
  1464 
  1465 text{* for any sequence, there is a monotonic subsequence *}
  1466 lemma seq_monosub:
  1467   fixes s :: "nat => 'a::linorder"
  1468   shows "\<exists>f. subseq f \<and> monoseq (\<lambda> n. (s (f n)))"
  1469 proof cases
  1470   let "?P p n" = "p > n \<and> (\<forall>m\<ge>p. s m \<le> s p)"
  1471   assume *: "\<forall>n. \<exists>p. ?P p n"
  1472   def f \<equiv> "rec_nat (SOME p. ?P p 0) (\<lambda>_ n. SOME p. ?P p n)"
  1473   have f_0: "f 0 = (SOME p. ?P p 0)" unfolding f_def by simp
  1474   have f_Suc: "\<And>i. f (Suc i) = (SOME p. ?P p (f i))" unfolding f_def nat.rec(2) ..
  1475   have P_0: "?P (f 0) 0" unfolding f_0 using *[rule_format] by (rule someI2_ex) auto
  1476   have P_Suc: "\<And>i. ?P (f (Suc i)) (f i)" unfolding f_Suc using *[rule_format] by (rule someI2_ex) auto
  1477   then have "subseq f" unfolding subseq_Suc_iff by auto
  1478   moreover have "monoseq (\<lambda>n. s (f n))" unfolding monoseq_Suc
  1479   proof (intro disjI2 allI)
  1480     fix n show "s (f (Suc n)) \<le> s (f n)"
  1481     proof (cases n)
  1482       case 0 with P_Suc[of 0] P_0 show ?thesis by auto
  1483     next
  1484       case (Suc m)
  1485       from P_Suc[of n] Suc have "f (Suc m) \<le> f (Suc (Suc m))" by simp
  1486       with P_Suc Suc show ?thesis by simp
  1487     qed
  1488   qed
  1489   ultimately show ?thesis by auto
  1490 next
  1491   let "?P p m" = "m < p \<and> s m < s p"
  1492   assume "\<not> (\<forall>n. \<exists>p>n. (\<forall>m\<ge>p. s m \<le> s p))"
  1493   then obtain N where N: "\<And>p. p > N \<Longrightarrow> \<exists>m>p. s p < s m" by (force simp: not_le le_less)
  1494   def f \<equiv> "rec_nat (SOME p. ?P p (Suc N)) (\<lambda>_ n. SOME p. ?P p n)"
  1495   have f_0: "f 0 = (SOME p. ?P p (Suc N))" unfolding f_def by simp
  1496   have f_Suc: "\<And>i. f (Suc i) = (SOME p. ?P p (f i))" unfolding f_def nat.rec(2) ..
  1497   have P_0: "?P (f 0) (Suc N)"
  1498     unfolding f_0 some_eq_ex[of "\<lambda>p. ?P p (Suc N)"] using N[of "Suc N"] by auto
  1499   { fix i have "N < f i \<Longrightarrow> ?P (f (Suc i)) (f i)"
  1500       unfolding f_Suc some_eq_ex[of "\<lambda>p. ?P p (f i)"] using N[of "f i"] . }
  1501   note P' = this
  1502   { fix i have "N < f i \<and> ?P (f (Suc i)) (f i)"
  1503       by (induct i) (insert P_0 P', auto) }
  1504   then have "subseq f" "monoseq (\<lambda>x. s (f x))"
  1505     unfolding subseq_Suc_iff monoseq_Suc by (auto simp: not_le intro: less_imp_le)
  1506   then show ?thesis by auto
  1507 qed
  1508 
  1509 lemma seq_suble: assumes sf: "subseq f" shows "n \<le> f n"
  1510 proof(induct n)
  1511   case 0 thus ?case by simp
  1512 next
  1513   case (Suc n)
  1514   from sf[unfolded subseq_Suc_iff, rule_format, of n] Suc.hyps
  1515   have "n < f (Suc n)" by arith
  1516   thus ?case by arith
  1517 qed
  1518 
  1519 lemma eventually_subseq:
  1520   "subseq r \<Longrightarrow> eventually P sequentially \<Longrightarrow> eventually (\<lambda>n. P (r n)) sequentially"
  1521   unfolding eventually_sequentially by (metis seq_suble le_trans)
  1522 
  1523 lemma not_eventually_sequentiallyD:
  1524   assumes P: "\<not> eventually P sequentially"
  1525   shows "\<exists>r. subseq r \<and> (\<forall>n. \<not> P (r n))"
  1526 proof -
  1527   from P have "\<forall>n. \<exists>m\<ge>n. \<not> P m"
  1528     unfolding eventually_sequentially by (simp add: not_less)
  1529   then obtain r where "\<And>n. r n \<ge> n" "\<And>n. \<not> P (r n)"
  1530     by (auto simp: choice_iff)
  1531   then show ?thesis
  1532     by (auto intro!: exI[of _ "\<lambda>n. r (((Suc \<circ> r) ^^ Suc n) 0)"]
  1533              simp: less_eq_Suc_le subseq_Suc_iff)
  1534 qed
  1535 
  1536 lemma filterlim_subseq: "subseq f \<Longrightarrow> filterlim f sequentially sequentially"
  1537   unfolding filterlim_iff by (metis eventually_subseq)
  1538 
  1539 lemma subseq_o: "subseq r \<Longrightarrow> subseq s \<Longrightarrow> subseq (r \<circ> s)"
  1540   unfolding subseq_def by simp
  1541 
  1542 lemma subseq_mono: assumes "subseq r" "m < n" shows "r m < r n"
  1543   using assms by (auto simp: subseq_def)
  1544 
  1545 lemma incseq_imp_monoseq:  "incseq X \<Longrightarrow> monoseq X"
  1546   by (simp add: incseq_def monoseq_def)
  1547 
  1548 lemma decseq_imp_monoseq:  "decseq X \<Longrightarrow> monoseq X"
  1549   by (simp add: decseq_def monoseq_def)
  1550 
  1551 lemma decseq_eq_incseq:
  1552   fixes X :: "nat \<Rightarrow> 'a::ordered_ab_group_add" shows "decseq X = incseq (\<lambda>n. - X n)" 
  1553   by (simp add: decseq_def incseq_def)
  1554 
  1555 lemma INT_decseq_offset:
  1556   assumes "decseq F"
  1557   shows "(\<Inter>i. F i) = (\<Inter>i\<in>{n..}. F i)"
  1558 proof safe
  1559   fix x i assume x: "x \<in> (\<Inter>i\<in>{n..}. F i)"
  1560   show "x \<in> F i"
  1561   proof cases
  1562     from x have "x \<in> F n" by auto
  1563     also assume "i \<le> n" with `decseq F` have "F n \<subseteq> F i"
  1564       unfolding decseq_def by simp
  1565     finally show ?thesis .
  1566   qed (insert x, simp)
  1567 qed auto
  1568 
  1569 lemma LIMSEQ_const_iff:
  1570   fixes k l :: "'a::t2_space"
  1571   shows "(\<lambda>n. k) ----> l \<longleftrightarrow> k = l"
  1572   using trivial_limit_sequentially by (rule tendsto_const_iff)
  1573 
  1574 lemma LIMSEQ_SUP:
  1575   "incseq X \<Longrightarrow> X ----> (SUP i. X i :: 'a :: {complete_linorder, linorder_topology})"
  1576   by (intro increasing_tendsto)
  1577      (auto simp: SUP_upper less_SUP_iff incseq_def eventually_sequentially intro: less_le_trans)
  1578 
  1579 lemma LIMSEQ_INF:
  1580   "decseq X \<Longrightarrow> X ----> (INF i. X i :: 'a :: {complete_linorder, linorder_topology})"
  1581   by (intro decreasing_tendsto)
  1582      (auto simp: INF_lower INF_less_iff decseq_def eventually_sequentially intro: le_less_trans)
  1583 
  1584 lemma LIMSEQ_ignore_initial_segment:
  1585   "f ----> a \<Longrightarrow> (\<lambda>n. f (n + k)) ----> a"
  1586   unfolding tendsto_def
  1587   by (subst eventually_sequentially_seg[where k=k])
  1588 
  1589 lemma LIMSEQ_offset:
  1590   "(\<lambda>n. f (n + k)) ----> a \<Longrightarrow> f ----> a"
  1591   unfolding tendsto_def
  1592   by (subst (asm) eventually_sequentially_seg[where k=k])
  1593 
  1594 lemma LIMSEQ_Suc: "f ----> l \<Longrightarrow> (\<lambda>n. f (Suc n)) ----> l"
  1595 by (drule_tac k="Suc 0" in LIMSEQ_ignore_initial_segment, simp)
  1596 
  1597 lemma LIMSEQ_imp_Suc: "(\<lambda>n. f (Suc n)) ----> l \<Longrightarrow> f ----> l"
  1598 by (rule_tac k="Suc 0" in LIMSEQ_offset, simp)
  1599 
  1600 lemma LIMSEQ_Suc_iff: "(\<lambda>n. f (Suc n)) ----> l = f ----> l"
  1601 by (blast intro: LIMSEQ_imp_Suc LIMSEQ_Suc)
  1602 
  1603 lemma LIMSEQ_unique:
  1604   fixes a b :: "'a::t2_space"
  1605   shows "\<lbrakk>X ----> a; X ----> b\<rbrakk> \<Longrightarrow> a = b"
  1606   using trivial_limit_sequentially by (rule tendsto_unique)
  1607 
  1608 lemma LIMSEQ_le_const:
  1609   "\<lbrakk>X ----> (x::'a::linorder_topology); \<exists>N. \<forall>n\<ge>N. a \<le> X n\<rbrakk> \<Longrightarrow> a \<le> x"
  1610   using tendsto_le_const[of sequentially X x a] by (simp add: eventually_sequentially)
  1611 
  1612 lemma LIMSEQ_le:
  1613   "\<lbrakk>X ----> x; Y ----> y; \<exists>N. \<forall>n\<ge>N. X n \<le> Y n\<rbrakk> \<Longrightarrow> x \<le> (y::'a::linorder_topology)"
  1614   using tendsto_le[of sequentially Y y X x] by (simp add: eventually_sequentially)
  1615 
  1616 lemma LIMSEQ_le_const2:
  1617   "\<lbrakk>X ----> (x::'a::linorder_topology); \<exists>N. \<forall>n\<ge>N. X n \<le> a\<rbrakk> \<Longrightarrow> x \<le> a"
  1618   by (rule LIMSEQ_le[of X x "\<lambda>n. a"]) (auto simp: tendsto_const)
  1619 
  1620 lemma convergentD: "convergent X ==> \<exists>L. (X ----> L)"
  1621 by (simp add: convergent_def)
  1622 
  1623 lemma convergentI: "(X ----> L) ==> convergent X"
  1624 by (auto simp add: convergent_def)
  1625 
  1626 lemma convergent_LIMSEQ_iff: "convergent X = (X ----> lim X)"
  1627 by (auto intro: theI LIMSEQ_unique simp add: convergent_def lim_def)
  1628 
  1629 lemma convergent_const: "convergent (\<lambda>n. c)"
  1630   by (rule convergentI, rule tendsto_const)
  1631 
  1632 lemma monoseq_le:
  1633   "monoseq a \<Longrightarrow> a ----> (x::'a::linorder_topology) \<Longrightarrow>
  1634     ((\<forall> n. a n \<le> x) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)) \<or> ((\<forall> n. x \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m))"
  1635   by (metis LIMSEQ_le_const LIMSEQ_le_const2 decseq_def incseq_def monoseq_iff)
  1636 
  1637 lemma LIMSEQ_subseq_LIMSEQ:
  1638   "\<lbrakk> X ----> L; subseq f \<rbrakk> \<Longrightarrow> (X o f) ----> L"
  1639   unfolding comp_def by (rule filterlim_compose[of X, OF _ filterlim_subseq])
  1640 
  1641 lemma convergent_subseq_convergent:
  1642   "\<lbrakk>convergent X; subseq f\<rbrakk> \<Longrightarrow> convergent (X o f)"
  1643   unfolding convergent_def by (auto intro: LIMSEQ_subseq_LIMSEQ)
  1644 
  1645 lemma limI: "X ----> L ==> lim X = L"
  1646   by (rule tendsto_Lim) (rule trivial_limit_sequentially)
  1647 
  1648 lemma lim_le: "convergent f \<Longrightarrow> (\<And>n. f n \<le> (x::'a::linorder_topology)) \<Longrightarrow> lim f \<le> x"
  1649   using LIMSEQ_le_const2[of f "lim f" x] by (simp add: convergent_LIMSEQ_iff)
  1650 
  1651 subsubsection{*Increasing and Decreasing Series*}
  1652 
  1653 lemma incseq_le: "incseq X \<Longrightarrow> X ----> L \<Longrightarrow> X n \<le> (L::'a::linorder_topology)"
  1654   by (metis incseq_def LIMSEQ_le_const)
  1655 
  1656 lemma decseq_le: "decseq X \<Longrightarrow> X ----> L \<Longrightarrow> (L::'a::linorder_topology) \<le> X n"
  1657   by (metis decseq_def LIMSEQ_le_const2)
  1658 
  1659 subsection {* First countable topologies *}
  1660 
  1661 class first_countable_topology = topological_space +
  1662   assumes first_countable_basis:
  1663     "\<exists>A::nat \<Rightarrow> 'a set. (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
  1664 
  1665 lemma (in first_countable_topology) countable_basis_at_decseq:
  1666   obtains A :: "nat \<Rightarrow> 'a set" where
  1667     "\<And>i. open (A i)" "\<And>i. x \<in> (A i)"
  1668     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  1669 proof atomize_elim
  1670   from first_countable_basis[of x] obtain A :: "nat \<Rightarrow> 'a set" where
  1671     nhds: "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1672     and incl: "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> \<exists>i. A i \<subseteq> S"  by auto
  1673   def F \<equiv> "\<lambda>n. \<Inter>i\<le>n. A i"
  1674   show "\<exists>A. (\<forall>i. open (A i)) \<and> (\<forall>i. x \<in> A i) \<and>
  1675       (\<forall>S. open S \<longrightarrow> x \<in> S \<longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially)"
  1676   proof (safe intro!: exI[of _ F])
  1677     fix i
  1678     show "open (F i)" using nhds(1) by (auto simp: F_def)
  1679     show "x \<in> F i" using nhds(2) by (auto simp: F_def)
  1680   next
  1681     fix S assume "open S" "x \<in> S"
  1682     from incl[OF this] obtain i where "F i \<subseteq> S" unfolding F_def by auto
  1683     moreover have "\<And>j. i \<le> j \<Longrightarrow> F j \<subseteq> F i"
  1684       by (auto simp: F_def)
  1685     ultimately show "eventually (\<lambda>i. F i \<subseteq> S) sequentially"
  1686       by (auto simp: eventually_sequentially)
  1687   qed
  1688 qed
  1689 
  1690 lemma (in first_countable_topology) countable_basis:
  1691   obtains A :: "nat \<Rightarrow> 'a set" where
  1692     "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1693     "\<And>F. (\<forall>n. F n \<in> A n) \<Longrightarrow> F ----> x"
  1694 proof atomize_elim
  1695   obtain A :: "nat \<Rightarrow> 'a set" where A:
  1696     "\<And>i. open (A i)"
  1697     "\<And>i. x \<in> A i"
  1698     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  1699     by (rule countable_basis_at_decseq) blast
  1700   {
  1701     fix F S assume "\<forall>n. F n \<in> A n" "open S" "x \<in> S"
  1702     with A(3)[of S] have "eventually (\<lambda>n. F n \<in> S) sequentially"
  1703       by (auto elim: eventually_elim1 simp: subset_eq)
  1704   }
  1705   with A show "\<exists>A. (\<forall>i. open (A i)) \<and> (\<forall>i. x \<in> A i) \<and> (\<forall>F. (\<forall>n. F n \<in> A n) \<longrightarrow> F ----> x)"
  1706     by (intro exI[of _ A]) (auto simp: tendsto_def)
  1707 qed
  1708 
  1709 lemma (in first_countable_topology) sequentially_imp_eventually_nhds_within:
  1710   assumes "\<forall>f. (\<forall>n. f n \<in> s) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially"
  1711   shows "eventually P (inf (nhds a) (principal s))"
  1712 proof (rule ccontr)
  1713   obtain A :: "nat \<Rightarrow> 'a set" where A:
  1714     "\<And>i. open (A i)"
  1715     "\<And>i. a \<in> A i"
  1716     "\<And>F. \<forall>n. F n \<in> A n \<Longrightarrow> F ----> a"
  1717     by (rule countable_basis) blast
  1718   assume "\<not> ?thesis"
  1719   with A have P: "\<exists>F. \<forall>n. F n \<in> s \<and> F n \<in> A n \<and> \<not> P (F n)"
  1720     unfolding eventually_inf_principal eventually_nhds by (intro choice) fastforce
  1721   then obtain F where F0: "\<forall>n. F n \<in> s" and F2: "\<forall>n. F n \<in> A n" and F3: "\<forall>n. \<not> P (F n)"
  1722     by blast
  1723   with A have "F ----> a" by auto
  1724   hence "eventually (\<lambda>n. P (F n)) sequentially"
  1725     using assms F0 by simp
  1726   thus "False" by (simp add: F3)
  1727 qed
  1728 
  1729 lemma (in first_countable_topology) eventually_nhds_within_iff_sequentially:
  1730   "eventually P (inf (nhds a) (principal s)) \<longleftrightarrow> 
  1731     (\<forall>f. (\<forall>n. f n \<in> s) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially)"
  1732 proof (safe intro!: sequentially_imp_eventually_nhds_within)
  1733   assume "eventually P (inf (nhds a) (principal s))" 
  1734   then obtain S where "open S" "a \<in> S" "\<forall>x\<in>S. x \<in> s \<longrightarrow> P x"
  1735     by (auto simp: eventually_inf_principal eventually_nhds)
  1736   moreover fix f assume "\<forall>n. f n \<in> s" "f ----> a"
  1737   ultimately show "eventually (\<lambda>n. P (f n)) sequentially"
  1738     by (auto dest!: topological_tendstoD elim: eventually_elim1)
  1739 qed
  1740 
  1741 lemma (in first_countable_topology) eventually_nhds_iff_sequentially:
  1742   "eventually P (nhds a) \<longleftrightarrow> (\<forall>f. f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially)"
  1743   using eventually_nhds_within_iff_sequentially[of P a UNIV] by simp
  1744 
  1745 subsection {* Function limit at a point *}
  1746 
  1747 abbreviation
  1748   LIM :: "('a::topological_space \<Rightarrow> 'b::topological_space) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool"
  1749         ("((_)/ -- (_)/ --> (_))" [60, 0, 60] 60) where
  1750   "f -- a --> L \<equiv> (f ---> L) (at a)"
  1751 
  1752 lemma tendsto_within_open: "a \<in> S \<Longrightarrow> open S \<Longrightarrow> (f ---> l) (at a within S) \<longleftrightarrow> (f -- a --> l)"
  1753   unfolding tendsto_def by (simp add: at_within_open[where S=S])
  1754 
  1755 lemma LIM_const_not_eq[tendsto_intros]:
  1756   fixes a :: "'a::perfect_space"
  1757   fixes k L :: "'b::t2_space"
  1758   shows "k \<noteq> L \<Longrightarrow> \<not> (\<lambda>x. k) -- a --> L"
  1759   by (simp add: tendsto_const_iff)
  1760 
  1761 lemmas LIM_not_zero = LIM_const_not_eq [where L = 0]
  1762 
  1763 lemma LIM_const_eq:
  1764   fixes a :: "'a::perfect_space"
  1765   fixes k L :: "'b::t2_space"
  1766   shows "(\<lambda>x. k) -- a --> L \<Longrightarrow> k = L"
  1767   by (simp add: tendsto_const_iff)
  1768 
  1769 lemma LIM_unique:
  1770   fixes a :: "'a::perfect_space" and L M :: "'b::t2_space"
  1771   shows "f -- a --> L \<Longrightarrow> f -- a --> M \<Longrightarrow> L = M"
  1772   using at_neq_bot by (rule tendsto_unique)
  1773 
  1774 text {* Limits are equal for functions equal except at limit point *}
  1775 
  1776 lemma LIM_equal: "\<forall>x. x \<noteq> a --> (f x = g x) \<Longrightarrow> (f -- a --> l) \<longleftrightarrow> (g -- a --> l)"
  1777   unfolding tendsto_def eventually_at_topological by simp
  1778 
  1779 lemma LIM_cong: "a = b \<Longrightarrow> (\<And>x. x \<noteq> b \<Longrightarrow> f x = g x) \<Longrightarrow> l = m \<Longrightarrow> (f -- a --> l) \<longleftrightarrow> (g -- b --> m)"
  1780   by (simp add: LIM_equal)
  1781 
  1782 lemma LIM_cong_limit: "f -- x --> L \<Longrightarrow> K = L \<Longrightarrow> f -- x --> K"
  1783   by simp
  1784 
  1785 lemma tendsto_at_iff_tendsto_nhds:
  1786   "g -- l --> g l \<longleftrightarrow> (g ---> g l) (nhds l)"
  1787   unfolding tendsto_def eventually_at_filter
  1788   by (intro ext all_cong imp_cong) (auto elim!: eventually_elim1)
  1789 
  1790 lemma tendsto_compose:
  1791   "g -- l --> g l \<Longrightarrow> (f ---> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> g l) F"
  1792   unfolding tendsto_at_iff_tendsto_nhds by (rule filterlim_compose[of g])
  1793 
  1794 lemma LIM_o: "\<lbrakk>g -- l --> g l; f -- a --> l\<rbrakk> \<Longrightarrow> (g \<circ> f) -- a --> g l"
  1795   unfolding o_def by (rule tendsto_compose)
  1796 
  1797 lemma tendsto_compose_eventually:
  1798   "g -- l --> m \<Longrightarrow> (f ---> l) F \<Longrightarrow> eventually (\<lambda>x. f x \<noteq> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> m) F"
  1799   by (rule filterlim_compose[of g _ "at l"]) (auto simp add: filterlim_at)
  1800 
  1801 lemma LIM_compose_eventually:
  1802   assumes f: "f -- a --> b"
  1803   assumes g: "g -- b --> c"
  1804   assumes inj: "eventually (\<lambda>x. f x \<noteq> b) (at a)"
  1805   shows "(\<lambda>x. g (f x)) -- a --> c"
  1806   using g f inj by (rule tendsto_compose_eventually)
  1807 
  1808 subsubsection {* Relation of LIM and LIMSEQ *}
  1809 
  1810 lemma (in first_countable_topology) sequentially_imp_eventually_within:
  1811   "(\<forall>f. (\<forall>n. f n \<in> s \<and> f n \<noteq> a) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially) \<Longrightarrow>
  1812     eventually P (at a within s)"
  1813   unfolding at_within_def
  1814   by (intro sequentially_imp_eventually_nhds_within) auto
  1815 
  1816 lemma (in first_countable_topology) sequentially_imp_eventually_at:
  1817   "(\<forall>f. (\<forall>n. f n \<noteq> a) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially) \<Longrightarrow> eventually P (at a)"
  1818   using assms sequentially_imp_eventually_within [where s=UNIV] by simp
  1819 
  1820 lemma LIMSEQ_SEQ_conv1:
  1821   fixes f :: "'a::topological_space \<Rightarrow> 'b::topological_space"
  1822   assumes f: "f -- a --> l"
  1823   shows "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. f (S n)) ----> l"
  1824   using tendsto_compose_eventually [OF f, where F=sequentially] by simp
  1825 
  1826 lemma LIMSEQ_SEQ_conv2:
  1827   fixes f :: "'a::first_countable_topology \<Rightarrow> 'b::topological_space"
  1828   assumes "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. f (S n)) ----> l"
  1829   shows "f -- a --> l"
  1830   using assms unfolding tendsto_def [where l=l] by (simp add: sequentially_imp_eventually_at)
  1831 
  1832 lemma LIMSEQ_SEQ_conv:
  1833   "(\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> (a::'a::first_countable_topology) \<longrightarrow> (\<lambda>n. X (S n)) ----> L) =
  1834    (X -- a --> (L::'b::topological_space))"
  1835   using LIMSEQ_SEQ_conv2 LIMSEQ_SEQ_conv1 ..
  1836 
  1837 lemma sequentially_imp_eventually_at_left:
  1838   fixes a :: "'a :: {dense_linorder, linorder_topology, first_countable_topology}"
  1839   assumes b[simp]: "b < a"
  1840   assumes *: "\<And>f. (\<And>n. b < f n) \<Longrightarrow> (\<And>n. f n < a) \<Longrightarrow> incseq f \<Longrightarrow> f ----> a \<Longrightarrow> eventually (\<lambda>n. P (f n)) sequentially"
  1841   shows "eventually P (at_left a)"
  1842 proof (safe intro!: sequentially_imp_eventually_within)
  1843   fix X assume X: "\<forall>n. X n \<in> {..<a} \<and> X n \<noteq> a" "X ----> a"
  1844   show "eventually (\<lambda>n. P (X n)) sequentially"
  1845   proof (rule ccontr)
  1846 
  1847     assume "\<not> eventually (\<lambda>n. P (X n)) sequentially"
  1848     from not_eventually_sequentiallyD[OF this]
  1849     obtain r where "subseq r" "\<And>n. \<not> P (X (r n))"
  1850       by auto
  1851     with X have "(X \<circ> r) ----> a"
  1852       by (auto intro: LIMSEQ_subseq_LIMSEQ)
  1853     from order_tendstoD(1)[OF this] obtain s' where s': "\<And>b i. b < a \<Longrightarrow> s' b \<le> i \<Longrightarrow> b < X (r i)"
  1854       unfolding eventually_sequentially comp_def by metis
  1855     def s \<equiv> "rec_nat (s' b) (\<lambda>_ i. max (s' (X (r i))) (Suc i))"
  1856     then have [simp]: "s 0 = s' b" "\<And>n. s (Suc n) = max (s' (X (r (s n)))) (Suc (s n))"
  1857       by auto
  1858     have "eventually (\<lambda>n. P (((X \<circ> r) \<circ> s) n)) sequentially"
  1859     proof (rule *)
  1860       from X show inc: "incseq (X \<circ> r \<circ> s)"
  1861         unfolding incseq_Suc_iff comp_def by (intro allI s'[THEN less_imp_le]) auto
  1862       { fix n show "b < (X \<circ> r \<circ> s) n"
  1863           using inc[THEN incseqD, of 0 n] s'[OF b order_refl] by simp }
  1864       { fix n show "(X \<circ> r \<circ> s) n < a"
  1865           using X by simp }
  1866       from `(X \<circ> r) ----> a` show "(X \<circ> r \<circ> s) ----> a"
  1867         by (rule LIMSEQ_subseq_LIMSEQ) (auto simp: subseq_Suc_iff)
  1868     qed
  1869     with `\<And>n. \<not> P (X (r n))` show False
  1870       by auto
  1871   qed
  1872 qed
  1873 
  1874 lemma tendsto_at_left_sequentially:
  1875   fixes a :: "_ :: {dense_linorder, linorder_topology, first_countable_topology}"
  1876   assumes "b < a"
  1877   assumes *: "\<And>S. (\<And>n. S n < a) \<Longrightarrow> (\<And>n. b < S n) \<Longrightarrow> incseq S \<Longrightarrow> S ----> a \<Longrightarrow> (\<lambda>n. X (S n)) ----> L"
  1878   shows "(X ---> L) (at_left a)"
  1879   using assms unfolding tendsto_def [where l=L]
  1880   by (simp add: sequentially_imp_eventually_at_left)
  1881 
  1882 subsection {* Continuity *}
  1883 
  1884 subsubsection {* Continuity on a set *}
  1885 
  1886 definition continuous_on :: "'a set \<Rightarrow> ('a :: topological_space \<Rightarrow> 'b :: topological_space) \<Rightarrow> bool" where
  1887   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. (f ---> f x) (at x within s))"
  1888 
  1889 lemma continuous_on_cong [cong]:
  1890   "s = t \<Longrightarrow> (\<And>x. x \<in> t \<Longrightarrow> f x = g x) \<Longrightarrow> continuous_on s f \<longleftrightarrow> continuous_on t g"
  1891   unfolding continuous_on_def by (intro ball_cong filterlim_cong) (auto simp: eventually_at_filter)
  1892 
  1893 lemma continuous_on_topological:
  1894   "continuous_on s f \<longleftrightarrow>
  1895     (\<forall>x\<in>s. \<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow> (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  1896   unfolding continuous_on_def tendsto_def eventually_at_topological by metis
  1897 
  1898 lemma continuous_on_open_invariant:
  1899   "continuous_on s f \<longleftrightarrow> (\<forall>B. open B \<longrightarrow> (\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s))"
  1900 proof safe
  1901   fix B :: "'b set" assume "continuous_on s f" "open B"
  1902   then have "\<forall>x\<in>f -` B \<inter> s. (\<exists>A. open A \<and> x \<in> A \<and> s \<inter> A \<subseteq> f -` B)"
  1903     by (auto simp: continuous_on_topological subset_eq Ball_def imp_conjL)
  1904   then obtain A where "\<forall>x\<in>f -` B \<inter> s. open (A x) \<and> x \<in> A x \<and> s \<inter> A x \<subseteq> f -` B"
  1905     unfolding bchoice_iff ..
  1906   then show "\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s"
  1907     by (intro exI[of _ "\<Union>x\<in>f -` B \<inter> s. A x"]) auto
  1908 next
  1909   assume B: "\<forall>B. open B \<longrightarrow> (\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s)"
  1910   show "continuous_on s f"
  1911     unfolding continuous_on_topological
  1912   proof safe
  1913     fix x B assume "x \<in> s" "open B" "f x \<in> B"
  1914     with B obtain A where A: "open A" "A \<inter> s = f -` B \<inter> s" by auto
  1915     with `x \<in> s` `f x \<in> B` show "\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)"
  1916       by (intro exI[of _ A]) auto
  1917   qed
  1918 qed
  1919 
  1920 lemma continuous_on_open_vimage:
  1921   "open s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>B. open B \<longrightarrow> open (f -` B \<inter> s))"
  1922   unfolding continuous_on_open_invariant
  1923   by (metis open_Int Int_absorb Int_commute[of s] Int_assoc[of _ _ s])
  1924 
  1925 corollary continuous_imp_open_vimage:
  1926   assumes "continuous_on s f" "open s" "open B" "f -` B \<subseteq> s"
  1927     shows "open (f -` B)"
  1928 by (metis assms continuous_on_open_vimage le_iff_inf)
  1929 
  1930 corollary open_vimage[continuous_intros]:
  1931   assumes "open s" and "continuous_on UNIV f"
  1932   shows "open (f -` s)"
  1933   using assms unfolding continuous_on_open_vimage [OF open_UNIV]
  1934   by simp
  1935 
  1936 lemma continuous_on_closed_invariant:
  1937   "continuous_on s f \<longleftrightarrow> (\<forall>B. closed B \<longrightarrow> (\<exists>A. closed A \<and> A \<inter> s = f -` B \<inter> s))"
  1938 proof -
  1939   have *: "\<And>P Q::'b set\<Rightarrow>bool. (\<And>A. P A \<longleftrightarrow> Q (- A)) \<Longrightarrow> (\<forall>A. P A) \<longleftrightarrow> (\<forall>A. Q A)"
  1940     by (metis double_compl)
  1941   show ?thesis
  1942     unfolding continuous_on_open_invariant by (intro *) (auto simp: open_closed[symmetric])
  1943 qed
  1944 
  1945 lemma continuous_on_closed_vimage:
  1946   "closed s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>B. closed B \<longrightarrow> closed (f -` B \<inter> s))"
  1947   unfolding continuous_on_closed_invariant
  1948   by (metis closed_Int Int_absorb Int_commute[of s] Int_assoc[of _ _ s])
  1949 
  1950 corollary closed_vimage[continuous_intros]:
  1951   assumes "closed s" and "continuous_on UNIV f"
  1952   shows "closed (f -` s)"
  1953   using assms unfolding continuous_on_closed_vimage [OF closed_UNIV]
  1954   by simp
  1955 
  1956 lemma continuous_on_open_Union:
  1957   "(\<And>s. s \<in> S \<Longrightarrow> open s) \<Longrightarrow> (\<And>s. s \<in> S \<Longrightarrow> continuous_on s f) \<Longrightarrow> continuous_on (\<Union>S) f"
  1958   unfolding continuous_on_def by safe (metis open_Union at_within_open UnionI)
  1959 
  1960 lemma continuous_on_open_UN:
  1961   "(\<And>s. s \<in> S \<Longrightarrow> open (A s)) \<Longrightarrow> (\<And>s. s \<in> S \<Longrightarrow> continuous_on (A s) f) \<Longrightarrow> continuous_on (\<Union>s\<in>S. A s) f"
  1962   unfolding Union_image_eq[symmetric] by (rule continuous_on_open_Union) auto
  1963 
  1964 lemma continuous_on_closed_Un:
  1965   "closed s \<Longrightarrow> closed t \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on t f \<Longrightarrow> continuous_on (s \<union> t) f"
  1966   by (auto simp add: continuous_on_closed_vimage closed_Un Int_Un_distrib)
  1967 
  1968 lemma continuous_on_If:
  1969   assumes closed: "closed s" "closed t" and cont: "continuous_on s f" "continuous_on t g"
  1970     and P: "\<And>x. x \<in> s \<Longrightarrow> \<not> P x \<Longrightarrow> f x = g x" "\<And>x. x \<in> t \<Longrightarrow> P x \<Longrightarrow> f x = g x"
  1971   shows "continuous_on (s \<union> t) (\<lambda>x. if P x then f x else g x)" (is "continuous_on _ ?h")
  1972 proof-
  1973   from P have "\<forall>x\<in>s. f x = ?h x" "\<forall>x\<in>t. g x = ?h x"
  1974     by auto
  1975   with cont have "continuous_on s ?h" "continuous_on t ?h"
  1976     by simp_all
  1977   with closed show ?thesis
  1978     by (rule continuous_on_closed_Un)
  1979 qed
  1980 
  1981 lemma continuous_on_id[continuous_intros]: "continuous_on s (\<lambda>x. x)"
  1982   unfolding continuous_on_def by (fast intro: tendsto_ident_at)
  1983 
  1984 lemma continuous_on_const[continuous_intros]: "continuous_on s (\<lambda>x. c)"
  1985   unfolding continuous_on_def by (auto intro: tendsto_const)
  1986 
  1987 lemma continuous_on_compose[continuous_intros]:
  1988   "continuous_on s f \<Longrightarrow> continuous_on (f ` s) g \<Longrightarrow> continuous_on s (g o f)"
  1989   unfolding continuous_on_topological by simp metis
  1990 
  1991 lemma continuous_on_compose2:
  1992   "continuous_on t g \<Longrightarrow> continuous_on s f \<Longrightarrow> t = f ` s \<Longrightarrow> continuous_on s (\<lambda>x. g (f x))"
  1993   using continuous_on_compose[of s f g] by (simp add: comp_def)
  1994 
  1995 subsubsection {* Continuity at a point *}
  1996 
  1997 definition continuous :: "'a::t2_space filter \<Rightarrow> ('a \<Rightarrow> 'b::topological_space) \<Rightarrow> bool" where
  1998   "continuous F f \<longleftrightarrow> (f ---> f (Lim F (\<lambda>x. x))) F"
  1999 
  2000 lemma continuous_bot[continuous_intros, simp]: "continuous bot f"
  2001   unfolding continuous_def by auto
  2002 
  2003 lemma continuous_trivial_limit: "trivial_limit net \<Longrightarrow> continuous net f"
  2004   by simp
  2005 
  2006 lemma continuous_within: "continuous (at x within s) f \<longleftrightarrow> (f ---> f x) (at x within s)"
  2007   by (cases "trivial_limit (at x within s)") (auto simp add: Lim_ident_at continuous_def)
  2008 
  2009 lemma continuous_within_topological:
  2010   "continuous (at x within s) f \<longleftrightarrow>
  2011     (\<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow> (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  2012   unfolding continuous_within tendsto_def eventually_at_topological by metis
  2013 
  2014 lemma continuous_within_compose[continuous_intros]:
  2015   "continuous (at x within s) f \<Longrightarrow> continuous (at (f x) within f ` s) g \<Longrightarrow>
  2016   continuous (at x within s) (g o f)"
  2017   by (simp add: continuous_within_topological) metis
  2018 
  2019 lemma continuous_within_compose2:
  2020   "continuous (at x within s) f \<Longrightarrow> continuous (at (f x) within f ` s) g \<Longrightarrow>
  2021   continuous (at x within s) (\<lambda>x. g (f x))"
  2022   using continuous_within_compose[of x s f g] by (simp add: comp_def)
  2023 
  2024 lemma continuous_at: "continuous (at x) f \<longleftrightarrow> f -- x --> f x"
  2025   using continuous_within[of x UNIV f] by simp
  2026 
  2027 lemma continuous_ident[continuous_intros, simp]: "continuous (at x within S) (\<lambda>x. x)"
  2028   unfolding continuous_within by (rule tendsto_ident_at)
  2029 
  2030 lemma continuous_const[continuous_intros, simp]: "continuous F (\<lambda>x. c)"
  2031   unfolding continuous_def by (rule tendsto_const)
  2032 
  2033 lemma continuous_on_eq_continuous_within:
  2034   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. continuous (at x within s) f)"
  2035   unfolding continuous_on_def continuous_within ..
  2036 
  2037 abbreviation isCont :: "('a::t2_space \<Rightarrow> 'b::topological_space) \<Rightarrow> 'a \<Rightarrow> bool" where
  2038   "isCont f a \<equiv> continuous (at a) f"
  2039 
  2040 lemma isCont_def: "isCont f a \<longleftrightarrow> f -- a --> f a"
  2041   by (rule continuous_at)
  2042 
  2043 lemma continuous_at_within: "isCont f x \<Longrightarrow> continuous (at x within s) f"
  2044   by (auto intro: tendsto_mono at_le simp: continuous_at continuous_within)
  2045 
  2046 lemma continuous_on_eq_continuous_at: "open s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. isCont f x)"
  2047   by (simp add: continuous_on_def continuous_at at_within_open[of _ s])
  2048 
  2049 lemma continuous_on_subset: "continuous_on s f \<Longrightarrow> t \<subseteq> s \<Longrightarrow> continuous_on t f"
  2050   unfolding continuous_on_def by (metis subset_eq tendsto_within_subset)
  2051 
  2052 lemma continuous_at_imp_continuous_on: "\<forall>x\<in>s. isCont f x \<Longrightarrow> continuous_on s f"
  2053   by (auto intro: continuous_at_within simp: continuous_on_eq_continuous_within)
  2054 
  2055 lemma isContI_continuous: "continuous (at x within UNIV) f \<Longrightarrow> isCont f x"
  2056   by simp
  2057 
  2058 lemma isCont_ident[continuous_intros, simp]: "isCont (\<lambda>x. x) a"
  2059   using continuous_ident by (rule isContI_continuous)
  2060 
  2061 lemmas isCont_const = continuous_const
  2062 
  2063 lemma isCont_o2: "isCont f a \<Longrightarrow> isCont g (f a) \<Longrightarrow> isCont (\<lambda>x. g (f x)) a"
  2064   unfolding isCont_def by (rule tendsto_compose)
  2065 
  2066 lemma isCont_o[continuous_intros]: "isCont f a \<Longrightarrow> isCont g (f a) \<Longrightarrow> isCont (g \<circ> f) a"
  2067   unfolding o_def by (rule isCont_o2)
  2068 
  2069 lemma isCont_tendsto_compose: "isCont g l \<Longrightarrow> (f ---> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> g l) F"
  2070   unfolding isCont_def by (rule tendsto_compose)
  2071 
  2072 lemma continuous_within_compose3:
  2073   "isCont g (f x) \<Longrightarrow> continuous (at x within s) f \<Longrightarrow> continuous (at x within s) (\<lambda>x. g (f x))"
  2074   using continuous_within_compose2[of x s f g] by (simp add: continuous_at_within)
  2075 
  2076 subsubsection{* Open-cover compactness *}
  2077 
  2078 context topological_space
  2079 begin
  2080 
  2081 definition compact :: "'a set \<Rightarrow> bool" where
  2082   compact_eq_heine_borel: -- "This name is used for backwards compatibility"
  2083     "compact S \<longleftrightarrow> (\<forall>C. (\<forall>c\<in>C. open c) \<and> S \<subseteq> \<Union>C \<longrightarrow> (\<exists>D\<subseteq>C. finite D \<and> S \<subseteq> \<Union>D))"
  2084 
  2085 lemma compactI:
  2086   assumes "\<And>C. \<forall>t\<in>C. open t \<Longrightarrow> s \<subseteq> \<Union> C \<Longrightarrow> \<exists>C'. C' \<subseteq> C \<and> finite C' \<and> s \<subseteq> \<Union> C'"
  2087   shows "compact s"
  2088   unfolding compact_eq_heine_borel using assms by metis
  2089 
  2090 lemma compact_empty[simp]: "compact {}"
  2091   by (auto intro!: compactI)
  2092 
  2093 lemma compactE:
  2094   assumes "compact s" and "\<forall>t\<in>C. open t" and "s \<subseteq> \<Union>C"
  2095   obtains C' where "C' \<subseteq> C" and "finite C'" and "s \<subseteq> \<Union>C'"
  2096   using assms unfolding compact_eq_heine_borel by metis
  2097 
  2098 lemma compactE_image:
  2099   assumes "compact s" and "\<forall>t\<in>C. open (f t)" and "s \<subseteq> (\<Union>c\<in>C. f c)"
  2100   obtains C' where "C' \<subseteq> C" and "finite C'" and "s \<subseteq> (\<Union>c\<in>C'. f c)"
  2101   using assms unfolding ball_simps[symmetric] SUP_def
  2102   by (metis (lifting) finite_subset_image compact_eq_heine_borel[of s])
  2103 
  2104 lemma compact_inter_closed [intro]:
  2105   assumes "compact s" and "closed t"
  2106   shows "compact (s \<inter> t)"
  2107 proof (rule compactI)
  2108   fix C assume C: "\<forall>c\<in>C. open c" and cover: "s \<inter> t \<subseteq> \<Union>C"
  2109   from C `closed t` have "\<forall>c\<in>C \<union> {-t}. open c" by auto
  2110   moreover from cover have "s \<subseteq> \<Union>(C \<union> {-t})" by auto
  2111   ultimately have "\<exists>D\<subseteq>C \<union> {-t}. finite D \<and> s \<subseteq> \<Union>D"
  2112     using `compact s` unfolding compact_eq_heine_borel by auto
  2113   then obtain D where "D \<subseteq> C \<union> {- t} \<and> finite D \<and> s \<subseteq> \<Union>D" ..
  2114   then show "\<exists>D\<subseteq>C. finite D \<and> s \<inter> t \<subseteq> \<Union>D"
  2115     by (intro exI[of _ "D - {-t}"]) auto
  2116 qed
  2117 
  2118 lemma inj_setminus: "inj_on uminus (A::'a set set)"
  2119   by (auto simp: inj_on_def)
  2120 
  2121 lemma compact_fip:
  2122   "compact U \<longleftrightarrow>
  2123     (\<forall>A. (\<forall>a\<in>A. closed a) \<longrightarrow> (\<forall>B \<subseteq> A. finite B \<longrightarrow> U \<inter> \<Inter>B \<noteq> {}) \<longrightarrow> U \<inter> \<Inter>A \<noteq> {})"
  2124   (is "_ \<longleftrightarrow> ?R")
  2125 proof (safe intro!: compact_eq_heine_borel[THEN iffD2])
  2126   fix A
  2127   assume "compact U"
  2128     and A: "\<forall>a\<in>A. closed a" "U \<inter> \<Inter>A = {}"
  2129     and fi: "\<forall>B \<subseteq> A. finite B \<longrightarrow> U \<inter> \<Inter>B \<noteq> {}"
  2130   from A have "(\<forall>a\<in>uminus`A. open a) \<and> U \<subseteq> \<Union>(uminus`A)"
  2131     by auto
  2132   with `compact U` obtain B where "B \<subseteq> A" "finite (uminus`B)" "U \<subseteq> \<Union>(uminus`B)"
  2133     unfolding compact_eq_heine_borel by (metis subset_image_iff)
  2134   with fi[THEN spec, of B] show False
  2135     by (auto dest: finite_imageD intro: inj_setminus)
  2136 next
  2137   fix A
  2138   assume ?R
  2139   assume "\<forall>a\<in>A. open a" "U \<subseteq> \<Union>A"
  2140   then have "U \<inter> \<Inter>(uminus`A) = {}" "\<forall>a\<in>uminus`A. closed a"
  2141     by auto
  2142   with `?R` obtain B where "B \<subseteq> A" "finite (uminus`B)" "U \<inter> \<Inter>(uminus`B) = {}"
  2143     by (metis subset_image_iff)
  2144   then show "\<exists>T\<subseteq>A. finite T \<and> U \<subseteq> \<Union>T"
  2145     by  (auto intro!: exI[of _ B] inj_setminus dest: finite_imageD)
  2146 qed
  2147 
  2148 lemma compact_imp_fip:
  2149   "compact s \<Longrightarrow> \<forall>t \<in> f. closed t \<Longrightarrow> \<forall>f'. finite f' \<and> f' \<subseteq> f \<longrightarrow> (s \<inter> (\<Inter> f') \<noteq> {}) \<Longrightarrow>
  2150     s \<inter> (\<Inter> f) \<noteq> {}"
  2151   unfolding compact_fip by auto
  2152 
  2153 lemma compact_imp_fip_image:
  2154   assumes "compact s"
  2155     and P: "\<And>i. i \<in> I \<Longrightarrow> closed (f i)"
  2156     and Q: "\<And>I'. finite I' \<Longrightarrow> I' \<subseteq> I \<Longrightarrow> (s \<inter> (\<Inter>i\<in>I'. f i) \<noteq> {})"
  2157   shows "s \<inter> (\<Inter>i\<in>I. f i) \<noteq> {}"
  2158 proof -
  2159   note `compact s`
  2160   moreover from P have "\<forall>i \<in> f ` I. closed i" by blast
  2161   moreover have "\<forall>A. finite A \<and> A \<subseteq> f ` I \<longrightarrow> (s \<inter> (\<Inter>A) \<noteq> {})"
  2162   proof (rule, rule, erule conjE)
  2163     fix A :: "'a set set"
  2164     assume "finite A"
  2165     moreover assume "A \<subseteq> f ` I"
  2166     ultimately obtain B where "B \<subseteq> I" and "finite B" and "A = f ` B"
  2167       using finite_subset_image [of A f I] by blast
  2168     with Q [of B] show "s \<inter> \<Inter>A \<noteq> {}" by simp
  2169   qed
  2170   ultimately have "s \<inter> (\<Inter>(f ` I)) \<noteq> {}" by (rule compact_imp_fip)
  2171   then show ?thesis by simp
  2172 qed
  2173 
  2174 end
  2175 
  2176 lemma (in t2_space) compact_imp_closed:
  2177   assumes "compact s" shows "closed s"
  2178 unfolding closed_def
  2179 proof (rule openI)
  2180   fix y assume "y \<in> - s"
  2181   let ?C = "\<Union>x\<in>s. {u. open u \<and> x \<in> u \<and> eventually (\<lambda>y. y \<notin> u) (nhds y)}"
  2182   note `compact s`
  2183   moreover have "\<forall>u\<in>?C. open u" by simp
  2184   moreover have "s \<subseteq> \<Union>?C"
  2185   proof
  2186     fix x assume "x \<in> s"
  2187     with `y \<in> - s` have "x \<noteq> y" by clarsimp
  2188     hence "\<exists>u v. open u \<and> open v \<and> x \<in> u \<and> y \<in> v \<and> u \<inter> v = {}"
  2189       by (rule hausdorff)
  2190     with `x \<in> s` show "x \<in> \<Union>?C"
  2191       unfolding eventually_nhds by auto
  2192   qed
  2193   ultimately obtain D where "D \<subseteq> ?C" and "finite D" and "s \<subseteq> \<Union>D"
  2194     by (rule compactE)
  2195   from `D \<subseteq> ?C` have "\<forall>x\<in>D. eventually (\<lambda>y. y \<notin> x) (nhds y)" by auto
  2196   with `finite D` have "eventually (\<lambda>y. y \<notin> \<Union>D) (nhds y)"
  2197     by (simp add: eventually_Ball_finite)
  2198   with `s \<subseteq> \<Union>D` have "eventually (\<lambda>y. y \<notin> s) (nhds y)"
  2199     by (auto elim!: eventually_mono [rotated])
  2200   thus "\<exists>t. open t \<and> y \<in> t \<and> t \<subseteq> - s"
  2201     by (simp add: eventually_nhds subset_eq)
  2202 qed
  2203 
  2204 lemma compact_continuous_image:
  2205   assumes f: "continuous_on s f" and s: "compact s"
  2206   shows "compact (f ` s)"
  2207 proof (rule compactI)
  2208   fix C assume "\<forall>c\<in>C. open c" and cover: "f`s \<subseteq> \<Union>C"
  2209   with f have "\<forall>c\<in>C. \<exists>A. open A \<and> A \<inter> s = f -` c \<inter> s"
  2210     unfolding continuous_on_open_invariant by blast
  2211   then obtain A where A: "\<forall>c\<in>C. open (A c) \<and> A c \<inter> s = f -` c \<inter> s"
  2212     unfolding bchoice_iff ..
  2213   with cover have "\<forall>c\<in>C. open (A c)" "s \<subseteq> (\<Union>c\<in>C. A c)"
  2214     by (fastforce simp add: subset_eq set_eq_iff)+
  2215   from compactE_image[OF s this] obtain D where "D \<subseteq> C" "finite D" "s \<subseteq> (\<Union>c\<in>D. A c)" .
  2216   with A show "\<exists>D \<subseteq> C. finite D \<and> f`s \<subseteq> \<Union>D"
  2217     by (intro exI[of _ D]) (fastforce simp add: subset_eq set_eq_iff)+
  2218 qed
  2219 
  2220 lemma continuous_on_inv:
  2221   fixes f :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  2222   assumes "continuous_on s f"  "compact s"  "\<forall>x\<in>s. g (f x) = x"
  2223   shows "continuous_on (f ` s) g"
  2224 unfolding continuous_on_topological
  2225 proof (clarsimp simp add: assms(3))
  2226   fix x :: 'a and B :: "'a set"
  2227   assume "x \<in> s" and "open B" and "x \<in> B"
  2228   have 1: "\<forall>x\<in>s. f x \<in> f ` (s - B) \<longleftrightarrow> x \<in> s - B"
  2229     using assms(3) by (auto, metis)
  2230   have "continuous_on (s - B) f"
  2231     using `continuous_on s f` Diff_subset
  2232     by (rule continuous_on_subset)
  2233   moreover have "compact (s - B)"
  2234     using `open B` and `compact s`
  2235     unfolding Diff_eq by (intro compact_inter_closed closed_Compl)
  2236   ultimately have "compact (f ` (s - B))"
  2237     by (rule compact_continuous_image)
  2238   hence "closed (f ` (s - B))"
  2239     by (rule compact_imp_closed)
  2240   hence "open (- f ` (s - B))"
  2241     by (rule open_Compl)
  2242   moreover have "f x \<in> - f ` (s - B)"
  2243     using `x \<in> s` and `x \<in> B` by (simp add: 1)
  2244   moreover have "\<forall>y\<in>s. f y \<in> - f ` (s - B) \<longrightarrow> y \<in> B"
  2245     by (simp add: 1)
  2246   ultimately show "\<exists>A. open A \<and> f x \<in> A \<and> (\<forall>y\<in>s. f y \<in> A \<longrightarrow> y \<in> B)"
  2247     by fast
  2248 qed
  2249 
  2250 lemma continuous_on_inv_into:
  2251   fixes f :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  2252   assumes s: "continuous_on s f" "compact s" and f: "inj_on f s"
  2253   shows "continuous_on (f ` s) (the_inv_into s f)"
  2254   by (rule continuous_on_inv[OF s]) (auto simp: the_inv_into_f_f[OF f])
  2255 
  2256 lemma (in linorder_topology) compact_attains_sup:
  2257   assumes "compact S" "S \<noteq> {}"
  2258   shows "\<exists>s\<in>S. \<forall>t\<in>S. t \<le> s"
  2259 proof (rule classical)
  2260   assume "\<not> (\<exists>s\<in>S. \<forall>t\<in>S. t \<le> s)"
  2261   then obtain t where t: "\<forall>s\<in>S. t s \<in> S" and "\<forall>s\<in>S. s < t s"
  2262     by (metis not_le)
  2263   then have "\<forall>s\<in>S. open {..< t s}" "S \<subseteq> (\<Union>s\<in>S. {..< t s})"
  2264     by auto
  2265   with `compact S` obtain C where "C \<subseteq> S" "finite C" and C: "S \<subseteq> (\<Union>s\<in>C. {..< t s})"
  2266     by (erule compactE_image)
  2267   with `S \<noteq> {}` have Max: "Max (t`C) \<in> t`C" and "\<forall>s\<in>t`C. s \<le> Max (t`C)"
  2268     by (auto intro!: Max_in)
  2269   with C have "S \<subseteq> {..< Max (t`C)}"
  2270     by (auto intro: less_le_trans simp: subset_eq)
  2271   with t Max `C \<subseteq> S` show ?thesis
  2272     by fastforce
  2273 qed
  2274 
  2275 lemma (in linorder_topology) compact_attains_inf:
  2276   assumes "compact S" "S \<noteq> {}"
  2277   shows "\<exists>s\<in>S. \<forall>t\<in>S. s \<le> t"
  2278 proof (rule classical)
  2279   assume "\<not> (\<exists>s\<in>S. \<forall>t\<in>S. s \<le> t)"
  2280   then obtain t where t: "\<forall>s\<in>S. t s \<in> S" and "\<forall>s\<in>S. t s < s"
  2281     by (metis not_le)
  2282   then have "\<forall>s\<in>S. open {t s <..}" "S \<subseteq> (\<Union>s\<in>S. {t s <..})"
  2283     by auto
  2284   with `compact S` obtain C where "C \<subseteq> S" "finite C" and C: "S \<subseteq> (\<Union>s\<in>C. {t s <..})"
  2285     by (erule compactE_image)
  2286   with `S \<noteq> {}` have Min: "Min (t`C) \<in> t`C" and "\<forall>s\<in>t`C. Min (t`C) \<le> s"
  2287     by (auto intro!: Min_in)
  2288   with C have "S \<subseteq> {Min (t`C) <..}"
  2289     by (auto intro: le_less_trans simp: subset_eq)
  2290   with t Min `C \<subseteq> S` show ?thesis
  2291     by fastforce
  2292 qed
  2293 
  2294 lemma continuous_attains_sup:
  2295   fixes f :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  2296   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f \<Longrightarrow> (\<exists>x\<in>s. \<forall>y\<in>s.  f y \<le> f x)"
  2297   using compact_attains_sup[of "f ` s"] compact_continuous_image[of s f] by auto
  2298 
  2299 lemma continuous_attains_inf:
  2300   fixes f :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  2301   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f \<Longrightarrow> (\<exists>x\<in>s. \<forall>y\<in>s. f x \<le> f y)"
  2302   using compact_attains_inf[of "f ` s"] compact_continuous_image[of s f] by auto
  2303 
  2304 
  2305 subsection {* Connectedness *}
  2306 
  2307 context topological_space
  2308 begin
  2309 
  2310 definition "connected S \<longleftrightarrow>
  2311   \<not> (\<exists>A B. open A \<and> open B \<and> S \<subseteq> A \<union> B \<and> A \<inter> B \<inter> S = {} \<and> A \<inter> S \<noteq> {} \<and> B \<inter> S \<noteq> {})"
  2312 
  2313 lemma connectedI:
  2314   "(\<And>A B. open A \<Longrightarrow> open B \<Longrightarrow> A \<inter> U \<noteq> {} \<Longrightarrow> B \<inter> U \<noteq> {} \<Longrightarrow> A \<inter> B \<inter> U = {} \<Longrightarrow> U \<subseteq> A \<union> B \<Longrightarrow> False)
  2315   \<Longrightarrow> connected U"
  2316   by (auto simp: connected_def)
  2317 
  2318 lemma connected_empty[simp]: "connected {}"
  2319   by (auto intro!: connectedI)
  2320 
  2321 lemma connectedD:
  2322   "connected A \<Longrightarrow> open U \<Longrightarrow> open V \<Longrightarrow> U \<inter> V \<inter> A = {} \<Longrightarrow> A \<subseteq> U \<union> V \<Longrightarrow> U \<inter> A = {} \<or> V \<inter> A = {}" 
  2323   by (auto simp: connected_def)
  2324 
  2325 end
  2326 
  2327 lemma connected_local_const:
  2328   assumes "connected A" "a \<in> A" "b \<in> A"
  2329   assumes *: "\<forall>a\<in>A. eventually (\<lambda>b. f a = f b) (at a within A)"
  2330   shows "f a = f b"
  2331 proof -
  2332   obtain S where S: "\<And>a. a \<in> A \<Longrightarrow> a \<in> S a" "\<And>a. a \<in> A \<Longrightarrow> open (S a)"
  2333     "\<And>a x. a \<in> A \<Longrightarrow> x \<in> S a \<Longrightarrow> x \<in> A \<Longrightarrow> f a = f x"
  2334     using * unfolding eventually_at_topological by metis
  2335 
  2336   let ?P = "\<Union>b\<in>{b\<in>A. f a = f b}. S b" and ?N = "\<Union>b\<in>{b\<in>A. f a \<noteq> f b}. S b"
  2337   have "?P \<inter> A = {} \<or> ?N \<inter> A = {}"
  2338     using `connected A` S `a\<in>A`
  2339     by (intro connectedD) (auto, metis)
  2340   then show "f a = f b"
  2341   proof
  2342     assume "?N \<inter> A = {}"
  2343     then have "\<forall>x\<in>A. f a = f x"
  2344       using S(1) by auto
  2345     with `b\<in>A` show ?thesis by auto
  2346   next
  2347     assume "?P \<inter> A = {}" then show ?thesis
  2348       using `a \<in> A` S(1)[of a] by auto
  2349   qed
  2350 qed
  2351 
  2352 lemma (in linorder_topology) connectedD_interval:
  2353   assumes "connected U" and xy: "x \<in> U" "y \<in> U" and "x \<le> z" "z \<le> y"
  2354   shows "z \<in> U"
  2355 proof -
  2356   have eq: "{..<z} \<union> {z<..} = - {z}"
  2357     by auto
  2358   { assume "z \<notin> U" "x < z" "z < y"
  2359     with xy have "\<not> connected U"
  2360       unfolding connected_def simp_thms
  2361       apply (rule_tac exI[of _ "{..< z}"])
  2362       apply (rule_tac exI[of _ "{z <..}"])
  2363       apply (auto simp add: eq)
  2364       done }
  2365   with assms show "z \<in> U"
  2366     by (metis less_le)
  2367 qed
  2368 
  2369 lemma connected_continuous_image:
  2370   assumes *: "continuous_on s f"
  2371   assumes "connected s"
  2372   shows "connected (f ` s)"
  2373 proof (rule connectedI)
  2374   fix A B assume A: "open A" "A \<inter> f ` s \<noteq> {}" and B: "open B" "B \<inter> f ` s \<noteq> {}" and
  2375     AB: "A \<inter> B \<inter> f ` s = {}" "f ` s \<subseteq> A \<union> B"
  2376   obtain A' where A': "open A'" "f -` A \<inter> s = A' \<inter> s"
  2377     using * `open A` unfolding continuous_on_open_invariant by metis
  2378   obtain B' where B': "open B'" "f -` B \<inter> s = B' \<inter> s"
  2379     using * `open B` unfolding continuous_on_open_invariant by metis
  2380 
  2381   have "\<exists>A B. open A \<and> open B \<and> s \<subseteq> A \<union> B \<and> A \<inter> B \<inter> s = {} \<and> A \<inter> s \<noteq> {} \<and> B \<inter> s \<noteq> {}"
  2382   proof (rule exI[of _ A'], rule exI[of _ B'], intro conjI)
  2383     have "s \<subseteq> (f -` A \<inter> s) \<union> (f -` B \<inter> s)" using AB by auto
  2384     then show "s \<subseteq> A' \<union> B'" using A' B' by auto
  2385   next
  2386     have "(f -` A \<inter> s) \<inter> (f -` B \<inter> s) = {}" using AB by auto
  2387     then show "A' \<inter> B' \<inter> s = {}" using A' B' by auto
  2388   qed (insert A' B' A B, auto)
  2389   with `connected s` show False
  2390     unfolding connected_def by blast
  2391 qed
  2392 
  2393 
  2394 section {* Connectedness *}
  2395 
  2396 class linear_continuum_topology = linorder_topology + linear_continuum
  2397 begin
  2398 
  2399 lemma Inf_notin_open:
  2400   assumes A: "open A" and bnd: "\<forall>a\<in>A. x < a"
  2401   shows "Inf A \<notin> A"
  2402 proof
  2403   assume "Inf A \<in> A"
  2404   then obtain b where "b < Inf A" "{b <.. Inf A} \<subseteq> A"
  2405     using open_left[of A "Inf A" x] assms by auto
  2406   with dense[of b "Inf A"] obtain c where "c < Inf A" "c \<in> A"
  2407     by (auto simp: subset_eq)
  2408   then show False
  2409     using cInf_lower[OF `c \<in> A`] bnd by (metis not_le less_imp_le bdd_belowI)
  2410 qed
  2411 
  2412 lemma Sup_notin_open:
  2413   assumes A: "open A" and bnd: "\<forall>a\<in>A. a < x"
  2414   shows "Sup A \<notin> A"
  2415 proof
  2416   assume "Sup A \<in> A"
  2417   then obtain b where "Sup A < b" "{Sup A ..< b} \<subseteq> A"
  2418     using open_right[of A "Sup A" x] assms by auto
  2419   with dense[of "Sup A" b] obtain c where "Sup A < c" "c \<in> A"
  2420     by (auto simp: subset_eq)
  2421   then show False
  2422     using cSup_upper[OF `c \<in> A`] bnd by (metis less_imp_le not_le bdd_aboveI)
  2423 qed
  2424 
  2425 end
  2426 
  2427 instance linear_continuum_topology \<subseteq> perfect_space
  2428 proof
  2429   fix x :: 'a
  2430   obtain y where "x < y \<or> y < x"
  2431     using ex_gt_or_lt [of x] ..
  2432   with Inf_notin_open[of "{x}" y] Sup_notin_open[of "{x}" y]
  2433   show "\<not> open {x}"
  2434     by auto
  2435 qed
  2436 
  2437 lemma connectedI_interval:
  2438   fixes U :: "'a :: linear_continuum_topology set"
  2439   assumes *: "\<And>x y z. x \<in> U \<Longrightarrow> y \<in> U \<Longrightarrow> x \<le> z \<Longrightarrow> z \<le> y \<Longrightarrow> z \<in> U"
  2440   shows "connected U"
  2441 proof (rule connectedI)
  2442   { fix A B assume "open A" "open B" "A \<inter> B \<inter> U = {}" "U \<subseteq> A \<union> B"
  2443     fix x y assume "x < y" "x \<in> A" "y \<in> B" "x \<in> U" "y \<in> U"
  2444 
  2445     let ?z = "Inf (B \<inter> {x <..})"
  2446 
  2447     have "x \<le> ?z" "?z \<le> y"
  2448       using `y \<in> B` `x < y` by (auto intro: cInf_lower cInf_greatest)
  2449     with `x \<in> U` `y \<in> U` have "?z \<in> U"
  2450       by (rule *)
  2451     moreover have "?z \<notin> B \<inter> {x <..}"
  2452       using `open B` by (intro Inf_notin_open) auto
  2453     ultimately have "?z \<in> A"
  2454       using `x \<le> ?z` `A \<inter> B \<inter> U = {}` `x \<in> A` `U \<subseteq> A \<union> B` by auto
  2455 
  2456     { assume "?z < y"
  2457       obtain a where "?z < a" "{?z ..< a} \<subseteq> A"
  2458         using open_right[OF `open A` `?z \<in> A` `?z < y`] by auto
  2459       moreover obtain b where "b \<in> B" "x < b" "b < min a y"
  2460         using cInf_less_iff[of "B \<inter> {x <..}" "min a y"] `?z < a` `?z < y` `x < y` `y \<in> B`
  2461         by (auto intro: less_imp_le)
  2462       moreover have "?z \<le> b"
  2463         using `b \<in> B` `x < b`
  2464         by (intro cInf_lower) auto
  2465       moreover have "b \<in> U"
  2466         using `x \<le> ?z` `?z \<le> b` `b < min a y`
  2467         by (intro *[OF `x \<in> U` `y \<in> U`]) (auto simp: less_imp_le)
  2468       ultimately have "\<exists>b\<in>B. b \<in> A \<and> b \<in> U"
  2469         by (intro bexI[of _ b]) auto }
  2470     then have False
  2471       using `?z \<le> y` `?z \<in> A` `y \<in> B` `y \<in> U` `A \<inter> B \<inter> U = {}` unfolding le_less by blast }
  2472   note not_disjoint = this
  2473 
  2474   fix A B assume AB: "open A" "open B" "U \<subseteq> A \<union> B" "A \<inter> B \<inter> U = {}"
  2475   moreover assume "A \<inter> U \<noteq> {}" then obtain x where x: "x \<in> U" "x \<in> A" by auto
  2476   moreover assume "B \<inter> U \<noteq> {}" then obtain y where y: "y \<in> U" "y \<in> B" by auto
  2477   moreover note not_disjoint[of B A y x] not_disjoint[of A B x y]
  2478   ultimately show False by (cases x y rule: linorder_cases) auto
  2479 qed
  2480 
  2481 lemma connected_iff_interval:
  2482   fixes U :: "'a :: linear_continuum_topology set"
  2483   shows "connected U \<longleftrightarrow> (\<forall>x\<in>U. \<forall>y\<in>U. \<forall>z. x \<le> z \<longrightarrow> z \<le> y \<longrightarrow> z \<in> U)"
  2484   by (auto intro: connectedI_interval dest: connectedD_interval)
  2485 
  2486 lemma connected_UNIV[simp]: "connected (UNIV::'a::linear_continuum_topology set)"
  2487   unfolding connected_iff_interval by auto
  2488 
  2489 lemma connected_Ioi[simp]: "connected {a::'a::linear_continuum_topology <..}"
  2490   unfolding connected_iff_interval by auto
  2491 
  2492 lemma connected_Ici[simp]: "connected {a::'a::linear_continuum_topology ..}"
  2493   unfolding connected_iff_interval by auto
  2494 
  2495 lemma connected_Iio[simp]: "connected {..< a::'a::linear_continuum_topology}"
  2496   unfolding connected_iff_interval by auto
  2497 
  2498 lemma connected_Iic[simp]: "connected {.. a::'a::linear_continuum_topology}"
  2499   unfolding connected_iff_interval by auto
  2500 
  2501 lemma connected_Ioo[simp]: "connected {a <..< b::'a::linear_continuum_topology}"
  2502   unfolding connected_iff_interval by auto
  2503 
  2504 lemma connected_Ioc[simp]: "connected {a <.. b::'a::linear_continuum_topology}"
  2505   unfolding connected_iff_interval by auto
  2506 
  2507 lemma connected_Ico[simp]: "connected {a ..< b::'a::linear_continuum_topology}"
  2508   unfolding connected_iff_interval by auto
  2509 
  2510 lemma connected_Icc[simp]: "connected {a .. b::'a::linear_continuum_topology}"
  2511   unfolding connected_iff_interval by auto
  2512 
  2513 lemma connected_contains_Ioo: 
  2514   fixes A :: "'a :: linorder_topology set"
  2515   assumes A: "connected A" "a \<in> A" "b \<in> A" shows "{a <..< b} \<subseteq> A"
  2516   using connectedD_interval[OF A] by (simp add: subset_eq Ball_def less_imp_le)
  2517 
  2518 subsection {* Intermediate Value Theorem *}
  2519 
  2520 lemma IVT':
  2521   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2522   assumes y: "f a \<le> y" "y \<le> f b" "a \<le> b"
  2523   assumes *: "continuous_on {a .. b} f"
  2524   shows "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2525 proof -
  2526   have "connected {a..b}"
  2527     unfolding connected_iff_interval by auto
  2528   from connected_continuous_image[OF * this, THEN connectedD_interval, of "f a" "f b" y] y
  2529   show ?thesis
  2530     by (auto simp add: atLeastAtMost_def atLeast_def atMost_def)
  2531 qed
  2532 
  2533 lemma IVT2':
  2534   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2535   assumes y: "f b \<le> y" "y \<le> f a" "a \<le> b"
  2536   assumes *: "continuous_on {a .. b} f"
  2537   shows "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2538 proof -
  2539   have "connected {a..b}"
  2540     unfolding connected_iff_interval by auto
  2541   from connected_continuous_image[OF * this, THEN connectedD_interval, of "f b" "f a" y] y
  2542   show ?thesis
  2543     by (auto simp add: atLeastAtMost_def atLeast_def atMost_def)
  2544 qed
  2545 
  2546 lemma IVT:
  2547   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2548   shows "f a \<le> y \<Longrightarrow> y \<le> f b \<Longrightarrow> a \<le> b \<Longrightarrow> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x) \<Longrightarrow> \<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2549   by (rule IVT') (auto intro: continuous_at_imp_continuous_on)
  2550 
  2551 lemma IVT2:
  2552   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2553   shows "f b \<le> y \<Longrightarrow> y \<le> f a \<Longrightarrow> a \<le> b \<Longrightarrow> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x) \<Longrightarrow> \<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2554   by (rule IVT2') (auto intro: continuous_at_imp_continuous_on)
  2555 
  2556 lemma continuous_inj_imp_mono:
  2557   fixes f :: "'a::linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2558   assumes x: "a < x" "x < b"
  2559   assumes cont: "continuous_on {a..b} f"
  2560   assumes inj: "inj_on f {a..b}"
  2561   shows "(f a < f x \<and> f x < f b) \<or> (f b < f x \<and> f x < f a)"
  2562 proof -
  2563   note I = inj_on_iff[OF inj]
  2564   { assume "f x < f a" "f x < f b"
  2565     then obtain s t where "x \<le> s" "s \<le> b" "a \<le> t" "t \<le> x" "f s = f t" "f x < f s"
  2566       using IVT'[of f x "min (f a) (f b)" b] IVT2'[of f x "min (f a) (f b)" a] x
  2567       by (auto simp: continuous_on_subset[OF cont] less_imp_le)
  2568     with x I have False by auto }
  2569   moreover
  2570   { assume "f a < f x" "f b < f x"
  2571     then obtain s t where "x \<le> s" "s \<le> b" "a \<le> t" "t \<le> x" "f s = f t" "f s < f x"
  2572       using IVT'[of f a "max (f a) (f b)" x] IVT2'[of f b "max (f a) (f b)" x] x
  2573       by (auto simp: continuous_on_subset[OF cont] less_imp_le)
  2574     with x I have False by auto }
  2575   ultimately show ?thesis
  2576     using I[of a x] I[of x b] x less_trans[OF x] by (auto simp add: le_less less_imp_neq neq_iff)
  2577 qed
  2578 
  2579 subsection {* Setup @{typ "'a filter"} for lifting and transfer *}
  2580 
  2581 context begin interpretation lifting_syntax .
  2582 
  2583 definition rel_filter :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> 'b filter \<Rightarrow> bool"
  2584 where "rel_filter R F G = ((R ===> op =) ===> op =) (Rep_filter F) (Rep_filter G)"
  2585 
  2586 lemma rel_filter_eventually:
  2587   "rel_filter R F G \<longleftrightarrow> 
  2588   ((R ===> op =) ===> op =) (\<lambda>P. eventually P F) (\<lambda>P. eventually P G)"
  2589 by(simp add: rel_filter_def eventually_def)
  2590 
  2591 lemma filtermap_id [simp, id_simps]: "filtermap id = id"
  2592 by(simp add: fun_eq_iff id_def filtermap_ident)
  2593 
  2594 lemma filtermap_id' [simp]: "filtermap (\<lambda>x. x) = (\<lambda>F. F)"
  2595 using filtermap_id unfolding id_def .
  2596 
  2597 lemma Quotient_filter [quot_map]:
  2598   assumes Q: "Quotient R Abs Rep T"
  2599   shows "Quotient (rel_filter R) (filtermap Abs) (filtermap Rep) (rel_filter T)"
  2600 unfolding Quotient_alt_def
  2601 proof(intro conjI strip)
  2602   from Q have *: "\<And>x y. T x y \<Longrightarrow> Abs x = y"
  2603     unfolding Quotient_alt_def by blast
  2604 
  2605   fix F G
  2606   assume "rel_filter T F G"
  2607   thus "filtermap Abs F = G" unfolding filter_eq_iff
  2608     by(auto simp add: eventually_filtermap rel_filter_eventually * rel_funI del: iffI elim!: rel_funD)
  2609 next
  2610   from Q have *: "\<And>x. T (Rep x) x" unfolding Quotient_alt_def by blast
  2611 
  2612   fix F
  2613   show "rel_filter T (filtermap Rep F) F" 
  2614     by(auto elim: rel_funD intro: * intro!: ext arg_cong[where f="\<lambda>P. eventually P F"] rel_funI
  2615             del: iffI simp add: eventually_filtermap rel_filter_eventually)
  2616 qed(auto simp add: map_fun_def o_def eventually_filtermap filter_eq_iff fun_eq_iff rel_filter_eventually
  2617          fun_quotient[OF fun_quotient[OF Q identity_quotient] identity_quotient, unfolded Quotient_alt_def])
  2618 
  2619 lemma eventually_parametric [transfer_rule]:
  2620   "((A ===> op =) ===> rel_filter A ===> op =) eventually eventually"
  2621 by(simp add: rel_fun_def rel_filter_eventually)
  2622 
  2623 lemma rel_filter_eq [relator_eq]: "rel_filter op = = op ="
  2624 by(auto simp add: rel_filter_eventually rel_fun_eq fun_eq_iff filter_eq_iff)
  2625 
  2626 lemma rel_filter_mono [relator_mono]:
  2627   "A \<le> B \<Longrightarrow> rel_filter A \<le> rel_filter B"
  2628 unfolding rel_filter_eventually[abs_def]
  2629 by(rule le_funI)+(intro fun_mono fun_mono[THEN le_funD, THEN le_funD] order.refl)
  2630 
  2631 lemma rel_filter_conversep [simp]: "rel_filter A\<inverse>\<inverse> = (rel_filter A)\<inverse>\<inverse>"
  2632 by(auto simp add: rel_filter_eventually fun_eq_iff rel_fun_def)
  2633 
  2634 lemma is_filter_parametric_aux:
  2635   assumes "is_filter F"
  2636   assumes [transfer_rule]: "bi_total A" "bi_unique A"
  2637   and [transfer_rule]: "((A ===> op =) ===> op =) F G"
  2638   shows "is_filter G"
  2639 proof -
  2640   interpret is_filter F by fact
  2641   show ?thesis
  2642   proof
  2643     have "F (\<lambda>_. True) = G (\<lambda>x. True)" by transfer_prover
  2644     thus "G (\<lambda>x. True)" by(simp add: True)
  2645   next
  2646     fix P' Q'
  2647     assume "G P'" "G Q'"
  2648     moreover
  2649     from bi_total_fun[OF `bi_unique A` bi_total_eq, unfolded bi_total_def]
  2650     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
  2651     have "F P = G P'" "F Q = G Q'" by transfer_prover+
  2652     ultimately have "F (\<lambda>x. P x \<and> Q x)" by(simp add: conj)
  2653     moreover have "F (\<lambda>x. P x \<and> Q x) = G (\<lambda>x. P' x \<and> Q' x)" by transfer_prover
  2654     ultimately show "G (\<lambda>x. P' x \<and> Q' x)" by simp
  2655   next
  2656     fix P' Q'
  2657     assume "\<forall>x. P' x \<longrightarrow> Q' x" "G P'"
  2658     moreover
  2659     from bi_total_fun[OF `bi_unique A` bi_total_eq, unfolded bi_total_def]
  2660     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
  2661     have "F P = G P'" by transfer_prover
  2662     moreover have "(\<forall>x. P x \<longrightarrow> Q x) \<longleftrightarrow> (\<forall>x. P' x \<longrightarrow> Q' x)" by transfer_prover
  2663     ultimately have "F Q" by(simp add: mono)
  2664     moreover have "F Q = G Q'" by transfer_prover
  2665     ultimately show "G Q'" by simp
  2666   qed
  2667 qed
  2668 
  2669 lemma is_filter_parametric [transfer_rule]:
  2670   "\<lbrakk> bi_total A; bi_unique A \<rbrakk>
  2671   \<Longrightarrow> (((A ===> op =) ===> op =) ===> op =) is_filter is_filter"
  2672 apply(rule rel_funI)
  2673 apply(rule iffI)
  2674  apply(erule (3) is_filter_parametric_aux)
  2675 apply(erule is_filter_parametric_aux[where A="conversep A"])
  2676 apply(auto simp add: rel_fun_def)
  2677 done
  2678 
  2679 lemma left_total_rel_filter [transfer_rule]:
  2680   assumes [transfer_rule]: "bi_total A" "bi_unique A"
  2681   shows "left_total (rel_filter A)"
  2682 proof(rule left_totalI)
  2683   fix F :: "'a filter"
  2684   from bi_total_fun[OF bi_unique_fun[OF `bi_total A` bi_unique_eq] bi_total_eq]
  2685   obtain G where [transfer_rule]: "((A ===> op =) ===> op =) (\<lambda>P. eventually P F) G" 
  2686     unfolding  bi_total_def by blast
  2687   moreover have "is_filter (\<lambda>P. eventually P F) \<longleftrightarrow> is_filter G" by transfer_prover
  2688   hence "is_filter G" by(simp add: eventually_def is_filter_Rep_filter)
  2689   ultimately have "rel_filter A F (Abs_filter G)"
  2690     by(simp add: rel_filter_eventually eventually_Abs_filter)
  2691   thus "\<exists>G. rel_filter A F G" ..
  2692 qed
  2693 
  2694 lemma right_total_rel_filter [transfer_rule]:
  2695   "\<lbrakk> bi_total A; bi_unique A \<rbrakk> \<Longrightarrow> right_total (rel_filter A)"
  2696 using left_total_rel_filter[of "A\<inverse>\<inverse>"] by simp
  2697 
  2698 lemma bi_total_rel_filter [transfer_rule]:
  2699   assumes "bi_total A" "bi_unique A"
  2700   shows "bi_total (rel_filter A)"
  2701 unfolding bi_total_alt_def using assms
  2702 by(simp add: left_total_rel_filter right_total_rel_filter)
  2703 
  2704 lemma left_unique_rel_filter [transfer_rule]:
  2705   assumes "left_unique A"
  2706   shows "left_unique (rel_filter A)"
  2707 proof(rule left_uniqueI)
  2708   fix F F' G
  2709   assume [transfer_rule]: "rel_filter A F G" "rel_filter A F' G"
  2710   show "F = F'"
  2711     unfolding filter_eq_iff
  2712   proof
  2713     fix P :: "'a \<Rightarrow> bool"
  2714     obtain P' where [transfer_rule]: "(A ===> op =) P P'"
  2715       using left_total_fun[OF assms left_total_eq] unfolding left_total_def by blast
  2716     have "eventually P F = eventually P' G" 
  2717       and "eventually P F' = eventually P' G" by transfer_prover+
  2718     thus "eventually P F = eventually P F'" by simp
  2719   qed
  2720 qed
  2721 
  2722 lemma right_unique_rel_filter [transfer_rule]:
  2723   "right_unique A \<Longrightarrow> right_unique (rel_filter A)"
  2724 using left_unique_rel_filter[of "A\<inverse>\<inverse>"] by simp
  2725 
  2726 lemma bi_unique_rel_filter [transfer_rule]:
  2727   "bi_unique A \<Longrightarrow> bi_unique (rel_filter A)"
  2728 by(simp add: bi_unique_alt_def left_unique_rel_filter right_unique_rel_filter)
  2729 
  2730 lemma top_filter_parametric [transfer_rule]:
  2731   "bi_total A \<Longrightarrow> (rel_filter A) top top"
  2732 by(simp add: rel_filter_eventually All_transfer)
  2733 
  2734 lemma bot_filter_parametric [transfer_rule]: "(rel_filter A) bot bot"
  2735 by(simp add: rel_filter_eventually rel_fun_def)
  2736 
  2737 lemma sup_filter_parametric [transfer_rule]:
  2738   "(rel_filter A ===> rel_filter A ===> rel_filter A) sup sup"
  2739 by(fastforce simp add: rel_filter_eventually[abs_def] eventually_sup dest: rel_funD)
  2740 
  2741 lemma Sup_filter_parametric [transfer_rule]:
  2742   "(rel_set (rel_filter A) ===> rel_filter A) Sup Sup"
  2743 proof(rule rel_funI)
  2744   fix S T
  2745   assume [transfer_rule]: "rel_set (rel_filter A) S T"
  2746   show "rel_filter A (Sup S) (Sup T)"
  2747     by(simp add: rel_filter_eventually eventually_Sup) transfer_prover
  2748 qed
  2749 
  2750 lemma principal_parametric [transfer_rule]:
  2751   "(rel_set A ===> rel_filter A) principal principal"
  2752 proof(rule rel_funI)
  2753   fix S S'
  2754   assume [transfer_rule]: "rel_set A S S'"
  2755   show "rel_filter A (principal S) (principal S')"
  2756     by(simp add: rel_filter_eventually eventually_principal) transfer_prover
  2757 qed
  2758 
  2759 context
  2760   fixes A :: "'a \<Rightarrow> 'b \<Rightarrow> bool"
  2761   assumes [transfer_rule]: "bi_unique A" 
  2762 begin
  2763 
  2764 lemma le_filter_parametric [transfer_rule]:
  2765   "(rel_filter A ===> rel_filter A ===> op =) op \<le> op \<le>"
  2766 unfolding le_filter_def[abs_def] by transfer_prover
  2767 
  2768 lemma less_filter_parametric [transfer_rule]:
  2769   "(rel_filter A ===> rel_filter A ===> op =) op < op <"
  2770 unfolding less_filter_def[abs_def] by transfer_prover
  2771 
  2772 context
  2773   assumes [transfer_rule]: "bi_total A"
  2774 begin
  2775 
  2776 lemma Inf_filter_parametric [transfer_rule]:
  2777   "(rel_set (rel_filter A) ===> rel_filter A) Inf Inf"
  2778 unfolding Inf_filter_def[abs_def] by transfer_prover
  2779 
  2780 lemma inf_filter_parametric [transfer_rule]:
  2781   "(rel_filter A ===> rel_filter A ===> rel_filter A) inf inf"
  2782 proof(intro rel_funI)+
  2783   fix F F' G G'
  2784   assume [transfer_rule]: "rel_filter A F F'" "rel_filter A G G'"
  2785   have "rel_filter A (Inf {F, G}) (Inf {F', G'})" by transfer_prover
  2786   thus "rel_filter A (inf F G) (inf F' G')" by simp
  2787 qed
  2788 
  2789 end
  2790 
  2791 end
  2792 
  2793 end
  2794 
  2795 end