src/HOL/Algebra/UnivPoly.thy
author ballarin
Mon Jul 26 15:48:50 2004 +0200 (2004-07-26)
changeset 15076 4b3d280ef06a
parent 15045 d59f7e2e18d3
child 15095 63f5f4c265dd
permissions -rw-r--r--
New prover for transitive and reflexive-transitive closure of relations.
- Code in Provers/trancl.ML
- HOL: Simplifier set up to use it as solver
     1 (*
     2   Title:     HOL/Algebra/UnivPoly.thy
     3   Id:        $Id$
     4   Author:    Clemens Ballarin, started 9 December 1996
     5   Copyright: Clemens Ballarin
     6 *)
     7 
     8 header {* Univariate Polynomials *}
     9 
    10 theory UnivPoly = Module:
    11 
    12 text {*
    13   Polynomials are formalised as modules with additional operations for
    14   extracting coefficients from polynomials and for obtaining monomials
    15   from coefficients and exponents (record @{text "up_ring"}).  The
    16   carrier set is a set of bounded functions from Nat to the
    17   coefficient domain.  Bounded means that these functions return zero
    18   above a certain bound (the degree).  There is a chapter on the
    19   formalisation of polynomials in the PhD thesis \cite{Ballarin:1999},
    20   which was implemented with axiomatic type classes.  This was later
    21   ported to Locales.
    22 *}
    23 
    24 
    25 subsection {* The Constructor for Univariate Polynomials *}
    26 
    27 locale bound =
    28   fixes z :: 'a
    29     and n :: nat
    30     and f :: "nat => 'a"
    31   assumes bound: "!!m. n < m \<Longrightarrow> f m = z"
    32 
    33 declare bound.intro [intro!]
    34   and bound.bound [dest]
    35 
    36 lemma bound_below:
    37   assumes bound: "bound z m f" and nonzero: "f n \<noteq> z" shows "n \<le> m"
    38 proof (rule classical)
    39   assume "~ ?thesis"
    40   then have "m < n" by arith
    41   with bound have "f n = z" ..
    42   with nonzero show ?thesis by contradiction
    43 qed
    44 
    45 record ('a, 'p) up_ring = "('a, 'p) module" +
    46   monom :: "['a, nat] => 'p"
    47   coeff :: "['p, nat] => 'a"
    48 
    49 constdefs (structure R)
    50   up :: "_ => (nat => 'a) set"
    51   "up R == {f. f \<in> UNIV -> carrier R & (EX n. bound \<zero> n f)}"
    52   UP :: "_ => ('a, nat => 'a) up_ring"
    53   "UP R == (|
    54     carrier = up R,
    55     mult = (%p:up R. %q:up R. %n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n-i)),
    56     one = (%i. if i=0 then \<one> else \<zero>),
    57     zero = (%i. \<zero>),
    58     add = (%p:up R. %q:up R. %i. p i \<oplus> q i),
    59     smult = (%a:carrier R. %p:up R. %i. a \<otimes> p i),
    60     monom = (%a:carrier R. %n i. if i=n then a else \<zero>),
    61     coeff = (%p:up R. %n. p n) |)"
    62 
    63 text {*
    64   Properties of the set of polynomials @{term up}.
    65 *}
    66 
    67 lemma mem_upI [intro]:
    68   "[| !!n. f n \<in> carrier R; EX n. bound (zero R) n f |] ==> f \<in> up R"
    69   by (simp add: up_def Pi_def)
    70 
    71 lemma mem_upD [dest]:
    72   "f \<in> up R ==> f n \<in> carrier R"
    73   by (simp add: up_def Pi_def)
    74 
    75 lemma (in cring) bound_upD [dest]:
    76   "f \<in> up R ==> EX n. bound \<zero> n f"
    77   by (simp add: up_def)
    78 
    79 lemma (in cring) up_one_closed:
    80    "(%n. if n = 0 then \<one> else \<zero>) \<in> up R"
    81   using up_def by force
    82 
    83 lemma (in cring) up_smult_closed:
    84   "[| a \<in> carrier R; p \<in> up R |] ==> (%i. a \<otimes> p i) \<in> up R"
    85   by force
    86 
    87 lemma (in cring) up_add_closed:
    88   "[| p \<in> up R; q \<in> up R |] ==> (%i. p i \<oplus> q i) \<in> up R"
    89 proof
    90   fix n
    91   assume "p \<in> up R" and "q \<in> up R"
    92   then show "p n \<oplus> q n \<in> carrier R"
    93     by auto
    94 next
    95   assume UP: "p \<in> up R" "q \<in> up R"
    96   show "EX n. bound \<zero> n (%i. p i \<oplus> q i)"
    97   proof -
    98     from UP obtain n where boundn: "bound \<zero> n p" by fast
    99     from UP obtain m where boundm: "bound \<zero> m q" by fast
   100     have "bound \<zero> (max n m) (%i. p i \<oplus> q i)"
   101     proof
   102       fix i
   103       assume "max n m < i"
   104       with boundn and boundm and UP show "p i \<oplus> q i = \<zero>" by fastsimp
   105     qed
   106     then show ?thesis ..
   107   qed
   108 qed
   109 
   110 lemma (in cring) up_a_inv_closed:
   111   "p \<in> up R ==> (%i. \<ominus> (p i)) \<in> up R"
   112 proof
   113   assume R: "p \<in> up R"
   114   then obtain n where "bound \<zero> n p" by auto
   115   then have "bound \<zero> n (%i. \<ominus> p i)" by auto
   116   then show "EX n. bound \<zero> n (%i. \<ominus> p i)" by auto
   117 qed auto
   118 
   119 lemma (in cring) up_mult_closed:
   120   "[| p \<in> up R; q \<in> up R |] ==>
   121   (%n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n-i)) \<in> up R"
   122 proof
   123   fix n
   124   assume "p \<in> up R" "q \<in> up R"
   125   then show "(\<Oplus>i \<in> {..n}. p i \<otimes> q (n-i)) \<in> carrier R"
   126     by (simp add: mem_upD  funcsetI)
   127 next
   128   assume UP: "p \<in> up R" "q \<in> up R"
   129   show "EX n. bound \<zero> n (%n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n-i))"
   130   proof -
   131     from UP obtain n where boundn: "bound \<zero> n p" by fast
   132     from UP obtain m where boundm: "bound \<zero> m q" by fast
   133     have "bound \<zero> (n + m) (%n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n - i))"
   134     proof
   135       fix k assume bound: "n + m < k"
   136       {
   137         fix i
   138         have "p i \<otimes> q (k-i) = \<zero>"
   139         proof (cases "n < i")
   140           case True
   141           with boundn have "p i = \<zero>" by auto
   142           moreover from UP have "q (k-i) \<in> carrier R" by auto
   143           ultimately show ?thesis by simp
   144         next
   145           case False
   146           with bound have "m < k-i" by arith
   147           with boundm have "q (k-i) = \<zero>" by auto
   148           moreover from UP have "p i \<in> carrier R" by auto
   149           ultimately show ?thesis by simp
   150         qed
   151       }
   152       then show "(\<Oplus>i \<in> {..k}. p i \<otimes> q (k-i)) = \<zero>"
   153         by (simp add: Pi_def)
   154     qed
   155     then show ?thesis by fast
   156   qed
   157 qed
   158 
   159 
   160 subsection {* Effect of operations on coefficients *}
   161 
   162 locale UP = struct R + struct P +
   163   defines P_def: "P == UP R"
   164 
   165 locale UP_cring = UP + cring R
   166 
   167 locale UP_domain = UP_cring + "domain" R
   168 
   169 text {*
   170   Temporarily declare @{text UP.P_def} as simp rule.
   171 *}  (* TODO: use antiquotation once text (in locale) is supported. *)
   172 
   173 declare (in UP) P_def [simp]
   174 
   175 lemma (in UP_cring) coeff_monom [simp]:
   176   "a \<in> carrier R ==>
   177   coeff P (monom P a m) n = (if m=n then a else \<zero>)"
   178 proof -
   179   assume R: "a \<in> carrier R"
   180   then have "(%n. if n = m then a else \<zero>) \<in> up R"
   181     using up_def by force
   182   with R show ?thesis by (simp add: UP_def)
   183 qed
   184 
   185 lemma (in UP_cring) coeff_zero [simp]:
   186   "coeff P \<zero>\<^sub>2 n = \<zero>"
   187   by (auto simp add: UP_def)
   188 
   189 lemma (in UP_cring) coeff_one [simp]:
   190   "coeff P \<one>\<^sub>2 n = (if n=0 then \<one> else \<zero>)"
   191   using up_one_closed by (simp add: UP_def)
   192 
   193 lemma (in UP_cring) coeff_smult [simp]:
   194   "[| a \<in> carrier R; p \<in> carrier P |] ==>
   195   coeff P (a \<odot>\<^sub>2 p) n = a \<otimes> coeff P p n"
   196   by (simp add: UP_def up_smult_closed)
   197 
   198 lemma (in UP_cring) coeff_add [simp]:
   199   "[| p \<in> carrier P; q \<in> carrier P |] ==>
   200   coeff P (p \<oplus>\<^sub>2 q) n = coeff P p n \<oplus> coeff P q n"
   201   by (simp add: UP_def up_add_closed)
   202 
   203 lemma (in UP_cring) coeff_mult [simp]:
   204   "[| p \<in> carrier P; q \<in> carrier P |] ==>
   205   coeff P (p \<otimes>\<^sub>2 q) n = (\<Oplus>i \<in> {..n}. coeff P p i \<otimes> coeff P q (n-i))"
   206   by (simp add: UP_def up_mult_closed)
   207 
   208 lemma (in UP) up_eqI:
   209   assumes prem: "!!n. coeff P p n = coeff P q n"
   210     and R: "p \<in> carrier P" "q \<in> carrier P"
   211   shows "p = q"
   212 proof
   213   fix x
   214   from prem and R show "p x = q x" by (simp add: UP_def)
   215 qed
   216 
   217 subsection {* Polynomials form a commutative ring. *}
   218 
   219 text {* Operations are closed over @{term P}. *}
   220 
   221 lemma (in UP_cring) UP_mult_closed [simp]:
   222   "[| p \<in> carrier P; q \<in> carrier P |] ==> p \<otimes>\<^sub>2 q \<in> carrier P"
   223   by (simp add: UP_def up_mult_closed)
   224 
   225 lemma (in UP_cring) UP_one_closed [simp]:
   226   "\<one>\<^sub>2 \<in> carrier P"
   227   by (simp add: UP_def up_one_closed)
   228 
   229 lemma (in UP_cring) UP_zero_closed [intro, simp]:
   230   "\<zero>\<^sub>2 \<in> carrier P"
   231   by (auto simp add: UP_def)
   232 
   233 lemma (in UP_cring) UP_a_closed [intro, simp]:
   234   "[| p \<in> carrier P; q \<in> carrier P |] ==> p \<oplus>\<^sub>2 q \<in> carrier P"
   235   by (simp add: UP_def up_add_closed)
   236 
   237 lemma (in UP_cring) monom_closed [simp]:
   238   "a \<in> carrier R ==> monom P a n \<in> carrier P"
   239   by (auto simp add: UP_def up_def Pi_def)
   240 
   241 lemma (in UP_cring) UP_smult_closed [simp]:
   242   "[| a \<in> carrier R; p \<in> carrier P |] ==> a \<odot>\<^sub>2 p \<in> carrier P"
   243   by (simp add: UP_def up_smult_closed)
   244 
   245 lemma (in UP) coeff_closed [simp]:
   246   "p \<in> carrier P ==> coeff P p n \<in> carrier R"
   247   by (auto simp add: UP_def)
   248 
   249 declare (in UP) P_def [simp del]
   250 
   251 text {* Algebraic ring properties *}
   252 
   253 lemma (in UP_cring) UP_a_assoc:
   254   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   255   shows "(p \<oplus>\<^sub>2 q) \<oplus>\<^sub>2 r = p \<oplus>\<^sub>2 (q \<oplus>\<^sub>2 r)"
   256   by (rule up_eqI, simp add: a_assoc R, simp_all add: R)
   257 
   258 lemma (in UP_cring) UP_l_zero [simp]:
   259   assumes R: "p \<in> carrier P"
   260   shows "\<zero>\<^sub>2 \<oplus>\<^sub>2 p = p"
   261   by (rule up_eqI, simp_all add: R)
   262 
   263 lemma (in UP_cring) UP_l_neg_ex:
   264   assumes R: "p \<in> carrier P"
   265   shows "EX q : carrier P. q \<oplus>\<^sub>2 p = \<zero>\<^sub>2"
   266 proof -
   267   let ?q = "%i. \<ominus> (p i)"
   268   from R have closed: "?q \<in> carrier P"
   269     by (simp add: UP_def P_def up_a_inv_closed)
   270   from R have coeff: "!!n. coeff P ?q n = \<ominus> (coeff P p n)"
   271     by (simp add: UP_def P_def up_a_inv_closed)
   272   show ?thesis
   273   proof
   274     show "?q \<oplus>\<^sub>2 p = \<zero>\<^sub>2"
   275       by (auto intro!: up_eqI simp add: R closed coeff R.l_neg)
   276   qed (rule closed)
   277 qed
   278 
   279 lemma (in UP_cring) UP_a_comm:
   280   assumes R: "p \<in> carrier P" "q \<in> carrier P"
   281   shows "p \<oplus>\<^sub>2 q = q \<oplus>\<^sub>2 p"
   282   by (rule up_eqI, simp add: a_comm R, simp_all add: R)
   283 
   284 ML_setup {*
   285   simpset_ref() := simpset() setsubgoaler asm_full_simp_tac;
   286 *}
   287 
   288 lemma (in UP_cring) UP_m_assoc:
   289   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   290   shows "(p \<otimes>\<^sub>2 q) \<otimes>\<^sub>2 r = p \<otimes>\<^sub>2 (q \<otimes>\<^sub>2 r)"
   291 proof (rule up_eqI)
   292   fix n
   293   {
   294     fix k and a b c :: "nat=>'a"
   295     assume R: "a \<in> UNIV -> carrier R" "b \<in> UNIV -> carrier R"
   296       "c \<in> UNIV -> carrier R"
   297     then have "k <= n ==>
   298       (\<Oplus>j \<in> {..k}. (\<Oplus>i \<in> {..j}. a i \<otimes> b (j-i)) \<otimes> c (n-j)) =
   299       (\<Oplus>j \<in> {..k}. a j \<otimes> (\<Oplus>i \<in> {..k-j}. b i \<otimes> c (n-j-i)))"
   300       (concl is "?eq k")
   301     proof (induct k)
   302       case 0 then show ?case by (simp add: Pi_def m_assoc)
   303     next
   304       case (Suc k)
   305       then have "k <= n" by arith
   306       then have "?eq k" by (rule Suc)
   307       with R show ?case
   308         by (simp cong: finsum_cong
   309              add: Suc_diff_le Pi_def l_distr r_distr m_assoc)
   310           (simp cong: finsum_cong add: Pi_def a_ac finsum_ldistr m_assoc)
   311     qed
   312   }
   313   with R show "coeff P ((p \<otimes>\<^sub>2 q) \<otimes>\<^sub>2 r) n = coeff P (p \<otimes>\<^sub>2 (q \<otimes>\<^sub>2 r)) n"
   314     by (simp add: Pi_def)
   315 qed (simp_all add: R)
   316 
   317 ML_setup {*
   318   simpset_ref() := simpset() setsubgoaler asm_simp_tac;
   319 *}
   320 
   321 lemma (in UP_cring) UP_l_one [simp]:
   322   assumes R: "p \<in> carrier P"
   323   shows "\<one>\<^sub>2 \<otimes>\<^sub>2 p = p"
   324 proof (rule up_eqI)
   325   fix n
   326   show "coeff P (\<one>\<^sub>2 \<otimes>\<^sub>2 p) n = coeff P p n"
   327   proof (cases n)
   328     case 0 with R show ?thesis by simp
   329   next
   330     case Suc with R show ?thesis
   331       by (simp del: finsum_Suc add: finsum_Suc2 Pi_def)
   332   qed
   333 qed (simp_all add: R)
   334 
   335 lemma (in UP_cring) UP_l_distr:
   336   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   337   shows "(p \<oplus>\<^sub>2 q) \<otimes>\<^sub>2 r = (p \<otimes>\<^sub>2 r) \<oplus>\<^sub>2 (q \<otimes>\<^sub>2 r)"
   338   by (rule up_eqI) (simp add: l_distr R Pi_def, simp_all add: R)
   339 
   340 lemma (in UP_cring) UP_m_comm:
   341   assumes R: "p \<in> carrier P" "q \<in> carrier P"
   342   shows "p \<otimes>\<^sub>2 q = q \<otimes>\<^sub>2 p"
   343 proof (rule up_eqI)
   344   fix n
   345   {
   346     fix k and a b :: "nat=>'a"
   347     assume R: "a \<in> UNIV -> carrier R" "b \<in> UNIV -> carrier R"
   348     then have "k <= n ==>
   349       (\<Oplus>i \<in> {..k}. a i \<otimes> b (n-i)) =
   350       (\<Oplus>i \<in> {..k}. a (k-i) \<otimes> b (i+n-k))"
   351       (concl is "?eq k")
   352     proof (induct k)
   353       case 0 then show ?case by (simp add: Pi_def)
   354     next
   355       case (Suc k) then show ?case
   356         by (subst finsum_Suc2) (simp add: Pi_def a_comm)+
   357     qed
   358   }
   359   note l = this
   360   from R show "coeff P (p \<otimes>\<^sub>2 q) n =  coeff P (q \<otimes>\<^sub>2 p) n"
   361     apply (simp add: Pi_def)
   362     apply (subst l)
   363     apply (auto simp add: Pi_def)
   364     apply (simp add: m_comm)
   365     done
   366 qed (simp_all add: R)
   367 
   368 theorem (in UP_cring) UP_cring:
   369   "cring P"
   370   by (auto intro!: cringI abelian_groupI comm_monoidI UP_a_assoc UP_l_zero
   371     UP_l_neg_ex UP_a_comm UP_m_assoc UP_l_one UP_m_comm UP_l_distr)
   372 
   373 lemma (in UP_cring) UP_ring:  (* preliminary *)
   374   "ring P"
   375   by (auto intro: ring.intro cring.axioms UP_cring)
   376 
   377 lemma (in UP_cring) UP_a_inv_closed [intro, simp]:
   378   "p \<in> carrier P ==> \<ominus>\<^sub>2 p \<in> carrier P"
   379   by (rule abelian_group.a_inv_closed
   380     [OF ring.is_abelian_group [OF UP_ring]])
   381 
   382 lemma (in UP_cring) coeff_a_inv [simp]:
   383   assumes R: "p \<in> carrier P"
   384   shows "coeff P (\<ominus>\<^sub>2 p) n = \<ominus> (coeff P p n)"
   385 proof -
   386   from R coeff_closed UP_a_inv_closed have
   387     "coeff P (\<ominus>\<^sub>2 p) n = \<ominus> coeff P p n \<oplus> (coeff P p n \<oplus> coeff P (\<ominus>\<^sub>2 p) n)"
   388     by algebra
   389   also from R have "... =  \<ominus> (coeff P p n)"
   390     by (simp del: coeff_add add: coeff_add [THEN sym]
   391       abelian_group.r_neg [OF ring.is_abelian_group [OF UP_ring]])
   392   finally show ?thesis .
   393 qed
   394 
   395 text {*
   396   Instantiation of lemmas from @{term cring}.
   397 *}
   398 
   399 lemma (in UP_cring) UP_monoid:
   400   "monoid P"
   401   by (fast intro!: cring.is_comm_monoid comm_monoid.axioms monoid.intro
   402     UP_cring)
   403 (* TODO: provide cring.is_monoid *)
   404 
   405 lemma (in UP_cring) UP_comm_monoid:
   406   "comm_monoid P"
   407   by (fast intro!: cring.is_comm_monoid UP_cring)
   408 
   409 lemma (in UP_cring) UP_abelian_monoid:
   410   "abelian_monoid P"
   411   by (fast intro!: abelian_group.axioms ring.is_abelian_group UP_ring)
   412 
   413 lemma (in UP_cring) UP_abelian_group:
   414   "abelian_group P"
   415   by (fast intro!: ring.is_abelian_group UP_ring)
   416 
   417 lemmas (in UP_cring) UP_r_one [simp] =
   418   monoid.r_one [OF UP_monoid]
   419 
   420 lemmas (in UP_cring) UP_nat_pow_closed [intro, simp] =
   421   monoid.nat_pow_closed [OF UP_monoid]
   422 
   423 lemmas (in UP_cring) UP_nat_pow_0 [simp] =
   424   monoid.nat_pow_0 [OF UP_monoid]
   425 
   426 lemmas (in UP_cring) UP_nat_pow_Suc [simp] =
   427   monoid.nat_pow_Suc [OF UP_monoid]
   428 
   429 lemmas (in UP_cring) UP_nat_pow_one [simp] =
   430   monoid.nat_pow_one [OF UP_monoid]
   431 
   432 lemmas (in UP_cring) UP_nat_pow_mult =
   433   monoid.nat_pow_mult [OF UP_monoid]
   434 
   435 lemmas (in UP_cring) UP_nat_pow_pow =
   436   monoid.nat_pow_pow [OF UP_monoid]
   437 
   438 lemmas (in UP_cring) UP_m_lcomm =
   439   comm_monoid.m_lcomm [OF UP_comm_monoid]
   440 
   441 lemmas (in UP_cring) UP_m_ac = UP_m_assoc UP_m_comm UP_m_lcomm
   442 
   443 lemmas (in UP_cring) UP_nat_pow_distr =
   444   comm_monoid.nat_pow_distr [OF UP_comm_monoid]
   445 
   446 lemmas (in UP_cring) UP_a_lcomm = abelian_monoid.a_lcomm [OF UP_abelian_monoid]
   447 
   448 lemmas (in UP_cring) UP_r_zero [simp] =
   449   abelian_monoid.r_zero [OF UP_abelian_monoid]
   450 
   451 lemmas (in UP_cring) UP_a_ac = UP_a_assoc UP_a_comm UP_a_lcomm
   452 
   453 lemmas (in UP_cring) UP_finsum_empty [simp] =
   454   abelian_monoid.finsum_empty [OF UP_abelian_monoid]
   455 
   456 lemmas (in UP_cring) UP_finsum_insert [simp] =
   457   abelian_monoid.finsum_insert [OF UP_abelian_monoid]
   458 
   459 lemmas (in UP_cring) UP_finsum_zero [simp] =
   460   abelian_monoid.finsum_zero [OF UP_abelian_monoid]
   461 
   462 lemmas (in UP_cring) UP_finsum_closed [simp] =
   463   abelian_monoid.finsum_closed [OF UP_abelian_monoid]
   464 
   465 lemmas (in UP_cring) UP_finsum_Un_Int =
   466   abelian_monoid.finsum_Un_Int [OF UP_abelian_monoid]
   467 
   468 lemmas (in UP_cring) UP_finsum_Un_disjoint =
   469   abelian_monoid.finsum_Un_disjoint [OF UP_abelian_monoid]
   470 
   471 lemmas (in UP_cring) UP_finsum_addf =
   472   abelian_monoid.finsum_addf [OF UP_abelian_monoid]
   473 
   474 lemmas (in UP_cring) UP_finsum_cong' =
   475   abelian_monoid.finsum_cong' [OF UP_abelian_monoid]
   476 
   477 lemmas (in UP_cring) UP_finsum_0 [simp] =
   478   abelian_monoid.finsum_0 [OF UP_abelian_monoid]
   479 
   480 lemmas (in UP_cring) UP_finsum_Suc [simp] =
   481   abelian_monoid.finsum_Suc [OF UP_abelian_monoid]
   482 
   483 lemmas (in UP_cring) UP_finsum_Suc2 =
   484   abelian_monoid.finsum_Suc2 [OF UP_abelian_monoid]
   485 
   486 lemmas (in UP_cring) UP_finsum_add [simp] =
   487   abelian_monoid.finsum_add [OF UP_abelian_monoid]
   488 
   489 lemmas (in UP_cring) UP_finsum_cong =
   490   abelian_monoid.finsum_cong [OF UP_abelian_monoid]
   491 
   492 lemmas (in UP_cring) UP_minus_closed [intro, simp] =
   493   abelian_group.minus_closed [OF UP_abelian_group]
   494 
   495 lemmas (in UP_cring) UP_a_l_cancel [simp] =
   496   abelian_group.a_l_cancel [OF UP_abelian_group]
   497 
   498 lemmas (in UP_cring) UP_a_r_cancel [simp] =
   499   abelian_group.a_r_cancel [OF UP_abelian_group]
   500 
   501 lemmas (in UP_cring) UP_l_neg =
   502   abelian_group.l_neg [OF UP_abelian_group]
   503 
   504 lemmas (in UP_cring) UP_r_neg =
   505   abelian_group.r_neg [OF UP_abelian_group]
   506 
   507 lemmas (in UP_cring) UP_minus_zero [simp] =
   508   abelian_group.minus_zero [OF UP_abelian_group]
   509 
   510 lemmas (in UP_cring) UP_minus_minus [simp] =
   511   abelian_group.minus_minus [OF UP_abelian_group]
   512 
   513 lemmas (in UP_cring) UP_minus_add =
   514   abelian_group.minus_add [OF UP_abelian_group]
   515 
   516 lemmas (in UP_cring) UP_r_neg2 =
   517   abelian_group.r_neg2 [OF UP_abelian_group]
   518 
   519 lemmas (in UP_cring) UP_r_neg1 =
   520   abelian_group.r_neg1 [OF UP_abelian_group]
   521 
   522 lemmas (in UP_cring) UP_r_distr =
   523   ring.r_distr [OF UP_ring]
   524 
   525 lemmas (in UP_cring) UP_l_null [simp] =
   526   ring.l_null [OF UP_ring]
   527 
   528 lemmas (in UP_cring) UP_r_null [simp] =
   529   ring.r_null [OF UP_ring]
   530 
   531 lemmas (in UP_cring) UP_l_minus =
   532   ring.l_minus [OF UP_ring]
   533 
   534 lemmas (in UP_cring) UP_r_minus =
   535   ring.r_minus [OF UP_ring]
   536 
   537 lemmas (in UP_cring) UP_finsum_ldistr =
   538   cring.finsum_ldistr [OF UP_cring]
   539 
   540 lemmas (in UP_cring) UP_finsum_rdistr =
   541   cring.finsum_rdistr [OF UP_cring]
   542 
   543 
   544 subsection {* Polynomials form an Algebra *}
   545 
   546 lemma (in UP_cring) UP_smult_l_distr:
   547   "[| a \<in> carrier R; b \<in> carrier R; p \<in> carrier P |] ==>
   548   (a \<oplus> b) \<odot>\<^sub>2 p = a \<odot>\<^sub>2 p \<oplus>\<^sub>2 b \<odot>\<^sub>2 p"
   549   by (rule up_eqI) (simp_all add: R.l_distr)
   550 
   551 lemma (in UP_cring) UP_smult_r_distr:
   552   "[| a \<in> carrier R; p \<in> carrier P; q \<in> carrier P |] ==>
   553   a \<odot>\<^sub>2 (p \<oplus>\<^sub>2 q) = a \<odot>\<^sub>2 p \<oplus>\<^sub>2 a \<odot>\<^sub>2 q"
   554   by (rule up_eqI) (simp_all add: R.r_distr)
   555 
   556 lemma (in UP_cring) UP_smult_assoc1:
   557       "[| a \<in> carrier R; b \<in> carrier R; p \<in> carrier P |] ==>
   558       (a \<otimes> b) \<odot>\<^sub>2 p = a \<odot>\<^sub>2 (b \<odot>\<^sub>2 p)"
   559   by (rule up_eqI) (simp_all add: R.m_assoc)
   560 
   561 lemma (in UP_cring) UP_smult_one [simp]:
   562       "p \<in> carrier P ==> \<one> \<odot>\<^sub>2 p = p"
   563   by (rule up_eqI) simp_all
   564 
   565 lemma (in UP_cring) UP_smult_assoc2:
   566   "[| a \<in> carrier R; p \<in> carrier P; q \<in> carrier P |] ==>
   567   (a \<odot>\<^sub>2 p) \<otimes>\<^sub>2 q = a \<odot>\<^sub>2 (p \<otimes>\<^sub>2 q)"
   568   by (rule up_eqI) (simp_all add: R.finsum_rdistr R.m_assoc Pi_def)
   569 
   570 text {*
   571   Instantiation of lemmas from @{term algebra}.
   572 *}
   573 
   574 (* TODO: move to CRing.thy, really a fact missing from the locales package *)
   575 
   576 lemma (in cring) cring:
   577   "cring R"
   578   by (fast intro: cring.intro prems)
   579 
   580 lemma (in UP_cring) UP_algebra:
   581   "algebra R P"
   582   by (auto intro: algebraI cring UP_cring UP_smult_l_distr UP_smult_r_distr
   583     UP_smult_assoc1 UP_smult_assoc2)
   584 
   585 lemmas (in UP_cring) UP_smult_l_null [simp] =
   586   algebra.smult_l_null [OF UP_algebra]
   587 
   588 lemmas (in UP_cring) UP_smult_r_null [simp] =
   589   algebra.smult_r_null [OF UP_algebra]
   590 
   591 lemmas (in UP_cring) UP_smult_l_minus =
   592   algebra.smult_l_minus [OF UP_algebra]
   593 
   594 lemmas (in UP_cring) UP_smult_r_minus =
   595   algebra.smult_r_minus [OF UP_algebra]
   596 
   597 subsection {* Further lemmas involving monomials *}
   598 
   599 lemma (in UP_cring) monom_zero [simp]:
   600   "monom P \<zero> n = \<zero>\<^sub>2"
   601   by (simp add: UP_def P_def)
   602 
   603 ML_setup {*
   604   simpset_ref() := simpset() setsubgoaler asm_full_simp_tac;
   605 *}
   606 
   607 lemma (in UP_cring) monom_mult_is_smult:
   608   assumes R: "a \<in> carrier R" "p \<in> carrier P"
   609   shows "monom P a 0 \<otimes>\<^sub>2 p = a \<odot>\<^sub>2 p"
   610 proof (rule up_eqI)
   611   fix n
   612   have "coeff P (p \<otimes>\<^sub>2 monom P a 0) n = coeff P (a \<odot>\<^sub>2 p) n"
   613   proof (cases n)
   614     case 0 with R show ?thesis by (simp add: R.m_comm)
   615   next
   616     case Suc with R show ?thesis
   617       by (simp cong: finsum_cong add: R.r_null Pi_def)
   618         (simp add: m_comm)
   619   qed
   620   with R show "coeff P (monom P a 0 \<otimes>\<^sub>2 p) n = coeff P (a \<odot>\<^sub>2 p) n"
   621     by (simp add: UP_m_comm)
   622 qed (simp_all add: R)
   623 
   624 ML_setup {*
   625   simpset_ref() := simpset() setsubgoaler asm_simp_tac;
   626 *}
   627 
   628 lemma (in UP_cring) monom_add [simp]:
   629   "[| a \<in> carrier R; b \<in> carrier R |] ==>
   630   monom P (a \<oplus> b) n = monom P a n \<oplus>\<^sub>2 monom P b n"
   631   by (rule up_eqI) simp_all
   632 
   633 ML_setup {*
   634   simpset_ref() := simpset() setsubgoaler asm_full_simp_tac;
   635 *}
   636 
   637 lemma (in UP_cring) monom_one_Suc:
   638   "monom P \<one> (Suc n) = monom P \<one> n \<otimes>\<^sub>2 monom P \<one> 1"
   639 proof (rule up_eqI)
   640   fix k
   641   show "coeff P (monom P \<one> (Suc n)) k = coeff P (monom P \<one> n \<otimes>\<^sub>2 monom P \<one> 1) k"
   642   proof (cases "k = Suc n")
   643     case True show ?thesis
   644     proof -
   645       from True have less_add_diff:
   646         "!!i. [| n < i; i <= n + m |] ==> n + m - i < m" by arith
   647       from True have "coeff P (monom P \<one> (Suc n)) k = \<one>" by simp
   648       also from True
   649       have "... = (\<Oplus>i \<in> {..<n} \<union> {n}. coeff P (monom P \<one> n) i \<otimes>
   650         coeff P (monom P \<one> 1) (k - i))"
   651         by (simp cong: finsum_cong add: finsum_Un_disjoint Pi_def)
   652       also have "... = (\<Oplus>i \<in>  {..n}. coeff P (monom P \<one> n) i \<otimes>
   653         coeff P (monom P \<one> 1) (k - i))"
   654         by (simp only: ivl_disj_un_singleton)
   655       also from True have "... = (\<Oplus>i \<in> {..n} \<union> {n<..k}. coeff P (monom P \<one> n) i \<otimes>
   656         coeff P (monom P \<one> 1) (k - i))"
   657         by (simp cong: finsum_cong add: finsum_Un_disjoint ivl_disj_int_one
   658           order_less_imp_not_eq Pi_def)
   659       also from True have "... = coeff P (monom P \<one> n \<otimes>\<^sub>2 monom P \<one> 1) k"
   660         by (simp add: ivl_disj_un_one)
   661       finally show ?thesis .
   662     qed
   663   next
   664     case False
   665     note neq = False
   666     let ?s =
   667       "\<lambda>i. (if n = i then \<one> else \<zero>) \<otimes> (if Suc 0 = k - i then \<one> else \<zero>)"
   668     from neq have "coeff P (monom P \<one> (Suc n)) k = \<zero>" by simp
   669     also have "... = (\<Oplus>i \<in> {..k}. ?s i)"
   670     proof -
   671       have f1: "(\<Oplus>i \<in> {..<n}. ?s i) = \<zero>" by (simp cong: finsum_cong add: Pi_def)
   672       from neq have f2: "(\<Oplus>i \<in> {n}. ?s i) = \<zero>"
   673         by (simp cong: finsum_cong add: Pi_def) arith
   674       have f3: "n < k ==> (\<Oplus>i \<in> {n<..k}. ?s i) = \<zero>"
   675         by (simp cong: finsum_cong add: order_less_imp_not_eq Pi_def)
   676       show ?thesis
   677       proof (cases "k < n")
   678         case True then show ?thesis by (simp cong: finsum_cong add: Pi_def)
   679       next
   680         case False then have n_le_k: "n <= k" by arith
   681         show ?thesis
   682         proof (cases "n = k")
   683           case True
   684           then have "\<zero> = (\<Oplus>i \<in> {..<n} \<union> {n}. ?s i)"
   685             by (simp cong: finsum_cong add: finsum_Un_disjoint
   686               ivl_disj_int_singleton Pi_def)
   687           also from True have "... = (\<Oplus>i \<in> {..k}. ?s i)"
   688             by (simp only: ivl_disj_un_singleton)
   689           finally show ?thesis .
   690         next
   691           case False with n_le_k have n_less_k: "n < k" by arith
   692           with neq have "\<zero> = (\<Oplus>i \<in> {..<n} \<union> {n}. ?s i)"
   693             by (simp add: finsum_Un_disjoint f1 f2
   694               ivl_disj_int_singleton Pi_def del: Un_insert_right)
   695           also have "... = (\<Oplus>i \<in> {..n}. ?s i)"
   696             by (simp only: ivl_disj_un_singleton)
   697           also from n_less_k neq have "... = (\<Oplus>i \<in> {..n} \<union> {n<..k}. ?s i)"
   698             by (simp add: finsum_Un_disjoint f3 ivl_disj_int_one Pi_def)
   699           also from n_less_k have "... = (\<Oplus>i \<in> {..k}. ?s i)"
   700             by (simp only: ivl_disj_un_one)
   701           finally show ?thesis .
   702         qed
   703       qed
   704     qed
   705     also have "... = coeff P (monom P \<one> n \<otimes>\<^sub>2 monom P \<one> 1) k" by simp
   706     finally show ?thesis .
   707   qed
   708 qed (simp_all)
   709 
   710 ML_setup {*
   711   simpset_ref() := simpset() setsubgoaler asm_simp_tac;
   712 *}
   713 
   714 lemma (in UP_cring) monom_mult_smult:
   715   "[| a \<in> carrier R; b \<in> carrier R |] ==> monom P (a \<otimes> b) n = a \<odot>\<^sub>2 monom P b n"
   716   by (rule up_eqI) simp_all
   717 
   718 lemma (in UP_cring) monom_one [simp]:
   719   "monom P \<one> 0 = \<one>\<^sub>2"
   720   by (rule up_eqI) simp_all
   721 
   722 lemma (in UP_cring) monom_one_mult:
   723   "monom P \<one> (n + m) = monom P \<one> n \<otimes>\<^sub>2 monom P \<one> m"
   724 proof (induct n)
   725   case 0 show ?case by simp
   726 next
   727   case Suc then show ?case
   728     by (simp only: add_Suc monom_one_Suc) (simp add: UP_m_ac)
   729 qed
   730 
   731 lemma (in UP_cring) monom_mult [simp]:
   732   assumes R: "a \<in> carrier R" "b \<in> carrier R"
   733   shows "monom P (a \<otimes> b) (n + m) = monom P a n \<otimes>\<^sub>2 monom P b m"
   734 proof -
   735   from R have "monom P (a \<otimes> b) (n + m) = monom P (a \<otimes> b \<otimes> \<one>) (n + m)" by simp
   736   also from R have "... = a \<otimes> b \<odot>\<^sub>2 monom P \<one> (n + m)"
   737     by (simp add: monom_mult_smult del: r_one)
   738   also have "... = a \<otimes> b \<odot>\<^sub>2 (monom P \<one> n \<otimes>\<^sub>2 monom P \<one> m)"
   739     by (simp only: monom_one_mult)
   740   also from R have "... = a \<odot>\<^sub>2 (b \<odot>\<^sub>2 (monom P \<one> n \<otimes>\<^sub>2 monom P \<one> m))"
   741     by (simp add: UP_smult_assoc1)
   742   also from R have "... = a \<odot>\<^sub>2 (b \<odot>\<^sub>2 (monom P \<one> m \<otimes>\<^sub>2 monom P \<one> n))"
   743     by (simp add: UP_m_comm)
   744   also from R have "... = a \<odot>\<^sub>2 ((b \<odot>\<^sub>2 monom P \<one> m) \<otimes>\<^sub>2 monom P \<one> n)"
   745     by (simp add: UP_smult_assoc2)
   746   also from R have "... = a \<odot>\<^sub>2 (monom P \<one> n \<otimes>\<^sub>2 (b \<odot>\<^sub>2 monom P \<one> m))"
   747     by (simp add: UP_m_comm)
   748   also from R have "... = (a \<odot>\<^sub>2 monom P \<one> n) \<otimes>\<^sub>2 (b \<odot>\<^sub>2 monom P \<one> m)"
   749     by (simp add: UP_smult_assoc2)
   750   also from R have "... = monom P (a \<otimes> \<one>) n \<otimes>\<^sub>2 monom P (b \<otimes> \<one>) m"
   751     by (simp add: monom_mult_smult del: r_one)
   752   also from R have "... = monom P a n \<otimes>\<^sub>2 monom P b m" by simp
   753   finally show ?thesis .
   754 qed
   755 
   756 lemma (in UP_cring) monom_a_inv [simp]:
   757   "a \<in> carrier R ==> monom P (\<ominus> a) n = \<ominus>\<^sub>2 monom P a n"
   758   by (rule up_eqI) simp_all
   759 
   760 lemma (in UP_cring) monom_inj:
   761   "inj_on (%a. monom P a n) (carrier R)"
   762 proof (rule inj_onI)
   763   fix x y
   764   assume R: "x \<in> carrier R" "y \<in> carrier R" and eq: "monom P x n = monom P y n"
   765   then have "coeff P (monom P x n) n = coeff P (monom P y n) n" by simp
   766   with R show "x = y" by simp
   767 qed
   768 
   769 subsection {* The degree function *}
   770 
   771 constdefs (structure R)
   772   deg :: "[_, nat => 'a] => nat"
   773   "deg R p == LEAST n. bound \<zero> n (coeff (UP R) p)"
   774 
   775 lemma (in UP_cring) deg_aboveI:
   776   "[| (!!m. n < m ==> coeff P p m = \<zero>); p \<in> carrier P |] ==> deg R p <= n"
   777   by (unfold deg_def P_def) (fast intro: Least_le)
   778 (*
   779 lemma coeff_bound_ex: "EX n. bound n (coeff p)"
   780 proof -
   781   have "(%n. coeff p n) : UP" by (simp add: coeff_def Rep_UP)
   782   then obtain n where "bound n (coeff p)" by (unfold UP_def) fast
   783   then show ?thesis ..
   784 qed
   785 
   786 lemma bound_coeff_obtain:
   787   assumes prem: "(!!n. bound n (coeff p) ==> P)" shows "P"
   788 proof -
   789   have "(%n. coeff p n) : UP" by (simp add: coeff_def Rep_UP)
   790   then obtain n where "bound n (coeff p)" by (unfold UP_def) fast
   791   with prem show P .
   792 qed
   793 *)
   794 lemma (in UP_cring) deg_aboveD:
   795   "[| deg R p < m; p \<in> carrier P |] ==> coeff P p m = \<zero>"
   796 proof -
   797   assume R: "p \<in> carrier P" and "deg R p < m"
   798   from R obtain n where "bound \<zero> n (coeff P p)"
   799     by (auto simp add: UP_def P_def)
   800   then have "bound \<zero> (deg R p) (coeff P p)"
   801     by (auto simp: deg_def P_def dest: LeastI)
   802   then show ?thesis ..
   803 qed
   804 
   805 lemma (in UP_cring) deg_belowI:
   806   assumes non_zero: "n ~= 0 ==> coeff P p n ~= \<zero>"
   807     and R: "p \<in> carrier P"
   808   shows "n <= deg R p"
   809 -- {* Logically, this is a slightly stronger version of
   810   @{thm [source] deg_aboveD} *}
   811 proof (cases "n=0")
   812   case True then show ?thesis by simp
   813 next
   814   case False then have "coeff P p n ~= \<zero>" by (rule non_zero)
   815   then have "~ deg R p < n" by (fast dest: deg_aboveD intro: R)
   816   then show ?thesis by arith
   817 qed
   818 
   819 lemma (in UP_cring) lcoeff_nonzero_deg:
   820   assumes deg: "deg R p ~= 0" and R: "p \<in> carrier P"
   821   shows "coeff P p (deg R p) ~= \<zero>"
   822 proof -
   823   from R obtain m where "deg R p <= m" and m_coeff: "coeff P p m ~= \<zero>"
   824   proof -
   825     have minus: "!!(n::nat) m. n ~= 0 ==> (n - Suc 0 < m) = (n <= m)"
   826       by arith
   827 (* TODO: why does proof not work with "1" *)
   828     from deg have "deg R p - 1 < (LEAST n. bound \<zero> n (coeff P p))"
   829       by (unfold deg_def P_def) arith
   830     then have "~ bound \<zero> (deg R p - 1) (coeff P p)" by (rule not_less_Least)
   831     then have "EX m. deg R p - 1 < m & coeff P p m ~= \<zero>"
   832       by (unfold bound_def) fast
   833     then have "EX m. deg R p <= m & coeff P p m ~= \<zero>" by (simp add: deg minus)
   834     then show ?thesis by auto
   835   qed
   836   with deg_belowI R have "deg R p = m" by fastsimp
   837   with m_coeff show ?thesis by simp
   838 qed
   839 
   840 lemma (in UP_cring) lcoeff_nonzero_nonzero:
   841   assumes deg: "deg R p = 0" and nonzero: "p ~= \<zero>\<^sub>2" and R: "p \<in> carrier P"
   842   shows "coeff P p 0 ~= \<zero>"
   843 proof -
   844   have "EX m. coeff P p m ~= \<zero>"
   845   proof (rule classical)
   846     assume "~ ?thesis"
   847     with R have "p = \<zero>\<^sub>2" by (auto intro: up_eqI)
   848     with nonzero show ?thesis by contradiction
   849   qed
   850   then obtain m where coeff: "coeff P p m ~= \<zero>" ..
   851   then have "m <= deg R p" by (rule deg_belowI)
   852   then have "m = 0" by (simp add: deg)
   853   with coeff show ?thesis by simp
   854 qed
   855 
   856 lemma (in UP_cring) lcoeff_nonzero:
   857   assumes neq: "p ~= \<zero>\<^sub>2" and R: "p \<in> carrier P"
   858   shows "coeff P p (deg R p) ~= \<zero>"
   859 proof (cases "deg R p = 0")
   860   case True with neq R show ?thesis by (simp add: lcoeff_nonzero_nonzero)
   861 next
   862   case False with neq R show ?thesis by (simp add: lcoeff_nonzero_deg)
   863 qed
   864 
   865 lemma (in UP_cring) deg_eqI:
   866   "[| !!m. n < m ==> coeff P p m = \<zero>;
   867       !!n. n ~= 0 ==> coeff P p n ~= \<zero>; p \<in> carrier P |] ==> deg R p = n"
   868 by (fast intro: le_anti_sym deg_aboveI deg_belowI)
   869 
   870 (* Degree and polynomial operations *)
   871 
   872 lemma (in UP_cring) deg_add [simp]:
   873   assumes R: "p \<in> carrier P" "q \<in> carrier P"
   874   shows "deg R (p \<oplus>\<^sub>2 q) <= max (deg R p) (deg R q)"
   875 proof (cases "deg R p <= deg R q")
   876   case True show ?thesis
   877     by (rule deg_aboveI) (simp_all add: True R deg_aboveD)
   878 next
   879   case False show ?thesis
   880     by (rule deg_aboveI) (simp_all add: False R deg_aboveD)
   881 qed
   882 
   883 lemma (in UP_cring) deg_monom_le:
   884   "a \<in> carrier R ==> deg R (monom P a n) <= n"
   885   by (intro deg_aboveI) simp_all
   886 
   887 lemma (in UP_cring) deg_monom [simp]:
   888   "[| a ~= \<zero>; a \<in> carrier R |] ==> deg R (monom P a n) = n"
   889   by (fastsimp intro: le_anti_sym deg_aboveI deg_belowI)
   890 
   891 lemma (in UP_cring) deg_const [simp]:
   892   assumes R: "a \<in> carrier R" shows "deg R (monom P a 0) = 0"
   893 proof (rule le_anti_sym)
   894   show "deg R (monom P a 0) <= 0" by (rule deg_aboveI) (simp_all add: R)
   895 next
   896   show "0 <= deg R (monom P a 0)" by (rule deg_belowI) (simp_all add: R)
   897 qed
   898 
   899 lemma (in UP_cring) deg_zero [simp]:
   900   "deg R \<zero>\<^sub>2 = 0"
   901 proof (rule le_anti_sym)
   902   show "deg R \<zero>\<^sub>2 <= 0" by (rule deg_aboveI) simp_all
   903 next
   904   show "0 <= deg R \<zero>\<^sub>2" by (rule deg_belowI) simp_all
   905 qed
   906 
   907 lemma (in UP_cring) deg_one [simp]:
   908   "deg R \<one>\<^sub>2 = 0"
   909 proof (rule le_anti_sym)
   910   show "deg R \<one>\<^sub>2 <= 0" by (rule deg_aboveI) simp_all
   911 next
   912   show "0 <= deg R \<one>\<^sub>2" by (rule deg_belowI) simp_all
   913 qed
   914 
   915 lemma (in UP_cring) deg_uminus [simp]:
   916   assumes R: "p \<in> carrier P" shows "deg R (\<ominus>\<^sub>2 p) = deg R p"
   917 proof (rule le_anti_sym)
   918   show "deg R (\<ominus>\<^sub>2 p) <= deg R p" by (simp add: deg_aboveI deg_aboveD R)
   919 next
   920   show "deg R p <= deg R (\<ominus>\<^sub>2 p)"
   921     by (simp add: deg_belowI lcoeff_nonzero_deg
   922       inj_on_iff [OF a_inv_inj, of _ "\<zero>", simplified] R)
   923 qed
   924 
   925 lemma (in UP_domain) deg_smult_ring:
   926   "[| a \<in> carrier R; p \<in> carrier P |] ==>
   927   deg R (a \<odot>\<^sub>2 p) <= (if a = \<zero> then 0 else deg R p)"
   928   by (cases "a = \<zero>") (simp add: deg_aboveI deg_aboveD)+
   929 
   930 lemma (in UP_domain) deg_smult [simp]:
   931   assumes R: "a \<in> carrier R" "p \<in> carrier P"
   932   shows "deg R (a \<odot>\<^sub>2 p) = (if a = \<zero> then 0 else deg R p)"
   933 proof (rule le_anti_sym)
   934   show "deg R (a \<odot>\<^sub>2 p) <= (if a = \<zero> then 0 else deg R p)"
   935     by (rule deg_smult_ring)
   936 next
   937   show "(if a = \<zero> then 0 else deg R p) <= deg R (a \<odot>\<^sub>2 p)"
   938   proof (cases "a = \<zero>")
   939   qed (simp, simp add: deg_belowI lcoeff_nonzero_deg integral_iff R)
   940 qed
   941 
   942 lemma (in UP_cring) deg_mult_cring:
   943   assumes R: "p \<in> carrier P" "q \<in> carrier P"
   944   shows "deg R (p \<otimes>\<^sub>2 q) <= deg R p + deg R q"
   945 proof (rule deg_aboveI)
   946   fix m
   947   assume boundm: "deg R p + deg R q < m"
   948   {
   949     fix k i
   950     assume boundk: "deg R p + deg R q < k"
   951     then have "coeff P p i \<otimes> coeff P q (k - i) = \<zero>"
   952     proof (cases "deg R p < i")
   953       case True then show ?thesis by (simp add: deg_aboveD R)
   954     next
   955       case False with boundk have "deg R q < k - i" by arith
   956       then show ?thesis by (simp add: deg_aboveD R)
   957     qed
   958   }
   959   with boundm R show "coeff P (p \<otimes>\<^sub>2 q) m = \<zero>" by simp
   960 qed (simp add: R)
   961 
   962 ML_setup {*
   963   simpset_ref() := simpset() setsubgoaler asm_full_simp_tac;
   964 *}
   965 
   966 lemma (in UP_domain) deg_mult [simp]:
   967   "[| p ~= \<zero>\<^sub>2; q ~= \<zero>\<^sub>2; p \<in> carrier P; q \<in> carrier P |] ==>
   968   deg R (p \<otimes>\<^sub>2 q) = deg R p + deg R q"
   969 proof (rule le_anti_sym)
   970   assume "p \<in> carrier P" " q \<in> carrier P"
   971   show "deg R (p \<otimes>\<^sub>2 q) <= deg R p + deg R q" by (rule deg_mult_cring)
   972 next
   973   let ?s = "(%i. coeff P p i \<otimes> coeff P q (deg R p + deg R q - i))"
   974   assume R: "p \<in> carrier P" "q \<in> carrier P" and nz: "p ~= \<zero>\<^sub>2" "q ~= \<zero>\<^sub>2"
   975   have less_add_diff: "!!(k::nat) n m. k < n ==> m < n + m - k" by arith
   976   show "deg R p + deg R q <= deg R (p \<otimes>\<^sub>2 q)"
   977   proof (rule deg_belowI, simp add: R)
   978     have "finsum R ?s {.. deg R p + deg R q}
   979       = finsum R ?s ({..< deg R p} Un {deg R p .. deg R p + deg R q})"
   980       by (simp only: ivl_disj_un_one)
   981     also have "... = finsum R ?s {deg R p .. deg R p + deg R q}"
   982       by (simp cong: finsum_cong add: finsum_Un_disjoint ivl_disj_int_one
   983         deg_aboveD less_add_diff R Pi_def)
   984     also have "...= finsum R ?s ({deg R p} Un {deg R p <.. deg R p + deg R q})"
   985       by (simp only: ivl_disj_un_singleton)
   986     also have "... = coeff P p (deg R p) \<otimes> coeff P q (deg R q)"
   987       by (simp cong: finsum_cong add: finsum_Un_disjoint
   988         ivl_disj_int_singleton deg_aboveD R Pi_def)
   989     finally have "finsum R ?s {.. deg R p + deg R q}
   990       = coeff P p (deg R p) \<otimes> coeff P q (deg R q)" .
   991     with nz show "finsum R ?s {.. deg R p + deg R q} ~= \<zero>"
   992       by (simp add: integral_iff lcoeff_nonzero R)
   993     qed (simp add: R)
   994   qed
   995 
   996 lemma (in UP_cring) coeff_finsum:
   997   assumes fin: "finite A"
   998   shows "p \<in> A -> carrier P ==>
   999     coeff P (finsum P p A) k == finsum R (%i. coeff P (p i) k) A"
  1000   using fin by induct (auto simp: Pi_def)
  1001 
  1002 ML_setup {*
  1003   simpset_ref() := simpset() setsubgoaler asm_full_simp_tac;
  1004 *}
  1005 
  1006 lemma (in UP_cring) up_repr:
  1007   assumes R: "p \<in> carrier P"
  1008   shows "(\<Oplus>\<^sub>2 i \<in> {..deg R p}. monom P (coeff P p i) i) = p"
  1009 proof (rule up_eqI)
  1010   let ?s = "(%i. monom P (coeff P p i) i)"
  1011   fix k
  1012   from R have RR: "!!i. (if i = k then coeff P p i else \<zero>) \<in> carrier R"
  1013     by simp
  1014   show "coeff P (finsum P ?s {..deg R p}) k = coeff P p k"
  1015   proof (cases "k <= deg R p")
  1016     case True
  1017     hence "coeff P (finsum P ?s {..deg R p}) k =
  1018           coeff P (finsum P ?s ({..k} Un {k<..deg R p})) k"
  1019       by (simp only: ivl_disj_un_one)
  1020     also from True
  1021     have "... = coeff P (finsum P ?s {..k}) k"
  1022       by (simp cong: finsum_cong add: finsum_Un_disjoint
  1023         ivl_disj_int_one order_less_imp_not_eq2 coeff_finsum R RR Pi_def)
  1024     also
  1025     have "... = coeff P (finsum P ?s ({..<k} Un {k})) k"
  1026       by (simp only: ivl_disj_un_singleton)
  1027     also have "... = coeff P p k"
  1028       by (simp cong: finsum_cong add: setsum_Un_disjoint
  1029         ivl_disj_int_singleton coeff_finsum deg_aboveD R RR Pi_def)
  1030     finally show ?thesis .
  1031   next
  1032     case False
  1033     hence "coeff P (finsum P ?s {..deg R p}) k =
  1034           coeff P (finsum P ?s ({..<deg R p} Un {deg R p})) k"
  1035       by (simp only: ivl_disj_un_singleton)
  1036     also from False have "... = coeff P p k"
  1037       by (simp cong: finsum_cong add: setsum_Un_disjoint ivl_disj_int_singleton
  1038         coeff_finsum deg_aboveD R Pi_def)
  1039     finally show ?thesis .
  1040   qed
  1041 qed (simp_all add: R Pi_def)
  1042 
  1043 lemma (in UP_cring) up_repr_le:
  1044   "[| deg R p <= n; p \<in> carrier P |] ==>
  1045   finsum P (%i. monom P (coeff P p i) i) {..n} = p"
  1046 proof -
  1047   let ?s = "(%i. monom P (coeff P p i) i)"
  1048   assume R: "p \<in> carrier P" and "deg R p <= n"
  1049   then have "finsum P ?s {..n} = finsum P ?s ({..deg R p} Un {deg R p<..n})"
  1050     by (simp only: ivl_disj_un_one)
  1051   also have "... = finsum P ?s {..deg R p}"
  1052     by (simp cong: UP_finsum_cong add: UP_finsum_Un_disjoint ivl_disj_int_one
  1053       deg_aboveD R Pi_def)
  1054   also have "... = p" by (rule up_repr)
  1055   finally show ?thesis .
  1056 qed
  1057 
  1058 ML_setup {*
  1059   simpset_ref() := simpset() setsubgoaler asm_simp_tac;
  1060 *}
  1061 
  1062 subsection {* Polynomials over an integral domain form an integral domain *}
  1063 
  1064 lemma domainI:
  1065   assumes cring: "cring R"
  1066     and one_not_zero: "one R ~= zero R"
  1067     and integral: "!!a b. [| mult R a b = zero R; a \<in> carrier R;
  1068       b \<in> carrier R |] ==> a = zero R | b = zero R"
  1069   shows "domain R"
  1070   by (auto intro!: domain.intro domain_axioms.intro cring.axioms prems
  1071     del: disjCI)
  1072 
  1073 lemma (in UP_domain) UP_one_not_zero:
  1074   "\<one>\<^sub>2 ~= \<zero>\<^sub>2"
  1075 proof
  1076   assume "\<one>\<^sub>2 = \<zero>\<^sub>2"
  1077   hence "coeff P \<one>\<^sub>2 0 = (coeff P \<zero>\<^sub>2 0)" by simp
  1078   hence "\<one> = \<zero>" by simp
  1079   with one_not_zero show "False" by contradiction
  1080 qed
  1081 
  1082 lemma (in UP_domain) UP_integral:
  1083   "[| p \<otimes>\<^sub>2 q = \<zero>\<^sub>2; p \<in> carrier P; q \<in> carrier P |] ==> p = \<zero>\<^sub>2 | q = \<zero>\<^sub>2"
  1084 proof -
  1085   fix p q
  1086   assume pq: "p \<otimes>\<^sub>2 q = \<zero>\<^sub>2" and R: "p \<in> carrier P" "q \<in> carrier P"
  1087   show "p = \<zero>\<^sub>2 | q = \<zero>\<^sub>2"
  1088   proof (rule classical)
  1089     assume c: "~ (p = \<zero>\<^sub>2 | q = \<zero>\<^sub>2)"
  1090     with R have "deg R p + deg R q = deg R (p \<otimes>\<^sub>2 q)" by simp
  1091     also from pq have "... = 0" by simp
  1092     finally have "deg R p + deg R q = 0" .
  1093     then have f1: "deg R p = 0 & deg R q = 0" by simp
  1094     from f1 R have "p = (\<Oplus>\<^sub>2 i \<in> {..0}. monom P (coeff P p i) i)"
  1095       by (simp only: up_repr_le)
  1096     also from R have "... = monom P (coeff P p 0) 0" by simp
  1097     finally have p: "p = monom P (coeff P p 0) 0" .
  1098     from f1 R have "q = (\<Oplus>\<^sub>2 i \<in> {..0}. monom P (coeff P q i) i)"
  1099       by (simp only: up_repr_le)
  1100     also from R have "... = monom P (coeff P q 0) 0" by simp
  1101     finally have q: "q = monom P (coeff P q 0) 0" .
  1102     from R have "coeff P p 0 \<otimes> coeff P q 0 = coeff P (p \<otimes>\<^sub>2 q) 0" by simp
  1103     also from pq have "... = \<zero>" by simp
  1104     finally have "coeff P p 0 \<otimes> coeff P q 0 = \<zero>" .
  1105     with R have "coeff P p 0 = \<zero> | coeff P q 0 = \<zero>"
  1106       by (simp add: R.integral_iff)
  1107     with p q show "p = \<zero>\<^sub>2 | q = \<zero>\<^sub>2" by fastsimp
  1108   qed
  1109 qed
  1110 
  1111 theorem (in UP_domain) UP_domain:
  1112   "domain P"
  1113   by (auto intro!: domainI UP_cring UP_one_not_zero UP_integral del: disjCI)
  1114 
  1115 text {*
  1116   Instantiation of results from @{term domain}.
  1117 *}
  1118 
  1119 lemmas (in UP_domain) UP_zero_not_one [simp] =
  1120   domain.zero_not_one [OF UP_domain]
  1121 
  1122 lemmas (in UP_domain) UP_integral_iff =
  1123   domain.integral_iff [OF UP_domain]
  1124 
  1125 lemmas (in UP_domain) UP_m_lcancel =
  1126   domain.m_lcancel [OF UP_domain]
  1127 
  1128 lemmas (in UP_domain) UP_m_rcancel =
  1129   domain.m_rcancel [OF UP_domain]
  1130 
  1131 lemma (in UP_domain) smult_integral:
  1132   "[| a \<odot>\<^sub>2 p = \<zero>\<^sub>2; a \<in> carrier R; p \<in> carrier P |] ==> a = \<zero> | p = \<zero>\<^sub>2"
  1133   by (simp add: monom_mult_is_smult [THEN sym] UP_integral_iff
  1134     inj_on_iff [OF monom_inj, of _ "\<zero>", simplified])
  1135 
  1136 
  1137 subsection {* Evaluation Homomorphism and Universal Property*}
  1138 
  1139 (* alternative congruence rule (possibly more efficient)
  1140 lemma (in abelian_monoid) finsum_cong2:
  1141   "[| !!i. i \<in> A ==> f i \<in> carrier G = True; A = B;
  1142   !!i. i \<in> B ==> f i = g i |] ==> finsum G f A = finsum G g B"
  1143   sorry*)
  1144 
  1145 ML_setup {*
  1146   simpset_ref() := simpset() setsubgoaler asm_full_simp_tac;
  1147 *}
  1148 
  1149 theorem (in cring) diagonal_sum:
  1150   "[| f \<in> {..n + m::nat} -> carrier R; g \<in> {..n + m} -> carrier R |] ==>
  1151   (\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1152   (\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1153 proof -
  1154   assume Rf: "f \<in> {..n + m} -> carrier R" and Rg: "g \<in> {..n + m} -> carrier R"
  1155   {
  1156     fix j
  1157     have "j <= n + m ==>
  1158       (\<Oplus>k \<in> {..j}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1159       (\<Oplus>k \<in> {..j}. \<Oplus>i \<in> {..j - k}. f k \<otimes> g i)"
  1160     proof (induct j)
  1161       case 0 from Rf Rg show ?case by (simp add: Pi_def)
  1162     next
  1163       case (Suc j)
  1164       (* The following could be simplified if there was a reasoner for
  1165         total orders integrated with simp. *)
  1166       have R6: "!!i k. [| k <= j; i <= Suc j - k |] ==> g i \<in> carrier R"
  1167         using Suc by (auto intro!: funcset_mem [OF Rg]) arith
  1168       have R8: "!!i k. [| k <= Suc j; i <= k |] ==> g (k - i) \<in> carrier R"
  1169         using Suc by (auto intro!: funcset_mem [OF Rg]) arith
  1170       have R9: "!!i k. [| k <= Suc j |] ==> f k \<in> carrier R"
  1171         using Suc by (auto intro!: funcset_mem [OF Rf])
  1172       have R10: "!!i k. [| k <= Suc j; i <= Suc j - k |] ==> g i \<in> carrier R"
  1173         using Suc by (auto intro!: funcset_mem [OF Rg]) arith
  1174       have R11: "g 0 \<in> carrier R"
  1175         using Suc by (auto intro!: funcset_mem [OF Rg])
  1176       from Suc show ?case
  1177         by (simp cong: finsum_cong add: Suc_diff_le a_ac
  1178           Pi_def R6 R8 R9 R10 R11)
  1179     qed
  1180   }
  1181   then show ?thesis by fast
  1182 qed
  1183 
  1184 lemma (in abelian_monoid) boundD_carrier:
  1185   "[| bound \<zero> n f; n < m |] ==> f m \<in> carrier G"
  1186   by auto
  1187 
  1188 theorem (in cring) cauchy_product:
  1189   assumes bf: "bound \<zero> n f" and bg: "bound \<zero> m g"
  1190     and Rf: "f \<in> {..n} -> carrier R" and Rg: "g \<in> {..m} -> carrier R"
  1191   shows "(\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1192     (\<Oplus>i \<in> {..n}. f i) \<otimes> (\<Oplus>i \<in> {..m}. g i)"        (* State revese direction? *)
  1193 proof -
  1194   have f: "!!x. f x \<in> carrier R"
  1195   proof -
  1196     fix x
  1197     show "f x \<in> carrier R"
  1198       using Rf bf boundD_carrier by (cases "x <= n") (auto simp: Pi_def)
  1199   qed
  1200   have g: "!!x. g x \<in> carrier R"
  1201   proof -
  1202     fix x
  1203     show "g x \<in> carrier R"
  1204       using Rg bg boundD_carrier by (cases "x <= m") (auto simp: Pi_def)
  1205   qed
  1206   from f g have "(\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1207       (\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1208     by (simp add: diagonal_sum Pi_def)
  1209   also have "... = (\<Oplus>k \<in> {..n} \<union> {n<..n + m}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1210     by (simp only: ivl_disj_un_one)
  1211   also from f g have "... = (\<Oplus>k \<in> {..n}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1212     by (simp cong: finsum_cong
  1213       add: bound.bound [OF bf] finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1214   also from f g have "... = (\<Oplus>k \<in> {..n}. \<Oplus>i \<in> {..m} \<union> {m<..n + m - k}. f k \<otimes> g i)"
  1215     by (simp cong: finsum_cong add: ivl_disj_un_one le_add_diff Pi_def)
  1216   also from f g have "... = (\<Oplus>k \<in> {..n}. \<Oplus>i \<in> {..m}. f k \<otimes> g i)"
  1217     by (simp cong: finsum_cong
  1218       add: bound.bound [OF bg] finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1219   also from f g have "... = (\<Oplus>i \<in> {..n}. f i) \<otimes> (\<Oplus>i \<in> {..m}. g i)"
  1220     by (simp add: finsum_ldistr diagonal_sum Pi_def,
  1221       simp cong: finsum_cong add: finsum_rdistr Pi_def)
  1222   finally show ?thesis .
  1223 qed
  1224 
  1225 lemma (in UP_cring) const_ring_hom:
  1226   "(%a. monom P a 0) \<in> ring_hom R P"
  1227   by (auto intro!: ring_hom_memI intro: up_eqI simp: monom_mult_is_smult)
  1228 
  1229 constdefs (structure S)
  1230   eval :: "[_, _, 'a => 'b, 'b, nat => 'a] => 'b"
  1231   "eval R S phi s == \<lambda>p \<in> carrier (UP R).
  1232     \<Oplus>i \<in> {..deg R p}. phi (coeff (UP R) p i) \<otimes> pow S s i"
  1233 (*
  1234   "eval R S phi s p == if p \<in> carrier (UP R)
  1235   then finsum S (%i. mult S (phi (coeff (UP R) p i)) (pow S s i)) {..deg R p}
  1236   else arbitrary"
  1237 *)
  1238 
  1239 locale ring_hom_UP_cring = ring_hom_cring R S + UP_cring R
  1240 
  1241 lemma (in ring_hom_UP_cring) eval_on_carrier:
  1242   "p \<in> carrier P ==>
  1243     eval R S phi s p =
  1244     (\<Oplus>\<^sub>2 i \<in> {..deg R p}. phi (coeff P p i) \<otimes>\<^sub>2 pow S s i)"
  1245   by (unfold eval_def, fold P_def) simp
  1246 
  1247 lemma (in ring_hom_UP_cring) eval_extensional:
  1248   "eval R S phi s \<in> extensional (carrier P)"
  1249   by (unfold eval_def, fold P_def) simp
  1250 
  1251 theorem (in ring_hom_UP_cring) eval_ring_hom:
  1252   "s \<in> carrier S ==> eval R S h s \<in> ring_hom P S"
  1253 proof (rule ring_hom_memI)
  1254   fix p
  1255   assume RS: "p \<in> carrier P" "s \<in> carrier S"
  1256   then show "eval R S h s p \<in> carrier S"
  1257     by (simp only: eval_on_carrier) (simp add: Pi_def)
  1258 next
  1259   fix p q
  1260   assume RS: "p \<in> carrier P" "q \<in> carrier P" "s \<in> carrier S"
  1261   then show "eval R S h s (p \<otimes>\<^sub>3 q) = eval R S h s p \<otimes>\<^sub>2 eval R S h s q"
  1262   proof (simp only: eval_on_carrier UP_mult_closed)
  1263     from RS have
  1264       "(\<Oplus>\<^sub>2 i \<in> {..deg R (p \<otimes>\<^sub>3 q)}. h (coeff P (p \<otimes>\<^sub>3 q) i) \<otimes>\<^sub>2 s (^)\<^sub>2 i) =
  1265       (\<Oplus>\<^sub>2 i \<in> {..deg R (p \<otimes>\<^sub>3 q)} \<union> {deg R (p \<otimes>\<^sub>3 q)<..deg R p + deg R q}.
  1266         h (coeff P (p \<otimes>\<^sub>3 q) i) \<otimes>\<^sub>2 s (^)\<^sub>2 i)"
  1267       by (simp cong: finsum_cong
  1268         add: deg_aboveD finsum_Un_disjoint ivl_disj_int_one Pi_def
  1269         del: coeff_mult)
  1270     also from RS have "... =
  1271       (\<Oplus>\<^sub>2 i \<in> {..deg R p + deg R q}. h (coeff P (p \<otimes>\<^sub>3 q) i) \<otimes>\<^sub>2 s (^)\<^sub>2 i)"
  1272       by (simp only: ivl_disj_un_one deg_mult_cring)
  1273     also from RS have "... =
  1274       (\<Oplus>\<^sub>2 i \<in> {..deg R p + deg R q}.
  1275        \<Oplus>\<^sub>2 k \<in> {..i}. h (coeff P p k) \<otimes>\<^sub>2 h (coeff P q (i - k)) \<otimes>\<^sub>2 (s (^)\<^sub>2 k \<otimes>\<^sub>2 s (^)\<^sub>2 (i - k)))"
  1276       by (simp cong: finsum_cong add: nat_pow_mult Pi_def
  1277         S.m_ac S.finsum_rdistr)
  1278     also from RS have "... =
  1279       (\<Oplus>\<^sub>2i\<in>{..deg R p}. h (coeff P p i) \<otimes>\<^sub>2 s (^)\<^sub>2 i) \<otimes>\<^sub>2
  1280       (\<Oplus>\<^sub>2i\<in>{..deg R q}. h (coeff P q i) \<otimes>\<^sub>2 s (^)\<^sub>2 i)"
  1281       by (simp add: S.cauchy_product [THEN sym] bound.intro deg_aboveD S.m_ac
  1282         Pi_def)
  1283     finally show
  1284       "(\<Oplus>\<^sub>2 i \<in> {..deg R (p \<otimes>\<^sub>3 q)}. h (coeff P (p \<otimes>\<^sub>3 q) i) \<otimes>\<^sub>2 s (^)\<^sub>2 i) =
  1285       (\<Oplus>\<^sub>2 i \<in> {..deg R p}. h (coeff P p i) \<otimes>\<^sub>2 s (^)\<^sub>2 i) \<otimes>\<^sub>2
  1286       (\<Oplus>\<^sub>2 i \<in> {..deg R q}. h (coeff P q i) \<otimes>\<^sub>2 s (^)\<^sub>2 i)" .
  1287   qed
  1288 next
  1289   fix p q
  1290   assume RS: "p \<in> carrier P" "q \<in> carrier P" "s \<in> carrier S"
  1291   then show "eval R S h s (p \<oplus>\<^sub>3 q) = eval R S h s p \<oplus>\<^sub>2 eval R S h s q"
  1292   proof (simp only: eval_on_carrier UP_a_closed)
  1293     from RS have
  1294       "(\<Oplus>\<^sub>2i \<in> {..deg R (p \<oplus>\<^sub>3 q)}. h (coeff P (p \<oplus>\<^sub>3 q) i) \<otimes>\<^sub>2 s (^)\<^sub>2 i) =
  1295       (\<Oplus>\<^sub>2i \<in> {..deg R (p \<oplus>\<^sub>3 q)} \<union> {deg R (p \<oplus>\<^sub>3 q)<..max (deg R p) (deg R q)}.
  1296         h (coeff P (p \<oplus>\<^sub>3 q) i) \<otimes>\<^sub>2 s (^)\<^sub>2 i)"
  1297       by (simp cong: finsum_cong
  1298         add: deg_aboveD finsum_Un_disjoint ivl_disj_int_one Pi_def
  1299         del: coeff_add)
  1300     also from RS have "... =
  1301         (\<Oplus>\<^sub>2 i \<in> {..max (deg R p) (deg R q)}. h (coeff P (p \<oplus>\<^sub>3 q) i) \<otimes>\<^sub>2 s (^)\<^sub>2 i)"
  1302       by (simp add: ivl_disj_un_one)
  1303     also from RS have "... =
  1304       (\<Oplus>\<^sub>2i\<in>{..max (deg R p) (deg R q)}. h (coeff P p i) \<otimes>\<^sub>2 s (^)\<^sub>2 i) \<oplus>\<^sub>2
  1305       (\<Oplus>\<^sub>2i\<in>{..max (deg R p) (deg R q)}. h (coeff P q i) \<otimes>\<^sub>2 s (^)\<^sub>2 i)"
  1306       by (simp cong: finsum_cong
  1307         add: l_distr deg_aboveD finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1308     also have "... =
  1309         (\<Oplus>\<^sub>2 i \<in> {..deg R p} \<union> {deg R p<..max (deg R p) (deg R q)}.
  1310           h (coeff P p i) \<otimes>\<^sub>2 s (^)\<^sub>2 i) \<oplus>\<^sub>2
  1311         (\<Oplus>\<^sub>2 i \<in> {..deg R q} \<union> {deg R q<..max (deg R p) (deg R q)}.
  1312           h (coeff P q i) \<otimes>\<^sub>2 s (^)\<^sub>2 i)"
  1313       by (simp only: ivl_disj_un_one le_maxI1 le_maxI2)
  1314     also from RS have "... =
  1315       (\<Oplus>\<^sub>2 i \<in> {..deg R p}. h (coeff P p i) \<otimes>\<^sub>2 s (^)\<^sub>2 i) \<oplus>\<^sub>2
  1316       (\<Oplus>\<^sub>2 i \<in> {..deg R q}. h (coeff P q i) \<otimes>\<^sub>2 s (^)\<^sub>2 i)"
  1317       by (simp cong: finsum_cong
  1318         add: deg_aboveD finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1319     finally show
  1320       "(\<Oplus>\<^sub>2i \<in> {..deg R (p \<oplus>\<^sub>3 q)}. h (coeff P (p \<oplus>\<^sub>3 q) i) \<otimes>\<^sub>2 s (^)\<^sub>2 i) =
  1321       (\<Oplus>\<^sub>2i \<in> {..deg R p}. h (coeff P p i) \<otimes>\<^sub>2 s (^)\<^sub>2 i) \<oplus>\<^sub>2
  1322       (\<Oplus>\<^sub>2i \<in> {..deg R q}. h (coeff P q i) \<otimes>\<^sub>2 s (^)\<^sub>2 i)"
  1323       .
  1324   qed
  1325 next
  1326   assume S: "s \<in> carrier S"
  1327   then show "eval R S h s \<one>\<^sub>3 = \<one>\<^sub>2"
  1328     by (simp only: eval_on_carrier UP_one_closed) simp
  1329 qed
  1330 
  1331 text {* Instantiation of ring homomorphism lemmas. *}
  1332 
  1333 lemma (in ring_hom_UP_cring) ring_hom_cring_P_S:
  1334   "s \<in> carrier S ==> ring_hom_cring P S (eval R S h s)"
  1335   by (fast intro!: ring_hom_cring.intro UP_cring cring.axioms prems
  1336   intro: ring_hom_cring_axioms.intro eval_ring_hom)
  1337 
  1338 lemma (in ring_hom_UP_cring) UP_hom_closed [intro, simp]:
  1339   "[| s \<in> carrier S; p \<in> carrier P |] ==> eval R S h s p \<in> carrier S"
  1340   by (rule ring_hom_cring.hom_closed [OF ring_hom_cring_P_S])
  1341 
  1342 lemma (in ring_hom_UP_cring) UP_hom_mult [simp]:
  1343   "[| s \<in> carrier S; p \<in> carrier P; q \<in> carrier P |] ==>
  1344   eval R S h s (p \<otimes>\<^sub>3 q) = eval R S h s p \<otimes>\<^sub>2 eval R S h s q"
  1345   by (rule ring_hom_cring.hom_mult [OF ring_hom_cring_P_S])
  1346 
  1347 lemma (in ring_hom_UP_cring) UP_hom_add [simp]:
  1348   "[| s \<in> carrier S; p \<in> carrier P; q \<in> carrier P |] ==>
  1349   eval R S h s (p \<oplus>\<^sub>3 q) = eval R S h s p \<oplus>\<^sub>2 eval R S h s q"
  1350   by (rule ring_hom_cring.hom_add [OF ring_hom_cring_P_S])
  1351 
  1352 lemma (in ring_hom_UP_cring) UP_hom_one [simp]:
  1353   "s \<in> carrier S ==> eval R S h s \<one>\<^sub>3 = \<one>\<^sub>2"
  1354   by (rule ring_hom_cring.hom_one [OF ring_hom_cring_P_S])
  1355 
  1356 lemma (in ring_hom_UP_cring) UP_hom_zero [simp]:
  1357   "s \<in> carrier S ==> eval R S h s \<zero>\<^sub>3 = \<zero>\<^sub>2"
  1358   by (rule ring_hom_cring.hom_zero [OF ring_hom_cring_P_S])
  1359 
  1360 lemma (in ring_hom_UP_cring) UP_hom_a_inv [simp]:
  1361   "[| s \<in> carrier S; p \<in> carrier P |] ==>
  1362   (eval R S h s) (\<ominus>\<^sub>3 p) = \<ominus>\<^sub>2 (eval R S h s) p"
  1363   by (rule ring_hom_cring.hom_a_inv [OF ring_hom_cring_P_S])
  1364 
  1365 lemma (in ring_hom_UP_cring) UP_hom_finsum [simp]:
  1366   "[| s \<in> carrier S; finite A; f \<in> A -> carrier P |] ==>
  1367   (eval R S h s) (finsum P f A) = finsum S (eval R S h s o f) A"
  1368   by (rule ring_hom_cring.hom_finsum [OF ring_hom_cring_P_S])
  1369 
  1370 lemma (in ring_hom_UP_cring) UP_hom_finprod [simp]:
  1371   "[| s \<in> carrier S; finite A; f \<in> A -> carrier P |] ==>
  1372   (eval R S h s) (finprod P f A) = finprod S (eval R S h s o f) A"
  1373   by (rule ring_hom_cring.hom_finprod [OF ring_hom_cring_P_S])
  1374 
  1375 text {* Further properties of the evaluation homomorphism. *}
  1376 
  1377 (* The following lemma could be proved in UP\_cring with the additional
  1378    assumption that h is closed. *)
  1379 
  1380 lemma (in ring_hom_UP_cring) eval_const:
  1381   "[| s \<in> carrier S; r \<in> carrier R |] ==> eval R S h s (monom P r 0) = h r"
  1382   by (simp only: eval_on_carrier monom_closed) simp
  1383 
  1384 text {* The following proof is complicated by the fact that in arbitrary
  1385   rings one might have @{term "one R = zero R"}. *}
  1386 
  1387 (* TODO: simplify by cases "one R = zero R" *)
  1388 
  1389 lemma (in ring_hom_UP_cring) eval_monom1:
  1390   "s \<in> carrier S ==> eval R S h s (monom P \<one> 1) = s"
  1391 proof (simp only: eval_on_carrier monom_closed R.one_closed)
  1392   assume S: "s \<in> carrier S"
  1393   then have
  1394     "(\<Oplus>\<^sub>2 i \<in> {..deg R (monom P \<one> 1)}. h (coeff P (monom P \<one> 1) i) \<otimes>\<^sub>2 s (^)\<^sub>2 i) =
  1395     (\<Oplus>\<^sub>2i\<in>{..deg R (monom P \<one> 1)} \<union> {deg R (monom P \<one> 1)<..1}.
  1396       h (coeff P (monom P \<one> 1) i) \<otimes>\<^sub>2 s (^)\<^sub>2 i)"
  1397     by (simp cong: finsum_cong del: coeff_monom
  1398       add: deg_aboveD finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1399   also have "... =
  1400     (\<Oplus>\<^sub>2 i \<in> {..1}. h (coeff P (monom P \<one> 1) i) \<otimes>\<^sub>2 s (^)\<^sub>2 i)"
  1401     by (simp only: ivl_disj_un_one deg_monom_le R.one_closed)
  1402   also have "... = s"
  1403   proof (cases "s = \<zero>\<^sub>2")
  1404     case True then show ?thesis by (simp add: Pi_def)
  1405   next
  1406     case False with S show ?thesis by (simp add: Pi_def)
  1407   qed
  1408   finally show "(\<Oplus>\<^sub>2 i \<in> {..deg R (monom P \<one> 1)}.
  1409     h (coeff P (monom P \<one> 1) i) \<otimes>\<^sub>2 s (^)\<^sub>2 i) = s" .
  1410 qed
  1411 
  1412 lemma (in UP_cring) monom_pow:
  1413   assumes R: "a \<in> carrier R"
  1414   shows "(monom P a n) (^)\<^sub>2 m = monom P (a (^) m) (n * m)"
  1415 proof (induct m)
  1416   case 0 from R show ?case by simp
  1417 next
  1418   case Suc with R show ?case
  1419     by (simp del: monom_mult add: monom_mult [THEN sym] add_commute)
  1420 qed
  1421 
  1422 lemma (in ring_hom_cring) hom_pow [simp]:
  1423   "x \<in> carrier R ==> h (x (^) n) = h x (^)\<^sub>2 (n::nat)"
  1424   by (induct n) simp_all
  1425 
  1426 lemma (in ring_hom_UP_cring) UP_hom_pow [simp]:
  1427   "[| s \<in> carrier S; p \<in> carrier P |] ==>
  1428   (eval R S h s) (p (^)\<^sub>3 n) = eval R S h s p (^)\<^sub>2 (n::nat)"
  1429   by (rule ring_hom_cring.hom_pow [OF ring_hom_cring_P_S])
  1430 
  1431 lemma (in ring_hom_UP_cring) eval_monom:
  1432   "[| s \<in> carrier S; r \<in> carrier R |] ==>
  1433   eval R S h s (monom P r n) = h r \<otimes>\<^sub>2 s (^)\<^sub>2 n"
  1434 proof -
  1435   assume RS: "s \<in> carrier S" "r \<in> carrier R"
  1436   then have "eval R S h s (monom P r n) =
  1437     eval R S h s (monom P r 0 \<otimes>\<^sub>3 (monom P \<one> 1) (^)\<^sub>3 n)"
  1438     by (simp del: monom_mult UP_hom_mult UP_hom_pow
  1439       add: monom_mult [THEN sym] monom_pow)
  1440   also from RS eval_monom1 have "... = h r \<otimes>\<^sub>2 s (^)\<^sub>2 n"
  1441     by (simp add: eval_const)
  1442   finally show ?thesis .
  1443 qed
  1444 
  1445 lemma (in ring_hom_UP_cring) eval_smult:
  1446   "[| s \<in> carrier S; r \<in> carrier R; p \<in> carrier P |] ==>
  1447   eval R S h s (r \<odot>\<^sub>3 p) = h r \<otimes>\<^sub>2 eval R S h s p"
  1448   by (simp add: monom_mult_is_smult [THEN sym] eval_const)
  1449 
  1450 lemma ring_hom_cringI:
  1451   assumes "cring R"
  1452     and "cring S"
  1453     and "h \<in> ring_hom R S"
  1454   shows "ring_hom_cring R S h"
  1455   by (fast intro: ring_hom_cring.intro ring_hom_cring_axioms.intro
  1456     cring.axioms prems)
  1457 
  1458 lemma (in ring_hom_UP_cring) UP_hom_unique:
  1459   assumes Phi: "Phi \<in> ring_hom P S" "Phi (monom P \<one> (Suc 0)) = s"
  1460       "!!r. r \<in> carrier R ==> Phi (monom P r 0) = h r"
  1461     and Psi: "Psi \<in> ring_hom P S" "Psi (monom P \<one> (Suc 0)) = s"
  1462       "!!r. r \<in> carrier R ==> Psi (monom P r 0) = h r"
  1463     and RS: "s \<in> carrier S" "p \<in> carrier P"
  1464   shows "Phi p = Psi p"
  1465 proof -
  1466   have Phi_hom: "ring_hom_cring P S Phi"
  1467     by (auto intro: ring_hom_cringI UP_cring S.cring Phi)
  1468   have Psi_hom: "ring_hom_cring P S Psi"
  1469     by (auto intro: ring_hom_cringI UP_cring S.cring Psi)
  1470   have "Phi p = Phi (\<Oplus>\<^sub>3i \<in> {..deg R p}. monom P (coeff P p i) 0 \<otimes>\<^sub>3 monom P \<one> 1 (^)\<^sub>3 i)"
  1471     by (simp add: up_repr RS monom_mult [THEN sym] monom_pow del: monom_mult)
  1472   also have "... = Psi (\<Oplus>\<^sub>3i\<in>{..deg R p}. monom P (coeff P p i) 0 \<otimes>\<^sub>3 monom P \<one> 1 (^)\<^sub>3 i)"
  1473     by (simp add: ring_hom_cring.hom_finsum [OF Phi_hom]
  1474       ring_hom_cring.hom_mult [OF Phi_hom]
  1475       ring_hom_cring.hom_pow [OF Phi_hom] Phi
  1476       ring_hom_cring.hom_finsum [OF Psi_hom]
  1477       ring_hom_cring.hom_mult [OF Psi_hom]
  1478       ring_hom_cring.hom_pow [OF Psi_hom] Psi RS Pi_def comp_def)
  1479   also have "... = Psi p"
  1480     by (simp add: up_repr RS monom_mult [THEN sym] monom_pow del: monom_mult)
  1481   finally show ?thesis .
  1482 qed
  1483 
  1484 
  1485 theorem (in ring_hom_UP_cring) UP_universal_property:
  1486   "s \<in> carrier S ==>
  1487   EX! Phi. Phi \<in> ring_hom P S \<inter> extensional (carrier P) &
  1488     Phi (monom P \<one> 1) = s &
  1489     (ALL r : carrier R. Phi (monom P r 0) = h r)"
  1490   using eval_monom1
  1491   apply (auto intro: eval_ring_hom eval_const eval_extensional)
  1492   apply (rule extensionalityI)
  1493   apply (auto intro: UP_hom_unique)
  1494   done
  1495 
  1496 subsection {* Sample application of evaluation homomorphism *}
  1497 
  1498 lemma ring_hom_UP_cringI:
  1499   assumes "cring R"
  1500     and "cring S"
  1501     and "h \<in> ring_hom R S"
  1502   shows "ring_hom_UP_cring R S h"
  1503   by (fast intro: ring_hom_UP_cring.intro ring_hom_cring_axioms.intro
  1504     cring.axioms prems)
  1505 
  1506 constdefs
  1507   INTEG :: "int ring"
  1508   "INTEG == (| carrier = UNIV, mult = op *, one = 1, zero = 0, add = op + |)"
  1509 
  1510 lemma cring_INTEG:
  1511   "cring INTEG"
  1512   by (unfold INTEG_def) (auto intro!: cringI abelian_groupI comm_monoidI
  1513     zadd_zminus_inverse2 zadd_zmult_distrib)
  1514 
  1515 lemma INTEG_id:
  1516   "ring_hom_UP_cring INTEG INTEG id"
  1517   by (fast intro: ring_hom_UP_cringI cring_INTEG id_ring_hom)
  1518 
  1519 text {*
  1520   An instantiation mechanism would now import all theorems and lemmas
  1521   valid in the context of homomorphisms between @{term INTEG} and @{term
  1522   "UP INTEG"}.
  1523 *}
  1524 
  1525 lemma INTEG_closed [intro, simp]:
  1526   "z \<in> carrier INTEG"
  1527   by (unfold INTEG_def) simp
  1528 
  1529 lemma INTEG_mult [simp]:
  1530   "mult INTEG z w = z * w"
  1531   by (unfold INTEG_def) simp
  1532 
  1533 lemma INTEG_pow [simp]:
  1534   "pow INTEG z n = z ^ n"
  1535   by (induct n) (simp_all add: INTEG_def nat_pow_def)
  1536 
  1537 lemma "eval INTEG INTEG id 10 (monom (UP INTEG) 5 2) = 500"
  1538   by (simp add: ring_hom_UP_cring.eval_monom [OF INTEG_id])
  1539 
  1540 end