src/HOL/Lim.thy
author hoelzl
Mon Dec 03 18:19:12 2012 +0100 (2012-12-03)
changeset 50331 4b6dc5077e98
parent 45031 9583f2b56f85
child 51471 cad22a3cc09c
permissions -rw-r--r--
use filterlim in Lim and SEQ; tuned proofs
     1 (*  Title       : Lim.thy
     2     Author      : Jacques D. Fleuriot
     3     Copyright   : 1998  University of Cambridge
     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2004
     5 *)
     6 
     7 header{* Limits and Continuity *}
     8 
     9 theory Lim
    10 imports SEQ
    11 begin
    12 
    13 text{*Standard Definitions*}
    14 
    15 abbreviation
    16   LIM :: "['a::topological_space \<Rightarrow> 'b::topological_space, 'a, 'b] \<Rightarrow> bool"
    17         ("((_)/ -- (_)/ --> (_))" [60, 0, 60] 60) where
    18   "f -- a --> L \<equiv> (f ---> L) (at a)"
    19 
    20 definition
    21   isCont :: "['a::topological_space \<Rightarrow> 'b::topological_space, 'a] \<Rightarrow> bool" where
    22   "isCont f a = (f -- a --> (f a))"
    23 
    24 definition
    25   isUCont :: "['a::metric_space \<Rightarrow> 'b::metric_space] \<Rightarrow> bool" where
    26   "isUCont f = (\<forall>r>0. \<exists>s>0. \<forall>x y. dist x y < s \<longrightarrow> dist (f x) (f y) < r)"
    27 
    28 subsection {* Limits of Functions *}
    29 
    30 lemma LIM_def: "f -- a --> L =
    31      (\<forall>r > 0. \<exists>s > 0. \<forall>x. x \<noteq> a & dist x a < s
    32         --> dist (f x) L < r)"
    33 unfolding tendsto_iff eventually_at ..
    34 
    35 lemma metric_LIM_I:
    36   "(\<And>r. 0 < r \<Longrightarrow> \<exists>s>0. \<forall>x. x \<noteq> a \<and> dist x a < s \<longrightarrow> dist (f x) L < r)
    37     \<Longrightarrow> f -- a --> L"
    38 by (simp add: LIM_def)
    39 
    40 lemma metric_LIM_D:
    41   "\<lbrakk>f -- a --> L; 0 < r\<rbrakk>
    42     \<Longrightarrow> \<exists>s>0. \<forall>x. x \<noteq> a \<and> dist x a < s \<longrightarrow> dist (f x) L < r"
    43 by (simp add: LIM_def)
    44 
    45 lemma LIM_eq:
    46   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
    47   shows "f -- a --> L =
    48      (\<forall>r>0.\<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)"
    49 by (simp add: LIM_def dist_norm)
    50 
    51 lemma LIM_I:
    52   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
    53   shows "(!!r. 0<r ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)
    54       ==> f -- a --> L"
    55 by (simp add: LIM_eq)
    56 
    57 lemma LIM_D:
    58   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
    59   shows "[| f -- a --> L; 0<r |]
    60       ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r"
    61 by (simp add: LIM_eq)
    62 
    63 lemma LIM_offset:
    64   fixes a :: "'a::real_normed_vector"
    65   shows "f -- a --> L \<Longrightarrow> (\<lambda>x. f (x + k)) -- a - k --> L"
    66 apply (rule topological_tendstoI)
    67 apply (drule (2) topological_tendstoD)
    68 apply (simp only: eventually_at dist_norm)
    69 apply (clarify, rule_tac x=d in exI, safe)
    70 apply (drule_tac x="x + k" in spec)
    71 apply (simp add: algebra_simps)
    72 done
    73 
    74 lemma LIM_offset_zero:
    75   fixes a :: "'a::real_normed_vector"
    76   shows "f -- a --> L \<Longrightarrow> (\<lambda>h. f (a + h)) -- 0 --> L"
    77 by (drule_tac k="a" in LIM_offset, simp add: add_commute)
    78 
    79 lemma LIM_offset_zero_cancel:
    80   fixes a :: "'a::real_normed_vector"
    81   shows "(\<lambda>h. f (a + h)) -- 0 --> L \<Longrightarrow> f -- a --> L"
    82 by (drule_tac k="- a" in LIM_offset, simp)
    83 
    84 lemma LIM_cong_limit: "\<lbrakk> f -- x --> L ; K = L \<rbrakk> \<Longrightarrow> f -- x --> K" by simp
    85 
    86 lemma LIM_zero:
    87   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
    88   shows "(f ---> l) F \<Longrightarrow> ((\<lambda>x. f x - l) ---> 0) F"
    89 unfolding tendsto_iff dist_norm by simp
    90 
    91 lemma LIM_zero_cancel:
    92   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
    93   shows "((\<lambda>x. f x - l) ---> 0) F \<Longrightarrow> (f ---> l) F"
    94 unfolding tendsto_iff dist_norm by simp
    95 
    96 lemma LIM_zero_iff:
    97   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
    98   shows "((\<lambda>x. f x - l) ---> 0) F = (f ---> l) F"
    99 unfolding tendsto_iff dist_norm by simp
   100 
   101 lemma metric_LIM_imp_LIM:
   102   assumes f: "f -- a --> l"
   103   assumes le: "\<And>x. x \<noteq> a \<Longrightarrow> dist (g x) m \<le> dist (f x) l"
   104   shows "g -- a --> m"
   105   by (rule metric_tendsto_imp_tendsto [OF f],
   106     auto simp add: eventually_at_topological le)
   107 
   108 lemma LIM_imp_LIM:
   109   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   110   fixes g :: "'a::topological_space \<Rightarrow> 'c::real_normed_vector"
   111   assumes f: "f -- a --> l"
   112   assumes le: "\<And>x. x \<noteq> a \<Longrightarrow> norm (g x - m) \<le> norm (f x - l)"
   113   shows "g -- a --> m"
   114   by (rule metric_LIM_imp_LIM [OF f],
   115     simp add: dist_norm le)
   116 
   117 lemma LIM_const_not_eq:
   118   fixes a :: "'a::perfect_space"
   119   fixes k L :: "'b::t2_space"
   120   shows "k \<noteq> L \<Longrightarrow> \<not> (\<lambda>x. k) -- a --> L"
   121   by (simp add: tendsto_const_iff)
   122 
   123 lemmas LIM_not_zero = LIM_const_not_eq [where L = 0]
   124 
   125 lemma LIM_const_eq:
   126   fixes a :: "'a::perfect_space"
   127   fixes k L :: "'b::t2_space"
   128   shows "(\<lambda>x. k) -- a --> L \<Longrightarrow> k = L"
   129   by (simp add: tendsto_const_iff)
   130 
   131 lemma LIM_unique:
   132   fixes a :: "'a::perfect_space"
   133   fixes L M :: "'b::t2_space"
   134   shows "\<lbrakk>f -- a --> L; f -- a --> M\<rbrakk> \<Longrightarrow> L = M"
   135   using at_neq_bot by (rule tendsto_unique)
   136 
   137 text{*Limits are equal for functions equal except at limit point*}
   138 lemma LIM_equal:
   139      "[| \<forall>x. x \<noteq> a --> (f x = g x) |] ==> (f -- a --> l) = (g -- a --> l)"
   140 unfolding tendsto_def eventually_at_topological by simp
   141 
   142 lemma LIM_cong:
   143   "\<lbrakk>a = b; \<And>x. x \<noteq> b \<Longrightarrow> f x = g x; l = m\<rbrakk>
   144    \<Longrightarrow> ((\<lambda>x. f x) -- a --> l) = ((\<lambda>x. g x) -- b --> m)"
   145 by (simp add: LIM_equal)
   146 
   147 lemma metric_LIM_equal2:
   148   assumes 1: "0 < R"
   149   assumes 2: "\<And>x. \<lbrakk>x \<noteq> a; dist x a < R\<rbrakk> \<Longrightarrow> f x = g x"
   150   shows "g -- a --> l \<Longrightarrow> f -- a --> l"
   151 apply (rule topological_tendstoI)
   152 apply (drule (2) topological_tendstoD)
   153 apply (simp add: eventually_at, safe)
   154 apply (rule_tac x="min d R" in exI, safe)
   155 apply (simp add: 1)
   156 apply (simp add: 2)
   157 done
   158 
   159 lemma LIM_equal2:
   160   fixes f g :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
   161   assumes 1: "0 < R"
   162   assumes 2: "\<And>x. \<lbrakk>x \<noteq> a; norm (x - a) < R\<rbrakk> \<Longrightarrow> f x = g x"
   163   shows "g -- a --> l \<Longrightarrow> f -- a --> l"
   164 by (rule metric_LIM_equal2 [OF 1 2], simp_all add: dist_norm)
   165 
   166 lemma LIM_compose_eventually:
   167   assumes f: "f -- a --> b"
   168   assumes g: "g -- b --> c"
   169   assumes inj: "eventually (\<lambda>x. f x \<noteq> b) (at a)"
   170   shows "(\<lambda>x. g (f x)) -- a --> c"
   171   using g f inj by (rule tendsto_compose_eventually)
   172 
   173 lemma metric_LIM_compose2:
   174   assumes f: "f -- a --> b"
   175   assumes g: "g -- b --> c"
   176   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> f x \<noteq> b"
   177   shows "(\<lambda>x. g (f x)) -- a --> c"
   178   using g f inj [folded eventually_at]
   179   by (rule tendsto_compose_eventually)
   180 
   181 lemma LIM_compose2:
   182   fixes a :: "'a::real_normed_vector"
   183   assumes f: "f -- a --> b"
   184   assumes g: "g -- b --> c"
   185   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> b"
   186   shows "(\<lambda>x. g (f x)) -- a --> c"
   187 by (rule metric_LIM_compose2 [OF f g inj [folded dist_norm]])
   188 
   189 lemma LIM_o: "\<lbrakk>g -- l --> g l; f -- a --> l\<rbrakk> \<Longrightarrow> (g \<circ> f) -- a --> g l"
   190   unfolding o_def by (rule tendsto_compose)
   191 
   192 lemma real_LIM_sandwich_zero:
   193   fixes f g :: "'a::topological_space \<Rightarrow> real"
   194   assumes f: "f -- a --> 0"
   195   assumes 1: "\<And>x. x \<noteq> a \<Longrightarrow> 0 \<le> g x"
   196   assumes 2: "\<And>x. x \<noteq> a \<Longrightarrow> g x \<le> f x"
   197   shows "g -- a --> 0"
   198 proof (rule LIM_imp_LIM [OF f])
   199   fix x assume x: "x \<noteq> a"
   200   have "norm (g x - 0) = g x" by (simp add: 1 x)
   201   also have "g x \<le> f x" by (rule 2 [OF x])
   202   also have "f x \<le> \<bar>f x\<bar>" by (rule abs_ge_self)
   203   also have "\<bar>f x\<bar> = norm (f x - 0)" by simp
   204   finally show "norm (g x - 0) \<le> norm (f x - 0)" .
   205 qed
   206 
   207 
   208 subsection {* Continuity *}
   209 
   210 lemma LIM_isCont_iff:
   211   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
   212   shows "(f -- a --> f a) = ((\<lambda>h. f (a + h)) -- 0 --> f a)"
   213 by (rule iffI [OF LIM_offset_zero LIM_offset_zero_cancel])
   214 
   215 lemma isCont_iff:
   216   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
   217   shows "isCont f x = (\<lambda>h. f (x + h)) -- 0 --> f x"
   218 by (simp add: isCont_def LIM_isCont_iff)
   219 
   220 lemma isCont_ident [simp]: "isCont (\<lambda>x. x) a"
   221   unfolding isCont_def by (rule tendsto_ident_at)
   222 
   223 lemma isCont_const [simp]: "isCont (\<lambda>x. k) a"
   224   unfolding isCont_def by (rule tendsto_const)
   225 
   226 lemma isCont_norm [simp]:
   227   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   228   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. norm (f x)) a"
   229   unfolding isCont_def by (rule tendsto_norm)
   230 
   231 lemma isCont_rabs [simp]:
   232   fixes f :: "'a::topological_space \<Rightarrow> real"
   233   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. \<bar>f x\<bar>) a"
   234   unfolding isCont_def by (rule tendsto_rabs)
   235 
   236 lemma isCont_add [simp]:
   237   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   238   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x + g x) a"
   239   unfolding isCont_def by (rule tendsto_add)
   240 
   241 lemma isCont_minus [simp]:
   242   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   243   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. - f x) a"
   244   unfolding isCont_def by (rule tendsto_minus)
   245 
   246 lemma isCont_diff [simp]:
   247   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   248   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x - g x) a"
   249   unfolding isCont_def by (rule tendsto_diff)
   250 
   251 lemma isCont_mult [simp]:
   252   fixes f g :: "'a::topological_space \<Rightarrow> 'b::real_normed_algebra"
   253   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x * g x) a"
   254   unfolding isCont_def by (rule tendsto_mult)
   255 
   256 lemma isCont_inverse [simp]:
   257   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_div_algebra"
   258   shows "\<lbrakk>isCont f a; f a \<noteq> 0\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. inverse (f x)) a"
   259   unfolding isCont_def by (rule tendsto_inverse)
   260 
   261 lemma isCont_divide [simp]:
   262   fixes f g :: "'a::topological_space \<Rightarrow> 'b::real_normed_field"
   263   shows "\<lbrakk>isCont f a; isCont g a; g a \<noteq> 0\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x / g x) a"
   264   unfolding isCont_def by (rule tendsto_divide)
   265 
   266 lemma isCont_tendsto_compose:
   267   "\<lbrakk>isCont g l; (f ---> l) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. g (f x)) ---> g l) F"
   268   unfolding isCont_def by (rule tendsto_compose)
   269 
   270 lemma metric_isCont_LIM_compose2:
   271   assumes f [unfolded isCont_def]: "isCont f a"
   272   assumes g: "g -- f a --> l"
   273   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> f x \<noteq> f a"
   274   shows "(\<lambda>x. g (f x)) -- a --> l"
   275 by (rule metric_LIM_compose2 [OF f g inj])
   276 
   277 lemma isCont_LIM_compose2:
   278   fixes a :: "'a::real_normed_vector"
   279   assumes f [unfolded isCont_def]: "isCont f a"
   280   assumes g: "g -- f a --> l"
   281   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> f a"
   282   shows "(\<lambda>x. g (f x)) -- a --> l"
   283 by (rule LIM_compose2 [OF f g inj])
   284 
   285 lemma isCont_o2: "\<lbrakk>isCont f a; isCont g (f a)\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. g (f x)) a"
   286   unfolding isCont_def by (rule tendsto_compose)
   287 
   288 lemma isCont_o: "\<lbrakk>isCont f a; isCont g (f a)\<rbrakk> \<Longrightarrow> isCont (g o f) a"
   289   unfolding o_def by (rule isCont_o2)
   290 
   291 lemma (in bounded_linear) isCont:
   292   "isCont g a \<Longrightarrow> isCont (\<lambda>x. f (g x)) a"
   293   unfolding isCont_def by (rule tendsto)
   294 
   295 lemma (in bounded_bilinear) isCont:
   296   "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x ** g x) a"
   297   unfolding isCont_def by (rule tendsto)
   298 
   299 lemmas isCont_scaleR [simp] =
   300   bounded_bilinear.isCont [OF bounded_bilinear_scaleR]
   301 
   302 lemmas isCont_of_real [simp] =
   303   bounded_linear.isCont [OF bounded_linear_of_real]
   304 
   305 lemma isCont_power [simp]:
   306   fixes f :: "'a::topological_space \<Rightarrow> 'b::{power,real_normed_algebra}"
   307   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. f x ^ n) a"
   308   unfolding isCont_def by (rule tendsto_power)
   309 
   310 lemma isCont_sgn [simp]:
   311   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   312   shows "\<lbrakk>isCont f a; f a \<noteq> 0\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. sgn (f x)) a"
   313   unfolding isCont_def by (rule tendsto_sgn)
   314 
   315 lemma isCont_setsum [simp]:
   316   fixes f :: "'a \<Rightarrow> 'b::topological_space \<Rightarrow> 'c::real_normed_vector"
   317   fixes A :: "'a set"
   318   shows "\<forall>i\<in>A. isCont (f i) a \<Longrightarrow> isCont (\<lambda>x. \<Sum>i\<in>A. f i x) a"
   319   unfolding isCont_def by (simp add: tendsto_setsum)
   320 
   321 lemmas isCont_intros =
   322   isCont_ident isCont_const isCont_norm isCont_rabs isCont_add isCont_minus
   323   isCont_diff isCont_mult isCont_inverse isCont_divide isCont_scaleR
   324   isCont_of_real isCont_power isCont_sgn isCont_setsum
   325 
   326 subsection {* Uniform Continuity *}
   327 
   328 lemma isUCont_isCont: "isUCont f ==> isCont f x"
   329 by (simp add: isUCont_def isCont_def LIM_def, force)
   330 
   331 lemma isUCont_Cauchy:
   332   "\<lbrakk>isUCont f; Cauchy X\<rbrakk> \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
   333 unfolding isUCont_def
   334 apply (rule metric_CauchyI)
   335 apply (drule_tac x=e in spec, safe)
   336 apply (drule_tac e=s in metric_CauchyD, safe)
   337 apply (rule_tac x=M in exI, simp)
   338 done
   339 
   340 lemma (in bounded_linear) isUCont: "isUCont f"
   341 unfolding isUCont_def dist_norm
   342 proof (intro allI impI)
   343   fix r::real assume r: "0 < r"
   344   obtain K where K: "0 < K" and norm_le: "\<And>x. norm (f x) \<le> norm x * K"
   345     using pos_bounded by fast
   346   show "\<exists>s>0. \<forall>x y. norm (x - y) < s \<longrightarrow> norm (f x - f y) < r"
   347   proof (rule exI, safe)
   348     from r K show "0 < r / K" by (rule divide_pos_pos)
   349   next
   350     fix x y :: 'a
   351     assume xy: "norm (x - y) < r / K"
   352     have "norm (f x - f y) = norm (f (x - y))" by (simp only: diff)
   353     also have "\<dots> \<le> norm (x - y) * K" by (rule norm_le)
   354     also from K xy have "\<dots> < r" by (simp only: pos_less_divide_eq)
   355     finally show "norm (f x - f y) < r" .
   356   qed
   357 qed
   358 
   359 lemma (in bounded_linear) Cauchy: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
   360 by (rule isUCont [THEN isUCont_Cauchy])
   361 
   362 
   363 subsection {* Relation of LIM and LIMSEQ *}
   364 
   365 lemma sequentially_imp_eventually_within:
   366   fixes a :: "'a::metric_space"
   367   assumes "\<forall>f. (\<forall>n. f n \<in> s \<and> f n \<noteq> a) \<and> f ----> a \<longrightarrow>
   368     eventually (\<lambda>n. P (f n)) sequentially"
   369   shows "eventually P (at a within s)"
   370 proof (rule ccontr)
   371   let ?I = "\<lambda>n. inverse (real (Suc n))"
   372   def F \<equiv> "\<lambda>n::nat. SOME x. x \<in> s \<and> x \<noteq> a \<and> dist x a < ?I n \<and> \<not> P x"
   373   assume "\<not> eventually P (at a within s)"
   374   hence P: "\<forall>d>0. \<exists>x. x \<in> s \<and> x \<noteq> a \<and> dist x a < d \<and> \<not> P x"
   375     unfolding Limits.eventually_within Limits.eventually_at by fast
   376   hence "\<And>n. \<exists>x. x \<in> s \<and> x \<noteq> a \<and> dist x a < ?I n \<and> \<not> P x" by simp
   377   hence F: "\<And>n. F n \<in> s \<and> F n \<noteq> a \<and> dist (F n) a < ?I n \<and> \<not> P (F n)"
   378     unfolding F_def by (rule someI_ex)
   379   hence F0: "\<forall>n. F n \<in> s" and F1: "\<forall>n. F n \<noteq> a"
   380     and F2: "\<forall>n. dist (F n) a < ?I n" and F3: "\<forall>n. \<not> P (F n)"
   381     by fast+
   382   from LIMSEQ_inverse_real_of_nat have "F ----> a"
   383     by (rule metric_tendsto_imp_tendsto,
   384       simp add: dist_norm F2 less_imp_le)
   385   hence "eventually (\<lambda>n. P (F n)) sequentially"
   386     using assms F0 F1 by simp
   387   thus "False" by (simp add: F3)
   388 qed
   389 
   390 lemma sequentially_imp_eventually_at:
   391   fixes a :: "'a::metric_space"
   392   assumes "\<forall>f. (\<forall>n. f n \<noteq> a) \<and> f ----> a \<longrightarrow>
   393     eventually (\<lambda>n. P (f n)) sequentially"
   394   shows "eventually P (at a)"
   395   using assms sequentially_imp_eventually_within [where s=UNIV] by simp
   396 
   397 lemma LIMSEQ_SEQ_conv1:
   398   fixes f :: "'a::topological_space \<Rightarrow> 'b::topological_space"
   399   assumes f: "f -- a --> l"
   400   shows "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. f (S n)) ----> l"
   401   using tendsto_compose_eventually [OF f, where F=sequentially] by simp
   402 
   403 lemma LIMSEQ_SEQ_conv2:
   404   fixes f :: "'a::metric_space \<Rightarrow> 'b::topological_space"
   405   assumes "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. f (S n)) ----> l"
   406   shows "f -- a --> l"
   407   using assms unfolding tendsto_def [where l=l]
   408   by (simp add: sequentially_imp_eventually_at)
   409 
   410 lemma LIMSEQ_SEQ_conv:
   411   "(\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> (a::'a::metric_space) \<longrightarrow> (\<lambda>n. X (S n)) ----> L) =
   412    (X -- a --> (L::'b::topological_space))"
   413   using LIMSEQ_SEQ_conv2 LIMSEQ_SEQ_conv1 ..
   414 
   415 lemma LIM_less_bound: 
   416   fixes f :: "real \<Rightarrow> real"
   417   assumes ev: "b < x" "\<forall> x' \<in> { b <..< x}. 0 \<le> f x'" and "isCont f x"
   418   shows "0 \<le> f x"
   419 proof (rule tendsto_le_const)
   420   show "(f ---> f x) (at_left x)"
   421     using `isCont f x` by (simp add: filterlim_at_split isCont_def)
   422   show "eventually (\<lambda>x. 0 \<le> f x) (at_left x)"
   423     using ev by (auto simp: eventually_within_less dist_real_def intro!: exI[of _ "x - b"])
   424 qed simp
   425 
   426 end