author wenzelm
Wed Nov 28 15:59:18 2012 +0100 (2012-11-28)
changeset 50252 4aa34bd43228
parent 50245 dea9363887a6
child 50884 2b21b4e2d7cb
permissions -rw-r--r--
eliminated slightly odd identifiers;
     1 (*  Title:      HOL/Probability/Projective_Limit.thy
     2     Author:     Fabian Immler, TU M√ľnchen
     3 *)
     5 header {* Projective Limit *}
     7 theory Projective_Limit
     8   imports
     9     Caratheodory
    10     Fin_Map
    11     Regularity
    12     Projective_Family
    13     Infinite_Product_Measure
    14     "~~/src/HOL/Library/Countable_Set"
    15 begin
    17 subsection {* Sequences of Finite Maps in Compact Sets *}
    19 locale finmap_seqs_into_compact =
    20   fixes K::"nat \<Rightarrow> (nat \<Rightarrow>\<^isub>F 'a::metric_space) set" and f::"nat \<Rightarrow> (nat \<Rightarrow>\<^isub>F 'a)" and M
    21   assumes compact: "\<And>n. compact (K n)"
    22   assumes f_in_K: "\<And>n. K n \<noteq> {}"
    23   assumes domain_K: "\<And>n. k \<in> K n \<Longrightarrow> domain k = domain (f n)"
    24   assumes proj_in_K:
    25     "\<And>t n m. m \<ge> n \<Longrightarrow> t \<in> domain (f n) \<Longrightarrow> (f m)\<^isub>F t \<in> (\<lambda>k. (k)\<^isub>F t) ` K n"
    26 begin
    28 lemma proj_in_K': "(\<exists>n. \<forall>m \<ge> n. (f m)\<^isub>F t \<in> (\<lambda>k. (k)\<^isub>F t) ` K n)"
    29   using proj_in_K f_in_K
    30 proof cases
    31   obtain k where "k \<in> K (Suc 0)" using f_in_K by auto
    32   assume "\<forall>n. t \<notin> domain (f n)"
    33   thus ?thesis
    34     by (auto intro!: exI[where x=1] image_eqI[OF _ `k \<in> K (Suc 0)`]
    35       simp: domain_K[OF `k \<in> K (Suc 0)`])
    36 qed blast
    38 lemma proj_in_KE:
    39   obtains n where "\<And>m. m \<ge> n \<Longrightarrow> (f m)\<^isub>F t \<in> (\<lambda>k. (k)\<^isub>F t) ` K n"
    40   using proj_in_K' by blast
    42 lemma compact_projset:
    43   shows "compact ((\<lambda>k. (k)\<^isub>F i) ` K n)"
    44   using continuous_proj compact by (rule compact_continuous_image)
    46 end
    48 lemma compactE':
    49   assumes "compact S" "\<forall>n\<ge>m. f n \<in> S"
    50   obtains l r where "l \<in> S" "subseq r" "((f \<circ> r) ---> l) sequentially"
    51 proof atomize_elim
    52   have "subseq (op + m)" by (simp add: subseq_def)
    53   have "\<forall>n. (f o (\<lambda>i. m + i)) n \<in> S" using assms by auto
    54   from compactE[OF `compact S` this] guess l r .
    55   hence "l \<in> S" "subseq ((\<lambda>i. m + i) o r) \<and> (f \<circ> ((\<lambda>i. m + i) o r)) ----> l"
    56     using subseq_o[OF `subseq (op + m)` `subseq r`] by (auto simp: o_def)
    57   thus "\<exists>l r. l \<in> S \<and> subseq r \<and> (f \<circ> r) ----> l" by blast
    58 qed
    60 sublocale finmap_seqs_into_compact \<subseteq> subseqs "\<lambda>n s. (\<exists>l. (\<lambda>i. ((f o s) i)\<^isub>F n) ----> l)"
    61 proof
    62   fix n s
    63   assume "subseq s"
    64   from proj_in_KE[of n] guess n0 . note n0 = this
    65   have "\<forall>i \<ge> n0. ((f \<circ> s) i)\<^isub>F n \<in> (\<lambda>k. (k)\<^isub>F n) ` K n0"
    66   proof safe
    67     fix i assume "n0 \<le> i"
    68     also have "\<dots> \<le> s i" by (rule seq_suble) fact
    69     finally have "n0 \<le> s i" .
    70     with n0 show "((f \<circ> s) i)\<^isub>F n \<in> (\<lambda>k. (k)\<^isub>F n) ` K n0 "
    71       by auto
    72   qed
    73   from compactE'[OF compact_projset this] guess ls rs .
    74   thus "\<exists>r'. subseq r' \<and> (\<exists>l. (\<lambda>i. ((f \<circ> (s \<circ> r')) i)\<^isub>F n) ----> l)" by (auto simp: o_def)
    75 qed
    77 lemma (in finmap_seqs_into_compact) diagonal_tendsto: "\<exists>l. (\<lambda>i. (f (diagseq i))\<^isub>F n) ----> l"
    78 proof -
    79   have "\<And>i n0. (f o seqseq i) i = f (diagseq i)" unfolding diagseq_def by simp
    80   from reducer_reduces obtain l where l: "(\<lambda>i. ((f \<circ> seqseq (Suc n)) i)\<^isub>F n) ----> l"
    81     unfolding seqseq_reducer
    82   by auto
    83   have "(\<lambda>i. (f (diagseq (i + Suc n)))\<^isub>F n) =
    84     (\<lambda>i. ((f o (diagseq o (op + (Suc n)))) i)\<^isub>F n)" by (simp add: add_commute)
    85   also have "\<dots> =
    86     (\<lambda>i. ((f o ((seqseq (Suc n) o (\<lambda>x. fold_reduce (Suc n) x (Suc n + x))))) i)\<^isub>F n)"
    87     unfolding diagseq_seqseq by simp
    88   also have "\<dots> = (\<lambda>i. ((f o ((seqseq (Suc n)))) i)\<^isub>F n) o (\<lambda>x. fold_reduce (Suc n) x (Suc n + x))"
    89     by (simp add: o_def)
    90   also have "\<dots> ----> l"
    91   proof (rule LIMSEQ_subseq_LIMSEQ[OF _ subseq_diagonal_rest], rule tendstoI)
    92     fix e::real assume "0 < e"
    93     from tendstoD[OF l `0 < e`]
    94     show "eventually (\<lambda>x. dist (((f \<circ> seqseq (Suc n)) x)\<^isub>F n) l < e)
    95       sequentially" .
    96   qed
    97   finally show ?thesis by (intro exI) (rule LIMSEQ_offset)
    98 qed
   100 subsection {* Daniell-Kolmogorov Theorem *}
   102 text {* Existence of Projective Limit *}
   104 locale polish_projective = projective_family I P "\<lambda>_. borel::'a::polish_space measure"
   105   for I::"'i set" and P
   106 begin
   108 abbreviation "lim\<^isub>B \<equiv> (\<lambda>J P. limP J (\<lambda>_. borel) P)"
   110 lemma emeasure_limB_emb_not_empty:
   111   assumes "I \<noteq> {}"
   112   assumes X: "J \<noteq> {}" "J \<subseteq> I" "finite J" "\<forall>i\<in>J. B i \<in> sets borel"
   113   shows "emeasure (lim\<^isub>B I P) (emb I J (Pi\<^isub>E J B)) = emeasure (lim\<^isub>B J P) (Pi\<^isub>E J B)"
   114 proof -
   115   let ?\<Omega> = "\<Pi>\<^isub>E i\<in>I. space borel"
   116   let ?G = generator
   117   interpret G!: algebra ?\<Omega> generator by (intro  algebra_generator) fact
   118   note mu_G_mono =
   119     G.additive_increasing[OF positive_mu_G[OF `I \<noteq> {}`] additive_mu_G[OF `I \<noteq> {}`],
   120       THEN increasingD]
   121   write mu_G  ("\<mu>G")
   123   have "\<exists>\<mu>. (\<forall>s\<in>?G. \<mu> s = \<mu>G s) \<and> measure_space ?\<Omega> (sigma_sets ?\<Omega> ?G) \<mu>"
   124   proof (rule G.caratheodory_empty_continuous[OF positive_mu_G additive_mu_G,
   125       OF `I \<noteq> {}`, OF `I \<noteq> {}`])
   126     fix A assume "A \<in> ?G"
   127     with generatorE guess J X . note JX = this
   128     interpret prob_space "P J" using proj_prob_space[OF `finite J`] .
   129     show "\<mu>G A \<noteq> \<infinity>" using JX by (simp add: limP_finite)
   130   next
   131     fix Z assume Z: "range Z \<subseteq> ?G" "decseq Z" "(\<Inter>i. Z i) = {}"
   132     then have "decseq (\<lambda>i. \<mu>G (Z i))"
   133       by (auto intro!: mu_G_mono simp: decseq_def)
   134     moreover
   135     have "(INF i. \<mu>G (Z i)) = 0"
   136     proof (rule ccontr)
   137       assume "(INF i. \<mu>G (Z i)) \<noteq> 0" (is "?a \<noteq> 0")
   138       moreover have "0 \<le> ?a"
   139         using Z positive_mu_G[OF `I \<noteq> {}`] by (auto intro!: INF_greatest simp: positive_def)
   140       ultimately have "0 < ?a" by auto
   141       hence "?a \<noteq> -\<infinity>" by auto
   142       have "\<forall>n. \<exists>J B. J \<noteq> {} \<and> finite J \<and> J \<subseteq> I \<and> B \<in> sets (Pi\<^isub>M J (\<lambda>_. borel)) \<and>
   143         Z n = emb I J B \<and> \<mu>G (Z n) = emeasure (lim\<^isub>B J P) B"
   144         using Z by (intro allI generator_Ex) auto
   145       then obtain J' B' where J': "\<And>n. J' n \<noteq> {}" "\<And>n. finite (J' n)" "\<And>n. J' n \<subseteq> I"
   146           "\<And>n. B' n \<in> sets (\<Pi>\<^isub>M i\<in>J' n. borel)"
   147         and Z_emb: "\<And>n. Z n = emb I (J' n) (B' n)"
   148         unfolding choice_iff by blast
   149       moreover def J \<equiv> "\<lambda>n. (\<Union>i\<le>n. J' i)"
   150       moreover def B \<equiv> "\<lambda>n. emb (J n) (J' n) (B' n)"
   151       ultimately have J: "\<And>n. J n \<noteq> {}" "\<And>n. finite (J n)" "\<And>n. J n \<subseteq> I"
   152         "\<And>n. B n \<in> sets (\<Pi>\<^isub>M i\<in>J n. borel)"
   153         by auto
   154       have J_mono: "\<And>n m. n \<le> m \<Longrightarrow> J n \<subseteq> J m"
   155         unfolding J_def by force
   156       have "\<forall>n. \<exists>j. j \<in> J n" using J by blast
   157       then obtain j where j: "\<And>n. j n \<in> J n"
   158         unfolding choice_iff by blast
   159       note [simp] = `\<And>n. finite (J n)`
   160       from J  Z_emb have Z_eq: "\<And>n. Z n = emb I (J n) (B n)" "\<And>n. Z n \<in> ?G"
   161         unfolding J_def B_def by (subst prod_emb_trans) (insert Z, auto)
   162       interpret prob_space "P (J i)" for i using proj_prob_space by simp
   163       have "?a \<le> \<mu>G (Z 0)" by (auto intro: INF_lower)
   164       also have "\<dots> < \<infinity>" using J by (auto simp: Z_eq mu_G_eq limP_finite proj_sets)
   165       finally have "?a \<noteq> \<infinity>" by simp
   166       have "\<And>n. \<bar>\<mu>G (Z n)\<bar> \<noteq> \<infinity>" unfolding Z_eq using J J_mono
   167         by (subst mu_G_eq) (auto simp: limP_finite proj_sets mu_G_eq)
   169       have countable_UN_J: "countable (\<Union>n. J n)" by (simp add: countable_finite)
   170       def Utn \<equiv> "to_nat_on (\<Union>n. J n)"
   171       interpret function_to_finmap "J n" Utn "from_nat_into (\<Union>n. J n)" for n
   172         by unfold_locales (auto simp: Utn_def intro: from_nat_into_to_nat_on[OF countable_UN_J])
   173       have inj_on_Utn: "inj_on Utn (\<Union>n. J n)"
   174         unfolding Utn_def using countable_UN_J by (rule inj_on_to_nat_on)
   175       hence inj_on_Utn_J: "\<And>n. inj_on Utn (J n)" by (rule subset_inj_on) auto
   176       def P' \<equiv> "\<lambda>n. mapmeasure n (P (J n)) (\<lambda>_. borel)"
   177       let ?SUP = "\<lambda>n. SUP K : {K. K \<subseteq> fm n ` (B n) \<and> compact K}. emeasure (P' n) K"
   178       {
   179         fix n
   180         interpret finite_measure "P (J n)" by unfold_locales
   181         have "emeasure (P (J n)) (B n) = emeasure (P' n) (fm n ` (B n))"
   182           using J by (auto simp: P'_def mapmeasure_PiM proj_space proj_sets)
   183         also
   184         have "\<dots> = ?SUP n"
   185         proof (rule inner_regular)
   186           show "emeasure (P' n) (space (P' n)) \<noteq> \<infinity>"
   187             unfolding P'_def
   188             by (auto simp: P'_def mapmeasure_PiF fm_measurable proj_space proj_sets)
   189           show "sets (P' n) = sets borel" by (simp add: borel_eq_PiF_borel P'_def)
   190         next
   191           show "fm n ` B n \<in> sets borel"
   192             unfolding borel_eq_PiF_borel
   193             by (auto simp del: J(2) simp: P'_def fm_image_measurable_finite proj_sets J)
   194         qed
   195         finally
   196         have "emeasure (P (J n)) (B n) = ?SUP n" "?SUP n \<noteq> \<infinity>" "?SUP n \<noteq> - \<infinity>" by auto
   197       } note R = this
   198       have "\<forall>n. \<exists>K. emeasure (P (J n)) (B n) - emeasure (P' n) K \<le> 2 powr (-n) * ?a
   199         \<and> compact K \<and> K \<subseteq> fm n ` B n"
   200       proof
   201         fix n
   202         have "emeasure (P' n) (space (P' n)) \<noteq> \<infinity>"
   203           by (simp add: mapmeasure_PiF P'_def proj_space proj_sets)
   204         then interpret finite_measure "P' n" ..
   205         show "\<exists>K. emeasure (P (J n)) (B n) - emeasure (P' n) K \<le> ereal (2 powr - real n) * ?a \<and>
   206             compact K \<and> K \<subseteq> fm n ` B n"
   207           unfolding R
   208         proof (rule ccontr)
   209           assume H: "\<not> (\<exists>K'. ?SUP n - emeasure (P' n) K' \<le> ereal (2 powr - real n)  * ?a \<and>
   210             compact K' \<and> K' \<subseteq> fm n ` B n)"
   211           have "?SUP n \<le> ?SUP n - 2 powr (-n) * ?a"
   212           proof (intro SUP_least)
   213             fix K
   214             assume "K \<in> {K. K \<subseteq> fm n ` B n \<and> compact K}"
   215             with H have "\<not> ?SUP n - emeasure (P' n) K \<le> 2 powr (-n) * ?a"
   216               by auto
   217             hence "?SUP n - emeasure (P' n) K > 2 powr (-n) * ?a"
   218               unfolding not_less[symmetric] by simp
   219             hence "?SUP n - 2 powr (-n) * ?a > emeasure (P' n) K"
   220               using `0 < ?a` by (auto simp add: ereal_less_minus_iff ac_simps)
   221             thus "?SUP n - 2 powr (-n) * ?a \<ge> emeasure (P' n) K" by simp
   222           qed
   223           hence "?SUP n + 0 \<le> ?SUP n - (2 powr (-n) * ?a)" using `0 < ?a` by simp
   224           hence "?SUP n + 0 \<le> ?SUP n + - (2 powr (-n) * ?a)" unfolding minus_ereal_def .
   225           hence "0 \<le> - (2 powr (-n) * ?a)"
   226             using `?SUP _ \<noteq> \<infinity>` `?SUP _ \<noteq> - \<infinity>`
   227             by (subst (asm) ereal_add_le_add_iff) (auto simp:)
   228           moreover have "ereal (2 powr - real n) * ?a > 0" using `0 < ?a`
   229             by (auto simp: ereal_zero_less_0_iff)
   230           ultimately show False by simp
   231         qed
   232       qed
   233       then obtain K' where K':
   234         "\<And>n. emeasure (P (J n)) (B n) - emeasure (P' n) (K' n) \<le> ereal (2 powr - real n) * ?a"
   235         "\<And>n. compact (K' n)" "\<And>n. K' n \<subseteq> fm n ` B n"
   236         unfolding choice_iff by blast
   237       def K \<equiv> "\<lambda>n. fm n -` K' n \<inter> space (Pi\<^isub>M (J n) (\<lambda>_. borel))"
   238       have K_sets: "\<And>n. K n \<in> sets (Pi\<^isub>M (J n) (\<lambda>_. borel))"
   239         unfolding K_def
   240         using compact_imp_closed[OF `compact (K' _)`]
   241         by (intro measurable_sets[OF fm_measurable, of _ "Collect finite"])
   242            (auto simp: borel_eq_PiF_borel[symmetric])
   243       have K_B: "\<And>n. K n \<subseteq> B n"
   244       proof
   245         fix x n
   246         assume "x \<in> K n" hence fm_in: "fm n x \<in> fm n ` B n"
   247           using K' by (force simp: K_def)
   248         show "x \<in> B n"
   249           using `x \<in> K n` K_sets sets.sets_into_space J[of n]
   250           by (intro inj_on_image_mem_iff[OF inj_on_fm _ fm_in, of "\<lambda>_. borel"]) auto
   251       qed
   252       def Z' \<equiv> "\<lambda>n. emb I (J n) (K n)"
   253       have Z': "\<And>n. Z' n \<subseteq> Z n"
   254         unfolding Z_eq unfolding Z'_def
   255       proof (rule prod_emb_mono, safe)
   256         fix n x assume "x \<in> K n"
   257         hence "fm n x \<in> K' n" "x \<in> space (Pi\<^isub>M (J n) (\<lambda>_. borel))"
   258           by (simp_all add: K_def proj_space)
   259         note this(1)
   260         also have "K' n \<subseteq> fm n ` B n" by (simp add: K')
   261         finally have "fm n x \<in> fm n ` B n" .
   262         thus "x \<in> B n"
   263         proof safe
   264           fix y assume "y \<in> B n"
   265           moreover
   266           hence "y \<in> space (Pi\<^isub>M (J n) (\<lambda>_. borel))" using J sets.sets_into_space[of "B n" "P (J n)"]
   267             by (auto simp add: proj_space proj_sets)
   268           assume "fm n x = fm n y"
   269           note inj_onD[OF inj_on_fm[OF space_borel],
   270             OF `fm n x = fm n y` `x \<in> space _` `y \<in> space _`]
   271           ultimately show "x \<in> B n" by simp
   272         qed
   273       qed
   274       { fix n
   275         have "Z' n \<in> ?G" using K' unfolding Z'_def
   276           apply (intro generatorI'[OF J(1-3)])
   277           unfolding K_def proj_space
   278           apply (rule measurable_sets[OF fm_measurable[of _ "Collect finite"]])
   279           apply (auto simp add: P'_def borel_eq_PiF_borel[symmetric] compact_imp_closed)
   280           done
   281       }
   282       def Y \<equiv> "\<lambda>n. \<Inter>i\<in>{1..n}. Z' i"
   283       hence "\<And>n k. Y (n + k) \<subseteq> Y n" by (induct_tac k) (auto simp: Y_def)
   284       hence Y_mono: "\<And>n m. n \<le> m \<Longrightarrow> Y m \<subseteq> Y n" by (auto simp: le_iff_add)
   285       have Y_Z': "\<And>n. n \<ge> 1 \<Longrightarrow> Y n \<subseteq> Z' n" by (auto simp: Y_def)
   286       hence Y_Z: "\<And>n. n \<ge> 1 \<Longrightarrow> Y n \<subseteq> Z n" using Z' by auto
   287       have Y_notempty: "\<And>n. n \<ge> 1 \<Longrightarrow> (Y n) \<noteq> {}"
   288       proof -
   289         fix n::nat assume "n \<ge> 1" hence "Y n \<subseteq> Z n" by fact
   290         have "Y n = (\<Inter> i\<in>{1..n}. emb I (J n) (emb (J n) (J i) (K i)))" using J J_mono
   291           by (auto simp: Y_def Z'_def)
   292         also have "\<dots> = prod_emb I (\<lambda>_. borel) (J n) (\<Inter> i\<in>{1..n}. emb (J n) (J i) (K i))"
   293           using `n \<ge> 1`
   294           by (subst prod_emb_INT) auto
   295         finally
   296         have Y_emb:
   297           "Y n = prod_emb I (\<lambda>_. borel) (J n)
   298             (\<Inter> i\<in>{1..n}. prod_emb (J n) (\<lambda>_. borel) (J i) (K i))" .
   299         hence "Y n \<in> ?G" using J J_mono K_sets `n \<ge> 1` by (intro generatorI[OF _ _ _ _ Y_emb]) auto
   300         hence "\<bar>\<mu>G (Y n)\<bar> \<noteq> \<infinity>" unfolding Y_emb using J J_mono K_sets `n \<ge> 1`
   301           by (subst mu_G_eq) (auto simp: limP_finite proj_sets mu_G_eq)
   302         interpret finite_measure "(limP (J n) (\<lambda>_. borel) P)"
   303         proof
   304           have "emeasure (limP (J n) (\<lambda>_. borel) P) (J n \<rightarrow>\<^isub>E space borel) \<noteq> \<infinity>"
   305             using J by (subst emeasure_limP) auto
   306           thus  "emeasure (limP (J n) (\<lambda>_. borel) P) (space (limP (J n) (\<lambda>_. borel) P)) \<noteq> \<infinity>"
   307              by (simp add: space_PiM)
   308         qed
   309         have "\<mu>G (Z n) = limP (J n) (\<lambda>_. borel) P (B n)"
   310           unfolding Z_eq using J by (auto simp: mu_G_eq)
   311         moreover have "\<mu>G (Y n) =
   312           limP (J n) (\<lambda>_. borel) P (\<Inter>i\<in>{Suc 0..n}. prod_emb (J n) (\<lambda>_. borel) (J i) (K i))"
   313           unfolding Y_emb using J J_mono K_sets `n \<ge> 1` by (subst mu_G_eq) auto
   314         moreover have "\<mu>G (Z n - Y n) = limP (J n) (\<lambda>_. borel) P
   315           (B n - (\<Inter>i\<in>{Suc 0..n}. prod_emb (J n) (\<lambda>_. borel) (J i) (K i)))"
   316           unfolding Z_eq Y_emb prod_emb_Diff[symmetric] using J J_mono K_sets `n \<ge> 1`
   317           by (subst mu_G_eq) (auto intro!: sets.Diff)
   318         ultimately
   319         have "\<mu>G (Z n) - \<mu>G (Y n) = \<mu>G (Z n - Y n)"
   320           using J J_mono K_sets `n \<ge> 1`
   321           by (simp only: emeasure_eq_measure)
   322             (auto dest!: bspec[where x=n]
   323             simp: extensional_restrict emeasure_eq_measure prod_emb_iff
   324             intro!: measure_Diff[symmetric] set_mp[OF K_B])
   325         also have subs: "Z n - Y n \<subseteq> (\<Union> i\<in>{1..n}. (Z i - Z' i))" using Z' Z `n \<ge> 1`
   326           unfolding Y_def by (force simp: decseq_def)
   327         have "Z n - Y n \<in> ?G" "(\<Union> i\<in>{1..n}. (Z i - Z' i)) \<in> ?G"
   328           using `Z' _ \<in> ?G` `Z _ \<in> ?G` `Y _ \<in> ?G` by auto
   329         hence "\<mu>G (Z n - Y n) \<le> \<mu>G (\<Union> i\<in>{1..n}. (Z i - Z' i))"
   330           using subs G.additive_increasing[OF positive_mu_G[OF `I \<noteq> {}`] additive_mu_G[OF `I \<noteq> {}`]]
   331           unfolding increasing_def by auto
   332         also have "\<dots> \<le> (\<Sum> i\<in>{1..n}. \<mu>G (Z i - Z' i))" using `Z _ \<in> ?G` `Z' _ \<in> ?G`
   333           by (intro G.subadditive[OF positive_mu_G additive_mu_G, OF `I \<noteq> {}` `I \<noteq> {}`]) auto
   334         also have "\<dots> \<le> (\<Sum> i\<in>{1..n}. 2 powr -real i * ?a)"
   335         proof (rule setsum_mono)
   336           fix i assume "i \<in> {1..n}" hence "i \<le> n" by simp
   337           have "\<mu>G (Z i - Z' i) = \<mu>G (prod_emb I (\<lambda>_. borel) (J i) (B i - K i))"
   338             unfolding Z'_def Z_eq by simp
   339           also have "\<dots> = P (J i) (B i - K i)"
   340             apply (subst mu_G_eq) using J K_sets apply auto
   341             apply (subst limP_finite) apply auto
   342             done
   343           also have "\<dots> = P (J i) (B i) - P (J i) (K i)"
   344             apply (subst emeasure_Diff) using K_sets J `K _ \<subseteq> B _` apply (auto simp: proj_sets)
   345             done
   346           also have "\<dots> = P (J i) (B i) - P' i (K' i)"
   347             unfolding K_def P'_def
   348             by (auto simp: mapmeasure_PiF proj_space proj_sets borel_eq_PiF_borel[symmetric]
   349               compact_imp_closed[OF `compact (K' _)`] space_PiM PiE_def)
   350           also have "\<dots> \<le> ereal (2 powr - real i) * ?a" using K'(1)[of i] .
   351           finally show "\<mu>G (Z i - Z' i) \<le> (2 powr - real i) * ?a" .
   352         qed
   353         also have "\<dots> = (\<Sum> i\<in>{1..n}. ereal (2 powr -real i) * ereal(real ?a))"
   354           using `?a \<noteq> \<infinity>` `?a \<noteq> - \<infinity>` by (subst ereal_real') auto
   355         also have "\<dots> = ereal (\<Sum> i\<in>{1..n}. (2 powr -real i) * (real ?a))" by simp
   356         also have "\<dots> = ereal ((\<Sum> i\<in>{1..n}. (2 powr -real i)) * real ?a)"
   357           by (simp add: setsum_left_distrib)
   358         also have "\<dots> < ereal (1 * real ?a)" unfolding less_ereal.simps
   359         proof (rule mult_strict_right_mono)
   360           have "(\<Sum>i\<in>{1..n}. 2 powr - real i) = (\<Sum>i\<in>{1..<Suc n}. (1/2) ^ i)"
   361             by (rule setsum_cong)
   362                (auto simp: powr_realpow[symmetric] powr_minus powr_divide inverse_eq_divide)
   363           also have "{1..<Suc n} = {0..<Suc n} - {0}" by auto
   364           also have "setsum (op ^ (1 / 2::real)) ({0..<Suc n} - {0}) =
   365             setsum (op ^ (1 / 2)) ({0..<Suc n}) - 1" by (auto simp: setsum_diff1)
   366           also have "\<dots> < 1" by (subst sumr_geometric) auto
   367           finally show "(\<Sum>i = 1..n. 2 powr - real i) < 1" .
   368         qed (auto simp:
   369           `0 < ?a` `?a \<noteq> \<infinity>` `?a \<noteq> - \<infinity>` ereal_less_real_iff zero_ereal_def[symmetric])
   370         also have "\<dots> = ?a" using `0 < ?a` `?a \<noteq> \<infinity>` by (auto simp: ereal_real')
   371         also have "\<dots> \<le> \<mu>G (Z n)" by (auto intro: INF_lower)
   372         finally have "\<mu>G (Z n) - \<mu>G (Y n) < \<mu>G (Z n)" .
   373         hence R: "\<mu>G (Z n) < \<mu>G (Z n) + \<mu>G (Y n)"
   374           using `\<bar>\<mu>G (Y n)\<bar> \<noteq> \<infinity>` by (simp add: ereal_minus_less)
   375         have "0 \<le> (- \<mu>G (Z n)) + \<mu>G (Z n)" using `\<bar>\<mu>G (Z n)\<bar> \<noteq> \<infinity>` by auto
   376         also have "\<dots> < (- \<mu>G (Z n)) + (\<mu>G (Z n) + \<mu>G (Y n))"
   377           apply (rule ereal_less_add[OF _ R]) using `\<bar>\<mu>G (Z n)\<bar> \<noteq> \<infinity>` by auto
   378         finally have "\<mu>G (Y n) > 0"
   379           using `\<bar>\<mu>G (Z n)\<bar> \<noteq> \<infinity>` by (auto simp: ac_simps zero_ereal_def[symmetric])
   380         thus "Y n \<noteq> {}" using positive_mu_G `I \<noteq> {}` by (auto simp add: positive_def)
   381       qed
   382       hence "\<forall>n\<in>{1..}. \<exists>y. y \<in> Y n" by auto
   383       then obtain y where y: "\<And>n. n \<ge> 1 \<Longrightarrow> y n \<in> Y n" unfolding bchoice_iff by force
   384       {
   385         fix t and n m::nat
   386         assume "1 \<le> n" "n \<le> m" hence "1 \<le> m" by simp
   387         from Y_mono[OF `m \<ge> n`] y[OF `1 \<le> m`] have "y m \<in> Y n" by auto
   388         also have "\<dots> \<subseteq> Z' n" using Y_Z'[OF `1 \<le> n`] .
   389         finally
   390         have "fm n (restrict (y m) (J n)) \<in> K' n"
   391           unfolding Z'_def K_def prod_emb_iff by (simp add: Z'_def K_def prod_emb_iff)
   392         moreover have "finmap_of (J n) (restrict (y m) (J n)) = finmap_of (J n) (y m)"
   393           using J by (simp add: fm_def)
   394         ultimately have "fm n (y m) \<in> K' n" by simp
   395       } note fm_in_K' = this
   396       interpret finmap_seqs_into_compact "\<lambda>n. K' (Suc n)" "\<lambda>k. fm (Suc k) (y (Suc k))" borel
   397       proof
   398         fix n show "compact (K' n)" by fact
   399       next
   400         fix n
   401         from Y_mono[of n "Suc n"] y[of "Suc n"] have "y (Suc n) \<in> Y (Suc n)" by auto
   402         also have "\<dots> \<subseteq> Z' (Suc n)" using Y_Z' by auto
   403         finally
   404         have "fm (Suc n) (restrict (y (Suc n)) (J (Suc n))) \<in> K' (Suc n)"
   405           unfolding Z'_def K_def prod_emb_iff by (simp add: Z'_def K_def prod_emb_iff)
   406         thus "K' (Suc n) \<noteq> {}" by auto
   407         fix k
   408         assume "k \<in> K' (Suc n)"
   409         with K'[of "Suc n"] sets.sets_into_space have "k \<in> fm (Suc n) ` B (Suc n)" by auto
   410         then obtain b where "k = fm (Suc n) b" by auto
   411         thus "domain k = domain (fm (Suc n) (y (Suc n)))"
   412           by (simp_all add: fm_def)
   413       next
   414         fix t and n m::nat
   415         assume "n \<le> m" hence "Suc n \<le> Suc m" by simp
   416         assume "t \<in> domain (fm (Suc n) (y (Suc n)))"
   417         then obtain j where j: "t = Utn j" "j \<in> J (Suc n)" by auto
   418         hence "j \<in> J (Suc m)" using J_mono[OF `Suc n \<le> Suc m`] by auto
   419         have img: "fm (Suc n) (y (Suc m)) \<in> K' (Suc n)" using `n \<le> m`
   420           by (intro fm_in_K') simp_all
   421         show "(fm (Suc m) (y (Suc m)))\<^isub>F t \<in> (\<lambda>k. (k)\<^isub>F t) ` K' (Suc n)"
   422           apply (rule image_eqI[OF _ img])
   423           using `j \<in> J (Suc n)` `j \<in> J (Suc m)`
   424           unfolding j by (subst proj_fm, auto)+
   425       qed
   426       have "\<forall>t. \<exists>z. (\<lambda>i. (fm (Suc (diagseq i)) (y (Suc (diagseq i))))\<^isub>F t) ----> z"
   427         using diagonal_tendsto ..
   428       then obtain z where z:
   429         "\<And>t. (\<lambda>i. (fm (Suc (diagseq i)) (y (Suc (diagseq i))))\<^isub>F t) ----> z t"
   430         unfolding choice_iff by blast
   431       {
   432         fix n :: nat assume "n \<ge> 1"
   433         have "\<And>i. domain (fm n (y (Suc (diagseq i)))) = domain (finmap_of (Utn ` J n) z)"
   434           by simp
   435         moreover
   436         {
   437           fix t
   438           assume t: "t \<in> domain (finmap_of (Utn ` J n) z)"
   439           hence "t \<in> Utn ` J n" by simp
   440           then obtain j where j: "t = Utn j" "j \<in> J n" by auto
   441           have "(\<lambda>i. (fm n (y (Suc (diagseq i))))\<^isub>F t) ----> z t"
   442             apply (subst (2) tendsto_iff, subst eventually_sequentially)
   443           proof safe
   444             fix e :: real assume "0 < e"
   445             { fix i x assume "i \<ge> n" "t \<in> domain (fm n x)"
   446               moreover
   447               hence "t \<in> domain (fm i x)" using J_mono[OF `i \<ge> n`] by auto
   448               ultimately have "(fm i x)\<^isub>F t = (fm n x)\<^isub>F t"
   449                 using j by (auto simp: proj_fm dest!: inj_onD[OF inj_on_Utn])
   450             } note index_shift = this
   451             have I: "\<And>i. i \<ge> n \<Longrightarrow> Suc (diagseq i) \<ge> n"
   452               apply (rule le_SucI)
   453               apply (rule order_trans) apply simp
   454               apply (rule seq_suble[OF subseq_diagseq])
   455               done
   456             from z
   457             have "\<exists>N. \<forall>i\<ge>N. dist ((fm (Suc (diagseq i)) (y (Suc (diagseq i))))\<^isub>F t) (z t) < e"
   458               unfolding tendsto_iff eventually_sequentially using `0 < e` by auto
   459             then obtain N where N: "\<And>i. i \<ge> N \<Longrightarrow>
   460               dist ((fm (Suc (diagseq i)) (y (Suc (diagseq i))))\<^isub>F t) (z t) < e" by auto
   461             show "\<exists>N. \<forall>na\<ge>N. dist ((fm n (y (Suc (diagseq na))))\<^isub>F t) (z t) < e "
   462             proof (rule exI[where x="max N n"], safe)
   463               fix na assume "max N n \<le> na"
   464               hence  "dist ((fm n (y (Suc (diagseq na))))\<^isub>F t) (z t) =
   465                       dist ((fm (Suc (diagseq na)) (y (Suc (diagseq na))))\<^isub>F t) (z t)" using t
   466                 by (subst index_shift[OF I]) auto
   467               also have "\<dots> < e" using `max N n \<le> na` by (intro N) simp
   468               finally show "dist ((fm n (y (Suc (diagseq na))))\<^isub>F t) (z t) < e" .
   469             qed
   470           qed
   471           hence "(\<lambda>i. (fm n (y (Suc (diagseq i))))\<^isub>F t) ----> (finmap_of (Utn ` J n) z)\<^isub>F t"
   472             by (simp add: tendsto_intros)
   473         } ultimately
   474         have "(\<lambda>i. fm n (y (Suc (diagseq i)))) ----> finmap_of (Utn ` J n) z"
   475           by (rule tendsto_finmap)
   476         hence "((\<lambda>i. fm n (y (Suc (diagseq i)))) o (\<lambda>i. i + n)) ----> finmap_of (Utn ` J n) z"
   477           by (intro lim_subseq) (simp add: subseq_def)
   478         moreover
   479         have "(\<forall>i. ((\<lambda>i. fm n (y (Suc (diagseq i)))) o (\<lambda>i. i + n)) i \<in> K' n)"
   480           apply (auto simp add: o_def intro!: fm_in_K' `1 \<le> n` le_SucI)
   481           apply (rule le_trans)
   482           apply (rule le_add2)
   483           using seq_suble[OF subseq_diagseq]
   484           apply auto
   485           done
   486         moreover
   487         from `compact (K' n)` have "closed (K' n)" by (rule compact_imp_closed)
   488         ultimately
   489         have "finmap_of (Utn ` J n) z \<in> K' n"
   490           unfolding closed_sequential_limits by blast
   491         also have "finmap_of (Utn ` J n) z  = fm n (\<lambda>i. z (Utn i))"
   492           unfolding finmap_eq_iff
   493         proof clarsimp
   494           fix i assume "i \<in> J n"
   495           moreover hence "from_nat_into (\<Union>n. J n) (Utn i) = i"
   496             unfolding Utn_def
   497             by (subst from_nat_into_to_nat_on[OF countable_UN_J]) auto
   498           ultimately show "z (Utn i) = (fm n (\<lambda>i. z (Utn i)))\<^isub>F (Utn i)"
   499             by (simp add: finmap_eq_iff fm_def compose_def)
   500         qed
   501         finally have "fm n (\<lambda>i. z (Utn i)) \<in> K' n" .
   502         moreover
   503         let ?J = "\<Union>n. J n"
   504         have "(?J \<inter> J n) = J n" by auto
   505         ultimately have "restrict (\<lambda>i. z (Utn i)) (?J \<inter> J n) \<in> K n"
   506           unfolding K_def by (auto simp: proj_space space_PiM)
   507         hence "restrict (\<lambda>i. z (Utn i)) ?J \<in> Z' n" unfolding Z'_def
   508           using J by (auto simp: prod_emb_def PiE_def extensional_def)
   509         also have "\<dots> \<subseteq> Z n" using Z' by simp
   510         finally have "restrict (\<lambda>i. z (Utn i)) ?J \<in> Z n" .
   511       } note in_Z = this
   512       hence "(\<Inter>i\<in>{1..}. Z i) \<noteq> {}" by auto
   513       hence "(\<Inter>i. Z i) \<noteq> {}" using Z INT_decseq_offset[OF `decseq Z`] by simp
   514       thus False using Z by simp
   515     qed
   516     ultimately show "(\<lambda>i. \<mu>G (Z i)) ----> 0"
   517       using LIMSEQ_ereal_INFI[of "\<lambda>i. \<mu>G (Z i)"] by simp
   518   qed
   519   then guess \<mu> .. note \<mu> = this
   520   def f \<equiv> "finmap_of J B"
   521   show "emeasure (lim\<^isub>B I P) (emb I J (Pi\<^isub>E J B)) = emeasure (lim\<^isub>B J P) (Pi\<^isub>E J B)"
   522   proof (subst emeasure_extend_measure_Pair[OF limP_def, of I "\<lambda>_. borel" \<mu>])
   523     show "positive (sets (lim\<^isub>B I P)) \<mu>" "countably_additive (sets (lim\<^isub>B I P)) \<mu>"
   524       using \<mu> unfolding sets_limP sets_PiM_generator by (auto simp: measure_space_def)
   525   next
   526     show "(J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> B \<in> J \<rightarrow> sets borel"
   527       using assms by (auto simp: f_def)
   528   next
   529     fix J and X::"'i \<Rightarrow> 'a set"
   530     show "prod_emb I (\<lambda>_. borel) J (Pi\<^isub>E J X) \<in> Pow (I \<rightarrow>\<^isub>E space borel)"
   531       by (auto simp: prod_emb_def)
   532     assume JX: "(J \<noteq> {} \<or> I = {}) \<and> finite J \<and> J \<subseteq> I \<and> X \<in> J \<rightarrow> sets borel"
   533     hence "emb I J (Pi\<^isub>E J X) \<in> generator" using assms
   534       by (intro generatorI[where J=J and X="Pi\<^isub>E J X"]) (auto intro: sets_PiM_I_finite)
   535     hence "\<mu> (emb I J (Pi\<^isub>E J X)) = \<mu>G (emb I J (Pi\<^isub>E J X))" using \<mu> by simp
   536     also have "\<dots> = emeasure (P J) (Pi\<^isub>E J X)"
   537       using JX assms proj_sets
   538       by (subst mu_G_eq) (auto simp: mu_G_eq limP_finite intro: sets_PiM_I_finite)
   539     finally show "\<mu> (emb I J (Pi\<^isub>E J X)) = emeasure (P J) (Pi\<^isub>E J X)" .
   540   next
   541     show "emeasure (P J) (Pi\<^isub>E J B) = emeasure (limP J (\<lambda>_. borel) P) (Pi\<^isub>E J B)"
   542       using assms by (simp add: f_def limP_finite Pi_def)
   543   qed
   544 qed
   546 end
   548 hide_const (open) PiF
   549 hide_const (open) Pi\<^isub>F
   550 hide_const (open) Pi'
   551 hide_const (open) Abs_finmap
   552 hide_const (open) Rep_finmap
   553 hide_const (open) finmap_of
   554 hide_const (open) proj
   555 hide_const (open) domain
   556 hide_const (open) basis_finmap
   558 sublocale polish_projective \<subseteq> P!: prob_space "(lim\<^isub>B I P)"
   559 proof
   560   show "emeasure (lim\<^isub>B I P) (space (lim\<^isub>B I P)) = 1"
   561   proof cases
   562     assume "I = {}"
   563     interpret prob_space "P {}" using proj_prob_space by simp
   564     show ?thesis
   565       by (simp add: space_PiM_empty limP_finite emeasure_space_1 `I = {}`)
   566   next
   567     assume "I \<noteq> {}"
   568     then obtain i where "i \<in> I" by auto
   569     interpret prob_space "P {i}" using proj_prob_space by simp
   570     have R: "(space (lim\<^isub>B I P)) = (emb I {i} (Pi\<^isub>E {i} (\<lambda>_. space borel)))"
   571       by (auto simp: prod_emb_def space_PiM)
   572     moreover have "extensional {i} = space (P {i})" by (simp add: proj_space space_PiM PiE_def)
   573     ultimately show ?thesis using `i \<in> I`
   574       apply (subst R)
   575       apply (subst emeasure_limB_emb_not_empty)
   576       apply (auto simp: limP_finite emeasure_space_1 PiE_def)
   577       done
   578   qed
   579 qed
   581 context polish_projective begin
   583 lemma emeasure_limB_emb:
   584   assumes X: "J \<subseteq> I" "finite J" "\<forall>i\<in>J. B i \<in> sets borel"
   585   shows "emeasure (lim\<^isub>B I P) (emb I J (Pi\<^isub>E J B)) = emeasure (P J) (Pi\<^isub>E J B)"
   586 proof cases
   587   interpret prob_space "P {}" using proj_prob_space by simp
   588   assume "J = {}"
   589   moreover have "emb I {} {\<lambda>x. undefined} = space (lim\<^isub>B I P)"
   590     by (auto simp: space_PiM prod_emb_def)
   591   moreover have "{\<lambda>x. undefined} = space (lim\<^isub>B {} P)"
   592     by (auto simp: space_PiM prod_emb_def)
   593   ultimately show ?thesis
   594     by (simp add: P.emeasure_space_1 limP_finite emeasure_space_1 del: space_limP)
   595 next
   596   assume "J \<noteq> {}" with X show ?thesis
   597     by (subst emeasure_limB_emb_not_empty) (auto simp: limP_finite)
   598 qed
   600 lemma measure_limB_emb:
   601   assumes "J \<subseteq> I" "finite J" "\<forall>i\<in>J. B i \<in> sets borel"
   602   shows "measure (lim\<^isub>B I P) (emb I J (Pi\<^isub>E J B)) = measure (P J) (Pi\<^isub>E J B)"
   603 proof -
   604   interpret prob_space "P J" using proj_prob_space assms by simp
   605   show ?thesis
   606     using emeasure_limB_emb[OF assms]
   607     unfolding emeasure_eq_measure limP_finite[OF `finite J` `J \<subseteq> I`] P.emeasure_eq_measure
   608     by simp
   609 qed
   611 end
   613 locale polish_product_prob_space =
   614   product_prob_space "\<lambda>_. borel::('a::polish_space) measure" I for I::"'i set"
   616 sublocale polish_product_prob_space \<subseteq> P: polish_projective I "\<lambda>J. PiM J (\<lambda>_. borel::('a) measure)"
   617 proof qed
   619 lemma (in polish_product_prob_space) limP_eq_PiM:
   620   "I \<noteq> {} \<Longrightarrow> lim\<^isub>P I (\<lambda>_. borel) (\<lambda>J. PiM J (\<lambda>_. borel::('a) measure)) =
   621     PiM I (\<lambda>_. borel)"
   622   by (rule PiM_eq) (auto simp: emeasure_PiM emeasure_limB_emb)
   624 end