src/HOL/Library/Float.thy
author hoelzl
Fri Apr 20 11:14:39 2012 +0200 (2012-04-20)
changeset 47621 4cf6011fb884
parent 47615 341fd902ef1c
child 47780 3357688660ff
permissions -rw-r--r--
hide code generation facts in the Float theory, they are only exported for Approximation
     1 (*  Title:      HOL/Library/Float.thy
     2     Author:     Johannes Hölzl, Fabian Immler
     3     Copyright   2012  TU München
     4 *)
     5 
     6 header {* Floating-Point Numbers *}
     7 
     8 theory Float
     9 imports Complex_Main "~~/src/HOL/Library/Lattice_Algebras"
    10 begin
    11 
    12 typedef float = "{m * 2 powr e | (m :: int) (e :: int). True }"
    13   morphisms real_of_float float_of
    14   by auto
    15 
    16 defs (overloaded)
    17   real_of_float_def[code_unfold]: "real \<equiv> real_of_float"
    18 
    19 lemma type_definition_float': "type_definition real float_of float"
    20   using type_definition_float unfolding real_of_float_def .
    21 
    22 setup_lifting (no_abs_code) type_definition_float'
    23 
    24 lemmas float_of_inject[simp]
    25 
    26 declare [[coercion "real :: float \<Rightarrow> real"]]
    27 
    28 lemma real_of_float_eq:
    29   fixes f1 f2 :: float shows "f1 = f2 \<longleftrightarrow> real f1 = real f2"
    30   unfolding real_of_float_def real_of_float_inject ..
    31 
    32 lemma float_of_real[simp]: "float_of (real x) = x"
    33   unfolding real_of_float_def by (rule real_of_float_inverse)
    34 
    35 lemma real_float[simp]: "x \<in> float \<Longrightarrow> real (float_of x) = x"
    36   unfolding real_of_float_def by (rule float_of_inverse)
    37 
    38 subsection {* Real operations preserving the representation as floating point number *}
    39 
    40 lemma floatI: fixes m e :: int shows "m * 2 powr e = x \<Longrightarrow> x \<in> float"
    41   by (auto simp: float_def)
    42 
    43 lemma zero_float[simp]: "0 \<in> float" by (auto simp: float_def)
    44 lemma one_float[simp]: "1 \<in> float" by (intro floatI[of 1 0]) simp
    45 lemma numeral_float[simp]: "numeral i \<in> float" by (intro floatI[of "numeral i" 0]) simp  
    46 lemma neg_numeral_float[simp]: "neg_numeral i \<in> float" by (intro floatI[of "neg_numeral i" 0]) simp
    47 lemma real_of_int_float[simp]: "real (x :: int) \<in> float" by (intro floatI[of x 0]) simp
    48 lemma real_of_nat_float[simp]: "real (x :: nat) \<in> float" by (intro floatI[of x 0]) simp
    49 lemma two_powr_int_float[simp]: "2 powr (real (i::int)) \<in> float" by (intro floatI[of 1 i]) simp
    50 lemma two_powr_nat_float[simp]: "2 powr (real (i::nat)) \<in> float" by (intro floatI[of 1 i]) simp
    51 lemma two_powr_minus_int_float[simp]: "2 powr - (real (i::int)) \<in> float" by (intro floatI[of 1 "-i"]) simp
    52 lemma two_powr_minus_nat_float[simp]: "2 powr - (real (i::nat)) \<in> float" by (intro floatI[of 1 "-i"]) simp
    53 lemma two_powr_numeral_float[simp]: "2 powr numeral i \<in> float" by (intro floatI[of 1 "numeral i"]) simp
    54 lemma two_powr_neg_numeral_float[simp]: "2 powr neg_numeral i \<in> float" by (intro floatI[of 1 "neg_numeral i"]) simp
    55 lemma two_pow_float[simp]: "2 ^ n \<in> float" by (intro floatI[of 1 "n"]) (simp add: powr_realpow)
    56 lemma real_of_float_float[simp]: "real (f::float) \<in> float" by (cases f) simp
    57 
    58 lemma plus_float[simp]: "r \<in> float \<Longrightarrow> p \<in> float \<Longrightarrow> r + p \<in> float"
    59   unfolding float_def
    60 proof (safe, simp)
    61   fix e1 m1 e2 m2 :: int
    62   { fix e1 m1 e2 m2 :: int assume "e1 \<le> e2"
    63     then have "m1 * 2 powr e1 + m2 * 2 powr e2 = (m1 + m2 * 2 ^ nat (e2 - e1)) * 2 powr e1"
    64       by (simp add: powr_realpow[symmetric] powr_divide2[symmetric] field_simps)
    65     then have "\<exists>(m::int) (e::int). m1 * 2 powr e1 + m2 * 2 powr e2 = m * 2 powr e"
    66       by blast }
    67   note * = this
    68   show "\<exists>(m::int) (e::int). m1 * 2 powr e1 + m2 * 2 powr e2 = m * 2 powr e"
    69   proof (cases e1 e2 rule: linorder_le_cases)
    70     assume "e2 \<le> e1" from *[OF this, of m2 m1] show ?thesis by (simp add: ac_simps)
    71   qed (rule *)
    72 qed
    73 
    74 lemma uminus_float[simp]: "x \<in> float \<Longrightarrow> -x \<in> float"
    75   apply (auto simp: float_def)
    76   apply (rule_tac x="-x" in exI)
    77   apply (rule_tac x="xa" in exI)
    78   apply (simp add: field_simps)
    79   done
    80 
    81 lemma times_float[simp]: "x \<in> float \<Longrightarrow> y \<in> float \<Longrightarrow> x * y \<in> float"
    82   apply (auto simp: float_def)
    83   apply (rule_tac x="x * xa" in exI)
    84   apply (rule_tac x="xb + xc" in exI)
    85   apply (simp add: powr_add)
    86   done
    87 
    88 lemma minus_float[simp]: "x \<in> float \<Longrightarrow> y \<in> float \<Longrightarrow> x - y \<in> float"
    89   unfolding ab_diff_minus by (intro uminus_float plus_float)
    90 
    91 lemma abs_float[simp]: "x \<in> float \<Longrightarrow> abs x \<in> float"
    92   by (cases x rule: linorder_cases[of 0]) auto
    93 
    94 lemma sgn_of_float[simp]: "x \<in> float \<Longrightarrow> sgn x \<in> float"
    95   by (cases x rule: linorder_cases[of 0]) (auto intro!: uminus_float)
    96 
    97 lemma div_power_2_float[simp]: "x \<in> float \<Longrightarrow> x / 2^d \<in> float"
    98   apply (auto simp add: float_def)
    99   apply (rule_tac x="x" in exI)
   100   apply (rule_tac x="xa - d" in exI)
   101   apply (simp add: powr_realpow[symmetric] field_simps powr_add[symmetric])
   102   done
   103 
   104 lemma div_power_2_int_float[simp]: "x \<in> float \<Longrightarrow> x / (2::int)^d \<in> float"
   105   apply (auto simp add: float_def)
   106   apply (rule_tac x="x" in exI)
   107   apply (rule_tac x="xa - d" in exI)
   108   apply (simp add: powr_realpow[symmetric] field_simps powr_add[symmetric])
   109   done
   110 
   111 lemma div_numeral_Bit0_float[simp]:
   112   assumes x: "x / numeral n \<in> float" shows "x / (numeral (Num.Bit0 n)) \<in> float"
   113 proof -
   114   have "(x / numeral n) / 2^1 \<in> float"
   115     by (intro x div_power_2_float)
   116   also have "(x / numeral n) / 2^1 = x / (numeral (Num.Bit0 n))"
   117     by (induct n) auto
   118   finally show ?thesis .
   119 qed
   120 
   121 lemma div_neg_numeral_Bit0_float[simp]:
   122   assumes x: "x / numeral n \<in> float" shows "x / (neg_numeral (Num.Bit0 n)) \<in> float"
   123 proof -
   124   have "- (x / numeral (Num.Bit0 n)) \<in> float" using x by simp
   125   also have "- (x / numeral (Num.Bit0 n)) = x / neg_numeral (Num.Bit0 n)"
   126     unfolding neg_numeral_def by (simp del: minus_numeral)
   127   finally show ?thesis .
   128 qed
   129 
   130 lift_definition Float :: "int \<Rightarrow> int \<Rightarrow> float" is "\<lambda>(m::int) (e::int). m * 2 powr e" by simp
   131 declare Float.rep_eq[simp]
   132 
   133 code_datatype Float
   134 
   135 subsection {* Arithmetic operations on floating point numbers *}
   136 
   137 instantiation float :: "{ring_1, linorder, linordered_ring, linordered_idom, numeral, equal}"
   138 begin
   139 
   140 lift_definition zero_float :: float is 0 by simp
   141 declare zero_float.rep_eq[simp]
   142 lift_definition one_float :: float is 1 by simp
   143 declare one_float.rep_eq[simp]
   144 lift_definition plus_float :: "float \<Rightarrow> float \<Rightarrow> float" is "op +" by simp
   145 declare plus_float.rep_eq[simp]
   146 lift_definition times_float :: "float \<Rightarrow> float \<Rightarrow> float" is "op *" by simp
   147 declare times_float.rep_eq[simp]
   148 lift_definition minus_float :: "float \<Rightarrow> float \<Rightarrow> float" is "op -" by simp
   149 declare minus_float.rep_eq[simp]
   150 lift_definition uminus_float :: "float \<Rightarrow> float" is "uminus" by simp
   151 declare uminus_float.rep_eq[simp]
   152 
   153 lift_definition abs_float :: "float \<Rightarrow> float" is abs by simp
   154 declare abs_float.rep_eq[simp]
   155 lift_definition sgn_float :: "float \<Rightarrow> float" is sgn by simp
   156 declare sgn_float.rep_eq[simp]
   157 
   158 lift_definition equal_float :: "float \<Rightarrow> float \<Rightarrow> bool" is "op = :: real \<Rightarrow> real \<Rightarrow> bool" ..
   159 
   160 lift_definition less_eq_float :: "float \<Rightarrow> float \<Rightarrow> bool" is "op \<le>" ..
   161 declare less_eq_float.rep_eq[simp]
   162 lift_definition less_float :: "float \<Rightarrow> float \<Rightarrow> bool" is "op <" ..
   163 declare less_float.rep_eq[simp]
   164 
   165 instance
   166   proof qed (transfer, fastforce simp add: field_simps intro: mult_left_mono mult_right_mono)+
   167 end
   168 
   169 lemma real_of_float_power[simp]: fixes f::float shows "real (f^n) = real f^n"
   170   by (induct n) simp_all
   171 
   172 lemma fixes x y::float 
   173   shows real_of_float_min: "real (min x y) = min (real x) (real y)"
   174     and real_of_float_max: "real (max x y) = max (real x) (real y)"
   175   by (simp_all add: min_def max_def)
   176 
   177 instance float :: dense_linorder
   178 proof
   179   fix a b :: float
   180   show "\<exists>c. a < c"
   181     apply (intro exI[of _ "a + 1"])
   182     apply transfer
   183     apply simp
   184     done
   185   show "\<exists>c. c < a"
   186     apply (intro exI[of _ "a - 1"])
   187     apply transfer
   188     apply simp
   189     done
   190   assume "a < b"
   191   then show "\<exists>c. a < c \<and> c < b"
   192     apply (intro exI[of _ "(a + b) * Float 1 -1"])
   193     apply transfer
   194     apply (simp add: powr_neg_numeral) 
   195     done
   196 qed
   197 
   198 instantiation float :: lattice_ab_group_add
   199 begin
   200 
   201 definition inf_float::"float\<Rightarrow>float\<Rightarrow>float"
   202 where "inf_float a b = min a b"
   203 
   204 definition sup_float::"float\<Rightarrow>float\<Rightarrow>float"
   205 where "sup_float a b = max a b"
   206 
   207 instance
   208   by default
   209      (transfer, simp_all add: inf_float_def sup_float_def real_of_float_min real_of_float_max)+
   210 end
   211 
   212 lemma float_numeral[simp]: "real (numeral x :: float) = numeral x"
   213   apply (induct x)
   214   apply simp
   215   apply (simp_all only: numeral_Bit0 numeral_Bit1 real_of_float_eq real_float
   216                   plus_float.rep_eq one_float.rep_eq plus_float numeral_float one_float)
   217   done
   218 
   219 lemma transfer_numeral [transfer_rule]: 
   220   "fun_rel (op =) cr_float (numeral :: _ \<Rightarrow> real) (numeral :: _ \<Rightarrow> float)"
   221   unfolding fun_rel_def cr_float_def by simp
   222 
   223 lemma float_neg_numeral[simp]: "real (neg_numeral x :: float) = neg_numeral x"
   224   by (simp add: minus_numeral[symmetric] del: minus_numeral)
   225 
   226 lemma transfer_neg_numeral [transfer_rule]: 
   227   "fun_rel (op =) cr_float (neg_numeral :: _ \<Rightarrow> real) (neg_numeral :: _ \<Rightarrow> float)"
   228   unfolding fun_rel_def cr_float_def by simp
   229 
   230 lemma
   231   shows float_of_numeral[simp]: "numeral k = float_of (numeral k)"
   232     and float_of_neg_numeral[simp]: "neg_numeral k = float_of (neg_numeral k)"
   233   unfolding real_of_float_eq by simp_all
   234 
   235 subsection {* Represent floats as unique mantissa and exponent *}
   236 
   237 lemma int_induct_abs[case_names less]:
   238   fixes j :: int
   239   assumes H: "\<And>n. (\<And>i. \<bar>i\<bar> < \<bar>n\<bar> \<Longrightarrow> P i) \<Longrightarrow> P n"
   240   shows "P j"
   241 proof (induct "nat \<bar>j\<bar>" arbitrary: j rule: less_induct)
   242   case less show ?case by (rule H[OF less]) simp
   243 qed
   244 
   245 lemma int_cancel_factors:
   246   fixes n :: int assumes "1 < r" shows "n = 0 \<or> (\<exists>k i. n = k * r ^ i \<and> \<not> r dvd k)"
   247 proof (induct n rule: int_induct_abs)
   248   case (less n)
   249   { fix m assume n: "n \<noteq> 0" "n = m * r"
   250     then have "\<bar>m \<bar> < \<bar>n\<bar>"
   251       by (metis abs_dvd_iff abs_ge_self assms comm_semiring_1_class.normalizing_semiring_rules(7)
   252                 dvd_imp_le_int dvd_refl dvd_triv_right linorder_neq_iff linorder_not_le
   253                 mult_eq_0_iff zdvd_mult_cancel1)
   254     from less[OF this] n have "\<exists>k i. n = k * r ^ Suc i \<and> \<not> r dvd k" by auto }
   255   then show ?case
   256     by (metis comm_semiring_1_class.normalizing_semiring_rules(12,7) dvdE power_0)
   257 qed
   258 
   259 lemma mult_powr_eq_mult_powr_iff_asym:
   260   fixes m1 m2 e1 e2 :: int
   261   assumes m1: "\<not> 2 dvd m1" and "e1 \<le> e2"
   262   shows "m1 * 2 powr e1 = m2 * 2 powr e2 \<longleftrightarrow> m1 = m2 \<and> e1 = e2"
   263 proof
   264   have "m1 \<noteq> 0" using m1 unfolding dvd_def by auto
   265   assume eq: "m1 * 2 powr e1 = m2 * 2 powr e2"
   266   with `e1 \<le> e2` have "m1 = m2 * 2 powr nat (e2 - e1)"
   267     by (simp add: powr_divide2[symmetric] field_simps)
   268   also have "\<dots> = m2 * 2^nat (e2 - e1)"
   269     by (simp add: powr_realpow)
   270   finally have m1_eq: "m1 = m2 * 2^nat (e2 - e1)"
   271     unfolding real_of_int_inject .
   272   with m1 have "m1 = m2"
   273     by (cases "nat (e2 - e1)") (auto simp add: dvd_def)
   274   then show "m1 = m2 \<and> e1 = e2"
   275     using eq `m1 \<noteq> 0` by (simp add: powr_inj)
   276 qed simp
   277 
   278 lemma mult_powr_eq_mult_powr_iff:
   279   fixes m1 m2 e1 e2 :: int
   280   shows "\<not> 2 dvd m1 \<Longrightarrow> \<not> 2 dvd m2 \<Longrightarrow> m1 * 2 powr e1 = m2 * 2 powr e2 \<longleftrightarrow> m1 = m2 \<and> e1 = e2"
   281   using mult_powr_eq_mult_powr_iff_asym[of m1 e1 e2 m2]
   282   using mult_powr_eq_mult_powr_iff_asym[of m2 e2 e1 m1]
   283   by (cases e1 e2 rule: linorder_le_cases) auto
   284 
   285 lemma floatE_normed:
   286   assumes x: "x \<in> float"
   287   obtains (zero) "x = 0"
   288    | (powr) m e :: int where "x = m * 2 powr e" "\<not> 2 dvd m" "x \<noteq> 0"
   289 proof atomize_elim
   290   { assume "x \<noteq> 0"
   291     from x obtain m e :: int where x: "x = m * 2 powr e" by (auto simp: float_def)
   292     with `x \<noteq> 0` int_cancel_factors[of 2 m] obtain k i where "m = k * 2 ^ i" "\<not> 2 dvd k"
   293       by auto
   294     with `\<not> 2 dvd k` x have "\<exists>(m::int) (e::int). x = m * 2 powr e \<and> \<not> (2::int) dvd m"
   295       by (rule_tac exI[of _ "k"], rule_tac exI[of _ "e + int i"])
   296          (simp add: powr_add powr_realpow) }
   297   then show "x = 0 \<or> (\<exists>(m::int) (e::int). x = m * 2 powr e \<and> \<not> (2::int) dvd m \<and> x \<noteq> 0)"
   298     by blast
   299 qed
   300 
   301 lemma float_normed_cases:
   302   fixes f :: float
   303   obtains (zero) "f = 0"
   304    | (powr) m e :: int where "real f = m * 2 powr e" "\<not> 2 dvd m" "f \<noteq> 0"
   305 proof (atomize_elim, induct f)
   306   case (float_of y) then show ?case
   307     by (cases rule: floatE_normed) (auto simp: zero_float_def)
   308 qed
   309 
   310 definition mantissa :: "float \<Rightarrow> int" where
   311   "mantissa f = fst (SOME p::int \<times> int. (f = 0 \<and> fst p = 0 \<and> snd p = 0)
   312    \<or> (f \<noteq> 0 \<and> real f = real (fst p) * 2 powr real (snd p) \<and> \<not> 2 dvd fst p))"
   313 
   314 definition exponent :: "float \<Rightarrow> int" where
   315   "exponent f = snd (SOME p::int \<times> int. (f = 0 \<and> fst p = 0 \<and> snd p = 0)
   316    \<or> (f \<noteq> 0 \<and> real f = real (fst p) * 2 powr real (snd p) \<and> \<not> 2 dvd fst p))"
   317 
   318 lemma 
   319   shows exponent_0[simp]: "exponent (float_of 0) = 0" (is ?E)
   320     and mantissa_0[simp]: "mantissa (float_of 0) = 0" (is ?M)
   321 proof -
   322   have "\<And>p::int \<times> int. fst p = 0 \<and> snd p = 0 \<longleftrightarrow> p = (0, 0)" by auto
   323   then show ?E ?M
   324     by (auto simp add: mantissa_def exponent_def zero_float_def)
   325 qed
   326 
   327 lemma
   328   shows mantissa_exponent: "real f = mantissa f * 2 powr exponent f" (is ?E)
   329     and mantissa_not_dvd: "f \<noteq> (float_of 0) \<Longrightarrow> \<not> 2 dvd mantissa f" (is "_ \<Longrightarrow> ?D")
   330 proof cases
   331   assume [simp]: "f \<noteq> (float_of 0)"
   332   have "f = mantissa f * 2 powr exponent f \<and> \<not> 2 dvd mantissa f"
   333   proof (cases f rule: float_normed_cases)
   334     case (powr m e)
   335     then have "\<exists>p::int \<times> int. (f = 0 \<and> fst p = 0 \<and> snd p = 0)
   336      \<or> (f \<noteq> 0 \<and> real f = real (fst p) * 2 powr real (snd p) \<and> \<not> 2 dvd fst p)"
   337       by auto
   338     then show ?thesis
   339       unfolding exponent_def mantissa_def
   340       by (rule someI2_ex) (simp add: zero_float_def)
   341   qed (simp add: zero_float_def)
   342   then show ?E ?D by auto
   343 qed simp
   344 
   345 lemma mantissa_noteq_0: "f \<noteq> float_of 0 \<Longrightarrow> mantissa f \<noteq> 0"
   346   using mantissa_not_dvd[of f] by auto
   347 
   348 lemma 
   349   fixes m e :: int
   350   defines "f \<equiv> float_of (m * 2 powr e)"
   351   assumes dvd: "\<not> 2 dvd m"
   352   shows mantissa_float: "mantissa f = m" (is "?M")
   353     and exponent_float: "m \<noteq> 0 \<Longrightarrow> exponent f = e" (is "_ \<Longrightarrow> ?E")
   354 proof cases
   355   assume "m = 0" with dvd show "mantissa f = m" by auto
   356 next
   357   assume "m \<noteq> 0"
   358   then have f_not_0: "f \<noteq> float_of 0" by (simp add: f_def)
   359   from mantissa_exponent[of f]
   360   have "m * 2 powr e = mantissa f * 2 powr exponent f"
   361     by (auto simp add: f_def)
   362   then show "?M" "?E"
   363     using mantissa_not_dvd[OF f_not_0] dvd
   364     by (auto simp: mult_powr_eq_mult_powr_iff)
   365 qed
   366 
   367 subsection {* Compute arithmetic operations *}
   368 
   369 lemma Float_mantissa_exponent: "Float (mantissa f) (exponent f) = f"
   370   unfolding real_of_float_eq mantissa_exponent[of f] by simp
   371 
   372 lemma Float_cases[case_names Float, cases type: float]:
   373   fixes f :: float
   374   obtains (Float) m e :: int where "f = Float m e"
   375   using Float_mantissa_exponent[symmetric]
   376   by (atomize_elim) auto
   377 
   378 lemma denormalize_shift:
   379   assumes f_def: "f \<equiv> Float m e" and not_0: "f \<noteq> float_of 0"
   380   obtains i where "m = mantissa f * 2 ^ i" "e = exponent f - i"
   381 proof
   382   from mantissa_exponent[of f] f_def
   383   have "m * 2 powr e = mantissa f * 2 powr exponent f"
   384     by simp
   385   then have eq: "m = mantissa f * 2 powr (exponent f - e)"
   386     by (simp add: powr_divide2[symmetric] field_simps)
   387   moreover
   388   have "e \<le> exponent f"
   389   proof (rule ccontr)
   390     assume "\<not> e \<le> exponent f"
   391     then have pos: "exponent f < e" by simp
   392     then have "2 powr (exponent f - e) = 2 powr - real (e - exponent f)"
   393       by simp
   394     also have "\<dots> = 1 / 2^nat (e - exponent f)"
   395       using pos by (simp add: powr_realpow[symmetric] powr_divide2[symmetric])
   396     finally have "m * 2^nat (e - exponent f) = real (mantissa f)"
   397       using eq by simp
   398     then have "mantissa f = m * 2^nat (e - exponent f)"
   399       unfolding real_of_int_inject by simp
   400     with `exponent f < e` have "2 dvd mantissa f"
   401       apply (intro dvdI[where k="m * 2^(nat (e-exponent f)) div 2"])
   402       apply (cases "nat (e - exponent f)")
   403       apply auto
   404       done
   405     then show False using mantissa_not_dvd[OF not_0] by simp
   406   qed
   407   ultimately have "real m = mantissa f * 2^nat (exponent f - e)"
   408     by (simp add: powr_realpow[symmetric])
   409   with `e \<le> exponent f`
   410   show "m = mantissa f * 2 ^ nat (exponent f - e)" "e = exponent f - nat (exponent f - e)"
   411     unfolding real_of_int_inject by auto
   412 qed
   413 
   414 lemma compute_float_zero[code_unfold, code]: "0 = Float 0 0"
   415   by transfer simp
   416 hide_fact (open) compute_float_zero
   417 
   418 lemma compute_float_one[code_unfold, code]: "1 = Float 1 0"
   419   by transfer simp
   420 hide_fact (open) compute_float_one
   421 
   422 definition normfloat :: "float \<Rightarrow> float" where
   423   [simp]: "normfloat x = x"
   424 
   425 lemma compute_normfloat[code]: "normfloat (Float m e) =
   426   (if m mod 2 = 0 \<and> m \<noteq> 0 then normfloat (Float (m div 2) (e + 1))
   427                            else if m = 0 then 0 else Float m e)"
   428   unfolding normfloat_def
   429   by transfer (auto simp add: powr_add zmod_eq_0_iff)
   430 hide_fact (open) compute_normfloat
   431 
   432 lemma compute_float_numeral[code_abbrev]: "Float (numeral k) 0 = numeral k"
   433   by transfer simp
   434 hide_fact (open) compute_float_numeral
   435 
   436 lemma compute_float_neg_numeral[code_abbrev]: "Float (neg_numeral k) 0 = neg_numeral k"
   437   by transfer simp
   438 hide_fact (open) compute_float_neg_numeral
   439 
   440 lemma compute_float_uminus[code]: "- Float m1 e1 = Float (- m1) e1"
   441   by transfer simp
   442 hide_fact (open) compute_float_uminus
   443 
   444 lemma compute_float_times[code]: "Float m1 e1 * Float m2 e2 = Float (m1 * m2) (e1 + e2)"
   445   by transfer (simp add: field_simps powr_add)
   446 hide_fact (open) compute_float_times
   447 
   448 lemma compute_float_plus[code]: "Float m1 e1 + Float m2 e2 =
   449   (if e1 \<le> e2 then Float (m1 + m2 * 2^nat (e2 - e1)) e1
   450               else Float (m2 + m1 * 2^nat (e1 - e2)) e2)"
   451   by transfer (simp add: field_simps powr_realpow[symmetric] powr_divide2[symmetric])
   452 hide_fact (open) compute_float_plus
   453 
   454 lemma compute_float_minus[code]: fixes f g::float shows "f - g = f + (-g)"
   455   by simp
   456 hide_fact (open) compute_float_minus
   457 
   458 lemma compute_float_sgn[code]: "sgn (Float m1 e1) = (if 0 < m1 then 1 else if m1 < 0 then -1 else 0)"
   459   by transfer (simp add: sgn_times)
   460 hide_fact (open) compute_float_sgn
   461 
   462 lift_definition is_float_pos :: "float \<Rightarrow> bool" is "op < 0 :: real \<Rightarrow> bool" ..
   463 
   464 lemma compute_is_float_pos[code]: "is_float_pos (Float m e) \<longleftrightarrow> 0 < m"
   465   by transfer (auto simp add: zero_less_mult_iff not_le[symmetric, of _ 0])
   466 hide_fact (open) compute_is_float_pos
   467 
   468 lemma compute_float_less[code]: "a < b \<longleftrightarrow> is_float_pos (b - a)"
   469   by transfer (simp add: field_simps)
   470 hide_fact (open) compute_float_less
   471 
   472 lift_definition is_float_nonneg :: "float \<Rightarrow> bool" is "op \<le> 0 :: real \<Rightarrow> bool" ..
   473 
   474 lemma compute_is_float_nonneg[code]: "is_float_nonneg (Float m e) \<longleftrightarrow> 0 \<le> m"
   475   by transfer (auto simp add: zero_le_mult_iff not_less[symmetric, of _ 0])
   476 hide_fact (open) compute_is_float_nonneg
   477 
   478 lemma compute_float_le[code]: "a \<le> b \<longleftrightarrow> is_float_nonneg (b - a)"
   479   by transfer (simp add: field_simps)
   480 hide_fact (open) compute_float_le
   481 
   482 lift_definition is_float_zero :: "float \<Rightarrow> bool"  is "op = 0 :: real \<Rightarrow> bool" by simp
   483 
   484 lemma compute_is_float_zero[code]: "is_float_zero (Float m e) \<longleftrightarrow> 0 = m"
   485   by transfer (auto simp add: is_float_zero_def)
   486 hide_fact (open) compute_is_float_zero
   487 
   488 lemma compute_float_abs[code]: "abs (Float m e) = Float (abs m) e"
   489   by transfer (simp add: abs_mult)
   490 hide_fact (open) compute_float_abs
   491 
   492 lemma compute_float_eq[code]: "equal_class.equal f g = is_float_zero (f - g)"
   493   by transfer simp
   494 hide_fact (open) compute_float_eq
   495 
   496 subsection {* Rounding Real numbers *}
   497 
   498 definition round_down :: "int \<Rightarrow> real \<Rightarrow> real" where
   499   "round_down prec x = floor (x * 2 powr prec) * 2 powr -prec"
   500 
   501 definition round_up :: "int \<Rightarrow> real \<Rightarrow> real" where
   502   "round_up prec x = ceiling (x * 2 powr prec) * 2 powr -prec"
   503 
   504 lemma round_down_float[simp]: "round_down prec x \<in> float"
   505   unfolding round_down_def
   506   by (auto intro!: times_float simp: real_of_int_minus[symmetric] simp del: real_of_int_minus)
   507 
   508 lemma round_up_float[simp]: "round_up prec x \<in> float"
   509   unfolding round_up_def
   510   by (auto intro!: times_float simp: real_of_int_minus[symmetric] simp del: real_of_int_minus)
   511 
   512 lemma round_up: "x \<le> round_up prec x"
   513   by (simp add: powr_minus_divide le_divide_eq round_up_def)
   514 
   515 lemma round_down: "round_down prec x \<le> x"
   516   by (simp add: powr_minus_divide divide_le_eq round_down_def)
   517 
   518 lemma round_up_0[simp]: "round_up p 0 = 0"
   519   unfolding round_up_def by simp
   520 
   521 lemma round_down_0[simp]: "round_down p 0 = 0"
   522   unfolding round_down_def by simp
   523 
   524 lemma round_up_diff_round_down:
   525   "round_up prec x - round_down prec x \<le> 2 powr -prec"
   526 proof -
   527   have "round_up prec x - round_down prec x =
   528     (ceiling (x * 2 powr prec) - floor (x * 2 powr prec)) * 2 powr -prec"
   529     by (simp add: round_up_def round_down_def field_simps)
   530   also have "\<dots> \<le> 1 * 2 powr -prec"
   531     by (rule mult_mono)
   532        (auto simp del: real_of_int_diff
   533              simp: real_of_int_diff[symmetric] real_of_int_le_one_cancel_iff ceiling_diff_floor_le_1)
   534   finally show ?thesis by simp
   535 qed
   536 
   537 lemma round_down_shift: "round_down p (x * 2 powr k) = 2 powr k * round_down (p + k) x"
   538   unfolding round_down_def
   539   by (simp add: powr_add powr_mult field_simps powr_divide2[symmetric])
   540     (simp add: powr_add[symmetric])
   541 
   542 lemma round_up_shift: "round_up p (x * 2 powr k) = 2 powr k * round_up (p + k) x"
   543   unfolding round_up_def
   544   by (simp add: powr_add powr_mult field_simps powr_divide2[symmetric])
   545     (simp add: powr_add[symmetric])
   546 
   547 subsection {* Rounding Floats *}
   548 
   549 lift_definition float_up :: "int \<Rightarrow> float \<Rightarrow> float" is round_up by simp
   550 declare float_up.rep_eq[simp]
   551 
   552 lemma float_up_correct:
   553   shows "real (float_up e f) - real f \<in> {0..2 powr -e}"
   554 unfolding atLeastAtMost_iff
   555 proof
   556   have "round_up e f - f \<le> round_up e f - round_down e f" using round_down by simp
   557   also have "\<dots> \<le> 2 powr -e" using round_up_diff_round_down by simp
   558   finally show "real (float_up e f) - real f \<le> 2 powr real (- e)"
   559     by simp
   560 qed (simp add: algebra_simps round_up)
   561 
   562 lift_definition float_down :: "int \<Rightarrow> float \<Rightarrow> float" is round_down by simp
   563 declare float_down.rep_eq[simp]
   564 
   565 lemma float_down_correct:
   566   shows "real f - real (float_down e f) \<in> {0..2 powr -e}"
   567 unfolding atLeastAtMost_iff
   568 proof
   569   have "f - round_down e f \<le> round_up e f - round_down e f" using round_up by simp
   570   also have "\<dots> \<le> 2 powr -e" using round_up_diff_round_down by simp
   571   finally show "real f - real (float_down e f) \<le> 2 powr real (- e)"
   572     by simp
   573 qed (simp add: algebra_simps round_down)
   574 
   575 lemma compute_float_down[code]:
   576   "float_down p (Float m e) =
   577     (if p + e < 0 then Float (m div 2^nat (-(p + e))) (-p) else Float m e)"
   578 proof cases
   579   assume "p + e < 0"
   580   hence "real ((2::int) ^ nat (-(p + e))) = 2 powr (-(p + e))"
   581     using powr_realpow[of 2 "nat (-(p + e))"] by simp
   582   also have "... = 1 / 2 powr p / 2 powr e"
   583     unfolding powr_minus_divide real_of_int_minus by (simp add: powr_add)
   584   finally show ?thesis
   585     using `p + e < 0`
   586     by transfer (simp add: ac_simps round_down_def floor_divide_eq_div[symmetric])
   587 next
   588   assume "\<not> p + e < 0"
   589   then have r: "real e + real p = real (nat (e + p))" by simp
   590   have r: "\<lfloor>(m * 2 powr e) * 2 powr real p\<rfloor> = (m * 2 powr e) * 2 powr real p"
   591     by (auto intro: exI[where x="m*2^nat (e+p)"]
   592              simp add: ac_simps powr_add[symmetric] r powr_realpow)
   593   with `\<not> p + e < 0` show ?thesis
   594     by transfer
   595        (auto simp add: round_down_def field_simps powr_add powr_minus inverse_eq_divide)
   596 qed
   597 hide_fact (open) compute_float_down
   598 
   599 lemma ceil_divide_floor_conv:
   600 assumes "b \<noteq> 0"
   601 shows "\<lceil>real a / real b\<rceil> = (if b dvd a then a div b else \<lfloor>real a / real b\<rfloor> + 1)"
   602 proof cases
   603   assume "\<not> b dvd a"
   604   hence "a mod b \<noteq> 0" by auto
   605   hence ne: "real (a mod b) / real b \<noteq> 0" using `b \<noteq> 0` by auto
   606   have "\<lceil>real a / real b\<rceil> = \<lfloor>real a / real b\<rfloor> + 1"
   607   apply (rule ceiling_eq) apply (auto simp: floor_divide_eq_div[symmetric])
   608   proof -
   609     have "real \<lfloor>real a / real b\<rfloor> \<le> real a / real b" by simp
   610     moreover have "real \<lfloor>real a / real b\<rfloor> \<noteq> real a / real b"
   611     apply (subst (2) real_of_int_div_aux) unfolding floor_divide_eq_div using ne `b \<noteq> 0` by auto
   612     ultimately show "real \<lfloor>real a / real b\<rfloor> < real a / real b" by arith
   613   qed
   614   thus ?thesis using `\<not> b dvd a` by simp
   615 qed (simp add: ceiling_def real_of_int_minus[symmetric] divide_minus_left[symmetric]
   616   floor_divide_eq_div dvd_neg_div del: divide_minus_left real_of_int_minus)
   617 
   618 lemma compute_float_up[code]:
   619   "float_up p (Float m e) =
   620     (let P = 2^nat (-(p + e)); r = m mod P in
   621       if p + e < 0 then Float (m div P + (if r = 0 then 0 else 1)) (-p) else Float m e)"
   622 proof cases
   623   assume "p + e < 0"
   624   hence "real ((2::int) ^ nat (-(p + e))) = 2 powr (-(p + e))"
   625     using powr_realpow[of 2 "nat (-(p + e))"] by simp
   626   also have "... = 1 / 2 powr p / 2 powr e"
   627   unfolding powr_minus_divide real_of_int_minus by (simp add: powr_add)
   628   finally have twopow_rewrite:
   629     "real ((2::int) ^ nat (- (p + e))) = 1 / 2 powr real p / 2 powr real e" .
   630   with `p + e < 0` have powr_rewrite:
   631     "2 powr real e * 2 powr real p = 1 / real ((2::int) ^ nat (- (p + e)))"
   632     unfolding powr_divide2 by simp
   633   show ?thesis
   634   proof cases
   635     assume "2^nat (-(p + e)) dvd m"
   636     with `p + e < 0` twopow_rewrite show ?thesis
   637       by transfer (auto simp: ac_simps round_up_def floor_divide_eq_div dvd_eq_mod_eq_0)
   638   next
   639     assume ndvd: "\<not> 2 ^ nat (- (p + e)) dvd m"
   640     have one_div: "real m * (1 / real ((2::int) ^ nat (- (p + e)))) =
   641       real m / real ((2::int) ^ nat (- (p + e)))"
   642       by (simp add: field_simps)
   643     have "real \<lceil>real m * (2 powr real e * 2 powr real p)\<rceil> =
   644       real \<lfloor>real m * (2 powr real e * 2 powr real p)\<rfloor> + 1"
   645       using ndvd unfolding powr_rewrite one_div
   646       by (subst ceil_divide_floor_conv) (auto simp: field_simps)
   647     thus ?thesis using `p + e < 0` twopow_rewrite
   648       by transfer (auto simp: ac_simps round_up_def floor_divide_eq_div[symmetric])
   649   qed
   650 next
   651   assume "\<not> p + e < 0"
   652   then have r1: "real e + real p = real (nat (e + p))" by simp
   653   have r: "\<lceil>(m * 2 powr e) * 2 powr real p\<rceil> = (m * 2 powr e) * 2 powr real p"
   654     by (auto simp add: ac_simps powr_add[symmetric] r1 powr_realpow
   655       intro: exI[where x="m*2^nat (e+p)"])
   656   then show ?thesis using `\<not> p + e < 0`
   657     by transfer
   658        (simp add: round_up_def floor_divide_eq_div field_simps powr_add powr_minus inverse_eq_divide)
   659 qed
   660 hide_fact (open) compute_float_up
   661 
   662 lemmas real_of_ints =
   663   real_of_int_zero
   664   real_of_one
   665   real_of_int_add
   666   real_of_int_minus
   667   real_of_int_diff
   668   real_of_int_mult
   669   real_of_int_power
   670   real_numeral
   671 lemmas real_of_nats =
   672   real_of_nat_zero
   673   real_of_nat_one
   674   real_of_nat_1
   675   real_of_nat_add
   676   real_of_nat_mult
   677   real_of_nat_power
   678 
   679 lemmas int_of_reals = real_of_ints[symmetric]
   680 lemmas nat_of_reals = real_of_nats[symmetric]
   681 
   682 lemma two_real_int: "(2::real) = real (2::int)" by simp
   683 lemma two_real_nat: "(2::real) = real (2::nat)" by simp
   684 
   685 lemma mult_cong: "a = c ==> b = d ==> a*b = c*d" by simp
   686 
   687 subsection {* Compute bitlen of integers *}
   688 
   689 definition bitlen :: "int \<Rightarrow> int" where
   690   "bitlen a = (if a > 0 then \<lfloor>log 2 a\<rfloor> + 1 else 0)"
   691 
   692 lemma bitlen_nonneg: "0 \<le> bitlen x"
   693 proof -
   694   {
   695     assume "0 > x"
   696     have "-1 = log 2 (inverse 2)" by (subst log_inverse) simp_all
   697     also have "... < log 2 (-x)" using `0 > x` by auto
   698     finally have "-1 < log 2 (-x)" .
   699   } thus "0 \<le> bitlen x" unfolding bitlen_def by (auto intro!: add_nonneg_nonneg)
   700 qed
   701 
   702 lemma bitlen_bounds:
   703   assumes "x > 0"
   704   shows "2 ^ nat (bitlen x - 1) \<le> x \<and> x < 2 ^ nat (bitlen x)"
   705 proof
   706   have "(2::real) ^ nat \<lfloor>log 2 (real x)\<rfloor> = 2 powr real (floor (log 2 (real x)))"
   707     using powr_realpow[symmetric, of 2 "nat \<lfloor>log 2 (real x)\<rfloor>"] `x > 0`
   708     using real_nat_eq_real[of "floor (log 2 (real x))"]
   709     by simp
   710   also have "... \<le> 2 powr log 2 (real x)"
   711     by simp
   712   also have "... = real x"
   713     using `0 < x` by simp
   714   finally have "2 ^ nat \<lfloor>log 2 (real x)\<rfloor> \<le> real x" by simp
   715   thus "2 ^ nat (bitlen x - 1) \<le> x" using `x > 0`
   716     by (simp add: bitlen_def)
   717 next
   718   have "x \<le> 2 powr (log 2 x)" using `x > 0` by simp
   719   also have "... < 2 ^ nat (\<lfloor>log 2 (real x)\<rfloor> + 1)"
   720     apply (simp add: powr_realpow[symmetric])
   721     using `x > 0` by simp
   722   finally show "x < 2 ^ nat (bitlen x)" using `x > 0`
   723     by (simp add: bitlen_def ac_simps int_of_reals del: real_of_ints)
   724 qed
   725 
   726 lemma bitlen_pow2[simp]:
   727   assumes "b > 0"
   728   shows "bitlen (b * 2 ^ c) = bitlen b + c"
   729 proof -
   730   from assms have "b * 2 ^ c > 0" by (auto intro: mult_pos_pos)
   731   thus ?thesis
   732     using floor_add[of "log 2 b" c] assms
   733     by (auto simp add: log_mult log_nat_power bitlen_def)
   734 qed
   735 
   736 lemma bitlen_Float:
   737 fixes m e
   738 defines "f \<equiv> Float m e"
   739 shows "bitlen (\<bar>mantissa f\<bar>) + exponent f = (if m = 0 then 0 else bitlen \<bar>m\<bar> + e)"
   740 proof cases
   741   assume "m \<noteq> 0"
   742   hence "f \<noteq> float_of 0"
   743     unfolding real_of_float_eq by (simp add: f_def)
   744   hence "mantissa f \<noteq> 0"
   745     by (simp add: mantissa_noteq_0)
   746   moreover
   747   from f_def[THEN denormalize_shift, OF `f \<noteq> float_of 0`] guess i .
   748   ultimately show ?thesis by (simp add: abs_mult)
   749 qed (simp add: f_def bitlen_def Float_def)
   750 
   751 lemma compute_bitlen[code]:
   752   shows "bitlen x = (if x > 0 then bitlen (x div 2) + 1 else 0)"
   753 proof -
   754   { assume "2 \<le> x"
   755     then have "\<lfloor>log 2 (x div 2)\<rfloor> + 1 = \<lfloor>log 2 (x - x mod 2)\<rfloor>"
   756       by (simp add: log_mult zmod_zdiv_equality')
   757     also have "\<dots> = \<lfloor>log 2 (real x)\<rfloor>"
   758     proof cases
   759       assume "x mod 2 = 0" then show ?thesis by simp
   760     next
   761       def n \<equiv> "\<lfloor>log 2 (real x)\<rfloor>"
   762       then have "0 \<le> n"
   763         using `2 \<le> x` by simp
   764       assume "x mod 2 \<noteq> 0"
   765       with `2 \<le> x` have "x mod 2 = 1" "\<not> 2 dvd x" by (auto simp add: dvd_eq_mod_eq_0)
   766       with `2 \<le> x` have "x \<noteq> 2^nat n" by (cases "nat n") auto
   767       moreover
   768       { have "real (2^nat n :: int) = 2 powr (nat n)"
   769           by (simp add: powr_realpow)
   770         also have "\<dots> \<le> 2 powr (log 2 x)"
   771           using `2 \<le> x` by (simp add: n_def del: powr_log_cancel)
   772         finally have "2^nat n \<le> x" using `2 \<le> x` by simp }
   773       ultimately have "2^nat n \<le> x - 1" by simp
   774       then have "2^nat n \<le> real (x - 1)"
   775         unfolding real_of_int_le_iff[symmetric] by simp
   776       { have "n = \<lfloor>log 2 (2^nat n)\<rfloor>"
   777           using `0 \<le> n` by (simp add: log_nat_power)
   778         also have "\<dots> \<le> \<lfloor>log 2 (x - 1)\<rfloor>"
   779           using `2^nat n \<le> real (x - 1)` `0 \<le> n` `2 \<le> x` by (auto intro: floor_mono)
   780         finally have "n \<le> \<lfloor>log 2 (x - 1)\<rfloor>" . }
   781       moreover have "\<lfloor>log 2 (x - 1)\<rfloor> \<le> n"
   782         using `2 \<le> x` by (auto simp add: n_def intro!: floor_mono)
   783       ultimately show "\<lfloor>log 2 (x - x mod 2)\<rfloor> = \<lfloor>log 2 x\<rfloor>"
   784         unfolding n_def `x mod 2 = 1` by auto
   785     qed
   786     finally have "\<lfloor>log 2 (x div 2)\<rfloor> + 1 = \<lfloor>log 2 x\<rfloor>" . }
   787   moreover
   788   { assume "x < 2" "0 < x"
   789     then have "x = 1" by simp
   790     then have "\<lfloor>log 2 (real x)\<rfloor> = 0" by simp }
   791   ultimately show ?thesis
   792     unfolding bitlen_def
   793     by (auto simp: pos_imp_zdiv_pos_iff not_le)
   794 qed
   795 hide_fact (open) compute_bitlen
   796 
   797 lemma float_gt1_scale: assumes "1 \<le> Float m e"
   798   shows "0 \<le> e + (bitlen m - 1)"
   799 proof -
   800   have "0 < Float m e" using assms by auto
   801   hence "0 < m" using powr_gt_zero[of 2 e]
   802     by (auto simp: zero_less_mult_iff)
   803   hence "m \<noteq> 0" by auto
   804   show ?thesis
   805   proof (cases "0 \<le> e")
   806     case True thus ?thesis using `0 < m`  by (simp add: bitlen_def)
   807   next
   808     have "(1::int) < 2" by simp
   809     case False let ?S = "2^(nat (-e))"
   810     have "inverse (2 ^ nat (- e)) = 2 powr e" using assms False powr_realpow[of 2 "nat (-e)"]
   811       by (auto simp: powr_minus field_simps inverse_eq_divide)
   812     hence "1 \<le> real m * inverse ?S" using assms False powr_realpow[of 2 "nat (-e)"]
   813       by (auto simp: powr_minus)
   814     hence "1 * ?S \<le> real m * inverse ?S * ?S" by (rule mult_right_mono, auto)
   815     hence "?S \<le> real m" unfolding mult_assoc by auto
   816     hence "?S \<le> m" unfolding real_of_int_le_iff[symmetric] by auto
   817     from this bitlen_bounds[OF `0 < m`, THEN conjunct2]
   818     have "nat (-e) < (nat (bitlen m))" unfolding power_strict_increasing_iff[OF `1 < 2`, symmetric] by (rule order_le_less_trans)
   819     hence "-e < bitlen m" using False by auto
   820     thus ?thesis by auto
   821   qed
   822 qed
   823 
   824 lemma bitlen_div: assumes "0 < m" shows "1 \<le> real m / 2^nat (bitlen m - 1)" and "real m / 2^nat (bitlen m - 1) < 2"
   825 proof -
   826   let ?B = "2^nat(bitlen m - 1)"
   827 
   828   have "?B \<le> m" using bitlen_bounds[OF `0 <m`] ..
   829   hence "1 * ?B \<le> real m" unfolding real_of_int_le_iff[symmetric] by auto
   830   thus "1 \<le> real m / ?B" by auto
   831 
   832   have "m \<noteq> 0" using assms by auto
   833   have "0 \<le> bitlen m - 1" using `0 < m` by (auto simp: bitlen_def)
   834 
   835   have "m < 2^nat(bitlen m)" using bitlen_bounds[OF `0 <m`] ..
   836   also have "\<dots> = 2^nat(bitlen m - 1 + 1)" using `0 < m` by (auto simp: bitlen_def)
   837   also have "\<dots> = ?B * 2" unfolding nat_add_distrib[OF `0 \<le> bitlen m - 1` zero_le_one] by auto
   838   finally have "real m < 2 * ?B" unfolding real_of_int_less_iff[symmetric] by auto
   839   hence "real m / ?B < 2 * ?B / ?B" by (rule divide_strict_right_mono, auto)
   840   thus "real m / ?B < 2" by auto
   841 qed
   842 
   843 subsection {* Approximation of positive rationals *}
   844 
   845 lemma zdiv_zmult_twopow_eq: fixes a b::int shows "a div b div (2 ^ n) = a div (b * 2 ^ n)"
   846 by (simp add: zdiv_zmult2_eq)
   847 
   848 lemma div_mult_twopow_eq: fixes a b::nat shows "a div ((2::nat) ^ n) div b = a div (b * 2 ^ n)"
   849   by (cases "b=0") (simp_all add: div_mult2_eq[symmetric] ac_simps)
   850 
   851 lemma real_div_nat_eq_floor_of_divide:
   852   fixes a b::nat
   853   shows "a div b = real (floor (a/b))"
   854 by (metis floor_divide_eq_div real_of_int_of_nat_eq zdiv_int)
   855 
   856 definition "rat_precision prec x y = int prec - (bitlen x - bitlen y)"
   857 
   858 lift_definition lapprox_posrat :: "nat \<Rightarrow> nat \<Rightarrow> nat \<Rightarrow> float"
   859   is "\<lambda>prec (x::nat) (y::nat). round_down (rat_precision prec x y) (x / y)" by simp
   860 
   861 lemma compute_lapprox_posrat[code]:
   862   fixes prec x y 
   863   shows "lapprox_posrat prec x y = 
   864    (let 
   865        l = rat_precision prec x y;
   866        d = if 0 \<le> l then x * 2^nat l div y else x div 2^nat (- l) div y
   867     in normfloat (Float d (- l)))"
   868     unfolding div_mult_twopow_eq normfloat_def
   869     by transfer
   870        (simp add: round_down_def powr_int real_div_nat_eq_floor_of_divide field_simps Let_def
   871              del: two_powr_minus_int_float)
   872 hide_fact (open) compute_lapprox_posrat
   873 
   874 lift_definition rapprox_posrat :: "nat \<Rightarrow> nat \<Rightarrow> nat \<Rightarrow> float"
   875   is "\<lambda>prec (x::nat) (y::nat). round_up (rat_precision prec x y) (x / y)" by simp
   876 
   877 (* TODO: optimize using zmod_zmult2_eq, pdivmod ? *)
   878 lemma compute_rapprox_posrat[code]:
   879   fixes prec x y
   880   defines "l \<equiv> rat_precision prec x y"
   881   shows "rapprox_posrat prec x y = (let
   882      l = l ;
   883      X = if 0 \<le> l then (x * 2^nat l, y) else (x, y * 2^nat(-l)) ;
   884      d = fst X div snd X ;
   885      m = fst X mod snd X
   886    in normfloat (Float (d + (if m = 0 \<or> y = 0 then 0 else 1)) (- l)))"
   887 proof (cases "y = 0")
   888   assume "y = 0" thus ?thesis unfolding normfloat_def by transfer simp
   889 next
   890   assume "y \<noteq> 0"
   891   show ?thesis
   892   proof (cases "0 \<le> l")
   893     assume "0 \<le> l"
   894     def x' == "x * 2 ^ nat l"
   895     have "int x * 2 ^ nat l = x'" by (simp add: x'_def int_mult int_power)
   896     moreover have "real x * 2 powr real l = real x'"
   897       by (simp add: powr_realpow[symmetric] `0 \<le> l` x'_def)
   898     ultimately show ?thesis
   899       unfolding normfloat_def
   900       using ceil_divide_floor_conv[of y x'] powr_realpow[of 2 "nat l"] `0 \<le> l` `y \<noteq> 0`
   901         l_def[symmetric, THEN meta_eq_to_obj_eq]
   902       by transfer
   903          (simp add: floor_divide_eq_div[symmetric] dvd_eq_mod_eq_0 round_up_def)
   904    next
   905     assume "\<not> 0 \<le> l"
   906     def y' == "y * 2 ^ nat (- l)"
   907     from `y \<noteq> 0` have "y' \<noteq> 0" by (simp add: y'_def)
   908     have "int y * 2 ^ nat (- l) = y'" by (simp add: y'_def int_mult int_power)
   909     moreover have "real x * real (2::int) powr real l / real y = x / real y'"
   910       using `\<not> 0 \<le> l`
   911       by (simp add: powr_realpow[symmetric] powr_minus y'_def field_simps inverse_eq_divide)
   912     ultimately show ?thesis
   913       unfolding normfloat_def
   914       using ceil_divide_floor_conv[of y' x] `\<not> 0 \<le> l` `y' \<noteq> 0` `y \<noteq> 0`
   915         l_def[symmetric, THEN meta_eq_to_obj_eq]
   916       by transfer
   917          (simp add: round_up_def ceil_divide_floor_conv floor_divide_eq_div[symmetric] dvd_eq_mod_eq_0)
   918   qed
   919 qed
   920 hide_fact (open) compute_rapprox_posrat
   921 
   922 lemma rat_precision_pos:
   923   assumes "0 \<le> x" and "0 < y" and "2 * x < y" and "0 < n"
   924   shows "rat_precision n (int x) (int y) > 0"
   925 proof -
   926   { assume "0 < x" hence "log 2 x + 1 = log 2 (2 * x)" by (simp add: log_mult) }
   927   hence "bitlen (int x) < bitlen (int y)" using assms
   928     by (simp add: bitlen_def del: floor_add_one)
   929       (auto intro!: floor_mono simp add: floor_add_one[symmetric] simp del: floor_add floor_add_one)
   930   thus ?thesis
   931     using assms by (auto intro!: pos_add_strict simp add: field_simps rat_precision_def)
   932 qed
   933 
   934 lemma power_aux: assumes "x > 0" shows "(2::int) ^ nat (x - 1) \<le> 2 ^ nat x - 1"
   935 proof -
   936   def y \<equiv> "nat (x - 1)" moreover
   937   have "(2::int) ^ y \<le> (2 ^ (y + 1)) - 1" by simp
   938   ultimately show ?thesis using assms by simp
   939 qed
   940 
   941 lemma rapprox_posrat_less1:
   942   assumes "0 \<le> x" and "0 < y" and "2 * x < y" and "0 < n"
   943   shows "real (rapprox_posrat n x y) < 1"
   944 proof -
   945   have powr1: "2 powr real (rat_precision n (int x) (int y)) = 
   946     2 ^ nat (rat_precision n (int x) (int y))" using rat_precision_pos[of x y n] assms
   947     by (simp add: powr_realpow[symmetric])
   948   have "x * 2 powr real (rat_precision n (int x) (int y)) / y = (x / y) *
   949      2 powr real (rat_precision n (int x) (int y))" by simp
   950   also have "... < (1 / 2) * 2 powr real (rat_precision n (int x) (int y))"
   951     apply (rule mult_strict_right_mono) by (insert assms) auto
   952   also have "\<dots> = 2 powr real (rat_precision n (int x) (int y) - 1)"
   953     by (simp add: powr_add diff_def powr_neg_numeral)
   954   also have "\<dots> = 2 ^ nat (rat_precision n (int x) (int y) - 1)"
   955     using rat_precision_pos[of x y n] assms by (simp add: powr_realpow[symmetric])
   956   also have "\<dots> \<le> 2 ^ nat (rat_precision n (int x) (int y)) - 1"
   957     unfolding int_of_reals real_of_int_le_iff
   958     using rat_precision_pos[OF assms] by (rule power_aux)
   959   finally show ?thesis
   960     apply (transfer fixing: n x y)
   961     apply (simp add: round_up_def field_simps powr_minus inverse_eq_divide powr1)
   962     unfolding int_of_reals real_of_int_less_iff
   963     apply (simp add: ceiling_less_eq)
   964     done
   965 qed
   966 
   967 lift_definition lapprox_rat :: "nat \<Rightarrow> int \<Rightarrow> int \<Rightarrow> float" is
   968   "\<lambda>prec (x::int) (y::int). round_down (rat_precision prec \<bar>x\<bar> \<bar>y\<bar>) (x / y)" by simp
   969 
   970 lemma compute_lapprox_rat[code]:
   971   "lapprox_rat prec x y =
   972     (if y = 0 then 0
   973     else if 0 \<le> x then
   974       (if 0 < y then lapprox_posrat prec (nat x) (nat y)
   975       else - (rapprox_posrat prec (nat x) (nat (-y)))) 
   976       else (if 0 < y
   977         then - (rapprox_posrat prec (nat (-x)) (nat y))
   978         else lapprox_posrat prec (nat (-x)) (nat (-y))))"
   979   by transfer (auto simp: round_up_def round_down_def ceiling_def ac_simps)
   980 hide_fact (open) compute_lapprox_rat
   981 
   982 lift_definition rapprox_rat :: "nat \<Rightarrow> int \<Rightarrow> int \<Rightarrow> float" is
   983   "\<lambda>prec (x::int) (y::int). round_up (rat_precision prec \<bar>x\<bar> \<bar>y\<bar>) (x / y)" by simp
   984 
   985 lemma compute_rapprox_rat[code]:
   986   "rapprox_rat prec x y =
   987     (if y = 0 then 0
   988     else if 0 \<le> x then
   989       (if 0 < y then rapprox_posrat prec (nat x) (nat y)
   990       else - (lapprox_posrat prec (nat x) (nat (-y)))) 
   991       else (if 0 < y
   992         then - (lapprox_posrat prec (nat (-x)) (nat y))
   993         else rapprox_posrat prec (nat (-x)) (nat (-y))))"
   994   by transfer (auto simp: round_up_def round_down_def ceiling_def ac_simps)
   995 hide_fact (open) compute_rapprox_rat
   996 
   997 subsection {* Division *}
   998 
   999 lift_definition float_divl :: "nat \<Rightarrow> float \<Rightarrow> float \<Rightarrow> float" is
  1000   "\<lambda>(prec::nat) a b. round_down (prec + \<lfloor> log 2 \<bar>b\<bar> \<rfloor> - \<lfloor> log 2 \<bar>a\<bar> \<rfloor>) (a / b)" by simp
  1001 
  1002 lemma compute_float_divl[code]:
  1003   "float_divl prec (Float m1 s1) (Float m2 s2) = lapprox_rat prec m1 m2 * Float 1 (s1 - s2)"
  1004 proof cases
  1005   let ?f1 = "real m1 * 2 powr real s1" and ?f2 = "real m2 * 2 powr real s2"
  1006   let ?m = "real m1 / real m2" and ?s = "2 powr real (s1 - s2)"
  1007   assume not_0: "m1 \<noteq> 0 \<and> m2 \<noteq> 0"
  1008   then have eq2: "(int prec + \<lfloor>log 2 \<bar>?f2\<bar>\<rfloor> - \<lfloor>log 2 \<bar>?f1\<bar>\<rfloor>) = rat_precision prec \<bar>m1\<bar> \<bar>m2\<bar> + (s2 - s1)"
  1009     by (simp add: abs_mult log_mult rat_precision_def bitlen_def)
  1010   have eq1: "real m1 * 2 powr real s1 / (real m2 * 2 powr real s2) = ?m * ?s"
  1011     by (simp add: field_simps powr_divide2[symmetric])
  1012 
  1013   show ?thesis
  1014     using not_0 
  1015     by (transfer fixing: m1 s1 m2 s2 prec) (unfold eq1 eq2 round_down_shift, simp add: field_simps)
  1016 qed (transfer, auto)
  1017 hide_fact (open) compute_float_divl
  1018 
  1019 lift_definition float_divr :: "nat \<Rightarrow> float \<Rightarrow> float \<Rightarrow> float" is
  1020   "\<lambda>(prec::nat) a b. round_up (prec + \<lfloor> log 2 \<bar>b\<bar> \<rfloor> - \<lfloor> log 2 \<bar>a\<bar> \<rfloor>) (a / b)" by simp
  1021 
  1022 lemma compute_float_divr[code]:
  1023   "float_divr prec (Float m1 s1) (Float m2 s2) = rapprox_rat prec m1 m2 * Float 1 (s1 - s2)"
  1024 proof cases
  1025   let ?f1 = "real m1 * 2 powr real s1" and ?f2 = "real m2 * 2 powr real s2"
  1026   let ?m = "real m1 / real m2" and ?s = "2 powr real (s1 - s2)"
  1027   assume not_0: "m1 \<noteq> 0 \<and> m2 \<noteq> 0"
  1028   then have eq2: "(int prec + \<lfloor>log 2 \<bar>?f2\<bar>\<rfloor> - \<lfloor>log 2 \<bar>?f1\<bar>\<rfloor>) = rat_precision prec \<bar>m1\<bar> \<bar>m2\<bar> + (s2 - s1)"
  1029     by (simp add: abs_mult log_mult rat_precision_def bitlen_def)
  1030   have eq1: "real m1 * 2 powr real s1 / (real m2 * 2 powr real s2) = ?m * ?s"
  1031     by (simp add: field_simps powr_divide2[symmetric])
  1032 
  1033   show ?thesis
  1034     using not_0 
  1035     by (transfer fixing: m1 s1 m2 s2 prec) (unfold eq1 eq2 round_up_shift, simp add: field_simps)
  1036 qed (transfer, auto)
  1037 hide_fact (open) compute_float_divr
  1038 
  1039 subsection {* Lemmas needed by Approximate *}
  1040 
  1041 lemma Float_num[simp]: shows
  1042    "real (Float 1 0) = 1" and "real (Float 1 1) = 2" and "real (Float 1 2) = 4" and
  1043    "real (Float 1 -1) = 1/2" and "real (Float 1 -2) = 1/4" and "real (Float 1 -3) = 1/8" and
  1044    "real (Float -1 0) = -1" and "real (Float (number_of n) 0) = number_of n"
  1045 using two_powr_int_float[of 2] two_powr_int_float[of "-1"] two_powr_int_float[of "-2"] two_powr_int_float[of "-3"]
  1046 using powr_realpow[of 2 2] powr_realpow[of 2 3]
  1047 using powr_minus[of 2 1] powr_minus[of 2 2] powr_minus[of 2 3]
  1048 by auto
  1049 
  1050 lemma real_of_Float_int[simp]: "real (Float n 0) = real n" by simp
  1051 
  1052 lemma float_zero[simp]: "real (Float 0 e) = 0" by simp
  1053 
  1054 lemma abs_div_2_less: "a \<noteq> 0 \<Longrightarrow> a \<noteq> -1 \<Longrightarrow> abs((a::int) div 2) < abs a"
  1055 by arith
  1056 
  1057 lemma lapprox_rat:
  1058   shows "real (lapprox_rat prec x y) \<le> real x / real y"
  1059   using round_down by (simp add: lapprox_rat_def)
  1060 
  1061 lemma mult_div_le: fixes a b:: int assumes "b > 0" shows "a \<ge> b * (a div b)"
  1062 proof -
  1063   from zmod_zdiv_equality'[of a b]
  1064   have "a = b * (a div b) + a mod b" by simp
  1065   also have "... \<ge> b * (a div b) + 0" apply (rule add_left_mono) apply (rule pos_mod_sign)
  1066   using assms by simp
  1067   finally show ?thesis by simp
  1068 qed
  1069 
  1070 lemma lapprox_rat_nonneg:
  1071   fixes n x y
  1072   defines "p == int n - ((bitlen \<bar>x\<bar>) - (bitlen \<bar>y\<bar>))"
  1073   assumes "0 \<le> x" "0 < y"
  1074   shows "0 \<le> real (lapprox_rat n x y)"
  1075 using assms unfolding lapprox_rat_def p_def[symmetric] round_down_def real_of_int_minus[symmetric]
  1076    powr_int[of 2, simplified]
  1077   by (auto simp add: inverse_eq_divide intro!: mult_nonneg_nonneg divide_nonneg_pos mult_pos_pos)
  1078 
  1079 lemma rapprox_rat: "real x / real y \<le> real (rapprox_rat prec x y)"
  1080   using round_up by (simp add: rapprox_rat_def)
  1081 
  1082 lemma rapprox_rat_le1:
  1083   fixes n x y
  1084   assumes xy: "0 \<le> x" "0 < y" "x \<le> y"
  1085   shows "real (rapprox_rat n x y) \<le> 1"
  1086 proof -
  1087   have "bitlen \<bar>x\<bar> \<le> bitlen \<bar>y\<bar>"
  1088     using xy unfolding bitlen_def by (auto intro!: floor_mono)
  1089   then have "0 \<le> rat_precision n \<bar>x\<bar> \<bar>y\<bar>" by (simp add: rat_precision_def)
  1090   have "real \<lceil>real x / real y * 2 powr real (rat_precision n \<bar>x\<bar> \<bar>y\<bar>)\<rceil>
  1091       \<le> real \<lceil>2 powr real (rat_precision n \<bar>x\<bar> \<bar>y\<bar>)\<rceil>"
  1092     using xy by (auto intro!: ceiling_mono simp: field_simps)
  1093   also have "\<dots> = 2 powr real (rat_precision n \<bar>x\<bar> \<bar>y\<bar>)"
  1094     using `0 \<le> rat_precision n \<bar>x\<bar> \<bar>y\<bar>`
  1095     by (auto intro!: exI[of _ "2^nat (rat_precision n \<bar>x\<bar> \<bar>y\<bar>)"] simp: powr_int)
  1096   finally show ?thesis
  1097     by (simp add: rapprox_rat_def round_up_def)
  1098        (simp add: powr_minus inverse_eq_divide)
  1099 qed
  1100 
  1101 lemma rapprox_rat_nonneg_neg: 
  1102   "0 \<le> x \<Longrightarrow> y < 0 \<Longrightarrow> real (rapprox_rat n x y) \<le> 0"
  1103   unfolding rapprox_rat_def round_up_def
  1104   by (auto simp: field_simps mult_le_0_iff zero_le_mult_iff)
  1105 
  1106 lemma rapprox_rat_neg:
  1107   "x < 0 \<Longrightarrow> 0 < y \<Longrightarrow> real (rapprox_rat n x y) \<le> 0"
  1108   unfolding rapprox_rat_def round_up_def
  1109   by (auto simp: field_simps mult_le_0_iff)
  1110 
  1111 lemma rapprox_rat_nonpos_pos:
  1112   "x \<le> 0 \<Longrightarrow> 0 < y \<Longrightarrow> real (rapprox_rat n x y) \<le> 0"
  1113   unfolding rapprox_rat_def round_up_def
  1114   by (auto simp: field_simps mult_le_0_iff)
  1115 
  1116 lemma float_divl: "real (float_divl prec x y) \<le> real x / real y"
  1117   by transfer (simp add: round_down)
  1118 
  1119 lemma float_divl_lower_bound:
  1120   "0 \<le> x \<Longrightarrow> 0 < y \<Longrightarrow> 0 \<le> real (float_divl prec x y)"
  1121   by transfer (simp add: round_down_def zero_le_mult_iff zero_le_divide_iff)
  1122 
  1123 lemma exponent_1: "exponent 1 = 0"
  1124   using exponent_float[of 1 0] by (simp add: one_float_def)
  1125 
  1126 lemma mantissa_1: "mantissa 1 = 1"
  1127   using mantissa_float[of 1 0] by (simp add: one_float_def)
  1128 
  1129 lemma bitlen_1: "bitlen 1 = 1"
  1130   by (simp add: bitlen_def)
  1131 
  1132 lemma mantissa_eq_zero_iff: "mantissa x = 0 \<longleftrightarrow> x = 0"
  1133 proof
  1134   assume "mantissa x = 0" hence z: "0 = real x" using mantissa_exponent by simp
  1135   show "x = 0" by (simp add: zero_float_def z)
  1136 qed (simp add: zero_float_def)
  1137 
  1138 lemma float_upper_bound: "x \<le> 2 powr (bitlen \<bar>mantissa x\<bar> + exponent x)"
  1139 proof (cases "x = 0", simp)
  1140   assume "x \<noteq> 0" hence "mantissa x \<noteq> 0" using mantissa_eq_zero_iff by auto
  1141   have "x = mantissa x * 2 powr (exponent x)" by (rule mantissa_exponent)
  1142   also have "mantissa x \<le> \<bar>mantissa x\<bar>" by simp
  1143   also have "... \<le> 2 powr (bitlen \<bar>mantissa x\<bar>)"
  1144     using bitlen_bounds[of "\<bar>mantissa x\<bar>"] bitlen_nonneg `mantissa x \<noteq> 0`
  1145     by (simp add: powr_int) (simp only: two_real_int int_of_reals real_of_int_abs[symmetric]
  1146       real_of_int_le_iff less_imp_le)
  1147   finally show ?thesis by (simp add: powr_add)
  1148 qed
  1149 
  1150 lemma float_divl_pos_less1_bound:
  1151   "0 < real x \<Longrightarrow> real x < 1 \<Longrightarrow> prec \<ge> 1 \<Longrightarrow> 1 \<le> real (float_divl prec 1 x)"
  1152 proof transfer
  1153   fix prec :: nat and x :: real assume x: "0 < x" "x < 1" "x \<in> float" and prec: "1 \<le> prec"
  1154   def p \<equiv> "int prec + \<lfloor>log 2 \<bar>x\<bar>\<rfloor>" 
  1155   show "1 \<le> round_down (int prec + \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - \<lfloor>log 2 \<bar>1\<bar>\<rfloor>) (1 / x) "
  1156   proof cases
  1157     assume nonneg: "0 \<le> p"
  1158     hence "2 powr real (p) = floor (real ((2::int) ^ nat p)) * floor (1::real)"
  1159       by (simp add: powr_int del: real_of_int_power) simp
  1160     also have "floor (1::real) \<le> floor (1 / x)" using x prec by simp
  1161     also have "floor (real ((2::int) ^ nat p)) * floor (1 / x) \<le>
  1162       floor (real ((2::int) ^ nat p) * (1 / x))"
  1163       by (rule le_mult_floor) (auto simp: x prec less_imp_le)
  1164     finally have "2 powr real p \<le> floor (2 powr nat p / x)" by (simp add: powr_realpow)
  1165     thus ?thesis unfolding p_def[symmetric]
  1166       using x prec nonneg by (simp add: powr_minus inverse_eq_divide round_down_def)
  1167   next
  1168     assume neg: "\<not> 0 \<le> p"
  1169 
  1170     have "x = 2 powr (log 2 x)"
  1171       using x by simp
  1172     also have "2 powr (log 2 x) \<le> 2 powr p"
  1173     proof (rule powr_mono)
  1174       have "log 2 x \<le> \<lceil>log 2 x\<rceil>"
  1175         by simp
  1176       also have "\<dots> \<le> \<lfloor>log 2 x\<rfloor> + 1"
  1177         using ceiling_diff_floor_le_1[of "log 2 x"] by simp
  1178       also have "\<dots> \<le> \<lfloor>log 2 x\<rfloor> + prec"
  1179         using prec by simp
  1180       finally show "log 2 x \<le> real p"
  1181         using x by (simp add: p_def)
  1182     qed simp
  1183     finally have x_le: "x \<le> 2 powr p" .
  1184 
  1185     from neg have "2 powr real p \<le> 2 powr 0"
  1186       by (intro powr_mono) auto
  1187     also have "\<dots> \<le> \<lfloor>2 powr 0\<rfloor>" by simp
  1188     also have "\<dots> \<le> \<lfloor>2 powr real p / x\<rfloor>" unfolding real_of_int_le_iff
  1189       using x x_le by (intro floor_mono) (simp add:  pos_le_divide_eq mult_pos_pos)
  1190     finally show ?thesis
  1191       using prec x unfolding p_def[symmetric]
  1192       by (simp add: round_down_def powr_minus_divide pos_le_divide_eq mult_pos_pos)
  1193   qed
  1194 qed
  1195 
  1196 lemma float_divr: "real x / real y \<le> real (float_divr prec x y)"
  1197   using round_up by transfer simp
  1198 
  1199 lemma float_divr_pos_less1_lower_bound: assumes "0 < x" and "x < 1" shows "1 \<le> float_divr prec 1 x"
  1200 proof -
  1201   have "1 \<le> 1 / real x" using `0 < x` and `x < 1` by auto
  1202   also have "\<dots> \<le> real (float_divr prec 1 x)" using float_divr[where x=1 and y=x] by auto
  1203   finally show ?thesis by auto
  1204 qed
  1205 
  1206 lemma float_divr_nonpos_pos_upper_bound:
  1207   "real x \<le> 0 \<Longrightarrow> 0 < real y \<Longrightarrow> real (float_divr prec x y) \<le> 0"
  1208   by transfer (auto simp: field_simps mult_le_0_iff divide_le_0_iff round_up_def)
  1209 
  1210 lemma float_divr_nonneg_neg_upper_bound:
  1211   "0 \<le> real x \<Longrightarrow> real y < 0 \<Longrightarrow> real (float_divr prec x y) \<le> 0"
  1212   by transfer (auto simp: field_simps mult_le_0_iff zero_le_mult_iff divide_le_0_iff round_up_def)
  1213 
  1214 lift_definition float_round_up :: "nat \<Rightarrow> float \<Rightarrow> float" is
  1215   "\<lambda>(prec::nat) x. round_up (prec - \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - 1) x" by simp
  1216 
  1217 lemma float_round_up: "real x \<le> real (float_round_up prec x)"
  1218   using round_up by transfer simp
  1219 
  1220 lift_definition float_round_down :: "nat \<Rightarrow> float \<Rightarrow> float" is
  1221   "\<lambda>(prec::nat) x. round_down (prec - \<lfloor>log 2 \<bar>x\<bar>\<rfloor> - 1) x" by simp
  1222 
  1223 lemma float_round_down: "real (float_round_down prec x) \<le> real x"
  1224   using round_down by transfer simp
  1225 
  1226 lemma floor_add2[simp]: "\<lfloor> real i + x \<rfloor> = i + \<lfloor> x \<rfloor>"
  1227   using floor_add[of x i] by (simp del: floor_add add: ac_simps)
  1228 
  1229 lemma compute_float_round_down[code]:
  1230   "float_round_down prec (Float m e) = (let d = bitlen (abs m) - int prec in
  1231     if 0 < d then let P = 2^nat d ; n = m div P in Float n (e + d)
  1232              else Float m e)"
  1233   using Float.compute_float_down[of "prec - bitlen \<bar>m\<bar> - e" m e, symmetric]
  1234   by transfer (simp add: field_simps abs_mult log_mult bitlen_def cong del: if_weak_cong)
  1235 hide_fact (open) compute_float_round_down
  1236 
  1237 lemma compute_float_round_up[code]:
  1238   "float_round_up prec (Float m e) = (let d = (bitlen (abs m) - int prec) in
  1239      if 0 < d then let P = 2^nat d ; n = m div P ; r = m mod P
  1240                    in Float (n + (if r = 0 then 0 else 1)) (e + d)
  1241               else Float m e)"
  1242   using Float.compute_float_up[of "prec - bitlen \<bar>m\<bar> - e" m e, symmetric]
  1243   unfolding Let_def
  1244   by transfer (simp add: field_simps abs_mult log_mult bitlen_def cong del: if_weak_cong)
  1245 hide_fact (open) compute_float_round_up
  1246 
  1247 lemma Float_le_zero_iff: "Float a b \<le> 0 \<longleftrightarrow> a \<le> 0"
  1248  apply (auto simp: zero_float_def mult_le_0_iff)
  1249  using powr_gt_zero[of 2 b] by simp
  1250 
  1251 lemma real_of_float_pprt[simp]: fixes a::float shows "real (pprt a) = pprt (real a)"
  1252   unfolding pprt_def sup_float_def max_def sup_real_def by auto
  1253 
  1254 lemma real_of_float_nprt[simp]: fixes a::float shows "real (nprt a) = nprt (real a)"
  1255   unfolding nprt_def inf_float_def min_def inf_real_def by auto
  1256 
  1257 lift_definition int_floor_fl :: "float \<Rightarrow> int" is floor by simp
  1258 
  1259 lemma compute_int_floor_fl[code]:
  1260   "int_floor_fl (Float m e) = (if 0 \<le> e then m * 2 ^ nat e else m div (2 ^ (nat (-e))))"
  1261   by transfer (simp add: powr_int int_of_reals floor_divide_eq_div del: real_of_ints)
  1262 hide_fact (open) compute_int_floor_fl
  1263 
  1264 lift_definition floor_fl :: "float \<Rightarrow> float" is "\<lambda>x. real (floor x)" by simp
  1265 
  1266 lemma compute_floor_fl[code]:
  1267   "floor_fl (Float m e) = (if 0 \<le> e then Float m e else Float (m div (2 ^ (nat (-e)))) 0)"
  1268   by transfer (simp add: powr_int int_of_reals floor_divide_eq_div del: real_of_ints)
  1269 hide_fact (open) compute_floor_fl
  1270 
  1271 lemma floor_fl: "real (floor_fl x) \<le> real x" by transfer simp
  1272 
  1273 lemma int_floor_fl: "real (int_floor_fl x) \<le> real x" by transfer simp
  1274 
  1275 lemma floor_pos_exp: "exponent (floor_fl x) \<ge> 0"
  1276 proof cases
  1277   assume nzero: "floor_fl x \<noteq> float_of 0"
  1278   have "floor_fl x = Float \<lfloor>real x\<rfloor> 0" by transfer simp
  1279   from denormalize_shift[OF this[THEN eq_reflection] nzero] guess i . note i = this
  1280   thus ?thesis by simp
  1281 qed (simp add: floor_fl_def)
  1282 
  1283 end
  1284