src/Pure/sign.ML
author wenzelm
Wed Jul 13 20:36:18 2011 +0200 (2011-07-13)
changeset 43794 49cbbe2768a8
parent 43278 1fbdcebb364b
child 45427 fca432074fb2
permissions -rw-r--r--
sub-structural sharing after Syntax.check phase, with global interning of logical entities (the latter is relevant when bypassing default parsing via YXML);
minor tuning;
     1 (*  Title:      Pure/sign.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Logical signature content: naming conventions, concrete syntax, type
     5 signature, polymorphic constants.
     6 *)
     7 
     8 signature SIGN =
     9 sig
    10   val rep_sg: theory ->
    11    {naming: Name_Space.naming,
    12     syn: Syntax.syntax,
    13     tsig: Type.tsig,
    14     consts: Consts.T}
    15   val map_naming: (Name_Space.naming -> Name_Space.naming) -> theory -> theory
    16   val naming_of: theory -> Name_Space.naming
    17   val full_name: theory -> binding -> string
    18   val full_name_path: theory -> string -> binding -> string
    19   val full_bname: theory -> bstring -> string
    20   val full_bname_path: theory -> string -> bstring -> string
    21   val syn_of: theory -> Syntax.syntax
    22   val tsig_of: theory -> Type.tsig
    23   val classes_of: theory -> Sorts.algebra
    24   val all_classes: theory -> class list
    25   val super_classes: theory -> class -> class list
    26   val minimize_sort: theory -> sort -> sort
    27   val complete_sort: theory -> sort -> sort
    28   val set_defsort: sort -> theory -> theory
    29   val defaultS: theory -> sort
    30   val subsort: theory -> sort * sort -> bool
    31   val of_sort: theory -> typ * sort -> bool
    32   val inter_sort: theory -> sort * sort -> sort
    33   val witness_sorts: theory -> (typ * sort) list -> sort list -> (typ * sort) list
    34   val is_logtype: theory -> string -> bool
    35   val typ_instance: theory -> typ * typ -> bool
    36   val typ_equiv: theory -> typ * typ -> bool
    37   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    38   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    39   val consts_of: theory -> Consts.T
    40   val the_const_constraint: theory -> string -> typ
    41   val const_type: theory -> string -> typ option
    42   val the_const_type: theory -> string -> typ
    43   val declared_tyname: theory -> string -> bool
    44   val declared_const: theory -> string -> bool
    45   val const_monomorphic: theory -> string -> bool
    46   val const_typargs: theory -> string * typ -> typ list
    47   val const_instance: theory -> string * typ list -> typ
    48   val mk_const: theory -> string * typ list -> term
    49   val class_space: theory -> Name_Space.T
    50   val type_space: theory -> Name_Space.T
    51   val const_space: theory -> Name_Space.T
    52   val intern_class: theory -> xstring -> string
    53   val intern_type: theory -> xstring -> string
    54   val intern_const: theory -> xstring -> string
    55   val class_alias: binding -> class -> theory -> theory
    56   val type_alias: binding -> string -> theory -> theory
    57   val const_alias: binding -> string -> theory -> theory
    58   val arity_number: theory -> string -> int
    59   val arity_sorts: theory -> string -> sort -> sort list
    60   val certify_class: theory -> class -> class
    61   val certify_sort: theory -> sort -> sort
    62   val certify_typ: theory -> typ -> typ
    63   val certify_typ_mode: Type.mode -> theory -> typ -> typ
    64   val certify': bool -> Context.pretty -> bool -> Consts.T -> theory -> term -> term * typ * int
    65   val certify_term: theory -> term -> term * typ * int
    66   val cert_term: theory -> term -> term
    67   val cert_prop: theory -> term -> term
    68   val no_frees: Proof.context -> term -> term
    69   val no_vars: Proof.context -> term -> term
    70   val add_types: Proof.context -> (binding * int * mixfix) list -> theory -> theory
    71   val add_types_global: (binding * int * mixfix) list -> theory -> theory
    72   val add_nonterminals: Proof.context -> binding list -> theory -> theory
    73   val add_nonterminals_global: binding list -> theory -> theory
    74   val add_type_abbrev: Proof.context -> binding * string list * typ -> theory -> theory
    75   val add_syntax: (string * string * mixfix) list -> theory -> theory
    76   val add_syntax_i: (string * typ * mixfix) list -> theory -> theory
    77   val add_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    78   val add_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    79   val del_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    80   val del_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    81   val type_notation: bool -> Syntax.mode -> (typ * mixfix) list -> theory -> theory
    82   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
    83   val declare_const: Proof.context -> (binding * typ) * mixfix -> theory -> term * theory
    84   val declare_const_global: (binding * typ) * mixfix -> theory -> term * theory
    85   val add_consts: (binding * string * mixfix) list -> theory -> theory
    86   val add_consts_i: (binding * typ * mixfix) list -> theory -> theory
    87   val add_abbrev: string -> binding * term -> theory -> (term * term) * theory
    88   val revert_abbrev: string -> string -> theory -> theory
    89   val add_const_constraint: string * typ option -> theory -> theory
    90   val primitive_class: binding * class list -> theory -> theory
    91   val primitive_classrel: class * class -> theory -> theory
    92   val primitive_arity: arity -> theory -> theory
    93   val add_trfuns:
    94     (string * (Ast.ast list -> Ast.ast)) list *
    95     (string * (term list -> term)) list *
    96     (string * (term list -> term)) list *
    97     (string * (Ast.ast list -> Ast.ast)) list -> theory -> theory
    98   val add_trfunsT: (string * (typ -> term list -> term)) list -> theory -> theory
    99   val add_advanced_trfuns:
   100     (string * (Proof.context -> Ast.ast list -> Ast.ast)) list *
   101     (string * (Proof.context -> term list -> term)) list *
   102     (string * (Proof.context -> term list -> term)) list *
   103     (string * (Proof.context -> Ast.ast list -> Ast.ast)) list -> theory -> theory
   104   val add_advanced_trfunsT:
   105     (string * (Proof.context -> typ -> term list -> term)) list -> theory -> theory
   106   val add_trrules: Ast.ast Syntax.trrule list -> theory -> theory
   107   val del_trrules: Ast.ast Syntax.trrule list -> theory -> theory
   108   val new_group: theory -> theory
   109   val reset_group: theory -> theory
   110   val add_path: string -> theory -> theory
   111   val root_path: theory -> theory
   112   val parent_path: theory -> theory
   113   val mandatory_path: string -> theory -> theory
   114   val qualified_path: bool -> binding -> theory -> theory
   115   val local_path: theory -> theory
   116   val restore_naming: theory -> theory -> theory
   117   val hide_class: bool -> string -> theory -> theory
   118   val hide_type: bool -> string -> theory -> theory
   119   val hide_const: bool -> string -> theory -> theory
   120 end
   121 
   122 structure Sign: SIGN =
   123 struct
   124 
   125 (** datatype sign **)
   126 
   127 datatype sign = Sign of
   128  {naming: Name_Space.naming,    (*common naming conventions*)
   129   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   130   tsig: Type.tsig,              (*order-sorted signature of types*)
   131   consts: Consts.T};            (*polymorphic constants*)
   132 
   133 fun make_sign (naming, syn, tsig, consts) =
   134   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   135 
   136 structure Data = Theory_Data_PP
   137 (
   138   type T = sign;
   139   fun extend (Sign {syn, tsig, consts, ...}) =
   140     make_sign (Name_Space.default_naming, syn, tsig, consts);
   141 
   142   val empty =
   143     make_sign (Name_Space.default_naming, Syntax.empty_syntax, Type.empty_tsig, Consts.empty);
   144 
   145   fun merge pp (sign1, sign2) =
   146     let
   147       val ctxt = Syntax.init_pretty pp;
   148       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   149       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   150 
   151       val naming = Name_Space.default_naming;
   152       val syn = Syntax.merge_syntaxes syn1 syn2;
   153       val tsig = Type.merge_tsig ctxt (tsig1, tsig2);
   154       val consts = Consts.merge (consts1, consts2);
   155     in make_sign (naming, syn, tsig, consts) end;
   156 );
   157 
   158 fun rep_sg thy = Data.get thy |> (fn Sign args => args);
   159 
   160 fun map_sign f = Data.map (fn Sign {naming, syn, tsig, consts} =>
   161   make_sign (f (naming, syn, tsig, consts)));
   162 
   163 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   164 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   165 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   166 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   167 
   168 
   169 (* naming *)
   170 
   171 val naming_of = #naming o rep_sg;
   172 
   173 val full_name = Name_Space.full_name o naming_of;
   174 fun full_name_path thy path = Name_Space.full_name (Name_Space.add_path path (naming_of thy));
   175 
   176 fun full_bname thy = Name_Space.full_name (naming_of thy) o Binding.name;
   177 fun full_bname_path thy path = full_name_path thy path o Binding.name;
   178 
   179 
   180 (* syntax *)
   181 
   182 val syn_of = #syn o rep_sg;
   183 
   184 
   185 (* type signature *)
   186 
   187 val tsig_of = #tsig o rep_sg;
   188 
   189 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   190 val all_classes = Sorts.all_classes o classes_of;
   191 val super_classes = Sorts.super_classes o classes_of;
   192 val minimize_sort = Sorts.minimize_sort o classes_of;
   193 val complete_sort = Sorts.complete_sort o classes_of;
   194 
   195 val set_defsort = map_tsig o Type.set_defsort;
   196 val defaultS = Type.defaultS o tsig_of;
   197 val subsort = Type.subsort o tsig_of;
   198 val of_sort = Type.of_sort o tsig_of;
   199 val inter_sort = Type.inter_sort o tsig_of;
   200 val witness_sorts = Type.witness_sorts o tsig_of;
   201 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   202 
   203 val typ_instance = Type.typ_instance o tsig_of;
   204 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   205 val typ_match = Type.typ_match o tsig_of;
   206 val typ_unify = Type.unify o tsig_of;
   207 
   208 
   209 (* polymorphic constants *)
   210 
   211 val consts_of = #consts o rep_sg;
   212 val the_const_constraint = Consts.the_constraint o consts_of;
   213 val the_const_type = #2 oo (Consts.the_const o consts_of);
   214 val const_type = try o the_const_type;
   215 val const_monomorphic = Consts.is_monomorphic o consts_of;
   216 val const_typargs = Consts.typargs o consts_of;
   217 val const_instance = Consts.instance o consts_of;
   218 
   219 fun mk_const thy (c, Ts) = Const (c, const_instance thy (c, Ts));
   220 
   221 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   222 val declared_const = can o the_const_constraint;
   223 
   224 
   225 
   226 (** name spaces **)
   227 
   228 val class_space = Type.class_space o tsig_of;
   229 val type_space = Type.type_space o tsig_of;
   230 val const_space = Consts.space_of o consts_of;
   231 
   232 val intern_class = Name_Space.intern o class_space;
   233 val intern_type = Name_Space.intern o type_space;
   234 val intern_const = Name_Space.intern o const_space;
   235 
   236 fun class_alias b c thy = map_tsig (Type.class_alias (naming_of thy) b c) thy;
   237 fun type_alias b c thy = map_tsig (Type.type_alias (naming_of thy) b c) thy;
   238 fun const_alias b c thy = map_consts (Consts.alias (naming_of thy) b c) thy;
   239 
   240 
   241 
   242 (** certify entities **)    (*exception TYPE*)
   243 
   244 (* certify wrt. type signature *)
   245 
   246 val arity_number = Type.arity_number o tsig_of;
   247 fun arity_sorts thy = Type.arity_sorts (Context.pretty_global thy) (tsig_of thy);
   248 
   249 val certify_class = Type.cert_class o tsig_of;
   250 val certify_sort = Type.cert_sort o tsig_of;
   251 val certify_typ = Type.cert_typ o tsig_of;
   252 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   253 
   254 
   255 (* certify term/prop *)
   256 
   257 local
   258 
   259 fun type_check pp tm =
   260   let
   261     fun err_appl bs t T u U =
   262       let
   263         val xs = map Free bs;           (*we do not rename here*)
   264         val t' = subst_bounds (xs, t);
   265         val u' = subst_bounds (xs, u);
   266         val msg = Type.appl_error (Syntax.init_pretty pp) t' T u' U;
   267       in raise TYPE (msg, [T, U], [t', u']) end;
   268 
   269     fun typ_of (_, Const (_, T)) = T
   270       | typ_of (_, Free  (_, T)) = T
   271       | typ_of (_, Var (_, T)) = T
   272       | typ_of (bs, Bound i) = snd (nth bs i handle General.Subscript =>
   273           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   274       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   275       | typ_of (bs, t $ u) =
   276           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   277             (case T of
   278               Type ("fun", [T1, T2]) =>
   279                 if T1 = U then T2 else err_appl bs t T u U
   280             | _ => err_appl bs t T u U)
   281           end;
   282   in typ_of ([], tm) end;
   283 
   284 fun err msg = raise TYPE (msg, [], []);
   285 
   286 fun check_vars (t $ u) = (check_vars t; check_vars u)
   287   | check_vars (Abs (_, _, t)) = check_vars t
   288   | check_vars (Free (x, _)) =
   289       if Long_Name.is_qualified x then err ("Malformed variable: " ^ quote x) else ()
   290   | check_vars (Var (xi as (_, i), _)) =
   291       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   292   | check_vars _ = ();
   293 
   294 in
   295 
   296 fun certify' prop pp do_expand consts thy tm =
   297   let
   298     val _ = check_vars tm;
   299     val tm' = Term.map_types (certify_typ thy) tm;
   300     val T = type_check pp tm';
   301     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   302     val tm'' = Consts.certify pp (tsig_of thy) do_expand consts tm';
   303   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   304 
   305 fun certify_term thy = certify' false (Context.pretty_global thy) true (consts_of thy) thy;
   306 fun cert_term_abbrev thy =
   307   #1 o certify' false (Context.pretty_global thy) false (consts_of thy) thy;
   308 val cert_term = #1 oo certify_term;
   309 fun cert_prop thy = #1 o certify' true (Context.pretty_global thy) true (consts_of thy) thy;
   310 
   311 end;
   312 
   313 
   314 (* specifications *)
   315 
   316 fun no_variables kind add addT mk mkT ctxt tm =
   317   (case (add tm [], addT tm []) of
   318     ([], []) => tm
   319   | (frees, tfrees) => error (Pretty.string_of (Pretty.block
   320       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") :: Pretty.brk 1 ::
   321        Pretty.commas
   322         (map (Syntax.pretty_term ctxt o mk) frees @ map (Syntax.pretty_typ ctxt o mkT) tfrees)))));
   323 
   324 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   325 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   326 
   327 
   328 
   329 (** signature extension functions **)  (*exception ERROR/TYPE*)
   330 
   331 (* add type constructors *)
   332 
   333 fun add_types ctxt types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   334   let
   335     fun type_syntax (b, n, mx) =
   336       (Lexicon.mark_type (Name_Space.full_name naming b), Mixfix.make_type n, mx);
   337     val syn' = Syntax.update_type_gram true Syntax.mode_default (map type_syntax types) syn;
   338     val tsig' = fold (fn (a, n, _) => Type.add_type ctxt naming (a, n)) types tsig;
   339   in (naming, syn', tsig', consts) end);
   340 
   341 fun add_types_global types thy =
   342   add_types (Syntax.init_pretty_global thy) types thy;
   343 
   344 
   345 (* add nonterminals *)
   346 
   347 fun add_nonterminals ctxt ns = map_sign (fn (naming, syn, tsig, consts) =>
   348   (naming, syn, fold (Type.add_nonterminal ctxt naming) ns tsig, consts));
   349 
   350 fun add_nonterminals_global ns thy =
   351   add_nonterminals (Syntax.init_pretty_global thy) ns thy;
   352 
   353 
   354 (* add type abbreviations *)
   355 
   356 fun add_type_abbrev ctxt abbr = map_sign (fn (naming, syn, tsig, consts) =>
   357   (naming, syn, Type.add_abbrev ctxt naming abbr tsig, consts));
   358 
   359 
   360 (* modify syntax *)
   361 
   362 fun gen_syntax change_gram parse_typ mode args thy =
   363   let
   364     val ctxt = Proof_Context.init_global thy;
   365     fun prep (c, T, mx) = (c, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt T), mx)
   366       handle ERROR msg => cat_error msg ("in syntax declaration " ^ quote c);
   367   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   368 
   369 fun gen_add_syntax x = gen_syntax (Syntax.update_const_gram true) x;
   370 
   371 val add_modesyntax = gen_add_syntax Syntax.parse_typ;
   372 val add_modesyntax_i = gen_add_syntax (K I);
   373 val add_syntax = add_modesyntax Syntax.mode_default;
   374 val add_syntax_i = add_modesyntax_i Syntax.mode_default;
   375 val del_modesyntax = gen_syntax (Syntax.update_const_gram false) Syntax.parse_typ;
   376 val del_modesyntax_i = gen_syntax (Syntax.update_const_gram false) (K I);
   377 
   378 fun type_notation add mode args =
   379   let
   380     fun type_syntax (Type (c, args), mx) =
   381           SOME (Lexicon.mark_type c, Mixfix.make_type (length args), mx)
   382       | type_syntax _ = NONE;
   383   in map_syn (Syntax.update_type_gram add mode (map_filter type_syntax args)) end;
   384 
   385 fun notation add mode args thy =
   386   let
   387     fun const_syntax (Const (c, _), mx) =
   388           (case try (Consts.type_scheme (consts_of thy)) c of
   389             SOME T => SOME (Lexicon.mark_const c, T, mx)
   390           | NONE => NONE)
   391       | const_syntax _ = NONE;
   392   in gen_syntax (Syntax.update_const_gram add) (K I) mode (map_filter const_syntax args) thy end;
   393 
   394 
   395 (* add constants *)
   396 
   397 local
   398 
   399 fun gen_add_consts parse_typ ctxt raw_args thy =
   400   let
   401     val prepT = Type.no_tvars o Term.no_dummyT o certify_typ thy o parse_typ ctxt;
   402     fun prep (b, raw_T, mx) =
   403       let
   404         val c = full_name thy b;
   405         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   406           cat_error msg ("in declaration of constant " ^ Binding.print b);
   407         val T' = Logic.varifyT_global T;
   408       in ((b, T'), (Lexicon.mark_const c, T', mx), Const (c, T)) end;
   409     val args = map prep raw_args;
   410   in
   411     thy
   412     |> map_consts (fold (Consts.declare ctxt (naming_of thy) o #1) args)
   413     |> add_syntax_i (map #2 args)
   414     |> pair (map #3 args)
   415   end;
   416 
   417 in
   418 
   419 fun add_consts args thy =
   420   #2 (gen_add_consts Syntax.parse_typ (Proof_Context.init_global thy) args thy);
   421 fun add_consts_i args thy =
   422   #2 (gen_add_consts (K I) (Proof_Context.init_global thy) args thy);
   423 
   424 fun declare_const ctxt ((b, T), mx) = yield_singleton (gen_add_consts (K I) ctxt) (b, T, mx);
   425 fun declare_const_global arg thy = declare_const (Proof_Context.init_global thy) arg thy;
   426 
   427 end;
   428 
   429 
   430 (* abbreviations *)
   431 
   432 fun add_abbrev mode (b, raw_t) thy =
   433   let
   434     val ctxt = Syntax.init_pretty_global thy;
   435     val prep_tm = no_frees ctxt o Term.no_dummy_patterns o cert_term_abbrev thy;
   436     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   437       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ Binding.print b);
   438     val (res, consts') = consts_of thy
   439       |> Consts.abbreviate ctxt (tsig_of thy) (naming_of thy) mode (b, t);
   440   in (res, thy |> map_consts (K consts')) end;
   441 
   442 fun revert_abbrev mode c = map_consts (Consts.revert_abbrev mode c);
   443 
   444 
   445 (* add constraints *)
   446 
   447 fun add_const_constraint (c, opt_T) thy =
   448   let
   449     fun prepT raw_T =
   450       let val T = Logic.varifyT_global (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   451       in cert_term thy (Const (c, T)); T end
   452       handle TYPE (msg, _, _) => error msg;
   453   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   454 
   455 
   456 (* primitive classes and arities *)
   457 
   458 fun primitive_class (bclass, classes) thy =
   459   thy
   460   |> map_sign (fn (naming, syn, tsig, consts) =>
   461     let
   462       val ctxt = Syntax.init_pretty_global thy;
   463       val tsig' = Type.add_class ctxt naming (bclass, classes) tsig;
   464     in (naming, syn, tsig', consts) end)
   465   |> add_consts_i [(Binding.map_name Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   466 
   467 fun primitive_classrel arg thy =
   468   thy |> map_tsig (Type.add_classrel (Syntax.init_pretty_global thy) arg);
   469 
   470 fun primitive_arity arg thy =
   471   thy |> map_tsig (Type.add_arity (Syntax.init_pretty_global thy) arg);
   472 
   473 
   474 (* add translation functions *)
   475 
   476 local
   477 
   478 fun mk trs = map Syntax_Ext.mk_trfun trs;
   479 
   480 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   481   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   482 
   483 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   484 
   485 in
   486 
   487 val add_trfuns = gen_add_trfuns Syntax.update_trfuns Syntax_Trans.non_typed_tr';
   488 val add_trfunsT = gen_add_trfunsT Syntax.update_trfuns;
   489 val add_advanced_trfuns = gen_add_trfuns Syntax.update_advanced_trfuns Syntax_Trans.non_typed_tr'';
   490 val add_advanced_trfunsT = gen_add_trfunsT Syntax.update_advanced_trfuns;
   491 
   492 end;
   493 
   494 
   495 (* translation rules *)
   496 
   497 val add_trrules = map_syn o Syntax.update_trrules;
   498 val del_trrules = map_syn o Syntax.remove_trrules;
   499 
   500 
   501 (* naming *)
   502 
   503 val new_group = map_naming Name_Space.new_group;
   504 val reset_group = map_naming Name_Space.reset_group;
   505 
   506 val add_path = map_naming o Name_Space.add_path;
   507 val root_path = map_naming Name_Space.root_path;
   508 val parent_path = map_naming Name_Space.parent_path;
   509 val mandatory_path = map_naming o Name_Space.mandatory_path;
   510 val qualified_path = map_naming oo Name_Space.qualified_path;
   511 
   512 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   513 
   514 val restore_naming = map_naming o K o naming_of;
   515 
   516 
   517 (* hide names *)
   518 
   519 val hide_class = map_tsig oo Type.hide_class;
   520 val hide_type = map_tsig oo Type.hide_type;
   521 val hide_const = map_consts oo Consts.hide;
   522 
   523 end;