src/Pure/pure_thy.ML
author wenzelm
Thu Jul 08 18:31:04 1999 +0200 (1999-07-08)
changeset 6930 4b40fb299f9f
parent 6846 f2380295d4dd
child 6977 4781c0673e83
permissions -rw-r--r--
improved error msgs of cterm_instantiate;
fixed incr_indexes;
     1 (*  Title:      Pure/pure_thy.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Theorem database, derived theory operations, and the ProtoPure theory.
     6 *)
     7 
     8 signature BASIC_PURE_THY =
     9 sig
    10   val print_theorems: theory -> unit
    11   val print_theory: theory -> unit
    12   val get_thm: theory -> xstring -> thm
    13   val get_thms: theory -> xstring -> thm list
    14   val get_thmss: theory -> xstring list -> thm list
    15   val thms_of: theory -> (string * thm) list
    16   structure ProtoPure:
    17     sig
    18       val thy: theory
    19       val flexpair_def: thm
    20       val Goal_def: thm
    21     end
    22 end;
    23 
    24 signature PURE_THY =
    25 sig
    26   include BASIC_PURE_THY
    27   val cond_extern_thm_sg: Sign.sg -> string -> xstring
    28   val thms_closure: theory -> xstring -> thm list option
    29   val thms_containing: theory -> string list -> (string * thm) list
    30   val default_name: string -> string
    31   val store_thm: (bstring * thm) * theory attribute list -> theory -> theory * thm
    32   val smart_store_thm: (bstring * thm) -> thm
    33   val add_thms: ((bstring * thm) * theory attribute list) list -> theory -> theory
    34   val add_thmss: ((bstring * thm list) * theory attribute list) list -> theory -> theory
    35   val have_thmss: bstring option -> theory attribute list ->
    36     (thm list * theory attribute list) list -> theory -> theory * thm list
    37   val add_axioms: ((bstring * string) * theory attribute list) list -> theory -> theory
    38   val add_axioms_i: ((bstring * term) * theory attribute list) list -> theory -> theory
    39   val add_axiomss: ((bstring * string list) * theory attribute list) list -> theory -> theory
    40   val add_axiomss_i: ((bstring * term list) * theory attribute list) list -> theory -> theory
    41   val add_defs: ((bstring * string) * theory attribute list) list -> theory -> theory
    42   val add_defs_i: ((bstring * term) * theory attribute list) list -> theory -> theory
    43   val add_defss: ((bstring * string list) * theory attribute list) list -> theory -> theory
    44   val add_defss_i: ((bstring * term list) * theory attribute list) list -> theory -> theory
    45   val get_name: theory -> string
    46   val put_name: string -> theory -> theory
    47   val global_path: theory -> theory
    48   val local_path: theory -> theory
    49   val begin_theory: string -> theory list -> theory
    50   val end_theory: theory -> theory
    51   val checkpoint: theory -> theory
    52   val add_typedecls: (bstring * string list * mixfix) list -> theory -> theory
    53   val dummy_patternN: string
    54 end;
    55 
    56 structure PureThy: PURE_THY =
    57 struct
    58 
    59 
    60 (*** theorem database ***)
    61 
    62 (** data kind 'Pure/theorems' **)
    63 
    64 structure TheoremsDataArgs =
    65 struct
    66   val name = "Pure/theorems";
    67 
    68   type T =
    69     {space: NameSpace.T,
    70       thms_tab: thm list Symtab.table,
    71       const_idx: int * (int * thm) list Symtab.table} ref;
    72 
    73   fun mk_empty _ =
    74     ref {space = NameSpace.empty, thms_tab = Symtab.empty, const_idx = (0, Symtab.empty)} : T;
    75 
    76   val empty = mk_empty ();
    77   fun copy (ref x) = ref x;
    78   val prep_ext = mk_empty;
    79   val merge = mk_empty;
    80 
    81   fun print sg (ref {space, thms_tab, const_idx = _}) =
    82     let
    83       val prt_thm = Display.pretty_thm o Thm.transfer_sg sg;
    84       fun prt_thms (name, [th]) =
    85             Pretty.block [Pretty.str (name ^ ":"), Pretty.brk 1, prt_thm th]
    86         | prt_thms (name, ths) = Pretty.big_list (name ^ ":") (map prt_thm ths);
    87 
    88       val thmss = NameSpace.cond_extern_table space thms_tab;
    89     in
    90       Pretty.writeln (Display.pretty_name_space ("theorem name space", space));
    91       Pretty.writeln (Pretty.big_list "theorems:" (map prt_thms thmss))
    92     end;
    93 end;
    94 
    95 structure TheoremsData = TheoryDataFun(TheoremsDataArgs);
    96 val get_theorems_sg = TheoremsData.get_sg;
    97 val get_theorems = TheoremsData.get;
    98 
    99 val cond_extern_thm_sg = NameSpace.cond_extern o #space o ! o get_theorems_sg;
   100 
   101 
   102 (* print theory *)
   103 
   104 val print_theorems = TheoremsData.print;
   105 fun print_theory thy =
   106   (Display.print_theory thy; print_theorems thy);
   107 
   108 
   109 
   110 (** retrieve theorems **)
   111 
   112 (* thms_closure *)
   113 
   114 (*note: we avoid life references to the theory, so users may safely
   115   keep thms_closure with moderate space consumption*)
   116 
   117 fun thms_closure_aux thy =
   118   let val ref {space, thms_tab, ...} = get_theorems thy
   119   in fn name => Symtab.lookup (thms_tab, NameSpace.intern space name) end;
   120 
   121 fun thms_closure thy =
   122   let val closures = map thms_closure_aux (thy :: Theory.ancestors_of thy)
   123   in fn name => get_first (fn f => f name) closures end;
   124 
   125 
   126 (* get_thms etc. *)
   127 
   128 fun lookup_thms name thy = thms_closure_aux thy name;
   129 
   130 fun get_thms thy name =
   131   (case get_first (lookup_thms name) (thy :: Theory.ancestors_of thy) of
   132     None => raise THEORY ("Unknown theorem(s) " ^ quote name, [thy])
   133   | Some thms => thms);
   134 
   135 fun get_thm thy name =
   136   (case get_thms thy name of
   137     [thm] => thm
   138   | _ => raise THEORY ("Single theorem expected " ^ quote name, [thy]));
   139 
   140 fun get_thmss thy names = flat (map (get_thms thy) names);
   141 
   142 
   143 (* thms_of *)
   144 
   145 fun attach_name thm = (Thm.name_of_thm thm, thm);
   146 
   147 fun thms_of thy =
   148   let val ref {thms_tab, ...} = get_theorems thy in
   149     map attach_name (flat (map snd (Symtab.dest thms_tab)))
   150   end;
   151 
   152 
   153 
   154 (** theorems indexed by constants **)
   155 
   156 (* make index *)
   157 
   158 val ignore = ["Trueprop", "all", "==>", "=="];
   159 
   160 fun add_const_idx ((next, table), thm) =
   161   let
   162     val {hyps, prop, ...} = Thm.rep_thm thm;
   163     val consts =
   164       foldr add_term_consts (hyps, add_term_consts (prop, [])) \\ ignore;
   165 
   166     fun add (tab, c) =
   167       Symtab.update ((c, (next, thm) :: Symtab.lookup_multi (tab, c)), tab);
   168   in (next + 1, foldl add (table, consts)) end;
   169 
   170 fun make_const_idx thm_tab =
   171   Symtab.foldl (fn (x, (_, ths)) => foldl add_const_idx (x, ths)) ((0, Symtab.empty), thm_tab);
   172 
   173 
   174 (* lookup index *)
   175 
   176 (*search locally*)
   177 fun containing [] thy = thms_of thy
   178   | containing consts thy =
   179       let
   180         fun int ([], _) = []
   181           | int (_, []) = []
   182           | int (xxs as ((x as (i:int, _)) :: xs), yys as ((y as (j, _)) :: ys)) =
   183               if i = j then x :: int (xs, ys)
   184               else if i > j then int (xs, yys)
   185               else int (xxs, ys);
   186 
   187         fun ints [xs] = xs
   188           | ints xss = if exists null xss then [] else foldl int (hd xss, tl xss);
   189 
   190         val ref {const_idx = (_, ctab), ...} = get_theorems thy;
   191         val ithmss = map (fn c => Symtab.lookup_multi (ctab, c)) consts;
   192       in
   193         map (attach_name o snd) (ints ithmss)
   194       end;
   195 
   196 (*search globally*)
   197 fun thms_containing thy consts =
   198   flat (map (containing (consts \\ ignore)) (thy :: Theory.ancestors_of thy));
   199 
   200 
   201 
   202 (** store theorems **)                    (*DESTRUCTIVE*)
   203 
   204 (* naming *)
   205 
   206 val defaultN = "it";
   207 val default_name = fn "" => defaultN | name => name;
   208 
   209 fun gen_names len name =
   210   map (fn i => name ^ "_" ^ string_of_int i) (1 upto len);
   211 
   212 fun name_single name x = [(default_name name, x)];
   213 fun name_multi name xs = gen_names (length xs) (default_name name) ~~ xs;
   214 
   215 
   216 (* enter_thmx *)
   217 
   218 fun cond_warning name msg = if Sign.base_name name = defaultN then () else warning msg;
   219 
   220 fun warn_overwrite name =
   221   cond_warning name ("Replaced old copy of theorems " ^ quote name);
   222 
   223 fun warn_same name =
   224   cond_warning name ("Theorem database already contains a copy of " ^ quote name);
   225 
   226 fun enter_thmx sg app_name (bname, thmx) =
   227   let
   228     val name = Sign.full_name sg (default_name bname);
   229     val named_thms = map Thm.name_thm (app_name name thmx);
   230 
   231     val r as ref {space, thms_tab, const_idx} = get_theorems_sg sg;
   232 
   233     val overwrite =
   234       (case Symtab.lookup (thms_tab, name) of
   235         None => false
   236       | Some thms' =>
   237           if length thms' = length named_thms andalso forall2 Thm.eq_thm (thms', named_thms) then
   238             (warn_same name; false)
   239           else (warn_overwrite name; true));
   240 
   241     val space' = NameSpace.extend (space, [name]);
   242     val thms_tab' = Symtab.update ((name, named_thms), thms_tab);
   243     val const_idx' =
   244       if overwrite then make_const_idx thms_tab'
   245       else foldl add_const_idx (const_idx, named_thms);
   246   in
   247     r := {space = space', thms_tab = thms_tab', const_idx = const_idx'};
   248     named_thms
   249   end;
   250 
   251 
   252 (* add_thms(s) *)
   253 
   254 fun add_thmx app_name app_att ((bname, thmx), atts) thy =
   255   let
   256     val (thy', thmx') = app_att ((thy, thmx), atts);
   257     val thms'' = enter_thmx (Theory.sign_of thy') app_name (bname, thmx');
   258   in (thy', thms'') end;
   259 
   260 fun add_thmxs name app = Library.apply o map (fst oo add_thmx name app);
   261 
   262 val add_thms = add_thmxs name_single Thm.apply_attributes;
   263 val add_thmss = add_thmxs name_multi Thm.applys_attributes;
   264 
   265 
   266 (* have_thmss *)
   267 
   268 fun have_thmss opt_bname more_atts ths_atts thy =
   269   let
   270     fun app (x, (ths, atts)) = Thm.applys_attributes ((x, ths), atts);
   271     val (thy', thmss') =
   272       foldl_map app (thy, map (fn (ths, atts) => (ths, atts @ more_atts)) ths_atts);
   273     val thms' = flat thmss';
   274     val thms'' =
   275       (case opt_bname of
   276         None => thms'
   277       | Some bname => enter_thmx (Theory.sign_of thy') name_multi (bname, thms'));
   278   in (thy', thms'') end;
   279 
   280 
   281 (* store_thm *)
   282 
   283 fun store_thm th_atts thy =
   284   let val (thy', [th']) = add_thmx name_single Thm.apply_attributes th_atts thy
   285   in (thy', th') end;
   286 
   287 
   288 (* smart_store_thm *)
   289 
   290 fun smart_store_thm (name, thm) =
   291   hd (enter_thmx (Thm.sign_of_thm thm) name_single (name, thm));
   292 
   293 
   294 (* store axioms as theorems *)
   295 
   296 local
   297   fun add_ax app_name add ((name, axs), atts) thy =
   298     let
   299       val named_axs = app_name name axs;
   300       val thy' = add named_axs thy;
   301       val thms = map (Thm.get_axiom thy' o fst) named_axs;
   302     in add_thmss [((name, thms), atts)] thy' end;
   303 
   304   fun add_axs app_name add = Library.apply o map (add_ax app_name add);
   305 in
   306   val add_axioms    = add_axs name_single Theory.add_axioms;
   307   val add_axioms_i  = add_axs name_single Theory.add_axioms_i;
   308   val add_axiomss   = add_axs name_multi Theory.add_axioms;
   309   val add_axiomss_i = add_axs name_multi Theory.add_axioms_i;
   310   val add_defs      = add_axs name_single Theory.add_defs;
   311   val add_defs_i    = add_axs name_single Theory.add_defs_i;
   312   val add_defss     = add_axs name_multi Theory.add_defs;
   313   val add_defss_i   = add_axs name_multi Theory.add_defs_i;
   314 end;
   315 
   316 
   317 
   318 (*** derived theory operations ***)
   319 
   320 (** theory management **)
   321 
   322 (* data kind 'Pure/theory_management' *)
   323 
   324 structure TheoryManagementDataArgs =
   325 struct
   326   val name = "Pure/theory_management";
   327   type T = {name: string, version: int};
   328 
   329   val empty = {name = "", version = 0};
   330   val copy = I;
   331   val prep_ext  = I;
   332   fun merge _ = empty;
   333   fun print _ _ = ();
   334 end;
   335 
   336 structure TheoryManagementData = TheoryDataFun(TheoryManagementDataArgs);
   337 val get_info = TheoryManagementData.get;
   338 val put_info = TheoryManagementData.put;
   339 
   340 
   341 (* get / put name *)
   342 
   343 val get_name = #name o get_info;
   344 fun put_name name = put_info {name = name, version = 0};
   345 
   346 
   347 (* control prefixing of theory name *)
   348 
   349 val global_path = Theory.root_path;
   350 
   351 fun local_path thy =
   352   thy |> Theory.root_path |> Theory.add_path (get_name thy);
   353 
   354 
   355 (* begin / end theory *)
   356 
   357 fun begin_theory name thys =
   358   Theory.prep_ext_merge thys
   359   |> put_name name
   360   |> local_path;
   361 
   362 fun end_theory thy = Theory.add_name (get_name thy) thy;
   363 
   364 fun checkpoint thy =
   365   if is_draft thy then
   366     let val {name, version} = get_info thy in
   367       thy
   368       |> Theory.add_name (name ^ ":" ^ string_of_int version)
   369       |> put_info {name = name, version = version + 1}
   370     end
   371   else thy;
   372 
   373 
   374 
   375 (** add logical types **)
   376 
   377 fun add_typedecls decls thy =
   378   let
   379     val full = Sign.full_name (Theory.sign_of thy);
   380 
   381     fun type_of (raw_name, vs, mx) =
   382       if null (duplicates vs) then (raw_name, length vs, mx)
   383       else error ("Duplicate parameters in type declaration: " ^ quote raw_name);
   384 
   385     fun arity_of (raw_name, len, mx) =
   386       (full (Syntax.type_name raw_name mx), replicate len logicS, logicS);
   387 
   388     val types = map type_of decls;
   389     val arities = map arity_of types;
   390   in
   391     thy
   392     |> Theory.add_types types
   393     |> Theory.add_arities_i arities
   394   end;
   395 
   396 
   397 
   398 (*** the ProtoPure theory ***)
   399 
   400 val dummy_patternN = "dummy_pattern";
   401 
   402 val proto_pure =
   403   Theory.pre_pure
   404   |> Library.apply [TheoremsData.init, TheoryManagementData.init]
   405   |> put_name "ProtoPure"
   406   |> global_path
   407   |> Theory.add_types
   408    [("fun", 2, NoSyn),
   409     ("prop", 0, NoSyn),
   410     ("itself", 1, NoSyn),
   411     ("dummy", 0, NoSyn)]
   412   |> Theory.add_classes_i [(logicC, [])]
   413   |> Theory.add_defsort_i logicS
   414   |> Theory.add_arities_i
   415    [("fun", [logicS, logicS], logicS),
   416     ("prop", [], logicS),
   417     ("itself", [logicS], logicS)]
   418   |> Theory.add_nonterminals Syntax.pure_nonterms
   419   |> Theory.add_syntax Syntax.pure_syntax
   420   |> Theory.add_modesyntax (Symbol.symbolsN, true) Syntax.pure_sym_syntax
   421   |> Theory.add_modesyntax (Symbol.xsymbolsN, true) Syntax.pure_xsym_syntax
   422   |> Theory.add_trfuns Syntax.pure_trfuns
   423   |> Theory.add_trfunsT Syntax.pure_trfunsT
   424   |> Theory.add_syntax
   425    [("==>", "[prop, prop] => prop", Delimfix "op ==>")]
   426   |> Theory.add_consts
   427    [("==", "['a::{}, 'a] => prop", InfixrName ("==", 2)),
   428     ("=?=", "['a::{}, 'a] => prop", InfixrName ("=?=", 2)),
   429     ("==>", "[prop, prop] => prop", Mixfix ("(_/ ==> _)", [2, 1], 1)),
   430     ("all", "('a => prop) => prop", Binder ("!!", 0, 0)),
   431     ("Goal", "prop => prop", Mixfix ("GOAL _", [999], 1000)),
   432     ("TYPE", "'a itself", NoSyn),
   433     (dummy_patternN, "'a", Delimfix "'_")]
   434   |> Theory.add_modesyntax ("", false)
   435     [("Goal", "prop => prop", Mixfix ("_", [0], 0))]
   436   |> local_path
   437   |> (add_defs o map Thm.no_attributes)
   438    [("flexpair_def", "(t =?= u) == (t == u::'a::{})"),
   439     ("Goal_def", "GOAL (PROP A) == PROP A")]
   440   |> end_theory;
   441 
   442 structure ProtoPure =
   443 struct
   444   val thy = proto_pure;
   445   val flexpair_def = get_axiom thy "flexpair_def";
   446   val Goal_def = get_axiom thy "Goal_def";
   447 end;
   448 
   449 
   450 end;
   451 
   452 
   453 structure BasicPureThy: BASIC_PURE_THY = PureThy;
   454 open BasicPureThy;