src/HOL/Product_Type.thy
author wenzelm
Wed Nov 30 16:27:10 2011 +0100 (2011-11-30)
changeset 45694 4a8743618257
parent 45662 4f7c05990420
child 45696 476ad865f125
permissions -rw-r--r--
prefer typedef without extra definition and alternative name;
tuned proofs;
     1 (*  Title:      HOL/Product_Type.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 header {* Cartesian products *}
     7 
     8 theory Product_Type
     9 imports Typedef Inductive Fun
    10 uses
    11   ("Tools/split_rule.ML")
    12   ("Tools/inductive_set.ML")
    13 begin
    14 
    15 subsection {* @{typ bool} is a datatype *}
    16 
    17 rep_datatype True False by (auto intro: bool_induct)
    18 
    19 declare case_split [cases type: bool]
    20   -- "prefer plain propositional version"
    21 
    22 lemma
    23   shows [code]: "HOL.equal False P \<longleftrightarrow> \<not> P"
    24     and [code]: "HOL.equal True P \<longleftrightarrow> P" 
    25     and [code]: "HOL.equal P False \<longleftrightarrow> \<not> P" 
    26     and [code]: "HOL.equal P True \<longleftrightarrow> P"
    27     and [code nbe]: "HOL.equal P P \<longleftrightarrow> True"
    28   by (simp_all add: equal)
    29 
    30 lemma If_case_cert:
    31   assumes "CASE \<equiv> (\<lambda>b. If b f g)"
    32   shows "(CASE True \<equiv> f) &&& (CASE False \<equiv> g)"
    33   using assms by simp_all
    34 
    35 setup {*
    36   Code.add_case @{thm If_case_cert}
    37 *}
    38 
    39 code_const "HOL.equal \<Colon> bool \<Rightarrow> bool \<Rightarrow> bool"
    40   (Haskell infix 4 "==")
    41 
    42 code_instance bool :: equal
    43   (Haskell -)
    44 
    45 
    46 subsection {* The @{text unit} type *}
    47 
    48 typedef (open) unit = "{True}"
    49   by auto
    50 
    51 definition Unity :: unit  ("'(')")
    52   where "() = Abs_unit True"
    53 
    54 lemma unit_eq [no_atp]: "u = ()"
    55   by (induct u) (simp add: Unity_def)
    56 
    57 text {*
    58   Simplification procedure for @{thm [source] unit_eq}.  Cannot use
    59   this rule directly --- it loops!
    60 *}
    61 
    62 simproc_setup unit_eq ("x::unit") = {*
    63   fn _ => fn _ => fn ct =>
    64     if HOLogic.is_unit (term_of ct) then NONE
    65     else SOME (mk_meta_eq @{thm unit_eq})
    66 *}
    67 
    68 rep_datatype "()" by simp
    69 
    70 lemma unit_all_eq1: "(!!x::unit. PROP P x) == PROP P ()"
    71   by simp
    72 
    73 lemma unit_all_eq2: "(!!x::unit. PROP P) == PROP P"
    74   by (rule triv_forall_equality)
    75 
    76 text {*
    77   This rewrite counters the effect of simproc @{text unit_eq} on @{term
    78   [source] "%u::unit. f u"}, replacing it by @{term [source]
    79   f} rather than by @{term [source] "%u. f ()"}.
    80 *}
    81 
    82 lemma unit_abs_eta_conv [simp, no_atp]: "(%u::unit. f ()) = f"
    83   by (rule ext) simp
    84 
    85 lemma UNIV_unit [no_atp]:
    86   "UNIV = {()}" by auto
    87 
    88 instantiation unit :: default
    89 begin
    90 
    91 definition "default = ()"
    92 
    93 instance ..
    94 
    95 end
    96 
    97 lemma [code]:
    98   "HOL.equal (u\<Colon>unit) v \<longleftrightarrow> True" unfolding equal unit_eq [of u] unit_eq [of v] by rule+
    99 
   100 code_type unit
   101   (SML "unit")
   102   (OCaml "unit")
   103   (Haskell "()")
   104   (Scala "Unit")
   105 
   106 code_const Unity
   107   (SML "()")
   108   (OCaml "()")
   109   (Haskell "()")
   110   (Scala "()")
   111 
   112 code_instance unit :: equal
   113   (Haskell -)
   114 
   115 code_const "HOL.equal \<Colon> unit \<Rightarrow> unit \<Rightarrow> bool"
   116   (Haskell infix 4 "==")
   117 
   118 code_reserved SML
   119   unit
   120 
   121 code_reserved OCaml
   122   unit
   123 
   124 code_reserved Scala
   125   Unit
   126 
   127 
   128 subsection {* The product type *}
   129 
   130 subsubsection {* Type definition *}
   131 
   132 definition Pair_Rep :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool" where
   133   "Pair_Rep a b = (\<lambda>x y. x = a \<and> y = b)"
   134 
   135 typedef ('a, 'b) prod (infixr "*" 20) = "{f. \<exists>a b. f = Pair_Rep (a\<Colon>'a) (b\<Colon>'b)}"
   136   by auto
   137 
   138 type_notation (xsymbols)
   139   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   140 type_notation (HTML output)
   141   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   142 
   143 definition Pair :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<times> 'b" where
   144   "Pair a b = Abs_prod (Pair_Rep a b)"
   145 
   146 rep_datatype Pair proof -
   147   fix P :: "'a \<times> 'b \<Rightarrow> bool" and p
   148   assume "\<And>a b. P (Pair a b)"
   149   then show "P p" by (cases p) (auto simp add: prod_def Pair_def Pair_Rep_def)
   150 next
   151   fix a c :: 'a and b d :: 'b
   152   have "Pair_Rep a b = Pair_Rep c d \<longleftrightarrow> a = c \<and> b = d"
   153     by (auto simp add: Pair_Rep_def fun_eq_iff)
   154   moreover have "Pair_Rep a b \<in> prod" and "Pair_Rep c d \<in> prod"
   155     by (auto simp add: prod_def)
   156   ultimately show "Pair a b = Pair c d \<longleftrightarrow> a = c \<and> b = d"
   157     by (simp add: Pair_def Abs_prod_inject)
   158 qed
   159 
   160 declare prod.simps(2) [nitpick_simp del]
   161 
   162 declare prod.weak_case_cong [cong del]
   163 
   164 
   165 subsubsection {* Tuple syntax *}
   166 
   167 abbreviation (input) split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   168   "split \<equiv> prod_case"
   169 
   170 text {*
   171   Patterns -- extends pre-defined type @{typ pttrn} used in
   172   abstractions.
   173 *}
   174 
   175 nonterminal tuple_args and patterns
   176 
   177 syntax
   178   "_tuple"      :: "'a => tuple_args => 'a * 'b"        ("(1'(_,/ _'))")
   179   "_tuple_arg"  :: "'a => tuple_args"                   ("_")
   180   "_tuple_args" :: "'a => tuple_args => tuple_args"     ("_,/ _")
   181   "_pattern"    :: "[pttrn, patterns] => pttrn"         ("'(_,/ _')")
   182   ""            :: "pttrn => patterns"                  ("_")
   183   "_patterns"   :: "[pttrn, patterns] => patterns"      ("_,/ _")
   184 
   185 translations
   186   "(x, y)" == "CONST Pair x y"
   187   "_tuple x (_tuple_args y z)" == "_tuple x (_tuple_arg (_tuple y z))"
   188   "%(x, y, zs). b" == "CONST prod_case (%x (y, zs). b)"
   189   "%(x, y). b" == "CONST prod_case (%x y. b)"
   190   "_abs (CONST Pair x y) t" => "%(x, y). t"
   191   -- {* The last rule accommodates tuples in `case C ... (x,y) ... => ...'
   192      The (x,y) is parsed as `Pair x y' because it is logic, not pttrn *}
   193 
   194 (*reconstruct pattern from (nested) splits, avoiding eta-contraction of body;
   195   works best with enclosing "let", if "let" does not avoid eta-contraction*)
   196 print_translation {*
   197 let
   198   fun split_tr' [Abs (x, T, t as (Abs abs))] =
   199         (* split (%x y. t) => %(x,y) t *)
   200         let
   201           val (y, t') = Syntax_Trans.atomic_abs_tr' abs;
   202           val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   203         in
   204           Syntax.const @{syntax_const "_abs"} $
   205             (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   206         end
   207     | split_tr' [Abs (x, T, (s as Const (@{const_syntax prod_case}, _) $ t))] =
   208         (* split (%x. (split (%y z. t))) => %(x,y,z). t *)
   209         let
   210           val Const (@{syntax_const "_abs"}, _) $
   211             (Const (@{syntax_const "_pattern"}, _) $ y $ z) $ t' = split_tr' [t];
   212           val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   213         in
   214           Syntax.const @{syntax_const "_abs"} $
   215             (Syntax.const @{syntax_const "_pattern"} $ x' $
   216               (Syntax.const @{syntax_const "_patterns"} $ y $ z)) $ t''
   217         end
   218     | split_tr' [Const (@{const_syntax prod_case}, _) $ t] =
   219         (* split (split (%x y z. t)) => %((x, y), z). t *)
   220         split_tr' [(split_tr' [t])] (* inner split_tr' creates next pattern *)
   221     | split_tr' [Const (@{syntax_const "_abs"}, _) $ x_y $ Abs abs] =
   222         (* split (%pttrn z. t) => %(pttrn,z). t *)
   223         let val (z, t) = Syntax_Trans.atomic_abs_tr' abs in
   224           Syntax.const @{syntax_const "_abs"} $
   225             (Syntax.const @{syntax_const "_pattern"} $ x_y $ z) $ t
   226         end
   227     | split_tr' _ = raise Match;
   228 in [(@{const_syntax prod_case}, split_tr')] end
   229 *}
   230 
   231 (* print "split f" as "\<lambda>(x,y). f x y" and "split (\<lambda>x. f x)" as "\<lambda>(x,y). f x y" *) 
   232 typed_print_translation {*
   233 let
   234   fun split_guess_names_tr' T [Abs (x, _, Abs _)] = raise Match
   235     | split_guess_names_tr' T [Abs (x, xT, t)] =
   236         (case (head_of t) of
   237           Const (@{const_syntax prod_case}, _) => raise Match
   238         | _ =>
   239           let 
   240             val (_ :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   241             val (y, t') = Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 1 t $ Bound 0);
   242             val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, xT, t');
   243           in
   244             Syntax.const @{syntax_const "_abs"} $
   245               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   246           end)
   247     | split_guess_names_tr' T [t] =
   248         (case head_of t of
   249           Const (@{const_syntax prod_case}, _) => raise Match
   250         | _ =>
   251           let
   252             val (xT :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   253             val (y, t') =
   254               Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 2 t $ Bound 1 $ Bound 0);
   255             val (x', t'') = Syntax_Trans.atomic_abs_tr' ("x", xT, t');
   256           in
   257             Syntax.const @{syntax_const "_abs"} $
   258               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   259           end)
   260     | split_guess_names_tr' _ _ = raise Match;
   261 in [(@{const_syntax prod_case}, split_guess_names_tr')] end
   262 *}
   263 
   264 (* Force eta-contraction for terms of the form "Q A (%p. prod_case P p)"
   265    where Q is some bounded quantifier or set operator.
   266    Reason: the above prints as "Q p : A. case p of (x,y) \<Rightarrow> P x y"
   267    whereas we want "Q (x,y):A. P x y".
   268    Otherwise prevent eta-contraction.
   269 *)
   270 print_translation {*
   271 let
   272   fun contract Q f ts =
   273     case ts of
   274       [A, Abs(_, _, (s as Const (@{const_syntax prod_case},_) $ t) $ Bound 0)]
   275       => if Term.is_dependent t then f ts else Syntax.const Q $ A $ s
   276     | _ => f ts;
   277   fun contract2 (Q,f) = (Q, contract Q f);
   278   val pairs =
   279     [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Ball} @{syntax_const "_Ball"},
   280      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Bex} @{syntax_const "_Bex"},
   281      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INFI} @{syntax_const "_INF"},
   282      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax SUPR} @{syntax_const "_SUP"}]
   283 in map contract2 pairs end
   284 *}
   285 
   286 subsubsection {* Code generator setup *}
   287 
   288 code_type prod
   289   (SML infix 2 "*")
   290   (OCaml infix 2 "*")
   291   (Haskell "!((_),/ (_))")
   292   (Scala "((_),/ (_))")
   293 
   294 code_const Pair
   295   (SML "!((_),/ (_))")
   296   (OCaml "!((_),/ (_))")
   297   (Haskell "!((_),/ (_))")
   298   (Scala "!((_),/ (_))")
   299 
   300 code_instance prod :: equal
   301   (Haskell -)
   302 
   303 code_const "HOL.equal \<Colon> 'a \<times> 'b \<Rightarrow> 'a \<times> 'b \<Rightarrow> bool"
   304   (Haskell infix 4 "==")
   305 
   306 
   307 subsubsection {* Fundamental operations and properties *}
   308 
   309 lemma surj_pair [simp]: "EX x y. p = (x, y)"
   310   by (cases p) simp
   311 
   312 definition fst :: "'a \<times> 'b \<Rightarrow> 'a" where
   313   "fst p = (case p of (a, b) \<Rightarrow> a)"
   314 
   315 definition snd :: "'a \<times> 'b \<Rightarrow> 'b" where
   316   "snd p = (case p of (a, b) \<Rightarrow> b)"
   317 
   318 lemma fst_conv [simp, code]: "fst (a, b) = a"
   319   unfolding fst_def by simp
   320 
   321 lemma snd_conv [simp, code]: "snd (a, b) = b"
   322   unfolding snd_def by simp
   323 
   324 code_const fst and snd
   325   (Haskell "fst" and "snd")
   326 
   327 lemma prod_case_unfold [nitpick_unfold]: "prod_case = (%c p. c (fst p) (snd p))"
   328   by (simp add: fun_eq_iff split: prod.split)
   329 
   330 lemma fst_eqD: "fst (x, y) = a ==> x = a"
   331   by simp
   332 
   333 lemma snd_eqD: "snd (x, y) = a ==> y = a"
   334   by simp
   335 
   336 lemma pair_collapse [simp]: "(fst p, snd p) = p"
   337   by (cases p) simp
   338 
   339 lemmas surjective_pairing = pair_collapse [symmetric]
   340 
   341 lemma prod_eq_iff: "s = t \<longleftrightarrow> fst s = fst t \<and> snd s = snd t"
   342   by (cases s, cases t) simp
   343 
   344 lemma prod_eqI [intro?]: "fst p = fst q \<Longrightarrow> snd p = snd q \<Longrightarrow> p = q"
   345   by (simp add: prod_eq_iff)
   346 
   347 lemma split_conv [simp, code]: "split f (a, b) = f a b"
   348   by (fact prod.cases)
   349 
   350 lemma splitI: "f a b \<Longrightarrow> split f (a, b)"
   351   by (rule split_conv [THEN iffD2])
   352 
   353 lemma splitD: "split f (a, b) \<Longrightarrow> f a b"
   354   by (rule split_conv [THEN iffD1])
   355 
   356 lemma split_Pair [simp]: "(\<lambda>(x, y). (x, y)) = id"
   357   by (simp add: fun_eq_iff split: prod.split)
   358 
   359 lemma split_eta: "(\<lambda>(x, y). f (x, y)) = f"
   360   -- {* Subsumes the old @{text split_Pair} when @{term f} is the identity function. *}
   361   by (simp add: fun_eq_iff split: prod.split)
   362 
   363 lemma split_comp: "split (f \<circ> g) x = f (g (fst x)) (snd x)"
   364   by (cases x) simp
   365 
   366 lemma split_twice: "split f (split g p) = split (\<lambda>x y. split f (g x y)) p"
   367   by (cases p) simp
   368 
   369 lemma The_split: "The (split P) = (THE xy. P (fst xy) (snd xy))"
   370   by (simp add: prod_case_unfold)
   371 
   372 lemma split_weak_cong: "p = q \<Longrightarrow> split c p = split c q"
   373   -- {* Prevents simplification of @{term c}: much faster *}
   374   by (fact prod.weak_case_cong)
   375 
   376 lemma cond_split_eta: "(!!x y. f x y = g (x, y)) ==> (%(x, y). f x y) = g"
   377   by (simp add: split_eta)
   378 
   379 lemma split_paired_all: "(!!x. PROP P x) == (!!a b. PROP P (a, b))"
   380 proof
   381   fix a b
   382   assume "!!x. PROP P x"
   383   then show "PROP P (a, b)" .
   384 next
   385   fix x
   386   assume "!!a b. PROP P (a, b)"
   387   from `PROP P (fst x, snd x)` show "PROP P x" by simp
   388 qed
   389 
   390 text {*
   391   The rule @{thm [source] split_paired_all} does not work with the
   392   Simplifier because it also affects premises in congrence rules,
   393   where this can lead to premises of the form @{text "!!a b. ... =
   394   ?P(a, b)"} which cannot be solved by reflexivity.
   395 *}
   396 
   397 lemmas split_tupled_all = split_paired_all unit_all_eq2
   398 
   399 ML {*
   400   (* replace parameters of product type by individual component parameters *)
   401   val safe_full_simp_tac = generic_simp_tac true (true, false, false);
   402   local (* filtering with exists_paired_all is an essential optimization *)
   403     fun exists_paired_all (Const ("all", _) $ Abs (_, T, t)) =
   404           can HOLogic.dest_prodT T orelse exists_paired_all t
   405       | exists_paired_all (t $ u) = exists_paired_all t orelse exists_paired_all u
   406       | exists_paired_all (Abs (_, _, t)) = exists_paired_all t
   407       | exists_paired_all _ = false;
   408     val ss = HOL_basic_ss
   409       addsimps [@{thm split_paired_all}, @{thm unit_all_eq2}, @{thm unit_abs_eta_conv}]
   410       addsimprocs [@{simproc unit_eq}];
   411   in
   412     val split_all_tac = SUBGOAL (fn (t, i) =>
   413       if exists_paired_all t then safe_full_simp_tac ss i else no_tac);
   414     val unsafe_split_all_tac = SUBGOAL (fn (t, i) =>
   415       if exists_paired_all t then full_simp_tac ss i else no_tac);
   416     fun split_all th =
   417    if exists_paired_all (Thm.prop_of th) then full_simplify ss th else th;
   418   end;
   419 *}
   420 
   421 declaration {* fn _ =>
   422   Classical.map_cs (fn cs => cs addSbefore ("split_all_tac", split_all_tac))
   423 *}
   424 
   425 lemma split_paired_All [simp]: "(ALL x. P x) = (ALL a b. P (a, b))"
   426   -- {* @{text "[iff]"} is not a good idea because it makes @{text blast} loop *}
   427   by fast
   428 
   429 lemma split_paired_Ex [simp]: "(EX x. P x) = (EX a b. P (a, b))"
   430   by fast
   431 
   432 lemma split_paired_The: "(THE x. P x) = (THE (a, b). P (a, b))"
   433   -- {* Can't be added to simpset: loops! *}
   434   by (simp add: split_eta)
   435 
   436 text {*
   437   Simplification procedure for @{thm [source] cond_split_eta}.  Using
   438   @{thm [source] split_eta} as a rewrite rule is not general enough,
   439   and using @{thm [source] cond_split_eta} directly would render some
   440   existing proofs very inefficient; similarly for @{text
   441   split_beta}.
   442 *}
   443 
   444 ML {*
   445 local
   446   val cond_split_eta_ss = HOL_basic_ss addsimps @{thms cond_split_eta};
   447   fun Pair_pat k 0 (Bound m) = (m = k)
   448     | Pair_pat k i (Const (@{const_name Pair},  _) $ Bound m $ t) =
   449         i > 0 andalso m = k + i andalso Pair_pat k (i - 1) t
   450     | Pair_pat _ _ _ = false;
   451   fun no_args k i (Abs (_, _, t)) = no_args (k + 1) i t
   452     | no_args k i (t $ u) = no_args k i t andalso no_args k i u
   453     | no_args k i (Bound m) = m < k orelse m > k + i
   454     | no_args _ _ _ = true;
   455   fun split_pat tp i (Abs  (_, _, t)) = if tp 0 i t then SOME (i, t) else NONE
   456     | split_pat tp i (Const (@{const_name prod_case}, _) $ Abs (_, _, t)) = split_pat tp (i + 1) t
   457     | split_pat tp i _ = NONE;
   458   fun metaeq ss lhs rhs = mk_meta_eq (Goal.prove (Simplifier.the_context ss) [] []
   459         (HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs, rhs)))
   460         (K (simp_tac (Simplifier.inherit_context ss cond_split_eta_ss) 1)));
   461 
   462   fun beta_term_pat k i (Abs (_, _, t)) = beta_term_pat (k + 1) i t
   463     | beta_term_pat k i (t $ u) =
   464         Pair_pat k i (t $ u) orelse (beta_term_pat k i t andalso beta_term_pat k i u)
   465     | beta_term_pat k i t = no_args k i t;
   466   fun eta_term_pat k i (f $ arg) = no_args k i f andalso Pair_pat k i arg
   467     | eta_term_pat _ _ _ = false;
   468   fun subst arg k i (Abs (x, T, t)) = Abs (x, T, subst arg (k+1) i t)
   469     | subst arg k i (t $ u) =
   470         if Pair_pat k i (t $ u) then incr_boundvars k arg
   471         else (subst arg k i t $ subst arg k i u)
   472     | subst arg k i t = t;
   473 in
   474   fun beta_proc ss (s as Const (@{const_name prod_case}, _) $ Abs (_, _, t) $ arg) =
   475         (case split_pat beta_term_pat 1 t of
   476           SOME (i, f) => SOME (metaeq ss s (subst arg 0 i f))
   477         | NONE => NONE)
   478     | beta_proc _ _ = NONE;
   479   fun eta_proc ss (s as Const (@{const_name prod_case}, _) $ Abs (_, _, t)) =
   480         (case split_pat eta_term_pat 1 t of
   481           SOME (_, ft) => SOME (metaeq ss s (let val (f $ arg) = ft in f end))
   482         | NONE => NONE)
   483     | eta_proc _ _ = NONE;
   484 end;
   485 *}
   486 simproc_setup split_beta ("split f z") = {* fn _ => fn ss => fn ct => beta_proc ss (term_of ct) *}
   487 simproc_setup split_eta ("split f") = {* fn _ => fn ss => fn ct => eta_proc ss (term_of ct) *}
   488 
   489 lemma split_beta [mono]: "(%(x, y). P x y) z = P (fst z) (snd z)"
   490   by (subst surjective_pairing, rule split_conv)
   491 
   492 lemma split_split [no_atp]: "R(split c p) = (ALL x y. p = (x, y) --> R(c x y))"
   493   -- {* For use with @{text split} and the Simplifier. *}
   494   by (insert surj_pair [of p], clarify, simp)
   495 
   496 text {*
   497   @{thm [source] split_split} could be declared as @{text "[split]"}
   498   done after the Splitter has been speeded up significantly;
   499   precompute the constants involved and don't do anything unless the
   500   current goal contains one of those constants.
   501 *}
   502 
   503 lemma split_split_asm [no_atp]: "R (split c p) = (~(EX x y. p = (x, y) & (~R (c x y))))"
   504 by (subst split_split, simp)
   505 
   506 text {*
   507   \medskip @{term split} used as a logical connective or set former.
   508 
   509   \medskip These rules are for use with @{text blast}; could instead
   510   call @{text simp} using @{thm [source] prod.split} as rewrite. *}
   511 
   512 lemma splitI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> split c p"
   513   apply (simp only: split_tupled_all)
   514   apply (simp (no_asm_simp))
   515   done
   516 
   517 lemma splitI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> split c p x"
   518   apply (simp only: split_tupled_all)
   519   apply (simp (no_asm_simp))
   520   done
   521 
   522 lemma splitE: "split c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   523   by (induct p) auto
   524 
   525 lemma splitE': "split c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   526   by (induct p) auto
   527 
   528 lemma splitE2:
   529   "[| Q (split P z);  !!x y. [|z = (x, y); Q (P x y)|] ==> R |] ==> R"
   530 proof -
   531   assume q: "Q (split P z)"
   532   assume r: "!!x y. [|z = (x, y); Q (P x y)|] ==> R"
   533   show R
   534     apply (rule r surjective_pairing)+
   535     apply (rule split_beta [THEN subst], rule q)
   536     done
   537 qed
   538 
   539 lemma splitD': "split R (a,b) c ==> R a b c"
   540   by simp
   541 
   542 lemma mem_splitI: "z: c a b ==> z: split c (a, b)"
   543   by simp
   544 
   545 lemma mem_splitI2: "!!p. [| !!a b. p = (a, b) ==> z: c a b |] ==> z: split c p"
   546 by (simp only: split_tupled_all, simp)
   547 
   548 lemma mem_splitE:
   549   assumes major: "z \<in> split c p"
   550     and cases: "\<And>x y. p = (x, y) \<Longrightarrow> z \<in> c x y \<Longrightarrow> Q"
   551   shows Q
   552   by (rule major [unfolded prod_case_unfold] cases surjective_pairing)+
   553 
   554 declare mem_splitI2 [intro!] mem_splitI [intro!] splitI2' [intro!] splitI2 [intro!] splitI [intro!]
   555 declare mem_splitE [elim!] splitE' [elim!] splitE [elim!]
   556 
   557 ML {*
   558 local (* filtering with exists_p_split is an essential optimization *)
   559   fun exists_p_split (Const (@{const_name prod_case},_) $ _ $ (Const (@{const_name Pair},_)$_$_)) = true
   560     | exists_p_split (t $ u) = exists_p_split t orelse exists_p_split u
   561     | exists_p_split (Abs (_, _, t)) = exists_p_split t
   562     | exists_p_split _ = false;
   563   val ss = HOL_basic_ss addsimps @{thms split_conv};
   564 in
   565 val split_conv_tac = SUBGOAL (fn (t, i) =>
   566     if exists_p_split t then safe_full_simp_tac ss i else no_tac);
   567 end;
   568 *}
   569 
   570 (* This prevents applications of splitE for already splitted arguments leading
   571    to quite time-consuming computations (in particular for nested tuples) *)
   572 declaration {* fn _ =>
   573   Classical.map_cs (fn cs => cs addSbefore ("split_conv_tac", split_conv_tac))
   574 *}
   575 
   576 lemma split_eta_SetCompr [simp,no_atp]: "(%u. EX x y. u = (x, y) & P (x, y)) = P"
   577   by (rule ext) fast
   578 
   579 lemma split_eta_SetCompr2 [simp,no_atp]: "(%u. EX x y. u = (x, y) & P x y) = split P"
   580   by (rule ext) fast
   581 
   582 lemma split_part [simp]: "(%(a,b). P & Q a b) = (%ab. P & split Q ab)"
   583   -- {* Allows simplifications of nested splits in case of independent predicates. *}
   584   by (rule ext) blast
   585 
   586 (* Do NOT make this a simp rule as it
   587    a) only helps in special situations
   588    b) can lead to nontermination in the presence of split_def
   589 *)
   590 lemma split_comp_eq: 
   591   fixes f :: "'a => 'b => 'c" and g :: "'d => 'a"
   592   shows "(%u. f (g (fst u)) (snd u)) = (split (%x. f (g x)))"
   593   by (rule ext) auto
   594 
   595 lemma pair_imageI [intro]: "(a, b) : A ==> f a b : (%(a, b). f a b) ` A"
   596   apply (rule_tac x = "(a, b)" in image_eqI)
   597    apply auto
   598   done
   599 
   600 lemma The_split_eq [simp]: "(THE (x',y'). x = x' & y = y') = (x, y)"
   601   by blast
   602 
   603 (*
   604 the following  would be slightly more general,
   605 but cannot be used as rewrite rule:
   606 ### Cannot add premise as rewrite rule because it contains (type) unknowns:
   607 ### ?y = .x
   608 Goal "[| P y; !!x. P x ==> x = y |] ==> (@(x',y). x = x' & P y) = (x,y)"
   609 by (rtac some_equality 1)
   610 by ( Simp_tac 1)
   611 by (split_all_tac 1)
   612 by (Asm_full_simp_tac 1)
   613 qed "The_split_eq";
   614 *)
   615 
   616 text {*
   617   Setup of internal @{text split_rule}.
   618 *}
   619 
   620 lemmas prod_caseI = prod.cases [THEN iffD2]
   621 
   622 lemma prod_caseI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> prod_case c p"
   623   by (fact splitI2)
   624 
   625 lemma prod_caseI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> prod_case c p x"
   626   by (fact splitI2')
   627 
   628 lemma prod_caseE: "prod_case c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   629   by (fact splitE)
   630 
   631 lemma prod_caseE': "prod_case c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   632   by (fact splitE')
   633 
   634 declare prod_caseI [intro!]
   635 
   636 lemma prod_case_beta:
   637   "prod_case f p = f (fst p) (snd p)"
   638   by (fact split_beta)
   639 
   640 lemma prod_cases3 [cases type]:
   641   obtains (fields) a b c where "y = (a, b, c)"
   642   by (cases y, case_tac b) blast
   643 
   644 lemma prod_induct3 [case_names fields, induct type]:
   645     "(!!a b c. P (a, b, c)) ==> P x"
   646   by (cases x) blast
   647 
   648 lemma prod_cases4 [cases type]:
   649   obtains (fields) a b c d where "y = (a, b, c, d)"
   650   by (cases y, case_tac c) blast
   651 
   652 lemma prod_induct4 [case_names fields, induct type]:
   653     "(!!a b c d. P (a, b, c, d)) ==> P x"
   654   by (cases x) blast
   655 
   656 lemma prod_cases5 [cases type]:
   657   obtains (fields) a b c d e where "y = (a, b, c, d, e)"
   658   by (cases y, case_tac d) blast
   659 
   660 lemma prod_induct5 [case_names fields, induct type]:
   661     "(!!a b c d e. P (a, b, c, d, e)) ==> P x"
   662   by (cases x) blast
   663 
   664 lemma prod_cases6 [cases type]:
   665   obtains (fields) a b c d e f where "y = (a, b, c, d, e, f)"
   666   by (cases y, case_tac e) blast
   667 
   668 lemma prod_induct6 [case_names fields, induct type]:
   669     "(!!a b c d e f. P (a, b, c, d, e, f)) ==> P x"
   670   by (cases x) blast
   671 
   672 lemma prod_cases7 [cases type]:
   673   obtains (fields) a b c d e f g where "y = (a, b, c, d, e, f, g)"
   674   by (cases y, case_tac f) blast
   675 
   676 lemma prod_induct7 [case_names fields, induct type]:
   677     "(!!a b c d e f g. P (a, b, c, d, e, f, g)) ==> P x"
   678   by (cases x) blast
   679 
   680 lemma split_def:
   681   "split = (\<lambda>c p. c (fst p) (snd p))"
   682   by (fact prod_case_unfold)
   683 
   684 definition internal_split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   685   "internal_split == split"
   686 
   687 lemma internal_split_conv: "internal_split c (a, b) = c a b"
   688   by (simp only: internal_split_def split_conv)
   689 
   690 use "Tools/split_rule.ML"
   691 setup Split_Rule.setup
   692 
   693 hide_const internal_split
   694 
   695 
   696 subsubsection {* Derived operations *}
   697 
   698 definition curry    :: "('a \<times> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'c" where
   699   "curry = (\<lambda>c x y. c (x, y))"
   700 
   701 lemma curry_conv [simp, code]: "curry f a b = f (a, b)"
   702   by (simp add: curry_def)
   703 
   704 lemma curryI [intro!]: "f (a, b) \<Longrightarrow> curry f a b"
   705   by (simp add: curry_def)
   706 
   707 lemma curryD [dest!]: "curry f a b \<Longrightarrow> f (a, b)"
   708   by (simp add: curry_def)
   709 
   710 lemma curryE: "curry f a b \<Longrightarrow> (f (a, b) \<Longrightarrow> Q) \<Longrightarrow> Q"
   711   by (simp add: curry_def)
   712 
   713 lemma curry_split [simp]: "curry (split f) = f"
   714   by (simp add: curry_def split_def)
   715 
   716 lemma split_curry [simp]: "split (curry f) = f"
   717   by (simp add: curry_def split_def)
   718 
   719 text {*
   720   The composition-uncurry combinator.
   721 *}
   722 
   723 notation fcomp (infixl "\<circ>>" 60)
   724 
   725 definition scomp :: "('a \<Rightarrow> 'b \<times> 'c) \<Rightarrow> ('b \<Rightarrow> 'c \<Rightarrow> 'd) \<Rightarrow> 'a \<Rightarrow> 'd" (infixl "\<circ>\<rightarrow>" 60) where
   726   "f \<circ>\<rightarrow> g = (\<lambda>x. prod_case g (f x))"
   727 
   728 lemma scomp_unfold: "scomp = (\<lambda>f g x. g (fst (f x)) (snd (f x)))"
   729   by (simp add: fun_eq_iff scomp_def prod_case_unfold)
   730 
   731 lemma scomp_apply [simp]: "(f \<circ>\<rightarrow> g) x = prod_case g (f x)"
   732   by (simp add: scomp_unfold prod_case_unfold)
   733 
   734 lemma Pair_scomp: "Pair x \<circ>\<rightarrow> f = f x"
   735   by (simp add: fun_eq_iff)
   736 
   737 lemma scomp_Pair: "x \<circ>\<rightarrow> Pair = x"
   738   by (simp add: fun_eq_iff)
   739 
   740 lemma scomp_scomp: "(f \<circ>\<rightarrow> g) \<circ>\<rightarrow> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>\<rightarrow> h)"
   741   by (simp add: fun_eq_iff scomp_unfold)
   742 
   743 lemma scomp_fcomp: "(f \<circ>\<rightarrow> g) \<circ>> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>> h)"
   744   by (simp add: fun_eq_iff scomp_unfold fcomp_def)
   745 
   746 lemma fcomp_scomp: "(f \<circ>> g) \<circ>\<rightarrow> h = f \<circ>> (g \<circ>\<rightarrow> h)"
   747   by (simp add: fun_eq_iff scomp_unfold)
   748 
   749 code_const scomp
   750   (Eval infixl 3 "#->")
   751 
   752 no_notation fcomp (infixl "\<circ>>" 60)
   753 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
   754 
   755 text {*
   756   @{term map_pair} --- action of the product functor upon
   757   functions.
   758 *}
   759 
   760 definition map_pair :: "('a \<Rightarrow> 'c) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'd" where
   761   "map_pair f g = (\<lambda>(x, y). (f x, g y))"
   762 
   763 lemma map_pair_simp [simp, code]:
   764   "map_pair f g (a, b) = (f a, g b)"
   765   by (simp add: map_pair_def)
   766 
   767 enriched_type map_pair: map_pair
   768   by (auto simp add: split_paired_all)
   769 
   770 lemma fst_map_pair [simp]:
   771   "fst (map_pair f g x) = f (fst x)"
   772   by (cases x) simp_all
   773 
   774 lemma snd_prod_fun [simp]:
   775   "snd (map_pair f g x) = g (snd x)"
   776   by (cases x) simp_all
   777 
   778 lemma fst_comp_map_pair [simp]:
   779   "fst \<circ> map_pair f g = f \<circ> fst"
   780   by (rule ext) simp_all
   781 
   782 lemma snd_comp_map_pair [simp]:
   783   "snd \<circ> map_pair f g = g \<circ> snd"
   784   by (rule ext) simp_all
   785 
   786 lemma map_pair_compose:
   787   "map_pair (f1 o f2) (g1 o g2) = (map_pair f1 g1 o map_pair f2 g2)"
   788   by (rule ext) (simp add: map_pair.compositionality comp_def)
   789 
   790 lemma map_pair_ident [simp]:
   791   "map_pair (%x. x) (%y. y) = (%z. z)"
   792   by (rule ext) (simp add: map_pair.identity)
   793 
   794 lemma map_pair_imageI [intro]:
   795   "(a, b) \<in> R \<Longrightarrow> (f a, g b) \<in> map_pair f g ` R"
   796   by (rule image_eqI) simp_all
   797 
   798 lemma prod_fun_imageE [elim!]:
   799   assumes major: "c \<in> map_pair f g ` R"
   800     and cases: "\<And>x y. c = (f x, g y) \<Longrightarrow> (x, y) \<in> R \<Longrightarrow> P"
   801   shows P
   802   apply (rule major [THEN imageE])
   803   apply (case_tac x)
   804   apply (rule cases)
   805   apply simp_all
   806   done
   807 
   808 definition apfst :: "('a \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'b" where
   809   "apfst f = map_pair f id"
   810 
   811 definition apsnd :: "('b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'a \<times> 'c" where
   812   "apsnd f = map_pair id f"
   813 
   814 lemma apfst_conv [simp, code]:
   815   "apfst f (x, y) = (f x, y)" 
   816   by (simp add: apfst_def)
   817 
   818 lemma apsnd_conv [simp, code]:
   819   "apsnd f (x, y) = (x, f y)" 
   820   by (simp add: apsnd_def)
   821 
   822 lemma fst_apfst [simp]:
   823   "fst (apfst f x) = f (fst x)"
   824   by (cases x) simp
   825 
   826 lemma fst_apsnd [simp]:
   827   "fst (apsnd f x) = fst x"
   828   by (cases x) simp
   829 
   830 lemma snd_apfst [simp]:
   831   "snd (apfst f x) = snd x"
   832   by (cases x) simp
   833 
   834 lemma snd_apsnd [simp]:
   835   "snd (apsnd f x) = f (snd x)"
   836   by (cases x) simp
   837 
   838 lemma apfst_compose:
   839   "apfst f (apfst g x) = apfst (f \<circ> g) x"
   840   by (cases x) simp
   841 
   842 lemma apsnd_compose:
   843   "apsnd f (apsnd g x) = apsnd (f \<circ> g) x"
   844   by (cases x) simp
   845 
   846 lemma apfst_apsnd [simp]:
   847   "apfst f (apsnd g x) = (f (fst x), g (snd x))"
   848   by (cases x) simp
   849 
   850 lemma apsnd_apfst [simp]:
   851   "apsnd f (apfst g x) = (g (fst x), f (snd x))"
   852   by (cases x) simp
   853 
   854 lemma apfst_id [simp] :
   855   "apfst id = id"
   856   by (simp add: fun_eq_iff)
   857 
   858 lemma apsnd_id [simp] :
   859   "apsnd id = id"
   860   by (simp add: fun_eq_iff)
   861 
   862 lemma apfst_eq_conv [simp]:
   863   "apfst f x = apfst g x \<longleftrightarrow> f (fst x) = g (fst x)"
   864   by (cases x) simp
   865 
   866 lemma apsnd_eq_conv [simp]:
   867   "apsnd f x = apsnd g x \<longleftrightarrow> f (snd x) = g (snd x)"
   868   by (cases x) simp
   869 
   870 lemma apsnd_apfst_commute:
   871   "apsnd f (apfst g p) = apfst g (apsnd f p)"
   872   by simp
   873 
   874 text {*
   875   Disjoint union of a family of sets -- Sigma.
   876 *}
   877 
   878 definition Sigma :: "['a set, 'a => 'b set] => ('a \<times> 'b) set" where
   879   Sigma_def: "Sigma A B == UN x:A. UN y:B x. {Pair x y}"
   880 
   881 abbreviation
   882   Times :: "['a set, 'b set] => ('a * 'b) set"
   883     (infixr "<*>" 80) where
   884   "A <*> B == Sigma A (%_. B)"
   885 
   886 notation (xsymbols)
   887   Times  (infixr "\<times>" 80)
   888 
   889 notation (HTML output)
   890   Times  (infixr "\<times>" 80)
   891 
   892 hide_const (open) Times
   893 
   894 syntax
   895   "_Sigma" :: "[pttrn, 'a set, 'b set] => ('a * 'b) set"  ("(3SIGMA _:_./ _)" [0, 0, 10] 10)
   896 translations
   897   "SIGMA x:A. B" == "CONST Sigma A (%x. B)"
   898 
   899 lemma SigmaI [intro!]: "[| a:A;  b:B(a) |] ==> (a,b) : Sigma A B"
   900   by (unfold Sigma_def) blast
   901 
   902 lemma SigmaE [elim!]:
   903     "[| c: Sigma A B;
   904         !!x y.[| x:A;  y:B(x);  c=(x,y) |] ==> P
   905      |] ==> P"
   906   -- {* The general elimination rule. *}
   907   by (unfold Sigma_def) blast
   908 
   909 text {*
   910   Elimination of @{term "(a, b) : A \<times> B"} -- introduces no
   911   eigenvariables.
   912 *}
   913 
   914 lemma SigmaD1: "(a, b) : Sigma A B ==> a : A"
   915   by blast
   916 
   917 lemma SigmaD2: "(a, b) : Sigma A B ==> b : B a"
   918   by blast
   919 
   920 lemma SigmaE2:
   921     "[| (a, b) : Sigma A B;
   922         [| a:A;  b:B(a) |] ==> P
   923      |] ==> P"
   924   by blast
   925 
   926 lemma Sigma_cong:
   927      "\<lbrakk>A = B; !!x. x \<in> B \<Longrightarrow> C x = D x\<rbrakk>
   928       \<Longrightarrow> (SIGMA x: A. C x) = (SIGMA x: B. D x)"
   929   by auto
   930 
   931 lemma Sigma_mono: "[| A <= C; !!x. x:A ==> B x <= D x |] ==> Sigma A B <= Sigma C D"
   932   by blast
   933 
   934 lemma Sigma_empty1 [simp]: "Sigma {} B = {}"
   935   by blast
   936 
   937 lemma Sigma_empty2 [simp]: "A <*> {} = {}"
   938   by blast
   939 
   940 lemma UNIV_Times_UNIV [simp]: "UNIV <*> UNIV = UNIV"
   941   by auto
   942 
   943 lemma Compl_Times_UNIV1 [simp]: "- (UNIV <*> A) = UNIV <*> (-A)"
   944   by auto
   945 
   946 lemma Compl_Times_UNIV2 [simp]: "- (A <*> UNIV) = (-A) <*> UNIV"
   947   by auto
   948 
   949 lemma mem_Sigma_iff [iff]: "((a,b): Sigma A B) = (a:A & b:B(a))"
   950   by blast
   951 
   952 lemma Times_subset_cancel2: "x:C ==> (A <*> C <= B <*> C) = (A <= B)"
   953   by blast
   954 
   955 lemma Times_eq_cancel2: "x:C ==> (A <*> C = B <*> C) = (A = B)"
   956   by (blast elim: equalityE)
   957 
   958 lemma SetCompr_Sigma_eq:
   959     "Collect (split (%x y. P x & Q x y)) = (SIGMA x:Collect P. Collect (Q x))"
   960   by blast
   961 
   962 lemma Collect_split [simp]: "{(a,b). P a & Q b} = Collect P <*> Collect Q"
   963   by blast
   964 
   965 lemma UN_Times_distrib:
   966   "(UN (a,b):(A <*> B). E a <*> F b) = (UNION A E) <*> (UNION B F)"
   967   -- {* Suggested by Pierre Chartier *}
   968   by blast
   969 
   970 lemma split_paired_Ball_Sigma [simp,no_atp]:
   971     "(ALL z: Sigma A B. P z) = (ALL x:A. ALL y: B x. P(x,y))"
   972   by blast
   973 
   974 lemma split_paired_Bex_Sigma [simp,no_atp]:
   975     "(EX z: Sigma A B. P z) = (EX x:A. EX y: B x. P(x,y))"
   976   by blast
   977 
   978 lemma Sigma_Un_distrib1: "(SIGMA i:I Un J. C(i)) = (SIGMA i:I. C(i)) Un (SIGMA j:J. C(j))"
   979   by blast
   980 
   981 lemma Sigma_Un_distrib2: "(SIGMA i:I. A(i) Un B(i)) = (SIGMA i:I. A(i)) Un (SIGMA i:I. B(i))"
   982   by blast
   983 
   984 lemma Sigma_Int_distrib1: "(SIGMA i:I Int J. C(i)) = (SIGMA i:I. C(i)) Int (SIGMA j:J. C(j))"
   985   by blast
   986 
   987 lemma Sigma_Int_distrib2: "(SIGMA i:I. A(i) Int B(i)) = (SIGMA i:I. A(i)) Int (SIGMA i:I. B(i))"
   988   by blast
   989 
   990 lemma Sigma_Diff_distrib1: "(SIGMA i:I - J. C(i)) = (SIGMA i:I. C(i)) - (SIGMA j:J. C(j))"
   991   by blast
   992 
   993 lemma Sigma_Diff_distrib2: "(SIGMA i:I. A(i) - B(i)) = (SIGMA i:I. A(i)) - (SIGMA i:I. B(i))"
   994   by blast
   995 
   996 lemma Sigma_Union: "Sigma (Union X) B = (UN A:X. Sigma A B)"
   997   by blast
   998 
   999 text {*
  1000   Non-dependent versions are needed to avoid the need for higher-order
  1001   matching, especially when the rules are re-oriented.
  1002 *}
  1003 
  1004 lemma Times_Un_distrib1: "(A Un B) <*> C = (A <*> C) Un (B <*> C)"
  1005 by blast
  1006 
  1007 lemma Times_Int_distrib1: "(A Int B) <*> C = (A <*> C) Int (B <*> C)"
  1008 by blast
  1009 
  1010 lemma Times_Diff_distrib1: "(A - B) <*> C = (A <*> C) - (B <*> C)"
  1011 by blast
  1012 
  1013 lemma Times_empty[simp]: "A \<times> B = {} \<longleftrightarrow> A = {} \<or> B = {}"
  1014   by auto
  1015 
  1016 lemma fst_image_times[simp]: "fst ` (A \<times> B) = (if B = {} then {} else A)"
  1017   by force
  1018 
  1019 lemma snd_image_times[simp]: "snd ` (A \<times> B) = (if A = {} then {} else B)"
  1020   by force
  1021 
  1022 lemma insert_times_insert[simp]:
  1023   "insert a A \<times> insert b B =
  1024    insert (a,b) (A \<times> insert b B \<union> insert a A \<times> B)"
  1025 by blast
  1026 
  1027 lemma vimage_Times: "f -` (A \<times> B) = ((fst \<circ> f) -` A) \<inter> ((snd \<circ> f) -` B)"
  1028   by (auto, case_tac "f x", auto)
  1029 
  1030 lemma swap_inj_on:
  1031   "inj_on (\<lambda>(i, j). (j, i)) A"
  1032   by (auto intro!: inj_onI)
  1033 
  1034 lemma swap_product:
  1035   "(%(i, j). (j, i)) ` (A \<times> B) = B \<times> A"
  1036   by (simp add: split_def image_def) blast
  1037 
  1038 lemma image_split_eq_Sigma:
  1039   "(\<lambda>x. (f x, g x)) ` A = Sigma (f ` A) (\<lambda>x. g ` (f -` {x} \<inter> A))"
  1040 proof (safe intro!: imageI vimageI)
  1041   fix a b assume *: "a \<in> A" "b \<in> A" and eq: "f a = f b"
  1042   show "(f b, g a) \<in> (\<lambda>x. (f x, g x)) ` A"
  1043     using * eq[symmetric] by auto
  1044 qed simp_all
  1045 
  1046 text {* The following @{const map_pair} lemmas are due to Joachim Breitner: *}
  1047 
  1048 lemma map_pair_inj_on:
  1049   assumes "inj_on f A" and "inj_on g B"
  1050   shows "inj_on (map_pair f g) (A \<times> B)"
  1051 proof (rule inj_onI)
  1052   fix x :: "'a \<times> 'c" and y :: "'a \<times> 'c"
  1053   assume "x \<in> A \<times> B" hence "fst x \<in> A" and "snd x \<in> B" by auto
  1054   assume "y \<in> A \<times> B" hence "fst y \<in> A" and "snd y \<in> B" by auto
  1055   assume "map_pair f g x = map_pair f g y"
  1056   hence "fst (map_pair f g x) = fst (map_pair f g y)" by (auto)
  1057   hence "f (fst x) = f (fst y)" by (cases x,cases y,auto)
  1058   with `inj_on f A` and `fst x \<in> A` and `fst y \<in> A`
  1059   have "fst x = fst y" by (auto dest:dest:inj_onD)
  1060   moreover from `map_pair f g x = map_pair f g y`
  1061   have "snd (map_pair f g x) = snd (map_pair f g y)" by (auto)
  1062   hence "g (snd x) = g (snd y)" by (cases x,cases y,auto)
  1063   with `inj_on g B` and `snd x \<in> B` and `snd y \<in> B`
  1064   have "snd x = snd y" by (auto dest:dest:inj_onD)
  1065   ultimately show "x = y" by(rule prod_eqI)
  1066 qed
  1067 
  1068 lemma map_pair_surj:
  1069   fixes f :: "'a \<Rightarrow> 'b" and g :: "'c \<Rightarrow> 'd"
  1070   assumes "surj f" and "surj g"
  1071   shows "surj (map_pair f g)"
  1072 unfolding surj_def
  1073 proof
  1074   fix y :: "'b \<times> 'd"
  1075   from `surj f` obtain a where "fst y = f a" by (auto elim:surjE)
  1076   moreover
  1077   from `surj g` obtain b where "snd y = g b" by (auto elim:surjE)
  1078   ultimately have "(fst y, snd y) = map_pair f g (a,b)" by auto
  1079   thus "\<exists>x. y = map_pair f g x" by auto
  1080 qed
  1081 
  1082 lemma map_pair_surj_on:
  1083   assumes "f ` A = A'" and "g ` B = B'"
  1084   shows "map_pair f g ` (A \<times> B) = A' \<times> B'"
  1085 unfolding image_def
  1086 proof(rule set_eqI,rule iffI)
  1087   fix x :: "'a \<times> 'c"
  1088   assume "x \<in> {y\<Colon>'a \<times> 'c. \<exists>x\<Colon>'b \<times> 'd\<in>A \<times> B. y = map_pair f g x}"
  1089   then obtain y where "y \<in> A \<times> B" and "x = map_pair f g y" by blast
  1090   from `image f A = A'` and `y \<in> A \<times> B` have "f (fst y) \<in> A'" by auto
  1091   moreover from `image g B = B'` and `y \<in> A \<times> B` have "g (snd y) \<in> B'" by auto
  1092   ultimately have "(f (fst y), g (snd y)) \<in> (A' \<times> B')" by auto
  1093   with `x = map_pair f g y` show "x \<in> A' \<times> B'" by (cases y, auto)
  1094 next
  1095   fix x :: "'a \<times> 'c"
  1096   assume "x \<in> A' \<times> B'" hence "fst x \<in> A'" and "snd x \<in> B'" by auto
  1097   from `image f A = A'` and `fst x \<in> A'` have "fst x \<in> image f A" by auto
  1098   then obtain a where "a \<in> A" and "fst x = f a" by (rule imageE)
  1099   moreover from `image g B = B'` and `snd x \<in> B'`
  1100   obtain b where "b \<in> B" and "snd x = g b" by auto
  1101   ultimately have "(fst x, snd x) = map_pair f g (a,b)" by auto
  1102   moreover from `a \<in> A` and  `b \<in> B` have "(a , b) \<in> A \<times> B" by auto
  1103   ultimately have "\<exists>y \<in> A \<times> B. x = map_pair f g y" by auto
  1104   thus "x \<in> {x. \<exists>y \<in> A \<times> B. x = map_pair f g y}" by auto
  1105 qed
  1106 
  1107 
  1108 subsection {* Inductively defined sets *}
  1109 
  1110 use "Tools/inductive_set.ML"
  1111 setup Inductive_Set.setup
  1112 
  1113 
  1114 subsection {* Legacy theorem bindings and duplicates *}
  1115 
  1116 lemma PairE:
  1117   obtains x y where "p = (x, y)"
  1118   by (fact prod.exhaust)
  1119 
  1120 lemma Pair_inject:
  1121   assumes "(a, b) = (a', b')"
  1122     and "a = a' ==> b = b' ==> R"
  1123   shows R
  1124   using assms by simp
  1125 
  1126 lemmas Pair_eq = prod.inject
  1127 
  1128 lemmas split = split_conv  -- {* for backwards compatibility *}
  1129 
  1130 lemmas Pair_fst_snd_eq = prod_eq_iff
  1131 
  1132 hide_const (open) prod
  1133 
  1134 end