src/HOL/SMT.thy
author boehmes
Wed Dec 15 08:39:24 2010 +0100 (2010-12-15)
changeset 41125 4a9eec045f2a
parent 41124 1de17a2de5ad
child 41126 e0bd443c0fdd
permissions -rw-r--r--
added option to enable trigger inference;
better documentation of triggers and SMT available options
     1 (*  Title:      HOL/SMT.thy
     2     Author:     Sascha Boehme, TU Muenchen
     3 *)
     4 
     5 header {* Bindings to Satisfiability Modulo Theories (SMT) solvers *}
     6 
     7 theory SMT
     8 imports List
     9 uses
    10   "Tools/Datatype/datatype_selectors.ML"
    11   "Tools/SMT/smt_utils.ML"
    12   "Tools/SMT/smt_failure.ML"
    13   "Tools/SMT/smt_config.ML"
    14   "Tools/SMT/smt_monomorph.ML"
    15   ("Tools/SMT/smt_builtin.ML")
    16   ("Tools/SMT/smt_normalize.ML")
    17   ("Tools/SMT/smt_translate.ML")
    18   ("Tools/SMT/smt_solver.ML")
    19   ("Tools/SMT/smtlib_interface.ML")
    20   ("Tools/SMT/z3_proof_parser.ML")
    21   ("Tools/SMT/z3_proof_tools.ML")
    22   ("Tools/SMT/z3_proof_literals.ML")
    23   ("Tools/SMT/z3_proof_methods.ML")
    24   ("Tools/SMT/z3_proof_reconstruction.ML")
    25   ("Tools/SMT/z3_model.ML")
    26   ("Tools/SMT/z3_interface.ML")
    27   ("Tools/SMT/smt_setup_solvers.ML")
    28 begin
    29 
    30 
    31 
    32 subsection {* Triggers for quantifier instantiation *}
    33 
    34 text {*
    35 Some SMT solvers support patterns as a quantifier instantiation
    36 heuristics.  Patterns may either be positive terms (tagged by "pat")
    37 triggering quantifier instantiations -- when the solver finds a
    38 term matching a positive pattern, it instantiates the corresponding
    39 quantifier accordingly -- or negative terms (tagged by "nopat")
    40 inhibiting quantifier instantiations.  A list of patterns
    41 of the same kind is called a multipattern, and all patterns in a
    42 multipattern are considered conjunctively for quantifier instantiation.
    43 A list of multipatterns is called a trigger, and their multipatterns
    44 act disjunctively during quantifier instantiation.  Each multipattern
    45 should mention at least all quantified variables of the preceding
    46 quantifier block.
    47 *}
    48 
    49 datatype pattern = Pattern
    50 
    51 definition pat :: "'a \<Rightarrow> pattern" where "pat _ = Pattern"
    52 definition nopat :: "'a \<Rightarrow> pattern" where "nopat _ = Pattern"
    53 
    54 definition trigger :: "pattern list list \<Rightarrow> bool \<Rightarrow> bool"
    55 where "trigger _ P = P"
    56 
    57 
    58 
    59 subsection {* Quantifier weights *}
    60 
    61 text {*
    62 Weight annotations to quantifiers influence the priority of quantifier
    63 instantiations.  They should be handled with care for solvers, which support
    64 them, because incorrect choices of weights might render a problem unsolvable.
    65 *}
    66 
    67 definition weight :: "int \<Rightarrow> bool \<Rightarrow> bool" where "weight _ P = P"
    68 
    69 text {*
    70 Weights must be non-negative.  The value @{text 0} is equivalent to providing
    71 no weight at all.
    72 
    73 Weights should only be used at quantifiers and only inside triggers (if the
    74 quantifier has triggers).  Valid usages of weights are as follows:
    75 
    76 \begin{itemize}
    77 \item
    78 @{term "\<forall>x. trigger [[pat (P x)]] (weight 2 (P x))"}
    79 \item
    80 @{term "\<forall>x. weight 3 (P x)"}
    81 \end{itemize}
    82 *}
    83 
    84 
    85 
    86 subsection {* Higher-order encoding *}
    87 
    88 text {*
    89 Application is made explicit for constants occurring with varying
    90 numbers of arguments.  This is achieved by the introduction of the
    91 following constant.
    92 *}
    93 
    94 definition fun_app where "fun_app f x = f x"
    95 
    96 text {*
    97 Some solvers support a theory of arrays which can be used to encode
    98 higher-order functions.  The following set of lemmas specifies the
    99 properties of such (extensional) arrays.
   100 *}
   101 
   102 lemmas array_rules = ext fun_upd_apply fun_upd_same fun_upd_other
   103   fun_upd_upd fun_app_def
   104 
   105 
   106 
   107 subsection {* First-order logic *}
   108 
   109 text {*
   110 Some SMT solvers only accept problems in first-order logic, i.e.,
   111 where formulas and terms are syntactically separated. When
   112 translating higher-order into first-order problems, all
   113 uninterpreted constants (those not built-in in the target solver)
   114 are treated as function symbols in the first-order sense.  Their
   115 occurrences as head symbols in atoms (i.e., as predicate symbols) are
   116 turned into terms by equating such atoms with @{term True}.
   117 Whenever the boolean type occurs in first-order terms, it is replaced
   118 by the following type.
   119 *}
   120 
   121 typedecl term_bool
   122 
   123 
   124 
   125 subsection {* Integer division and modulo for Z3 *}
   126 
   127 definition z3div :: "int \<Rightarrow> int \<Rightarrow> int" where
   128   "z3div k l = (if 0 \<le> l then k div l else -(k div (-l)))"
   129 
   130 definition z3mod :: "int \<Rightarrow> int \<Rightarrow> int" where
   131   "z3mod k l = (if 0 \<le> l then k mod l else k mod (-l))"
   132 
   133 lemma div_by_z3div: "k div l = (
   134      if k = 0 \<or> l = 0 then 0
   135      else if (0 < k \<and> 0 < l) \<or> (k < 0 \<and> 0 < l) then z3div k l
   136      else z3div (-k) (-l))"
   137   by (auto simp add: z3div_def)
   138 
   139 lemma mod_by_z3mod: "k mod l = (
   140      if l = 0 then k
   141      else if k = 0 then 0
   142      else if (0 < k \<and> 0 < l) \<or> (k < 0 \<and> 0 < l) then z3mod k l
   143      else - z3mod (-k) (-l))"
   144   by (auto simp add: z3mod_def)
   145 
   146 
   147 
   148 subsection {* Setup *}
   149 
   150 use "Tools/SMT/smt_builtin.ML"
   151 use "Tools/SMT/smt_normalize.ML"
   152 use "Tools/SMT/smt_translate.ML"
   153 use "Tools/SMT/smt_solver.ML"
   154 use "Tools/SMT/smtlib_interface.ML"
   155 use "Tools/SMT/z3_interface.ML"
   156 use "Tools/SMT/z3_proof_parser.ML"
   157 use "Tools/SMT/z3_proof_tools.ML"
   158 use "Tools/SMT/z3_proof_literals.ML"
   159 use "Tools/SMT/z3_proof_methods.ML"
   160 use "Tools/SMT/z3_proof_reconstruction.ML"
   161 use "Tools/SMT/z3_model.ML"
   162 use "Tools/SMT/smt_setup_solvers.ML"
   163 
   164 setup {*
   165   SMT_Config.setup #>
   166   SMT_Normalize.setup #>
   167   SMT_Solver.setup #>
   168   SMTLIB_Interface.setup #>
   169   Z3_Interface.setup #>
   170   Z3_Proof_Reconstruction.setup #>
   171   SMT_Setup_Solvers.setup
   172 *}
   173 
   174 
   175 
   176 subsection {* Configuration *}
   177 
   178 text {*
   179 The current configuration can be printed by the command
   180 @{text smt_status}, which shows the values of most options.
   181 *}
   182 
   183 
   184 
   185 subsection {* General configuration options *}
   186 
   187 text {*
   188 The option @{text smt_solver} can be used to change the target SMT
   189 solver.  The possible values are @{text cvc3}, @{text yices}, and
   190 @{text z3}.  It is advisable to locally install the selected solver,
   191 although this is not necessary for @{text cvc3} and @{text z3}, which
   192 can also be used over an Internet-based service.
   193 
   194 When using local SMT solvers, the path to their binaries should be
   195 declared by setting the following environment variables:
   196 @{text CVC3_SOLVER}, @{text YICES_SOLVER}, and @{text Z3_SOLVER}.
   197 *}
   198 
   199 declare [[ smt_solver = z3 ]]
   200 
   201 text {*
   202 Since SMT solvers are potentially non-terminating, there is a timeout
   203 (given in seconds) to restrict their runtime.  A value greater than
   204 120 (seconds) is in most cases not advisable.
   205 *}
   206 
   207 declare [[ smt_timeout = 20 ]]
   208 
   209 text {*
   210 SMT solvers apply randomized heuristics.  In case a problem is not
   211 solvable by an SMT solver, changing the following option might help.
   212 *}
   213 
   214 declare [[ smt_random_seed = 1 ]]
   215 
   216 text {*
   217 In general, the binding to SMT solvers runs as an oracle, i.e, the SMT
   218 solvers are fully trusted without additional checks.  The following
   219 option can cause the SMT solver to run in proof-producing mode, giving
   220 a checkable certificate.  This is currently only implemented for Z3.
   221 *}
   222 
   223 declare [[ smt_oracle = false ]]
   224 
   225 text {*
   226 Each SMT solver provides several commandline options to tweak its
   227 behaviour.  They can be passed to the solver by setting the following
   228 options.
   229 *}
   230 
   231 declare [[ cvc3_options = "", yices_options = "", z3_options = "" ]]
   232 
   233 text {*
   234 Enable the following option to use built-in support for datatypes and
   235 records.  Currently, this is only implemented for Z3 running in oracle
   236 mode.
   237 *}
   238 
   239 declare [[ smt_datatypes = false ]]
   240 
   241 text {*
   242 The SMT method provides an inference mechanism to detect simple triggers
   243 in quantified formulas, which might increase the number of problems
   244 solvable by SMT solvers (note: triggers guide quantifier instantiations
   245 in the SMT solver).  To turn it on, set the following option.
   246 *}
   247 
   248 declare [[ smt_infer_triggers = false ]]
   249 
   250 text {*
   251 The SMT method monomorphizes the given facts, that is, it tries to
   252 instantiate all schematic type variables with fixed types occurring
   253 in the problem.  This is a (possibly nonterminating) fixed-point
   254 construction whose cycles are limited by the following option.
   255 *}
   256 
   257 declare [[ smt_monomorph_limit = 10 ]]
   258 
   259 
   260 
   261 subsection {* Certificates *}
   262 
   263 text {*
   264 By setting the option @{text smt_certificates} to the name of a file,
   265 all following applications of an SMT solver a cached in that file.
   266 Any further application of the same SMT solver (using the very same
   267 configuration) re-uses the cached certificate instead of invoking the
   268 solver.  An empty string disables caching certificates.
   269 
   270 The filename should be given as an explicit path.  It is good
   271 practice to use the name of the current theory (with ending
   272 @{text ".certs"} instead of @{text ".thy"}) as the certificates file.
   273 *}
   274 
   275 declare [[ smt_certificates = "" ]]
   276 
   277 text {*
   278 The option @{text smt_fixed} controls whether only stored
   279 certificates are should be used or invocation of an SMT solver is
   280 allowed.  When set to @{text true}, no SMT solver will ever be
   281 invoked and only the existing certificates found in the configured
   282 cache are used;  when set to @{text false} and there is no cached
   283 certificate for some proposition, then the configured SMT solver is
   284 invoked.
   285 *}
   286 
   287 declare [[ smt_fixed = false ]]
   288 
   289 
   290 
   291 subsection {* Tracing *}
   292 
   293 text {*
   294 The SMT method, when applied, traces important information.  To
   295 make it entirely silent, set the following option to @{text false}.
   296 *}
   297 
   298 declare [[ smt_verbose = true ]]
   299 
   300 text {*
   301 For tracing the generated problem file given to the SMT solver as
   302 well as the returned result of the solver, the option
   303 @{text smt_trace} should be set to @{text true}.
   304 *}
   305 
   306 declare [[ smt_trace = false ]]
   307 
   308 text {*
   309 From the set of assumptions given to the SMT solver, those assumptions
   310 used in the proof are traced when the following option is set to
   311 @{term true}.  This only works for Z3 when it runs in non-oracle mode
   312 (see options @{text smt_solver} and @{text smt_oracle} above).
   313 *}
   314 
   315 declare [[ smt_trace_used_facts = false ]]
   316 
   317 
   318 
   319 subsection {* Schematic rules for Z3 proof reconstruction *}
   320 
   321 text {*
   322 Several prof rules of Z3 are not very well documented.  There are two
   323 lemma groups which can turn failing Z3 proof reconstruction attempts
   324 into succeeding ones: the facts in @{text z3_rule} are tried prior to
   325 any implemented reconstruction procedure for all uncertain Z3 proof
   326 rules;  the facts in @{text z3_simp} are only fed to invocations of
   327 the simplifier when reconstructing theory-specific proof steps.
   328 *}
   329 
   330 lemmas [z3_rule] =
   331   refl eq_commute conj_commute disj_commute simp_thms nnf_simps
   332   ring_distribs field_simps times_divide_eq_right times_divide_eq_left
   333   if_True if_False not_not
   334 
   335 lemma [z3_rule]:
   336   "(P \<longrightarrow> Q) = (Q \<or> \<not>P)"
   337   "(\<not>P \<longrightarrow> Q) = (P \<or> Q)"
   338   "(\<not>P \<longrightarrow> Q) = (Q \<or> P)"
   339   by auto
   340 
   341 lemma [z3_rule]:
   342   "((P = Q) \<longrightarrow> R) = (R | (Q = (\<not>P)))"
   343   by auto
   344 
   345 lemma [z3_rule]:
   346   "((\<not>P) = P) = False"
   347   "(P = (\<not>P)) = False"
   348   "(P \<noteq> Q) = (Q = (\<not>P))"
   349   "(P = Q) = ((\<not>P \<or> Q) \<and> (P \<or> \<not>Q))"
   350   "(P \<noteq> Q) = ((\<not>P \<or> \<not>Q) \<and> (P \<or> Q))"
   351   by auto
   352 
   353 lemma [z3_rule]:
   354   "(if P then P else \<not>P) = True"
   355   "(if \<not>P then \<not>P else P) = True"
   356   "(if P then True else False) = P"
   357   "(if P then False else True) = (\<not>P)"
   358   "(if \<not>P then x else y) = (if P then y else x)"
   359   "f (if P then x else y) = (if P then f x else f y)"
   360   by auto
   361 
   362 lemma [z3_rule]:
   363   "P = Q \<or> P \<or> Q"
   364   "P = Q \<or> \<not>P \<or> \<not>Q"
   365   "(\<not>P) = Q \<or> \<not>P \<or> Q"
   366   "(\<not>P) = Q \<or> P \<or> \<not>Q"
   367   "P = (\<not>Q) \<or> \<not>P \<or> Q"
   368   "P = (\<not>Q) \<or> P \<or> \<not>Q"
   369   "P \<noteq> Q \<or> P \<or> \<not>Q"
   370   "P \<noteq> Q \<or> \<not>P \<or> Q"
   371   "P \<noteq> (\<not>Q) \<or> P \<or> Q"
   372   "(\<not>P) \<noteq> Q \<or> P \<or> Q"
   373   "P \<or> Q \<or> P \<noteq> (\<not>Q)"
   374   "P \<or> Q \<or> (\<not>P) \<noteq> Q"
   375   "P \<or> \<not>Q \<or> P \<noteq> Q"
   376   "\<not>P \<or> Q \<or> P \<noteq> Q"
   377   by auto
   378 
   379 lemma [z3_rule]:
   380   "0 + (x::int) = x"
   381   "x + 0 = x"
   382   "0 * x = 0"
   383   "1 * x = x"
   384   "x + y = y + x"
   385   by auto
   386 
   387 
   388 
   389 hide_type term_bool
   390 hide_type (open) pattern
   391 hide_const Pattern fun_app
   392 hide_const (open) trigger pat nopat weight z3div z3mod
   393 
   394 
   395 
   396 subsection {* Selectors for datatypes *}
   397 
   398 setup {* Datatype_Selectors.setup *}
   399 
   400 declare [[ selector Pair 1 = fst, selector Pair 2 = snd ]]
   401 declare [[ selector Cons 1 = hd, selector Cons 2 = tl ]]
   402 
   403 end