src/HOL/HOL.thy
author haftmann
Tue Jun 10 15:30:58 2008 +0200 (2008-06-10)
changeset 27107 4a7415c67063
parent 26957 e3f04fdd994d
child 27126 3ede9103de8e
permissions -rw-r--r--
localized Least in Orderings.thy
     1 (*  Title:      HOL/HOL.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     4 *)
     5 
     6 header {* The basis of Higher-Order Logic *}
     7 
     8 theory HOL
     9 imports Pure
    10 uses
    11   ("hologic.ML")
    12   "~~/src/Tools/IsaPlanner/zipper.ML"
    13   "~~/src/Tools/IsaPlanner/isand.ML"
    14   "~~/src/Tools/IsaPlanner/rw_tools.ML"
    15   "~~/src/Tools/IsaPlanner/rw_inst.ML"
    16   "~~/src/Provers/project_rule.ML"
    17   "~~/src/Provers/hypsubst.ML"
    18   "~~/src/Provers/splitter.ML"
    19   "~~/src/Provers/classical.ML"
    20   "~~/src/Provers/blast.ML"
    21   "~~/src/Provers/clasimp.ML"
    22   "~~/src/Provers/eqsubst.ML"
    23   "~~/src/Provers/quantifier1.ML"
    24   ("simpdata.ML")
    25   "~~/src/Tools/random_word.ML"
    26   "~~/src/Tools/atomize_elim.ML"
    27   "~~/src/Tools/induct.ML"
    28   "~~/src/Tools/code/code_name.ML"
    29   "~~/src/Tools/code/code_funcgr.ML"
    30   "~~/src/Tools/code/code_thingol.ML"
    31   "~~/src/Tools/code/code_target.ML"
    32   "~~/src/Tools/nbe.ML"
    33 begin
    34 
    35 subsection {* Primitive logic *}
    36 
    37 subsubsection {* Core syntax *}
    38 
    39 classes type
    40 defaultsort type
    41 setup {* ObjectLogic.add_base_sort @{sort type} *}
    42 
    43 arities
    44   "fun" :: (type, type) type
    45   itself :: (type) type
    46 
    47 global
    48 
    49 typedecl bool
    50 
    51 judgment
    52   Trueprop      :: "bool => prop"                   ("(_)" 5)
    53 
    54 consts
    55   Not           :: "bool => bool"                   ("~ _" [40] 40)
    56   True          :: bool
    57   False         :: bool
    58   arbitrary     :: 'a
    59 
    60   The           :: "('a => bool) => 'a"
    61   All           :: "('a => bool) => bool"           (binder "ALL " 10)
    62   Ex            :: "('a => bool) => bool"           (binder "EX " 10)
    63   Ex1           :: "('a => bool) => bool"           (binder "EX! " 10)
    64   Let           :: "['a, 'a => 'b] => 'b"
    65 
    66   "op ="        :: "['a, 'a] => bool"               (infixl "=" 50)
    67   "op &"        :: "[bool, bool] => bool"           (infixr "&" 35)
    68   "op |"        :: "[bool, bool] => bool"           (infixr "|" 30)
    69   "op -->"      :: "[bool, bool] => bool"           (infixr "-->" 25)
    70 
    71 local
    72 
    73 consts
    74   If            :: "[bool, 'a, 'a] => 'a"           ("(if (_)/ then (_)/ else (_))" 10)
    75 
    76 
    77 subsubsection {* Additional concrete syntax *}
    78 
    79 notation (output)
    80   "op ="  (infix "=" 50)
    81 
    82 abbreviation
    83   not_equal :: "['a, 'a] => bool"  (infixl "~=" 50) where
    84   "x ~= y == ~ (x = y)"
    85 
    86 notation (output)
    87   not_equal  (infix "~=" 50)
    88 
    89 notation (xsymbols)
    90   Not  ("\<not> _" [40] 40) and
    91   "op &"  (infixr "\<and>" 35) and
    92   "op |"  (infixr "\<or>" 30) and
    93   "op -->"  (infixr "\<longrightarrow>" 25) and
    94   not_equal  (infix "\<noteq>" 50)
    95 
    96 notation (HTML output)
    97   Not  ("\<not> _" [40] 40) and
    98   "op &"  (infixr "\<and>" 35) and
    99   "op |"  (infixr "\<or>" 30) and
   100   not_equal  (infix "\<noteq>" 50)
   101 
   102 abbreviation (iff)
   103   iff :: "[bool, bool] => bool"  (infixr "<->" 25) where
   104   "A <-> B == A = B"
   105 
   106 notation (xsymbols)
   107   iff  (infixr "\<longleftrightarrow>" 25)
   108 
   109 
   110 nonterminals
   111   letbinds  letbind
   112   case_syn  cases_syn
   113 
   114 syntax
   115   "_The"        :: "[pttrn, bool] => 'a"                 ("(3THE _./ _)" [0, 10] 10)
   116 
   117   "_bind"       :: "[pttrn, 'a] => letbind"              ("(2_ =/ _)" 10)
   118   ""            :: "letbind => letbinds"                 ("_")
   119   "_binds"      :: "[letbind, letbinds] => letbinds"     ("_;/ _")
   120   "_Let"        :: "[letbinds, 'a] => 'a"                ("(let (_)/ in (_))" 10)
   121 
   122   "_case_syntax":: "['a, cases_syn] => 'b"               ("(case _ of/ _)" 10)
   123   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ =>/ _)" 10)
   124   ""            :: "case_syn => cases_syn"               ("_")
   125   "_case2"      :: "[case_syn, cases_syn] => cases_syn"  ("_/ | _")
   126 
   127 translations
   128   "THE x. P"              == "The (%x. P)"
   129   "_Let (_binds b bs) e"  == "_Let b (_Let bs e)"
   130   "let x = a in e"        == "Let a (%x. e)"
   131 
   132 print_translation {*
   133 (* To avoid eta-contraction of body: *)
   134 [("The", fn [Abs abs] =>
   135      let val (x,t) = atomic_abs_tr' abs
   136      in Syntax.const "_The" $ x $ t end)]
   137 *}
   138 
   139 syntax (xsymbols)
   140   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ \<Rightarrow>/ _)" 10)
   141 
   142 notation (xsymbols)
   143   All  (binder "\<forall>" 10) and
   144   Ex  (binder "\<exists>" 10) and
   145   Ex1  (binder "\<exists>!" 10)
   146 
   147 notation (HTML output)
   148   All  (binder "\<forall>" 10) and
   149   Ex  (binder "\<exists>" 10) and
   150   Ex1  (binder "\<exists>!" 10)
   151 
   152 notation (HOL)
   153   All  (binder "! " 10) and
   154   Ex  (binder "? " 10) and
   155   Ex1  (binder "?! " 10)
   156 
   157 
   158 subsubsection {* Axioms and basic definitions *}
   159 
   160 axioms
   161   eq_reflection:  "(x=y) ==> (x==y)"
   162 
   163   refl:           "t = (t::'a)"
   164 
   165   ext:            "(!!x::'a. (f x ::'b) = g x) ==> (%x. f x) = (%x. g x)"
   166     -- {*Extensionality is built into the meta-logic, and this rule expresses
   167          a related property.  It is an eta-expanded version of the traditional
   168          rule, and similar to the ABS rule of HOL*}
   169 
   170   the_eq_trivial: "(THE x. x = a) = (a::'a)"
   171 
   172   impI:           "(P ==> Q) ==> P-->Q"
   173   mp:             "[| P-->Q;  P |] ==> Q"
   174 
   175 
   176 defs
   177   True_def:     "True      == ((%x::bool. x) = (%x. x))"
   178   All_def:      "All(P)    == (P = (%x. True))"
   179   Ex_def:       "Ex(P)     == !Q. (!x. P x --> Q) --> Q"
   180   False_def:    "False     == (!P. P)"
   181   not_def:      "~ P       == P-->False"
   182   and_def:      "P & Q     == !R. (P-->Q-->R) --> R"
   183   or_def:       "P | Q     == !R. (P-->R) --> (Q-->R) --> R"
   184   Ex1_def:      "Ex1(P)    == ? x. P(x) & (! y. P(y) --> y=x)"
   185 
   186 axioms
   187   iff:          "(P-->Q) --> (Q-->P) --> (P=Q)"
   188   True_or_False:  "(P=True) | (P=False)"
   189 
   190 defs
   191   Let_def:      "Let s f == f(s)"
   192   if_def:       "If P x y == THE z::'a. (P=True --> z=x) & (P=False --> z=y)"
   193 
   194 finalconsts
   195   "op ="
   196   "op -->"
   197   The
   198   arbitrary
   199 
   200 axiomatization
   201   undefined :: 'a
   202 
   203 axiomatization where
   204   undefined_fun: "undefined x = undefined"
   205 
   206 
   207 subsubsection {* Generic classes and algebraic operations *}
   208 
   209 class default = type +
   210   fixes default :: 'a
   211 
   212 class zero = type + 
   213   fixes zero :: 'a  ("0")
   214 
   215 class one = type +
   216   fixes one  :: 'a  ("1")
   217 
   218 hide (open) const zero one
   219 
   220 class plus = type +
   221   fixes plus :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "+" 65)
   222 
   223 class minus = type +
   224   fixes minus :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "-" 65)
   225 
   226 class uminus = type +
   227   fixes uminus :: "'a \<Rightarrow> 'a"  ("- _" [81] 80)
   228 
   229 class times = type +
   230   fixes times :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "*" 70)
   231 
   232 class inverse = type +
   233   fixes inverse :: "'a \<Rightarrow> 'a"
   234     and divide :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "'/" 70)
   235 
   236 class abs = type +
   237   fixes abs :: "'a \<Rightarrow> 'a"
   238 begin
   239 
   240 notation (xsymbols)
   241   abs  ("\<bar>_\<bar>")
   242 
   243 notation (HTML output)
   244   abs  ("\<bar>_\<bar>")
   245 
   246 end
   247 
   248 class sgn = type +
   249   fixes sgn :: "'a \<Rightarrow> 'a"
   250 
   251 class ord = type +
   252   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   253     and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   254 begin
   255 
   256 notation
   257   less_eq  ("op <=") and
   258   less_eq  ("(_/ <= _)" [51, 51] 50) and
   259   less  ("op <") and
   260   less  ("(_/ < _)"  [51, 51] 50)
   261   
   262 notation (xsymbols)
   263   less_eq  ("op \<le>") and
   264   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
   265 
   266 notation (HTML output)
   267   less_eq  ("op \<le>") and
   268   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
   269 
   270 abbreviation (input)
   271   greater_eq  (infix ">=" 50) where
   272   "x >= y \<equiv> y <= x"
   273 
   274 notation (input)
   275   greater_eq  (infix "\<ge>" 50)
   276 
   277 abbreviation (input)
   278   greater  (infix ">" 50) where
   279   "x > y \<equiv> y < x"
   280 
   281 end
   282 
   283 syntax
   284   "_index1"  :: index    ("\<^sub>1")
   285 translations
   286   (index) "\<^sub>1" => (index) "\<^bsub>\<struct>\<^esub>"
   287 
   288 typed_print_translation {*
   289 let
   290   fun tr' c = (c, fn show_sorts => fn T => fn ts =>
   291     if T = dummyT orelse not (! show_types) andalso can Term.dest_Type T then raise Match
   292     else Syntax.const Syntax.constrainC $ Syntax.const c $ Syntax.term_of_typ show_sorts T);
   293 in map tr' [@{const_syntax HOL.one}, @{const_syntax HOL.zero}] end;
   294 *} -- {* show types that are presumably too general *}
   295 
   296 
   297 subsection {* Fundamental rules *}
   298 
   299 subsubsection {* Equality *}
   300 
   301 text {* Thanks to Stephan Merz *}
   302 lemma subst:
   303   assumes eq: "s = t" and p: "P s"
   304   shows "P t"
   305 proof -
   306   from eq have meta: "s \<equiv> t"
   307     by (rule eq_reflection)
   308   from p show ?thesis
   309     by (unfold meta)
   310 qed
   311 
   312 lemma sym: "s = t ==> t = s"
   313   by (erule subst) (rule refl)
   314 
   315 lemma ssubst: "t = s ==> P s ==> P t"
   316   by (drule sym) (erule subst)
   317 
   318 lemma trans: "[| r=s; s=t |] ==> r=t"
   319   by (erule subst)
   320 
   321 lemma meta_eq_to_obj_eq: 
   322   assumes meq: "A == B"
   323   shows "A = B"
   324   by (unfold meq) (rule refl)
   325 
   326 text {* Useful with @{text erule} for proving equalities from known equalities. *}
   327      (* a = b
   328         |   |
   329         c = d   *)
   330 lemma box_equals: "[| a=b;  a=c;  b=d |] ==> c=d"
   331 apply (rule trans)
   332 apply (rule trans)
   333 apply (rule sym)
   334 apply assumption+
   335 done
   336 
   337 text {* For calculational reasoning: *}
   338 
   339 lemma forw_subst: "a = b ==> P b ==> P a"
   340   by (rule ssubst)
   341 
   342 lemma back_subst: "P a ==> a = b ==> P b"
   343   by (rule subst)
   344 
   345 
   346 subsubsection {*Congruence rules for application*}
   347 
   348 (*similar to AP_THM in Gordon's HOL*)
   349 lemma fun_cong: "(f::'a=>'b) = g ==> f(x)=g(x)"
   350 apply (erule subst)
   351 apply (rule refl)
   352 done
   353 
   354 (*similar to AP_TERM in Gordon's HOL and FOL's subst_context*)
   355 lemma arg_cong: "x=y ==> f(x)=f(y)"
   356 apply (erule subst)
   357 apply (rule refl)
   358 done
   359 
   360 lemma arg_cong2: "\<lbrakk> a = b; c = d \<rbrakk> \<Longrightarrow> f a c = f b d"
   361 apply (erule ssubst)+
   362 apply (rule refl)
   363 done
   364 
   365 lemma cong: "[| f = g; (x::'a) = y |] ==> f(x) = g(y)"
   366 apply (erule subst)+
   367 apply (rule refl)
   368 done
   369 
   370 
   371 subsubsection {*Equality of booleans -- iff*}
   372 
   373 lemma iffI: assumes "P ==> Q" and "Q ==> P" shows "P=Q"
   374   by (iprover intro: iff [THEN mp, THEN mp] impI assms)
   375 
   376 lemma iffD2: "[| P=Q; Q |] ==> P"
   377   by (erule ssubst)
   378 
   379 lemma rev_iffD2: "[| Q; P=Q |] ==> P"
   380   by (erule iffD2)
   381 
   382 lemma iffD1: "Q = P \<Longrightarrow> Q \<Longrightarrow> P"
   383   by (drule sym) (rule iffD2)
   384 
   385 lemma rev_iffD1: "Q \<Longrightarrow> Q = P \<Longrightarrow> P"
   386   by (drule sym) (rule rev_iffD2)
   387 
   388 lemma iffE:
   389   assumes major: "P=Q"
   390     and minor: "[| P --> Q; Q --> P |] ==> R"
   391   shows R
   392   by (iprover intro: minor impI major [THEN iffD2] major [THEN iffD1])
   393 
   394 
   395 subsubsection {*True*}
   396 
   397 lemma TrueI: "True"
   398   unfolding True_def by (rule refl)
   399 
   400 lemma eqTrueI: "P ==> P = True"
   401   by (iprover intro: iffI TrueI)
   402 
   403 lemma eqTrueE: "P = True ==> P"
   404   by (erule iffD2) (rule TrueI)
   405 
   406 
   407 subsubsection {*Universal quantifier*}
   408 
   409 lemma allI: assumes "!!x::'a. P(x)" shows "ALL x. P(x)"
   410   unfolding All_def by (iprover intro: ext eqTrueI assms)
   411 
   412 lemma spec: "ALL x::'a. P(x) ==> P(x)"
   413 apply (unfold All_def)
   414 apply (rule eqTrueE)
   415 apply (erule fun_cong)
   416 done
   417 
   418 lemma allE:
   419   assumes major: "ALL x. P(x)"
   420     and minor: "P(x) ==> R"
   421   shows R
   422   by (iprover intro: minor major [THEN spec])
   423 
   424 lemma all_dupE:
   425   assumes major: "ALL x. P(x)"
   426     and minor: "[| P(x); ALL x. P(x) |] ==> R"
   427   shows R
   428   by (iprover intro: minor major major [THEN spec])
   429 
   430 
   431 subsubsection {* False *}
   432 
   433 text {*
   434   Depends upon @{text spec}; it is impossible to do propositional
   435   logic before quantifiers!
   436 *}
   437 
   438 lemma FalseE: "False ==> P"
   439   apply (unfold False_def)
   440   apply (erule spec)
   441   done
   442 
   443 lemma False_neq_True: "False = True ==> P"
   444   by (erule eqTrueE [THEN FalseE])
   445 
   446 
   447 subsubsection {* Negation *}
   448 
   449 lemma notI:
   450   assumes "P ==> False"
   451   shows "~P"
   452   apply (unfold not_def)
   453   apply (iprover intro: impI assms)
   454   done
   455 
   456 lemma False_not_True: "False ~= True"
   457   apply (rule notI)
   458   apply (erule False_neq_True)
   459   done
   460 
   461 lemma True_not_False: "True ~= False"
   462   apply (rule notI)
   463   apply (drule sym)
   464   apply (erule False_neq_True)
   465   done
   466 
   467 lemma notE: "[| ~P;  P |] ==> R"
   468   apply (unfold not_def)
   469   apply (erule mp [THEN FalseE])
   470   apply assumption
   471   done
   472 
   473 lemma notI2: "(P \<Longrightarrow> \<not> Pa) \<Longrightarrow> (P \<Longrightarrow> Pa) \<Longrightarrow> \<not> P"
   474   by (erule notE [THEN notI]) (erule meta_mp)
   475 
   476 
   477 subsubsection {*Implication*}
   478 
   479 lemma impE:
   480   assumes "P-->Q" "P" "Q ==> R"
   481   shows "R"
   482 by (iprover intro: assms mp)
   483 
   484 (* Reduces Q to P-->Q, allowing substitution in P. *)
   485 lemma rev_mp: "[| P;  P --> Q |] ==> Q"
   486 by (iprover intro: mp)
   487 
   488 lemma contrapos_nn:
   489   assumes major: "~Q"
   490       and minor: "P==>Q"
   491   shows "~P"
   492 by (iprover intro: notI minor major [THEN notE])
   493 
   494 (*not used at all, but we already have the other 3 combinations *)
   495 lemma contrapos_pn:
   496   assumes major: "Q"
   497       and minor: "P ==> ~Q"
   498   shows "~P"
   499 by (iprover intro: notI minor major notE)
   500 
   501 lemma not_sym: "t ~= s ==> s ~= t"
   502   by (erule contrapos_nn) (erule sym)
   503 
   504 lemma eq_neq_eq_imp_neq: "[| x = a ; a ~= b; b = y |] ==> x ~= y"
   505   by (erule subst, erule ssubst, assumption)
   506 
   507 (*still used in HOLCF*)
   508 lemma rev_contrapos:
   509   assumes pq: "P ==> Q"
   510       and nq: "~Q"
   511   shows "~P"
   512 apply (rule nq [THEN contrapos_nn])
   513 apply (erule pq)
   514 done
   515 
   516 subsubsection {*Existential quantifier*}
   517 
   518 lemma exI: "P x ==> EX x::'a. P x"
   519 apply (unfold Ex_def)
   520 apply (iprover intro: allI allE impI mp)
   521 done
   522 
   523 lemma exE:
   524   assumes major: "EX x::'a. P(x)"
   525       and minor: "!!x. P(x) ==> Q"
   526   shows "Q"
   527 apply (rule major [unfolded Ex_def, THEN spec, THEN mp])
   528 apply (iprover intro: impI [THEN allI] minor)
   529 done
   530 
   531 
   532 subsubsection {*Conjunction*}
   533 
   534 lemma conjI: "[| P; Q |] ==> P&Q"
   535 apply (unfold and_def)
   536 apply (iprover intro: impI [THEN allI] mp)
   537 done
   538 
   539 lemma conjunct1: "[| P & Q |] ==> P"
   540 apply (unfold and_def)
   541 apply (iprover intro: impI dest: spec mp)
   542 done
   543 
   544 lemma conjunct2: "[| P & Q |] ==> Q"
   545 apply (unfold and_def)
   546 apply (iprover intro: impI dest: spec mp)
   547 done
   548 
   549 lemma conjE:
   550   assumes major: "P&Q"
   551       and minor: "[| P; Q |] ==> R"
   552   shows "R"
   553 apply (rule minor)
   554 apply (rule major [THEN conjunct1])
   555 apply (rule major [THEN conjunct2])
   556 done
   557 
   558 lemma context_conjI:
   559   assumes "P" "P ==> Q" shows "P & Q"
   560 by (iprover intro: conjI assms)
   561 
   562 
   563 subsubsection {*Disjunction*}
   564 
   565 lemma disjI1: "P ==> P|Q"
   566 apply (unfold or_def)
   567 apply (iprover intro: allI impI mp)
   568 done
   569 
   570 lemma disjI2: "Q ==> P|Q"
   571 apply (unfold or_def)
   572 apply (iprover intro: allI impI mp)
   573 done
   574 
   575 lemma disjE:
   576   assumes major: "P|Q"
   577       and minorP: "P ==> R"
   578       and minorQ: "Q ==> R"
   579   shows "R"
   580 by (iprover intro: minorP minorQ impI
   581                  major [unfolded or_def, THEN spec, THEN mp, THEN mp])
   582 
   583 
   584 subsubsection {*Classical logic*}
   585 
   586 lemma classical:
   587   assumes prem: "~P ==> P"
   588   shows "P"
   589 apply (rule True_or_False [THEN disjE, THEN eqTrueE])
   590 apply assumption
   591 apply (rule notI [THEN prem, THEN eqTrueI])
   592 apply (erule subst)
   593 apply assumption
   594 done
   595 
   596 lemmas ccontr = FalseE [THEN classical, standard]
   597 
   598 (*notE with premises exchanged; it discharges ~R so that it can be used to
   599   make elimination rules*)
   600 lemma rev_notE:
   601   assumes premp: "P"
   602       and premnot: "~R ==> ~P"
   603   shows "R"
   604 apply (rule ccontr)
   605 apply (erule notE [OF premnot premp])
   606 done
   607 
   608 (*Double negation law*)
   609 lemma notnotD: "~~P ==> P"
   610 apply (rule classical)
   611 apply (erule notE)
   612 apply assumption
   613 done
   614 
   615 lemma contrapos_pp:
   616   assumes p1: "Q"
   617       and p2: "~P ==> ~Q"
   618   shows "P"
   619 by (iprover intro: classical p1 p2 notE)
   620 
   621 
   622 subsubsection {*Unique existence*}
   623 
   624 lemma ex1I:
   625   assumes "P a" "!!x. P(x) ==> x=a"
   626   shows "EX! x. P(x)"
   627 by (unfold Ex1_def, iprover intro: assms exI conjI allI impI)
   628 
   629 text{*Sometimes easier to use: the premises have no shared variables.  Safe!*}
   630 lemma ex_ex1I:
   631   assumes ex_prem: "EX x. P(x)"
   632       and eq: "!!x y. [| P(x); P(y) |] ==> x=y"
   633   shows "EX! x. P(x)"
   634 by (iprover intro: ex_prem [THEN exE] ex1I eq)
   635 
   636 lemma ex1E:
   637   assumes major: "EX! x. P(x)"
   638       and minor: "!!x. [| P(x);  ALL y. P(y) --> y=x |] ==> R"
   639   shows "R"
   640 apply (rule major [unfolded Ex1_def, THEN exE])
   641 apply (erule conjE)
   642 apply (iprover intro: minor)
   643 done
   644 
   645 lemma ex1_implies_ex: "EX! x. P x ==> EX x. P x"
   646 apply (erule ex1E)
   647 apply (rule exI)
   648 apply assumption
   649 done
   650 
   651 
   652 subsubsection {*THE: definite description operator*}
   653 
   654 lemma the_equality:
   655   assumes prema: "P a"
   656       and premx: "!!x. P x ==> x=a"
   657   shows "(THE x. P x) = a"
   658 apply (rule trans [OF _ the_eq_trivial])
   659 apply (rule_tac f = "The" in arg_cong)
   660 apply (rule ext)
   661 apply (rule iffI)
   662  apply (erule premx)
   663 apply (erule ssubst, rule prema)
   664 done
   665 
   666 lemma theI:
   667   assumes "P a" and "!!x. P x ==> x=a"
   668   shows "P (THE x. P x)"
   669 by (iprover intro: assms the_equality [THEN ssubst])
   670 
   671 lemma theI': "EX! x. P x ==> P (THE x. P x)"
   672 apply (erule ex1E)
   673 apply (erule theI)
   674 apply (erule allE)
   675 apply (erule mp)
   676 apply assumption
   677 done
   678 
   679 (*Easier to apply than theI: only one occurrence of P*)
   680 lemma theI2:
   681   assumes "P a" "!!x. P x ==> x=a" "!!x. P x ==> Q x"
   682   shows "Q (THE x. P x)"
   683 by (iprover intro: assms theI)
   684 
   685 lemma the1I2: assumes "EX! x. P x" "\<And>x. P x \<Longrightarrow> Q x" shows "Q (THE x. P x)"
   686 by(iprover intro:assms(2) theI2[where P=P and Q=Q] ex1E[OF assms(1)]
   687            elim:allE impE)
   688 
   689 lemma the1_equality [elim?]: "[| EX!x. P x; P a |] ==> (THE x. P x) = a"
   690 apply (rule the_equality)
   691 apply  assumption
   692 apply (erule ex1E)
   693 apply (erule all_dupE)
   694 apply (drule mp)
   695 apply  assumption
   696 apply (erule ssubst)
   697 apply (erule allE)
   698 apply (erule mp)
   699 apply assumption
   700 done
   701 
   702 lemma the_sym_eq_trivial: "(THE y. x=y) = x"
   703 apply (rule the_equality)
   704 apply (rule refl)
   705 apply (erule sym)
   706 done
   707 
   708 
   709 subsubsection {*Classical intro rules for disjunction and existential quantifiers*}
   710 
   711 lemma disjCI:
   712   assumes "~Q ==> P" shows "P|Q"
   713 apply (rule classical)
   714 apply (iprover intro: assms disjI1 disjI2 notI elim: notE)
   715 done
   716 
   717 lemma excluded_middle: "~P | P"
   718 by (iprover intro: disjCI)
   719 
   720 text {*
   721   case distinction as a natural deduction rule.
   722   Note that @{term "~P"} is the second case, not the first
   723 *}
   724 lemma case_split_thm:
   725   assumes prem1: "P ==> Q"
   726       and prem2: "~P ==> Q"
   727   shows "Q"
   728 apply (rule excluded_middle [THEN disjE])
   729 apply (erule prem2)
   730 apply (erule prem1)
   731 done
   732 lemmas case_split = case_split_thm [case_names True False]
   733 
   734 (*Classical implies (-->) elimination. *)
   735 lemma impCE:
   736   assumes major: "P-->Q"
   737       and minor: "~P ==> R" "Q ==> R"
   738   shows "R"
   739 apply (rule excluded_middle [of P, THEN disjE])
   740 apply (iprover intro: minor major [THEN mp])+
   741 done
   742 
   743 (*This version of --> elimination works on Q before P.  It works best for
   744   those cases in which P holds "almost everywhere".  Can't install as
   745   default: would break old proofs.*)
   746 lemma impCE':
   747   assumes major: "P-->Q"
   748       and minor: "Q ==> R" "~P ==> R"
   749   shows "R"
   750 apply (rule excluded_middle [of P, THEN disjE])
   751 apply (iprover intro: minor major [THEN mp])+
   752 done
   753 
   754 (*Classical <-> elimination. *)
   755 lemma iffCE:
   756   assumes major: "P=Q"
   757       and minor: "[| P; Q |] ==> R"  "[| ~P; ~Q |] ==> R"
   758   shows "R"
   759 apply (rule major [THEN iffE])
   760 apply (iprover intro: minor elim: impCE notE)
   761 done
   762 
   763 lemma exCI:
   764   assumes "ALL x. ~P(x) ==> P(a)"
   765   shows "EX x. P(x)"
   766 apply (rule ccontr)
   767 apply (iprover intro: assms exI allI notI notE [of "\<exists>x. P x"])
   768 done
   769 
   770 
   771 subsubsection {* Intuitionistic Reasoning *}
   772 
   773 lemma impE':
   774   assumes 1: "P --> Q"
   775     and 2: "Q ==> R"
   776     and 3: "P --> Q ==> P"
   777   shows R
   778 proof -
   779   from 3 and 1 have P .
   780   with 1 have Q by (rule impE)
   781   with 2 show R .
   782 qed
   783 
   784 lemma allE':
   785   assumes 1: "ALL x. P x"
   786     and 2: "P x ==> ALL x. P x ==> Q"
   787   shows Q
   788 proof -
   789   from 1 have "P x" by (rule spec)
   790   from this and 1 show Q by (rule 2)
   791 qed
   792 
   793 lemma notE':
   794   assumes 1: "~ P"
   795     and 2: "~ P ==> P"
   796   shows R
   797 proof -
   798   from 2 and 1 have P .
   799   with 1 show R by (rule notE)
   800 qed
   801 
   802 lemma TrueE: "True ==> P ==> P" .
   803 lemma notFalseE: "~ False ==> P ==> P" .
   804 
   805 lemmas [Pure.elim!] = disjE iffE FalseE conjE exE TrueE notFalseE
   806   and [Pure.intro!] = iffI conjI impI TrueI notI allI refl
   807   and [Pure.elim 2] = allE notE' impE'
   808   and [Pure.intro] = exI disjI2 disjI1
   809 
   810 lemmas [trans] = trans
   811   and [sym] = sym not_sym
   812   and [Pure.elim?] = iffD1 iffD2 impE
   813 
   814 use "hologic.ML"
   815 
   816 
   817 subsubsection {* Atomizing meta-level connectives *}
   818 
   819 lemma atomize_all [atomize]: "(!!x. P x) == Trueprop (ALL x. P x)"
   820 proof
   821   assume "!!x. P x"
   822   then show "ALL x. P x" ..
   823 next
   824   assume "ALL x. P x"
   825   then show "!!x. P x" by (rule allE)
   826 qed
   827 
   828 lemma atomize_imp [atomize]: "(A ==> B) == Trueprop (A --> B)"
   829 proof
   830   assume r: "A ==> B"
   831   show "A --> B" by (rule impI) (rule r)
   832 next
   833   assume "A --> B" and A
   834   then show B by (rule mp)
   835 qed
   836 
   837 lemma atomize_not: "(A ==> False) == Trueprop (~A)"
   838 proof
   839   assume r: "A ==> False"
   840   show "~A" by (rule notI) (rule r)
   841 next
   842   assume "~A" and A
   843   then show False by (rule notE)
   844 qed
   845 
   846 lemma atomize_eq [atomize]: "(x == y) == Trueprop (x = y)"
   847 proof
   848   assume "x == y"
   849   show "x = y" by (unfold `x == y`) (rule refl)
   850 next
   851   assume "x = y"
   852   then show "x == y" by (rule eq_reflection)
   853 qed
   854 
   855 lemma atomize_conj [atomize]:
   856   includes meta_conjunction_syntax
   857   shows "(A && B) == Trueprop (A & B)"
   858 proof
   859   assume conj: "A && B"
   860   show "A & B"
   861   proof (rule conjI)
   862     from conj show A by (rule conjunctionD1)
   863     from conj show B by (rule conjunctionD2)
   864   qed
   865 next
   866   assume conj: "A & B"
   867   show "A && B"
   868   proof -
   869     from conj show A ..
   870     from conj show B ..
   871   qed
   872 qed
   873 
   874 lemmas [symmetric, rulify] = atomize_all atomize_imp
   875   and [symmetric, defn] = atomize_all atomize_imp atomize_eq
   876 
   877 
   878 subsubsection {* Atomizing elimination rules *}
   879 
   880 setup AtomizeElim.setup
   881 
   882 lemma atomize_exL[atomize_elim]: "(!!x. P x ==> Q) == ((EX x. P x) ==> Q)"
   883   by rule iprover+
   884 
   885 lemma atomize_conjL[atomize_elim]: "(A ==> B ==> C) == (A & B ==> C)"
   886   by rule iprover+
   887 
   888 lemma atomize_disjL[atomize_elim]: "((A ==> C) ==> (B ==> C) ==> C) == ((A | B ==> C) ==> C)"
   889   by rule iprover+
   890 
   891 lemma atomize_elimL[atomize_elim]: "(!!B. (A ==> B) ==> B) == Trueprop A" ..
   892 
   893 
   894 subsection {* Package setup *}
   895 
   896 subsubsection {* Classical Reasoner setup *}
   897 
   898 lemma imp_elim: "P --> Q ==> (~ R ==> P) ==> (Q ==> R) ==> R"
   899   by (rule classical) iprover
   900 
   901 lemma swap: "~ P ==> (~ R ==> P) ==> R"
   902   by (rule classical) iprover
   903 
   904 lemma thin_refl:
   905   "\<And>X. \<lbrakk> x=x; PROP W \<rbrakk> \<Longrightarrow> PROP W" .
   906 
   907 ML {*
   908 structure Hypsubst = HypsubstFun(
   909 struct
   910   structure Simplifier = Simplifier
   911   val dest_eq = HOLogic.dest_eq
   912   val dest_Trueprop = HOLogic.dest_Trueprop
   913   val dest_imp = HOLogic.dest_imp
   914   val eq_reflection = @{thm eq_reflection}
   915   val rev_eq_reflection = @{thm meta_eq_to_obj_eq}
   916   val imp_intr = @{thm impI}
   917   val rev_mp = @{thm rev_mp}
   918   val subst = @{thm subst}
   919   val sym = @{thm sym}
   920   val thin_refl = @{thm thin_refl};
   921 end);
   922 open Hypsubst;
   923 
   924 structure Classical = ClassicalFun(
   925 struct
   926   val imp_elim = @{thm imp_elim}
   927   val not_elim = @{thm notE}
   928   val swap = @{thm swap}
   929   val classical = @{thm classical}
   930   val sizef = Drule.size_of_thm
   931   val hyp_subst_tacs = [Hypsubst.hyp_subst_tac]
   932 end);
   933 
   934 structure BasicClassical: BASIC_CLASSICAL = Classical; 
   935 open BasicClassical;
   936 
   937 ML_Context.value_antiq "claset"
   938   (Scan.succeed ("claset", "Classical.local_claset_of (ML_Context.the_local_context ())"));
   939 
   940 structure ResAtpset = NamedThmsFun(val name = "atp" val description = "ATP rules");
   941 
   942 structure ResBlacklist = NamedThmsFun(val name = "noatp" val description = "Theorems blacklisted for ATP");
   943 *}
   944 
   945 text {*ResBlacklist holds theorems blacklisted to sledgehammer. 
   946   These theorems typically produce clauses that are prolific (match too many equality or
   947   membership literals) and relate to seldom-used facts. Some duplicate other rules.*}
   948 
   949 setup {*
   950 let
   951   (*prevent substitution on bool*)
   952   fun hyp_subst_tac' i thm = if i <= Thm.nprems_of thm andalso
   953     Term.exists_Const (fn ("op =", Type (_, [T, _])) => T <> Type ("bool", []) | _ => false)
   954       (nth (Thm.prems_of thm) (i - 1)) then Hypsubst.hyp_subst_tac i thm else no_tac thm;
   955 in
   956   Hypsubst.hypsubst_setup
   957   #> ContextRules.addSWrapper (fn tac => hyp_subst_tac' ORELSE' tac)
   958   #> Classical.setup
   959   #> ResAtpset.setup
   960   #> ResBlacklist.setup
   961 end
   962 *}
   963 
   964 declare iffI [intro!]
   965   and notI [intro!]
   966   and impI [intro!]
   967   and disjCI [intro!]
   968   and conjI [intro!]
   969   and TrueI [intro!]
   970   and refl [intro!]
   971 
   972 declare iffCE [elim!]
   973   and FalseE [elim!]
   974   and impCE [elim!]
   975   and disjE [elim!]
   976   and conjE [elim!]
   977   and conjE [elim!]
   978 
   979 declare ex_ex1I [intro!]
   980   and allI [intro!]
   981   and the_equality [intro]
   982   and exI [intro]
   983 
   984 declare exE [elim!]
   985   allE [elim]
   986 
   987 ML {* val HOL_cs = @{claset} *}
   988 
   989 lemma contrapos_np: "~ Q ==> (~ P ==> Q) ==> P"
   990   apply (erule swap)
   991   apply (erule (1) meta_mp)
   992   done
   993 
   994 declare ex_ex1I [rule del, intro! 2]
   995   and ex1I [intro]
   996 
   997 lemmas [intro?] = ext
   998   and [elim?] = ex1_implies_ex
   999 
  1000 (*Better then ex1E for classical reasoner: needs no quantifier duplication!*)
  1001 lemma alt_ex1E [elim!]:
  1002   assumes major: "\<exists>!x. P x"
  1003       and prem: "\<And>x. \<lbrakk> P x; \<forall>y y'. P y \<and> P y' \<longrightarrow> y = y' \<rbrakk> \<Longrightarrow> R"
  1004   shows R
  1005 apply (rule ex1E [OF major])
  1006 apply (rule prem)
  1007 apply (tactic {* ares_tac @{thms allI} 1 *})+
  1008 apply (tactic {* etac (Classical.dup_elim @{thm allE}) 1 *})
  1009 apply iprover
  1010 done
  1011 
  1012 ML {*
  1013 structure Blast = BlastFun
  1014 (
  1015   type claset = Classical.claset
  1016   val equality_name = @{const_name "op ="}
  1017   val not_name = @{const_name Not}
  1018   val notE = @{thm notE}
  1019   val ccontr = @{thm ccontr}
  1020   val contr_tac = Classical.contr_tac
  1021   val dup_intr = Classical.dup_intr
  1022   val hyp_subst_tac = Hypsubst.blast_hyp_subst_tac
  1023   val claset = Classical.claset
  1024   val rep_cs = Classical.rep_cs
  1025   val cla_modifiers = Classical.cla_modifiers
  1026   val cla_meth' = Classical.cla_meth'
  1027 );
  1028 val Blast_tac = Blast.Blast_tac;
  1029 val blast_tac = Blast.blast_tac;
  1030 *}
  1031 
  1032 setup Blast.setup
  1033 
  1034 
  1035 subsubsection {* Simplifier *}
  1036 
  1037 lemma eta_contract_eq: "(%s. f s) = f" ..
  1038 
  1039 lemma simp_thms:
  1040   shows not_not: "(~ ~ P) = P"
  1041   and Not_eq_iff: "((~P) = (~Q)) = (P = Q)"
  1042   and
  1043     "(P ~= Q) = (P = (~Q))"
  1044     "(P | ~P) = True"    "(~P | P) = True"
  1045     "(x = x) = True"
  1046   and not_True_eq_False: "(\<not> True) = False"
  1047   and not_False_eq_True: "(\<not> False) = True"
  1048   and
  1049     "(~P) ~= P"  "P ~= (~P)"
  1050     "(True=P) = P"
  1051   and eq_True: "(P = True) = P"
  1052   and "(False=P) = (~P)"
  1053   and eq_False: "(P = False) = (\<not> P)"
  1054   and
  1055     "(True --> P) = P"  "(False --> P) = True"
  1056     "(P --> True) = True"  "(P --> P) = True"
  1057     "(P --> False) = (~P)"  "(P --> ~P) = (~P)"
  1058     "(P & True) = P"  "(True & P) = P"
  1059     "(P & False) = False"  "(False & P) = False"
  1060     "(P & P) = P"  "(P & (P & Q)) = (P & Q)"
  1061     "(P & ~P) = False"    "(~P & P) = False"
  1062     "(P | True) = True"  "(True | P) = True"
  1063     "(P | False) = P"  "(False | P) = P"
  1064     "(P | P) = P"  "(P | (P | Q)) = (P | Q)" and
  1065     "(ALL x. P) = P"  "(EX x. P) = P"  "EX x. x=t"  "EX x. t=x"
  1066     -- {* needed for the one-point-rule quantifier simplification procs *}
  1067     -- {* essential for termination!! *} and
  1068     "!!P. (EX x. x=t & P(x)) = P(t)"
  1069     "!!P. (EX x. t=x & P(x)) = P(t)"
  1070     "!!P. (ALL x. x=t --> P(x)) = P(t)"
  1071     "!!P. (ALL x. t=x --> P(x)) = P(t)"
  1072   by (blast, blast, blast, blast, blast, iprover+)
  1073 
  1074 lemma disj_absorb: "(A | A) = A"
  1075   by blast
  1076 
  1077 lemma disj_left_absorb: "(A | (A | B)) = (A | B)"
  1078   by blast
  1079 
  1080 lemma conj_absorb: "(A & A) = A"
  1081   by blast
  1082 
  1083 lemma conj_left_absorb: "(A & (A & B)) = (A & B)"
  1084   by blast
  1085 
  1086 lemma eq_ac:
  1087   shows eq_commute: "(a=b) = (b=a)"
  1088     and eq_left_commute: "(P=(Q=R)) = (Q=(P=R))"
  1089     and eq_assoc: "((P=Q)=R) = (P=(Q=R))" by (iprover, blast+)
  1090 lemma neq_commute: "(a~=b) = (b~=a)" by iprover
  1091 
  1092 lemma conj_comms:
  1093   shows conj_commute: "(P&Q) = (Q&P)"
  1094     and conj_left_commute: "(P&(Q&R)) = (Q&(P&R))" by iprover+
  1095 lemma conj_assoc: "((P&Q)&R) = (P&(Q&R))" by iprover
  1096 
  1097 lemmas conj_ac = conj_commute conj_left_commute conj_assoc
  1098 
  1099 lemma disj_comms:
  1100   shows disj_commute: "(P|Q) = (Q|P)"
  1101     and disj_left_commute: "(P|(Q|R)) = (Q|(P|R))" by iprover+
  1102 lemma disj_assoc: "((P|Q)|R) = (P|(Q|R))" by iprover
  1103 
  1104 lemmas disj_ac = disj_commute disj_left_commute disj_assoc
  1105 
  1106 lemma conj_disj_distribL: "(P&(Q|R)) = (P&Q | P&R)" by iprover
  1107 lemma conj_disj_distribR: "((P|Q)&R) = (P&R | Q&R)" by iprover
  1108 
  1109 lemma disj_conj_distribL: "(P|(Q&R)) = ((P|Q) & (P|R))" by iprover
  1110 lemma disj_conj_distribR: "((P&Q)|R) = ((P|R) & (Q|R))" by iprover
  1111 
  1112 lemma imp_conjR: "(P --> (Q&R)) = ((P-->Q) & (P-->R))" by iprover
  1113 lemma imp_conjL: "((P&Q) -->R)  = (P --> (Q --> R))" by iprover
  1114 lemma imp_disjL: "((P|Q) --> R) = ((P-->R)&(Q-->R))" by iprover
  1115 
  1116 text {* These two are specialized, but @{text imp_disj_not1} is useful in @{text "Auth/Yahalom"}. *}
  1117 lemma imp_disj_not1: "(P --> Q | R) = (~Q --> P --> R)" by blast
  1118 lemma imp_disj_not2: "(P --> Q | R) = (~R --> P --> Q)" by blast
  1119 
  1120 lemma imp_disj1: "((P-->Q)|R) = (P--> Q|R)" by blast
  1121 lemma imp_disj2: "(Q|(P-->R)) = (P--> Q|R)" by blast
  1122 
  1123 lemma imp_cong: "(P = P') ==> (P' ==> (Q = Q')) ==> ((P --> Q) = (P' --> Q'))"
  1124   by iprover
  1125 
  1126 lemma de_Morgan_disj: "(~(P | Q)) = (~P & ~Q)" by iprover
  1127 lemma de_Morgan_conj: "(~(P & Q)) = (~P | ~Q)" by blast
  1128 lemma not_imp: "(~(P --> Q)) = (P & ~Q)" by blast
  1129 lemma not_iff: "(P~=Q) = (P = (~Q))" by blast
  1130 lemma disj_not1: "(~P | Q) = (P --> Q)" by blast
  1131 lemma disj_not2: "(P | ~Q) = (Q --> P)"  -- {* changes orientation :-( *}
  1132   by blast
  1133 lemma imp_conv_disj: "(P --> Q) = ((~P) | Q)" by blast
  1134 
  1135 lemma iff_conv_conj_imp: "(P = Q) = ((P --> Q) & (Q --> P))" by iprover
  1136 
  1137 
  1138 lemma cases_simp: "((P --> Q) & (~P --> Q)) = Q"
  1139   -- {* Avoids duplication of subgoals after @{text split_if}, when the true and false *}
  1140   -- {* cases boil down to the same thing. *}
  1141   by blast
  1142 
  1143 lemma not_all: "(~ (! x. P(x))) = (? x.~P(x))" by blast
  1144 lemma imp_all: "((! x. P x) --> Q) = (? x. P x --> Q)" by blast
  1145 lemma not_ex: "(~ (? x. P(x))) = (! x.~P(x))" by iprover
  1146 lemma imp_ex: "((? x. P x) --> Q) = (! x. P x --> Q)" by iprover
  1147 lemma all_not_ex: "(ALL x. P x) = (~ (EX x. ~ P x ))" by blast
  1148 
  1149 declare All_def [noatp]
  1150 
  1151 lemma ex_disj_distrib: "(? x. P(x) | Q(x)) = ((? x. P(x)) | (? x. Q(x)))" by iprover
  1152 lemma all_conj_distrib: "(!x. P(x) & Q(x)) = ((! x. P(x)) & (! x. Q(x)))" by iprover
  1153 
  1154 text {*
  1155   \medskip The @{text "&"} congruence rule: not included by default!
  1156   May slow rewrite proofs down by as much as 50\% *}
  1157 
  1158 lemma conj_cong:
  1159     "(P = P') ==> (P' ==> (Q = Q')) ==> ((P & Q) = (P' & Q'))"
  1160   by iprover
  1161 
  1162 lemma rev_conj_cong:
  1163     "(Q = Q') ==> (Q' ==> (P = P')) ==> ((P & Q) = (P' & Q'))"
  1164   by iprover
  1165 
  1166 text {* The @{text "|"} congruence rule: not included by default! *}
  1167 
  1168 lemma disj_cong:
  1169     "(P = P') ==> (~P' ==> (Q = Q')) ==> ((P | Q) = (P' | Q'))"
  1170   by blast
  1171 
  1172 
  1173 text {* \medskip if-then-else rules *}
  1174 
  1175 lemma if_True: "(if True then x else y) = x"
  1176   by (unfold if_def) blast
  1177 
  1178 lemma if_False: "(if False then x else y) = y"
  1179   by (unfold if_def) blast
  1180 
  1181 lemma if_P: "P ==> (if P then x else y) = x"
  1182   by (unfold if_def) blast
  1183 
  1184 lemma if_not_P: "~P ==> (if P then x else y) = y"
  1185   by (unfold if_def) blast
  1186 
  1187 lemma split_if: "P (if Q then x else y) = ((Q --> P(x)) & (~Q --> P(y)))"
  1188   apply (rule case_split [of Q])
  1189    apply (simplesubst if_P)
  1190     prefer 3 apply (simplesubst if_not_P, blast+)
  1191   done
  1192 
  1193 lemma split_if_asm: "P (if Q then x else y) = (~((Q & ~P x) | (~Q & ~P y)))"
  1194 by (simplesubst split_if, blast)
  1195 
  1196 lemmas if_splits [noatp] = split_if split_if_asm
  1197 
  1198 lemma if_cancel: "(if c then x else x) = x"
  1199 by (simplesubst split_if, blast)
  1200 
  1201 lemma if_eq_cancel: "(if x = y then y else x) = x"
  1202 by (simplesubst split_if, blast)
  1203 
  1204 lemma if_bool_eq_conj: "(if P then Q else R) = ((P-->Q) & (~P-->R))"
  1205   -- {* This form is useful for expanding @{text "if"}s on the RIGHT of the @{text "==>"} symbol. *}
  1206   by (rule split_if)
  1207 
  1208 lemma if_bool_eq_disj: "(if P then Q else R) = ((P&Q) | (~P&R))"
  1209   -- {* And this form is useful for expanding @{text "if"}s on the LEFT. *}
  1210   apply (simplesubst split_if, blast)
  1211   done
  1212 
  1213 lemma Eq_TrueI: "P ==> P == True" by (unfold atomize_eq) iprover
  1214 lemma Eq_FalseI: "~P ==> P == False" by (unfold atomize_eq) iprover
  1215 
  1216 text {* \medskip let rules for simproc *}
  1217 
  1218 lemma Let_folded: "f x \<equiv> g x \<Longrightarrow>  Let x f \<equiv> Let x g"
  1219   by (unfold Let_def)
  1220 
  1221 lemma Let_unfold: "f x \<equiv> g \<Longrightarrow>  Let x f \<equiv> g"
  1222   by (unfold Let_def)
  1223 
  1224 text {*
  1225   The following copy of the implication operator is useful for
  1226   fine-tuning congruence rules.  It instructs the simplifier to simplify
  1227   its premise.
  1228 *}
  1229 
  1230 constdefs
  1231   simp_implies :: "[prop, prop] => prop"  (infixr "=simp=>" 1)
  1232   [code func del]: "simp_implies \<equiv> op ==>"
  1233 
  1234 lemma simp_impliesI:
  1235   assumes PQ: "(PROP P \<Longrightarrow> PROP Q)"
  1236   shows "PROP P =simp=> PROP Q"
  1237   apply (unfold simp_implies_def)
  1238   apply (rule PQ)
  1239   apply assumption
  1240   done
  1241 
  1242 lemma simp_impliesE:
  1243   assumes PQ: "PROP P =simp=> PROP Q"
  1244   and P: "PROP P"
  1245   and QR: "PROP Q \<Longrightarrow> PROP R"
  1246   shows "PROP R"
  1247   apply (rule QR)
  1248   apply (rule PQ [unfolded simp_implies_def])
  1249   apply (rule P)
  1250   done
  1251 
  1252 lemma simp_implies_cong:
  1253   assumes PP' :"PROP P == PROP P'"
  1254   and P'QQ': "PROP P' ==> (PROP Q == PROP Q')"
  1255   shows "(PROP P =simp=> PROP Q) == (PROP P' =simp=> PROP Q')"
  1256 proof (unfold simp_implies_def, rule equal_intr_rule)
  1257   assume PQ: "PROP P \<Longrightarrow> PROP Q"
  1258   and P': "PROP P'"
  1259   from PP' [symmetric] and P' have "PROP P"
  1260     by (rule equal_elim_rule1)
  1261   then have "PROP Q" by (rule PQ)
  1262   with P'QQ' [OF P'] show "PROP Q'" by (rule equal_elim_rule1)
  1263 next
  1264   assume P'Q': "PROP P' \<Longrightarrow> PROP Q'"
  1265   and P: "PROP P"
  1266   from PP' and P have P': "PROP P'" by (rule equal_elim_rule1)
  1267   then have "PROP Q'" by (rule P'Q')
  1268   with P'QQ' [OF P', symmetric] show "PROP Q"
  1269     by (rule equal_elim_rule1)
  1270 qed
  1271 
  1272 lemma uncurry:
  1273   assumes "P \<longrightarrow> Q \<longrightarrow> R"
  1274   shows "P \<and> Q \<longrightarrow> R"
  1275   using assms by blast
  1276 
  1277 lemma iff_allI:
  1278   assumes "\<And>x. P x = Q x"
  1279   shows "(\<forall>x. P x) = (\<forall>x. Q x)"
  1280   using assms by blast
  1281 
  1282 lemma iff_exI:
  1283   assumes "\<And>x. P x = Q x"
  1284   shows "(\<exists>x. P x) = (\<exists>x. Q x)"
  1285   using assms by blast
  1286 
  1287 lemma all_comm:
  1288   "(\<forall>x y. P x y) = (\<forall>y x. P x y)"
  1289   by blast
  1290 
  1291 lemma ex_comm:
  1292   "(\<exists>x y. P x y) = (\<exists>y x. P x y)"
  1293   by blast
  1294 
  1295 use "simpdata.ML"
  1296 ML {* open Simpdata *}
  1297 
  1298 setup {*
  1299   Simplifier.method_setup Splitter.split_modifiers
  1300   #> Simplifier.map_simpset (K Simpdata.simpset_simprocs)
  1301   #> Splitter.setup
  1302   #> clasimp_setup
  1303   #> EqSubst.setup
  1304 *}
  1305 
  1306 text {* Simproc for proving @{text "(y = x) == False"} from premise @{text "~(x = y)"}: *}
  1307 
  1308 simproc_setup neq ("x = y") = {* fn _ =>
  1309 let
  1310   val neq_to_EQ_False = @{thm not_sym} RS @{thm Eq_FalseI};
  1311   fun is_neq eq lhs rhs thm =
  1312     (case Thm.prop_of thm of
  1313       _ $ (Not $ (eq' $ l' $ r')) =>
  1314         Not = HOLogic.Not andalso eq' = eq andalso
  1315         r' aconv lhs andalso l' aconv rhs
  1316     | _ => false);
  1317   fun proc ss ct =
  1318     (case Thm.term_of ct of
  1319       eq $ lhs $ rhs =>
  1320         (case find_first (is_neq eq lhs rhs) (Simplifier.prems_of_ss ss) of
  1321           SOME thm => SOME (thm RS neq_to_EQ_False)
  1322         | NONE => NONE)
  1323      | _ => NONE);
  1324 in proc end;
  1325 *}
  1326 
  1327 simproc_setup let_simp ("Let x f") = {*
  1328 let
  1329   val (f_Let_unfold, x_Let_unfold) =
  1330     let val [(_$(f$x)$_)] = prems_of @{thm Let_unfold}
  1331     in (cterm_of @{theory} f, cterm_of @{theory} x) end
  1332   val (f_Let_folded, x_Let_folded) =
  1333     let val [(_$(f$x)$_)] = prems_of @{thm Let_folded}
  1334     in (cterm_of @{theory} f, cterm_of @{theory} x) end;
  1335   val g_Let_folded =
  1336     let val [(_$_$(g$_))] = prems_of @{thm Let_folded} in cterm_of @{theory} g end;
  1337 
  1338   fun proc _ ss ct =
  1339     let
  1340       val ctxt = Simplifier.the_context ss;
  1341       val thy = ProofContext.theory_of ctxt;
  1342       val t = Thm.term_of ct;
  1343       val ([t'], ctxt') = Variable.import_terms false [t] ctxt;
  1344     in Option.map (hd o Variable.export ctxt' ctxt o single)
  1345       (case t' of Const ("Let",_) $ x $ f => (* x and f are already in normal form *)
  1346         if is_Free x orelse is_Bound x orelse is_Const x
  1347         then SOME @{thm Let_def}
  1348         else
  1349           let
  1350             val n = case f of (Abs (x,_,_)) => x | _ => "x";
  1351             val cx = cterm_of thy x;
  1352             val {T=xT,...} = rep_cterm cx;
  1353             val cf = cterm_of thy f;
  1354             val fx_g = Simplifier.rewrite ss (Thm.capply cf cx);
  1355             val (_$_$g) = prop_of fx_g;
  1356             val g' = abstract_over (x,g);
  1357           in (if (g aconv g')
  1358                then
  1359                   let
  1360                     val rl =
  1361                       cterm_instantiate [(f_Let_unfold,cf),(x_Let_unfold,cx)] @{thm Let_unfold};
  1362                   in SOME (rl OF [fx_g]) end
  1363                else if Term.betapply (f,x) aconv g then NONE (*avoid identity conversion*)
  1364                else let
  1365                      val abs_g'= Abs (n,xT,g');
  1366                      val g'x = abs_g'$x;
  1367                      val g_g'x = symmetric (beta_conversion false (cterm_of thy g'x));
  1368                      val rl = cterm_instantiate
  1369                                [(f_Let_folded,cterm_of thy f),(x_Let_folded,cx),
  1370                                 (g_Let_folded,cterm_of thy abs_g')]
  1371                                @{thm Let_folded};
  1372                    in SOME (rl OF [transitive fx_g g_g'x])
  1373                    end)
  1374           end
  1375       | _ => NONE)
  1376     end
  1377 in proc end *}
  1378 
  1379 
  1380 lemma True_implies_equals: "(True \<Longrightarrow> PROP P) \<equiv> PROP P"
  1381 proof
  1382   assume "True \<Longrightarrow> PROP P"
  1383   from this [OF TrueI] show "PROP P" .
  1384 next
  1385   assume "PROP P"
  1386   then show "PROP P" .
  1387 qed
  1388 
  1389 lemma ex_simps:
  1390   "!!P Q. (EX x. P x & Q)   = ((EX x. P x) & Q)"
  1391   "!!P Q. (EX x. P & Q x)   = (P & (EX x. Q x))"
  1392   "!!P Q. (EX x. P x | Q)   = ((EX x. P x) | Q)"
  1393   "!!P Q. (EX x. P | Q x)   = (P | (EX x. Q x))"
  1394   "!!P Q. (EX x. P x --> Q) = ((ALL x. P x) --> Q)"
  1395   "!!P Q. (EX x. P --> Q x) = (P --> (EX x. Q x))"
  1396   -- {* Miniscoping: pushing in existential quantifiers. *}
  1397   by (iprover | blast)+
  1398 
  1399 lemma all_simps:
  1400   "!!P Q. (ALL x. P x & Q)   = ((ALL x. P x) & Q)"
  1401   "!!P Q. (ALL x. P & Q x)   = (P & (ALL x. Q x))"
  1402   "!!P Q. (ALL x. P x | Q)   = ((ALL x. P x) | Q)"
  1403   "!!P Q. (ALL x. P | Q x)   = (P | (ALL x. Q x))"
  1404   "!!P Q. (ALL x. P x --> Q) = ((EX x. P x) --> Q)"
  1405   "!!P Q. (ALL x. P --> Q x) = (P --> (ALL x. Q x))"
  1406   -- {* Miniscoping: pushing in universal quantifiers. *}
  1407   by (iprover | blast)+
  1408 
  1409 lemmas [simp] =
  1410   triv_forall_equality (*prunes params*)
  1411   True_implies_equals  (*prune asms `True'*)
  1412   if_True
  1413   if_False
  1414   if_cancel
  1415   if_eq_cancel
  1416   imp_disjL
  1417   (*In general it seems wrong to add distributive laws by default: they
  1418     might cause exponential blow-up.  But imp_disjL has been in for a while
  1419     and cannot be removed without affecting existing proofs.  Moreover,
  1420     rewriting by "(P|Q --> R) = ((P-->R)&(Q-->R))" might be justified on the
  1421     grounds that it allows simplification of R in the two cases.*)
  1422   conj_assoc
  1423   disj_assoc
  1424   de_Morgan_conj
  1425   de_Morgan_disj
  1426   imp_disj1
  1427   imp_disj2
  1428   not_imp
  1429   disj_not1
  1430   not_all
  1431   not_ex
  1432   cases_simp
  1433   the_eq_trivial
  1434   the_sym_eq_trivial
  1435   ex_simps
  1436   all_simps
  1437   simp_thms
  1438 
  1439 lemmas [cong] = imp_cong simp_implies_cong
  1440 lemmas [split] = split_if
  1441 
  1442 ML {* val HOL_ss = @{simpset} *}
  1443 
  1444 text {* Simplifies x assuming c and y assuming ~c *}
  1445 lemma if_cong:
  1446   assumes "b = c"
  1447       and "c \<Longrightarrow> x = u"
  1448       and "\<not> c \<Longrightarrow> y = v"
  1449   shows "(if b then x else y) = (if c then u else v)"
  1450   unfolding if_def using assms by simp
  1451 
  1452 text {* Prevents simplification of x and y:
  1453   faster and allows the execution of functional programs. *}
  1454 lemma if_weak_cong [cong]:
  1455   assumes "b = c"
  1456   shows "(if b then x else y) = (if c then x else y)"
  1457   using assms by (rule arg_cong)
  1458 
  1459 text {* Prevents simplification of t: much faster *}
  1460 lemma let_weak_cong:
  1461   assumes "a = b"
  1462   shows "(let x = a in t x) = (let x = b in t x)"
  1463   using assms by (rule arg_cong)
  1464 
  1465 text {* To tidy up the result of a simproc.  Only the RHS will be simplified. *}
  1466 lemma eq_cong2:
  1467   assumes "u = u'"
  1468   shows "(t \<equiv> u) \<equiv> (t \<equiv> u')"
  1469   using assms by simp
  1470 
  1471 lemma if_distrib:
  1472   "f (if c then x else y) = (if c then f x else f y)"
  1473   by simp
  1474 
  1475 text {* This lemma restricts the effect of the rewrite rule u=v to the left-hand
  1476   side of an equality.  Used in @{text "{Integ,Real}/simproc.ML"} *}
  1477 lemma restrict_to_left:
  1478   assumes "x = y"
  1479   shows "(x = z) = (y = z)"
  1480   using assms by simp
  1481 
  1482 
  1483 subsubsection {* Generic cases and induction *}
  1484 
  1485 text {* Rule projections: *}
  1486 
  1487 ML {*
  1488 structure ProjectRule = ProjectRuleFun
  1489 (
  1490   val conjunct1 = @{thm conjunct1};
  1491   val conjunct2 = @{thm conjunct2};
  1492   val mp = @{thm mp};
  1493 )
  1494 *}
  1495 
  1496 constdefs
  1497   induct_forall where "induct_forall P == \<forall>x. P x"
  1498   induct_implies where "induct_implies A B == A \<longrightarrow> B"
  1499   induct_equal where "induct_equal x y == x = y"
  1500   induct_conj where "induct_conj A B == A \<and> B"
  1501 
  1502 lemma induct_forall_eq: "(!!x. P x) == Trueprop (induct_forall (\<lambda>x. P x))"
  1503   by (unfold atomize_all induct_forall_def)
  1504 
  1505 lemma induct_implies_eq: "(A ==> B) == Trueprop (induct_implies A B)"
  1506   by (unfold atomize_imp induct_implies_def)
  1507 
  1508 lemma induct_equal_eq: "(x == y) == Trueprop (induct_equal x y)"
  1509   by (unfold atomize_eq induct_equal_def)
  1510 
  1511 lemma induct_conj_eq:
  1512   includes meta_conjunction_syntax
  1513   shows "(A && B) == Trueprop (induct_conj A B)"
  1514   by (unfold atomize_conj induct_conj_def)
  1515 
  1516 lemmas induct_atomize = induct_forall_eq induct_implies_eq induct_equal_eq induct_conj_eq
  1517 lemmas induct_rulify [symmetric, standard] = induct_atomize
  1518 lemmas induct_rulify_fallback =
  1519   induct_forall_def induct_implies_def induct_equal_def induct_conj_def
  1520 
  1521 
  1522 lemma induct_forall_conj: "induct_forall (\<lambda>x. induct_conj (A x) (B x)) =
  1523     induct_conj (induct_forall A) (induct_forall B)"
  1524   by (unfold induct_forall_def induct_conj_def) iprover
  1525 
  1526 lemma induct_implies_conj: "induct_implies C (induct_conj A B) =
  1527     induct_conj (induct_implies C A) (induct_implies C B)"
  1528   by (unfold induct_implies_def induct_conj_def) iprover
  1529 
  1530 lemma induct_conj_curry: "(induct_conj A B ==> PROP C) == (A ==> B ==> PROP C)"
  1531 proof
  1532   assume r: "induct_conj A B ==> PROP C" and A B
  1533   show "PROP C" by (rule r) (simp add: induct_conj_def `A` `B`)
  1534 next
  1535   assume r: "A ==> B ==> PROP C" and "induct_conj A B"
  1536   show "PROP C" by (rule r) (simp_all add: `induct_conj A B` [unfolded induct_conj_def])
  1537 qed
  1538 
  1539 lemmas induct_conj = induct_forall_conj induct_implies_conj induct_conj_curry
  1540 
  1541 hide const induct_forall induct_implies induct_equal induct_conj
  1542 
  1543 text {* Method setup. *}
  1544 
  1545 ML {*
  1546   structure Induct = InductFun
  1547   (
  1548     val cases_default = @{thm case_split}
  1549     val atomize = @{thms induct_atomize}
  1550     val rulify = @{thms induct_rulify}
  1551     val rulify_fallback = @{thms induct_rulify_fallback}
  1552   );
  1553 *}
  1554 
  1555 setup Induct.setup
  1556 
  1557 
  1558 subsection {* Other simple lemmas and lemma duplicates *}
  1559 
  1560 lemma Let_0 [simp]: "Let 0 f = f 0"
  1561   unfolding Let_def ..
  1562 
  1563 lemma Let_1 [simp]: "Let 1 f = f 1"
  1564   unfolding Let_def ..
  1565 
  1566 lemma ex1_eq [iff]: "EX! x. x = t" "EX! x. t = x"
  1567   by blast+
  1568 
  1569 lemma choice_eq: "(ALL x. EX! y. P x y) = (EX! f. ALL x. P x (f x))"
  1570   apply (rule iffI)
  1571   apply (rule_tac a = "%x. THE y. P x y" in ex1I)
  1572   apply (fast dest!: theI')
  1573   apply (fast intro: ext the1_equality [symmetric])
  1574   apply (erule ex1E)
  1575   apply (rule allI)
  1576   apply (rule ex1I)
  1577   apply (erule spec)
  1578   apply (erule_tac x = "%z. if z = x then y else f z" in allE)
  1579   apply (erule impE)
  1580   apply (rule allI)
  1581   apply (rule_tac P = "xa = x" in case_split_thm)
  1582   apply (drule_tac [3] x = x in fun_cong, simp_all)
  1583   done
  1584 
  1585 lemma mk_left_commute:
  1586   fixes f (infix "\<otimes>" 60)
  1587   assumes a: "\<And>x y z. (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)" and
  1588           c: "\<And>x y. x \<otimes> y = y \<otimes> x"
  1589   shows "x \<otimes> (y \<otimes> z) = y \<otimes> (x \<otimes> z)"
  1590   by (rule trans [OF trans [OF c a] arg_cong [OF c, of "f y"]])
  1591 
  1592 lemmas eq_sym_conv = eq_commute
  1593 
  1594 lemma nnf_simps:
  1595   "(\<not>(P \<and> Q)) = (\<not> P \<or> \<not> Q)" "(\<not> (P \<or> Q)) = (\<not> P \<and> \<not>Q)" "(P \<longrightarrow> Q) = (\<not>P \<or> Q)" 
  1596   "(P = Q) = ((P \<and> Q) \<or> (\<not>P \<and> \<not> Q))" "(\<not>(P = Q)) = ((P \<and> \<not> Q) \<or> (\<not>P \<and> Q))" 
  1597   "(\<not> \<not>(P)) = P"
  1598 by blast+
  1599 
  1600 
  1601 subsection {* Basic ML bindings *}
  1602 
  1603 ML {*
  1604 val FalseE = @{thm FalseE}
  1605 val Let_def = @{thm Let_def}
  1606 val TrueI = @{thm TrueI}
  1607 val allE = @{thm allE}
  1608 val allI = @{thm allI}
  1609 val all_dupE = @{thm all_dupE}
  1610 val arg_cong = @{thm arg_cong}
  1611 val box_equals = @{thm box_equals}
  1612 val ccontr = @{thm ccontr}
  1613 val classical = @{thm classical}
  1614 val conjE = @{thm conjE}
  1615 val conjI = @{thm conjI}
  1616 val conjunct1 = @{thm conjunct1}
  1617 val conjunct2 = @{thm conjunct2}
  1618 val disjCI = @{thm disjCI}
  1619 val disjE = @{thm disjE}
  1620 val disjI1 = @{thm disjI1}
  1621 val disjI2 = @{thm disjI2}
  1622 val eq_reflection = @{thm eq_reflection}
  1623 val ex1E = @{thm ex1E}
  1624 val ex1I = @{thm ex1I}
  1625 val ex1_implies_ex = @{thm ex1_implies_ex}
  1626 val exE = @{thm exE}
  1627 val exI = @{thm exI}
  1628 val excluded_middle = @{thm excluded_middle}
  1629 val ext = @{thm ext}
  1630 val fun_cong = @{thm fun_cong}
  1631 val iffD1 = @{thm iffD1}
  1632 val iffD2 = @{thm iffD2}
  1633 val iffI = @{thm iffI}
  1634 val impE = @{thm impE}
  1635 val impI = @{thm impI}
  1636 val meta_eq_to_obj_eq = @{thm meta_eq_to_obj_eq}
  1637 val mp = @{thm mp}
  1638 val notE = @{thm notE}
  1639 val notI = @{thm notI}
  1640 val not_all = @{thm not_all}
  1641 val not_ex = @{thm not_ex}
  1642 val not_iff = @{thm not_iff}
  1643 val not_not = @{thm not_not}
  1644 val not_sym = @{thm not_sym}
  1645 val refl = @{thm refl}
  1646 val rev_mp = @{thm rev_mp}
  1647 val spec = @{thm spec}
  1648 val ssubst = @{thm ssubst}
  1649 val subst = @{thm subst}
  1650 val sym = @{thm sym}
  1651 val trans = @{thm trans}
  1652 *}
  1653 
  1654 
  1655 subsection {* Code generator basic setup -- see further @{text Code_Setup.thy} *}
  1656 
  1657 code_datatype Trueprop "prop"
  1658 
  1659 code_datatype "TYPE('a\<Colon>{})"
  1660 
  1661 lemma Let_case_cert:
  1662   assumes "CASE \<equiv> (\<lambda>x. Let x f)"
  1663   shows "CASE x \<equiv> f x"
  1664   using assms by simp_all
  1665 
  1666 lemma If_case_cert:
  1667   includes meta_conjunction_syntax
  1668   assumes "CASE \<equiv> (\<lambda>b. If b f g)"
  1669   shows "(CASE True \<equiv> f) && (CASE False \<equiv> g)"
  1670   using assms by simp_all
  1671 
  1672 setup {*
  1673   Code.add_case @{thm Let_case_cert}
  1674   #> Code.add_case @{thm If_case_cert}
  1675   #> Code.add_undefined @{const_name undefined}
  1676 *}
  1677 
  1678 class eq = type +
  1679   fixes eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
  1680   assumes eq: "eq x y \<longleftrightarrow> x = y "
  1681 begin
  1682 
  1683 lemma equals_eq [code inline, code func]: "op = \<equiv> eq"
  1684   by (rule eq_reflection) (rule ext, rule ext, rule sym, rule eq)
  1685 
  1686 declare equals_eq [symmetric, code post]
  1687 
  1688 end
  1689 
  1690 hide (open) const eq
  1691 hide const eq
  1692 
  1693 setup {*
  1694   CodeUnit.add_const_alias @{thm equals_eq}
  1695   #> CodeName.setup
  1696   #> CodeTarget.setup
  1697   #> Nbe.setup
  1698 *}
  1699 
  1700 lemma [code func]:
  1701   shows "False \<and> x \<longleftrightarrow> False"
  1702     and "True \<and> x \<longleftrightarrow> x"
  1703     and "x \<and> False \<longleftrightarrow> False"
  1704     and "x \<and> True \<longleftrightarrow> x" by simp_all
  1705 
  1706 lemma [code func]:
  1707   shows "False \<or> x \<longleftrightarrow> x"
  1708     and "True \<or> x \<longleftrightarrow> True"
  1709     and "x \<or> False \<longleftrightarrow> x"
  1710     and "x \<or> True \<longleftrightarrow> True" by simp_all
  1711 
  1712 lemma [code func]:
  1713   shows "\<not> True \<longleftrightarrow> False"
  1714     and "\<not> False \<longleftrightarrow> True" by (rule HOL.simp_thms)+
  1715 
  1716 
  1717 
  1718 subsection {* Legacy tactics and ML bindings *}
  1719 
  1720 ML {*
  1721 fun strip_tac i = REPEAT (resolve_tac [impI, allI] i);
  1722 
  1723 (* combination of (spec RS spec RS ...(j times) ... spec RS mp) *)
  1724 local
  1725   fun wrong_prem (Const ("All", _) $ (Abs (_, _, t))) = wrong_prem t
  1726     | wrong_prem (Bound _) = true
  1727     | wrong_prem _ = false;
  1728   val filter_right = filter (not o wrong_prem o HOLogic.dest_Trueprop o hd o Thm.prems_of);
  1729 in
  1730   fun smp i = funpow i (fn m => filter_right ([spec] RL m)) ([mp]);
  1731   fun smp_tac j = EVERY'[dresolve_tac (smp j), atac];
  1732 end;
  1733 
  1734 val all_conj_distrib = thm "all_conj_distrib";
  1735 val all_simps = thms "all_simps";
  1736 val atomize_not = thm "atomize_not";
  1737 val case_split = thm "case_split";
  1738 val case_split_thm = thm "case_split_thm"
  1739 val cases_simp = thm "cases_simp";
  1740 val choice_eq = thm "choice_eq"
  1741 val cong = thm "cong"
  1742 val conj_comms = thms "conj_comms";
  1743 val conj_cong = thm "conj_cong";
  1744 val de_Morgan_conj = thm "de_Morgan_conj";
  1745 val de_Morgan_disj = thm "de_Morgan_disj";
  1746 val disj_assoc = thm "disj_assoc";
  1747 val disj_comms = thms "disj_comms";
  1748 val disj_cong = thm "disj_cong";
  1749 val eq_ac = thms "eq_ac";
  1750 val eq_cong2 = thm "eq_cong2"
  1751 val Eq_FalseI = thm "Eq_FalseI";
  1752 val Eq_TrueI = thm "Eq_TrueI";
  1753 val Ex1_def = thm "Ex1_def"
  1754 val ex_disj_distrib = thm "ex_disj_distrib";
  1755 val ex_simps = thms "ex_simps";
  1756 val if_cancel = thm "if_cancel";
  1757 val if_eq_cancel = thm "if_eq_cancel";
  1758 val if_False = thm "if_False";
  1759 val iff_conv_conj_imp = thm "iff_conv_conj_imp";
  1760 val iff = thm "iff"
  1761 val if_splits = thms "if_splits";
  1762 val if_True = thm "if_True";
  1763 val if_weak_cong = thm "if_weak_cong"
  1764 val imp_all = thm "imp_all";
  1765 val imp_cong = thm "imp_cong";
  1766 val imp_conjL = thm "imp_conjL";
  1767 val imp_conjR = thm "imp_conjR";
  1768 val imp_conv_disj = thm "imp_conv_disj";
  1769 val simp_implies_def = thm "simp_implies_def";
  1770 val simp_thms = thms "simp_thms";
  1771 val split_if = thm "split_if";
  1772 val the1_equality = thm "the1_equality"
  1773 val theI = thm "theI"
  1774 val theI' = thm "theI'"
  1775 val True_implies_equals = thm "True_implies_equals";
  1776 val nnf_conv = Simplifier.rewrite (HOL_basic_ss addsimps simp_thms @ @{thms "nnf_simps"})
  1777 
  1778 *}
  1779 
  1780 end