src/Pure/context.ML
author haftmann
Thu Oct 22 13:48:06 2009 +0200 (2009-10-22)
changeset 33063 4d462963a7db
parent 33033 fcc77a029bb2
child 33517 d064fa48f305
permissions -rw-r--r--
map_range (and map_index) combinator
     1 (*  Title:      Pure/context.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Generic theory contexts with unique identity, arbitrarily typed data,
     5 monotonic development graph and history support.  Generic proof
     6 contexts with arbitrarily typed data.
     7 
     8 Firm naming conventions:
     9    thy, thy', thy1, thy2: theory
    10    ctxt, ctxt', ctxt1, ctxt2: Proof.context
    11    context: Context.generic
    12 *)
    13 
    14 signature BASIC_CONTEXT =
    15 sig
    16   type theory
    17   type theory_ref
    18   exception THEORY of string * theory list
    19   structure Proof: sig type context end
    20   structure ProofContext:
    21   sig
    22     val theory_of: Proof.context -> theory
    23     val init: theory -> Proof.context
    24   end
    25 end;
    26 
    27 signature CONTEXT =
    28 sig
    29   include BASIC_CONTEXT
    30   (*theory context*)
    31   val parents_of: theory -> theory list
    32   val ancestors_of: theory -> theory list
    33   val theory_name: theory -> string
    34   val is_stale: theory -> bool
    35   val is_draft: theory -> bool
    36   val reject_draft: theory -> theory
    37   val PureN: string
    38   val display_names: theory -> string list
    39   val pretty_thy: theory -> Pretty.T
    40   val string_of_thy: theory -> string
    41   val pretty_abbrev_thy: theory -> Pretty.T
    42   val str_of_thy: theory -> string
    43   val deref: theory_ref -> theory
    44   val check_thy: theory -> theory_ref
    45   val eq_thy: theory * theory -> bool
    46   val subthy: theory * theory -> bool
    47   val joinable: theory * theory -> bool
    48   val merge: theory * theory -> theory
    49   val merge_refs: theory_ref * theory_ref -> theory_ref
    50   val copy_thy: theory -> theory
    51   val checkpoint_thy: theory -> theory
    52   val finish_thy: theory -> theory
    53   val begin_thy: (theory -> Pretty.pp) -> string -> theory list -> theory
    54   (*proof context*)
    55   val raw_transfer: theory -> Proof.context -> Proof.context
    56   (*generic context*)
    57   datatype generic = Theory of theory | Proof of Proof.context
    58   val cases: (theory -> 'a) -> (Proof.context -> 'a) -> generic -> 'a
    59   val mapping: (theory -> theory) -> (Proof.context -> Proof.context) -> generic -> generic
    60   val mapping_result: (theory -> 'a * theory) -> (Proof.context -> 'a * Proof.context) ->
    61     generic -> 'a * generic
    62   val the_theory: generic -> theory
    63   val the_proof: generic -> Proof.context
    64   val map_theory: (theory -> theory) -> generic -> generic
    65   val map_proof: (Proof.context -> Proof.context) -> generic -> generic
    66   val map_theory_result: (theory -> 'a * theory) -> generic -> 'a * generic
    67   val map_proof_result: (Proof.context -> 'a * Proof.context) -> generic -> 'a * generic
    68   val theory_map: (generic -> generic) -> theory -> theory
    69   val proof_map: (generic -> generic) -> Proof.context -> Proof.context
    70   val theory_of: generic -> theory  (*total*)
    71   val proof_of: generic -> Proof.context  (*total*)
    72   (*thread data*)
    73   val thread_data: unit -> generic option
    74   val the_thread_data: unit -> generic
    75   val set_thread_data: generic option -> unit
    76   val setmp_thread_data: generic option -> ('a -> 'b) -> 'a -> 'b
    77   val >> : (generic -> generic) -> unit
    78   val >>> : (generic -> 'a * generic) -> 'a
    79 end;
    80 
    81 signature PRIVATE_CONTEXT =
    82 sig
    83   include CONTEXT
    84   structure Theory_Data:
    85   sig
    86     val declare: Object.T -> (Object.T -> Object.T) -> (Object.T -> Object.T) ->
    87       (Pretty.pp -> Object.T * Object.T -> Object.T) -> serial
    88     val get: serial -> (Object.T -> 'a) -> theory -> 'a
    89     val put: serial -> ('a -> Object.T) -> 'a -> theory -> theory
    90   end
    91   structure Proof_Data:
    92   sig
    93     val declare: (theory -> Object.T) -> serial
    94     val get: serial -> (Object.T -> 'a) -> Proof.context -> 'a
    95     val put: serial -> ('a -> Object.T) -> 'a -> Proof.context -> Proof.context
    96   end
    97 end;
    98 
    99 structure Context: PRIVATE_CONTEXT =
   100 struct
   101 
   102 (*** theory context ***)
   103 
   104 (** theory data **)
   105 
   106 (* data kinds and access methods *)
   107 
   108 (*private copy avoids potential conflict of table exceptions*)
   109 structure Datatab = Table(type key = int val ord = int_ord);
   110 
   111 local
   112 
   113 type kind =
   114  {empty: Object.T,
   115   copy: Object.T -> Object.T,
   116   extend: Object.T -> Object.T,
   117   merge: Pretty.pp -> Object.T * Object.T -> Object.T};
   118 
   119 val kinds = Unsynchronized.ref (Datatab.empty: kind Datatab.table);
   120 
   121 fun invoke f k =
   122   (case Datatab.lookup (! kinds) k of
   123     SOME kind => f kind
   124   | NONE => sys_error "Invalid theory data identifier");
   125 
   126 in
   127 
   128 fun invoke_empty k = invoke (K o #empty) k ();
   129 val invoke_copy = invoke #copy;
   130 val invoke_extend = invoke #extend;
   131 fun invoke_merge pp = invoke (fn kind => #merge kind pp);
   132 
   133 fun declare_theory_data empty copy extend merge =
   134   let
   135     val k = serial ();
   136     val kind = {empty = empty, copy = copy, extend = extend, merge = merge};
   137     val _ = CRITICAL (fn () => Unsynchronized.change kinds (Datatab.update (k, kind)));
   138   in k end;
   139 
   140 val copy_data = Datatab.map' invoke_copy;
   141 val extend_data = Datatab.map' invoke_extend;
   142 
   143 fun merge_data pp (data1, data2) =
   144   Datatab.keys (Datatab.merge (K true) (data1, data2))
   145   |> Par_List.map (fn k =>
   146     (case (Datatab.lookup data1 k, Datatab.lookup data2 k) of
   147       (SOME x, NONE) => (k, invoke_extend k x)
   148     | (NONE, SOME y) => (k, invoke_extend k y)
   149     | (SOME x, SOME y) => (k, invoke_merge pp k (invoke_extend k x, invoke_extend k y))))
   150   |> Datatab.make;
   151 
   152 end;
   153 
   154 
   155 
   156 (** datatype theory **)
   157 
   158 datatype theory =
   159   Theory of
   160    (*identity*)
   161    {self: theory Unsynchronized.ref option,  (*dynamic self reference -- follows theory changes*)
   162     draft: bool,                  (*draft mode -- linear destructive changes*)
   163     id: serial,                   (*identifier*)
   164     ids: unit Inttab.table} *     (*cumulative identifiers of non-drafts -- symbolic body content*)
   165    (*data*)
   166    Object.T Datatab.table *       (*body content*)
   167    (*ancestry*)
   168    {parents: theory list,         (*immediate predecessors*)
   169     ancestors: theory list} *     (*all predecessors -- canonical reverse order*)
   170    (*history*)
   171    {name: string,                 (*official theory name*)
   172     stage: int};                  (*checkpoint counter*)
   173 
   174 exception THEORY of string * theory list;
   175 
   176 fun rep_theory (Theory args) = args;
   177 
   178 val identity_of = #1 o rep_theory;
   179 val data_of = #2 o rep_theory;
   180 val ancestry_of = #3 o rep_theory;
   181 val history_of = #4 o rep_theory;
   182 
   183 fun make_identity self draft id ids = {self = self, draft = draft, id = id, ids = ids};
   184 fun make_ancestry parents ancestors = {parents = parents, ancestors = ancestors};
   185 fun make_history name stage = {name = name, stage = stage};
   186 
   187 val the_self = the o #self o identity_of;
   188 val parents_of = #parents o ancestry_of;
   189 val ancestors_of = #ancestors o ancestry_of;
   190 val theory_name = #name o history_of;
   191 
   192 
   193 (* staleness *)
   194 
   195 fun eq_id (i: int, j) = i = j;
   196 
   197 fun is_stale
   198     (Theory ({self =
   199         SOME (Unsynchronized.ref (Theory ({id = id', ...}, _, _, _))), id, ...}, _, _, _)) =
   200       not (eq_id (id, id'))
   201   | is_stale (Theory ({self = NONE, ...}, _, _, _)) = true;
   202 
   203 fun vitalize (thy as Theory ({self = SOME r, ...}, _, _, _)) = (r := thy; thy)
   204   | vitalize (thy as Theory ({self = NONE, draft, id, ids}, data, ancestry, history)) =
   205       let
   206         val r = Unsynchronized.ref thy;
   207         val thy' = Theory (make_identity (SOME r) draft id ids, data, ancestry, history);
   208       in r := thy'; thy' end;
   209 
   210 
   211 (* draft mode *)
   212 
   213 val is_draft = #draft o identity_of;
   214 
   215 fun reject_draft thy =
   216   if is_draft thy then
   217     raise THEORY ("Illegal draft theory -- stable checkpoint required", [thy])
   218   else thy;
   219 
   220 
   221 (* names *)
   222 
   223 val PureN = "Pure";
   224 val draftN = "#";
   225 val finished = ~1;
   226 
   227 fun display_names thy =
   228   let
   229     val draft = if is_draft thy then [draftN] else [];
   230     val {stage, ...} = history_of thy;
   231     val name =
   232       if stage = finished then theory_name thy
   233       else theory_name thy ^ ":" ^ string_of_int stage;
   234     val ancestor_names = map theory_name (ancestors_of thy);
   235     val stale = if is_stale thy then ["!"] else [];
   236   in rev (stale @ draft @ [name] @ ancestor_names) end;
   237 
   238 val pretty_thy = Pretty.str_list "{" "}" o display_names;
   239 val string_of_thy = Pretty.string_of o pretty_thy;
   240 
   241 fun pretty_abbrev_thy thy =
   242   let
   243     val names = display_names thy;
   244     val n = length names;
   245     val abbrev = if n > 5 then "..." :: List.drop (names, n - 5) else names;
   246   in Pretty.str_list "{" "}" abbrev end;
   247 
   248 val str_of_thy = Pretty.str_of o pretty_abbrev_thy;
   249 
   250 
   251 (* theory references *)
   252 
   253 (*theory_ref provides a safe way to store dynamic references to a
   254   theory in external data structures -- a plain theory value would
   255   become stale as the self reference moves on*)
   256 
   257 datatype theory_ref = Theory_Ref of theory Unsynchronized.ref;
   258 
   259 fun deref (Theory_Ref (Unsynchronized.ref thy)) = thy;
   260 
   261 fun check_thy thy =  (*thread-safe version*)
   262   let val thy_ref = Theory_Ref (the_self thy) in
   263     if is_stale thy then error ("Stale theory encountered:\n" ^ string_of_thy thy)
   264     else thy_ref
   265   end;
   266 
   267 
   268 (* build ids *)
   269 
   270 fun insert_id draft id ids =
   271   if draft then ids
   272   else Inttab.update (id, ()) ids;
   273 
   274 fun merge_ids
   275     (Theory ({draft = draft1, id = id1, ids = ids1, ...}, _, _, _))
   276     (Theory ({draft = draft2, id = id2, ids = ids2, ...}, _, _, _)) =
   277   Inttab.merge (K true) (ids1, ids2)
   278   |> insert_id draft1 id1
   279   |> insert_id draft2 id2;
   280 
   281 
   282 (* equality and inclusion *)
   283 
   284 val eq_thy = eq_id o pairself (#id o identity_of);
   285 
   286 fun proper_subthy (Theory ({id, ...}, _, _, _), Theory ({ids, ...}, _, _, _)) =
   287   Inttab.defined ids id;
   288 
   289 fun subthy thys = eq_thy thys orelse proper_subthy thys;
   290 
   291 fun joinable (thy1, thy2) = subthy (thy1, thy2) orelse subthy (thy2, thy1);
   292 
   293 
   294 (* consistent ancestors *)
   295 
   296 fun extend_ancestors thy thys =
   297   if member eq_thy thys thy then
   298     raise THEORY ("Duplicate theory node", thy :: thys)
   299   else thy :: thys;
   300 
   301 fun extend_ancestors_of thy = extend_ancestors thy (ancestors_of thy);
   302 
   303 val merge_ancestors = merge (fn (thy1, thy2) =>
   304   eq_thy (thy1, thy2) orelse
   305     theory_name thy1 = theory_name thy2 andalso
   306       raise THEORY ("Inconsistent theory versions", [thy1, thy2]));
   307 
   308 
   309 (* trivial merge *)
   310 
   311 fun merge (thy1, thy2) =
   312   if eq_thy (thy1, thy2) then thy1
   313   else if proper_subthy (thy2, thy1) then thy1
   314   else if proper_subthy (thy1, thy2) then thy2
   315   else error (cat_lines ["Attempt to perform non-trivial merge of theories:",
   316     str_of_thy thy1, str_of_thy thy2]);
   317 
   318 fun merge_refs (ref1, ref2) =
   319   if ref1 = ref2 then ref1
   320   else check_thy (merge (deref ref1, deref ref2));
   321 
   322 
   323 
   324 (** build theories **)
   325 
   326 (* primitives *)
   327 
   328 fun create_thy self draft ids data ancestry history =
   329   let val identity = make_identity self draft (serial ()) ids;
   330   in vitalize (Theory (identity, data, ancestry, history)) end;
   331 
   332 fun change_thy draft' f thy =
   333   let
   334     val Theory ({self, draft, id, ids}, data, ancestry, history) = thy;
   335     val (self', data', ancestry') =
   336       if draft then (self, data, ancestry)    (*destructive change!*)
   337       else if #stage history > 0
   338       then (NONE, copy_data data, ancestry)
   339       else (NONE, extend_data data, make_ancestry [thy] (extend_ancestors_of thy));
   340     val ids' = insert_id draft id ids;
   341     val data'' = f data';
   342     val thy' = NAMED_CRITICAL "theory" (fn () =>
   343       (check_thy thy; create_thy self' draft' ids' data'' ancestry' history));
   344   in thy' end;
   345 
   346 val name_thy = change_thy false I;
   347 val extend_thy = change_thy true I;
   348 val modify_thy = change_thy true;
   349 
   350 fun copy_thy thy =
   351   let
   352     val Theory ({draft, id, ids, ...}, data, ancestry, history) = thy;
   353     val ids' = insert_id draft id ids;
   354     val data' = copy_data data;
   355     val thy' = NAMED_CRITICAL "theory" (fn () =>
   356       (check_thy thy; create_thy NONE true ids' data' ancestry history));
   357   in thy' end;
   358 
   359 val pre_pure_thy = create_thy NONE true Inttab.empty
   360   Datatab.empty (make_ancestry [] []) (make_history PureN 0);
   361 
   362 
   363 (* named theory nodes *)
   364 
   365 fun merge_thys pp (thy1, thy2) =
   366   let
   367     val ids = merge_ids thy1 thy2;
   368     val data = merge_data (pp thy1) (data_of thy1, data_of thy2);
   369     val ancestry = make_ancestry [] [];
   370     val history = make_history "" 0;
   371     val thy' = NAMED_CRITICAL "theory" (fn () =>
   372      (check_thy thy1; check_thy thy2; create_thy NONE true ids data ancestry history));
   373   in thy' end;
   374 
   375 fun maximal_thys thys =
   376   thys |> filter_out (fn thy => exists (fn thy' => proper_subthy (thy, thy')) thys);
   377 
   378 fun begin_thy pp name imports =
   379   if name = "" orelse name = draftN then error ("Bad theory name: " ^ quote name)
   380   else
   381     let
   382       val parents = maximal_thys (distinct eq_thy imports);
   383       val ancestors =
   384         Library.foldl merge_ancestors ([], map ancestors_of parents)
   385         |> fold extend_ancestors parents;
   386 
   387       val Theory ({ids, ...}, data, _, _) =
   388         (case parents of
   389           [] => error "No parent theories"
   390         | [thy] => extend_thy thy
   391         | thy :: thys => Library.foldl (merge_thys pp) (thy, thys));
   392 
   393       val ancestry = make_ancestry parents ancestors;
   394       val history = make_history name 0;
   395       val thy' = NAMED_CRITICAL "theory" (fn () =>
   396         (map check_thy imports; create_thy NONE true ids data ancestry history));
   397     in thy' end;
   398 
   399 
   400 (* history stages *)
   401 
   402 fun history_stage f thy =
   403   let
   404     val {name, stage} = history_of thy;
   405     val _ = stage = finished andalso raise THEORY ("Theory already finished", [thy]);
   406     val history' = make_history name (f stage);
   407     val thy' as Theory (identity', data', ancestry', _) = name_thy thy;
   408     val thy'' = NAMED_CRITICAL "theory" (fn () =>
   409       (check_thy thy'; vitalize (Theory (identity', data', ancestry', history'))));
   410   in thy'' end;
   411 
   412 fun checkpoint_thy thy =
   413   if is_draft thy then history_stage (fn stage => stage + 1) thy
   414   else thy;
   415 
   416 val finish_thy = history_stage (fn _ => finished);
   417 
   418 
   419 (* theory data *)
   420 
   421 structure Theory_Data =
   422 struct
   423 
   424 val declare = declare_theory_data;
   425 
   426 fun get k dest thy =
   427   dest ((case Datatab.lookup (data_of thy) k of
   428     SOME x => x
   429   | NONE => invoke_copy k (invoke_empty k)));   (*adhoc value*)
   430 
   431 fun put k mk x = modify_thy (Datatab.update (k, mk x));
   432 
   433 end;
   434 
   435 
   436 
   437 (*** proof context ***)
   438 
   439 (* datatype Proof.context *)
   440 
   441 structure Proof =
   442 struct
   443   datatype context = Context of Object.T Datatab.table * theory_ref;
   444 end;
   445 
   446 fun theory_of_proof (Proof.Context (_, thy_ref)) = deref thy_ref;
   447 fun data_of_proof (Proof.Context (data, _)) = data;
   448 fun map_prf f (Proof.Context (data, thy_ref)) = Proof.Context (f data, thy_ref);
   449 
   450 
   451 (* proof data kinds *)
   452 
   453 local
   454 
   455 val kinds = Unsynchronized.ref (Datatab.empty: (theory -> Object.T) Datatab.table);
   456 
   457 fun invoke_init k =
   458   (case Datatab.lookup (! kinds) k of
   459     SOME init => init
   460   | NONE => sys_error "Invalid proof data identifier");
   461 
   462 fun init_data thy =
   463   Datatab.map' (fn k => fn _ => invoke_init k thy) (! kinds);
   464 
   465 fun init_new_data data thy =
   466   Datatab.merge (K true) (data, init_data thy);
   467 
   468 in
   469 
   470 fun raw_transfer thy' (Proof.Context (data, thy_ref)) =
   471   let
   472     val thy = deref thy_ref;
   473     val _ = subthy (thy, thy') orelse error "transfer proof context: not a super theory";
   474     val _ = check_thy thy;
   475     val data' = init_new_data data thy';
   476     val thy_ref' = check_thy thy';
   477   in Proof.Context (data', thy_ref') end;
   478 
   479 structure ProofContext =
   480 struct
   481   val theory_of = theory_of_proof;
   482   fun init thy = Proof.Context (init_data thy, check_thy thy);
   483 end;
   484 
   485 structure Proof_Data =
   486 struct
   487 
   488 fun declare init =
   489   let
   490     val k = serial ();
   491     val _ = CRITICAL (fn () => Unsynchronized.change kinds (Datatab.update (k, init)));
   492   in k end;
   493 
   494 fun get k dest prf =
   495   dest (case Datatab.lookup (data_of_proof prf) k of
   496     SOME x => x
   497   | NONE => invoke_init k (ProofContext.theory_of prf));   (*adhoc value*)
   498 
   499 fun put k mk x = map_prf (Datatab.update (k, mk x));
   500 
   501 end;
   502 
   503 end;
   504 
   505 
   506 
   507 (*** generic context ***)
   508 
   509 datatype generic = Theory of theory | Proof of Proof.context;
   510 
   511 fun cases f _ (Theory thy) = f thy
   512   | cases _ g (Proof prf) = g prf;
   513 
   514 fun mapping f g = cases (Theory o f) (Proof o g);
   515 fun mapping_result f g = cases (apsnd Theory o f) (apsnd Proof o g);
   516 
   517 val the_theory = cases I (fn _ => error "Ill-typed context: theory expected");
   518 val the_proof = cases (fn _ => error "Ill-typed context: proof expected") I;
   519 
   520 fun map_theory f = Theory o f o the_theory;
   521 fun map_proof f = Proof o f o the_proof;
   522 
   523 fun map_theory_result f = apsnd Theory o f o the_theory;
   524 fun map_proof_result f = apsnd Proof o f o the_proof;
   525 
   526 fun theory_map f = the_theory o f o Theory;
   527 fun proof_map f = the_proof o f o Proof;
   528 
   529 val theory_of = cases I ProofContext.theory_of;
   530 val proof_of = cases ProofContext.init I;
   531 
   532 
   533 
   534 (** thread data **)
   535 
   536 local val tag = Universal.tag () : generic option Universal.tag in
   537 
   538 fun thread_data () =
   539   (case Thread.getLocal tag of
   540     SOME (SOME context) => SOME context
   541   | _ => NONE);
   542 
   543 fun the_thread_data () =
   544   (case thread_data () of
   545     SOME context => context
   546   | _ => error "Unknown context");
   547 
   548 fun set_thread_data context = Thread.setLocal (tag, context);
   549 fun setmp_thread_data context = Library.setmp_thread_data tag (thread_data ()) context;
   550 
   551 end;
   552 
   553 fun >>> f =
   554   let
   555     val (res, context') = f (the_thread_data ());
   556     val _ = set_thread_data (SOME context');
   557   in res end;
   558 
   559 nonfix >>;
   560 fun >> f = >>> (fn context => ((), f context));
   561 
   562 val _ = set_thread_data (SOME (Theory pre_pure_thy));
   563 
   564 end;
   565 
   566 structure Basic_Context: BASIC_CONTEXT = Context;
   567 open Basic_Context;
   568 
   569 
   570 
   571 (*** type-safe interfaces for data declarations ***)
   572 
   573 (** theory data **)
   574 
   575 signature THEORY_DATA_ARGS =
   576 sig
   577   type T
   578   val empty: T
   579   val copy: T -> T
   580   val extend: T -> T
   581   val merge: Pretty.pp -> T * T -> T
   582 end;
   583 
   584 signature THEORY_DATA =
   585 sig
   586   type T
   587   val get: theory -> T
   588   val put: T -> theory -> theory
   589   val map: (T -> T) -> theory -> theory
   590   val init: theory -> theory
   591 end;
   592 
   593 functor TheoryDataFun(Data: THEORY_DATA_ARGS): THEORY_DATA =
   594 struct
   595 
   596 type T = Data.T;
   597 exception Data of T;
   598 
   599 val kind = Context.Theory_Data.declare
   600   (Data Data.empty)
   601   (fn Data x => Data (Data.copy x))
   602   (fn Data x => Data (Data.extend x))
   603   (fn pp => fn (Data x1, Data x2) => Data (Data.merge pp (x1, x2)));
   604 
   605 val get = Context.Theory_Data.get kind (fn Data x => x);
   606 val put = Context.Theory_Data.put kind Data;
   607 fun map f thy = put (f (get thy)) thy;
   608 
   609 fun init thy = map I thy;
   610 
   611 end;
   612 
   613 
   614 
   615 (** proof data **)
   616 
   617 signature PROOF_DATA_ARGS =
   618 sig
   619   type T
   620   val init: theory -> T
   621 end;
   622 
   623 signature PROOF_DATA =
   624 sig
   625   type T
   626   val get: Proof.context -> T
   627   val put: T -> Proof.context -> Proof.context
   628   val map: (T -> T) -> Proof.context -> Proof.context
   629 end;
   630 
   631 functor ProofDataFun(Data: PROOF_DATA_ARGS): PROOF_DATA =
   632 struct
   633 
   634 type T = Data.T;
   635 exception Data of T;
   636 
   637 val kind = Context.Proof_Data.declare (Data o Data.init);
   638 
   639 val get = Context.Proof_Data.get kind (fn Data x => x);
   640 val put = Context.Proof_Data.put kind Data;
   641 fun map f prf = put (f (get prf)) prf;
   642 
   643 end;
   644 
   645 
   646 
   647 (** generic data **)
   648 
   649 signature GENERIC_DATA_ARGS =
   650 sig
   651   type T
   652   val empty: T
   653   val extend: T -> T
   654   val merge: Pretty.pp -> T * T -> T
   655 end;
   656 
   657 signature GENERIC_DATA =
   658 sig
   659   type T
   660   val get: Context.generic -> T
   661   val put: T -> Context.generic -> Context.generic
   662   val map: (T -> T) -> Context.generic -> Context.generic
   663 end;
   664 
   665 functor GenericDataFun(Data: GENERIC_DATA_ARGS): GENERIC_DATA =
   666 struct
   667 
   668 structure Thy_Data = TheoryDataFun(open Data val copy = I);
   669 structure Prf_Data = ProofDataFun(type T = Data.T val init = Thy_Data.get);
   670 
   671 type T = Data.T;
   672 
   673 fun get (Context.Theory thy) = Thy_Data.get thy
   674   | get (Context.Proof prf) = Prf_Data.get prf;
   675 
   676 fun put x (Context.Theory thy) = Context.Theory (Thy_Data.put x thy)
   677   | put x (Context.Proof prf) = Context.Proof (Prf_Data.put x prf);
   678 
   679 fun map f ctxt = put (f (get ctxt)) ctxt;
   680 
   681 end;
   682 
   683 (*hide private interface*)
   684 structure Context: CONTEXT = Context;
   685