src/HOL/Tools/ATP/atp_proof.ML
author haftmann
Wed Dec 08 13:34:50 2010 +0100 (2010-12-08)
changeset 41075 4bed56dc95fb
parent 40684 c7ba327eb58c
child 41092 1b796ffa8347
permissions -rw-r--r--
primitive definitions of bot/top/inf/sup for bool and fun are named with canonical suffix `_def` rather than `_eq`
     1 (*  Title:      HOL/Tools/ATP/atp_proof.ML
     2     Author:     Lawrence C. Paulson, Cambridge University Computer Laboratory
     3     Author:     Claire Quigley, Cambridge University Computer Laboratory
     4     Author:     Jasmin Blanchette, TU Muenchen
     5 
     6 Abstract representation of ATP proofs and TSTP/Vampire/SPASS syntax.
     7 *)
     8 
     9 signature ATP_PROOF =
    10 sig
    11   type 'a fo_term = 'a ATP_Problem.fo_term
    12   type 'a uniform_formula = 'a ATP_Problem.uniform_formula
    13 
    14   datatype failure =
    15     Unprovable | IncompleteUnprovable | CantConnect | TimedOut |
    16     OutOfResources | SpassTooOld | VampireTooOld | NoPerl | NoLibwwwPerl |
    17     MalformedInput | MalformedOutput | Interrupted | Crashed | InternalError |
    18     UnknownError
    19 
    20   type step_name = string * string option
    21 
    22   datatype 'a step =
    23     Definition of step_name * 'a * 'a |
    24     Inference of step_name * 'a * step_name list
    25 
    26   type 'a proof = 'a uniform_formula step list
    27 
    28   val strip_spaces : (char -> bool) -> string -> string
    29   val string_for_failure : string -> failure -> string
    30   val extract_important_message : string -> string
    31   val extract_known_failure :
    32     (failure * string) list -> string -> failure option
    33   val extract_tstplike_proof_and_outcome :
    34     bool -> int -> (string * string) list -> (failure * string) list -> string
    35     -> string * failure option
    36   val is_same_step : step_name * step_name -> bool
    37   val atp_proof_from_tstplike_string : string -> string proof
    38   val map_term_names_in_atp_proof :
    39     (string -> string) -> string proof -> string proof
    40   val nasty_atp_proof : string Symtab.table -> string proof -> string proof
    41 end;
    42 
    43 structure ATP_Proof : ATP_PROOF =
    44 struct
    45 
    46 open ATP_Problem
    47 
    48 datatype failure =
    49   Unprovable | IncompleteUnprovable | CantConnect | TimedOut | OutOfResources |
    50   SpassTooOld | VampireTooOld | NoPerl | NoLibwwwPerl | MalformedInput |
    51   MalformedOutput | Interrupted | Crashed | InternalError | UnknownError
    52 
    53 fun strip_spaces_in_list _ [] = []
    54   | strip_spaces_in_list _ [c1] = if Char.isSpace c1 then [] else [str c1]
    55   | strip_spaces_in_list is_evil [c1, c2] =
    56     strip_spaces_in_list is_evil [c1] @ strip_spaces_in_list is_evil [c2]
    57   | strip_spaces_in_list is_evil (c1 :: c2 :: c3 :: cs) =
    58     if Char.isSpace c1 then
    59       strip_spaces_in_list is_evil (c2 :: c3 :: cs)
    60     else if Char.isSpace c2 then
    61       if Char.isSpace c3 then
    62         strip_spaces_in_list is_evil (c1 :: c3 :: cs)
    63       else
    64         str c1 :: (if forall is_evil [c1, c3] then [" "] else []) @
    65         strip_spaces_in_list is_evil (c3 :: cs)
    66     else
    67       str c1 :: strip_spaces_in_list is_evil (c2 :: c3 :: cs)
    68 fun strip_spaces is_evil =
    69   implode o strip_spaces_in_list is_evil o String.explode
    70 
    71 fun is_ident_char c = Char.isAlphaNum c orelse c = #"_"
    72 val strip_spaces_except_between_ident_chars = strip_spaces is_ident_char
    73 
    74 fun missing_message_tail prover =
    75   " appears to be missing. You will need to install it if you want to run " ^
    76   prover ^ "s remotely."
    77 
    78 fun string_for_failure prover Unprovable =
    79     "The " ^ prover ^ " problem is unprovable."
    80   | string_for_failure prover IncompleteUnprovable =
    81     "The " ^ prover ^ " cannot prove the problem."
    82   | string_for_failure _ CantConnect = "Cannot connect to remote server."
    83   | string_for_failure _ TimedOut = "Timed out."
    84   | string_for_failure prover OutOfResources =
    85     "The " ^ prover ^ " ran out of resources."
    86   | string_for_failure _ SpassTooOld =
    87     "Isabelle requires a more recent version of SPASS with support for the \
    88     \TPTP syntax. To install it, download and extract the package \
    89     \\"http://isabelle.in.tum.de/dist/contrib/spass-3.7.tar.gz\" and add the \
    90     \\"spass-3.7\" directory's absolute path to " ^
    91     quote (Path.implode (Path.expand (Path.appends
    92                (Path.variable "ISABELLE_HOME_USER" ::
    93                 map Path.basic ["etc", "components"])))) ^
    94     " on a line of its own."
    95   | string_for_failure _ VampireTooOld =
    96     "Isabelle requires a more recent version of Vampire. To install it, follow \
    97     \the instructions from the Sledgehammer manual (\"isabelle doc\
    98     \ sledgehammer\")."
    99   | string_for_failure prover NoPerl = "Perl" ^ missing_message_tail prover
   100   | string_for_failure prover NoLibwwwPerl =
   101     "The Perl module \"libwww-perl\"" ^ missing_message_tail prover
   102   | string_for_failure prover MalformedInput =
   103     "The " ^ prover ^ " problem is malformed. Please report this to the Isabelle \
   104     \developers."
   105   | string_for_failure prover MalformedOutput =
   106     "The " ^ prover ^ " output is malformed."
   107   | string_for_failure prover Interrupted = "The " ^ prover ^ " was interrupted."
   108   | string_for_failure prover Crashed = "The " ^ prover ^ " crashed."
   109   | string_for_failure prover InternalError =
   110     "An internal " ^ prover ^ " error occurred."
   111   | string_for_failure prover UnknownError =
   112     "An unknown " ^ prover ^ " error occurred."
   113 
   114 fun extract_delimited (begin_delim, end_delim) output =
   115   output |> first_field begin_delim |> the |> snd
   116          |> first_field end_delim |> the |> fst
   117          |> first_field "\n" |> the |> snd
   118   handle Option.Option => ""
   119 
   120 val tstp_important_message_delims =
   121   ("% SZS start RequiredInformation", "% SZS end RequiredInformation")
   122 
   123 fun extract_important_message output =
   124   case extract_delimited tstp_important_message_delims output of
   125     "" => ""
   126   | s => s |> space_explode "\n" |> filter_out (curry (op =) "")
   127            |> map (perhaps (try (unprefix "%")))
   128            |> map (perhaps (try (unprefix " ")))
   129            |> space_implode "\n " |> quote
   130 
   131 (* Splits by the first possible of a list of delimiters. *)
   132 fun extract_tstplike_proof delims output =
   133   case pairself (find_first (fn s => String.isSubstring s output))
   134                 (ListPair.unzip delims) of
   135     (SOME begin_delim, SOME end_delim) =>
   136     extract_delimited (begin_delim, end_delim) output
   137   | _ => ""
   138 
   139 fun extract_known_failure known_failures output =
   140   known_failures
   141   |> find_first (fn (_, pattern) => String.isSubstring pattern output)
   142   |> Option.map fst
   143 
   144 fun extract_tstplike_proof_and_outcome complete res_code proof_delims
   145                                        known_failures output =
   146   case extract_known_failure known_failures output of
   147     NONE => (case extract_tstplike_proof proof_delims output of
   148              "" => ("", SOME (if res_code = 0 andalso output = "" then
   149                                 Interrupted
   150                               else
   151                                 UnknownError))
   152            | tstplike_proof => if res_code = 0 then (tstplike_proof, NONE)
   153                                else ("", SOME UnknownError))
   154   | SOME failure =>
   155     ("", SOME (if failure = IncompleteUnprovable andalso complete then
   156                  Unprovable
   157                else
   158                  failure))
   159 
   160 fun mk_anot (AConn (ANot, [phi])) = phi
   161   | mk_anot phi = AConn (ANot, [phi])
   162 fun mk_aconn c (phi1, phi2) = AConn (c, [phi1, phi2])
   163 
   164 type step_name = string * string option
   165 
   166 fun is_same_step p = p |> pairself fst |> op =
   167 
   168 fun step_name_ord p =
   169   let val q = pairself fst p in
   170     (* The "unprefix" part is to cope with remote Vampire's output. The proper
   171        solution would be to perform a topological sort, e.g. using the nice
   172        "Graph" functor. *)
   173     case pairself (Int.fromString o perhaps (try (unprefix "f"))) q of
   174       (NONE, NONE) => string_ord q
   175     | (NONE, SOME _) => LESS
   176     | (SOME _, NONE) => GREATER
   177     | (SOME i, SOME j) => int_ord (i, j)
   178   end
   179 
   180 datatype 'a step =
   181   Definition of step_name * 'a * 'a |
   182   Inference of step_name * 'a * step_name list
   183 
   184 type 'a proof = 'a uniform_formula step list
   185 
   186 fun step_name (Definition (name, _, _)) = name
   187   | step_name (Inference (name, _, _)) = name
   188 
   189 (**** PARSING OF TSTP FORMAT ****)
   190 
   191 (*Strings enclosed in single quotes, e.g. filenames*)
   192 val scan_general_id =
   193   $$ "'" |-- Scan.repeat (~$$ "'") --| $$ "'" >> implode
   194   || Scan.repeat ($$ "$") -- Scan.many1 Symbol.is_letdig
   195      >> (fn (ss1, ss2) => implode ss1 ^ implode ss2)
   196 
   197 (* Generalized first-order terms, which include file names, numbers, etc. *)
   198 fun parse_annotation strict x =
   199   ((scan_general_id ::: Scan.repeat ($$ " " |-- scan_general_id)
   200       >> (strict ? filter (is_some o Int.fromString)))
   201    -- Scan.optional (parse_annotation strict) [] >> op @
   202    || $$ "(" |-- parse_annotations strict --| $$ ")"
   203    || $$ "[" |-- parse_annotations strict --| $$ "]") x
   204 and parse_annotations strict x =
   205   (Scan.optional (parse_annotation strict
   206                   ::: Scan.repeat ($$ "," |-- parse_annotation strict)) []
   207    >> flat) x
   208 
   209 (* Vampire proof lines sometimes contain needless information such as "(0:3)",
   210    which can be hard to disambiguate from function application in an LL(1)
   211    parser. As a workaround, we extend the TPTP term syntax with such detritus
   212    and ignore it. *)
   213 fun parse_vampire_detritus x =
   214   (scan_general_id |-- $$ ":" --| scan_general_id >> K []) x
   215 
   216 fun parse_term x =
   217   (scan_general_id
   218     -- Scan.optional ($$ "(" |-- (parse_vampire_detritus || parse_terms)
   219                       --| $$ ")") []
   220     --| Scan.optional ($$ "(" |-- parse_vampire_detritus --| $$ ")") []
   221    >> ATerm) x
   222 and parse_terms x = (parse_term ::: Scan.repeat ($$ "," |-- parse_term)) x
   223 
   224 fun parse_atom x =
   225   (parse_term -- Scan.option (Scan.option ($$ "!") --| $$ "=" -- parse_term)
   226    >> (fn (u1, NONE) => AAtom u1
   227         | (u1, SOME (NONE, u2)) => AAtom (ATerm ("c_equal", [u1, u2]))
   228         | (u1, SOME (SOME _, u2)) =>
   229           mk_anot (AAtom (ATerm ("c_equal", [u1, u2]))))) x
   230 
   231 fun fo_term_head (ATerm (s, _)) = s
   232 
   233 (* TPTP formulas are fully parenthesized, so we don't need to worry about
   234    operator precedence. *)
   235 fun parse_formula x =
   236   (($$ "(" |-- parse_formula --| $$ ")"
   237     || ($$ "!" >> K AForall || $$ "?" >> K AExists)
   238        --| $$ "[" -- parse_terms --| $$ "]" --| $$ ":" -- parse_formula
   239        >> (fn ((q, ts), phi) => AQuant (q, map fo_term_head ts, phi))
   240     || $$ "~" |-- parse_formula >> mk_anot
   241     || parse_atom)
   242    -- Scan.option ((Scan.this_string "=>" >> K AImplies
   243                     || Scan.this_string "<=>" >> K AIff
   244                     || Scan.this_string "<~>" >> K ANotIff
   245                     || Scan.this_string "<=" >> K AIf
   246                     || $$ "|" >> K AOr || $$ "&" >> K AAnd)
   247                    -- parse_formula)
   248    >> (fn (phi1, NONE) => phi1
   249         | (phi1, SOME (c, phi2)) => mk_aconn c (phi1, phi2))) x
   250 
   251 val parse_tstp_extra_arguments =
   252   Scan.optional ($$ "," |-- parse_annotation false
   253                  --| Scan.option ($$ "," |-- parse_annotations false)) []
   254 
   255 (* Syntax: (fof|cnf)\(<num>, <formula_role>, <formula> <extra_arguments>\).
   256    The <num> could be an identifier, but we assume integers. *)
   257 val parse_tstp_line =
   258   ((Scan.this_string "fof" || Scan.this_string "cnf") -- $$ "(")
   259     |-- scan_general_id --| $$ "," -- Symbol.scan_id --| $$ ","
   260     -- parse_formula -- parse_tstp_extra_arguments --| $$ ")" --| $$ "."
   261    >> (fn (((num, role), phi), deps) =>
   262           let
   263             val (name, deps) =
   264               case deps of
   265                 ["file", _, s] => ((num, SOME s), [])
   266               | _ => ((num, NONE), deps)
   267           in
   268             case role of
   269               "definition" =>
   270               (case phi of
   271                  AConn (AIff, [phi1 as AAtom _, phi2]) =>
   272                  Definition (name, phi1, phi2)
   273                | AAtom (ATerm ("c_equal", _)) =>
   274                  (* Vampire's equality proxy axiom *)
   275                  Inference (name, phi, map (rpair NONE) deps)
   276                | _ => raise Fail "malformed definition")
   277             | _ => Inference (name, phi, map (rpair NONE) deps)
   278           end)
   279 
   280 (**** PARSING OF VAMPIRE OUTPUT ****)
   281 
   282 (* Syntax: <num>. <formula> <annotation> *)
   283 val parse_vampire_line =
   284   scan_general_id --| $$ "." -- parse_formula -- parse_annotation true
   285   >> (fn ((num, phi), deps) =>
   286          Inference ((num, NONE), phi, map (rpair NONE) deps))
   287 
   288 (**** PARSING OF SPASS OUTPUT ****)
   289 
   290 (* SPASS returns clause references of the form "x.y". We ignore "y", whose role
   291    is not clear anyway. *)
   292 val parse_dot_name = scan_general_id --| $$ "." --| scan_general_id
   293 
   294 val parse_spass_annotations =
   295   Scan.optional ($$ ":" |-- Scan.repeat (parse_dot_name
   296                                          --| Scan.option ($$ ","))) []
   297 
   298 (* It is not clear why some literals are followed by sequences of stars and/or
   299    pluses. We ignore them. *)
   300 fun parse_decorated_atom x =
   301   (parse_atom --| Scan.repeat ($$ "*" || $$ "+" || $$ " ")) x
   302 
   303 fun mk_horn ([], []) = AAtom (ATerm ("c_False", []))
   304   | mk_horn ([], pos_lits) = foldr1 (mk_aconn AOr) pos_lits
   305   | mk_horn (neg_lits, []) = mk_anot (foldr1 (mk_aconn AAnd) neg_lits)
   306   | mk_horn (neg_lits, pos_lits) =
   307     mk_aconn AImplies (foldr1 (mk_aconn AAnd) neg_lits,
   308                        foldr1 (mk_aconn AOr) pos_lits)
   309 
   310 fun parse_horn_clause x =
   311   (Scan.repeat parse_decorated_atom --| $$ "|" --| $$ "|"
   312      -- Scan.repeat parse_decorated_atom --| $$ "-" --| $$ ">"
   313      -- Scan.repeat parse_decorated_atom
   314    >> (mk_horn o apfst (op @))) x
   315 
   316 (* Syntax: <num>[0:<inference><annotations>]
   317    <atoms> || <atoms> -> <atoms>. *)
   318 fun parse_spass_line x =
   319   (scan_general_id --| $$ "[" --| $$ "0" --| $$ ":" --| Symbol.scan_id
   320      -- parse_spass_annotations --| $$ "]" -- parse_horn_clause --| $$ "."
   321    >> (fn ((num, deps), u) =>
   322           Inference ((num, NONE), u, map (rpair NONE) deps))) x
   323 
   324 fun parse_line x = (parse_tstp_line || parse_vampire_line || parse_spass_line) x
   325 val parse_proof =
   326   fst o Scan.finite Symbol.stopper
   327             (Scan.error (!! (fn _ => raise Fail "unrecognized ATP output")
   328                             (Scan.repeat1 parse_line)))
   329   o raw_explode o strip_spaces_except_between_ident_chars
   330 
   331 fun clean_up_dependency seen dep = find_first (curry is_same_step dep) seen
   332 fun clean_up_dependencies _ [] = []
   333   | clean_up_dependencies seen ((step as Definition (name, _, _)) :: steps) =
   334     step :: clean_up_dependencies (name :: seen) steps
   335   | clean_up_dependencies seen (Inference (name, u, deps) :: steps) =
   336     Inference (name, u, map_filter (clean_up_dependency seen) deps) ::
   337     clean_up_dependencies (name :: seen) steps
   338 
   339 val atp_proof_from_tstplike_string =
   340   suffix "$" (* the $ sign acts as a sentinel (FIXME: needed?) *)
   341   #> parse_proof
   342   #> sort (step_name_ord o pairself step_name)
   343   #> clean_up_dependencies []
   344 
   345 fun map_term_names_in_term f (ATerm (s, ts)) =
   346   ATerm (f s, map (map_term_names_in_term f) ts)
   347 fun map_term_names_in_formula f (AQuant (q, xs, phi)) =
   348     AQuant (q, xs, map_term_names_in_formula f phi)
   349   | map_term_names_in_formula f (AConn (c, phis)) =
   350     AConn (c, map (map_term_names_in_formula f) phis)
   351   | map_term_names_in_formula f (AAtom t) = AAtom (map_term_names_in_term f t)
   352 fun map_term_names_in_step f (Definition (name, phi1, phi2)) =
   353     Definition (name, map_term_names_in_formula f phi1,
   354                 map_term_names_in_formula f phi2)
   355   | map_term_names_in_step f (Inference (name, phi, deps)) =
   356     Inference (name, map_term_names_in_formula f phi, deps)
   357 fun map_term_names_in_atp_proof f = map (map_term_names_in_step f)
   358 
   359 fun nasty_name pool s = s |> Symtab.lookup pool |> the_default s
   360 fun nasty_atp_proof pool =
   361   if Symtab.is_empty pool then I
   362   else map_term_names_in_atp_proof (nasty_name pool)
   363 
   364 end;