src/HOL/Limits.thy
author noschinl
Mon Mar 12 21:28:10 2012 +0100 (2012-03-12)
changeset 46886 4cd29473c65d
parent 45892 8dcf6692433f
child 46887 cb891d9a23c1
permissions -rw-r--r--
add eventually_elim method
     1 (*  Title       : Limits.thy
     2     Author      : Brian Huffman
     3 *)
     4 
     5 header {* Filters and Limits *}
     6 
     7 theory Limits
     8 imports RealVector
     9 begin
    10 
    11 subsection {* Filters *}
    12 
    13 text {*
    14   This definition also allows non-proper filters.
    15 *}
    16 
    17 locale is_filter =
    18   fixes F :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
    19   assumes True: "F (\<lambda>x. True)"
    20   assumes conj: "F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x) \<Longrightarrow> F (\<lambda>x. P x \<and> Q x)"
    21   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x)"
    22 
    23 typedef (open) 'a filter = "{F :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter F}"
    24 proof
    25   show "(\<lambda>x. True) \<in> ?filter" by (auto intro: is_filter.intro)
    26 qed
    27 
    28 lemma is_filter_Rep_filter: "is_filter (Rep_filter F)"
    29   using Rep_filter [of F] by simp
    30 
    31 lemma Abs_filter_inverse':
    32   assumes "is_filter F" shows "Rep_filter (Abs_filter F) = F"
    33   using assms by (simp add: Abs_filter_inverse)
    34 
    35 
    36 subsection {* Eventually *}
    37 
    38 definition eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
    39   where "eventually P F \<longleftrightarrow> Rep_filter F P"
    40 
    41 lemma eventually_Abs_filter:
    42   assumes "is_filter F" shows "eventually P (Abs_filter F) = F P"
    43   unfolding eventually_def using assms by (simp add: Abs_filter_inverse)
    44 
    45 lemma filter_eq_iff:
    46   shows "F = F' \<longleftrightarrow> (\<forall>P. eventually P F = eventually P F')"
    47   unfolding Rep_filter_inject [symmetric] fun_eq_iff eventually_def ..
    48 
    49 lemma eventually_True [simp]: "eventually (\<lambda>x. True) F"
    50   unfolding eventually_def
    51   by (rule is_filter.True [OF is_filter_Rep_filter])
    52 
    53 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P F"
    54 proof -
    55   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
    56   thus "eventually P F" by simp
    57 qed
    58 
    59 lemma eventually_mono:
    60   "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually P F \<Longrightarrow> eventually Q F"
    61   unfolding eventually_def
    62   by (rule is_filter.mono [OF is_filter_Rep_filter])
    63 
    64 lemma eventually_conj:
    65   assumes P: "eventually (\<lambda>x. P x) F"
    66   assumes Q: "eventually (\<lambda>x. Q x) F"
    67   shows "eventually (\<lambda>x. P x \<and> Q x) F"
    68   using assms unfolding eventually_def
    69   by (rule is_filter.conj [OF is_filter_Rep_filter])
    70 
    71 lemma eventually_mp:
    72   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
    73   assumes "eventually (\<lambda>x. P x) F"
    74   shows "eventually (\<lambda>x. Q x) F"
    75 proof (rule eventually_mono)
    76   show "\<forall>x. (P x \<longrightarrow> Q x) \<and> P x \<longrightarrow> Q x" by simp
    77   show "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) F"
    78     using assms by (rule eventually_conj)
    79 qed
    80 
    81 lemma eventually_rev_mp:
    82   assumes "eventually (\<lambda>x. P x) F"
    83   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
    84   shows "eventually (\<lambda>x. Q x) F"
    85 using assms(2) assms(1) by (rule eventually_mp)
    86 
    87 lemma eventually_conj_iff:
    88   "eventually (\<lambda>x. P x \<and> Q x) F \<longleftrightarrow> eventually P F \<and> eventually Q F"
    89   by (auto intro: eventually_conj elim: eventually_rev_mp)
    90 
    91 lemma eventually_elim1:
    92   assumes "eventually (\<lambda>i. P i) F"
    93   assumes "\<And>i. P i \<Longrightarrow> Q i"
    94   shows "eventually (\<lambda>i. Q i) F"
    95   using assms by (auto elim!: eventually_rev_mp)
    96 
    97 lemma eventually_elim2:
    98   assumes "eventually (\<lambda>i. P i) F"
    99   assumes "eventually (\<lambda>i. Q i) F"
   100   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
   101   shows "eventually (\<lambda>i. R i) F"
   102   using assms by (auto elim!: eventually_rev_mp)
   103 
   104 lemma eventually_subst:
   105   assumes "eventually (\<lambda>n. P n = Q n) F"
   106   shows "eventually P F = eventually Q F" (is "?L = ?R")
   107 proof -
   108   from assms have "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   109       and "eventually (\<lambda>x. Q x \<longrightarrow> P x) F"
   110     by (auto elim: eventually_elim1)
   111   then show ?thesis by (auto elim: eventually_elim2)
   112 qed
   113 
   114 ML {*
   115   fun ev_elim_tac ctxt thms thm = let
   116       val thy = Proof_Context.theory_of ctxt
   117       val mp_thms = thms RL [@{thm eventually_rev_mp}]
   118       val raw_elim_thm =
   119         (@{thm allI} RS @{thm always_eventually})
   120         |> fold (fn thm1 => fn thm2 => thm2 RS thm1) mp_thms
   121         |> fold (fn _ => fn thm => @{thm impI} RS thm) thms
   122       val cases_prop = prop_of (raw_elim_thm RS thm)
   123       val cases = (Rule_Cases.make_common (thy, cases_prop) [(("elim", []), [])])
   124     in
   125       CASES cases (rtac raw_elim_thm 1) thm
   126     end
   127 
   128   fun eventually_elim_setup name =
   129     Method.setup name (Scan.succeed (fn ctxt => METHOD_CASES (ev_elim_tac ctxt)))
   130       "elimination of eventually quantifiers"
   131 *}
   132 
   133 setup {* eventually_elim_setup @{binding "eventually_elim"} *}
   134 
   135 
   136 subsection {* Finer-than relation *}
   137 
   138 text {* @{term "F \<le> F'"} means that filter @{term F} is finer than
   139 filter @{term F'}. *}
   140 
   141 instantiation filter :: (type) complete_lattice
   142 begin
   143 
   144 definition le_filter_def:
   145   "F \<le> F' \<longleftrightarrow> (\<forall>P. eventually P F' \<longrightarrow> eventually P F)"
   146 
   147 definition
   148   "(F :: 'a filter) < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   149 
   150 definition
   151   "top = Abs_filter (\<lambda>P. \<forall>x. P x)"
   152 
   153 definition
   154   "bot = Abs_filter (\<lambda>P. True)"
   155 
   156 definition
   157   "sup F F' = Abs_filter (\<lambda>P. eventually P F \<and> eventually P F')"
   158 
   159 definition
   160   "inf F F' = Abs_filter
   161       (\<lambda>P. \<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   162 
   163 definition
   164   "Sup S = Abs_filter (\<lambda>P. \<forall>F\<in>S. eventually P F)"
   165 
   166 definition
   167   "Inf S = Sup {F::'a filter. \<forall>F'\<in>S. F \<le> F'}"
   168 
   169 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
   170   unfolding top_filter_def
   171   by (rule eventually_Abs_filter, rule is_filter.intro, auto)
   172 
   173 lemma eventually_bot [simp]: "eventually P bot"
   174   unfolding bot_filter_def
   175   by (subst eventually_Abs_filter, rule is_filter.intro, auto)
   176 
   177 lemma eventually_sup:
   178   "eventually P (sup F F') \<longleftrightarrow> eventually P F \<and> eventually P F'"
   179   unfolding sup_filter_def
   180   by (rule eventually_Abs_filter, rule is_filter.intro)
   181      (auto elim!: eventually_rev_mp)
   182 
   183 lemma eventually_inf:
   184   "eventually P (inf F F') \<longleftrightarrow>
   185    (\<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   186   unfolding inf_filter_def
   187   apply (rule eventually_Abs_filter, rule is_filter.intro)
   188   apply (fast intro: eventually_True)
   189   apply clarify
   190   apply (intro exI conjI)
   191   apply (erule (1) eventually_conj)
   192   apply (erule (1) eventually_conj)
   193   apply simp
   194   apply auto
   195   done
   196 
   197 lemma eventually_Sup:
   198   "eventually P (Sup S) \<longleftrightarrow> (\<forall>F\<in>S. eventually P F)"
   199   unfolding Sup_filter_def
   200   apply (rule eventually_Abs_filter, rule is_filter.intro)
   201   apply (auto intro: eventually_conj elim!: eventually_rev_mp)
   202   done
   203 
   204 instance proof
   205   fix F F' F'' :: "'a filter" and S :: "'a filter set"
   206   { show "F < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   207     by (rule less_filter_def) }
   208   { show "F \<le> F"
   209     unfolding le_filter_def by simp }
   210   { assume "F \<le> F'" and "F' \<le> F''" thus "F \<le> F''"
   211     unfolding le_filter_def by simp }
   212   { assume "F \<le> F'" and "F' \<le> F" thus "F = F'"
   213     unfolding le_filter_def filter_eq_iff by fast }
   214   { show "F \<le> top"
   215     unfolding le_filter_def eventually_top by (simp add: always_eventually) }
   216   { show "bot \<le> F"
   217     unfolding le_filter_def by simp }
   218   { show "F \<le> sup F F'" and "F' \<le> sup F F'"
   219     unfolding le_filter_def eventually_sup by simp_all }
   220   { assume "F \<le> F''" and "F' \<le> F''" thus "sup F F' \<le> F''"
   221     unfolding le_filter_def eventually_sup by simp }
   222   { show "inf F F' \<le> F" and "inf F F' \<le> F'"
   223     unfolding le_filter_def eventually_inf by (auto intro: eventually_True) }
   224   { assume "F \<le> F'" and "F \<le> F''" thus "F \<le> inf F' F''"
   225     unfolding le_filter_def eventually_inf
   226     by (auto elim!: eventually_mono intro: eventually_conj) }
   227   { assume "F \<in> S" thus "F \<le> Sup S"
   228     unfolding le_filter_def eventually_Sup by simp }
   229   { assume "\<And>F. F \<in> S \<Longrightarrow> F \<le> F'" thus "Sup S \<le> F'"
   230     unfolding le_filter_def eventually_Sup by simp }
   231   { assume "F'' \<in> S" thus "Inf S \<le> F''"
   232     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   233   { assume "\<And>F'. F' \<in> S \<Longrightarrow> F \<le> F'" thus "F \<le> Inf S"
   234     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   235 qed
   236 
   237 end
   238 
   239 lemma filter_leD:
   240   "F \<le> F' \<Longrightarrow> eventually P F' \<Longrightarrow> eventually P F"
   241   unfolding le_filter_def by simp
   242 
   243 lemma filter_leI:
   244   "(\<And>P. eventually P F' \<Longrightarrow> eventually P F) \<Longrightarrow> F \<le> F'"
   245   unfolding le_filter_def by simp
   246 
   247 lemma eventually_False:
   248   "eventually (\<lambda>x. False) F \<longleftrightarrow> F = bot"
   249   unfolding filter_eq_iff by (auto elim: eventually_rev_mp)
   250 
   251 abbreviation (input) trivial_limit :: "'a filter \<Rightarrow> bool"
   252   where "trivial_limit F \<equiv> F = bot"
   253 
   254 lemma trivial_limit_def: "trivial_limit F \<longleftrightarrow> eventually (\<lambda>x. False) F"
   255   by (rule eventually_False [symmetric])
   256 
   257 
   258 subsection {* Map function for filters *}
   259 
   260 definition filtermap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow> 'b filter"
   261   where "filtermap f F = Abs_filter (\<lambda>P. eventually (\<lambda>x. P (f x)) F)"
   262 
   263 lemma eventually_filtermap:
   264   "eventually P (filtermap f F) = eventually (\<lambda>x. P (f x)) F"
   265   unfolding filtermap_def
   266   apply (rule eventually_Abs_filter)
   267   apply (rule is_filter.intro)
   268   apply (auto elim!: eventually_rev_mp)
   269   done
   270 
   271 lemma filtermap_ident: "filtermap (\<lambda>x. x) F = F"
   272   by (simp add: filter_eq_iff eventually_filtermap)
   273 
   274 lemma filtermap_filtermap:
   275   "filtermap f (filtermap g F) = filtermap (\<lambda>x. f (g x)) F"
   276   by (simp add: filter_eq_iff eventually_filtermap)
   277 
   278 lemma filtermap_mono: "F \<le> F' \<Longrightarrow> filtermap f F \<le> filtermap f F'"
   279   unfolding le_filter_def eventually_filtermap by simp
   280 
   281 lemma filtermap_bot [simp]: "filtermap f bot = bot"
   282   by (simp add: filter_eq_iff eventually_filtermap)
   283 
   284 
   285 subsection {* Sequentially *}
   286 
   287 definition sequentially :: "nat filter"
   288   where "sequentially = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<ge>k. P n)"
   289 
   290 lemma eventually_sequentially:
   291   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   292 unfolding sequentially_def
   293 proof (rule eventually_Abs_filter, rule is_filter.intro)
   294   fix P Q :: "nat \<Rightarrow> bool"
   295   assume "\<exists>i. \<forall>n\<ge>i. P n" and "\<exists>j. \<forall>n\<ge>j. Q n"
   296   then obtain i j where "\<forall>n\<ge>i. P n" and "\<forall>n\<ge>j. Q n" by auto
   297   then have "\<forall>n\<ge>max i j. P n \<and> Q n" by simp
   298   then show "\<exists>k. \<forall>n\<ge>k. P n \<and> Q n" ..
   299 qed auto
   300 
   301 lemma sequentially_bot [simp, intro]: "sequentially \<noteq> bot"
   302   unfolding filter_eq_iff eventually_sequentially by auto
   303 
   304 lemmas trivial_limit_sequentially = sequentially_bot
   305 
   306 lemma eventually_False_sequentially [simp]:
   307   "\<not> eventually (\<lambda>n. False) sequentially"
   308   by (simp add: eventually_False)
   309 
   310 lemma le_sequentially:
   311   "F \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) F)"
   312   unfolding le_filter_def eventually_sequentially
   313   by (safe, fast, drule_tac x=N in spec, auto elim: eventually_rev_mp)
   314 
   315 lemma eventually_sequentiallyI:
   316   assumes "\<And>x. c \<le> x \<Longrightarrow> P x"
   317   shows "eventually P sequentially"
   318 using assms by (auto simp: eventually_sequentially)
   319 
   320 
   321 subsection {* Standard filters *}
   322 
   323 definition within :: "'a filter \<Rightarrow> 'a set \<Rightarrow> 'a filter" (infixr "within" 70)
   324   where "F within S = Abs_filter (\<lambda>P. eventually (\<lambda>x. x \<in> S \<longrightarrow> P x) F)"
   325 
   326 definition (in topological_space) nhds :: "'a \<Rightarrow> 'a filter"
   327   where "nhds a = Abs_filter (\<lambda>P. \<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   328 
   329 definition (in topological_space) at :: "'a \<Rightarrow> 'a filter"
   330   where "at a = nhds a within - {a}"
   331 
   332 lemma eventually_within:
   333   "eventually P (F within S) = eventually (\<lambda>x. x \<in> S \<longrightarrow> P x) F"
   334   unfolding within_def
   335   by (rule eventually_Abs_filter, rule is_filter.intro)
   336      (auto elim!: eventually_rev_mp)
   337 
   338 lemma within_UNIV [simp]: "F within UNIV = F"
   339   unfolding filter_eq_iff eventually_within by simp
   340 
   341 lemma within_empty [simp]: "F within {} = bot"
   342   unfolding filter_eq_iff eventually_within by simp
   343 
   344 lemma eventually_nhds:
   345   "eventually P (nhds a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   346 unfolding nhds_def
   347 proof (rule eventually_Abs_filter, rule is_filter.intro)
   348   have "open UNIV \<and> a \<in> UNIV \<and> (\<forall>x\<in>UNIV. True)" by simp
   349   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. True)" by - rule
   350 next
   351   fix P Q
   352   assume "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
   353      and "\<exists>T. open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)"
   354   then obtain S T where
   355     "open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
   356     "open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)" by auto
   357   hence "open (S \<inter> T) \<and> a \<in> S \<inter> T \<and> (\<forall>x\<in>(S \<inter> T). P x \<and> Q x)"
   358     by (simp add: open_Int)
   359   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x \<and> Q x)" by - rule
   360 qed auto
   361 
   362 lemma eventually_nhds_metric:
   363   "eventually P (nhds a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. dist x a < d \<longrightarrow> P x)"
   364 unfolding eventually_nhds open_dist
   365 apply safe
   366 apply fast
   367 apply (rule_tac x="{x. dist x a < d}" in exI, simp)
   368 apply clarsimp
   369 apply (rule_tac x="d - dist x a" in exI, clarsimp)
   370 apply (simp only: less_diff_eq)
   371 apply (erule le_less_trans [OF dist_triangle])
   372 done
   373 
   374 lemma nhds_neq_bot [simp]: "nhds a \<noteq> bot"
   375   unfolding trivial_limit_def eventually_nhds by simp
   376 
   377 lemma eventually_at_topological:
   378   "eventually P (at a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> P x))"
   379 unfolding at_def eventually_within eventually_nhds by simp
   380 
   381 lemma eventually_at:
   382   fixes a :: "'a::metric_space"
   383   shows "eventually P (at a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> P x)"
   384 unfolding at_def eventually_within eventually_nhds_metric by auto
   385 
   386 lemma at_eq_bot_iff: "at a = bot \<longleftrightarrow> open {a}"
   387   unfolding trivial_limit_def eventually_at_topological
   388   by (safe, case_tac "S = {a}", simp, fast, fast)
   389 
   390 lemma at_neq_bot [simp]: "at (a::'a::perfect_space) \<noteq> bot"
   391   by (simp add: at_eq_bot_iff not_open_singleton)
   392 
   393 
   394 subsection {* Boundedness *}
   395 
   396 definition Bfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   397   where "Bfun f F = (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) F)"
   398 
   399 lemma BfunI:
   400   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) F" shows "Bfun f F"
   401 unfolding Bfun_def
   402 proof (intro exI conjI allI)
   403   show "0 < max K 1" by simp
   404 next
   405   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) F"
   406     using K by (rule eventually_elim1, simp)
   407 qed
   408 
   409 lemma BfunE:
   410   assumes "Bfun f F"
   411   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) F"
   412 using assms unfolding Bfun_def by fast
   413 
   414 
   415 subsection {* Convergence to Zero *}
   416 
   417 definition Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   418   where "Zfun f F = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) F)"
   419 
   420 lemma ZfunI:
   421   "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F) \<Longrightarrow> Zfun f F"
   422   unfolding Zfun_def by simp
   423 
   424 lemma ZfunD:
   425   "\<lbrakk>Zfun f F; 0 < r\<rbrakk> \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F"
   426   unfolding Zfun_def by simp
   427 
   428 lemma Zfun_ssubst:
   429   "eventually (\<lambda>x. f x = g x) F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun f F"
   430   unfolding Zfun_def by (auto elim!: eventually_rev_mp)
   431 
   432 lemma Zfun_zero: "Zfun (\<lambda>x. 0) F"
   433   unfolding Zfun_def by simp
   434 
   435 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) F = Zfun (\<lambda>x. f x) F"
   436   unfolding Zfun_def by simp
   437 
   438 lemma Zfun_imp_Zfun:
   439   assumes f: "Zfun f F"
   440   assumes g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F"
   441   shows "Zfun (\<lambda>x. g x) F"
   442 proof (cases)
   443   assume K: "0 < K"
   444   show ?thesis
   445   proof (rule ZfunI)
   446     fix r::real assume "0 < r"
   447     hence "0 < r / K"
   448       using K by (rule divide_pos_pos)
   449     then have "eventually (\<lambda>x. norm (f x) < r / K) F"
   450       using ZfunD [OF f] by fast
   451     with g show "eventually (\<lambda>x. norm (g x) < r) F"
   452     proof (rule eventually_elim2)
   453       fix x
   454       assume *: "norm (g x) \<le> norm (f x) * K"
   455       assume "norm (f x) < r / K"
   456       hence "norm (f x) * K < r"
   457         by (simp add: pos_less_divide_eq K)
   458       thus "norm (g x) < r"
   459         by (simp add: order_le_less_trans [OF *])
   460     qed
   461   qed
   462 next
   463   assume "\<not> 0 < K"
   464   hence K: "K \<le> 0" by (simp only: not_less)
   465   show ?thesis
   466   proof (rule ZfunI)
   467     fix r :: real
   468     assume "0 < r"
   469     from g show "eventually (\<lambda>x. norm (g x) < r) F"
   470     proof (rule eventually_elim1)
   471       fix x
   472       assume "norm (g x) \<le> norm (f x) * K"
   473       also have "\<dots> \<le> norm (f x) * 0"
   474         using K norm_ge_zero by (rule mult_left_mono)
   475       finally show "norm (g x) < r"
   476         using `0 < r` by simp
   477     qed
   478   qed
   479 qed
   480 
   481 lemma Zfun_le: "\<lbrakk>Zfun g F; \<forall>x. norm (f x) \<le> norm (g x)\<rbrakk> \<Longrightarrow> Zfun f F"
   482   by (erule_tac K="1" in Zfun_imp_Zfun, simp)
   483 
   484 lemma Zfun_add:
   485   assumes f: "Zfun f F" and g: "Zfun g F"
   486   shows "Zfun (\<lambda>x. f x + g x) F"
   487 proof (rule ZfunI)
   488   fix r::real assume "0 < r"
   489   hence r: "0 < r / 2" by simp
   490   have "eventually (\<lambda>x. norm (f x) < r/2) F"
   491     using f r by (rule ZfunD)
   492   moreover
   493   have "eventually (\<lambda>x. norm (g x) < r/2) F"
   494     using g r by (rule ZfunD)
   495   ultimately
   496   show "eventually (\<lambda>x. norm (f x + g x) < r) F"
   497   proof (rule eventually_elim2)
   498     fix x
   499     assume *: "norm (f x) < r/2" "norm (g x) < r/2"
   500     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
   501       by (rule norm_triangle_ineq)
   502     also have "\<dots> < r/2 + r/2"
   503       using * by (rule add_strict_mono)
   504     finally show "norm (f x + g x) < r"
   505       by simp
   506   qed
   507 qed
   508 
   509 lemma Zfun_minus: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. - f x) F"
   510   unfolding Zfun_def by simp
   511 
   512 lemma Zfun_diff: "\<lbrakk>Zfun f F; Zfun g F\<rbrakk> \<Longrightarrow> Zfun (\<lambda>x. f x - g x) F"
   513   by (simp only: diff_minus Zfun_add Zfun_minus)
   514 
   515 lemma (in bounded_linear) Zfun:
   516   assumes g: "Zfun g F"
   517   shows "Zfun (\<lambda>x. f (g x)) F"
   518 proof -
   519   obtain K where "\<And>x. norm (f x) \<le> norm x * K"
   520     using bounded by fast
   521   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) F"
   522     by simp
   523   with g show ?thesis
   524     by (rule Zfun_imp_Zfun)
   525 qed
   526 
   527 lemma (in bounded_bilinear) Zfun:
   528   assumes f: "Zfun f F"
   529   assumes g: "Zfun g F"
   530   shows "Zfun (\<lambda>x. f x ** g x) F"
   531 proof (rule ZfunI)
   532   fix r::real assume r: "0 < r"
   533   obtain K where K: "0 < K"
   534     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   535     using pos_bounded by fast
   536   from K have K': "0 < inverse K"
   537     by (rule positive_imp_inverse_positive)
   538   have "eventually (\<lambda>x. norm (f x) < r) F"
   539     using f r by (rule ZfunD)
   540   moreover
   541   have "eventually (\<lambda>x. norm (g x) < inverse K) F"
   542     using g K' by (rule ZfunD)
   543   ultimately
   544   show "eventually (\<lambda>x. norm (f x ** g x) < r) F"
   545   proof (rule eventually_elim2)
   546     fix x
   547     assume *: "norm (f x) < r" "norm (g x) < inverse K"
   548     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   549       by (rule norm_le)
   550     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
   551       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero * K)
   552     also from K have "r * inverse K * K = r"
   553       by simp
   554     finally show "norm (f x ** g x) < r" .
   555   qed
   556 qed
   557 
   558 lemma (in bounded_bilinear) Zfun_left:
   559   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. f x ** a) F"
   560   by (rule bounded_linear_left [THEN bounded_linear.Zfun])
   561 
   562 lemma (in bounded_bilinear) Zfun_right:
   563   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. a ** f x) F"
   564   by (rule bounded_linear_right [THEN bounded_linear.Zfun])
   565 
   566 lemmas Zfun_mult = bounded_bilinear.Zfun [OF bounded_bilinear_mult]
   567 lemmas Zfun_mult_right = bounded_bilinear.Zfun_right [OF bounded_bilinear_mult]
   568 lemmas Zfun_mult_left = bounded_bilinear.Zfun_left [OF bounded_bilinear_mult]
   569 
   570 
   571 subsection {* Limits *}
   572 
   573 definition (in topological_space)
   574   tendsto :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b filter \<Rightarrow> bool" (infixr "--->" 55) where
   575   "(f ---> l) F \<longleftrightarrow> (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) F)"
   576 
   577 definition real_tendsto_inf :: "('a \<Rightarrow> real) \<Rightarrow> 'a filter \<Rightarrow> bool" where
   578   "real_tendsto_inf f F \<equiv> \<forall>x. eventually (\<lambda>y. x < f y) F"
   579 
   580 ML {*
   581 structure Tendsto_Intros = Named_Thms
   582 (
   583   val name = @{binding tendsto_intros}
   584   val description = "introduction rules for tendsto"
   585 )
   586 *}
   587 
   588 setup Tendsto_Intros.setup
   589 
   590 lemma tendsto_mono: "F \<le> F' \<Longrightarrow> (f ---> l) F' \<Longrightarrow> (f ---> l) F"
   591   unfolding tendsto_def le_filter_def by fast
   592 
   593 lemma topological_tendstoI:
   594   "(\<And>S. open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F)
   595     \<Longrightarrow> (f ---> l) F"
   596   unfolding tendsto_def by auto
   597 
   598 lemma topological_tendstoD:
   599   "(f ---> l) F \<Longrightarrow> open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F"
   600   unfolding tendsto_def by auto
   601 
   602 lemma tendstoI:
   603   assumes "\<And>e. 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
   604   shows "(f ---> l) F"
   605   apply (rule topological_tendstoI)
   606   apply (simp add: open_dist)
   607   apply (drule (1) bspec, clarify)
   608   apply (drule assms)
   609   apply (erule eventually_elim1, simp)
   610   done
   611 
   612 lemma tendstoD:
   613   "(f ---> l) F \<Longrightarrow> 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
   614   apply (drule_tac S="{x. dist x l < e}" in topological_tendstoD)
   615   apply (clarsimp simp add: open_dist)
   616   apply (rule_tac x="e - dist x l" in exI, clarsimp)
   617   apply (simp only: less_diff_eq)
   618   apply (erule le_less_trans [OF dist_triangle])
   619   apply simp
   620   apply simp
   621   done
   622 
   623 lemma tendsto_iff:
   624   "(f ---> l) F \<longleftrightarrow> (\<forall>e>0. eventually (\<lambda>x. dist (f x) l < e) F)"
   625   using tendstoI tendstoD by fast
   626 
   627 lemma tendsto_Zfun_iff: "(f ---> a) F = Zfun (\<lambda>x. f x - a) F"
   628   by (simp only: tendsto_iff Zfun_def dist_norm)
   629 
   630 lemma tendsto_bot [simp]: "(f ---> a) bot"
   631   unfolding tendsto_def by simp
   632 
   633 lemma tendsto_ident_at [tendsto_intros]: "((\<lambda>x. x) ---> a) (at a)"
   634   unfolding tendsto_def eventually_at_topological by auto
   635 
   636 lemma tendsto_ident_at_within [tendsto_intros]:
   637   "((\<lambda>x. x) ---> a) (at a within S)"
   638   unfolding tendsto_def eventually_within eventually_at_topological by auto
   639 
   640 lemma tendsto_const [tendsto_intros]: "((\<lambda>x. k) ---> k) F"
   641   by (simp add: tendsto_def)
   642 
   643 lemma tendsto_unique:
   644   fixes f :: "'a \<Rightarrow> 'b::t2_space"
   645   assumes "\<not> trivial_limit F" and "(f ---> a) F" and "(f ---> b) F"
   646   shows "a = b"
   647 proof (rule ccontr)
   648   assume "a \<noteq> b"
   649   obtain U V where "open U" "open V" "a \<in> U" "b \<in> V" "U \<inter> V = {}"
   650     using hausdorff [OF `a \<noteq> b`] by fast
   651   have "eventually (\<lambda>x. f x \<in> U) F"
   652     using `(f ---> a) F` `open U` `a \<in> U` by (rule topological_tendstoD)
   653   moreover
   654   have "eventually (\<lambda>x. f x \<in> V) F"
   655     using `(f ---> b) F` `open V` `b \<in> V` by (rule topological_tendstoD)
   656   ultimately
   657   have "eventually (\<lambda>x. False) F"
   658   proof (rule eventually_elim2)
   659     fix x
   660     assume "f x \<in> U" "f x \<in> V"
   661     hence "f x \<in> U \<inter> V" by simp
   662     with `U \<inter> V = {}` show "False" by simp
   663   qed
   664   with `\<not> trivial_limit F` show "False"
   665     by (simp add: trivial_limit_def)
   666 qed
   667 
   668 lemma tendsto_const_iff:
   669   fixes a b :: "'a::t2_space"
   670   assumes "\<not> trivial_limit F" shows "((\<lambda>x. a) ---> b) F \<longleftrightarrow> a = b"
   671   by (safe intro!: tendsto_const tendsto_unique [OF assms tendsto_const])
   672 
   673 lemma tendsto_compose:
   674   assumes g: "(g ---> g l) (at l)"
   675   assumes f: "(f ---> l) F"
   676   shows "((\<lambda>x. g (f x)) ---> g l) F"
   677 proof (rule topological_tendstoI)
   678   fix B assume B: "open B" "g l \<in> B"
   679   obtain A where A: "open A" "l \<in> A"
   680     and gB: "\<forall>y. y \<in> A \<longrightarrow> g y \<in> B"
   681     using topological_tendstoD [OF g B] B(2)
   682     unfolding eventually_at_topological by fast
   683   hence "\<forall>x. f x \<in> A \<longrightarrow> g (f x) \<in> B" by simp
   684   from this topological_tendstoD [OF f A]
   685   show "eventually (\<lambda>x. g (f x) \<in> B) F"
   686     by (rule eventually_mono)
   687 qed
   688 
   689 lemma tendsto_compose_eventually:
   690   assumes g: "(g ---> m) (at l)"
   691   assumes f: "(f ---> l) F"
   692   assumes inj: "eventually (\<lambda>x. f x \<noteq> l) F"
   693   shows "((\<lambda>x. g (f x)) ---> m) F"
   694 proof (rule topological_tendstoI)
   695   fix B assume B: "open B" "m \<in> B"
   696   obtain A where A: "open A" "l \<in> A"
   697     and gB: "\<And>y. y \<in> A \<Longrightarrow> y \<noteq> l \<Longrightarrow> g y \<in> B"
   698     using topological_tendstoD [OF g B]
   699     unfolding eventually_at_topological by fast
   700   show "eventually (\<lambda>x. g (f x) \<in> B) F"
   701     using topological_tendstoD [OF f A] inj
   702     by (rule eventually_elim2) (simp add: gB)
   703 qed
   704 
   705 lemma metric_tendsto_imp_tendsto:
   706   assumes f: "(f ---> a) F"
   707   assumes le: "eventually (\<lambda>x. dist (g x) b \<le> dist (f x) a) F"
   708   shows "(g ---> b) F"
   709 proof (rule tendstoI)
   710   fix e :: real assume "0 < e"
   711   with f have "eventually (\<lambda>x. dist (f x) a < e) F" by (rule tendstoD)
   712   with le show "eventually (\<lambda>x. dist (g x) b < e) F"
   713     using le_less_trans by (rule eventually_elim2)
   714 qed
   715 
   716 lemma real_tendsto_inf_real: "real_tendsto_inf real sequentially"
   717 proof (unfold real_tendsto_inf_def, rule allI)
   718   fix x show "eventually (\<lambda>y. x < real y) sequentially"
   719     by (rule eventually_sequentiallyI[of "natceiling (x + 1)"])
   720         (simp add: natceiling_le_eq)
   721 qed
   722 
   723 
   724 
   725 subsubsection {* Distance and norms *}
   726 
   727 lemma tendsto_dist [tendsto_intros]:
   728   assumes f: "(f ---> l) F" and g: "(g ---> m) F"
   729   shows "((\<lambda>x. dist (f x) (g x)) ---> dist l m) F"
   730 proof (rule tendstoI)
   731   fix e :: real assume "0 < e"
   732   hence e2: "0 < e/2" by simp
   733   from tendstoD [OF f e2] tendstoD [OF g e2]
   734   show "eventually (\<lambda>x. dist (dist (f x) (g x)) (dist l m) < e) F"
   735   proof (rule eventually_elim2)
   736     fix x assume "dist (f x) l < e/2" "dist (g x) m < e/2"
   737     then show "dist (dist (f x) (g x)) (dist l m) < e"
   738       unfolding dist_real_def
   739       using dist_triangle2 [of "f x" "g x" "l"]
   740       using dist_triangle2 [of "g x" "l" "m"]
   741       using dist_triangle3 [of "l" "m" "f x"]
   742       using dist_triangle [of "f x" "m" "g x"]
   743       by arith
   744   qed
   745 qed
   746 
   747 lemma norm_conv_dist: "norm x = dist x 0"
   748   unfolding dist_norm by simp
   749 
   750 lemma tendsto_norm [tendsto_intros]:
   751   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> norm a) F"
   752   unfolding norm_conv_dist by (intro tendsto_intros)
   753 
   754 lemma tendsto_norm_zero:
   755   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> 0) F"
   756   by (drule tendsto_norm, simp)
   757 
   758 lemma tendsto_norm_zero_cancel:
   759   "((\<lambda>x. norm (f x)) ---> 0) F \<Longrightarrow> (f ---> 0) F"
   760   unfolding tendsto_iff dist_norm by simp
   761 
   762 lemma tendsto_norm_zero_iff:
   763   "((\<lambda>x. norm (f x)) ---> 0) F \<longleftrightarrow> (f ---> 0) F"
   764   unfolding tendsto_iff dist_norm by simp
   765 
   766 lemma tendsto_rabs [tendsto_intros]:
   767   "(f ---> (l::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> \<bar>l\<bar>) F"
   768   by (fold real_norm_def, rule tendsto_norm)
   769 
   770 lemma tendsto_rabs_zero:
   771   "(f ---> (0::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> 0) F"
   772   by (fold real_norm_def, rule tendsto_norm_zero)
   773 
   774 lemma tendsto_rabs_zero_cancel:
   775   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<Longrightarrow> (f ---> 0) F"
   776   by (fold real_norm_def, rule tendsto_norm_zero_cancel)
   777 
   778 lemma tendsto_rabs_zero_iff:
   779   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<longleftrightarrow> (f ---> 0) F"
   780   by (fold real_norm_def, rule tendsto_norm_zero_iff)
   781 
   782 subsubsection {* Addition and subtraction *}
   783 
   784 lemma tendsto_add [tendsto_intros]:
   785   fixes a b :: "'a::real_normed_vector"
   786   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> a + b) F"
   787   by (simp only: tendsto_Zfun_iff add_diff_add Zfun_add)
   788 
   789 lemma tendsto_add_zero:
   790   fixes f g :: "'a::type \<Rightarrow> 'b::real_normed_vector"
   791   shows "\<lbrakk>(f ---> 0) F; (g ---> 0) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> 0) F"
   792   by (drule (1) tendsto_add, simp)
   793 
   794 lemma tendsto_minus [tendsto_intros]:
   795   fixes a :: "'a::real_normed_vector"
   796   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. - f x) ---> - a) F"
   797   by (simp only: tendsto_Zfun_iff minus_diff_minus Zfun_minus)
   798 
   799 lemma tendsto_minus_cancel:
   800   fixes a :: "'a::real_normed_vector"
   801   shows "((\<lambda>x. - f x) ---> - a) F \<Longrightarrow> (f ---> a) F"
   802   by (drule tendsto_minus, simp)
   803 
   804 lemma tendsto_diff [tendsto_intros]:
   805   fixes a b :: "'a::real_normed_vector"
   806   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x - g x) ---> a - b) F"
   807   by (simp add: diff_minus tendsto_add tendsto_minus)
   808 
   809 lemma tendsto_setsum [tendsto_intros]:
   810   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::real_normed_vector"
   811   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> a i) F"
   812   shows "((\<lambda>x. \<Sum>i\<in>S. f i x) ---> (\<Sum>i\<in>S. a i)) F"
   813 proof (cases "finite S")
   814   assume "finite S" thus ?thesis using assms
   815     by (induct, simp add: tendsto_const, simp add: tendsto_add)
   816 next
   817   assume "\<not> finite S" thus ?thesis
   818     by (simp add: tendsto_const)
   819 qed
   820 
   821 lemma real_tendsto_sandwich:
   822   fixes f g h :: "'a \<Rightarrow> real"
   823   assumes ev: "eventually (\<lambda>n. f n \<le> g n) net" "eventually (\<lambda>n. g n \<le> h n) net"
   824   assumes lim: "(f ---> c) net" "(h ---> c) net"
   825   shows "(g ---> c) net"
   826 proof -
   827   have "((\<lambda>n. g n - f n) ---> 0) net"
   828   proof (rule metric_tendsto_imp_tendsto)
   829     show "eventually (\<lambda>n. dist (g n - f n) 0 \<le> dist (h n - f n) 0) net"
   830       using ev by (rule eventually_elim2) (simp add: dist_real_def)
   831     show "((\<lambda>n. h n - f n) ---> 0) net"
   832       using tendsto_diff[OF lim(2,1)] by simp
   833   qed
   834   from tendsto_add[OF this lim(1)] show ?thesis by simp
   835 qed
   836 
   837 subsubsection {* Linear operators and multiplication *}
   838 
   839 lemma (in bounded_linear) tendsto:
   840   "(g ---> a) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> f a) F"
   841   by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
   842 
   843 lemma (in bounded_linear) tendsto_zero:
   844   "(g ---> 0) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> 0) F"
   845   by (drule tendsto, simp only: zero)
   846 
   847 lemma (in bounded_bilinear) tendsto:
   848   "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x ** g x) ---> a ** b) F"
   849   by (simp only: tendsto_Zfun_iff prod_diff_prod
   850                  Zfun_add Zfun Zfun_left Zfun_right)
   851 
   852 lemma (in bounded_bilinear) tendsto_zero:
   853   assumes f: "(f ---> 0) F"
   854   assumes g: "(g ---> 0) F"
   855   shows "((\<lambda>x. f x ** g x) ---> 0) F"
   856   using tendsto [OF f g] by (simp add: zero_left)
   857 
   858 lemma (in bounded_bilinear) tendsto_left_zero:
   859   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. f x ** c) ---> 0) F"
   860   by (rule bounded_linear.tendsto_zero [OF bounded_linear_left])
   861 
   862 lemma (in bounded_bilinear) tendsto_right_zero:
   863   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. c ** f x) ---> 0) F"
   864   by (rule bounded_linear.tendsto_zero [OF bounded_linear_right])
   865 
   866 lemmas tendsto_of_real [tendsto_intros] =
   867   bounded_linear.tendsto [OF bounded_linear_of_real]
   868 
   869 lemmas tendsto_scaleR [tendsto_intros] =
   870   bounded_bilinear.tendsto [OF bounded_bilinear_scaleR]
   871 
   872 lemmas tendsto_mult [tendsto_intros] =
   873   bounded_bilinear.tendsto [OF bounded_bilinear_mult]
   874 
   875 lemmas tendsto_mult_zero =
   876   bounded_bilinear.tendsto_zero [OF bounded_bilinear_mult]
   877 
   878 lemmas tendsto_mult_left_zero =
   879   bounded_bilinear.tendsto_left_zero [OF bounded_bilinear_mult]
   880 
   881 lemmas tendsto_mult_right_zero =
   882   bounded_bilinear.tendsto_right_zero [OF bounded_bilinear_mult]
   883 
   884 lemma tendsto_power [tendsto_intros]:
   885   fixes f :: "'a \<Rightarrow> 'b::{power,real_normed_algebra}"
   886   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. f x ^ n) ---> a ^ n) F"
   887   by (induct n) (simp_all add: tendsto_const tendsto_mult)
   888 
   889 lemma tendsto_setprod [tendsto_intros]:
   890   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   891   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> L i) F"
   892   shows "((\<lambda>x. \<Prod>i\<in>S. f i x) ---> (\<Prod>i\<in>S. L i)) F"
   893 proof (cases "finite S")
   894   assume "finite S" thus ?thesis using assms
   895     by (induct, simp add: tendsto_const, simp add: tendsto_mult)
   896 next
   897   assume "\<not> finite S" thus ?thesis
   898     by (simp add: tendsto_const)
   899 qed
   900 
   901 subsubsection {* Inverse and division *}
   902 
   903 lemma (in bounded_bilinear) Zfun_prod_Bfun:
   904   assumes f: "Zfun f F"
   905   assumes g: "Bfun g F"
   906   shows "Zfun (\<lambda>x. f x ** g x) F"
   907 proof -
   908   obtain K where K: "0 \<le> K"
   909     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   910     using nonneg_bounded by fast
   911   obtain B where B: "0 < B"
   912     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) F"
   913     using g by (rule BfunE)
   914   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) F"
   915   using norm_g proof (rule eventually_elim1)
   916     fix x
   917     assume *: "norm (g x) \<le> B"
   918     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   919       by (rule norm_le)
   920     also have "\<dots> \<le> norm (f x) * B * K"
   921       by (intro mult_mono' order_refl norm_g norm_ge_zero
   922                 mult_nonneg_nonneg K *)
   923     also have "\<dots> = norm (f x) * (B * K)"
   924       by (rule mult_assoc)
   925     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
   926   qed
   927   with f show ?thesis
   928     by (rule Zfun_imp_Zfun)
   929 qed
   930 
   931 lemma (in bounded_bilinear) flip:
   932   "bounded_bilinear (\<lambda>x y. y ** x)"
   933   apply default
   934   apply (rule add_right)
   935   apply (rule add_left)
   936   apply (rule scaleR_right)
   937   apply (rule scaleR_left)
   938   apply (subst mult_commute)
   939   using bounded by fast
   940 
   941 lemma (in bounded_bilinear) Bfun_prod_Zfun:
   942   assumes f: "Bfun f F"
   943   assumes g: "Zfun g F"
   944   shows "Zfun (\<lambda>x. f x ** g x) F"
   945   using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
   946 
   947 lemma Bfun_inverse_lemma:
   948   fixes x :: "'a::real_normed_div_algebra"
   949   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   950   apply (subst nonzero_norm_inverse, clarsimp)
   951   apply (erule (1) le_imp_inverse_le)
   952   done
   953 
   954 lemma Bfun_inverse:
   955   fixes a :: "'a::real_normed_div_algebra"
   956   assumes f: "(f ---> a) F"
   957   assumes a: "a \<noteq> 0"
   958   shows "Bfun (\<lambda>x. inverse (f x)) F"
   959 proof -
   960   from a have "0 < norm a" by simp
   961   hence "\<exists>r>0. r < norm a" by (rule dense)
   962   then obtain r where r1: "0 < r" and r2: "r < norm a" by fast
   963   have "eventually (\<lambda>x. dist (f x) a < r) F"
   964     using tendstoD [OF f r1] by fast
   965   hence "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) F"
   966   proof (rule eventually_elim1)
   967     fix x
   968     assume "dist (f x) a < r"
   969     hence 1: "norm (f x - a) < r"
   970       by (simp add: dist_norm)
   971     hence 2: "f x \<noteq> 0" using r2 by auto
   972     hence "norm (inverse (f x)) = inverse (norm (f x))"
   973       by (rule nonzero_norm_inverse)
   974     also have "\<dots> \<le> inverse (norm a - r)"
   975     proof (rule le_imp_inverse_le)
   976       show "0 < norm a - r" using r2 by simp
   977     next
   978       have "norm a - norm (f x) \<le> norm (a - f x)"
   979         by (rule norm_triangle_ineq2)
   980       also have "\<dots> = norm (f x - a)"
   981         by (rule norm_minus_commute)
   982       also have "\<dots> < r" using 1 .
   983       finally show "norm a - r \<le> norm (f x)" by simp
   984     qed
   985     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
   986   qed
   987   thus ?thesis by (rule BfunI)
   988 qed
   989 
   990 lemma tendsto_inverse [tendsto_intros]:
   991   fixes a :: "'a::real_normed_div_algebra"
   992   assumes f: "(f ---> a) F"
   993   assumes a: "a \<noteq> 0"
   994   shows "((\<lambda>x. inverse (f x)) ---> inverse a) F"
   995 proof -
   996   from a have "0 < norm a" by simp
   997   with f have "eventually (\<lambda>x. dist (f x) a < norm a) F"
   998     by (rule tendstoD)
   999   then have "eventually (\<lambda>x. f x \<noteq> 0) F"
  1000     unfolding dist_norm by (auto elim!: eventually_elim1)
  1001   with a have "eventually (\<lambda>x. inverse (f x) - inverse a =
  1002     - (inverse (f x) * (f x - a) * inverse a)) F"
  1003     by (auto elim!: eventually_elim1 simp: inverse_diff_inverse)
  1004   moreover have "Zfun (\<lambda>x. - (inverse (f x) * (f x - a) * inverse a)) F"
  1005     by (intro Zfun_minus Zfun_mult_left
  1006       bounded_bilinear.Bfun_prod_Zfun [OF bounded_bilinear_mult]
  1007       Bfun_inverse [OF f a] f [unfolded tendsto_Zfun_iff])
  1008   ultimately show ?thesis
  1009     unfolding tendsto_Zfun_iff by (rule Zfun_ssubst)
  1010 qed
  1011 
  1012 lemma tendsto_divide [tendsto_intros]:
  1013   fixes a b :: "'a::real_normed_field"
  1014   shows "\<lbrakk>(f ---> a) F; (g ---> b) F; b \<noteq> 0\<rbrakk>
  1015     \<Longrightarrow> ((\<lambda>x. f x / g x) ---> a / b) F"
  1016   by (simp add: tendsto_mult tendsto_inverse divide_inverse)
  1017 
  1018 lemma tendsto_sgn [tendsto_intros]:
  1019   fixes l :: "'a::real_normed_vector"
  1020   shows "\<lbrakk>(f ---> l) F; l \<noteq> 0\<rbrakk> \<Longrightarrow> ((\<lambda>x. sgn (f x)) ---> sgn l) F"
  1021   unfolding sgn_div_norm by (simp add: tendsto_intros)
  1022 
  1023 end