src/HOL/Analysis/Extended_Real_Limits.thy
author nipkow
Sat Dec 29 15:43:53 2018 +0100 (6 months ago)
changeset 69529 4ab9657b3257
parent 69517 dc20f278e8f3
child 69566 c41954ee87cf
permissions -rw-r--r--
capitalize proper names in lemma names
     1 (*  Title:      HOL/Analysis/Extended_Real_Limits.thy
     2     Author:     Johannes Hölzl, TU München
     3     Author:     Robert Himmelmann, TU München
     4     Author:     Armin Heller, TU München
     5     Author:     Bogdan Grechuk, University of Edinburgh
     6 *)
     7 
     8 section%important \<open>Limits on the Extended Real Number Line\<close> (* TO FIX: perhaps put all Nonstandard Analysis related
     9 topics together? *)
    10 
    11 theory Extended_Real_Limits
    12 imports
    13   Topology_Euclidean_Space
    14   "HOL-Library.Extended_Real"
    15   "HOL-Library.Extended_Nonnegative_Real"
    16   "HOL-Library.Indicator_Function"
    17 begin
    18 
    19 lemma%important compact_UNIV:
    20   "compact (UNIV :: 'a::{complete_linorder,linorder_topology,second_countable_topology} set)"
    21   using%unimportant compact_complete_linorder
    22   by (auto simp: seq_compact_eq_compact[symmetric] seq_compact_def)
    23 
    24 lemma%important compact_eq_closed:
    25   fixes S :: "'a::{complete_linorder,linorder_topology,second_countable_topology} set"
    26   shows "compact S \<longleftrightarrow> closed S"
    27   using%unimportant closed_Int_compact[of S, OF _ compact_UNIV] compact_imp_closed
    28   by auto
    29 
    30 lemma%important closed_contains_Sup_cl:
    31   fixes S :: "'a::{complete_linorder,linorder_topology,second_countable_topology} set"
    32   assumes "closed S"
    33     and "S \<noteq> {}"
    34   shows "Sup S \<in> S"
    35 proof%unimportant -
    36   from compact_eq_closed[of S] compact_attains_sup[of S] assms
    37   obtain s where S: "s \<in> S" "\<forall>t\<in>S. t \<le> s"
    38     by auto
    39   then have "Sup S = s"
    40     by (auto intro!: Sup_eqI)
    41   with S show ?thesis
    42     by simp
    43 qed
    44 
    45 lemma%important closed_contains_Inf_cl:
    46   fixes S :: "'a::{complete_linorder,linorder_topology,second_countable_topology} set"
    47   assumes "closed S"
    48     and "S \<noteq> {}"
    49   shows "Inf S \<in> S"
    50 proof%unimportant -
    51   from compact_eq_closed[of S] compact_attains_inf[of S] assms
    52   obtain s where S: "s \<in> S" "\<forall>t\<in>S. s \<le> t"
    53     by auto
    54   then have "Inf S = s"
    55     by (auto intro!: Inf_eqI)
    56   with S show ?thesis
    57     by simp
    58 qed
    59 
    60 instance enat :: second_countable_topology
    61 proof
    62   show "\<exists>B::enat set set. countable B \<and> open = generate_topology B"
    63   proof (intro exI conjI)
    64     show "countable (range lessThan \<union> range greaterThan::enat set set)"
    65       by auto
    66   qed (simp add: open_enat_def)
    67 qed
    68 
    69 instance%important ereal :: second_countable_topology
    70 proof%unimportant (standard, intro exI conjI)
    71   let ?B = "(\<Union>r\<in>\<rat>. {{..< r}, {r <..}} :: ereal set set)"
    72   show "countable ?B"
    73     by (auto intro: countable_rat)
    74   show "open = generate_topology ?B"
    75   proof (intro ext iffI)
    76     fix S :: "ereal set"
    77     assume "open S"
    78     then show "generate_topology ?B S"
    79       unfolding open_generated_order
    80     proof induct
    81       case (Basis b)
    82       then obtain e where "b = {..<e} \<or> b = {e<..}"
    83         by auto
    84       moreover have "{..<e} = \<Union>{{..<x}|x. x \<in> \<rat> \<and> x < e}" "{e<..} = \<Union>{{x<..}|x. x \<in> \<rat> \<and> e < x}"
    85         by (auto dest: ereal_dense3
    86                  simp del: ex_simps
    87                  simp add: ex_simps[symmetric] conj_commute Rats_def image_iff)
    88       ultimately show ?case
    89         by (auto intro: generate_topology.intros)
    90     qed (auto intro: generate_topology.intros)
    91   next
    92     fix S
    93     assume "generate_topology ?B S"
    94     then show "open S"
    95       by induct auto
    96   qed
    97 qed
    98 
    99 text \<open>This is a copy from \<open>ereal :: second_countable_topology\<close>. Maybe find a common super class of
   100 topological spaces where the rational numbers are densely embedded ?\<close>
   101 instance%important ennreal :: second_countable_topology
   102 proof%unimportant (standard, intro exI conjI)
   103   let ?B = "(\<Union>r\<in>\<rat>. {{..< r}, {r <..}} :: ennreal set set)"
   104   show "countable ?B"
   105     by (auto intro: countable_rat)
   106   show "open = generate_topology ?B"
   107   proof (intro ext iffI)
   108     fix S :: "ennreal set"
   109     assume "open S"
   110     then show "generate_topology ?B S"
   111       unfolding open_generated_order
   112     proof induct
   113       case (Basis b)
   114       then obtain e where "b = {..<e} \<or> b = {e<..}"
   115         by auto
   116       moreover have "{..<e} = \<Union>{{..<x}|x. x \<in> \<rat> \<and> x < e}" "{e<..} = \<Union>{{x<..}|x. x \<in> \<rat> \<and> e < x}"
   117         by (auto dest: ennreal_rat_dense
   118                  simp del: ex_simps
   119                  simp add: ex_simps[symmetric] conj_commute Rats_def image_iff)
   120       ultimately show ?case
   121         by (auto intro: generate_topology.intros)
   122     qed (auto intro: generate_topology.intros)
   123   next
   124     fix S
   125     assume "generate_topology ?B S"
   126     then show "open S"
   127       by induct auto
   128   qed
   129 qed
   130 
   131 lemma%important ereal_open_closed_aux:
   132   fixes S :: "ereal set"
   133   assumes "open S"
   134     and "closed S"
   135     and S: "(-\<infinity>) \<notin> S"
   136   shows "S = {}"
   137 proof%unimportant (rule ccontr)
   138   assume "\<not> ?thesis"
   139   then have *: "Inf S \<in> S"
   140 
   141     by (metis assms(2) closed_contains_Inf_cl)
   142   {
   143     assume "Inf S = -\<infinity>"
   144     then have False
   145       using * assms(3) by auto
   146   }
   147   moreover
   148   {
   149     assume "Inf S = \<infinity>"
   150     then have "S = {\<infinity>}"
   151       by (metis Inf_eq_PInfty \<open>S \<noteq> {}\<close>)
   152     then have False
   153       by (metis assms(1) not_open_singleton)
   154   }
   155   moreover
   156   {
   157     assume fin: "\<bar>Inf S\<bar> \<noteq> \<infinity>"
   158     from ereal_open_cont_interval[OF assms(1) * fin]
   159     obtain e where e: "e > 0" "{Inf S - e<..<Inf S + e} \<subseteq> S" .
   160     then obtain b where b: "Inf S - e < b" "b < Inf S"
   161       using fin ereal_between[of "Inf S" e] dense[of "Inf S - e"]
   162       by auto
   163     then have "b \<in> {Inf S - e <..< Inf S + e}"
   164       using e fin ereal_between[of "Inf S" e]
   165       by auto
   166     then have "b \<in> S"
   167       using e by auto
   168     then have False
   169       using b by (metis complete_lattice_class.Inf_lower leD)
   170   }
   171   ultimately show False
   172     by auto
   173 qed
   174 
   175 lemma%important ereal_open_closed:
   176   fixes S :: "ereal set"
   177   shows "open S \<and> closed S \<longleftrightarrow> S = {} \<or> S = UNIV"
   178 proof%unimportant -
   179   {
   180     assume lhs: "open S \<and> closed S"
   181     {
   182       assume "-\<infinity> \<notin> S"
   183       then have "S = {}"
   184         using lhs ereal_open_closed_aux by auto
   185     }
   186     moreover
   187     {
   188       assume "-\<infinity> \<in> S"
   189       then have "- S = {}"
   190         using lhs ereal_open_closed_aux[of "-S"] by auto
   191     }
   192     ultimately have "S = {} \<or> S = UNIV"
   193       by auto
   194   }
   195   then show ?thesis
   196     by auto
   197 qed
   198 
   199 lemma%important ereal_open_atLeast:
   200   fixes x :: ereal
   201   shows "open {x..} \<longleftrightarrow> x = -\<infinity>"
   202 proof%unimportant
   203   assume "x = -\<infinity>"
   204   then have "{x..} = UNIV"
   205     by auto
   206   then show "open {x..}"
   207     by auto
   208 next
   209   assume "open {x..}"
   210   then have "open {x..} \<and> closed {x..}"
   211     by auto
   212   then have "{x..} = UNIV"
   213     unfolding ereal_open_closed by auto
   214   then show "x = -\<infinity>"
   215     by (simp add: bot_ereal_def atLeast_eq_UNIV_iff)
   216 qed
   217 
   218 lemma%important mono_closed_real:
   219   fixes S :: "real set"
   220   assumes mono: "\<forall>y z. y \<in> S \<and> y \<le> z \<longrightarrow> z \<in> S"
   221     and "closed S"
   222   shows "S = {} \<or> S = UNIV \<or> (\<exists>a. S = {a..})"
   223 proof%unimportant -
   224   {
   225     assume "S \<noteq> {}"
   226     { assume ex: "\<exists>B. \<forall>x\<in>S. B \<le> x"
   227       then have *: "\<forall>x\<in>S. Inf S \<le> x"
   228         using cInf_lower[of _ S] ex by (metis bdd_below_def)
   229       then have "Inf S \<in> S"
   230         apply (subst closed_contains_Inf)
   231         using ex \<open>S \<noteq> {}\<close> \<open>closed S\<close>
   232         apply auto
   233         done
   234       then have "\<forall>x. Inf S \<le> x \<longleftrightarrow> x \<in> S"
   235         using mono[rule_format, of "Inf S"] *
   236         by auto
   237       then have "S = {Inf S ..}"
   238         by auto
   239       then have "\<exists>a. S = {a ..}"
   240         by auto
   241     }
   242     moreover
   243     {
   244       assume "\<not> (\<exists>B. \<forall>x\<in>S. B \<le> x)"
   245       then have nex: "\<forall>B. \<exists>x\<in>S. x < B"
   246         by (simp add: not_le)
   247       {
   248         fix y
   249         obtain x where "x\<in>S" and "x < y"
   250           using nex by auto
   251         then have "y \<in> S"
   252           using mono[rule_format, of x y] by auto
   253       }
   254       then have "S = UNIV"
   255         by auto
   256     }
   257     ultimately have "S = UNIV \<or> (\<exists>a. S = {a ..})"
   258       by blast
   259   }
   260   then show ?thesis
   261     by blast
   262 qed
   263 
   264 lemma%important mono_closed_ereal:
   265   fixes S :: "real set"
   266   assumes mono: "\<forall>y z. y \<in> S \<and> y \<le> z \<longrightarrow> z \<in> S"
   267     and "closed S"
   268   shows "\<exists>a. S = {x. a \<le> ereal x}"
   269 proof%unimportant -
   270   {
   271     assume "S = {}"
   272     then have ?thesis
   273       apply (rule_tac x=PInfty in exI)
   274       apply auto
   275       done
   276   }
   277   moreover
   278   {
   279     assume "S = UNIV"
   280     then have ?thesis
   281       apply (rule_tac x="-\<infinity>" in exI)
   282       apply auto
   283       done
   284   }
   285   moreover
   286   {
   287     assume "\<exists>a. S = {a ..}"
   288     then obtain a where "S = {a ..}"
   289       by auto
   290     then have ?thesis
   291       apply (rule_tac x="ereal a" in exI)
   292       apply auto
   293       done
   294   }
   295   ultimately show ?thesis
   296     using mono_closed_real[of S] assms by auto
   297 qed
   298 
   299 lemma%important Liminf_within:
   300   fixes f :: "'a::metric_space \<Rightarrow> 'b::complete_lattice"
   301   shows "Liminf (at x within S) f = (SUP e\<in>{0<..}. INF y\<in>(S \<inter> ball x e - {x}). f y)"
   302   unfolding Liminf_def eventually_at
   303 proof%unimportant (rule SUP_eq, simp_all add: Ball_def Bex_def, safe)
   304   fix P d
   305   assume "0 < d" and "\<forall>y. y \<in> S \<longrightarrow> y \<noteq> x \<and> dist y x < d \<longrightarrow> P y"
   306   then have "S \<inter> ball x d - {x} \<subseteq> {x. P x}"
   307     by (auto simp: zero_less_dist_iff dist_commute)
   308   then show "\<exists>r>0. Inf (f ` (Collect P)) \<le> Inf (f ` (S \<inter> ball x r - {x}))"
   309     by (intro exI[of _ d] INF_mono conjI \<open>0 < d\<close>) auto
   310 next
   311   fix d :: real
   312   assume "0 < d"
   313   then show "\<exists>P. (\<exists>d>0. \<forall>xa. xa \<in> S \<longrightarrow> xa \<noteq> x \<and> dist xa x < d \<longrightarrow> P xa) \<and>
   314     Inf (f ` (S \<inter> ball x d - {x})) \<le> Inf (f ` (Collect P))"
   315     by (intro exI[of _ "\<lambda>y. y \<in> S \<inter> ball x d - {x}"])
   316        (auto intro!: INF_mono exI[of _ d] simp: dist_commute)
   317 qed
   318 
   319 lemma%important Limsup_within:
   320   fixes f :: "'a::metric_space \<Rightarrow> 'b::complete_lattice"
   321   shows "Limsup (at x within S) f = (INF e\<in>{0<..}. SUP y\<in>(S \<inter> ball x e - {x}). f y)"
   322   unfolding Limsup_def eventually_at
   323 proof%unimportant (rule INF_eq, simp_all add: Ball_def Bex_def, safe)
   324   fix P d
   325   assume "0 < d" and "\<forall>y. y \<in> S \<longrightarrow> y \<noteq> x \<and> dist y x < d \<longrightarrow> P y"
   326   then have "S \<inter> ball x d - {x} \<subseteq> {x. P x}"
   327     by (auto simp: zero_less_dist_iff dist_commute)
   328   then show "\<exists>r>0. Sup (f ` (S \<inter> ball x r - {x})) \<le> Sup (f ` (Collect P))"
   329     by (intro exI[of _ d] SUP_mono conjI \<open>0 < d\<close>) auto
   330 next
   331   fix d :: real
   332   assume "0 < d"
   333   then show "\<exists>P. (\<exists>d>0. \<forall>xa. xa \<in> S \<longrightarrow> xa \<noteq> x \<and> dist xa x < d \<longrightarrow> P xa) \<and>
   334     Sup (f ` (Collect P)) \<le> Sup (f ` (S \<inter> ball x d - {x}))"
   335     by (intro exI[of _ "\<lambda>y. y \<in> S \<inter> ball x d - {x}"])
   336        (auto intro!: SUP_mono exI[of _ d] simp: dist_commute)
   337 qed
   338 
   339 lemma Liminf_at:
   340   fixes f :: "'a::metric_space \<Rightarrow> 'b::complete_lattice"
   341   shows "Liminf (at x) f = (SUP e\<in>{0<..}. INF y\<in>(ball x e - {x}). f y)"
   342   using Liminf_within[of x UNIV f] by simp
   343 
   344 lemma Limsup_at:
   345   fixes f :: "'a::metric_space \<Rightarrow> 'b::complete_lattice"
   346   shows "Limsup (at x) f = (INF e\<in>{0<..}. SUP y\<in>(ball x e - {x}). f y)"
   347   using Limsup_within[of x UNIV f] by simp
   348 
   349 lemma min_Liminf_at:
   350   fixes f :: "'a::metric_space \<Rightarrow> 'b::complete_linorder"
   351   shows "min (f x) (Liminf (at x) f) = (SUP e\<in>{0<..}. INF y\<in>ball x e. f y)"
   352   unfolding inf_min[symmetric] Liminf_at
   353   apply (subst inf_commute)
   354   apply (subst SUP_inf)
   355   apply (intro SUP_cong[OF refl])
   356   apply (cut_tac A="ball x xa - {x}" and B="{x}" and M=f in INF_union)
   357   apply (drule sym)
   358   apply auto
   359   apply (metis INF_absorb centre_in_ball)
   360   done
   361 
   362 
   363 subsection%important \<open>Extended-Real.thy\<close> (*FIX title *)
   364 
   365 lemma sum_constant_ereal:
   366   fixes a::ereal
   367   shows "(\<Sum>i\<in>I. a) = a * card I"
   368 apply (cases "finite I", induct set: finite, simp_all)
   369 apply (cases a, auto, metis (no_types, hide_lams) add.commute mult.commute semiring_normalization_rules(3))
   370 done
   371 
   372 lemma real_lim_then_eventually_real:
   373   assumes "(u \<longlongrightarrow> ereal l) F"
   374   shows "eventually (\<lambda>n. u n = ereal(real_of_ereal(u n))) F"
   375 proof -
   376   have "ereal l \<in> {-\<infinity><..<(\<infinity>::ereal)}" by simp
   377   moreover have "open {-\<infinity><..<(\<infinity>::ereal)}" by simp
   378   ultimately have "eventually (\<lambda>n. u n \<in> {-\<infinity><..<(\<infinity>::ereal)}) F" using assms tendsto_def by blast
   379   moreover have "\<And>x. x \<in> {-\<infinity><..<(\<infinity>::ereal)} \<Longrightarrow> x = ereal(real_of_ereal x)" using ereal_real by auto
   380   ultimately show ?thesis by (metis (mono_tags, lifting) eventually_mono)
   381 qed
   382 
   383 lemma%important ereal_Inf_cmult:
   384   assumes "c>(0::real)"
   385   shows "Inf {ereal c * x |x. P x} = ereal c * Inf {x. P x}"
   386 proof%unimportant -
   387   have "(\<lambda>x::ereal. c * x) (Inf {x::ereal. P x}) = Inf ((\<lambda>x::ereal. c * x)`{x::ereal. P x})"
   388     apply (rule mono_bij_Inf)
   389     apply (simp add: assms ereal_mult_left_mono less_imp_le mono_def)
   390     apply (rule bij_betw_byWitness[of _ "\<lambda>x. (x::ereal) / c"], auto simp add: assms ereal_mult_divide)
   391     using assms ereal_divide_eq apply auto
   392     done
   393   then show ?thesis by (simp only: setcompr_eq_image[symmetric])
   394 qed
   395 
   396 
   397 subsubsection%important \<open>Continuity of addition\<close>
   398 
   399 text \<open>The next few lemmas remove an unnecessary assumption in \verb+tendsto_add_ereal+, culminating
   400 in \verb+tendsto_add_ereal_general+ which essentially says that the addition
   401 is continuous on ereal times ereal, except at $(-\infty, \infty)$ and $(\infty, -\infty)$.
   402 It is much more convenient in many situations, see for instance the proof of
   403 \verb+tendsto_sum_ereal+ below.\<close>
   404 
   405 lemma%important tendsto_add_ereal_PInf:
   406   fixes y :: ereal
   407   assumes y: "y \<noteq> -\<infinity>"
   408   assumes f: "(f \<longlongrightarrow> \<infinity>) F" and g: "(g \<longlongrightarrow> y) F"
   409   shows "((\<lambda>x. f x + g x) \<longlongrightarrow> \<infinity>) F"
   410 proof%unimportant -
   411   have "\<exists>C. eventually (\<lambda>x. g x > ereal C) F"
   412   proof (cases y)
   413     case (real r)
   414     have "y > y-1" using y real by (simp add: ereal_between(1))
   415     then have "eventually (\<lambda>x. g x > y - 1) F" using g y order_tendsto_iff by auto
   416     moreover have "y-1 = ereal(real_of_ereal(y-1))"
   417       by (metis real ereal_eq_1(1) ereal_minus(1) real_of_ereal.simps(1))
   418     ultimately have "eventually (\<lambda>x. g x > ereal(real_of_ereal(y - 1))) F" by simp
   419     then show ?thesis by auto
   420   next
   421     case (PInf)
   422     have "eventually (\<lambda>x. g x > ereal 0) F" using g PInf by (simp add: tendsto_PInfty)
   423     then show ?thesis by auto
   424   qed (simp add: y)
   425   then obtain C::real where ge: "eventually (\<lambda>x. g x > ereal C) F" by auto
   426 
   427   {
   428     fix M::real
   429     have "eventually (\<lambda>x. f x > ereal(M - C)) F" using f by (simp add: tendsto_PInfty)
   430     then have "eventually (\<lambda>x. (f x > ereal (M-C)) \<and> (g x > ereal C)) F"
   431       by (auto simp add: ge eventually_conj_iff)
   432     moreover have "\<And>x. ((f x > ereal (M-C)) \<and> (g x > ereal C)) \<Longrightarrow> (f x + g x > ereal M)"
   433       using ereal_add_strict_mono2 by fastforce
   434     ultimately have "eventually (\<lambda>x. f x + g x > ereal M) F" using eventually_mono by force
   435   }
   436   then show ?thesis by (simp add: tendsto_PInfty)
   437 qed
   438 
   439 text\<open>One would like to deduce the next lemma from the previous one, but the fact
   440 that $-(x+y)$ is in general different from $(-x) + (-y)$ in ereal creates difficulties,
   441 so it is more efficient to copy the previous proof.\<close>
   442 
   443 lemma%important tendsto_add_ereal_MInf:
   444   fixes y :: ereal
   445   assumes y: "y \<noteq> \<infinity>"
   446   assumes f: "(f \<longlongrightarrow> -\<infinity>) F" and g: "(g \<longlongrightarrow> y) F"
   447   shows "((\<lambda>x. f x + g x) \<longlongrightarrow> -\<infinity>) F"
   448 proof%unimportant -
   449   have "\<exists>C. eventually (\<lambda>x. g x < ereal C) F"
   450   proof (cases y)
   451     case (real r)
   452     have "y < y+1" using y real by (simp add: ereal_between(1))
   453     then have "eventually (\<lambda>x. g x < y + 1) F" using g y order_tendsto_iff by force
   454     moreover have "y+1 = ereal(real_of_ereal (y+1))" by (simp add: real)
   455     ultimately have "eventually (\<lambda>x. g x < ereal(real_of_ereal(y + 1))) F" by simp
   456     then show ?thesis by auto
   457   next
   458     case (MInf)
   459     have "eventually (\<lambda>x. g x < ereal 0) F" using g MInf by (simp add: tendsto_MInfty)
   460     then show ?thesis by auto
   461   qed (simp add: y)
   462   then obtain C::real where ge: "eventually (\<lambda>x. g x < ereal C) F" by auto
   463 
   464   {
   465     fix M::real
   466     have "eventually (\<lambda>x. f x < ereal(M - C)) F" using f by (simp add: tendsto_MInfty)
   467     then have "eventually (\<lambda>x. (f x < ereal (M- C)) \<and> (g x < ereal C)) F"
   468       by (auto simp add: ge eventually_conj_iff)
   469     moreover have "\<And>x. ((f x < ereal (M-C)) \<and> (g x < ereal C)) \<Longrightarrow> (f x + g x < ereal M)"
   470       using ereal_add_strict_mono2 by fastforce
   471     ultimately have "eventually (\<lambda>x. f x + g x < ereal M) F" using eventually_mono by force
   472   }
   473   then show ?thesis by (simp add: tendsto_MInfty)
   474 qed
   475 
   476 lemma%important tendsto_add_ereal_general1:
   477   fixes x y :: ereal
   478   assumes y: "\<bar>y\<bar> \<noteq> \<infinity>"
   479   assumes f: "(f \<longlongrightarrow> x) F" and g: "(g \<longlongrightarrow> y) F"
   480   shows "((\<lambda>x. f x + g x) \<longlongrightarrow> x + y) F"
   481 proof%unimportant (cases x)
   482   case (real r)
   483   have a: "\<bar>x\<bar> \<noteq> \<infinity>" by (simp add: real)
   484   show ?thesis by (rule tendsto_add_ereal[OF a, OF y, OF f, OF g])
   485 next
   486   case PInf
   487   then show ?thesis using tendsto_add_ereal_PInf assms by force
   488 next
   489   case MInf
   490   then show ?thesis using tendsto_add_ereal_MInf assms
   491     by (metis abs_ereal.simps(3) ereal_MInfty_eq_plus)
   492 qed
   493 
   494 lemma%important tendsto_add_ereal_general2:
   495   fixes x y :: ereal
   496   assumes x: "\<bar>x\<bar> \<noteq> \<infinity>"
   497       and f: "(f \<longlongrightarrow> x) F" and g: "(g \<longlongrightarrow> y) F"
   498   shows "((\<lambda>x. f x + g x) \<longlongrightarrow> x + y) F"
   499 proof%unimportant -
   500   have "((\<lambda>x. g x + f x) \<longlongrightarrow> x + y) F"
   501     using tendsto_add_ereal_general1[OF x, OF g, OF f] add.commute[of "y", of "x"] by simp
   502   moreover have "\<And>x. g x + f x = f x + g x" using add.commute by auto
   503   ultimately show ?thesis by simp
   504 qed
   505 
   506 text \<open>The next lemma says that the addition is continuous on ereal, except at
   507 the pairs $(-\infty, \infty)$ and $(\infty, -\infty)$.\<close>
   508 
   509 lemma%important tendsto_add_ereal_general [tendsto_intros]:
   510   fixes x y :: ereal
   511   assumes "\<not>((x=\<infinity> \<and> y=-\<infinity>) \<or> (x=-\<infinity> \<and> y=\<infinity>))"
   512       and f: "(f \<longlongrightarrow> x) F" and g: "(g \<longlongrightarrow> y) F"
   513   shows "((\<lambda>x. f x + g x) \<longlongrightarrow> x + y) F"
   514 proof%unimportant (cases x)
   515   case (real r)
   516   show ?thesis
   517     apply (rule tendsto_add_ereal_general2) using real assms by auto
   518 next
   519   case (PInf)
   520   then have "y \<noteq> -\<infinity>" using assms by simp
   521   then show ?thesis using tendsto_add_ereal_PInf PInf assms by auto
   522 next
   523   case (MInf)
   524   then have "y \<noteq> \<infinity>" using assms by simp
   525   then show ?thesis using tendsto_add_ereal_MInf MInf f g by (metis ereal_MInfty_eq_plus)
   526 qed
   527 
   528 subsubsection%important \<open>Continuity of multiplication\<close>
   529 
   530 text \<open>In the same way as for addition, we prove that the multiplication is continuous on
   531 ereal times ereal, except at $(\infty, 0)$ and $(-\infty, 0)$ and $(0, \infty)$ and $(0, -\infty)$,
   532 starting with specific situations.\<close>
   533 
   534 lemma%important tendsto_mult_real_ereal:
   535   assumes "(u \<longlongrightarrow> ereal l) F" "(v \<longlongrightarrow> ereal m) F"
   536   shows "((\<lambda>n. u n * v n) \<longlongrightarrow> ereal l * ereal m) F"
   537 proof%unimportant -
   538   have ureal: "eventually (\<lambda>n. u n = ereal(real_of_ereal(u n))) F" by (rule real_lim_then_eventually_real[OF assms(1)])
   539   then have "((\<lambda>n. ereal(real_of_ereal(u n))) \<longlongrightarrow> ereal l) F" using assms by auto
   540   then have limu: "((\<lambda>n. real_of_ereal(u n)) \<longlongrightarrow> l) F" by auto
   541   have vreal: "eventually (\<lambda>n. v n = ereal(real_of_ereal(v n))) F" by (rule real_lim_then_eventually_real[OF assms(2)])
   542   then have "((\<lambda>n. ereal(real_of_ereal(v n))) \<longlongrightarrow> ereal m) F" using assms by auto
   543   then have limv: "((\<lambda>n. real_of_ereal(v n)) \<longlongrightarrow> m) F" by auto
   544 
   545   {
   546     fix n assume "u n = ereal(real_of_ereal(u n))" "v n = ereal(real_of_ereal(v n))"
   547     then have "ereal(real_of_ereal(u n) * real_of_ereal(v n)) = u n * v n" by (metis times_ereal.simps(1))
   548   }
   549   then have *: "eventually (\<lambda>n. ereal(real_of_ereal(u n) * real_of_ereal(v n)) = u n * v n) F"
   550     using eventually_elim2[OF ureal vreal] by auto
   551 
   552   have "((\<lambda>n. real_of_ereal(u n) * real_of_ereal(v n)) \<longlongrightarrow> l * m) F" using tendsto_mult[OF limu limv] by auto
   553   then have "((\<lambda>n. ereal(real_of_ereal(u n)) * real_of_ereal(v n)) \<longlongrightarrow> ereal(l * m)) F" by auto
   554   then show ?thesis using * filterlim_cong by fastforce
   555 qed
   556 
   557 lemma%important tendsto_mult_ereal_PInf:
   558   fixes f g::"_ \<Rightarrow> ereal"
   559   assumes "(f \<longlongrightarrow> l) F" "l>0" "(g \<longlongrightarrow> \<infinity>) F"
   560   shows "((\<lambda>x. f x * g x) \<longlongrightarrow> \<infinity>) F"
   561 proof%unimportant -
   562   obtain a::real where "0 < ereal a" "a < l" using assms(2) using ereal_dense2 by blast
   563   have *: "eventually (\<lambda>x. f x > a) F" using \<open>a < l\<close> assms(1) by (simp add: order_tendsto_iff)
   564   {
   565     fix K::real
   566     define M where "M = max K 1"
   567     then have "M > 0" by simp
   568     then have "ereal(M/a) > 0" using \<open>ereal a > 0\<close> by simp
   569     then have "\<And>x. ((f x > a) \<and> (g x > M/a)) \<Longrightarrow> (f x * g x > ereal a * ereal(M/a))"
   570       using ereal_mult_mono_strict'[where ?c = "M/a", OF \<open>0 < ereal a\<close>] by auto
   571     moreover have "ereal a * ereal(M/a) = M" using \<open>ereal a > 0\<close> by simp
   572     ultimately have "\<And>x. ((f x > a) \<and> (g x > M/a)) \<Longrightarrow> (f x * g x > M)" by simp
   573     moreover have "M \<ge> K" unfolding M_def by simp
   574     ultimately have Imp: "\<And>x. ((f x > a) \<and> (g x > M/a)) \<Longrightarrow> (f x * g x > K)"
   575       using ereal_less_eq(3) le_less_trans by blast
   576 
   577     have "eventually (\<lambda>x. g x > M/a) F" using assms(3) by (simp add: tendsto_PInfty)
   578     then have "eventually (\<lambda>x. (f x > a) \<and> (g x > M/a)) F"
   579       using * by (auto simp add: eventually_conj_iff)
   580     then have "eventually (\<lambda>x. f x * g x > K) F" using eventually_mono Imp by force
   581   }
   582   then show ?thesis by (auto simp add: tendsto_PInfty)
   583 qed
   584 
   585 lemma%important tendsto_mult_ereal_pos:
   586   fixes f g::"_ \<Rightarrow> ereal"
   587   assumes "(f \<longlongrightarrow> l) F" "(g \<longlongrightarrow> m) F" "l>0" "m>0"
   588   shows "((\<lambda>x. f x * g x) \<longlongrightarrow> l * m) F"
   589 proof%unimportant (cases)
   590   assume *: "l = \<infinity> \<or> m = \<infinity>"
   591   then show ?thesis
   592   proof (cases)
   593     assume "m = \<infinity>"
   594     then show ?thesis using tendsto_mult_ereal_PInf assms by auto
   595   next
   596     assume "\<not>(m = \<infinity>)"
   597     then have "l = \<infinity>" using * by simp
   598     then have "((\<lambda>x. g x * f x) \<longlongrightarrow> l * m) F" using tendsto_mult_ereal_PInf assms by auto
   599     moreover have "\<And>x. g x * f x = f x * g x" using mult.commute by auto
   600     ultimately show ?thesis by simp
   601   qed
   602 next
   603   assume "\<not>(l = \<infinity> \<or> m = \<infinity>)"
   604   then have "l < \<infinity>" "m < \<infinity>" by auto
   605   then obtain lr mr where "l = ereal lr" "m = ereal mr"
   606     using \<open>l>0\<close> \<open>m>0\<close> by (metis ereal_cases ereal_less(6) not_less_iff_gr_or_eq)
   607   then show ?thesis using tendsto_mult_real_ereal assms by auto
   608 qed
   609 
   610 text \<open>We reduce the general situation to the positive case by multiplying by suitable signs.
   611 Unfortunately, as ereal is not a ring, all the neat sign lemmas are not available there. We
   612 give the bare minimum we need.\<close>
   613 
   614 lemma ereal_sgn_abs:
   615   fixes l::ereal
   616   shows "sgn(l) * l = abs(l)"
   617 apply (cases l) by (auto simp add: sgn_if ereal_less_uminus_reorder)
   618 
   619 lemma sgn_squared_ereal:
   620   assumes "l \<noteq> (0::ereal)"
   621   shows "sgn(l) * sgn(l) = 1"
   622 apply (cases l) using assms by (auto simp add: one_ereal_def sgn_if)
   623 
   624 lemma%important tendsto_mult_ereal [tendsto_intros]:
   625   fixes f g::"_ \<Rightarrow> ereal"
   626   assumes "(f \<longlongrightarrow> l) F" "(g \<longlongrightarrow> m) F" "\<not>((l=0 \<and> abs(m) = \<infinity>) \<or> (m=0 \<and> abs(l) = \<infinity>))"
   627   shows "((\<lambda>x. f x * g x) \<longlongrightarrow> l * m) F"
   628 proof%unimportant (cases)
   629   assume "l=0 \<or> m=0"
   630   then have "abs(l) \<noteq> \<infinity>" "abs(m) \<noteq> \<infinity>" using assms(3) by auto
   631   then obtain lr mr where "l = ereal lr" "m = ereal mr" by auto
   632   then show ?thesis using tendsto_mult_real_ereal assms by auto
   633 next
   634   have sgn_finite: "\<And>a::ereal. abs(sgn a) \<noteq> \<infinity>"
   635     by (metis MInfty_neq_ereal(2) PInfty_neq_ereal(2) abs_eq_infinity_cases ereal_times(1) ereal_times(3) ereal_uminus_eq_reorder sgn_ereal.elims)
   636   then have sgn_finite2: "\<And>a b::ereal. abs(sgn a * sgn b) \<noteq> \<infinity>"
   637     by (metis abs_eq_infinity_cases abs_ereal.simps(2) abs_ereal.simps(3) ereal_mult_eq_MInfty ereal_mult_eq_PInfty)
   638   assume "\<not>(l=0 \<or> m=0)"
   639   then have "l \<noteq> 0" "m \<noteq> 0" by auto
   640   then have "abs(l) > 0" "abs(m) > 0"
   641     by (metis abs_ereal_ge0 abs_ereal_less0 abs_ereal_pos ereal_uminus_uminus ereal_uminus_zero less_le not_less)+
   642   then have "sgn(l) * l > 0" "sgn(m) * m > 0" using ereal_sgn_abs by auto
   643   moreover have "((\<lambda>x. sgn(l) * f x) \<longlongrightarrow> (sgn(l) * l)) F"
   644     by (rule tendsto_cmult_ereal, auto simp add: sgn_finite assms(1))
   645   moreover have "((\<lambda>x. sgn(m) * g x) \<longlongrightarrow> (sgn(m) * m)) F"
   646     by (rule tendsto_cmult_ereal, auto simp add: sgn_finite assms(2))
   647   ultimately have *: "((\<lambda>x. (sgn(l) * f x) * (sgn(m) * g x)) \<longlongrightarrow> (sgn(l) * l) * (sgn(m) * m)) F"
   648     using tendsto_mult_ereal_pos by force
   649   have "((\<lambda>x. (sgn(l) * sgn(m)) * ((sgn(l) * f x) * (sgn(m) * g x))) \<longlongrightarrow> (sgn(l) * sgn(m)) * ((sgn(l) * l) * (sgn(m) * m))) F"
   650     by (rule tendsto_cmult_ereal, auto simp add: sgn_finite2 *)
   651   moreover have "\<And>x. (sgn(l) * sgn(m)) * ((sgn(l) * f x) * (sgn(m) * g x)) = f x * g x"
   652     by (metis mult.left_neutral sgn_squared_ereal[OF \<open>l \<noteq> 0\<close>] sgn_squared_ereal[OF \<open>m \<noteq> 0\<close>] mult.assoc mult.commute)
   653   moreover have "(sgn(l) * sgn(m)) * ((sgn(l) * l) * (sgn(m) * m)) = l * m"
   654     by (metis mult.left_neutral sgn_squared_ereal[OF \<open>l \<noteq> 0\<close>] sgn_squared_ereal[OF \<open>m \<noteq> 0\<close>] mult.assoc mult.commute)
   655   ultimately show ?thesis by auto
   656 qed
   657 
   658 lemma tendsto_cmult_ereal_general [tendsto_intros]:
   659   fixes f::"_ \<Rightarrow> ereal" and c::ereal
   660   assumes "(f \<longlongrightarrow> l) F" "\<not> (l=0 \<and> abs(c) = \<infinity>)"
   661   shows "((\<lambda>x. c * f x) \<longlongrightarrow> c * l) F"
   662 by (cases "c = 0", auto simp add: assms tendsto_mult_ereal)
   663 
   664 
   665 subsubsection%important \<open>Continuity of division\<close>
   666 
   667 lemma%important tendsto_inverse_ereal_PInf:
   668   fixes u::"_ \<Rightarrow> ereal"
   669   assumes "(u \<longlongrightarrow> \<infinity>) F"
   670   shows "((\<lambda>x. 1/ u x) \<longlongrightarrow> 0) F"
   671 proof%unimportant -
   672   {
   673     fix e::real assume "e>0"
   674     have "1/e < \<infinity>" by auto
   675     then have "eventually (\<lambda>n. u n > 1/e) F" using assms(1) by (simp add: tendsto_PInfty)
   676     moreover
   677     {
   678       fix z::ereal assume "z>1/e"
   679       then have "z>0" using \<open>e>0\<close> using less_le_trans not_le by fastforce
   680       then have "1/z \<ge> 0" by auto
   681       moreover have "1/z < e" using \<open>e>0\<close> \<open>z>1/e\<close>
   682         apply (cases z) apply auto
   683         by (metis (mono_tags, hide_lams) less_ereal.simps(2) less_ereal.simps(4) divide_less_eq ereal_divide_less_pos ereal_less(4)
   684             ereal_less_eq(4) less_le_trans mult_eq_0_iff not_le not_one_less_zero times_ereal.simps(1))
   685       ultimately have "1/z \<ge> 0" "1/z < e" by auto
   686     }
   687     ultimately have "eventually (\<lambda>n. 1/u n<e) F" "eventually (\<lambda>n. 1/u n\<ge>0) F" by (auto simp add: eventually_mono)
   688   } note * = this
   689   show ?thesis
   690   proof (subst order_tendsto_iff, auto)
   691     fix a::ereal assume "a<0"
   692     then show "eventually (\<lambda>n. 1/u n > a) F" using *(2) eventually_mono less_le_trans linordered_field_no_ub by fastforce
   693   next
   694     fix a::ereal assume "a>0"
   695     then obtain e::real where "e>0" "a>e" using ereal_dense2 ereal_less(2) by blast
   696     then have "eventually (\<lambda>n. 1/u n < e) F" using *(1) by auto
   697     then show "eventually (\<lambda>n. 1/u n < a) F" using \<open>a>e\<close> by (metis (mono_tags, lifting) eventually_mono less_trans)
   698   qed
   699 qed
   700 
   701 text \<open>The next lemma deserves to exist by itself, as it is so common and useful.\<close>
   702 
   703 lemma tendsto_inverse_real [tendsto_intros]:
   704   fixes u::"_ \<Rightarrow> real"
   705   shows "(u \<longlongrightarrow> l) F \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> ((\<lambda>x. 1/ u x) \<longlongrightarrow> 1/l) F"
   706   using tendsto_inverse unfolding inverse_eq_divide .
   707 
   708 lemma%important tendsto_inverse_ereal [tendsto_intros]:
   709   fixes u::"_ \<Rightarrow> ereal"
   710   assumes "(u \<longlongrightarrow> l) F" "l \<noteq> 0"
   711   shows "((\<lambda>x. 1/ u x) \<longlongrightarrow> 1/l) F"
   712 proof%unimportant (cases l)
   713   case (real r)
   714   then have "r \<noteq> 0" using assms(2) by auto
   715   then have "1/l = ereal(1/r)" using real by (simp add: one_ereal_def)
   716   define v where "v = (\<lambda>n. real_of_ereal(u n))"
   717   have ureal: "eventually (\<lambda>n. u n = ereal(v n)) F" unfolding v_def using real_lim_then_eventually_real assms(1) real by auto
   718   then have "((\<lambda>n. ereal(v n)) \<longlongrightarrow> ereal r) F" using assms real v_def by auto
   719   then have *: "((\<lambda>n. v n) \<longlongrightarrow> r) F" by auto
   720   then have "((\<lambda>n. 1/v n) \<longlongrightarrow> 1/r) F" using \<open>r \<noteq> 0\<close> tendsto_inverse_real by auto
   721   then have lim: "((\<lambda>n. ereal(1/v n)) \<longlongrightarrow> 1/l) F" using \<open>1/l = ereal(1/r)\<close> by auto
   722 
   723   have "r \<in> -{0}" "open (-{(0::real)})" using \<open>r \<noteq> 0\<close> by auto
   724   then have "eventually (\<lambda>n. v n \<in> -{0}) F" using * using topological_tendstoD by blast
   725   then have "eventually (\<lambda>n. v n \<noteq> 0) F" by auto
   726   moreover
   727   {
   728     fix n assume H: "v n \<noteq> 0" "u n = ereal(v n)"
   729     then have "ereal(1/v n) = 1/ereal(v n)" by (simp add: one_ereal_def)
   730     then have "ereal(1/v n) = 1/u n" using H(2) by simp
   731   }
   732   ultimately have "eventually (\<lambda>n. ereal(1/v n) = 1/u n) F" using ureal eventually_elim2 by force
   733   with Lim_transform_eventually[OF this lim] show ?thesis by simp
   734 next
   735   case (PInf)
   736   then have "1/l = 0" by auto
   737   then show ?thesis using tendsto_inverse_ereal_PInf assms PInf by auto
   738 next
   739   case (MInf)
   740   then have "1/l = 0" by auto
   741   have "1/z = -1/ -z" if "z < 0" for z::ereal
   742     apply (cases z) using divide_ereal_def \<open> z < 0 \<close> by auto
   743   moreover have "eventually (\<lambda>n. u n < 0) F" by (metis (no_types) MInf assms(1) tendsto_MInfty zero_ereal_def)
   744   ultimately have *: "eventually (\<lambda>n. -1/-u n = 1/u n) F" by (simp add: eventually_mono)
   745 
   746   define v where "v = (\<lambda>n. - u n)"
   747   have "(v \<longlongrightarrow> \<infinity>) F" unfolding v_def using MInf assms(1) tendsto_uminus_ereal by fastforce
   748   then have "((\<lambda>n. 1/v n) \<longlongrightarrow> 0) F" using tendsto_inverse_ereal_PInf by auto
   749   then have "((\<lambda>n. -1/v n) \<longlongrightarrow> 0) F" using tendsto_uminus_ereal by fastforce
   750   then show ?thesis unfolding v_def using Lim_transform_eventually[OF *] \<open> 1/l = 0 \<close> by auto
   751 qed
   752 
   753 lemma%important tendsto_divide_ereal [tendsto_intros]:
   754   fixes f g::"_ \<Rightarrow> ereal"
   755   assumes "(f \<longlongrightarrow> l) F" "(g \<longlongrightarrow> m) F" "m \<noteq> 0" "\<not>(abs(l) = \<infinity> \<and> abs(m) = \<infinity>)"
   756   shows "((\<lambda>x. f x / g x) \<longlongrightarrow> l / m) F"
   757 proof%unimportant -
   758   define h where "h = (\<lambda>x. 1/ g x)"
   759   have *: "(h \<longlongrightarrow> 1/m) F" unfolding h_def using assms(2) assms(3) tendsto_inverse_ereal by auto
   760   have "((\<lambda>x. f x * h x) \<longlongrightarrow> l * (1/m)) F"
   761     apply (rule tendsto_mult_ereal[OF assms(1) *]) using assms(3) assms(4) by (auto simp add: divide_ereal_def)
   762   moreover have "f x * h x = f x / g x" for x unfolding h_def by (simp add: divide_ereal_def)
   763   moreover have "l * (1/m) = l/m" by (simp add: divide_ereal_def)
   764   ultimately show ?thesis unfolding h_def using Lim_transform_eventually by auto
   765 qed
   766 
   767 
   768 subsubsection%important \<open>Further limits\<close>
   769 
   770 text \<open>The assumptions of @{thm tendsto_diff_ereal} are too strong, we weaken them here.\<close>
   771 
   772 lemma%important tendsto_diff_ereal_general [tendsto_intros]:
   773   fixes u v::"'a \<Rightarrow> ereal"
   774   assumes "(u \<longlongrightarrow> l) F" "(v \<longlongrightarrow> m) F" "\<not>((l = \<infinity> \<and> m = \<infinity>) \<or> (l = -\<infinity> \<and> m = -\<infinity>))"
   775   shows "((\<lambda>n. u n - v n) \<longlongrightarrow> l - m) F"
   776 proof%unimportant -
   777   have "((\<lambda>n. u n + (-v n)) \<longlongrightarrow> l + (-m)) F"
   778     apply (intro tendsto_intros assms) using assms by (auto simp add: ereal_uminus_eq_reorder)
   779   then show ?thesis by (simp add: minus_ereal_def)
   780 qed
   781 
   782 lemma id_nat_ereal_tendsto_PInf [tendsto_intros]:
   783   "(\<lambda> n::nat. real n) \<longlonglongrightarrow> \<infinity>"
   784 by (simp add: filterlim_real_sequentially tendsto_PInfty_eq_at_top)
   785 
   786 lemma%important tendsto_at_top_pseudo_inverse [tendsto_intros]:
   787   fixes u::"nat \<Rightarrow> nat"
   788   assumes "LIM n sequentially. u n :> at_top"
   789   shows "LIM n sequentially. Inf {N. u N \<ge> n} :> at_top"
   790 proof%unimportant -
   791   {
   792     fix C::nat
   793     define M where "M = Max {u n| n. n \<le> C}+1"
   794     {
   795       fix n assume "n \<ge> M"
   796       have "eventually (\<lambda>N. u N \<ge> n) sequentially" using assms
   797         by (simp add: filterlim_at_top)
   798       then have *: "{N. u N \<ge> n} \<noteq> {}" by force
   799 
   800       have "N > C" if "u N \<ge> n" for N
   801       proof (rule ccontr)
   802         assume "\<not>(N > C)"
   803         have "u N \<le> Max {u n| n. n \<le> C}"
   804           apply (rule Max_ge) using \<open>\<not>(N > C)\<close> by auto
   805         then show False using \<open>u N \<ge> n\<close> \<open>n \<ge> M\<close> unfolding M_def by auto
   806       qed
   807       then have **: "{N. u N \<ge> n} \<subseteq> {C..}" by fastforce
   808       have "Inf {N. u N \<ge> n} \<ge> C"
   809         by (metis "*" "**" Inf_nat_def1 atLeast_iff subset_eq)
   810     }
   811     then have "eventually (\<lambda>n. Inf {N. u N \<ge> n} \<ge> C) sequentially"
   812       using eventually_sequentially by auto
   813   }
   814   then show ?thesis using filterlim_at_top by auto
   815 qed
   816 
   817 lemma%important pseudo_inverse_finite_set:
   818   fixes u::"nat \<Rightarrow> nat"
   819   assumes "LIM n sequentially. u n :> at_top"
   820   shows "finite {N. u N \<le> n}"
   821 proof%unimportant -
   822   fix n
   823   have "eventually (\<lambda>N. u N \<ge> n+1) sequentially" using assms
   824     by (simp add: filterlim_at_top)
   825   then obtain N1 where N1: "\<And>N. N \<ge> N1 \<Longrightarrow> u N \<ge> n + 1"
   826     using eventually_sequentially by auto
   827   have "{N. u N \<le> n} \<subseteq> {..<N1}"
   828     apply auto using N1 by (metis Suc_eq_plus1 not_less not_less_eq_eq)
   829   then show "finite {N. u N \<le> n}" by (simp add: finite_subset)
   830 qed
   831 
   832 lemma tendsto_at_top_pseudo_inverse2 [tendsto_intros]:
   833   fixes u::"nat \<Rightarrow> nat"
   834   assumes "LIM n sequentially. u n :> at_top"
   835   shows "LIM n sequentially. Max {N. u N \<le> n} :> at_top"
   836 proof -
   837   {
   838     fix N0::nat
   839     have "N0 \<le> Max {N. u N \<le> n}" if "n \<ge> u N0" for n
   840       apply (rule Max.coboundedI) using pseudo_inverse_finite_set[OF assms] that by auto
   841     then have "eventually (\<lambda>n. N0 \<le> Max {N. u N \<le> n}) sequentially"
   842       using eventually_sequentially by blast
   843   }
   844   then show ?thesis using filterlim_at_top by auto
   845 qed
   846 
   847 lemma ereal_truncation_top [tendsto_intros]:
   848   fixes x::ereal
   849   shows "(\<lambda>n::nat. min x n) \<longlonglongrightarrow> x"
   850 proof (cases x)
   851   case (real r)
   852   then obtain K::nat where "K>0" "K > abs(r)" using reals_Archimedean2 gr0I by auto
   853   then have "min x n = x" if "n \<ge> K" for n apply (subst real, subst real, auto) using that eq_iff by fastforce
   854   then have "eventually (\<lambda>n. min x n = x) sequentially" using eventually_at_top_linorder by blast
   855   then show ?thesis by (simp add: Lim_eventually)
   856 next
   857   case (PInf)
   858   then have "min x n = n" for n::nat by (auto simp add: min_def)
   859   then show ?thesis using id_nat_ereal_tendsto_PInf PInf by auto
   860 next
   861   case (MInf)
   862   then have "min x n = x" for n::nat by (auto simp add: min_def)
   863   then show ?thesis by auto
   864 qed
   865 
   866 lemma%important ereal_truncation_real_top [tendsto_intros]:
   867   fixes x::ereal
   868   assumes "x \<noteq> - \<infinity>"
   869   shows "(\<lambda>n::nat. real_of_ereal(min x n)) \<longlonglongrightarrow> x"
   870 proof%unimportant (cases x)
   871   case (real r)
   872   then obtain K::nat where "K>0" "K > abs(r)" using reals_Archimedean2 gr0I by auto
   873   then have "min x n = x" if "n \<ge> K" for n apply (subst real, subst real, auto) using that eq_iff by fastforce
   874   then have "real_of_ereal(min x n) = r" if "n \<ge> K" for n using real that by auto
   875   then have "eventually (\<lambda>n. real_of_ereal(min x n) = r) sequentially" using eventually_at_top_linorder by blast
   876   then have "(\<lambda>n. real_of_ereal(min x n)) \<longlonglongrightarrow> r" by (simp add: Lim_eventually)
   877   then show ?thesis using real by auto
   878 next
   879   case (PInf)
   880   then have "real_of_ereal(min x n) = n" for n::nat by (auto simp add: min_def)
   881   then show ?thesis using id_nat_ereal_tendsto_PInf PInf by auto
   882 qed (simp add: assms)
   883 
   884 lemma%important ereal_truncation_bottom [tendsto_intros]:
   885   fixes x::ereal
   886   shows "(\<lambda>n::nat. max x (- real n)) \<longlonglongrightarrow> x"
   887 proof%unimportant (cases x)
   888   case (real r)
   889   then obtain K::nat where "K>0" "K > abs(r)" using reals_Archimedean2 gr0I by auto
   890   then have "max x (-real n) = x" if "n \<ge> K" for n apply (subst real, subst real, auto) using that eq_iff by fastforce
   891   then have "eventually (\<lambda>n. max x (-real n) = x) sequentially" using eventually_at_top_linorder by blast
   892   then show ?thesis by (simp add: Lim_eventually)
   893 next
   894   case (MInf)
   895   then have "max x (-real n) = (-1)* ereal(real n)" for n::nat by (auto simp add: max_def)
   896   moreover have "(\<lambda>n. (-1)* ereal(real n)) \<longlonglongrightarrow> -\<infinity>"
   897     using tendsto_cmult_ereal[of "-1", OF _ id_nat_ereal_tendsto_PInf] by (simp add: one_ereal_def)
   898   ultimately show ?thesis using MInf by auto
   899 next
   900   case (PInf)
   901   then have "max x (-real n) = x" for n::nat by (auto simp add: max_def)
   902   then show ?thesis by auto
   903 qed
   904 
   905 lemma%important ereal_truncation_real_bottom [tendsto_intros]:
   906   fixes x::ereal
   907   assumes "x \<noteq> \<infinity>"
   908   shows "(\<lambda>n::nat. real_of_ereal(max x (- real n))) \<longlonglongrightarrow> x"
   909 proof%unimportant (cases x)
   910   case (real r)
   911   then obtain K::nat where "K>0" "K > abs(r)" using reals_Archimedean2 gr0I by auto
   912   then have "max x (-real n) = x" if "n \<ge> K" for n apply (subst real, subst real, auto) using that eq_iff by fastforce
   913   then have "real_of_ereal(max x (-real n)) = r" if "n \<ge> K" for n using real that by auto
   914   then have "eventually (\<lambda>n. real_of_ereal(max x (-real n)) = r) sequentially" using eventually_at_top_linorder by blast
   915   then have "(\<lambda>n. real_of_ereal(max x (-real n))) \<longlonglongrightarrow> r" by (simp add: Lim_eventually)
   916   then show ?thesis using real by auto
   917 next
   918   case (MInf)
   919   then have "real_of_ereal(max x (-real n)) = (-1)* ereal(real n)" for n::nat by (auto simp add: max_def)
   920   moreover have "(\<lambda>n. (-1)* ereal(real n)) \<longlonglongrightarrow> -\<infinity>"
   921     using tendsto_cmult_ereal[of "-1", OF _ id_nat_ereal_tendsto_PInf] by (simp add: one_ereal_def)
   922   ultimately show ?thesis using MInf by auto
   923 qed (simp add: assms)
   924 
   925 text \<open>the next one is copied from \verb+tendsto_sum+.\<close>
   926 lemma tendsto_sum_ereal [tendsto_intros]:
   927   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> ereal"
   928   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i \<longlongrightarrow> a i) F"
   929           "\<And>i. abs(a i) \<noteq> \<infinity>"
   930   shows "((\<lambda>x. \<Sum>i\<in>S. f i x) \<longlongrightarrow> (\<Sum>i\<in>S. a i)) F"
   931 proof (cases "finite S")
   932   assume "finite S" then show ?thesis using assms
   933     by (induct, simp, simp add: tendsto_add_ereal_general2 assms)
   934 qed(simp)
   935 
   936 
   937 lemma%important continuous_ereal_abs:
   938   "continuous_on (UNIV::ereal set) abs"
   939 proof%unimportant -
   940   have "continuous_on ({..0} \<union> {(0::ereal)..}) abs"
   941     apply (rule continuous_on_closed_Un, auto)
   942     apply (rule iffD1[OF continuous_on_cong, of "{..0}" _ "\<lambda>x. -x"])
   943     using less_eq_ereal_def apply (auto simp add: continuous_uminus_ereal)
   944     apply (rule iffD1[OF continuous_on_cong, of "{0..}" _ "\<lambda>x. x"])
   945       apply (auto simp add: continuous_on_id)
   946     done
   947   moreover have "(UNIV::ereal set) = {..0} \<union> {(0::ereal)..}" by auto
   948   ultimately show ?thesis by auto
   949 qed
   950 
   951 lemmas continuous_on_compose_ereal_abs[continuous_intros] =
   952   continuous_on_compose2[OF continuous_ereal_abs _ subset_UNIV]
   953 
   954 lemma tendsto_abs_ereal [tendsto_intros]:
   955   assumes "(u \<longlongrightarrow> (l::ereal)) F"
   956   shows "((\<lambda>n. abs(u n)) \<longlongrightarrow> abs l) F"
   957 using continuous_ereal_abs assms by (metis UNIV_I continuous_on tendsto_compose)
   958 
   959 lemma ereal_minus_real_tendsto_MInf [tendsto_intros]:
   960   "(\<lambda>x. ereal (- real x)) \<longlonglongrightarrow> - \<infinity>"
   961 by (subst uminus_ereal.simps(1)[symmetric], intro tendsto_intros)
   962 
   963 
   964 subsection%important \<open>Extended-Nonnegative-Real.thy\<close> (*FIX title *)
   965 
   966 lemma tendsto_diff_ennreal_general [tendsto_intros]:
   967   fixes u v::"'a \<Rightarrow> ennreal"
   968   assumes "(u \<longlongrightarrow> l) F" "(v \<longlongrightarrow> m) F" "\<not>(l = \<infinity> \<and> m = \<infinity>)"
   969   shows "((\<lambda>n. u n - v n) \<longlongrightarrow> l - m) F"
   970 proof -
   971   have "((\<lambda>n. e2ennreal(enn2ereal(u n) - enn2ereal(v n))) \<longlongrightarrow> e2ennreal(enn2ereal l - enn2ereal m)) F"
   972     apply (intro tendsto_intros) using assms by  auto
   973   then show ?thesis by auto
   974 qed
   975 
   976 lemma%important tendsto_mult_ennreal [tendsto_intros]:
   977   fixes l m::ennreal
   978   assumes "(u \<longlongrightarrow> l) F" "(v \<longlongrightarrow> m) F" "\<not>((l = 0 \<and> m = \<infinity>) \<or> (l = \<infinity> \<and> m = 0))"
   979   shows "((\<lambda>n. u n * v n) \<longlongrightarrow> l * m) F"
   980 proof%unimportant -
   981   have "((\<lambda>n. e2ennreal(enn2ereal (u n) * enn2ereal (v n))) \<longlongrightarrow> e2ennreal(enn2ereal l * enn2ereal m)) F"
   982     apply (intro tendsto_intros) using assms apply auto
   983     using enn2ereal_inject zero_ennreal.rep_eq by fastforce+
   984   moreover have "e2ennreal(enn2ereal (u n) * enn2ereal (v n)) = u n * v n" for n
   985     by (subst times_ennreal.abs_eq[symmetric], auto simp add: eq_onp_same_args)
   986   moreover have "e2ennreal(enn2ereal l * enn2ereal m)  = l * m"
   987     by (subst times_ennreal.abs_eq[symmetric], auto simp add: eq_onp_same_args)
   988   ultimately show ?thesis
   989     by auto
   990 qed
   991 
   992 
   993 subsection%important \<open>monoset\<close>
   994 
   995 definition%important (in order) mono_set:
   996   "mono_set S \<longleftrightarrow> (\<forall>x y. x \<le> y \<longrightarrow> x \<in> S \<longrightarrow> y \<in> S)"
   997 
   998 lemma (in order) mono_greaterThan [intro, simp]: "mono_set {B<..}" unfolding mono_set by auto
   999 lemma (in order) mono_atLeast [intro, simp]: "mono_set {B..}" unfolding mono_set by auto
  1000 lemma (in order) mono_UNIV [intro, simp]: "mono_set UNIV" unfolding mono_set by auto
  1001 lemma (in order) mono_empty [intro, simp]: "mono_set {}" unfolding mono_set by auto
  1002 
  1003 lemma%important (in complete_linorder) mono_set_iff:
  1004   fixes S :: "'a set"
  1005   defines "a \<equiv> Inf S"
  1006   shows "mono_set S \<longleftrightarrow> S = {a <..} \<or> S = {a..}" (is "_ = ?c")
  1007 proof%unimportant
  1008   assume "mono_set S"
  1009   then have mono: "\<And>x y. x \<le> y \<Longrightarrow> x \<in> S \<Longrightarrow> y \<in> S"
  1010     by (auto simp: mono_set)
  1011   show ?c
  1012   proof cases
  1013     assume "a \<in> S"
  1014     show ?c
  1015       using mono[OF _ \<open>a \<in> S\<close>]
  1016       by (auto intro: Inf_lower simp: a_def)
  1017   next
  1018     assume "a \<notin> S"
  1019     have "S = {a <..}"
  1020     proof safe
  1021       fix x assume "x \<in> S"
  1022       then have "a \<le> x"
  1023         unfolding a_def by (rule Inf_lower)
  1024       then show "a < x"
  1025         using \<open>x \<in> S\<close> \<open>a \<notin> S\<close> by (cases "a = x") auto
  1026     next
  1027       fix x assume "a < x"
  1028       then obtain y where "y < x" "y \<in> S"
  1029         unfolding a_def Inf_less_iff ..
  1030       with mono[of y x] show "x \<in> S"
  1031         by auto
  1032     qed
  1033     then show ?c ..
  1034   qed
  1035 qed auto
  1036 
  1037 lemma ereal_open_mono_set:
  1038   fixes S :: "ereal set"
  1039   shows "open S \<and> mono_set S \<longleftrightarrow> S = UNIV \<or> S = {Inf S <..}"
  1040   by (metis Inf_UNIV atLeast_eq_UNIV_iff ereal_open_atLeast
  1041     ereal_open_closed mono_set_iff open_ereal_greaterThan)
  1042 
  1043 lemma ereal_closed_mono_set:
  1044   fixes S :: "ereal set"
  1045   shows "closed S \<and> mono_set S \<longleftrightarrow> S = {} \<or> S = {Inf S ..}"
  1046   by (metis Inf_UNIV atLeast_eq_UNIV_iff closed_ereal_atLeast
  1047     ereal_open_closed mono_empty mono_set_iff open_ereal_greaterThan)
  1048 
  1049 lemma%important ereal_Liminf_Sup_monoset:
  1050   fixes f :: "'a \<Rightarrow> ereal"
  1051   shows "Liminf net f =
  1052     Sup {l. \<forall>S. open S \<longrightarrow> mono_set S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) net}"
  1053     (is "_ = Sup ?A")
  1054 proof%unimportant (safe intro!: Liminf_eqI complete_lattice_class.Sup_upper complete_lattice_class.Sup_least)
  1055   fix P
  1056   assume P: "eventually P net"
  1057   fix S
  1058   assume S: "mono_set S" "Inf (f ` (Collect P)) \<in> S"
  1059   {
  1060     fix x
  1061     assume "P x"
  1062     then have "Inf (f ` (Collect P)) \<le> f x"
  1063       by (intro complete_lattice_class.INF_lower) simp
  1064     with S have "f x \<in> S"
  1065       by (simp add: mono_set)
  1066   }
  1067   with P show "eventually (\<lambda>x. f x \<in> S) net"
  1068     by (auto elim: eventually_mono)
  1069 next
  1070   fix y l
  1071   assume S: "\<forall>S. open S \<longrightarrow> mono_set S \<longrightarrow> l \<in> S \<longrightarrow> eventually  (\<lambda>x. f x \<in> S) net"
  1072   assume P: "\<forall>P. eventually P net \<longrightarrow> Inf (f ` (Collect P)) \<le> y"
  1073   show "l \<le> y"
  1074   proof (rule dense_le)
  1075     fix B
  1076     assume "B < l"
  1077     then have "eventually (\<lambda>x. f x \<in> {B <..}) net"
  1078       by (intro S[rule_format]) auto
  1079     then have "Inf (f ` {x. B < f x}) \<le> y"
  1080       using P by auto
  1081     moreover have "B \<le> Inf (f ` {x. B < f x})"
  1082       by (intro INF_greatest) auto
  1083     ultimately show "B \<le> y"
  1084       by simp
  1085   qed
  1086 qed
  1087 
  1088 lemma%important ereal_Limsup_Inf_monoset:
  1089   fixes f :: "'a \<Rightarrow> ereal"
  1090   shows "Limsup net f =
  1091     Inf {l. \<forall>S. open S \<longrightarrow> mono_set (uminus ` S) \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) net}"
  1092     (is "_ = Inf ?A")
  1093 proof%unimportant (safe intro!: Limsup_eqI complete_lattice_class.Inf_lower complete_lattice_class.Inf_greatest)
  1094   fix P
  1095   assume P: "eventually P net"
  1096   fix S
  1097   assume S: "mono_set (uminus`S)" "Sup (f ` (Collect P)) \<in> S"
  1098   {
  1099     fix x
  1100     assume "P x"
  1101     then have "f x \<le> Sup (f ` (Collect P))"
  1102       by (intro complete_lattice_class.SUP_upper) simp
  1103     with S(1)[unfolded mono_set, rule_format, of "- Sup (f ` (Collect P))" "- f x"] S(2)
  1104     have "f x \<in> S"
  1105       by (simp add: inj_image_mem_iff) }
  1106   with P show "eventually (\<lambda>x. f x \<in> S) net"
  1107     by (auto elim: eventually_mono)
  1108 next
  1109   fix y l
  1110   assume S: "\<forall>S. open S \<longrightarrow> mono_set (uminus ` S) \<longrightarrow> l \<in> S \<longrightarrow> eventually  (\<lambda>x. f x \<in> S) net"
  1111   assume P: "\<forall>P. eventually P net \<longrightarrow> y \<le> Sup (f ` (Collect P))"
  1112   show "y \<le> l"
  1113   proof (rule dense_ge)
  1114     fix B
  1115     assume "l < B"
  1116     then have "eventually (\<lambda>x. f x \<in> {..< B}) net"
  1117       by (intro S[rule_format]) auto
  1118     then have "y \<le> Sup (f ` {x. f x < B})"
  1119       using P by auto
  1120     moreover have "Sup (f ` {x. f x < B}) \<le> B"
  1121       by (intro SUP_least) auto
  1122     ultimately show "y \<le> B"
  1123       by simp
  1124   qed
  1125 qed
  1126 
  1127 lemma%important liminf_bounded_open:
  1128   fixes x :: "nat \<Rightarrow> ereal"
  1129   shows "x0 \<le> liminf x \<longleftrightarrow> (\<forall>S. open S \<longrightarrow> mono_set S \<longrightarrow> x0 \<in> S \<longrightarrow> (\<exists>N. \<forall>n\<ge>N. x n \<in> S))"
  1130   (is "_ \<longleftrightarrow> ?P x0")
  1131 proof%unimportant
  1132   assume "?P x0"
  1133   then show "x0 \<le> liminf x"
  1134     unfolding ereal_Liminf_Sup_monoset eventually_sequentially
  1135     by (intro complete_lattice_class.Sup_upper) auto
  1136 next
  1137   assume "x0 \<le> liminf x"
  1138   {
  1139     fix S :: "ereal set"
  1140     assume om: "open S" "mono_set S" "x0 \<in> S"
  1141     {
  1142       assume "S = UNIV"
  1143       then have "\<exists>N. \<forall>n\<ge>N. x n \<in> S"
  1144         by auto
  1145     }
  1146     moreover
  1147     {
  1148       assume "S \<noteq> UNIV"
  1149       then obtain B where B: "S = {B<..}"
  1150         using om ereal_open_mono_set by auto
  1151       then have "B < x0"
  1152         using om by auto
  1153       then have "\<exists>N. \<forall>n\<ge>N. x n \<in> S"
  1154         unfolding B
  1155         using \<open>x0 \<le> liminf x\<close> liminf_bounded_iff
  1156         by auto
  1157     }
  1158     ultimately have "\<exists>N. \<forall>n\<ge>N. x n \<in> S"
  1159       by auto
  1160   }
  1161   then show "?P x0"
  1162     by auto
  1163 qed
  1164 
  1165 lemma%important limsup_finite_then_bounded:
  1166   fixes u::"nat \<Rightarrow> real"
  1167   assumes "limsup u < \<infinity>"
  1168   shows "\<exists>C. \<forall>n. u n \<le> C"
  1169 proof%unimportant -
  1170   obtain C where C: "limsup u < C" "C < \<infinity>" using assms ereal_dense2 by blast
  1171   then have "C = ereal(real_of_ereal C)" using ereal_real by force
  1172   have "eventually (\<lambda>n. u n < C) sequentially" using C(1) unfolding Limsup_def
  1173     apply (auto simp add: INF_less_iff)
  1174     using SUP_lessD eventually_mono by fastforce
  1175   then obtain N where N: "\<And>n. n \<ge> N \<Longrightarrow> u n < C" using eventually_sequentially by auto
  1176   define D where "D = max (real_of_ereal C) (Max {u n |n. n \<le> N})"
  1177   have "\<And>n. u n \<le> D"
  1178   proof -
  1179     fix n show "u n \<le> D"
  1180     proof (cases)
  1181       assume *: "n \<le> N"
  1182       have "u n \<le> Max {u n |n. n \<le> N}" by (rule Max_ge, auto simp add: *)
  1183       then show "u n \<le> D" unfolding D_def by linarith
  1184     next
  1185       assume "\<not>(n \<le> N)"
  1186       then have "n \<ge> N" by simp
  1187       then have "u n < C" using N by auto
  1188       then have "u n < real_of_ereal C" using \<open>C = ereal(real_of_ereal C)\<close> less_ereal.simps(1) by fastforce
  1189       then show "u n \<le> D" unfolding D_def by linarith
  1190     qed
  1191   qed
  1192   then show ?thesis by blast
  1193 qed
  1194 
  1195 lemma liminf_finite_then_bounded_below:
  1196   fixes u::"nat \<Rightarrow> real"
  1197   assumes "liminf u > -\<infinity>"
  1198   shows "\<exists>C. \<forall>n. u n \<ge> C"
  1199 proof -
  1200   obtain C where C: "liminf u > C" "C > -\<infinity>" using assms using ereal_dense2 by blast
  1201   then have "C = ereal(real_of_ereal C)" using ereal_real by force
  1202   have "eventually (\<lambda>n. u n > C) sequentially" using C(1) unfolding Liminf_def
  1203     apply (auto simp add: less_SUP_iff)
  1204     using eventually_elim2 less_INF_D by fastforce
  1205   then obtain N where N: "\<And>n. n \<ge> N \<Longrightarrow> u n > C" using eventually_sequentially by auto
  1206   define D where "D = min (real_of_ereal C) (Min {u n |n. n \<le> N})"
  1207   have "\<And>n. u n \<ge> D"
  1208   proof -
  1209     fix n show "u n \<ge> D"
  1210     proof (cases)
  1211       assume *: "n \<le> N"
  1212       have "u n \<ge> Min {u n |n. n \<le> N}" by (rule Min_le, auto simp add: *)
  1213       then show "u n \<ge> D" unfolding D_def by linarith
  1214     next
  1215       assume "\<not>(n \<le> N)"
  1216       then have "n \<ge> N" by simp
  1217       then have "u n > C" using N by auto
  1218       then have "u n > real_of_ereal C" using \<open>C = ereal(real_of_ereal C)\<close> less_ereal.simps(1) by fastforce
  1219       then show "u n \<ge> D" unfolding D_def by linarith
  1220     qed
  1221   qed
  1222   then show ?thesis by blast
  1223 qed
  1224 
  1225 lemma liminf_upper_bound:
  1226   fixes u:: "nat \<Rightarrow> ereal"
  1227   assumes "liminf u < l"
  1228   shows "\<exists>N>k. u N < l"
  1229 by (metis assms gt_ex less_le_trans liminf_bounded_iff not_less)
  1230 
  1231 lemma limsup_shift:
  1232   "limsup (\<lambda>n. u (n+1)) = limsup u"
  1233 proof -
  1234   have "(SUP m\<in>{n+1..}. u m) = (SUP m\<in>{n..}. u (m + 1))" for n
  1235     apply (rule SUP_eq) using Suc_le_D by auto
  1236   then have a: "(INF n. SUP m\<in>{n..}. u (m + 1)) = (INF n. (SUP m\<in>{n+1..}. u m))" by auto
  1237   have b: "(INF n. (SUP m\<in>{n+1..}. u m)) = (INF n\<in>{1..}. (SUP m\<in>{n..}. u m))"
  1238     apply (rule INF_eq) using Suc_le_D by auto
  1239   have "(INF n\<in>{1..}. v n) = (INF n. v n)" if "decseq v" for v::"nat \<Rightarrow> 'a"
  1240     apply (rule INF_eq) using \<open>decseq v\<close> decseq_Suc_iff by auto
  1241   moreover have "decseq (\<lambda>n. (SUP m\<in>{n..}. u m))" by (simp add: SUP_subset_mono decseq_def)
  1242   ultimately have c: "(INF n\<in>{1..}. (SUP m\<in>{n..}. u m)) = (INF n. (SUP m\<in>{n..}. u m))" by simp
  1243   have "(INF n. Sup (u ` {n..})) = (INF n. SUP m\<in>{n..}. u (m + 1))" using a b c by simp
  1244   then show ?thesis by (auto cong: limsup_INF_SUP)
  1245 qed
  1246 
  1247 lemma limsup_shift_k:
  1248   "limsup (\<lambda>n. u (n+k)) = limsup u"
  1249 proof (induction k)
  1250   case (Suc k)
  1251   have "limsup (\<lambda>n. u (n+k+1)) = limsup (\<lambda>n. u (n+k))" using limsup_shift[where ?u="\<lambda>n. u(n+k)"] by simp
  1252   then show ?case using Suc.IH by simp
  1253 qed (auto)
  1254 
  1255 lemma liminf_shift:
  1256   "liminf (\<lambda>n. u (n+1)) = liminf u"
  1257 proof -
  1258   have "(INF m\<in>{n+1..}. u m) = (INF m\<in>{n..}. u (m + 1))" for n
  1259     apply (rule INF_eq) using Suc_le_D by (auto)
  1260   then have a: "(SUP n. INF m\<in>{n..}. u (m + 1)) = (SUP n. (INF m\<in>{n+1..}. u m))" by auto
  1261   have b: "(SUP n. (INF m\<in>{n+1..}. u m)) = (SUP n\<in>{1..}. (INF m\<in>{n..}. u m))"
  1262     apply (rule SUP_eq) using Suc_le_D by (auto)
  1263   have "(SUP n\<in>{1..}. v n) = (SUP n. v n)" if "incseq v" for v::"nat \<Rightarrow> 'a"
  1264     apply (rule SUP_eq) using \<open>incseq v\<close> incseq_Suc_iff by auto
  1265   moreover have "incseq (\<lambda>n. (INF m\<in>{n..}. u m))" by (simp add: INF_superset_mono mono_def)
  1266   ultimately have c: "(SUP n\<in>{1..}. (INF m\<in>{n..}. u m)) = (SUP n. (INF m\<in>{n..}. u m))" by simp
  1267   have "(SUP n. Inf (u ` {n..})) = (SUP n. INF m\<in>{n..}. u (m + 1))" using a b c by simp
  1268   then show ?thesis by (auto cong: liminf_SUP_INF)
  1269 qed
  1270 
  1271 lemma liminf_shift_k:
  1272   "liminf (\<lambda>n. u (n+k)) = liminf u"
  1273 proof (induction k)
  1274   case (Suc k)
  1275   have "liminf (\<lambda>n. u (n+k+1)) = liminf (\<lambda>n. u (n+k))" using liminf_shift[where ?u="\<lambda>n. u(n+k)"] by simp
  1276   then show ?case using Suc.IH by simp
  1277 qed (auto)
  1278 
  1279 lemma%important Limsup_obtain:
  1280   fixes u::"_ \<Rightarrow> 'a :: complete_linorder"
  1281   assumes "Limsup F u > c"
  1282   shows "\<exists>i. u i > c"
  1283 proof%unimportant -
  1284   have "(INF P\<in>{P. eventually P F}. SUP x\<in>{x. P x}. u x) > c" using assms by (simp add: Limsup_def)
  1285   then show ?thesis by (metis eventually_True mem_Collect_eq less_INF_D less_SUP_iff)
  1286 qed
  1287 
  1288 text \<open>The next lemma is extremely useful, as it often makes it possible to reduce statements
  1289 about limsups to statements about limits.\<close>
  1290 
  1291 lemma%important limsup_subseq_lim:
  1292   fixes u::"nat \<Rightarrow> 'a :: {complete_linorder, linorder_topology}"
  1293   shows "\<exists>r::nat\<Rightarrow>nat. strict_mono r \<and> (u o r) \<longlonglongrightarrow> limsup u"
  1294 proof%unimportant (cases)
  1295   assume "\<forall>n. \<exists>p>n. \<forall>m\<ge>p. u m \<le> u p"
  1296   then have "\<exists>r. \<forall>n. (\<forall>m\<ge>r n. u m \<le> u (r n)) \<and> r n < r (Suc n)"
  1297     by (intro dependent_nat_choice) (auto simp: conj_commute)
  1298   then obtain r :: "nat \<Rightarrow> nat" where "strict_mono r" and mono: "\<And>n m. r n \<le> m \<Longrightarrow> u m \<le> u (r n)"
  1299     by (auto simp: strict_mono_Suc_iff)
  1300   define umax where "umax = (\<lambda>n. (SUP m\<in>{n..}. u m))"
  1301   have "decseq umax" unfolding umax_def by (simp add: SUP_subset_mono antimono_def)
  1302   then have "umax \<longlonglongrightarrow> limsup u" unfolding umax_def by (metis LIMSEQ_INF limsup_INF_SUP)
  1303   then have *: "(umax o r) \<longlonglongrightarrow> limsup u" by (simp add: LIMSEQ_subseq_LIMSEQ \<open>strict_mono r\<close>)
  1304   have "\<And>n. umax(r n) = u(r n)" unfolding umax_def using mono
  1305     by (metis SUP_le_iff antisym atLeast_def mem_Collect_eq order_refl)
  1306   then have "umax o r = u o r" unfolding o_def by simp
  1307   then have "(u o r) \<longlonglongrightarrow> limsup u" using * by simp
  1308   then show ?thesis using \<open>strict_mono r\<close> by blast
  1309 next
  1310   assume "\<not> (\<forall>n. \<exists>p>n. (\<forall>m\<ge>p. u m \<le> u p))"
  1311   then obtain N where N: "\<And>p. p > N \<Longrightarrow> \<exists>m>p. u p < u m" by (force simp: not_le le_less)
  1312   have "\<exists>r. \<forall>n. N < r n \<and> r n < r (Suc n) \<and> (\<forall>i\<in> {N<..r (Suc n)}. u i \<le> u (r (Suc n)))"
  1313   proof (rule dependent_nat_choice)
  1314     fix x assume "N < x"
  1315     then have a: "finite {N<..x}" "{N<..x} \<noteq> {}" by simp_all
  1316     have "Max {u i |i. i \<in> {N<..x}} \<in> {u i |i. i \<in> {N<..x}}" apply (rule Max_in) using a by (auto)
  1317     then obtain p where "p \<in> {N<..x}" and upmax: "u p = Max{u i |i. i \<in> {N<..x}}" by auto
  1318     define U where "U = {m. m > p \<and> u p < u m}"
  1319     have "U \<noteq> {}" unfolding U_def using N[of p] \<open>p \<in> {N<..x}\<close> by auto
  1320     define y where "y = Inf U"
  1321     then have "y \<in> U" using \<open>U \<noteq> {}\<close> by (simp add: Inf_nat_def1)
  1322     have a: "\<And>i. i \<in> {N<..x} \<Longrightarrow> u i \<le> u p"
  1323     proof -
  1324       fix i assume "i \<in> {N<..x}"
  1325       then have "u i \<in> {u i |i. i \<in> {N<..x}}" by blast
  1326       then show "u i \<le> u p" using upmax by simp
  1327     qed
  1328     moreover have "u p < u y" using \<open>y \<in> U\<close> U_def by auto
  1329     ultimately have "y \<notin> {N<..x}" using not_le by blast
  1330     moreover have "y > N" using \<open>y \<in> U\<close> U_def \<open>p \<in> {N<..x}\<close> by auto
  1331     ultimately have "y > x" by auto
  1332 
  1333     have "\<And>i. i \<in> {N<..y} \<Longrightarrow> u i \<le> u y"
  1334     proof -
  1335       fix i assume "i \<in> {N<..y}" show "u i \<le> u y"
  1336       proof (cases)
  1337         assume "i = y"
  1338         then show ?thesis by simp
  1339       next
  1340         assume "\<not>(i=y)"
  1341         then have i:"i \<in> {N<..<y}" using \<open>i \<in> {N<..y}\<close> by simp
  1342         have "u i \<le> u p"
  1343         proof (cases)
  1344           assume "i \<le> x"
  1345           then have "i \<in> {N<..x}" using i by simp
  1346           then show ?thesis using a by simp
  1347         next
  1348           assume "\<not>(i \<le> x)"
  1349           then have "i > x" by simp
  1350           then have *: "i > p" using \<open>p \<in> {N<..x}\<close> by simp
  1351           have "i < Inf U" using i y_def by simp
  1352           then have "i \<notin> U" using Inf_nat_def not_less_Least by auto
  1353           then show ?thesis using U_def * by auto
  1354         qed
  1355         then show "u i \<le> u y" using \<open>u p < u y\<close> by auto
  1356       qed
  1357     qed
  1358     then have "N < y \<and> x < y \<and> (\<forall>i\<in>{N<..y}. u i \<le> u y)" using \<open>y > x\<close> \<open>y > N\<close> by auto
  1359     then show "\<exists>y>N. x < y \<and> (\<forall>i\<in>{N<..y}. u i \<le> u y)" by auto
  1360   qed (auto)
  1361   then obtain r where r: "\<forall>n. N < r n \<and> r n < r (Suc n) \<and> (\<forall>i\<in> {N<..r (Suc n)}. u i \<le> u (r (Suc n)))" by auto
  1362   have "strict_mono r" using r by (auto simp: strict_mono_Suc_iff)
  1363   have "incseq (u o r)" unfolding o_def using r by (simp add: incseq_SucI order.strict_implies_order)
  1364   then have "(u o r) \<longlonglongrightarrow> (SUP n. (u o r) n)" using LIMSEQ_SUP by blast
  1365   then have "limsup (u o r) = (SUP n. (u o r) n)" by (simp add: lim_imp_Limsup)
  1366   moreover have "limsup (u o r) \<le> limsup u" using \<open>strict_mono r\<close> by (simp add: limsup_subseq_mono)
  1367   ultimately have "(SUP n. (u o r) n) \<le> limsup u" by simp
  1368 
  1369   {
  1370     fix i assume i: "i \<in> {N<..}"
  1371     obtain n where "i < r (Suc n)" using \<open>strict_mono r\<close> using Suc_le_eq seq_suble by blast
  1372     then have "i \<in> {N<..r(Suc n)}" using i by simp
  1373     then have "u i \<le> u (r(Suc n))" using r by simp
  1374     then have "u i \<le> (SUP n. (u o r) n)" unfolding o_def by (meson SUP_upper2 UNIV_I)
  1375   }
  1376   then have "(SUP i\<in>{N<..}. u i) \<le> (SUP n. (u o r) n)" using SUP_least by blast
  1377   then have "limsup u \<le> (SUP n. (u o r) n)" unfolding Limsup_def
  1378     by (metis (mono_tags, lifting) INF_lower2 atLeast_Suc_greaterThan atLeast_def eventually_ge_at_top mem_Collect_eq)
  1379   then have "limsup u = (SUP n. (u o r) n)" using \<open>(SUP n. (u o r) n) \<le> limsup u\<close> by simp
  1380   then have "(u o r) \<longlonglongrightarrow> limsup u" using \<open>(u o r) \<longlonglongrightarrow> (SUP n. (u o r) n)\<close> by simp
  1381   then show ?thesis using \<open>strict_mono r\<close> by auto
  1382 qed
  1383 
  1384 lemma%important liminf_subseq_lim:
  1385   fixes u::"nat \<Rightarrow> 'a :: {complete_linorder, linorder_topology}"
  1386   shows "\<exists>r::nat\<Rightarrow>nat. strict_mono r \<and> (u o r) \<longlonglongrightarrow> liminf u"
  1387 proof%unimportant (cases)
  1388   assume "\<forall>n. \<exists>p>n. \<forall>m\<ge>p. u m \<ge> u p"
  1389   then have "\<exists>r. \<forall>n. (\<forall>m\<ge>r n. u m \<ge> u (r n)) \<and> r n < r (Suc n)"
  1390     by (intro dependent_nat_choice) (auto simp: conj_commute)
  1391   then obtain r :: "nat \<Rightarrow> nat" where "strict_mono r" and mono: "\<And>n m. r n \<le> m \<Longrightarrow> u m \<ge> u (r n)"
  1392     by (auto simp: strict_mono_Suc_iff)
  1393   define umin where "umin = (\<lambda>n. (INF m\<in>{n..}. u m))"
  1394   have "incseq umin" unfolding umin_def by (simp add: INF_superset_mono incseq_def)
  1395   then have "umin \<longlonglongrightarrow> liminf u" unfolding umin_def by (metis LIMSEQ_SUP liminf_SUP_INF)
  1396   then have *: "(umin o r) \<longlonglongrightarrow> liminf u" by (simp add: LIMSEQ_subseq_LIMSEQ \<open>strict_mono r\<close>)
  1397   have "\<And>n. umin(r n) = u(r n)" unfolding umin_def using mono
  1398     by (metis le_INF_iff antisym atLeast_def mem_Collect_eq order_refl)
  1399   then have "umin o r = u o r" unfolding o_def by simp
  1400   then have "(u o r) \<longlonglongrightarrow> liminf u" using * by simp
  1401   then show ?thesis using \<open>strict_mono r\<close> by blast
  1402 next
  1403   assume "\<not> (\<forall>n. \<exists>p>n. (\<forall>m\<ge>p. u m \<ge> u p))"
  1404   then obtain N where N: "\<And>p. p > N \<Longrightarrow> \<exists>m>p. u p > u m" by (force simp: not_le le_less)
  1405   have "\<exists>r. \<forall>n. N < r n \<and> r n < r (Suc n) \<and> (\<forall>i\<in> {N<..r (Suc n)}. u i \<ge> u (r (Suc n)))"
  1406   proof (rule dependent_nat_choice)
  1407     fix x assume "N < x"
  1408     then have a: "finite {N<..x}" "{N<..x} \<noteq> {}" by simp_all
  1409     have "Min {u i |i. i \<in> {N<..x}} \<in> {u i |i. i \<in> {N<..x}}" apply (rule Min_in) using a by (auto)
  1410     then obtain p where "p \<in> {N<..x}" and upmin: "u p = Min{u i |i. i \<in> {N<..x}}" by auto
  1411     define U where "U = {m. m > p \<and> u p > u m}"
  1412     have "U \<noteq> {}" unfolding U_def using N[of p] \<open>p \<in> {N<..x}\<close> by auto
  1413     define y where "y = Inf U"
  1414     then have "y \<in> U" using \<open>U \<noteq> {}\<close> by (simp add: Inf_nat_def1)
  1415     have a: "\<And>i. i \<in> {N<..x} \<Longrightarrow> u i \<ge> u p"
  1416     proof -
  1417       fix i assume "i \<in> {N<..x}"
  1418       then have "u i \<in> {u i |i. i \<in> {N<..x}}" by blast
  1419       then show "u i \<ge> u p" using upmin by simp
  1420     qed
  1421     moreover have "u p > u y" using \<open>y \<in> U\<close> U_def by auto
  1422     ultimately have "y \<notin> {N<..x}" using not_le by blast
  1423     moreover have "y > N" using \<open>y \<in> U\<close> U_def \<open>p \<in> {N<..x}\<close> by auto
  1424     ultimately have "y > x" by auto
  1425 
  1426     have "\<And>i. i \<in> {N<..y} \<Longrightarrow> u i \<ge> u y"
  1427     proof -
  1428       fix i assume "i \<in> {N<..y}" show "u i \<ge> u y"
  1429       proof (cases)
  1430         assume "i = y"
  1431         then show ?thesis by simp
  1432       next
  1433         assume "\<not>(i=y)"
  1434         then have i:"i \<in> {N<..<y}" using \<open>i \<in> {N<..y}\<close> by simp
  1435         have "u i \<ge> u p"
  1436         proof (cases)
  1437           assume "i \<le> x"
  1438           then have "i \<in> {N<..x}" using i by simp
  1439           then show ?thesis using a by simp
  1440         next
  1441           assume "\<not>(i \<le> x)"
  1442           then have "i > x" by simp
  1443           then have *: "i > p" using \<open>p \<in> {N<..x}\<close> by simp
  1444           have "i < Inf U" using i y_def by simp
  1445           then have "i \<notin> U" using Inf_nat_def not_less_Least by auto
  1446           then show ?thesis using U_def * by auto
  1447         qed
  1448         then show "u i \<ge> u y" using \<open>u p > u y\<close> by auto
  1449       qed
  1450     qed
  1451     then have "N < y \<and> x < y \<and> (\<forall>i\<in>{N<..y}. u i \<ge> u y)" using \<open>y > x\<close> \<open>y > N\<close> by auto
  1452     then show "\<exists>y>N. x < y \<and> (\<forall>i\<in>{N<..y}. u i \<ge> u y)" by auto
  1453   qed (auto)
  1454   then obtain r :: "nat \<Rightarrow> nat" 
  1455     where r: "\<forall>n. N < r n \<and> r n < r (Suc n) \<and> (\<forall>i\<in> {N<..r (Suc n)}. u i \<ge> u (r (Suc n)))" by auto
  1456   have "strict_mono r" using r by (auto simp: strict_mono_Suc_iff)
  1457   have "decseq (u o r)" unfolding o_def using r by (simp add: decseq_SucI order.strict_implies_order)
  1458   then have "(u o r) \<longlonglongrightarrow> (INF n. (u o r) n)" using LIMSEQ_INF by blast
  1459   then have "liminf (u o r) = (INF n. (u o r) n)" by (simp add: lim_imp_Liminf)
  1460   moreover have "liminf (u o r) \<ge> liminf u" using \<open>strict_mono r\<close> by (simp add: liminf_subseq_mono)
  1461   ultimately have "(INF n. (u o r) n) \<ge> liminf u" by simp
  1462 
  1463   {
  1464     fix i assume i: "i \<in> {N<..}"
  1465     obtain n where "i < r (Suc n)" using \<open>strict_mono r\<close> using Suc_le_eq seq_suble by blast
  1466     then have "i \<in> {N<..r(Suc n)}" using i by simp
  1467     then have "u i \<ge> u (r(Suc n))" using r by simp
  1468     then have "u i \<ge> (INF n. (u o r) n)" unfolding o_def by (meson INF_lower2 UNIV_I)
  1469   }
  1470   then have "(INF i\<in>{N<..}. u i) \<ge> (INF n. (u o r) n)" using INF_greatest by blast
  1471   then have "liminf u \<ge> (INF n. (u o r) n)" unfolding Liminf_def
  1472     by (metis (mono_tags, lifting) SUP_upper2 atLeast_Suc_greaterThan atLeast_def eventually_ge_at_top mem_Collect_eq)
  1473   then have "liminf u = (INF n. (u o r) n)" using \<open>(INF n. (u o r) n) \<ge> liminf u\<close> by simp
  1474   then have "(u o r) \<longlonglongrightarrow> liminf u" using \<open>(u o r) \<longlonglongrightarrow> (INF n. (u o r) n)\<close> by simp
  1475   then show ?thesis using \<open>strict_mono r\<close> by auto
  1476 qed
  1477 
  1478 text \<open>The following statement about limsups is reduced to a statement about limits using
  1479 subsequences thanks to \verb+limsup_subseq_lim+. The statement for limits follows for instance from
  1480 \verb+tendsto_add_ereal_general+.\<close>
  1481 
  1482 lemma%important ereal_limsup_add_mono:
  1483   fixes u v::"nat \<Rightarrow> ereal"
  1484   shows "limsup (\<lambda>n. u n + v n) \<le> limsup u + limsup v"
  1485 proof%unimportant (cases)
  1486   assume "(limsup u = \<infinity>) \<or> (limsup v = \<infinity>)"
  1487   then have "limsup u + limsup v = \<infinity>" by simp
  1488   then show ?thesis by auto
  1489 next
  1490   assume "\<not>((limsup u = \<infinity>) \<or> (limsup v = \<infinity>))"
  1491   then have "limsup u < \<infinity>" "limsup v < \<infinity>" by auto
  1492 
  1493   define w where "w = (\<lambda>n. u n + v n)"
  1494   obtain r where r: "strict_mono r" "(w o r) \<longlonglongrightarrow> limsup w" using limsup_subseq_lim by auto
  1495   obtain s where s: "strict_mono s" "(u o r o s) \<longlonglongrightarrow> limsup (u o r)" using limsup_subseq_lim by auto
  1496   obtain t where t: "strict_mono t" "(v o r o s o t) \<longlonglongrightarrow> limsup (v o r o s)" using limsup_subseq_lim by auto
  1497 
  1498   define a where "a = r o s o t"
  1499   have "strict_mono a" using r s t by (simp add: a_def strict_mono_o)
  1500   have l:"(w o a) \<longlonglongrightarrow> limsup w"
  1501          "(u o a) \<longlonglongrightarrow> limsup (u o r)"
  1502          "(v o a) \<longlonglongrightarrow> limsup (v o r o s)"
  1503   apply (metis (no_types, lifting) r(2) s(1) t(1) LIMSEQ_subseq_LIMSEQ a_def comp_assoc)
  1504   apply (metis (no_types, lifting) s(2) t(1) LIMSEQ_subseq_LIMSEQ a_def comp_assoc)
  1505   apply (metis (no_types, lifting) t(2) a_def comp_assoc)
  1506   done
  1507 
  1508   have "limsup (u o r) \<le> limsup u" by (simp add: limsup_subseq_mono r(1))
  1509   then have a: "limsup (u o r) \<noteq> \<infinity>" using \<open>limsup u < \<infinity>\<close> by auto
  1510   have "limsup (v o r o s) \<le> limsup v" 
  1511     by (simp add: comp_assoc limsup_subseq_mono r(1) s(1) strict_mono_o)
  1512   then have b: "limsup (v o r o s) \<noteq> \<infinity>" using \<open>limsup v < \<infinity>\<close> by auto
  1513 
  1514   have "(\<lambda>n. (u o a) n + (v o a) n) \<longlonglongrightarrow> limsup (u o r) + limsup (v o r o s)"
  1515     using l tendsto_add_ereal_general a b by fastforce
  1516   moreover have "(\<lambda>n. (u o a) n + (v o a) n) = (w o a)" unfolding w_def by auto
  1517   ultimately have "(w o a) \<longlonglongrightarrow> limsup (u o r) + limsup (v o r o s)" by simp
  1518   then have "limsup w = limsup (u o r) + limsup (v o r o s)" using l(1) LIMSEQ_unique by blast
  1519   then have "limsup w \<le> limsup u + limsup v"
  1520     using \<open>limsup (u o r) \<le> limsup u\<close> \<open>limsup (v o r o s) \<le> limsup v\<close> add_mono by simp
  1521   then show ?thesis unfolding w_def by simp
  1522 qed
  1523 
  1524 text \<open>There is an asymmetry between liminfs and limsups in ereal, as $\infty + (-\infty) = \infty$.
  1525 This explains why there are more assumptions in the next lemma dealing with liminfs that in the
  1526 previous one about limsups.\<close>
  1527 
  1528 lemma%important ereal_liminf_add_mono:
  1529   fixes u v::"nat \<Rightarrow> ereal"
  1530   assumes "\<not>((liminf u = \<infinity> \<and> liminf v = -\<infinity>) \<or> (liminf u = -\<infinity> \<and> liminf v = \<infinity>))"
  1531   shows "liminf (\<lambda>n. u n + v n) \<ge> liminf u + liminf v"
  1532 proof%unimportant (cases)
  1533   assume "(liminf u = -\<infinity>) \<or> (liminf v = -\<infinity>)"
  1534   then have *: "liminf u + liminf v = -\<infinity>" using assms by auto
  1535   show ?thesis by (simp add: *)
  1536 next
  1537   assume "\<not>((liminf u = -\<infinity>) \<or> (liminf v = -\<infinity>))"
  1538   then have "liminf u > -\<infinity>" "liminf v > -\<infinity>" by auto
  1539 
  1540   define w where "w = (\<lambda>n. u n + v n)"
  1541   obtain r where r: "strict_mono r" "(w o r) \<longlonglongrightarrow> liminf w" using liminf_subseq_lim by auto
  1542   obtain s where s: "strict_mono s" "(u o r o s) \<longlonglongrightarrow> liminf (u o r)" using liminf_subseq_lim by auto
  1543   obtain t where t: "strict_mono t" "(v o r o s o t) \<longlonglongrightarrow> liminf (v o r o s)" using liminf_subseq_lim by auto
  1544 
  1545   define a where "a = r o s o t"
  1546   have "strict_mono a" using r s t by (simp add: a_def strict_mono_o)
  1547   have l:"(w o a) \<longlonglongrightarrow> liminf w"
  1548          "(u o a) \<longlonglongrightarrow> liminf (u o r)"
  1549          "(v o a) \<longlonglongrightarrow> liminf (v o r o s)"
  1550   apply (metis (no_types, lifting) r(2) s(1) t(1) LIMSEQ_subseq_LIMSEQ a_def comp_assoc)
  1551   apply (metis (no_types, lifting) s(2) t(1) LIMSEQ_subseq_LIMSEQ a_def comp_assoc)
  1552   apply (metis (no_types, lifting) t(2) a_def comp_assoc)
  1553   done
  1554 
  1555   have "liminf (u o r) \<ge> liminf u" by (simp add: liminf_subseq_mono r(1))
  1556   then have a: "liminf (u o r) \<noteq> -\<infinity>" using \<open>liminf u > -\<infinity>\<close> by auto
  1557   have "liminf (v o r o s) \<ge> liminf v" 
  1558     by (simp add: comp_assoc liminf_subseq_mono r(1) s(1) strict_mono_o)
  1559   then have b: "liminf (v o r o s) \<noteq> -\<infinity>" using \<open>liminf v > -\<infinity>\<close> by auto
  1560 
  1561   have "(\<lambda>n. (u o a) n + (v o a) n) \<longlonglongrightarrow> liminf (u o r) + liminf (v o r o s)"
  1562     using l tendsto_add_ereal_general a b by fastforce
  1563   moreover have "(\<lambda>n. (u o a) n + (v o a) n) = (w o a)" unfolding w_def by auto
  1564   ultimately have "(w o a) \<longlonglongrightarrow> liminf (u o r) + liminf (v o r o s)" by simp
  1565   then have "liminf w = liminf (u o r) + liminf (v o r o s)" using l(1) LIMSEQ_unique by blast
  1566   then have "liminf w \<ge> liminf u + liminf v"
  1567     using \<open>liminf (u o r) \<ge> liminf u\<close> \<open>liminf (v o r o s) \<ge> liminf v\<close> add_mono by simp
  1568   then show ?thesis unfolding w_def by simp
  1569 qed
  1570 
  1571 lemma%important ereal_limsup_lim_add:
  1572   fixes u v::"nat \<Rightarrow> ereal"
  1573   assumes "u \<longlonglongrightarrow> a" "abs(a) \<noteq> \<infinity>"
  1574   shows "limsup (\<lambda>n. u n + v n) = a + limsup v"
  1575 proof%unimportant -
  1576   have "limsup u = a" using assms(1) using tendsto_iff_Liminf_eq_Limsup trivial_limit_at_top_linorder by blast
  1577   have "(\<lambda>n. -u n) \<longlonglongrightarrow> -a" using assms(1) by auto
  1578   then have "limsup (\<lambda>n. -u n) = -a" using tendsto_iff_Liminf_eq_Limsup trivial_limit_at_top_linorder by blast
  1579 
  1580   have "limsup (\<lambda>n. u n + v n) \<le> limsup u + limsup v"
  1581     by (rule ereal_limsup_add_mono)
  1582   then have up: "limsup (\<lambda>n. u n + v n) \<le> a + limsup v" using \<open>limsup u = a\<close> by simp
  1583 
  1584   have a: "limsup (\<lambda>n. (u n + v n) + (-u n)) \<le> limsup (\<lambda>n. u n + v n) + limsup (\<lambda>n. -u n)"
  1585     by (rule ereal_limsup_add_mono)
  1586   have "eventually (\<lambda>n. u n = ereal(real_of_ereal(u n))) sequentially" using assms
  1587     real_lim_then_eventually_real by auto
  1588   moreover have "\<And>x. x = ereal(real_of_ereal(x)) \<Longrightarrow> x + (-x) = 0"
  1589     by (metis plus_ereal.simps(1) right_minus uminus_ereal.simps(1) zero_ereal_def)
  1590   ultimately have "eventually (\<lambda>n. u n + (-u n) = 0) sequentially"
  1591     by (metis (mono_tags, lifting) eventually_mono)
  1592   moreover have "\<And>n. u n + (-u n) = 0 \<Longrightarrow> u n + v n + (-u n) = v n"
  1593     by (metis add.commute add.left_commute add.left_neutral)
  1594   ultimately have "eventually (\<lambda>n. u n + v n + (-u n) = v n) sequentially"
  1595     using eventually_mono by force
  1596   then have "limsup v = limsup (\<lambda>n. u n + v n + (-u n))" using Limsup_eq by force
  1597   then have "limsup v \<le> limsup (\<lambda>n. u n + v n) -a" using a \<open>limsup (\<lambda>n. -u n) = -a\<close> by (simp add: minus_ereal_def)
  1598   then have "limsup (\<lambda>n. u n + v n) \<ge> a + limsup v" using assms(2) by (metis add.commute ereal_le_minus)
  1599   then show ?thesis using up by simp
  1600 qed
  1601 
  1602 lemma%important ereal_limsup_lim_mult:
  1603   fixes u v::"nat \<Rightarrow> ereal"
  1604   assumes "u \<longlonglongrightarrow> a" "a>0" "a \<noteq> \<infinity>"
  1605   shows "limsup (\<lambda>n. u n * v n) = a * limsup v"
  1606 proof%unimportant -
  1607   define w where "w = (\<lambda>n. u n * v n)"
  1608   obtain r where r: "strict_mono r" "(v o r) \<longlonglongrightarrow> limsup v" using limsup_subseq_lim by auto
  1609   have "(u o r) \<longlonglongrightarrow> a" using assms(1) LIMSEQ_subseq_LIMSEQ r by auto
  1610   with tendsto_mult_ereal[OF this r(2)] have "(\<lambda>n. (u o r) n * (v o r) n) \<longlonglongrightarrow> a * limsup v" using assms(2) assms(3) by auto
  1611   moreover have "\<And>n. (w o r) n = (u o r) n * (v o r) n" unfolding w_def by auto
  1612   ultimately have "(w o r) \<longlonglongrightarrow> a * limsup v" unfolding w_def by presburger
  1613   then have "limsup (w o r) = a * limsup v" by (simp add: tendsto_iff_Liminf_eq_Limsup)
  1614   then have I: "limsup w \<ge> a * limsup v" by (metis limsup_subseq_mono r(1))
  1615 
  1616   obtain s where s: "strict_mono s" "(w o s) \<longlonglongrightarrow> limsup w" using limsup_subseq_lim by auto
  1617   have *: "(u o s) \<longlonglongrightarrow> a" using assms(1) LIMSEQ_subseq_LIMSEQ s by auto
  1618   have "eventually (\<lambda>n. (u o s) n > 0) sequentially" using assms(2) * order_tendsto_iff by blast
  1619   moreover have "eventually (\<lambda>n. (u o s) n < \<infinity>) sequentially" using assms(3) * order_tendsto_iff by blast
  1620   moreover have "(w o s) n / (u o s) n = (v o s) n" if "(u o s) n > 0" "(u o s) n < \<infinity>" for n
  1621     unfolding w_def using that by (auto simp add: ereal_divide_eq)
  1622   ultimately have "eventually (\<lambda>n. (w o s) n / (u o s) n = (v o s) n) sequentially" using eventually_elim2 by force
  1623   moreover have "(\<lambda>n. (w o s) n / (u o s) n) \<longlonglongrightarrow> (limsup w) / a"
  1624     apply (rule tendsto_divide_ereal[OF s(2) *]) using assms(2) assms(3) by auto
  1625   ultimately have "(v o s) \<longlonglongrightarrow> (limsup w) / a" using Lim_transform_eventually by fastforce
  1626   then have "limsup (v o s) = (limsup w) / a" by (simp add: tendsto_iff_Liminf_eq_Limsup)
  1627   then have "limsup v \<ge> (limsup w) / a" by (metis limsup_subseq_mono s(1))
  1628   then have "a * limsup v \<ge> limsup w" using assms(2) assms(3) by (simp add: ereal_divide_le_pos)
  1629   then show ?thesis using I unfolding w_def by auto
  1630 qed
  1631 
  1632 lemma%important ereal_liminf_lim_mult:
  1633   fixes u v::"nat \<Rightarrow> ereal"
  1634   assumes "u \<longlonglongrightarrow> a" "a>0" "a \<noteq> \<infinity>"
  1635   shows "liminf (\<lambda>n. u n * v n) = a * liminf v"
  1636 proof%unimportant -
  1637   define w where "w = (\<lambda>n. u n * v n)"
  1638   obtain r where r: "strict_mono r" "(v o r) \<longlonglongrightarrow> liminf v" using liminf_subseq_lim by auto
  1639   have "(u o r) \<longlonglongrightarrow> a" using assms(1) LIMSEQ_subseq_LIMSEQ r by auto
  1640   with tendsto_mult_ereal[OF this r(2)] have "(\<lambda>n. (u o r) n * (v o r) n) \<longlonglongrightarrow> a * liminf v" using assms(2) assms(3) by auto
  1641   moreover have "\<And>n. (w o r) n = (u o r) n * (v o r) n" unfolding w_def by auto
  1642   ultimately have "(w o r) \<longlonglongrightarrow> a * liminf v" unfolding w_def by presburger
  1643   then have "liminf (w o r) = a * liminf v" by (simp add: tendsto_iff_Liminf_eq_Limsup)
  1644   then have I: "liminf w \<le> a * liminf v" by (metis liminf_subseq_mono r(1))
  1645 
  1646   obtain s where s: "strict_mono s" "(w o s) \<longlonglongrightarrow> liminf w" using liminf_subseq_lim by auto
  1647   have *: "(u o s) \<longlonglongrightarrow> a" using assms(1) LIMSEQ_subseq_LIMSEQ s by auto
  1648   have "eventually (\<lambda>n. (u o s) n > 0) sequentially" using assms(2) * order_tendsto_iff by blast
  1649   moreover have "eventually (\<lambda>n. (u o s) n < \<infinity>) sequentially" using assms(3) * order_tendsto_iff by blast
  1650   moreover have "(w o s) n / (u o s) n = (v o s) n" if "(u o s) n > 0" "(u o s) n < \<infinity>" for n
  1651     unfolding w_def using that by (auto simp add: ereal_divide_eq)
  1652   ultimately have "eventually (\<lambda>n. (w o s) n / (u o s) n = (v o s) n) sequentially" using eventually_elim2 by force
  1653   moreover have "(\<lambda>n. (w o s) n / (u o s) n) \<longlonglongrightarrow> (liminf w) / a"
  1654     apply (rule tendsto_divide_ereal[OF s(2) *]) using assms(2) assms(3) by auto
  1655   ultimately have "(v o s) \<longlonglongrightarrow> (liminf w) / a" using Lim_transform_eventually by fastforce
  1656   then have "liminf (v o s) = (liminf w) / a" by (simp add: tendsto_iff_Liminf_eq_Limsup)
  1657   then have "liminf v \<le> (liminf w) / a" by (metis liminf_subseq_mono s(1))
  1658   then have "a * liminf v \<le> liminf w" using assms(2) assms(3) by (simp add: ereal_le_divide_pos)
  1659   then show ?thesis using I unfolding w_def by auto
  1660 qed
  1661 
  1662 lemma%important ereal_liminf_lim_add:
  1663   fixes u v::"nat \<Rightarrow> ereal"
  1664   assumes "u \<longlonglongrightarrow> a" "abs(a) \<noteq> \<infinity>"
  1665   shows "liminf (\<lambda>n. u n + v n) = a + liminf v"
  1666 proof%unimportant -
  1667   have "liminf u = a" using assms(1) tendsto_iff_Liminf_eq_Limsup trivial_limit_at_top_linorder by blast
  1668   then have *: "abs(liminf u) \<noteq> \<infinity>" using assms(2) by auto
  1669   have "(\<lambda>n. -u n) \<longlonglongrightarrow> -a" using assms(1) by auto
  1670   then have "liminf (\<lambda>n. -u n) = -a" using tendsto_iff_Liminf_eq_Limsup trivial_limit_at_top_linorder by blast
  1671   then have **: "abs(liminf (\<lambda>n. -u n)) \<noteq> \<infinity>" using assms(2) by auto
  1672 
  1673   have "liminf (\<lambda>n. u n + v n) \<ge> liminf u + liminf v"
  1674     apply (rule ereal_liminf_add_mono) using * by auto
  1675   then have up: "liminf (\<lambda>n. u n + v n) \<ge> a + liminf v" using \<open>liminf u = a\<close> by simp
  1676 
  1677   have a: "liminf (\<lambda>n. (u n + v n) + (-u n)) \<ge> liminf (\<lambda>n. u n + v n) + liminf (\<lambda>n. -u n)"
  1678     apply (rule ereal_liminf_add_mono) using ** by auto
  1679   have "eventually (\<lambda>n. u n = ereal(real_of_ereal(u n))) sequentially" using assms
  1680     real_lim_then_eventually_real by auto
  1681   moreover have "\<And>x. x = ereal(real_of_ereal(x)) \<Longrightarrow> x + (-x) = 0"
  1682     by (metis plus_ereal.simps(1) right_minus uminus_ereal.simps(1) zero_ereal_def)
  1683   ultimately have "eventually (\<lambda>n. u n + (-u n) = 0) sequentially"
  1684     by (metis (mono_tags, lifting) eventually_mono)
  1685   moreover have "\<And>n. u n + (-u n) = 0 \<Longrightarrow> u n + v n + (-u n) = v n"
  1686     by (metis add.commute add.left_commute add.left_neutral)
  1687   ultimately have "eventually (\<lambda>n. u n + v n + (-u n) = v n) sequentially"
  1688     using eventually_mono by force
  1689   then have "liminf v = liminf (\<lambda>n. u n + v n + (-u n))" using Liminf_eq by force
  1690   then have "liminf v \<ge> liminf (\<lambda>n. u n + v n) -a" using a \<open>liminf (\<lambda>n. -u n) = -a\<close> by (simp add: minus_ereal_def)
  1691   then have "liminf (\<lambda>n. u n + v n) \<le> a + liminf v" using assms(2) by (metis add.commute ereal_minus_le)
  1692   then show ?thesis using up by simp
  1693 qed
  1694 
  1695 lemma%important ereal_liminf_limsup_add:
  1696   fixes u v::"nat \<Rightarrow> ereal"
  1697   shows "liminf (\<lambda>n. u n + v n) \<le> liminf u + limsup v"
  1698 proof%unimportant (cases)
  1699   assume "limsup v = \<infinity> \<or> liminf u = \<infinity>"
  1700   then show ?thesis by auto
  1701 next
  1702   assume "\<not>(limsup v = \<infinity> \<or> liminf u = \<infinity>)"
  1703   then have "limsup v < \<infinity>" "liminf u < \<infinity>" by auto
  1704 
  1705   define w where "w = (\<lambda>n. u n + v n)"
  1706   obtain r where r: "strict_mono r" "(u o r) \<longlonglongrightarrow> liminf u" using liminf_subseq_lim by auto
  1707   obtain s where s: "strict_mono s" "(w o r o s) \<longlonglongrightarrow> liminf (w o r)" using liminf_subseq_lim by auto
  1708   obtain t where t: "strict_mono t" "(v o r o s o t) \<longlonglongrightarrow> limsup (v o r o s)" using limsup_subseq_lim by auto
  1709 
  1710   define a where "a = r o s o t"
  1711   have "strict_mono a" using r s t by (simp add: a_def strict_mono_o)
  1712   have l:"(u o a) \<longlonglongrightarrow> liminf u"
  1713          "(w o a) \<longlonglongrightarrow> liminf (w o r)"
  1714          "(v o a) \<longlonglongrightarrow> limsup (v o r o s)"
  1715   apply (metis (no_types, lifting) r(2) s(1) t(1) LIMSEQ_subseq_LIMSEQ a_def comp_assoc)
  1716   apply (metis (no_types, lifting) s(2) t(1) LIMSEQ_subseq_LIMSEQ a_def comp_assoc)
  1717   apply (metis (no_types, lifting) t(2) a_def comp_assoc)
  1718   done
  1719 
  1720   have "liminf (w o r) \<ge> liminf w" by (simp add: liminf_subseq_mono r(1))
  1721   have "limsup (v o r o s) \<le> limsup v" 
  1722     by (simp add: comp_assoc limsup_subseq_mono r(1) s(1) strict_mono_o)
  1723   then have b: "limsup (v o r o s) < \<infinity>" using \<open>limsup v < \<infinity>\<close> by auto
  1724 
  1725   have "(\<lambda>n. (u o a) n + (v o a) n) \<longlonglongrightarrow> liminf u + limsup (v o r o s)"
  1726     apply (rule tendsto_add_ereal_general) using b \<open>liminf u < \<infinity>\<close> l(1) l(3) by force+
  1727   moreover have "(\<lambda>n. (u o a) n + (v o a) n) = (w o a)" unfolding w_def by auto
  1728   ultimately have "(w o a) \<longlonglongrightarrow> liminf u + limsup (v o r o s)" by simp
  1729   then have "liminf (w o r) = liminf u + limsup (v o r o s)" using l(2) using LIMSEQ_unique by blast
  1730   then have "liminf w \<le> liminf u + limsup v"
  1731     using \<open>liminf (w o r) \<ge> liminf w\<close> \<open>limsup (v o r o s) \<le> limsup v\<close>
  1732     by (metis add_mono_thms_linordered_semiring(2) le_less_trans not_less)
  1733   then show ?thesis unfolding w_def by simp
  1734 qed
  1735 
  1736 lemma ereal_liminf_limsup_minus:
  1737   fixes u v::"nat \<Rightarrow> ereal"
  1738   shows "liminf (\<lambda>n. u n - v n) \<le> limsup u - limsup v"
  1739   unfolding minus_ereal_def
  1740   apply (subst add.commute)
  1741   apply (rule order_trans[OF ereal_liminf_limsup_add])
  1742   using ereal_Limsup_uminus[of sequentially "\<lambda>n. - v n"]
  1743   apply (simp add: add.commute)
  1744   done
  1745 
  1746 
  1747 lemma%important liminf_minus_ennreal:
  1748   fixes u v::"nat \<Rightarrow> ennreal"
  1749   shows "(\<And>n. v n \<le> u n) \<Longrightarrow> liminf (\<lambda>n. u n - v n) \<le> limsup u - limsup v"
  1750   unfolding liminf_SUP_INF limsup_INF_SUP
  1751   including ennreal.lifting
  1752 proof%unimportant (transfer, clarsimp)
  1753   fix v u :: "nat \<Rightarrow> ereal" assume *: "\<forall>x. 0 \<le> v x" "\<forall>x. 0 \<le> u x" "\<And>n. v n \<le> u n"
  1754   moreover have "0 \<le> limsup u - limsup v"
  1755     using * by (intro ereal_diff_positive Limsup_mono always_eventually) simp
  1756   moreover have "0 \<le> Sup (u ` {x..})" for x
  1757     using * by (intro SUP_upper2[of x]) auto
  1758   moreover have "0 \<le> Sup (v ` {x..})" for x
  1759     using * by (intro SUP_upper2[of x]) auto
  1760   ultimately show "(SUP n. INF n\<in>{n..}. max 0 (u n - v n))
  1761             \<le> max 0 ((INF x. max 0 (Sup (u ` {x..}))) - (INF x. max 0 (Sup (v ` {x..}))))"
  1762     by (auto simp: * ereal_diff_positive max.absorb2 liminf_SUP_INF[symmetric] limsup_INF_SUP[symmetric] ereal_liminf_limsup_minus)
  1763 qed
  1764 
  1765 subsection%unimportant "Relate extended reals and the indicator function"
  1766 
  1767 lemma ereal_indicator_le_0: "(indicator S x::ereal) \<le> 0 \<longleftrightarrow> x \<notin> S"
  1768   by (auto split: split_indicator simp: one_ereal_def)
  1769 
  1770 lemma ereal_indicator: "ereal (indicator A x) = indicator A x"
  1771   by (auto simp: indicator_def one_ereal_def)
  1772 
  1773 lemma ereal_mult_indicator: "ereal (x * indicator A y) = ereal x * indicator A y"
  1774   by (simp split: split_indicator)
  1775 
  1776 lemma ereal_indicator_mult: "ereal (indicator A y * x) = indicator A y * ereal x"
  1777   by (simp split: split_indicator)
  1778 
  1779 lemma ereal_indicator_nonneg[simp, intro]: "0 \<le> (indicator A x ::ereal)"
  1780   unfolding indicator_def by auto
  1781 
  1782 lemma indicator_inter_arith_ereal: "indicator A x * indicator B x = (indicator (A \<inter> B) x :: ereal)"
  1783   by (simp split: split_indicator)
  1784 
  1785 end