src/Pure/theory.ML
author wenzelm
Thu Jul 08 18:31:04 1999 +0200 (1999-07-08)
changeset 6930 4b40fb299f9f
parent 6661 24185f54f177
child 6980 bb526ba7ba5f
permissions -rw-r--r--
improved error msgs of cterm_instantiate;
fixed incr_indexes;
     1 (*  Title:      Pure/theory.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4     Copyright   1996  University of Cambridge
     5 
     6 The abstract type "theory" of theories.
     7 *)
     8 
     9 signature BASIC_THEORY =
    10 sig
    11   type theory
    12   exception THEORY of string * theory list
    13   val rep_theory: theory ->
    14     {sign: Sign.sg,
    15       axioms: term Symtab.table,
    16       oracles: ((Sign.sg * Object.T -> term) * stamp) Symtab.table,
    17       parents: theory list,
    18       ancestors: theory list}
    19   val sign_of: theory -> Sign.sg
    20   val is_draft: theory -> bool
    21   val syn_of: theory -> Syntax.syntax
    22   val parents_of: theory -> theory list
    23   val ancestors_of: theory -> theory list
    24   val subthy: theory * theory -> bool
    25   val eq_thy: theory * theory -> bool
    26   val cert_axm: Sign.sg -> string * term -> string * term
    27   val read_def_axm: Sign.sg * (indexname -> typ option) * (indexname -> sort option) ->
    28     string list -> string * string -> string * term
    29   val read_axm: Sign.sg -> string * string -> string * term
    30   val inferT_axm: Sign.sg -> string * term -> string * term
    31 end
    32 
    33 signature THEORY =
    34 sig
    35   include BASIC_THEORY
    36   val axiomK: string
    37   val oracleK: string
    38   (*theory extension primitives*)
    39   val add_classes: (bclass * xclass list) list -> theory -> theory
    40   val add_classes_i: (bclass * class list) list -> theory -> theory
    41   val add_classrel: (xclass * xclass) list -> theory -> theory
    42   val add_classrel_i: (class * class) list -> theory -> theory
    43   val add_defsort: xsort -> theory -> theory
    44   val add_defsort_i: sort -> theory -> theory
    45   val add_types: (bstring * int * mixfix) list -> theory -> theory
    46   val add_nonterminals: bstring list -> theory -> theory
    47   val add_tyabbrs: (bstring * string list * string * mixfix) list
    48     -> theory -> theory
    49   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list
    50     -> theory -> theory
    51   val add_arities: (xstring * xsort list * xsort) list -> theory -> theory
    52   val add_arities_i: (string * sort list * sort) list -> theory -> theory
    53   val add_consts: (bstring * string * mixfix) list -> theory -> theory
    54   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
    55   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    56   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    57   val add_modesyntax: string * bool -> (bstring * string * mixfix) list -> theory -> theory
    58   val add_modesyntax_i: string * bool -> (bstring * typ * mixfix) list -> theory -> theory
    59   val add_trfuns:
    60     (string * (Syntax.ast list -> Syntax.ast)) list *
    61     (string * (term list -> term)) list *
    62     (string * (term list -> term)) list *
    63     (string * (Syntax.ast list -> Syntax.ast)) list -> theory -> theory
    64   val add_trfunsT:
    65     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
    66   val add_tokentrfuns:
    67     (string * string * (string -> string * real)) list -> theory -> theory
    68   val add_mode_tokentrfuns: string -> (string * (string -> string * real)) list
    69     -> theory -> theory
    70   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    71   val add_trrules_i: Syntax.ast Syntax.trrule list -> theory -> theory
    72   val add_axioms: (bstring * string) list -> theory -> theory
    73   val add_axioms_i: (bstring * term) list -> theory -> theory
    74   val add_oracle: bstring * (Sign.sg * Object.T -> term) -> theory -> theory
    75   val add_defs: (bstring * string) list -> theory -> theory
    76   val add_defs_i: (bstring * term) list -> theory -> theory
    77   val add_path: string -> theory -> theory
    78   val parent_path: theory -> theory
    79   val root_path: theory -> theory
    80   val add_space: string * string list -> theory -> theory
    81   val add_name: string -> theory -> theory
    82   val copy: theory -> theory
    83   val prep_ext: theory -> theory
    84   val prep_ext_merge: theory list -> theory
    85   val merge_theories: string -> theory * theory -> theory
    86   val requires: theory -> string -> string -> unit
    87   val assert_super: theory -> theory -> theory
    88   val pre_pure: theory
    89 end;
    90 
    91 signature PRIVATE_THEORY =
    92 sig
    93   include THEORY
    94   val init_data: Object.kind -> (Object.T * (Object.T -> Object.T) * (Object.T -> Object.T) *
    95     (Object.T * Object.T -> Object.T) * (Sign.sg -> Object.T -> unit)) -> theory -> theory
    96   val print_data: Object.kind -> theory -> unit
    97   val get_data: Object.kind -> (Object.T -> 'a) -> theory -> 'a
    98   val put_data: Object.kind -> ('a -> Object.T) -> 'a -> theory -> theory
    99 end;
   100 
   101 
   102 structure Theory: PRIVATE_THEORY =
   103 struct
   104 
   105 
   106 (** datatype theory **)
   107 
   108 datatype theory =
   109   Theory of {
   110     sign: Sign.sg,
   111     axioms: term Symtab.table,
   112     oracles: ((Sign.sg * Object.T -> term) * stamp) Symtab.table,
   113     parents: theory list,
   114     ancestors: theory list};
   115 
   116 fun make_theory sign axms oras parents ancestors =
   117   Theory {sign = sign, axioms = axms, oracles = oras,
   118     parents = parents, ancestors = ancestors};
   119 
   120 fun rep_theory (Theory args) = args;
   121 
   122 val sign_of = #sign o rep_theory;
   123 val is_draft = Sign.is_draft o sign_of;
   124 val syn_of = #syn o Sign.rep_sg o sign_of;
   125 val parents_of = #parents o rep_theory;
   126 val ancestors_of = #ancestors o rep_theory;
   127 
   128 (*errors involving theories*)
   129 exception THEORY of string * theory list;
   130 
   131 (*compare theories*)
   132 val subthy = Sign.subsig o pairself sign_of;
   133 val eq_thy = Sign.eq_sg o pairself sign_of;
   134 
   135 (*check for some theory*)
   136 fun requires thy name what =
   137   if exists (equal name) (Sign.stamp_names_of (sign_of thy)) then ()
   138   else error ("Require theory " ^ quote name ^ " as an ancestor for " ^ what);
   139 
   140 fun assert_super thy1 thy2 =
   141   if subthy (thy1, thy2) then thy2
   142   else raise THEORY ("Not a super theory", [thy1, thy2]);
   143 
   144 (*partial Pure theory*)
   145 val pre_pure = make_theory Sign.pre_pure Symtab.empty Symtab.empty [] [];
   146 
   147 
   148 
   149 (** extend theory **)
   150 
   151 (*name space kinds*)
   152 val axiomK = "axiom";
   153 val oracleK = "oracle";
   154 
   155 
   156 (* extend logical part of a theory *)
   157 
   158 fun err_dup_axms names =
   159   error ("Duplicate axiom name(s) " ^ commas_quote names);
   160 
   161 fun err_dup_oras names =
   162   error ("Duplicate oracles " ^ commas_quote names);
   163 
   164 fun ext_theory thy ext_sg new_axms new_oras =
   165   let
   166     val Theory {sign, axioms, oracles, parents, ancestors} = thy;
   167     val draft = Sign.is_draft sign;
   168     val axioms' =
   169       Symtab.extend (if draft then axioms else Symtab.empty, new_axms)
   170         handle Symtab.DUPS names => err_dup_axms names;
   171     val oracles' =
   172       Symtab.extend (oracles, new_oras)
   173         handle Symtab.DUPS names => err_dup_oras names;
   174     val (parents', ancestors') =
   175       if draft then (parents, ancestors) else ([thy], thy :: ancestors);
   176   in
   177     make_theory (ext_sg sign) axioms' oracles' parents' ancestors'
   178   end;
   179 
   180 
   181 (* extend signature of a theory *)
   182 
   183 fun ext_sign extfun decls thy = ext_theory thy (extfun decls) [] [];
   184 
   185 val add_classes      = ext_sign Sign.add_classes;
   186 val add_classes_i    = ext_sign Sign.add_classes_i;
   187 val add_classrel     = ext_sign Sign.add_classrel;
   188 val add_classrel_i   = ext_sign Sign.add_classrel_i;
   189 val add_defsort      = ext_sign Sign.add_defsort;
   190 val add_defsort_i    = ext_sign Sign.add_defsort_i;
   191 val add_types        = ext_sign Sign.add_types;
   192 val add_nonterminals = ext_sign Sign.add_nonterminals;
   193 val add_tyabbrs      = ext_sign Sign.add_tyabbrs;
   194 val add_tyabbrs_i    = ext_sign Sign.add_tyabbrs_i;
   195 val add_arities      = ext_sign Sign.add_arities;
   196 val add_arities_i    = ext_sign Sign.add_arities_i;
   197 val add_consts       = ext_sign Sign.add_consts;
   198 val add_consts_i     = ext_sign Sign.add_consts_i;
   199 val add_syntax       = ext_sign Sign.add_syntax;
   200 val add_syntax_i     = ext_sign Sign.add_syntax_i;
   201 val add_modesyntax   = curry (ext_sign Sign.add_modesyntax);
   202 val add_modesyntax_i = curry (ext_sign Sign.add_modesyntax_i);
   203 val add_trfuns       = ext_sign Sign.add_trfuns;
   204 val add_trfunsT      = ext_sign Sign.add_trfunsT;
   205 val add_tokentrfuns  = ext_sign Sign.add_tokentrfuns;
   206 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   207 val add_trrules      = ext_sign Sign.add_trrules;
   208 val add_trrules_i    = ext_sign Sign.add_trrules_i;
   209 val add_path         = ext_sign Sign.add_path;
   210 val parent_path      = add_path "..";
   211 val root_path        = add_path "/";
   212 val add_space        = ext_sign Sign.add_space;
   213 val add_name         = ext_sign Sign.add_name;
   214 val copy             = ext_sign (K Sign.copy) ();
   215 val prep_ext         = ext_sign (K Sign.prep_ext) ();
   216 
   217 
   218 
   219 (** add axioms **)
   220 
   221 (* prepare axioms *)
   222 
   223 fun err_in_axm name =
   224   error ("The error(s) above occurred in axiom " ^ quote name);
   225 
   226 fun no_vars tm =
   227   if null (term_vars tm) andalso null (term_tvars tm) then tm
   228   else error "Illegal schematic variable(s) in term";
   229 
   230 fun cert_axm sg (name, raw_tm) =
   231   let
   232     val (t, T, _) = Sign.certify_term sg raw_tm
   233       handle TYPE (msg, _, _) => error msg
   234            | TERM (msg, _) => error msg;
   235   in
   236     assert (T = propT) "Term not of type prop";
   237     (name, no_vars t)
   238   end
   239   handle ERROR => err_in_axm name;
   240 
   241 (*some duplication of code with read_def_cterm*)
   242 fun read_def_axm (sg, types, sorts) used (name, str) =
   243   let
   244     val ts = Syntax.read (#syn (Sign.rep_sg sg)) propT str;
   245     val (t, _) = Sign.infer_types sg types sorts used true (ts, propT);
   246   in cert_axm sg (name,t) end
   247   handle ERROR => err_in_axm name;
   248 
   249 fun read_axm sg name_str = read_def_axm (sg, K None, K None) [] name_str;
   250 
   251 fun inferT_axm sg (name, pre_tm) =
   252   let
   253     val (t, _) = Sign.infer_types sg (K None) (K None) [] true ([pre_tm], propT);
   254   in (name, no_vars t) end
   255   handle ERROR => err_in_axm name;
   256 
   257 
   258 (* extend axioms of a theory *)
   259 
   260 fun ext_axms prep_axm raw_axms (thy as Theory {sign, ...}) =
   261   let
   262     val raw_axms' = map (apfst (Sign.full_name sign)) raw_axms;
   263     val axioms =
   264       map (apsnd (Term.compress_term o Logic.varify) o prep_axm sign) raw_axms';
   265     val ext_sg = Sign.add_space (axiomK, map fst axioms);
   266   in
   267     ext_theory thy ext_sg axioms []
   268   end;
   269 
   270 val add_axioms = ext_axms read_axm;
   271 val add_axioms_i = ext_axms cert_axm;
   272 
   273 
   274 (* add oracle **)
   275 
   276 fun add_oracle (raw_name, oracle) (thy as Theory {sign, ...}) =
   277   let
   278     val name = Sign.full_name sign raw_name;
   279     val ext_sg = Sign.add_space (oracleK, [name]);
   280   in
   281     ext_theory thy ext_sg [] [(name, (oracle, stamp ()))]
   282   end;
   283 
   284 
   285 
   286 (** add constant definitions **)
   287 
   288 (* all_axioms_of *)
   289 
   290 (*results may contain duplicates!*)
   291 
   292 fun all_axioms_of thy =
   293   flat (map (Symtab.dest o #axioms o rep_theory) (thy :: ancestors_of thy));
   294 
   295 
   296 (* clash_types, clash_consts *)
   297 
   298 (*check if types have common instance (ignoring sorts)*)
   299 
   300 fun clash_types ty1 ty2 =
   301   let
   302     val ty1' = Type.varifyT ty1;
   303     val ty2' = incr_tvar (maxidx_of_typ ty1' + 1) (Type.varifyT ty2);
   304   in
   305     Type.raw_unify (ty1', ty2')
   306   end;
   307 
   308 fun clash_consts (c1, ty1) (c2, ty2) =
   309   c1 = c2 andalso clash_types ty1 ty2;
   310 
   311 
   312 (* clash_defns *)
   313 
   314 fun clash_defn c_ty (name, tm) =
   315   let val (c, ty') = dest_Const (head_of (fst (Logic.dest_equals tm))) in
   316     if clash_consts c_ty (c, ty') then Some (name, ty') else None
   317   end handle TERM _ => None;
   318 
   319 fun clash_defns c_ty axms =
   320   distinct (mapfilter (clash_defn c_ty) axms);
   321 
   322 
   323 (* dest_defn *)
   324 
   325 fun dest_defn tm =
   326   let
   327     fun err msg = raise TERM (msg, [tm]);
   328 
   329     val (lhs, rhs) = Logic.dest_equals (Logic.strip_imp_concl tm)
   330       handle TERM _ => err "Not a meta-equality (==)";
   331     val (head, args) = strip_comb lhs;
   332     val (c, ty) = dest_Const head
   333       handle TERM _ => err "Head of lhs not a constant";
   334 
   335     fun occs_const (Const c_ty') = (c_ty' = (c, ty))
   336       | occs_const (Abs (_, _, t)) = occs_const t
   337       | occs_const (t $ u) = occs_const t orelse occs_const u
   338       | occs_const _ = false;
   339 
   340     fun dest_free (Free (x, _)) = x
   341       | dest_free (Const ("TYPE", Type ("itself", [TFree (x, _)]))) = x
   342       | dest_free _ = raise Match;
   343 
   344     val show_frees = commas_quote o map dest_free;
   345     val show_tfrees = commas_quote o map fst;
   346 
   347     val lhs_dups = duplicates args;
   348     val rhs_extras = gen_rems (op =) (term_frees rhs, args);
   349     val rhs_extrasT = gen_rems (op =) (term_tfrees rhs, typ_tfrees ty);
   350   in
   351     if not (forall (can dest_free) args) then
   352       err "Arguments (on lhs) must be variables"
   353     else if not (null lhs_dups) then
   354       err ("Duplicate variables on lhs: " ^ show_frees lhs_dups)
   355     else if not (null rhs_extras) then
   356       err ("Extra variables on rhs: " ^ show_frees rhs_extras)
   357     else if not (null rhs_extrasT) then
   358       err ("Extra type variables on rhs: " ^ show_tfrees rhs_extrasT)
   359     else if occs_const rhs then
   360       err ("Constant to be defined occurs on rhs")
   361     else (c, ty)
   362   end;
   363 
   364 
   365 (* check_defn *)
   366 
   367 fun err_in_defn sg name msg =
   368   (error_msg msg; error ("The error(s) above occurred in definition " ^
   369     quote (Sign.full_name sg name)));
   370 
   371 fun check_defn sign (axms, (name, tm)) =
   372   let
   373     fun show_const (c, ty) = quote (Pretty.string_of (Pretty.block
   374       [Pretty.str (c ^ " ::"), Pretty.brk 1, Sign.pretty_typ sign ty]));
   375 
   376     fun show_defn c (dfn, ty') = show_const (c, ty') ^ " in " ^ dfn;
   377     fun show_defns c = cat_lines o map (show_defn c);
   378 
   379     val (c, ty) = dest_defn tm
   380       handle TERM (msg, _) => err_in_defn sign name msg;
   381     val defns = clash_defns (c, ty) axms;
   382   in
   383     if not (null defns) then
   384       err_in_defn sign name ("Definition of " ^ show_const (c, ty) ^
   385         "\nclashes with " ^ show_defns c defns)
   386     else (name, tm) :: axms
   387   end;
   388 
   389 
   390 (* add_defs *)
   391 
   392 fun ext_defns prep_axm raw_axms thy =
   393   let
   394     val axms = map (prep_axm (sign_of thy)) raw_axms;
   395     val all_axms = all_axioms_of thy;
   396   in
   397     foldl (check_defn (sign_of thy)) (all_axms, axms);
   398     add_axioms_i axms thy
   399   end;
   400 
   401 val add_defs_i = ext_defns cert_axm;
   402 val add_defs = ext_defns read_axm;
   403 
   404 
   405 
   406 (** additional theory data **)
   407 
   408 val init_data = curry (ext_sign Sign.init_data);
   409 fun print_data kind = Sign.print_data kind o sign_of;
   410 fun get_data kind f = Sign.get_data kind f o sign_of;
   411 fun put_data kind f = ext_sign (Sign.put_data kind f);
   412 
   413 
   414 
   415 (** merge theories **)          (*exception ERROR*)
   416 
   417 fun merge_sign (sg, thy) =
   418   Sign.nontriv_merge (sg, sign_of thy) handle TERM (msg, _) => error msg;
   419 
   420 (*merge list of theories from left to right, preparing extend*)
   421 fun prep_ext_merge thys =
   422   if null thys then
   423     error "Merge: no parent theories"
   424   else if exists is_draft thys then
   425     error "Attempt to merge draft theories"
   426   else
   427     let
   428       val sign' =
   429         foldl merge_sign (sign_of (hd thys), tl thys)
   430         |> Sign.prep_ext
   431         |> Sign.add_path "/";
   432 
   433       val axioms' = Symtab.empty;
   434 
   435       fun eq_ora ((_, (_, s1: stamp)), (_, (_, s2))) = s1 = s2;
   436       val oracles' =
   437         Symtab.make (gen_distinct eq_ora
   438           (flat (map (Symtab.dest o #oracles o rep_theory) thys)))
   439         handle Symtab.DUPS names => err_dup_oras names;
   440 
   441       val parents' = gen_distinct eq_thy thys;
   442       val ancestors' =
   443         gen_distinct eq_thy (parents' @ flat (map ancestors_of thys));
   444     in
   445       make_theory sign' axioms' oracles' parents' ancestors'
   446     end;
   447 
   448 fun merge_theories name (thy1, thy2) =
   449   prep_ext_merge [thy1, thy2]
   450   |> add_name name;
   451 
   452 
   453 end;
   454 
   455 structure BasicTheory: BASIC_THEORY = Theory;
   456 open BasicTheory;